git.notmuchmail.org Git - notmuch/blob - notmuch.el

   1 ; notmuch.el --- run notmuch within emacs
   2 ;
   3 ; Copyright © Carl Worth
   4 ;
   5 ; This file is part of Notmuch.
   6 ;
   7 ; Notmuch is free software: you can redistribute it and/or modify it
   8 ; under the terms of the GNU General Public License as published by
   9 ; the Free Software Foundation, either version 3 of the License, or
  10 ; (at your option) any later version.
  11 ;
  12 ; Notmuch is distributed in the hope that it will be useful, but
  13 ; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 ; General Public License for more details.
  16 ;
  17 ; You should have received a copy of the GNU General Public License
  18 ; along with Notmuch.  If not, see <http://www.gnu.org/licenses/>.
  19 ;
  20 ; Authors: Carl Worth <cworth@cworth.org>
  21
  22 ; This is an emacs-based interface to the notmuch mail system.
  23 ;
  24 ; You will first need to have the notmuch program installed and have a
  25 ; notmuch database built in order to use this. See
  26 ; http://notmuchmail.org for details.
  27 ;
  28 ; To install this software, copy it to a directory that is on the
  29 ; `load-path' variable within emacs (a good candidate is
  30 ; /usr/local/share/emacs/site-lisp). If you are viewing this from the
  31 ; notmuch source distribution then you can simply run:
  32 ;
  33 ;       sudo make install-emacs
  34 ;
  35 ; to install it.
  36 ;
  37 ; Then, to actually run it, add:
  38 ;
  39 ;       (require 'notmuch)
  40 ;
  41 ; to your ~/.emacs file, and then run "M-x notmuch" from within emacs,
  42 ; or run:
  43 ;
  44 ;       emacs -f notmuch
  45 ;
  46 ; Have fun, and let us know if you have any comment, questions, or
  47 ; kudos: Notmuch list <notmuch@notmuchmail.org> (subscription is not
  48 ; required, but is available from http://notmuchmail.org).
  49
  50 (require 'cl)
  51 (require 'mm-view)
  52 (require 'message)
  53
  54 (defvar notmuch-show-mode-map
  55   (let ((map (make-sparse-keymap)))
  56     (define-key map "?" 'notmuch-help)
  57     (define-key map "q" 'kill-this-buffer)
  58     (define-key map (kbd "C-p") 'notmuch-show-previous-line)
  59     (define-key map (kbd "C-n") 'notmuch-show-next-line)
  60     (define-key map (kbd "M-TAB") 'notmuch-show-previous-button)
  61     (define-key map (kbd "TAB") 'notmuch-show-next-button)
  62     (define-key map "s" 'notmuch-search)
  63     (define-key map "m" 'message-mail)
  64     (define-key map "f" 'notmuch-show-forward-current)
  65     (define-key map "r" 'notmuch-show-reply)
  66     (define-key map "|" 'notmuch-show-pipe-message)
  67     (define-key map "w" 'notmuch-show-save-attachments)
  68     (define-key map "V" 'notmuch-show-view-raw-message)
  69     (define-key map "v" 'notmuch-show-view-all-mime-parts)
  70     (define-key map "-" 'notmuch-show-remove-tag)
  71     (define-key map "+" 'notmuch-show-add-tag)
  72     (define-key map "X" 'notmuch-show-mark-read-then-archive-then-exit)
  73     (define-key map "x" 'notmuch-show-archive-thread-then-exit)
  74     (define-key map "A" 'notmuch-show-mark-read-then-archive-thread)
  75     (define-key map "a" 'notmuch-show-archive-thread)
  76     (define-key map "p" 'notmuch-show-previous-message)
  77     (define-key map "N" 'notmuch-show-mark-read-then-next-open-message)
  78     (define-key map "n" 'notmuch-show-next-message)
  79     (define-key map (kbd "DEL") 'notmuch-show-rewind)
  80     (define-key map " " 'notmuch-show-advance-marking-read-and-archiving)
  81     map)
  82   "Keymap for \"notmuch show\" buffers.")
  83 (fset 'notmuch-show-mode-map notmuch-show-mode-map)
  84
  85 (defvar notmuch-show-signature-regexp "\\(-- ?\\|_+\\)$"
  86   "Pattern to match a line that separates content from signature.
  87
  88 The regexp can (and should) include $ to match the end of the
  89 line, but should not include ^ to match the beginning of the
  90 line. This is because notmuch may have inserted additional space
  91 for indentation at the beginning of the line. But notmuch will
  92 move past the indentation when testing this pattern, (so that the
  93 pattern can still test against the entire line).")
  94
  95 (defvar notmuch-show-signature-lines-max 12
  96   "Maximum length of signature that will be hidden by default.")
  97
  98 (defvar notmuch-command "notmuch"
  99   "Command to run the notmuch binary.")
 100
 101 (defvar notmuch-show-message-begin-regexp    "\fmessage{")
 102 (defvar notmuch-show-message-end-regexp      "\fmessage}")
 103 (defvar notmuch-show-header-begin-regexp     "\fheader{")
 104 (defvar notmuch-show-header-end-regexp       "\fheader}")
 105 (defvar notmuch-show-body-begin-regexp       "\fbody{")
 106 (defvar notmuch-show-body-end-regexp         "\fbody}")
 107 (defvar notmuch-show-attachment-begin-regexp "\fattachment{")
 108 (defvar notmuch-show-attachment-end-regexp   "\fattachment}")
 109 (defvar notmuch-show-part-begin-regexp       "\fpart{")
 110 (defvar notmuch-show-part-end-regexp         "\fpart}")
 111 (defvar notmuch-show-marker-regexp "\f\\(message\\|header\\|body\\|attachment\\|part\\)[{}].*$")
 112
 113 (defvar notmuch-show-id-regexp "\\(id:[^ ]*\\)")
 114 (defvar notmuch-show-depth-match-regexp " depth:\\([0-9]*\\).*match:\\([01]\\) ")
 115 (defvar notmuch-show-filename-regexp "filename:\\(.*\\)$")
 116 (defvar notmuch-show-tags-regexp "(\\([^)]*\\))$")
 117
 118 (defvar notmuch-show-parent-buffer nil)
 119 (defvar notmuch-show-body-read-visible nil)
 120 (defvar notmuch-show-citations-visible nil)
 121 (defvar notmuch-show-signatures-visible nil)
 122 (defvar notmuch-show-headers-visible nil)
 123
 124 ; XXX: This should be a generic function in emacs somewhere, not here
 125 (defun point-invisible-p ()
 126   "Return whether the character at point is invisible.
 127
 128 Here visibility is determined by `buffer-invisibility-spec' and
 129 the invisible property of any overlays for point. It doesn't have
 130 anything to do with whether point is currently being displayed
 131 within the current window."
 132   (let ((prop (get-char-property (point) 'invisible)))
 133     (if (eq buffer-invisibility-spec t)
 134         prop
 135       (or (memq prop buffer-invisibility-spec)
 136           (assq prop buffer-invisibility-spec)))))
 137
 138 (defun notmuch-select-tag-with-completion (prompt &rest search-terms)
 139   (let ((tag-list
 140          (with-output-to-string
 141            (with-current-buffer standard-output
 142              (apply 'call-process notmuch-command nil t nil "search-tags" search-terms)))))
 143     (completing-read prompt (split-string tag-list "\n+" t) nil nil nil)))
 144
 145 (defun notmuch-show-next-line ()
 146   "Like builtin `next-line' but ensuring we end on a visible character.
 147
 148 By advancing forward until reaching a visible character.
 149
 150 Unlike builtin `next-line' this version accepts no arguments."
 151   (interactive)
 152   (set 'this-command 'next-line)
 153   (call-interactively 'next-line)
 154   (while (point-invisible-p)
 155     (forward-char)))
 156
 157 (defun notmuch-show-previous-line ()
 158   "Like builtin `previous-line' but ensuring we end on a visible character.
 159
 160 By advancing forward until reaching a visible character.
 161
 162 Unlike builtin `previous-line' this version accepts no arguments."
 163   (interactive)
 164   (set 'this-command 'previous-line)
 165   (call-interactively 'previous-line)
 166   (while (point-invisible-p)
 167     (forward-char)))
 168
 169 (defun notmuch-show-get-message-id ()
 170   (save-excursion
 171     (beginning-of-line)
 172     (if (not (looking-at notmuch-show-message-begin-regexp))
 173         (re-search-backward notmuch-show-message-begin-regexp))
 174     (re-search-forward notmuch-show-id-regexp)
 175     (buffer-substring-no-properties (match-beginning 1) (match-end 1))))
 176
 177 (defun notmuch-show-get-filename ()
 178   (save-excursion
 179     (beginning-of-line)
 180     (if (not (looking-at notmuch-show-message-begin-regexp))
 181         (re-search-backward notmuch-show-message-begin-regexp))
 182     (re-search-forward notmuch-show-filename-regexp)
 183     (buffer-substring-no-properties (match-beginning 1) (match-end 1))))
 184
 185 (defun notmuch-show-set-tags (tags)
 186   (save-excursion
 187     (beginning-of-line)
 188     (if (not (looking-at notmuch-show-message-begin-regexp))
 189         (re-search-backward notmuch-show-message-begin-regexp))
 190     (re-search-forward notmuch-show-tags-regexp)
 191     (let ((inhibit-read-only t)
 192           (beg (match-beginning 1))
 193           (end (match-end 1)))
 194       (delete-region beg end)
 195       (goto-char beg)
 196       (insert (mapconcat 'identity tags " ")))))
 197
 198 (defun notmuch-show-get-tags ()
 199   (save-excursion
 200     (beginning-of-line)
 201     (if (not (looking-at notmuch-show-message-begin-regexp))
 202         (re-search-backward notmuch-show-message-begin-regexp))
 203     (re-search-forward notmuch-show-tags-regexp)
 204     (split-string (buffer-substring (match-beginning 1) (match-end 1)))))
 205
 206 (defun notmuch-show-add-tag (&rest toadd)
 207   "Add a tag to the current message."
 208   (interactive
 209    (list (notmuch-select-tag-with-completion "Tag to add: ")))
 210   (apply 'notmuch-call-notmuch-process
 211          (append (cons "tag"
 212                        (mapcar (lambda (s) (concat "+" s)) toadd))
 213                  (cons (notmuch-show-get-message-id) nil)))
 214   (notmuch-show-set-tags (sort (union toadd (notmuch-show-get-tags) :test 'string=) 'string<)))
 215
 216 (defun notmuch-show-remove-tag (&rest toremove)
 217   "Remove a tag from the current message."
 218   (interactive
 219    (list (notmuch-select-tag-with-completion "Tag to remove: " (notmuch-show-get-message-id))))
 220   (let ((tags (notmuch-show-get-tags)))
 221     (if (intersection tags toremove :test 'string=)
 222         (progn
 223           (apply 'notmuch-call-notmuch-process
 224                  (append (cons "tag"
 225                                (mapcar (lambda (s) (concat "-" s)) toremove))
 226                          (cons (notmuch-show-get-message-id) nil)))
 227           (notmuch-show-set-tags (sort (set-difference tags toremove :test 'string=) 'string<))))))
 228
 229 (defun notmuch-show-archive-thread-maybe-mark-read (markread)
 230   (save-excursion
 231     (goto-char (point-min))
 232     (while (not (eobp))
 233       (if markread
 234           (notmuch-show-remove-tag "unread" "inbox")
 235         (notmuch-show-remove-tag "inbox"))
 236       (if (not (eobp))
 237           (forward-char))
 238       (if (not (re-search-forward notmuch-show-message-begin-regexp nil t))
 239           (goto-char (point-max)))))
 240   (let ((parent-buffer notmuch-show-parent-buffer))
 241     (kill-this-buffer)
 242     (if parent-buffer
 243         (progn
 244           (switch-to-buffer parent-buffer)
 245           (forward-line)
 246           (notmuch-search-show-thread)))))
 247
 248 (defun notmuch-show-mark-read-then-archive-thread ()
 249   "Remove unread tags from thread, then archive and show next thread.
 250
 251 Archive each message currently shown by removing the \"unread\"
 252 and \"inbox\" tag from each. Then kill this buffer and show the
 253 next thread from the search from which this thread was originally
 254 shown.
 255
 256 Note: This command is safe from any race condition of new messages
 257 being delivered to the same thread. It does not archive the
 258 entire thread, but only the messages shown in the current
 259 buffer."
 260   (interactive)
 261   (notmuch-show-archive-thread-maybe-mark-read t))
 262
 263 (defun notmuch-show-archive-thread ()
 264   "Archive each message in thread, then show next thread from search.
 265
 266 Archive each message currently shown by removing the \"inbox\"
 267 tag from each. Then kill this buffer and show the next thread
 268 from the search from which this thread was originally shown.
 269
 270 Note: This command is safe from any race condition of new messages
 271 being delivered to the same thread. It does not archive the
 272 entire thread, but only the messages shown in the current
 273 buffer."
 274   (interactive)
 275   (notmuch-show-archive-thread-maybe-mark-read nil))
 276
 277 (defun notmuch-show-archive-thread-then-exit ()
 278   "Archive each message in thread, then exit back to search results."
 279   (interactive)
 280   (notmuch-show-archive-thread)
 281   (kill-this-buffer))
 282
 283 (defun notmuch-show-mark-read-then-archive-then-exit ()
 284   "Remove unread tags from thread, then archive and exit to search results."
 285   (interactive)
 286   (notmuch-show-mark-read-then-archive-thread)
 287   (kill-this-buffer))
 288
 289 (defun notmuch-show-view-raw-message ()
 290   "View the raw email of the current message."
 291   (interactive)
 292   (view-file (notmuch-show-get-filename)))
 293
 294 (defmacro with-current-notmuch-show-message (&rest body)
 295   "Evaluate body with current buffer set to the text of current message"
 296   `(save-excursion
 297      (let ((filename (notmuch-show-get-filename)))
 298        (let ((buf (generate-new-buffer (concat "*notmuch-msg-" filename "*"))))
 299          (with-current-buffer buf
 300            (insert-file-contents filename nil nil nil t)
 301            ,@body)
 302         (kill-buffer buf)))))
 303
 304 (defun notmuch-show-view-all-mime-parts ()
 305   "Use external viewers to view all attachments from the current message."
 306   (interactive)
 307   (with-current-notmuch-show-message
 308    (mm-display-parts (mm-dissect-buffer))))
 309
 310 (defun notmuch-foreach-mime-part (function mm-handle)
 311   (cond ((stringp (car mm-handle))
 312          (dolist (part (cdr mm-handle))
 313            (notmuch-foreach-mime-part function part)))
 314         ((bufferp (car mm-handle))
 315          (funcall function mm-handle))
 316         (t (dolist (part mm-handle)
 317              (notmuch-foreach-mime-part function part)))))
 318
 319 (defun notmuch-count-attachments (mm-handle)
 320   (let ((count 0))
 321     (notmuch-foreach-mime-part
 322      (lambda (p)
 323        (let ((disposition (mm-handle-disposition p)))
 324          (and (listp disposition)
 325               (equal (car disposition) "attachment")
 326               (incf count))))
 327      mm-handle)
 328     count))
 329
 330 (defun notmuch-save-attachments (mm-handle &optional queryp)
 331   (notmuch-foreach-mime-part
 332    (lambda (p)
 333      (let ((disposition (mm-handle-disposition p)))
 334        (and (listp disposition)
 335             (equal (car disposition) "attachment")
 336             (or (not queryp)
 337                 (y-or-n-p
 338                  (concat "Save '" (cdr (assq 'filename disposition)) "' ")))
 339             (mm-save-part p))))
 340    mm-handle))
 341
 342 (defun notmuch-show-save-attachments ()
 343   "Save all attachments from the current message."
 344   (interactive)
 345   (with-current-notmuch-show-message
 346    (let ((mm-handle (mm-dissect-buffer)))
 347      (notmuch-save-attachments
 348       mm-handle (> (notmuch-count-attachments mm-handle) 1))))
 349   (message "Done"))
 350
 351 (defun notmuch-reply (query-string)
 352   (switch-to-buffer (generate-new-buffer "notmuch-draft"))
 353   (call-process notmuch-command nil t nil "reply" query-string)
 354   (message-insert-signature)
 355   (goto-char (point-min))
 356   (if (re-search-forward "^$" nil t)
 357       (progn
 358         (insert "--text follows this line--")
 359         (forward-line)))
 360   (message-mode))
 361
 362 (defun notmuch-show-reply ()
 363   "Begin composing a reply to the current message in a new buffer."
 364   (interactive)
 365   (let ((message-id (notmuch-show-get-message-id)))
 366     (notmuch-reply message-id)))
 367
 368 (defun notmuch-show-forward-current ()
 369   "Forward the current message."
 370   (interactive)
 371   (with-current-notmuch-show-message
 372    (message-forward)))
 373
 374 (defun notmuch-show-pipe-message (command)
 375   "Pipe the contents of the current message to the given command.
 376
 377 The given command will be executed with the raw contents of the
 378 current email message as stdin. Anything printed by the command
 379 to stdout or stderr will appear in the *Messages* buffer."
 380   (interactive "sPipe message to command: ")
 381   (apply 'start-process-shell-command "notmuch-pipe-command" "*notmuch-pipe*"
 382          (list command " < " (shell-quote-argument (notmuch-show-get-filename)))))
 383
 384 (defun notmuch-show-move-to-current-message-summary-line ()
 385   "Move to the beginning of the one-line summary of the current message.
 386
 387 This gives us a stable place to move to and work from since the
 388 summary line is always visible. This is important since moving to
 389 an invisible location is unreliable, (the main command loop moves
 390 point either forward or backward to the next visible character
 391 when a command ends with point on an invisible character).
 392
 393 Emits an error if point is not within a valid message, (that is
 394 no pattern of `notmuch-show-message-begin-regexp' could be found
 395 by searching backward)."
 396   (beginning-of-line)
 397   (if (not (looking-at notmuch-show-message-begin-regexp))
 398       (if (re-search-backward notmuch-show-message-begin-regexp nil t)
 399           (forward-line 2)
 400         (error "Not within a valid message."))
 401     (forward-line 2)))
 402
 403 (defun notmuch-show-last-message-p ()
 404   "Predicate testing whether point is within the last message."
 405   (save-window-excursion
 406     (save-excursion
 407       (notmuch-show-move-to-current-message-summary-line)
 408       (not (re-search-forward notmuch-show-message-begin-regexp nil t)))))
 409
 410 (defun notmuch-show-message-unread-p ()
 411   "Predicate testing whether current message is unread."
 412   (member "unread" (notmuch-show-get-tags)))
 413
 414 (defun notmuch-show-message-open-p ()
 415   "Predicate testing whether current message is open (body is visible)."
 416   (let ((btn (previous-button (point) t)))
 417     (while (not (button-has-type-p btn 'notmuch-button-body-toggle-type))
 418       (setq btn (previous-button (button-start btn))))
 419     (not (invisible-p (button-get btn 'invisibility-spec)))))
 420
 421 (defun notmuch-show-next-message ()
 422   "Advance to the beginning of the next message in the buffer.
 423
 424 Moves to the last visible character of the current message if
 425 already on the last message in the buffer.
 426
 427 Returns nil if already on the last message in the buffer."
 428   (interactive)
 429   (notmuch-show-move-to-current-message-summary-line)
 430   (if (re-search-forward notmuch-show-message-begin-regexp nil t)
 431       (progn
 432         (notmuch-show-move-to-current-message-summary-line)
 433         (recenter 0)
 434         t)
 435     (goto-char (- (point-max) 1))
 436     (while (point-invisible-p)
 437       (backward-char))
 438     (recenter 0)
 439     nil))
 440
 441 (defun notmuch-show-find-next-message ()
 442   "Returns the position of the next message in the buffer.
 443
 444 Or the position of the last visible character of the current
 445 message if already within the last message in the buffer."
 446   ; save-excursion doesn't save our window position
 447   ; save-window-excursion doesn't save point
 448   ; Looks like we have to use both.
 449   (save-excursion
 450     (save-window-excursion
 451       (notmuch-show-next-message)
 452       (point))))
 453
 454 (defun notmuch-show-next-unread-message ()
 455   "Advance to the beginning of the next unread message in the buffer.
 456
 457 Moves to the last visible character of the current message if
 458 there are no more unread messages past the current point."
 459   (notmuch-show-next-message)
 460   (while (and (not (notmuch-show-last-message-p))
 461               (not (notmuch-show-message-unread-p)))
 462     (notmuch-show-next-message))
 463   (if (not (notmuch-show-message-unread-p))
 464       (notmuch-show-next-message)))
 465
 466 (defun notmuch-show-next-open-message ()
 467   "Advance to the next open message (that is, body is not invisible)."
 468   (while (and (notmuch-show-next-message)
 469               (not (notmuch-show-message-open-p)))))
 470
 471 (defun notmuch-show-previous-message ()
 472   "Backup to the beginning of the previous message in the buffer.
 473
 474 If within a message rather than at the beginning of it, then
 475 simply move to the beginning of the current message."
 476   (interactive)
 477   (let ((start (point)))
 478     (notmuch-show-move-to-current-message-summary-line)
 479     (if (not (< (point) start))
 480         ; Go backward twice to skip the current message's marker
 481         (progn
 482           (re-search-backward notmuch-show-message-begin-regexp nil t)
 483           (re-search-backward notmuch-show-message-begin-regexp nil t)
 484           (notmuch-show-move-to-current-message-summary-line)
 485           ))
 486     (recenter 0)))
 487
 488 (defun notmuch-show-find-previous-message ()
 489   "Returns the position of the previous message in the buffer.
 490
 491 Or the position of the beginning of the current message if point
 492 is originally within the message rather than at the beginning of
 493 it."
 494   ; save-excursion doesn't save our window position
 495   ; save-window-excursion doesn't save point
 496   ; Looks like we have to use both.
 497   (save-excursion
 498     (save-window-excursion
 499       (notmuch-show-previous-message)
 500       (point))))
 501
 502 (defun notmuch-show-mark-read-then-next-open-message ()
 503   "Remove unread tag from this message, then advance to next open message."
 504   (interactive)
 505   (notmuch-show-remove-tag "unread")
 506   (notmuch-show-next-open-message))
 507
 508 (defun notmuch-show-rewind ()
 509   "Backup through the thread, (reverse scrolling compared to \\[notmuch-show-advance-marking-read-and-archiving]).
 510
 511 Specifically, if the beginning of the previous email is fewer
 512 than `window-height' lines from the current point, move to it
 513 just like `notmuch-show-previous-message'.
 514
 515 Otherwise, just scroll down a screenful of the current message.
 516
 517 This command does not modify any message tags, (it does not undo
 518 any effects from previous calls to
 519 `notmuch-show-advance-marking-read-and-archiving'."
 520   (interactive)
 521   (let ((previous (notmuch-show-find-previous-message)))
 522     (if (> (count-lines previous (point)) (- (window-height) next-screen-context-lines))
 523         (progn
 524           (condition-case nil
 525               (scroll-down nil)
 526             ((beginning-of-buffer) nil))
 527           (goto-char (window-start)))
 528       (notmuch-show-previous-message))))
 529
 530 (defun notmuch-show-advance-marking-read-and-archiving ()
 531   "Advance through thread, marking read and archiving.
 532
 533 This command is intended to be one of the simplest ways to
 534 process a thread of email. It does the following:
 535
 536 If the current message in the thread is not yet fully visible,
 537 scroll by a near screenful to read more of the message.
 538
 539 Otherwise, (the end of the current message is already within the
 540 current window), remove the \"unread\" tag (if present) from the
 541 current message and advance to the next open message.
 542
 543 Finally, if there is no further message to advance to, and this
 544 last message is already read, then archive the entire current
 545 thread, (remove the \"inbox\" tag from each message). Also kill
 546 this buffer, and display the next thread from the search from
 547 which this thread was originally shown."
 548   (interactive)
 549   (let ((next (notmuch-show-find-next-message))
 550         (unread (notmuch-show-message-unread-p)))
 551     (if (> next (window-end))
 552         (scroll-up nil)
 553       (let ((last (notmuch-show-last-message-p)))
 554         (notmuch-show-mark-read-then-next-open-message)
 555         (if last
 556             (notmuch-show-archive-thread))))))
 557
 558 (defun notmuch-show-next-button ()
 559   "Advance point to the next button in the buffer."
 560   (interactive)
 561   (goto-char (button-start (next-button (point)))))
 562
 563 (defun notmuch-show-previous-button ()
 564   "Move point back to the previous button in the buffer."
 565   (interactive)
 566   (goto-char (button-start (previous-button (point)))))
 567
 568 (defun notmuch-toggle-invisible-action (cite-button)
 569   (let ((invis-spec (button-get cite-button 'invisibility-spec)))
 570         (if (invisible-p invis-spec)
 571             (remove-from-invisibility-spec invis-spec)
 572           (add-to-invisibility-spec invis-spec)
 573           ))
 574   (force-window-update)
 575   (redisplay t))
 576
 577 (define-button-type 'notmuch-button-invisibility-toggle-type
 578   'action 'notmuch-toggle-invisible-action
 579   'follow-link t
 580   'face "default")
 581 (define-button-type 'notmuch-button-citation-toggle-type 'help-echo "mouse-1, RET: Show citation"
 582   :supertype 'notmuch-button-invisibility-toggle-type)
 583 (define-button-type 'notmuch-button-signature-toggle-type 'help-echo "mouse-1, RET: Show signature"
 584   :supertype 'notmuch-button-invisibility-toggle-type)
 585 (define-button-type 'notmuch-button-headers-toggle-type 'help-echo "mouse-1, RET: Show headers"
 586   :supertype 'notmuch-button-invisibility-toggle-type)
 587 (define-button-type 'notmuch-button-body-toggle-type
 588   'help-echo "mouse-1, RET: Show message"
 589   'face 'notmuch-message-summary-face
 590   :supertype 'notmuch-button-invisibility-toggle-type)
 591
 592 (defun notmuch-show-markup-citations-region (beg end depth)
 593   (goto-char beg)
 594   (beginning-of-line)
 595   (while (< (point) end)
 596     (let ((beg-sub (point-marker))
 597           (indent (make-string depth ? ))
 598           (citation "[[:space:]]*>"))
 599       (if (looking-at citation)
 600           (progn
 601             (while (looking-at citation)
 602               (forward-line))
 603             (let ((overlay (make-overlay beg-sub (point)))
 604                   (invis-spec (make-symbol "notmuch-citation-region")))
 605               (add-to-invisibility-spec invis-spec)
 606               (overlay-put overlay 'invisible invis-spec)
 607               (let ((p (point))
 608                     (cite-button-text
 609                      (concat "["  (number-to-string (count-lines beg-sub (point)))
 610                              "-line citation.]")))
 611                 (goto-char (- beg-sub 1))
 612                 (insert (concat "\n" indent))
 613                 (insert-button cite-button-text
 614                                'invisibility-spec invis-spec
 615                                :type 'notmuch-button-citation-toggle-type)
 616                 (insert "\n")
 617                 (goto-char (+ (length cite-button-text) p))
 618               ))))
 619       (move-to-column depth)
 620       (if (looking-at notmuch-show-signature-regexp)
 621           (let ((sig-lines (- (count-lines beg-sub end) 1)))
 622             (if (<= sig-lines notmuch-show-signature-lines-max)
 623                 (progn
 624                   (let ((invis-spec (make-symbol "notmuch-signature-region")))
 625                     (add-to-invisibility-spec invis-spec)
 626                     (overlay-put (make-overlay beg-sub end)
 627                                  'invisible invis-spec)
 628
 629                     (goto-char (- beg-sub 1))
 630                     (insert (concat "\n" indent))
 631                     (let ((sig-button-text (concat "[" (number-to-string sig-lines)
 632                                                    "-line signature.]")))
 633                       (insert-button sig-button-text 'invisibility-spec invis-spec
 634                                      :type 'notmuch-button-signature-toggle-type)
 635                      )
 636                     (insert "\n")
 637                     (goto-char end))))))
 638       (forward-line))))
 639
 640 (defun notmuch-show-markup-part (beg end depth)
 641   (if (re-search-forward notmuch-show-part-begin-regexp nil t)
 642       (progn
 643         (forward-line)
 644         (let ((beg (point-marker)))
 645           (re-search-forward notmuch-show-part-end-regexp)
 646           (let ((end (copy-marker (match-beginning 0))))
 647             (goto-char end)
 648             (if (not (bolp))
 649                 (insert "\n"))
 650             (indent-rigidly beg end depth)
 651             (notmuch-show-markup-citations-region beg end depth)
 652             ; Advance to the next part (if any) (so the outer loop can
 653             ; determine whether we've left the current message.
 654             (if (re-search-forward notmuch-show-part-begin-regexp nil t)
 655                 (beginning-of-line)))))
 656     (goto-char end)))
 657
 658 (defun notmuch-show-markup-parts-region (beg end depth)
 659   (save-excursion
 660     (goto-char beg)
 661     (while (< (point) end)
 662       (notmuch-show-markup-part beg end depth))))
 663
 664 (defun notmuch-show-markup-body (depth match btn)
 665   "Markup a message body, (indenting, buttonizing citations,
 666 etc.), and conditionally hiding the body itself if the message
 667 has been read and does not match the current search.
 668
 669 DEPTH specifies the depth at which this message appears in the
 670 tree of the current thread, (the top-level messages have depth 0
 671 and each reply increases depth by 1). MATCH indicates whether
 672 this message is regarded as matching the current search. BTN is
 673 the button which is used to toggle the visibility of this
 674 message.
 675
 676 When this function is called, point must be within the message, but
 677 before the delimiter marking the beginning of the body."
 678   (re-search-forward notmuch-show-body-begin-regexp)
 679   (forward-line)
 680   (let ((beg (point-marker)))
 681     (re-search-forward notmuch-show-body-end-regexp)
 682     (let ((end (copy-marker (match-beginning 0))))
 683       (notmuch-show-markup-parts-region beg end depth)
 684       (let ((invis-spec (make-symbol "notmuch-show-body-read")))
 685         (overlay-put (make-overlay beg end)
 686                      'invisible invis-spec)
 687         (button-put btn 'invisibility-spec invis-spec)
 688         (if (not (or (notmuch-show-message-unread-p) match))
 689             (add-to-invisibility-spec invis-spec)))
 690       (set-marker beg nil)
 691       (set-marker end nil)
 692       )))
 693
 694 (defun notmuch-fontify-headers ()
 695   (while (looking-at "[[:space:]]")
 696     (forward-char))
 697   (if (looking-at "[Tt]o:")
 698       (progn
 699         (overlay-put (make-overlay (point) (re-search-forward ":"))
 700                      'face 'message-header-name)
 701         (overlay-put (make-overlay (point) (re-search-forward ".*$"))
 702                      'face 'message-header-to))
 703     (if (looking-at "[B]?[Cc][Cc]:")
 704         (progn
 705           (overlay-put (make-overlay (point) (re-search-forward ":"))
 706                        'face 'message-header-name)
 707           (overlay-put (make-overlay (point) (re-search-forward ".*$"))
 708                        'face 'message-header-cc))
 709       (if (looking-at "[Ss]ubject:")
 710           (progn
 711             (overlay-put (make-overlay (point) (re-search-forward ":"))
 712                          'face 'message-header-name)
 713             (overlay-put (make-overlay (point) (re-search-forward ".*$"))
 714                          'face 'message-header-subject))
 715         (if (looking-at "[Ff]rom:")
 716             (progn
 717               (overlay-put (make-overlay (point) (re-search-forward ":"))
 718                            'face 'message-header-name)
 719               (overlay-put (make-overlay (point) (re-search-forward ".*$"))
 720                            'face 'message-header-other)))))))
 721
 722 (defun notmuch-show-markup-header (message-begin depth)
 723   "Buttonize and decorate faces in a message header.
 724
 725 MESSAGE-BEGIN is the position of the absolute first character in
 726 the message (including all delimiters that will end up being
 727 invisible etc.). This is to allow a button to reliably extend to
 728 the beginning of the message even if point is positioned at an
 729 invisible character (such as the beginning of the buffer).
 730
 731 DEPTH specifies the depth at which this message appears in the
 732 tree of the current thread, (the top-level messages have depth 0
 733 and each reply increases depth by 1)."
 734   (re-search-forward notmuch-show-header-begin-regexp)
 735   (forward-line)
 736   (let ((beg (point-marker))
 737         (summary-end (copy-marker (line-beginning-position 2)))
 738         (subject-end (copy-marker (line-end-position 2)))
 739         (invis-spec (make-symbol "notmuch-show-header"))
 740         (btn nil))
 741     (re-search-forward notmuch-show-header-end-regexp)
 742     (beginning-of-line)
 743     (let ((end (point-marker)))
 744       (indent-rigidly beg end depth)
 745       (goto-char beg)
 746       (setq btn (make-button message-begin summary-end :type 'notmuch-button-body-toggle-type))
 747       (forward-line)
 748       (add-to-invisibility-spec invis-spec)
 749       (overlay-put (make-overlay subject-end end)
 750                    'invisible invis-spec)
 751       (make-button (line-beginning-position) subject-end
 752                    'invisibility-spec invis-spec
 753                    :type 'notmuch-button-headers-toggle-type)
 754       (while (looking-at "[[:space:]]*[A-Za-z][-A-Za-z0-9]*:")
 755         (beginning-of-line)
 756         (notmuch-fontify-headers)
 757         (forward-line)
 758         )
 759       (goto-char end)
 760       (insert "\n")
 761       (set-marker beg nil)
 762       (set-marker summary-end nil)
 763       (set-marker subject-end nil)
 764       (set-marker end nil)
 765       )
 766   btn))
 767
 768 (defun notmuch-show-markup-message ()
 769   (if (re-search-forward notmuch-show-message-begin-regexp nil t)
 770       (let ((message-begin (match-beginning 0)))
 771         (re-search-forward notmuch-show-depth-match-regexp)
 772         (let ((depth (string-to-number (buffer-substring (match-beginning 1) (match-end 1))))
 773               (match (string= "1" (buffer-substring (match-beginning 2) (match-end 2))))
 774               (btn nil))
 775           (setq btn (notmuch-show-markup-header message-begin depth))
 776           (notmuch-show-markup-body depth match btn)))
 777     (goto-char (point-max))))
 778
 779 (defun notmuch-show-hide-markers ()
 780   (save-excursion
 781     (goto-char (point-min))
 782     (while (not (eobp))
 783       (if (re-search-forward notmuch-show-marker-regexp nil t)
 784           (progn
 785             (overlay-put (make-overlay (match-beginning 0) (+ (match-end 0) 1))
 786                          'invisible 'notmuch-show-marker))
 787         (goto-char (point-max))))))
 788
 789 (defun notmuch-show-markup-messages ()
 790   (save-excursion
 791     (goto-char (point-min))
 792     (while (not (eobp))
 793       (notmuch-show-markup-message)))
 794   (notmuch-show-hide-markers))
 795
 796 (defun notmuch-documentation-first-line (symbol)
 797   "Return the first line of the documentation string for SYMBOL."
 798   (let ((doc (documentation symbol)))
 799     (if doc
 800         (with-temp-buffer
 801           (insert (documentation symbol t))
 802           (goto-char (point-min))
 803           (let ((beg (point)))
 804             (end-of-line)
 805             (buffer-substring beg (point))))
 806       "")))
 807
 808 (defun notmuch-prefix-key-description (key)
 809   "Given a prefix key code, return a human-readable string representation.
 810
 811 This is basically just `format-kbd-macro' but we also convert ESC to M-."
 812   (let ((desc (format-kbd-macro (vector key))))
 813     (if (string= desc "ESC")
 814         "M-"
 815       (concat desc " "))))
 816
 817 ; I would think that emacs would have code handy for walking a keymap
 818 ; and generating strings for each key, and I would prefer to just call
 819 ; that. But I couldn't find any (could be all implemented in C I
 820 ; suppose), so I wrote my own here.
 821 (defun notmuch-substitute-one-command-key-with-prefix (prefix binding)
 822   "For a key binding, return a string showing a human-readable
 823 representation of the prefixed key as well as the first line of
 824 documentation from the bound function.
 825
 826 For a mouse binding, return nil."
 827   (let ((key (car binding))
 828         (action (cdr binding)))
 829     (if (mouse-event-p key)
 830         nil
 831       (if (keymapp action)
 832           (let ((substitute (apply-partially 'notmuch-substitute-one-command-key-with-prefix (notmuch-prefix-key-description key))))
 833             (mapconcat substitute (cdr action) "\n"))
 834         (concat prefix (format-kbd-macro (vector key))
 835                 "\t"
 836                 (notmuch-documentation-first-line action))))))
 837
 838 (defalias 'notmuch-substitute-one-command-key
 839   (apply-partially 'notmuch-substitute-one-command-key-with-prefix nil))
 840
 841 (defun notmuch-substitute-command-keys (doc)
 842   "Like `substitute-command-keys' but with documentation, not function names."
 843   (let ((beg 0))
 844     (while (string-match "\\\\{\\([^}[:space:]]*\\)}" doc beg)
 845       (let ((map (substring doc (match-beginning 1) (match-end 1))))
 846         (setq doc (replace-match (mapconcat 'notmuch-substitute-one-command-key
 847                                             (cdr (symbol-value (intern map))) "\n") 1 1 doc)))
 848       (setq beg (match-end 0)))
 849     doc))
 850
 851 (defun notmuch-help ()
 852   "Display help for the current notmuch mode."
 853   (interactive)
 854   (let* ((mode major-mode)
 855          (doc (substitute-command-keys (notmuch-substitute-command-keys (documentation mode t)))))
 856     (with-current-buffer (generate-new-buffer "*notmuch-help*")
 857       (insert doc)
 858       (goto-char (point-min))
 859       (set-buffer-modified-p nil)
 860       (view-buffer (current-buffer) 'kill-buffer-if-not-modified))))
 861
 862 ;;;###autoload
 863 (defun notmuch-show-mode ()
 864   "Major mode for viewing a thread with notmuch.
 865
 866 This buffer contains the results of the \"notmuch show\" command
 867 for displaying a single thread of email from your email archives.
 868
 869 By default, various components of email messages, (citations,
 870 signatures, already-read messages), are hidden. You can make
 871 these parts visible by clicking with the mouse button or by
 872 pressing RET after positioning the cursor on a hidden part, (for
 873 which \\[notmuch-show-next-button] and \\[notmuch-show-previous-button] are helpful).
 874
 875 Reading the thread sequentially is well-supported by pressing
 876 \\[notmuch-show-advance-marking-read-and-archiving]. This will scroll the current message (if necessary),
 877 advance to the next message, or advance to the next thread (if
 878 already on the last message of a thread). As each message is
 879 scrolled away its \"unread\" tag will be removed, and as each
 880 thread is scrolled away the \"inbox\" tag will be removed from
 881 each message in the thread.
 882
 883 Other commands are available to read or manipulate the thread more
 884 selectively, (such as '\\[notmuch-show-next-message]' and '\\[notmuch-show-previous-message]' to advance to messages without
 885 removing any tags, and '\\[notmuch-show-archive-thread]' to archive an entire thread without
 886 scrolling through with \\[notmuch-show-advance-marking-read-and-archiving]).
 887
 888 You can add or remove arbitary tags from the current message with
 889 '\\[notmuch-show-add-tag]' or '\\[notmuch-show-remove-tag]'.
 890
 891 All currently available key bindings:
 892
 893 \\{notmuch-show-mode-map}"
 894   (interactive)
 895   (kill-all-local-variables)
 896   (add-to-invisibility-spec 'notmuch-show-marker)
 897   (use-local-map notmuch-show-mode-map)
 898   (setq major-mode 'notmuch-show-mode
 899         mode-name "notmuch-show")
 900   (setq buffer-read-only t))
 901
 902 (defgroup notmuch nil
 903   "Notmuch mail reader for Emacs."
 904   :group 'mail)
 905
 906 (defcustom notmuch-show-hook nil
 907   "List of functions to call when notmuch displays a message."
 908   :type 'hook
 909   :options '(goto-address)
 910   :group 'notmuch)
 911
 912 (defcustom notmuch-search-hook nil
 913   "List of functions to call when notmuch displays the search results."
 914   :type 'hook
 915   :options '(hl-line-mode)
 916   :group 'notmuch)
 917
 918 ; Make show mode a bit prettier, highlighting URLs and using word wrap
 919
 920 (defun notmuch-show-pretty-hook ()
 921   (goto-address-mode 1)
 922   (visual-line-mode))
 923
 924 (add-hook 'notmuch-show-hook 'notmuch-show-pretty-hook)
 925 (add-hook 'notmuch-search-hook
 926           (lambda()
 927             (hl-line-mode 1) ))
 928
 929 (defun notmuch-show (thread-id &optional parent-buffer)
 930   "Run \"notmuch show\" with the given thread ID and display results.
 931
 932 The optional PARENT-BUFFER is the notmuch-search buffer from
 933 which this notmuch-show command was executed, (so that the next
 934 thread from that buffer can be show when done with this one)."
 935   (interactive "sNotmuch show: ")
 936   (let ((query notmuch-search-query-string)
 937         (buffer (get-buffer-create (concat "*notmuch-show-" thread-id "*"))))
 938     (switch-to-buffer buffer)
 939     (notmuch-show-mode)
 940     (set (make-local-variable 'notmuch-show-parent-buffer) parent-buffer)
 941     (let ((proc (get-buffer-process (current-buffer)))
 942           (inhibit-read-only t))
 943       (if proc
 944           (error "notmuch search process already running for query `%s'" thread-id)
 945         )
 946       (erase-buffer)
 947       (goto-char (point-min))
 948       (save-excursion
 949         (call-process notmuch-command nil t nil "show" "--entire-thread" thread-id "and (" query ")")
 950         (notmuch-show-markup-messages)
 951         )
 952       (run-hooks 'notmuch-show-hook)
 953       ; Move straight to the first open message
 954       (if (not (notmuch-show-message-open-p))
 955           (notmuch-show-next-open-message))
 956       )))
 957
 958 (defvar notmuch-search-authors-width 40
 959   "Number of columns to use to display authors in a notmuch-search buffer.")
 960
 961 (defvar notmuch-search-mode-map
 962   (let ((map (make-sparse-keymap)))
 963     (define-key map "?" 'notmuch-help)
 964     (define-key map "q" 'kill-this-buffer)
 965     (define-key map "x" 'kill-this-buffer)
 966     (define-key map (kbd "<DEL>") 'notmuch-search-scroll-down)
 967     (define-key map "b" 'notmuch-search-scroll-down)
 968     (define-key map " " 'notmuch-search-scroll-up)
 969     (define-key map "<" 'notmuch-search-first-thread)
 970     (define-key map ">" 'notmuch-search-last-thread)
 971     (define-key map "p" 'notmuch-search-previous-thread)
 972     (define-key map "n" 'notmuch-search-next-thread)
 973     (define-key map "r" 'notmuch-search-reply-to-thread)
 974     (define-key map "m" 'message-mail)
 975     (define-key map "s" 'notmuch-search)
 976     (define-key map "o" 'notmuch-search-toggle-order)
 977     (define-key map "=" 'notmuch-search-refresh-view)
 978     (define-key map "t" 'notmuch-search-filter-by-tag)
 979     (define-key map "f" 'notmuch-search-filter)
 980     (define-key map [mouse-1] 'notmuch-search-show-thread)
 981     (define-key map "*" 'notmuch-search-operate-all)
 982     (define-key map "a" 'notmuch-search-archive-thread)
 983     (define-key map "-" 'notmuch-search-remove-tag)
 984     (define-key map "+" 'notmuch-search-add-tag)
 985     (define-key map (kbd "RET") 'notmuch-search-show-thread)
 986     map)
 987   "Keymap for \"notmuch search\" buffers.")
 988 (fset 'notmuch-search-mode-map notmuch-search-mode-map)
 989
 990 (defvar notmuch-search-query-string)
 991 (defvar notmuch-search-oldest-first t
 992   "Show the oldest mail first in the search-mode")
 993
 994 (defvar notmuch-search-disjunctive-regexp      "\\<[oO][rR]\\>")
 995
 996 (defun notmuch-search-scroll-up ()
 997   "Move forward through search results by one window's worth."
 998   (interactive)
 999   (condition-case nil
1000       (scroll-up nil)
1001     ((end-of-buffer) (notmuch-search-last-thread))))
1002
1003 (defun notmuch-search-scroll-down ()
1004   "Move backward through the search results by one window's worth."
1005   (interactive)
1006   ; I don't know why scroll-down doesn't signal beginning-of-buffer
1007   ; the way that scroll-up signals end-of-buffer, but c'est la vie.
1008   ;
1009   ; So instead of trapping a signal we instead check whether the
1010   ; window begins on the first line of the buffer and if so, move
1011   ; directly to that position. (We have to count lines since the
1012   ; window-start position is not the same as point-min due to the
1013   ; invisible thread-ID characters on the first line.
1014   (if (equal (count-lines (point-min) (window-start)) 0)
1015       (goto-char (point-min))
1016     (scroll-down nil)))
1017
1018 (defun notmuch-search-next-thread ()
1019   "Select the next thread in the search results."
1020   (interactive)
1021   (forward-line 1))
1022
1023 (defun notmuch-search-previous-thread ()
1024   "Select the previous thread in the search results."
1025   (interactive)
1026   (forward-line -1))
1027
1028 (defun notmuch-search-last-thread ()
1029   "Select the last thread in the search results."
1030   (interactive)
1031   (goto-char (point-max))
1032   (forward-line -2))
1033
1034 (defun notmuch-search-first-thread ()
1035   "Select the first thread in the search results."
1036   (interactive)
1037   (goto-char (point-min)))
1038
1039 (defface notmuch-message-summary-face
1040  '((((class color) (background light)) (:background "#f0f0f0"))
1041    (((class color) (background dark)) (:background "#303030")))
1042  "Face for the single-line message summary in notmuch-show-mode."
1043  :group 'notmuch)
1044
1045 (defface notmuch-tag-face
1046   '((((class color)
1047       (background dark))
1048      (:foreground "OliveDrab1"))
1049     (((class color)
1050       (background light))
1051      (:foreground "navy blue" :bold t))
1052     (t
1053      (:bold t)))
1054   "Notmuch search mode face used to highligh tags."
1055   :group 'notmuch)
1056
1057 (defvar notmuch-tag-face-alist nil
1058   "List containing the tag list that need to be highlighed")
1059
1060 (defvar notmuch-search-font-lock-keywords  nil)
1061
1062 ;;;###autoload
1063 (defun notmuch-search-mode ()
1064   "Major mode displaying results of a notmuch search.
1065
1066 This buffer contains the results of a \"notmuch search\" of your
1067 email archives. Each line in the buffer represents a single
1068 thread giving a summary of the thread (a relative date, the
1069 number of matched messages and total messages in the thread,
1070 participants in the thread, a representative subject line, and
1071 any tags).
1072
1073 Pressing \\[notmuch-search-show-thread] on any line displays that thread. The '\\[notmuch-search-add-tag]' and '\\[notmuch-search-remove-tag]'
1074 keys can be used to add or remove tags from a thread. The '\\[notmuch-search-archive-thread]' key
1075 is a convenience for archiving a thread (removing the \"inbox\"
1076 tag). The '\\[notmuch-search-operate-all]' key can be used to add or remove a tag from all
1077 threads in the current buffer.
1078
1079 Other useful commands are '\\[notmuch-search-filter]' for filtering the current search
1080 based on an additional query string, '\\[notmuch-search-filter-by-tag]' for filtering to include
1081 only messages with a given tag, and '\\[notmuch-search]' to execute a new, global
1082 search.
1083
1084 Complete list of currently available key bindings:
1085
1086 \\{notmuch-search-mode-map}"
1087   (interactive)
1088   (kill-all-local-variables)
1089   (make-local-variable 'notmuch-search-query-string)
1090   (make-local-variable 'notmuch-search-oldest-first)
1091   (set (make-local-variable 'scroll-preserve-screen-position) t)
1092   (add-to-invisibility-spec 'notmuch-search)
1093   (use-local-map notmuch-search-mode-map)
1094   (setq truncate-lines t)
1095   (setq major-mode 'notmuch-search-mode
1096         mode-name "notmuch-search")
1097   (setq buffer-read-only t)
1098   (if (not notmuch-tag-face-alist)
1099       (add-to-list 'notmuch-search-font-lock-keywords (list
1100                 "(\\([^)]*\\))$" '(1  'notmuch-tag-face)))
1101     (let ((notmuch-search-tags (mapcar 'car notmuch-tag-face-alist)))
1102       (loop for notmuch-search-tag  in notmuch-search-tags
1103             do (add-to-list 'notmuch-search-font-lock-keywords (list
1104                         (concat "([^)]*\\(" notmuch-search-tag "\\)[^)]*)$")
1105                         `(1  ,(cdr (assoc notmuch-search-tag notmuch-tag-face-alist))))))))
1106   (set (make-local-variable 'font-lock-defaults)
1107          '(notmuch-search-font-lock-keywords t)))
1108
1109 (defun notmuch-search-find-thread-id ()
1110   "Return the thread for the current thread"
1111   (get-text-property (point) 'notmuch-search-thread-id))
1112
1113 (defun notmuch-search-find-authors ()
1114   "Return the authors for the current thread"
1115   (get-text-property (point) 'notmuch-search-authors))
1116
1117 (defun notmuch-search-find-subject ()
1118   "Return the subject for the current thread"
1119   (get-text-property (point) 'notmuch-search-subject))
1120
1121 (defun notmuch-search-show-thread ()
1122   "Display the currently selected thread."
1123   (interactive)
1124   (let ((thread-id (notmuch-search-find-thread-id)))
1125     (if (> (length thread-id) 0)
1126         (notmuch-show thread-id (current-buffer))
1127       (error "End of search results"))))
1128
1129 (defun notmuch-search-reply-to-thread ()
1130   "Begin composing a reply to the entire current thread in a new buffer."
1131   (interactive)
1132   (let ((message-id (notmuch-search-find-thread-id)))
1133     (notmuch-reply message-id)))
1134
1135 (defun notmuch-call-notmuch-process (&rest args)
1136   "Synchronously invoke \"notmuch\" with the given list of arguments.
1137
1138 Output from the process will be presented to the user as an error
1139 and will also appear in a buffer named \"*Notmuch errors*\"."
1140   (let ((error-buffer (get-buffer-create "*Notmuch errors*")))
1141     (with-current-buffer error-buffer
1142         (erase-buffer))
1143     (if (eq (apply 'call-process notmuch-command nil error-buffer nil args) 0)
1144         (point)
1145       (progn
1146         (with-current-buffer error-buffer
1147           (let ((beg (point-min))
1148                 (end (- (point-max) 1)))
1149             (error (buffer-substring beg end))
1150             ))))))
1151
1152 (defun notmuch-search-set-tags (tags)
1153   (save-excursion
1154     (end-of-line)
1155     (re-search-backward "(")
1156     (forward-char)
1157     (let ((beg (point))
1158           (inhibit-read-only t))
1159       (re-search-forward ")")
1160       (backward-char)
1161       (let ((end (point)))
1162         (delete-region beg end)
1163         (insert (mapconcat  'identity tags " "))))))
1164
1165 (defun notmuch-search-get-tags ()
1166   (save-excursion
1167     (end-of-line)
1168     (re-search-backward "(")
1169     (let ((beg (+ (point) 1)))
1170       (re-search-forward ")")
1171       (let ((end (- (point) 1)))
1172         (split-string (buffer-substring beg end))))))
1173
1174 (defun notmuch-search-add-tag (tag)
1175   "Add a tag to the currently selected thread.
1176
1177 The tag is added to messages in the currently selected thread
1178 which match the current search terms."
1179   (interactive
1180    (list (notmuch-select-tag-with-completion "Tag to add: ")))
1181   (notmuch-call-notmuch-process "tag" (concat "+" tag) (notmuch-search-find-thread-id) " and " notmuch-search-query-string)
1182   (notmuch-search-set-tags (delete-dups (sort (cons tag (notmuch-search-get-tags)) 'string<))))
1183
1184 (defun notmuch-search-remove-tag (tag)
1185   "Remove a tag from the currently selected thread.
1186
1187 The tag is removed from messages in the currently selected thread
1188 which match the current search terms."
1189   (interactive
1190    (list (notmuch-select-tag-with-completion "Tag to remove: " (notmuch-search-find-thread-id))))
1191   (notmuch-call-notmuch-process "tag" (concat "-" tag) (notmuch-search-find-thread-id) " and " notmuch-search-query-string)
1192   (notmuch-search-set-tags (delete tag (notmuch-search-get-tags))))
1193
1194 (defun notmuch-search-archive-thread ()
1195   "Archive the currently selected thread (remove its \"inbox\" tag).
1196
1197 This function advances the next thread when finished."
1198   (interactive)
1199   (notmuch-search-remove-tag "inbox")
1200   (forward-line))
1201
1202 (defun notmuch-search-process-sentinel (proc msg)
1203   "Add a message to let user know when \"notmuch search\" exits"
1204   (let ((buffer (process-buffer proc))
1205         (status (process-status proc))
1206         (exit-status (process-exit-status proc)))
1207     (if (memq status '(exit signal))
1208         (if (buffer-live-p buffer)
1209             (with-current-buffer buffer
1210               (save-excursion
1211                 (let ((inhibit-read-only t))
1212                   (goto-char (point-max))
1213                   (if (eq status 'signal)
1214                       (insert "Incomplete search results (search process was killed).\n"))
1215                   (if (eq status 'exit)
1216                       (progn
1217                         (insert "End of search results.")
1218                         (if (not (= exit-status 0))
1219                             (insert (format " (process returned %d)" exit-status)))
1220                         (insert "\n"))))))))))
1221
1222 (defun notmuch-search-process-filter (proc string)
1223   "Process and filter the output of \"notmuch search\""
1224   (let ((buffer (process-buffer proc)))
1225     (if (buffer-live-p buffer)
1226         (with-current-buffer buffer
1227           (save-excursion
1228             (let ((line 0)
1229                   (more t)
1230                   (inhibit-read-only t))
1231               (while more
1232                 (if (string-match "^\\(thread:[0-9A-Fa-f]*\\) \\(.*\\) \\(\\[[0-9/]*\\]\\) \\([^:]*\\); \\(.*\\) (\\([^()]*\\))$" string line)
1233                     (let* ((thread-id (match-string 1 string))
1234                            (date (match-string 2 string))
1235                            (count (match-string 3 string))
1236                            (authors (match-string 4 string))
1237                            (authors-length (length authors))
1238                            (subject (match-string 5 string))
1239                            (tags (match-string 6 string)))
1240                       (if (> authors-length 40)
1241                           (set 'authors (concat (substring authors 0 (- 40 3)) "...")))
1242                       (goto-char (point-max))
1243                       (let ((beg (point-marker)))
1244                         (insert (format "%s %-7s %-40s %s (%s)\n" date count authors subject tags))
1245                         (put-text-property beg (point-marker) 'notmuch-search-thread-id thread-id)
1246                         (put-text-property beg (point-marker) 'notmuch-search-authors authors)
1247                         (put-text-property beg (point-marker) 'notmuch-search-subject subject))
1248                       (set 'line (match-end 0)))
1249                   (set 'more nil))))))
1250       (delete-process proc))))
1251
1252 (defun notmuch-search-operate-all (action)
1253   "Add/remove tags from all matching messages.
1254
1255 Tis command adds or removes tags from all messages matching the
1256 current search terms. When called interactively, this command
1257 will prompt for tags to be added or removed. Tags prefixed with
1258 '+' will be added and tags prefixed with '-' will be removed.
1259
1260 Each character of the tag name may consist of alphanumeric
1261 characters as well as `_.+-'.
1262 "
1263   (interactive "sOperation (+add -drop): notmuch tag ")
1264   (let ((action-split (split-string action " +")))
1265     ;; Perform some validation
1266     (let ((words action-split))
1267       (when (null words) (error "No operation given"))
1268       (while words
1269         (unless (string-match-p "^[-+][-+_.[:word:]]+$" (car words))
1270           (error "Action must be of the form `+thistag -that_tag'"))
1271         (setq words (cdr words))))
1272     (apply 'notmuch-call-notmuch-process "tag"
1273            (append action-split (list notmuch-search-query-string) nil))))
1274
1275 ;;;###autoload
1276 (defun notmuch-search (query &optional oldest-first)
1277   "Run \"notmuch search\" with the given query string and display results."
1278   (interactive "sNotmuch search: ")
1279   (let ((buffer (get-buffer-create (concat "*notmuch-search-" query "*"))))
1280     (switch-to-buffer buffer)
1281     (notmuch-search-mode)
1282     (set 'notmuch-search-query-string query)
1283     (set 'notmuch-search-oldest-first oldest-first)
1284     (let ((proc (get-buffer-process (current-buffer)))
1285           (inhibit-read-only t))
1286       (if proc
1287           (error "notmuch search process already running for query `%s'" query)
1288         )
1289       (erase-buffer)
1290       (goto-char (point-min))
1291       (save-excursion
1292         (let ((proc (start-process-shell-command
1293                      "notmuch-search" buffer notmuch-command "search"
1294                      (if oldest-first "--sort=oldest-first" "--sort=newest-first")
1295                      (shell-quote-argument query))))
1296           (set-process-sentinel proc 'notmuch-search-process-sentinel)
1297           (set-process-filter proc 'notmuch-search-process-filter))))
1298     (run-hooks 'notmuch-search-hook)))
1299
1300 (defun notmuch-search-refresh-view ()
1301   "Refresh the current view.
1302
1303 Kills the current buffer and runs a new search with the same
1304 query string as the current search. If the current thread is in
1305 the new search results, then point will be placed on the same
1306 thread. Otherwise, point will be moved to attempt to be in the
1307 same relative position within the new buffer."
1308   (interactive)
1309   (let ((here (point))
1310         (oldest-first notmuch-search-oldest-first)
1311         (thread (notmuch-search-find-thread-id))
1312         (query notmuch-search-query-string))
1313     (kill-this-buffer)
1314     (notmuch-search query oldest-first)
1315     (goto-char (point-min))
1316     (if (re-search-forward (concat "^" thread) nil t)
1317         (beginning-of-line)
1318       (goto-char here))))
1319
1320 (defun notmuch-search-toggle-order ()
1321   "Toggle the current search order.
1322
1323 By default, the \"inbox\" view created by `notmuch' is displayed
1324 in chronological order (oldest thread at the beginning of the
1325 buffer), while any global searches created by `notmuch-search'
1326 are displayed in reverse-chronological order (newest thread at
1327 the beginning of the buffer).
1328
1329 This command toggles the sort order for the current search.
1330
1331 Note that any filtered searches created by
1332 `notmuch-search-filter' retain the search order of the parent
1333 search."
1334   (interactive)
1335   (set 'notmuch-search-oldest-first (not notmuch-search-oldest-first))
1336   (notmuch-search-refresh-view))
1337
1338 (defun notmuch-search-filter (query)
1339   "Filter the current search results based on an additional query string.
1340
1341 Runs a new search matching only messages that match both the
1342 current search results AND the additional query string provided."
1343   (interactive "sFilter search: ")
1344   (let ((grouped-query (if (string-match-p notmuch-search-disjunctive-regexp query) (concat "( " query " )") query)))
1345     (notmuch-search (concat notmuch-search-query-string " and " grouped-query) notmuch-search-oldest-first)))
1346
1347 (defun notmuch-search-filter-by-tag (tag)
1348   "Filter the current search results based on a single tag.
1349
1350 Runs a new search matching only messages that match both the
1351 current search results AND that are tagged with the given tag."
1352   (interactive
1353    (list (notmuch-select-tag-with-completion "Filter by tag: ")))
1354   (notmuch-search (concat notmuch-search-query-string " and tag:" tag) notmuch-search-oldest-first))
1355
1356
1357 ;;;###autoload
1358 (defun notmuch ()
1359   "Run notmuch to display all mail with tag of 'inbox'"
1360   (interactive)
1361   (notmuch-search "tag:inbox" notmuch-search-oldest-first))
1362
1363 (setq mail-user-agent 'message-user-agent)
1364
1365 (defvar notmuch-folder-mode-map
1366   (let ((map (make-sparse-keymap)))
1367     (define-key map "?" 'notmuch-help)
1368     (define-key map "x" 'kill-this-buffer)
1369     (define-key map "q" 'kill-this-buffer)
1370     (define-key map ">" 'notmuch-folder-last)
1371     (define-key map "<" 'notmuch-folder-first)
1372     (define-key map "=" 'notmuch-folder)
1373     (define-key map "s" 'notmuch-search)
1374     (define-key map [mouse-1] 'notmuch-folder-show-search)
1375     (define-key map (kbd "RET") 'notmuch-folder-show-search)
1376     (define-key map "p" 'notmuch-folder-previous)
1377     (define-key map "n" 'notmuch-folder-next)
1378     map)
1379   "Keymap for \"notmuch folder\" buffers.")
1380
1381 (fset 'notmuch-folder-mode-map notmuch-folder-mode-map)
1382
1383 (defcustom notmuch-folders (quote (("inbox" . "tag:inbox") ("unread" . "tag:unread")))
1384   "List of searches for the notmuch folder view"
1385   :type '(alist :key-type (string) :value-type (string))
1386   :group 'notmuch)
1387
1388 (defun notmuch-folder-mode ()
1389   "Major mode for showing notmuch 'folders'.
1390
1391 This buffer contains a list of message counts returned by a
1392 customizable set of searches of your email archives. Each line in
1393 the buffer shows the name of a saved search and the resulting
1394 message count.
1395
1396 Pressing RET on any line opens a search window containing the
1397 results for the saved search on that line.
1398
1399 Here is an example of how the search list could be
1400 customized, (the following text would be placed in your ~/.emacs
1401 file):
1402
1403 (setq notmuch-folders '((\"inbox\" . \"tag:inbox\")
1404                         (\"unread\" . \"tag:inbox AND tag:unread\")
1405                         (\"notmuch\" . \"tag:inbox AND to:notmuchmail.org\")))
1406
1407 Of course, you can have any number of folders, each configured
1408 with any supported search terms (see \"notmuch help search-terms\").
1409
1410 Currently available key bindings:
1411
1412 \\{notmuch-folder-mode-map}"
1413   (interactive)
1414   (kill-all-local-variables)
1415   (use-local-map 'notmuch-folder-mode-map)
1416   (setq truncate-lines t)
1417   (hl-line-mode 1)
1418   (setq major-mode 'notmuch-folder-mode
1419         mode-name "notmuch-folder")
1420   (setq buffer-read-only t))
1421
1422 (defun notmuch-folder-next ()
1423   "Select the next folder in the list."
1424   (interactive)
1425   (forward-line 1)
1426   (if (eobp)
1427       (forward-line -1)))
1428
1429 (defun notmuch-folder-previous ()
1430   "Select the previous folder in the list."
1431   (interactive)
1432   (forward-line -1))
1433
1434 (defun notmuch-folder-first ()
1435   "Select the first folder in the list."
1436   (interactive)
1437   (goto-char (point-min)))
1438
1439 (defun notmuch-folder-last ()
1440   "Select the last folder in the list."
1441   (interactive)
1442   (goto-char (point-max))
1443   (forward-line -1))
1444
1445 (defun notmuch-folder-add (folders)
1446   (if folders
1447       (let ((name (car (car folders)))
1448             (inhibit-read-only t)
1449             (search (cdr (car folders))))
1450         (insert name)
1451         (indent-to 16 1)
1452         (call-process notmuch-command nil t nil "count" search)
1453         (notmuch-folder-add (cdr folders)))))
1454
1455 (defun notmuch-folder-find-name ()
1456   (save-excursion
1457     (beginning-of-line)
1458     (let ((beg (point)))
1459       (forward-word)
1460       (filter-buffer-substring beg (point)))))
1461
1462 (defun notmuch-folder-show-search (&optional folder)
1463   "Show a search window for the search related to the specified folder."
1464   (interactive)
1465   (if (null folder)
1466       (setq folder (notmuch-folder-find-name)))
1467   (let ((search (assoc folder notmuch-folders)))
1468     (if search
1469         (notmuch-search (cdr search) notmuch-search-oldest-first))))
1470
1471 ;;;###autoload
1472 (defun notmuch-folder ()
1473   "Show the notmuch folder view and update the displayed counts."
1474   (interactive)
1475   (let ((buffer (get-buffer-create "*notmuch-folders*")))
1476     (switch-to-buffer buffer)
1477     (let ((inhibit-read-only t)
1478           (n (line-number-at-pos)))
1479       (erase-buffer)
1480       (notmuch-folder-mode)
1481       (notmuch-folder-add notmuch-folders)
1482       (goto-char (point-min))
1483       (goto-line n))))
1484
1485 (provide 'notmuch)