git.notmuchmail.org Git - notmuch/blob - notmuch.el

   1 ; notmuch.el --- run notmuch within emacs
   2 ;
   3 ; Copyright © Carl Worth
   4 ;
   5 ; This file is part of Notmuch.
   6 ;
   7 ; Notmuch is free software: you can redistribute it and/or modify it
   8 ; under the terms of the GNU General Public License as published by
   9 ; the Free Software Foundation, either version 3 of the License, or
  10 ; (at your option) any later version.
  11 ;
  12 ; Notmuch is distributed in the hope that it will be useful, but
  13 ; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 ; General Public License for more details.
  16 ;
  17 ; You should have received a copy of the GNU General Public License
  18 ; along with Notmuch.  If not, see <http://www.gnu.org/licenses/>.
  19 ;
  20 ; Authors: Carl Worth <cworth@cworth.org>
  21
  22 ; This is an emacs-based interface to the notmuch mail system.
  23 ;
  24 ; You will first need to have the notmuch program installed and have a
  25 ; notmuch database built in order to use this. See
  26 ; http://notmuchmail.org for details.
  27 ;
  28 ; To install this software, copy it to a directory that is on the
  29 ; `load-path' variable within emacs (a good candidate is
  30 ; /usr/local/share/emacs/site-lisp). If you are viewing this from the
  31 ; notmuch source distribution then you can simply run:
  32 ;
  33 ;       sudo make install-emacs
  34 ;
  35 ; to install it.
  36 ;
  37 ; Then, to actually run it, add:
  38 ;
  39 ;       (require 'notmuch)
  40 ;
  41 ; to your ~/.emacs file, and then run "M-x notmuch" from within emacs,
  42 ; or run:
  43 ;
  44 ;       emacs -f notmuch
  45 ;
  46 ; Have fun, and let us know if you have any comment, questions, or
  47 ; kudos: Notmuch list <notmuch@notmuchmail.org> (subscription is not
  48 ; required, but is available from http://notmuchmail.org).
  49
  50 (require 'cl)
  51 (require 'mm-view)
  52
  53 (defvar notmuch-show-mode-map
  54   (let ((map (make-sparse-keymap)))
  55     ; I don't actually want all of these toggle commands occupying
  56     ; keybindings. They steal valuable key-binding space, are hard
  57     ; to remember, and act globally rather than locally.
  58     ;
  59     ; Will be much preferable to switch to direct manipulation for
  60     ; toggling visibility of these components. Probably using
  61     ; overlays-at to query and manipulate the current overlay.
  62     (define-key map "a" 'notmuch-show-archive-thread)
  63     (define-key map "A" 'notmuch-show-mark-read-then-archive-thread)
  64     (define-key map "b" 'notmuch-show-toggle-body-read-visible)
  65     (define-key map "c" 'notmuch-show-toggle-citations-visible)
  66     (define-key map "h" 'notmuch-show-toggle-headers-visible)
  67     (define-key map "m" 'message-mail)
  68     (define-key map "n" 'notmuch-show-next-message)
  69     (define-key map "N" 'notmuch-show-mark-read-then-next-open-message)
  70     (define-key map "p" 'notmuch-show-previous-message)
  71     (define-key map (kbd "C-n") 'notmuch-show-next-line)
  72     (define-key map (kbd "C-p") 'notmuch-show-previous-line)
  73     (define-key map "q" 'kill-this-buffer)
  74     (define-key map "r" 'notmuch-show-reply)
  75     (define-key map "s" 'notmuch-show-toggle-signatures-visible)
  76     (define-key map "v" 'notmuch-show-view-all-mime-parts)
  77     (define-key map "w" 'notmuch-show-view-raw-message)
  78     (define-key map "x" 'kill-this-buffer)
  79     (define-key map "+" 'notmuch-show-add-tag)
  80     (define-key map "-" 'notmuch-show-remove-tag)
  81     (define-key map (kbd "DEL") 'notmuch-show-rewind)
  82     (define-key map " " 'notmuch-show-advance-marking-read-and-archiving)
  83     (define-key map "|" 'notmuch-show-pipe-message)
  84     (define-key map "?" 'describe-mode)
  85     map)
  86   "Keymap for \"notmuch show\" buffers.")
  87 (fset 'notmuch-show-mode-map notmuch-show-mode-map)
  88
  89 (defvar notmuch-show-signature-regexp "\\(-- ?\\|_+\\)$"
  90   "Pattern to match a line that separates content from signature.
  91
  92 The regexp can (and should) include $ to match the end of the
  93 line, but should not include ^ to match the beginning of the
  94 line. This is because notmuch may have inserted additional space
  95 for indentation at the beginning of the line. But notmuch will
  96 move past the indentation when testing this pattern, (so that the
  97 pattern can still test against the entire line).")
  98
  99 (defvar notmuch-show-signature-lines-max 12
 100   "Maximum length of signature that will be hidden by default.")
 101
 102 (defvar notmuch-command "notmuch"
 103   "Command to run the notmuch binary.")
 104
 105 (defvar notmuch-show-message-begin-regexp    "\fmessage{")
 106 (defvar notmuch-show-message-end-regexp      "\fmessage}")
 107 (defvar notmuch-show-header-begin-regexp     "\fheader{")
 108 (defvar notmuch-show-header-end-regexp       "\fheader}")
 109 (defvar notmuch-show-body-begin-regexp       "\fbody{")
 110 (defvar notmuch-show-body-end-regexp         "\fbody}")
 111 (defvar notmuch-show-attachment-begin-regexp "\fattachment{")
 112 (defvar notmuch-show-attachment-end-regexp   "\fattachment}")
 113 (defvar notmuch-show-part-begin-regexp       "\fpart{")
 114 (defvar notmuch-show-part-end-regexp         "\fpart}")
 115 (defvar notmuch-show-marker-regexp "\f\\(message\\|header\\|body\\|attachment\\|part\\)[{}].*$")
 116
 117 (defvar notmuch-show-id-regexp "\\(id:[^ ]*\\)")
 118 (defvar notmuch-show-depth-regexp " depth:\\([0-9]*\\) ")
 119 (defvar notmuch-show-filename-regexp "filename:\\(.*\\)$")
 120 (defvar notmuch-show-tags-regexp "(\\([^)]*\\))$")
 121
 122 (defvar notmuch-show-parent-buffer nil)
 123 (defvar notmuch-show-body-read-visible nil)
 124 (defvar notmuch-show-citations-visible nil)
 125 (defvar notmuch-show-signatures-visible nil)
 126 (defvar notmuch-show-headers-visible nil)
 127
 128 ; XXX: This should be a generic function in emacs somewhere, not here
 129 (defun point-invisible-p ()
 130   "Return whether the character at point is invisible.
 131
 132 Here visibility is determined by `buffer-invisibility-spec' and
 133 the invisible property of any overlays for point. It doesn't have
 134 anything to do with whether point is currently being displayed
 135 within the current window."
 136   (let ((prop (get-char-property (point) 'invisible)))
 137     (if (eq buffer-invisibility-spec t)
 138         prop
 139       (or (memq prop buffer-invisibility-spec)
 140           (assq prop buffer-invisibility-spec)))))
 141
 142 (defun notmuch-show-next-line ()
 143   "Like builtin `next-line' but ensuring we end on a visible character.
 144
 145 By advancing forward until reaching a visible character.
 146
 147 Unlike builtin `next-line' this version accepts no arguments."
 148   (interactive)
 149   (set 'this-command 'next-line)
 150   (call-interactively 'next-line)
 151   (while (point-invisible-p)
 152     (forward-char)))
 153
 154 (defun notmuch-show-previous-line ()
 155   "Like builtin `previous-line' but ensuring we end on a visible character.
 156
 157 By advancing forward until reaching a visible character.
 158
 159 Unlike builtin `next-line' this version accepts no arguments."
 160   (interactive)
 161   (set 'this-command 'previous-line)
 162   (call-interactively 'previous-line)
 163   (while (point-invisible-p)
 164     (forward-char)))
 165
 166 (defun notmuch-show-get-message-id ()
 167   (save-excursion
 168     (beginning-of-line)
 169     (if (not (looking-at notmuch-show-message-begin-regexp))
 170         (re-search-backward notmuch-show-message-begin-regexp))
 171     (re-search-forward notmuch-show-id-regexp)
 172     (buffer-substring (match-beginning 1) (match-end 1))))
 173
 174 (defun notmuch-show-get-filename ()
 175   (save-excursion
 176     (beginning-of-line)
 177     (if (not (looking-at notmuch-show-message-begin-regexp))
 178         (re-search-backward notmuch-show-message-begin-regexp))
 179     (re-search-forward notmuch-show-filename-regexp)
 180     (buffer-substring (match-beginning 1) (match-end 1))))
 181
 182 (defun notmuch-show-set-tags (tags)
 183   (save-excursion
 184     (beginning-of-line)
 185     (if (not (looking-at notmuch-show-message-begin-regexp))
 186         (re-search-backward notmuch-show-message-begin-regexp))
 187     (re-search-forward notmuch-show-tags-regexp)
 188     (let ((inhibit-read-only t)
 189           (beg (match-beginning 1))
 190           (end (match-end 1)))
 191       (delete-region beg end)
 192       (goto-char beg)
 193       (insert (mapconcat 'identity tags " ")))))
 194
 195 (defun notmuch-show-get-tags ()
 196   (save-excursion
 197     (beginning-of-line)
 198     (if (not (looking-at notmuch-show-message-begin-regexp))
 199         (re-search-backward notmuch-show-message-begin-regexp))
 200     (re-search-forward notmuch-show-tags-regexp)
 201     (split-string (buffer-substring (match-beginning 1) (match-end 1)))))
 202
 203 (defun notmuch-show-add-tag (&rest toadd)
 204   "Add a tag to the current message."
 205   (interactive "sTag to add: ")
 206   (apply 'notmuch-call-notmuch-process
 207          (append (cons "tag"
 208                        (mapcar (lambda (s) (concat "+" s)) toadd))
 209                  (cons (notmuch-show-get-message-id) nil)))
 210   (notmuch-show-set-tags (sort (union toadd (notmuch-show-get-tags) :test 'string=) 'string<)))
 211
 212 (defun notmuch-show-remove-tag (&rest toremove)
 213   "Remove a tag from the current message."
 214   (interactive "sTag to remove: ")
 215   (let ((tags (notmuch-show-get-tags)))
 216     (if (intersection tags toremove :test 'string=)
 217         (progn
 218           (apply 'notmuch-call-notmuch-process
 219                  (append (cons "tag"
 220                                (mapcar (lambda (s) (concat "-" s)) toremove))
 221                          (cons (notmuch-show-get-message-id) nil)))
 222           (notmuch-show-set-tags (sort (set-difference tags toremove :test 'string=) 'string<))))))
 223
 224 (defun notmuch-show-archive-thread-maybe-mark-read (markread)
 225   (save-excursion
 226     (goto-char (point-min))
 227     (while (not (eobp))
 228       (if markread
 229           (notmuch-show-remove-tag "unread" "inbox")
 230         (notmuch-show-remove-tag "inbox"))
 231       (if (not (eobp))
 232           (forward-char))
 233       (if (not (re-search-forward notmuch-show-message-begin-regexp nil t))
 234           (goto-char (point-max)))))
 235   (let ((parent-buffer notmuch-show-parent-buffer))
 236     (kill-this-buffer)
 237     (if parent-buffer
 238         (progn
 239           (switch-to-buffer parent-buffer)
 240           (forward-line)
 241           (notmuch-search-show-thread)))))
 242
 243 (defun notmuch-show-mark-read-then-archive-thread ()
 244   "Remove \"unread\" tag from each message, then archive and show next thread.
 245
 246 Archive each message currently shown by removing the \"unread\"
 247 and \"inbox\" tag from each. Then kill this buffer and show the
 248 next thread from the search from which this thread was originally
 249 shown.
 250
 251 Note: This command is safe from any race condition of new messages
 252 being delivered to the same thread. It does not archive the
 253 entire thread, but only the messages shown in the current
 254 buffer."
 255   (interactive)
 256   (notmuch-show-archive-thread-maybe-mark-read t))
 257
 258 (defun notmuch-show-archive-thread ()
 259   "Archive each message in thread, and show next thread from search.
 260
 261 Archive each message currently shown by removing the \"inbox\"
 262 tag from each. Then kill this buffer and show the next thread
 263 from the search from which this thread was originally shown.
 264
 265 Note: This command is safe from any race condition of new messages
 266 being delivered to the same thread. It does not archive the
 267 entire thread, but only the messages shown in the current
 268 buffer."
 269   (interactive)
 270   (notmuch-show-archive-thread-maybe-mark-read nil))
 271
 272 (defun notmuch-show-view-raw-message ()
 273   "View the raw email of the current message."
 274   (interactive)
 275   (view-file (notmuch-show-get-filename)))
 276
 277 (defun notmuch-show-view-all-mime-parts ()
 278   "Use external viewers (according to mailcap) to view all MIME-encoded parts."
 279   (interactive)
 280   (save-excursion
 281     (let ((filename (notmuch-show-get-filename)))
 282       (switch-to-buffer (generate-new-buffer (concat "*notmuch-mime-"
 283                                                      filename
 284                                                      "*")))
 285       (insert-file-contents filename nil nil nil t)
 286       (mm-display-parts (mm-dissect-buffer))
 287       (kill-this-buffer))))
 288
 289 (defun notmuch-reply (query-string)
 290   (switch-to-buffer (generate-new-buffer "notmuch-draft"))
 291   (call-process notmuch-command nil t nil "reply" query-string)
 292   (goto-char (point-min))
 293   (if (re-search-forward "^$" nil t)
 294       (progn
 295         (insert "--text follows this line--")
 296         (forward-line)))
 297   (message-mode))
 298
 299 (defun notmuch-show-reply ()
 300   "Begin composing a reply to the current message in a new buffer."
 301   (interactive)
 302   (let ((message-id (notmuch-show-get-message-id)))
 303     (notmuch-reply message-id)))
 304
 305 (defun notmuch-show-pipe-message (command)
 306   "Pipe the contents of the current message to the given command.
 307
 308 The given command will be executed with the raw contents of the
 309 current email message as stdin. Anything printed by the command
 310 to stdout or stderr will appear in the *Messages* buffer."
 311   (interactive "sPipe message to command: ")
 312   (apply 'start-process-shell-command "notmuch-pipe-command" "*notmuch-pipe*" (split-string (concat command " < " (notmuch-show-get-filename)))))
 313
 314 (defun notmuch-show-move-to-current-message-summary-line ()
 315   "Move to the beginning of the one-line summary of the current message.
 316
 317 This gives us a stable place to move to and work from since the
 318 summary line is always visible. This is important since moving to
 319 an invisible location is unreliable, (the main command loop moves
 320 point either forward or backward to the next visible character
 321 when a command ends with point on an invisible character).
 322
 323 Emits an error if point is not within a valid message, (that is
 324 not pattern of `notmuch-show-message-begin-regexp' could be found
 325 by searching backward)."
 326   (beginning-of-line)
 327   (if (not (looking-at notmuch-show-message-begin-regexp))
 328       (if (re-search-backward notmuch-show-message-begin-regexp nil t)
 329           (forward-line 2)
 330         (error "Not within a valid message."))
 331     (forward-line 2)))
 332
 333 (defun notmuch-show-last-message-p ()
 334   "Predicate testing whether point is within the last message."
 335   (save-window-excursion
 336     (save-excursion
 337       (notmuch-show-move-to-current-message-summary-line)
 338       (not (re-search-forward notmuch-show-message-begin-regexp nil t)))))
 339
 340 (defun notmuch-show-message-unread-p ()
 341   "Preficate testing whether current message is unread."
 342   (member "unread" (notmuch-show-get-tags)))
 343
 344 (defun notmuch-show-next-message ()
 345   "Advance to the beginning of the next message in the buffer.
 346
 347 Moves to the last visible character of the current message if
 348 already on the last message in the buffer."
 349   (interactive)
 350   (notmuch-show-move-to-current-message-summary-line)
 351   (if (re-search-forward notmuch-show-message-begin-regexp nil t)
 352       (notmuch-show-move-to-current-message-summary-line)
 353     (goto-char (- (point-max) 1))
 354     (while (point-invisible-p)
 355       (backward-char)))
 356   (recenter 0))
 357
 358 (defun notmuch-show-find-next-message ()
 359   "Returns the position of the next message in the buffer.
 360
 361 Or the position of the last visible character of the current
 362 message if already within the last message in the buffer."
 363   ; save-excursion doesn't save our window position
 364   ; save-window-excursion doesn't save point
 365   ; Looks like we have to use both.
 366   (save-excursion
 367     (save-window-excursion
 368       (notmuch-show-next-message)
 369       (point))))
 370
 371 (defun notmuch-show-next-unread-message ()
 372   "Advance to the beginning of the next unread message in the buffer.
 373
 374 Moves to the last visible character of the current message if
 375 there are no more unread messages past the current point."
 376   (notmuch-show-next-message)
 377   (while (and (not (notmuch-show-last-message-p))
 378               (not (notmuch-show-message-unread-p)))
 379     (notmuch-show-next-message))
 380   (if (not (notmuch-show-message-unread-p))
 381       (notmuch-show-next-message)))
 382
 383 (defun notmuch-show-next-open-message ()
 384   "Advance to the next message which is not hidden.
 385
 386 If read messages are currently hidden, advance to the next unread
 387 message. Otherwise, advance to the next message."
 388   (if (or (memq 'notmuch-show-body-read buffer-invisibility-spec)
 389           (assq 'notmuch-show-body-read buffer-invisibility-spec))
 390       (notmuch-show-next-unread-message)
 391     (notmuch-show-next-message)))
 392
 393 (defun notmuch-show-previous-message ()
 394   "Backup to the beginning of the previous message in the buffer.
 395
 396 If within a message rather than at the beginning of it, then
 397 simply move to the beginning of the current message."
 398   (interactive)
 399   (let ((start (point)))
 400     (notmuch-show-move-to-current-message-summary-line)
 401     (if (not (< (point) start))
 402         ; Go backward twice to skip the current message's marker
 403         (progn
 404           (re-search-backward notmuch-show-message-begin-regexp nil t)
 405           (re-search-backward notmuch-show-message-begin-regexp nil t)
 406           (notmuch-show-move-to-current-message-summary-line)
 407           ))
 408     (recenter 0)))
 409
 410 (defun notmuch-show-find-previous-message ()
 411   "Returns the position of the previous message in the buffer.
 412
 413 Or the position of the beginning of the current message if point
 414 is originally within the message rather than at the beginning of
 415 it."
 416   ; save-excursion doesn't save our window position
 417   ; save-window-excursion doesn't save point
 418   ; Looks like we have to use both.
 419   (save-excursion
 420     (save-window-excursion
 421       (notmuch-show-previous-message)
 422       (point))))
 423
 424 (defun notmuch-show-mark-read-then-next-open-message ()
 425   "Remove unread tag from current message, then advance to next unread message."
 426   (interactive)
 427   (notmuch-show-remove-tag "unread")
 428   (notmuch-show-next-open-message))
 429
 430 (defun notmuch-show-rewind ()
 431   "Do reverse scrolling compared to `notmuch-show-advance-marking-read-and-archiving'
 432
 433 Specifically, if the beginning of the previous email is fewer
 434 than `window-height' lines from the current point, move to it
 435 just like `notmuch-show-previous-message'.
 436
 437 Otherwise, just scroll down a screenful of the current message.
 438
 439 This command does not modify any message tags, (it does not undo
 440 any effects from previous calls to
 441 `notmuch-show-advance-marking-read-and-archiving'."
 442   (interactive)
 443   (let ((previous (notmuch-show-find-previous-message)))
 444     (if (> (count-lines previous (point)) (- (window-height) next-screen-context-lines))
 445         (progn
 446           (condition-case nil
 447               (scroll-down nil)
 448             ((beginning-of-buffer) nil))
 449           (goto-char (window-start)))
 450       (notmuch-show-previous-message))))
 451
 452 (defun notmuch-show-advance-marking-read-and-archiving ()
 453   "Advance through buffer, marking read and archiving.
 454
 455 This command is intended to be one of the simplest ways to
 456 process a thread of email. It does the following:
 457
 458 If the current message in the thread is not yet fully visible,
 459 scroll by a near screenful to read more of the message.
 460
 461 Otherwise, (the end of the current message is already within the
 462 current window), remove the \"unread\" tag (if present) from the
 463 current message and advance to the next open message.
 464
 465 Finally, if there is no further message to advance to, and this
 466 last message is already read, then archive the entire current
 467 thread, (remove the \"inbox\" tag from each message). Also kill
 468 this buffer, and display the next thread from the search from
 469 which this thread was originally shown."
 470   (interactive)
 471   (let ((next (notmuch-show-find-next-message))
 472         (unread (notmuch-show-message-unread-p)))
 473     (if (> next (window-end))
 474         (scroll-up nil)
 475       (let ((last (notmuch-show-last-message-p)))
 476         (notmuch-show-mark-read-then-next-open-message)
 477         (if last
 478             (notmuch-show-archive-thread))))))
 479
 480 (defun notmuch-show-markup-citations-region (beg end depth)
 481   (goto-char beg)
 482   (beginning-of-line)
 483   (while (< (point) end)
 484     (let ((beg-sub (point-marker))
 485           (indent (make-string depth ? ))
 486           (citation "[[:space:]]*>"))
 487       (if (looking-at citation)
 488           (progn
 489             (while (looking-at citation)
 490               (forward-line))
 491             (let ((overlay (make-overlay beg-sub (point))))
 492               (overlay-put overlay 'invisible 'notmuch-show-citation)
 493               (let (
 494                     (p (point))
 495                     (cite-button-text (concat "[" (number-to-string (count-lines beg-sub (point)))
 496                                               "-line citation. Press 'c' to show.]"))
 497                     )
 498                 (goto-char (- beg-sub 1))
 499                 (insert (concat "\n" indent))
 500                 (insert-button cite-button-text)
 501                 (insert "\n")
 502                 (goto-char (+ (length cite-button-text) p))
 503               ))))
 504       (move-to-column depth)
 505       (if (looking-at notmuch-show-signature-regexp)
 506           (let ((sig-lines (- (count-lines beg-sub end) 1)))
 507             (if (<= sig-lines notmuch-show-signature-lines-max)
 508                 (progn
 509                   (overlay-put (make-overlay beg-sub end)
 510                                'invisible 'notmuch-show-signature)
 511                   (goto-char (- beg-sub 1))
 512                   (insert (concat "\n" indent))
 513                   (insert-button (concat "[" (number-to-string sig-lines)
 514                                          "-line signature. Press 's' to show.]"))
 515                   (insert "\n")
 516                   (goto-char end)))))
 517       (forward-line))))
 518
 519 (defun notmuch-show-markup-part (beg end depth)
 520   (if (re-search-forward notmuch-show-part-begin-regexp nil t)
 521       (progn
 522         (forward-line)
 523         (let ((beg (point-marker)))
 524           (re-search-forward notmuch-show-part-end-regexp)
 525           (let ((end (copy-marker (match-beginning 0))))
 526             (goto-char end)
 527             (if (not (bolp))
 528                 (insert "\n"))
 529             (indent-rigidly beg end depth)
 530             (notmuch-show-markup-citations-region beg end depth)
 531             ; Advance to the next part (if any) (so the outer loop can
 532             ; determine whether we've left the current message.
 533             (if (re-search-forward notmuch-show-part-begin-regexp nil t)
 534                 (beginning-of-line)))))
 535     (goto-char end)))
 536
 537 (defun notmuch-show-markup-parts-region (beg end depth)
 538   (save-excursion
 539     (goto-char beg)
 540     (while (< (point) end)
 541       (notmuch-show-markup-part beg end depth))))
 542
 543 (defun notmuch-show-markup-body (depth)
 544   (re-search-forward notmuch-show-body-begin-regexp)
 545   (forward-line)
 546   (let ((beg (point-marker)))
 547     (re-search-forward notmuch-show-body-end-regexp)
 548     (let ((end (copy-marker (match-beginning 0))))
 549       (notmuch-show-markup-parts-region beg end depth)
 550       (if (not (notmuch-show-message-unread-p))
 551           (overlay-put (make-overlay beg end)
 552                        'invisible 'notmuch-show-body-read))
 553       (set-marker beg nil)
 554       (set-marker end nil)
 555       )))
 556
 557 (defun notmuch-show-markup-header (depth)
 558   (re-search-forward notmuch-show-header-begin-regexp)
 559   (forward-line)
 560   (let ((beg (point-marker)))
 561     (end-of-line)
 562     ; Inverse video for subject
 563     (overlay-put (make-overlay beg (point)) 'face '(:inverse-video t))
 564     (forward-line 2)
 565     (let ((beg-hidden (point-marker)))
 566       (re-search-forward notmuch-show-header-end-regexp)
 567       (beginning-of-line)
 568       (let ((end (point-marker)))
 569         (indent-rigidly beg end depth)
 570         (overlay-put (make-overlay beg-hidden end)
 571                      'invisible 'notmuch-show-header)
 572         (set-marker beg nil)
 573         (set-marker beg-hidden nil)
 574         (set-marker end nil)
 575         ))))
 576
 577 (defun notmuch-show-markup-message ()
 578   (if (re-search-forward notmuch-show-message-begin-regexp nil t)
 579       (progn
 580         (re-search-forward notmuch-show-depth-regexp)
 581         (let ((depth (string-to-number (buffer-substring (match-beginning 1) (match-end 1)))))
 582           (notmuch-show-markup-header depth)
 583           (notmuch-show-markup-body depth)))
 584     (goto-char (point-max))))
 585
 586 (defun notmuch-show-hide-markers ()
 587   (save-excursion
 588     (goto-char (point-min))
 589     (while (not (eobp))
 590       (if (re-search-forward notmuch-show-marker-regexp nil t)
 591           (progn
 592             (overlay-put (make-overlay (match-beginning 0) (+ (match-end 0) 1))
 593                          'invisible 'notmuch-show-marker))
 594         (goto-char (point-max))))))
 595
 596 (defun notmuch-show-markup-messages ()
 597   (save-excursion
 598     (goto-char (point-min))
 599     (while (not (eobp))
 600       (notmuch-show-markup-message)))
 601   (notmuch-show-hide-markers))
 602
 603 (defun notmuch-show-toggle-citations-visible ()
 604   "Toggle visibility of citations"
 605   (interactive)
 606   (if notmuch-show-citations-visible
 607       (add-to-invisibility-spec 'notmuch-show-citation)
 608     (remove-from-invisibility-spec 'notmuch-show-citation))
 609   (set 'notmuch-show-citations-visible (not notmuch-show-citations-visible))
 610   ; Need to force the redisplay for some reason
 611   (force-window-update)
 612   (redisplay t))
 613
 614 (defun notmuch-show-toggle-signatures-visible ()
 615   "Toggle visibility of signatures"
 616   (interactive)
 617   (if notmuch-show-signatures-visible
 618       (add-to-invisibility-spec 'notmuch-show-signature)
 619     (remove-from-invisibility-spec 'notmuch-show-signature))
 620   (set 'notmuch-show-signatures-visible (not notmuch-show-signatures-visible))
 621   ; Need to force the redisplay for some reason
 622   (force-window-update)
 623   (redisplay t))
 624
 625 (defun notmuch-show-toggle-headers-visible ()
 626   "Toggle visibility of header fields"
 627   (interactive)
 628   (if notmuch-show-headers-visible
 629       (add-to-invisibility-spec 'notmuch-show-header)
 630     (remove-from-invisibility-spec 'notmuch-show-header))
 631   (set 'notmuch-show-headers-visible (not notmuch-show-headers-visible))
 632   ; Need to force the redisplay for some reason
 633   (force-window-update)
 634   (redisplay t))
 635
 636 (defun notmuch-show-toggle-body-read-visible ()
 637   "Toggle visibility of message bodies of read messages"
 638   (interactive)
 639   (if notmuch-show-body-read-visible
 640       (add-to-invisibility-spec 'notmuch-show-body-read)
 641     (remove-from-invisibility-spec 'notmuch-show-body-read))
 642   (set 'notmuch-show-body-read-visible (not notmuch-show-body-read-visible))
 643   ; Need to force the redisplay for some reason
 644   (force-window-update)
 645   (redisplay t))
 646
 647 ;;;###autoload
 648 (defun notmuch-show-mode ()
 649   "Major mode for viewing a thread with notmuch.
 650
 651 This buffer contains the results of the \"notmuch show\" command
 652 for displaying a single thread of email from your email archives.
 653
 654 By default, various components of email messages, (citations,
 655 signatures, already-read messages), are invisible to help you
 656 focus on the most important things, (new text from unread
 657 messages). See the various commands below for toggling the
 658 visibility of hidden components.
 659
 660 The `notmuch-show-next-message' and
 661 `notmuch-show-previous-message' commands, (bound to 'n' and 'p by
 662 default), allow you to navigate to the next and previous
 663 messages. Each time you navigate away from a message with
 664 `notmuch-show-next-message' the current message will have its
 665 \"unread\" tag removed.
 666
 667 You can add or remove tags from the current message with '+' and
 668 '-'.  You can also archive all messages in the current
 669 view, (remove the \"inbox\" tag from each), with
 670 `notmuch-show-archive-thread' (bound to 'a' by default).
 671
 672 \\{notmuch-show-mode-map}"
 673   (interactive)
 674   (kill-all-local-variables)
 675   (set (make-local-variable 'notmuch-show-headers-visible) t)
 676   (notmuch-show-toggle-headers-visible)
 677   (set (make-local-variable 'notmuch-show-body-read-visible) t)
 678   (notmuch-show-toggle-body-read-visible)
 679   (set (make-local-variable 'notmuch-show-citations-visible) t)
 680   (notmuch-show-toggle-citations-visible)
 681   (set (make-local-variable 'notmuch-show-signatures-visible) t)
 682   (notmuch-show-toggle-signatures-visible)
 683   (add-to-invisibility-spec 'notmuch-show-marker)
 684   (use-local-map notmuch-show-mode-map)
 685   (setq major-mode 'notmuch-show-mode
 686         mode-name "notmuch-show")
 687   (setq buffer-read-only t))
 688
 689 ;;;###autoload
 690
 691 (defgroup notmuch nil
 692   "Notmuch mail reader for Emacs."
 693   :group 'mail)
 694
 695 (defcustom notmuch-show-hook nil
 696   "List of functions to call when notmuch displays a message."
 697   :type 'hook
 698   :options '(goto-address)
 699   :group 'notmuch)
 700
 701 (defcustom notmuch-search-hook nil
 702   "List of functions to call when notmuch displays the search results."
 703   :type 'hook
 704   :options '(hl-line-mode)
 705   :group 'notmuch)
 706
 707 ; Make show mode a bit prettier, highlighting URLs and using word wrap
 708
 709 (defun notmuch-show-pretty-hook ()
 710   (goto-address-mode 1)
 711   (visual-line-mode))
 712
 713 (add-hook 'notmuch-show-hook 'notmuch-show-pretty-hook)
 714 (add-hook 'notmuch-search-hook
 715           (lambda()
 716             (hl-line-mode 1) ))
 717
 718 (defun notmuch-show (thread-id &optional parent-buffer)
 719   "Run \"notmuch show\" with the given thread ID and display results.
 720
 721 The optional PARENT-BUFFER is the notmuch-search buffer from
 722 which this notmuch-show command was executed, (so that the next
 723 thread from that buffer can be show when done with this one)."
 724   (interactive "sNotmuch show: ")
 725   (let ((buffer (get-buffer-create (concat "*notmuch-show-" thread-id "*"))))
 726     (switch-to-buffer buffer)
 727     (notmuch-show-mode)
 728     (set (make-local-variable 'notmuch-show-parent-buffer) parent-buffer)
 729     (let ((proc (get-buffer-process (current-buffer)))
 730           (inhibit-read-only t))
 731       (if proc
 732           (error "notmuch search process already running for query `%s'" thread-id)
 733         )
 734       (erase-buffer)
 735       (goto-char (point-min))
 736       (save-excursion
 737         (call-process notmuch-command nil t nil "show" thread-id)
 738         (notmuch-show-markup-messages)
 739         )
 740       (run-hooks 'notmuch-show-hook)
 741       ; Move straight to the first unread message
 742       (if (not (notmuch-show-message-unread-p))
 743           (progn
 744             (notmuch-show-next-unread-message)
 745             ; But if there are no unread messages, go back to the
 746             ; beginning of the buffer, and open up the bodies of all
 747             ; read message.
 748             (if (not (notmuch-show-message-unread-p))
 749                 (progn
 750                   (goto-char (point-min))
 751                   (notmuch-show-toggle-body-read-visible)))))
 752       )))
 753
 754 (defvar notmuch-search-authors-width 40
 755   "Number of columns to use to display authors in a notmuch-search buffer.")
 756
 757 (defvar notmuch-search-mode-map
 758   (let ((map (make-sparse-keymap)))
 759     (define-key map "a" 'notmuch-search-archive-thread)
 760     (define-key map "b" 'notmuch-search-scroll-down)
 761     (define-key map "f" 'notmuch-search-filter)
 762     (define-key map "m" 'message-mail)
 763     (define-key map "n" 'next-line)
 764     (define-key map "o" 'notmuch-search-toggle-order)
 765     (define-key map "p" 'previous-line)
 766     (define-key map "q" 'kill-this-buffer)
 767     (define-key map "r" 'notmuch-search-reply-to-thread)
 768     (define-key map "s" 'notmuch-search)
 769     (define-key map "t" 'notmuch-search-filter-by-tag)
 770     (define-key map "x" 'kill-this-buffer)
 771     (define-key map (kbd "RET") 'notmuch-search-show-thread)
 772     (define-key map "+" 'notmuch-search-add-tag)
 773     (define-key map "-" 'notmuch-search-remove-tag)
 774     (define-key map "<" 'beginning-of-buffer)
 775     (define-key map ">" 'notmuch-search-goto-last-thread)
 776     (define-key map "=" 'notmuch-search-refresh-view)
 777     (define-key map "\M->" 'notmuch-search-goto-last-thread)
 778     (define-key map " " 'notmuch-search-scroll-up)
 779     (define-key map (kbd "<DEL>") 'notmuch-search-scroll-down)
 780     (define-key map "?" 'describe-mode)
 781     map)
 782   "Keymap for \"notmuch search\" buffers.")
 783 (fset 'notmuch-search-mode-map notmuch-search-mode-map)
 784
 785 (defvar notmuch-search-query-string)
 786 (defvar notmuch-search-oldest-first)
 787
 788 (defun notmuch-search-scroll-up ()
 789   "Scroll up, moving point to last message in thread if at end."
 790   (interactive)
 791   (condition-case nil
 792       (scroll-up nil)
 793     ((end-of-buffer) (notmuch-search-goto-last-thread))))
 794
 795 (defun notmuch-search-scroll-down ()
 796   "Scroll down, moving point to first message in thread if at beginning."
 797   (interactive)
 798   ; I don't know why scroll-down doesn't signal beginning-of-buffer
 799   ; the way that scroll-up signals end-of-buffer, but c'est la vie.
 800   ;
 801   ; So instead of trapping a signal we instead check whether the
 802   ; window begins on the first line of the buffer and if so, move
 803   ; directly to that position. (We have to count lines since the
 804   ; window-start position is not the same as point-min due to the
 805   ; invisible thread-ID characters on the first line.
 806   (if (equal (count-lines (point-min) (window-start)) 1)
 807       (goto-char (window-start))
 808     (scroll-down nil)))
 809
 810 (defun notmuch-search-goto-last-thread ()
 811   "Move point to the last thread in the buffer."
 812   (interactive)
 813   (goto-char (point-max))
 814   (forward-line -1))
 815
 816 ;;;###autoload
 817 (defun notmuch-search-mode ()
 818   "Major mode for searching mail with notmuch.
 819
 820 This buffer contains the results of a \"notmuch search\" of your
 821 email archives. Each line in the buffer represents a single
 822 thread giving a relative date for the thread and a subject.
 823
 824 Pressing RET on any line displays that thread. The '+' and '-'
 825 keys can be used to add or remove tags from a thread. The 'a' key
 826 is a convenience key for archiving a thread (removing the
 827 \"inbox\" tag).
 828
 829 Other useful commands are `notmuch-search-filter' for filtering
 830 the current search based on an additional query string,
 831 `notmuch-search-filter-by-tag' for filtering to include only
 832 messages with a given tag, and `notmuch-search' to execute a new,
 833 global search.
 834
 835 \\{notmuch-search-mode-map}"
 836   (interactive)
 837   (kill-all-local-variables)
 838   (make-local-variable 'notmuch-search-query-string)
 839   (make-local-variable 'notmuch-search-oldest-first)
 840   (set (make-local-variable 'scroll-preserve-screen-position) t)
 841   (add-to-invisibility-spec 'notmuch-search)
 842   (use-local-map notmuch-search-mode-map)
 843   (setq truncate-lines t)
 844   (setq major-mode 'notmuch-search-mode
 845         mode-name "notmuch-search")
 846   (setq buffer-read-only t))
 847
 848 (defun notmuch-search-find-thread-id ()
 849   (save-excursion
 850     (beginning-of-line)
 851     (let ((beg (point)))
 852       (re-search-forward "thread:[a-fA-F0-9]*" nil t)
 853       (filter-buffer-substring beg (point)))))
 854
 855 (defun notmuch-search-markup-this-thread-id ()
 856   (beginning-of-line)
 857   (let ((beg (point)))
 858     (if (re-search-forward "thread:[a-fA-F0-9]*" nil t)
 859         (progn
 860           (forward-char)
 861           (overlay-put (make-overlay beg (point)) 'invisible 'notmuch-search)
 862           (re-search-forward ".*\\[[0-9]*/[0-9]*\\] \\([^;]*\\)\\(;\\)")
 863           (let* ((authors (buffer-substring (match-beginning 1) (match-end 1)))
 864                  (authors-length (length authors)))
 865             ;; Drop the semi-colon
 866             (replace-match "" t nil nil 2)
 867             (if (<= authors-length notmuch-search-authors-width)
 868                 (replace-match (concat authors (make-string
 869                                                 (- notmuch-search-authors-width
 870                                                    authors-length) ? )) t t nil 1)
 871               (replace-match (concat (substring authors 0 (- notmuch-search-authors-width 3)) "...") t t nil 1)))))))
 872
 873 (defun notmuch-search-markup-thread-ids ()
 874   (save-excursion
 875     (goto-char (point-min))
 876     (while (not (eobp))
 877       (notmuch-search-markup-this-thread-id)
 878       (forward-line))))
 879
 880 (defun notmuch-search-show-thread ()
 881   (interactive)
 882   (let ((thread-id (notmuch-search-find-thread-id)))
 883     (if (> (length thread-id) 0)
 884         (notmuch-show thread-id (current-buffer))
 885       (error "End of search results"))))
 886
 887 (defun notmuch-search-reply-to-thread ()
 888   "Begin composing a reply to the entire current thread in a new buffer."
 889   (interactive)
 890   (let ((message-id (notmuch-search-find-thread-id)))
 891     (notmuch-reply message-id)))
 892
 893 (defun notmuch-call-notmuch-process (&rest args)
 894   "Synchronously invoke \"notmuch\" with the given list of arguments.
 895
 896 Output from the process will be presented to the user as an error
 897 and will also appear in a buffer named \"*Notmuch errors*\"."
 898   (let ((error-buffer (get-buffer-create "*Notmuch errors*")))
 899     (with-current-buffer error-buffer
 900         (erase-buffer))
 901     (if (eq (apply 'call-process notmuch-command nil error-buffer nil args) 0)
 902         (point)
 903       (progn
 904         (with-current-buffer error-buffer
 905           (let ((beg (point-min))
 906                 (end (- (point-max) 1)))
 907             (error (buffer-substring beg end))
 908             ))))))
 909
 910 (defun notmuch-search-set-tags (tags)
 911   (save-excursion
 912     (end-of-line)
 913     (re-search-backward "(")
 914     (forward-char)
 915     (let ((beg (point))
 916           (inhibit-read-only t))
 917       (re-search-forward ")")
 918       (backward-char)
 919       (let ((end (point)))
 920         (delete-region beg end)
 921         (insert (mapconcat  'identity tags " "))))))
 922
 923 (defun notmuch-search-get-tags ()
 924   (save-excursion
 925     (end-of-line)
 926     (re-search-backward "(")
 927     (let ((beg (+ (point) 1)))
 928       (re-search-forward ")")
 929       (let ((end (- (point) 1)))
 930         (split-string (buffer-substring beg end))))))
 931
 932 (defun notmuch-search-add-tag (tag)
 933   (interactive "sTag to add: ")
 934   (notmuch-call-notmuch-process "tag" (concat "+" tag) (notmuch-search-find-thread-id))
 935   (notmuch-search-set-tags (delete-dups (sort (cons tag (notmuch-search-get-tags)) 'string<))))
 936
 937 (defun notmuch-search-remove-tag (tag)
 938   (interactive "sTag to remove: ")
 939   (notmuch-call-notmuch-process "tag" (concat "-" tag) (notmuch-search-find-thread-id))
 940   (notmuch-search-set-tags (delete tag (notmuch-search-get-tags))))
 941
 942 (defun notmuch-search-archive-thread ()
 943   "Archive the current thread (remove its \"inbox\" tag).
 944
 945 This function advances point to the next line when finished."
 946   (interactive)
 947   (notmuch-search-remove-tag "inbox")
 948   (forward-line))
 949
 950 (defun notmuch-search (query &optional oldest-first)
 951   "Run \"notmuch search\" with the given query string and display results."
 952   (interactive "sNotmuch search: ")
 953   (let ((buffer (get-buffer-create (concat "*notmuch-search-" query "*"))))
 954     (switch-to-buffer buffer)
 955     (notmuch-search-mode)
 956     (set 'notmuch-search-query-string query)
 957     (set 'notmuch-search-oldest-first oldest-first)
 958     (let ((proc (get-buffer-process (current-buffer)))
 959           (inhibit-read-only t))
 960       (if proc
 961           (error "notmuch search process already running for query `%s'" query)
 962         )
 963       (erase-buffer)
 964       (goto-char (point-min))
 965       (save-excursion
 966         (if oldest-first
 967             (call-process notmuch-command nil t nil "search" "--sort=oldest-first" query)
 968           (call-process notmuch-command nil t nil "search" "--sort=newest-first" query))
 969         (notmuch-search-markup-thread-ids)
 970         ))
 971     (run-hooks 'notmuch-search-hook)))
 972
 973 (defun notmuch-search-refresh-view ()
 974   "Refresh the current view.
 975
 976 Kills the current buffer and runs a new search with the same
 977 query string as the current search. If the current thread is in
 978 the new search results, then point will be placed on the same
 979 thread. Otherwise, point will be moved to attempt to be in the
 980 same relative position within the new buffer."
 981   (interactive)
 982   (let ((here (point))
 983         (oldest-first notmuch-search-oldest-first)
 984         (thread (notmuch-search-find-thread-id))
 985         (query notmuch-search-query-string))
 986     (kill-this-buffer)
 987     (notmuch-search query oldest-first)
 988     (goto-char (point-min))
 989     (if (re-search-forward (concat "^" thread) nil t)
 990         (beginning-of-line)
 991       (goto-char here))))
 992
 993 (defun notmuch-search-toggle-order ()
 994   "Toggle the current search order.
 995
 996 By default, the \"inbox\" view created by `notmuch' is displayed
 997 in chronological order (oldest thread at the beginning of the
 998 buffer), while any global searches created by `notmuch-search'
 999 are displayed in reverse-chronological order (newest thread at
1000 the beginning of the buffer).
1001
1002 This command toggles the sort order for the current search.
1003
1004 Note that any filtered searches created by
1005 `notmuch-search-filter' retain the search order of the parent
1006 search."
1007   (interactive)
1008   (set 'notmuch-search-oldest-first (not notmuch-search-oldest-first))
1009   (notmuch-search-refresh-view))
1010
1011 (defun notmuch-search-filter (query)
1012   "Filter the current search results based on an additional query string.
1013
1014 Runs a new search matching only messages that match both the
1015 current search results AND the additional query string provided."
1016   (interactive "sFilter search: ")
1017   (notmuch-search (concat notmuch-search-query-string " and " query) notmuch-search-oldest-first))
1018
1019 (defun notmuch-search-filter-by-tag (tag)
1020   "Filter the current search results based on a single tag.
1021
1022 Runs a new search matching only messages that match both the
1023 current search results AND that are tagged with the given tag."
1024   (interactive "sFilter by tag: ")
1025   (notmuch-search (concat notmuch-search-query-string " and tag:" tag) notmuch-search-oldest-first))
1026
1027 (defun notmuch ()
1028   "Run notmuch to display all mail with tag of 'inbox'"
1029   (interactive)
1030   (notmuch-search "tag:inbox" t))
1031
1032 (setq mail-user-agent 'message-user-agent)
1033
1034 (provide 'notmuch)