git.notmuchmail.org Git - notmuch/blob - test/test-lib.el

   1 ;; test-lib.el --- auxiliary stuff for Notmuch Emacs tests.
   2 ;;
   3 ;; Copyright © Carl Worth
   4 ;; Copyright © David Edmondson
   5 ;;
   6 ;; This file is part of Notmuch test suit.
   7 ;;
   8 ;; Notmuch is free software: you can redistribute it and/or modify it
   9 ;; under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation, either version 3 of the License, or
  11 ;; (at your option) any later version.
  12 ;;
  13 ;; Notmuch is distributed in the hope that it will be useful, but
  14 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 ;; General Public License for more details.
  17 ;;
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with Notmuch.  If not, see <http://www.gnu.org/licenses/>.
  20 ;;
  21 ;; Authors: Dmitry Kurochkin <dmitry.kurochkin@gmail.com>
  22
  23 (require 'cl)   ;; This code is generally used uncompiled.
  24
  25 ;; `read-file-name' by default uses `completing-read' function to read
  26 ;; user input.  It does not respect `standard-input' variable which we
  27 ;; use in tests to provide user input.  So replace it with a plain
  28 ;; `read' call.
  29 (setq read-file-name-function (lambda (&rest _) (read)))
  30
  31 ;; Work around a bug in emacs 23.1 and emacs 23.2 which prevents
  32 ;; noninteractive (kill-emacs) from emacsclient.
  33 (if (and (= emacs-major-version 23) (< emacs-minor-version 3))
  34   (defadvice kill-emacs (before disable-yes-or-no-p activate)
  35     "Disable yes-or-no-p before executing kill-emacs"
  36     (defun yes-or-no-p (prompt) t)))
  37
  38 ;; Emacs bug #2930:
  39 ;;      23.0.92; `accept-process-output' and `sleep-for' do not run sentinels
  40 ;; seems to be present in Emacs 23.1.
  41 ;; Running `list-processes' after `accept-process-output' seems to work
  42 ;; around this problem.
  43 (if (and (= emacs-major-version 23) (= emacs-minor-version 1))
  44   (defadvice accept-process-output (after run-list-processes activate)
  45     "run list-processes after executing accept-process-output"
  46     (list-processes)))
  47
  48 (defun notmuch-test-wait ()
  49   "Wait for process completion."
  50   (while (get-buffer-process (current-buffer))
  51     (accept-process-output nil 0.1)))
  52
  53 (defun test-output (&optional filename)
  54   "Save current buffer to file FILENAME.  Default FILENAME is OUTPUT."
  55   (write-region (point-min) (point-max) (or filename "OUTPUT")))
  56
  57 (defun test-visible-output (&optional filename)
  58   "Save visible text in current buffer to file FILENAME.  Default
  59 FILENAME is OUTPUT."
  60   (let ((text (visible-buffer-string)))
  61     (with-temp-file (or filename "OUTPUT") (insert text))))
  62
  63 (defun visible-buffer-string ()
  64   "Same as `buffer-string', but excludes invisible text and
  65 removes any text properties."
  66   (visible-buffer-substring (point-min) (point-max)))
  67
  68 (defun visible-buffer-substring (start end)
  69   "Same as `buffer-substring-no-properties', but excludes
  70 invisible text."
  71   (let (str)
  72     (while (< start end)
  73       (let ((next-pos (next-char-property-change start end)))
  74         (when (not (invisible-p start))
  75           (setq str (concat str (buffer-substring-no-properties
  76                                  start next-pos))))
  77         (setq start next-pos)))
  78     str))
  79
  80 (defun orphan-watchdog-check (pid)
  81   "Periodically check that the process with id PID is still
  82 running, quit if it terminated."
  83   (if (not (process-attributes pid))
  84       (kill-emacs)))
  85
  86 (defun orphan-watchdog (pid)
  87   "Initiate orphan watchdog check."
  88   ; If process-attributes returns nil right away, that probably means
  89   ; it is unimplimented. So we delay two minutes before killing emacs.
  90   (if (process-attributes pid)
  91       (run-at-time 60 60 'orphan-watchdog-check pid)
  92     (run-at-time 120 60 'orphan-watchdog-check pid)))
  93
  94 (defun hook-counter (hook)
  95   "Count how many times a hook is called.  Increments
  96 `hook'-counter variable value if it is bound, otherwise does
  97 nothing."
  98   (let ((counter (intern (concat (symbol-name hook) "-counter"))))
  99     (if (boundp counter)
 100         (set counter (1+ (symbol-value counter))))))
 101
 102 (defun add-hook-counter (hook)
 103   "Add hook to count how many times `hook' is called."
 104   (add-hook hook (apply-partially 'hook-counter hook)))
 105
 106 (add-hook-counter 'notmuch-hello-mode-hook)
 107 (add-hook-counter 'notmuch-hello-refresh-hook)
 108
 109 (defadvice notmuch-search-process-filter (around pessimal activate disable)
 110   "Feed notmuch-search-process-filter one character at a time."
 111   (let ((string (ad-get-arg 1)))
 112     (loop for char across string
 113           do (progn
 114                (ad-set-arg 1 (char-to-string char))
 115                ad-do-it))))
 116
 117 (defun notmuch-test-mark-links ()
 118   "Enclose links in the current buffer with << and >>."
 119   ;; Links are often created by jit-lock functions
 120   (jit-lock-fontify-now)
 121   (save-excursion
 122     (let ((inhibit-read-only t))
 123       (goto-char (point-min))
 124       (let ((button))
 125         (while (setq button (next-button (point)))
 126           (goto-char (button-start button))
 127           (insert "<<")
 128           (goto-char (button-end button))
 129           (insert ">>"))))))
 130
 131 (defmacro notmuch-test-run (&rest body)
 132   "Evaluate a BODY of test expressions and output the result."
 133   `(with-temp-buffer
 134      (let ((buffer (current-buffer))
 135            (result (progn ,@body)))
 136        (switch-to-buffer buffer)
 137        (insert (if (stringp result)
 138                    result
 139                  (prin1-to-string result)))
 140        (test-output))))
 141
 142 (defun notmuch-test-report-unexpected (output expected)
 143   "Report that the OUTPUT does not match the EXPECTED result."
 144   (concat "Expect:\t" (prin1-to-string expected) "\n"
 145           "Output:\t" (prin1-to-string output) "\n"))
 146
 147 (defun notmuch-test-expect-equal (output expected)
 148   "Compare OUTPUT with EXPECTED. Report any discrepencies."
 149   (if (equal output expected)
 150       t
 151     (cond
 152      ((and (listp output)
 153            (listp expected))
 154       ;; Reporting the difference between two lists is done by
 155       ;; reporting differing elements of OUTPUT and EXPECTED
 156       ;; pairwise. This is expected to make analysis of failures
 157       ;; simpler.
 158       (apply #'concat (loop for o in output
 159                             for e in expected
 160                             if (not (equal o e))
 161                             collect (notmuch-test-report-unexpected o e))))
 162
 163      (t
 164       (notmuch-test-report-unexpected output expected)))))