git.notmuchmail.org Git - notmuch/blob - test/test-lib.el

   1 ;; test-lib.el --- auxiliary stuff for Notmuch Emacs tests.
   2 ;;
   3 ;; Copyright © Carl Worth
   4 ;; Copyright © David Edmondson
   5 ;;
   6 ;; This file is part of Notmuch test suit.
   7 ;;
   8 ;; Notmuch is free software: you can redistribute it and/or modify it
   9 ;; under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation, either version 3 of the License, or
  11 ;; (at your option) any later version.
  12 ;;
  13 ;; Notmuch is distributed in the hope that it will be useful, but
  14 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 ;; General Public License for more details.
  17 ;;
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with Notmuch.  If not, see <https://www.gnu.org/licenses/>.
  20 ;;
  21 ;; Authors: Dmitry Kurochkin <dmitry.kurochkin@gmail.com>
  22
  23 (require 'cl-lib)
  24
  25 ;; Ensure that the dynamic variables that are defined by this library
  26 ;; are defined by the time that we let-bind them.  This is needed
  27 ;; because starting with Emacs 27 undeclared variables in evaluated
  28 ;; interactive code (such as our tests) use lexical scope.
  29 (require 'smtpmail)
  30
  31 ;; `read-file-name' by default uses `completing-read' function to read
  32 ;; user input.  It does not respect `standard-input' variable which we
  33 ;; use in tests to provide user input.  So replace it with a plain
  34 ;; `read' call.
  35 (setq read-file-name-function (lambda (&rest _) (read)))
  36
  37 ;; Work around a bug in emacs 23.1 and emacs 23.2 which prevents
  38 ;; noninteractive (kill-emacs) from emacsclient.
  39 (if (and (= emacs-major-version 23) (< emacs-minor-version 3))
  40   (defadvice kill-emacs (before disable-yes-or-no-p activate)
  41     "Disable yes-or-no-p before executing kill-emacs"
  42     (defun yes-or-no-p (prompt) t)))
  43
  44 ;; Emacs bug #2930:
  45 ;;      23.0.92; `accept-process-output' and `sleep-for' do not run sentinels
  46 ;; seems to be present in Emacs 23.1.
  47 ;; Running `list-processes' after `accept-process-output' seems to work
  48 ;; around this problem.
  49 (if (and (= emacs-major-version 23) (= emacs-minor-version 1))
  50   (defadvice accept-process-output (after run-list-processes activate)
  51     "run list-processes after executing accept-process-output"
  52     (list-processes)))
  53
  54 (defun notmuch-test-wait ()
  55   "Wait for process completion."
  56   (while (get-buffer-process (current-buffer))
  57     (accept-process-output nil 0.1)))
  58
  59 (defun test-output (&optional filename)
  60   "Save current buffer to file FILENAME.  Default FILENAME is OUTPUT."
  61   (notmuch-post-command)
  62   (write-region (point-min) (point-max) (or filename "OUTPUT")))
  63
  64 (defun test-visible-output (&optional filename)
  65   "Save visible text in current buffer to file FILENAME.  Default
  66 FILENAME is OUTPUT."
  67   (notmuch-post-command)
  68   (let ((text (visible-buffer-string))
  69         ;; Tests expect output in UTF-8 encoding
  70         (coding-system-for-write 'utf-8))
  71     (with-temp-file (or filename "OUTPUT") (insert text))))
  72
  73 (defun visible-buffer-string ()
  74   "Same as `buffer-string', but excludes invisible text and
  75 removes any text properties."
  76   (visible-buffer-substring (point-min) (point-max)))
  77
  78 (defun visible-buffer-substring (start end)
  79   "Same as `buffer-substring-no-properties', but excludes
  80 invisible text."
  81   (let (str)
  82     (while (< start end)
  83       (let ((next-pos (next-char-property-change start end)))
  84         (when (not (invisible-p start))
  85           (setq str (concat str (buffer-substring-no-properties
  86                                  start next-pos))))
  87         (setq start next-pos)))
  88     str))
  89
  90 ;; process-attributes is not defined everywhere, so define an
  91 ;; alternate way to test if a process still exists.
  92
  93 (defun test-process-running (pid)
  94   (= 0
  95    (signal-process pid 0)))
  96
  97 (defun orphan-watchdog-check (pid)
  98   "Periodically check that the process with id PID is still
  99 running, quit if it terminated."
 100   (if (not (test-process-running pid))
 101       (kill-emacs)))
 102
 103 (defun orphan-watchdog (pid)
 104   "Initiate orphan watchdog check."
 105   (run-at-time 60 60 'orphan-watchdog-check pid))
 106
 107 (defvar notmuch-hello-mode-hook-counter -100
 108   "Tests that care about this counter must let-bind it to 0.")
 109 (add-hook 'notmuch-hello-mode-hook
 110           (lambda () (cl-incf notmuch-hello-mode-hook-counter)))
 111
 112 (defvar notmuch-hello-refresh-hook-counter -100
 113   "Tests that care about this counter must let-bind it to 0.")
 114 (add-hook 'notmuch-hello-refresh-hook
 115           (lambda () (cl-incf notmuch-hello-refresh-hook-counter)))
 116
 117 (defadvice notmuch-search-process-filter (around pessimal activate disable)
 118   "Feed notmuch-search-process-filter one character at a time."
 119   (let ((string (ad-get-arg 1)))
 120     (cl-loop for char across string
 121              do (progn
 122                   (ad-set-arg 1 (char-to-string char))
 123                   ad-do-it))))
 124
 125 (defun notmuch-test-mark-links ()
 126   "Enclose links in the current buffer with << and >>."
 127   ;; Links are often created by jit-lock functions
 128   (jit-lock-fontify-now)
 129   (save-excursion
 130     (let ((inhibit-read-only t))
 131       (goto-char (point-min))
 132       (let ((button))
 133         (while (setq button (next-button (point)))
 134           (goto-char (button-start button))
 135           (insert "<<")
 136           (goto-char (button-end button))
 137           (insert ">>"))))))
 138
 139 (defmacro notmuch-test-run (&rest body)
 140   "Evaluate a BODY of test expressions and output the result."
 141   `(with-temp-buffer
 142      (let ((buffer (current-buffer))
 143            (result (progn ,@body)))
 144        (switch-to-buffer buffer)
 145        (insert (if (stringp result)
 146                    result
 147                  (prin1-to-string result)))
 148        (test-output))))
 149
 150 (defun notmuch-test-report-unexpected (output expected)
 151   "Report that the OUTPUT does not match the EXPECTED result."
 152   (concat "Expect:\t" (prin1-to-string expected) "\n"
 153           "Output:\t" (prin1-to-string output) "\n"))
 154
 155 (defun notmuch-test-expect-equal (output expected)
 156   "Compare OUTPUT with EXPECTED. Report any discrepencies."
 157   (if (equal output expected)
 158       t
 159     (cond
 160      ((and (listp output)
 161            (listp expected))
 162       ;; Reporting the difference between two lists is done by
 163       ;; reporting differing elements of OUTPUT and EXPECTED
 164       ;; pairwise. This is expected to make analysis of failures
 165       ;; simpler.
 166       (apply #'concat (cl-loop for o in output
 167                                for e in expected
 168                                if (not (equal o e))
 169                                collect (notmuch-test-report-unexpected o e))))
 170
 171      (t
 172       (notmuch-test-report-unexpected output expected)))))
 173
 174 (defun notmuch-post-command ()
 175   (run-hooks 'post-command-hook))
 176
 177 (defmacro notmuch-test-progn (&rest body)
 178   (cons 'progn
 179         (mapcar
 180          (lambda (x) `(prog1 ,x (notmuch-post-command)))
 181          body)))
 182
 183 ;; For historical reasons, we hide deleted tags by default in the test
 184 ;; suite
 185 (setq notmuch-tag-deleted-formats
 186       '((".*" nil)))
 187
 188 ;; Also for historical reasons, we set the fcc handler to file not
 189 ;; insert.
 190
 191 (setq notmuch-maildir-use-notmuch-insert nil)
 192
 193 ;; force a common html renderer, to avoid test variations between
 194 ;; environments
 195
 196 (setq mm-text-html-renderer 'html2text)