git.notmuchmail.org Git - notmuch/blob - test/test-lib.el

   1 ;; test-lib.el --- auxiliary stuff for Notmuch Emacs tests.
   2 ;;
   3 ;; Copyright © Carl Worth
   4 ;; Copyright © David Edmondson
   5 ;;
   6 ;; This file is part of Notmuch test suit.
   7 ;;
   8 ;; Notmuch is free software: you can redistribute it and/or modify it
   9 ;; under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation, either version 3 of the License, or
  11 ;; (at your option) any later version.
  12 ;;
  13 ;; Notmuch is distributed in the hope that it will be useful, but
  14 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 ;; General Public License for more details.
  17 ;;
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with Notmuch.  If not, see <http://www.gnu.org/licenses/>.
  20 ;;
  21 ;; Authors: Dmitry Kurochkin <dmitry.kurochkin@gmail.com>
  22
  23 (require 'cl)   ;; This code is generally used uncompiled.
  24
  25 ;; `read-file-name' by default uses `completing-read' function to read
  26 ;; user input.  It does not respect `standard-input' variable which we
  27 ;; use in tests to provide user input.  So replace it with a plain
  28 ;; `read' call.
  29 (setq read-file-name-function (lambda (&rest _) (read)))
  30
  31 ;; Work around a bug in emacs 23.1 and emacs 23.2 which prevents
  32 ;; noninteractive (kill-emacs) from emacsclient.
  33 (if (and (= emacs-major-version 23) (< emacs-minor-version 3))
  34   (defadvice kill-emacs (before disable-yes-or-no-p activate)
  35     "Disable yes-or-no-p before executing kill-emacs"
  36     (defun yes-or-no-p (prompt) t)))
  37
  38 ;; Emacs bug #2930:
  39 ;;      23.0.92; `accept-process-output' and `sleep-for' do not run sentinels
  40 ;; seems to be present in Emacs 23.1.
  41 ;; Running `list-processes' after `accept-process-output' seems to work
  42 ;; around this problem.
  43 (if (and (= emacs-major-version 23) (= emacs-minor-version 1))
  44   (defadvice accept-process-output (after run-list-processes activate)
  45     "run list-processes after executing accept-process-output"
  46     (list-processes)))
  47
  48 (defun notmuch-test-wait ()
  49   "Wait for process completion."
  50   (while (get-buffer-process (current-buffer))
  51     (accept-process-output nil 0.1)))
  52
  53 (defun test-output (&optional filename)
  54   "Save current buffer to file FILENAME.  Default FILENAME is OUTPUT."
  55   (write-region (point-min) (point-max) (or filename "OUTPUT")))
  56
  57 (defun test-visible-output (&optional filename)
  58   "Save visible text in current buffer to file FILENAME.  Default
  59 FILENAME is OUTPUT."
  60   (let ((text (visible-buffer-string)))
  61     (with-temp-file (or filename "OUTPUT") (insert text))))
  62
  63 (defun visible-buffer-string ()
  64   "Same as `buffer-string', but excludes invisible text and
  65 removes any text properties."
  66   (visible-buffer-substring (point-min) (point-max)))
  67
  68 (defun visible-buffer-substring (start end)
  69   "Same as `buffer-substring-no-properties', but excludes
  70 invisible text."
  71   (let (str)
  72     (while (< start end)
  73       (let ((next-pos (next-char-property-change start end)))
  74         (when (not (invisible-p start))
  75           (setq str (concat str (buffer-substring-no-properties
  76                                  start next-pos))))
  77         (setq start next-pos)))
  78     str))
  79
  80 ;; process-attributes is not defined everywhere, so define an
  81 ;; alternate way to test if a process still exists.
  82
  83 (defun test-process-running (pid)
  84   (= 0
  85    (signal-process pid 0)))
  86
  87 (defun orphan-watchdog-check (pid)
  88   "Periodically check that the process with id PID is still
  89 running, quit if it terminated."
  90   (if (not (test-process-running pid))
  91       (kill-emacs)))
  92
  93 (defun orphan-watchdog (pid)
  94   "Initiate orphan watchdog check."
  95   (run-at-time 60 60 'orphan-watchdog-check pid))
  96
  97 (defun hook-counter (hook)
  98   "Count how many times a hook is called.  Increments
  99 `hook'-counter variable value if it is bound, otherwise does
 100 nothing."
 101   (let ((counter (intern (concat (symbol-name hook) "-counter"))))
 102     (if (boundp counter)
 103         (set counter (1+ (symbol-value counter))))))
 104
 105 (defun add-hook-counter (hook)
 106   "Add hook to count how many times `hook' is called."
 107   (add-hook hook (apply-partially 'hook-counter hook)))
 108
 109 (add-hook-counter 'notmuch-hello-mode-hook)
 110 (add-hook-counter 'notmuch-hello-refresh-hook)
 111
 112 (defadvice notmuch-search-process-filter (around pessimal activate disable)
 113   "Feed notmuch-search-process-filter one character at a time."
 114   (let ((string (ad-get-arg 1)))
 115     (loop for char across string
 116           do (progn
 117                (ad-set-arg 1 (char-to-string char))
 118                ad-do-it))))
 119
 120 (defun notmuch-test-mark-links ()
 121   "Enclose links in the current buffer with << and >>."
 122   ;; Links are often created by jit-lock functions
 123   (jit-lock-fontify-now)
 124   (save-excursion
 125     (let ((inhibit-read-only t))
 126       (goto-char (point-min))
 127       (let ((button))
 128         (while (setq button (next-button (point)))
 129           (goto-char (button-start button))
 130           (insert "<<")
 131           (goto-char (button-end button))
 132           (insert ">>"))))))
 133
 134 (defmacro notmuch-test-run (&rest body)
 135   "Evaluate a BODY of test expressions and output the result."
 136   `(with-temp-buffer
 137      (let ((buffer (current-buffer))
 138            (result (progn ,@body)))
 139        (switch-to-buffer buffer)
 140        (insert (if (stringp result)
 141                    result
 142                  (prin1-to-string result)))
 143        (test-output))))
 144
 145 (defun notmuch-test-report-unexpected (output expected)
 146   "Report that the OUTPUT does not match the EXPECTED result."
 147   (concat "Expect:\t" (prin1-to-string expected) "\n"
 148           "Output:\t" (prin1-to-string output) "\n"))
 149
 150 (defun notmuch-test-expect-equal (output expected)
 151   "Compare OUTPUT with EXPECTED. Report any discrepencies."
 152   (if (equal output expected)
 153       t
 154     (cond
 155      ((and (listp output)
 156            (listp expected))
 157       ;; Reporting the difference between two lists is done by
 158       ;; reporting differing elements of OUTPUT and EXPECTED
 159       ;; pairwise. This is expected to make analysis of failures
 160       ;; simpler.
 161       (apply #'concat (loop for o in output
 162                             for e in expected
 163                             if (not (equal o e))
 164                             collect (notmuch-test-report-unexpected o e))))
 165
 166      (t
 167       (notmuch-test-report-unexpected output expected)))))
 168
 169 ;; For historical reasons, we hide deleted tags by default in the test
 170 ;; suite
 171 (setq notmuch-tag-deleted-formats
 172       '((".*" nil)))