git.notmuchmail.org Git - notmuch/blob - contrib/notmuch-pick/notmuch-pick.el

   1 ;; notmuch-pick.el --- displaying notmuch forests.
   2 ;;
   3 ;; Copyright © Carl Worth
   4 ;; Copyright © David Edmondson
   5 ;; Copyright © Mark Walters
   6 ;;
   7 ;; This file is part of Notmuch.
   8 ;;
   9 ;; Notmuch is free software: you can redistribute it and/or modify it
  10 ;; under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation, either version 3 of the License, or
  12 ;; (at your option) any later version.
  13 ;;
  14 ;; Notmuch is distributed in the hope that it will be useful, but
  15 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 ;; General Public License for more details.
  18 ;;
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with Notmuch.  If not, see <http://www.gnu.org/licenses/>.
  21 ;;
  22 ;; Authors: David Edmondson <dme@dme.org>
  23 ;;          Mark Walters <markwalters1009@gmail.com>
  24
  25 (require 'mail-parse)
  26
  27 (require 'notmuch-lib)
  28 (require 'notmuch-query)
  29 (require 'notmuch-show)
  30 (require 'notmuch) ;; XXX ATM, as notmuch-search-mode-map is defined here
  31
  32 (eval-when-compile (require 'cl))
  33
  34 (declare-function notmuch-call-notmuch-process "notmuch" (&rest args))
  35 (declare-function notmuch-show "notmuch-show" (&rest args))
  36 (declare-function notmuch-tag "notmuch" (query &rest tags))
  37 (declare-function notmuch-show-strip-re "notmuch-show" (subject))
  38 (declare-function notmuch-show-spaces-n "notmuch-show" (n))
  39 (declare-function notmuch-read-query "notmuch" (prompt))
  40 (declare-function notmuch-read-tag-changes "notmuch" (&optional initial-input &rest search-terms))
  41 (declare-function notmuch-update-tags "notmuch" (current-tags tag-changes))
  42 (declare-function notmuch-hello-trim "notmuch-hello" (search))
  43 (declare-function notmuch-search-find-thread-id "notmuch" ())
  44 (declare-function notmuch-search-find-subject "notmuch" ())
  45
  46 ;; the following variable is defined in notmuch.el
  47 (defvar notmuch-search-query-string)
  48
  49 (defgroup notmuch-pick nil
  50   "Showing message and thread structure."
  51   :group 'notmuch)
  52
  53 ;; This is ugly. We can't run setup-show-out until it has been defined
  54 ;; which needs the keymap to be defined. So we defer setting up to
  55 ;; notmuch-pick-init.
  56 (defcustom notmuch-pick-show-out nil
  57   "View selected messages in new window rather than split-pane."
  58   :type 'boolean
  59   :group 'notmuch-pick
  60   :set (lambda (symbol value)
  61          (set-default symbol value)
  62          (when (fboundp 'notmuch-pick-setup-show-out)
  63            (notmuch-pick-setup-show-out))))
  64
  65 (defcustom notmuch-pick-result-format
  66   `(("date" . "%12s  ")
  67     ("authors" . "%-20s")
  68     ("subject" . " %-54s ")
  69     ("tags" . "(%s)"))
  70   "Result formatting for Pick. Supported fields are: date,
  71         authors, subject, tags Note: subject includes the tree
  72         structure graphics, and the author string should not
  73         contain whitespace (put it in the neighbouring fields
  74         instead).  For example:
  75         (setq notmuch-pick-result-format \(\(\"authors\" . \"%-40s\"\)
  76                                              \(\"subject\" . \"%s\"\)\)\)"
  77   :type '(alist :key-type (string) :value-type (string))
  78   :group 'notmuch-pick)
  79
  80 (defcustom notmuch-pick-asynchronous-parser t
  81   "Use the asynchronous parser."
  82   :type 'boolean
  83   :group 'notmuch-pick)
  84
  85 ;; Faces for messages that match the query.
  86 (defface notmuch-pick-match-date-face
  87   '((t :inherit default))
  88   "Face used in pick mode for the date in messages matching the query."
  89   :group 'notmuch-pick
  90   :group 'notmuch-faces)
  91
  92 (defface notmuch-pick-match-author-face
  93   '((((class color)
  94       (background dark))
  95      (:foreground "OliveDrab1"))
  96     (((class color)
  97       (background light))
  98      (:foreground "dark blue"))
  99     (t
 100      (:bold t)))
 101   "Face used in pick mode for the date in messages matching the query."
 102   :group 'notmuch-pick
 103   :group 'notmuch-faces)
 104
 105 (defface notmuch-pick-match-subject-face
 106   '((t :inherit default))
 107   "Face used in pick mode for the subject in messages matching the query."
 108   :group 'notmuch-pick
 109   :group 'notmuch-faces)
 110
 111 (defface notmuch-pick-match-tag-face
 112   '((((class color)
 113       (background dark))
 114      (:foreground "OliveDrab1"))
 115     (((class color)
 116       (background light))
 117      (:foreground "navy blue" :bold t))
 118     (t
 119      (:bold t)))
 120   "Face used in pick mode for tags in messages matching the query."
 121   :group 'notmuch-pick
 122   :group 'notmuch-faces)
 123
 124 ;; Faces for messages that do not match the query.
 125 (defface notmuch-pick-no-match-date-face
 126   '((t (:foreground "gray")))
 127   "Face used in pick mode for non-matching dates."
 128   :group 'notmuch-pick
 129   :group 'notmuch-faces)
 130
 131 (defface notmuch-pick-no-match-subject-face
 132   '((t (:foreground "gray")))
 133   "Face used in pick mode for non-matching subjects."
 134   :group 'notmuch-pick
 135   :group 'notmuch-faces)
 136
 137 (defface notmuch-pick-no-match-author-face
 138   '((t (:foreground "gray")))
 139   "Face used in pick mode for the date in messages matching the query."
 140   :group 'notmuch-pick
 141   :group 'notmuch-faces)
 142
 143 (defface notmuch-pick-no-match-tag-face
 144   '((t (:foreground "gray")))
 145   "Face used in pick mode face for non-matching tags."
 146   :group 'notmuch-pick
 147   :group 'notmuch-faces)
 148
 149 (defvar notmuch-pick-previous-subject
 150   "The subject of the most recent result shown during the async display")
 151 (make-variable-buffer-local 'notmuch-pick-previous-subject)
 152
 153 (defvar notmuch-pick-basic-query nil
 154   "A buffer local copy of argument query to the function notmuch-pick")
 155 (make-variable-buffer-local 'notmuch-pick-basic-query)
 156
 157 (defvar notmuch-pick-query-context nil
 158   "A buffer local copy of argument query-context to the function notmuch-pick")
 159 (make-variable-buffer-local 'notmuch-pick-query-context)
 160
 161 (defvar notmuch-pick-target-msg nil
 162   "A buffer local copy of argument target to the function notmuch-pick")
 163 (make-variable-buffer-local 'notmuch-pick-target-msg)
 164
 165 (defvar notmuch-pick-open-target nil
 166   "A buffer local copy of argument open-target to the function notmuch-pick")
 167 (make-variable-buffer-local 'notmuch-pick-open-target)
 168
 169 (defvar notmuch-pick-buffer-name nil
 170   "A buffer local copy of argument buffer-name to the function notmuch-pick")
 171 (make-variable-buffer-local 'notmuch-pick-buffer-name)
 172
 173 (defvar notmuch-pick-message-window nil
 174   "The window of the message pane.
 175
 176 It is set in both the pick buffer and the child show buffer. It
 177 is used to try and close the message pane when quitting pick or
 178 the child show buffer.")
 179 (make-variable-buffer-local 'notmuch-pick-message-window)
 180 (put 'notmuch-pick-message-window 'permanent-local t)
 181
 182 (defvar notmuch-pick-message-buffer nil
 183   "The buffer name of the show buffer in the message pane.
 184
 185 This is used to try and make sure we don't close the message pane
 186 if the user has loaded a different buffer in that window.")
 187 (make-variable-buffer-local 'notmuch-pick-message-buffer)
 188 (put 'notmuch-pick-message-buffer 'permanent-local t)
 189
 190 (defvar notmuch-pick-mode-map
 191   (let ((map (make-sparse-keymap)))
 192     (define-key map [mouse-1] 'notmuch-pick-show-message)
 193     (define-key map "q" 'notmuch-pick-quit)
 194     (define-key map "x" 'notmuch-pick-quit)
 195     (define-key map "?" 'notmuch-help)
 196     (define-key map "a" 'notmuch-pick-archive-message-then-next)
 197     (define-key map "=" 'notmuch-pick-refresh-view)
 198     (define-key map "s" 'notmuch-pick-to-search)
 199     (define-key map "z" 'notmuch-pick-to-pick)
 200     (define-key map "m" 'notmuch-pick-new-mail)
 201     (define-key map "f" 'notmuch-pick-forward-message)
 202     (define-key map "r" 'notmuch-pick-reply-sender)
 203     (define-key map "R" 'notmuch-pick-reply)
 204     (define-key map "n" 'notmuch-pick-next-matching-message)
 205     (define-key map "p" 'notmuch-pick-prev-matching-message)
 206     (define-key map "N" 'notmuch-pick-next-message)
 207     (define-key map "P" 'notmuch-pick-prev-message)
 208     (define-key map "|" 'notmuch-pick-pipe-message)
 209     (define-key map "-" 'notmuch-pick-remove-tag)
 210     (define-key map "+" 'notmuch-pick-add-tag)
 211     (define-key map " " 'notmuch-pick-scroll-or-next)
 212     (define-key map "b" 'notmuch-pick-scroll-message-window-back)
 213     map))
 214 (fset 'notmuch-pick-mode-map notmuch-pick-mode-map)
 215
 216 (defun notmuch-pick-setup-show-out ()
 217   "Set up the keymap for showing a thread
 218
 219 This uses the value of the defcustom notmuch-pick-show-out to
 220 decide whether to show a message in the message pane or in the
 221 whole window."
 222   (let ((map notmuch-pick-mode-map))
 223     (if notmuch-pick-show-out
 224         (progn
 225           (define-key map (kbd "M-RET") 'notmuch-pick-show-message)
 226           (define-key map (kbd "RET") 'notmuch-pick-show-message-out))
 227       (progn
 228         (define-key map (kbd "RET") 'notmuch-pick-show-message)
 229         (define-key map (kbd "M-RET") 'notmuch-pick-show-message-out)))))
 230
 231 (defun notmuch-pick-get-message-properties ()
 232   "Return the properties of the current message as a plist.
 233
 234 Some useful entries are:
 235 :headers - Property list containing the headers :Date, :Subject, :From, etc.
 236 :tags - Tags for this message"
 237   (save-excursion
 238     (beginning-of-line)
 239     (get-text-property (point) :notmuch-message-properties)))
 240
 241 ;; XXX This should really be a lib function but we are trying to
 242 ;; reduce impact on the code base.
 243 (defun notmuch-show-get-prop (prop &optional props)
 244   "This is a pick overridden version of notmuch-show-get-prop
 245
 246 It gets property PROP from PROPS or, if PROPS is nil, the current
 247 message in either pick or show. This means that several functions
 248 in notmuch-show now work unchanged in pick as they just need the
 249 correct message properties."
 250   (let ((props (or props
 251                    (cond ((eq major-mode 'notmuch-show-mode)
 252                           (notmuch-show-get-message-properties))
 253                          ((eq major-mode 'notmuch-pick-mode)
 254                           (notmuch-pick-get-message-properties))))))
 255     (plist-get props prop)))
 256
 257 (defun notmuch-pick-set-message-properties (props)
 258   (save-excursion
 259     (beginning-of-line)
 260     (put-text-property (point) (+ (point) 1) :notmuch-message-properties props)))
 261
 262 (defun notmuch-pick-set-prop (prop val &optional props)
 263   (let ((inhibit-read-only t)
 264         (props (or props
 265                    (notmuch-pick-get-message-properties))))
 266     (plist-put props prop val)
 267     (notmuch-pick-set-message-properties props)))
 268
 269 (defun notmuch-pick-get-prop (prop &optional props)
 270   (let ((props (or props
 271                    (notmuch-pick-get-message-properties))))
 272     (plist-get props prop)))
 273
 274 (defun notmuch-pick-set-tags (tags)
 275   "Set the tags of the current message."
 276   (notmuch-pick-set-prop :tags tags))
 277
 278 (defun notmuch-pick-get-tags ()
 279   "Return the tags of the current message."
 280   (notmuch-pick-get-prop :tags))
 281
 282 (defun notmuch-pick-get-message-id ()
 283   "Return the message id of the current message."
 284   (let ((id (notmuch-pick-get-prop :id)))
 285     (if id
 286         (notmuch-id-to-query id)
 287       nil)))
 288
 289 (defun notmuch-pick-get-match ()
 290   "Return whether the current message is a match."
 291   (interactive)
 292   (notmuch-pick-get-prop :match))
 293
 294 (defun notmuch-pick-refresh-result ()
 295   "Redisplay the current message line.
 296
 297 This redisplays the current line based on the messages
 298 properties (as they are now). This is used when tags are
 299 updated."
 300   (let ((init-point (point))
 301         (end (line-end-position))
 302         (msg (notmuch-pick-get-message-properties))
 303         (inhibit-read-only t))
 304     (beginning-of-line)
 305     ;; This is a little tricky: we override
 306     ;; notmuch-pick-previous-subject to get the decision between
 307     ;; ... and a subject right and it stops notmuch-pick-insert-msg
 308     ;; from overwriting the buffer local copy of
 309     ;; notmuch-pick-previous-subject if this is called while the
 310     ;; buffer is displaying.
 311     (let ((notmuch-pick-previous-subject (notmuch-pick-get-prop :previous-subject)))
 312       (delete-region (point) (1+ (line-end-position)))
 313       (notmuch-pick-insert-msg msg))
 314     (let ((new-end (line-end-position)))
 315       (goto-char (if (= init-point end)
 316                      new-end
 317                    (min init-point (- new-end 1)))))))
 318
 319 (defun notmuch-pick-tag-update-display (&optional tag-changes)
 320   "Update display for TAG-CHANGES to current message.
 321
 322 Does NOT change the database."
 323   (let* ((current-tags (notmuch-pick-get-tags))
 324          (new-tags (notmuch-update-tags current-tags tag-changes)))
 325     (unless (equal current-tags new-tags)
 326       (notmuch-pick-set-tags new-tags)
 327       (notmuch-pick-refresh-result))))
 328
 329 (defun notmuch-pick-tag (&optional tag-changes)
 330   "Change tags for the current message"
 331   (interactive)
 332   (setq tag-changes (notmuch-tag (notmuch-pick-get-message-id) tag-changes))
 333   (notmuch-pick-tag-update-display tag-changes))
 334
 335 (defun notmuch-pick-add-tag ()
 336   "Same as `notmuch-pick-tag' but sets initial input to '+'."
 337   (interactive)
 338   (notmuch-pick-tag "+"))
 339
 340 (defun notmuch-pick-remove-tag ()
 341   "Same as `notmuch-pick-tag' but sets initial input to '-'."
 342   (interactive)
 343   (notmuch-pick-tag "-"))
 344
 345 ;; The next two functions close the message window before searching or
 346 ;; picking but they do so after the user has entered the query (in
 347 ;; case the user was basing the query on something in the message
 348 ;; window).
 349
 350 (defun notmuch-pick-to-search ()
 351   "Run \"notmuch search\" with the given `query' and display results."
 352   (interactive)
 353   (let ((query (notmuch-read-query "Notmuch search: ")))
 354     (notmuch-pick-close-message-window)
 355     (notmuch-search query)))
 356
 357 (defun notmuch-pick-to-pick ()
 358   "Run a query and display results in experimental notmuch-pick mode"
 359   (interactive)
 360   (let ((query (notmuch-read-query "Notmuch pick: ")))
 361     (notmuch-pick-close-message-window)
 362     (notmuch-pick query)))
 363
 364 ;; This function should be in notmuch-hello.el but we are trying to
 365 ;; minimise impact on the rest of the codebase.
 366 (defun notmuch-pick-from-hello (&optional search)
 367   "Run a query and display results in experimental notmuch-pick mode"
 368   (interactive)
 369   (unless (null search)
 370     (setq search (notmuch-hello-trim search))
 371     (let ((history-delete-duplicates t))
 372       (add-to-history 'notmuch-search-history search)))
 373   (notmuch-pick search))
 374
 375 ;; This function should be in notmuch-show.el but be we trying to
 376 ;; minimise impact on the rest of the codebase.
 377 (defun notmuch-pick-from-show-current-query ()
 378   "Call notmuch pick with the current query"
 379   (interactive)
 380   (notmuch-pick notmuch-show-thread-id
 381                 notmuch-show-query-context
 382                 (notmuch-show-get-message-id)))
 383
 384 ;; This function should be in notmuch.el but be we trying to minimise
 385 ;; impact on the rest of the codebase.
 386 (defun notmuch-pick-from-search-current-query ()
 387   "Call notmuch pick with the current query"
 388   (interactive)
 389   (notmuch-pick notmuch-search-query-string))
 390
 391 ;; This function should be in notmuch.el but be we trying to minimise
 392 ;; impact on the rest of the codebase.
 393 (defun notmuch-pick-from-search-thread ()
 394   "Show the selected thread with notmuch-pick"
 395   (interactive)
 396   (notmuch-pick (notmuch-search-find-thread-id)
 397                 notmuch-search-query-string
 398                 nil
 399                 (notmuch-prettify-subject (notmuch-search-find-subject))
 400                 t))
 401
 402 (defun notmuch-pick-message-window-kill-hook ()
 403   "Close the message pane when exiting the show buffer."
 404   (let ((buffer (current-buffer)))
 405     (when (and (window-live-p notmuch-pick-message-window)
 406                (eq (window-buffer notmuch-pick-message-window) buffer))
 407       ;; We do not want an error if this is the sole window in the
 408       ;; frame and I do not know how to test for that in emacs pre
 409       ;; 24. Hence we just ignore-errors.
 410       (ignore-errors
 411         (delete-window notmuch-pick-message-window)))))
 412
 413 (defun notmuch-pick-show-message ()
 414   "Show the current message (in split-pane)."
 415   (interactive)
 416   (let ((id (notmuch-pick-get-message-id))
 417         (inhibit-read-only t)
 418         buffer)
 419     (when id
 420       ;; We close and reopen the window to kill off un-needed buffers
 421       ;; this might cause flickering but seems ok.
 422       (notmuch-pick-close-message-window)
 423       (setq notmuch-pick-message-window
 424             (split-window-vertically (/ (window-height) 4)))
 425       (with-selected-window notmuch-pick-message-window
 426         ;; Since we are only displaying one message do not indent.
 427         (let ((notmuch-show-indent-messages-width 0)
 428               (notmuch-show-only-matching-messages t))
 429           (setq buffer (notmuch-show id nil nil nil))))
 430       ;; We need the `let' as notmuch-pick-message-window is buffer local.
 431       (let ((window notmuch-pick-message-window))
 432         (with-current-buffer buffer
 433           (setq notmuch-pick-message-window window)
 434           (add-hook 'kill-buffer-hook 'notmuch-pick-message-window-kill-hook)))
 435       (when notmuch-show-mark-read-tags
 436         (notmuch-pick-tag-update-display notmuch-show-mark-read-tags))
 437       (setq notmuch-pick-message-buffer buffer))))
 438
 439 (defun notmuch-pick-show-message-out ()
 440   "Show the current message (in whole window)."
 441   (interactive)
 442   (let ((id (notmuch-pick-get-message-id))
 443         (inhibit-read-only t)
 444         buffer)
 445     (when id
 446       ;; We close the window to kill off un-needed buffers.
 447       (notmuch-pick-close-message-window)
 448       (notmuch-show id nil nil nil))))
 449
 450 (defun notmuch-pick-scroll-message-window ()
 451   "Scroll the message window (if it exists)"
 452   (interactive)
 453   (when (window-live-p notmuch-pick-message-window)
 454     (with-selected-window notmuch-pick-message-window
 455       (if (pos-visible-in-window-p (point-max))
 456           t
 457         (scroll-up)))))
 458
 459 (defun notmuch-pick-scroll-message-window-back ()
 460   "Scroll the message window back(if it exists)"
 461   (interactive)
 462   (when (window-live-p notmuch-pick-message-window)
 463     (with-selected-window notmuch-pick-message-window
 464       (if (pos-visible-in-window-p (point-min))
 465           t
 466         (scroll-down)))))
 467
 468 (defun notmuch-pick-scroll-or-next ()
 469   "Scroll the message window. If it at end go to next message."
 470   (interactive)
 471   (when (notmuch-pick-scroll-message-window)
 472     (notmuch-pick-next-matching-message)))
 473
 474 (defun notmuch-pick-quit ()
 475   "Close the split view or exit pick."
 476   (interactive)
 477   (unless (notmuch-pick-close-message-window)
 478     (kill-buffer (current-buffer))))
 479
 480 (defun notmuch-pick-close-message-window ()
 481   "Close the message-window. Return t if close succeeds."
 482   (interactive)
 483   (when (and (window-live-p notmuch-pick-message-window)
 484              (eq (window-buffer notmuch-pick-message-window) notmuch-pick-message-buffer))
 485     (delete-window notmuch-pick-message-window)
 486     (unless (get-buffer-window-list notmuch-pick-message-buffer)
 487       (kill-buffer notmuch-pick-message-buffer))
 488     t))
 489
 490 (defun notmuch-pick-archive-message (&optional unarchive)
 491   "Archive the current message.
 492
 493 Archive the current message by applying the tag changes in
 494 `notmuch-archive-tags' to it. If a prefix argument is given, the
 495 message will be \"unarchived\", i.e. the tag changes in
 496 `notmuch-archive-tags' will be reversed."
 497   (interactive "P")
 498   (when notmuch-archive-tags
 499     (apply 'notmuch-pick-tag
 500            (notmuch-tag-change-list notmuch-archive-tags unarchive))))
 501
 502 (defun notmuch-pick-archive-message-then-next (&optional unarchive)
 503   "Archive the current message and move to next matching message."
 504   (interactive "P")
 505   (notmuch-pick-archive-message unarchive)
 506   (notmuch-pick-next-matching-message))
 507
 508 (defun notmuch-pick-next-message ()
 509   "Move to next message."
 510   (interactive)
 511   (forward-line)
 512   (when (window-live-p notmuch-pick-message-window)
 513     (notmuch-pick-show-message)))
 514
 515 (defun notmuch-pick-prev-message ()
 516   "Move to previous message."
 517   (interactive)
 518   (forward-line -1)
 519   (when (window-live-p notmuch-pick-message-window)
 520     (notmuch-pick-show-message)))
 521
 522 (defun notmuch-pick-prev-matching-message ()
 523   "Move to previous matching message."
 524   (interactive)
 525   (forward-line -1)
 526   (while (and (not (bobp)) (not (notmuch-pick-get-match)))
 527     (forward-line -1))
 528   (when (window-live-p notmuch-pick-message-window)
 529     (notmuch-pick-show-message)))
 530
 531 (defun notmuch-pick-next-matching-message ()
 532   "Move to next matching message."
 533   (interactive)
 534   (forward-line)
 535   (while (and (not (eobp)) (not (notmuch-pick-get-match)))
 536     (forward-line))
 537   (when (window-live-p notmuch-pick-message-window)
 538     (notmuch-pick-show-message)))
 539
 540 (defun notmuch-pick-refresh-view ()
 541   "Refresh view."
 542   (interactive)
 543   (let ((inhibit-read-only t)
 544         (basic-query notmuch-pick-basic-query)
 545         (query-context notmuch-pick-query-context)
 546         (target (notmuch-pick-get-message-id))
 547         (buffer-name notmuch-pick-buffer-name))
 548     (erase-buffer)
 549     (notmuch-pick-worker basic-query
 550                          query-context
 551                          target
 552                          (get-buffer buffer-name))))
 553
 554 (defmacro with-current-notmuch-pick-message (&rest body)
 555   "Evaluate body with current buffer set to the text of current message"
 556   `(save-excursion
 557      (let ((id (notmuch-pick-get-message-id)))
 558        (let ((buf (generate-new-buffer (concat "*notmuch-msg-" id "*"))))
 559          (with-current-buffer buf
 560             (call-process notmuch-command nil t nil "show" "--format=raw" id)
 561            ,@body)
 562          (kill-buffer buf)))))
 563
 564 (defun notmuch-pick-new-mail (&optional prompt-for-sender)
 565   "Compose new mail."
 566   (interactive "P")
 567   (notmuch-pick-close-message-window)
 568   (notmuch-mua-new-mail prompt-for-sender ))
 569
 570 (defun notmuch-pick-forward-message (&optional prompt-for-sender)
 571   "Forward the current message."
 572   (interactive "P")
 573   (notmuch-pick-close-message-window)
 574   (with-current-notmuch-pick-message
 575    (notmuch-mua-new-forward-message prompt-for-sender)))
 576
 577 (defun notmuch-pick-reply (&optional prompt-for-sender)
 578   "Reply to the sender and all recipients of the current message."
 579   (interactive "P")
 580   (notmuch-pick-close-message-window)
 581   (notmuch-mua-new-reply (notmuch-pick-get-message-id) prompt-for-sender t))
 582
 583 (defun notmuch-pick-reply-sender (&optional prompt-for-sender)
 584   "Reply to the sender of the current message."
 585   (interactive "P")
 586   (notmuch-pick-close-message-window)
 587   (notmuch-mua-new-reply (notmuch-pick-get-message-id) prompt-for-sender nil))
 588
 589 ;; Shamelessly stolen from notmuch-show.el: maybe should be unified.
 590 (defun notmuch-pick-pipe-message (command)
 591   "Pipe the contents of the current message to the given command.
 592
 593 The given command will be executed with the raw contents of the
 594 current email message as stdin. Anything printed by the command
 595 to stdout or stderr will appear in the *notmuch-pipe* buffer.
 596
 597 When invoked with a prefix argument, the command will receive all
 598 open messages in the current thread (formatted as an mbox) rather
 599 than only the current message."
 600   (interactive "sPipe message to command: ")
 601   (let ((shell-command
 602          (concat notmuch-command " show --format=raw "
 603                  (shell-quote-argument (notmuch-pick-get-message-id)) " | " command))
 604          (buf (get-buffer-create (concat "*notmuch-pipe*"))))
 605     (with-current-buffer buf
 606       (setq buffer-read-only nil)
 607       (erase-buffer)
 608       (let ((exit-code (call-process-shell-command shell-command nil buf)))
 609         (goto-char (point-max))
 610         (set-buffer-modified-p nil)
 611         (setq buffer-read-only t)
 612         (unless (zerop exit-code)
 613           (switch-to-buffer-other-window buf)
 614           (message (format "Command '%s' exited abnormally with code %d"
 615                            shell-command exit-code)))))))
 616
 617 (defun notmuch-pick-clean-address (address)
 618   "Try to clean a single email ADDRESS for display. Return
 619 AUTHOR_NAME if present, otherwise return AUTHOR_EMAIL. Return
 620 unchanged ADDRESS if parsing fails."
 621   (let* ((clean-address (notmuch-clean-address address))
 622          (p-address (car clean-address))
 623          (p-name (cdr clean-address)))
 624
 625     ;; If we have a name return that otherwise return the address.
 626     (or p-name p-address)))
 627
 628 (defun notmuch-pick-insert-field (field format-string msg)
 629   (let* ((headers (plist-get msg :headers))
 630         (match (plist-get msg :match)))
 631     (cond
 632      ((string-equal field "date")
 633       (let ((face (if match
 634                       'notmuch-pick-match-date-face
 635                     'notmuch-pick-no-match-date-face)))
 636         (insert (propertize (format format-string (plist-get msg :date_relative))
 637                             'face face))))
 638
 639      ((string-equal field "subject")
 640       (let ((tree-status (plist-get msg :tree-status))
 641             (bare-subject (notmuch-show-strip-re (plist-get headers :Subject)))
 642             (face (if match
 643                       'notmuch-pick-match-subject-face
 644                     'notmuch-pick-no-match-subject-face)))
 645         (insert (propertize (format format-string
 646                                     (concat
 647                                      (mapconcat #'identity (reverse tree-status) "")
 648                                      (if (string= notmuch-pick-previous-subject bare-subject)
 649                                          " ..."
 650                                        bare-subject)))
 651                             'face face))
 652         (setq notmuch-pick-previous-subject bare-subject)))
 653
 654      ((string-equal field "authors")
 655       (let ((author (notmuch-pick-clean-address (plist-get headers :From)))
 656             (len (length (format format-string "")))
 657             (face (if match
 658                       'notmuch-pick-match-author-face
 659                     'notmuch-pick-no-match-author-face)))
 660         (when (> (length author) len)
 661           (setq author (substring author 0 len)))
 662         (insert (propertize (format format-string author)
 663                             'face face))))
 664
 665      ((string-equal field "tags")
 666       (let ((tags (plist-get msg :tags))
 667             (face (if match
 668                           'notmuch-pick-match-tag-face
 669                         'notmuch-pick-no-match-tag-face)))
 670         (when tags
 671           (insert (propertize (format format-string
 672                                       (mapconcat #'identity tags ", "))
 673                               'face face))))))))
 674
 675 (defun notmuch-pick-insert-msg (msg)
 676   "Insert the message MSG according to notmuch-pick-result-format"
 677   ;; We need to save the previous subject as it will get overwritten
 678   ;; by the insert-field calls.
 679   (let ((previous-subject notmuch-pick-previous-subject))
 680     (dolist (spec notmuch-pick-result-format)
 681       (notmuch-pick-insert-field (car spec) (cdr spec) msg))
 682     (notmuch-pick-set-message-properties msg)
 683     (notmuch-pick-set-prop :previous-subject previous-subject)
 684     (insert "\n")))
 685
 686 (defun notmuch-pick-goto-and-insert-msg (msg)
 687   "Insert msg at the end of the buffer. Move point to msg if it is the target"
 688   (save-excursion
 689     (goto-char (point-max))
 690     (notmuch-pick-insert-msg msg))
 691   (let ((msg-id (notmuch-id-to-query (plist-get msg :id)))
 692         (target notmuch-pick-target-msg))
 693     (when (or (and (not target) (plist-get msg :match))
 694               (string= msg-id target))
 695       (setq notmuch-pick-target-msg "found")
 696       (goto-char (point-max))
 697       (forward-line -1)
 698       (when notmuch-pick-open-target
 699         (notmuch-pick-show-message)))))
 700
 701 (defun notmuch-pick-insert-tree (tree depth tree-status first last)
 702   "Insert the message tree TREE at depth DEPTH in the current thread.
 703
 704 A message tree is another name for a single sub-thread: i.e., a
 705 message together with all its descendents."
 706   (let ((msg (car tree))
 707         (replies (cadr tree)))
 708
 709       (cond
 710        ((and (< 0 depth) (not last))
 711         (push "├" tree-status))
 712        ((and (< 0 depth) last)
 713         (push "╰" tree-status))
 714        ((and (eq 0 depth) first last)
 715 ;;        (push "─" tree-status)) choice between this and next line is matter of taste.
 716         (push " " tree-status))
 717        ((and (eq 0 depth) first (not last))
 718           (push "┬" tree-status))
 719        ((and (eq 0 depth) (not first) last)
 720         (push "╰" tree-status))
 721        ((and (eq 0 depth) (not first) (not last))
 722         (push "├" tree-status)))
 723
 724       (push (concat (if replies "┬" "─") "►") tree-status)
 725       (notmuch-pick-goto-and-insert-msg (plist-put msg :tree-status tree-status))
 726       (pop tree-status)
 727       (pop tree-status)
 728
 729       (if last
 730           (push " " tree-status)
 731         (push "│" tree-status))
 732
 733     (notmuch-pick-insert-thread replies (1+ depth) tree-status)))
 734
 735 (defun notmuch-pick-insert-thread (thread depth tree-status)
 736   "Insert the collection of sibling sub-threads THREAD at depth DEPTH in the current forest."
 737   (let ((n (length thread)))
 738     (loop for tree in thread
 739           for count from 1 to n
 740
 741           do (notmuch-pick-insert-tree tree depth tree-status (eq count 1) (eq count n)))))
 742
 743 (defun notmuch-pick-insert-forest-thread (forest-thread)
 744   "Insert a single complete thread."
 745   (let (tree-status)
 746     ;; Reset at the start of each main thread.
 747     (setq notmuch-pick-previous-subject nil)
 748     (notmuch-pick-insert-thread forest-thread 0 tree-status)))
 749
 750 (defun notmuch-pick-insert-forest (forest)
 751   "Insert a forest of threads.
 752
 753 This function inserts a collection of several complete threads as
 754 passed to it by notmuch-pick-process-filter."
 755   (mapc 'notmuch-pick-insert-forest-thread forest))
 756
 757 (defun notmuch-pick-mode ()
 758   "Major mode displaying messages (as opposed to threads) of of a notmuch search.
 759
 760 This buffer contains the results of a \"notmuch pick\" of your
 761 email archives. Each line in the buffer represents a single
 762 message giving the relative date, the author, subject, and any
 763 tags.
 764
 765 Pressing \\[notmuch-pick-show-message] on any line displays that message.
 766
 767 Complete list of currently available key bindings:
 768
 769 \\{notmuch-pick-mode-map}"
 770
 771   (interactive)
 772   (kill-all-local-variables)
 773   (use-local-map notmuch-pick-mode-map)
 774   (setq major-mode 'notmuch-pick-mode
 775         mode-name "notmuch-pick")
 776   (hl-line-mode 1)
 777   (setq buffer-read-only t
 778         truncate-lines t))
 779
 780 (defun notmuch-pick-process-sentinel (proc msg)
 781   "Add a message to let user know when \"notmuch pick\" exits"
 782   (let ((buffer (process-buffer proc))
 783         (status (process-status proc))
 784         (exit-status (process-exit-status proc))
 785         (never-found-target-thread nil))
 786     (when (memq status '(exit signal))
 787         (kill-buffer (process-get proc 'parse-buf))
 788         (if (buffer-live-p buffer)
 789             (with-current-buffer buffer
 790               (save-excursion
 791                 (let ((inhibit-read-only t)
 792                       (atbob (bobp)))
 793                   (goto-char (point-max))
 794                   (if (eq status 'signal)
 795                       (insert "Incomplete search results (pick process was killed).\n"))
 796                   (when (eq status 'exit)
 797                     (insert "End of search results.")
 798                     (unless (= exit-status 0)
 799                       (insert (format " (process returned %d)" exit-status)))
 800                     (insert "\n")))))))))
 801
 802 (defun notmuch-pick-process-filter (proc string)
 803   "Process and filter the output of \"notmuch show\" (for pick)"
 804   (let ((results-buf (process-buffer proc))
 805         (parse-buf (process-get proc 'parse-buf))
 806         (inhibit-read-only t)
 807         done)
 808     (if (not (buffer-live-p results-buf))
 809         (delete-process proc)
 810       (with-current-buffer parse-buf
 811         ;; Insert new data
 812         (save-excursion
 813           (goto-char (point-max))
 814           (insert string))
 815         (notmuch-sexp-parse-partial-list 'notmuch-pick-insert-forest-thread
 816                                          results-buf)))))
 817
 818 (defun notmuch-pick-worker (basic-query &optional query-context target buffer open-target)
 819   (interactive)
 820   (notmuch-pick-mode)
 821   (setq notmuch-pick-basic-query basic-query)
 822   (setq notmuch-pick-query-context query-context)
 823   (setq notmuch-pick-buffer-name (buffer-name buffer))
 824   (setq notmuch-pick-target-msg target)
 825   (setq notmuch-pick-open-target open-target)
 826
 827   (erase-buffer)
 828   (goto-char (point-min))
 829   (let* ((search-args (concat basic-query
 830                        (if query-context (concat " and (" query-context ")"))
 831                        ))
 832          (message-arg "--entire-thread"))
 833     (if (equal (car (process-lines notmuch-command "count" search-args)) "0")
 834         (setq search-args basic-query))
 835     (if notmuch-pick-asynchronous-parser
 836         (let ((proc (notmuch-start-notmuch
 837                      "notmuch-pick" buffer #'notmuch-pick-process-sentinel
 838                      "show" "--body=false" "--format=sexp"
 839                      message-arg search-args))
 840               ;; Use a scratch buffer to accumulate partial output.
 841               ;; This buffer will be killed by the sentinel, which
 842               ;; should be called no matter how the process dies.
 843               (parse-buf (generate-new-buffer " *notmuch pick parse*")))
 844           (process-put proc 'parse-buf parse-buf)
 845           (set-process-filter proc 'notmuch-pick-process-filter)
 846           (set-process-query-on-exit-flag proc nil))
 847       (progn
 848         (notmuch-pick-insert-forest
 849          (notmuch-query-get-threads
 850           (list "--body=false" message-arg search-args)))
 851         (save-excursion
 852           (goto-char (point-max))
 853           (insert "End of search results.\n"))))))
 854
 855
 856 (defun notmuch-pick (&optional query query-context target buffer-name open-target)
 857   "Run notmuch pick with the given `query' and display the results.
 858
 859 The arguments are:
 860   QUERY: the main query. This can be any query but in many cases will be
 861       a single thread. If nil this is read interactively from the minibuffer.
 862   QUERY-CONTEXT: is an additional term for the query. The query used
 863       is QUERY and QUERY-CONTEXT unless that does not match any messages
 864       in which case we fall back to just QUERY.
 865   TARGET: A message ID (with the id: prefix) that will be made
 866       current if it appears in the pick results.
 867   BUFFER-NAME: the name of the buffer to show the pick tree. If
 868       it is nil \"*notmuch-pick\" followed by QUERY is used.
 869   OPEN-TARGET: If TRUE open the target message in the message pane."
 870   (interactive "sNotmuch pick: ")
 871   (if (null query)
 872       (setq query (notmuch-read-query "Notmuch pick: ")))
 873   (let ((buffer (get-buffer-create (generate-new-buffer-name
 874                                     (or buffer-name
 875                                         (concat "*notmuch-pick-" query "*")))))
 876         (inhibit-read-only t))
 877
 878     (switch-to-buffer buffer)
 879     ;; Don't track undo information for this buffer
 880     (set 'buffer-undo-list t)
 881
 882     (notmuch-pick-worker query query-context target buffer open-target)
 883
 884     (setq truncate-lines t)))
 885
 886
 887 ;; Set up key bindings from the rest of notmuch.
 888 (define-key 'notmuch-search-mode-map "z" 'notmuch-pick)
 889 (define-key 'notmuch-search-mode-map "Z" 'notmuch-pick-from-search-current-query)
 890 (define-key 'notmuch-search-mode-map (kbd "M-RET") 'notmuch-pick-from-search-thread)
 891 (define-key 'notmuch-hello-mode-map "z" 'notmuch-pick-from-hello)
 892 (define-key 'notmuch-show-mode-map "z" 'notmuch-pick)
 893 (define-key 'notmuch-show-mode-map "Z" 'notmuch-pick-from-show-current-query)
 894 (notmuch-pick-setup-show-out)
 895 (message "Initialised notmuch-pick")
 896
 897 (provide 'notmuch-pick)