50686f0589a49a13325bac4d02d344a9e49cf5f0
[notmuch] / contrib / notmuch-pick / notmuch-pick.el
1 ;; notmuch-pick.el --- displaying notmuch forests.
2 ;;
3 ;; Copyright © Carl Worth
4 ;; Copyright © David Edmondson
5 ;; Copyright © Mark Walters
6 ;;
7 ;; This file is part of Notmuch.
8 ;;
9 ;; Notmuch is free software: you can redistribute it and/or modify it
10 ;; under the terms of the GNU General Public License as published by
11 ;; the Free Software Foundation, either version 3 of the License, or
12 ;; (at your option) any later version.
13 ;;
14 ;; Notmuch is distributed in the hope that it will be useful, but
15 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
17 ;; General Public License for more details.
18 ;;
19 ;; You should have received a copy of the GNU General Public License
20 ;; along with Notmuch.  If not, see <http://www.gnu.org/licenses/>.
21 ;;
22 ;; Authors: David Edmondson <dme@dme.org>
23 ;;          Mark Walters <markwalters1009@gmail.com>
24
25 (require 'mail-parse)
26
27 (require 'notmuch-lib)
28 (require 'notmuch-query)
29 (require 'notmuch-show)
30 (require 'notmuch) ;; XXX ATM, as notmuch-search-mode-map is defined here
31
32 (eval-when-compile (require 'cl))
33
34 (declare-function notmuch-call-notmuch-process "notmuch" (&rest args))
35 (declare-function notmuch-show "notmuch-show" (&rest args))
36 (declare-function notmuch-tag "notmuch" (query &rest tags))
37 (declare-function notmuch-show-strip-re "notmuch-show" (subject))
38 (declare-function notmuch-show-spaces-n "notmuch-show" (n))
39 (declare-function notmuch-read-query "notmuch" (prompt))
40 (declare-function notmuch-read-tag-changes "notmuch" (&optional initial-input &rest search-terms))
41 (declare-function notmuch-update-tags "notmuch" (current-tags tag-changes))
42 (declare-function notmuch-hello-trim "notmuch-hello" (search))
43 (declare-function notmuch-search-find-thread-id "notmuch" ())
44 (declare-function notmuch-search-find-subject "notmuch" ())
45
46 ;; the following variable is defined in notmuch.el
47 (defvar notmuch-search-query-string)
48
49 (defgroup notmuch-pick nil
50   "Showing message and thread structure."
51   :group 'notmuch)
52
53 ;; This is ugly. We can't run setup-show-out until it has been defined
54 ;; which needs the keymap to be defined. So we defer setting up to
55 ;; notmuch-pick-init.
56 (defcustom notmuch-pick-show-out nil
57   "View selected messages in new window rather than split-pane."
58   :type 'boolean
59   :group 'notmuch-pick
60   :set (lambda (symbol value)
61          (set-default symbol value)
62          (when (fboundp 'notmuch-pick-setup-show-out)
63            (notmuch-pick-setup-show-out))))
64
65 (defcustom notmuch-pick-result-format
66   `(("date" . "%12s  ")
67     ("authors" . "%-20s")
68     ("subject" . " %-54s ")
69     ("tags" . "(%s)"))
70   "Result formatting for Pick. Supported fields are: date,
71         authors, subject, tags Note: subject includes the tree
72         structure graphics, and the author string should not
73         contain whitespace (put it in the neighbouring fields
74         instead).  For example:
75         (setq notmuch-pick-result-format \(\(\"authors\" . \"%-40s\"\)
76                                              \(\"subject\" . \"%s\"\)\)\)"
77   :type '(alist :key-type (string) :value-type (string))
78   :group 'notmuch-pick)
79
80 (defcustom notmuch-pick-asynchronous-parser t
81   "Use the asynchronous parser."
82   :type 'boolean
83   :group 'notmuch-pick)
84
85 ;; Faces for messages that match the query.
86 (defface notmuch-pick-match-date-face
87   '((t :inherit default))
88   "Face used in pick mode for the date in messages matching the query."
89   :group 'notmuch-pick
90   :group 'notmuch-faces)
91
92 (defface notmuch-pick-match-author-face
93   '((((class color)
94       (background dark))
95      (:foreground "OliveDrab1"))
96     (((class color)
97       (background light))
98      (:foreground "dark blue"))
99     (t
100      (:bold t)))
101   "Face used in pick mode for the date in messages matching the query."
102   :group 'notmuch-pick
103   :group 'notmuch-faces)
104
105 (defface notmuch-pick-match-subject-face
106   '((t :inherit default))
107   "Face used in pick mode for the subject in messages matching the query."
108   :group 'notmuch-pick
109   :group 'notmuch-faces)
110
111 (defface notmuch-pick-match-tag-face
112   '((((class color)
113       (background dark))
114      (:foreground "OliveDrab1"))
115     (((class color)
116       (background light))
117      (:foreground "navy blue" :bold t))
118     (t
119      (:bold t)))
120   "Face used in pick mode for tags in messages matching the query."
121   :group 'notmuch-pick
122   :group 'notmuch-faces)
123
124 ;; Faces for messages that do not match the query.
125 (defface notmuch-pick-no-match-date-face
126   '((t (:foreground "gray")))
127   "Face used in pick mode for non-matching dates."
128   :group 'notmuch-pick
129   :group 'notmuch-faces)
130
131 (defface notmuch-pick-no-match-subject-face
132   '((t (:foreground "gray")))
133   "Face used in pick mode for non-matching subjects."
134   :group 'notmuch-pick
135   :group 'notmuch-faces)
136
137 (defface notmuch-pick-no-match-author-face
138   '((t (:foreground "gray")))
139   "Face used in pick mode for the date in messages matching the query."
140   :group 'notmuch-pick
141   :group 'notmuch-faces)
142
143 (defface notmuch-pick-no-match-tag-face
144   '((t (:foreground "gray")))
145   "Face used in pick mode face for non-matching tags."
146   :group 'notmuch-pick
147   :group 'notmuch-faces)
148
149 (defvar notmuch-pick-previous-subject
150   "The subject of the most recent result shown during the async display")
151 (make-variable-buffer-local 'notmuch-pick-previous-subject)
152
153 (defvar notmuch-pick-basic-query nil
154   "A buffer local copy of argument query to the function notmuch-pick")
155 (make-variable-buffer-local 'notmuch-pick-basic-query)
156
157 (defvar notmuch-pick-query-context nil
158   "A buffer local copy of argument query-context to the function notmuch-pick")
159 (make-variable-buffer-local 'notmuch-pick-query-context)
160
161 (defvar notmuch-pick-target-msg nil
162   "A buffer local copy of argument target to the function notmuch-pick")
163 (make-variable-buffer-local 'notmuch-pick-target-msg)
164
165 (defvar notmuch-pick-open-target nil
166   "A buffer local copy of argument open-target to the function notmuch-pick")
167 (make-variable-buffer-local 'notmuch-pick-open-target)
168
169 (defvar notmuch-pick-buffer-name nil
170   "A buffer local copy of argument buffer-name to the function notmuch-pick")
171 (make-variable-buffer-local 'notmuch-pick-buffer-name)
172
173 (defvar notmuch-pick-message-window nil
174   "The window of the message pane.
175
176 It is set in both the pick buffer and the child show buffer. It
177 is used to try and close the message pane when quitting pick or
178 the child show buffer.")
179 (make-variable-buffer-local 'notmuch-pick-message-window)
180 (put 'notmuch-pick-message-window 'permanent-local t)
181
182 (defvar notmuch-pick-message-buffer nil
183   "The buffer name of the show buffer in the message pane.
184
185 This is used to try and make sure we don't close the message pane
186 if the user has loaded a different buffer in that window.")
187 (make-variable-buffer-local 'notmuch-pick-message-buffer)
188 (put 'notmuch-pick-message-buffer 'permanent-local t)
189
190 (defvar notmuch-pick-mode-map
191   (let ((map (make-sparse-keymap)))
192     (define-key map [mouse-1] 'notmuch-pick-show-message)
193     (define-key map "q" 'notmuch-pick-quit)
194     (define-key map "x" 'notmuch-pick-quit)
195     (define-key map "?" 'notmuch-help)
196     (define-key map "a" 'notmuch-pick-archive-message-then-next)
197     (define-key map "=" 'notmuch-pick-refresh-view)
198     (define-key map "s" 'notmuch-pick-to-search)
199     (define-key map "z" 'notmuch-pick-to-pick)
200     (define-key map "m" 'notmuch-pick-new-mail)
201     (define-key map "f" 'notmuch-pick-forward-message)
202     (define-key map "r" 'notmuch-pick-reply-sender)
203     (define-key map "R" 'notmuch-pick-reply)
204     (define-key map "n" 'notmuch-pick-next-matching-message)
205     (define-key map "p" 'notmuch-pick-prev-matching-message)
206     (define-key map "N" 'notmuch-pick-next-message)
207     (define-key map "P" 'notmuch-pick-prev-message)
208     (define-key map "|" 'notmuch-pick-pipe-message)
209     (define-key map "-" 'notmuch-pick-remove-tag)
210     (define-key map "+" 'notmuch-pick-add-tag)
211     (define-key map " " 'notmuch-pick-scroll-or-next)
212     (define-key map "b" 'notmuch-pick-scroll-message-window-back)
213     map))
214 (fset 'notmuch-pick-mode-map notmuch-pick-mode-map)
215
216 (defun notmuch-pick-setup-show-out ()
217   "Set up the keymap for showing a thread
218
219 This uses the value of the defcustom notmuch-pick-show-out to
220 decide whether to show a message in the message pane or in the
221 whole window."
222   (let ((map notmuch-pick-mode-map))
223     (if notmuch-pick-show-out
224         (progn
225           (define-key map (kbd "M-RET") 'notmuch-pick-show-message)
226           (define-key map (kbd "RET") 'notmuch-pick-show-message-out))
227       (progn
228         (define-key map (kbd "RET") 'notmuch-pick-show-message)
229         (define-key map (kbd "M-RET") 'notmuch-pick-show-message-out)))))
230
231 (defun notmuch-pick-get-message-properties ()
232   "Return the properties of the current message as a plist.
233
234 Some useful entries are:
235 :headers - Property list containing the headers :Date, :Subject, :From, etc.
236 :tags - Tags for this message"
237   (save-excursion
238     (beginning-of-line)
239     (get-text-property (point) :notmuch-message-properties)))
240
241 (defun notmuch-pick-set-message-properties (props)
242   (save-excursion
243     (beginning-of-line)
244     (put-text-property (point) (+ (point) 1) :notmuch-message-properties props)))
245
246 (defun notmuch-pick-set-prop (prop val &optional props)
247   (let ((inhibit-read-only t)
248         (props (or props
249                    (notmuch-pick-get-message-properties))))
250     (plist-put props prop val)
251     (notmuch-pick-set-message-properties props)))
252
253 (defun notmuch-pick-get-prop (prop &optional props)
254   (let ((props (or props
255                    (notmuch-pick-get-message-properties))))
256     (plist-get props prop)))
257
258 (defun notmuch-pick-set-tags (tags)
259   "Set the tags of the current message."
260   (notmuch-pick-set-prop :tags tags))
261
262 (defun notmuch-pick-get-tags ()
263   "Return the tags of the current message."
264   (notmuch-pick-get-prop :tags))
265
266 (defun notmuch-pick-get-message-id ()
267   "Return the message id of the current message."
268   (let ((id (notmuch-pick-get-prop :id)))
269     (if id
270         (notmuch-id-to-query id)
271       nil)))
272
273 (defun notmuch-pick-get-match ()
274   "Return whether the current message is a match."
275   (interactive)
276   (notmuch-pick-get-prop :match))
277
278 (defun notmuch-pick-refresh-result ()
279   "Redisplay the current message line.
280
281 This redisplays the current line based on the messages
282 properties (as they are now). This is used when tags are
283 updated."
284   (let ((init-point (point))
285         (end (line-end-position))
286         (msg (notmuch-pick-get-message-properties))
287         (inhibit-read-only t))
288     (beginning-of-line)
289     ;; This is a little tricky: we override
290     ;; notmuch-pick-previous-subject to get the decision between
291     ;; ... and a subject right and it stops notmuch-pick-insert-msg
292     ;; from overwriting the buffer local copy of
293     ;; notmuch-pick-previous-subject if this is called while the
294     ;; buffer is displaying.
295     (let ((notmuch-pick-previous-subject (notmuch-pick-get-prop :previous-subject)))
296       (delete-region (point) (1+ (line-end-position)))
297       (notmuch-pick-insert-msg msg))
298     (let ((new-end (line-end-position)))
299       (goto-char (if (= init-point end)
300                      new-end
301                    (min init-point (- new-end 1)))))))
302
303 (defun notmuch-pick-tag-update-display (&optional tag-changes)
304   "Update display for TAG-CHANGES to current message.
305
306 Does NOT change the database."
307   (let* ((current-tags (notmuch-pick-get-tags))
308          (new-tags (notmuch-update-tags current-tags tag-changes)))
309     (unless (equal current-tags new-tags)
310       (notmuch-pick-set-tags new-tags)
311       (notmuch-pick-refresh-result))))
312
313 (defun notmuch-pick-tag (&optional tag-changes)
314   "Change tags for the current message"
315   (interactive)
316   (setq tag-changes (notmuch-tag (notmuch-pick-get-message-id) tag-changes))
317   (notmuch-pick-tag-update-display tag-changes))
318
319 (defun notmuch-pick-add-tag ()
320   "Same as `notmuch-pick-tag' but sets initial input to '+'."
321   (interactive)
322   (notmuch-pick-tag "+"))
323
324 (defun notmuch-pick-remove-tag ()
325   "Same as `notmuch-pick-tag' but sets initial input to '-'."
326   (interactive)
327   (notmuch-pick-tag "-"))
328
329 ;; The next two functions close the message window before searching or
330 ;; picking but they do so after the user has entered the query (in
331 ;; case the user was basing the query on something in the message
332 ;; window).
333
334 (defun notmuch-pick-to-search ()
335   "Run \"notmuch search\" with the given `query' and display results."
336   (interactive)
337   (let ((query (notmuch-read-query "Notmuch search: ")))
338     (notmuch-pick-close-message-window)
339     (notmuch-search query)))
340
341 (defun notmuch-pick-to-pick ()
342   "Run a query and display results in experimental notmuch-pick mode"
343   (interactive)
344   (let ((query (notmuch-read-query "Notmuch pick: ")))
345     (notmuch-pick-close-message-window)
346     (notmuch-pick query)))
347
348 ;; This function should be in notmuch-hello.el but we are trying to
349 ;; minimise impact on the rest of the codebase.
350 (defun notmuch-pick-from-hello (&optional search)
351   "Run a query and display results in experimental notmuch-pick mode"
352   (interactive)
353   (unless (null search)
354     (setq search (notmuch-hello-trim search))
355     (let ((history-delete-duplicates t))
356       (add-to-history 'notmuch-search-history search)))
357   (notmuch-pick search))
358
359 ;; This function should be in notmuch-show.el but be we trying to
360 ;; minimise impact on the rest of the codebase.
361 (defun notmuch-pick-from-show-current-query ()
362   "Call notmuch pick with the current query"
363   (interactive)
364   (notmuch-pick notmuch-show-thread-id
365                 notmuch-show-query-context
366                 (notmuch-show-get-message-id)))
367
368 ;; This function should be in notmuch.el but be we trying to minimise
369 ;; impact on the rest of the codebase.
370 (defun notmuch-pick-from-search-current-query ()
371   "Call notmuch pick with the current query"
372   (interactive)
373   (notmuch-pick notmuch-search-query-string))
374
375 ;; This function should be in notmuch.el but be we trying to minimise
376 ;; impact on the rest of the codebase.
377 (defun notmuch-pick-from-search-thread ()
378   "Show the selected thread with notmuch-pick"
379   (interactive)
380   (notmuch-pick (notmuch-search-find-thread-id)
381                 notmuch-search-query-string
382                 nil
383                 (notmuch-prettify-subject (notmuch-search-find-subject))
384                 t))
385
386 (defun notmuch-pick-message-window-kill-hook ()
387   (let ((buffer (current-buffer)))
388     (when (and (window-live-p notmuch-pick-message-window)
389                (eq (window-buffer notmuch-pick-message-window) buffer))
390       ;; We do not want an error if this is the sole window in the
391       ;; frame and I do not know how to test for that in emacs pre
392       ;; 24. Hence we just ignore-errors.
393       (ignore-errors
394         (delete-window notmuch-pick-message-window)))))
395
396 (defun notmuch-pick-show-message ()
397   "Show the current message (in split-pane)."
398   (interactive)
399   (let ((id (notmuch-pick-get-message-id))
400         (inhibit-read-only t)
401         buffer)
402     (when id
403       ;; We close and reopen the window to kill off un-needed buffers
404       ;; this might cause flickering but seems ok.
405       (notmuch-pick-close-message-window)
406       (setq notmuch-pick-message-window
407             (split-window-vertically (/ (window-height) 4)))
408       (with-selected-window notmuch-pick-message-window
409         ;; Since we are only displaying one message do not indent.
410         (let ((notmuch-show-indent-messages-width 0)
411               (notmuch-show-only-matching-messages t))
412           (setq buffer (notmuch-show id nil nil nil))))
413       ;; We need the `let' as notmuch-pick-message-window is buffer local.
414       (let ((window notmuch-pick-message-window))
415         (with-current-buffer buffer
416           (setq notmuch-pick-message-window window)
417           (add-hook 'kill-buffer-hook 'notmuch-pick-message-window-kill-hook)))
418       (when notmuch-show-mark-read-tags
419         (notmuch-pick-tag-update-display notmuch-show-mark-read-tags))
420       (setq notmuch-pick-message-buffer buffer))))
421
422 (defun notmuch-pick-show-message-out ()
423   "Show the current message (in whole window)."
424   (interactive)
425   (let ((id (notmuch-pick-get-message-id))
426         (inhibit-read-only t)
427         buffer)
428     (when id
429       ;; We close the window to kill off un-needed buffers.
430       (notmuch-pick-close-message-window)
431       (notmuch-show id nil nil nil))))
432
433 (defun notmuch-pick-scroll-message-window ()
434   "Scroll the message window (if it exists)"
435   (interactive)
436   (when (window-live-p notmuch-pick-message-window)
437     (with-selected-window notmuch-pick-message-window
438       (if (pos-visible-in-window-p (point-max))
439           t
440         (scroll-up)))))
441
442 (defun notmuch-pick-scroll-message-window-back ()
443   "Scroll the message window back(if it exists)"
444   (interactive)
445   (when (window-live-p notmuch-pick-message-window)
446     (with-selected-window notmuch-pick-message-window
447       (if (pos-visible-in-window-p (point-min))
448           t
449         (scroll-down)))))
450
451 (defun notmuch-pick-scroll-or-next ()
452   "Scroll the message window. If it at end go to next message."
453   (interactive)
454   (when (notmuch-pick-scroll-message-window)
455     (notmuch-pick-next-matching-message)))
456
457 (defun notmuch-pick-quit ()
458   "Close the split view or exit pick."
459   (interactive)
460   (unless (notmuch-pick-close-message-window)
461     (kill-buffer (current-buffer))))
462
463 (defun notmuch-pick-close-message-window ()
464   "Close the message-window. Return t if close succeeds."
465   (interactive)
466   (when (and (window-live-p notmuch-pick-message-window)
467              (eq (window-buffer notmuch-pick-message-window) notmuch-pick-message-buffer))
468     (delete-window notmuch-pick-message-window)
469     (unless (get-buffer-window-list notmuch-pick-message-buffer)
470       (kill-buffer notmuch-pick-message-buffer))
471     t))
472
473 (defun notmuch-pick-archive-message (&optional unarchive)
474   "Archive the current message.
475
476 Archive the current message by applying the tag changes in
477 `notmuch-archive-tags' to it. If a prefix argument is given, the
478 message will be \"unarchived\", i.e. the tag changes in
479 `notmuch-archive-tags' will be reversed."
480   (interactive "P")
481   (when notmuch-archive-tags
482     (apply 'notmuch-pick-tag
483            (notmuch-tag-change-list notmuch-archive-tags unarchive))))
484
485 (defun notmuch-pick-archive-message-then-next (&optional unarchive)
486   "Archive the current message and move to next matching message."
487   (interactive "P")
488   (notmuch-pick-archive-message unarchive)
489   (notmuch-pick-next-matching-message))
490
491 (defun notmuch-pick-next-message ()
492   "Move to next message."
493   (interactive)
494   (forward-line)
495   (when (window-live-p notmuch-pick-message-window)
496     (notmuch-pick-show-message)))
497
498 (defun notmuch-pick-prev-message ()
499   "Move to previous message."
500   (interactive)
501   (forward-line -1)
502   (when (window-live-p notmuch-pick-message-window)
503     (notmuch-pick-show-message)))
504
505 (defun notmuch-pick-prev-matching-message ()
506   "Move to previous matching message."
507   (interactive)
508   (forward-line -1)
509   (while (and (not (bobp)) (not (notmuch-pick-get-match)))
510     (forward-line -1))
511   (when (window-live-p notmuch-pick-message-window)
512     (notmuch-pick-show-message)))
513
514 (defun notmuch-pick-next-matching-message ()
515   "Move to next matching message."
516   (interactive)
517   (forward-line)
518   (while (and (not (eobp)) (not (notmuch-pick-get-match)))
519     (forward-line))
520   (when (window-live-p notmuch-pick-message-window)
521     (notmuch-pick-show-message)))
522
523 (defun notmuch-pick-refresh-view ()
524   "Refresh view."
525   (interactive)
526   (let ((inhibit-read-only t)
527         (basic-query notmuch-pick-basic-query)
528         (query-context notmuch-pick-query-context)
529         (target (notmuch-pick-get-message-id))
530         (buffer-name notmuch-pick-buffer-name))
531     (erase-buffer)
532     (notmuch-pick-worker basic-query
533                          query-context
534                          target
535                          (get-buffer buffer-name))))
536
537 (defmacro with-current-notmuch-pick-message (&rest body)
538   "Evaluate body with current buffer set to the text of current message"
539   `(save-excursion
540      (let ((id (notmuch-pick-get-message-id)))
541        (let ((buf (generate-new-buffer (concat "*notmuch-msg-" id "*"))))
542          (with-current-buffer buf
543             (call-process notmuch-command nil t nil "show" "--format=raw" id)
544            ,@body)
545          (kill-buffer buf)))))
546
547 (defun notmuch-pick-new-mail (&optional prompt-for-sender)
548   "Compose new mail."
549   (interactive "P")
550   (notmuch-pick-close-message-window)
551   (notmuch-mua-new-mail prompt-for-sender ))
552
553 (defun notmuch-pick-forward-message (&optional prompt-for-sender)
554   "Forward the current message."
555   (interactive "P")
556   (notmuch-pick-close-message-window)
557   (with-current-notmuch-pick-message
558    (notmuch-mua-new-forward-message prompt-for-sender)))
559
560 (defun notmuch-pick-reply (&optional prompt-for-sender)
561   "Reply to the sender and all recipients of the current message."
562   (interactive "P")
563   (notmuch-pick-close-message-window)
564   (notmuch-mua-new-reply (notmuch-pick-get-message-id) prompt-for-sender t))
565
566 (defun notmuch-pick-reply-sender (&optional prompt-for-sender)
567   "Reply to the sender of the current message."
568   (interactive "P")
569   (notmuch-pick-close-message-window)
570   (notmuch-mua-new-reply (notmuch-pick-get-message-id) prompt-for-sender nil))
571
572 ;; Shamelessly stolen from notmuch-show.el: maybe should be unified.
573 (defun notmuch-pick-pipe-message (command)
574   "Pipe the contents of the current message to the given command.
575
576 The given command will be executed with the raw contents of the
577 current email message as stdin. Anything printed by the command
578 to stdout or stderr will appear in the *notmuch-pipe* buffer.
579
580 When invoked with a prefix argument, the command will receive all
581 open messages in the current thread (formatted as an mbox) rather
582 than only the current message."
583   (interactive "sPipe message to command: ")
584   (let ((shell-command
585          (concat notmuch-command " show --format=raw "
586                  (shell-quote-argument (notmuch-pick-get-message-id)) " | " command))
587          (buf (get-buffer-create (concat "*notmuch-pipe*"))))
588     (with-current-buffer buf
589       (setq buffer-read-only nil)
590       (erase-buffer)
591       (let ((exit-code (call-process-shell-command shell-command nil buf)))
592         (goto-char (point-max))
593         (set-buffer-modified-p nil)
594         (setq buffer-read-only t)
595         (unless (zerop exit-code)
596           (switch-to-buffer-other-window buf)
597           (message (format "Command '%s' exited abnormally with code %d"
598                            shell-command exit-code)))))))
599
600 (defun notmuch-pick-clean-address (address)
601   "Try to clean a single email ADDRESS for display. Return
602 AUTHOR_NAME if present, otherwise return AUTHOR_EMAIL. Return
603 unchanged ADDRESS if parsing fails."
604   (let* ((clean-address (notmuch-clean-address address))
605          (p-address (car clean-address))
606          (p-name (cdr clean-address)))
607
608     ;; If we have a name return that otherwise return the address.
609     (or p-name p-address)))
610
611 (defun notmuch-pick-insert-field (field format-string msg)
612   (let* ((headers (plist-get msg :headers))
613         (match (plist-get msg :match)))
614     (cond
615      ((string-equal field "date")
616       (let ((face (if match
617                       'notmuch-pick-match-date-face
618                     'notmuch-pick-no-match-date-face)))
619         (insert (propertize (format format-string (plist-get msg :date_relative))
620                             'face face))))
621
622      ((string-equal field "subject")
623       (let ((tree-status (plist-get msg :tree-status))
624             (bare-subject (notmuch-show-strip-re (plist-get headers :Subject)))
625             (face (if match
626                       'notmuch-pick-match-subject-face
627                     'notmuch-pick-no-match-subject-face)))
628         (insert (propertize (format format-string
629                                     (concat
630                                      (mapconcat #'identity (reverse tree-status) "")
631                                      (if (string= notmuch-pick-previous-subject bare-subject)
632                                          " ..."
633                                        bare-subject)))
634                             'face face))
635         (setq notmuch-pick-previous-subject bare-subject)))
636
637      ((string-equal field "authors")
638       (let ((author (notmuch-pick-clean-address (plist-get headers :From)))
639             (len (length (format format-string "")))
640             (face (if match
641                       'notmuch-pick-match-author-face
642                     'notmuch-pick-no-match-author-face)))
643         (when (> (length author) len)
644           (setq author (substring author 0 len)))
645         (insert (propertize (format format-string author)
646                             'face face))))
647
648      ((string-equal field "tags")
649       (let ((tags (plist-get msg :tags))
650             (face (if match
651                           'notmuch-pick-match-tag-face
652                         'notmuch-pick-no-match-tag-face)))
653         (when tags
654           (insert (propertize (format format-string
655                                       (mapconcat #'identity tags ", "))
656                               'face face))))))))
657
658 (defun notmuch-pick-insert-msg (msg)
659   "Insert the message MSG according to notmuch-pick-result-format"
660   ;; We need to save the previous subject as it will get overwritten
661   ;; by the insert-field calls.
662   (let ((previous-subject notmuch-pick-previous-subject))
663     (dolist (spec notmuch-pick-result-format)
664       (notmuch-pick-insert-field (car spec) (cdr spec) msg))
665     (notmuch-pick-set-message-properties msg)
666     (notmuch-pick-set-prop :previous-subject previous-subject)
667     (insert "\n")))
668
669 (defun notmuch-pick-goto-and-insert-msg (msg)
670   "Insert msg at the end of the buffer. Move point to msg if it is the target"
671   (save-excursion
672     (goto-char (point-max))
673     (notmuch-pick-insert-msg msg))
674   (let ((msg-id (notmuch-id-to-query (plist-get msg :id)))
675         (target notmuch-pick-target-msg))
676     (when (or (and (not target) (plist-get msg :match))
677               (string= msg-id target))
678       (setq notmuch-pick-target-msg "found")
679       (goto-char (point-max))
680       (forward-line -1)
681       (when notmuch-pick-open-target
682         (notmuch-pick-show-message)))))
683
684 (defun notmuch-pick-insert-tree (tree depth tree-status first last)
685   "Insert the message tree TREE at depth DEPTH in the current thread."
686   (let ((msg (car tree))
687         (replies (cadr tree)))
688
689       (cond
690        ((and (< 0 depth) (not last))
691         (push "├" tree-status))
692        ((and (< 0 depth) last)
693         (push "╰" tree-status))
694        ((and (eq 0 depth) first last)
695 ;;        (push "─" tree-status)) choice between this and next line is matter of taste.
696         (push " " tree-status))
697        ((and (eq 0 depth) first (not last))
698           (push "┬" tree-status))
699        ((and (eq 0 depth) (not first) last)
700         (push "╰" tree-status))
701        ((and (eq 0 depth) (not first) (not last))
702         (push "├" tree-status)))
703
704       (push (concat (if replies "┬" "─") "►") tree-status)
705       (notmuch-pick-goto-and-insert-msg (plist-put msg :tree-status tree-status))
706       (pop tree-status)
707       (pop tree-status)
708
709       (if last
710           (push " " tree-status)
711         (push "│" tree-status))
712
713     (notmuch-pick-insert-thread replies (1+ depth) tree-status)))
714
715 (defun notmuch-pick-insert-thread (thread depth tree-status)
716   "Insert the thread THREAD at depth DEPTH >= 1 in the current forest."
717   (let ((n (length thread)))
718     (loop for tree in thread
719           for count from 1 to n
720
721           do (notmuch-pick-insert-tree tree depth tree-status (eq count 1) (eq count n)))))
722
723 (defun notmuch-pick-insert-forest-thread (forest-thread)
724   (let (tree-status)
725     ;; Reset at the start of each main thread.
726     (setq notmuch-pick-previous-subject nil)
727     (notmuch-pick-insert-thread forest-thread 0 tree-status)))
728
729 (defun notmuch-pick-insert-forest (forest)
730   (mapc 'notmuch-pick-insert-forest-thread forest))
731
732 (defun notmuch-pick-mode ()
733   "Major mode displaying messages (as opposed to threads) of of a notmuch search.
734
735 This buffer contains the results of a \"notmuch pick\" of your
736 email archives. Each line in the buffer represents a single
737 message giving the relative date, the author, subject, and any
738 tags.
739
740 Pressing \\[notmuch-pick-show-message] on any line displays that message.
741
742 Complete list of currently available key bindings:
743
744 \\{notmuch-pick-mode-map}"
745
746   (interactive)
747   (kill-all-local-variables)
748   (use-local-map notmuch-pick-mode-map)
749   (setq major-mode 'notmuch-pick-mode
750         mode-name "notmuch-pick")
751   (hl-line-mode 1)
752   (setq buffer-read-only t
753         truncate-lines t))
754
755 (defun notmuch-pick-process-sentinel (proc msg)
756   "Add a message to let user know when \"notmuch pick\" exits"
757   (let ((buffer (process-buffer proc))
758         (status (process-status proc))
759         (exit-status (process-exit-status proc))
760         (never-found-target-thread nil))
761     (when (memq status '(exit signal))
762         (kill-buffer (process-get proc 'parse-buf))
763         (if (buffer-live-p buffer)
764             (with-current-buffer buffer
765               (save-excursion
766                 (let ((inhibit-read-only t)
767                       (atbob (bobp)))
768                   (goto-char (point-max))
769                   (if (eq status 'signal)
770                       (insert "Incomplete search results (pick process was killed).\n"))
771                   (when (eq status 'exit)
772                     (insert "End of search results.")
773                     (unless (= exit-status 0)
774                       (insert (format " (process returned %d)" exit-status)))
775                     (insert "\n")))))))))
776
777 (defun notmuch-pick-process-filter (proc string)
778   "Process and filter the output of \"notmuch show\" (for pick)"
779   (let ((results-buf (process-buffer proc))
780         (parse-buf (process-get proc 'parse-buf))
781         (inhibit-read-only t)
782         done)
783     (if (not (buffer-live-p results-buf))
784         (delete-process proc)
785       (with-current-buffer parse-buf
786         ;; Insert new data
787         (save-excursion
788           (goto-char (point-max))
789           (insert string))
790         (notmuch-sexp-parse-partial-list 'notmuch-pick-insert-forest-thread
791                                          results-buf)))))
792
793 (defun notmuch-pick-worker (basic-query &optional query-context target buffer open-target)
794   (interactive)
795   (notmuch-pick-mode)
796   (setq notmuch-pick-basic-query basic-query)
797   (setq notmuch-pick-query-context query-context)
798   (setq notmuch-pick-buffer-name (buffer-name buffer))
799   (setq notmuch-pick-target-msg target)
800   (setq notmuch-pick-open-target open-target)
801
802   (erase-buffer)
803   (goto-char (point-min))
804   (let* ((search-args (concat basic-query
805                        (if query-context (concat " and (" query-context ")"))
806                        ))
807          (message-arg "--entire-thread"))
808     (if (equal (car (process-lines notmuch-command "count" search-args)) "0")
809         (setq search-args basic-query))
810     (if notmuch-pick-asynchronous-parser
811         (let ((proc (start-process
812                      "notmuch-pick" buffer
813                      notmuch-command "show" "--body=false" "--format=sexp"
814                      message-arg search-args))
815               ;; Use a scratch buffer to accumulate partial output.
816               ;; This buffer will be killed by the sentinel, which
817               ;; should be called no matter how the process dies.
818               (parse-buf (generate-new-buffer " *notmuch pick parse*")))
819           (process-put proc 'parse-buf parse-buf)
820           (set-process-sentinel proc 'notmuch-pick-process-sentinel)
821           (set-process-filter proc 'notmuch-pick-process-filter)
822           (set-process-query-on-exit-flag proc nil))
823       (progn
824         (notmuch-pick-insert-forest
825          (notmuch-query-get-threads
826           (list "--body=false" message-arg search-args)))
827         (save-excursion
828           (goto-char (point-max))
829           (insert "End of search results.\n"))))))
830
831
832 (defun notmuch-pick (&optional query query-context target buffer-name open-target)
833   "Run notmuch pick with the given `query' and display the results.
834
835 The arguments are:
836   QUERY: the main query. This can be any query but in many cases will be
837       a single thread. If nil this is read interactively from the minibuffer.
838   QUERY-CONTEXT: is an additional term for the query. The query used
839       is QUERY and QUERY-CONTEXT unless that does not match any messages
840       in which case we fall back to just QUERY.
841   TARGET: A message ID (with the id: prefix) that will be made
842       current if it appears in the pick results.
843   BUFFER-NAME: the name of the buffer to show the pick tree. If
844       it is nil \"*notmuch-pick\" followed by QUERY is used.
845   OPEN-TARGET: If TRUE open the target message in the message pane."
846   (interactive "sNotmuch pick: ")
847   (if (null query)
848       (setq query (notmuch-read-query "Notmuch pick: ")))
849   (let ((buffer (get-buffer-create (generate-new-buffer-name
850                                     (or buffer-name
851                                         (concat "*notmuch-pick-" query "*")))))
852         (inhibit-read-only t))
853
854     (switch-to-buffer buffer)
855     ;; Don't track undo information for this buffer
856     (set 'buffer-undo-list t)
857
858     (notmuch-pick-worker query query-context target buffer open-target)
859
860     (setq truncate-lines t)))
861
862
863 ;; Set up key bindings from the rest of notmuch.
864 (define-key 'notmuch-search-mode-map "z" 'notmuch-pick)
865 (define-key 'notmuch-search-mode-map "Z" 'notmuch-pick-from-search-current-query)
866 (define-key 'notmuch-search-mode-map (kbd "M-RET") 'notmuch-pick-from-search-thread)
867 (define-key 'notmuch-hello-mode-map "z" 'notmuch-pick-from-hello)
868 (define-key 'notmuch-show-mode-map "z" 'notmuch-pick)
869 (define-key 'notmuch-show-mode-map "Z" 'notmuch-pick-from-show-current-query)
870 (notmuch-pick-setup-show-out)
871 (message "Initialised notmuch-pick")
872
873 (provide 'notmuch-pick)