d016014430d94071c9b08d626550532546ce4c6c
[notmuch] / contrib / notmuch-pick / notmuch-pick.el
1 ;; notmuch-pick.el --- displaying notmuch forests.
2 ;;
3 ;; Copyright © Carl Worth
4 ;; Copyright © David Edmondson
5 ;; Copyright © Mark Walters
6 ;;
7 ;; This file is part of Notmuch.
8 ;;
9 ;; Notmuch is free software: you can redistribute it and/or modify it
10 ;; under the terms of the GNU General Public License as published by
11 ;; the Free Software Foundation, either version 3 of the License, or
12 ;; (at your option) any later version.
13 ;;
14 ;; Notmuch is distributed in the hope that it will be useful, but
15 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
17 ;; General Public License for more details.
18 ;;
19 ;; You should have received a copy of the GNU General Public License
20 ;; along with Notmuch.  If not, see <http://www.gnu.org/licenses/>.
21 ;;
22 ;; Authors: David Edmondson <dme@dme.org>
23 ;;          Mark Walters <markwalters1009@gmail.com>
24
25 (require 'mail-parse)
26
27 (require 'notmuch-lib)
28 (require 'notmuch-query)
29 (require 'notmuch-show)
30 (require 'notmuch) ;; XXX ATM, as notmuch-search-mode-map is defined here
31
32 (eval-when-compile (require 'cl))
33
34 (declare-function notmuch-call-notmuch-process "notmuch" (&rest args))
35 (declare-function notmuch-show "notmuch-show" (&rest args))
36 (declare-function notmuch-tag "notmuch" (query &rest tags))
37 (declare-function notmuch-show-strip-re "notmuch-show" (subject))
38 (declare-function notmuch-show-spaces-n "notmuch-show" (n))
39 (declare-function notmuch-read-query "notmuch" (prompt))
40 (declare-function notmuch-read-tag-changes "notmuch" (&optional initial-input &rest search-terms))
41 (declare-function notmuch-update-tags "notmuch" (current-tags tag-changes))
42 (declare-function notmuch-hello-trim "notmuch-hello" (search))
43 (declare-function notmuch-search-find-thread-id "notmuch" ())
44 (declare-function notmuch-search-find-subject "notmuch" ())
45
46 ;; the following variable is defined in notmuch.el
47 (defvar notmuch-search-query-string)
48
49 (defgroup notmuch-pick nil
50   "Showing message and thread structure."
51   :group 'notmuch)
52
53 ;; This is ugly. We can't run setup-show-out until it has been defined
54 ;; which needs the keymap to be defined. So we defer setting up to
55 ;; notmuch-pick-init.
56 (defcustom notmuch-pick-show-out nil
57   "View selected messages in new window rather than split-pane."
58   :type 'boolean
59   :group 'notmuch-pick
60   :set (lambda (symbol value)
61          (set-default symbol value)
62          (when (fboundp 'notmuch-pick-setup-show-out)
63            (notmuch-pick-setup-show-out))))
64
65 (defcustom notmuch-pick-result-format
66   `(("date" . "%12s  ")
67     ("authors" . "%-20s")
68     ("subject" . " %-54s ")
69     ("tags" . "(%s)"))
70   "Result formatting for Pick. Supported fields are: date,
71         authors, subject, tags Note: subject includes the tree
72         structure graphics, and the author string should not
73         contain whitespace (put it in the neighbouring fields
74         instead).  For example:
75         (setq notmuch-pick-result-format \(\(\"authors\" . \"%-40s\"\)
76                                              \(\"subject\" . \"%s\"\)\)\)"
77   :type '(alist :key-type (string) :value-type (string))
78   :group 'notmuch-pick)
79
80 ;; Faces for messages that match the query.
81 (defface notmuch-pick-match-date-face
82   '((t :inherit default))
83   "Face used in pick mode for the date in messages matching the query."
84   :group 'notmuch-pick
85   :group 'notmuch-faces)
86
87 (defface notmuch-pick-match-author-face
88   '((((class color)
89       (background dark))
90      (:foreground "OliveDrab1"))
91     (((class color)
92       (background light))
93      (:foreground "dark blue"))
94     (t
95      (:bold t)))
96   "Face used in pick mode for the date in messages matching the query."
97   :group 'notmuch-pick
98   :group 'notmuch-faces)
99
100 (defface notmuch-pick-match-subject-face
101   '((t :inherit default))
102   "Face used in pick mode for the subject in messages matching the query."
103   :group 'notmuch-pick
104   :group 'notmuch-faces)
105
106 (defface notmuch-pick-match-tag-face
107   '((((class color)
108       (background dark))
109      (:foreground "OliveDrab1"))
110     (((class color)
111       (background light))
112      (:foreground "navy blue" :bold t))
113     (t
114      (:bold t)))
115   "Face used in pick mode for tags in messages matching the query."
116   :group 'notmuch-pick
117   :group 'notmuch-faces)
118
119 ;; Faces for messages that do not match the query.
120 (defface notmuch-pick-no-match-date-face
121   '((t (:foreground "gray")))
122   "Face used in pick mode for non-matching dates."
123   :group 'notmuch-pick
124   :group 'notmuch-faces)
125
126 (defface notmuch-pick-no-match-subject-face
127   '((t (:foreground "gray")))
128   "Face used in pick mode for non-matching subjects."
129   :group 'notmuch-pick
130   :group 'notmuch-faces)
131
132 (defface notmuch-pick-no-match-author-face
133   '((t (:foreground "gray")))
134   "Face used in pick mode for the date in messages matching the query."
135   :group 'notmuch-pick
136   :group 'notmuch-faces)
137
138 (defface notmuch-pick-no-match-tag-face
139   '((t (:foreground "gray")))
140   "Face used in pick mode face for non-matching tags."
141   :group 'notmuch-pick
142   :group 'notmuch-faces)
143
144 (defvar notmuch-pick-previous-subject
145   "The subject of the most recent result shown during the async display")
146 (make-variable-buffer-local 'notmuch-pick-previous-subject)
147
148 (defvar notmuch-pick-basic-query nil
149   "A buffer local copy of argument query to the function notmuch-pick")
150 (make-variable-buffer-local 'notmuch-pick-basic-query)
151
152 (defvar notmuch-pick-query-context nil
153   "A buffer local copy of argument query-context to the function notmuch-pick")
154 (make-variable-buffer-local 'notmuch-pick-query-context)
155
156 (defvar notmuch-pick-target-msg nil
157   "A buffer local copy of argument target to the function notmuch-pick")
158 (make-variable-buffer-local 'notmuch-pick-target-msg)
159
160 (defvar notmuch-pick-open-target nil
161   "A buffer local copy of argument open-target to the function notmuch-pick")
162 (make-variable-buffer-local 'notmuch-pick-open-target)
163
164 (defvar notmuch-pick-buffer-name nil
165   "A buffer local copy of argument buffer-name to the function notmuch-pick")
166 (make-variable-buffer-local 'notmuch-pick-buffer-name)
167
168 (defvar notmuch-pick-message-window nil
169   "The window of the message pane.
170
171 It is set in both the pick buffer and the child show buffer. It
172 is used to try and close the message pane when quitting pick or
173 the child show buffer.")
174 (make-variable-buffer-local 'notmuch-pick-message-window)
175 (put 'notmuch-pick-message-window 'permanent-local t)
176
177 (defvar notmuch-pick-message-buffer nil
178   "The buffer name of the show buffer in the message pane.
179
180 This is used to try and make sure we don't close the message pane
181 if the user has loaded a different buffer in that window.")
182 (make-variable-buffer-local 'notmuch-pick-message-buffer)
183 (put 'notmuch-pick-message-buffer 'permanent-local t)
184
185 (defun notmuch-pick-to-message-pane (func)
186   "Execute FUNC in message pane.
187
188 This function returns a function (so can be used as a keybinding)
189 which executes function FUNC in the message pane if it is
190 open (if the message pane is closed it does nothing)."
191   `(lambda ()
192       ,(concat "(In message pane) " (documentation func t))
193      (interactive)
194      (when (window-live-p notmuch-pick-message-window)
195        (with-selected-window notmuch-pick-message-window
196          (call-interactively #',func)))))
197
198 (defun notmuch-pick-button-activate (&optional button)
199   "Activate BUTTON or button at point
200
201 This function does not give an error if there is no button."
202   (interactive)
203   (let ((button (or button (button-at (point)))))
204     (when button (button-activate button))))
205
206 (defun notmuch-pick-close-message-pane-and (func)
207   "Close message pane and execute FUNC.
208
209 This function returns a function (so can be used as a keybinding)
210 which closes the message pane if open and then executes function
211 FUNC."
212   `(lambda ()
213       ,(concat "(Close message pane and) " (documentation func t))
214      (interactive)
215      (notmuch-pick-close-message-window)
216      (call-interactively #',func)))
217
218 (defvar notmuch-pick-mode-map
219   (let ((map (make-sparse-keymap)))
220     (define-key map [mouse-1] 'notmuch-pick-show-message)
221     ;; these use notmuch-show functions directly
222     (define-key map "|" 'notmuch-show-pipe-message)
223     (define-key map "w" 'notmuch-show-save-attachments)
224     (define-key map "v" 'notmuch-show-view-all-mime-parts)
225     (define-key map "c" 'notmuch-show-stash-map)
226
227     ;; these apply to the message pane
228     (define-key map (kbd "M-TAB") (notmuch-pick-to-message-pane #'notmuch-show-previous-button))
229     (define-key map (kbd "<backtab>")  (notmuch-pick-to-message-pane #'notmuch-show-previous-button))
230     (define-key map (kbd "TAB") (notmuch-pick-to-message-pane #'notmuch-show-next-button))
231     (define-key map "e" (notmuch-pick-to-message-pane #'notmuch-pick-button-activate))
232
233     ;; bindings from show (or elsewhere) but we close the message pane first.
234     (define-key map "m" (notmuch-pick-close-message-pane-and #'notmuch-mua-new-mail))
235     (define-key map "f" (notmuch-pick-close-message-pane-and #'notmuch-show-forward-message))
236     (define-key map "r" (notmuch-pick-close-message-pane-and #'notmuch-show-reply-sender))
237     (define-key map "R" (notmuch-pick-close-message-pane-and #'notmuch-show-reply))
238     (define-key map "V" (notmuch-pick-close-message-pane-and #'notmuch-show-view-raw-message))
239     (define-key map "?" (notmuch-pick-close-message-pane-and #'notmuch-help))
240
241     ;; The main pick bindings
242     (define-key map "q" 'notmuch-pick-quit)
243     (define-key map "x" 'notmuch-pick-quit)
244     (define-key map "A" 'notmuch-pick-archive-thread)
245     (define-key map "a" 'notmuch-pick-archive-message-then-next)
246     (define-key map "=" 'notmuch-pick-refresh-view)
247     (define-key map "s" 'notmuch-pick-to-search)
248     (define-key map "z" 'notmuch-pick-to-pick)
249     (define-key map "n" 'notmuch-pick-next-matching-message)
250     (define-key map "p" 'notmuch-pick-prev-matching-message)
251     (define-key map "N" 'notmuch-pick-next-message)
252     (define-key map "P" 'notmuch-pick-prev-message)
253     (define-key map "-" 'notmuch-pick-remove-tag)
254     (define-key map "+" 'notmuch-pick-add-tag)
255     (define-key map "*" 'notmuch-pick-tag-thread)
256     (define-key map " " 'notmuch-pick-scroll-or-next)
257     (define-key map "b" 'notmuch-pick-scroll-message-window-back)
258     map))
259 (fset 'notmuch-pick-mode-map notmuch-pick-mode-map)
260
261 (defun notmuch-pick-setup-show-out ()
262   "Set up the keymap for showing a thread
263
264 This uses the value of the defcustom notmuch-pick-show-out to
265 decide whether to show a message in the message pane or in the
266 whole window."
267   (let ((map notmuch-pick-mode-map))
268     (if notmuch-pick-show-out
269         (progn
270           (define-key map (kbd "M-RET") 'notmuch-pick-show-message)
271           (define-key map (kbd "RET") 'notmuch-pick-show-message-out))
272       (progn
273         (define-key map (kbd "RET") 'notmuch-pick-show-message)
274         (define-key map (kbd "M-RET") 'notmuch-pick-show-message-out)))))
275
276 (defun notmuch-pick-get-message-properties ()
277   "Return the properties of the current message as a plist.
278
279 Some useful entries are:
280 :headers - Property list containing the headers :Date, :Subject, :From, etc.
281 :tags - Tags for this message"
282   (save-excursion
283     (beginning-of-line)
284     (get-text-property (point) :notmuch-message-properties)))
285
286 ;; XXX This should really be a lib function but we are trying to
287 ;; reduce impact on the code base.
288 (defun notmuch-show-get-prop (prop &optional props)
289   "This is a pick overridden version of notmuch-show-get-prop
290
291 It gets property PROP from PROPS or, if PROPS is nil, the current
292 message in either pick or show. This means that several functions
293 in notmuch-show now work unchanged in pick as they just need the
294 correct message properties."
295   (let ((props (or props
296                    (cond ((eq major-mode 'notmuch-show-mode)
297                           (notmuch-show-get-message-properties))
298                          ((eq major-mode 'notmuch-pick-mode)
299                           (notmuch-pick-get-message-properties))))))
300     (plist-get props prop)))
301
302 (defun notmuch-pick-set-message-properties (props)
303   (save-excursion
304     (beginning-of-line)
305     (put-text-property (point) (+ (point) 1) :notmuch-message-properties props)))
306
307 (defun notmuch-pick-set-prop (prop val &optional props)
308   (let ((inhibit-read-only t)
309         (props (or props
310                    (notmuch-pick-get-message-properties))))
311     (plist-put props prop val)
312     (notmuch-pick-set-message-properties props)))
313
314 (defun notmuch-pick-get-prop (prop &optional props)
315   (let ((props (or props
316                    (notmuch-pick-get-message-properties))))
317     (plist-get props prop)))
318
319 (defun notmuch-pick-set-tags (tags)
320   "Set the tags of the current message."
321   (notmuch-pick-set-prop :tags tags))
322
323 (defun notmuch-pick-get-tags ()
324   "Return the tags of the current message."
325   (notmuch-pick-get-prop :tags))
326
327 (defun notmuch-pick-get-message-id ()
328   "Return the message id of the current message."
329   (let ((id (notmuch-pick-get-prop :id)))
330     (if id
331         (notmuch-id-to-query id)
332       nil)))
333
334 (defun notmuch-pick-get-match ()
335   "Return whether the current message is a match."
336   (interactive)
337   (notmuch-pick-get-prop :match))
338
339 (defun notmuch-pick-refresh-result ()
340   "Redisplay the current message line.
341
342 This redisplays the current line based on the messages
343 properties (as they are now). This is used when tags are
344 updated."
345   (let ((init-point (point))
346         (end (line-end-position))
347         (msg (notmuch-pick-get-message-properties))
348         (inhibit-read-only t))
349     (beginning-of-line)
350     ;; This is a little tricky: we override
351     ;; notmuch-pick-previous-subject to get the decision between
352     ;; ... and a subject right and it stops notmuch-pick-insert-msg
353     ;; from overwriting the buffer local copy of
354     ;; notmuch-pick-previous-subject if this is called while the
355     ;; buffer is displaying.
356     (let ((notmuch-pick-previous-subject (notmuch-pick-get-prop :previous-subject)))
357       (delete-region (point) (1+ (line-end-position)))
358       (notmuch-pick-insert-msg msg))
359     (let ((new-end (line-end-position)))
360       (goto-char (if (= init-point end)
361                      new-end
362                    (min init-point (- new-end 1)))))))
363
364 (defun notmuch-pick-tag-update-display (&optional tag-changes)
365   "Update display for TAG-CHANGES to current message.
366
367 Does NOT change the database."
368   (let* ((current-tags (notmuch-pick-get-tags))
369          (new-tags (notmuch-update-tags current-tags tag-changes)))
370     (unless (equal current-tags new-tags)
371       (notmuch-pick-set-tags new-tags)
372       (notmuch-pick-refresh-result))))
373
374 (defun notmuch-pick-tag (&optional tag-changes)
375   "Change tags for the current message"
376   (interactive)
377   (setq tag-changes (notmuch-tag (notmuch-pick-get-message-id) tag-changes))
378   (notmuch-pick-tag-update-display tag-changes))
379
380 (defun notmuch-pick-add-tag ()
381   "Same as `notmuch-pick-tag' but sets initial input to '+'."
382   (interactive)
383   (notmuch-pick-tag "+"))
384
385 (defun notmuch-pick-remove-tag ()
386   "Same as `notmuch-pick-tag' but sets initial input to '-'."
387   (interactive)
388   (notmuch-pick-tag "-"))
389
390 ;; The next two functions close the message window before searching or
391 ;; picking but they do so after the user has entered the query (in
392 ;; case the user was basing the query on something in the message
393 ;; window).
394
395 (defun notmuch-pick-to-search ()
396   "Run \"notmuch search\" with the given `query' and display results."
397   (interactive)
398   (let ((query (notmuch-read-query "Notmuch search: ")))
399     (notmuch-pick-close-message-window)
400     (notmuch-search query)))
401
402 (defun notmuch-pick-to-pick ()
403   "Run a query and display results in experimental notmuch-pick mode"
404   (interactive)
405   (let ((query (notmuch-read-query "Notmuch pick: ")))
406     (notmuch-pick-close-message-window)
407     (notmuch-pick query)))
408
409 ;; This function should be in notmuch-hello.el but we are trying to
410 ;; minimise impact on the rest of the codebase.
411 (defun notmuch-pick-from-hello (&optional search)
412   "Run a query and display results in experimental notmuch-pick mode"
413   (interactive)
414   (unless (null search)
415     (setq search (notmuch-hello-trim search))
416     (let ((history-delete-duplicates t))
417       (add-to-history 'notmuch-search-history search)))
418   (notmuch-pick search))
419
420 ;; This function should be in notmuch-show.el but be we trying to
421 ;; minimise impact on the rest of the codebase.
422 (defun notmuch-pick-from-show-current-query ()
423   "Call notmuch pick with the current query"
424   (interactive)
425   (notmuch-pick notmuch-show-thread-id
426                 notmuch-show-query-context
427                 (notmuch-show-get-message-id)))
428
429 ;; This function should be in notmuch.el but be we trying to minimise
430 ;; impact on the rest of the codebase.
431 (defun notmuch-pick-from-search-current-query ()
432   "Call notmuch pick with the current query"
433   (interactive)
434   (notmuch-pick notmuch-search-query-string))
435
436 ;; This function should be in notmuch.el but be we trying to minimise
437 ;; impact on the rest of the codebase.
438 (defun notmuch-pick-from-search-thread ()
439   "Show the selected thread with notmuch-pick"
440   (interactive)
441   (notmuch-pick (notmuch-search-find-thread-id)
442                 notmuch-search-query-string
443                 nil
444                 (notmuch-prettify-subject (notmuch-search-find-subject))
445                 t))
446
447 (defun notmuch-pick-message-window-kill-hook ()
448   "Close the message pane when exiting the show buffer."
449   (let ((buffer (current-buffer)))
450     (when (and (window-live-p notmuch-pick-message-window)
451                (eq (window-buffer notmuch-pick-message-window) buffer))
452       ;; We do not want an error if this is the sole window in the
453       ;; frame and I do not know how to test for that in emacs pre
454       ;; 24. Hence we just ignore-errors.
455       (ignore-errors
456         (delete-window notmuch-pick-message-window)))))
457
458 (defun notmuch-pick-show-message ()
459   "Show the current message (in split-pane)."
460   (interactive)
461   (let ((id (notmuch-pick-get-message-id))
462         (inhibit-read-only t)
463         buffer)
464     (when id
465       ;; We close and reopen the window to kill off un-needed buffers
466       ;; this might cause flickering but seems ok.
467       (notmuch-pick-close-message-window)
468       (setq notmuch-pick-message-window
469             (split-window-vertically (/ (window-height) 4)))
470       (with-selected-window notmuch-pick-message-window
471         ;; Since we are only displaying one message do not indent.
472         (let ((notmuch-show-indent-messages-width 0)
473               (notmuch-show-only-matching-messages t))
474           (setq buffer (notmuch-show id nil nil nil))))
475       ;; We need the `let' as notmuch-pick-message-window is buffer local.
476       (let ((window notmuch-pick-message-window))
477         (with-current-buffer buffer
478           (setq notmuch-pick-message-window window)
479           (add-hook 'kill-buffer-hook 'notmuch-pick-message-window-kill-hook)))
480       (when notmuch-show-mark-read-tags
481         (notmuch-pick-tag-update-display notmuch-show-mark-read-tags))
482       (setq notmuch-pick-message-buffer buffer))))
483
484 (defun notmuch-pick-show-message-out ()
485   "Show the current message (in whole window)."
486   (interactive)
487   (let ((id (notmuch-pick-get-message-id))
488         (inhibit-read-only t)
489         buffer)
490     (when id
491       ;; We close the window to kill off un-needed buffers.
492       (notmuch-pick-close-message-window)
493       (notmuch-show id nil nil nil))))
494
495 (defun notmuch-pick-scroll-message-window ()
496   "Scroll the message window (if it exists)"
497   (interactive)
498   (when (window-live-p notmuch-pick-message-window)
499     (with-selected-window notmuch-pick-message-window
500       (if (pos-visible-in-window-p (point-max))
501           t
502         (scroll-up)))))
503
504 (defun notmuch-pick-scroll-message-window-back ()
505   "Scroll the message window back(if it exists)"
506   (interactive)
507   (when (window-live-p notmuch-pick-message-window)
508     (with-selected-window notmuch-pick-message-window
509       (if (pos-visible-in-window-p (point-min))
510           t
511         (scroll-down)))))
512
513 (defun notmuch-pick-scroll-or-next ()
514   "Scroll the message window. If it at end go to next message."
515   (interactive)
516   (when (notmuch-pick-scroll-message-window)
517     (notmuch-pick-next-matching-message)))
518
519 (defun notmuch-pick-quit ()
520   "Close the split view or exit pick."
521   (interactive)
522   (unless (notmuch-pick-close-message-window)
523     (kill-buffer (current-buffer))))
524
525 (defun notmuch-pick-close-message-window ()
526   "Close the message-window. Return t if close succeeds."
527   (interactive)
528   (when (and (window-live-p notmuch-pick-message-window)
529              (eq (window-buffer notmuch-pick-message-window) notmuch-pick-message-buffer))
530     (delete-window notmuch-pick-message-window)
531     (unless (get-buffer-window-list notmuch-pick-message-buffer)
532       (kill-buffer notmuch-pick-message-buffer))
533     t))
534
535 (defun notmuch-pick-archive-message (&optional unarchive)
536   "Archive the current message.
537
538 Archive the current message by applying the tag changes in
539 `notmuch-archive-tags' to it. If a prefix argument is given, the
540 message will be \"unarchived\", i.e. the tag changes in
541 `notmuch-archive-tags' will be reversed."
542   (interactive "P")
543   (when notmuch-archive-tags
544     (apply 'notmuch-pick-tag
545            (notmuch-tag-change-list notmuch-archive-tags unarchive))))
546
547 (defun notmuch-pick-archive-message-then-next (&optional unarchive)
548   "Archive the current message and move to next matching message."
549   (interactive "P")
550   (notmuch-pick-archive-message unarchive)
551   (notmuch-pick-next-matching-message))
552
553 (defun notmuch-pick-next-message ()
554   "Move to next message."
555   (interactive)
556   (forward-line)
557   (when (window-live-p notmuch-pick-message-window)
558     (notmuch-pick-show-message)))
559
560 (defun notmuch-pick-prev-message ()
561   "Move to previous message."
562   (interactive)
563   (forward-line -1)
564   (when (window-live-p notmuch-pick-message-window)
565     (notmuch-pick-show-message)))
566
567 (defun notmuch-pick-prev-matching-message ()
568   "Move to previous matching message."
569   (interactive)
570   (forward-line -1)
571   (while (and (not (bobp)) (not (notmuch-pick-get-match)))
572     (forward-line -1))
573   (when (window-live-p notmuch-pick-message-window)
574     (notmuch-pick-show-message)))
575
576 (defun notmuch-pick-next-matching-message ()
577   "Move to next matching message."
578   (interactive)
579   (forward-line)
580   (while (and (not (eobp)) (not (notmuch-pick-get-match)))
581     (forward-line))
582   (when (window-live-p notmuch-pick-message-window)
583     (notmuch-pick-show-message)))
584
585 (defun notmuch-pick-refresh-view ()
586   "Refresh view."
587   (interactive)
588   (let ((inhibit-read-only t)
589         (basic-query notmuch-pick-basic-query)
590         (query-context notmuch-pick-query-context)
591         (target (notmuch-pick-get-message-id))
592         (buffer-name notmuch-pick-buffer-name))
593     (erase-buffer)
594     (notmuch-pick-worker basic-query
595                          query-context
596                          target
597                          (get-buffer buffer-name))))
598
599 (defun notmuch-pick-thread-top ()
600   (when (notmuch-pick-get-message-properties)
601     (while (not (or (notmuch-pick-get-prop :first) (eobp)))
602       (forward-line -1))))
603
604 (defun notmuch-pick-thread-mapcar (function)
605   "Iterate through all messages in the current thread
606  and call FUNCTION for side effects."
607   (save-excursion
608     (notmuch-pick-thread-top)
609     (loop collect (funcall function)
610           do (forward-line)
611           while (and (notmuch-pick-get-message-properties)
612                      (not (notmuch-pick-get-prop :first))))))
613
614 (defun notmuch-pick-get-messages-ids-thread-search ()
615   "Return a search string for all message ids of messages in the current thread."
616   (mapconcat 'identity
617              (notmuch-pick-thread-mapcar 'notmuch-pick-get-message-id)
618              " or "))
619
620 (defun notmuch-pick-tag-thread (&optional tag-changes)
621   "Tag all messages in the current thread"
622   (interactive)
623   (when (notmuch-pick-get-message-properties)
624     (let ((tag-changes (notmuch-tag (notmuch-pick-get-messages-ids-thread-search) tag-changes)))
625       (notmuch-pick-thread-mapcar
626        (lambda () (notmuch-pick-tag-update-display tag-changes))))))
627
628 (defun notmuch-pick-archive-thread (&optional unarchive)
629   "Archive each message in thread.
630
631 Archive each message currently shown by applying the tag changes
632 in `notmuch-archive-tags' to each. If a prefix argument is given,
633 the messages will be \"unarchived\", i.e. the tag changes in
634 `notmuch-archive-tags' will be reversed.
635
636 Note: This command is safe from any race condition of new messages
637 being delivered to the same thread. It does not archive the
638 entire thread, but only the messages shown in the current
639 buffer."
640   (interactive "P")
641   (when notmuch-archive-tags
642     (notmuch-pick-tag-thread
643      (notmuch-tag-change-list notmuch-archive-tags unarchive))))
644
645 ;; Functions below here display the pick buffer itself.
646
647 (defun notmuch-pick-clean-address (address)
648   "Try to clean a single email ADDRESS for display. Return
649 AUTHOR_NAME if present, otherwise return AUTHOR_EMAIL. Return
650 unchanged ADDRESS if parsing fails."
651   (let* ((clean-address (notmuch-clean-address address))
652          (p-address (car clean-address))
653          (p-name (cdr clean-address)))
654
655     ;; If we have a name return that otherwise return the address.
656     (or p-name p-address)))
657
658 (defun notmuch-pick-insert-field (field format-string msg)
659   (let* ((headers (plist-get msg :headers))
660         (match (plist-get msg :match)))
661     (cond
662      ((string-equal field "date")
663       (let ((face (if match
664                       'notmuch-pick-match-date-face
665                     'notmuch-pick-no-match-date-face)))
666         (insert (propertize (format format-string (plist-get msg :date_relative))
667                             'face face))))
668
669      ((string-equal field "subject")
670       (let ((tree-status (plist-get msg :tree-status))
671             (bare-subject (notmuch-show-strip-re (plist-get headers :Subject)))
672             (face (if match
673                       'notmuch-pick-match-subject-face
674                     'notmuch-pick-no-match-subject-face)))
675         (insert (propertize (format format-string
676                                     (concat
677                                      (mapconcat #'identity (reverse tree-status) "")
678                                      (if (string= notmuch-pick-previous-subject bare-subject)
679                                          " ..."
680                                        bare-subject)))
681                             'face face))
682         (setq notmuch-pick-previous-subject bare-subject)))
683
684      ((string-equal field "authors")
685       (let ((author (notmuch-pick-clean-address (plist-get headers :From)))
686             (len (length (format format-string "")))
687             (face (if match
688                       'notmuch-pick-match-author-face
689                     'notmuch-pick-no-match-author-face)))
690         (when (> (length author) len)
691           (setq author (substring author 0 len)))
692         (insert (propertize (format format-string author)
693                             'face face))))
694
695      ((string-equal field "tags")
696       (let ((tags (plist-get msg :tags))
697             (face (if match
698                           'notmuch-pick-match-tag-face
699                         'notmuch-pick-no-match-tag-face)))
700         (when tags
701           (insert (propertize (format format-string
702                                       (mapconcat #'identity tags ", "))
703                               'face face))))))))
704
705 (defun notmuch-pick-insert-msg (msg)
706   "Insert the message MSG according to notmuch-pick-result-format"
707   ;; We need to save the previous subject as it will get overwritten
708   ;; by the insert-field calls.
709   (let ((previous-subject notmuch-pick-previous-subject))
710     (dolist (spec notmuch-pick-result-format)
711       (notmuch-pick-insert-field (car spec) (cdr spec) msg))
712     (notmuch-pick-set-message-properties msg)
713     (notmuch-pick-set-prop :previous-subject previous-subject)
714     (insert "\n")))
715
716 (defun notmuch-pick-goto-and-insert-msg (msg)
717   "Insert msg at the end of the buffer. Move point to msg if it is the target"
718   (save-excursion
719     (goto-char (point-max))
720     (notmuch-pick-insert-msg msg))
721   (let ((msg-id (notmuch-id-to-query (plist-get msg :id)))
722         (target notmuch-pick-target-msg))
723     (when (or (and (not target) (plist-get msg :match))
724               (string= msg-id target))
725       (setq notmuch-pick-target-msg "found")
726       (goto-char (point-max))
727       (forward-line -1)
728       (when notmuch-pick-open-target
729         (notmuch-pick-show-message)))))
730
731 (defun notmuch-pick-insert-tree (tree depth tree-status first last)
732   "Insert the message tree TREE at depth DEPTH in the current thread.
733
734 A message tree is another name for a single sub-thread: i.e., a
735 message together with all its descendents."
736   (let ((msg (car tree))
737         (replies (cadr tree)))
738
739       (cond
740        ((and (< 0 depth) (not last))
741         (push "├" tree-status))
742        ((and (< 0 depth) last)
743         (push "╰" tree-status))
744        ((and (eq 0 depth) first last)
745 ;;        (push "─" tree-status)) choice between this and next line is matter of taste.
746         (push " " tree-status))
747        ((and (eq 0 depth) first (not last))
748           (push "┬" tree-status))
749        ((and (eq 0 depth) (not first) last)
750         (push "╰" tree-status))
751        ((and (eq 0 depth) (not first) (not last))
752         (push "├" tree-status)))
753
754       (push (concat (if replies "┬" "─") "►") tree-status)
755       (plist-put msg :first (and first (eq 0 depth)))
756       (notmuch-pick-goto-and-insert-msg (plist-put msg :tree-status tree-status))
757       (pop tree-status)
758       (pop tree-status)
759
760       (if last
761           (push " " tree-status)
762         (push "│" tree-status))
763
764     (notmuch-pick-insert-thread replies (1+ depth) tree-status)))
765
766 (defun notmuch-pick-insert-thread (thread depth tree-status)
767   "Insert the collection of sibling sub-threads THREAD at depth DEPTH in the current forest."
768   (let ((n (length thread)))
769     (loop for tree in thread
770           for count from 1 to n
771
772           do (notmuch-pick-insert-tree tree depth tree-status (eq count 1) (eq count n)))))
773
774 (defun notmuch-pick-insert-forest-thread (forest-thread)
775   "Insert a single complete thread."
776   (let (tree-status)
777     ;; Reset at the start of each main thread.
778     (setq notmuch-pick-previous-subject nil)
779     (notmuch-pick-insert-thread forest-thread 0 tree-status)))
780
781 (defun notmuch-pick-insert-forest (forest)
782   "Insert a forest of threads.
783
784 This function inserts a collection of several complete threads as
785 passed to it by notmuch-pick-process-filter."
786   (mapc 'notmuch-pick-insert-forest-thread forest))
787
788 (defun notmuch-pick-mode ()
789   "Major mode displaying messages (as opposed to threads) of of a notmuch search.
790
791 This buffer contains the results of a \"notmuch pick\" of your
792 email archives. Each line in the buffer represents a single
793 message giving the relative date, the author, subject, and any
794 tags.
795
796 Pressing \\[notmuch-pick-show-message] on any line displays that message.
797
798 Complete list of currently available key bindings:
799
800 \\{notmuch-pick-mode-map}"
801
802   (interactive)
803   (kill-all-local-variables)
804   (use-local-map notmuch-pick-mode-map)
805   (setq major-mode 'notmuch-pick-mode
806         mode-name "notmuch-pick")
807   (hl-line-mode 1)
808   (setq buffer-read-only t
809         truncate-lines t))
810
811 (defun notmuch-pick-process-sentinel (proc msg)
812   "Add a message to let user know when \"notmuch pick\" exits"
813   (let ((buffer (process-buffer proc))
814         (status (process-status proc))
815         (exit-status (process-exit-status proc))
816         (never-found-target-thread nil))
817     (when (memq status '(exit signal))
818         (kill-buffer (process-get proc 'parse-buf))
819         (if (buffer-live-p buffer)
820             (with-current-buffer buffer
821               (save-excursion
822                 (let ((inhibit-read-only t)
823                       (atbob (bobp)))
824                   (goto-char (point-max))
825                   (if (eq status 'signal)
826                       (insert "Incomplete search results (pick process was killed).\n"))
827                   (when (eq status 'exit)
828                     (insert "End of search results.")
829                     (unless (= exit-status 0)
830                       (insert (format " (process returned %d)" exit-status)))
831                     (insert "\n")))))))))
832
833 (defun notmuch-pick-process-filter (proc string)
834   "Process and filter the output of \"notmuch show\" (for pick)"
835   (let ((results-buf (process-buffer proc))
836         (parse-buf (process-get proc 'parse-buf))
837         (inhibit-read-only t)
838         done)
839     (if (not (buffer-live-p results-buf))
840         (delete-process proc)
841       (with-current-buffer parse-buf
842         ;; Insert new data
843         (save-excursion
844           (goto-char (point-max))
845           (insert string))
846         (notmuch-sexp-parse-partial-list 'notmuch-pick-insert-forest-thread
847                                          results-buf)))))
848
849 (defun notmuch-pick-worker (basic-query &optional query-context target buffer open-target)
850   (interactive)
851   (notmuch-pick-mode)
852   (setq notmuch-pick-basic-query basic-query)
853   (setq notmuch-pick-query-context query-context)
854   (setq notmuch-pick-buffer-name (buffer-name buffer))
855   (setq notmuch-pick-target-msg target)
856   (setq notmuch-pick-open-target open-target)
857
858   (erase-buffer)
859   (goto-char (point-min))
860   (let* ((search-args (concat basic-query
861                        (if query-context (concat " and (" query-context ")"))
862                        ))
863          (message-arg "--entire-thread"))
864     (if (equal (car (process-lines notmuch-command "count" search-args)) "0")
865         (setq search-args basic-query))
866     (let ((proc (notmuch-start-notmuch
867                  "notmuch-pick" buffer #'notmuch-pick-process-sentinel
868                  "show" "--body=false" "--format=sexp"
869                  message-arg search-args))
870           ;; Use a scratch buffer to accumulate partial output.
871           ;; This buffer will be killed by the sentinel, which
872           ;; should be called no matter how the process dies.
873           (parse-buf (generate-new-buffer " *notmuch pick parse*")))
874       (process-put proc 'parse-buf parse-buf)
875       (set-process-filter proc 'notmuch-pick-process-filter)
876       (set-process-query-on-exit-flag proc nil))))
877
878 (defun notmuch-pick (&optional query query-context target buffer-name open-target)
879   "Run notmuch pick with the given `query' and display the results.
880
881 The arguments are:
882   QUERY: the main query. This can be any query but in many cases will be
883       a single thread. If nil this is read interactively from the minibuffer.
884   QUERY-CONTEXT: is an additional term for the query. The query used
885       is QUERY and QUERY-CONTEXT unless that does not match any messages
886       in which case we fall back to just QUERY.
887   TARGET: A message ID (with the id: prefix) that will be made
888       current if it appears in the pick results.
889   BUFFER-NAME: the name of the buffer to show the pick tree. If
890       it is nil \"*notmuch-pick\" followed by QUERY is used.
891   OPEN-TARGET: If TRUE open the target message in the message pane."
892   (interactive "sNotmuch pick: ")
893   (if (null query)
894       (setq query (notmuch-read-query "Notmuch pick: ")))
895   (let ((buffer (get-buffer-create (generate-new-buffer-name
896                                     (or buffer-name
897                                         (concat "*notmuch-pick-" query "*")))))
898         (inhibit-read-only t))
899
900     (switch-to-buffer buffer)
901     ;; Don't track undo information for this buffer
902     (set 'buffer-undo-list t)
903
904     (notmuch-pick-worker query query-context target buffer open-target)
905
906     (setq truncate-lines t)))
907
908
909 ;; Set up key bindings from the rest of notmuch.
910 (define-key 'notmuch-search-mode-map "z" 'notmuch-pick)
911 (define-key 'notmuch-search-mode-map "Z" 'notmuch-pick-from-search-current-query)
912 (define-key 'notmuch-search-mode-map (kbd "M-RET") 'notmuch-pick-from-search-thread)
913 (define-key 'notmuch-hello-mode-map "z" 'notmuch-pick-from-hello)
914 (define-key 'notmuch-show-mode-map "z" 'notmuch-pick)
915 (define-key 'notmuch-show-mode-map "Z" 'notmuch-pick-from-show-current-query)
916 (notmuch-pick-setup-show-out)
917 (message "Initialised notmuch-pick")
918
919 (provide 'notmuch-pick)