f8e516583dfec6da1ae5fd9fbfa6d6a82377b0af
[notmuch] / emacs / notmuch-lib.el
1 ;; notmuch-lib.el --- common variables, functions and function declarations
2 ;;
3 ;; Copyright © Carl Worth
4 ;;
5 ;; This file is part of Notmuch.
6 ;;
7 ;; Notmuch is free software: you can redistribute it and/or modify it
8 ;; under the terms of the GNU General Public License as published by
9 ;; the Free Software Foundation, either version 3 of the License, or
10 ;; (at your option) any later version.
11 ;;
12 ;; Notmuch is distributed in the hope that it will be useful, but
13 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
15 ;; General Public License for more details.
16 ;;
17 ;; You should have received a copy of the GNU General Public License
18 ;; along with Notmuch.  If not, see <http://www.gnu.org/licenses/>.
19 ;;
20 ;; Authors: Carl Worth <cworth@cworth.org>
21
22 ;; This is an part of an emacs-based interface to the notmuch mail system.
23
24 (require 'mm-view)
25 (require 'mm-decode)
26 (require 'cl)
27
28 (autoload 'notmuch-jump-search "notmuch-jump"
29   "Jump to a saved search by shortcut key." t)
30
31 (defgroup notmuch nil
32   "Notmuch mail reader for Emacs."
33   :group 'mail)
34
35 (defgroup notmuch-hello nil
36   "Overview of saved searches, tags, etc."
37   :group 'notmuch)
38
39 (defgroup notmuch-search nil
40   "Searching and sorting mail."
41   :group 'notmuch)
42
43 (defgroup notmuch-show nil
44   "Showing messages and threads."
45   :group 'notmuch)
46
47 (defgroup notmuch-send nil
48   "Sending messages from Notmuch."
49   :group 'notmuch)
50
51 (custom-add-to-group 'notmuch-send 'message 'custom-group)
52
53 (defgroup notmuch-crypto nil
54   "Processing and display of cryptographic MIME parts."
55   :group 'notmuch)
56
57 (defgroup notmuch-hooks nil
58   "Running custom code on well-defined occasions."
59   :group 'notmuch)
60
61 (defgroup notmuch-external nil
62   "Running external commands from within Notmuch."
63   :group 'notmuch)
64
65 (defgroup notmuch-faces nil
66   "Graphical attributes for displaying text"
67   :group 'notmuch)
68
69 (defcustom notmuch-command "notmuch"
70   "Name of the notmuch binary.
71
72 This can be a relative or absolute path to the notmuch binary.
73 If this is a relative path, it will be searched for in all of the
74 directories given in `exec-path' (which is, by default, based on
75 $PATH)."
76   :type 'string
77   :group 'notmuch-external)
78
79 (defcustom notmuch-search-oldest-first t
80   "Show the oldest mail first when searching.
81
82 This variable defines the default sort order for displaying
83 search results. Note that any filtered searches created by
84 `notmuch-search-filter' retain the search order of the parent
85 search."
86   :type 'boolean
87   :group 'notmuch-search)
88
89 (defcustom notmuch-poll-script nil
90   "[Deprecated] Command to run to incorporate new mail into the notmuch database.
91
92 This option has been deprecated in favor of \"notmuch new\"
93 hooks (see man notmuch-hooks).  To change the path to the notmuch
94 binary, customize `notmuch-command'.
95
96 This variable controls the action invoked by
97 `notmuch-poll-and-refresh-this-buffer' (bound by default to 'G')
98 to incorporate new mail into the notmuch database.
99
100 If set to nil (the default), new mail is processed by invoking
101 \"notmuch new\". Otherwise, this should be set to a string that
102 gives the name of an external script that processes new mail. If
103 set to the empty string, no command will be run.
104
105 The external script could do any of the following depending on
106 the user's needs:
107
108 1. Invoke a program to transfer mail to the local mail store
109 2. Invoke \"notmuch new\" to incorporate the new mail
110 3. Invoke one or more \"notmuch tag\" commands to classify the mail"
111   :type '(choice (const :tag "notmuch new" nil)
112                  (const :tag "Disabled" "")
113                  (string :tag "Custom script"))
114   :group 'notmuch-external)
115
116 ;;
117
118 (defvar notmuch-search-history nil
119   "Variable to store notmuch searches history.")
120
121 (defcustom notmuch-archive-tags '("-inbox")
122   "List of tag changes to apply to a message or a thread when it is archived.
123
124 Tags starting with \"+\" (or not starting with either \"+\" or
125 \"-\") in the list will be added, and tags starting with \"-\"
126 will be removed from the message or thread being archived.
127
128 For example, if you wanted to remove an \"inbox\" tag and add an
129 \"archived\" tag, you would set:
130     (\"-inbox\" \"+archived\")"
131   :type '(repeat string)
132   :group 'notmuch-search
133   :group 'notmuch-show)
134
135 (defvar notmuch-common-keymap
136   (let ((map (make-sparse-keymap)))
137     (define-key map "?" 'notmuch-help)
138     (define-key map "q" 'notmuch-bury-or-kill-this-buffer)
139     (define-key map "s" 'notmuch-search)
140     (define-key map "z" 'notmuch-tree)
141     (define-key map "m" 'notmuch-mua-new-mail)
142     (define-key map "=" 'notmuch-refresh-this-buffer)
143     (define-key map "G" 'notmuch-poll-and-refresh-this-buffer)
144     (define-key map "j" 'notmuch-jump-search)
145     map)
146   "Keymap shared by all notmuch modes.")
147
148 ;; By default clicking on a button does not select the window
149 ;; containing the button (as opposed to clicking on a widget which
150 ;; does). This means that the button action is then executed in the
151 ;; current selected window which can cause problems if the button
152 ;; changes the buffer (e.g., id: links) or moves point.
153 ;;
154 ;; This provides a button type which overrides mouse-action so that
155 ;; the button's window is selected before the action is run. Other
156 ;; notmuch buttons can get the same behaviour by inheriting from this
157 ;; button type.
158 (define-button-type 'notmuch-button-type
159   'mouse-action (lambda (button)
160                   (select-window (posn-window (event-start last-input-event)))
161                   (button-activate button)))
162
163 (defun notmuch-command-to-string (&rest args)
164   "Synchronously invoke \"notmuch\" with the given list of arguments.
165
166 If notmuch exits with a non-zero status, output from the process
167 will appear in a buffer named \"*Notmuch errors*\" and an error
168 will be signaled.
169
170 Otherwise the output will be returned"
171   (with-temp-buffer
172     (let* ((status (apply #'call-process notmuch-command nil t nil args))
173            (output (buffer-string)))
174       (notmuch-check-exit-status status (cons notmuch-command args) output)
175       output)))
176
177 (defvar notmuch--cli-sane-p nil
178   "Cache whether the CLI seems to be configured sanely.")
179
180 (defun notmuch-cli-sane-p ()
181   "Return t if the cli seems to be configured sanely."
182   (unless notmuch--cli-sane-p
183     (let ((status (call-process notmuch-command nil nil nil
184                                 "config" "get" "user.primary_email")))
185       (setq notmuch--cli-sane-p (= status 0))))
186   notmuch--cli-sane-p)
187
188 (defun notmuch-assert-cli-sane ()
189   (unless (notmuch-cli-sane-p)
190     (notmuch-logged-error
191      "notmuch cli seems misconfigured or unconfigured."
192 "Perhaps you haven't run \"notmuch setup\" yet? Try running this
193 on the command line, and then retry your notmuch command")))
194
195 (defun notmuch-version ()
196   "Return a string with the notmuch version number."
197   (let ((long-string
198          ;; Trim off the trailing newline.
199          (substring (notmuch-command-to-string "--version") 0 -1)))
200     (if (string-match "^notmuch\\( version\\)? \\(.*\\)$"
201                       long-string)
202         (match-string 2 long-string)
203       "unknown")))
204
205 (defun notmuch-config-get (item)
206   "Return a value from the notmuch configuration."
207   (let* ((val (notmuch-command-to-string "config" "get" item))
208          (len (length val)))
209     ;; Trim off the trailing newline (if the value is empty or not
210     ;; configured, there will be no newline)
211     (if (and (> len 0) (= (aref val (- len 1)) ?\n))
212         (substring val 0 -1)
213       val)))
214
215 (defun notmuch-database-path ()
216   "Return the database.path value from the notmuch configuration."
217   (notmuch-config-get "database.path"))
218
219 (defun notmuch-user-name ()
220   "Return the user.name value from the notmuch configuration."
221   (notmuch-config-get "user.name"))
222
223 (defun notmuch-user-primary-email ()
224   "Return the user.primary_email value from the notmuch configuration."
225   (notmuch-config-get "user.primary_email"))
226
227 (defun notmuch-user-other-email ()
228   "Return the user.other_email value (as a list) from the notmuch configuration."
229   (split-string (notmuch-config-get "user.other_email") "\n" t))
230
231 (defun notmuch-poll ()
232   "Run \"notmuch new\" or an external script to import mail.
233
234 Invokes `notmuch-poll-script', \"notmuch new\", or does nothing
235 depending on the value of `notmuch-poll-script'."
236   (interactive)
237   (if (stringp notmuch-poll-script)
238       (unless (string= notmuch-poll-script "")
239         (call-process notmuch-poll-script nil nil))
240     (call-process notmuch-command nil nil nil "new")))
241
242 (defun notmuch-bury-or-kill-this-buffer ()
243   "Undisplay the current buffer.
244
245 Bury the current buffer, unless there is only one window showing
246 it, in which case it is killed."
247   (interactive)
248   (if (> (length (get-buffer-window-list nil nil t)) 1)
249       (bury-buffer)
250     (kill-buffer)))
251
252 (defun notmuch-documentation-first-line (symbol)
253   "Return the first line of the documentation string for SYMBOL."
254   (let ((doc (documentation symbol)))
255     (if doc
256         (with-temp-buffer
257           (insert (documentation symbol t))
258           (goto-char (point-min))
259           (let ((beg (point)))
260             (end-of-line)
261             (buffer-substring beg (point))))
262       "")))
263
264 (defun notmuch-prefix-key-description (key)
265   "Given a prefix key code, return a human-readable string representation.
266
267 This is basically just `format-kbd-macro' but we also convert ESC to M-."
268   (let* ((key-vector (if (vectorp key) key (vector key)))
269          (desc (format-kbd-macro key-vector)))
270     (if (string= desc "ESC")
271         "M-"
272       (concat desc " "))))
273
274
275 (defun notmuch-describe-key (actual-key binding prefix ua-keys tail)
276   "Prepend cons cells describing prefix-arg ACTUAL-KEY and ACTUAL-KEY to TAIL
277
278 It does not prepend if ACTUAL-KEY is already listed in TAIL."
279   (let ((key-string (concat prefix (format-kbd-macro actual-key))))
280     ;; We don't include documentation if the key-binding is
281     ;; over-ridden. Note, over-riding a binding automatically hides the
282     ;; prefixed version too.
283     (unless (assoc key-string tail)
284       (when (and ua-keys (symbolp binding)
285                  (get binding 'notmuch-prefix-doc))
286         ;; Documentation for prefixed command
287         (let ((ua-desc (key-description ua-keys)))
288           (push (cons (concat ua-desc " " prefix (format-kbd-macro actual-key))
289                       (get binding 'notmuch-prefix-doc))
290                 tail)))
291       ;; Documentation for command
292       (push (cons key-string
293                   (or (and (symbolp binding) (get binding 'notmuch-doc))
294                       (notmuch-documentation-first-line binding)))
295             tail)))
296     tail)
297
298 (defun notmuch-describe-remaps (remap-keymap ua-keys base-keymap prefix tail)
299   ;; Remappings are represented as a binding whose first "event" is
300   ;; 'remap.  Hence, if the keymap has any remappings, it will have a
301   ;; binding whose "key" is 'remap, and whose "binding" is itself a
302   ;; keymap that maps not from keys to commands, but from old (remapped)
303   ;; functions to the commands to use in their stead.
304   (map-keymap
305    (lambda (command binding)
306      (mapc
307       (lambda (actual-key)
308         (setq tail (notmuch-describe-key actual-key binding prefix ua-keys tail)))
309       (where-is-internal command base-keymap)))
310    remap-keymap)
311   tail)
312
313 (defun notmuch-describe-keymap (keymap ua-keys base-keymap &optional prefix tail)
314   "Return a list of cons cells, each describing one binding in KEYMAP.
315
316 Each cons cell consists of a string giving a human-readable
317 description of the key, and a one-line description of the bound
318 function.  See `notmuch-help' for an overview of how this
319 documentation is extracted.
320
321 UA-KEYS should be a key sequence bound to `universal-argument'.
322 It will be used to describe bindings of commands that support a
323 prefix argument.  PREFIX and TAIL are used internally."
324   (map-keymap
325    (lambda (key binding)
326      (cond ((mouse-event-p key) nil)
327            ((keymapp binding)
328             (setq tail
329                   (if (eq key 'remap)
330                       (notmuch-describe-remaps
331                        binding ua-keys base-keymap prefix tail)
332                     (notmuch-describe-keymap
333                      binding ua-keys base-keymap (notmuch-prefix-key-description key) tail))))
334            (binding
335             (setq tail (notmuch-describe-key (vector key) binding prefix ua-keys tail)))))
336    keymap)
337   tail)
338
339 (defun notmuch-substitute-command-keys (doc)
340   "Like `substitute-command-keys' but with documentation, not function names."
341   (let ((beg 0))
342     (while (string-match "\\\\{\\([^}[:space:]]*\\)}" doc beg)
343       (let ((desc
344              (save-match-data
345                (let* ((keymap-name (substring doc (match-beginning 1) (match-end 1)))
346                       (keymap (symbol-value (intern keymap-name)))
347                       (ua-keys (where-is-internal 'universal-argument keymap t))
348                       (desc-alist (notmuch-describe-keymap keymap ua-keys keymap))
349                       (desc-list (mapcar (lambda (arg) (concat (car arg) "\t" (cdr arg))) desc-alist)))
350                  (mapconcat #'identity desc-list "\n")))))
351         (setq doc (replace-match desc 1 1 doc)))
352       (setq beg (match-end 0)))
353     doc))
354
355 (defun notmuch-help ()
356   "Display help for the current notmuch mode.
357
358 This is similar to `describe-function' for the current major
359 mode, but bindings tables are shown with documentation strings
360 rather than command names.  By default, this uses the first line
361 of each command's documentation string.  A command can override
362 this by setting the 'notmuch-doc property of its command symbol.
363 A command that supports a prefix argument can explicitly document
364 its prefixed behavior by setting the 'notmuch-prefix-doc property
365 of its command symbol."
366   (interactive)
367   (let* ((mode major-mode)
368          (doc (substitute-command-keys (notmuch-substitute-command-keys (documentation mode t)))))
369     (with-current-buffer (generate-new-buffer "*notmuch-help*")
370       (insert doc)
371       (goto-char (point-min))
372       (set-buffer-modified-p nil)
373       (view-buffer (current-buffer) 'kill-buffer-if-not-modified))))
374
375 (defun notmuch-subkeymap-help ()
376   "Show help for a subkeymap."
377   (interactive)
378   (let* ((key (this-command-keys-vector))
379         (prefix (make-vector (1- (length key)) nil))
380         (i 0))
381     (while (< i (length prefix))
382       (aset prefix i (aref key i))
383       (setq i (1+ i)))
384
385     (let* ((subkeymap (key-binding prefix))
386            (ua-keys (where-is-internal 'universal-argument nil t))
387            (prefix-string (notmuch-prefix-key-description prefix))
388            (desc-alist (notmuch-describe-keymap subkeymap ua-keys subkeymap prefix-string))
389            (desc-list (mapcar (lambda (arg) (concat (car arg) "\t" (cdr arg))) desc-alist))
390            (desc (mapconcat #'identity desc-list "\n")))
391       (with-help-window (help-buffer)
392         (with-current-buffer standard-output
393           (insert "\nPress 'q' to quit this window.\n\n")
394           (insert desc)))
395       (pop-to-buffer (help-buffer)))))
396
397 (defvar notmuch-buffer-refresh-function nil
398   "Function to call to refresh the current buffer.")
399 (make-variable-buffer-local 'notmuch-buffer-refresh-function)
400
401 (defun notmuch-refresh-this-buffer ()
402   "Refresh the current buffer."
403   (interactive)
404   (when notmuch-buffer-refresh-function
405     (if (commandp notmuch-buffer-refresh-function)
406         ;; Pass prefix argument, etc.
407         (call-interactively notmuch-buffer-refresh-function)
408       (funcall notmuch-buffer-refresh-function))))
409
410 (defun notmuch-poll-and-refresh-this-buffer ()
411   "Invoke `notmuch-poll' to import mail, then refresh the current buffer."
412   (interactive)
413   (notmuch-poll)
414   (notmuch-refresh-this-buffer))
415
416 (defun notmuch-prettify-subject (subject)
417   ;; This function is used by `notmuch-search-process-filter' which
418   ;; requires that we not disrupt its' matching state.
419   (save-match-data
420     (if (and subject
421              (string-match "^[ \t]*$" subject))
422         "[No Subject]"
423       subject)))
424
425 (defun notmuch-sanitize (str)
426   "Sanitize control character in STR.
427
428 This includes newlines, tabs, and other funny characters."
429   (replace-regexp-in-string "[[:cntrl:]\x7f\u2028\u2029]+" " " str))
430
431 (defun notmuch-escape-boolean-term (term)
432   "Escape a boolean term for use in a query.
433
434 The caller is responsible for prepending the term prefix and a
435 colon.  This performs minimal escaping in order to produce
436 user-friendly queries."
437
438   (save-match-data
439     (if (or (equal term "")
440             ;; To be pessimistic, only pass through terms composed
441             ;; entirely of ASCII printing characters other than ", (,
442             ;; and ).
443             (string-match "[^!#-'*-~]" term))
444         ;; Requires escaping
445         (concat "\"" (replace-regexp-in-string "\"" "\"\"" term t t) "\"")
446       term)))
447
448 (defun notmuch-id-to-query (id)
449   "Return a query that matches the message with id ID."
450   (concat "id:" (notmuch-escape-boolean-term id)))
451
452 (defun notmuch-hex-encode (str)
453   "Hex-encode STR (e.g., as used by batch tagging).
454
455 This replaces spaces, percents, and double quotes in STR with
456 %NN where NN is the hexadecimal value of the character."
457   (replace-regexp-in-string
458    "[ %\"]" (lambda (match) (format "%%%02x" (aref match 0))) str))
459
460 ;;
461
462 (defun notmuch-common-do-stash (text)
463   "Common function to stash text in kill ring, and display in minibuffer."
464   (if text
465       (progn
466         (kill-new text)
467         (message "Stashed: %s" text))
468     ;; There is nothing to stash so stash an empty string so the user
469     ;; doesn't accidentally paste something else somewhere.
470     (kill-new "")
471     (message "Nothing to stash!")))
472
473 ;;
474
475 (defun notmuch-remove-if-not (predicate list)
476   "Return a copy of LIST with all items not satisfying PREDICATE removed."
477   (let (out)
478     (while list
479       (when (funcall predicate (car list))
480         (push (car list) out))
481       (setq list (cdr list)))
482     (nreverse out)))
483
484 (defun notmuch-plist-delete (plist property)
485   (let* ((xplist (cons nil plist))
486          (pred xplist))
487     (while (cdr pred)
488       (when (eq (cadr pred) property)
489         (setcdr pred (cdddr pred)))
490       (setq pred (cddr pred)))
491     (cdr xplist)))
492
493 (defun notmuch-split-content-type (content-type)
494   "Split content/type into 'content' and 'type'"
495   (split-string content-type "/"))
496
497 (defun notmuch-match-content-type (t1 t2)
498   "Return t if t1 and t2 are matching content types, taking wildcards into account"
499   (let ((st1 (notmuch-split-content-type t1))
500         (st2 (notmuch-split-content-type t2)))
501     (if (or (string= (cadr st1) "*")
502             (string= (cadr st2) "*"))
503         ;; Comparison of content types should be case insensitive.
504         (string= (downcase (car st1)) (downcase (car st2)))
505       (string= (downcase t1) (downcase t2)))))
506
507 (defvar notmuch-multipart/alternative-discouraged
508   '(
509     ;; Avoid HTML parts.
510     "text/html"
511     ;; multipart/related usually contain a text/html part and some associated graphics.
512     "multipart/related"
513     ))
514
515 (defun notmuch-multipart/alternative-choose (types)
516   "Return a list of preferred types from the given list of types"
517   ;; Based on `mm-preferred-alternative-precedence'.
518   (let ((seq types))
519     (dolist (pref (reverse notmuch-multipart/alternative-discouraged))
520       (dolist (elem (copy-sequence seq))
521         (when (string-match pref elem)
522           (setq seq (nconc (delete elem seq) (list elem))))))
523     seq))
524
525 (defun notmuch-parts-filter-by-type (parts type)
526   "Given a list of message parts, return a list containing the ones matching
527 the given type."
528   (remove-if-not
529    (lambda (part) (notmuch-match-content-type (plist-get part :content-type) type))
530    parts))
531
532 (defun notmuch-get-bodypart-binary (msg part process-crypto &optional cache)
533   "Return the unprocessed content of PART in MSG as a unibyte string.
534
535 This returns the \"raw\" content of the given part after content
536 transfer decoding, but with no further processing (see the
537 discussion of --format=raw in man notmuch-show).  In particular,
538 this does no charset conversion.
539
540 If CACHE is non-nil, the content of this part will be saved in
541 MSG (if it isn't already)."
542   (let ((data (plist-get part :binary-content)))
543     (when (not data)
544       (let ((args `("show" "--format=raw"
545                     ,(format "--part=%d" (plist-get part :id))
546                     ,@(when process-crypto '("--decrypt"))
547                     ,(notmuch-id-to-query (plist-get msg :id)))))
548         (with-temp-buffer
549           ;; Emacs internally uses a UTF-8-like multibyte string
550           ;; representation by default (regardless of the coding
551           ;; system, which only affects how it goes from outside data
552           ;; to this internal representation).  This *almost* never
553           ;; matters.  Annoyingly, it does matter if we use this data
554           ;; in an image descriptor, since Emacs will use its internal
555           ;; data buffer directly and this multibyte representation
556           ;; corrupts binary image formats.  Since the caller is
557           ;; asking for binary data, a unibyte string is a more
558           ;; appropriate representation anyway.
559           (set-buffer-multibyte nil)
560           (let ((coding-system-for-read 'no-conversion))
561             (apply #'call-process notmuch-command nil '(t nil) nil args)
562             (setq data (buffer-string)))))
563       (when cache
564         ;; Cheat.  part is non-nil, and `plist-put' always modifies
565         ;; the list in place if it's non-nil.
566         (plist-put part :binary-content data)))
567     data))
568
569 (defun notmuch-get-bodypart-text (msg part process-crypto &optional cache)
570   "Return the text content of PART in MSG.
571
572 This returns the content of the given part as a multibyte Lisp
573 string after performing content transfer decoding and any
574 necessary charset decoding.  It is an error to use this for
575 non-text/* parts.
576
577 If CACHE is non-nil, the content of this part will be saved in
578 MSG (if it isn't already)."
579   (let ((content (plist-get part :content)))
580     (when (not content)
581       ;; Use show --format=sexp to fetch decoded content
582       (let* ((args `("show" "--format=sexp" "--include-html"
583                      ,(format "--part=%s" (plist-get part :id))
584                      ,@(when process-crypto '("--decrypt"))
585                      ,(notmuch-id-to-query (plist-get msg :id))))
586              (npart (apply #'notmuch-call-notmuch-sexp args)))
587         (setq content (plist-get npart :content))
588         (when (not content)
589           (error "Internal error: No :content from %S" args)))
590       (when cache
591         (plist-put part :content content)))
592     content))
593
594 ;; Workaround: The call to `mm-display-part' below triggers a bug in
595 ;; Emacs 24 if it attempts to use the shr renderer to display an HTML
596 ;; part with images in it (demonstrated in 24.1 and 24.2 on Debian and
597 ;; Fedora 17, though unreproducable in other configurations).
598 ;; `mm-shr' references the variable `gnus-inhibit-images' without
599 ;; first loading gnus-art, which defines it, resulting in a
600 ;; void-variable error.  Hence, we advise `mm-shr' to ensure gnus-art
601 ;; is loaded.
602 (if (>= emacs-major-version 24)
603     (defadvice mm-shr (before load-gnus-arts activate)
604       (require 'gnus-art nil t)
605       (ad-disable-advice 'mm-shr 'before 'load-gnus-arts)
606       (ad-activate 'mm-shr)))
607
608 (defun notmuch-mm-display-part-inline (msg part content-type process-crypto)
609   "Use the mm-decode/mm-view functions to display a part in the
610 current buffer, if possible."
611   (let ((display-buffer (current-buffer)))
612     (with-temp-buffer
613       ;; In case we already have :content, use it and tell mm-* that
614       ;; it's already been charset-decoded by using the fake
615       ;; `gnus-decoded' charset.  Otherwise, we'll fetch the binary
616       ;; part content and let mm-* decode it.
617       (let* ((have-content (plist-member part :content))
618              (charset (if have-content 'gnus-decoded
619                         (plist-get part :content-charset)))
620              (handle (mm-make-handle (current-buffer) `(,content-type (charset . ,charset)))))
621         ;; If the user wants the part inlined, insert the content and
622         ;; test whether we are able to inline it (which includes both
623         ;; capability and suitability tests).
624         (when (mm-inlined-p handle)
625           (if have-content
626               (insert (notmuch-get-bodypart-text msg part process-crypto))
627             (insert (notmuch-get-bodypart-binary msg part process-crypto)))
628           (when (mm-inlinable-p handle)
629             (set-buffer display-buffer)
630             (mm-display-part handle)
631             t))))))
632
633 ;; Converts a plist of headers to an alist of headers. The input plist should
634 ;; have symbols of the form :Header as keys, and the resulting alist will have
635 ;; symbols of the form 'Header as keys.
636 (defun notmuch-headers-plist-to-alist (plist)
637   (loop for (key value . rest) on plist by #'cddr
638         collect (cons (intern (substring (symbol-name key) 1)) value)))
639
640 (defun notmuch-face-ensure-list-form (face)
641   "Return FACE in face list form.
642
643 If FACE is already a face list, it will be returned as-is.  If
644 FACE is a face name or face plist, it will be returned as a
645 single element face list."
646   (if (and (listp face) (not (keywordp (car face))))
647       face
648     (list face)))
649
650 (defun notmuch-apply-face (object face &optional below start end)
651   "Combine FACE into the 'face text property of OBJECT between START and END.
652
653 This function combines FACE with any existing faces between START
654 and END in OBJECT.  Attributes specified by FACE take precedence
655 over existing attributes unless BELOW is non-nil.
656
657 OBJECT may be a string, a buffer, or nil (which means the current
658 buffer).  If object is a string, START and END are 0-based;
659 otherwise they are buffer positions (integers or markers).  FACE
660 must be a face name (a symbol or string), a property list of face
661 attributes, or a list of these.  If START and/or END are omitted,
662 they default to the beginning/end of OBJECT.  For convenience
663 when applied to strings, this returns OBJECT."
664
665   ;; A face property can have three forms: a face name (a string or
666   ;; symbol), a property list, or a list of these two forms.  In the
667   ;; list case, the faces will be combined, with the earlier faces
668   ;; taking precedent.  Here we canonicalize everything to list form
669   ;; to make it easy to combine.
670   (let ((pos (cond (start start)
671                    ((stringp object) 0)
672                    (t 1)))
673         (end (cond (end end)
674                    ((stringp object) (length object))
675                    (t (1+ (buffer-size object)))))
676         (face-list (notmuch-face-ensure-list-form face)))
677     (while (< pos end)
678       (let* ((cur (get-text-property pos 'face object))
679              (cur-list (notmuch-face-ensure-list-form cur))
680              (new (cond ((null cur-list) face)
681                         (below (append cur-list face-list))
682                         (t (append face-list cur-list))))
683              (next (next-single-property-change pos 'face object end)))
684         (put-text-property pos next 'face new object)
685         (setq pos next))))
686   object)
687
688 (defun notmuch-map-text-property (start end prop func &optional object)
689   "Transform text property PROP using FUNC.
690
691 Applies FUNC to each distinct value of the text property PROP
692 between START and END of OBJECT, setting PROP to the value
693 returned by FUNC."
694   (while (< start end)
695     (let ((value (get-text-property start prop object))
696           (next (next-single-property-change start prop object end)))
697       (put-text-property start next prop (funcall func value) object)
698       (setq start next))))
699
700 (defun notmuch-logged-error (msg &optional extra)
701   "Log MSG and EXTRA to *Notmuch errors* and signal MSG.
702
703 This logs MSG and EXTRA to the *Notmuch errors* buffer and
704 signals MSG as an error.  If EXTRA is non-nil, text referring the
705 user to the *Notmuch errors* buffer will be appended to the
706 signaled error.  This function does not return."
707
708   (with-current-buffer (get-buffer-create "*Notmuch errors*")
709     (goto-char (point-max))
710     (unless (bobp)
711       (newline))
712     (save-excursion
713       (insert "[" (current-time-string) "]\n" msg)
714       (unless (bolp)
715         (newline))
716       (when extra
717         (insert extra)
718         (unless (bolp)
719           (newline)))))
720   (error "%s" (concat msg (when extra
721                             " (see *Notmuch errors* for more details)"))))
722
723 (defun notmuch-check-async-exit-status (proc msg &optional command err-file)
724   "If PROC exited abnormally, pop up an error buffer and signal an error.
725
726 This is a wrapper around `notmuch-check-exit-status' for
727 asynchronous process sentinels.  PROC and MSG must be the
728 arguments passed to the sentinel.  COMMAND and ERR-FILE, if
729 provided, are passed to `notmuch-check-exit-status'.  If COMMAND
730 is not provided, it is taken from `process-command'."
731   (let ((exit-status
732          (case (process-status proc)
733            ((exit) (process-exit-status proc))
734            ((signal) msg))))
735     (when exit-status
736       (notmuch-check-exit-status exit-status (or command (process-command proc))
737                                  nil err-file))))
738
739 (defun notmuch-check-exit-status (exit-status command &optional output err-file)
740   "If EXIT-STATUS is non-zero, pop up an error buffer and signal an error.
741
742 If EXIT-STATUS is non-zero, pop up a notmuch error buffer
743 describing the error and signal an Elisp error.  EXIT-STATUS must
744 be a number indicating the exit status code of a process or a
745 string describing the signal that terminated the process (such as
746 returned by `call-process').  COMMAND must be a list giving the
747 command and its arguments.  OUTPUT, if provided, is a string
748 giving the output of command.  ERR-FILE, if provided, is the name
749 of a file containing the error output of command.  OUTPUT and the
750 contents of ERR-FILE will be included in the error message."
751
752   (cond
753    ((eq exit-status 0) t)
754    ((eq exit-status 20)
755     (notmuch-logged-error "notmuch CLI version mismatch
756 Emacs requested an older output format than supported by the notmuch CLI.
757 You may need to restart Emacs or upgrade your notmuch Emacs package."))
758    ((eq exit-status 21)
759     (notmuch-logged-error "notmuch CLI version mismatch
760 Emacs requested a newer output format than supported by the notmuch CLI.
761 You may need to restart Emacs or upgrade your notmuch package."))
762    (t
763     (let* ((err (when err-file
764                   (with-temp-buffer
765                     (insert-file-contents err-file)
766                     (unless (eobp)
767                       (buffer-string)))))
768            (extra
769             (concat
770              "command: " (mapconcat #'shell-quote-argument command " ") "\n"
771              (if (integerp exit-status)
772                  (format "exit status: %s\n" exit-status)
773                (format "exit signal: %s\n" exit-status))
774              (when err
775                (concat "stderr:\n" err))
776              (when output
777                (concat "stdout:\n" output)))))
778         (if err
779             ;; We have an error message straight from the CLI.
780             (notmuch-logged-error
781              (replace-regexp-in-string "[ \n\r\t\f]*\\'" "" err) extra)
782           ;; We only have combined output from the CLI; don't inundate
783           ;; the user with it.  Mimic `process-lines'.
784           (notmuch-logged-error (format "%s exited with status %s"
785                                         (car command) exit-status)
786                                 extra))
787         ;; `notmuch-logged-error' does not return.
788         ))))
789
790 (defun notmuch-call-notmuch--helper (destination args)
791   "Helper for synchronous notmuch invocation commands.
792
793 This wraps `call-process'.  DESTINATION has the same meaning as
794 for `call-process'.  ARGS is as described for
795 `notmuch-call-notmuch-process'."
796
797   (let (stdin-string)
798     (while (keywordp (car args))
799       (case (car args)
800         (:stdin-string (setq stdin-string (cadr args)
801                              args (cddr args)))
802         (otherwise
803          (error "Unknown keyword argument: %s" (car args)))))
804     (if (null stdin-string)
805         (apply #'call-process notmuch-command nil destination nil args)
806       (insert stdin-string)
807       (apply #'call-process-region (point-min) (point-max)
808              notmuch-command t destination nil args))))
809
810 (defun notmuch-call-notmuch-process (&rest args)
811   "Synchronously invoke `notmuch-command' with ARGS.
812
813 The caller may provide keyword arguments before ARGS.  Currently
814 supported keyword arguments are:
815
816   :stdin-string STRING - Write STRING to stdin
817
818 If notmuch exits with a non-zero status, output from the process
819 will appear in a buffer named \"*Notmuch errors*\" and an error
820 will be signaled."
821   (with-temp-buffer
822     (let ((status (notmuch-call-notmuch--helper t args)))
823       (notmuch-check-exit-status status (cons notmuch-command args)
824                                  (buffer-string)))))
825
826 (defun notmuch-call-notmuch-sexp (&rest args)
827   "Invoke `notmuch-command' with ARGS and return the parsed S-exp output.
828
829 This is equivalent to `notmuch-call-notmuch-process', but parses
830 notmuch's output as an S-expression and returns the parsed value.
831 Like `notmuch-call-notmuch-process', if notmuch exits with a
832 non-zero status, this will report its output and signal an
833 error."
834
835   (with-temp-buffer
836     (let ((err-file (make-temp-file "nmerr")))
837       (unwind-protect
838           (let ((status (notmuch-call-notmuch--helper (list t err-file) args)))
839             (notmuch-check-exit-status status (cons notmuch-command args)
840                                        (buffer-string) err-file)
841             (goto-char (point-min))
842             (read (current-buffer)))
843         (delete-file err-file)))))
844
845 (defun notmuch-start-notmuch (name buffer sentinel &rest args)
846   "Start and return an asynchronous notmuch command.
847
848 This starts and returns an asynchronous process running
849 `notmuch-command' with ARGS.  The exit status is checked via
850 `notmuch-check-async-exit-status'.  Output written to stderr is
851 redirected and displayed when the process exits (even if the
852 process exits successfully).  NAME and BUFFER are the same as in
853 `start-process'.  SENTINEL is a process sentinel function to call
854 when the process exits, or nil for none.  The caller must *not*
855 invoke `set-process-sentinel' directly on the returned process,
856 as that will interfere with the handling of stderr and the exit
857 status."
858
859   ;; There is no way (as of Emacs 24.3) to capture stdout and stderr
860   ;; separately for asynchronous processes, or even to redirect stderr
861   ;; to a file, so we use a trivial shell wrapper to send stderr to a
862   ;; temporary file and clean things up in the sentinel.
863   (let* ((err-file (make-temp-file "nmerr"))
864          ;; Use a pipe
865          (process-connection-type nil)
866          ;; Find notmuch using Emacs' `exec-path'
867          (command (or (executable-find notmuch-command)
868                       (error "command not found: %s" notmuch-command)))
869          (proc (apply #'start-process name buffer
870                       "/bin/sh" "-c"
871                       "exec 2>\"$1\"; shift; exec \"$0\" \"$@\""
872                       command err-file args)))
873     (process-put proc 'err-file err-file)
874     (process-put proc 'sub-sentinel sentinel)
875     (process-put proc 'real-command (cons notmuch-command args))
876     (set-process-sentinel proc #'notmuch-start-notmuch-sentinel)
877     proc))
878
879 (defun notmuch-start-notmuch-sentinel (proc event)
880   (let ((err-file (process-get proc 'err-file))
881         (sub-sentinel (process-get proc 'sub-sentinel))
882         (real-command (process-get proc 'real-command)))
883     (condition-case err
884         (progn
885           ;; Invoke the sub-sentinel, if any
886           (when sub-sentinel
887             (funcall sub-sentinel proc event))
888           ;; Check the exit status.  This will signal an error if the
889           ;; exit status is non-zero.  Don't do this if the process
890           ;; buffer is dead since that means Emacs killed the process
891           ;; and there's no point in telling the user that (but we
892           ;; still check for and report stderr output below).
893           (when (buffer-live-p (process-buffer proc))
894             (notmuch-check-async-exit-status proc event real-command err-file))
895           ;; If that didn't signal an error, then any error output was
896           ;; really warning output.  Show warnings, if any.
897           (let ((warnings
898                  (with-temp-buffer
899                    (unless (= (second (insert-file-contents err-file)) 0)
900                      (end-of-line)
901                      ;; Show first line; stuff remaining lines in the
902                      ;; errors buffer.
903                      (let ((l1 (buffer-substring (point-min) (point))))
904                        (skip-chars-forward "\n")
905                        (cons l1 (unless (eobp)
906                                   (buffer-substring (point) (point-max)))))))))
907             (when warnings
908               (notmuch-logged-error (car warnings) (cdr warnings)))))
909       (error
910        ;; Emacs behaves strangely if an error escapes from a sentinel,
911        ;; so turn errors into messages.
912        (message "%s" (error-message-string err))))
913     (ignore-errors (delete-file err-file))))
914
915 ;; This variable is used only buffer local, but it needs to be
916 ;; declared globally first to avoid compiler warnings.
917 (defvar notmuch-show-process-crypto nil)
918 (make-variable-buffer-local 'notmuch-show-process-crypto)
919
920 (provide 'notmuch-lib)
921
922 ;; Local Variables:
923 ;; byte-compile-warnings: (not cl-functions)
924 ;; End: