4b8c66fdb2a1feefeacbee711acceef752f7c3a3
[notmuch] / emacs / notmuch-show.el
1 ;;; notmuch-show.el --- displaying notmuch forests.
2 ;;
3 ;; Copyright © Carl Worth
4 ;; Copyright © David Edmondson
5 ;;
6 ;; This file is part of Notmuch.
7 ;;
8 ;; Notmuch is free software: you can redistribute it and/or modify it
9 ;; under the terms of the GNU General Public License as published by
10 ;; the Free Software Foundation, either version 3 of the License, or
11 ;; (at your option) any later version.
12 ;;
13 ;; Notmuch is distributed in the hope that it will be useful, but
14 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
16 ;; General Public License for more details.
17 ;;
18 ;; You should have received a copy of the GNU General Public License
19 ;; along with Notmuch.  If not, see <http://www.gnu.org/licenses/>.
20 ;;
21 ;; Authors: Carl Worth <cworth@cworth.org>
22 ;;          David Edmondson <dme@dme.org>
23
24 ;;; Code:
25
26 (eval-when-compile (require 'cl))
27 (require 'mm-view)
28 (require 'message)
29 (require 'mm-decode)
30 (require 'mailcap)
31 (require 'icalendar)
32 (require 'goto-addr)
33
34 (require 'notmuch-lib)
35 (require 'notmuch-tag)
36 (require 'notmuch-query)
37 (require 'notmuch-wash)
38 (require 'notmuch-mua)
39 (require 'notmuch-crypto)
40 (require 'notmuch-print)
41
42 (declare-function notmuch-call-notmuch-process "notmuch" (&rest args))
43 (declare-function notmuch-search-next-thread "notmuch" nil)
44 (declare-function notmuch-search-previous-thread "notmuch" nil)
45 (declare-function notmuch-search-show-thread "notmuch" nil)
46 (declare-function notmuch-foreach-mime-part "notmuch" (function mm-handle))
47 (declare-function notmuch-count-attachments "notmuch" (mm-handle))
48 (declare-function notmuch-save-attachments "notmuch" (mm-handle &optional queryp))
49 (declare-function notmuch-tree "notmuch-tree"
50                   (&optional query query-context target buffer-name open-target))
51 (declare-function notmuch-tree-get-message-properties "notmuch-tree" nil)
52 (declare-function notmuch-read-query "notmuch" (prompt))
53
54 (defcustom notmuch-message-headers '("Subject" "To" "Cc" "Date")
55   "Headers that should be shown in a message, in this order.
56
57 For an open message, all of these headers will be made visible
58 according to `notmuch-message-headers-visible' or can be toggled
59 with `notmuch-show-toggle-visibility-headers'. For a closed message,
60 only the first header in the list will be visible."
61   :type '(repeat string)
62   :group 'notmuch-show)
63
64 (defcustom notmuch-message-headers-visible t
65   "Should the headers be visible by default?
66
67 If this value is non-nil, then all of the headers defined in
68 `notmuch-message-headers' will be visible by default in the display
69 of each message. Otherwise, these headers will be hidden and
70 `notmuch-show-toggle-visibility-headers' can be used to make them
71 visible for any given message."
72   :type 'boolean
73   :group 'notmuch-show)
74
75 (defcustom notmuch-show-relative-dates t
76   "Display relative dates in the message summary line."
77   :type 'boolean
78   :group 'notmuch-show)
79
80 (defvar notmuch-show-markup-headers-hook '(notmuch-show-colour-headers)
81   "A list of functions called to decorate the headers listed in
82 `notmuch-message-headers'.")
83
84 (defcustom notmuch-show-hook '(notmuch-show-turn-on-visual-line-mode)
85   "Functions called after populating a `notmuch-show' buffer."
86   :type 'hook
87   :options '(notmuch-show-turn-on-visual-line-mode)
88   :group 'notmuch-show
89   :group 'notmuch-hooks)
90
91 (defcustom notmuch-show-insert-text/plain-hook '(notmuch-wash-wrap-long-lines
92                                                  notmuch-wash-tidy-citations
93                                                  notmuch-wash-elide-blank-lines
94                                                  notmuch-wash-excerpt-citations)
95   "Functions used to improve the display of text/plain parts."
96   :type 'hook
97   :options '(notmuch-wash-convert-inline-patch-to-part
98              notmuch-wash-wrap-long-lines
99              notmuch-wash-tidy-citations
100              notmuch-wash-elide-blank-lines
101              notmuch-wash-excerpt-citations)
102   :group 'notmuch-show
103   :group 'notmuch-hooks)
104
105 (defcustom notmuch-show-max-text-part-size 100000
106   "Maximum size of a text part to be shown by default in characters.
107
108 Set to 0 to show the part regardless of size."
109   :type 'integer
110   :group 'notmuch-show)
111
112 ;; Mostly useful for debugging.
113 (defcustom notmuch-show-all-multipart/alternative-parts nil
114   "Should all parts of multipart/alternative parts be shown?"
115   :type 'boolean
116   :group 'notmuch-show)
117
118 (defcustom notmuch-show-indent-messages-width 1
119   "Width of message indentation in threads.
120
121 Messages are shown indented according to their depth in a thread.
122 This variable determines the width of this indentation measured
123 in number of blanks.  Defaults to `1', choose `0' to disable
124 indentation."
125   :type 'integer
126   :group 'notmuch-show)
127
128 (defcustom notmuch-show-indent-multipart nil
129   "Should the sub-parts of a multipart/* part be indented?"
130   ;; dme: Not sure which is a good default.
131   :type 'boolean
132   :group 'notmuch-show)
133
134 (defcustom notmuch-show-part-button-default-action 'notmuch-show-save-part
135   "Default part header button action (on ENTER or mouse click)."
136   :group 'notmuch-show
137   :type '(choice (const :tag "Save part"
138                         notmuch-show-save-part)
139                  (const :tag "View part"
140                         notmuch-show-view-part)
141                  (const :tag "View interactively"
142                         notmuch-show-interactively-view-part)))
143
144 (defcustom notmuch-show-only-matching-messages nil
145   "Only matching messages are shown by default."
146   :type 'boolean
147   :group 'notmuch-show)
148
149 ;; By default, block all external images to prevent privacy leaks and
150 ;; potential attacks.
151 (defcustom notmuch-show-text/html-blocked-images "."
152   "Remote images that have URLs matching this regexp will be blocked."
153   :type '(choice (const nil) regexp)
154   :group 'notmuch-show)
155
156 (defvar notmuch-show-thread-id nil)
157 (make-variable-buffer-local 'notmuch-show-thread-id)
158
159 (defvar notmuch-show-parent-buffer nil)
160 (make-variable-buffer-local 'notmuch-show-parent-buffer)
161
162 (defvar notmuch-show-query-context nil)
163 (make-variable-buffer-local 'notmuch-show-query-context)
164
165 (defvar notmuch-show-process-crypto nil)
166 (make-variable-buffer-local 'notmuch-show-process-crypto)
167
168 (defvar notmuch-show-elide-non-matching-messages nil)
169 (make-variable-buffer-local 'notmuch-show-elide-non-matching-messages)
170
171 (defvar notmuch-show-indent-content t)
172 (make-variable-buffer-local 'notmuch-show-indent-content)
173
174 (defvar notmuch-show-attachment-debug nil
175   "If t log stdout and stderr from attachment handlers
176
177 When set to nil (the default) stdout and stderr from attachment
178 handlers is discarded. When set to t the stdout and stderr from
179 each attachment handler is logged in buffers with names beginning
180 \" *notmuch-part*\". This option requires emacs version at least
181 24.3 to work.")
182
183 (defcustom notmuch-show-stash-mlarchive-link-alist
184   '(("Gmane" . "http://mid.gmane.org/")
185     ("MARC" . "http://marc.info/?i=")
186     ("Mail Archive, The" . "http://mid.mail-archive.com/")
187     ("LKML" . "http://lkml.kernel.org/r/")
188     ;; FIXME: can these services be searched by `Message-Id' ?
189     ;; ("MarkMail" . "http://markmail.org/")
190     ;; ("Nabble" . "http://nabble.com/")
191     ;; ("opensubscriber" . "http://opensubscriber.com/")
192     )
193   "List of Mailing List Archives to use when stashing links.
194
195 This list is used for generating a Mailing List Archive reference
196 URI with the current message's Message-Id in
197 `notmuch-show-stash-mlarchive-link'.
198
199 If the cdr of the alist element is not a function, the cdr is
200 expected to contain a URI that is concatenated with the current
201 message's Message-Id to create a ML archive reference URI.
202
203 If the cdr is a function, the function is called with the
204 Message-Id as the argument, and the function is expected to
205 return the ML archive reference URI."
206   :type '(alist :key-type (string :tag "Name")
207                 :value-type (choice
208                              (string :tag "URL")
209                              (function :tag "Function returning the URL")))
210   :group 'notmuch-show)
211
212 (defcustom notmuch-show-stash-mlarchive-link-default "Gmane"
213   "Default Mailing List Archive to use when stashing links.
214
215 This is used when `notmuch-show-stash-mlarchive-link' isn't
216 provided with an MLA argument nor `completing-read' input."
217   :type `(choice
218           ,@(mapcar
219              (lambda (mla)
220                (list 'const :tag (car mla) :value (car mla)))
221              notmuch-show-stash-mlarchive-link-alist))
222   :group 'notmuch-show)
223
224 (defcustom notmuch-show-mark-read-tags '("-unread")
225   "List of tag changes to apply to a message when it is marked as read.
226
227 Tags starting with \"+\" (or not starting with either \"+\" or
228 \"-\") in the list will be added, and tags starting with \"-\"
229 will be removed from the message being marked as read.
230
231 For example, if you wanted to remove an \"unread\" tag and add a
232 \"read\" tag (which would make little sense), you would set:
233     (\"-unread\" \"+read\")"
234   :type '(repeat string)
235   :group 'notmuch-show)
236
237 (defcustom notmuch-show-mark-read-function #'notmuch-show-seen-current-message
238   "Function to control which messages are marked read.
239
240 The function should take two arguments START and END which will
241 be the start and end of the visible portion of the buffer and
242 should mark the appropriate messages read by applying
243 `notmuch-show-mark-read'. This function will be called after
244 every user interaction with notmuch."
245   :type 'function
246   :group 'notmuch-show)
247
248 (defmacro with-current-notmuch-show-message (&rest body)
249   "Evaluate body with current buffer set to the text of current message"
250   `(save-excursion
251      (let ((id (notmuch-show-get-message-id)))
252        (let ((buf (generate-new-buffer (concat "*notmuch-msg-" id "*"))))
253          (with-current-buffer buf
254            (let ((coding-system-for-read 'no-conversion))
255              (call-process notmuch-command nil t nil "show" "--format=raw" id))
256            ,@body)
257          (kill-buffer buf)))))
258
259 (defun notmuch-show-turn-on-visual-line-mode ()
260   "Enable Visual Line mode."
261   (visual-line-mode t))
262
263 ;; DEPRECATED in Notmuch 0.16 since we now have convenient part
264 ;; commands.  We'll keep the command around for a version or two in
265 ;; case people want to bind it themselves.
266 (defun notmuch-show-view-all-mime-parts ()
267   "Use external viewers to view all attachments from the current message."
268   (interactive)
269   (with-current-notmuch-show-message
270    ;; We override the mm-inline-media-tests to indicate which message
271    ;; parts are already sufficiently handled by the original
272    ;; presentation of the message in notmuch-show mode. These parts
273    ;; will be inserted directly into the temporary buffer of
274    ;; with-current-notmuch-show-message and silently discarded.
275    ;;
276    ;; Any MIME part not explicitly mentioned here will be handled by an
277    ;; external viewer as configured in the various mailcap files.
278    (let ((mm-inline-media-tests '(
279                                   ("text/.*" ignore identity)
280                                   ("application/pgp-signature" ignore identity)
281                                   ("multipart/alternative" ignore identity)
282                                   ("multipart/mixed" ignore identity)
283                                   ("multipart/related" ignore identity)
284                                  )))
285      (mm-display-parts (mm-dissect-buffer)))))
286
287 (defun notmuch-show-save-attachments ()
288   "Save all attachments from the current message."
289   (interactive)
290   (with-current-notmuch-show-message
291    (let ((mm-handle (mm-dissect-buffer)))
292      (notmuch-save-attachments
293       mm-handle (> (notmuch-count-attachments mm-handle) 1))))
294   (message "Done"))
295
296 (defun notmuch-show-with-message-as-text (fn)
297   "Apply FN to a text representation of the current message.
298
299 FN is called with one argument, the message properties. It should
300 operation on the contents of the current buffer."
301
302   ;; Remake the header to ensure that all information is available.
303   (let* ((to (notmuch-show-get-to))
304          (cc (notmuch-show-get-cc))
305          (from (notmuch-show-get-from))
306          (subject (notmuch-show-get-subject))
307          (date (notmuch-show-get-date))
308          (tags (notmuch-show-get-tags))
309          (depth (notmuch-show-get-depth))
310
311          (header (concat
312                   "Subject: " subject "\n"
313                   "To: " to "\n"
314                   (if (not (string= cc ""))
315                       (concat "Cc: " cc "\n")
316                     "")
317                   "From: " from "\n"
318                   "Date: " date "\n"
319                   (if tags
320                       (concat "Tags: "
321                               (mapconcat #'identity tags ", ") "\n")
322                     "")))
323          (all (buffer-substring (notmuch-show-message-top)
324                                 (notmuch-show-message-bottom)))
325
326          (props (notmuch-show-get-message-properties))
327          (indenting notmuch-show-indent-content))
328     (with-temp-buffer
329       (insert all)
330       (if indenting
331           (indent-rigidly (point-min) (point-max) (- depth)))
332       ;; Remove the original header.
333       (goto-char (point-min))
334       (re-search-forward "^$" (point-max) nil)
335       (delete-region (point-min) (point))
336       (insert header)
337       (funcall fn props))))
338
339 (defun notmuch-show-print-message ()
340   "Print the current message."
341   (interactive)
342   (notmuch-show-with-message-as-text 'notmuch-print-message))
343
344 (defun notmuch-show-fontify-header ()
345   (let ((face (cond
346                ((looking-at "[Tt]o:")
347                 'message-header-to)
348                ((looking-at "[Bb]?[Cc][Cc]:")
349                 'message-header-cc)
350                ((looking-at "[Ss]ubject:")
351                 'message-header-subject)
352                (t
353                 'message-header-other))))
354
355     (overlay-put (make-overlay (point) (re-search-forward ":"))
356                  'face 'message-header-name)
357     (overlay-put (make-overlay (point) (re-search-forward ".*$"))
358                  'face face)))
359
360 (defun notmuch-show-colour-headers ()
361   "Apply some colouring to the current headers."
362   (goto-char (point-min))
363   (while (looking-at "^[A-Za-z][-A-Za-z0-9]*:")
364     (notmuch-show-fontify-header)
365     (forward-line)))
366
367 (defun notmuch-show-spaces-n (n)
368   "Return a string comprised of `n' spaces."
369   (make-string n ? ))
370
371 (defun notmuch-show-update-tags (tags)
372   "Update the displayed tags of the current message."
373   (save-excursion
374     (goto-char (notmuch-show-message-top))
375     (if (re-search-forward "(\\([^()]*\\))$" (line-end-position) t)
376         (let ((inhibit-read-only t))
377           (replace-match (concat "("
378                                  (notmuch-tag-format-tags tags (notmuch-show-get-prop :orig-tags))
379                                  ")"))))))
380
381 (defun notmuch-clean-address (address)
382   "Try to clean a single email ADDRESS for display. Return a cons
383 cell of (AUTHOR_EMAIL AUTHOR_NAME). Return (ADDRESS nil) if
384 parsing fails."
385   (condition-case nil
386     (let (p-name p-address)
387       ;; It would be convenient to use `mail-header-parse-address',
388       ;; but that expects un-decoded mailbox parts, whereas our
389       ;; mailbox parts are already decoded (and hence may contain
390       ;; UTF-8). Given that notmuch should handle most of the awkward
391       ;; cases, some simple string deconstruction should be sufficient
392       ;; here.
393       (cond
394        ;; "User <user@dom.ain>" style.
395        ((string-match "\\(.*\\) <\\(.*\\)>" address)
396         (setq p-name (match-string 1 address)
397               p-address (match-string 2 address)))
398
399        ;; "<user@dom.ain>" style.
400        ((string-match "<\\(.*\\)>" address)
401         (setq p-address (match-string 1 address)))
402
403        ;; Everything else.
404        (t
405         (setq p-address address)))
406
407       (when p-name
408         ;; Remove elements of the mailbox part that are not relevant for
409         ;; display, even if they are required during transport:
410         ;;
411         ;; Backslashes.
412         (setq p-name (replace-regexp-in-string "\\\\" "" p-name))
413
414         ;; Outer single and double quotes, which might be nested.
415         (loop
416          with start-of-loop
417          do (setq start-of-loop p-name)
418
419          when (string-match "^\"\\(.*\\)\"$" p-name)
420          do (setq p-name (match-string 1 p-name))
421
422          when (string-match "^'\\(.*\\)'$" p-name)
423          do (setq p-name (match-string 1 p-name))
424
425          until (string= start-of-loop p-name)))
426
427       ;; If the address is 'foo@bar.com <foo@bar.com>' then show just
428       ;; 'foo@bar.com'.
429       (when (string= p-name p-address)
430         (setq p-name nil))
431
432       (cons p-address p-name))
433     (error (cons address nil))))
434
435 (defun notmuch-show-clean-address (address)
436   "Try to clean a single email ADDRESS for display.  Return
437 unchanged ADDRESS if parsing fails."
438   (let* ((clean-address (notmuch-clean-address address))
439          (p-address (car clean-address))
440          (p-name (cdr clean-address)))
441     ;; If no name, return just the address.
442     (if (not p-name)
443         p-address
444       ;; Otherwise format the name and address together.
445       (concat p-name " <" p-address ">"))))
446
447 (defun notmuch-show-insert-headerline (headers date tags depth)
448   "Insert a notmuch style headerline based on HEADERS for a
449 message at DEPTH in the current thread."
450   (let ((start (point)))
451     (insert (notmuch-show-spaces-n (* notmuch-show-indent-messages-width depth))
452             (notmuch-sanitize
453              (notmuch-show-clean-address (plist-get headers :From)))
454             " ("
455             date
456             ") ("
457             (notmuch-tag-format-tags tags tags)
458             ")\n")
459     (overlay-put (make-overlay start (point)) 'face 'notmuch-message-summary-face)))
460
461 (defun notmuch-show-insert-header (header header-value)
462   "Insert a single header."
463   (insert header ": " (notmuch-sanitize header-value) "\n"))
464
465 (defun notmuch-show-insert-headers (headers)
466   "Insert the headers of the current message."
467   (let ((start (point)))
468     (mapc (lambda (header)
469             (let* ((header-symbol (intern (concat ":" header)))
470                    (header-value (plist-get headers header-symbol)))
471               (if (and header-value
472                        (not (string-equal "" header-value)))
473                   (notmuch-show-insert-header header header-value))))
474           notmuch-message-headers)
475     (save-excursion
476       (save-restriction
477         (narrow-to-region start (point-max))
478         (run-hooks 'notmuch-show-markup-headers-hook)))))
479
480 (define-button-type 'notmuch-show-part-button-type
481   'action 'notmuch-show-part-button-default
482   'follow-link t
483   'face 'message-mml
484   :supertype 'notmuch-button-type)
485
486 (defun notmuch-show-insert-part-header (nth content-type declared-type &optional name comment)
487   (let ((button)
488         (base-label (concat (when name (concat name ": "))
489                             declared-type
490                             (unless (string-equal declared-type content-type)
491                               (concat " (as " content-type ")"))
492                             comment)))
493
494     (setq button
495           (insert-button
496            (concat "[ " base-label " ]")
497            :base-label base-label
498            :type 'notmuch-show-part-button-type
499            :notmuch-part-hidden nil))
500     (insert "\n")
501     ;; return button
502     button))
503
504 (defun notmuch-show-toggle-part-invisibility (&optional button)
505   (interactive)
506   (let ((button (or button (button-at (point)))))
507     (when button
508       (let ((overlay (button-get button 'overlay))
509             (lazy-part (button-get button :notmuch-lazy-part)))
510         ;; We have a part to toggle if there is an overlay or if there is a lazy part.
511         ;; If neither is present we cannot toggle the part so we just return nil.
512         (when (or overlay lazy-part)
513           (let* ((show (button-get button :notmuch-part-hidden))
514                  (new-start (button-start button))
515                  (button-label (button-get button :base-label))
516                  (old-point (point))
517                  (properties (text-properties-at (button-start button)))
518                  (inhibit-read-only t))
519             ;; Toggle the button itself.
520             (button-put button :notmuch-part-hidden (not show))
521             (goto-char new-start)
522             (insert "[ " button-label (if show " ]" " (hidden) ]"))
523             (set-text-properties new-start (point) properties)
524             (let ((old-end (button-end button)))
525               (move-overlay button new-start (point))
526               (delete-region (point) old-end))
527             (goto-char (min old-point (1- (button-end button))))
528             ;; Return nil if there is a lazy-part, it is empty, and we are
529             ;; trying to show it.  In all other cases return t.
530             (if lazy-part
531                 (when show
532                   (button-put button :notmuch-lazy-part nil)
533                   (notmuch-show-lazy-part lazy-part button))
534               ;; else there must be an overlay.
535               (overlay-put overlay 'invisible (not show))
536               t)))))))
537
538 ;; Part content ID handling
539
540 (defvar notmuch-show--cids nil
541   "Alist from raw content ID to (MSG PART).")
542 (make-variable-buffer-local 'notmuch-show--cids)
543
544 (defun notmuch-show--register-cids (msg part)
545   "Register content-IDs in PART and all of PART's sub-parts."
546   (let ((content-id (plist-get part :content-id)))
547     (when content-id
548       ;; Note that content-IDs are globally unique, except when they
549       ;; aren't: RFC 2046 section 5.1.4 permits children of a
550       ;; multipart/alternative to have the same content-ID, in which
551       ;; case the MUA is supposed to pick the best one it can render.
552       ;; We simply add the content-ID to the beginning of our alist;
553       ;; so if this happens, we'll take the last (and "best")
554       ;; alternative (even if we can't render it).
555       (push (list content-id msg part) notmuch-show--cids)))
556   ;; Recurse on sub-parts
557   (let ((ctype (notmuch-split-content-type
558                 (downcase (plist-get part :content-type)))))
559     (cond ((equal (first ctype) "multipart")
560            (mapc (apply-partially #'notmuch-show--register-cids msg)
561                  (plist-get part :content)))
562           ((equal ctype '("message" "rfc822"))
563            (notmuch-show--register-cids
564             msg
565             (first (plist-get (first (plist-get part :content)) :body)))))))
566
567 (defun notmuch-show--get-cid-content (cid)
568   "Return a list (CID-content content-type) or nil.
569
570 This will only find parts from messages that have been inserted
571 into the current buffer.  CID must be a raw content ID, without
572 enclosing angle brackets, a cid: prefix, or URL encoding.  This
573 will return nil if the CID is unknown or cannot be retrieved."
574   (let ((descriptor (cdr (assoc cid notmuch-show--cids))))
575     (when descriptor
576       (let* ((msg (first descriptor))
577              (part (second descriptor))
578              ;; Request caching for this content, as some messages
579              ;; reference the same cid: part many times (hundreds!).
580              (content (notmuch-get-bodypart-binary
581                        msg part notmuch-show-process-crypto 'cache))
582              (content-type (plist-get part :content-type)))
583         (list content content-type)))))
584
585 (defun notmuch-show-setup-w3m ()
586   "Instruct w3m how to retrieve content from a \"related\" part of a message."
587   (interactive)
588   (if (boundp 'w3m-cid-retrieve-function-alist)
589     (unless (assq 'notmuch-show-mode w3m-cid-retrieve-function-alist)
590       (push (cons 'notmuch-show-mode #'notmuch-show--cid-w3m-retrieve)
591             w3m-cid-retrieve-function-alist)))
592   (setq mm-inline-text-html-with-images t))
593
594 (defvar w3m-current-buffer) ;; From `w3m.el'.
595 (defun notmuch-show--cid-w3m-retrieve (url &rest args)
596   ;; url includes the cid: prefix and is URL encoded (see RFC 2392).
597   (let* ((cid (url-unhex-string (substring url 4)))
598          (content-and-type
599           (with-current-buffer w3m-current-buffer
600             (notmuch-show--get-cid-content cid))))
601     (when content-and-type
602       (insert (first content-and-type))
603       (second content-and-type))))
604
605 ;; MIME part renderers
606
607 (defun notmuch-show-multipart/*-to-list (part)
608   (mapcar (lambda (inner-part) (plist-get inner-part :content-type))
609           (plist-get part :content)))
610
611 (defun notmuch-show-insert-part-multipart/alternative (msg part content-type nth depth button)
612   (let ((chosen-type (car (notmuch-multipart/alternative-choose msg (notmuch-show-multipart/*-to-list part))))
613         (inner-parts (plist-get part :content))
614         (start (point)))
615     ;; This inserts all parts of the chosen type rather than just one,
616     ;; but it's not clear that this is the wrong thing to do - which
617     ;; should be chosen if there are more than one that match?
618     (mapc (lambda (inner-part)
619             (let* ((inner-type (plist-get inner-part :content-type))
620                   (hide (not (or notmuch-show-all-multipart/alternative-parts
621                            (string= chosen-type inner-type)))))
622               (notmuch-show-insert-bodypart msg inner-part depth hide)))
623           inner-parts)
624
625     (when notmuch-show-indent-multipart
626       (indent-rigidly start (point) 1)))
627   t)
628
629 (defun notmuch-show-insert-part-multipart/related (msg part content-type nth depth button)
630   (let ((inner-parts (plist-get part :content))
631         (start (point)))
632
633     ;; Render the primary part.  FIXME: Support RFC 2387 Start header.
634     (notmuch-show-insert-bodypart msg (car inner-parts) depth)
635     ;; Add hidden buttons for the rest
636     (mapc (lambda (inner-part)
637             (notmuch-show-insert-bodypart msg inner-part depth t))
638           (cdr inner-parts))
639
640     (when notmuch-show-indent-multipart
641       (indent-rigidly start (point) 1)))
642   t)
643
644 (defun notmuch-show-insert-part-multipart/signed (msg part content-type nth depth button)
645   (when button
646     (button-put button 'face 'notmuch-crypto-part-header))
647
648   ;; Insert a button detailing the signature status.
649   (notmuch-crypto-insert-sigstatus-button (car (plist-get part :sigstatus))
650                                           (notmuch-show-get-header :From msg))
651
652   (let ((inner-parts (plist-get part :content))
653         (start (point)))
654     ;; Show all of the parts.
655     (mapc (lambda (inner-part)
656             (notmuch-show-insert-bodypart msg inner-part depth))
657           inner-parts)
658
659     (when notmuch-show-indent-multipart
660       (indent-rigidly start (point) 1)))
661   t)
662
663 (defun notmuch-show-insert-part-multipart/encrypted (msg part content-type nth depth button)
664   (when button
665     (button-put button 'face 'notmuch-crypto-part-header))
666
667   ;; Insert a button detailing the encryption status.
668   (notmuch-crypto-insert-encstatus-button (car (plist-get part :encstatus)))
669
670   ;; Insert a button detailing the signature status.
671   (notmuch-crypto-insert-sigstatus-button (car (plist-get part :sigstatus))
672                                           (notmuch-show-get-header :From msg))
673
674   (let ((inner-parts (plist-get part :content))
675         (start (point)))
676     ;; Show all of the parts.
677     (mapc (lambda (inner-part)
678             (notmuch-show-insert-bodypart msg inner-part depth))
679           inner-parts)
680
681     (when notmuch-show-indent-multipart
682       (indent-rigidly start (point) 1)))
683   t)
684
685 (defun notmuch-show-insert-part-multipart/* (msg part content-type nth depth button)
686   (let ((inner-parts (plist-get part :content))
687         (start (point)))
688     ;; Show all of the parts.
689     (mapc (lambda (inner-part)
690             (notmuch-show-insert-bodypart msg inner-part depth))
691           inner-parts)
692
693     (when notmuch-show-indent-multipart
694       (indent-rigidly start (point) 1)))
695   t)
696
697 (defun notmuch-show-insert-part-message/rfc822 (msg part content-type nth depth button)
698   (let* ((message (car (plist-get part :content)))
699          (body (car (plist-get message :body)))
700          (start (point)))
701
702     ;; Override `notmuch-message-headers' to force `From' to be
703     ;; displayed.
704     (let ((notmuch-message-headers '("From" "Subject" "To" "Cc" "Date")))
705       (notmuch-show-insert-headers (plist-get message :headers)))
706
707     ;; Blank line after headers to be compatible with the normal
708     ;; message display.
709     (insert "\n")
710
711     ;; Show the body
712     (notmuch-show-insert-bodypart msg body depth)
713
714     (when notmuch-show-indent-multipart
715       (indent-rigidly start (point) 1)))
716   t)
717
718 (defun notmuch-show-insert-part-text/plain (msg part content-type nth depth button)
719   ;; For backward compatibility we want to apply the text/plain hook
720   ;; to the whole of the part including the part button if there is
721   ;; one.
722   (let ((start (if button
723                    (button-start button)
724                  (point))))
725     (insert (notmuch-get-bodypart-text msg part notmuch-show-process-crypto))
726     (save-excursion
727       (save-restriction
728         (narrow-to-region start (point-max))
729         (run-hook-with-args 'notmuch-show-insert-text/plain-hook msg depth))))
730   t)
731
732 (defun notmuch-show-insert-part-text/calendar (msg part content-type nth depth button)
733   (insert (with-temp-buffer
734             (insert (notmuch-get-bodypart-text msg part notmuch-show-process-crypto))
735             ;; notmuch-get-bodypart-text does no newline conversion.
736             ;; Replace CRLF with LF before icalendar can use it.
737             (goto-char (point-min))
738             (while (re-search-forward "\r\n" nil t)
739               (replace-match "\n" nil nil))
740             (let ((file (make-temp-file "notmuch-ical"))
741                   result)
742               (unwind-protect
743                   (progn
744                     (unless (icalendar-import-buffer file t)
745                       (error "Icalendar import error. See *icalendar-errors* for more information"))
746                     (set-buffer (get-file-buffer file))
747                     (setq result (buffer-substring (point-min) (point-max)))
748                     (set-buffer-modified-p nil)
749                     (kill-buffer (current-buffer)))
750                 (delete-file file))
751               result)))
752   t)
753
754 ;; For backwards compatibility.
755 (defun notmuch-show-insert-part-text/x-vcalendar (msg part content-type nth depth button)
756   (notmuch-show-insert-part-text/calendar msg part content-type nth depth button))
757
758 (defun notmuch-show-get-mime-type-of-application/octet-stream (part)
759   ;; If we can deduce a MIME type from the filename of the attachment,
760   ;; we return that.
761   (if (plist-get part :filename)
762       (let ((extension (file-name-extension (plist-get part :filename)))
763             mime-type)
764         (if extension
765             (progn
766               (mailcap-parse-mimetypes)
767               (setq mime-type (mailcap-extension-to-mime extension))
768               (if (and mime-type
769                        (not (string-equal mime-type "application/octet-stream")))
770                   mime-type
771                 nil))
772           nil))))
773
774 (defun notmuch-show-insert-part-text/html (msg part content-type nth depth button)
775   (if (eq mm-text-html-renderer 'shr)
776       ;; It's easier to drive shr ourselves than to work around the
777       ;; goofy things `mm-shr' does (like irreversibly taking over
778       ;; content ID handling).
779
780       ;; FIXME: If we block an image, offer a button to load external
781       ;; images.
782       (let ((shr-blocked-images notmuch-show-text/html-blocked-images))
783         (notmuch-show--insert-part-text/html-shr msg part))
784     ;; Otherwise, let message-mode do the heavy lifting
785     ;;
786     ;; w3m sets up a keymap which "leaks" outside the invisible region
787     ;; and causes strange effects in notmuch. We set
788     ;; mm-inline-text-html-with-w3m-keymap to nil to tell w3m not to
789     ;; set a keymap (so the normal notmuch-show-mode-map remains).
790     (let ((mm-inline-text-html-with-w3m-keymap nil)
791           ;; FIXME: If we block an image, offer a button to load external
792           ;; images.
793           (gnus-blocked-images notmuch-show-text/html-blocked-images))
794       (notmuch-show-insert-part-*/* msg part content-type nth depth button))))
795
796 ;; These functions are used by notmuch-show--insert-part-text/html-shr
797 (declare-function libxml-parse-html-region "xml.c")
798 (declare-function shr-insert-document "shr")
799
800 (defun notmuch-show--insert-part-text/html-shr (msg part)
801   ;; Make sure shr is loaded before we start let-binding its globals
802   (require 'shr)
803   (let ((dom (let ((process-crypto notmuch-show-process-crypto))
804                (with-temp-buffer
805                  (insert (notmuch-get-bodypart-text msg part process-crypto))
806                  (libxml-parse-html-region (point-min) (point-max)))))
807         (shr-content-function
808          (lambda (url)
809            ;; shr strips the "cid:" part of URL, but doesn't
810            ;; URL-decode it (see RFC 2392).
811            (let ((cid (url-unhex-string url)))
812              (first (notmuch-show--get-cid-content cid))))))
813     (shr-insert-document dom)
814     t))
815
816 (defun notmuch-show-insert-part-*/* (msg part content-type nth depth button)
817   ;; This handler _must_ succeed - it is the handler of last resort.
818   (notmuch-mm-display-part-inline msg part content-type notmuch-show-process-crypto)
819   t)
820
821 ;; Functions for determining how to handle MIME parts.
822
823 (defun notmuch-show-handlers-for (content-type)
824   "Return a list of content handlers for a part of type CONTENT-TYPE."
825   (let (result)
826     (mapc (lambda (func)
827             (if (functionp func)
828                 (push func result)))
829           ;; Reverse order of prefrence.
830           (list (intern (concat "notmuch-show-insert-part-*/*"))
831                 (intern (concat
832                          "notmuch-show-insert-part-"
833                          (car (notmuch-split-content-type content-type))
834                          "/*"))
835                 (intern (concat "notmuch-show-insert-part-" content-type))))
836     result))
837
838 ;; \f
839
840 (defun notmuch-show-insert-bodypart-internal (msg part content-type nth depth button)
841   ;; Run the handlers until one of them succeeds.
842   (loop for handler in (notmuch-show-handlers-for content-type)
843         until (condition-case err
844                   (funcall handler msg part content-type nth depth button)
845                 ;; Specifying `debug' here lets the debugger run if
846                 ;; `debug-on-error' is non-nil.
847                 ((debug error)
848                  (insert "!!! Bodypart handler `" (prin1-to-string handler) "' threw an error:\n"
849                          "!!! " (error-message-string err) "\n")
850                  nil))))
851
852 (defun notmuch-show-create-part-overlays (button beg end)
853   "Add an overlay to the part between BEG and END"
854
855   ;; If there is no button (i.e., the part is text/plain and the first
856   ;; part) or if the part has no content then we don't make the part
857   ;; toggleable.
858   (when (and button (/= beg end))
859     (button-put button 'overlay (make-overlay beg end))
860     ;; Return true if we created an overlay.
861     t))
862
863 (defun notmuch-show-record-part-information (part beg end)
864   "Store PART as a text property from BEG to END"
865
866   ;; Record part information.  Since we already inserted subparts,
867   ;; don't override existing :notmuch-part properties.
868   (notmuch-map-text-property beg end :notmuch-part
869                              (lambda (v) (or v part)))
870   ;; Make :notmuch-part front sticky and rear non-sticky so it stays
871   ;; applied to the beginning of each line when we indent the
872   ;; message.  Since we're operating on arbitrary renderer output,
873   ;; watch out for sticky specs of t, which means all properties are
874   ;; front-sticky/rear-nonsticky.
875   (notmuch-map-text-property beg end 'front-sticky
876                              (lambda (v) (if (listp v)
877                                              (pushnew :notmuch-part v)
878                                            v)))
879   (notmuch-map-text-property beg end 'rear-nonsticky
880                              (lambda (v) (if (listp v)
881                                              (pushnew :notmuch-part v)
882                                            v))))
883
884 (defun notmuch-show-lazy-part (part-args button)
885   ;; Insert the lazy part after the button for the part. We would just
886   ;; move to the start of the new line following the button and insert
887   ;; the part but that point might have text properties (eg colours
888   ;; from a message header etc) so instead we start from the last
889   ;; character of the button by adding a newline and finish by
890   ;; removing the extra newline from the end of the part.
891   (save-excursion
892     (goto-char (button-end button))
893     (insert "\n")
894     (let* ((inhibit-read-only t)
895            ;; We need to use markers for the start and end of the part
896            ;; because the part insertion functions do not guarantee
897            ;; to leave point at the end of the part.
898            (part-beg (copy-marker (point) nil))
899            (part-end (copy-marker (point) t))
900            ;; We have to save the depth as we can't find the depth
901            ;; when narrowed.
902            (depth (notmuch-show-get-depth)))
903       (save-restriction
904         (narrow-to-region part-beg part-end)
905         (delete-region part-beg part-end)
906         (apply #'notmuch-show-insert-bodypart-internal part-args)
907         (indent-rigidly part-beg part-end depth))
908       (goto-char part-end)
909       (delete-char 1)
910       (notmuch-show-record-part-information (second part-args)
911                                             (button-start button)
912                                             part-end)
913       ;; Create the overlay. If the lazy-part turned out to be empty/not
914       ;; showable this returns nil.
915       (notmuch-show-create-part-overlays button part-beg part-end))))
916
917 (defun notmuch-show-mime-type (part)
918   "Return the correct mime-type to use for PART."
919   (let ((content-type (downcase (plist-get part :content-type))))
920     (or (and (string= content-type "application/octet-stream")
921              (notmuch-show-get-mime-type-of-application/octet-stream part))
922         (and (string= content-type "inline patch")
923              "text/x-diff")
924         content-type)))
925
926 ;; The following variable can be overridden by let bindings.
927 (defvar notmuch-show-insert-header-p-function 'notmuch-show-insert-header-p
928   "Specify which function decides which part headers get inserted.
929
930 The function should take two parameters, PART and HIDE, and
931 should return non-NIL if a header button should be inserted for
932 this part.")
933
934 (defun notmuch-show-insert-header-p (part hide)
935   ;; Show all part buttons except for the first part if it is text/plain.
936   (let ((mime-type (notmuch-show-mime-type part)))
937     (not (and (string= mime-type "text/plain")
938               (<= (plist-get part :id) 1)))))
939
940 (defun notmuch-show-reply-insert-header-p-never (part hide)
941   nil)
942
943 (defun notmuch-show-reply-insert-header-p-trimmed (part hide)
944   (let ((mime-type (notmuch-show-mime-type part)))
945     (and (not (notmuch-match-content-type mime-type "multipart/*"))
946          (not hide))))
947
948 (defun notmuch-show-reply-insert-header-p-minimal (part hide)
949   (let ((mime-type (notmuch-show-mime-type part)))
950     (and (notmuch-match-content-type mime-type "text/*")
951          (not hide))))
952
953 (defun notmuch-show-insert-bodypart (msg part depth &optional hide)
954   "Insert the body part PART at depth DEPTH in the current thread.
955
956 HIDE determines whether to show or hide the part and the button
957 as follows: If HIDE is nil, show the part and the button. If HIDE
958 is t, hide the part initially and show the button."
959
960   (let* ((content-type (downcase (plist-get part :content-type)))
961          (mime-type (notmuch-show-mime-type part))
962          (nth (plist-get part :id))
963          (long (and (notmuch-match-content-type mime-type "text/*")
964                     (> notmuch-show-max-text-part-size 0)
965                     (> (length (plist-get part :content)) notmuch-show-max-text-part-size)))
966          (beg (point))
967          ;; This default header-p function omits the part button for
968          ;; the first (or only) part if this is text/plain.
969          (button (when (funcall notmuch-show-insert-header-p-function part hide)
970                    (notmuch-show-insert-part-header nth mime-type content-type (plist-get part :filename))))
971          ;; Hide the part initially if HIDE is t, or if it is too long
972          ;; and we have a button to allow toggling.
973          (show-part (not (or (equal hide t)
974                              (and long button))))
975          (content-beg (point)))
976
977     ;; Store the computed mime-type for later use (e.g. by attachment handlers).
978     (plist-put part :computed-type mime-type)
979
980     (if show-part
981         (notmuch-show-insert-bodypart-internal msg part mime-type nth depth button)
982       (when button
983         (button-put button :notmuch-lazy-part
984                     (list msg part mime-type nth depth button))))
985
986     ;; Some of the body part handlers leave point somewhere up in the
987     ;; part, so we make sure that we're down at the end.
988     (goto-char (point-max))
989     ;; Ensure that the part ends with a carriage return.
990     (unless (bolp)
991       (insert "\n"))
992     ;; We do not create the overlay for hidden (lazy) parts until
993     ;; they are inserted.
994     (if show-part
995         (notmuch-show-create-part-overlays button content-beg (point))
996       (save-excursion
997         (notmuch-show-toggle-part-invisibility button)))
998     (notmuch-show-record-part-information part beg (point))))
999
1000 (defun notmuch-show-insert-body (msg body depth)
1001   "Insert the body BODY at depth DEPTH in the current thread."
1002
1003   ;; Register all content IDs for this message.  According to RFC
1004   ;; 2392, content IDs are *global*, but it's okay if an MUA treats
1005   ;; them as only global within a message.
1006   (notmuch-show--register-cids msg (first body))
1007
1008   (mapc (lambda (part) (notmuch-show-insert-bodypart msg part depth)) body))
1009
1010 (defun notmuch-show-make-symbol (type)
1011   (make-symbol (concat "notmuch-show-" type)))
1012
1013 (defun notmuch-show-strip-re (string)
1014   (replace-regexp-in-string "^\\([Rr]e: *\\)+" "" string))
1015
1016 (defvar notmuch-show-previous-subject "")
1017 (make-variable-buffer-local 'notmuch-show-previous-subject)
1018
1019 (defun notmuch-show-insert-msg (msg depth)
1020   "Insert the message MSG at depth DEPTH in the current thread."
1021   (let* ((headers (plist-get msg :headers))
1022          ;; Indentation causes the buffer offset of the start/end
1023          ;; points to move, so we must use markers.
1024          message-start message-end
1025          content-start content-end
1026          headers-start headers-end
1027          (bare-subject (notmuch-show-strip-re (plist-get headers :Subject))))
1028
1029     (setq message-start (point-marker))
1030
1031     (notmuch-show-insert-headerline headers
1032                                     (or (if notmuch-show-relative-dates
1033                                             (plist-get msg :date_relative)
1034                                           nil)
1035                                         (plist-get headers :Date))
1036                                     (plist-get msg :tags) depth)
1037
1038     (setq content-start (point-marker))
1039
1040     ;; Set `headers-start' to point after the 'Subject:' header to be
1041     ;; compatible with the existing implementation. This just sets it
1042     ;; to after the first header.
1043     (notmuch-show-insert-headers headers)
1044     (save-excursion
1045       (goto-char content-start)
1046       ;; If the subject of this message is the same as that of the
1047       ;; previous message, don't display it when this message is
1048       ;; collapsed.
1049       (when (not (string= notmuch-show-previous-subject
1050                           bare-subject))
1051         (forward-line 1))
1052       (setq headers-start (point-marker)))
1053     (setq headers-end (point-marker))
1054
1055     (setq notmuch-show-previous-subject bare-subject)
1056
1057     ;; A blank line between the headers and the body.
1058     (insert "\n")
1059     (notmuch-show-insert-body msg (plist-get msg :body)
1060                               (if notmuch-show-indent-content depth 0))
1061     ;; Ensure that the body ends with a newline.
1062     (unless (bolp)
1063       (insert "\n"))
1064     (setq content-end (point-marker))
1065
1066     ;; Indent according to the depth in the thread.
1067     (if notmuch-show-indent-content
1068         (indent-rigidly content-start content-end (* notmuch-show-indent-messages-width depth)))
1069
1070     (setq message-end (point-max-marker))
1071
1072     ;; Save the extents of this message over the whole text of the
1073     ;; message.
1074     (put-text-property message-start message-end :notmuch-message-extent (cons message-start message-end))
1075
1076     ;; Create overlays used to control visibility
1077     (plist-put msg :headers-overlay (make-overlay headers-start headers-end))
1078     (plist-put msg :message-overlay (make-overlay headers-start content-end))
1079
1080     (plist-put msg :depth depth)
1081
1082     ;; Save the properties for this message. Currently this saves the
1083     ;; entire message (augmented it with other stuff), which seems
1084     ;; like overkill. We might save a reduced subset (for example, not
1085     ;; the content).
1086     (notmuch-show-set-message-properties msg)
1087
1088     ;; Set header visibility.
1089     (notmuch-show-headers-visible msg notmuch-message-headers-visible)
1090
1091     ;; Message visibility depends on whether it matched the search
1092     ;; criteria.
1093     (notmuch-show-message-visible msg (and (plist-get msg :match)
1094                                            (not (plist-get msg :excluded))))))
1095
1096 (defun notmuch-show-toggle-process-crypto ()
1097   "Toggle the processing of cryptographic MIME parts."
1098   (interactive)
1099   (setq notmuch-show-process-crypto (not notmuch-show-process-crypto))
1100   (message (if notmuch-show-process-crypto
1101                "Processing cryptographic MIME parts."
1102              "Not processing cryptographic MIME parts."))
1103   (notmuch-show-refresh-view))
1104
1105 (defun notmuch-show-toggle-elide-non-matching ()
1106   "Toggle the display of non-matching messages."
1107   (interactive)
1108   (setq notmuch-show-elide-non-matching-messages (not notmuch-show-elide-non-matching-messages))
1109   (message (if notmuch-show-elide-non-matching-messages
1110                "Showing matching messages only."
1111              "Showing all messages."))
1112   (notmuch-show-refresh-view))
1113
1114 (defun notmuch-show-toggle-thread-indentation ()
1115   "Toggle the indentation of threads."
1116   (interactive)
1117   (setq notmuch-show-indent-content (not notmuch-show-indent-content))
1118   (message (if notmuch-show-indent-content
1119                "Content is indented."
1120              "Content is not indented."))
1121   (notmuch-show-refresh-view))
1122
1123 (defun notmuch-show-insert-tree (tree depth)
1124   "Insert the message tree TREE at depth DEPTH in the current thread."
1125   (let ((msg (car tree))
1126         (replies (cadr tree)))
1127     ;; We test whether there is a message or just some replies.
1128     (when msg
1129       (notmuch-show-insert-msg msg depth))
1130     (notmuch-show-insert-thread replies (1+ depth))))
1131
1132 (defun notmuch-show-insert-thread (thread depth)
1133   "Insert the thread THREAD at depth DEPTH in the current forest."
1134   (mapc (lambda (tree) (notmuch-show-insert-tree tree depth)) thread))
1135
1136 (defun notmuch-show-insert-forest (forest)
1137   "Insert the forest of threads FOREST."
1138   (mapc (lambda (thread) (notmuch-show-insert-thread thread 0)) forest))
1139
1140 (defvar notmuch-id-regexp
1141   (concat
1142    ;; Match the id: prefix only if it begins a word (to disallow, for
1143    ;; example, matching cid:).
1144    "\\<id:\\("
1145    ;; If the term starts with a ", then parse Xapian's quoted boolean
1146    ;; term syntax, which allows for anything as long as embedded
1147    ;; double quotes escaped by doubling them.  We also disallow
1148    ;; newlines (which Xapian allows) to prevent runaway terms.
1149    "\"\\([^\"\n]\\|\"\"\\)*\""
1150    ;; Otherwise, parse Xapian's unquoted syntax, which goes up to the
1151    ;; next space or ).  We disallow [.,;] as the last character
1152    ;; because these are probably part of the surrounding text, and not
1153    ;; part of the id.  This doesn't match single character ids; meh.
1154    "\\|[^\"[:space:])][^[:space:])]*[^])[:space:].,:;?!]"
1155    "\\)")
1156   "The regexp used to match id: links in messages.")
1157
1158 (defvar notmuch-mid-regexp
1159   ;; goto-address-url-regexp matched cid: links, which have the same
1160   ;; grammar as the message ID part of a mid: link.  Construct the
1161   ;; regexp using the same technique as goto-address-url-regexp.
1162   (concat "\\<mid:\\(" thing-at-point-url-path-regexp "\\)")
1163   "The regexp used to match mid: links in messages.
1164
1165 See RFC 2392.")
1166
1167 (defun notmuch-show-buttonise-links (start end)
1168   "Buttonise URLs and mail addresses between START and END.
1169
1170 This also turns id:\"<message id>\"-parts and mid: links into
1171 buttons for a corresponding notmuch search."
1172   (goto-address-fontify-region start end)
1173   (save-excursion
1174     (let (links)
1175       (goto-char start)
1176       (while (re-search-forward notmuch-id-regexp end t)
1177         (push (list (match-beginning 0) (match-end 0)
1178                     (match-string-no-properties 0)) links))
1179       (goto-char start)
1180       (while (re-search-forward notmuch-mid-regexp end t)
1181         (let* ((mid-cid (match-string-no-properties 1))
1182                (mid (save-match-data
1183                       (string-match "^[^/]*" mid-cid)
1184                       (url-unhex-string (match-string 0 mid-cid)))))
1185           (push (list (match-beginning 0) (match-end 0)
1186                       (notmuch-id-to-query mid)) links)))
1187       (dolist (link links)
1188         ;; Remove the overlay created by goto-address-mode
1189         (remove-overlays (first link) (second link) 'goto-address t)
1190         (make-text-button (first link) (second link)
1191                           :type 'notmuch-button-type
1192                           'action `(lambda (arg)
1193                                      (notmuch-show ,(third link) current-prefix-arg))
1194                           'follow-link t
1195                           'help-echo "Mouse-1, RET: search for this message"
1196                           'face goto-address-mail-face)))))
1197
1198 ;;;###autoload
1199 (defun notmuch-show (thread-id &optional elide-toggle parent-buffer query-context buffer-name)
1200   "Run \"notmuch show\" with the given thread ID and display results.
1201
1202 ELIDE-TOGGLE, if non-nil, inverts the default elide behavior.
1203
1204 The optional PARENT-BUFFER is the notmuch-search buffer from
1205 which this notmuch-show command was executed, (so that the
1206 next thread from that buffer can be show when done with this
1207 one).
1208
1209 The optional QUERY-CONTEXT is a notmuch search term. Only
1210 messages from the thread matching this search term are shown if
1211 non-nil.
1212
1213 The optional BUFFER-NAME provides the name of the buffer in
1214 which the message thread is shown. If it is nil (which occurs
1215 when the command is called interactively) the argument to the
1216 function is used.
1217
1218 Returns the buffer containing the messages, or NIL if no messages
1219 matched."
1220   (interactive "sNotmuch show: \nP")
1221   (let ((buffer-name (generate-new-buffer-name
1222                       (or buffer-name
1223                           (concat "*notmuch-" thread-id "*")))))
1224     (switch-to-buffer (get-buffer-create buffer-name))
1225     ;; No need to track undo information for this buffer.
1226     (setq buffer-undo-list t)
1227
1228     (notmuch-show-mode)
1229
1230     ;; Set various buffer local variables to their appropriate initial
1231     ;; state. Do this after enabling `notmuch-show-mode' so that they
1232     ;; aren't wiped out.
1233     (setq notmuch-show-thread-id thread-id
1234           notmuch-show-parent-buffer parent-buffer
1235           notmuch-show-query-context query-context
1236
1237           notmuch-show-process-crypto notmuch-crypto-process-mime
1238           ;; If `elide-toggle', invert the default value.
1239           notmuch-show-elide-non-matching-messages
1240           (if elide-toggle
1241               (not notmuch-show-only-matching-messages)
1242             notmuch-show-only-matching-messages))
1243
1244     (add-hook 'post-command-hook #'notmuch-show-command-hook nil t)
1245     (jit-lock-register #'notmuch-show-buttonise-links)
1246
1247     (notmuch-tag-clear-cache)
1248
1249     (let ((inhibit-read-only t))
1250       (if (notmuch-show--build-buffer)
1251           ;; Messages were inserted into the buffer.
1252           (current-buffer)
1253
1254         ;; No messages were inserted - presumably none matched the
1255         ;; query.
1256         (kill-buffer (current-buffer))
1257         (ding)
1258         (message "No messages matched the query!")
1259         nil))))
1260
1261 (defun notmuch-show--build-buffer (&optional state)
1262   "Display messages matching the current buffer context.
1263
1264 Apply the previously saved STATE if supplied, otherwise show the
1265 first relevant message.
1266
1267 If no messages match the query return NIL."
1268   (let* ((basic-args (list notmuch-show-thread-id))
1269          (args (if notmuch-show-query-context
1270                    (append (list "\'") basic-args
1271                            (list "and (" notmuch-show-query-context ")\'"))
1272                  (append (list "\'") basic-args (list "\'"))))
1273          (cli-args (cons "--exclude=false"
1274                          (when notmuch-show-elide-non-matching-messages
1275                            (list "--entire-thread=false"))))
1276
1277          (forest (or (notmuch-query-get-threads (append cli-args args))
1278                      ;; If a query context reduced the number of
1279                      ;; results to zero, try again without it.
1280                      (and notmuch-show-query-context
1281                           (notmuch-query-get-threads (append cli-args basic-args)))))
1282
1283          ;; Must be reset every time we are going to start inserting
1284          ;; messages into the buffer.
1285          (notmuch-show-previous-subject ""))
1286
1287     (when forest
1288       (notmuch-show-insert-forest forest)
1289
1290       ;; Store the original tags for each message so that we can
1291       ;; display changes.
1292       (notmuch-show-mapc
1293        (lambda () (notmuch-show-set-prop :orig-tags (notmuch-show-get-tags))))
1294
1295       ;; Set the header line to the subject of the first message.
1296       (setq header-line-format
1297             (replace-regexp-in-string "%" "%%"
1298                                       (notmuch-sanitize
1299                                        (notmuch-show-strip-re
1300                                         (notmuch-show-get-subject)))))
1301
1302       (run-hooks 'notmuch-show-hook)
1303
1304       (if state
1305           (notmuch-show-apply-state state)
1306         ;; With no state to apply, just go to the first message.
1307         (notmuch-show-goto-first-wanted-message)))
1308
1309     ;; Report back to the caller whether any messages matched.
1310     forest))
1311
1312 (defun notmuch-show-capture-state ()
1313   "Capture the state of the current buffer.
1314
1315 This includes:
1316  - the list of open messages,
1317  - the current message."
1318   (list (notmuch-show-get-message-id) (notmuch-show-get-message-ids-for-open-messages)))
1319
1320 (defun notmuch-show-get-query ()
1321   "Return the current query in this show buffer"
1322   (if notmuch-show-query-context
1323       (concat notmuch-show-thread-id
1324               " and ("
1325               notmuch-show-query-context
1326               ")")
1327     notmuch-show-thread-id))
1328
1329 (defun notmuch-show-goto-message (msg-id)
1330   "Go to message with msg-id."
1331   (goto-char (point-min))
1332   (unless (loop if (string= msg-id (notmuch-show-get-message-id))
1333                 return t
1334                 until (not (notmuch-show-goto-message-next)))
1335     (goto-char (point-min))
1336     (message "Message-id not found."))
1337   (notmuch-show-message-adjust))
1338
1339 (defun notmuch-show-apply-state (state)
1340   "Apply STATE to the current buffer.
1341
1342 This includes:
1343  - opening the messages previously opened,
1344  - closing all other messages,
1345  - moving to the correct current message."
1346   (let ((current (car state))
1347         (open (cadr state)))
1348
1349     ;; Open those that were open.
1350     (goto-char (point-min))
1351     (loop do (notmuch-show-message-visible (notmuch-show-get-message-properties)
1352                                            (member (notmuch-show-get-message-id) open))
1353           until (not (notmuch-show-goto-message-next)))
1354
1355     ;; Go to the previously open message.
1356     (notmuch-show-goto-message current)))
1357
1358 (defun notmuch-show-refresh-view (&optional reset-state)
1359   "Refresh the current view.
1360
1361 Refreshes the current view, observing changes in display
1362 preferences. If invoked with a prefix argument (or RESET-STATE is
1363 non-nil) then the state of the buffer (open/closed messages) is
1364 reset based on the original query."
1365   (interactive "P")
1366   (let ((inhibit-read-only t)
1367         (state (unless reset-state
1368                  (notmuch-show-capture-state))))
1369     ;; `erase-buffer' does not seem to remove overlays, which can lead
1370     ;; to weird effects such as remaining images, so remove them
1371     ;; manually.
1372     (remove-overlays)
1373     (erase-buffer)
1374
1375     (unless (notmuch-show--build-buffer state)
1376       ;; No messages were inserted.
1377       (kill-buffer (current-buffer))
1378       (ding)
1379       (message "Refreshing the buffer resulted in no messages!"))))
1380
1381 (defvar notmuch-show-stash-map
1382   (let ((map (make-sparse-keymap)))
1383     (define-key map "c" 'notmuch-show-stash-cc)
1384     (define-key map "d" 'notmuch-show-stash-date)
1385     (define-key map "F" 'notmuch-show-stash-filename)
1386     (define-key map "f" 'notmuch-show-stash-from)
1387     (define-key map "i" 'notmuch-show-stash-message-id)
1388     (define-key map "I" 'notmuch-show-stash-message-id-stripped)
1389     (define-key map "s" 'notmuch-show-stash-subject)
1390     (define-key map "T" 'notmuch-show-stash-tags)
1391     (define-key map "t" 'notmuch-show-stash-to)
1392     (define-key map "l" 'notmuch-show-stash-mlarchive-link)
1393     (define-key map "L" 'notmuch-show-stash-mlarchive-link-and-go)
1394     (define-key map "G" 'notmuch-show-stash-git-send-email)
1395     (define-key map "?" 'notmuch-subkeymap-help)
1396     map)
1397   "Submap for stash commands")
1398 (fset 'notmuch-show-stash-map notmuch-show-stash-map)
1399
1400 (defvar notmuch-show-part-map
1401   (let ((map (make-sparse-keymap)))
1402     (define-key map "s" 'notmuch-show-save-part)
1403     (define-key map "v" 'notmuch-show-view-part)
1404     (define-key map "o" 'notmuch-show-interactively-view-part)
1405     (define-key map "|" 'notmuch-show-pipe-part)
1406     (define-key map "?" 'notmuch-subkeymap-help)
1407     map)
1408   "Submap for part commands")
1409 (fset 'notmuch-show-part-map notmuch-show-part-map)
1410
1411 (defvar notmuch-show-mode-map
1412   (let ((map (make-sparse-keymap)))
1413     (set-keymap-parent map notmuch-common-keymap)
1414     (define-key map "Z" 'notmuch-tree-from-show-current-query)
1415     (define-key map (kbd "<C-tab>") 'widget-backward)
1416     (define-key map (kbd "M-TAB") 'notmuch-show-previous-button)
1417     (define-key map (kbd "<backtab>") 'notmuch-show-previous-button)
1418     (define-key map (kbd "TAB") 'notmuch-show-next-button)
1419     (define-key map "f" 'notmuch-show-forward-message)
1420     (define-key map "F" 'notmuch-show-forward-open-messages)
1421     (define-key map "l" 'notmuch-show-filter-thread)
1422     (define-key map "r" 'notmuch-show-reply-sender)
1423     (define-key map "R" 'notmuch-show-reply)
1424     (define-key map "|" 'notmuch-show-pipe-message)
1425     (define-key map "w" 'notmuch-show-save-attachments)
1426     (define-key map "V" 'notmuch-show-view-raw-message)
1427     (define-key map "c" 'notmuch-show-stash-map)
1428     (define-key map "h" 'notmuch-show-toggle-visibility-headers)
1429     (define-key map "*" 'notmuch-show-tag-all)
1430     (define-key map "-" 'notmuch-show-remove-tag)
1431     (define-key map "+" 'notmuch-show-add-tag)
1432     (define-key map "X" 'notmuch-show-archive-thread-then-exit)
1433     (define-key map "x" 'notmuch-show-archive-message-then-next-or-exit)
1434     (define-key map "A" 'notmuch-show-archive-thread-then-next)
1435     (define-key map "a" 'notmuch-show-archive-message-then-next-or-next-thread)
1436     (define-key map "N" 'notmuch-show-next-message)
1437     (define-key map "P" 'notmuch-show-previous-message)
1438     (define-key map "n" 'notmuch-show-next-open-message)
1439     (define-key map "p" 'notmuch-show-previous-open-message)
1440     (define-key map (kbd "M-n") 'notmuch-show-next-thread-show)
1441     (define-key map (kbd "M-p") 'notmuch-show-previous-thread-show)
1442     (define-key map (kbd "DEL") 'notmuch-show-rewind)
1443     (define-key map " " 'notmuch-show-advance-and-archive)
1444     (define-key map (kbd "M-RET") 'notmuch-show-open-or-close-all)
1445     (define-key map (kbd "RET") 'notmuch-show-toggle-message)
1446     (define-key map "#" 'notmuch-show-print-message)
1447     (define-key map "!" 'notmuch-show-toggle-elide-non-matching)
1448     (define-key map "$" 'notmuch-show-toggle-process-crypto)
1449     (define-key map "<" 'notmuch-show-toggle-thread-indentation)
1450     (define-key map "t" 'toggle-truncate-lines)
1451     (define-key map "." 'notmuch-show-part-map)
1452     map)
1453   "Keymap for \"notmuch show\" buffers.")
1454 (fset 'notmuch-show-mode-map notmuch-show-mode-map)
1455
1456 (defun notmuch-show-mode ()
1457   "Major mode for viewing a thread with notmuch.
1458
1459 This buffer contains the results of the \"notmuch show\" command
1460 for displaying a single thread of email from your email archives.
1461
1462 By default, various components of email messages, (citations,
1463 signatures, already-read messages), are hidden. You can make
1464 these parts visible by clicking with the mouse button or by
1465 pressing RET after positioning the cursor on a hidden part, (for
1466 which \\[notmuch-show-next-button] and \\[notmuch-show-previous-button] are helpful).
1467
1468 Reading the thread sequentially is well-supported by pressing
1469 \\[notmuch-show-advance-and-archive]. This will scroll the current message (if necessary), advance
1470 to the next message, or advance to the next thread (if already on
1471 the last message of a thread).
1472
1473 Other commands are available to read or manipulate the thread
1474 more selectively, (such as '\\[notmuch-show-next-message]' and '\\[notmuch-show-previous-message]' to advance to messages
1475 without removing any tags, and '\\[notmuch-show-archive-thread]' to archive an entire thread
1476 without scrolling through with \\[notmuch-show-advance-and-archive]).
1477
1478 You can add or remove arbitrary tags from the current message with
1479 '\\[notmuch-show-add-tag]' or '\\[notmuch-show-remove-tag]'.
1480
1481 All currently available key bindings:
1482
1483 \\{notmuch-show-mode-map}"
1484   (interactive)
1485   (kill-all-local-variables)
1486   (setq notmuch-buffer-refresh-function #'notmuch-show-refresh-view)
1487   (use-local-map notmuch-show-mode-map)
1488   (setq major-mode 'notmuch-show-mode
1489         mode-name "notmuch-show")
1490   (setq buffer-read-only t
1491         truncate-lines t))
1492
1493 (defun notmuch-tree-from-show-current-query ()
1494   "Call notmuch tree with the current query"
1495   (interactive)
1496   (notmuch-tree notmuch-show-thread-id
1497                 notmuch-show-query-context
1498                 (notmuch-show-get-message-id)))
1499
1500 (defun notmuch-show-move-to-message-top ()
1501   (goto-char (notmuch-show-message-top)))
1502
1503 (defun notmuch-show-move-to-message-bottom ()
1504   (goto-char (notmuch-show-message-bottom)))
1505
1506 (defun notmuch-show-message-adjust ()
1507   (recenter 0))
1508
1509 ;; Movement related functions.
1510
1511 ;; There's some strangeness here where a text property applied to a
1512 ;; region a->b is not found when point is at b. We walk backwards
1513 ;; until finding the property.
1514 (defun notmuch-show-message-extent ()
1515   (let (r)
1516     (save-excursion
1517       (while (not (setq r (get-text-property (point) :notmuch-message-extent)))
1518         (backward-char)))
1519     r))
1520
1521 (defun notmuch-show-message-top ()
1522   (car (notmuch-show-message-extent)))
1523
1524 (defun notmuch-show-message-bottom ()
1525   (cdr (notmuch-show-message-extent)))
1526
1527 (defun notmuch-show-goto-message-next ()
1528   (let ((start (point)))
1529     (notmuch-show-move-to-message-bottom)
1530     (if (not (eobp))
1531         t
1532       (goto-char start)
1533       nil)))
1534
1535 (defun notmuch-show-goto-message-previous ()
1536   (notmuch-show-move-to-message-top)
1537   (if (bobp)
1538       nil
1539     (backward-char)
1540     (notmuch-show-move-to-message-top)
1541     t))
1542
1543 (defun notmuch-show-mapc (function)
1544   "Iterate through all messages in the current thread with
1545 `notmuch-show-goto-message-next' and call FUNCTION for side
1546 effects."
1547   (save-excursion
1548     (goto-char (point-min))
1549     (loop do (funcall function)
1550           while (notmuch-show-goto-message-next))))
1551
1552 ;; Functions relating to the visibility of messages and their
1553 ;; components.
1554
1555 (defun notmuch-show-message-visible (props visible-p)
1556   (overlay-put (plist-get props :message-overlay) 'invisible (not visible-p))
1557   (notmuch-show-set-prop :message-visible visible-p props))
1558
1559 (defun notmuch-show-headers-visible (props visible-p)
1560   (overlay-put (plist-get props :headers-overlay) 'invisible (not visible-p))
1561   (notmuch-show-set-prop :headers-visible visible-p props))
1562
1563 ;; Functions for setting and getting attributes of the current
1564 ;; message.
1565
1566 (defun notmuch-show-set-message-properties (props)
1567   (save-excursion
1568     (notmuch-show-move-to-message-top)
1569     (put-text-property (point) (+ (point) 1) :notmuch-message-properties props)))
1570
1571 (defun notmuch-show-get-message-properties ()
1572   "Return the properties of the current message as a plist.
1573
1574 Some useful entries are:
1575 :headers - Property list containing the headers :Date, :Subject, :From, etc.
1576 :body - Body of the message
1577 :tags - Tags for this message"
1578   (save-excursion
1579     (notmuch-show-move-to-message-top)
1580     (get-text-property (point) :notmuch-message-properties)))
1581
1582 (defun notmuch-show-get-part-properties ()
1583   "Return the properties of the innermost part containing point.
1584
1585 This is the part property list retrieved from the CLI.  Signals
1586 an error if there is no part containing point."
1587   (or (get-text-property (point) :notmuch-part)
1588       (error "No message part here")))
1589
1590 (defun notmuch-show-set-prop (prop val &optional props)
1591   (let ((inhibit-read-only t)
1592         (props (or props
1593                    (notmuch-show-get-message-properties))))
1594     (plist-put props prop val)
1595     (notmuch-show-set-message-properties props)))
1596
1597 (defun notmuch-show-get-prop (prop &optional props)
1598   "Get property PROP from current message in show or tree mode.
1599
1600 It gets property PROP from PROPS or, if PROPS is nil, the current
1601 message in either tree or show. This means that several utility
1602 functions in notmuch-show can be used directly by notmuch-tree as
1603 they just need the correct message properties."
1604   (let ((props (or props
1605                    (cond ((eq major-mode 'notmuch-show-mode)
1606                           (notmuch-show-get-message-properties))
1607                          ((eq major-mode 'notmuch-tree-mode)
1608                           (notmuch-tree-get-message-properties))
1609                          (t nil)))))
1610     (plist-get props prop)))
1611
1612 (defun notmuch-show-get-message-id (&optional bare)
1613   "Return an id: query for the Message-Id of the current message.
1614
1615 If optional argument BARE is non-nil, return
1616 the Message-Id without id: prefix and escaping."
1617   (if bare
1618       (notmuch-show-get-prop :id)
1619     (notmuch-id-to-query (notmuch-show-get-prop :id))))
1620
1621 (defun notmuch-show-get-messages-ids ()
1622   "Return all id: queries of messages in the current thread."
1623   (let ((message-ids))
1624     (notmuch-show-mapc
1625      (lambda () (push (notmuch-show-get-message-id) message-ids)))
1626     message-ids))
1627
1628 (defun notmuch-show-get-messages-ids-search ()
1629   "Return a search string for all message ids of messages in the
1630 current thread."
1631   (mapconcat 'identity (notmuch-show-get-messages-ids) " or "))
1632
1633 ;; dme: Would it make sense to use a macro for many of these?
1634
1635 (defun notmuch-show-get-filename ()
1636   "Return the filename of the current message."
1637   (notmuch-show-get-prop :filename))
1638
1639 (defun notmuch-show-get-header (header &optional props)
1640   "Return the named header of the current message, if any."
1641   (plist-get (notmuch-show-get-prop :headers props) header))
1642
1643 (defun notmuch-show-get-cc ()
1644   (notmuch-show-get-header :Cc))
1645
1646 (defun notmuch-show-get-date ()
1647   (notmuch-show-get-header :Date))
1648
1649 (defun notmuch-show-get-from ()
1650   (notmuch-show-get-header :From))
1651
1652 (defun notmuch-show-get-subject ()
1653   (notmuch-show-get-header :Subject))
1654
1655 (defun notmuch-show-get-to ()
1656   (notmuch-show-get-header :To))
1657
1658 (defun notmuch-show-get-depth ()
1659   (notmuch-show-get-prop :depth))
1660
1661 (defun notmuch-show-set-tags (tags)
1662   "Set the tags of the current message."
1663   (notmuch-show-set-prop :tags tags)
1664   (notmuch-show-update-tags tags))
1665
1666 (defun notmuch-show-get-tags ()
1667   "Return the tags of the current message."
1668   (notmuch-show-get-prop :tags))
1669
1670 (defun notmuch-show-message-visible-p ()
1671   "Is the current message visible?"
1672   (notmuch-show-get-prop :message-visible))
1673
1674 (defun notmuch-show-headers-visible-p ()
1675   "Are the headers of the current message visible?"
1676   (notmuch-show-get-prop :headers-visible))
1677
1678 (put 'notmuch-show-mark-read 'notmuch-prefix-doc
1679      "Mark the current message as unread.")
1680 (defun notmuch-show-mark-read (&optional unread)
1681   "Mark the current message as read.
1682
1683 Mark the current message as read by applying the tag changes in
1684 `notmuch-show-mark-read-tags' to it (remove the \"unread\" tag by
1685 default). If a prefix argument is given, the message will be
1686 marked as unread, i.e. the tag changes in
1687 `notmuch-show-mark-read-tags' will be reversed."
1688   (interactive "P")
1689   (when notmuch-show-mark-read-tags
1690     (apply 'notmuch-show-tag-message
1691            (notmuch-tag-change-list notmuch-show-mark-read-tags unread))))
1692
1693 (defun notmuch-show-seen-current-message (start end)
1694   "Mark the current message read if it is open.
1695
1696 We only mark it read once: if it is changed back then that is a
1697 user decision and we should not override it."
1698   (when (and (notmuch-show-message-visible-p)
1699              (not (notmuch-show-get-prop :seen)))
1700         (notmuch-show-mark-read)
1701         (notmuch-show-set-prop :seen t)))
1702
1703 (defun notmuch-show-command-hook ()
1704   (when (eq major-mode 'notmuch-show-mode)
1705     ;; We need to redisplay to get window-start and window-end correct.
1706     (redisplay)
1707     (save-excursion
1708       (funcall notmuch-show-mark-read-function (window-start) (window-end)))))
1709
1710 (defun notmuch-show-filter-thread (query)
1711   "Filter or LIMIT the current thread based on a new query string.
1712
1713 Reshows the current thread with matches defined by the new query-string."
1714   (interactive (list (notmuch-read-query "Filter thread: ")))
1715   (let ((msg-id (notmuch-show-get-message-id)))
1716     (setq notmuch-show-query-context (if (string= query "") nil query))
1717     (notmuch-show-refresh-view t)
1718     (notmuch-show-goto-message msg-id)))
1719
1720 ;; Functions for getting attributes of several messages in the current
1721 ;; thread.
1722
1723 (defun notmuch-show-get-message-ids-for-open-messages ()
1724   "Return a list of all id: queries for open messages in the current thread."
1725   (save-excursion
1726     (let (message-ids done)
1727       (goto-char (point-min))
1728       (while (not done)
1729         (if (notmuch-show-message-visible-p)
1730             (setq message-ids (append message-ids (list (notmuch-show-get-message-id)))))
1731         (setq done (not (notmuch-show-goto-message-next)))
1732         )
1733       message-ids
1734       )))
1735
1736 ;; Commands typically bound to keys.
1737
1738 (defun notmuch-show-advance ()
1739   "Advance through thread.
1740
1741 If the current message in the thread is not yet fully visible,
1742 scroll by a near screenful to read more of the message.
1743
1744 Otherwise, (the end of the current message is already within the
1745 current window), advance to the next open message."
1746   (interactive)
1747   (let* ((end-of-this-message (notmuch-show-message-bottom))
1748          (visible-end-of-this-message (1- end-of-this-message))
1749          (ret nil))
1750     (while (invisible-p visible-end-of-this-message)
1751       (setq visible-end-of-this-message
1752             (max (point-min)
1753                  (1- (previous-single-char-property-change
1754                       visible-end-of-this-message 'invisible)))))
1755     (cond
1756      ;; Ideally we would test `end-of-this-message' against the result
1757      ;; of `window-end', but that doesn't account for the fact that
1758      ;; the end of the message might be hidden.
1759      ((and visible-end-of-this-message
1760            (> visible-end-of-this-message (window-end)))
1761       ;; The bottom of this message is not visible - scroll.
1762       (scroll-up nil))
1763
1764      ((not (= end-of-this-message (point-max)))
1765       ;; This is not the last message - move to the next visible one.
1766       (notmuch-show-next-open-message))
1767
1768      ((not (= (point) (point-max)))
1769       ;; This is the last message, but the cursor is not at the end of
1770       ;; the buffer. Move it there.
1771       (goto-char (point-max)))
1772
1773      (t
1774       ;; This is the last message - change the return value
1775       (setq ret t)))
1776     ret))
1777
1778 (defun notmuch-show-advance-and-archive ()
1779   "Advance through thread and archive.
1780
1781 This command is intended to be one of the simplest ways to
1782 process a thread of email. It works exactly like
1783 notmuch-show-advance, in that it scrolls through messages in a
1784 show buffer, except that when it gets to the end of the buffer it
1785 archives the entire current thread, (apply changes in
1786 `notmuch-archive-tags'), kills the buffer, and displays the next
1787 thread from the search from which this thread was originally
1788 shown."
1789   (interactive)
1790   (if (notmuch-show-advance)
1791       (notmuch-show-archive-thread-then-next)))
1792
1793 (defun notmuch-show-rewind ()
1794   "Backup through the thread (reverse scrolling compared to \\[notmuch-show-advance-and-archive]).
1795
1796 Specifically, if the beginning of the previous email is fewer
1797 than `window-height' lines from the current point, move to it
1798 just like `notmuch-show-previous-message'.
1799
1800 Otherwise, just scroll down a screenful of the current message.
1801
1802 This command does not modify any message tags, (it does not undo
1803 any effects from previous calls to
1804 `notmuch-show-advance-and-archive'."
1805   (interactive)
1806   (let ((start-of-message (notmuch-show-message-top))
1807         (start-of-window (window-start)))
1808     (cond
1809       ;; Either this message is properly aligned with the start of the
1810       ;; window or the start of this message is not visible on the
1811       ;; screen - scroll.
1812      ((or (= start-of-message start-of-window)
1813           (< start-of-message start-of-window))
1814       (scroll-down)
1815       ;; If a small number of lines from the previous message are
1816       ;; visible, realign so that the top of the current message is at
1817       ;; the top of the screen.
1818       (when (<= (count-screen-lines (window-start) start-of-message)
1819                 next-screen-context-lines)
1820         (goto-char (notmuch-show-message-top))
1821         (notmuch-show-message-adjust))
1822       ;; Move to the top left of the window.
1823       (goto-char (window-start)))
1824      (t
1825       ;; Move to the previous message.
1826       (notmuch-show-previous-message)))))
1827
1828 (put 'notmuch-show-reply 'notmuch-prefix-doc "... and prompt for sender")
1829 (defun notmuch-show-reply (&optional prompt-for-sender)
1830   "Reply to the sender and all recipients of the current message."
1831   (interactive "P")
1832   (notmuch-mua-new-reply (notmuch-show-get-message-id) prompt-for-sender t))
1833
1834 (put 'notmuch-show-reply-sender 'notmuch-prefix-doc "... and prompt for sender")
1835 (defun notmuch-show-reply-sender (&optional prompt-for-sender)
1836   "Reply to the sender of the current message."
1837   (interactive "P")
1838   (notmuch-mua-new-reply (notmuch-show-get-message-id) prompt-for-sender nil))
1839
1840 (put 'notmuch-show-forward-message 'notmuch-prefix-doc
1841      "... and prompt for sender")
1842 (defun notmuch-show-forward-message (&optional prompt-for-sender)
1843   "Forward the current message."
1844   (interactive "P")
1845   (notmuch-mua-new-forward-messages (list (notmuch-show-get-message-id))
1846                                     prompt-for-sender))
1847
1848 (put 'notmuch-show-forward-open-messages 'notmuch-prefix-doc
1849      "... and prompt for sender")
1850 (defun notmuch-show-forward-open-messages (&optional prompt-for-sender)
1851   "Forward the currently open messages."
1852   (interactive "P")
1853   (let ((open-messages (notmuch-show-get-message-ids-for-open-messages)))
1854     (unless open-messages
1855       (error "No open messages to forward."))
1856     (notmuch-mua-new-forward-messages open-messages prompt-for-sender)))
1857
1858 (defun notmuch-show-resend-message (addresses)
1859   "Resend the current message."
1860   (interactive (list (notmuch-address-from-minibuffer "Resend to: ")))
1861   (when (y-or-n-p (concat "Confirm resend to " addresses " "))
1862     (notmuch-show-view-raw-message)
1863     (message-resend addresses)
1864     (notmuch-bury-or-kill-this-buffer)))
1865
1866 (defun notmuch-show-next-message (&optional pop-at-end)
1867   "Show the next message.
1868
1869 If a prefix argument is given and this is the last message in the
1870 thread, navigate to the next thread in the parent search buffer."
1871   (interactive "P")
1872   (if (notmuch-show-goto-message-next)
1873       (notmuch-show-message-adjust)
1874     (if pop-at-end
1875         (notmuch-show-next-thread)
1876       (goto-char (point-max)))))
1877
1878 (defun notmuch-show-previous-message ()
1879   "Show the previous message or the start of the current message."
1880   (interactive)
1881   (if (= (point) (notmuch-show-message-top))
1882       (notmuch-show-goto-message-previous)
1883     (notmuch-show-move-to-message-top))
1884   (notmuch-show-message-adjust))
1885
1886 (defun notmuch-show-next-open-message (&optional pop-at-end)
1887   "Show the next open message.
1888
1889 If a prefix argument is given and this is the last open message
1890 in the thread, navigate to the next thread in the parent search
1891 buffer. Return t if there was a next open message in the thread
1892 to show, nil otherwise."
1893   (interactive "P")
1894   (let (r)
1895     (while (and (setq r (notmuch-show-goto-message-next))
1896                 (not (notmuch-show-message-visible-p))))
1897     (if r
1898         (notmuch-show-message-adjust)
1899       (if pop-at-end
1900           (notmuch-show-next-thread)
1901         (goto-char (point-max))))
1902     r))
1903
1904 (defun notmuch-show-next-matching-message ()
1905   "Show the next matching message."
1906   (interactive)
1907   (let (r)
1908     (while (and (setq r (notmuch-show-goto-message-next))
1909                 (not (notmuch-show-get-prop :match))))
1910     (if r
1911         (notmuch-show-message-adjust)
1912       (goto-char (point-max)))))
1913
1914 (defun notmuch-show-open-if-matched ()
1915   "Open a message if it is matched (whether or not excluded)."
1916   (let ((props (notmuch-show-get-message-properties)))
1917     (notmuch-show-message-visible props (plist-get props :match))))
1918
1919 (defun notmuch-show-goto-first-wanted-message ()
1920   "Move to the first open message and mark it read"
1921   (goto-char (point-min))
1922   (unless (notmuch-show-message-visible-p)
1923     (notmuch-show-next-open-message))
1924   (when (eobp)
1925     ;; There are no matched non-excluded messages so open all matched
1926     ;; (necessarily excluded) messages and go to the first.
1927     (notmuch-show-mapc 'notmuch-show-open-if-matched)
1928     (force-window-update)
1929     (goto-char (point-min))
1930     (unless (notmuch-show-message-visible-p)
1931       (notmuch-show-next-open-message))))
1932
1933 (defun notmuch-show-previous-open-message ()
1934   "Show the previous open message."
1935   (interactive)
1936   (while (and (if (= (point) (notmuch-show-message-top))
1937                   (notmuch-show-goto-message-previous)
1938                 (notmuch-show-move-to-message-top))
1939               (not (notmuch-show-message-visible-p))))
1940   (notmuch-show-message-adjust))
1941
1942 (defun notmuch-show-view-raw-message ()
1943   "View the original source of the current message."
1944   (interactive)
1945   (let* ((id (notmuch-show-get-message-id))
1946          (buf (get-buffer-create (concat "*notmuch-raw-" id "*")))
1947          (inhibit-read-only t))
1948     (switch-to-buffer buf)
1949     (erase-buffer)
1950     (let ((coding-system-for-read 'no-conversion))
1951       (call-process notmuch-command nil t nil "show" "--format=raw" id))
1952     (goto-char (point-min))
1953     (set-buffer-modified-p nil)
1954     (setq buffer-read-only t)
1955     (view-buffer buf 'kill-buffer-if-not-modified)))
1956
1957 (put 'notmuch-show-pipe-message 'notmuch-doc
1958      "Pipe the contents of the current message to a command.")
1959 (put 'notmuch-show-pipe-message 'notmuch-prefix-doc
1960      "Pipe the thread as an mbox to a command.")
1961 (defun notmuch-show-pipe-message (entire-thread command)
1962   "Pipe the contents of the current message (or thread) to COMMAND.
1963
1964 COMMAND will be executed with the raw contents of the current
1965 email message as stdin. Anything printed by the command to stdout
1966 or stderr will appear in the *notmuch-pipe* buffer.
1967
1968 If ENTIRE-THREAD is non-nil (or when invoked with a prefix
1969 argument), COMMAND will receive all open messages in the current
1970 thread (formatted as an mbox) rather than only the current
1971 message."
1972   (interactive (let ((query-string (if current-prefix-arg
1973                                        "Pipe all open messages to command: "
1974                                      "Pipe message to command: ")))
1975                  (list current-prefix-arg (read-string query-string))))
1976   (let (shell-command)
1977     (if entire-thread
1978         (setq shell-command
1979               (concat notmuch-command " show --format=mbox --exclude=false "
1980                       (shell-quote-argument
1981                        (mapconcat 'identity (notmuch-show-get-message-ids-for-open-messages) " OR "))
1982                       " | " command))
1983       (setq shell-command
1984             (concat notmuch-command " show --format=raw "
1985                     (shell-quote-argument (notmuch-show-get-message-id)) " | " command)))
1986     (let ((cwd default-directory)
1987           (buf (get-buffer-create (concat "*notmuch-pipe*"))))
1988       (with-current-buffer buf
1989         (setq buffer-read-only nil)
1990         (erase-buffer)
1991         ;; Use the originating buffer's working directory instead of
1992         ;; that of the pipe buffer.
1993         (cd cwd)
1994         (let ((exit-code (call-process-shell-command shell-command nil buf)))
1995           (goto-char (point-max))
1996           (set-buffer-modified-p nil)
1997           (setq buffer-read-only t)
1998           (unless (zerop exit-code)
1999             (switch-to-buffer-other-window buf)
2000             (message (format "Command '%s' exited abnormally with code %d"
2001                              shell-command exit-code))))))))
2002
2003 (defun notmuch-show-tag-message (&rest tag-changes)
2004   "Change tags for the current message.
2005
2006 TAG-CHANGES is a list of tag operations for `notmuch-tag'."
2007   (let* ((current-tags (notmuch-show-get-tags))
2008          (new-tags (notmuch-update-tags current-tags tag-changes)))
2009     (unless (equal current-tags new-tags)
2010       (notmuch-tag (notmuch-show-get-message-id) tag-changes)
2011       (notmuch-show-set-tags new-tags))))
2012
2013 (defun notmuch-show-tag (tag-changes)
2014   "Change tags for the current message.
2015
2016 See `notmuch-tag' for information on the format of TAG-CHANGES."
2017   (interactive (list (notmuch-read-tag-changes (notmuch-show-get-tags)
2018                                                "Tag message")))
2019   (notmuch-tag (notmuch-show-get-message-id) tag-changes)
2020   (let* ((current-tags (notmuch-show-get-tags))
2021          (new-tags (notmuch-update-tags current-tags tag-changes)))
2022     (unless (equal current-tags new-tags)
2023       (notmuch-show-set-tags new-tags))))
2024
2025 (defun notmuch-show-tag-all (tag-changes)
2026   "Change tags for all messages in the current show buffer.
2027
2028 See `notmuch-tag' for information on the format of TAG-CHANGES."
2029   (interactive
2030    (list (let (tags)
2031            (notmuch-show-mapc
2032             (lambda () (setq tags (append (notmuch-show-get-tags) tags))))
2033            (notmuch-read-tag-changes tags "Tag thread"))))
2034   (notmuch-tag (notmuch-show-get-messages-ids-search) tag-changes)
2035   (notmuch-show-mapc
2036    (lambda ()
2037      (let* ((current-tags (notmuch-show-get-tags))
2038             (new-tags (notmuch-update-tags current-tags tag-changes)))
2039        (unless (equal current-tags new-tags)
2040          (notmuch-show-set-tags new-tags))))))
2041
2042 (defun notmuch-show-add-tag (tag-changes)
2043   "Change tags for the current message (defaulting to add).
2044
2045 Same as `notmuch-show-tag' but sets initial input to '+'."
2046   (interactive
2047    (list (notmuch-read-tag-changes (notmuch-show-get-tags) "Tag message" "+")))
2048   (notmuch-show-tag tag-changes))
2049
2050 (defun notmuch-show-remove-tag (tag-changes)
2051   "Change tags for the current message (defaulting to remove).
2052
2053 Same as `notmuch-show-tag' but sets initial input to '-'."
2054   (interactive
2055    (list (notmuch-read-tag-changes (notmuch-show-get-tags) "Tag message" "-")))
2056   (notmuch-show-tag tag-changes))
2057
2058 (defun notmuch-show-toggle-visibility-headers ()
2059   "Toggle the visibility of the current message headers."
2060   (interactive)
2061   (let ((props (notmuch-show-get-message-properties)))
2062     (notmuch-show-headers-visible
2063      props
2064      (not (plist-get props :headers-visible))))
2065   (force-window-update))
2066
2067 (defun notmuch-show-toggle-message ()
2068   "Toggle the visibility of the current message."
2069   (interactive)
2070   (let ((props (notmuch-show-get-message-properties)))
2071     (notmuch-show-message-visible
2072      props
2073      (not (plist-get props :message-visible))))
2074   (force-window-update))
2075
2076 (put 'notmuch-show-open-or-close-all 'notmuch-doc "Show all messages.")
2077 (put 'notmuch-show-open-or-close-all 'notmuch-prefix-doc "Hide all messages.")
2078 (defun notmuch-show-open-or-close-all ()
2079   "Set the visibility all of the messages in the current thread.
2080
2081 By default make all of the messages visible. With a prefix
2082 argument, hide all of the messages."
2083   (interactive)
2084   (save-excursion
2085     (goto-char (point-min))
2086     (loop do (notmuch-show-message-visible (notmuch-show-get-message-properties)
2087                                            (not current-prefix-arg))
2088           until (not (notmuch-show-goto-message-next))))
2089   (force-window-update))
2090
2091 (defun notmuch-show-next-button ()
2092   "Advance point to the next button in the buffer."
2093   (interactive)
2094   (forward-button 1))
2095
2096 (defun notmuch-show-previous-button ()
2097   "Move point back to the previous button in the buffer."
2098   (interactive)
2099   (backward-button 1))
2100
2101 (defun notmuch-show-next-thread (&optional show previous)
2102   "Move to the next item in the search results, if any.
2103
2104 If SHOW is non-nil, open the next item in a show
2105 buffer. Otherwise just highlight the next item in the search
2106 buffer. If PREVIOUS is non-nil, move to the previous item in the
2107 search results instead."
2108   (interactive "P")
2109   (let ((parent-buffer notmuch-show-parent-buffer))
2110     (notmuch-bury-or-kill-this-buffer)
2111     (when (buffer-live-p parent-buffer)
2112       (switch-to-buffer parent-buffer)
2113       (and (if previous
2114                (notmuch-search-previous-thread)
2115              (notmuch-search-next-thread))
2116            show
2117            (notmuch-search-show-thread)))))
2118
2119 (defun notmuch-show-next-thread-show ()
2120   "Show the next thread in the search results, if any."
2121   (interactive)
2122   (notmuch-show-next-thread t))
2123
2124 (defun notmuch-show-previous-thread-show ()
2125   "Show the previous thread in the search results, if any."
2126   (interactive)
2127   (notmuch-show-next-thread t t))
2128
2129 (put 'notmuch-show-archive-thread 'notmuch-prefix-doc
2130      "Un-archive each message in thread.")
2131 (defun notmuch-show-archive-thread (&optional unarchive)
2132   "Archive each message in thread.
2133
2134 Archive each message currently shown by applying the tag changes
2135 in `notmuch-archive-tags' to each. If a prefix argument is given,
2136 the messages will be \"unarchived\", i.e. the tag changes in
2137 `notmuch-archive-tags' will be reversed.
2138
2139 Note: This command is safe from any race condition of new messages
2140 being delivered to the same thread. It does not archive the
2141 entire thread, but only the messages shown in the current
2142 buffer."
2143   (interactive "P")
2144   (when notmuch-archive-tags
2145     (notmuch-show-tag-all
2146      (notmuch-tag-change-list notmuch-archive-tags unarchive))))
2147
2148 (defun notmuch-show-archive-thread-then-next ()
2149   "Archive all messages in the current buffer, then show next thread from search."
2150   (interactive)
2151   (notmuch-show-archive-thread)
2152   (notmuch-show-next-thread t))
2153
2154 (defun notmuch-show-archive-thread-then-exit ()
2155   "Archive all messages in the current buffer, then exit back to search results."
2156   (interactive)
2157   (notmuch-show-archive-thread)
2158   (notmuch-show-next-thread))
2159
2160 (put 'notmuch-show-archive-message 'notmuch-prefix-doc
2161      "Un-archive the current message.")
2162 (defun notmuch-show-archive-message (&optional unarchive)
2163   "Archive the current message.
2164
2165 Archive the current message by applying the tag changes in
2166 `notmuch-archive-tags' to it. If a prefix argument is given, the
2167 message will be \"unarchived\", i.e. the tag changes in
2168 `notmuch-archive-tags' will be reversed."
2169   (interactive "P")
2170   (when notmuch-archive-tags
2171     (apply 'notmuch-show-tag-message
2172            (notmuch-tag-change-list notmuch-archive-tags unarchive))))
2173
2174 (defun notmuch-show-archive-message-then-next-or-exit ()
2175   "Archive the current message, then show the next open message in the current thread.
2176
2177 If at the last open message in the current thread, then exit back
2178 to search results."
2179   (interactive)
2180   (notmuch-show-archive-message)
2181   (notmuch-show-next-open-message t))
2182
2183 (defun notmuch-show-archive-message-then-next-or-next-thread ()
2184   "Archive the current message, then show the next open message in the current thread.
2185
2186 If at the last open message in the current thread, then show next
2187 thread from search."
2188   (interactive)
2189   (notmuch-show-archive-message)
2190   (unless (notmuch-show-next-open-message)
2191     (notmuch-show-next-thread t)))
2192
2193 (defun notmuch-show-stash-cc ()
2194   "Copy CC field of current message to kill-ring."
2195   (interactive)
2196   (notmuch-common-do-stash (notmuch-show-get-cc)))
2197
2198 (defun notmuch-show-stash-date ()
2199   "Copy date of current message to kill-ring."
2200   (interactive)
2201   (notmuch-common-do-stash (notmuch-show-get-date)))
2202
2203 (defun notmuch-show-stash-filename ()
2204   "Copy filename of current message to kill-ring."
2205   (interactive)
2206   (notmuch-common-do-stash (notmuch-show-get-filename)))
2207
2208 (defun notmuch-show-stash-from ()
2209   "Copy From address of current message to kill-ring."
2210   (interactive)
2211   (notmuch-common-do-stash (notmuch-show-get-from)))
2212
2213 (put 'notmuch-show-stash-message-id 'notmuch-prefix-doc
2214      "Copy thread: query matching current thread to kill-ring.")
2215 (defun notmuch-show-stash-message-id (&optional stash-thread-id)
2216   "Copy id: query matching the current message to kill-ring.
2217
2218 If invoked with a prefix argument (or STASH-THREAD-ID is
2219 non-nil), copy thread: query matching the current thread to
2220 kill-ring."
2221   (interactive "P")
2222   (if stash-thread-id
2223       (notmuch-common-do-stash notmuch-show-thread-id)
2224     (notmuch-common-do-stash (notmuch-show-get-message-id))))
2225
2226 (defun notmuch-show-stash-message-id-stripped ()
2227   "Copy message ID of current message (sans `id:' prefix) to kill-ring."
2228   (interactive)
2229   (notmuch-common-do-stash (notmuch-show-get-message-id t)))
2230
2231 (defun notmuch-show-stash-subject ()
2232   "Copy Subject field of current message to kill-ring."
2233   (interactive)
2234   (notmuch-common-do-stash (notmuch-show-get-subject)))
2235
2236 (defun notmuch-show-stash-tags ()
2237   "Copy tags of current message to kill-ring as a comma separated list."
2238   (interactive)
2239   (notmuch-common-do-stash (mapconcat 'identity (notmuch-show-get-tags) ",")))
2240
2241 (defun notmuch-show-stash-to ()
2242   "Copy To address of current message to kill-ring."
2243   (interactive)
2244   (notmuch-common-do-stash (notmuch-show-get-to)))
2245
2246 (defun notmuch-show-stash-mlarchive-link (&optional mla)
2247   "Copy an ML Archive URI for the current message to the kill-ring.
2248
2249 This presumes that the message is available at the selected Mailing List Archive.
2250
2251 If optional argument MLA is non-nil, use the provided key instead of prompting
2252 the user (see `notmuch-show-stash-mlarchive-link-alist')."
2253   (interactive)
2254   (let ((url (cdr (assoc
2255                    (or mla
2256                        (let ((completion-ignore-case t))
2257                          (completing-read
2258                           "Mailing List Archive: "
2259                           notmuch-show-stash-mlarchive-link-alist
2260                           nil t nil nil
2261                           notmuch-show-stash-mlarchive-link-default)))
2262                    notmuch-show-stash-mlarchive-link-alist))))
2263     (notmuch-common-do-stash
2264      (if (functionp url)
2265          (funcall url (notmuch-show-get-message-id t))
2266        (concat url (notmuch-show-get-message-id t))))))
2267
2268 (defun notmuch-show-stash-mlarchive-link-and-go (&optional mla)
2269   "Copy an ML Archive URI for the current message to the kill-ring and visit it.
2270
2271 This presumes that the message is available at the selected Mailing List Archive.
2272
2273 If optional argument MLA is non-nil, use the provided key instead of prompting
2274 the user (see `notmuch-show-stash-mlarchive-link-alist')."
2275   (interactive)
2276   (notmuch-show-stash-mlarchive-link mla)
2277   (browse-url (current-kill 0 t)))
2278
2279 (defun notmuch-show-stash-git-helper (addresses prefix)
2280   "Escape, trim, quote, and add PREFIX to each address in list of ADDRESSES, and return the result as a single string."
2281   (mapconcat (lambda (x)
2282                (concat prefix "\""
2283                        ;; escape double-quotes
2284                        (replace-regexp-in-string
2285                         "\"" "\\\\\""
2286                         ;; trim leading and trailing spaces
2287                         (replace-regexp-in-string
2288                          "\\(^ *\\| *$\\)" ""
2289                          x)) "\""))
2290              addresses " "))
2291
2292 (put 'notmuch-show-stash-git-send-email 'notmuch-prefix-doc
2293      "Copy From/To/Cc of current message to kill-ring in a form suitable for pasting to git send-email command line.")
2294
2295 (defun notmuch-show-stash-git-send-email (&optional no-in-reply-to)
2296   "Copy From/To/Cc/Message-Id of current message to kill-ring in a form suitable for pasting to git send-email command line.
2297
2298 If invoked with a prefix argument (or NO-IN-REPLY-TO is non-nil),
2299 omit --in-reply-to=<Message-Id>."
2300   (interactive "P")
2301   (notmuch-common-do-stash
2302    (mapconcat 'identity
2303               (remove ""
2304                       (list
2305                        (notmuch-show-stash-git-helper
2306                         (message-tokenize-header (notmuch-show-get-from)) "--to=")
2307                        (notmuch-show-stash-git-helper
2308                         (message-tokenize-header (notmuch-show-get-to)) "--to=")
2309                        (notmuch-show-stash-git-helper
2310                         (message-tokenize-header (notmuch-show-get-cc)) "--cc=")
2311                        (unless no-in-reply-to
2312                          (notmuch-show-stash-git-helper
2313                           (list (notmuch-show-get-message-id t)) "--in-reply-to="))))
2314               " ")))
2315
2316 ;; Interactive part functions and their helpers
2317
2318 (defun notmuch-show-generate-part-buffer (msg part)
2319   "Return a temporary buffer containing the specified part's content."
2320   (let ((buf (generate-new-buffer " *notmuch-part*"))
2321         (process-crypto notmuch-show-process-crypto))
2322     (with-current-buffer buf
2323       ;; This is always used in the content of mm handles, which
2324       ;; expect undecoded, binary part content.
2325       (insert (notmuch-get-bodypart-binary msg part process-crypto)))
2326     buf))
2327
2328 (defun notmuch-show-current-part-handle ()
2329   "Return an mm-handle for the part containing point.
2330
2331 This creates a temporary buffer for the part's content; the
2332 caller is responsible for killing this buffer as appropriate."
2333   (let* ((msg (notmuch-show-get-message-properties))
2334          (part (notmuch-show-get-part-properties))
2335          (buf (notmuch-show-generate-part-buffer msg part))
2336          (computed-type (plist-get part :computed-type))
2337          (filename (plist-get part :filename))
2338          (disposition (if filename `(attachment (filename . ,filename)))))
2339     (mm-make-handle buf (list computed-type) nil nil disposition)))
2340
2341 (defun notmuch-show-apply-to-current-part-handle (fn)
2342   "Apply FN to an mm-handle for the part containing point.
2343
2344 This ensures that the temporary buffer created for the mm-handle
2345 is destroyed when FN returns."
2346   (let ((handle (notmuch-show-current-part-handle)))
2347     ;; emacs 24.3+ puts stdout/stderr into the calling buffer so we
2348     ;; call it from a temp-buffer, unless
2349     ;; notmuch-show-attachment-debug is non-nil in which case we put
2350     ;; it in " *notmuch-part*".
2351     (unwind-protect
2352         (if notmuch-show-attachment-debug
2353             (with-current-buffer (generate-new-buffer " *notmuch-part*")
2354               (funcall fn handle))
2355           (with-temp-buffer
2356             (funcall fn handle)))
2357       (kill-buffer (mm-handle-buffer handle)))))
2358
2359 (defun notmuch-show-part-button-default (&optional button)
2360   (interactive)
2361   (let ((button (or button (button-at (point)))))
2362     ;; Try to toggle the part, if that fails then call the default
2363     ;; action. The toggle fails if the part has no emacs renderable
2364     ;; content.
2365     (unless (notmuch-show-toggle-part-invisibility button)
2366       (call-interactively notmuch-show-part-button-default-action))))
2367
2368 (defun notmuch-show-save-part ()
2369   "Save the MIME part containing point to a file."
2370   (interactive)
2371   (notmuch-show-apply-to-current-part-handle #'mm-save-part))
2372
2373 (defun notmuch-show-view-part ()
2374   "View the MIME part containing point in an external viewer."
2375   (interactive)
2376   ;; Set mm-inlined-types to nil to force an external viewer
2377   (let ((mm-inlined-types nil))
2378     (notmuch-show-apply-to-current-part-handle #'mm-display-part)))
2379
2380 (defun notmuch-show-interactively-view-part ()
2381   "View the MIME part containing point, prompting for a viewer."
2382   (interactive)
2383   (notmuch-show-apply-to-current-part-handle #'mm-interactively-view-part))
2384
2385 (defun notmuch-show-pipe-part ()
2386   "Pipe the MIME part containing point to an external command."
2387   (interactive)
2388   (notmuch-show-apply-to-current-part-handle #'mm-pipe-part))
2389
2390
2391 (provide 'notmuch-show)
2392
2393 ;;; notmuch-show.el ends here