59931453a018a4b7a5a58749e7d6447d696f2606
[notmuch] / emacs / notmuch-show.el
1 ;;; notmuch-show.el --- displaying notmuch forests.
2 ;;
3 ;; Copyright © Carl Worth
4 ;; Copyright © David Edmondson
5 ;;
6 ;; This file is part of Notmuch.
7 ;;
8 ;; Notmuch is free software: you can redistribute it and/or modify it
9 ;; under the terms of the GNU General Public License as published by
10 ;; the Free Software Foundation, either version 3 of the License, or
11 ;; (at your option) any later version.
12 ;;
13 ;; Notmuch is distributed in the hope that it will be useful, but
14 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
16 ;; General Public License for more details.
17 ;;
18 ;; You should have received a copy of the GNU General Public License
19 ;; along with Notmuch.  If not, see <https://www.gnu.org/licenses/>.
20 ;;
21 ;; Authors: Carl Worth <cworth@cworth.org>
22 ;;          David Edmondson <dme@dme.org>
23
24 ;;; Code:
25
26 (eval-when-compile
27   (require 'cl-lib)
28   (require 'pcase))
29
30 (require 'mm-view)
31 (require 'message)
32 (require 'mm-decode)
33 (require 'mailcap)
34 (require 'icalendar)
35 (require 'goto-addr)
36
37 (require 'notmuch-lib)
38 (require 'notmuch-tag)
39 (require 'notmuch-query)
40 (require 'notmuch-wash)
41 (require 'notmuch-mua)
42 (require 'notmuch-crypto)
43 (require 'notmuch-print)
44 (require 'notmuch-draft)
45
46 (declare-function notmuch-call-notmuch-process "notmuch" (&rest args))
47 (declare-function notmuch-search-next-thread "notmuch" nil)
48 (declare-function notmuch-search-previous-thread "notmuch" nil)
49 (declare-function notmuch-search-show-thread "notmuch" nil)
50 (declare-function notmuch-foreach-mime-part "notmuch" (function mm-handle))
51 (declare-function notmuch-count-attachments "notmuch" (mm-handle))
52 (declare-function notmuch-save-attachments "notmuch" (mm-handle &optional queryp))
53 (declare-function notmuch-tree "notmuch-tree"
54                   (&optional query query-context target buffer-name open-target unthreaded))
55 (declare-function notmuch-tree-get-message-properties "notmuch-tree" nil)
56 (declare-function notmuch-unthreaded
57                   (&optional query query-context target buffer-name open-target))
58 (declare-function notmuch-read-query "notmuch" (prompt))
59 (declare-function notmuch-draft-resume "notmuch-draft" (id))
60
61 (defcustom notmuch-message-headers '("Subject" "To" "Cc" "Date")
62   "Headers that should be shown in a message, in this order.
63
64 For an open message, all of these headers will be made visible
65 according to `notmuch-message-headers-visible' or can be toggled
66 with `notmuch-show-toggle-visibility-headers'. For a closed message,
67 only the first header in the list will be visible."
68   :type '(repeat string)
69   :group 'notmuch-show)
70
71 (defcustom notmuch-message-headers-visible t
72   "Should the headers be visible by default?
73
74 If this value is non-nil, then all of the headers defined in
75 `notmuch-message-headers' will be visible by default in the display
76 of each message. Otherwise, these headers will be hidden and
77 `notmuch-show-toggle-visibility-headers' can be used to make them
78 visible for any given message."
79   :type 'boolean
80   :group 'notmuch-show)
81
82 (defcustom notmuch-show-relative-dates t
83   "Display relative dates in the message summary line."
84   :type 'boolean
85   :group 'notmuch-show)
86
87 (defvar notmuch-show-markup-headers-hook '(notmuch-show-colour-headers)
88   "A list of functions called to decorate the headers listed in
89 `notmuch-message-headers'.")
90
91 (defcustom notmuch-show-hook '(notmuch-show-turn-on-visual-line-mode)
92   "Functions called after populating a `notmuch-show' buffer."
93   :type 'hook
94   :options '(notmuch-show-turn-on-visual-line-mode)
95   :group 'notmuch-show
96   :group 'notmuch-hooks)
97
98 (defcustom notmuch-show-insert-text/plain-hook '(notmuch-wash-wrap-long-lines
99                                                  notmuch-wash-tidy-citations
100                                                  notmuch-wash-elide-blank-lines
101                                                  notmuch-wash-excerpt-citations)
102   "Functions used to improve the display of text/plain parts."
103   :type 'hook
104   :options '(notmuch-wash-convert-inline-patch-to-part
105              notmuch-wash-wrap-long-lines
106              notmuch-wash-tidy-citations
107              notmuch-wash-elide-blank-lines
108              notmuch-wash-excerpt-citations)
109   :group 'notmuch-show
110   :group 'notmuch-hooks)
111
112 (defcustom notmuch-show-max-text-part-size 100000
113   "Maximum size of a text part to be shown by default in characters.
114
115 Set to 0 to show the part regardless of size."
116   :type 'integer
117   :group 'notmuch-show)
118
119 ;; Mostly useful for debugging.
120 (defcustom notmuch-show-all-multipart/alternative-parts nil
121   "Should all parts of multipart/alternative parts be shown?"
122   :type 'boolean
123   :group 'notmuch-show)
124
125 (defcustom notmuch-show-indent-messages-width 1
126   "Width of message indentation in threads.
127
128 Messages are shown indented according to their depth in a thread.
129 This variable determines the width of this indentation measured
130 in number of blanks.  Defaults to `1', choose `0' to disable
131 indentation."
132   :type 'integer
133   :group 'notmuch-show)
134
135 (defcustom notmuch-show-indent-multipart nil
136   "Should the sub-parts of a multipart/* part be indented?"
137   ;; dme: Not sure which is a good default.
138   :type 'boolean
139   :group 'notmuch-show)
140
141 (defcustom notmuch-show-part-button-default-action 'notmuch-show-save-part
142   "Default part header button action (on ENTER or mouse click)."
143   :group 'notmuch-show
144   :type '(choice (const :tag "Save part"
145                         notmuch-show-save-part)
146                  (const :tag "View part"
147                         notmuch-show-view-part)
148                  (const :tag "View interactively"
149                         notmuch-show-interactively-view-part)))
150
151 (defcustom notmuch-show-only-matching-messages nil
152   "Only matching messages are shown by default."
153   :type 'boolean
154   :group 'notmuch-show)
155
156 ;; By default, block all external images to prevent privacy leaks and
157 ;; potential attacks.
158 (defcustom notmuch-show-text/html-blocked-images "."
159   "Remote images that have URLs matching this regexp will be blocked."
160   :type '(choice (const nil) regexp)
161   :group 'notmuch-show)
162
163 (defvar notmuch-show-thread-id nil)
164 (make-variable-buffer-local 'notmuch-show-thread-id)
165
166 (defvar notmuch-show-parent-buffer nil)
167 (make-variable-buffer-local 'notmuch-show-parent-buffer)
168
169 (defvar notmuch-show-query-context nil)
170 (make-variable-buffer-local 'notmuch-show-query-context)
171
172 (defvar notmuch-show-process-crypto nil)
173 (make-variable-buffer-local 'notmuch-show-process-crypto)
174
175 (defvar notmuch-show-elide-non-matching-messages nil)
176 (make-variable-buffer-local 'notmuch-show-elide-non-matching-messages)
177
178 (defvar notmuch-show-indent-content t)
179 (make-variable-buffer-local 'notmuch-show-indent-content)
180
181 (defvar notmuch-show-attachment-debug nil
182   "If t log stdout and stderr from attachment handlers
183
184 When set to nil (the default) stdout and stderr from attachment
185 handlers is discarded. When set to t the stdout and stderr from
186 each attachment handler is logged in buffers with names beginning
187 \" *notmuch-part*\". This option requires emacs version at least
188 24.3 to work.")
189
190 (defcustom notmuch-show-stash-mlarchive-link-alist
191   '(("Gmane" . "https://mid.gmane.org/")
192     ("MARC" . "https://marc.info/?i=")
193     ("Mail Archive, The" . "https://mid.mail-archive.com/")
194     ("LKML" . "https://lkml.kernel.org/r/")
195     ;; FIXME: can these services be searched by `Message-Id' ?
196     ;; ("MarkMail" . "http://markmail.org/")
197     ;; ("Nabble" . "http://nabble.com/")
198     ;; ("opensubscriber" . "http://opensubscriber.com/")
199     )
200   "List of Mailing List Archives to use when stashing links.
201
202 This list is used for generating a Mailing List Archive reference
203 URI with the current message's Message-Id in
204 `notmuch-show-stash-mlarchive-link'.
205
206 If the cdr of the alist element is not a function, the cdr is
207 expected to contain a URI that is concatenated with the current
208 message's Message-Id to create a ML archive reference URI.
209
210 If the cdr is a function, the function is called with the
211 Message-Id as the argument, and the function is expected to
212 return the ML archive reference URI."
213   :type '(alist :key-type (string :tag "Name")
214                 :value-type (choice
215                              (string :tag "URL")
216                              (function :tag "Function returning the URL")))
217   :group 'notmuch-show)
218
219 (defcustom notmuch-show-stash-mlarchive-link-default "Gmane"
220   "Default Mailing List Archive to use when stashing links.
221
222 This is used when `notmuch-show-stash-mlarchive-link' isn't
223 provided with an MLA argument nor `completing-read' input."
224   :type `(choice
225           ,@(mapcar
226              (lambda (mla)
227                (list 'const :tag (car mla) :value (car mla)))
228              notmuch-show-stash-mlarchive-link-alist))
229   :group 'notmuch-show)
230
231 (defcustom notmuch-show-mark-read-tags '("-unread")
232   "List of tag changes to apply to a message when it is marked as read.
233
234 Tags starting with \"+\" (or not starting with either \"+\" or
235 \"-\") in the list will be added, and tags starting with \"-\"
236 will be removed from the message being marked as read.
237
238 For example, if you wanted to remove an \"unread\" tag and add a
239 \"read\" tag (which would make little sense), you would set:
240     (\"-unread\" \"+read\")"
241   :type '(repeat string)
242   :group 'notmuch-show)
243
244 (defcustom notmuch-show-mark-read-function #'notmuch-show-seen-current-message
245   "Function to control which messages are marked read.
246
247 The function should take two arguments START and END which will
248 be the start and end of the visible portion of the buffer and
249 should mark the appropriate messages read by applying
250 `notmuch-show-mark-read'. This function will be called after
251 every user interaction with notmuch."
252   :type 'function
253   :group 'notmuch-show)
254
255 (defcustom notmuch-show-imenu-indent nil
256   "Should Imenu display messages indented.
257
258 By default, Imenu (see Info node `(emacs) Imenu') in a
259 notmuch-show buffer displays all messages straight.  This is
260 because the default Emacs frontend for Imenu makes it difficult
261 to select an Imenu entry with spaces in front.  Other imenu
262 frontends such as counsel-imenu does not have this limitation.
263 In these cases, Imenu entries can be indented to reflect the
264 position of the message in the thread."
265   :type 'boolean
266   :group 'notmuch-show)
267
268 (defmacro with-current-notmuch-show-message (&rest body)
269   "Evaluate body with current buffer set to the text of current message"
270   `(save-excursion
271      (let ((id (notmuch-show-get-message-id)))
272        (let ((buf (generate-new-buffer (concat "*notmuch-msg-" id "*"))))
273          (with-current-buffer buf
274            (let ((coding-system-for-read 'no-conversion))
275              (call-process notmuch-command nil t nil "show" "--format=raw" id))
276            ,@body)
277          (kill-buffer buf)))))
278
279 (defun notmuch-show-turn-on-visual-line-mode ()
280   "Enable Visual Line mode."
281   (visual-line-mode t))
282
283 ;; DEPRECATED in Notmuch 0.16 since we now have convenient part
284 ;; commands.  We'll keep the command around for a version or two in
285 ;; case people want to bind it themselves.
286 (defun notmuch-show-view-all-mime-parts ()
287   "Use external viewers to view all attachments from the current message."
288   (interactive)
289   (with-current-notmuch-show-message
290    ;; We override the mm-inline-media-tests to indicate which message
291    ;; parts are already sufficiently handled by the original
292    ;; presentation of the message in notmuch-show mode. These parts
293    ;; will be inserted directly into the temporary buffer of
294    ;; with-current-notmuch-show-message and silently discarded.
295    ;;
296    ;; Any MIME part not explicitly mentioned here will be handled by an
297    ;; external viewer as configured in the various mailcap files.
298    (let ((mm-inline-media-tests '(
299                                   ("text/.*" ignore identity)
300                                   ("application/pgp-signature" ignore identity)
301                                   ("multipart/alternative" ignore identity)
302                                   ("multipart/mixed" ignore identity)
303                                   ("multipart/related" ignore identity)
304                                  )))
305      (mm-display-parts (mm-dissect-buffer)))))
306
307 (defun notmuch-show-save-attachments ()
308   "Save all attachments from the current message."
309   (interactive)
310   (with-current-notmuch-show-message
311    (let ((mm-handle (mm-dissect-buffer)))
312      (notmuch-save-attachments
313       mm-handle (> (notmuch-count-attachments mm-handle) 1))))
314   (message "Done"))
315
316 (defun notmuch-show-with-message-as-text (fn)
317   "Apply FN to a text representation of the current message.
318
319 FN is called with one argument, the message properties. It should
320 operation on the contents of the current buffer."
321
322   ;; Remake the header to ensure that all information is available.
323   (let* ((to (notmuch-show-get-to))
324          (cc (notmuch-show-get-cc))
325          (from (notmuch-show-get-from))
326          (subject (notmuch-show-get-subject))
327          (date (notmuch-show-get-date))
328          (tags (notmuch-show-get-tags))
329          (depth (notmuch-show-get-depth))
330
331          (header (concat
332                   "Subject: " subject "\n"
333                   "To: " to "\n"
334                   (if (not (string= cc ""))
335                       (concat "Cc: " cc "\n")
336                     "")
337                   "From: " from "\n"
338                   "Date: " date "\n"
339                   (if tags
340                       (concat "Tags: "
341                               (mapconcat #'identity tags ", ") "\n")
342                     "")))
343          (all (buffer-substring (notmuch-show-message-top)
344                                 (notmuch-show-message-bottom)))
345
346          (props (notmuch-show-get-message-properties))
347          (indenting notmuch-show-indent-content))
348     (with-temp-buffer
349       (insert all)
350       (if indenting
351           (indent-rigidly (point-min) (point-max) (- (* notmuch-show-indent-messages-width depth))))
352       ;; Remove the original header.
353       (goto-char (point-min))
354       (re-search-forward "^$" (point-max) nil)
355       (delete-region (point-min) (point))
356       (insert header)
357       (funcall fn props))))
358
359 (defun notmuch-show-print-message ()
360   "Print the current message."
361   (interactive)
362   (notmuch-show-with-message-as-text 'notmuch-print-message))
363
364 (defun notmuch-show-fontify-header ()
365   (let ((face (cond
366                ((looking-at "[Tt]o:")
367                 'message-header-to)
368                ((looking-at "[Bb]?[Cc][Cc]:")
369                 'message-header-cc)
370                ((looking-at "[Ss]ubject:")
371                 'message-header-subject)
372                (t
373                 'message-header-other))))
374
375     (overlay-put (make-overlay (point) (re-search-forward ":"))
376                  'face 'message-header-name)
377     (overlay-put (make-overlay (point) (re-search-forward ".*$"))
378                  'face face)))
379
380 (defun notmuch-show-colour-headers ()
381   "Apply some colouring to the current headers."
382   (goto-char (point-min))
383   (while (looking-at "^[A-Za-z][-A-Za-z0-9]*:")
384     (notmuch-show-fontify-header)
385     (forward-line)))
386
387 (defun notmuch-show-spaces-n (n)
388   "Return a string comprised of `n' spaces."
389   (make-string n ? ))
390
391 (defun notmuch-show-update-tags (tags)
392   "Update the displayed tags of the current message."
393   (save-excursion
394     (goto-char (notmuch-show-message-top))
395     (if (re-search-forward "(\\([^()]*\\))$" (line-end-position) t)
396         (let ((inhibit-read-only t))
397           (replace-match (concat "("
398                                  (notmuch-tag-format-tags tags (notmuch-show-get-prop :orig-tags))
399                                  ")"))))))
400
401 (defun notmuch-clean-address (address)
402   "Try to clean a single email ADDRESS for display. Return a cons
403 cell of (AUTHOR_EMAIL AUTHOR_NAME). Return (ADDRESS nil) if
404 parsing fails."
405   (condition-case nil
406     (let (p-name p-address)
407       ;; It would be convenient to use `mail-header-parse-address',
408       ;; but that expects un-decoded mailbox parts, whereas our
409       ;; mailbox parts are already decoded (and hence may contain
410       ;; UTF-8). Given that notmuch should handle most of the awkward
411       ;; cases, some simple string deconstruction should be sufficient
412       ;; here.
413       (cond
414        ;; "User <user@dom.ain>" style.
415        ((string-match "\\(.*\\) <\\(.*\\)>" address)
416         (setq p-name (match-string 1 address)
417               p-address (match-string 2 address)))
418
419        ;; "<user@dom.ain>" style.
420        ((string-match "<\\(.*\\)>" address)
421         (setq p-address (match-string 1 address)))
422
423        ;; Everything else.
424        (t
425         (setq p-address address)))
426
427       (when p-name
428         ;; Remove elements of the mailbox part that are not relevant for
429         ;; display, even if they are required during transport:
430         ;;
431         ;; Backslashes.
432         (setq p-name (replace-regexp-in-string "\\\\" "" p-name))
433
434         ;; Outer single and double quotes, which might be nested.
435         (cl-loop with start-of-loop
436                  do (setq start-of-loop p-name)
437
438                  when (string-match "^\"\\(.*\\)\"$" p-name)
439                  do (setq p-name (match-string 1 p-name))
440
441                  when (string-match "^'\\(.*\\)'$" p-name)
442                  do (setq p-name (match-string 1 p-name))
443
444                  until (string= start-of-loop p-name)))
445
446       ;; If the address is 'foo@bar.com <foo@bar.com>' then show just
447       ;; 'foo@bar.com'.
448       (when (string= p-name p-address)
449         (setq p-name nil))
450
451       (cons p-address p-name))
452     (error (cons address nil))))
453
454 (defun notmuch-show-clean-address (address)
455   "Try to clean a single email ADDRESS for display.  Return
456 unchanged ADDRESS if parsing fails."
457   (let* ((clean-address (notmuch-clean-address address))
458          (p-address (car clean-address))
459          (p-name (cdr clean-address)))
460     ;; If no name, return just the address.
461     (if (not p-name)
462         p-address
463       ;; Otherwise format the name and address together.
464       (concat p-name " <" p-address ">"))))
465
466 (defun notmuch-show-insert-headerline (headers date tags depth)
467   "Insert a notmuch style headerline based on HEADERS for a
468 message at DEPTH in the current thread."
469   (let ((start (point)))
470     (insert (notmuch-show-spaces-n (* notmuch-show-indent-messages-width depth))
471             (notmuch-sanitize
472              (notmuch-show-clean-address (plist-get headers :From)))
473             " ("
474             date
475             ") ("
476             (notmuch-tag-format-tags tags tags)
477             ")\n")
478     (overlay-put (make-overlay start (point)) 'face 'notmuch-message-summary-face)))
479
480 (defun notmuch-show-insert-header (header header-value)
481   "Insert a single header."
482   (insert header ": " (notmuch-sanitize header-value) "\n"))
483
484 (defun notmuch-show-insert-headers (headers)
485   "Insert the headers of the current message."
486   (let ((start (point)))
487     (mapc (lambda (header)
488             (let* ((header-symbol (intern (concat ":" header)))
489                    (header-value (plist-get headers header-symbol)))
490               (if (and header-value
491                        (not (string-equal "" header-value)))
492                   (notmuch-show-insert-header header header-value))))
493           notmuch-message-headers)
494     (save-excursion
495       (save-restriction
496         (narrow-to-region start (point-max))
497         (run-hooks 'notmuch-show-markup-headers-hook)))))
498
499 (define-button-type 'notmuch-show-part-button-type
500   'action 'notmuch-show-part-button-default
501   'follow-link t
502   'face 'message-mml
503   :supertype 'notmuch-button-type)
504
505 (defun notmuch-show-insert-part-header (nth content-type declared-type &optional name comment)
506   (let ((button)
507         (base-label (concat (when name (concat name ": "))
508                             declared-type
509                             (unless (string-equal declared-type content-type)
510                               (concat " (as " content-type ")"))
511                             comment)))
512
513     (setq button
514           (insert-button
515            (concat "[ " base-label " ]")
516            :base-label base-label
517            :type 'notmuch-show-part-button-type
518            :notmuch-part-hidden nil))
519     (insert "\n")
520     ;; return button
521     button))
522
523 (defun notmuch-show-toggle-part-invisibility (&optional button)
524   (interactive)
525   (let ((button (or button (button-at (point)))))
526     (when button
527       (let ((overlay (button-get button 'overlay))
528             (lazy-part (button-get button :notmuch-lazy-part)))
529         ;; We have a part to toggle if there is an overlay or if there is a lazy part.
530         ;; If neither is present we cannot toggle the part so we just return nil.
531         (when (or overlay lazy-part)
532           (let* ((show (button-get button :notmuch-part-hidden))
533                  (new-start (button-start button))
534                  (button-label (button-get button :base-label))
535                  (old-point (point))
536                  (properties (text-properties-at (button-start button)))
537                  (inhibit-read-only t))
538             ;; Toggle the button itself.
539             (button-put button :notmuch-part-hidden (not show))
540             (goto-char new-start)
541             (insert "[ " button-label (if show " ]" " (hidden) ]"))
542             (set-text-properties new-start (point) properties)
543             (let ((old-end (button-end button)))
544               (move-overlay button new-start (point))
545               (delete-region (point) old-end))
546             (goto-char (min old-point (1- (button-end button))))
547             ;; Return nil if there is a lazy-part, it is empty, and we are
548             ;; trying to show it.  In all other cases return t.
549             (if lazy-part
550                 (when show
551                   (button-put button :notmuch-lazy-part nil)
552                   (notmuch-show-lazy-part lazy-part button))
553               ;; else there must be an overlay.
554               (overlay-put overlay 'invisible (not show))
555               t)))))))
556
557 ;; Part content ID handling
558
559 (defvar notmuch-show--cids nil
560   "Alist from raw content ID to (MSG PART).")
561 (make-variable-buffer-local 'notmuch-show--cids)
562
563 (defun notmuch-show--register-cids (msg part)
564   "Register content-IDs in PART and all of PART's sub-parts."
565   (let ((content-id (plist-get part :content-id)))
566     (when content-id
567       ;; Note that content-IDs are globally unique, except when they
568       ;; aren't: RFC 2046 section 5.1.4 permits children of a
569       ;; multipart/alternative to have the same content-ID, in which
570       ;; case the MUA is supposed to pick the best one it can render.
571       ;; We simply add the content-ID to the beginning of our alist;
572       ;; so if this happens, we'll take the last (and "best")
573       ;; alternative (even if we can't render it).
574       (push (list content-id msg part) notmuch-show--cids)))
575   ;; Recurse on sub-parts
576   (let ((ctype (notmuch-split-content-type
577                 (downcase (plist-get part :content-type)))))
578     (cond ((equal (car ctype) "multipart")
579            (mapc (apply-partially #'notmuch-show--register-cids msg)
580                  (plist-get part :content)))
581           ((equal ctype '("message" "rfc822"))
582            (notmuch-show--register-cids
583             msg
584             (car (plist-get (car (plist-get part :content)) :body)))))))
585
586 (defun notmuch-show--get-cid-content (cid)
587   "Return a list (CID-content content-type) or nil.
588
589 This will only find parts from messages that have been inserted
590 into the current buffer.  CID must be a raw content ID, without
591 enclosing angle brackets, a cid: prefix, or URL encoding.  This
592 will return nil if the CID is unknown or cannot be retrieved."
593   (let ((descriptor (cdr (assoc cid notmuch-show--cids))))
594     (when descriptor
595       (let* ((msg (car descriptor))
596              (part (cadr descriptor))
597              ;; Request caching for this content, as some messages
598              ;; reference the same cid: part many times (hundreds!).
599              (content (notmuch-get-bodypart-binary
600                        msg part notmuch-show-process-crypto 'cache))
601              (content-type (plist-get part :content-type)))
602         (list content content-type)))))
603
604 (defun notmuch-show-setup-w3m ()
605   "Instruct w3m how to retrieve content from a \"related\" part of a message."
606   (interactive)
607   (if (boundp 'w3m-cid-retrieve-function-alist)
608     (unless (assq 'notmuch-show-mode w3m-cid-retrieve-function-alist)
609       (push (cons 'notmuch-show-mode #'notmuch-show--cid-w3m-retrieve)
610             w3m-cid-retrieve-function-alist)))
611   (setq mm-html-inhibit-images nil))
612
613 (defvar w3m-current-buffer) ;; From `w3m.el'.
614 (defun notmuch-show--cid-w3m-retrieve (url &rest args)
615   ;; url includes the cid: prefix and is URL encoded (see RFC 2392).
616   (let* ((cid (url-unhex-string (substring url 4)))
617          (content-and-type
618           (with-current-buffer w3m-current-buffer
619             (notmuch-show--get-cid-content cid))))
620     (when content-and-type
621       (insert (car content-and-type))
622       (cadr content-and-type))))
623
624 ;; MIME part renderers
625
626 (defun notmuch-show-multipart/*-to-list (part)
627   (mapcar (lambda (inner-part) (plist-get inner-part :content-type))
628           (plist-get part :content)))
629
630 (defun notmuch-show-insert-part-multipart/alternative (msg part content-type nth depth button)
631   (let ((chosen-type (car (notmuch-multipart/alternative-choose msg (notmuch-show-multipart/*-to-list part))))
632         (inner-parts (plist-get part :content))
633         (start (point)))
634     ;; This inserts all parts of the chosen type rather than just one,
635     ;; but it's not clear that this is the wrong thing to do - which
636     ;; should be chosen if there are more than one that match?
637     (mapc (lambda (inner-part)
638             (let* ((inner-type (plist-get inner-part :content-type))
639                   (hide (not (or notmuch-show-all-multipart/alternative-parts
640                            (string= chosen-type inner-type)))))
641               (notmuch-show-insert-bodypart msg inner-part depth hide)))
642           inner-parts)
643
644     (when notmuch-show-indent-multipart
645       (indent-rigidly start (point) 1)))
646   t)
647
648 (defun notmuch-show-insert-part-multipart/related (msg part content-type nth depth button)
649   (let ((inner-parts (plist-get part :content))
650         (start (point)))
651
652     ;; Render the primary part.  FIXME: Support RFC 2387 Start header.
653     (notmuch-show-insert-bodypart msg (car inner-parts) depth)
654     ;; Add hidden buttons for the rest
655     (mapc (lambda (inner-part)
656             (notmuch-show-insert-bodypart msg inner-part depth t))
657           (cdr inner-parts))
658
659     (when notmuch-show-indent-multipart
660       (indent-rigidly start (point) 1)))
661   t)
662
663 (defun notmuch-show-insert-part-multipart/signed (msg part content-type nth depth button)
664   (when button
665     (button-put button 'face 'notmuch-crypto-part-header))
666
667   ;; Insert a button detailing the signature status.
668   (notmuch-crypto-insert-sigstatus-button (car (plist-get part :sigstatus))
669                                           (notmuch-show-get-header :From msg))
670
671   (let ((inner-parts (plist-get part :content))
672         (start (point)))
673     ;; Show all of the parts.
674     (mapc (lambda (inner-part)
675             (notmuch-show-insert-bodypart msg inner-part depth))
676           inner-parts)
677
678     (when notmuch-show-indent-multipart
679       (indent-rigidly start (point) 1)))
680   t)
681
682 (defun notmuch-show-insert-part-multipart/encrypted (msg part content-type nth depth button)
683   (when button
684     (button-put button 'face 'notmuch-crypto-part-header))
685
686   ;; Insert a button detailing the encryption status.
687   (notmuch-crypto-insert-encstatus-button (car (plist-get part :encstatus)))
688
689   ;; Insert a button detailing the signature status.
690   (notmuch-crypto-insert-sigstatus-button (car (plist-get part :sigstatus))
691                                           (notmuch-show-get-header :From msg))
692
693   (let ((inner-parts (plist-get part :content))
694         (start (point)))
695     ;; Show all of the parts.
696     (mapc (lambda (inner-part)
697             (notmuch-show-insert-bodypart msg inner-part depth))
698           inner-parts)
699
700     (when notmuch-show-indent-multipart
701       (indent-rigidly start (point) 1)))
702   t)
703
704 (defun notmuch-show-insert-part-application/pgp-encrypted (msg part content-type nth depth button)
705   t)
706
707 (defun notmuch-show-insert-part-multipart/* (msg part content-type nth depth button)
708   (let ((inner-parts (plist-get part :content))
709         (start (point)))
710     ;; Show all of the parts.
711     (mapc (lambda (inner-part)
712             (notmuch-show-insert-bodypart msg inner-part depth))
713           inner-parts)
714
715     (when notmuch-show-indent-multipart
716       (indent-rigidly start (point) 1)))
717   t)
718
719 (defun notmuch-show-insert-part-message/rfc822 (msg part content-type nth depth button)
720   (let* ((message (car (plist-get part :content)))
721          (body (car (plist-get message :body)))
722          (start (point)))
723
724     ;; Override `notmuch-message-headers' to force `From' to be
725     ;; displayed.
726     (let ((notmuch-message-headers '("From" "Subject" "To" "Cc" "Date")))
727       (notmuch-show-insert-headers (plist-get message :headers)))
728
729     ;; Blank line after headers to be compatible with the normal
730     ;; message display.
731     (insert "\n")
732
733     ;; Show the body
734     (notmuch-show-insert-bodypart msg body depth)
735
736     (when notmuch-show-indent-multipart
737       (indent-rigidly start (point) 1)))
738   t)
739
740 (defun notmuch-show-insert-part-text/plain (msg part content-type nth depth button)
741   ;; For backward compatibility we want to apply the text/plain hook
742   ;; to the whole of the part including the part button if there is
743   ;; one.
744   (let ((start (if button
745                    (button-start button)
746                  (point))))
747     (insert (notmuch-get-bodypart-text msg part notmuch-show-process-crypto))
748     (save-excursion
749       (save-restriction
750         (narrow-to-region start (point-max))
751         (run-hook-with-args 'notmuch-show-insert-text/plain-hook msg depth))))
752   t)
753
754 (defun notmuch-show-insert-part-text/calendar (msg part content-type nth depth button)
755   (insert (with-temp-buffer
756             (insert (notmuch-get-bodypart-text msg part notmuch-show-process-crypto))
757             ;; notmuch-get-bodypart-text does no newline conversion.
758             ;; Replace CRLF with LF before icalendar can use it.
759             (goto-char (point-min))
760             (while (re-search-forward "\r\n" nil t)
761               (replace-match "\n" nil nil))
762             (let ((file (make-temp-file "notmuch-ical"))
763                   result)
764               (unwind-protect
765                   (progn
766                     (unless (icalendar-import-buffer file t)
767                       (error "Icalendar import error. See *icalendar-errors* for more information"))
768                     (set-buffer (get-file-buffer file))
769                     (setq result (buffer-substring (point-min) (point-max)))
770                     (set-buffer-modified-p nil)
771                     (kill-buffer (current-buffer)))
772                 (delete-file file))
773               result)))
774   t)
775
776 ;; For backwards compatibility.
777 (defun notmuch-show-insert-part-text/x-vcalendar (msg part content-type nth depth button)
778   (notmuch-show-insert-part-text/calendar msg part content-type nth depth button))
779
780 (if (version< emacs-version "25.3")
781     ;; https://bugs.gnu.org/28350
782     ;;
783     ;; For newer emacs, we fall back to notmuch-show-insert-part-*/*
784     ;; (see notmuch-show-handlers-for)
785     (defun notmuch-show-insert-part-text/enriched (msg part content-type nth depth button)
786       ;; By requiring enriched below, we ensure that the function enriched-decode-display-prop
787       ;; is defined before it will be shadowed by the letf below. Otherwise the version
788       ;; in enriched.el may be loaded a bit later and used instead (for the first time).
789       (require 'enriched)
790       (cl-letf (((symbol-function 'enriched-decode-display-prop)
791                  (lambda (start end &optional param) (list start end))))
792         (notmuch-show-insert-part-*/* msg part content-type nth depth button))))
793
794 (defun notmuch-show-get-mime-type-of-application/octet-stream (part)
795   ;; If we can deduce a MIME type from the filename of the attachment,
796   ;; we return that.
797   (if (plist-get part :filename)
798       (let ((extension (file-name-extension (plist-get part :filename)))
799             mime-type)
800         (if extension
801             (progn
802               (mailcap-parse-mimetypes)
803               (setq mime-type (mailcap-extension-to-mime extension))
804               (if (and mime-type
805                        (not (string-equal mime-type "application/octet-stream")))
806                   mime-type
807                 nil))
808           nil))))
809
810 (defun notmuch-show-insert-part-text/html (msg part content-type nth depth button)
811   (if (eq mm-text-html-renderer 'shr)
812       ;; It's easier to drive shr ourselves than to work around the
813       ;; goofy things `mm-shr' does (like irreversibly taking over
814       ;; content ID handling).
815
816       ;; FIXME: If we block an image, offer a button to load external
817       ;; images.
818       (let ((shr-blocked-images notmuch-show-text/html-blocked-images))
819         (notmuch-show--insert-part-text/html-shr msg part))
820     ;; Otherwise, let message-mode do the heavy lifting
821     ;;
822     ;; w3m sets up a keymap which "leaks" outside the invisible region
823     ;; and causes strange effects in notmuch. We set
824     ;; mm-inline-text-html-with-w3m-keymap to nil to tell w3m not to
825     ;; set a keymap (so the normal notmuch-show-mode-map remains).
826     (let ((mm-inline-text-html-with-w3m-keymap nil)
827           ;; FIXME: If we block an image, offer a button to load external
828           ;; images.
829           (gnus-blocked-images notmuch-show-text/html-blocked-images))
830       (notmuch-show-insert-part-*/* msg part content-type nth depth button))))
831
832 ;; These functions are used by notmuch-show--insert-part-text/html-shr
833 (declare-function libxml-parse-html-region "xml.c")
834 (declare-function shr-insert-document "shr")
835
836 (defun notmuch-show--insert-part-text/html-shr (msg part)
837   ;; Make sure shr is loaded before we start let-binding its globals
838   (require 'shr)
839   (let ((dom (let ((process-crypto notmuch-show-process-crypto))
840                (with-temp-buffer
841                  (insert (notmuch-get-bodypart-text msg part process-crypto))
842                  (libxml-parse-html-region (point-min) (point-max)))))
843         (shr-content-function
844          (lambda (url)
845            ;; shr strips the "cid:" part of URL, but doesn't
846            ;; URL-decode it (see RFC 2392).
847            (let ((cid (url-unhex-string url)))
848              (car (notmuch-show--get-cid-content cid))))))
849     (shr-insert-document dom)
850     t))
851
852 (defun notmuch-show-insert-part-*/* (msg part content-type nth depth button)
853   ;; This handler _must_ succeed - it is the handler of last resort.
854   (notmuch-mm-display-part-inline msg part content-type notmuch-show-process-crypto)
855   t)
856
857 ;; Functions for determining how to handle MIME parts.
858
859 (defun notmuch-show-handlers-for (content-type)
860   "Return a list of content handlers for a part of type CONTENT-TYPE."
861   (let (result)
862     (mapc (lambda (func)
863             (if (functionp func)
864                 (push func result)))
865           ;; Reverse order of prefrence.
866           (list (intern (concat "notmuch-show-insert-part-*/*"))
867                 (intern (concat
868                          "notmuch-show-insert-part-"
869                          (car (notmuch-split-content-type content-type))
870                          "/*"))
871                 (intern (concat "notmuch-show-insert-part-" content-type))))
872     result))
873
874 ;; \f
875
876 (defun notmuch-show-insert-bodypart-internal (msg part content-type nth depth button)
877   ;; Run the handlers until one of them succeeds.
878   (cl-loop for handler in (notmuch-show-handlers-for content-type)
879            until (condition-case err
880                      (funcall handler msg part content-type nth depth button)
881                    ;; Specifying `debug' here lets the debugger run if
882                    ;; `debug-on-error' is non-nil.
883                    ((debug error)
884                     (insert "!!! Bodypart handler `" (prin1-to-string handler)
885                             "' threw an error:\n"
886                             "!!! " (error-message-string err) "\n")
887                     nil))))
888
889 (defun notmuch-show-create-part-overlays (button beg end)
890   "Add an overlay to the part between BEG and END"
891
892   ;; If there is no button (i.e., the part is text/plain and the first
893   ;; part) or if the part has no content then we don't make the part
894   ;; toggleable.
895   (when (and button (/= beg end))
896     (button-put button 'overlay (make-overlay beg end))
897     ;; Return true if we created an overlay.
898     t))
899
900 (defun notmuch-show-record-part-information (part beg end)
901   "Store PART as a text property from BEG to END"
902
903   ;; Record part information.  Since we already inserted subparts,
904   ;; don't override existing :notmuch-part properties.
905   (notmuch-map-text-property beg end :notmuch-part
906                              (lambda (v) (or v part)))
907   ;; Make :notmuch-part front sticky and rear non-sticky so it stays
908   ;; applied to the beginning of each line when we indent the
909   ;; message.  Since we're operating on arbitrary renderer output,
910   ;; watch out for sticky specs of t, which means all properties are
911   ;; front-sticky/rear-nonsticky.
912   (notmuch-map-text-property beg end 'front-sticky
913                              (lambda (v)
914                                (if (listp v)
915                                    (cl-pushnew :notmuch-part v)
916                                  v)))
917   (notmuch-map-text-property beg end 'rear-nonsticky
918                              (lambda (v)
919                                (if (listp v)
920                                    (cl-pushnew :notmuch-part v)
921                                  v))))
922
923 (defun notmuch-show-lazy-part (part-args button)
924   ;; Insert the lazy part after the button for the part. We would just
925   ;; move to the start of the new line following the button and insert
926   ;; the part but that point might have text properties (eg colours
927   ;; from a message header etc) so instead we start from the last
928   ;; character of the button by adding a newline and finish by
929   ;; removing the extra newline from the end of the part.
930   (save-excursion
931     (goto-char (button-end button))
932     (insert "\n")
933     (let* ((inhibit-read-only t)
934            ;; We need to use markers for the start and end of the part
935            ;; because the part insertion functions do not guarantee
936            ;; to leave point at the end of the part.
937            (part-beg (copy-marker (point) nil))
938            (part-end (copy-marker (point) t))
939            ;; We have to save the depth as we can't find the depth
940            ;; when narrowed.
941            (depth (notmuch-show-get-depth)))
942       (save-restriction
943         (narrow-to-region part-beg part-end)
944         (delete-region part-beg part-end)
945         (apply #'notmuch-show-insert-bodypart-internal part-args)
946         (indent-rigidly part-beg part-end (* notmuch-show-indent-messages-width depth)))
947       (goto-char part-end)
948       (delete-char 1)
949       (notmuch-show-record-part-information (cadr part-args)
950                                             (button-start button)
951                                             part-end)
952       ;; Create the overlay. If the lazy-part turned out to be empty/not
953       ;; showable this returns nil.
954       (notmuch-show-create-part-overlays button part-beg part-end))))
955
956 (defun notmuch-show-mime-type (part)
957   "Return the correct mime-type to use for PART."
958   (let ((content-type (downcase (plist-get part :content-type))))
959     (or (and (string= content-type "application/octet-stream")
960              (notmuch-show-get-mime-type-of-application/octet-stream part))
961         (and (string= content-type "inline patch")
962              "text/x-diff")
963         content-type)))
964
965 ;; The following variable can be overridden by let bindings.
966 (defvar notmuch-show-insert-header-p-function 'notmuch-show-insert-header-p
967   "Specify which function decides which part headers get inserted.
968
969 The function should take two parameters, PART and HIDE, and
970 should return non-NIL if a header button should be inserted for
971 this part.")
972
973 (defun notmuch-show-insert-header-p (part hide)
974   ;; Show all part buttons except for the first part if it is text/plain.
975   (let ((mime-type (notmuch-show-mime-type part)))
976     (not (and (string= mime-type "text/plain")
977               (<= (plist-get part :id) 1)))))
978
979 (defun notmuch-show-reply-insert-header-p-never (part hide)
980   nil)
981
982 (defun notmuch-show-reply-insert-header-p-trimmed (part hide)
983   (let ((mime-type (notmuch-show-mime-type part)))
984     (and (not (notmuch-match-content-type mime-type "multipart/*"))
985          (not hide))))
986
987 (defun notmuch-show-reply-insert-header-p-minimal (part hide)
988   (let ((mime-type (notmuch-show-mime-type part)))
989     (and (notmuch-match-content-type mime-type "text/*")
990          (not hide))))
991
992 (defun notmuch-show-insert-bodypart (msg part depth &optional hide)
993   "Insert the body part PART at depth DEPTH in the current thread.
994
995 HIDE determines whether to show or hide the part and the button
996 as follows: If HIDE is nil, show the part and the button. If HIDE
997 is t, hide the part initially and show the button."
998
999   (let* ((content-type (downcase (plist-get part :content-type)))
1000          (mime-type (notmuch-show-mime-type part))
1001          (nth (plist-get part :id))
1002          (long (and (notmuch-match-content-type mime-type "text/*")
1003                     (> notmuch-show-max-text-part-size 0)
1004                     (> (length (plist-get part :content)) notmuch-show-max-text-part-size)))
1005          (beg (point))
1006          ;; This default header-p function omits the part button for
1007          ;; the first (or only) part if this is text/plain.
1008          (button (when (funcall notmuch-show-insert-header-p-function part hide)
1009                    (notmuch-show-insert-part-header nth mime-type content-type (plist-get part :filename))))
1010          ;; Hide the part initially if HIDE is t, or if it is too long
1011          ;; and we have a button to allow toggling.
1012          (show-part (not (or (equal hide t)
1013                              (and long button))))
1014          (content-beg (point)))
1015
1016     ;; Store the computed mime-type for later use (e.g. by attachment handlers).
1017     (plist-put part :computed-type mime-type)
1018
1019     (if show-part
1020         (notmuch-show-insert-bodypart-internal msg part mime-type nth depth button)
1021       (when button
1022         (button-put button :notmuch-lazy-part
1023                     (list msg part mime-type nth depth button))))
1024
1025     ;; Some of the body part handlers leave point somewhere up in the
1026     ;; part, so we make sure that we're down at the end.
1027     (goto-char (point-max))
1028     ;; Ensure that the part ends with a carriage return.
1029     (unless (bolp)
1030       (insert "\n"))
1031     ;; We do not create the overlay for hidden (lazy) parts until
1032     ;; they are inserted.
1033     (if show-part
1034         (notmuch-show-create-part-overlays button content-beg (point))
1035       (save-excursion
1036         (notmuch-show-toggle-part-invisibility button)))
1037     (notmuch-show-record-part-information part beg (point))))
1038
1039 (defun notmuch-show-insert-body (msg body depth)
1040   "Insert the body BODY at depth DEPTH in the current thread."
1041
1042   ;; Register all content IDs for this message.  According to RFC
1043   ;; 2392, content IDs are *global*, but it's okay if an MUA treats
1044   ;; them as only global within a message.
1045   (notmuch-show--register-cids msg (car body))
1046
1047   (mapc (lambda (part) (notmuch-show-insert-bodypart msg part depth)) body))
1048
1049 (defun notmuch-show-make-symbol (type)
1050   (make-symbol (concat "notmuch-show-" type)))
1051
1052 (defun notmuch-show-strip-re (string)
1053   (replace-regexp-in-string "^\\([Rr]e: *\\)+" "" string))
1054
1055 (defvar notmuch-show-previous-subject "")
1056 (make-variable-buffer-local 'notmuch-show-previous-subject)
1057
1058 (defun notmuch-show-insert-msg (msg depth)
1059   "Insert the message MSG at depth DEPTH in the current thread."
1060   (let* ((headers (plist-get msg :headers))
1061          ;; Indentation causes the buffer offset of the start/end
1062          ;; points to move, so we must use markers.
1063          message-start message-end
1064          content-start content-end
1065          headers-start headers-end
1066          (bare-subject (notmuch-show-strip-re (plist-get headers :Subject))))
1067
1068     (setq message-start (point-marker))
1069
1070     (notmuch-show-insert-headerline headers
1071                                     (or (if notmuch-show-relative-dates
1072                                             (plist-get msg :date_relative)
1073                                           nil)
1074                                         (plist-get headers :Date))
1075                                     (plist-get msg :tags) depth)
1076
1077     (setq content-start (point-marker))
1078
1079     ;; Set `headers-start' to point after the 'Subject:' header to be
1080     ;; compatible with the existing implementation. This just sets it
1081     ;; to after the first header.
1082     (notmuch-show-insert-headers headers)
1083     (save-excursion
1084       (goto-char content-start)
1085       ;; If the subject of this message is the same as that of the
1086       ;; previous message, don't display it when this message is
1087       ;; collapsed.
1088       (when (not (string= notmuch-show-previous-subject
1089                           bare-subject))
1090         (forward-line 1))
1091       (setq headers-start (point-marker)))
1092     (setq headers-end (point-marker))
1093
1094     (setq notmuch-show-previous-subject bare-subject)
1095
1096     ;; A blank line between the headers and the body.
1097     (insert "\n")
1098     (notmuch-show-insert-body msg (plist-get msg :body)
1099                               (if notmuch-show-indent-content depth 0))
1100     ;; Ensure that the body ends with a newline.
1101     (unless (bolp)
1102       (insert "\n"))
1103     (setq content-end (point-marker))
1104
1105     ;; Indent according to the depth in the thread.
1106     (if notmuch-show-indent-content
1107         (indent-rigidly content-start content-end (* notmuch-show-indent-messages-width depth)))
1108
1109     (setq message-end (point-max-marker))
1110
1111     ;; Save the extents of this message over the whole text of the
1112     ;; message.
1113     (put-text-property message-start message-end :notmuch-message-extent (cons message-start message-end))
1114
1115     ;; Create overlays used to control visibility
1116     (plist-put msg :headers-overlay (make-overlay headers-start headers-end))
1117     (plist-put msg :message-overlay (make-overlay headers-start content-end))
1118
1119     (plist-put msg :depth depth)
1120
1121     ;; Save the properties for this message. Currently this saves the
1122     ;; entire message (augmented it with other stuff), which seems
1123     ;; like overkill. We might save a reduced subset (for example, not
1124     ;; the content).
1125     (notmuch-show-set-message-properties msg)
1126
1127     ;; Set header visibility.
1128     (notmuch-show-headers-visible msg notmuch-message-headers-visible)
1129
1130     ;; Message visibility depends on whether it matched the search
1131     ;; criteria.
1132     (notmuch-show-message-visible msg (and (plist-get msg :match)
1133                                            (not (plist-get msg :excluded))))))
1134
1135 (defun notmuch-show-toggle-process-crypto ()
1136   "Toggle the processing of cryptographic MIME parts."
1137   (interactive)
1138   (setq notmuch-show-process-crypto (not notmuch-show-process-crypto))
1139   (message (if notmuch-show-process-crypto
1140                "Processing cryptographic MIME parts."
1141              "Not processing cryptographic MIME parts."))
1142   (notmuch-show-refresh-view))
1143
1144 (defun notmuch-show-toggle-elide-non-matching ()
1145   "Toggle the display of non-matching messages."
1146   (interactive)
1147   (setq notmuch-show-elide-non-matching-messages (not notmuch-show-elide-non-matching-messages))
1148   (message (if notmuch-show-elide-non-matching-messages
1149                "Showing matching messages only."
1150              "Showing all messages."))
1151   (notmuch-show-refresh-view))
1152
1153 (defun notmuch-show-toggle-thread-indentation ()
1154   "Toggle the indentation of threads."
1155   (interactive)
1156   (setq notmuch-show-indent-content (not notmuch-show-indent-content))
1157   (message (if notmuch-show-indent-content
1158                "Content is indented."
1159              "Content is not indented."))
1160   (notmuch-show-refresh-view))
1161
1162 (defun notmuch-show-insert-tree (tree depth)
1163   "Insert the message tree TREE at depth DEPTH in the current thread."
1164   (let ((msg (car tree))
1165         (replies (cadr tree)))
1166     ;; We test whether there is a message or just some replies.
1167     (when msg
1168       (notmuch-show-insert-msg msg depth))
1169     (notmuch-show-insert-thread replies (1+ depth))))
1170
1171 (defun notmuch-show-insert-thread (thread depth)
1172   "Insert the thread THREAD at depth DEPTH in the current forest."
1173   (mapc (lambda (tree) (notmuch-show-insert-tree tree depth)) thread))
1174
1175 (defun notmuch-show-insert-forest (forest)
1176   "Insert the forest of threads FOREST."
1177   (mapc (lambda (thread) (notmuch-show-insert-thread thread 0)) forest))
1178
1179 (defvar notmuch-id-regexp
1180   (concat
1181    ;; Match the id: prefix only if it begins a word (to disallow, for
1182    ;; example, matching cid:).
1183    "\\<id:\\("
1184    ;; If the term starts with a ", then parse Xapian's quoted boolean
1185    ;; term syntax, which allows for anything as long as embedded
1186    ;; double quotes escaped by doubling them.  We also disallow
1187    ;; newlines (which Xapian allows) to prevent runaway terms.
1188    "\"\\([^\"\n]\\|\"\"\\)*\""
1189    ;; Otherwise, parse Xapian's unquoted syntax, which goes up to the
1190    ;; next space or ).  We disallow [.,;] as the last character
1191    ;; because these are probably part of the surrounding text, and not
1192    ;; part of the id.  This doesn't match single character ids; meh.
1193    "\\|[^\"[:space:])][^[:space:])]*[^])[:space:].,:;?!]"
1194    "\\)")
1195   "The regexp used to match id: links in messages.")
1196
1197 (defvar notmuch-mid-regexp
1198   ;; goto-address-url-regexp matched cid: links, which have the same
1199   ;; grammar as the message ID part of a mid: link.  Construct the
1200   ;; regexp using the same technique as goto-address-url-regexp.
1201   (concat "\\<mid:\\(" thing-at-point-url-path-regexp "\\)")
1202   "The regexp used to match mid: links in messages.
1203
1204 See RFC 2392.")
1205
1206 (defun notmuch-show-buttonise-links (start end)
1207   "Buttonise URLs and mail addresses between START and END.
1208
1209 This also turns id:\"<message id>\"-parts and mid: links into
1210 buttons for a corresponding notmuch search."
1211   (goto-address-fontify-region start end)
1212   (save-excursion
1213     (let (links
1214           (beg-line (progn (goto-char start) (line-beginning-position)))
1215           (end-line (progn (goto-char end) (line-end-position))))
1216       (goto-char beg-line)
1217       (while (re-search-forward notmuch-id-regexp end-line t)
1218         (push (list (match-beginning 0) (match-end 0)
1219                     (match-string-no-properties 0)) links))
1220       (goto-char beg-line)
1221       (while (re-search-forward notmuch-mid-regexp end-line t)
1222         (let* ((mid-cid (match-string-no-properties 1))
1223                (mid (save-match-data
1224                       (string-match "^[^/]*" mid-cid)
1225                       (url-unhex-string (match-string 0 mid-cid)))))
1226           (push (list (match-beginning 0) (match-end 0)
1227                       (notmuch-id-to-query mid)) links)))
1228       (pcase-dolist (`(,beg ,end ,link) links)
1229         ;; Remove the overlay created by goto-address-mode
1230         (remove-overlays beg end 'goto-address t)
1231         (make-text-button beg end
1232                           :type 'notmuch-button-type
1233                           'action `(lambda (arg)
1234                                      (notmuch-show ,link current-prefix-arg))
1235                           'follow-link t
1236                           'help-echo "Mouse-1, RET: search for this message"
1237                           'face goto-address-mail-face)))))
1238
1239 ;;;###autoload
1240 (defun notmuch-show (thread-id &optional elide-toggle parent-buffer query-context buffer-name)
1241   "Run \"notmuch show\" with the given thread ID and display results.
1242
1243 ELIDE-TOGGLE, if non-nil, inverts the default elide behavior.
1244
1245 The optional PARENT-BUFFER is the notmuch-search buffer from
1246 which this notmuch-show command was executed, (so that the
1247 next thread from that buffer can be show when done with this
1248 one).
1249
1250 The optional QUERY-CONTEXT is a notmuch search term. Only
1251 messages from the thread matching this search term are shown if
1252 non-nil.
1253
1254 The optional BUFFER-NAME provides the name of the buffer in
1255 which the message thread is shown. If it is nil (which occurs
1256 when the command is called interactively) the argument to the
1257 function is used.
1258
1259 Returns the buffer containing the messages, or NIL if no messages
1260 matched."
1261   (interactive "sNotmuch show: \nP")
1262   (let ((buffer-name (generate-new-buffer-name
1263                       (or buffer-name
1264                           (concat "*notmuch-" thread-id "*"))))
1265         ;; We override mm-inline-override-types to stop application/*
1266         ;; parts from being displayed unless the user has customized
1267         ;; it themselves.
1268         (mm-inline-override-types
1269          (if (equal mm-inline-override-types
1270                     (eval (car (get 'mm-inline-override-types 'standard-value))))
1271              (cons "application/*" mm-inline-override-types)
1272            mm-inline-override-types)))
1273     (switch-to-buffer (get-buffer-create buffer-name))
1274     ;; No need to track undo information for this buffer.
1275     (setq buffer-undo-list t)
1276
1277     (notmuch-show-mode)
1278
1279     ;; Set various buffer local variables to their appropriate initial
1280     ;; state. Do this after enabling `notmuch-show-mode' so that they
1281     ;; aren't wiped out.
1282     (setq notmuch-show-thread-id thread-id
1283           notmuch-show-parent-buffer parent-buffer
1284           notmuch-show-query-context (if (or (string= query-context "")
1285                                              (string= query-context "*"))
1286                                          nil query-context)
1287
1288           notmuch-show-process-crypto notmuch-crypto-process-mime
1289           ;; If `elide-toggle', invert the default value.
1290           notmuch-show-elide-non-matching-messages
1291           (if elide-toggle
1292               (not notmuch-show-only-matching-messages)
1293             notmuch-show-only-matching-messages))
1294
1295     (add-hook 'post-command-hook #'notmuch-show-command-hook nil t)
1296     (jit-lock-register #'notmuch-show-buttonise-links)
1297
1298     (notmuch-tag-clear-cache)
1299
1300     (let ((inhibit-read-only t))
1301       (if (notmuch-show--build-buffer)
1302           ;; Messages were inserted into the buffer.
1303           (current-buffer)
1304
1305         ;; No messages were inserted - presumably none matched the
1306         ;; query.
1307         (kill-buffer (current-buffer))
1308         (ding)
1309         (message "No messages matched the query!")
1310         nil))))
1311
1312 (defun notmuch-show--build-queries (thread context)
1313   "Return a list of queries to try for this search.
1314
1315 THREAD and CONTEXT are both strings, though CONTEXT may be nil.
1316 When CONTEXT is not nil, the first query is the conjunction of it
1317 and THREAD.  The next query is THREAD alone, and serves as a
1318 fallback if the prior matches no messages."
1319   (let (queries)
1320     (push (list thread) queries)
1321     (if context (push (list thread "and (" context ")") queries))
1322     queries))
1323
1324 (defun notmuch-show--build-buffer (&optional state)
1325   "Display messages matching the current buffer context.
1326
1327 Apply the previously saved STATE if supplied, otherwise show the
1328 first relevant message.
1329
1330 If no messages match the query return NIL."
1331   (let* ((cli-args (cons "--exclude=false"
1332                          (when notmuch-show-elide-non-matching-messages
1333                            (list "--entire-thread=false"))))
1334          (queries (notmuch-show--build-queries
1335                    notmuch-show-thread-id notmuch-show-query-context))
1336          (forest nil)
1337          ;; Must be reset every time we are going to start inserting
1338          ;; messages into the buffer.
1339          (notmuch-show-previous-subject ""))
1340     ;; Use results from the first query that returns some.
1341     (while (and (not forest) queries)
1342       (setq forest (notmuch-query-get-threads
1343                     (append cli-args (list "'") (car queries) (list "'"))))
1344       (setq queries (cdr queries)))
1345     (when forest
1346       (notmuch-show-insert-forest forest)
1347
1348       ;; Store the original tags for each message so that we can
1349       ;; display changes.
1350       (notmuch-show-mapc
1351        (lambda () (notmuch-show-set-prop :orig-tags (notmuch-show-get-tags))))
1352
1353       ;; Set the header line to the subject of the first message.
1354       (setq header-line-format
1355             (replace-regexp-in-string "%" "%%"
1356                                       (notmuch-sanitize
1357                                        (notmuch-show-strip-re
1358                                         (notmuch-show-get-subject)))))
1359
1360       (run-hooks 'notmuch-show-hook)
1361
1362       (if state
1363           (notmuch-show-apply-state state)
1364         ;; With no state to apply, just go to the first message.
1365         (notmuch-show-goto-first-wanted-message)))
1366
1367     ;; Report back to the caller whether any messages matched.
1368     forest))
1369
1370 (defun notmuch-show-capture-state ()
1371   "Capture the state of the current buffer.
1372
1373 This includes:
1374  - the list of open messages,
1375  - the combination of current message id with/for each visible window."
1376   (let* ((win-list (get-buffer-window-list (current-buffer) nil t))
1377          (win-id-combo (mapcar (lambda (win)
1378                                  (with-selected-window win
1379                                    (list win (notmuch-show-get-message-id))))
1380                                win-list)))
1381     (list win-id-combo (notmuch-show-get-message-ids-for-open-messages))))
1382
1383 (defun notmuch-show-get-query ()
1384   "Return the current query in this show buffer"
1385   (if notmuch-show-query-context
1386       (concat notmuch-show-thread-id
1387               " and ("
1388               notmuch-show-query-context
1389               ")")
1390     notmuch-show-thread-id))
1391
1392 (defun notmuch-show-goto-message (msg-id)
1393   "Go to message with msg-id."
1394   (goto-char (point-min))
1395   (unless (cl-loop if (string= msg-id (notmuch-show-get-message-id))
1396                    return t
1397                    until (not (notmuch-show-goto-message-next)))
1398     (goto-char (point-min))
1399     (message "Message-id not found."))
1400   (notmuch-show-message-adjust))
1401
1402 (defun notmuch-show-apply-state (state)
1403   "Apply STATE to the current buffer.
1404
1405 This includes:
1406  - opening the messages previously opened,
1407  - closing all other messages,
1408  - moving to the correct current message in every displayed window."
1409   (let ((win-msg-alist (car state))
1410         (open (cadr state)))
1411
1412     ;; Open those that were open.
1413     (goto-char (point-min))
1414     (cl-loop do (notmuch-show-message-visible (notmuch-show-get-message-properties)
1415                                               (member (notmuch-show-get-message-id) open))
1416              until (not (notmuch-show-goto-message-next)))
1417
1418     (dolist (win-msg-pair win-msg-alist)
1419       (with-selected-window (car win-msg-pair)
1420         ;; Go to the previously open message in this window
1421         (notmuch-show-goto-message (cadr win-msg-pair))))))
1422
1423 (defun notmuch-show-refresh-view (&optional reset-state)
1424   "Refresh the current view.
1425
1426 Refreshes the current view, observing changes in display
1427 preferences. If invoked with a prefix argument (or RESET-STATE is
1428 non-nil) then the state of the buffer (open/closed messages) is
1429 reset based on the original query."
1430   (interactive "P")
1431   (let ((inhibit-read-only t)
1432         (state (unless reset-state
1433                  (notmuch-show-capture-state))))
1434     ;; `erase-buffer' does not seem to remove overlays, which can lead
1435     ;; to weird effects such as remaining images, so remove them
1436     ;; manually.
1437     (remove-overlays)
1438     (erase-buffer)
1439
1440     (unless (notmuch-show--build-buffer state)
1441       ;; No messages were inserted.
1442       (kill-buffer (current-buffer))
1443       (ding)
1444       (message "Refreshing the buffer resulted in no messages!"))))
1445
1446 (defvar notmuch-show-stash-map
1447   (let ((map (make-sparse-keymap)))
1448     (define-key map "c" 'notmuch-show-stash-cc)
1449     (define-key map "d" 'notmuch-show-stash-date)
1450     (define-key map "F" 'notmuch-show-stash-filename)
1451     (define-key map "f" 'notmuch-show-stash-from)
1452     (define-key map "i" 'notmuch-show-stash-message-id)
1453     (define-key map "I" 'notmuch-show-stash-message-id-stripped)
1454     (define-key map "s" 'notmuch-show-stash-subject)
1455     (define-key map "T" 'notmuch-show-stash-tags)
1456     (define-key map "t" 'notmuch-show-stash-to)
1457     (define-key map "l" 'notmuch-show-stash-mlarchive-link)
1458     (define-key map "L" 'notmuch-show-stash-mlarchive-link-and-go)
1459     (define-key map "G" 'notmuch-show-stash-git-send-email)
1460     (define-key map "?" 'notmuch-subkeymap-help)
1461     map)
1462   "Submap for stash commands")
1463 (fset 'notmuch-show-stash-map notmuch-show-stash-map)
1464
1465 (defvar notmuch-show-part-map
1466   (let ((map (make-sparse-keymap)))
1467     (define-key map "s" 'notmuch-show-save-part)
1468     (define-key map "v" 'notmuch-show-view-part)
1469     (define-key map "o" 'notmuch-show-interactively-view-part)
1470     (define-key map "|" 'notmuch-show-pipe-part)
1471     (define-key map "m" 'notmuch-show-choose-mime-of-part)
1472     (define-key map "?" 'notmuch-subkeymap-help)
1473     map)
1474   "Submap for part commands")
1475 (fset 'notmuch-show-part-map notmuch-show-part-map)
1476
1477 (defvar notmuch-show-mode-map
1478   (let ((map (make-sparse-keymap)))
1479     (set-keymap-parent map notmuch-common-keymap)
1480     (define-key map "Z" 'notmuch-tree-from-show-current-query)
1481     (define-key map "U" 'notmuch-unthreaded-from-show-current-query)
1482     (define-key map (kbd "<C-tab>") 'widget-backward)
1483     (define-key map (kbd "M-TAB") 'notmuch-show-previous-button)
1484     (define-key map (kbd "<backtab>") 'notmuch-show-previous-button)
1485     (define-key map (kbd "TAB") 'notmuch-show-next-button)
1486     (define-key map "f" 'notmuch-show-forward-message)
1487     (define-key map "F" 'notmuch-show-forward-open-messages)
1488     (define-key map "b" 'notmuch-show-resend-message)
1489     (define-key map "l" 'notmuch-show-filter-thread)
1490     (define-key map "r" 'notmuch-show-reply-sender)
1491     (define-key map "R" 'notmuch-show-reply)
1492     (define-key map "|" 'notmuch-show-pipe-message)
1493     (define-key map "w" 'notmuch-show-save-attachments)
1494     (define-key map "V" 'notmuch-show-view-raw-message)
1495     (define-key map "e" 'notmuch-show-resume-message)
1496     (define-key map "c" 'notmuch-show-stash-map)
1497     (define-key map "h" 'notmuch-show-toggle-visibility-headers)
1498     (define-key map "k" 'notmuch-tag-jump)
1499     (define-key map "*" 'notmuch-show-tag-all)
1500     (define-key map "-" 'notmuch-show-remove-tag)
1501     (define-key map "+" 'notmuch-show-add-tag)
1502     (define-key map "X" 'notmuch-show-archive-thread-then-exit)
1503     (define-key map "x" 'notmuch-show-archive-message-then-next-or-exit)
1504     (define-key map "A" 'notmuch-show-archive-thread-then-next)
1505     (define-key map "a" 'notmuch-show-archive-message-then-next-or-next-thread)
1506     (define-key map "N" 'notmuch-show-next-message)
1507     (define-key map "P" 'notmuch-show-previous-message)
1508     (define-key map "n" 'notmuch-show-next-open-message)
1509     (define-key map "p" 'notmuch-show-previous-open-message)
1510     (define-key map (kbd "M-n") 'notmuch-show-next-thread-show)
1511     (define-key map (kbd "M-p") 'notmuch-show-previous-thread-show)
1512     (define-key map (kbd "DEL") 'notmuch-show-rewind)
1513     (define-key map " " 'notmuch-show-advance-and-archive)
1514     (define-key map (kbd "M-RET") 'notmuch-show-open-or-close-all)
1515     (define-key map (kbd "RET") 'notmuch-show-toggle-message)
1516     (define-key map "#" 'notmuch-show-print-message)
1517     (define-key map "!" 'notmuch-show-toggle-elide-non-matching)
1518     (define-key map "$" 'notmuch-show-toggle-process-crypto)
1519     (define-key map "<" 'notmuch-show-toggle-thread-indentation)
1520     (define-key map "t" 'toggle-truncate-lines)
1521     (define-key map "." 'notmuch-show-part-map)
1522     (define-key map "B" 'notmuch-show-browse-urls)
1523     map)
1524   "Keymap for \"notmuch show\" buffers.")
1525 (fset 'notmuch-show-mode-map notmuch-show-mode-map)
1526
1527 (define-derived-mode notmuch-show-mode fundamental-mode "notmuch-show"
1528   "Major mode for viewing a thread with notmuch.
1529
1530 This buffer contains the results of the \"notmuch show\" command
1531 for displaying a single thread of email from your email archives.
1532
1533 By default, various components of email messages, (citations,
1534 signatures, already-read messages), are hidden. You can make
1535 these parts visible by clicking with the mouse button or by
1536 pressing RET after positioning the cursor on a hidden part, (for
1537 which \\[notmuch-show-next-button] and \\[notmuch-show-previous-button] are helpful).
1538
1539 Reading the thread sequentially is well-supported by pressing
1540 \\[notmuch-show-advance-and-archive]. This will scroll the current message (if necessary), advance
1541 to the next message, or advance to the next thread (if already on
1542 the last message of a thread).
1543
1544 Other commands are available to read or manipulate the thread
1545 more selectively, (such as '\\[notmuch-show-next-message]' and '\\[notmuch-show-previous-message]' to advance to messages
1546 without removing any tags, and '\\[notmuch-show-archive-thread]' to archive an entire thread
1547 without scrolling through with \\[notmuch-show-advance-and-archive]).
1548
1549 You can add or remove arbitrary tags from the current message with
1550 '\\[notmuch-show-add-tag]' or '\\[notmuch-show-remove-tag]'.
1551
1552 All currently available key bindings:
1553
1554 \\{notmuch-show-mode-map}"
1555   (setq notmuch-buffer-refresh-function #'notmuch-show-refresh-view)
1556   (setq buffer-read-only t
1557         truncate-lines t)
1558   (setq imenu-prev-index-position-function
1559         #'notmuch-show-imenu-prev-index-position-function)
1560   (setq imenu-extract-index-name-function
1561         #'notmuch-show-imenu-extract-index-name-function))
1562
1563 (defun notmuch-tree-from-show-current-query ()
1564   "Call notmuch tree with the current query"
1565   (interactive)
1566   (notmuch-tree notmuch-show-thread-id
1567                 notmuch-show-query-context
1568                 (notmuch-show-get-message-id)))
1569
1570 (defun notmuch-unthreaded-from-show-current-query ()
1571   "Call notmuch unthreaded with the current query"
1572   (interactive)
1573   (notmuch-unthreaded notmuch-show-thread-id
1574                       notmuch-show-query-context
1575                       (notmuch-show-get-message-id)))
1576
1577 (defun notmuch-show-move-to-message-top ()
1578   (goto-char (notmuch-show-message-top)))
1579
1580 (defun notmuch-show-move-to-message-bottom ()
1581   (goto-char (notmuch-show-message-bottom)))
1582
1583 (defun notmuch-show-message-adjust ()
1584   (recenter 0))
1585
1586 ;; Movement related functions.
1587
1588 ;; There's some strangeness here where a text property applied to a
1589 ;; region a->b is not found when point is at b. We walk backwards
1590 ;; until finding the property.
1591 (defun notmuch-show-message-extent ()
1592   "Return a cons cell containing the start and end buffer offset
1593 of the current message."
1594   (let (r)
1595     (save-excursion
1596       (while (not (setq r (get-text-property (point) :notmuch-message-extent)))
1597         (backward-char)))
1598     r))
1599
1600 (defun notmuch-show-message-top ()
1601   (car (notmuch-show-message-extent)))
1602
1603 (defun notmuch-show-message-bottom ()
1604   (cdr (notmuch-show-message-extent)))
1605
1606 (defun notmuch-show-goto-message-next ()
1607   (let ((start (point)))
1608     (notmuch-show-move-to-message-bottom)
1609     (if (not (eobp))
1610         t
1611       (goto-char start)
1612       nil)))
1613
1614 (defun notmuch-show-goto-message-previous ()
1615   (notmuch-show-move-to-message-top)
1616   (if (bobp)
1617       nil
1618     (backward-char)
1619     (notmuch-show-move-to-message-top)
1620     t))
1621
1622 (defun notmuch-show-mapc (function)
1623   "Iterate through all messages in the current thread with
1624 `notmuch-show-goto-message-next' and call FUNCTION for side
1625 effects."
1626   (save-excursion
1627     (goto-char (point-min))
1628     (cl-loop do (funcall function)
1629              while (notmuch-show-goto-message-next))))
1630
1631 ;; Functions relating to the visibility of messages and their
1632 ;; components.
1633
1634 (defun notmuch-show-message-visible (props visible-p)
1635   (overlay-put (plist-get props :message-overlay) 'invisible (not visible-p))
1636   (notmuch-show-set-prop :message-visible visible-p props))
1637
1638 (defun notmuch-show-headers-visible (props visible-p)
1639   (overlay-put (plist-get props :headers-overlay) 'invisible (not visible-p))
1640   (notmuch-show-set-prop :headers-visible visible-p props))
1641
1642 ;; Functions for setting and getting attributes of the current
1643 ;; message.
1644
1645 (defun notmuch-show-set-message-properties (props)
1646   (save-excursion
1647     (notmuch-show-move-to-message-top)
1648     (put-text-property (point) (+ (point) 1) :notmuch-message-properties props)))
1649
1650 (defun notmuch-show-get-message-properties ()
1651   "Return the properties of the current message as a plist.
1652
1653 Some useful entries are:
1654 :headers - Property list containing the headers :Date, :Subject, :From, etc.
1655 :body - Body of the message
1656 :tags - Tags for this message"
1657   (save-excursion
1658     (notmuch-show-move-to-message-top)
1659     (get-text-property (point) :notmuch-message-properties)))
1660
1661 (defun notmuch-show-get-part-properties ()
1662   "Return the properties of the innermost part containing point.
1663
1664 This is the part property list retrieved from the CLI.  Signals
1665 an error if there is no part containing point."
1666   (or (get-text-property (point) :notmuch-part)
1667       (error "No message part here")))
1668
1669 (defun notmuch-show-set-prop (prop val &optional props)
1670   (let ((inhibit-read-only t)
1671         (props (or props
1672                    (notmuch-show-get-message-properties))))
1673     (plist-put props prop val)
1674     (notmuch-show-set-message-properties props)))
1675
1676 (defun notmuch-show-get-prop (prop &optional props)
1677   "Get property PROP from current message in show or tree mode.
1678
1679 It gets property PROP from PROPS or, if PROPS is nil, the current
1680 message in either tree or show. This means that several utility
1681 functions in notmuch-show can be used directly by notmuch-tree as
1682 they just need the correct message properties."
1683   (let ((props (or props
1684                    (cond ((eq major-mode 'notmuch-show-mode)
1685                           (notmuch-show-get-message-properties))
1686                          ((eq major-mode 'notmuch-tree-mode)
1687                           (notmuch-tree-get-message-properties))
1688                          (t nil)))))
1689     (plist-get props prop)))
1690
1691 (defun notmuch-show-get-message-id (&optional bare)
1692   "Return an id: query for the Message-Id of the current message.
1693
1694 If optional argument BARE is non-nil, return
1695 the Message-Id without id: prefix and escaping."
1696   (if bare
1697       (notmuch-show-get-prop :id)
1698     (notmuch-id-to-query (notmuch-show-get-prop :id))))
1699
1700 (defun notmuch-show-get-messages-ids ()
1701   "Return all id: queries of messages in the current thread."
1702   (let ((message-ids))
1703     (notmuch-show-mapc
1704      (lambda () (push (notmuch-show-get-message-id) message-ids)))
1705     message-ids))
1706
1707 (defun notmuch-show-get-messages-ids-search ()
1708   "Return a search string for all message ids of messages in the
1709 current thread."
1710   (mapconcat 'identity (notmuch-show-get-messages-ids) " or "))
1711
1712 ;; dme: Would it make sense to use a macro for many of these?
1713
1714 ;; XXX TODO figure out what to do about multiple filenames
1715 (defun notmuch-show-get-filename ()
1716   "Return the filename of the current message."
1717   (car (notmuch-show-get-prop :filename)))
1718
1719 (defun notmuch-show-get-header (header &optional props)
1720   "Return the named header of the current message, if any."
1721   (plist-get (notmuch-show-get-prop :headers props) header))
1722
1723 (defun notmuch-show-get-cc ()
1724   (notmuch-show-get-header :Cc))
1725
1726 (defun notmuch-show-get-date ()
1727   (notmuch-show-get-header :Date))
1728
1729 (defun notmuch-show-get-timestamp ()
1730   (notmuch-show-get-prop :timestamp))
1731
1732 (defun notmuch-show-get-from ()
1733   (notmuch-show-get-header :From))
1734
1735 (defun notmuch-show-get-subject ()
1736   (notmuch-show-get-header :Subject))
1737
1738 (defun notmuch-show-get-to ()
1739   (notmuch-show-get-header :To))
1740
1741 (defun notmuch-show-get-depth ()
1742   (notmuch-show-get-prop :depth))
1743
1744 (defun notmuch-show-set-tags (tags)
1745   "Set the tags of the current message."
1746   (notmuch-show-set-prop :tags tags)
1747   (notmuch-show-update-tags tags))
1748
1749 (defun notmuch-show-get-tags ()
1750   "Return the tags of the current message."
1751   (notmuch-show-get-prop :tags))
1752
1753 (defun notmuch-show-message-visible-p ()
1754   "Is the current message visible?"
1755   (notmuch-show-get-prop :message-visible))
1756
1757 (defun notmuch-show-headers-visible-p ()
1758   "Are the headers of the current message visible?"
1759   (notmuch-show-get-prop :headers-visible))
1760
1761 (put 'notmuch-show-mark-read 'notmuch-prefix-doc
1762      "Mark the current message as unread.")
1763 (defun notmuch-show-mark-read (&optional unread)
1764   "Mark the current message as read.
1765
1766 Mark the current message as read by applying the tag changes in
1767 `notmuch-show-mark-read-tags' to it (remove the \"unread\" tag by
1768 default). If a prefix argument is given, the message will be
1769 marked as unread, i.e. the tag changes in
1770 `notmuch-show-mark-read-tags' will be reversed."
1771   (interactive "P")
1772   (when notmuch-show-mark-read-tags
1773     (apply 'notmuch-show-tag-message
1774            (notmuch-tag-change-list notmuch-show-mark-read-tags unread))))
1775
1776 (defun notmuch-show-seen-current-message (start end)
1777   "Mark the current message read if it is open.
1778
1779 We only mark it read once: if it is changed back then that is a
1780 user decision and we should not override it."
1781   (when (and (notmuch-show-message-visible-p)
1782              (not (notmuch-show-get-prop :seen)))
1783         (notmuch-show-mark-read)
1784         (notmuch-show-set-prop :seen t)))
1785
1786 (defvar notmuch-show--seen-has-errored nil)
1787 (make-variable-buffer-local 'notmuch-show--seen-has-errored)
1788
1789 (defun notmuch-show-command-hook ()
1790   (when (eq major-mode 'notmuch-show-mode)
1791     ;; We need to redisplay to get window-start and window-end correct.
1792     (redisplay)
1793     (save-excursion
1794       (condition-case err
1795           (funcall notmuch-show-mark-read-function (window-start) (window-end))
1796         ((debug error)
1797          (unless notmuch-show--seen-has-errored
1798            (setq notmuch-show--seen-has-errored 't)
1799            (setq header-line-format
1800                  (concat header-line-format
1801                          (propertize "  [some mark read tag changes may have failed]"
1802                                      'face font-lock-warning-face)))))))))
1803
1804 (defun notmuch-show-filter-thread (query)
1805   "Filter or LIMIT the current thread based on a new query string.
1806
1807 Reshows the current thread with matches defined by the new query-string."
1808   (interactive (list (notmuch-read-query "Filter thread: ")))
1809   (let ((msg-id (notmuch-show-get-message-id)))
1810     (setq notmuch-show-query-context (if (string= query "") nil query))
1811     (notmuch-show-refresh-view t)
1812     (notmuch-show-goto-message msg-id)))
1813
1814 ;; Functions for getting attributes of several messages in the current
1815 ;; thread.
1816
1817 (defun notmuch-show-get-message-ids-for-open-messages ()
1818   "Return a list of all id: queries for open messages in the current thread."
1819   (save-excursion
1820     (let (message-ids done)
1821       (goto-char (point-min))
1822       (while (not done)
1823         (if (notmuch-show-message-visible-p)
1824             (setq message-ids (append message-ids (list (notmuch-show-get-message-id)))))
1825         (setq done (not (notmuch-show-goto-message-next)))
1826         )
1827       message-ids
1828       )))
1829
1830 ;; Commands typically bound to keys.
1831
1832 (defun notmuch-show-advance ()
1833   "Advance through thread.
1834
1835 If the current message in the thread is not yet fully visible,
1836 scroll by a near screenful to read more of the message.
1837
1838 Otherwise, (the end of the current message is already within the
1839 current window), advance to the next open message."
1840   (interactive)
1841   (let* ((end-of-this-message (notmuch-show-message-bottom))
1842          (visible-end-of-this-message (1- end-of-this-message))
1843          (ret nil))
1844     (while (invisible-p visible-end-of-this-message)
1845       (setq visible-end-of-this-message
1846             (max (point-min)
1847                  (1- (previous-single-char-property-change
1848                       visible-end-of-this-message 'invisible)))))
1849     (cond
1850      ;; Ideally we would test `end-of-this-message' against the result
1851      ;; of `window-end', but that doesn't account for the fact that
1852      ;; the end of the message might be hidden.
1853      ((and visible-end-of-this-message
1854            (> visible-end-of-this-message (window-end)))
1855       ;; The bottom of this message is not visible - scroll.
1856       (scroll-up nil))
1857
1858      ((not (= end-of-this-message (point-max)))
1859       ;; This is not the last message - move to the next visible one.
1860       (notmuch-show-next-open-message))
1861
1862      ((not (= (point) (point-max)))
1863       ;; This is the last message, but the cursor is not at the end of
1864       ;; the buffer. Move it there.
1865       (goto-char (point-max)))
1866
1867      (t
1868       ;; This is the last message - change the return value
1869       (setq ret t)))
1870     ret))
1871
1872 (defun notmuch-show-advance-and-archive ()
1873   "Advance through thread and archive.
1874
1875 This command is intended to be one of the simplest ways to
1876 process a thread of email. It works exactly like
1877 notmuch-show-advance, in that it scrolls through messages in a
1878 show buffer, except that when it gets to the end of the buffer it
1879 archives the entire current thread, (apply changes in
1880 `notmuch-archive-tags'), kills the buffer, and displays the next
1881 thread from the search from which this thread was originally
1882 shown."
1883   (interactive)
1884   (if (notmuch-show-advance)
1885       (notmuch-show-archive-thread-then-next)))
1886
1887 (defun notmuch-show-rewind ()
1888   "Backup through the thread (reverse scrolling compared to \\[notmuch-show-advance-and-archive]).
1889
1890 Specifically, if the beginning of the previous email is fewer
1891 than `window-height' lines from the current point, move to it
1892 just like `notmuch-show-previous-message'.
1893
1894 Otherwise, just scroll down a screenful of the current message.
1895
1896 This command does not modify any message tags, (it does not undo
1897 any effects from previous calls to
1898 `notmuch-show-advance-and-archive'."
1899   (interactive)
1900   (let ((start-of-message (notmuch-show-message-top))
1901         (start-of-window (window-start)))
1902     (cond
1903       ;; Either this message is properly aligned with the start of the
1904       ;; window or the start of this message is not visible on the
1905       ;; screen - scroll.
1906      ((or (= start-of-message start-of-window)
1907           (< start-of-message start-of-window))
1908       (scroll-down)
1909       ;; If a small number of lines from the previous message are
1910       ;; visible, realign so that the top of the current message is at
1911       ;; the top of the screen.
1912       (when (<= (count-screen-lines (window-start) start-of-message)
1913                 next-screen-context-lines)
1914         (goto-char (notmuch-show-message-top))
1915         (notmuch-show-message-adjust))
1916       ;; Move to the top left of the window.
1917       (goto-char (window-start)))
1918      (t
1919       ;; Move to the previous message.
1920       (notmuch-show-previous-message)))))
1921
1922 (put 'notmuch-show-reply 'notmuch-prefix-doc "... and prompt for sender")
1923 (defun notmuch-show-reply (&optional prompt-for-sender)
1924   "Reply to the sender and all recipients of the current message."
1925   (interactive "P")
1926   (notmuch-mua-new-reply (notmuch-show-get-message-id) prompt-for-sender t))
1927
1928 (put 'notmuch-show-reply-sender 'notmuch-prefix-doc "... and prompt for sender")
1929 (defun notmuch-show-reply-sender (&optional prompt-for-sender)
1930   "Reply to the sender of the current message."
1931   (interactive "P")
1932   (notmuch-mua-new-reply (notmuch-show-get-message-id) prompt-for-sender nil))
1933
1934 (put 'notmuch-show-forward-message 'notmuch-prefix-doc
1935      "... and prompt for sender")
1936 (defun notmuch-show-forward-message (&optional prompt-for-sender)
1937   "Forward the current message."
1938   (interactive "P")
1939   (notmuch-mua-new-forward-messages (list (notmuch-show-get-message-id))
1940                                     prompt-for-sender))
1941
1942 (put 'notmuch-show-forward-open-messages 'notmuch-prefix-doc
1943      "... and prompt for sender")
1944 (defun notmuch-show-forward-open-messages (&optional prompt-for-sender)
1945   "Forward the currently open messages."
1946   (interactive "P")
1947   (let ((open-messages (notmuch-show-get-message-ids-for-open-messages)))
1948     (unless open-messages
1949       (error "No open messages to forward."))
1950     (notmuch-mua-new-forward-messages open-messages prompt-for-sender)))
1951
1952 (defun notmuch-show-resend-message (addresses)
1953   "Resend the current message."
1954   (interactive (list (notmuch-address-from-minibuffer "Resend to: ")))
1955   (when (y-or-n-p (concat "Confirm resend to " addresses " "))
1956     (notmuch-show-view-raw-message)
1957     (message-resend addresses)
1958     (notmuch-bury-or-kill-this-buffer)))
1959
1960 (defun notmuch-show-next-message (&optional pop-at-end)
1961   "Show the next message.
1962
1963 If a prefix argument is given and this is the last message in the
1964 thread, navigate to the next thread in the parent search buffer."
1965   (interactive "P")
1966   (if (notmuch-show-goto-message-next)
1967       (notmuch-show-message-adjust)
1968     (if pop-at-end
1969         (notmuch-show-next-thread)
1970       (goto-char (point-max)))))
1971
1972 (defun notmuch-show-previous-message ()
1973   "Show the previous message or the start of the current message."
1974   (interactive)
1975   (if (= (point) (notmuch-show-message-top))
1976       (notmuch-show-goto-message-previous)
1977     (notmuch-show-move-to-message-top))
1978   (notmuch-show-message-adjust))
1979
1980 (defun notmuch-show-next-open-message (&optional pop-at-end)
1981   "Show the next open message.
1982
1983 If a prefix argument is given and this is the last open message
1984 in the thread, navigate to the next thread in the parent search
1985 buffer. Return t if there was a next open message in the thread
1986 to show, nil otherwise."
1987   (interactive "P")
1988   (let (r)
1989     (while (and (setq r (notmuch-show-goto-message-next))
1990                 (not (notmuch-show-message-visible-p))))
1991     (if r
1992         (notmuch-show-message-adjust)
1993       (if pop-at-end
1994           (notmuch-show-next-thread)
1995         (goto-char (point-max))))
1996     r))
1997
1998 (defun notmuch-show-next-matching-message ()
1999   "Show the next matching message."
2000   (interactive)
2001   (let (r)
2002     (while (and (setq r (notmuch-show-goto-message-next))
2003                 (not (notmuch-show-get-prop :match))))
2004     (if r
2005         (notmuch-show-message-adjust)
2006       (goto-char (point-max)))))
2007
2008 (defun notmuch-show-open-if-matched ()
2009   "Open a message if it is matched (whether or not excluded)."
2010   (let ((props (notmuch-show-get-message-properties)))
2011     (notmuch-show-message-visible props (plist-get props :match))))
2012
2013 (defun notmuch-show-goto-first-wanted-message ()
2014   "Move to the first open message and mark it read"
2015   (goto-char (point-min))
2016   (unless (notmuch-show-message-visible-p)
2017     (notmuch-show-next-open-message))
2018   (when (eobp)
2019     ;; There are no matched non-excluded messages so open all matched
2020     ;; (necessarily excluded) messages and go to the first.
2021     (notmuch-show-mapc 'notmuch-show-open-if-matched)
2022     (force-window-update)
2023     (goto-char (point-min))
2024     (unless (notmuch-show-message-visible-p)
2025       (notmuch-show-next-open-message))))
2026
2027 (defun notmuch-show-previous-open-message ()
2028   "Show the previous open message."
2029   (interactive)
2030   (while (and (if (= (point) (notmuch-show-message-top))
2031                   (notmuch-show-goto-message-previous)
2032                 (notmuch-show-move-to-message-top))
2033               (not (notmuch-show-message-visible-p))))
2034   (notmuch-show-message-adjust))
2035
2036 (defun notmuch-show-view-raw-message ()
2037   "View the original source of the current message."
2038   (interactive)
2039   (let* ((id (notmuch-show-get-message-id))
2040          (buf (get-buffer-create (concat "*notmuch-raw-" id "*")))
2041          (inhibit-read-only t))
2042     (switch-to-buffer buf)
2043     (erase-buffer)
2044     (let ((coding-system-for-read 'no-conversion))
2045       (call-process notmuch-command nil t nil "show" "--format=raw" id))
2046     (goto-char (point-min))
2047     (set-buffer-modified-p nil)
2048     (setq buffer-read-only t)
2049     (view-buffer buf 'kill-buffer-if-not-modified)))
2050
2051 (defun notmuch-show-resume-message ()
2052   "Resume EDITING the current draft message."
2053   (interactive)
2054   (notmuch-draft-resume (notmuch-show-get-message-id)))
2055
2056 (put 'notmuch-show-pipe-message 'notmuch-doc
2057      "Pipe the contents of the current message to a command.")
2058 (put 'notmuch-show-pipe-message 'notmuch-prefix-doc
2059      "Pipe the thread as an mbox to a command.")
2060 (defun notmuch-show-pipe-message (entire-thread command)
2061   "Pipe the contents of the current message (or thread) to COMMAND.
2062
2063 COMMAND will be executed with the raw contents of the current
2064 email message as stdin. Anything printed by the command to stdout
2065 or stderr will appear in the *notmuch-pipe* buffer.
2066
2067 If ENTIRE-THREAD is non-nil (or when invoked with a prefix
2068 argument), COMMAND will receive all open messages in the current
2069 thread (formatted as an mbox) rather than only the current
2070 message."
2071   (interactive (let ((query-string (if current-prefix-arg
2072                                        "Pipe all open messages to command: "
2073                                      "Pipe message to command: ")))
2074                  (list current-prefix-arg (read-string query-string))))
2075   (let (shell-command)
2076     (if entire-thread
2077         (setq shell-command
2078               (concat notmuch-command " show --format=mbox --exclude=false "
2079                       (shell-quote-argument
2080                        (mapconcat 'identity (notmuch-show-get-message-ids-for-open-messages) " OR "))
2081                       " | " command))
2082       (setq shell-command
2083             (concat notmuch-command " show --format=raw "
2084                     (shell-quote-argument (notmuch-show-get-message-id)) " | " command)))
2085     (let ((cwd default-directory)
2086           (buf (get-buffer-create (concat "*notmuch-pipe*"))))
2087       (with-current-buffer buf
2088         (setq buffer-read-only nil)
2089         (erase-buffer)
2090         ;; Use the originating buffer's working directory instead of
2091         ;; that of the pipe buffer.
2092         (cd cwd)
2093         (let ((exit-code (call-process-shell-command shell-command nil buf)))
2094           (goto-char (point-max))
2095           (set-buffer-modified-p nil)
2096           (setq buffer-read-only t)
2097           (unless (zerop exit-code)
2098             (switch-to-buffer-other-window buf)
2099             (message (format "Command '%s' exited abnormally with code %d"
2100                              shell-command exit-code))))))))
2101
2102 (defun notmuch-show-tag-message (&rest tag-changes)
2103   "Change tags for the current message.
2104
2105 TAG-CHANGES is a list of tag operations for `notmuch-tag'."
2106   (let* ((current-tags (notmuch-show-get-tags))
2107          (new-tags (notmuch-update-tags current-tags tag-changes)))
2108     (unless (equal current-tags new-tags)
2109       (notmuch-tag (notmuch-show-get-message-id) tag-changes)
2110       (notmuch-show-set-tags new-tags))))
2111
2112 (defun notmuch-show-tag (tag-changes)
2113   "Change tags for the current message.
2114
2115 See `notmuch-tag' for information on the format of TAG-CHANGES."
2116   (interactive (list (notmuch-read-tag-changes (notmuch-show-get-tags)
2117                                                "Tag message")))
2118   (notmuch-tag (notmuch-show-get-message-id) tag-changes)
2119   (let* ((current-tags (notmuch-show-get-tags))
2120          (new-tags (notmuch-update-tags current-tags tag-changes)))
2121     (unless (equal current-tags new-tags)
2122       (notmuch-show-set-tags new-tags))))
2123
2124 (defun notmuch-show-tag-all (tag-changes)
2125   "Change tags for all messages in the current show buffer.
2126
2127 See `notmuch-tag' for information on the format of TAG-CHANGES."
2128   (interactive
2129    (list (let (tags)
2130            (notmuch-show-mapc
2131             (lambda () (setq tags (append (notmuch-show-get-tags) tags))))
2132            (notmuch-read-tag-changes tags "Tag thread"))))
2133   (notmuch-tag (notmuch-show-get-messages-ids-search) tag-changes)
2134   (notmuch-show-mapc
2135    (lambda ()
2136      (let* ((current-tags (notmuch-show-get-tags))
2137             (new-tags (notmuch-update-tags current-tags tag-changes)))
2138        (unless (equal current-tags new-tags)
2139          (notmuch-show-set-tags new-tags))))))
2140
2141 (defun notmuch-show-add-tag (tag-changes)
2142   "Change tags for the current message (defaulting to add).
2143
2144 Same as `notmuch-show-tag' but sets initial input to '+'."
2145   (interactive
2146    (list (notmuch-read-tag-changes (notmuch-show-get-tags) "Tag message" "+")))
2147   (notmuch-show-tag tag-changes))
2148
2149 (defun notmuch-show-remove-tag (tag-changes)
2150   "Change tags for the current message (defaulting to remove).
2151
2152 Same as `notmuch-show-tag' but sets initial input to '-'."
2153   (interactive
2154    (list (notmuch-read-tag-changes (notmuch-show-get-tags) "Tag message" "-")))
2155   (notmuch-show-tag tag-changes))
2156
2157 (defun notmuch-show-toggle-visibility-headers ()
2158   "Toggle the visibility of the current message headers."
2159   (interactive)
2160   (let ((props (notmuch-show-get-message-properties)))
2161     (notmuch-show-headers-visible
2162      props
2163      (not (plist-get props :headers-visible))))
2164   (force-window-update))
2165
2166 (defun notmuch-show-toggle-message ()
2167   "Toggle the visibility of the current message."
2168   (interactive)
2169   (let ((props (notmuch-show-get-message-properties)))
2170     (notmuch-show-message-visible
2171      props
2172      (not (plist-get props :message-visible))))
2173   (force-window-update))
2174
2175 (put 'notmuch-show-open-or-close-all 'notmuch-doc "Show all messages.")
2176 (put 'notmuch-show-open-or-close-all 'notmuch-prefix-doc "Hide all messages.")
2177 (defun notmuch-show-open-or-close-all ()
2178   "Set the visibility all of the messages in the current thread.
2179
2180 By default make all of the messages visible. With a prefix
2181 argument, hide all of the messages."
2182   (interactive)
2183   (save-excursion
2184     (goto-char (point-min))
2185     (cl-loop do (notmuch-show-message-visible (notmuch-show-get-message-properties)
2186                                               (not current-prefix-arg))
2187              until (not (notmuch-show-goto-message-next))))
2188   (force-window-update))
2189
2190 (defun notmuch-show-next-button ()
2191   "Advance point to the next button in the buffer."
2192   (interactive)
2193   (forward-button 1))
2194
2195 (defun notmuch-show-previous-button ()
2196   "Move point back to the previous button in the buffer."
2197   (interactive)
2198   (backward-button 1))
2199
2200 (defun notmuch-show-next-thread (&optional show previous)
2201   "Move to the next item in the search results, if any.
2202
2203 If SHOW is non-nil, open the next item in a show
2204 buffer. Otherwise just highlight the next item in the search
2205 buffer. If PREVIOUS is non-nil, move to the previous item in the
2206 search results instead."
2207   (interactive "P")
2208   (let ((parent-buffer notmuch-show-parent-buffer))
2209     (notmuch-bury-or-kill-this-buffer)
2210     (when (buffer-live-p parent-buffer)
2211       (switch-to-buffer parent-buffer)
2212       (and (if previous
2213                (notmuch-search-previous-thread)
2214              (notmuch-search-next-thread))
2215            show
2216            (notmuch-search-show-thread)))))
2217
2218 (defun notmuch-show-next-thread-show ()
2219   "Show the next thread in the search results, if any."
2220   (interactive)
2221   (notmuch-show-next-thread t))
2222
2223 (defun notmuch-show-previous-thread-show ()
2224   "Show the previous thread in the search results, if any."
2225   (interactive)
2226   (notmuch-show-next-thread t t))
2227
2228 (put 'notmuch-show-archive-thread 'notmuch-prefix-doc
2229      "Un-archive each message in thread.")
2230 (defun notmuch-show-archive-thread (&optional unarchive)
2231   "Archive each message in thread.
2232
2233 Archive each message currently shown by applying the tag changes
2234 in `notmuch-archive-tags' to each. If a prefix argument is given,
2235 the messages will be \"unarchived\", i.e. the tag changes in
2236 `notmuch-archive-tags' will be reversed.
2237
2238 Note: This command is safe from any race condition of new messages
2239 being delivered to the same thread. It does not archive the
2240 entire thread, but only the messages shown in the current
2241 buffer."
2242   (interactive "P")
2243   (when notmuch-archive-tags
2244     (notmuch-show-tag-all
2245      (notmuch-tag-change-list notmuch-archive-tags unarchive))))
2246
2247 (defun notmuch-show-archive-thread-then-next ()
2248   "Archive all messages in the current buffer, then show next thread from search."
2249   (interactive)
2250   (notmuch-show-archive-thread)
2251   (notmuch-show-next-thread t))
2252
2253 (defun notmuch-show-archive-thread-then-exit ()
2254   "Archive all messages in the current buffer, then exit back to search results."
2255   (interactive)
2256   (notmuch-show-archive-thread)
2257   (notmuch-show-next-thread))
2258
2259 (put 'notmuch-show-archive-message 'notmuch-prefix-doc
2260      "Un-archive the current message.")
2261 (defun notmuch-show-archive-message (&optional unarchive)
2262   "Archive the current message.
2263
2264 Archive the current message by applying the tag changes in
2265 `notmuch-archive-tags' to it. If a prefix argument is given, the
2266 message will be \"unarchived\", i.e. the tag changes in
2267 `notmuch-archive-tags' will be reversed."
2268   (interactive "P")
2269   (when notmuch-archive-tags
2270     (apply 'notmuch-show-tag-message
2271            (notmuch-tag-change-list notmuch-archive-tags unarchive))))
2272
2273 (defun notmuch-show-archive-message-then-next-or-exit ()
2274   "Archive current message, then show next open message in current thread.
2275
2276 If at the last open message in the current thread, then exit back
2277 to search results."
2278   (interactive)
2279   (notmuch-show-archive-message)
2280   (notmuch-show-next-open-message t))
2281
2282 (defun notmuch-show-archive-message-then-next-or-next-thread ()
2283   "Archive current message, then show next open message in current or next thread.
2284
2285 If at the last open message in the current thread, then show next
2286 thread from search."
2287   (interactive)
2288   (notmuch-show-archive-message)
2289   (unless (notmuch-show-next-open-message)
2290     (notmuch-show-next-thread t)))
2291
2292 (defun notmuch-show-stash-cc ()
2293   "Copy CC field of current message to kill-ring."
2294   (interactive)
2295   (notmuch-common-do-stash (notmuch-show-get-cc)))
2296
2297 (put 'notmuch-show-stash-date 'notmuch-prefix-doc
2298      "Copy timestamp of current message to kill-ring.")
2299 (defun notmuch-show-stash-date (&optional stash-timestamp)
2300   "Copy date of current message to kill-ring.
2301
2302 If invoked with a prefix argument, copy timestamp of current
2303 message to kill-ring."
2304   (interactive "P")
2305   (if stash-timestamp
2306       (notmuch-common-do-stash (format "%d" (notmuch-show-get-timestamp)))
2307     (notmuch-common-do-stash (notmuch-show-get-date))))
2308
2309 (defun notmuch-show-stash-filename ()
2310   "Copy filename of current message to kill-ring."
2311   (interactive)
2312   (notmuch-common-do-stash (notmuch-show-get-filename)))
2313
2314 (defun notmuch-show-stash-from ()
2315   "Copy From address of current message to kill-ring."
2316   (interactive)
2317   (notmuch-common-do-stash (notmuch-show-get-from)))
2318
2319 (put 'notmuch-show-stash-message-id 'notmuch-prefix-doc
2320      "Copy thread: query matching current thread to kill-ring.")
2321 (defun notmuch-show-stash-message-id (&optional stash-thread-id)
2322   "Copy id: query matching the current message to kill-ring.
2323
2324 If invoked with a prefix argument (or STASH-THREAD-ID is
2325 non-nil), copy thread: query matching the current thread to
2326 kill-ring."
2327   (interactive "P")
2328   (if stash-thread-id
2329       (notmuch-common-do-stash notmuch-show-thread-id)
2330     (notmuch-common-do-stash (notmuch-show-get-message-id))))
2331
2332 (defun notmuch-show-stash-message-id-stripped ()
2333   "Copy message ID of current message (sans `id:' prefix) to kill-ring."
2334   (interactive)
2335   (notmuch-common-do-stash (notmuch-show-get-message-id t)))
2336
2337 (defun notmuch-show-stash-subject ()
2338   "Copy Subject field of current message to kill-ring."
2339   (interactive)
2340   (notmuch-common-do-stash (notmuch-show-get-subject)))
2341
2342 (defun notmuch-show-stash-tags ()
2343   "Copy tags of current message to kill-ring as a comma separated list."
2344   (interactive)
2345   (notmuch-common-do-stash (mapconcat 'identity (notmuch-show-get-tags) ",")))
2346
2347 (defun notmuch-show-stash-to ()
2348   "Copy To address of current message to kill-ring."
2349   (interactive)
2350   (notmuch-common-do-stash (notmuch-show-get-to)))
2351
2352 (defun notmuch-show-stash-mlarchive-link (&optional mla)
2353   "Copy an ML Archive URI for the current message to the kill-ring.
2354
2355 This presumes that the message is available at the selected Mailing List Archive.
2356
2357 If optional argument MLA is non-nil, use the provided key instead of prompting
2358 the user (see `notmuch-show-stash-mlarchive-link-alist')."
2359   (interactive)
2360   (let ((url (cdr (assoc
2361                    (or mla
2362                        (let ((completion-ignore-case t))
2363                          (completing-read
2364                           "Mailing List Archive: "
2365                           notmuch-show-stash-mlarchive-link-alist
2366                           nil t nil nil
2367                           notmuch-show-stash-mlarchive-link-default)))
2368                    notmuch-show-stash-mlarchive-link-alist))))
2369     (notmuch-common-do-stash
2370      (if (functionp url)
2371          (funcall url (notmuch-show-get-message-id t))
2372        (concat url (notmuch-show-get-message-id t))))))
2373
2374 (defun notmuch-show-stash-mlarchive-link-and-go (&optional mla)
2375   "Copy an ML Archive URI for the current message to the kill-ring and visit it.
2376
2377 This presumes that the message is available at the selected Mailing List Archive.
2378
2379 If optional argument MLA is non-nil, use the provided key instead of prompting
2380 the user (see `notmuch-show-stash-mlarchive-link-alist')."
2381   (interactive)
2382   (notmuch-show-stash-mlarchive-link mla)
2383   (browse-url (current-kill 0 t)))
2384
2385 (defun notmuch-show-stash-git-helper (addresses prefix)
2386   "Escape, trim, quote, and add PREFIX to each address in list of ADDRESSES, and return the result as a single string."
2387   (mapconcat (lambda (x)
2388                (concat prefix "\""
2389                        ;; escape double-quotes
2390                        (replace-regexp-in-string
2391                         "\"" "\\\\\""
2392                         ;; trim leading and trailing spaces
2393                         (replace-regexp-in-string
2394                          "\\(^ *\\| *$\\)" ""
2395                          x)) "\""))
2396              addresses " "))
2397
2398 (put 'notmuch-show-stash-git-send-email 'notmuch-prefix-doc
2399      "Copy From/To/Cc of current message to kill-ring in a form suitable for pasting to git send-email command line.")
2400
2401 (defun notmuch-show-stash-git-send-email (&optional no-in-reply-to)
2402   "Copy From/To/Cc/Message-Id of current message to kill-ring in a form suitable for pasting to git send-email command line.
2403
2404 If invoked with a prefix argument (or NO-IN-REPLY-TO is non-nil),
2405 omit --in-reply-to=<Message-Id>."
2406   (interactive "P")
2407   (notmuch-common-do-stash
2408    (mapconcat 'identity
2409               (remove ""
2410                       (list
2411                        (notmuch-show-stash-git-helper
2412                         (message-tokenize-header (notmuch-show-get-from)) "--to=")
2413                        (notmuch-show-stash-git-helper
2414                         (message-tokenize-header (notmuch-show-get-to)) "--to=")
2415                        (notmuch-show-stash-git-helper
2416                         (message-tokenize-header (notmuch-show-get-cc)) "--cc=")
2417                        (unless no-in-reply-to
2418                          (notmuch-show-stash-git-helper
2419                           (list (notmuch-show-get-message-id t)) "--in-reply-to="))))
2420               " ")))
2421
2422 ;; Interactive part functions and their helpers
2423
2424 (defun notmuch-show-generate-part-buffer (msg part)
2425   "Return a temporary buffer containing the specified part's content."
2426   (let ((buf (generate-new-buffer " *notmuch-part*"))
2427         (process-crypto notmuch-show-process-crypto))
2428     (with-current-buffer buf
2429       ;; This is always used in the content of mm handles, which
2430       ;; expect undecoded, binary part content.
2431       (insert (notmuch-get-bodypart-binary msg part process-crypto)))
2432     buf))
2433
2434 (defun notmuch-show-current-part-handle (&optional mime-type)
2435   "Return an mm-handle for the part containing point.
2436
2437 This creates a temporary buffer for the part's content; the
2438 caller is responsible for killing this buffer as appropriate.  If
2439 MIME-TYPE is given then set the handle's mime-type to MIME-TYPE."
2440   (let* ((msg (notmuch-show-get-message-properties))
2441          (part (notmuch-show-get-part-properties))
2442          (buf (notmuch-show-generate-part-buffer msg part))
2443          (computed-type (or mime-type (plist-get part :computed-type)))
2444          (filename (plist-get part :filename))
2445          (disposition (if filename `(attachment (filename . ,filename)))))
2446     (mm-make-handle buf (list computed-type) nil nil disposition)))
2447
2448 (defun notmuch-show-apply-to-current-part-handle (fn &optional mime-type)
2449   "Apply FN to an mm-handle for the part containing point.
2450
2451 This ensures that the temporary buffer created for the mm-handle
2452 is destroyed when FN returns. If MIME-TYPE is given then force
2453 part to be treated as if it had that mime-type."
2454   (let ((handle (notmuch-show-current-part-handle mime-type)))
2455     ;; emacs 24.3+ puts stdout/stderr into the calling buffer so we
2456     ;; call it from a temp-buffer, unless
2457     ;; notmuch-show-attachment-debug is non-nil in which case we put
2458     ;; it in " *notmuch-part*".
2459     (unwind-protect
2460         (if notmuch-show-attachment-debug
2461             (with-current-buffer (generate-new-buffer " *notmuch-part*")
2462               (funcall fn handle))
2463           (with-temp-buffer
2464             (funcall fn handle)))
2465       (kill-buffer (mm-handle-buffer handle)))))
2466
2467 (defun notmuch-show-part-button-default (&optional button)
2468   (interactive)
2469   (let ((button (or button (button-at (point)))))
2470     ;; Try to toggle the part, if that fails then call the default
2471     ;; action. The toggle fails if the part has no emacs renderable
2472     ;; content.
2473     (unless (notmuch-show-toggle-part-invisibility button)
2474       (call-interactively notmuch-show-part-button-default-action))))
2475
2476 (defun notmuch-show-save-part ()
2477   "Save the MIME part containing point to a file."
2478   (interactive)
2479   (notmuch-show-apply-to-current-part-handle #'mm-save-part))
2480
2481 (defun notmuch-show-view-part ()
2482   "View the MIME part containing point in an external viewer."
2483   (interactive)
2484   ;; Set mm-inlined-types to nil to force an external viewer
2485   (let ((mm-inlined-types nil))
2486     (notmuch-show-apply-to-current-part-handle #'mm-display-part)))
2487
2488 (defun notmuch-show-interactively-view-part ()
2489   "View the MIME part containing point, prompting for a viewer."
2490   (interactive)
2491   (notmuch-show-apply-to-current-part-handle #'mm-interactively-view-part))
2492
2493 (defun notmuch-show-pipe-part ()
2494   "Pipe the MIME part containing point to an external command."
2495   (interactive)
2496   (notmuch-show-apply-to-current-part-handle #'mm-pipe-part))
2497
2498
2499 (defun notmuch-show--mm-display-part (handle)
2500   "Use mm-display-part to display HANDLE in a new buffer.
2501
2502 If the part is displayed in an external application then close
2503 the new buffer."
2504   (let ((buf (get-buffer-create (generate-new-buffer-name
2505                                  (concat " *notmuch-internal-part*")))))
2506     (switch-to-buffer buf)
2507     (if (eq (mm-display-part handle) 'external)
2508         (kill-buffer buf)
2509       (goto-char (point-min))
2510       (set-buffer-modified-p nil)
2511       (view-buffer buf 'kill-buffer-if-not-modified))))
2512
2513 (defun notmuch-show-choose-mime-of-part (mime-type)
2514   "Choose the mime type to use for displaying part"
2515   (interactive
2516    (list (completing-read "Mime type to use (default text/plain): "
2517                           (mailcap-mime-types) nil nil nil nil "text/plain")))
2518   (notmuch-show-apply-to-current-part-handle #'notmuch-show--mm-display-part mime-type))
2519
2520 (defun notmuch-show-imenu-prev-index-position-function ()
2521   "Move point to previous message in notmuch-show buffer.
2522 This function is used as a value for
2523 `imenu-prev-index-position-function'."
2524   (if (bobp)
2525       nil
2526     (notmuch-show-previous-message)
2527     t))
2528
2529 (defun notmuch-show-imenu-extract-index-name-function ()
2530   "Return imenu name for line at point.
2531 This function is used as a value for
2532 `imenu-extract-index-name-function'.  Point should be at the
2533 beginning of the line."
2534   (back-to-indentation)
2535   (buffer-substring-no-properties (if notmuch-show-imenu-indent
2536                                       (line-beginning-position)
2537                                     (point))
2538                                   (line-end-position)))
2539
2540 (defmacro notmuch-show--with-currently-shown-message (&rest body)
2541   "Evaluate BODY with display restricted to the currently shown
2542 message."
2543   `(save-excursion
2544      (save-restriction
2545       (let ((extent (notmuch-show-message-extent)))
2546         (narrow-to-region (car extent) (cdr extent))
2547         ,@body))))
2548
2549 (defun notmuch-show--gather-urls ()
2550   "Gather any URLs in the current message."
2551   (notmuch-show--with-currently-shown-message
2552    (let (urls)
2553      (goto-char (point-min))
2554      (while (re-search-forward goto-address-url-regexp (point-max) t)
2555        (push (match-string-no-properties 0) urls))
2556      (reverse urls))))
2557
2558 (defun notmuch-show-browse-urls (&optional kill)
2559   "Offer to browse any URLs in the current message.
2560 With a prefix argument, copy the URL to the kill ring rather than
2561 browsing."
2562   (interactive "P")
2563   (let ((urls (notmuch-show--gather-urls))
2564         (prompt (if kill "Copy URL to kill ring: " "Browse URL: "))
2565         (fn (if kill #'kill-new #'browse-url)))
2566     (if urls
2567         (funcall fn (completing-read prompt urls nil nil nil nil (car urls)))
2568       (message "No URLs found."))))
2569
2570 (provide 'notmuch-show)
2571
2572 ;;; notmuch-show.el ends here