f3150af520912376419b9fb8db7a59a6d97797af
[notmuch] / emacs / notmuch-show.el
1 ;; notmuch-show.el --- displaying notmuch forests.
2 ;;
3 ;; Copyright © Carl Worth
4 ;; Copyright © David Edmondson
5 ;;
6 ;; This file is part of Notmuch.
7 ;;
8 ;; Notmuch is free software: you can redistribute it and/or modify it
9 ;; under the terms of the GNU General Public License as published by
10 ;; the Free Software Foundation, either version 3 of the License, or
11 ;; (at your option) any later version.
12 ;;
13 ;; Notmuch is distributed in the hope that it will be useful, but
14 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
16 ;; General Public License for more details.
17 ;;
18 ;; You should have received a copy of the GNU General Public License
19 ;; along with Notmuch.  If not, see <http://www.gnu.org/licenses/>.
20 ;;
21 ;; Authors: Carl Worth <cworth@cworth.org>
22 ;;          David Edmondson <dme@dme.org>
23
24 (eval-when-compile (require 'cl))
25 (require 'mm-view)
26 (require 'message)
27 (require 'mm-decode)
28 (require 'mailcap)
29
30 (require 'notmuch-lib)
31 (require 'notmuch-query)
32 (require 'notmuch-wash)
33 (require 'notmuch-mua)
34
35 (declare-function notmuch-call-notmuch-process "notmuch" (&rest args))
36 (declare-function notmuch-fontify-headers "notmuch" nil)
37 (declare-function notmuch-select-tag-with-completion "notmuch" (prompt &rest search-terms))
38 (declare-function notmuch-search-show-thread "notmuch" nil)
39
40 (defcustom notmuch-message-headers '("Subject" "To" "Cc" "Date")
41   "Headers that should be shown in a message, in this order.
42
43 For an open message, all of these headers will be made visible
44 according to `notmuch-message-headers-visible' or can be toggled
45 with `notmuch-show-toggle-headers'. For a closed message, only
46 the first header in the list will be visible."
47   :group 'notmuch
48   :type '(repeat string))
49
50 (defcustom notmuch-message-headers-visible t
51   "Should the headers be visible by default?
52
53 If this value is non-nil, then all of the headers defined in
54 `notmuch-message-headers' will be visible by default in the display
55 of each message. Otherwise, these headers will be hidden and
56 `notmuch-show-toggle-headers' can be used to make the visible for
57 any given message."
58   :group 'notmuch
59   :type 'boolean)
60
61 (defcustom notmuch-show-relative-dates t
62   "Display relative dates in the message summary line."
63   :group 'notmuch
64   :type 'boolean)
65
66 (defvar notmuch-show-markup-headers-hook '(notmuch-show-colour-headers)
67   "A list of functions called to decorate the headers listed in
68 `notmuch-message-headers'.")
69
70 (defcustom notmuch-show-hook nil
71   "Functions called after populating a `notmuch-show' buffer."
72   :group 'notmuch
73   :type 'hook)
74
75 (defcustom notmuch-show-insert-text/plain-hook '(notmuch-wash-excerpt-citations)
76   "Functions used to improve the display of text/plain parts."
77   :group 'notmuch
78   :type 'hook
79   :options '(notmuch-wash-convert-inline-patch-to-part
80              notmuch-wash-wrap-long-lines
81              notmuch-wash-tidy-citations
82              notmuch-wash-elide-blank-lines
83              notmuch-wash-excerpt-citations))
84
85 (defmacro with-current-notmuch-show-message (&rest body)
86   "Evaluate body with current buffer set to the text of current message"
87   `(save-excursion
88      (let ((id (notmuch-show-get-message-id)))
89        (let ((buf (generate-new-buffer (concat "*notmuch-msg-" id "*"))))
90          (with-current-buffer buf
91             (call-process notmuch-command nil t nil "show" "--format=raw" id)
92            ,@body)
93          (kill-buffer buf)))))
94
95 (defun notmuch-show-view-all-mime-parts ()
96   "Use external viewers to view all attachments from the current message."
97   (interactive)
98   (with-current-notmuch-show-message
99    ; We ovverride the mm-inline-media-tests to indicate which message
100    ; parts are already sufficiently handled by the original
101    ; presentation of the message in notmuch-show mode. These parts
102    ; will be inserted directly into the temporary buffer of
103    ; with-current-notmuch-show-message and silently discarded.
104    ;
105    ; Any MIME part not explicitly mentioned here will be handled by an
106    ; external viewer as configured in the various mailcap files.
107    (let ((mm-inline-media-tests '(
108                                   ("text/.*" ignore identity)
109                                   ("application/pgp-signature" ignore identity)
110                                   ("multipart/alternative" ignore identity)
111                                   ("multipart/mixed" ignore identity)
112                                   ("multipart/related" ignore identity)
113                                  )))
114      (mm-display-parts (mm-dissect-buffer)))))
115
116 (defun notmuch-foreach-mime-part (function mm-handle)
117   (cond ((stringp (car mm-handle))
118          (dolist (part (cdr mm-handle))
119            (notmuch-foreach-mime-part function part)))
120         ((bufferp (car mm-handle))
121          (funcall function mm-handle))
122         (t (dolist (part mm-handle)
123              (notmuch-foreach-mime-part function part)))))
124
125 (defun notmuch-count-attachments (mm-handle)
126   (let ((count 0))
127     (notmuch-foreach-mime-part
128      (lambda (p)
129        (let ((disposition (mm-handle-disposition p)))
130          (and (listp disposition)
131               (or (equal (car disposition) "attachment")
132                   (and (equal (car disposition) "inline")
133                        (assq 'filename disposition)))
134               (incf count))))
135      mm-handle)
136     count))
137
138 (defun notmuch-save-attachments (mm-handle &optional queryp)
139   (notmuch-foreach-mime-part
140    (lambda (p)
141      (let ((disposition (mm-handle-disposition p)))
142        (and (listp disposition)
143             (or (equal (car disposition) "attachment")
144                 (and (equal (car disposition) "inline")
145                      (assq 'filename disposition)))
146             (or (not queryp)
147                 (y-or-n-p
148                  (concat "Save '" (cdr (assq 'filename disposition)) "' ")))
149             (mm-save-part p))))
150    mm-handle))
151
152 (defun notmuch-show-save-attachments ()
153   "Save all attachments from the current message."
154   (interactive)
155   (with-current-notmuch-show-message
156    (let ((mm-handle (mm-dissect-buffer)))
157      (notmuch-save-attachments
158       mm-handle (> (notmuch-count-attachments mm-handle) 1))))
159   (message "Done"))
160
161 (defun notmuch-show-fontify-header ()
162   (let ((face (cond
163                ((looking-at "[Tt]o:")
164                 'message-header-to)
165                ((looking-at "[Bb]?[Cc][Cc]:")
166                 'message-header-cc)
167                ((looking-at "[Ss]ubject:")
168                 'message-header-subject)
169                ((looking-at "[Ff]rom:")
170                 'message-header-from)
171                (t
172                 'message-header-other))))
173
174     (overlay-put (make-overlay (point) (re-search-forward ":"))
175                  'face 'message-header-name)
176     (overlay-put (make-overlay (point) (re-search-forward ".*$"))
177                  'face face)))
178
179 (defun notmuch-show-colour-headers ()
180   "Apply some colouring to the current headers."
181   (goto-char (point-min))
182   (while (looking-at "^[A-Za-z][-A-Za-z0-9]*:")
183     (notmuch-show-fontify-header)
184     (forward-line)))
185
186 (defun notmuch-show-spaces-n (n)
187   "Return a string comprised of `n' spaces."
188   (make-string n ? ))
189
190 (defun notmuch-show-update-tags (tags)
191   "Update the displayed tags of the current message."
192   (save-excursion
193     (goto-char (notmuch-show-message-top))
194     (if (re-search-forward "(\\([^()]*\\))$" (line-end-position) t)
195         (let ((inhibit-read-only t))
196           (replace-match (concat "("
197                                  (propertize (mapconcat 'identity tags " ")
198                                              'face 'notmuch-tag-face)
199                                  ")"))))))
200
201 (defun notmuch-show-insert-headerline (headers date tags depth)
202   "Insert a notmuch style headerline based on HEADERS for a
203 message at DEPTH in the current thread."
204   (let ((start (point)))
205     (insert (notmuch-show-spaces-n depth)
206             (plist-get headers :From)
207             " ("
208             date
209             ") ("
210             (propertize (mapconcat 'identity tags " ")
211                         'face 'notmuch-tag-face)
212             ")\n")
213     (overlay-put (make-overlay start (point)) 'face 'notmuch-message-summary-face)))
214
215 (defun notmuch-show-insert-header (header header-value)
216   "Insert a single header."
217   (insert header ": " header-value "\n"))
218
219 (defun notmuch-show-insert-headers (headers)
220   "Insert the headers of the current message."
221   (let ((start (point)))
222     (mapc '(lambda (header)
223              (let* ((header-symbol (intern (concat ":" header)))
224                     (header-value (plist-get headers header-symbol)))
225                (if (and header-value
226                         (not (string-equal "" header-value)))
227                    (notmuch-show-insert-header header header-value))))
228           notmuch-message-headers)
229     (save-excursion
230       (save-restriction
231         (narrow-to-region start (point-max))
232         (run-hooks 'notmuch-show-markup-headers-hook)))))
233
234 (define-button-type 'notmuch-show-part-button-type
235   'action 'notmuch-show-part-button-action
236   'follow-link t
237   'face 'message-mml)
238
239 (defun notmuch-show-insert-part-header (nth content-type declared-type &optional name)
240   (insert-button
241    (concat "[ "
242            (if name (concat name ": ") "")
243            declared-type
244            (if (not (string-equal declared-type content-type))
245                (concat " (as " content-type ")")
246              "")
247            " ]\n")
248    :type 'notmuch-show-part-button-type
249    :notmuch-part nth
250    :notmuch-filename name))
251
252 ;; Functions handling particular MIME parts.
253
254 (defun notmuch-show-save-part (message-id nth &optional filename)
255   (with-temp-buffer
256     ;; Always acquires the part via `notmuch part', even if it is
257     ;; available in the JSON output.
258     (insert (notmuch-show-get-bodypart-internal message-id nth))
259     (let ((file (read-file-name
260                  "Filename to save as: "
261                  (or mailcap-download-directory "~/")
262                  nil nil
263                  filename))
264           (require-final-newline nil)
265           (coding-system-for-write 'no-conversion))
266       (write-region (point-min) (point-max) file))))
267
268 (defun notmuch-show-mm-display-part-inline (msg part content-type content)
269   "Use the mm-decode/mm-view functions to display a part in the
270 current buffer, if possible."
271   (let ((display-buffer (current-buffer)))
272     (with-temp-buffer
273       (insert content)
274       (let ((handle (mm-make-handle (current-buffer) (list content-type))))
275         (set-buffer display-buffer)
276         (if (and (mm-inlinable-p handle)
277                  (mm-inlined-p handle))
278             (progn
279               (mm-display-part handle)
280               t)
281           nil)))))
282
283 (defun notmuch-show-insert-part-text/plain (msg part content-type nth depth declared-type)
284   (let ((start (point)))
285     ;; If this text/plain part is not the first part in the message,
286     ;; insert a header to make this clear.
287     (if (> nth 1)
288         (notmuch-show-insert-part-header nth declared-type content-type (plist-get part :filename)))
289     (insert (notmuch-show-get-bodypart-content msg part nth))
290     (save-excursion
291       (save-restriction
292         (narrow-to-region start (point-max))
293         (run-hook-with-args 'notmuch-show-insert-text/plain-hook depth))))
294   t)
295
296 (defun notmuch-show-insert-part-application/octet-stream (msg part content-type nth depth declared-type)
297   ;; If we can deduce a MIME type from the filename of the attachment,
298   ;; do so and pass it on to the handler for that type.
299   (if (plist-get part :filename)
300       (let ((extension (file-name-extension (plist-get part :filename)))
301             mime-type)
302         (if extension
303             (progn
304               (mailcap-parse-mimetypes)
305               (setq mime-type (mailcap-extension-to-mime extension))
306               (if (and mime-type
307                        (not (string-equal mime-type "application/octet-stream")))
308                   (notmuch-show-insert-bodypart-internal msg part mime-type nth depth content-type)
309                 nil))
310           nil))))
311
312 (defun notmuch-show-insert-part-*/* (msg part content-type nth depth declared-type)
313   ;; This handler _must_ succeed - it is the handler of last resort.
314   (notmuch-show-insert-part-header nth content-type declared-type (plist-get part :filename))
315   (let ((content (notmuch-show-get-bodypart-content msg part nth)))
316     (if content
317         (notmuch-show-mm-display-part-inline msg part content-type content)))
318   t)
319
320 ;; Functions for determining how to handle MIME parts.
321
322 (defun notmuch-show-split-content-type (content-type)
323   (split-string content-type "/"))
324
325 (defun notmuch-show-handlers-for (content-type)
326   "Return a list of content handlers for a part of type CONTENT-TYPE."
327   (let (result)
328     (mapc (lambda (func)
329             (if (functionp func)
330                 (push func result)))
331           ;; Reverse order of prefrence.
332           (list (intern (concat "notmuch-show-insert-part-*/*"))
333                 (intern (concat
334                          "notmuch-show-insert-part-"
335                          (car (notmuch-show-split-content-type content-type))
336                          "/*"))
337                 (intern (concat "notmuch-show-insert-part-" content-type))))
338     result))
339
340 ;; Helper for parts which are generally not included in the default
341 ;; JSON output.
342
343 (defun notmuch-show-get-bodypart-internal (message-id part-number)
344   (with-temp-buffer
345     (let ((coding-system-for-read 'no-conversion))
346       (call-process notmuch-command nil t nil
347                     "part" (format "--part=%s" part-number) message-id)
348       (buffer-string))))
349
350 (defun notmuch-show-get-bodypart-content (msg part nth)
351   (or (plist-get part :content)
352       (notmuch-show-get-bodypart-internal (concat "id:" (plist-get msg :id)) nth)))
353
354 ;; \f
355
356 (defun notmuch-show-insert-bodypart-internal (msg part content-type nth depth declared-type)
357   (let ((handlers (notmuch-show-handlers-for content-type)))
358     ;; Run the content handlers until one of them returns a non-nil
359     ;; value.
360     (while (and handlers
361                 (not (funcall (car handlers) msg part content-type nth depth declared-type)))
362       (setq handlers (cdr handlers))))
363   t)
364
365 (defun notmuch-show-insert-bodypart (msg part depth)
366   "Insert the body part PART at depth DEPTH in the current thread."
367   (let ((content-type (downcase (plist-get part :content-type)))
368         (nth (plist-get part :id)))
369     (notmuch-show-insert-bodypart-internal msg part content-type nth depth content-type))
370   ;; Some of the body part handlers leave point somewhere up in the
371   ;; part, so we make sure that we're down at the end.
372   (goto-char (point-max))
373   ;; Ensure that the part ends with a carriage return.
374   (if (not (bolp))
375       (insert "\n")))
376
377 (defun notmuch-show-insert-body (msg body depth)
378   "Insert the body BODY at depth DEPTH in the current thread."
379   (mapc '(lambda (part) (notmuch-show-insert-bodypart msg part depth)) body))
380
381 (defun notmuch-show-make-symbol (type)
382   (make-symbol (concat "notmuch-show-" type)))
383
384 (defun notmuch-show-strip-re (string)
385   (replace-regexp-in-string "\\([Rr]e: *\\)+" "" string))
386
387 (defvar notmuch-show-previous-subject "")
388 (make-variable-buffer-local 'notmuch-show-previous-subject)
389
390 (defun notmuch-show-insert-msg (msg depth)
391   "Insert the message MSG at depth DEPTH in the current thread."
392   (let* ((headers (plist-get msg :headers))
393          ;; Indentation causes the buffer offset of the start/end
394          ;; points to move, so we must use markers.
395          message-start message-end
396          content-start content-end
397          headers-start headers-end
398          body-start body-end
399          (headers-invis-spec (notmuch-show-make-symbol "header"))
400          (message-invis-spec (notmuch-show-make-symbol "message"))
401          (bare-subject (notmuch-show-strip-re (plist-get headers :Subject))))
402
403     ;; Set `buffer-invisibility-spec' to `nil' (a list), otherwise
404     ;; removing items from `buffer-invisibility-spec' (which is what
405     ;; `notmuch-show-headers-visible' and
406     ;; `notmuch-show-message-visible' do) is a no-op and has no
407     ;; effect. This caused threads with only matching messages to have
408     ;; those messages hidden initially because
409     ;; `buffer-invisibility-spec' stayed `t'.
410     ;;
411     ;; This needs to be set here (rather than just above the call to
412     ;; `notmuch-show-headers-visible') because some of the part
413     ;; rendering or body washing functions
414     ;; (e.g. `notmuch-wash-text/plain-citations') manipulate
415     ;; `buffer-invisibility-spec').
416     (when (eq buffer-invisibility-spec t)
417       (setq buffer-invisibility-spec nil))
418
419     (setq message-start (point-marker))
420
421     (notmuch-show-insert-headerline headers
422                                     (or (if notmuch-show-relative-dates
423                                             (plist-get msg :date_relative)
424                                           nil)
425                                         (plist-get headers :Date))
426                                     (plist-get msg :tags) depth)
427
428     (setq content-start (point-marker))
429
430     ;; Set `headers-start' to point after the 'Subject:' header to be
431     ;; compatible with the existing implementation. This just sets it
432     ;; to after the first header.
433     (notmuch-show-insert-headers headers)
434     ;; Headers should include a blank line (backwards compatibility).
435     (insert "\n")
436     (save-excursion
437       (goto-char content-start)
438       ;; If the subject of this message is the same as that of the
439       ;; previous message, don't display it when this message is
440       ;; collapsed.
441       (when (not (string= notmuch-show-previous-subject
442                           bare-subject))
443         (forward-line 1))
444       (setq headers-start (point-marker)))
445     (setq headers-end (point-marker))
446
447     (setq notmuch-show-previous-subject bare-subject)
448
449     (setq body-start (point-marker))
450     (notmuch-show-insert-body msg (plist-get msg :body) depth)
451     ;; Ensure that the body ends with a newline.
452     (if (not (bolp))
453         (insert "\n"))
454     (setq body-end (point-marker))
455     (setq content-end (point-marker))
456
457     ;; Indent according to the depth in the thread.
458     (indent-rigidly content-start content-end depth)
459
460     (setq message-end (point-max-marker))
461
462     ;; Save the extents of this message over the whole text of the
463     ;; message.
464     (put-text-property message-start message-end :notmuch-message-extent (cons message-start message-end))
465
466     (plist-put msg :headers-invis-spec headers-invis-spec)
467     (overlay-put (make-overlay headers-start headers-end) 'invisible headers-invis-spec)
468
469     (plist-put msg :message-invis-spec message-invis-spec)
470     (overlay-put (make-overlay body-start body-end) 'invisible message-invis-spec)
471
472     ;; Save the properties for this message. Currently this saves the
473     ;; entire message (augmented it with other stuff), which seems
474     ;; like overkill. We might save a reduced subset (for example, not
475     ;; the content).
476     (notmuch-show-set-message-properties msg)
477
478     ;; Set header visibility.
479     (notmuch-show-headers-visible msg notmuch-message-headers-visible)
480
481     ;; Message visibility depends on whether it matched the search
482     ;; criteria.
483     (notmuch-show-message-visible msg (plist-get msg :match))))
484
485 (defun notmuch-show-insert-tree (tree depth)
486   "Insert the message tree TREE at depth DEPTH in the current thread."
487   (let ((msg (car tree))
488         (replies (cadr tree)))
489     (notmuch-show-insert-msg msg depth)
490     (notmuch-show-insert-thread replies (1+ depth))))
491
492 (defun notmuch-show-insert-thread (thread depth)
493   "Insert the thread THREAD at depth DEPTH in the current forest."
494   (mapc '(lambda (tree) (notmuch-show-insert-tree tree depth)) thread))
495
496 (defun notmuch-show-insert-forest (forest)
497   "Insert the forest of threads FOREST."
498   (mapc '(lambda (thread) (notmuch-show-insert-thread thread 0)) forest))
499
500 (defvar notmuch-show-parent-buffer nil)
501
502 ;;;###autoload
503 (defun notmuch-show (thread-id &optional parent-buffer query-context buffer-name)
504   "Run \"notmuch show\" with the given thread ID and display results.
505
506 The optional PARENT-BUFFER is the notmuch-search buffer from
507 which this notmuch-show command was executed, (so that the
508 next thread from that buffer can be show when done with this
509 one).
510
511 The optional QUERY-CONTEXT is a notmuch search term. Only
512 messages from the thread matching this search term are shown if
513 non-nil.
514
515 The optional BUFFER-NAME provides the neame of the buffer in
516 which the message thread is shown. If it is nil (which occurs
517 when the command is called interactively) the argument to the
518 function is used. "
519   (interactive "sNotmuch show: ")
520   (let ((buffer (get-buffer-create (generate-new-buffer-name
521                                     (or buffer-name
522                                         (concat "*notmuch-" thread-id "*")))))
523         (inhibit-read-only t))
524     (switch-to-buffer buffer)
525     (notmuch-show-mode)
526     (set (make-local-variable 'notmuch-show-parent-buffer) parent-buffer)
527     (erase-buffer)
528     (goto-char (point-min))
529     (save-excursion
530       (let* ((basic-args (list thread-id))
531              (args (if query-context
532                        (append (list "\'") basic-args (list "and (" query-context ")\'"))
533                      (append (list "\'") basic-args (list "\'")))))
534         (notmuch-show-insert-forest (notmuch-query-get-threads args))
535         ;; If the query context reduced the results to nothing, run
536         ;; the basic query.
537         (when (and (eq (buffer-size) 0)
538                    query-context)
539           (notmuch-show-insert-forest
540            (notmuch-query-get-threads basic-args))))
541
542       ;; Enable buttonisation of URLs and email addresses in the
543       ;; buffer.
544       (goto-address-mode t)
545       ;; Act on visual lines rather than logical lines.
546       (visual-line-mode t)
547
548       (run-hooks 'notmuch-show-hook))
549
550     ;; Move straight to the first open message
551     (if (not (notmuch-show-message-visible-p))
552         (notmuch-show-next-open-message))
553
554     ;; Set the header line to the subject of the first open message.
555     (setq header-line-format (notmuch-show-strip-re (notmuch-show-get-subject)))
556
557     (notmuch-show-mark-read)))
558
559 (defvar notmuch-show-stash-map
560   (let ((map (make-sparse-keymap)))
561     (define-key map "c" 'notmuch-show-stash-cc)
562     (define-key map "d" 'notmuch-show-stash-date)
563     (define-key map "F" 'notmuch-show-stash-filename)
564     (define-key map "f" 'notmuch-show-stash-from)
565     (define-key map "i" 'notmuch-show-stash-message-id)
566     (define-key map "s" 'notmuch-show-stash-subject)
567     (define-key map "T" 'notmuch-show-stash-tags)
568     (define-key map "t" 'notmuch-show-stash-to)
569     map)
570   "Submap for stash commands")
571 (fset 'notmuch-show-stash-map notmuch-show-stash-map)
572
573 (defvar notmuch-show-mode-map
574       (let ((map (make-sparse-keymap)))
575         (define-key map "?" 'notmuch-help)
576         (define-key map "q" 'notmuch-kill-this-buffer)
577         (define-key map (kbd "<C-tab>") 'widget-backward)
578         (define-key map (kbd "M-TAB") 'notmuch-show-previous-button)
579         (define-key map (kbd "<backtab>") 'notmuch-show-previous-button)
580         (define-key map (kbd "TAB") 'notmuch-show-next-button)
581         (define-key map "s" 'notmuch-search)
582         (define-key map "m" 'notmuch-mua-mail)
583         (define-key map "f" 'notmuch-show-forward-message)
584         (define-key map "r" 'notmuch-show-reply)
585         (define-key map "|" 'notmuch-show-pipe-message)
586         (define-key map "w" 'notmuch-show-save-attachments)
587         (define-key map "V" 'notmuch-show-view-raw-message)
588         (define-key map "v" 'notmuch-show-view-all-mime-parts)
589         (define-key map "c" 'notmuch-show-stash-map)
590         (define-key map "h" 'notmuch-show-toggle-headers)
591         (define-key map "-" 'notmuch-show-remove-tag)
592         (define-key map "+" 'notmuch-show-add-tag)
593         (define-key map "x" 'notmuch-show-archive-thread-then-exit)
594         (define-key map "a" 'notmuch-show-archive-thread)
595         (define-key map "N" 'notmuch-show-next-message)
596         (define-key map "P" 'notmuch-show-previous-message)
597         (define-key map "n" 'notmuch-show-next-open-message)
598         (define-key map "p" 'notmuch-show-previous-open-message)
599         (define-key map (kbd "DEL") 'notmuch-show-rewind)
600         (define-key map " " 'notmuch-show-advance-and-archive)
601         (define-key map (kbd "M-RET") 'notmuch-show-open-or-close-all)
602         (define-key map (kbd "RET") 'notmuch-show-toggle-message)
603         map)
604       "Keymap for \"notmuch show\" buffers.")
605 (fset 'notmuch-show-mode-map notmuch-show-mode-map)
606
607 (defun notmuch-show-mode ()
608   "Major mode for viewing a thread with notmuch.
609
610 This buffer contains the results of the \"notmuch show\" command
611 for displaying a single thread of email from your email archives.
612
613 By default, various components of email messages, (citations,
614 signatures, already-read messages), are hidden. You can make
615 these parts visible by clicking with the mouse button or by
616 pressing RET after positioning the cursor on a hidden part, (for
617 which \\[notmuch-show-next-button] and \\[notmuch-show-previous-button] are helpful).
618
619 Reading the thread sequentially is well-supported by pressing
620 \\[notmuch-show-advance-and-archive]. This will scroll the current message (if necessary), advance
621 to the next message, or advance to the next thread (if already on
622 the last message of a thread).
623
624 Other commands are available to read or manipulate the thread
625 more selectively, (such as '\\[notmuch-show-next-message]' and '\\[notmuch-show-previous-message]' to advance to messages
626 without removing any tags, and '\\[notmuch-show-archive-thread]' to archive an entire thread
627 without scrolling through with \\[notmuch-show-advance-and-archive]).
628
629 You can add or remove arbitary tags from the current message with
630 '\\[notmuch-show-add-tag]' or '\\[notmuch-show-remove-tag]'.
631
632 All currently available key bindings:
633
634 \\{notmuch-show-mode-map}"
635   (interactive)
636   (kill-all-local-variables)
637   (use-local-map notmuch-show-mode-map)
638   (setq major-mode 'notmuch-show-mode
639         mode-name "notmuch-show")
640   (setq buffer-read-only t))
641
642 (defun notmuch-show-move-to-message-top ()
643   (goto-char (notmuch-show-message-top)))
644
645 (defun notmuch-show-move-to-message-bottom ()
646   (goto-char (notmuch-show-message-bottom)))
647
648 (defun notmuch-show-message-adjust ()
649   (recenter 0))
650
651 ;; Movement related functions.
652
653 ;; There's some strangeness here where a text property applied to a
654 ;; region a->b is not found when point is at b. We walk backwards
655 ;; until finding the property.
656 (defun notmuch-show-message-extent ()
657   (let (r)
658     (save-excursion
659       (while (not (setq r (get-text-property (point) :notmuch-message-extent)))
660         (backward-char)))
661     r))
662
663 (defun notmuch-show-message-top ()
664   (car (notmuch-show-message-extent)))
665
666 (defun notmuch-show-message-bottom ()
667   (cdr (notmuch-show-message-extent)))
668
669 (defun notmuch-show-goto-message-next ()
670   (let ((start (point)))
671     (notmuch-show-move-to-message-bottom)
672     (if (not (eobp))
673         t
674       (goto-char start)
675       nil)))
676
677 (defun notmuch-show-goto-message-previous ()
678   (notmuch-show-move-to-message-top)
679   (if (bobp)
680       nil
681     (backward-char)
682     (notmuch-show-move-to-message-top)
683     t))
684
685 (defun notmuch-show-move-past-invisible-forward ()
686   (while (point-invisible-p)
687     (forward-char)))
688
689 (defun notmuch-show-move-past-invisible-backward ()
690   (while (point-invisible-p)
691     (backward-char)))
692
693 ;; Functions relating to the visibility of messages and their
694 ;; components.
695
696 (defun notmuch-show-element-visible (props visible-p spec-property)
697   (let ((spec (plist-get props spec-property)))
698     (if visible-p
699         (remove-from-invisibility-spec spec)
700       (add-to-invisibility-spec spec))))
701
702 (defun notmuch-show-message-visible (props visible-p)
703   (if visible-p
704       ;; When making the message visible, the headers may or not be
705       ;; visible. So we check that property separately.
706       (let ((headers-visible (plist-get props :headers-visible)))
707         (notmuch-show-element-visible props headers-visible :headers-invis-spec)
708         (notmuch-show-element-visible props t :message-invis-spec))
709     (notmuch-show-element-visible props nil :headers-invis-spec)
710     (notmuch-show-element-visible props nil :message-invis-spec))
711
712   (notmuch-show-set-prop :message-visible visible-p props))
713
714 (defun notmuch-show-headers-visible (props visible-p)
715   (if (plist-get props :message-visible)
716       (notmuch-show-element-visible props visible-p :headers-invis-spec))
717   (notmuch-show-set-prop :headers-visible visible-p props))
718
719 ;; Functions for setting and getting attributes of the current
720 ;; message.
721
722 (defun notmuch-show-set-message-properties (props)
723   (save-excursion
724     (notmuch-show-move-to-message-top)
725     (put-text-property (point) (+ (point) 1) :notmuch-message-properties props)))
726
727 (defun notmuch-show-get-message-properties ()
728   (save-excursion
729     (notmuch-show-move-to-message-top)
730     (get-text-property (point) :notmuch-message-properties)))
731
732 (defun notmuch-show-set-prop (prop val &optional props)
733   (let ((inhibit-read-only t)
734         (props (or props
735                    (notmuch-show-get-message-properties))))
736     (plist-put props prop val)
737     (notmuch-show-set-message-properties props)))
738
739 (defun notmuch-show-get-prop (prop &optional props)
740   (let ((props (or props
741                    (notmuch-show-get-message-properties))))
742     (plist-get props prop)))
743
744 (defun notmuch-show-get-message-id ()
745   "Return the message id of the current message."
746   (concat "id:\"" (notmuch-show-get-prop :id) "\""))
747
748 ;; dme: Would it make sense to use a macro for many of these?
749
750 (defun notmuch-show-get-filename ()
751   "Return the filename of the current message."
752   (notmuch-show-get-prop :filename))
753
754 (defun notmuch-show-get-header (header)
755   "Return the named header of the current message, if any."
756   (plist-get (notmuch-show-get-prop :headers) header))
757
758 (defun notmuch-show-get-cc ()
759   (notmuch-show-get-header :Cc))
760
761 (defun notmuch-show-get-date ()
762   (notmuch-show-get-header :Date))
763
764 (defun notmuch-show-get-from ()
765   (notmuch-show-get-header :From))
766
767 (defun notmuch-show-get-subject ()
768   (notmuch-show-get-header :Subject))
769
770 (defun notmuch-show-get-to ()
771   (notmuch-show-get-header :To))
772
773 (defun notmuch-show-set-tags (tags)
774   "Set the tags of the current message."
775   (notmuch-show-set-prop :tags tags)
776   (notmuch-show-update-tags tags))
777
778 (defun notmuch-show-get-tags ()
779   "Return the tags of the current message."
780   (notmuch-show-get-prop :tags))
781
782 (defun notmuch-show-message-visible-p ()
783   "Is the current message visible?"
784   (notmuch-show-get-prop :message-visible))
785
786 (defun notmuch-show-headers-visible-p ()
787   "Are the headers of the current message visible?"
788   (notmuch-show-get-prop :headers-visible))
789
790 (defun notmuch-show-mark-read ()
791   "Mark the current message as read."
792   (notmuch-show-remove-tag "unread"))
793
794 ;; Functions for getting attributes of several messages in the current
795 ;; thread.
796
797 (defun notmuch-show-get-message-ids-for-open-messages ()
798   "Return a list of all message IDs for open messages in the current thread."
799   (save-excursion
800     (let (message-ids done)
801       (goto-char (point-min))
802       (while (not done)
803         (if (notmuch-show-message-visible-p)
804             (setq message-ids (append message-ids (list (notmuch-show-get-message-id)))))
805         (setq done (not (notmuch-show-goto-message-next)))
806         )
807       message-ids
808       )))
809
810 ;; Commands typically bound to keys.
811
812 (defun notmuch-show-advance-and-archive ()
813   "Advance through thread and archive.
814
815 This command is intended to be one of the simplest ways to
816 process a thread of email. It does the following:
817
818 If the current message in the thread is not yet fully visible,
819 scroll by a near screenful to read more of the message.
820
821 Otherwise, (the end of the current message is already within the
822 current window), advance to the next open message.
823
824 Finally, if there is no further message to advance to, and this
825 last message is already read, then archive the entire current
826 thread, (remove the \"inbox\" tag from each message). Also kill
827 this buffer, and display the next thread from the search from
828 which this thread was originally shown."
829   (interactive)
830   (let ((end-of-this-message (notmuch-show-message-bottom)))
831     (cond
832      ;; Ideally we would test `end-of-this-message' against the result
833      ;; of `window-end', but that doesn't account for the fact that
834      ;; the end of the message might be hidden, so we have to actually
835      ;; go to the end, walk back over invisible text and then see if
836      ;; point is visible.
837      ((save-excursion
838         (goto-char (- end-of-this-message 1))
839         (notmuch-show-move-past-invisible-backward)
840         (> (point) (window-end)))
841       ;; The bottom of this message is not visible - scroll.
842       (scroll-up nil))
843
844      ((not (= end-of-this-message (point-max)))
845       ;; This is not the last message - move to the next visible one.
846       (notmuch-show-next-open-message))
847
848      (t
849       ;; This is the last message - archive the thread.
850       (notmuch-show-archive-thread)))))
851
852 (defun notmuch-show-rewind ()
853   "Backup through the thread, (reverse scrolling compared to \\[notmuch-show-advance-and-archive]).
854
855 Specifically, if the beginning of the previous email is fewer
856 than `window-height' lines from the current point, move to it
857 just like `notmuch-show-previous-message'.
858
859 Otherwise, just scroll down a screenful of the current message.
860
861 This command does not modify any message tags, (it does not undo
862 any effects from previous calls to
863 `notmuch-show-advance-and-archive'."
864   (interactive)
865   (let ((start-of-message (notmuch-show-message-top))
866         (start-of-window (window-start)))
867     (cond
868       ;; Either this message is properly aligned with the start of the
869       ;; window or the start of this message is not visible on the
870       ;; screen - scroll.
871      ((or (= start-of-message start-of-window)
872           (< start-of-message start-of-window))
873       (scroll-down)
874       ;; If a small number of lines from the previous message are
875       ;; visible, realign so that the top of the current message is at
876       ;; the top of the screen.
877       (if (<= (count-screen-lines (window-start) start-of-message)
878               next-screen-context-lines)
879           (progn
880             (goto-char (notmuch-show-message-top))
881             (notmuch-show-message-adjust)))
882       ;; Move to the top left of the window.
883       (goto-char (window-start)))
884      (t
885       ;; Move to the previous message.
886       (notmuch-show-previous-message)))))
887
888 (defun notmuch-show-reply ()
889   "Reply to the current message."
890   (interactive)
891   (notmuch-mua-reply (notmuch-show-get-message-id)))
892
893 (defun notmuch-show-forward-message ()
894   "Forward the current message."
895   (interactive)
896   (with-current-notmuch-show-message
897    (notmuch-mua-forward-message)))
898
899 (defun notmuch-show-next-message ()
900   "Show the next message."
901   (interactive)
902   (if (notmuch-show-goto-message-next)
903       (progn
904         (notmuch-show-mark-read)
905         (notmuch-show-message-adjust))
906     (goto-char (point-max))))
907
908 (defun notmuch-show-previous-message ()
909   "Show the previous message."
910   (interactive)
911   (notmuch-show-goto-message-previous)
912   (notmuch-show-mark-read)
913   (notmuch-show-message-adjust))
914
915 (defun notmuch-show-next-open-message ()
916   "Show the next message."
917   (interactive)
918   (let (r)
919     (while (and (setq r (notmuch-show-goto-message-next))
920                 (not (notmuch-show-message-visible-p))))
921     (if r
922         (progn
923           (notmuch-show-mark-read)
924           (notmuch-show-message-adjust))
925       (goto-char (point-max)))))
926
927 (defun notmuch-show-previous-open-message ()
928   "Show the previous message."
929   (interactive)
930   (while (and (notmuch-show-goto-message-previous)
931               (not (notmuch-show-message-visible-p))))
932   (notmuch-show-mark-read)
933   (notmuch-show-message-adjust))
934
935 (defun notmuch-show-view-raw-message ()
936   "View the file holding the current message."
937   (interactive)
938   (let* ((id (notmuch-show-get-message-id))
939          (buf (get-buffer-create (concat "*notmuch-raw-" id "*"))))
940     (call-process notmuch-command nil buf nil "show" "--format=raw" id)
941     (switch-to-buffer buf)
942     (goto-char (point-min))
943     (set-buffer-modified-p nil)
944     (view-buffer buf 'kill-buffer-if-not-modified)))
945
946 (defun notmuch-show-pipe-message (entire-thread command)
947   "Pipe the contents of the current message (or thread) to the given command.
948
949 The given command will be executed with the raw contents of the
950 current email message as stdin. Anything printed by the command
951 to stdout or stderr will appear in the *notmuch-pipe* buffer.
952
953 When invoked with a prefix argument, the command will receive all
954 open messages in the current thread (formatted as an mbox) rather
955 than only the current message."
956   (interactive "P\nsPipe message to command: ")
957   (let (shell-command)
958     (if entire-thread
959         (setq shell-command 
960               (concat notmuch-command " show --format=mbox "
961                       (shell-quote-argument
962                        (mapconcat 'identity (notmuch-show-get-message-ids-for-open-messages) " OR "))
963                       " | " command))
964       (setq shell-command
965             (concat notmuch-command " show --format=raw "
966                     (shell-quote-argument (notmuch-show-get-message-id)) " | " command)))
967     (let ((buf (get-buffer-create (concat "*notmuch-pipe*"))))
968       (with-current-buffer buf
969         (setq buffer-read-only nil)
970         (erase-buffer)
971         (let ((exit-code (call-process-shell-command shell-command nil buf)))
972           (goto-char (point-max))
973           (set-buffer-modified-p nil)
974           (setq buffer-read-only t)
975           (unless (zerop exit-code)
976             (switch-to-buffer-other-window buf)
977             (message (format "Command '%s' exited abnormally with code %d"
978                              shell-command exit-code))))))))
979
980 (defun notmuch-show-add-tags-worker (current-tags add-tags)
981   "Add to `current-tags' with any tags from `add-tags' not
982 currently present and return the result."
983   (let ((result-tags (copy-sequence current-tags)))
984     (mapc (lambda (add-tag)
985             (unless (member add-tag current-tags)
986               (setq result-tags (push add-tag result-tags))))
987             add-tags)
988     (sort result-tags 'string<)))
989
990 (defun notmuch-show-del-tags-worker (current-tags del-tags)
991   "Remove any tags in `del-tags' from `current-tags' and return
992 the result."
993   (let ((result-tags (copy-sequence current-tags)))
994     (mapc (lambda (del-tag)
995             (setq result-tags (delete del-tag result-tags)))
996           del-tags)
997     result-tags))
998
999 (defun notmuch-show-add-tag (&rest toadd)
1000   "Add a tag to the current message."
1001   (interactive
1002    (list (notmuch-select-tag-with-completion "Tag to add: ")))
1003
1004   (let* ((current-tags (notmuch-show-get-tags))
1005          (new-tags (notmuch-show-add-tags-worker current-tags toadd)))
1006
1007     (unless (equal current-tags new-tags)
1008       (apply 'notmuch-call-notmuch-process
1009              (append (cons "tag"
1010                            (mapcar (lambda (s) (concat "+" s)) toadd))
1011                      (cons (notmuch-show-get-message-id) nil)))
1012       (notmuch-show-set-tags new-tags))))
1013
1014 (defun notmuch-show-remove-tag (&rest toremove)
1015   "Remove a tag from the current message."
1016   (interactive
1017    (list (notmuch-select-tag-with-completion
1018           "Tag to remove: " (notmuch-show-get-message-id))))
1019
1020   (let* ((current-tags (notmuch-show-get-tags))
1021          (new-tags (notmuch-show-del-tags-worker current-tags toremove)))
1022
1023     (unless (equal current-tags new-tags)
1024       (apply 'notmuch-call-notmuch-process
1025              (append (cons "tag"
1026                            (mapcar (lambda (s) (concat "-" s)) toremove))
1027                      (cons (notmuch-show-get-message-id) nil)))
1028       (notmuch-show-set-tags new-tags))))
1029
1030 (defun notmuch-show-toggle-headers ()
1031   "Toggle the visibility of the current message headers."
1032   (interactive)
1033   (let ((props (notmuch-show-get-message-properties)))
1034     (notmuch-show-headers-visible
1035      props
1036      (not (plist-get props :headers-visible))))
1037   (force-window-update))
1038
1039 (defun notmuch-show-toggle-message ()
1040   "Toggle the visibility of the current message."
1041   (interactive)
1042   (let ((props (notmuch-show-get-message-properties)))
1043     (notmuch-show-message-visible
1044      props
1045      (not (plist-get props :message-visible))))
1046   (force-window-update))
1047
1048 (defun notmuch-show-open-or-close-all ()
1049   "Set the visibility all of the messages in the current thread.
1050 By default make all of the messages visible. With a prefix
1051 argument, hide all of the messages."
1052   (interactive)
1053   (save-excursion
1054     (goto-char (point-min))
1055     (loop do (notmuch-show-message-visible (notmuch-show-get-message-properties)
1056                                            (not current-prefix-arg))
1057           until (not (notmuch-show-goto-message-next))))
1058   (force-window-update))
1059
1060 (defun notmuch-show-next-button ()
1061   "Advance point to the next button in the buffer."
1062   (interactive)
1063   (forward-button 1))
1064
1065 (defun notmuch-show-previous-button ()
1066   "Move point back to the previous button in the buffer."
1067   (interactive)
1068   (backward-button 1))
1069
1070 (defun notmuch-show-archive-thread-internal (show-next)
1071   ;; Remove the tag from the current set of messages.
1072   (goto-char (point-min))
1073   (loop do (notmuch-show-remove-tag "inbox")
1074         until (not (notmuch-show-goto-message-next)))
1075   ;; Move to the next item in the search results, if any.
1076   (let ((parent-buffer notmuch-show-parent-buffer))
1077     (notmuch-kill-this-buffer)
1078     (if parent-buffer
1079         (progn
1080           (switch-to-buffer parent-buffer)
1081           (forward-line)
1082           (if show-next
1083               (notmuch-search-show-thread))))))
1084
1085 (defun notmuch-show-archive-thread ()
1086   "Archive each message in thread, then show next thread from search.
1087
1088 Archive each message currently shown by removing the \"inbox\"
1089 tag from each. Then kill this buffer and show the next thread
1090 from the search from which this thread was originally shown.
1091
1092 Note: This command is safe from any race condition of new messages
1093 being delivered to the same thread. It does not archive the
1094 entire thread, but only the messages shown in the current
1095 buffer."
1096   (interactive)
1097   (notmuch-show-archive-thread-internal t))
1098
1099 (defun notmuch-show-archive-thread-then-exit ()
1100   "Archive each message in thread, then exit back to search results."
1101   (interactive)
1102   (notmuch-show-archive-thread-internal nil))
1103
1104 (defun notmuch-show-stash-cc ()
1105   "Copy CC field of current message to kill-ring."
1106   (interactive)
1107   (notmuch-common-do-stash (notmuch-show-get-cc)))
1108
1109 (defun notmuch-show-stash-date ()
1110   "Copy date of current message to kill-ring."
1111   (interactive)
1112   (notmuch-common-do-stash (notmuch-show-get-date)))
1113
1114 (defun notmuch-show-stash-filename ()
1115   "Copy filename of current message to kill-ring."
1116   (interactive)
1117   (notmuch-common-do-stash (notmuch-show-get-filename)))
1118
1119 (defun notmuch-show-stash-from ()
1120   "Copy From address of current message to kill-ring."
1121   (interactive)
1122   (notmuch-common-do-stash (notmuch-show-get-from)))
1123
1124 (defun notmuch-show-stash-message-id ()
1125   "Copy message ID of current message to kill-ring."
1126   (interactive)
1127   (notmuch-common-do-stash (notmuch-show-get-message-id)))
1128
1129 (defun notmuch-show-stash-subject ()
1130   "Copy Subject field of current message to kill-ring."
1131   (interactive)
1132   (notmuch-common-do-stash (notmuch-show-get-subject)))
1133
1134 (defun notmuch-show-stash-tags ()
1135   "Copy tags of current message to kill-ring as a comma separated list."
1136   (interactive)
1137   (notmuch-common-do-stash (mapconcat 'identity (notmuch-show-get-tags) ",")))
1138
1139 (defun notmuch-show-stash-to ()
1140   "Copy To address of current message to kill-ring."
1141   (interactive)
1142   (notmuch-common-do-stash (notmuch-show-get-to)))
1143
1144 ;; Commands typically bound to buttons.
1145
1146 (defun notmuch-show-part-button-action (button)
1147   (let ((nth (button-get button :notmuch-part)))
1148     (if nth
1149         (notmuch-show-save-part (notmuch-show-get-message-id) nth
1150                                 (button-get button :notmuch-filename))
1151       (message "Not a valid part (is it a fake part?)."))))
1152
1153 ;;
1154
1155 (provide 'notmuch-show)