git.notmuchmail.org Git - notmuch/blob - emacs/notmuch.el

   1 ; notmuch.el --- run notmuch within emacs
   2 ;
   3 ; Copyright © Carl Worth
   4 ;
   5 ; This file is part of Notmuch.
   6 ;
   7 ; Notmuch is free software: you can redistribute it and/or modify it
   8 ; under the terms of the GNU General Public License as published by
   9 ; the Free Software Foundation, either version 3 of the License, or
  10 ; (at your option) any later version.
  11 ;
  12 ; Notmuch is distributed in the hope that it will be useful, but
  13 ; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 ; General Public License for more details.
  16 ;
  17 ; You should have received a copy of the GNU General Public License
  18 ; along with Notmuch.  If not, see <http://www.gnu.org/licenses/>.
  19 ;
  20 ; Authors: Carl Worth <cworth@cworth.org>
  21
  22 ; This is an emacs-based interface to the notmuch mail system.
  23 ;
  24 ; You will first need to have the notmuch program installed and have a
  25 ; notmuch database built in order to use this. See
  26 ; http://notmuchmail.org for details.
  27 ;
  28 ; To install this software, copy it to a directory that is on the
  29 ; `load-path' variable within emacs (a good candidate is
  30 ; /usr/local/share/emacs/site-lisp). If you are viewing this from the
  31 ; notmuch source distribution then you can simply run:
  32 ;
  33 ;       sudo make install-emacs
  34 ;
  35 ; to install it.
  36 ;
  37 ; Then, to actually run it, add:
  38 ;
  39 ;       (require 'notmuch)
  40 ;
  41 ; to your ~/.emacs file, and then run "M-x notmuch" from within emacs,
  42 ; or run:
  43 ;
  44 ;       emacs -f notmuch
  45 ;
  46 ; Have fun, and let us know if you have any comment, questions, or
  47 ; kudos: Notmuch list <notmuch@notmuchmail.org> (subscription is not
  48 ; required, but is available from http://notmuchmail.org).
  49
  50 (require 'cl)
  51 (require 'mm-view)
  52 (require 'message)
  53
  54 (require 'notmuch-lib)
  55 (require 'notmuch-show)
  56
  57 (defun notmuch-select-tag-with-completion (prompt &rest search-terms)
  58   (let ((tag-list
  59          (with-output-to-string
  60            (with-current-buffer standard-output
  61              (apply 'call-process notmuch-command nil t nil "search-tags" search-terms)))))
  62     (completing-read prompt (split-string tag-list "\n+" t) nil nil nil)))
  63
  64 (defun notmuch-foreach-mime-part (function mm-handle)
  65   (cond ((stringp (car mm-handle))
  66          (dolist (part (cdr mm-handle))
  67            (notmuch-foreach-mime-part function part)))
  68         ((bufferp (car mm-handle))
  69          (funcall function mm-handle))
  70         (t (dolist (part mm-handle)
  71              (notmuch-foreach-mime-part function part)))))
  72
  73 (defun notmuch-count-attachments (mm-handle)
  74   (let ((count 0))
  75     (notmuch-foreach-mime-part
  76      (lambda (p)
  77        (let ((disposition (mm-handle-disposition p)))
  78          (and (listp disposition)
  79               (or (equal (car disposition) "attachment")
  80                   (and (equal (car disposition) "inline")
  81                        (assq 'filename disposition)))
  82               (incf count))))
  83      mm-handle)
  84     count))
  85
  86 (defun notmuch-save-attachments (mm-handle &optional queryp)
  87   (notmuch-foreach-mime-part
  88    (lambda (p)
  89      (let ((disposition (mm-handle-disposition p)))
  90        (and (listp disposition)
  91             (or (equal (car disposition) "attachment")
  92                 (and (equal (car disposition) "inline")
  93                      (assq 'filename disposition)))
  94             (or (not queryp)
  95                 (y-or-n-p
  96                  (concat "Save '" (cdr (assq 'filename disposition)) "' ")))
  97             (mm-save-part p))))
  98    mm-handle))
  99
 100 (defun notmuch-reply (query-string)
 101   (switch-to-buffer (generate-new-buffer "notmuch-draft"))
 102   (call-process notmuch-command nil t nil "reply" query-string)
 103   (message-insert-signature)
 104   (goto-char (point-min))
 105   (if (re-search-forward "^$" nil t)
 106       (progn
 107         (insert "--text follows this line--")
 108         (forward-line)))
 109   (message-mode))
 110
 111 (defun notmuch-toggle-invisible-action (cite-button)
 112   (let ((invis-spec (button-get cite-button 'invisibility-spec)))
 113         (if (invisible-p invis-spec)
 114             (remove-from-invisibility-spec invis-spec)
 115           (add-to-invisibility-spec invis-spec)
 116           ))
 117   (force-window-update)
 118   (redisplay t))
 119
 120 (define-button-type 'notmuch-button-citation-toggle-type 'help-echo "mouse-1, RET: Show citation"
 121   :supertype 'notmuch-button-invisibility-toggle-type)
 122 (define-button-type 'notmuch-button-signature-toggle-type 'help-echo "mouse-1, RET: Show signature"
 123   :supertype 'notmuch-button-invisibility-toggle-type)
 124 (define-button-type 'notmuch-button-body-toggle-type
 125   'help-echo "mouse-1, RET: Show message"
 126   'face 'notmuch-message-summary-face
 127   :supertype 'notmuch-button-invisibility-toggle-type)
 128
 129 (defun notmuch-fontify-headers ()
 130   (while (looking-at "[[:space:]]")
 131     (forward-char))
 132   (if (looking-at "[Tt]o:")
 133       (progn
 134         (overlay-put (make-overlay (point) (re-search-forward ":"))
 135                      'face 'message-header-name)
 136         (overlay-put (make-overlay (point) (re-search-forward ".*$"))
 137                      'face 'message-header-to))
 138     (if (looking-at "[B]?[Cc][Cc]:")
 139         (progn
 140           (overlay-put (make-overlay (point) (re-search-forward ":"))
 141                        'face 'message-header-name)
 142           (overlay-put (make-overlay (point) (re-search-forward ".*$"))
 143                        'face 'message-header-cc))
 144       (if (looking-at "[Ss]ubject:")
 145           (progn
 146             (overlay-put (make-overlay (point) (re-search-forward ":"))
 147                          'face 'message-header-name)
 148             (overlay-put (make-overlay (point) (re-search-forward ".*$"))
 149                          'face 'message-header-subject))
 150         (if (looking-at "[Ff]rom:")
 151             (progn
 152               (overlay-put (make-overlay (point) (re-search-forward ":"))
 153                            'face 'message-header-name)
 154               (overlay-put (make-overlay (point) (re-search-forward ".*$"))
 155                            'face 'message-header-other))
 156           (if (looking-at "[Dd]ate:")
 157              (progn
 158                (overlay-put (make-overlay (point) (re-search-forward ":"))
 159                             'face 'message-header-name)
 160                (overlay-put (make-overlay (point) (re-search-forward ".*$"))
 161                             'face 'message-header-other))))))))
 162
 163 (defun notmuch-documentation-first-line (symbol)
 164   "Return the first line of the documentation string for SYMBOL."
 165   (let ((doc (documentation symbol)))
 166     (if doc
 167         (with-temp-buffer
 168           (insert (documentation symbol t))
 169           (goto-char (point-min))
 170           (let ((beg (point)))
 171             (end-of-line)
 172             (buffer-substring beg (point))))
 173       "")))
 174
 175 (defun notmuch-prefix-key-description (key)
 176   "Given a prefix key code, return a human-readable string representation.
 177
 178 This is basically just `format-kbd-macro' but we also convert ESC to M-."
 179   (let ((desc (format-kbd-macro (vector key))))
 180     (if (string= desc "ESC")
 181         "M-"
 182       (concat desc " "))))
 183
 184 ; I would think that emacs would have code handy for walking a keymap
 185 ; and generating strings for each key, and I would prefer to just call
 186 ; that. But I couldn't find any (could be all implemented in C I
 187 ; suppose), so I wrote my own here.
 188 (defun notmuch-substitute-one-command-key-with-prefix (prefix binding)
 189   "For a key binding, return a string showing a human-readable
 190 representation of the prefixed key as well as the first line of
 191 documentation from the bound function.
 192
 193 For a mouse binding, return nil."
 194   (let ((key (car binding))
 195         (action (cdr binding)))
 196     (if (mouse-event-p key)
 197         nil
 198       (if (keymapp action)
 199           (let ((substitute (apply-partially 'notmuch-substitute-one-command-key-with-prefix (notmuch-prefix-key-description key)))
 200                 (as-list))
 201             (map-keymap (lambda (a b)
 202                           (push (cons a b) as-list))
 203                         action)
 204             (mapconcat substitute as-list "\n"))
 205         (concat prefix (format-kbd-macro (vector key))
 206                 "\t"
 207                 (notmuch-documentation-first-line action))))))
 208
 209 (defalias 'notmuch-substitute-one-command-key
 210   (apply-partially 'notmuch-substitute-one-command-key-with-prefix nil))
 211
 212 (defun notmuch-substitute-command-keys (doc)
 213   "Like `substitute-command-keys' but with documentation, not function names."
 214   (let ((beg 0))
 215     (while (string-match "\\\\{\\([^}[:space:]]*\\)}" doc beg)
 216       (let ((map (substring doc (match-beginning 1) (match-end 1))))
 217         (setq doc (replace-match (mapconcat 'notmuch-substitute-one-command-key
 218                                             (cdr (symbol-value (intern map))) "\n") 1 1 doc)))
 219       (setq beg (match-end 0)))
 220     doc))
 221
 222 (defun notmuch-help ()
 223   "Display help for the current notmuch mode."
 224   (interactive)
 225   (let* ((mode major-mode)
 226          (doc (substitute-command-keys (notmuch-substitute-command-keys (documentation mode t)))))
 227     (with-current-buffer (generate-new-buffer "*notmuch-help*")
 228       (insert doc)
 229       (goto-char (point-min))
 230       (set-buffer-modified-p nil)
 231       (view-buffer (current-buffer) 'kill-buffer-if-not-modified))))
 232
 233 (defgroup notmuch nil
 234   "Notmuch mail reader for Emacs."
 235   :group 'mail)
 236
 237 (defcustom notmuch-search-hook nil
 238   "List of functions to call when notmuch displays the search results."
 239   :type 'hook
 240   :options '(hl-line-mode)
 241   :group 'notmuch)
 242
 243 (defvar notmuch-search-authors-width 20
 244   "Number of columns to use to display authors in a notmuch-search buffer.")
 245
 246 (defvar notmuch-search-mode-map
 247   (let ((map (make-sparse-keymap)))
 248     (define-key map "?" 'notmuch-help)
 249     (define-key map "q" 'kill-this-buffer)
 250     (define-key map "x" 'kill-this-buffer)
 251     (define-key map (kbd "<DEL>") 'notmuch-search-scroll-down)
 252     (define-key map "b" 'notmuch-search-scroll-down)
 253     (define-key map " " 'notmuch-search-scroll-up)
 254     (define-key map "<" 'notmuch-search-first-thread)
 255     (define-key map ">" 'notmuch-search-last-thread)
 256     (define-key map "p" 'notmuch-search-previous-thread)
 257     (define-key map "n" 'notmuch-search-next-thread)
 258     (define-key map "r" 'notmuch-search-reply-to-thread)
 259     (define-key map "m" 'message-mail)
 260     (define-key map "s" 'notmuch-search)
 261     (define-key map "o" 'notmuch-search-toggle-order)
 262     (define-key map "=" 'notmuch-search-refresh-view)
 263     (define-key map "t" 'notmuch-search-filter-by-tag)
 264     (define-key map "f" 'notmuch-search-filter)
 265     (define-key map [mouse-1] 'notmuch-search-show-thread)
 266     (define-key map "*" 'notmuch-search-operate-all)
 267     (define-key map "a" 'notmuch-search-archive-thread)
 268     (define-key map "-" 'notmuch-search-remove-tag)
 269     (define-key map "+" 'notmuch-search-add-tag)
 270     (define-key map (kbd "RET") 'notmuch-search-show-thread)
 271     (define-key map "F" 'notmuch-folder)
 272     map)
 273   "Keymap for \"notmuch search\" buffers.")
 274 (fset 'notmuch-search-mode-map notmuch-search-mode-map)
 275
 276 (defvar notmuch-search-query-string)
 277 (defvar notmuch-search-target-thread)
 278 (defvar notmuch-search-target-line)
 279 (defvar notmuch-search-oldest-first t
 280   "Show the oldest mail first in the search-mode")
 281
 282 (defvar notmuch-search-disjunctive-regexp      "\\<[oO][rR]\\>")
 283
 284 (defun notmuch-search-scroll-up ()
 285   "Move forward through search results by one window's worth."
 286   (interactive)
 287   (condition-case nil
 288       (scroll-up nil)
 289     ((end-of-buffer) (notmuch-search-last-thread))))
 290
 291 (defun notmuch-search-scroll-down ()
 292   "Move backward through the search results by one window's worth."
 293   (interactive)
 294   ; I don't know why scroll-down doesn't signal beginning-of-buffer
 295   ; the way that scroll-up signals end-of-buffer, but c'est la vie.
 296   ;
 297   ; So instead of trapping a signal we instead check whether the
 298   ; window begins on the first line of the buffer and if so, move
 299   ; directly to that position. (We have to count lines since the
 300   ; window-start position is not the same as point-min due to the
 301   ; invisible thread-ID characters on the first line.
 302   (if (equal (count-lines (point-min) (window-start)) 0)
 303       (goto-char (point-min))
 304     (scroll-down nil)))
 305
 306 (defun notmuch-search-next-thread ()
 307   "Select the next thread in the search results."
 308   (interactive)
 309   (forward-line 1))
 310
 311 (defun notmuch-search-previous-thread ()
 312   "Select the previous thread in the search results."
 313   (interactive)
 314   (forward-line -1))
 315
 316 (defun notmuch-search-last-thread ()
 317   "Select the last thread in the search results."
 318   (interactive)
 319   (goto-char (point-max))
 320   (forward-line -2))
 321
 322 (defun notmuch-search-first-thread ()
 323   "Select the first thread in the search results."
 324   (interactive)
 325   (goto-char (point-min)))
 326
 327 (defface notmuch-message-summary-face
 328  '((((class color) (background light)) (:background "#f0f0f0"))
 329    (((class color) (background dark)) (:background "#303030")))
 330  "Face for the single-line message summary in notmuch-show-mode."
 331  :group 'notmuch)
 332
 333 (defface notmuch-tag-face
 334   '((((class color)
 335       (background dark))
 336      (:foreground "OliveDrab1"))
 337     (((class color)
 338       (background light))
 339      (:foreground "navy blue" :bold t))
 340     (t
 341      (:bold t)))
 342   "Notmuch search mode face used to highligh tags."
 343   :group 'notmuch)
 344
 345 (defvar notmuch-tag-face-alist nil
 346   "List containing the tag list that need to be highlighed")
 347
 348 (defvar notmuch-search-font-lock-keywords  nil)
 349
 350 ;;;###autoload
 351 (defun notmuch-search-mode ()
 352   "Major mode displaying results of a notmuch search.
 353
 354 This buffer contains the results of a \"notmuch search\" of your
 355 email archives. Each line in the buffer represents a single
 356 thread giving a summary of the thread (a relative date, the
 357 number of matched messages and total messages in the thread,
 358 participants in the thread, a representative subject line, and
 359 any tags).
 360
 361 Pressing \\[notmuch-search-show-thread] on any line displays that thread. The '\\[notmuch-search-add-tag]' and '\\[notmuch-search-remove-tag]'
 362 keys can be used to add or remove tags from a thread. The '\\[notmuch-search-archive-thread]' key
 363 is a convenience for archiving a thread (removing the \"inbox\"
 364 tag). The '\\[notmuch-search-operate-all]' key can be used to add or remove a tag from all
 365 threads in the current buffer.
 366
 367 Other useful commands are '\\[notmuch-search-filter]' for filtering the current search
 368 based on an additional query string, '\\[notmuch-search-filter-by-tag]' for filtering to include
 369 only messages with a given tag, and '\\[notmuch-search]' to execute a new, global
 370 search.
 371
 372 Complete list of currently available key bindings:
 373
 374 \\{notmuch-search-mode-map}"
 375   (interactive)
 376   (kill-all-local-variables)
 377   (make-local-variable 'notmuch-search-query-string)
 378   (make-local-variable 'notmuch-search-oldest-first)
 379   (make-local-variable 'notmuch-search-target-thread)
 380   (make-local-variable 'notmuch-search-target-line)
 381   (set (make-local-variable 'scroll-preserve-screen-position) t)
 382   (add-to-invisibility-spec 'notmuch-search)
 383   (use-local-map notmuch-search-mode-map)
 384   (setq truncate-lines t)
 385   (setq major-mode 'notmuch-search-mode
 386         mode-name "notmuch-search")
 387   (setq buffer-read-only t)
 388   (if (not notmuch-tag-face-alist)
 389       (add-to-list 'notmuch-search-font-lock-keywords (list
 390                 "(\\([^()]*\\))$" '(1  'notmuch-tag-face)))
 391     (let ((notmuch-search-tags (mapcar 'car notmuch-tag-face-alist)))
 392       (loop for notmuch-search-tag  in notmuch-search-tags
 393             do (add-to-list 'notmuch-search-font-lock-keywords (list
 394                         (concat "([^)]*\\(" notmuch-search-tag "\\)[^)]*)$")
 395                         `(1  ,(cdr (assoc notmuch-search-tag notmuch-tag-face-alist))))))))
 396   (set (make-local-variable 'font-lock-defaults)
 397          '(notmuch-search-font-lock-keywords t)))
 398
 399 (defun notmuch-search-properties-in-region (property beg end)
 400   (save-excursion
 401     (let ((output nil)
 402           (last-line (line-number-at-pos end)))
 403       (goto-char beg)
 404       (beginning-of-line)
 405       (while (<= (line-number-at-pos) last-line)
 406         (setq output (cons (get-text-property (point) property) output))
 407         (forward-line 1))
 408       output)))
 409
 410 (defun notmuch-search-find-thread-id ()
 411   "Return the thread for the current thread"
 412   (get-text-property (point) 'notmuch-search-thread-id))
 413
 414 (defun notmuch-search-find-thread-id-region (beg end)
 415   "Return a list of threads for the current region"
 416   (notmuch-search-properties-in-region 'notmuch-search-thread-id beg end))
 417
 418 (defun notmuch-search-find-authors ()
 419   "Return the authors for the current thread"
 420   (get-text-property (point) 'notmuch-search-authors))
 421
 422 (defun notmuch-search-find-authors-region (beg end)
 423   "Return a list of authors for the current region"
 424   (notmuch-search-properties-in-region 'notmuch-search-authors beg end))
 425
 426 (defun notmuch-search-find-subject ()
 427   "Return the subject for the current thread"
 428   (get-text-property (point) 'notmuch-search-subject))
 429
 430 (defun notmuch-search-find-subject-region (beg end)
 431   "Return a list of authors for the current region"
 432   (notmuch-search-properties-in-region 'notmuch-search-subject beg end))
 433
 434 (defun notmuch-search-show-thread ()
 435   "Display the currently selected thread."
 436   (interactive)
 437   (let ((thread-id (notmuch-search-find-thread-id))
 438         (subject (notmuch-search-find-subject))
 439         buffer-name)
 440     (when (string-match "^[ \t]*$" subject)
 441       (setq subject "[No Subject]"))
 442     (setq buffer-name (concat "*"
 443                               (truncate-string-to-width subject 32 nil nil t)
 444                               "*"))
 445     (if (> (length thread-id) 0)
 446         (notmuch-show thread-id
 447                       (current-buffer)
 448                       notmuch-search-query-string
 449                       buffer-name)
 450       (error "End of search results"))))
 451
 452 (defun notmuch-search-reply-to-thread ()
 453   "Begin composing a reply to the entire current thread in a new buffer."
 454   (interactive)
 455   (let ((message-id (notmuch-search-find-thread-id)))
 456     (notmuch-reply message-id)))
 457
 458 (defun notmuch-call-notmuch-process (&rest args)
 459   "Synchronously invoke \"notmuch\" with the given list of arguments.
 460
 461 Output from the process will be presented to the user as an error
 462 and will also appear in a buffer named \"*Notmuch errors*\"."
 463   (let ((error-buffer (get-buffer-create "*Notmuch errors*")))
 464     (with-current-buffer error-buffer
 465         (erase-buffer))
 466     (if (eq (apply 'call-process notmuch-command nil error-buffer nil args) 0)
 467         (point)
 468       (progn
 469         (with-current-buffer error-buffer
 470           (let ((beg (point-min))
 471                 (end (- (point-max) 1)))
 472             (error (buffer-substring beg end))
 473             ))))))
 474
 475 (defun notmuch-search-set-tags (tags)
 476   (save-excursion
 477     (end-of-line)
 478     (re-search-backward "(")
 479     (forward-char)
 480     (let ((beg (point))
 481           (inhibit-read-only t))
 482       (re-search-forward ")")
 483       (backward-char)
 484       (let ((end (point)))
 485         (delete-region beg end)
 486         (insert (mapconcat  'identity tags " "))))))
 487
 488 (defun notmuch-search-get-tags ()
 489   (save-excursion
 490     (end-of-line)
 491     (re-search-backward "(")
 492     (let ((beg (+ (point) 1)))
 493       (re-search-forward ")")
 494       (let ((end (- (point) 1)))
 495         (split-string (buffer-substring beg end))))))
 496
 497 (defun notmuch-search-get-tags-region (beg end)
 498   (save-excursion
 499     (let ((output nil)
 500           (last-line (line-number-at-pos end)))
 501       (goto-char beg)
 502       (while (<= (line-number-at-pos) last-line)
 503         (setq output (append output (notmuch-search-get-tags)))
 504         (forward-line 1))
 505       output)))
 506
 507 (defun notmuch-search-add-tag-thread (tag)
 508   (notmuch-call-notmuch-process "tag" (concat "+" tag) (notmuch-search-find-thread-id))
 509   (notmuch-search-set-tags (delete-dups (sort (cons tag (notmuch-search-get-tags)) 'string<))))
 510
 511 (defun notmuch-search-add-tag-region (tag beg end)
 512   (let ((search-id-string (mapconcat 'identity (notmuch-search-find-thread-id-region beg end) " or ")))
 513     (notmuch-call-notmuch-process "tag" (concat "+" tag) search-id-string)
 514     (save-excursion
 515       (let ((last-line (line-number-at-pos end)))
 516         (goto-char beg)
 517         (while (<= (line-number-at-pos) last-line)
 518           (notmuch-search-set-tags (delete-dups (sort (cons tag (notmuch-search-get-tags)) 'string<)))
 519           (forward-line))))))
 520
 521 (defun notmuch-search-remove-tag-thread (tag)
 522   (notmuch-call-notmuch-process "tag" (concat "-" tag) (notmuch-search-find-thread-id))
 523   (notmuch-search-set-tags (delete tag (notmuch-search-get-tags))))
 524
 525 (defun notmuch-search-remove-tag-region (tag beg end)
 526   (let ((search-id-string (mapconcat 'identity (notmuch-search-find-thread-id-region beg end) " or ")))
 527     (notmuch-call-notmuch-process "tag" (concat "-" tag) search-id-string)
 528     (save-excursion
 529       (let ((last-line (line-number-at-pos end)))
 530         (goto-char beg)
 531         (while (<= (line-number-at-pos) last-line)
 532           (notmuch-search-set-tags (delete tag (notmuch-search-get-tags)))
 533           (forward-line))))))
 534
 535 (defun notmuch-search-add-tag (tag)
 536   "Add a tag to the currently selected thread or region.
 537
 538 The tag is added to all messages in the currently selected thread
 539 or threads in the current region."
 540   (interactive
 541    (list (notmuch-select-tag-with-completion "Tag to add: ")))
 542   (save-excursion
 543     (if (region-active-p)
 544         (let* ((beg (region-beginning))
 545                (end (region-end)))
 546           (notmuch-search-add-tag-region tag beg end))
 547       (notmuch-search-add-tag-thread tag))))
 548
 549 (defun notmuch-search-remove-tag (tag)
 550   "Remove a tag from the currently selected thread or region.
 551
 552 The tag is removed from all messages in the currently selected
 553 thread or threads in the current region."
 554   (interactive
 555    (list (notmuch-select-tag-with-completion
 556           "Tag to remove: "
 557           (if (region-active-p)
 558               (mapconcat 'identity
 559                          (notmuch-search-find-thread-id-region (region-beginning) (region-end))
 560                          " ")
 561             (notmuch-search-find-thread-id)))))
 562   (save-excursion
 563     (if (region-active-p)
 564         (let* ((beg (region-beginning))
 565                (end (region-end)))
 566           (notmuch-search-remove-tag-region tag beg end))
 567       (notmuch-search-remove-tag-thread tag))))
 568
 569 (defun notmuch-search-archive-thread ()
 570   "Archive the currently selected thread (remove its \"inbox\" tag).
 571
 572 This function advances the next thread when finished."
 573   (interactive)
 574   (notmuch-search-remove-tag-thread "inbox")
 575   (forward-line))
 576
 577 (defun notmuch-search-process-sentinel (proc msg)
 578   "Add a message to let user know when \"notmuch search\" exits"
 579   (let ((buffer (process-buffer proc))
 580         (status (process-status proc))
 581         (exit-status (process-exit-status proc))
 582         (never-found-target-thread nil))
 583     (if (memq status '(exit signal))
 584         (if (buffer-live-p buffer)
 585             (with-current-buffer buffer
 586               (save-excursion
 587                 (let ((inhibit-read-only t)
 588                       (atbob (bobp)))
 589                   (goto-char (point-max))
 590                   (if (eq status 'signal)
 591                       (insert "Incomplete search results (search process was killed).\n"))
 592                   (if (eq status 'exit)
 593                       (progn
 594                         (insert "End of search results.")
 595                         (if (not (= exit-status 0))
 596                             (insert (format " (process returned %d)" exit-status)))
 597                         (insert "\n")
 598                         (if (and atbob
 599                                  (not (string= notmuch-search-target-thread "found")))
 600                             (set 'never-found-target-thread t))))))
 601               (if (and never-found-target-thread
 602                        notmuch-search-target-line)
 603                   (goto-line notmuch-search-target-line)))))))
 604
 605 (defcustom notmuch-search-line-faces nil
 606   "Tag/face mapping for line highlighting in notmuch-search.
 607
 608 Here is an example of how to color search results based on tags.
 609 (the following text would be placed in your ~/.emacs file):
 610
 611 (setq notmuch-search-line-faces '((\"delete\" . '(:foreground \"red\"))
 612                                  (\"unread\" . '(:foreground \"green\"))))
 613
 614 Order matters: for lines with multiple tags, the the first
 615 matching will be applied."
 616   :type '(alist :key-type (string) :value-type (list))
 617   :group 'notmuch)
 618
 619 (defun notmuch-search-color-line (start end line-tag-list)
 620   "Colorize lines in notmuch-show based on tags"
 621   (if notmuch-search-line-faces
 622       (let ((overlay (make-overlay start end))
 623             (tags-faces (copy-alist notmuch-search-line-faces)))
 624         (while tags-faces
 625           (let* ((tag-face (car tags-faces))
 626                  (tag (car tag-face))
 627                  (face (cdr tag-face)))
 628             (cond ((member tag line-tag-list)
 629                    (overlay-put overlay 'face face)
 630                    (setq tags-faces nil))
 631                   (t
 632                    (setq tags-faces (cdr tags-faces)))))))))
 633
 634 (defun notmuch-search-process-filter (proc string)
 635   "Process and filter the output of \"notmuch search\""
 636   (let ((buffer (process-buffer proc))
 637         (found-target nil))
 638     (if (buffer-live-p buffer)
 639         (with-current-buffer buffer
 640           (save-excursion
 641             (let ((line 0)
 642                   (more t)
 643                   (inhibit-read-only t))
 644               (while more
 645                 (if (string-match "^\\(thread:[0-9A-Fa-f]*\\) \\(.*\\) \\(\\[[0-9/]*\\]\\) \\([^;]*\\); \\(.*\\) (\\([^()]*\\))$" string line)
 646                     (let* ((thread-id (match-string 1 string))
 647                            (date (match-string 2 string))
 648                            (count (match-string 3 string))
 649                            (authors (match-string 4 string))
 650                            (authors-length (length authors))
 651                            (subject (match-string 5 string))
 652                            (tags (match-string 6 string))
 653                            (tag-list (if tags (save-match-data (split-string tags)))))
 654                       (if (> authors-length notmuch-search-authors-width)
 655                           (set 'authors (concat (substring authors 0 (- notmuch-search-authors-width 3)) "...")))
 656                       (goto-char (point-max))
 657                       (let ((beg (point-marker))
 658                             (format-string (format "%%s %%-7s %%-%ds %%s (%%s)\n" notmuch-search-authors-width)))
 659                         (insert (format format-string date count authors subject tags))
 660                         (notmuch-search-color-line beg (point-marker) tag-list)
 661                         (put-text-property beg (point-marker) 'notmuch-search-thread-id thread-id)
 662                         (put-text-property beg (point-marker) 'notmuch-search-authors authors)
 663                         (put-text-property beg (point-marker) 'notmuch-search-subject subject)
 664                         (if (string= thread-id notmuch-search-target-thread)
 665                             (progn
 666                               (set 'found-target beg)
 667                               (set 'notmuch-search-target-thread "found"))))
 668                       (set 'line (match-end 0)))
 669                   (set 'more nil)))))
 670           (if found-target
 671               (goto-char found-target)))
 672       (delete-process proc))))
 673
 674 (defun notmuch-search-operate-all (action)
 675   "Add/remove tags from all matching messages.
 676
 677 Tis command adds or removes tags from all messages matching the
 678 current search terms. When called interactively, this command
 679 will prompt for tags to be added or removed. Tags prefixed with
 680 '+' will be added and tags prefixed with '-' will be removed.
 681
 682 Each character of the tag name may consist of alphanumeric
 683 characters as well as `_.+-'.
 684 "
 685   (interactive "sOperation (+add -drop): notmuch tag ")
 686   (let ((action-split (split-string action " +")))
 687     ;; Perform some validation
 688     (let ((words action-split))
 689       (when (null words) (error "No operation given"))
 690       (while words
 691         (unless (string-match-p "^[-+][-+_.[:word:]]+$" (car words))
 692           (error "Action must be of the form `+thistag -that_tag'"))
 693         (setq words (cdr words))))
 694     (apply 'notmuch-call-notmuch-process "tag"
 695            (append action-split (list notmuch-search-query-string) nil))))
 696
 697 ;;;###autoload
 698 (defun notmuch-search (query &optional oldest-first target-thread target-line)
 699   "Run \"notmuch search\" with the given query string and display results.
 700
 701 The optional parameters are used as follows:
 702
 703   oldest-first: A Boolean controlling the sort order of returned threads
 704   target-thread: A thread ID (with the thread: prefix) that will be made
 705                  current if it appears in the search results.
 706   target-line: The line number to move to if the target thread does not
 707                appear in the search results."
 708   (interactive "sNotmuch search: ")
 709   (let ((buffer (get-buffer-create (concat "*notmuch-search-" query "*"))))
 710     (switch-to-buffer buffer)
 711     (notmuch-search-mode)
 712     (set 'notmuch-search-query-string query)
 713     (set 'notmuch-search-oldest-first oldest-first)
 714     (set 'notmuch-search-target-thread target-thread)
 715     (set 'notmuch-search-target-line target-line)
 716     (let ((proc (get-buffer-process (current-buffer)))
 717           (inhibit-read-only t))
 718       (if proc
 719           (error "notmuch search process already running for query `%s'" query)
 720         )
 721       (erase-buffer)
 722       (goto-char (point-min))
 723       (save-excursion
 724         (let ((proc (start-process-shell-command
 725                      "notmuch-search" buffer notmuch-command "search"
 726                      (if oldest-first "--sort=oldest-first" "--sort=newest-first")
 727                      (shell-quote-argument query))))
 728           (set-process-sentinel proc 'notmuch-search-process-sentinel)
 729           (set-process-filter proc 'notmuch-search-process-filter))))
 730     (run-hooks 'notmuch-search-hook)))
 731
 732 (defun notmuch-search-refresh-view ()
 733   "Refresh the current view.
 734
 735 Kills the current buffer and runs a new search with the same
 736 query string as the current search. If the current thread is in
 737 the new search results, then point will be placed on the same
 738 thread. Otherwise, point will be moved to attempt to be in the
 739 same relative position within the new buffer."
 740   (interactive)
 741   (let ((target-line (line-number-at-pos))
 742         (oldest-first notmuch-search-oldest-first)
 743         (target-thread (notmuch-search-find-thread-id))
 744         (query notmuch-search-query-string))
 745     (kill-this-buffer)
 746     (notmuch-search query oldest-first target-thread target-line)
 747     (goto-char (point-min))
 748     ))
 749
 750 (defun notmuch-search-toggle-order ()
 751   "Toggle the current search order.
 752
 753 By default, the \"inbox\" view created by `notmuch' is displayed
 754 in chronological order (oldest thread at the beginning of the
 755 buffer), while any global searches created by `notmuch-search'
 756 are displayed in reverse-chronological order (newest thread at
 757 the beginning of the buffer).
 758
 759 This command toggles the sort order for the current search.
 760
 761 Note that any filtered searches created by
 762 `notmuch-search-filter' retain the search order of the parent
 763 search."
 764   (interactive)
 765   (set 'notmuch-search-oldest-first (not notmuch-search-oldest-first))
 766   (notmuch-search-refresh-view))
 767
 768 (defun notmuch-search-filter (query)
 769   "Filter the current search results based on an additional query string.
 770
 771 Runs a new search matching only messages that match both the
 772 current search results AND the additional query string provided."
 773   (interactive "sFilter search: ")
 774   (let ((grouped-query (if (string-match-p notmuch-search-disjunctive-regexp query) (concat "( " query " )") query)))
 775     (notmuch-search (concat notmuch-search-query-string " and " grouped-query) notmuch-search-oldest-first)))
 776
 777 (defun notmuch-search-filter-by-tag (tag)
 778   "Filter the current search results based on a single tag.
 779
 780 Runs a new search matching only messages that match both the
 781 current search results AND that are tagged with the given tag."
 782   (interactive
 783    (list (notmuch-select-tag-with-completion "Filter by tag: ")))
 784   (notmuch-search (concat notmuch-search-query-string " and tag:" tag) notmuch-search-oldest-first))
 785
 786 ;;;###autoload
 787 (defun notmuch ()
 788   "Run notmuch to display all mail with tag of 'inbox'"
 789   (interactive)
 790   (notmuch-search "tag:inbox" notmuch-search-oldest-first))
 791
 792 (setq mail-user-agent 'message-user-agent)
 793
 794 (defvar notmuch-folder-mode-map
 795   (let ((map (make-sparse-keymap)))
 796     (define-key map "?" 'notmuch-help)
 797     (define-key map "x" 'kill-this-buffer)
 798     (define-key map "q" 'kill-this-buffer)
 799     (define-key map "m" 'message-mail)
 800     (define-key map "e" 'notmuch-folder-show-empty-toggle)
 801     (define-key map ">" 'notmuch-folder-last)
 802     (define-key map "<" 'notmuch-folder-first)
 803     (define-key map "=" 'notmuch-folder)
 804     (define-key map "s" 'notmuch-search)
 805     (define-key map [mouse-1] 'notmuch-folder-show-search)
 806     (define-key map (kbd "RET") 'notmuch-folder-show-search)
 807     (define-key map " " 'notmuch-folder-show-search)
 808     (define-key map "p" 'notmuch-folder-previous)
 809     (define-key map "n" 'notmuch-folder-next)
 810     map)
 811   "Keymap for \"notmuch folder\" buffers.")
 812
 813 (fset 'notmuch-folder-mode-map notmuch-folder-mode-map)
 814
 815 (defcustom notmuch-folders (quote (("inbox" . "tag:inbox") ("unread" . "tag:unread")))
 816   "List of searches for the notmuch folder view"
 817   :type '(alist :key-type (string) :value-type (string))
 818   :group 'notmuch)
 819
 820 (defun notmuch-folder-mode ()
 821   "Major mode for showing notmuch 'folders'.
 822
 823 This buffer contains a list of message counts returned by a
 824 customizable set of searches of your email archives. Each line in
 825 the buffer shows the name of a saved search and the resulting
 826 message count.
 827
 828 Pressing RET on any line opens a search window containing the
 829 results for the saved search on that line.
 830
 831 Here is an example of how the search list could be
 832 customized, (the following text would be placed in your ~/.emacs
 833 file):
 834
 835 (setq notmuch-folders '((\"inbox\" . \"tag:inbox\")
 836                         (\"unread\" . \"tag:inbox AND tag:unread\")
 837                         (\"notmuch\" . \"tag:inbox AND to:notmuchmail.org\")))
 838
 839 Of course, you can have any number of folders, each configured
 840 with any supported search terms (see \"notmuch help search-terms\").
 841
 842 Currently available key bindings:
 843
 844 \\{notmuch-folder-mode-map}"
 845   (interactive)
 846   (kill-all-local-variables)
 847   (use-local-map 'notmuch-folder-mode-map)
 848   (setq truncate-lines t)
 849   (hl-line-mode 1)
 850   (setq major-mode 'notmuch-folder-mode
 851         mode-name "notmuch-folder")
 852   (setq buffer-read-only t))
 853
 854 (defun notmuch-folder-next ()
 855   "Select the next folder in the list."
 856   (interactive)
 857   (forward-line 1)
 858   (if (eobp)
 859       (forward-line -1)))
 860
 861 (defun notmuch-folder-previous ()
 862   "Select the previous folder in the list."
 863   (interactive)
 864   (forward-line -1))
 865
 866 (defun notmuch-folder-first ()
 867   "Select the first folder in the list."
 868   (interactive)
 869   (goto-char (point-min)))
 870
 871 (defun notmuch-folder-last ()
 872   "Select the last folder in the list."
 873   (interactive)
 874   (goto-char (point-max))
 875   (forward-line -1))
 876
 877 (defun notmuch-folder-count (search)
 878   (car (process-lines notmuch-command "count" search)))
 879
 880 (defvar notmuch-folder-show-empty t
 881   "Whether `notmuch-folder-mode' should display empty folders.")
 882
 883 (defun notmuch-folder-show-empty-toggle ()
 884   "Toggle the listing of empty folders"
 885   (interactive)
 886   (setq notmuch-folder-show-empty (not notmuch-folder-show-empty))
 887   (notmuch-folder))
 888
 889 (defun notmuch-folder-add (folders)
 890   (if folders
 891       (let* ((name (car (car folders)))
 892             (inhibit-read-only t)
 893             (search (cdr (car folders)))
 894             (count (notmuch-folder-count search)))
 895         (if (or notmuch-folder-show-empty
 896                 (not (equal count "0")))
 897             (progn
 898               (insert name)
 899               (indent-to 16 1)
 900               (insert count)
 901               (insert "\n")
 902               )
 903           )
 904         (notmuch-folder-add (cdr folders)))))
 905
 906 (defun notmuch-folder-find-name ()
 907   (save-excursion
 908     (beginning-of-line)
 909     (let ((beg (point)))
 910       (re-search-forward "\\([ \t]*[^ \t]+\\)")
 911       (filter-buffer-substring (match-beginning 1) (match-end 1)))))
 912
 913 (defun notmuch-folder-show-search (&optional folder)
 914   "Show a search window for the search related to the specified folder."
 915   (interactive)
 916   (if (null folder)
 917       (setq folder (notmuch-folder-find-name)))
 918   (let ((search (assoc folder notmuch-folders)))
 919     (if search
 920         (notmuch-search (cdr search) notmuch-search-oldest-first))))
 921
 922 ;;;###autoload
 923 (defun notmuch-folder ()
 924   "Show the notmuch folder view and update the displayed counts."
 925   (interactive)
 926   (let ((buffer (get-buffer-create "*notmuch-folders*")))
 927     (switch-to-buffer buffer)
 928     (let ((inhibit-read-only t)
 929           (n (line-number-at-pos)))
 930       (erase-buffer)
 931       (notmuch-folder-mode)
 932       (notmuch-folder-add notmuch-folders)
 933       (goto-char (point-min))
 934       (goto-line n))))
 935
 936 (provide 'notmuch)