5a24d8a749dda590fc4a1f89d9c3fe62f76553a3
[notmuch] / emacs / notmuch.el
1 ;;; notmuch.el --- run notmuch within emacs
2 ;;
3 ;; Copyright © Carl Worth
4 ;;
5 ;; This file is part of Notmuch.
6 ;;
7 ;; Notmuch is free software: you can redistribute it and/or modify it
8 ;; under the terms of the GNU General Public License as published by
9 ;; the Free Software Foundation, either version 3 of the License, or
10 ;; (at your option) any later version.
11 ;;
12 ;; Notmuch is distributed in the hope that it will be useful, but
13 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
15 ;; General Public License for more details.
16 ;;
17 ;; You should have received a copy of the GNU General Public License
18 ;; along with Notmuch.  If not, see <https://www.gnu.org/licenses/>.
19 ;;
20 ;; Authors: Carl Worth <cworth@cworth.org>
21 ;; Homepage: https://notmuchmail.org/
22
23 ;;; Commentary:
24
25 ;; This is an emacs-based interface to the notmuch mail system.
26 ;;
27 ;; You will first need to have the notmuch program installed and have a
28 ;; notmuch database built in order to use this. See
29 ;; https://notmuchmail.org for details.
30 ;;
31 ;; To install this software, copy it to a directory that is on the
32 ;; `load-path' variable within emacs (a good candidate is
33 ;; /usr/local/share/emacs/site-lisp). If you are viewing this from the
34 ;; notmuch source distribution then you can simply run:
35 ;;
36 ;;      sudo make install-emacs
37 ;;
38 ;; to install it.
39 ;;
40 ;; Then, to actually run it, add:
41 ;;
42 ;;      (autoload 'notmuch "notmuch" "Notmuch mail" t)
43 ;;
44 ;; to your ~/.emacs file, and then run "M-x notmuch" from within emacs,
45 ;; or run:
46 ;;
47 ;;      emacs -f notmuch
48 ;;
49 ;; Have fun, and let us know if you have any comment, questions, or
50 ;; kudos: Notmuch list <notmuch@notmuchmail.org> (subscription is not
51 ;; required, but is available from https://notmuchmail.org).
52 ;;
53 ;; Note for MELPA users (and others tracking the development version
54 ;; of notmuch-emacs):
55 ;;
56 ;; This emacs package needs a fairly closely matched version of the
57 ;; notmuch program. If you use the MELPA version of notmuch.el (as
58 ;; opposed to MELPA stable), you should be prepared to track the
59 ;; master development branch (i.e. build from git) for the notmuch
60 ;; program as well. Upgrading notmuch-emacs too far beyond the notmuch
61 ;; program can CAUSE YOUR EMAIL TO STOP WORKING.
62 ;;
63 ;; TL;DR: notmuch-emacs from MELPA and notmuch from distro packages is
64 ;; NOT SUPPORTED.
65 ;;
66 ;;; Code:
67
68 (eval-when-compile (require 'cl-lib))
69
70 (require 'mm-view)
71 (require 'message)
72
73 (require 'notmuch-lib)
74 (require 'notmuch-tag)
75 (require 'notmuch-show)
76 (require 'notmuch-tree)
77 (require 'notmuch-mua)
78 (require 'notmuch-hello)
79 (require 'notmuch-maildir-fcc)
80 (require 'notmuch-message)
81 (require 'notmuch-parser)
82
83 (defcustom notmuch-search-result-format
84   `(("date" . "%12s ")
85     ("count" . "%-7s ")
86     ("authors" . "%-20s ")
87     ("subject" . "%s ")
88     ("tags" . "(%s)"))
89   "Search result formatting. Supported fields are:
90         date, count, authors, subject, tags
91 For example:
92         (setq notmuch-search-result-format \(\(\"authors\" . \"%-40s\"\)
93                                              \(\"subject\" . \"%s\"\)\)\)
94 Line breaks are permitted in format strings (though this is
95 currently experimental).  Note that a line break at the end of an
96 \"authors\" field will get elided if the authors list is long;
97 place it instead at the beginning of the following field.  To
98 enter a line break when setting this variable with setq, use \\n.
99 To enter a line break in customize, press \\[quoted-insert] C-j."
100   :type '(alist :key-type (string) :value-type (string))
101   :group 'notmuch-search)
102
103 ;; The name of this variable `notmuch-init-file' is consistent with the
104 ;; convention used in e.g. emacs and gnus. The value, `notmuch-config[.el[c]]'
105 ;; is consistent with notmuch cli configuration file `~/.notmuch-config'.
106 (defcustom notmuch-init-file (locate-user-emacs-file "notmuch-config")
107   "Your Notmuch Emacs-Lisp configuration file name.
108 If a file with one of the suffixes defined by `get-load-suffixes' exists,
109 it will be read instead.
110 This file is read once when notmuch is loaded; the notmuch hooks added
111 there will be called at other points of notmuch execution."
112   :type 'file
113   :group 'notmuch)
114
115 (defvar notmuch-query-history nil
116   "Variable to store minibuffer history for notmuch queries")
117
118 (defun notmuch-foreach-mime-part (function mm-handle)
119   (cond ((stringp (car mm-handle))
120          (dolist (part (cdr mm-handle))
121            (notmuch-foreach-mime-part function part)))
122         ((bufferp (car mm-handle))
123          (funcall function mm-handle))
124         (t (dolist (part mm-handle)
125              (notmuch-foreach-mime-part function part)))))
126
127 (defun notmuch-count-attachments (mm-handle)
128   (let ((count 0))
129     (notmuch-foreach-mime-part
130      (lambda (p)
131        (let ((disposition (mm-handle-disposition p)))
132          (and (listp disposition)
133               (or (equal (car disposition) "attachment")
134                   (and (equal (car disposition) "inline")
135                        (assq 'filename disposition)))
136               (cl-incf count))))
137      mm-handle)
138     count))
139
140 (defun notmuch-save-attachments (mm-handle &optional queryp)
141   (notmuch-foreach-mime-part
142    (lambda (p)
143      (let ((disposition (mm-handle-disposition p)))
144        (and (listp disposition)
145             (or (equal (car disposition) "attachment")
146                 (and (equal (car disposition) "inline")
147                      (assq 'filename disposition)))
148             (or (not queryp)
149                 (y-or-n-p
150                  (concat "Save '" (cdr (assq 'filename disposition)) "' ")))
151             (mm-save-part p))))
152    mm-handle))
153
154 (require 'hl-line)
155
156 (defun notmuch-hl-line-mode ()
157   (prog1 (hl-line-mode)
158     (when hl-line-overlay
159       (overlay-put hl-line-overlay 'priority 1))))
160
161 (defcustom notmuch-search-hook '(notmuch-hl-line-mode)
162   "List of functions to call when notmuch displays the search results."
163   :type 'hook
164   :options '(notmuch-hl-line-mode)
165   :group 'notmuch-search
166   :group 'notmuch-hooks)
167
168 (defvar notmuch-search-mode-map
169   (let ((map (make-sparse-keymap)))
170     (set-keymap-parent map notmuch-common-keymap)
171     (define-key map "x" 'notmuch-bury-or-kill-this-buffer)
172     (define-key map (kbd "<DEL>") 'notmuch-search-scroll-down)
173     (define-key map "b" 'notmuch-search-scroll-down)
174     (define-key map " " 'notmuch-search-scroll-up)
175     (define-key map "<" 'notmuch-search-first-thread)
176     (define-key map ">" 'notmuch-search-last-thread)
177     (define-key map "p" 'notmuch-search-previous-thread)
178     (define-key map "n" 'notmuch-search-next-thread)
179     (define-key map "r" 'notmuch-search-reply-to-thread-sender)
180     (define-key map "R" 'notmuch-search-reply-to-thread)
181     (define-key map "o" 'notmuch-search-toggle-order)
182     (define-key map "c" 'notmuch-search-stash-map)
183     (define-key map "t" 'notmuch-search-filter-by-tag)
184     (define-key map "l" 'notmuch-search-filter)
185     (define-key map [mouse-1] 'notmuch-search-show-thread)
186     (define-key map "k" 'notmuch-tag-jump)
187     (define-key map "*" 'notmuch-search-tag-all)
188     (define-key map "a" 'notmuch-search-archive-thread)
189     (define-key map "-" 'notmuch-search-remove-tag)
190     (define-key map "+" 'notmuch-search-add-tag)
191     (define-key map (kbd "RET") 'notmuch-search-show-thread)
192     (define-key map (kbd "M-RET") 'notmuch-tree-from-search-thread)
193     (define-key map "Z" 'notmuch-tree-from-search-current-query)
194     (define-key map "U" 'notmuch-unthreaded-from-search-current-query)
195     map)
196   "Keymap for \"notmuch search\" buffers.")
197 (fset 'notmuch-search-mode-map notmuch-search-mode-map)
198
199 (defvar notmuch-search-stash-map
200   (let ((map (make-sparse-keymap)))
201     (define-key map "i" 'notmuch-search-stash-thread-id)
202     (define-key map "q" 'notmuch-stash-query)
203     (define-key map "?" 'notmuch-subkeymap-help)
204     map)
205   "Submap for stash commands")
206 (fset 'notmuch-search-stash-map notmuch-search-stash-map)
207
208 (defun notmuch-search-stash-thread-id ()
209   "Copy thread ID of current thread to kill-ring."
210   (interactive)
211   (notmuch-common-do-stash (notmuch-search-find-thread-id)))
212
213 (defun notmuch-stash-query ()
214   "Copy current query to kill-ring."
215   (interactive)
216   (notmuch-common-do-stash (notmuch-search-get-query)))
217
218 (defvar notmuch-search-query-string)
219 (defvar notmuch-search-target-thread)
220 (defvar notmuch-search-target-line)
221
222 (defvar notmuch-search-disjunctive-regexp      "\\<[oO][rR]\\>")
223
224 (defun notmuch-search-scroll-up ()
225   "Move forward through search results by one window's worth."
226   (interactive)
227   (condition-case nil
228       (scroll-up nil)
229     ((end-of-buffer) (notmuch-search-last-thread))))
230
231 (defun notmuch-search-scroll-down ()
232   "Move backward through the search results by one window's worth."
233   (interactive)
234   ;; I don't know why scroll-down doesn't signal beginning-of-buffer
235   ;; the way that scroll-up signals end-of-buffer, but c'est la vie.
236   ;;
237   ;; So instead of trapping a signal we instead check whether the
238   ;; window begins on the first line of the buffer and if so, move
239   ;; directly to that position. (We have to count lines since the
240   ;; window-start position is not the same as point-min due to the
241   ;; invisible thread-ID characters on the first line.
242   (if (equal (count-lines (point-min) (window-start)) 0)
243       (goto-char (point-min))
244     (scroll-down nil)))
245
246 (defun notmuch-search-next-thread ()
247   "Select the next thread in the search results."
248   (interactive)
249   (when (notmuch-search-get-result)
250     (goto-char (notmuch-search-result-end))))
251
252 (defun notmuch-search-previous-thread ()
253   "Select the previous thread in the search results."
254   (interactive)
255   (if (notmuch-search-get-result)
256       (unless (bobp)
257         (goto-char (notmuch-search-result-beginning (- (point) 1))))
258     ;; We must be past the end; jump to the last result
259     (notmuch-search-last-thread)))
260
261 (defun notmuch-search-last-thread ()
262   "Select the last thread in the search results."
263   (interactive)
264   (goto-char (point-max))
265   (forward-line -2)
266   (let ((beg (notmuch-search-result-beginning)))
267     (when beg (goto-char beg))))
268
269 (defun notmuch-search-first-thread ()
270   "Select the first thread in the search results."
271   (interactive)
272   (goto-char (point-min)))
273
274 (defface notmuch-message-summary-face
275  '((((class color) (background light)) (:background "#f0f0f0"))
276    (((class color) (background dark)) (:background "#303030")))
277  "Face for the single-line message summary in notmuch-show-mode."
278  :group 'notmuch-show
279  :group 'notmuch-faces)
280
281 (defface notmuch-search-date
282   '((t :inherit default))
283   "Face used in search mode for dates."
284   :group 'notmuch-search
285   :group 'notmuch-faces)
286
287 (defface notmuch-search-count
288   '((t :inherit default))
289   "Face used in search mode for the count matching the query."
290   :group 'notmuch-search
291   :group 'notmuch-faces)
292
293 (defface notmuch-search-subject
294   '((t :inherit default))
295   "Face used in search mode for subjects."
296   :group 'notmuch-search
297   :group 'notmuch-faces)
298
299 (defface notmuch-search-matching-authors
300   '((t :inherit default))
301   "Face used in search mode for authors matching the query."
302   :group 'notmuch-search
303   :group 'notmuch-faces)
304
305 (defface notmuch-search-non-matching-authors
306   '((((class color)
307       (background dark))
308      (:foreground "grey30"))
309     (((class color)
310       (background light))
311      (:foreground "grey60"))
312     (t
313      (:italic t)))
314   "Face used in search mode for authors not matching the query."
315   :group 'notmuch-search
316   :group 'notmuch-faces)
317
318 (defface notmuch-tag-face
319   '((((class color)
320       (background dark))
321      (:foreground "OliveDrab1"))
322     (((class color)
323       (background light))
324      (:foreground "navy blue" :bold t))
325     (t
326      (:bold t)))
327   "Face used in search mode face for tags."
328   :group 'notmuch-search
329   :group 'notmuch-faces)
330
331 (defface notmuch-search-flagged-face
332   '((((class color)
333       (background dark))
334      (:foreground "LightBlue1"))
335     (((class color)
336       (background light))
337      (:foreground "blue")))
338   "Face used in search mode face for flagged threads.
339
340 This face is the default value for the \"flagged\" tag in
341 `notmuch-search-line-faces`."
342   :group 'notmuch-search
343   :group 'notmuch-faces)
344
345 (defface notmuch-search-unread-face
346   '((t
347      (:weight bold)))
348   "Face used in search mode for unread threads.
349
350 This face is the default value for the \"unread\" tag in
351 `notmuch-search-line-faces`."
352   :group 'notmuch-search
353   :group 'notmuch-faces)
354
355 (define-derived-mode notmuch-search-mode fundamental-mode "notmuch-search"
356   "Major mode displaying results of a notmuch search.
357
358 This buffer contains the results of a \"notmuch search\" of your
359 email archives. Each line in the buffer represents a single
360 thread giving a summary of the thread (a relative date, the
361 number of matched messages and total messages in the thread,
362 participants in the thread, a representative subject line, and
363 any tags).
364
365 Pressing \\[notmuch-search-show-thread] on any line displays that
366 thread. The '\\[notmuch-search-add-tag]' and
367 '\\[notmuch-search-remove-tag]' keys can be used to add or remove
368 tags from a thread. The '\\[notmuch-search-archive-thread]' key
369 is a convenience for archiving a thread (applying changes in
370 `notmuch-archive-tags'). The '\\[notmuch-search-tag-all]' key can
371 be used to add and/or remove tags from all messages (as opposed
372 to threads) that match the current query.  Use with caution, as
373 this will also tag matching messages that arrived *after*
374 constructing the buffer.
375
376 Other useful commands are '\\[notmuch-search-filter]' for
377 filtering the current search based on an additional query string,
378 '\\[notmuch-search-filter-by-tag]' for filtering to include only
379 messages with a given tag, and '\\[notmuch-search]' to execute a
380 new, global search.
381
382 Complete list of currently available key bindings:
383
384 \\{notmuch-search-mode-map}"
385   (make-local-variable 'notmuch-search-query-string)
386   (make-local-variable 'notmuch-search-oldest-first)
387   (make-local-variable 'notmuch-search-target-thread)
388   (make-local-variable 'notmuch-search-target-line)
389   (setq notmuch-buffer-refresh-function #'notmuch-search-refresh-view)
390   (set (make-local-variable 'scroll-preserve-screen-position) t)
391   (add-to-invisibility-spec (cons 'ellipsis t))
392   (setq truncate-lines t)
393   (setq buffer-read-only t)
394   (setq imenu-prev-index-position-function
395         #'notmuch-search-imenu-prev-index-position-function)
396   (setq imenu-extract-index-name-function
397         #'notmuch-search-imenu-extract-index-name-function))
398
399 (defun notmuch-search-get-result (&optional pos)
400   "Return the result object for the thread at POS (or point).
401
402 If there is no thread at POS (or point), returns nil."
403   (get-text-property (or pos (point)) 'notmuch-search-result))
404
405 (defun notmuch-search-result-beginning (&optional pos)
406   "Return the point at the beginning of the thread at POS (or point).
407
408 If there is no thread at POS (or point), returns nil."
409   (when (notmuch-search-get-result pos)
410     ;; We pass 1+point because previous-single-property-change starts
411     ;; searching one before the position we give it.
412     (previous-single-property-change (1+ (or pos (point)))
413                                      'notmuch-search-result nil (point-min))))
414
415 (defun notmuch-search-result-end (&optional pos)
416   "Return the point at the end of the thread at POS (or point).
417
418 The returned point will be just after the newline character that
419 ends the result line.  If there is no thread at POS (or point),
420 returns nil"
421   (when (notmuch-search-get-result pos)
422     (next-single-property-change (or pos (point)) 'notmuch-search-result
423                                  nil (point-max))))
424
425 (defun notmuch-search-foreach-result (beg end fn)
426   "Invoke FN for each result between BEG and END.
427
428 FN should take one argument.  It will be applied to the
429 character position of the beginning of each result that overlaps
430 the region between points BEG and END.  As a special case, if (=
431 BEG END), FN will be applied to the result containing point
432 BEG."
433   (let ((pos (notmuch-search-result-beginning beg))
434         ;; End must be a marker in case fn changes the
435         ;; text.
436         (end (copy-marker end))
437         ;; Make sure we examine at least one result, even if
438         ;; (= beg end).
439         (first t))
440     ;; We have to be careful if the region extends beyond the results.
441     ;; In this case, pos could be null or there could be no result at
442     ;; pos.
443     (while (and pos (or (< pos end) first))
444       (when (notmuch-search-get-result pos)
445         (funcall fn pos))
446       (setq pos (notmuch-search-result-end pos)
447             first nil))))
448 ;; Unindent the function argument of notmuch-search-foreach-result so
449 ;; the indentation of callers doesn't get out of hand.
450 (put 'notmuch-search-foreach-result 'lisp-indent-function 2)
451
452 (defun notmuch-search-properties-in-region (property beg end)
453   (let (output)
454     (notmuch-search-foreach-result beg end
455       (lambda (pos)
456         (push (plist-get (notmuch-search-get-result pos) property) output)))
457     output))
458
459 (defun notmuch-search-find-thread-id (&optional bare)
460   "Return the thread for the current thread
461
462 If BARE is set then do not prefix with \"thread:\""
463   (let ((thread (plist-get (notmuch-search-get-result) :thread)))
464     (when thread (concat (unless bare "thread:") thread))))
465
466 (defun notmuch-search-find-stable-query ()
467   "Return the stable queries for the current thread.
468
469 This returns a list (MATCHED-QUERY UNMATCHED-QUERY) for the
470 matched and unmatched messages in the current thread."
471   (plist-get (notmuch-search-get-result) :query))
472
473 (defun notmuch-search-find-stable-query-region (beg end &optional only-matched)
474   "Return the stable query for the current region.
475
476 If ONLY-MATCHED is non-nil, include only matched messages.  If it
477 is nil, include both matched and unmatched messages. If there are
478 no messages in the region then return nil."
479   (let ((query-list nil) (all (not only-matched)))
480     (dolist (queries (notmuch-search-properties-in-region :query beg end))
481       (when (car queries)
482         (push (car queries) query-list))
483       (when (and all (cadr queries))
484         (push (cadr queries) query-list)))
485     (when query-list
486       (concat "(" (mapconcat 'identity query-list ") or (") ")"))))
487
488 (defun notmuch-search-find-authors ()
489   "Return the authors for the current thread"
490   (plist-get (notmuch-search-get-result) :authors))
491
492 (defun notmuch-search-find-authors-region (beg end)
493   "Return a list of authors for the current region"
494   (notmuch-search-properties-in-region :authors beg end))
495
496 (defun notmuch-search-find-subject ()
497   "Return the subject for the current thread"
498   (plist-get (notmuch-search-get-result) :subject))
499
500 (defun notmuch-search-find-subject-region (beg end)
501   "Return a list of authors for the current region"
502   (notmuch-search-properties-in-region :subject beg end))
503
504 (defun notmuch-search-show-thread (&optional elide-toggle)
505   "Display the currently selected thread.
506
507 With a prefix argument, invert the default value of
508 `notmuch-show-only-matching-messages' when displaying the
509 thread."
510   (interactive "P")
511   (let ((thread-id (notmuch-search-find-thread-id))
512         (subject (notmuch-search-find-subject)))
513     (if (> (length thread-id) 0)
514         (notmuch-show thread-id
515                       elide-toggle
516                       (current-buffer)
517                       notmuch-search-query-string
518                       ;; Name the buffer based on the subject.
519                       (concat "*" (truncate-string-to-width subject 30 nil nil t) "*"))
520       (message "End of search results."))))
521
522 (defun notmuch-tree-from-search-current-query ()
523   "Call notmuch tree with the current query"
524   (interactive)
525   (notmuch-tree notmuch-search-query-string))
526
527 (defun notmuch-unthreaded-from-search-current-query ()
528   "Call notmuch tree with the current query"
529   (interactive)
530   (notmuch-unthreaded notmuch-search-query-string))
531
532 (defun notmuch-tree-from-search-thread ()
533   "Show the selected thread with notmuch-tree"
534   (interactive)
535   (notmuch-tree (notmuch-search-find-thread-id)
536                 notmuch-search-query-string
537                 nil
538                 (notmuch-prettify-subject (notmuch-search-find-subject))
539                 t))
540
541 (defun notmuch-search-reply-to-thread (&optional prompt-for-sender)
542   "Begin composing a reply-all to the entire current thread in a new buffer."
543   (interactive "P")
544   (let ((message-id (notmuch-search-find-thread-id)))
545     (notmuch-mua-new-reply message-id prompt-for-sender t)))
546
547 (defun notmuch-search-reply-to-thread-sender (&optional prompt-for-sender)
548   "Begin composing a reply to the entire current thread in a new buffer."
549   (interactive "P")
550   (let ((message-id (notmuch-search-find-thread-id)))
551     (notmuch-mua-new-reply message-id prompt-for-sender nil)))
552
553 (defun notmuch-search-set-tags (tags &optional pos)
554   (let ((new-result (plist-put (notmuch-search-get-result pos) :tags tags)))
555     (notmuch-search-update-result new-result pos)))
556
557 (defun notmuch-search-get-tags (&optional pos)
558   (plist-get (notmuch-search-get-result pos) :tags))
559
560 (defun notmuch-search-get-tags-region (beg end)
561   (let (output)
562     (notmuch-search-foreach-result beg end
563       (lambda (pos)
564         (setq output (append output (notmuch-search-get-tags pos)))))
565     output))
566
567 (defun notmuch-search-interactive-tag-changes (&optional initial-input)
568   "Prompt for tag changes for the current thread or region.
569
570 Returns (TAG-CHANGES REGION-BEGIN REGION-END)."
571   (pcase-let ((`(,beg ,end) (notmuch-interactive-region)))
572     (list (notmuch-read-tag-changes (notmuch-search-get-tags-region beg end)
573                                     (if (= beg end) "Tag thread" "Tag region")
574                                     initial-input)
575           beg end)))
576
577 (defun notmuch-search-tag (tag-changes &optional beg end only-matched)
578   "Change tags for the currently selected thread or region.
579
580 See `notmuch-tag' for information on the format of TAG-CHANGES.
581 When called interactively, this uses the region if the region is
582 active.  When called directly, BEG and END provide the region.
583 If these are nil or not provided, then, if the region is active
584 this applied to all threads meeting the region, and if the region
585 is inactive this applies to the thread at point.
586
587 If ONLY-MATCHED is non-nil, only tag matched messages."
588   (interactive (notmuch-search-interactive-tag-changes))
589   (unless (and beg end)
590     (setq beg (car (notmuch-interactive-region))
591           end (cadr (notmuch-interactive-region))))
592   (let ((search-string (notmuch-search-find-stable-query-region
593                         beg end only-matched)))
594     (notmuch-tag search-string tag-changes)
595     (notmuch-search-foreach-result beg end
596       (lambda (pos)
597         (notmuch-search-set-tags
598          (notmuch-update-tags (notmuch-search-get-tags pos) tag-changes)
599          pos)))))
600
601 (defun notmuch-search-add-tag (tag-changes &optional beg end)
602   "Change tags for the current thread or region (defaulting to add).
603
604 Same as `notmuch-search-tag' but sets initial input to '+'."
605   (interactive (notmuch-search-interactive-tag-changes "+"))
606   (notmuch-search-tag tag-changes beg end))
607
608 (defun notmuch-search-remove-tag (tag-changes &optional beg end)
609   "Change tags for the current thread or region (defaulting to remove).
610
611 Same as `notmuch-search-tag' but sets initial input to '-'."
612   (interactive (notmuch-search-interactive-tag-changes "-"))
613   (notmuch-search-tag tag-changes beg end))
614
615 (put 'notmuch-search-archive-thread 'notmuch-prefix-doc
616      "Un-archive the currently selected thread.")
617 (defun notmuch-search-archive-thread (&optional unarchive beg end)
618   "Archive the currently selected thread or region.
619
620 Archive each message in the currently selected thread by applying
621 the tag changes in `notmuch-archive-tags' to each (remove the
622 \"inbox\" tag by default). If a prefix argument is given, the
623 messages will be \"unarchived\" (i.e. the tag changes in
624 `notmuch-archive-tags' will be reversed).
625
626 This function advances the next thread when finished."
627   (interactive (cons current-prefix-arg (notmuch-interactive-region)))
628   (when notmuch-archive-tags
629     (notmuch-search-tag
630      (notmuch-tag-change-list notmuch-archive-tags unarchive) beg end))
631   (when (eq beg end)
632     (notmuch-search-next-thread)))
633
634 (defun notmuch-search-update-result (result &optional pos)
635   "Replace the result object of the thread at POS (or point) by
636 RESULT and redraw it.
637
638 This will keep point in a reasonable location.  However, if there
639 are enclosing save-excursions and the saved point is in the
640 result being updated, the point will be restored to the beginning
641 of the result."
642   (let ((start (notmuch-search-result-beginning pos))
643         (end (notmuch-search-result-end pos))
644         (init-point (point))
645         (inhibit-read-only t))
646     ;; Delete the current thread
647     (delete-region start end)
648     ;; Insert the updated thread
649     (notmuch-search-show-result result start)
650     ;; If point was inside the old result, make an educated guess
651     ;; about where to place it now.  Unfortunately, this won't work
652     ;; with save-excursion (or any other markers that would be nice to
653     ;; preserve, such as the window start), but there's nothing we can
654     ;; do about that without a way to retrieve markers in a region.
655     (when (and (>= init-point start) (<= init-point end))
656       (let* ((new-end (notmuch-search-result-end start))
657              (new-point (if (= init-point end)
658                             new-end
659                           (min init-point (- new-end 1)))))
660         (goto-char new-point)))))
661
662 (defun notmuch-search-process-sentinel (proc msg)
663   "Add a message to let user know when \"notmuch search\" exits"
664   (let ((buffer (process-buffer proc))
665         (status (process-status proc))
666         (exit-status (process-exit-status proc))
667         (never-found-target-thread nil))
668     (when (memq status '(exit signal))
669       (catch 'return
670         (kill-buffer (process-get proc 'parse-buf))
671         (if (buffer-live-p buffer)
672             (with-current-buffer buffer
673               (save-excursion
674                 (let ((inhibit-read-only t)
675                       (atbob (bobp)))
676                   (goto-char (point-max))
677                   (if (eq status 'signal)
678                       (insert "Incomplete search results (search process was killed).\n"))
679                   (when (eq status 'exit)
680                     (insert "End of search results.\n")
681                     ;; For version mismatch, there's no point in
682                     ;; showing the search buffer
683                     (when (or (= exit-status 20) (= exit-status 21))
684                       (kill-buffer)
685                       (throw 'return nil))
686                     (if (and atbob
687                              (not (string= notmuch-search-target-thread "found")))
688                         (set 'never-found-target-thread t)))))
689               (when (and never-found-target-thread
690                        notmuch-search-target-line)
691                   (goto-char (point-min))
692                   (forward-line (1- notmuch-search-target-line)))))))))
693
694 (define-widget 'notmuch--custom-face-edit 'lazy
695   "Custom face edit with a tag Edit Face"
696   ;; I could not persuage custom-face-edit to respect the :tag
697   ;; property so create a widget specially
698   :tag "Manually specify face"
699   :type 'custom-face-edit)
700
701 (defcustom notmuch-search-line-faces
702   '(("unread" . notmuch-search-unread-face)
703     ("flagged" . notmuch-search-flagged-face))
704   "Alist of tags to faces for line highlighting in notmuch-search.
705 Each element looks like (TAG . FACE).
706 A thread with TAG will have FACE applied.
707
708 Here is an example of how to color search results based on tags.
709  (the following text would be placed in your ~/.emacs file):
710
711  (setq notmuch-search-line-faces \\='((\"unread\" . (:foreground \"green\"))
712                                    (\"deleted\" . (:foreground \"red\"
713                                                   :background \"blue\"))))
714
715 The FACE must be a face name (a symbol or string), a property
716 list of face attributes, or a list of these.  The faces for
717 matching tags are merged, with earlier attributes overriding
718 later. A message having both \"deleted\" and \"unread\" tags with
719 the above settings would have a green foreground and blue
720 background."
721   :type '(alist :key-type (string)
722                 :value-type (radio (face :tag "Face name")
723                                     (notmuch--custom-face-edit)))
724   :group 'notmuch-search
725   :group 'notmuch-faces)
726
727 (defun notmuch-search-color-line (start end line-tag-list)
728   "Colorize lines in `notmuch-show' based on tags."
729   ;; Reverse the list so earlier entries take precedence
730   (dolist (elem (reverse notmuch-search-line-faces))
731     (let ((tag (car elem))
732           (face (cdr elem)))
733       (when (member tag line-tag-list)
734         (notmuch-apply-face nil face nil start end)))))
735
736 (defun notmuch-search-author-propertize (authors)
737   "Split `authors' into matching and non-matching authors and
738 propertize appropriately. If no boundary between authors and
739 non-authors is found, assume that all of the authors match."
740   (if (string-match "\\(.*\\)|\\(.*\\)" authors)
741       (concat (propertize (concat (match-string 1 authors) ",")
742                           'face 'notmuch-search-matching-authors)
743               (propertize (match-string 2 authors)
744                           'face 'notmuch-search-non-matching-authors))
745     (propertize authors 'face 'notmuch-search-matching-authors)))
746
747 (defun notmuch-search-insert-authors (format-string authors)
748   ;; Save the match data to avoid interfering with
749   ;; `notmuch-search-process-filter'.
750   (save-match-data
751     (let* ((formatted-authors (format format-string authors))
752            (formatted-sample (format format-string ""))
753            (visible-string formatted-authors)
754            (invisible-string "")
755            (padding ""))
756
757       ;; Truncate the author string to fit the specification.
758       (if (> (length formatted-authors)
759              (length formatted-sample))
760           (let ((visible-length (- (length formatted-sample)
761                                    (length "... "))))
762             ;; Truncate the visible string according to the width of
763             ;; the display string.
764             (setq visible-string (substring formatted-authors 0 visible-length)
765                   invisible-string (substring formatted-authors visible-length))
766             ;; If possible, truncate the visible string at a natural
767             ;; break (comma or pipe), as incremental search doesn't
768             ;; match across the visible/invisible border.
769             (when (string-match "\\(.*\\)\\([,|] \\)\\([^,|]*\\)" visible-string)
770               ;; Second clause is destructive on `visible-string', so
771               ;; order is important.
772               (setq invisible-string (concat (match-string 3 visible-string)
773                                              invisible-string)
774                     visible-string (concat (match-string 1 visible-string)
775                                            (match-string 2 visible-string))))
776             ;; `visible-string' may be shorter than the space allowed
777             ;; by `format-string'. If so we must insert some padding
778             ;; after `invisible-string'.
779             (setq padding (make-string (- (length formatted-sample)
780                                           (length visible-string)
781                                           (length "..."))
782                                        ? ))))
783
784       ;; Use different faces to show matching and non-matching authors.
785       (if (string-match "\\(.*\\)|\\(.*\\)" visible-string)
786           ;; The visible string contains both matching and
787           ;; non-matching authors.
788           (setq visible-string (notmuch-search-author-propertize visible-string)
789                 ;; The invisible string must contain only non-matching
790                 ;; authors, as the visible-string contains both.
791                 invisible-string (propertize invisible-string
792                                              'face 'notmuch-search-non-matching-authors))
793         ;; The visible string contains only matching authors.
794         (setq visible-string (propertize visible-string
795                                          'face 'notmuch-search-matching-authors)
796               ;; The invisible string may contain both matching and
797               ;; non-matching authors.
798               invisible-string (notmuch-search-author-propertize invisible-string)))
799
800       ;; If there is any invisible text, add it as a tooltip to the
801       ;; visible text.
802       (when (not (string= invisible-string ""))
803         (setq visible-string (propertize visible-string 'help-echo (concat "..." invisible-string))))
804
805       ;; Insert the visible and, if present, invisible author strings.
806       (insert visible-string)
807       (when (not (string= invisible-string ""))
808         (let ((start (point))
809               overlay)
810           (insert invisible-string)
811           (setq overlay (make-overlay start (point)))
812           (overlay-put overlay 'invisible 'ellipsis)
813           (overlay-put overlay 'isearch-open-invisible #'delete-overlay)))
814       (insert padding))))
815
816 (defun notmuch-search-insert-field (field format-string result)
817   (cond
818    ((string-equal field "date")
819     (insert (propertize (format format-string (plist-get result :date_relative))
820                         'face 'notmuch-search-date)))
821    ((string-equal field "count")
822     (insert (propertize (format format-string
823                                 (format "[%s/%s]" (plist-get result :matched)
824                                         (plist-get result :total)))
825                         'face 'notmuch-search-count)))
826    ((string-equal field "subject")
827     (insert (propertize (format format-string
828                                 (notmuch-sanitize (plist-get result :subject)))
829                         'face 'notmuch-search-subject)))
830
831    ((string-equal field "authors")
832     (notmuch-search-insert-authors
833      format-string (notmuch-sanitize (plist-get result :authors))))
834
835    ((string-equal field "tags")
836     (let ((tags (plist-get result :tags))
837           (orig-tags (plist-get result :orig-tags)))
838       (insert (format format-string (notmuch-tag-format-tags tags orig-tags)))))))
839
840 (defun notmuch-search-show-result (result pos)
841   "Insert RESULT at POS."
842   ;; Ignore excluded matches
843   (unless (= (plist-get result :matched) 0)
844     (save-excursion
845       (goto-char pos)
846       (dolist (spec notmuch-search-result-format)
847         (notmuch-search-insert-field (car spec) (cdr spec) result))
848       (insert "\n")
849       (notmuch-search-color-line pos (point) (plist-get result :tags))
850       (put-text-property pos (point) 'notmuch-search-result result))))
851
852 (defun notmuch-search-append-result (result)
853   "Insert RESULT at the end of the buffer.
854
855 This is only called when a result is first inserted so it also
856 sets the :orig-tag property."
857   (let ((new-result (plist-put result :orig-tags (plist-get result :tags)))
858         (pos (point-max)))
859     (notmuch-search-show-result new-result pos)
860     (when (string= (plist-get result :thread) notmuch-search-target-thread)
861       (setq notmuch-search-target-thread "found")
862       (goto-char pos))))
863
864 (defun notmuch-search-process-filter (proc string)
865   "Process and filter the output of \"notmuch search\""
866   (let ((results-buf (process-buffer proc))
867         (parse-buf (process-get proc 'parse-buf))
868         (inhibit-read-only t)
869         done)
870     (when (buffer-live-p results-buf)
871       (with-current-buffer parse-buf
872         ;; Insert new data
873         (save-excursion
874           (goto-char (point-max))
875           (insert string))
876         (notmuch-sexp-parse-partial-list 'notmuch-search-append-result
877                                          results-buf)))))
878
879 (defun notmuch-search-tag-all (tag-changes)
880   "Add/remove tags from all messages in current search buffer.
881
882 See `notmuch-tag' for information on the format of TAG-CHANGES."
883   (interactive
884    (list (notmuch-read-tag-changes
885           (notmuch-search-get-tags-region (point-min) (point-max)) "Tag all")))
886   (notmuch-search-tag tag-changes (point-min) (point-max) t))
887
888 (defun notmuch-search-buffer-title (query)
889   "Returns the title for a buffer with notmuch search results."
890   (let* ((saved-search
891           (let (longest
892                 (longest-length 0))
893             (cl-loop for tuple in notmuch-saved-searches
894                      if (let ((quoted-query
895                                (regexp-quote (notmuch-saved-search-get tuple :query))))
896                           (and (string-match (concat "^" quoted-query) query)
897                                (> (length (match-string 0 query))
898                                   longest-length)))
899                      do (setq longest tuple))
900             longest))
901          (saved-search-name (notmuch-saved-search-get saved-search :name))
902          (saved-search-query (notmuch-saved-search-get saved-search :query)))
903     (cond ((and saved-search (equal saved-search-query query))
904            ;; Query is the same as saved search (ignoring case)
905            (concat "*notmuch-saved-search-" saved-search-name "*"))
906           (saved-search
907            (concat "*notmuch-search-"
908                    (replace-regexp-in-string (concat "^" (regexp-quote saved-search-query))
909                                              (concat "[ " saved-search-name " ]")
910                                              query)
911                    "*"))
912           (t
913            (concat "*notmuch-search-" query "*"))
914           )))
915
916 (defun notmuch-read-query (prompt)
917   "Read a notmuch-query from the minibuffer with completion.
918
919 PROMPT is the string to prompt with."
920   (let*
921       ((all-tags
922         (mapcar (lambda (tag) (notmuch-escape-boolean-term tag))
923                 (process-lines notmuch-command "search" "--output=tags" "*")))
924        (completions
925          (append (list "folder:" "path:" "thread:" "id:" "date:" "from:" "to:"
926                        "subject:" "attachment:")
927                  (mapcar (lambda (tag) (concat "tag:" tag)) all-tags)
928                  (mapcar (lambda (tag) (concat "is:" tag)) all-tags)
929                  (mapcar (lambda (mimetype) (concat "mimetype:" mimetype)) (mailcap-mime-types)))))
930     (let ((keymap (copy-keymap minibuffer-local-map))
931           (current-query (cl-case major-mode
932                            (notmuch-search-mode (notmuch-search-get-query))
933                            (notmuch-show-mode (notmuch-show-get-query))
934                            (notmuch-tree-mode (notmuch-tree-get-query))))
935           (minibuffer-completion-table
936            (completion-table-dynamic
937             (lambda (string)
938               ;; generate a list of possible completions for the current input
939               (cond
940                ;; this ugly regexp is used to get the last word of the input
941                ;; possibly preceded by a '('
942                ((string-match "\\(^\\|.* (?\\)\\([^ ]*\\)$" string)
943                 (mapcar (lambda (compl)
944                           (concat (match-string-no-properties 1 string) compl))
945                         (all-completions (match-string-no-properties 2 string)
946                                          completions)))
947                (t (list string)))))))
948       ;; this was simpler than convincing completing-read to accept spaces:
949       (define-key keymap (kbd "TAB") 'minibuffer-complete)
950       (let ((history-delete-duplicates t))
951         (read-from-minibuffer prompt nil keymap nil
952                               'notmuch-search-history current-query nil)))))
953
954 (defun notmuch-search-get-query ()
955   "Return the current query in this search buffer"
956   notmuch-search-query-string)
957
958 (put 'notmuch-search 'notmuch-doc "Search for messages.")
959 ;;;###autoload
960 (defun notmuch-search (&optional query oldest-first target-thread target-line no-display)
961   "Display threads matching QUERY in a notmuch-search buffer.
962
963 If QUERY is nil, it is read interactively from the minibuffer.
964 Other optional parameters are used as follows:
965
966   OLDEST-FIRST: A Boolean controlling the sort order of returned threads
967   TARGET-THREAD: A thread ID (without the thread: prefix) that will be made
968                  current if it appears in the search results.
969   TARGET-LINE: The line number to move to if the target thread does not
970                appear in the search results.
971   NO-DISPLAY: Do not try to foreground the search results buffer. If it is
972               already foregrounded i.e. displayed in a window, this has no
973               effect, meaning the buffer will remain visible.
974
975 When called interactively, this will prompt for a query and use
976 the configured default sort order."
977   (interactive
978    (list
979     ;; Prompt for a query
980     nil
981     ;; Use the default search order (if we're doing a search from a
982     ;; search buffer, ignore any buffer-local overrides)
983     (default-value 'notmuch-search-oldest-first)))
984
985   (let* ((query (or query (notmuch-read-query "Notmuch search: ")))
986          (buffer (get-buffer-create (notmuch-search-buffer-title query))))
987     (if no-display
988         (set-buffer buffer)
989       (switch-to-buffer buffer))
990     (notmuch-search-mode)
991     ;; Don't track undo information for this buffer
992     (set 'buffer-undo-list t)
993     (set 'notmuch-search-query-string query)
994     (set 'notmuch-search-oldest-first oldest-first)
995     (set 'notmuch-search-target-thread target-thread)
996     (set 'notmuch-search-target-line target-line)
997     (notmuch-tag-clear-cache)
998     (let ((proc (get-buffer-process (current-buffer)))
999           (inhibit-read-only t))
1000       (if proc
1001           (error "notmuch search process already running for query `%s'" query)
1002         )
1003       (erase-buffer)
1004       (goto-char (point-min))
1005       (save-excursion
1006         (let ((proc (notmuch-start-notmuch
1007                      "notmuch-search" buffer #'notmuch-search-process-sentinel
1008                      "search" "--format=sexp" "--format-version=4"
1009                      (if oldest-first
1010                          "--sort=oldest-first"
1011                        "--sort=newest-first")
1012                      query))
1013               ;; Use a scratch buffer to accumulate partial output.
1014               ;; This buffer will be killed by the sentinel, which
1015               ;; should be called no matter how the process dies.
1016               (parse-buf (generate-new-buffer " *notmuch search parse*")))
1017           (process-put proc 'parse-buf parse-buf)
1018           (set-process-filter proc 'notmuch-search-process-filter)
1019           (set-process-query-on-exit-flag proc nil))))
1020     (run-hooks 'notmuch-search-hook)))
1021
1022 (defun notmuch-search-refresh-view ()
1023   "Refresh the current view.
1024
1025 Erases the current buffer and runs a new search with the same
1026 query string as the current search. If the current thread is in
1027 the new search results, then point will be placed on the same
1028 thread. Otherwise, point will be moved to attempt to be in the
1029 same relative position within the new buffer."
1030   (interactive)
1031   (let ((target-line (line-number-at-pos))
1032         (oldest-first notmuch-search-oldest-first)
1033         (target-thread (notmuch-search-find-thread-id 'bare))
1034         (query notmuch-search-query-string))
1035     ;; notmuch-search erases the current buffer.
1036     (notmuch-search query oldest-first target-thread target-line t)
1037     (goto-char (point-min))))
1038
1039 (defun notmuch-search-toggle-order ()
1040   "Toggle the current search order.
1041
1042 This command toggles the sort order for the current search. The
1043 default sort order is defined by `notmuch-search-oldest-first'."
1044   (interactive)
1045   (set 'notmuch-search-oldest-first (not notmuch-search-oldest-first))
1046   (notmuch-search-refresh-view))
1047
1048 (defun notmuch-group-disjunctive-query-string (query-string)
1049   "Group query if it contains a complex expression.
1050
1051 Enclose QUERY-STRING in parentheses if it matches
1052 `notmuch-search-disjunctive-regexp'."
1053   (if (string-match-p notmuch-search-disjunctive-regexp query-string)
1054       (concat "( " query-string " )")
1055     query-string))
1056
1057 (defun notmuch-search-filter (query)
1058   "Filter or LIMIT the current search results based on an additional query string.
1059
1060 Runs a new search matching only messages that match both the
1061 current search results AND the additional query string provided."
1062   (interactive (list (notmuch-read-query "Filter search: ")))
1063   (let ((grouped-query (notmuch-group-disjunctive-query-string query))
1064         (grouped-original-query (notmuch-group-disjunctive-query-string
1065                                  notmuch-search-query-string)))
1066     (notmuch-search (if (string= grouped-original-query "*")
1067                         grouped-query
1068                       (concat grouped-original-query " and " grouped-query))
1069                     notmuch-search-oldest-first)))
1070
1071 (defun notmuch-search-filter-by-tag (tag)
1072   "Filter the current search results based on a single tag.
1073
1074 Runs a new search matching only messages that match both the
1075 current search results AND that are tagged with the given tag."
1076   (interactive
1077    (list (notmuch-select-tag-with-completion "Filter by tag: " notmuch-search-query-string)))
1078   (notmuch-search (concat notmuch-search-query-string " and tag:" tag) notmuch-search-oldest-first))
1079
1080 (defun notmuch-search-by-tag (tag)
1081   "Display threads matching TAG in a notmuch-search buffer."
1082   (interactive
1083    (list (notmuch-select-tag-with-completion "Notmuch search tag: ")))
1084   (notmuch-search (concat "tag:" tag)))
1085
1086 ;;;###autoload
1087 (defun notmuch ()
1088   "Run notmuch and display saved searches, known tags, etc."
1089   (interactive)
1090   (notmuch-hello))
1091
1092 (defun notmuch-interesting-buffer (b)
1093   "Is the current buffer of interest to a notmuch user?"
1094   (with-current-buffer b
1095     (memq major-mode '(notmuch-show-mode
1096                        notmuch-search-mode
1097                        notmuch-tree-mode
1098                        notmuch-hello-mode
1099                        notmuch-message-mode))))
1100
1101 ;;;###autoload
1102 (defun notmuch-cycle-notmuch-buffers ()
1103   "Cycle through any existing notmuch buffers (search, show or hello).
1104
1105 If the current buffer is the only notmuch buffer, bury it. If no
1106 notmuch buffers exist, run `notmuch'."
1107   (interactive)
1108
1109   (let (start first)
1110     ;; If the current buffer is a notmuch buffer, remember it and then
1111     ;; bury it.
1112     (when (notmuch-interesting-buffer (current-buffer))
1113       (setq start (current-buffer))
1114       (bury-buffer))
1115
1116     ;; Find the first notmuch buffer.
1117     (setq first (cl-loop for buffer in (buffer-list)
1118                          if (notmuch-interesting-buffer buffer)
1119                          return buffer))
1120
1121     (if first
1122         ;; If the first one we found is any other than the starting
1123         ;; buffer, switch to it.
1124         (unless (eq first start)
1125           (switch-to-buffer first))
1126       (notmuch))))
1127
1128 ;;;; Imenu Support
1129
1130 (defun notmuch-search-imenu-prev-index-position-function ()
1131   "Move point to previous message in notmuch-search buffer.
1132 This function is used as a value for
1133 `imenu-prev-index-position-function'."
1134   (notmuch-search-previous-thread))
1135
1136 (defun notmuch-search-imenu-extract-index-name-function ()
1137   "Return imenu name for line at point.
1138 This function is used as a value for
1139 `imenu-extract-index-name-function'.  Point should be at the
1140 beginning of the line."
1141   (let ((subject (notmuch-search-find-subject))
1142         (author (notmuch-search-find-authors)))
1143     (format "%s (%s)" subject author)))
1144
1145 (setq mail-user-agent 'notmuch-user-agent)
1146
1147 (provide 'notmuch)
1148
1149 ;; After provide to avoid loops if notmuch was require'd via notmuch-init-file.
1150 (if init-file-user ; don't load init file if the -q option was used.
1151     (load notmuch-init-file t t nil t))
1152
1153 ;;; notmuch.el ends here