75fe6900f1f9832d151514491d7dde816afc3aa8
[notmuch] / emacs / notmuch.el
1 ;;; notmuch.el --- run notmuch within emacs
2 ;;
3 ;; Copyright © Carl Worth
4 ;;
5 ;; This file is part of Notmuch.
6 ;;
7 ;; Notmuch is free software: you can redistribute it and/or modify it
8 ;; under the terms of the GNU General Public License as published by
9 ;; the Free Software Foundation, either version 3 of the License, or
10 ;; (at your option) any later version.
11 ;;
12 ;; Notmuch is distributed in the hope that it will be useful, but
13 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
15 ;; General Public License for more details.
16 ;;
17 ;; You should have received a copy of the GNU General Public License
18 ;; along with Notmuch.  If not, see <https://www.gnu.org/licenses/>.
19 ;;
20 ;; Authors: Carl Worth <cworth@cworth.org>
21 ;; Homepage: https://notmuchmail.org/
22
23 ;;; Commentary:
24
25 ;; This is an emacs-based interface to the notmuch mail system.
26 ;;
27 ;; You will first need to have the notmuch program installed and have a
28 ;; notmuch database built in order to use this. See
29 ;; https://notmuchmail.org for details.
30 ;;
31 ;; To install this software, copy it to a directory that is on the
32 ;; `load-path' variable within emacs (a good candidate is
33 ;; /usr/local/share/emacs/site-lisp). If you are viewing this from the
34 ;; notmuch source distribution then you can simply run:
35 ;;
36 ;;      sudo make install-emacs
37 ;;
38 ;; to install it.
39 ;;
40 ;; Then, to actually run it, add:
41 ;;
42 ;;      (autoload 'notmuch "notmuch" "Notmuch mail" t)
43 ;;
44 ;; to your ~/.emacs file, and then run "M-x notmuch" from within emacs,
45 ;; or run:
46 ;;
47 ;;      emacs -f notmuch
48 ;;
49 ;; Have fun, and let us know if you have any comment, questions, or
50 ;; kudos: Notmuch list <notmuch@notmuchmail.org> (subscription is not
51 ;; required, but is available from https://notmuchmail.org).
52 ;;
53 ;; Note for MELPA users (and others tracking the development version
54 ;; of notmuch-emacs):
55 ;;
56 ;; This emacs package needs a fairly closely matched version of the
57 ;; notmuch program. If you use the MELPA version of notmuch.el (as
58 ;; opposed to MELPA stable), you should be prepared to track the
59 ;; master development branch (i.e. build from git) for the notmuch
60 ;; program as well. Upgrading notmuch-emacs too far beyond the notmuch
61 ;; program can CAUSE YOUR EMAIL TO STOP WORKING.
62 ;;
63 ;; TL;DR: notmuch-emacs from MELPA and notmuch from distro packages is
64 ;; NOT SUPPORTED.
65 ;;
66 ;;; Code:
67
68 (eval-when-compile (require 'cl-lib))
69
70 (require 'mm-view)
71 (require 'message)
72
73 (require 'notmuch-lib)
74 (require 'notmuch-tag)
75 (require 'notmuch-show)
76 (require 'notmuch-tree)
77 (require 'notmuch-mua)
78 (require 'notmuch-hello)
79 (require 'notmuch-maildir-fcc)
80 (require 'notmuch-message)
81 (require 'notmuch-parser)
82
83 (defcustom notmuch-search-result-format
84   `(("date" . "%12s ")
85     ("count" . "%-7s ")
86     ("authors" . "%-20s ")
87     ("subject" . "%s ")
88     ("tags" . "(%s)"))
89   "Search result formatting. Supported fields are:
90         date, count, authors, subject, tags
91 For example:
92         (setq notmuch-search-result-format \(\(\"authors\" . \"%-40s\"\)
93                                              \(\"subject\" . \"%s\"\)\)\)
94 Line breaks are permitted in format strings (though this is
95 currently experimental).  Note that a line break at the end of an
96 \"authors\" field will get elided if the authors list is long;
97 place it instead at the beginning of the following field.  To
98 enter a line break when setting this variable with setq, use \\n.
99 To enter a line break in customize, press \\[quoted-insert] C-j."
100   :type '(alist :key-type (string) :value-type (string))
101   :group 'notmuch-search)
102
103 ;; The name of this variable `notmuch-init-file' is consistent with the
104 ;; convention used in e.g. emacs and gnus. The value, `notmuch-config[.el[c]]'
105 ;; is consistent with notmuch cli configuration file `~/.notmuch-config'.
106 (defcustom notmuch-init-file (locate-user-emacs-file "notmuch-config")
107   "Your Notmuch Emacs-Lisp configuration file name.
108 If a file with one of the suffixes defined by `get-load-suffixes' exists,
109 it will be read instead.
110 This file is read once when notmuch is loaded; the notmuch hooks added
111 there will be called at other points of notmuch execution."
112   :type 'file
113   :group 'notmuch)
114
115 (defvar notmuch-query-history nil
116   "Variable to store minibuffer history for notmuch queries.")
117
118 (defun notmuch-foreach-mime-part (function mm-handle)
119   (cond ((stringp (car mm-handle))
120          (dolist (part (cdr mm-handle))
121            (notmuch-foreach-mime-part function part)))
122         ((bufferp (car mm-handle))
123          (funcall function mm-handle))
124         (t (dolist (part mm-handle)
125              (notmuch-foreach-mime-part function part)))))
126
127 (defun notmuch-count-attachments (mm-handle)
128   (let ((count 0))
129     (notmuch-foreach-mime-part
130      (lambda (p)
131        (let ((disposition (mm-handle-disposition p)))
132          (and (listp disposition)
133               (or (equal (car disposition) "attachment")
134                   (and (equal (car disposition) "inline")
135                        (assq 'filename disposition)))
136               (cl-incf count))))
137      mm-handle)
138     count))
139
140 (defun notmuch-save-attachments (mm-handle &optional queryp)
141   (notmuch-foreach-mime-part
142    (lambda (p)
143      (let ((disposition (mm-handle-disposition p)))
144        (and (listp disposition)
145             (or (equal (car disposition) "attachment")
146                 (and (equal (car disposition) "inline")
147                      (assq 'filename disposition)))
148             (or (not queryp)
149                 (y-or-n-p
150                  (concat "Save '" (cdr (assq 'filename disposition)) "' ")))
151             (mm-save-part p))))
152    mm-handle))
153
154 (require 'hl-line)
155
156 (defun notmuch-hl-line-mode ()
157   (prog1 (hl-line-mode)
158     (when hl-line-overlay
159       (overlay-put hl-line-overlay 'priority 1))))
160
161 (defcustom notmuch-search-hook '(notmuch-hl-line-mode)
162   "List of functions to call when notmuch displays the search results."
163   :type 'hook
164   :options '(notmuch-hl-line-mode)
165   :group 'notmuch-search
166   :group 'notmuch-hooks)
167
168 (defvar notmuch-search-mode-map
169   (let ((map (make-sparse-keymap)))
170     (set-keymap-parent map notmuch-common-keymap)
171     (define-key map "x" 'notmuch-bury-or-kill-this-buffer)
172     (define-key map (kbd "<DEL>") 'notmuch-search-scroll-down)
173     (define-key map "b" 'notmuch-search-scroll-down)
174     (define-key map " " 'notmuch-search-scroll-up)
175     (define-key map "<" 'notmuch-search-first-thread)
176     (define-key map ">" 'notmuch-search-last-thread)
177     (define-key map "p" 'notmuch-search-previous-thread)
178     (define-key map "n" 'notmuch-search-next-thread)
179     (define-key map "r" 'notmuch-search-reply-to-thread-sender)
180     (define-key map "R" 'notmuch-search-reply-to-thread)
181     (define-key map "o" 'notmuch-search-toggle-order)
182     (define-key map "c" 'notmuch-search-stash-map)
183     (define-key map "t" 'notmuch-search-filter-by-tag)
184     (define-key map "l" 'notmuch-search-filter)
185     (define-key map [mouse-1] 'notmuch-search-show-thread)
186     (define-key map "k" 'notmuch-tag-jump)
187     (define-key map "*" 'notmuch-search-tag-all)
188     (define-key map "a" 'notmuch-search-archive-thread)
189     (define-key map "-" 'notmuch-search-remove-tag)
190     (define-key map "+" 'notmuch-search-add-tag)
191     (define-key map (kbd "RET") 'notmuch-search-show-thread)
192     (define-key map (kbd "M-RET") 'notmuch-tree-from-search-thread)
193     (define-key map "Z" 'notmuch-tree-from-search-current-query)
194     (define-key map "U" 'notmuch-unthreaded-from-search-current-query)
195     map)
196   "Keymap for \"notmuch search\" buffers.")
197 (fset 'notmuch-search-mode-map notmuch-search-mode-map)
198
199 (defvar notmuch-search-stash-map
200   (let ((map (make-sparse-keymap)))
201     (define-key map "i" 'notmuch-search-stash-thread-id)
202     (define-key map "q" 'notmuch-stash-query)
203     (define-key map "?" 'notmuch-subkeymap-help)
204     map)
205   "Submap for stash commands.")
206 (fset 'notmuch-search-stash-map notmuch-search-stash-map)
207
208 (defun notmuch-search-stash-thread-id ()
209   "Copy thread ID of current thread to kill-ring."
210   (interactive)
211   (notmuch-common-do-stash (notmuch-search-find-thread-id)))
212
213 (defun notmuch-stash-query ()
214   "Copy current query to kill-ring."
215   (interactive)
216   (notmuch-common-do-stash (notmuch-search-get-query)))
217
218 (defvar notmuch-search-query-string)
219 (defvar notmuch-search-target-thread)
220 (defvar notmuch-search-target-line)
221
222 (defvar notmuch-search-disjunctive-regexp      "\\<[oO][rR]\\>")
223
224 (defun notmuch-search-scroll-up ()
225   "Move forward through search results by one window's worth."
226   (interactive)
227   (condition-case nil
228       (scroll-up nil)
229     ((end-of-buffer) (notmuch-search-last-thread))))
230
231 (defun notmuch-search-scroll-down ()
232   "Move backward through the search results by one window's worth."
233   (interactive)
234   ;; I don't know why scroll-down doesn't signal beginning-of-buffer
235   ;; the way that scroll-up signals end-of-buffer, but c'est la vie.
236   ;;
237   ;; So instead of trapping a signal we instead check whether the
238   ;; window begins on the first line of the buffer and if so, move
239   ;; directly to that position. (We have to count lines since the
240   ;; window-start position is not the same as point-min due to the
241   ;; invisible thread-ID characters on the first line.
242   (if (equal (count-lines (point-min) (window-start)) 0)
243       (goto-char (point-min))
244     (scroll-down nil)))
245
246 (defun notmuch-search-next-thread ()
247   "Select the next thread in the search results."
248   (interactive)
249   (when (notmuch-search-get-result)
250     (goto-char (notmuch-search-result-end))))
251
252 (defun notmuch-search-previous-thread ()
253   "Select the previous thread in the search results."
254   (interactive)
255   (if (notmuch-search-get-result)
256       (unless (bobp)
257         (goto-char (notmuch-search-result-beginning (- (point) 1))))
258     ;; We must be past the end; jump to the last result
259     (notmuch-search-last-thread)))
260
261 (defun notmuch-search-last-thread ()
262   "Select the last thread in the search results."
263   (interactive)
264   (goto-char (point-max))
265   (forward-line -2)
266   (let ((beg (notmuch-search-result-beginning)))
267     (when beg
268       (goto-char beg))))
269
270 (defun notmuch-search-first-thread ()
271   "Select the first thread in the search results."
272   (interactive)
273   (goto-char (point-min)))
274
275 (defface notmuch-message-summary-face
276   `((((class color) (background light))
277      ,@(and (>= emacs-major-version 27) '(:extend t))
278      (:background "#f0f0f0"))
279     (((class color) (background dark))
280      ,@(and (>= emacs-major-version 27) '(:extend t))
281      (:background "#303030")))
282   "Face for the single-line message summary in notmuch-show-mode."
283   :group 'notmuch-show
284   :group 'notmuch-faces)
285
286 (defface notmuch-search-date
287   '((t :inherit default))
288   "Face used in search mode for dates."
289   :group 'notmuch-search
290   :group 'notmuch-faces)
291
292 (defface notmuch-search-count
293   '((t :inherit default))
294   "Face used in search mode for the count matching the query."
295   :group 'notmuch-search
296   :group 'notmuch-faces)
297
298 (defface notmuch-search-subject
299   '((t :inherit default))
300   "Face used in search mode for subjects."
301   :group 'notmuch-search
302   :group 'notmuch-faces)
303
304 (defface notmuch-search-matching-authors
305   '((t :inherit default))
306   "Face used in search mode for authors matching the query."
307   :group 'notmuch-search
308   :group 'notmuch-faces)
309
310 (defface notmuch-search-non-matching-authors
311   '((((class color)
312       (background dark))
313      (:foreground "grey30"))
314     (((class color)
315       (background light))
316      (:foreground "grey60"))
317     (t
318      (:italic t)))
319   "Face used in search mode for authors not matching the query."
320   :group 'notmuch-search
321   :group 'notmuch-faces)
322
323 (defface notmuch-tag-face
324   '((((class color)
325       (background dark))
326      (:foreground "OliveDrab1"))
327     (((class color)
328       (background light))
329      (:foreground "navy blue" :bold t))
330     (t
331      (:bold t)))
332   "Face used in search mode face for tags."
333   :group 'notmuch-search
334   :group 'notmuch-faces)
335
336 (defface notmuch-search-flagged-face
337   '((((class color)
338       (background dark))
339      (:foreground "LightBlue1"))
340     (((class color)
341       (background light))
342      (:foreground "blue")))
343   "Face used in search mode face for flagged threads.
344
345 This face is the default value for the \"flagged\" tag in
346 `notmuch-search-line-faces`."
347   :group 'notmuch-search
348   :group 'notmuch-faces)
349
350 (defface notmuch-search-unread-face
351   '((t
352      (:weight bold)))
353   "Face used in search mode for unread threads.
354
355 This face is the default value for the \"unread\" tag in
356 `notmuch-search-line-faces`."
357   :group 'notmuch-search
358   :group 'notmuch-faces)
359
360 (define-derived-mode notmuch-search-mode fundamental-mode "notmuch-search"
361   "Major mode displaying results of a notmuch search.
362
363 This buffer contains the results of a \"notmuch search\" of your
364 email archives. Each line in the buffer represents a single
365 thread giving a summary of the thread (a relative date, the
366 number of matched messages and total messages in the thread,
367 participants in the thread, a representative subject line, and
368 any tags).
369
370 Pressing \\[notmuch-search-show-thread] on any line displays that
371 thread. The '\\[notmuch-search-add-tag]' and
372 '\\[notmuch-search-remove-tag]' keys can be used to add or remove
373 tags from a thread. The '\\[notmuch-search-archive-thread]' key
374 is a convenience for archiving a thread (applying changes in
375 `notmuch-archive-tags'). The '\\[notmuch-search-tag-all]' key can
376 be used to add and/or remove tags from all messages (as opposed
377 to threads) that match the current query.  Use with caution, as
378 this will also tag matching messages that arrived *after*
379 constructing the buffer.
380
381 Other useful commands are '\\[notmuch-search-filter]' for
382 filtering the current search based on an additional query string,
383 '\\[notmuch-search-filter-by-tag]' for filtering to include only
384 messages with a given tag, and '\\[notmuch-search]' to execute a
385 new, global search.
386
387 Complete list of currently available key bindings:
388
389 \\{notmuch-search-mode-map}"
390   (make-local-variable 'notmuch-search-query-string)
391   (make-local-variable 'notmuch-search-oldest-first)
392   (make-local-variable 'notmuch-search-target-thread)
393   (make-local-variable 'notmuch-search-target-line)
394   (setq notmuch-buffer-refresh-function #'notmuch-search-refresh-view)
395   (set (make-local-variable 'scroll-preserve-screen-position) t)
396   (add-to-invisibility-spec (cons 'ellipsis t))
397   (setq truncate-lines t)
398   (setq buffer-read-only t)
399   (setq imenu-prev-index-position-function
400         #'notmuch-search-imenu-prev-index-position-function)
401   (setq imenu-extract-index-name-function
402         #'notmuch-search-imenu-extract-index-name-function))
403
404 (defun notmuch-search-get-result (&optional pos)
405   "Return the result object for the thread at POS (or point).
406
407 If there is no thread at POS (or point), returns nil."
408   (get-text-property (or pos (point)) 'notmuch-search-result))
409
410 (defun notmuch-search-result-beginning (&optional pos)
411   "Return the point at the beginning of the thread at POS (or point).
412
413 If there is no thread at POS (or point), returns nil."
414   (and (notmuch-search-get-result pos)
415        ;; We pass 1+point because previous-single-property-change starts
416        ;; searching one before the position we give it.
417        (previous-single-property-change (1+ (or pos (point)))
418                                         'notmuch-search-result nil
419                                         (point-min))))
420
421 (defun notmuch-search-result-end (&optional pos)
422   "Return the point at the end of the thread at POS (or point).
423
424 The returned point will be just after the newline character that
425 ends the result line.  If there is no thread at POS (or point),
426 returns nil."
427   (and (notmuch-search-get-result pos)
428        (next-single-property-change (or pos (point))
429                                     'notmuch-search-result nil
430                                     (point-max))))
431
432 (defun notmuch-search-foreach-result (beg end fn)
433   "Invoke FN for each result between BEG and END.
434
435 FN should take one argument.  It will be applied to the character
436 position of the beginning of each result that overlaps the region
437 between points BEG and END.  As a special case, if (= BEG END),
438 FN will be applied to the result containing point BEG."
439   (let ((pos (notmuch-search-result-beginning beg))
440         ;; End must be a marker in case fn changes the
441         ;; text.
442         (end (copy-marker end))
443         ;; Make sure we examine at least one result, even if
444         ;; (= beg end).
445         (first t))
446     ;; We have to be careful if the region extends beyond the results.
447     ;; In this case, pos could be null or there could be no result at
448     ;; pos.
449     (while (and pos (or (< pos end) first))
450       (when (notmuch-search-get-result pos)
451         (funcall fn pos))
452       (setq pos (notmuch-search-result-end pos))
453       (setq first nil))))
454 ;; Unindent the function argument of notmuch-search-foreach-result so
455 ;; the indentation of callers doesn't get out of hand.
456 (put 'notmuch-search-foreach-result 'lisp-indent-function 2)
457
458 (defun notmuch-search-properties-in-region (property beg end)
459   (let (output)
460     (notmuch-search-foreach-result beg end
461       (lambda (pos)
462         (push (plist-get (notmuch-search-get-result pos) property) output)))
463     output))
464
465 (defun notmuch-search-find-thread-id (&optional bare)
466   "Return the thread for the current thread.
467
468 If BARE is set then do not prefix with \"thread:\"."
469   (let ((thread (plist-get (notmuch-search-get-result) :thread)))
470     (when thread
471       (concat (and (not bare) "thread:") thread))))
472
473 (defun notmuch-search-find-stable-query ()
474   "Return the stable queries for the current thread.
475
476 This returns a list (MATCHED-QUERY UNMATCHED-QUERY) for the
477 matched and unmatched messages in the current thread."
478   (plist-get (notmuch-search-get-result) :query))
479
480 (defun notmuch-search-find-stable-query-region (beg end &optional only-matched)
481   "Return the stable query for the current region.
482
483 If ONLY-MATCHED is non-nil, include only matched messages.  If it
484 is nil, include both matched and unmatched messages. If there are
485 no messages in the region then return nil."
486   (let ((query-list nil) (all (not only-matched)))
487     (dolist (queries (notmuch-search-properties-in-region :query beg end))
488       (when (car queries)
489         (push (car queries) query-list))
490       (when (and all (cadr queries))
491         (push (cadr queries) query-list)))
492     (and query-list
493          (concat "(" (mapconcat 'identity query-list ") or (") ")"))))
494
495 (defun notmuch-search-find-authors ()
496   "Return the authors for the current thread."
497   (plist-get (notmuch-search-get-result) :authors))
498
499 (defun notmuch-search-find-authors-region (beg end)
500   "Return a list of authors for the current region."
501   (notmuch-search-properties-in-region :authors beg end))
502
503 (defun notmuch-search-find-subject ()
504   "Return the subject for the current thread."
505   (plist-get (notmuch-search-get-result) :subject))
506
507 (defun notmuch-search-find-subject-region (beg end)
508   "Return a list of authors for the current region."
509   (notmuch-search-properties-in-region :subject beg end))
510
511 (defun notmuch-search-show-thread (&optional elide-toggle)
512   "Display the currently selected thread.
513
514 With a prefix argument, invert the default value of
515 `notmuch-show-only-matching-messages' when displaying the
516 thread."
517   (interactive "P")
518   (let ((thread-id (notmuch-search-find-thread-id))
519         (subject (notmuch-search-find-subject)))
520     (if (> (length thread-id) 0)
521         (notmuch-show thread-id
522                       elide-toggle
523                       (current-buffer)
524                       notmuch-search-query-string
525                       ;; Name the buffer based on the subject.
526                       (concat "*"
527                               (truncate-string-to-width subject 30 nil nil t)
528                               "*"))
529       (message "End of search results."))))
530
531 (defun notmuch-tree-from-search-current-query ()
532   "Call notmuch tree with the current query."
533   (interactive)
534   (notmuch-tree notmuch-search-query-string))
535
536 (defun notmuch-unthreaded-from-search-current-query ()
537   "Call notmuch tree with the current query."
538   (interactive)
539   (notmuch-unthreaded notmuch-search-query-string))
540
541 (defun notmuch-tree-from-search-thread ()
542   "Show the selected thread with notmuch-tree."
543   (interactive)
544   (notmuch-tree (notmuch-search-find-thread-id)
545                 notmuch-search-query-string
546                 nil
547                 (notmuch-prettify-subject (notmuch-search-find-subject))
548                 t))
549
550 (defun notmuch-search-reply-to-thread (&optional prompt-for-sender)
551   "Begin composing a reply-all to the entire current thread in a new buffer."
552   (interactive "P")
553   (let ((message-id (notmuch-search-find-thread-id)))
554     (notmuch-mua-new-reply message-id prompt-for-sender t)))
555
556 (defun notmuch-search-reply-to-thread-sender (&optional prompt-for-sender)
557   "Begin composing a reply to the entire current thread in a new buffer."
558   (interactive "P")
559   (let ((message-id (notmuch-search-find-thread-id)))
560     (notmuch-mua-new-reply message-id prompt-for-sender nil)))
561
562 (defun notmuch-search-set-tags (tags &optional pos)
563   (let ((new-result (plist-put (notmuch-search-get-result pos) :tags tags)))
564     (notmuch-search-update-result new-result pos)))
565
566 (defun notmuch-search-get-tags (&optional pos)
567   (plist-get (notmuch-search-get-result pos) :tags))
568
569 (defun notmuch-search-get-tags-region (beg end)
570   (let (output)
571     (notmuch-search-foreach-result beg end
572       (lambda (pos)
573         (setq output (append output (notmuch-search-get-tags pos)))))
574     output))
575
576 (defun notmuch-search-interactive-tag-changes (&optional initial-input)
577   "Prompt for tag changes for the current thread or region.
578
579 Returns (TAG-CHANGES REGION-BEGIN REGION-END)."
580   (pcase-let ((`(,beg ,end) (notmuch-interactive-region)))
581     (list (notmuch-read-tag-changes (notmuch-search-get-tags-region beg end)
582                                     (if (= beg end) "Tag thread" "Tag region")
583                                     initial-input)
584           beg end)))
585
586 (defun notmuch-search-tag (tag-changes &optional beg end only-matched)
587   "Change tags for the currently selected thread or region.
588
589 See `notmuch-tag' for information on the format of TAG-CHANGES.
590 When called interactively, this uses the region if the region is
591 active.  When called directly, BEG and END provide the region.
592 If these are nil or not provided, then, if the region is active
593 this applied to all threads meeting the region, and if the region
594 is inactive this applies to the thread at point.
595
596 If ONLY-MATCHED is non-nil, only tag matched messages."
597   (interactive (notmuch-search-interactive-tag-changes))
598   (unless (and beg end)
599     (setq beg (car (notmuch-interactive-region)))
600     (setq end (cadr (notmuch-interactive-region))))
601   (let ((search-string (notmuch-search-find-stable-query-region
602                         beg end only-matched)))
603     (notmuch-tag search-string tag-changes)
604     (notmuch-search-foreach-result beg end
605       (lambda (pos)
606         (notmuch-search-set-tags
607          (notmuch-update-tags (notmuch-search-get-tags pos) tag-changes)
608          pos)))))
609
610 (defun notmuch-search-add-tag (tag-changes &optional beg end)
611   "Change tags for the current thread or region (defaulting to add).
612
613 Same as `notmuch-search-tag' but sets initial input to '+'."
614   (interactive (notmuch-search-interactive-tag-changes "+"))
615   (notmuch-search-tag tag-changes beg end))
616
617 (defun notmuch-search-remove-tag (tag-changes &optional beg end)
618   "Change tags for the current thread or region (defaulting to remove).
619
620 Same as `notmuch-search-tag' but sets initial input to '-'."
621   (interactive (notmuch-search-interactive-tag-changes "-"))
622   (notmuch-search-tag tag-changes beg end))
623
624 (put 'notmuch-search-archive-thread 'notmuch-prefix-doc
625      "Un-archive the currently selected thread.")
626 (defun notmuch-search-archive-thread (&optional unarchive beg end)
627   "Archive the currently selected thread or region.
628
629 Archive each message in the currently selected thread by applying
630 the tag changes in `notmuch-archive-tags' to each (remove the
631 \"inbox\" tag by default). If a prefix argument is given, the
632 messages will be \"unarchived\" (i.e. the tag changes in
633 `notmuch-archive-tags' will be reversed).
634
635 This function advances the next thread when finished."
636   (interactive (cons current-prefix-arg (notmuch-interactive-region)))
637   (when notmuch-archive-tags
638     (notmuch-search-tag
639      (notmuch-tag-change-list notmuch-archive-tags unarchive) beg end))
640   (when (eq beg end)
641     (notmuch-search-next-thread)))
642
643 (defun notmuch-search-update-result (result &optional pos)
644   "Replace the result object of the thread at POS (or point) by
645 RESULT and redraw it.
646
647 This will keep point in a reasonable location.  However, if there
648 are enclosing save-excursions and the saved point is in the
649 result being updated, the point will be restored to the beginning
650 of the result."
651   (let ((start (notmuch-search-result-beginning pos))
652         (end (notmuch-search-result-end pos))
653         (init-point (point))
654         (inhibit-read-only t))
655     ;; Delete the current thread
656     (delete-region start end)
657     ;; Insert the updated thread
658     (notmuch-search-show-result result start)
659     ;; If point was inside the old result, make an educated guess
660     ;; about where to place it now.  Unfortunately, this won't work
661     ;; with save-excursion (or any other markers that would be nice to
662     ;; preserve, such as the window start), but there's nothing we can
663     ;; do about that without a way to retrieve markers in a region.
664     (when (and (>= init-point start) (<= init-point end))
665       (let* ((new-end (notmuch-search-result-end start))
666              (new-point (if (= init-point end)
667                             new-end
668                           (min init-point (- new-end 1)))))
669         (goto-char new-point)))))
670
671 (defun notmuch-search-process-sentinel (proc msg)
672   "Add a message to let user know when \"notmuch search\" exits."
673   (let ((buffer (process-buffer proc))
674         (status (process-status proc))
675         (exit-status (process-exit-status proc))
676         (never-found-target-thread nil))
677     (when (memq status '(exit signal))
678       (catch 'return
679         (kill-buffer (process-get proc 'parse-buf))
680         (when (buffer-live-p buffer)
681           (with-current-buffer buffer
682             (save-excursion
683               (let ((inhibit-read-only t)
684                     (atbob (bobp)))
685                 (goto-char (point-max))
686                 (when (eq status 'signal)
687                   (insert "Incomplete search results (search process was killed).\n"))
688                 (when (eq status 'exit)
689                   (insert "End of search results.\n")
690                   ;; For version mismatch, there's no point in
691                   ;; showing the search buffer
692                   (when (or (= exit-status 20) (= exit-status 21))
693                     (kill-buffer)
694                     (throw 'return nil))
695                   (when (and atbob
696                              (not (string= notmuch-search-target-thread "found")))
697                     (set 'never-found-target-thread t)))))
698             (when (and never-found-target-thread
699                        notmuch-search-target-line)
700               (goto-char (point-min))
701               (forward-line (1- notmuch-search-target-line)))))))))
702
703 (define-widget 'notmuch--custom-face-edit 'lazy
704   "Custom face edit with a tag Edit Face"
705   ;; I could not persuage custom-face-edit to respect the :tag
706   ;; property so create a widget specially
707   :tag "Manually specify face"
708   :type 'custom-face-edit)
709
710 (defcustom notmuch-search-line-faces
711   '(("unread" . notmuch-search-unread-face)
712     ("flagged" . notmuch-search-flagged-face))
713   "Alist of tags to faces for line highlighting in notmuch-search.
714 Each element looks like (TAG . FACE).
715 A thread with TAG will have FACE applied.
716
717 Here is an example of how to color search results based on tags.
718  (the following text would be placed in your ~/.emacs file):
719
720  (setq notmuch-search-line-faces \\='((\"unread\" . (:foreground \"green\"))
721                                    (\"deleted\" . (:foreground \"red\"
722                                                   :background \"blue\"))))
723
724 The FACE must be a face name (a symbol or string), a property
725 list of face attributes, or a list of these.  The faces for
726 matching tags are merged, with earlier attributes overriding
727 later. A message having both \"deleted\" and \"unread\" tags with
728 the above settings would have a green foreground and blue
729 background."
730   :type '(alist :key-type (string)
731                 :value-type (radio (face :tag "Face name")
732                                    (notmuch--custom-face-edit)))
733   :group 'notmuch-search
734   :group 'notmuch-faces)
735
736 (defun notmuch-search-color-line (start end line-tag-list)
737   "Colorize lines in `notmuch-show' based on tags."
738   ;; Reverse the list so earlier entries take precedence
739   (dolist (elem (reverse notmuch-search-line-faces))
740     (let ((tag (car elem))
741           (face (cdr elem)))
742       (when (member tag line-tag-list)
743         (notmuch-apply-face nil face nil start end)))))
744
745 (defun notmuch-search-author-propertize (authors)
746   "Split `authors' into matching and non-matching authors and
747 propertize appropriately. If no boundary between authors and
748 non-authors is found, assume that all of the authors match."
749   (if (string-match "\\(.*\\)|\\(.*\\)" authors)
750       (concat (propertize (concat (match-string 1 authors) ",")
751                           'face 'notmuch-search-matching-authors)
752               (propertize (match-string 2 authors)
753                           'face 'notmuch-search-non-matching-authors))
754     (propertize authors 'face 'notmuch-search-matching-authors)))
755
756 (defun notmuch-search-insert-authors (format-string authors)
757   ;; Save the match data to avoid interfering with
758   ;; `notmuch-search-process-filter'.
759   (save-match-data
760     (let* ((formatted-authors (format format-string authors))
761            (formatted-sample (format format-string ""))
762            (visible-string formatted-authors)
763            (invisible-string "")
764            (padding ""))
765       ;; Truncate the author string to fit the specification.
766       (when (> (length formatted-authors)
767                (length formatted-sample))
768         (let ((visible-length (- (length formatted-sample)
769                                  (length "... "))))
770           ;; Truncate the visible string according to the width of
771           ;; the display string.
772           (setq visible-string (substring formatted-authors 0 visible-length))
773           (setq invisible-string (substring formatted-authors visible-length))
774           ;; If possible, truncate the visible string at a natural
775           ;; break (comma or pipe), as incremental search doesn't
776           ;; match across the visible/invisible border.
777           (when (string-match "\\(.*\\)\\([,|] \\)\\([^,|]*\\)" visible-string)
778             ;; Second clause is destructive on `visible-string', so
779             ;; order is important.
780             (setq invisible-string (concat (match-string 3 visible-string)
781                                            invisible-string))
782             (setq visible-string (concat (match-string 1 visible-string)
783                                          (match-string 2 visible-string))))
784           ;; `visible-string' may be shorter than the space allowed
785           ;; by `format-string'. If so we must insert some padding
786           ;; after `invisible-string'.
787           (setq padding (make-string (- (length formatted-sample)
788                                         (length visible-string)
789                                         (length "..."))
790                                      ? ))))
791       ;; Use different faces to show matching and non-matching authors.
792       (if (string-match "\\(.*\\)|\\(.*\\)" visible-string)
793           ;; The visible string contains both matching and
794           ;; non-matching authors.
795           (progn
796             (setq visible-string (notmuch-search-author-propertize visible-string))
797             ;; The invisible string must contain only non-matching
798             ;; authors, as the visible-string contains both.
799             (setq invisible-string (propertize invisible-string
800                                                'face 'notmuch-search-non-matching-authors)))
801         ;; The visible string contains only matching authors.
802         (setq visible-string (propertize visible-string
803                                          'face 'notmuch-search-matching-authors))
804         ;; The invisible string may contain both matching and
805         ;; non-matching authors.
806         (setq invisible-string (notmuch-search-author-propertize invisible-string)))
807       ;; If there is any invisible text, add it as a tooltip to the
808       ;; visible text.
809       (unless (string= invisible-string "")
810         (setq visible-string
811               (propertize visible-string
812                           'help-echo (concat "..." invisible-string))))
813       ;; Insert the visible and, if present, invisible author strings.
814       (insert visible-string)
815       (unless (string= invisible-string "")
816         (let ((start (point))
817               overlay)
818           (insert invisible-string)
819           (setq overlay (make-overlay start (point)))
820           (overlay-put overlay 'invisible 'ellipsis)
821           (overlay-put overlay 'isearch-open-invisible #'delete-overlay)))
822       (insert padding))))
823
824 (defun notmuch-search-insert-field (field format-string result)
825   (cond
826    ((string-equal field "date")
827     (insert (propertize (format format-string (plist-get result :date_relative))
828                         'face 'notmuch-search-date)))
829    ((string-equal field "count")
830     (insert (propertize (format format-string
831                                 (format "[%s/%s]" (plist-get result :matched)
832                                         (plist-get result :total)))
833                         'face 'notmuch-search-count)))
834    ((string-equal field "subject")
835     (insert (propertize (format format-string
836                                 (notmuch-sanitize (plist-get result :subject)))
837                         'face 'notmuch-search-subject)))
838    ((string-equal field "authors")
839     (notmuch-search-insert-authors
840      format-string (notmuch-sanitize (plist-get result :authors))))
841    ((string-equal field "tags")
842     (let ((tags (plist-get result :tags))
843           (orig-tags (plist-get result :orig-tags)))
844       (insert (format format-string (notmuch-tag-format-tags tags orig-tags)))))))
845
846 (defun notmuch-search-show-result (result pos)
847   "Insert RESULT at POS."
848   ;; Ignore excluded matches
849   (unless (= (plist-get result :matched) 0)
850     (save-excursion
851       (goto-char pos)
852       (dolist (spec notmuch-search-result-format)
853         (notmuch-search-insert-field (car spec) (cdr spec) result))
854       (insert "\n")
855       (notmuch-search-color-line pos (point) (plist-get result :tags))
856       (put-text-property pos (point) 'notmuch-search-result result))))
857
858 (defun notmuch-search-append-result (result)
859   "Insert RESULT at the end of the buffer.
860
861 This is only called when a result is first inserted so it also
862 sets the :orig-tag property."
863   (let ((new-result (plist-put result :orig-tags (plist-get result :tags)))
864         (pos (point-max)))
865     (notmuch-search-show-result new-result pos)
866     (when (string= (plist-get result :thread) notmuch-search-target-thread)
867       (setq notmuch-search-target-thread "found")
868       (goto-char pos))))
869
870 (defun notmuch-search-process-filter (proc string)
871   "Process and filter the output of \"notmuch search\"."
872   (let ((results-buf (process-buffer proc))
873         (parse-buf (process-get proc 'parse-buf))
874         (inhibit-read-only t)
875         done)
876     (when (buffer-live-p results-buf)
877       (with-current-buffer parse-buf
878         ;; Insert new data
879         (save-excursion
880           (goto-char (point-max))
881           (insert string))
882         (notmuch-sexp-parse-partial-list 'notmuch-search-append-result
883                                          results-buf)))))
884
885 (defun notmuch-search-tag-all (tag-changes)
886   "Add/remove tags from all messages in current search buffer.
887
888 See `notmuch-tag' for information on the format of TAG-CHANGES."
889   (interactive
890    (list (notmuch-read-tag-changes
891           (notmuch-search-get-tags-region (point-min) (point-max)) "Tag all")))
892   (notmuch-search-tag tag-changes (point-min) (point-max) t))
893
894 (defun notmuch-search-buffer-title (query)
895   "Returns the title for a buffer with notmuch search results."
896   (let* ((saved-search
897           (let (longest
898                 (longest-length 0))
899             (cl-loop for tuple in notmuch-saved-searches
900                      if (let ((quoted-query
901                                (regexp-quote
902                                 (notmuch-saved-search-get tuple :query))))
903                           (and (string-match (concat "^" quoted-query) query)
904                                (> (length (match-string 0 query))
905                                   longest-length)))
906                      do (setq longest tuple))
907             longest))
908          (saved-search-name (notmuch-saved-search-get saved-search :name))
909          (saved-search-query (notmuch-saved-search-get saved-search :query)))
910     (cond ((and saved-search (equal saved-search-query query))
911            ;; Query is the same as saved search (ignoring case)
912            (concat "*notmuch-saved-search-" saved-search-name "*"))
913           (saved-search
914            (concat "*notmuch-search-"
915                    (replace-regexp-in-string
916                     (concat "^" (regexp-quote saved-search-query))
917                     (concat "[ " saved-search-name " ]")
918                     query)
919                    "*"))
920           (t
921            (concat "*notmuch-search-" query "*")))))
922
923 (defun notmuch-read-query (prompt)
924   "Read a notmuch-query from the minibuffer with completion.
925
926 PROMPT is the string to prompt with."
927   (let*
928       ((all-tags
929         (mapcar (lambda (tag) (notmuch-escape-boolean-term tag))
930                 (process-lines notmuch-command "search" "--output=tags" "*")))
931        (completions
932         (append (list "folder:" "path:" "thread:" "id:" "date:" "from:" "to:"
933                       "subject:" "attachment:")
934                 (mapcar (lambda (tag) (concat "tag:" tag)) all-tags)
935                 (mapcar (lambda (tag) (concat "is:" tag)) all-tags)
936                 (mapcar (lambda (mimetype) (concat "mimetype:" mimetype))
937                         (mailcap-mime-types)))))
938     (let ((keymap (copy-keymap minibuffer-local-map))
939           (current-query (cl-case major-mode
940                            (notmuch-search-mode (notmuch-search-get-query))
941                            (notmuch-show-mode (notmuch-show-get-query))
942                            (notmuch-tree-mode (notmuch-tree-get-query))))
943           (minibuffer-completion-table
944            (completion-table-dynamic
945             (lambda (string)
946               ;; generate a list of possible completions for the current input
947               (cond
948                ;; this ugly regexp is used to get the last word of the input
949                ;; possibly preceded by a '('
950                ((string-match "\\(^\\|.* (?\\)\\([^ ]*\\)$" string)
951                 (mapcar (lambda (compl)
952                           (concat (match-string-no-properties 1 string) compl))
953                         (all-completions (match-string-no-properties 2 string)
954                                          completions)))
955                (t (list string)))))))
956       ;; this was simpler than convincing completing-read to accept spaces:
957       (define-key keymap (kbd "TAB") 'minibuffer-complete)
958       (let ((history-delete-duplicates t))
959         (read-from-minibuffer prompt nil keymap nil
960                               'notmuch-search-history current-query nil)))))
961
962 (defun notmuch-search-get-query ()
963   "Return the current query in this search buffer."
964   notmuch-search-query-string)
965
966 (put 'notmuch-search 'notmuch-doc "Search for messages.")
967 ;;;###autoload
968 (defun notmuch-search (&optional query oldest-first target-thread target-line no-display)
969   "Display threads matching QUERY in a notmuch-search buffer.
970
971 If QUERY is nil, it is read interactively from the minibuffer.
972 Other optional parameters are used as follows:
973
974   OLDEST-FIRST: A Boolean controlling the sort order of returned threads
975   TARGET-THREAD: A thread ID (without the thread: prefix) that will be made
976                  current if it appears in the search results.
977   TARGET-LINE: The line number to move to if the target thread does not
978                appear in the search results.
979   NO-DISPLAY: Do not try to foreground the search results buffer. If it is
980               already foregrounded i.e. displayed in a window, this has no
981               effect, meaning the buffer will remain visible.
982
983 When called interactively, this will prompt for a query and use
984 the configured default sort order."
985   (interactive
986    (list
987     ;; Prompt for a query
988     nil
989     ;; Use the default search order (if we're doing a search from a
990     ;; search buffer, ignore any buffer-local overrides)
991     (default-value 'notmuch-search-oldest-first)))
992
993   (let* ((query (or query (notmuch-read-query "Notmuch search: ")))
994          (buffer (get-buffer-create (notmuch-search-buffer-title query))))
995     (if no-display
996         (set-buffer buffer)
997       (switch-to-buffer buffer))
998     ;; avoid wiping out third party buffer-local variables in the case
999     ;; where we're just refreshing or changing the sort order of an
1000     ;; existing search results buffer
1001     (unless (eq major-mode 'notmuch-search-mode)
1002       (notmuch-search-mode))
1003     ;; Don't track undo information for this buffer
1004     (set 'buffer-undo-list t)
1005     (set 'notmuch-search-query-string query)
1006     (set 'notmuch-search-oldest-first oldest-first)
1007     (set 'notmuch-search-target-thread target-thread)
1008     (set 'notmuch-search-target-line target-line)
1009     (notmuch-tag-clear-cache)
1010     (let ((proc (get-buffer-process (current-buffer)))
1011           (inhibit-read-only t))
1012       (when proc
1013         (error "notmuch search process already running for query `%s'" query))
1014       (erase-buffer)
1015       (goto-char (point-min))
1016       (save-excursion
1017         (let ((proc (notmuch-start-notmuch
1018                      "notmuch-search" buffer #'notmuch-search-process-sentinel
1019                      "search" "--format=sexp" "--format-version=4"
1020                      (if oldest-first
1021                          "--sort=oldest-first"
1022                        "--sort=newest-first")
1023                      query))
1024               ;; Use a scratch buffer to accumulate partial output.
1025               ;; This buffer will be killed by the sentinel, which
1026               ;; should be called no matter how the process dies.
1027               (parse-buf (generate-new-buffer " *notmuch search parse*")))
1028           (process-put proc 'parse-buf parse-buf)
1029           (set-process-filter proc 'notmuch-search-process-filter)
1030           (set-process-query-on-exit-flag proc nil))))
1031     (run-hooks 'notmuch-search-hook)))
1032
1033 (defun notmuch-search-refresh-view ()
1034   "Refresh the current view.
1035
1036 Erases the current buffer and runs a new search with the same
1037 query string as the current search. If the current thread is in
1038 the new search results, then point will be placed on the same
1039 thread. Otherwise, point will be moved to attempt to be in the
1040 same relative position within the new buffer."
1041   (interactive)
1042   (let ((target-line (line-number-at-pos))
1043         (oldest-first notmuch-search-oldest-first)
1044         (target-thread (notmuch-search-find-thread-id 'bare))
1045         (query notmuch-search-query-string))
1046     ;; notmuch-search erases the current buffer.
1047     (notmuch-search query oldest-first target-thread target-line t)
1048     (goto-char (point-min))))
1049
1050 (defun notmuch-search-toggle-order ()
1051   "Toggle the current search order.
1052
1053 This command toggles the sort order for the current search. The
1054 default sort order is defined by `notmuch-search-oldest-first'."
1055   (interactive)
1056   (set 'notmuch-search-oldest-first (not notmuch-search-oldest-first))
1057   (notmuch-search-refresh-view))
1058
1059 (defun notmuch-group-disjunctive-query-string (query-string)
1060   "Group query if it contains a complex expression.
1061
1062 Enclose QUERY-STRING in parentheses if it matches
1063 `notmuch-search-disjunctive-regexp'."
1064   (if (string-match-p notmuch-search-disjunctive-regexp query-string)
1065       (concat "( " query-string " )")
1066     query-string))
1067
1068 (defun notmuch-search-filter (query)
1069   "Filter or LIMIT the current search results based on an additional query string.
1070
1071 Runs a new search matching only messages that match both the
1072 current search results AND the additional query string provided."
1073   (interactive (list (notmuch-read-query "Filter search: ")))
1074   (let ((grouped-query (notmuch-group-disjunctive-query-string query))
1075         (grouped-original-query (notmuch-group-disjunctive-query-string
1076                                  notmuch-search-query-string)))
1077     (notmuch-search (if (string= grouped-original-query "*")
1078                         grouped-query
1079                       (concat grouped-original-query " and " grouped-query))
1080                     notmuch-search-oldest-first)))
1081
1082 (defun notmuch-search-filter-by-tag (tag)
1083   "Filter the current search results based on a single tag.
1084
1085 Runs a new search matching only messages that match both the
1086 current search results AND that are tagged with the given tag."
1087   (interactive
1088    (list (notmuch-select-tag-with-completion "Filter by tag: "
1089                                              notmuch-search-query-string)))
1090   (notmuch-search (concat notmuch-search-query-string " and tag:" tag)
1091                   notmuch-search-oldest-first))
1092
1093 (defun notmuch-search-by-tag (tag)
1094   "Display threads matching TAG in a notmuch-search buffer."
1095   (interactive
1096    (list (notmuch-select-tag-with-completion "Notmuch search tag: ")))
1097   (notmuch-search (concat "tag:" tag)))
1098
1099 ;;;###autoload
1100 (defun notmuch ()
1101   "Run notmuch and display saved searches, known tags, etc."
1102   (interactive)
1103   (notmuch-hello))
1104
1105 (defun notmuch-interesting-buffer (b)
1106   "Is the current buffer of interest to a notmuch user?"
1107   (with-current-buffer b
1108     (memq major-mode '(notmuch-show-mode
1109                        notmuch-search-mode
1110                        notmuch-tree-mode
1111                        notmuch-hello-mode
1112                        notmuch-message-mode))))
1113
1114 ;;;###autoload
1115 (defun notmuch-cycle-notmuch-buffers ()
1116   "Cycle through any existing notmuch buffers (search, show or hello).
1117
1118 If the current buffer is the only notmuch buffer, bury it. If no
1119 notmuch buffers exist, run `notmuch'."
1120   (interactive)
1121   (let (start first)
1122     ;; If the current buffer is a notmuch buffer, remember it and then
1123     ;; bury it.
1124     (when (notmuch-interesting-buffer (current-buffer))
1125       (setq start (current-buffer))
1126       (bury-buffer))
1127
1128     ;; Find the first notmuch buffer.
1129     (setq first (cl-loop for buffer in (buffer-list)
1130                          if (notmuch-interesting-buffer buffer)
1131                          return buffer))
1132
1133     (if first
1134         ;; If the first one we found is any other than the starting
1135         ;; buffer, switch to it.
1136         (unless (eq first start)
1137           (switch-to-buffer first))
1138       (notmuch))))
1139
1140 ;;;; Imenu Support
1141
1142 (defun notmuch-search-imenu-prev-index-position-function ()
1143   "Move point to previous message in notmuch-search buffer.
1144 This function is used as a value for
1145 `imenu-prev-index-position-function'."
1146   (notmuch-search-previous-thread))
1147
1148 (defun notmuch-search-imenu-extract-index-name-function ()
1149   "Return imenu name for line at point.
1150 This function is used as a value for
1151 `imenu-extract-index-name-function'.  Point should be at the
1152 beginning of the line."
1153   (let ((subject (notmuch-search-find-subject))
1154         (author (notmuch-search-find-authors)))
1155     (format "%s (%s)" subject author)))
1156
1157 (setq mail-user-agent 'notmuch-user-agent)
1158
1159 (provide 'notmuch)
1160
1161 ;; After provide to avoid loops if notmuch was require'd via notmuch-init-file.
1162 (when init-file-user ; don't load init file if the -q option was used.
1163   (load notmuch-init-file t t nil t))
1164
1165 ;;; notmuch.el ends here