b0fd387ec0107b92c1b9642ad8e5268ec64d22f5
[notmuch] / emacs / notmuch.el
1 ;; notmuch.el --- run notmuch within emacs
2 ;;
3 ;; Copyright © Carl Worth
4 ;;
5 ;; This file is part of Notmuch.
6 ;;
7 ;; Notmuch is free software: you can redistribute it and/or modify it
8 ;; under the terms of the GNU General Public License as published by
9 ;; the Free Software Foundation, either version 3 of the License, or
10 ;; (at your option) any later version.
11 ;;
12 ;; Notmuch is distributed in the hope that it will be useful, but
13 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
15 ;; General Public License for more details.
16 ;;
17 ;; You should have received a copy of the GNU General Public License
18 ;; along with Notmuch.  If not, see <http://www.gnu.org/licenses/>.
19 ;;
20 ;; Authors: Carl Worth <cworth@cworth.org>
21
22 ;; This is an emacs-based interface to the notmuch mail system.
23 ;;
24 ;; You will first need to have the notmuch program installed and have a
25 ;; notmuch database built in order to use this. See
26 ;; http://notmuchmail.org for details.
27 ;;
28 ;; To install this software, copy it to a directory that is on the
29 ;; `load-path' variable within emacs (a good candidate is
30 ;; /usr/local/share/emacs/site-lisp). If you are viewing this from the
31 ;; notmuch source distribution then you can simply run:
32 ;;
33 ;;      sudo make install-emacs
34 ;;
35 ;; to install it.
36 ;;
37 ;; Then, to actually run it, add:
38 ;;
39 ;;      (require 'notmuch)
40 ;;
41 ;; to your ~/.emacs file, and then run "M-x notmuch" from within emacs,
42 ;; or run:
43 ;;
44 ;;      emacs -f notmuch
45 ;;
46 ;; Have fun, and let us know if you have any comment, questions, or
47 ;; kudos: Notmuch list <notmuch@notmuchmail.org> (subscription is not
48 ;; required, but is available from http://notmuchmail.org).
49
50 (eval-when-compile (require 'cl))
51 (require 'mm-view)
52 (require 'message)
53
54 (require 'notmuch-lib)
55 (require 'notmuch-tag)
56 (require 'notmuch-show)
57 (require 'notmuch-mua)
58 (require 'notmuch-hello)
59 (require 'notmuch-maildir-fcc)
60 (require 'notmuch-message)
61
62 (defcustom notmuch-search-result-format
63   `(("date" . "%12s ")
64     ("count" . "%-7s ")
65     ("authors" . "%-20s ")
66     ("subject" . "%s ")
67     ("tags" . "(%s)"))
68   "Search result formatting. Supported fields are:
69         date, count, authors, subject, tags
70 For example:
71         (setq notmuch-search-result-format \(\(\"authors\" . \"%-40s\"\)
72                                              \(\"subject\" . \"%s\"\)\)\)
73 Line breaks are permitted in format strings (though this is
74 currently experimental).  Note that a line break at the end of an
75 \"authors\" field will get elided if the authors list is long;
76 place it instead at the beginning of the following field.  To
77 enter a line break when setting this variable with setq, use \\n.
78 To enter a line break in customize, press \\[quoted-insert] C-j."
79   :type '(alist :key-type (string) :value-type (string))
80   :group 'notmuch-search)
81
82 (defvar notmuch-query-history nil
83   "Variable to store minibuffer history for notmuch queries")
84
85 (defun notmuch-foreach-mime-part (function mm-handle)
86   (cond ((stringp (car mm-handle))
87          (dolist (part (cdr mm-handle))
88            (notmuch-foreach-mime-part function part)))
89         ((bufferp (car mm-handle))
90          (funcall function mm-handle))
91         (t (dolist (part mm-handle)
92              (notmuch-foreach-mime-part function part)))))
93
94 (defun notmuch-count-attachments (mm-handle)
95   (let ((count 0))
96     (notmuch-foreach-mime-part
97      (lambda (p)
98        (let ((disposition (mm-handle-disposition p)))
99          (and (listp disposition)
100               (or (equal (car disposition) "attachment")
101                   (and (equal (car disposition) "inline")
102                        (assq 'filename disposition)))
103               (incf count))))
104      mm-handle)
105     count))
106
107 (defun notmuch-save-attachments (mm-handle &optional queryp)
108   (notmuch-foreach-mime-part
109    (lambda (p)
110      (let ((disposition (mm-handle-disposition p)))
111        (and (listp disposition)
112             (or (equal (car disposition) "attachment")
113                 (and (equal (car disposition) "inline")
114                      (assq 'filename disposition)))
115             (or (not queryp)
116                 (y-or-n-p
117                  (concat "Save '" (cdr (assq 'filename disposition)) "' ")))
118             (mm-save-part p))))
119    mm-handle))
120
121 (defun notmuch-documentation-first-line (symbol)
122   "Return the first line of the documentation string for SYMBOL."
123   (let ((doc (documentation symbol)))
124     (if doc
125         (with-temp-buffer
126           (insert (documentation symbol t))
127           (goto-char (point-min))
128           (let ((beg (point)))
129             (end-of-line)
130             (buffer-substring beg (point))))
131       "")))
132
133 (defun notmuch-prefix-key-description (key)
134   "Given a prefix key code, return a human-readable string representation.
135
136 This is basically just `format-kbd-macro' but we also convert ESC to M-."
137   (let ((desc (format-kbd-macro (vector key))))
138     (if (string= desc "ESC")
139         "M-"
140       (concat desc " "))))
141
142 ;; I would think that emacs would have code handy for walking a keymap
143 ;; and generating strings for each key, and I would prefer to just call
144 ;; that. But I couldn't find any (could be all implemented in C I
145 ;; suppose), so I wrote my own here.
146 (defun notmuch-substitute-one-command-key-with-prefix (prefix binding)
147   "For a key binding, return a string showing a human-readable
148 representation of the prefixed key as well as the first line of
149 documentation from the bound function.
150
151 For a mouse binding, return nil."
152   (let ((key (car binding))
153         (action (cdr binding)))
154     (if (mouse-event-p key)
155         nil
156       (if (keymapp action)
157           (let ((substitute (apply-partially 'notmuch-substitute-one-command-key-with-prefix (notmuch-prefix-key-description key)))
158                 (as-list))
159             (map-keymap (lambda (a b)
160                           (push (cons a b) as-list))
161                         action)
162             (mapconcat substitute as-list "\n"))
163         (concat prefix (format-kbd-macro (vector key))
164                 "\t"
165                 (notmuch-documentation-first-line action))))))
166
167 (defun notmuch-substitute-command-keys-one (key)
168   ;; A `keymap' key indicates inheritance from a parent keymap - the
169   ;; inherited mappings follow, so there is nothing to print for
170   ;; `keymap' itself.
171   (when (not (eq key 'keymap))
172     (notmuch-substitute-one-command-key-with-prefix nil key)))
173
174 (defun notmuch-substitute-command-keys (doc)
175   "Like `substitute-command-keys' but with documentation, not function names."
176   (let ((beg 0))
177     (while (string-match "\\\\{\\([^}[:space:]]*\\)}" doc beg)
178       (let* ((keymap-name (substring doc (match-beginning 1) (match-end 1)))
179              (keymap (symbol-value (intern keymap-name))))
180         (setq doc (replace-match
181                    (mapconcat #'notmuch-substitute-command-keys-one
182                               (cdr keymap) "\n")
183                    1 1 doc)))
184       (setq beg (match-end 0)))
185     doc))
186
187 (defun notmuch-help ()
188   "Display help for the current notmuch mode."
189   (interactive)
190   (let* ((mode major-mode)
191          (doc (substitute-command-keys (notmuch-substitute-command-keys (documentation mode t)))))
192     (with-current-buffer (generate-new-buffer "*notmuch-help*")
193       (insert doc)
194       (goto-char (point-min))
195       (set-buffer-modified-p nil)
196       (view-buffer (current-buffer) 'kill-buffer-if-not-modified))))
197
198 (require 'hl-line)
199
200 (defun notmuch-hl-line-mode ()
201   (prog1 (hl-line-mode)
202     (when hl-line-overlay
203       (overlay-put hl-line-overlay 'priority 1))))
204
205 (defcustom notmuch-search-hook '(notmuch-hl-line-mode)
206   "List of functions to call when notmuch displays the search results."
207   :type 'hook
208   :options '(notmuch-hl-line-mode)
209   :group 'notmuch-search
210   :group 'notmuch-hooks)
211
212 (defvar notmuch-search-mode-map
213   (let ((map (make-sparse-keymap)))
214     (define-key map "?" 'notmuch-help)
215     (define-key map "q" 'notmuch-search-quit)
216     (define-key map "x" 'notmuch-search-quit)
217     (define-key map (kbd "<DEL>") 'notmuch-search-scroll-down)
218     (define-key map "b" 'notmuch-search-scroll-down)
219     (define-key map " " 'notmuch-search-scroll-up)
220     (define-key map "<" 'notmuch-search-first-thread)
221     (define-key map ">" 'notmuch-search-last-thread)
222     (define-key map "p" 'notmuch-search-previous-thread)
223     (define-key map "n" 'notmuch-search-next-thread)
224     (define-key map "r" 'notmuch-search-reply-to-thread-sender)
225     (define-key map "R" 'notmuch-search-reply-to-thread)
226     (define-key map "m" 'notmuch-mua-new-mail)
227     (define-key map "s" 'notmuch-search)
228     (define-key map "o" 'notmuch-search-toggle-order)
229     (define-key map "c" 'notmuch-search-stash-map)
230     (define-key map "=" 'notmuch-search-refresh-view)
231     (define-key map "G" 'notmuch-search-poll-and-refresh-view)
232     (define-key map "t" 'notmuch-search-filter-by-tag)
233     (define-key map "f" 'notmuch-search-filter)
234     (define-key map [mouse-1] 'notmuch-search-show-thread)
235     (define-key map "*" 'notmuch-search-tag-all)
236     (define-key map "a" 'notmuch-search-archive-thread)
237     (define-key map "-" 'notmuch-search-remove-tag)
238     (define-key map "+" 'notmuch-search-add-tag)
239     (define-key map (kbd "RET") 'notmuch-search-show-thread)
240     map)
241   "Keymap for \"notmuch search\" buffers.")
242 (fset 'notmuch-search-mode-map notmuch-search-mode-map)
243
244 (defvar notmuch-search-stash-map
245   (let ((map (make-sparse-keymap)))
246     (define-key map "i" 'notmuch-search-stash-thread-id)
247     map)
248   "Submap for stash commands")
249 (fset 'notmuch-search-stash-map notmuch-search-stash-map)
250
251 (defun notmuch-search-stash-thread-id ()
252   "Copy thread ID of current thread to kill-ring."
253   (interactive)
254   (notmuch-common-do-stash (notmuch-search-find-thread-id)))
255
256 (defvar notmuch-search-query-string)
257 (defvar notmuch-search-target-thread)
258 (defvar notmuch-search-target-line)
259 (defvar notmuch-search-continuation)
260
261 (defvar notmuch-search-disjunctive-regexp      "\\<[oO][rR]\\>")
262
263 (defun notmuch-search-quit ()
264   "Exit the search buffer, calling any defined continuation function."
265   (interactive)
266   (let ((continuation notmuch-search-continuation))
267     (notmuch-kill-this-buffer)
268     (when continuation
269       (funcall continuation))))
270
271 (defun notmuch-search-scroll-up ()
272   "Move forward through search results by one window's worth."
273   (interactive)
274   (condition-case nil
275       (scroll-up nil)
276     ((end-of-buffer) (notmuch-search-last-thread))))
277
278 (defun notmuch-search-scroll-down ()
279   "Move backward through the search results by one window's worth."
280   (interactive)
281   ;; I don't know why scroll-down doesn't signal beginning-of-buffer
282   ;; the way that scroll-up signals end-of-buffer, but c'est la vie.
283   ;;
284   ;; So instead of trapping a signal we instead check whether the
285   ;; window begins on the first line of the buffer and if so, move
286   ;; directly to that position. (We have to count lines since the
287   ;; window-start position is not the same as point-min due to the
288   ;; invisible thread-ID characters on the first line.
289   (if (equal (count-lines (point-min) (window-start)) 0)
290       (goto-char (point-min))
291     (scroll-down nil)))
292
293 (defun notmuch-search-next-thread ()
294   "Select the next thread in the search results."
295   (interactive)
296   (when (notmuch-search-get-result)
297     (goto-char (notmuch-search-result-end))))
298
299 (defun notmuch-search-previous-thread ()
300   "Select the previous thread in the search results."
301   (interactive)
302   (if (notmuch-search-get-result)
303       (unless (bobp)
304         (goto-char (notmuch-search-result-beginning (- (point) 1))))
305     ;; We must be past the end; jump to the last result
306     (notmuch-search-last-thread)))
307
308 (defun notmuch-search-last-thread ()
309   "Select the last thread in the search results."
310   (interactive)
311   (goto-char (point-max))
312   (forward-line -2)
313   (let ((beg (notmuch-search-result-beginning)))
314     (when beg (goto-char beg))))
315
316 (defun notmuch-search-first-thread ()
317   "Select the first thread in the search results."
318   (interactive)
319   (goto-char (point-min)))
320
321 (defface notmuch-message-summary-face
322  '((((class color) (background light)) (:background "#f0f0f0"))
323    (((class color) (background dark)) (:background "#303030")))
324  "Face for the single-line message summary in notmuch-show-mode."
325  :group 'notmuch-show
326  :group 'notmuch-faces)
327
328 (defface notmuch-search-date
329   '((t :inherit default))
330   "Face used in search mode for dates."
331   :group 'notmuch-search
332   :group 'notmuch-faces)
333
334 (defface notmuch-search-count
335   '((t :inherit default))
336   "Face used in search mode for the count matching the query."
337   :group 'notmuch-search
338   :group 'notmuch-faces)
339
340 (defface notmuch-search-subject
341   '((t :inherit default))
342   "Face used in search mode for subjects."
343   :group 'notmuch-search
344   :group 'notmuch-faces)
345
346 (defface notmuch-search-matching-authors
347   '((t :inherit default))
348   "Face used in search mode for authors matching the query."
349   :group 'notmuch-search
350   :group 'notmuch-faces)
351
352 (defface notmuch-search-non-matching-authors
353   '((((class color)
354       (background dark))
355      (:foreground "grey30"))
356     (((class color)
357       (background light))
358      (:foreground "grey60"))
359     (t
360      (:italic t)))
361   "Face used in search mode for authors not matching the query."
362   :group 'notmuch-search
363   :group 'notmuch-faces)
364
365 (defface notmuch-tag-face
366   '((((class color)
367       (background dark))
368      (:foreground "OliveDrab1"))
369     (((class color)
370       (background light))
371      (:foreground "navy blue" :bold t))
372     (t
373      (:bold t)))
374   "Face used in search mode face for tags."
375   :group 'notmuch-search
376   :group 'notmuch-faces)
377
378 (defun notmuch-search-mode ()
379   "Major mode displaying results of a notmuch search.
380
381 This buffer contains the results of a \"notmuch search\" of your
382 email archives. Each line in the buffer represents a single
383 thread giving a summary of the thread (a relative date, the
384 number of matched messages and total messages in the thread,
385 participants in the thread, a representative subject line, and
386 any tags).
387
388 Pressing \\[notmuch-search-show-thread] on any line displays that thread. The '\\[notmuch-search-add-tag]' and '\\[notmuch-search-remove-tag]'
389 keys can be used to add or remove tags from a thread. The '\\[notmuch-search-archive-thread]' key
390 is a convenience for archiving a thread (removing the \"inbox\"
391 tag). The '\\[notmuch-search-tag-all]' key can be used to add and/or remove tags from all
392 messages (as opposed to threads) that match the current query.  Use with caution, as this
393 will also tag matching messages that arrived *after* constructing the buffer.
394
395 Other useful commands are '\\[notmuch-search-filter]' for filtering the current search
396 based on an additional query string, '\\[notmuch-search-filter-by-tag]' for filtering to include
397 only messages with a given tag, and '\\[notmuch-search]' to execute a new, global
398 search.
399
400 Complete list of currently available key bindings:
401
402 \\{notmuch-search-mode-map}"
403   (interactive)
404   (kill-all-local-variables)
405   (make-local-variable 'notmuch-search-query-string)
406   (make-local-variable 'notmuch-search-oldest-first)
407   (make-local-variable 'notmuch-search-target-thread)
408   (make-local-variable 'notmuch-search-target-line)
409   (set (make-local-variable 'notmuch-search-continuation) nil)
410   (set (make-local-variable 'scroll-preserve-screen-position) t)
411   (add-to-invisibility-spec (cons 'ellipsis t))
412   (use-local-map notmuch-search-mode-map)
413   (setq truncate-lines t)
414   (setq major-mode 'notmuch-search-mode
415         mode-name "notmuch-search")
416   (setq buffer-read-only t))
417
418 (defun notmuch-search-get-result (&optional pos)
419   "Return the result object for the thread at POS (or point).
420
421 If there is no thread at POS (or point), returns nil."
422   (get-text-property (or pos (point)) 'notmuch-search-result))
423
424 (defun notmuch-search-result-beginning (&optional pos)
425   "Return the point at the beginning of the thread at POS (or point).
426
427 If there is no thread at POS (or point), returns nil."
428   (when (notmuch-search-get-result pos)
429     ;; We pass 1+point because previous-single-property-change starts
430     ;; searching one before the position we give it.
431     (previous-single-property-change (1+ (or pos (point)))
432                                      'notmuch-search-result nil (point-min))))
433
434 (defun notmuch-search-result-end (&optional pos)
435   "Return the point at the end of the thread at POS (or point).
436
437 The returned point will be just after the newline character that
438 ends the result line.  If there is no thread at POS (or point),
439 returns nil"
440   (when (notmuch-search-get-result pos)
441     (next-single-property-change (or pos (point)) 'notmuch-search-result
442                                  nil (point-max))))
443
444 (defun notmuch-search-foreach-result (beg end function)
445   "Invoke FUNCTION for each result between BEG and END.
446
447 FUNCTION should take one argument.  It will be applied to the
448 character position of the beginning of each result that overlaps
449 the region between points BEG and END.  As a special case, if (=
450 BEG END), FUNCTION will be applied to the result containing point
451 BEG."
452
453   (lexical-let ((pos (notmuch-search-result-beginning beg))
454                 ;; End must be a marker in case function changes the
455                 ;; text.
456                 (end (copy-marker end))
457                 ;; Make sure we examine at least one result, even if
458                 ;; (= beg end).
459                 (first t))
460     ;; We have to be careful if the region extends beyond the results.
461     ;; In this case, pos could be null or there could be no result at
462     ;; pos.
463     (while (and pos (or (< pos end) first))
464       (when (notmuch-search-get-result pos)
465         (funcall function pos))
466       (setq pos (notmuch-search-result-end pos)
467             first nil))))
468 ;; Unindent the function argument of notmuch-search-foreach-result so
469 ;; the indentation of callers doesn't get out of hand.
470 (put 'notmuch-search-foreach-result 'lisp-indent-function 2)
471
472 (defun notmuch-search-properties-in-region (property beg end)
473   (let (output)
474     (notmuch-search-foreach-result beg end
475       (lambda (pos)
476         (push (plist-get (notmuch-search-get-result pos) property) output)))
477     output))
478
479 (defun notmuch-search-find-thread-id (&optional bare)
480   "Return the thread for the current thread
481
482 If BARE is set then do not prefix with \"thread:\""
483   (let ((thread (plist-get (notmuch-search-get-result) :thread)))
484     (when thread (concat (unless bare "thread:") thread))))
485
486 (defun notmuch-search-find-thread-id-region (beg end)
487   "Return a list of threads for the current region"
488   (mapcar (lambda (thread) (concat "thread:" thread))
489           (notmuch-search-properties-in-region :thread beg end)))
490
491 (defun notmuch-search-find-thread-id-region-search (beg end)
492   "Return a search string for threads for the current region"
493   (mapconcat 'identity (notmuch-search-find-thread-id-region beg end) " or "))
494
495 (defun notmuch-search-find-authors ()
496   "Return the authors for the current thread"
497   (plist-get (notmuch-search-get-result) :authors))
498
499 (defun notmuch-search-find-authors-region (beg end)
500   "Return a list of authors for the current region"
501   (notmuch-search-properties-in-region :authors beg end))
502
503 (defun notmuch-search-find-subject ()
504   "Return the subject for the current thread"
505   (plist-get (notmuch-search-get-result) :subject))
506
507 (defun notmuch-search-find-subject-region (beg end)
508   "Return a list of authors for the current region"
509   (notmuch-search-properties-in-region :subject beg end))
510
511 (defun notmuch-search-show-thread ()
512   "Display the currently selected thread."
513   (interactive)
514   (let ((thread-id (notmuch-search-find-thread-id))
515         (subject (notmuch-search-find-subject)))
516     (if (> (length thread-id) 0)
517         (notmuch-show thread-id
518                       (current-buffer)
519                       notmuch-search-query-string
520                       ;; Name the buffer based on the subject.
521                       (concat "*" (truncate-string-to-width subject 30 nil nil t) "*"))
522       (message "End of search results."))))
523
524 (defun notmuch-search-reply-to-thread (&optional prompt-for-sender)
525   "Begin composing a reply-all to the entire current thread in a new buffer."
526   (interactive "P")
527   (let ((message-id (notmuch-search-find-thread-id)))
528     (notmuch-mua-new-reply message-id prompt-for-sender t)))
529
530 (defun notmuch-search-reply-to-thread-sender (&optional prompt-for-sender)
531   "Begin composing a reply to the entire current thread in a new buffer."
532   (interactive "P")
533   (let ((message-id (notmuch-search-find-thread-id)))
534     (notmuch-mua-new-reply message-id prompt-for-sender nil)))
535
536 (defun notmuch-call-notmuch-process (&rest args)
537   "Synchronously invoke \"notmuch\" with the given list of arguments.
538
539 If notmuch exits with a non-zero status, output from the process
540 will appear in a buffer named \"*Notmuch errors*\" and an error
541 will be signaled."
542   (with-temp-buffer
543     (let ((status (apply #'call-process notmuch-command nil t nil args)))
544       (notmuch-check-exit-status status (cons notmuch-command args)
545                                  (buffer-string)))))
546
547 (defun notmuch-search-set-tags (tags &optional pos)
548   (let ((new-result (plist-put (notmuch-search-get-result pos) :tags tags)))
549     (notmuch-search-update-result new-result pos)))
550
551 (defun notmuch-search-get-tags (&optional pos)
552   (plist-get (notmuch-search-get-result pos) :tags))
553
554 (defun notmuch-search-get-tags-region (beg end)
555   (let (output)
556     (notmuch-search-foreach-result beg end
557       (lambda (pos)
558         (setq output (append output (notmuch-search-get-tags pos)))))
559     output))
560
561 (defun notmuch-search-tag-region (beg end &optional tag-changes)
562   "Change tags for threads in the given region."
563   (let ((search-string (notmuch-search-find-thread-id-region-search beg end)))
564     (setq tag-changes (funcall 'notmuch-tag search-string tag-changes))
565     (notmuch-search-foreach-result beg end
566       (lambda (pos)
567         (notmuch-search-set-tags
568          (notmuch-update-tags (notmuch-search-get-tags pos) tag-changes)
569          pos)))))
570
571 (defun notmuch-search-tag (&optional tag-changes)
572   "Change tags for the currently selected thread or region.
573
574 See `notmuch-tag' for information on the format of TAG-CHANGES."
575   (interactive)
576   (let* ((beg (if (region-active-p) (region-beginning) (point)))
577          (end (if (region-active-p) (region-end) (point))))
578     (funcall 'notmuch-search-tag-region beg end tag-changes)))
579
580 (defun notmuch-search-add-tag ()
581   "Same as `notmuch-search-tag' but sets initial input to '+'."
582   (interactive)
583   (notmuch-search-tag "+"))
584
585 (defun notmuch-search-remove-tag ()
586   "Same as `notmuch-search-tag' but sets initial input to '-'."
587   (interactive)
588   (notmuch-search-tag "-"))
589
590 (defun notmuch-search-archive-thread (&optional unarchive)
591   "Archive the currently selected thread.
592
593 Archive each message in the currently selected thread by applying
594 the tag changes in `notmuch-archive-tags' to each (remove the
595 \"inbox\" tag by default). If a prefix argument is given, the
596 messages will be \"unarchived\" (i.e. the tag changes in
597 `notmuch-archive-tags' will be reversed).
598
599 This function advances the next thread when finished."
600   (interactive "P")
601   (when notmuch-archive-tags
602     (notmuch-search-tag
603      (notmuch-tag-change-list notmuch-archive-tags unarchive)))
604   (notmuch-search-next-thread))
605
606 (defun notmuch-search-update-result (result &optional pos)
607   "Replace the result object of the thread at POS (or point) by
608 RESULT and redraw it.
609
610 This will keep point in a reasonable location.  However, if there
611 are enclosing save-excursions and the saved point is in the
612 result being updated, the point will be restored to the beginning
613 of the result."
614   (let ((start (notmuch-search-result-beginning pos))
615         (end (notmuch-search-result-end pos))
616         (init-point (point))
617         (inhibit-read-only t))
618     ;; Delete the current thread
619     (delete-region start end)
620     ;; Insert the updated thread
621     (notmuch-search-show-result result start)
622     ;; If point was inside the old result, make an educated guess
623     ;; about where to place it now.  Unfortunately, this won't work
624     ;; with save-excursion (or any other markers that would be nice to
625     ;; preserve, such as the window start), but there's nothing we can
626     ;; do about that without a way to retrieve markers in a region.
627     (when (and (>= init-point start) (<= init-point end))
628       (let* ((new-end (notmuch-search-result-end start))
629              (new-point (if (= init-point end)
630                             new-end
631                           (min init-point (- new-end 1)))))
632         (goto-char new-point)))))
633
634 (defun notmuch-search-process-sentinel (proc msg)
635   "Add a message to let user know when \"notmuch search\" exits"
636   (let ((buffer (process-buffer proc))
637         (status (process-status proc))
638         (exit-status (process-exit-status proc))
639         (never-found-target-thread nil))
640     (when (memq status '(exit signal))
641       (catch 'return
642         (kill-buffer (process-get proc 'parse-buf))
643         (if (buffer-live-p buffer)
644             (with-current-buffer buffer
645               (save-excursion
646                 (let ((inhibit-read-only t)
647                       (atbob (bobp)))
648                   (goto-char (point-max))
649                   (if (eq status 'signal)
650                       (insert "Incomplete search results (search process was killed).\n"))
651                   (when (eq status 'exit)
652                     (insert "End of search results.\n")
653                     (condition-case nil
654                         (notmuch-check-async-exit-status proc msg)
655                       ;; Suppress the error signal since strange
656                       ;; things happen if a sentinel signals.
657                       (error (throw 'return nil)))
658                     (if (and atbob
659                              (not (string= notmuch-search-target-thread "found")))
660                         (set 'never-found-target-thread t)))))
661               (when (and never-found-target-thread
662                        notmuch-search-target-line)
663                   (goto-char (point-min))
664                   (forward-line (1- notmuch-search-target-line)))))))))
665
666 (defcustom notmuch-search-line-faces '(("unread" :weight bold)
667                                        ("flagged" :foreground "blue"))
668   "Tag/face mapping for line highlighting in notmuch-search.
669
670 Here is an example of how to color search results based on tags.
671  (the following text would be placed in your ~/.emacs file):
672
673  (setq notmuch-search-line-faces '((\"deleted\" . (:foreground \"red\"
674                                                   :background \"blue\"))
675                                    (\"unread\" . (:foreground \"green\"))))
676
677 The attributes defined for matching tags are merged, with later
678 attributes overriding earlier. A message having both \"deleted\"
679 and \"unread\" tags with the above settings would have a green
680 foreground and blue background."
681   :type '(alist :key-type (string) :value-type (custom-face-edit))
682   :group 'notmuch-search
683   :group 'notmuch-faces)
684
685 (defun notmuch-search-color-line (start end line-tag-list)
686   "Colorize lines in `notmuch-show' based on tags."
687   (mapc (lambda (elem)
688           (let ((tag (car elem))
689                 (attributes (cdr elem)))
690             (when (member tag line-tag-list)
691               (notmuch-combine-face-text-property start end attributes))))
692         ;; Reverse the list so earlier entries take precedence
693         (reverse notmuch-search-line-faces)))
694
695 (defun notmuch-search-author-propertize (authors)
696   "Split `authors' into matching and non-matching authors and
697 propertize appropriately. If no boundary between authors and
698 non-authors is found, assume that all of the authors match."
699   (if (string-match "\\(.*\\)|\\(.*\\)" authors)
700       (concat (propertize (concat (match-string 1 authors) ",")
701                           'face 'notmuch-search-matching-authors)
702               (propertize (match-string 2 authors)
703                           'face 'notmuch-search-non-matching-authors))
704     (propertize authors 'face 'notmuch-search-matching-authors)))
705
706 (defun notmuch-search-insert-authors (format-string authors)
707   ;; Save the match data to avoid interfering with
708   ;; `notmuch-search-process-filter'.
709   (save-match-data
710     (let* ((formatted-authors (format format-string authors))
711            (formatted-sample (format format-string ""))
712            (visible-string formatted-authors)
713            (invisible-string "")
714            (padding ""))
715
716       ;; Truncate the author string to fit the specification.
717       (if (> (length formatted-authors)
718              (length formatted-sample))
719           (let ((visible-length (- (length formatted-sample)
720                                    (length "... "))))
721             ;; Truncate the visible string according to the width of
722             ;; the display string.
723             (setq visible-string (substring formatted-authors 0 visible-length)
724                   invisible-string (substring formatted-authors visible-length))
725             ;; If possible, truncate the visible string at a natural
726             ;; break (comma or pipe), as incremental search doesn't
727             ;; match across the visible/invisible border.
728             (when (string-match "\\(.*\\)\\([,|] \\)\\([^,|]*\\)" visible-string)
729               ;; Second clause is destructive on `visible-string', so
730               ;; order is important.
731               (setq invisible-string (concat (match-string 3 visible-string)
732                                              invisible-string)
733                     visible-string (concat (match-string 1 visible-string)
734                                            (match-string 2 visible-string))))
735             ;; `visible-string' may be shorter than the space allowed
736             ;; by `format-string'. If so we must insert some padding
737             ;; after `invisible-string'.
738             (setq padding (make-string (- (length formatted-sample)
739                                           (length visible-string)
740                                           (length "..."))
741                                        ? ))))
742
743       ;; Use different faces to show matching and non-matching authors.
744       (if (string-match "\\(.*\\)|\\(.*\\)" visible-string)
745           ;; The visible string contains both matching and
746           ;; non-matching authors.
747           (setq visible-string (notmuch-search-author-propertize visible-string)
748                 ;; The invisible string must contain only non-matching
749                 ;; authors, as the visible-string contains both.
750                 invisible-string (propertize invisible-string
751                                              'face 'notmuch-search-non-matching-authors))
752         ;; The visible string contains only matching authors.
753         (setq visible-string (propertize visible-string
754                                          'face 'notmuch-search-matching-authors)
755               ;; The invisible string may contain both matching and
756               ;; non-matching authors.
757               invisible-string (notmuch-search-author-propertize invisible-string)))
758
759       ;; If there is any invisible text, add it as a tooltip to the
760       ;; visible text.
761       (when (not (string= invisible-string ""))
762         (setq visible-string (propertize visible-string 'help-echo (concat "..." invisible-string))))
763
764       ;; Insert the visible and, if present, invisible author strings.
765       (insert visible-string)
766       (when (not (string= invisible-string ""))
767         (let ((start (point))
768               overlay)
769           (insert invisible-string)
770           (setq overlay (make-overlay start (point)))
771           (overlay-put overlay 'invisible 'ellipsis)
772           (overlay-put overlay 'isearch-open-invisible #'delete-overlay)))
773       (insert padding))))
774
775 (defun notmuch-search-insert-field (field format-string result)
776   (cond
777    ((string-equal field "date")
778     (insert (propertize (format format-string (plist-get result :date_relative))
779                         'face 'notmuch-search-date)))
780    ((string-equal field "count")
781     (insert (propertize (format format-string
782                                 (format "[%s/%s]" (plist-get result :matched)
783                                         (plist-get result :total)))
784                         'face 'notmuch-search-count)))
785    ((string-equal field "subject")
786     (insert (propertize (format format-string (plist-get result :subject))
787                         'face 'notmuch-search-subject)))
788
789    ((string-equal field "authors")
790     (notmuch-search-insert-authors format-string (plist-get result :authors)))
791
792    ((string-equal field "tags")
793     (let ((tags-str (mapconcat 'identity (plist-get result :tags) " ")))
794       (insert (propertize (format format-string tags-str)
795                           'face 'notmuch-tag-face))))))
796
797 (defun notmuch-search-show-result (result &optional pos)
798   "Insert RESULT at POS or the end of the buffer if POS is null."
799   ;; Ignore excluded matches
800   (unless (= (plist-get result :matched) 0)
801     (let ((beg (or pos (point-max))))
802       (save-excursion
803         (goto-char beg)
804         (dolist (spec notmuch-search-result-format)
805           (notmuch-search-insert-field (car spec) (cdr spec) result))
806         (insert "\n")
807         (notmuch-search-color-line beg (point) (plist-get result :tags))
808         (put-text-property beg (point) 'notmuch-search-result result))
809       (when (string= (plist-get result :thread) notmuch-search-target-thread)
810         (setq notmuch-search-target-thread "found")
811         (goto-char beg)))))
812
813 (defun notmuch-search-show-error (string &rest objects)
814   (save-excursion
815     (goto-char (point-max))
816     (insert "Error: Unexpected output from notmuch search:\n")
817     (insert (apply #'format string objects))
818     (insert "\n")))
819
820 (defun notmuch-search-process-filter (proc string)
821   "Process and filter the output of \"notmuch search\""
822   (let ((results-buf (process-buffer proc))
823         (parse-buf (process-get proc 'parse-buf))
824         (inhibit-read-only t)
825         done)
826     (if (not (buffer-live-p results-buf))
827         (delete-process proc)
828       (with-current-buffer parse-buf
829         ;; Insert new data
830         (save-excursion
831           (goto-char (point-max))
832           (insert string))
833         (notmuch-json-parse-partial-list 'notmuch-search-show-result
834                                          'notmuch-search-show-error
835                                          results-buf)))))
836
837 (defun notmuch-search-tag-all (&optional tag-changes)
838   "Add/remove tags from all messages in current search buffer.
839
840 See `notmuch-tag' for information on the format of TAG-CHANGES."
841   (interactive)
842   (apply 'notmuch-tag notmuch-search-query-string tag-changes))
843
844 (defun notmuch-search-buffer-title (query)
845   "Returns the title for a buffer with notmuch search results."
846   (let* ((saved-search
847           (let (longest
848                 (longest-length 0))
849             (loop for tuple in notmuch-saved-searches
850                   if (let ((quoted-query (regexp-quote (cdr tuple))))
851                        (and (string-match (concat "^" quoted-query) query)
852                             (> (length (match-string 0 query))
853                                longest-length)))
854                   do (setq longest tuple))
855             longest))
856          (saved-search-name (car saved-search))
857          (saved-search-query (cdr saved-search)))
858     (cond ((and saved-search (equal saved-search-query query))
859            ;; Query is the same as saved search (ignoring case)
860            (concat "*notmuch-saved-search-" saved-search-name "*"))
861           (saved-search
862            (concat "*notmuch-search-"
863                    (replace-regexp-in-string (concat "^" (regexp-quote saved-search-query))
864                                              (concat "[ " saved-search-name " ]")
865                                              query)
866                    "*"))
867           (t
868            (concat "*notmuch-search-" query "*"))
869           )))
870
871 (defun notmuch-read-query (prompt)
872   "Read a notmuch-query from the minibuffer with completion.
873
874 PROMPT is the string to prompt with."
875   (lexical-let
876       ((completions
877         (append (list "folder:" "thread:" "id:" "date:" "from:" "to:"
878                       "subject:" "attachment:")
879                 (mapcar (lambda (tag)
880                           (concat "tag:" (notmuch-escape-boolean-term tag)))
881                         (process-lines notmuch-command "search" "--output=tags" "*")))))
882     (let ((keymap (copy-keymap minibuffer-local-map))
883           (minibuffer-completion-table
884            (completion-table-dynamic
885             (lambda (string)
886               ;; generate a list of possible completions for the current input
887               (cond
888                ;; this ugly regexp is used to get the last word of the input
889                ;; possibly preceded by a '('
890                ((string-match "\\(^\\|.* (?\\)\\([^ ]*\\)$" string)
891                 (mapcar (lambda (compl)
892                           (concat (match-string-no-properties 1 string) compl))
893                         (all-completions (match-string-no-properties 2 string)
894                                          completions)))
895                (t (list string)))))))
896       ;; this was simpler than convincing completing-read to accept spaces:
897       (define-key keymap (kbd "TAB") 'minibuffer-complete)
898       (let ((history-delete-duplicates t))
899         (read-from-minibuffer prompt nil keymap nil
900                               'notmuch-search-history nil nil)))))
901
902 ;;;###autoload
903 (defun notmuch-search (&optional query oldest-first target-thread target-line continuation)
904   "Run \"notmuch search\" with the given `query' and display results.
905
906 If `query' is nil, it is read interactively from the minibuffer.
907 Other optional parameters are used as follows:
908
909   oldest-first: A Boolean controlling the sort order of returned threads
910   target-thread: A thread ID (without the thread: prefix) that will be made
911                  current if it appears in the search results.
912   target-line: The line number to move to if the target thread does not
913                appear in the search results."
914   (interactive)
915   (if (null query)
916       (setq query (notmuch-read-query "Notmuch search: ")))
917   (let ((buffer (get-buffer-create (notmuch-search-buffer-title query))))
918     (switch-to-buffer buffer)
919     (notmuch-search-mode)
920     ;; Don't track undo information for this buffer
921     (set 'buffer-undo-list t)
922     (set 'notmuch-search-query-string query)
923     (set 'notmuch-search-oldest-first oldest-first)
924     (set 'notmuch-search-target-thread target-thread)
925     (set 'notmuch-search-target-line target-line)
926     (set 'notmuch-search-continuation continuation)
927     (let ((proc (get-buffer-process (current-buffer)))
928           (inhibit-read-only t))
929       (if proc
930           (error "notmuch search process already running for query `%s'" query)
931         )
932       (erase-buffer)
933       (goto-char (point-min))
934       (save-excursion
935         (let ((proc (start-process
936                      "notmuch-search" buffer
937                      notmuch-command "search"
938                      "--format=json"
939                      (if oldest-first
940                          "--sort=oldest-first"
941                        "--sort=newest-first")
942                      query))
943               ;; Use a scratch buffer to accumulate partial output.
944               ;; This buffer will be killed by the sentinel, which
945               ;; should be called no matter how the process dies.
946               (parse-buf (generate-new-buffer " *notmuch search parse*")))
947           (process-put proc 'parse-buf parse-buf)
948           (set-process-sentinel proc 'notmuch-search-process-sentinel)
949           (set-process-filter proc 'notmuch-search-process-filter)
950           (set-process-query-on-exit-flag proc nil))))
951     (run-hooks 'notmuch-search-hook)))
952
953 (defun notmuch-search-refresh-view ()
954   "Refresh the current view.
955
956 Kills the current buffer and runs a new search with the same
957 query string as the current search. If the current thread is in
958 the new search results, then point will be placed on the same
959 thread. Otherwise, point will be moved to attempt to be in the
960 same relative position within the new buffer."
961   (interactive)
962   (let ((target-line (line-number-at-pos))
963         (oldest-first notmuch-search-oldest-first)
964         (target-thread (notmuch-search-find-thread-id 'bare))
965         (query notmuch-search-query-string)
966         (continuation notmuch-search-continuation))
967     (notmuch-kill-this-buffer)
968     (notmuch-search query oldest-first target-thread target-line continuation)
969     (goto-char (point-min))))
970
971 (defcustom notmuch-poll-script nil
972   "An external script to incorporate new mail into the notmuch database.
973
974 This variable controls the action invoked by
975 `notmuch-search-poll-and-refresh-view' and
976 `notmuch-hello-poll-and-update' (each have a default keybinding
977 of 'G') to incorporate new mail into the notmuch database.
978
979 If set to nil (the default), new mail is processed by invoking
980 \"notmuch new\". Otherwise, this should be set to a string that
981 gives the name of an external script that processes new mail. If
982 set to the empty string, no command will be run.
983
984 The external script could do any of the following depending on
985 the user's needs:
986
987 1. Invoke a program to transfer mail to the local mail store
988 2. Invoke \"notmuch new\" to incorporate the new mail
989 3. Invoke one or more \"notmuch tag\" commands to classify the mail
990
991 Note that the recommended way of achieving the same is using
992 \"notmuch new\" hooks."
993   :type '(choice (const :tag "notmuch new" nil)
994                  (const :tag "Disabled" "")
995                  (string :tag "Custom script"))
996   :group 'notmuch-external)
997
998 (defun notmuch-poll ()
999   "Run \"notmuch new\" or an external script to import mail.
1000
1001 Invokes `notmuch-poll-script', \"notmuch new\", or does nothing
1002 depending on the value of `notmuch-poll-script'."
1003   (interactive)
1004   (if (stringp notmuch-poll-script)
1005       (unless (string= notmuch-poll-script "")
1006         (call-process notmuch-poll-script nil nil))
1007     (call-process notmuch-command nil nil nil "new")))
1008
1009 (defun notmuch-search-poll-and-refresh-view ()
1010   "Invoke `notmuch-poll' to import mail, then refresh the current view."
1011   (interactive)
1012   (notmuch-poll)
1013   (notmuch-search-refresh-view))
1014
1015 (defun notmuch-search-toggle-order ()
1016   "Toggle the current search order.
1017
1018 By default, the \"inbox\" view created by `notmuch' is displayed
1019 in chronological order (oldest thread at the beginning of the
1020 buffer), while any global searches created by `notmuch-search'
1021 are displayed in reverse-chronological order (newest thread at
1022 the beginning of the buffer).
1023
1024 This command toggles the sort order for the current search.
1025
1026 Note that any filtered searches created by
1027 `notmuch-search-filter' retain the search order of the parent
1028 search."
1029   (interactive)
1030   (set 'notmuch-search-oldest-first (not notmuch-search-oldest-first))
1031   (notmuch-search-refresh-view))
1032
1033 (defun notmuch-search-filter (query)
1034   "Filter the current search results based on an additional query string.
1035
1036 Runs a new search matching only messages that match both the
1037 current search results AND the additional query string provided."
1038   (interactive (list (notmuch-read-query "Filter search: ")))
1039   (let ((grouped-query (if (string-match-p notmuch-search-disjunctive-regexp query)
1040                            (concat "( " query " )")
1041                          query)))
1042     (notmuch-search (if (string= notmuch-search-query-string "*")
1043                         grouped-query
1044                       (concat notmuch-search-query-string " and " grouped-query)) notmuch-search-oldest-first)))
1045
1046 (defun notmuch-search-filter-by-tag (tag)
1047   "Filter the current search results based on a single tag.
1048
1049 Runs a new search matching only messages that match both the
1050 current search results AND that are tagged with the given tag."
1051   (interactive
1052    (list (notmuch-select-tag-with-completion "Filter by tag: ")))
1053   (notmuch-search (concat notmuch-search-query-string " and tag:" tag) notmuch-search-oldest-first))
1054
1055 ;;;###autoload
1056 (defun notmuch ()
1057   "Run notmuch and display saved searches, known tags, etc."
1058   (interactive)
1059   (notmuch-hello))
1060
1061 (defun notmuch-interesting-buffer (b)
1062   "Is the current buffer of interest to a notmuch user?"
1063   (with-current-buffer b
1064     (memq major-mode '(notmuch-show-mode
1065                        notmuch-search-mode
1066                        notmuch-hello-mode
1067                        message-mode))))
1068
1069 ;;;###autoload
1070 (defun notmuch-cycle-notmuch-buffers ()
1071   "Cycle through any existing notmuch buffers (search, show or hello).
1072
1073 If the current buffer is the only notmuch buffer, bury it. If no
1074 notmuch buffers exist, run `notmuch'."
1075   (interactive)
1076
1077   (let (start first)
1078     ;; If the current buffer is a notmuch buffer, remember it and then
1079     ;; bury it.
1080     (when (notmuch-interesting-buffer (current-buffer))
1081       (setq start (current-buffer))
1082       (bury-buffer))
1083
1084     ;; Find the first notmuch buffer.
1085     (setq first (loop for buffer in (buffer-list)
1086                      if (notmuch-interesting-buffer buffer)
1087                      return buffer))
1088
1089     (if first
1090         ;; If the first one we found is any other than the starting
1091         ;; buffer, switch to it.
1092         (unless (eq first start)
1093           (switch-to-buffer first))
1094       (notmuch))))
1095
1096 (setq mail-user-agent 'notmuch-user-agent)
1097
1098 (provide 'notmuch)