git.notmuchmail.org Git - notmuch/blob - notmuch.el

   1 ; notmuch.el --- run notmuch within emacs
   2 ;
   3 ; Copyright © Carl Worth
   4 ;
   5 ; This file is part of Notmuch.
   6 ;
   7 ; Notmuch is free software: you can redistribute it and/or modify it
   8 ; under the terms of the GNU General Public License as published by
   9 ; the Free Software Foundation, either version 3 of the License, or
  10 ; (at your option) any later version.
  11 ;
  12 ; Notmuch is distributed in the hope that it will be useful, but
  13 ; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 ; General Public License for more details.
  16 ;
  17 ; You should have received a copy of the GNU General Public License
  18 ; along with Notmuch.  If not, see <http://www.gnu.org/licenses/>.
  19 ;
  20 ; Authors: Carl Worth <cworth@cworth.org>
  21
  22 ; This is an emacs-based interface to the notmuch mail system.
  23 ;
  24 ; You will first need to have the notmuch program installed and have a
  25 ; notmuch database built in order to use this. See
  26 ; http://notmuchmail.org for details.
  27 ;
  28 ; To install this software, copy it to a directory that is on the
  29 ; `load-path' variable within emacs (a good candidate is
  30 ; /usr/local/share/emacs/site-lisp). If you are viewing this from the
  31 ; notmuch source distribution then you can simply run:
  32 ;
  33 ;       sudo make install-emacs
  34 ;
  35 ; to install it.
  36 ;
  37 ; Then, to actually run it, add:
  38 ;
  39 ;       (require 'notmuch)
  40 ;
  41 ; to your ~/.emacs file, and then run "M-x notmuch" from within emacs,
  42 ; or run:
  43 ;
  44 ;       emacs -f notmuch
  45 ;
  46 ; Have fun, and let us know if you have any comment, questions, or
  47 ; kudos: Notmuch list <notmuch@notmuchmail.org> (subscription is not
  48 ; required, but is available from http://notmuchmail.org).
  49
  50 (require 'cl)
  51 (require 'mm-view)
  52
  53 (defvar notmuch-show-mode-map
  54   (let ((map (make-sparse-keymap)))
  55     ; I don't actually want all of these toggle commands occupying
  56     ; keybindings. They steal valuable key-binding space, are hard
  57     ; to remember, and act globally rather than locally.
  58     ;
  59     ; Will be much preferable to switch to direct manipulation for
  60     ; toggling visibility of these components. Probably using
  61     ; overlays-at to query and manipulate the current overlay.
  62     (define-key map "a" 'notmuch-show-archive-thread)
  63     (define-key map "A" 'notmuch-show-mark-read-then-archive-thread)
  64     (define-key map "b" 'notmuch-show-toggle-body-read-visible)
  65     (define-key map "c" 'notmuch-show-toggle-citations-visible)
  66     (define-key map "h" 'notmuch-show-toggle-headers-visible)
  67     (define-key map "m" 'message-mail)
  68     (define-key map "n" 'notmuch-show-next-message)
  69     (define-key map "N" 'notmuch-show-mark-read-then-next-open-message)
  70     (define-key map "p" 'notmuch-show-previous-message)
  71     (define-key map (kbd "C-n") 'notmuch-show-next-line)
  72     (define-key map (kbd "C-p") 'notmuch-show-previous-line)
  73     (define-key map "q" 'kill-this-buffer)
  74     (define-key map "r" 'notmuch-show-reply)
  75     (define-key map "s" 'notmuch-show-toggle-signatures-visible)
  76     (define-key map "v" 'notmuch-show-view-all-mime-parts)
  77     (define-key map "w" 'notmuch-show-view-raw-message)
  78     (define-key map "x" 'kill-this-buffer)
  79     (define-key map "+" 'notmuch-show-add-tag)
  80     (define-key map "-" 'notmuch-show-remove-tag)
  81     (define-key map (kbd "DEL") 'notmuch-show-rewind)
  82     (define-key map " " 'notmuch-show-advance-marking-read-and-archiving)
  83     (define-key map "|" 'notmuch-show-pipe-message)
  84     (define-key map "?" 'describe-mode)
  85     map)
  86   "Keymap for \"notmuch show\" buffers.")
  87 (fset 'notmuch-show-mode-map notmuch-show-mode-map)
  88
  89 (defvar notmuch-show-signature-regexp "\\(-- ?\\|_+\\)$"
  90   "Pattern to match a line that separates content from signature.
  91
  92 The regexp can (and should) include $ to match the end of the
  93 line, but should not include ^ to match the beginning of the
  94 line. This is because notmuch may have inserted additional space
  95 for indentation at the beginning of the line. But notmuch will
  96 move past the indentation when testing this pattern, (so that the
  97 pattern can still test against the entire line).")
  98
  99 (defvar notmuch-show-signature-lines-max 12
 100   "Maximum length of signature that will be hidden by default.")
 101
 102 (defvar notmuch-command "notmuch"
 103   "Command to run the notmuch binary.")
 104
 105 (defvar notmuch-show-message-begin-regexp    "\fmessage{")
 106 (defvar notmuch-show-message-end-regexp      "\fmessage}")
 107 (defvar notmuch-show-header-begin-regexp     "\fheader{")
 108 (defvar notmuch-show-header-end-regexp       "\fheader}")
 109 (defvar notmuch-show-body-begin-regexp       "\fbody{")
 110 (defvar notmuch-show-body-end-regexp         "\fbody}")
 111 (defvar notmuch-show-attachment-begin-regexp "\fattachment{")
 112 (defvar notmuch-show-attachment-end-regexp   "\fattachment}")
 113 (defvar notmuch-show-part-begin-regexp       "\fpart{")
 114 (defvar notmuch-show-part-end-regexp         "\fpart}")
 115 (defvar notmuch-show-marker-regexp "\f\\(message\\|header\\|body\\|attachment\\|part\\)[{}].*$")
 116
 117 (defvar notmuch-show-id-regexp "\\(id:[^ ]*\\)")
 118 (defvar notmuch-show-depth-regexp " depth:\\([0-9]*\\) ")
 119 (defvar notmuch-show-filename-regexp "filename:\\(.*\\)$")
 120 (defvar notmuch-show-tags-regexp "(\\([^)]*\\))$")
 121
 122 (defvar notmuch-show-parent-buffer nil)
 123 (defvar notmuch-show-body-read-visible nil)
 124 (defvar notmuch-show-citations-visible nil)
 125 (defvar notmuch-show-signatures-visible nil)
 126 (defvar notmuch-show-headers-visible nil)
 127
 128 ; XXX: This should be a generic function in emacs somewhere, not here
 129 (defun point-invisible-p ()
 130   "Return whether the character at point is invisible.
 131
 132 Here visibility is determined by `buffer-invisibility-spec' and
 133 the invisible property of any overlays for point. It doesn't have
 134 anything to do with whether point is currently being displayed
 135 within the current window."
 136   (let ((prop (get-char-property (point) 'invisible)))
 137     (if (eq buffer-invisibility-spec t)
 138         prop
 139       (or (memq prop buffer-invisibility-spec)
 140           (assq prop buffer-invisibility-spec)))))
 141
 142 (defun notmuch-show-next-line ()
 143   "Like builtin `next-line' but ensuring we end on a visible character.
 144
 145 By advancing forward until reaching a visible character.
 146
 147 Unlike builtin `next-line' this version accepts no arguments."
 148   (interactive)
 149   (set 'this-command 'next-line)
 150   (call-interactively 'next-line)
 151   (while (point-invisible-p)
 152     (forward-char)))
 153
 154 (defun notmuch-show-previous-line ()
 155   "Like builtin `previous-line' but ensuring we end on a visible character.
 156
 157 By advancing forward until reaching a visible character.
 158
 159 Unlike builtin `next-line' this version accepts no arguments."
 160   (interactive)
 161   (set 'this-command 'previous-line)
 162   (call-interactively 'previous-line)
 163   (while (point-invisible-p)
 164     (forward-char)))
 165
 166 (defun notmuch-show-get-message-id ()
 167   (save-excursion
 168     (beginning-of-line)
 169     (if (not (looking-at notmuch-show-message-begin-regexp))
 170         (re-search-backward notmuch-show-message-begin-regexp))
 171     (re-search-forward notmuch-show-id-regexp)
 172     (buffer-substring (match-beginning 1) (match-end 1))))
 173
 174 (defun notmuch-show-get-filename ()
 175   (save-excursion
 176     (beginning-of-line)
 177     (if (not (looking-at notmuch-show-message-begin-regexp))
 178         (re-search-backward notmuch-show-message-begin-regexp))
 179     (re-search-forward notmuch-show-filename-regexp)
 180     (buffer-substring (match-beginning 1) (match-end 1))))
 181
 182 (defun notmuch-show-set-tags (tags)
 183   (save-excursion
 184     (beginning-of-line)
 185     (if (not (looking-at notmuch-show-message-begin-regexp))
 186         (re-search-backward notmuch-show-message-begin-regexp))
 187     (re-search-forward notmuch-show-tags-regexp)
 188     (let ((inhibit-read-only t)
 189           (beg (match-beginning 1))
 190           (end (match-end 1)))
 191       (delete-region beg end)
 192       (goto-char beg)
 193       (insert (mapconcat 'identity tags " ")))))
 194
 195 (defun notmuch-show-get-tags ()
 196   (save-excursion
 197     (beginning-of-line)
 198     (if (not (looking-at notmuch-show-message-begin-regexp))
 199         (re-search-backward notmuch-show-message-begin-regexp))
 200     (re-search-forward notmuch-show-tags-regexp)
 201     (split-string (buffer-substring (match-beginning 1) (match-end 1)))))
 202
 203 (defun notmuch-show-add-tag (&rest toadd)
 204   "Add a tag to the current message."
 205   (interactive "sTag to add: ")
 206   (apply 'notmuch-call-notmuch-process
 207          (append (cons "tag"
 208                        (mapcar (lambda (s) (concat "+" s)) toadd))
 209                  (cons (notmuch-show-get-message-id) nil)))
 210   (notmuch-show-set-tags (sort (union toadd (notmuch-show-get-tags) :test 'string=) 'string<)))
 211
 212 (defun notmuch-show-remove-tag (&rest toremove)
 213   "Remove a tag from the current message."
 214   (interactive "sTag to remove: ")
 215   (let ((tags (notmuch-show-get-tags)))
 216     (if (intersection tags toremove :test 'string=)
 217         (progn
 218           (apply 'notmuch-call-notmuch-process
 219                  (append (cons "tag"
 220                                (mapcar (lambda (s) (concat "-" s)) toremove))
 221                          (cons (notmuch-show-get-message-id) nil)))
 222           (notmuch-show-set-tags (sort (set-difference tags toremove :test 'string=) 'string<))))))
 223
 224 (defun notmuch-show-archive-thread-maybe-mark-read (markread)
 225   (save-excursion
 226     (goto-char (point-min))
 227     (while (not (eobp))
 228       (if markread
 229           (notmuch-show-remove-tag "unread" "inbox")
 230         (notmuch-show-remove-tag "inbox"))
 231       (if (not (eobp))
 232           (forward-char))
 233       (if (not (re-search-forward notmuch-show-message-begin-regexp nil t))
 234           (goto-char (point-max)))))
 235   (let ((parent-buffer notmuch-show-parent-buffer))
 236     (kill-this-buffer)
 237     (if parent-buffer
 238         (progn
 239           (switch-to-buffer parent-buffer)
 240           (forward-line)
 241           (notmuch-search-show-thread)))))
 242
 243 (defun notmuch-show-mark-read-then-archive-thread ()
 244   "Remove \"unread\" tag from each message, then archive and show next thread.
 245
 246 Archive each message currently shown by removing the \"unread\"
 247 and \"inbox\" tag from each. Then kill this buffer and show the
 248 next thread from the search from which this thread was originally
 249 shown.
 250
 251 Note: This command is safe from any race condition of new messages
 252 being delivered to the same thread. It does not archive the
 253 entire thread, but only the messages shown in the current
 254 buffer."
 255   (interactive)
 256   (notmuch-show-archive-thread-maybe-mark-read t))
 257
 258 (defun notmuch-show-archive-thread ()
 259   "Archive each message in thread, and show next thread from search.
 260
 261 Archive each message currently shown by removing the \"inbox\"
 262 tag from each. Then kill this buffer and show the next thread
 263 from the search from which this thread was originally shown.
 264
 265 Note: This command is safe from any race condition of new messages
 266 being delivered to the same thread. It does not archive the
 267 entire thread, but only the messages shown in the current
 268 buffer."
 269   (interactive)
 270   (notmuch-show-archive-thread-maybe-mark-read nil))
 271
 272 (defun notmuch-show-view-raw-message ()
 273   "View the raw email of the current message."
 274   (interactive)
 275   (view-file (notmuch-show-get-filename)))
 276
 277 (defun notmuch-show-view-all-mime-parts ()
 278   "Use external viewers (according to mailcap) to view all MIME-encoded parts."
 279   (interactive)
 280   (save-excursion
 281     (let ((filename (notmuch-show-get-filename)))
 282       (switch-to-buffer (generate-new-buffer (concat "*notmuch-mime-"
 283                                                      filename
 284                                                      "*")))
 285       (insert-file-contents filename nil nil nil t)
 286       (mm-display-parts (mm-dissect-buffer))
 287       (kill-this-buffer))))
 288
 289 (defun notmuch-reply (query-string)
 290   (switch-to-buffer (generate-new-buffer "notmuch-draft"))
 291   (call-process notmuch-command nil t nil "reply" query-string)
 292   (goto-char (point-min))
 293   (if (re-search-forward "^$" nil t)
 294       (progn
 295         (insert "--text follows this line--")
 296         (forward-line)))
 297   (message-mode))
 298
 299 (defun notmuch-show-reply ()
 300   "Begin composing a reply to the current message in a new buffer."
 301   (interactive)
 302   (let ((message-id (notmuch-show-get-message-id)))
 303     (notmuch-reply message-id)))
 304
 305 (defun notmuch-show-pipe-message (command)
 306   "Pipe the contents of the current message to the given command.
 307
 308 The given command will be executed with the raw contents of the
 309 current email message as stdin. Anything printed by the command
 310 to stdout or stderr will appear in the *Messages* buffer."
 311   (interactive "sPipe message to command: ")
 312   (apply 'start-process-shell-command "notmuch-pipe-command" "*notmuch-pipe*" (split-string (concat command " < " (notmuch-show-get-filename)))))
 313
 314 (defun notmuch-show-move-to-current-message-summary-line ()
 315   "Move to the beginning of the one-line summary of the current message.
 316
 317 This gives us a stable place to move to and work from since the
 318 summary line is always visible. This is important since moving to
 319 an invisible location is unreliable, (the main command loop moves
 320 point either forward or backward to the next visible character
 321 when a command ends with point on an invisible character).
 322
 323 Emits an error if point is not within a valid message, (that is
 324 not pattern of `notmuch-show-message-begin-regexp' could be found
 325 by searching backward)."
 326   (beginning-of-line)
 327   (if (not (looking-at notmuch-show-message-begin-regexp))
 328       (if (re-search-backward notmuch-show-message-begin-regexp nil t)
 329           (forward-line 2)
 330         (error "Not within a valid message."))
 331     (forward-line 2)))
 332
 333 (defun notmuch-show-last-message-p ()
 334   "Predicate testing whether point is within the last message."
 335   (save-window-excursion
 336     (save-excursion
 337       (notmuch-show-move-to-current-message-summary-line)
 338       (not (re-search-forward notmuch-show-message-begin-regexp nil t)))))
 339
 340 (defun notmuch-show-message-unread-p ()
 341   "Preficate testing whether current message is unread."
 342   (member "unread" (notmuch-show-get-tags)))
 343
 344 (defun notmuch-show-next-message ()
 345   "Advance to the beginning of the next message in the buffer.
 346
 347 Moves to the last visible character of the current message if
 348 already on the last message in the buffer."
 349   (interactive)
 350   (notmuch-show-move-to-current-message-summary-line)
 351   (if (re-search-forward notmuch-show-message-begin-regexp nil t)
 352       (notmuch-show-move-to-current-message-summary-line)
 353     (goto-char (- (point-max) 1))
 354     (while (point-invisible-p)
 355       (backward-char)))
 356   (recenter 0))
 357
 358 (defun notmuch-show-find-next-message ()
 359   "Returns the position of the next message in the buffer.
 360
 361 Or the position of the last visible character of the current
 362 message if already within the last message in the buffer."
 363   ; save-excursion doesn't save our window position
 364   ; save-window-excursion doesn't save point
 365   ; Looks like we have to use both.
 366   (save-excursion
 367     (save-window-excursion
 368       (notmuch-show-next-message)
 369       (point))))
 370
 371 (defun notmuch-show-next-unread-message ()
 372   "Advance to the beginning of the next unread message in the buffer.
 373
 374 Moves to the last visible character of the current message if
 375 there are no more unread messages past the current point."
 376   (notmuch-show-next-message)
 377   (while (and (not (notmuch-show-last-message-p))
 378               (not (notmuch-show-message-unread-p)))
 379     (notmuch-show-next-message))
 380   (if (not (notmuch-show-message-unread-p))
 381       (notmuch-show-next-message)))
 382
 383 (defun notmuch-show-next-open-message ()
 384   "Advance to the next message which is not hidden.
 385
 386 If read messages are currently hidden, advance to the next unread
 387 message. Otherwise, advance to the next message."
 388   (if (or (memq 'notmuch-show-body-read buffer-invisibility-spec)
 389           (assq 'notmuch-show-body-read buffer-invisibility-spec))
 390       (notmuch-show-next-unread-message)
 391     (notmuch-show-next-message)))
 392
 393 (defun notmuch-show-previous-message ()
 394   "Backup to the beginning of the previous message in the buffer.
 395
 396 If within a message rather than at the beginning of it, then
 397 simply move to the beginning of the current message."
 398   (interactive)
 399   (let ((start (point)))
 400     (notmuch-show-move-to-current-message-summary-line)
 401     (if (not (< (point) start))
 402         ; Go backward twice to skip the current message's marker
 403         (progn
 404           (re-search-backward notmuch-show-message-begin-regexp nil t)
 405           (re-search-backward notmuch-show-message-begin-regexp nil t)
 406           (notmuch-show-move-to-current-message-summary-line)
 407           ))
 408     (recenter 0)))
 409
 410 (defun notmuch-show-find-previous-message ()
 411   "Returns the position of the previous message in the buffer.
 412
 413 Or the position of the beginning of the current message if point
 414 is originally within the message rather than at the beginning of
 415 it."
 416   ; save-excursion doesn't save our window position
 417   ; save-window-excursion doesn't save point
 418   ; Looks like we have to use both.
 419   (save-excursion
 420     (save-window-excursion
 421       (notmuch-show-previous-message)
 422       (point))))
 423
 424 (defun notmuch-show-mark-read-then-next-open-message ()
 425   "Remove unread tag from current message, then advance to next unread message."
 426   (interactive)
 427   (notmuch-show-remove-tag "unread")
 428   (notmuch-show-next-open-message))
 429
 430 (defun notmuch-show-rewind ()
 431   "Do reverse scrolling compared to `notmuch-show-advance-marking-read-and-archiving'
 432
 433 Specifically, if the beginning of the previous email is fewer
 434 than `window-height' lines from the current point, move to it
 435 just like `notmuch-show-previous-message'.
 436
 437 Otherwise, just scroll down a screenful of the current message.
 438
 439 This command does not modify any message tags, (it does not undo
 440 any effects from previous calls to
 441 `notmuch-show-advance-marking-read-and-archiving'."
 442   (interactive)
 443   (let ((previous (notmuch-show-find-previous-message)))
 444     (if (> (count-lines previous (point)) (- (window-height) next-screen-context-lines))
 445         (progn
 446           (condition-case nil
 447               (scroll-down nil)
 448             ((beginning-of-buffer) nil))
 449           (goto-char (window-start)))
 450       (notmuch-show-previous-message))))
 451
 452 (defun notmuch-show-advance-marking-read-and-archiving ()
 453   "Advance through buffer, marking read and archiving.
 454
 455 This command is intended to be one of the simplest ways to
 456 process a thread of email. It does the following:
 457
 458 If the current message in the thread is not yet fully visible,
 459 scroll by a near screenful to read more of the message.
 460
 461 Otherwise, (the end of the current message is already within the
 462 current window), remove the \"unread\" tag (if present) from the
 463 current message and advance to the next open message.
 464
 465 Finally, if there is no further message to advance to, and this
 466 last message is already read, then archive the entire current
 467 thread, (remove the \"inbox\" tag from each message). Also kill
 468 this buffer, and display the next thread from the search from
 469 which this thread was originally shown."
 470   (interactive)
 471   (let ((next (notmuch-show-find-next-message))
 472         (unread (notmuch-show-message-unread-p)))
 473     (if (> next (window-end))
 474         (scroll-up nil)
 475       (let ((last (notmuch-show-last-message-p)))
 476         (notmuch-show-mark-read-then-next-open-message)
 477         (if last
 478             (notmuch-show-archive-thread))))))
 479
 480 (defun notmuch-toggle-invisible-action (cite-button)
 481   (let ((invis-spec (button-get button 'invisibility-spec)))
 482         (if (invisible-p invis-spec)
 483             (remove-from-invisibility-spec invis-spec)
 484           (add-to-invisibility-spec invis-spec)
 485           ))
 486   (goto-char (button-end cite-button)))
 487
 488 (defun notmuch-show-markup-citations-region (beg end depth)
 489   (goto-char beg)
 490   (beginning-of-line)
 491   (while (< (point) end)
 492     (let ((beg-sub (point-marker))
 493           (indent (make-string depth ? ))
 494           (citation "[[:space:]]*>"))
 495       (if (looking-at citation)
 496           (progn
 497             (while (looking-at citation)
 498               (forward-line))
 499             (let ((overlay (make-overlay beg-sub (point)))
 500                   (invis-spec (make-symbol "notmuch-citation-region")))
 501               (add-to-invisibility-spec invis-spec)
 502               (overlay-put overlay 'invisible invis-spec)
 503               (let (
 504                     (p (point))
 505                     (cite-button-text
 506                      (concat "["  (number-to-string (count-lines beg-sub (point)))
 507                              "-line citation.]"))
 508                     )
 509                 (goto-char (- beg-sub 1))
 510                 (insert (concat "\n" indent))
 511                 (let ((cite-button (insert-button cite-button-text)))
 512                   (button-put cite-button 'invisibility-spec invis-spec)
 513                   (button-put cite-button 'action 'notmuch-toggle-invisible-action)
 514                   (button-put cite-button 'help-echo
 515                               "mouse-2, RET: Show citation")
 516
 517                   )
 518                 (insert "\n")
 519                 (goto-char (+ (length cite-button-text) p))
 520               ))))
 521       (move-to-column depth)
 522       (if (looking-at notmuch-show-signature-regexp)
 523           (let ((sig-lines (- (count-lines beg-sub end) 1)))
 524             (if (<= sig-lines notmuch-show-signature-lines-max)
 525                 (progn
 526                   (let ((invis-spec (make-symbol "notmuch-signature-region")))
 527                     (add-to-invisibility-spec invis-spec)
 528                     (overlay-put (make-overlay beg-sub end)
 529                                  'invisible invis-spec)
 530
 531                     (goto-char (- beg-sub 1))
 532                     (insert (concat "\n" indent))
 533                     (let ((sig-button (insert-button
 534                                        (concat "[" (number-to-string sig-lines)
 535                                          "-line signature.]"))))
 536                       (button-put sig-button 'invisibility-spec invis-spec)
 537                       (button-put sig-button 'action
 538                                   'notmuch-toggle-invisible-action)
 539                       (button-put sig-button 'help-echo
 540                                   "mouse-2, RET: Show signature")
 541                       )
 542                     (insert "\n")
 543                     (goto-char end))))))
 544       (forward-line))))
 545
 546 (defun notmuch-show-markup-part (beg end depth)
 547   (if (re-search-forward notmuch-show-part-begin-regexp nil t)
 548       (progn
 549         (forward-line)
 550         (let ((beg (point-marker)))
 551           (re-search-forward notmuch-show-part-end-regexp)
 552           (let ((end (copy-marker (match-beginning 0))))
 553             (goto-char end)
 554             (if (not (bolp))
 555                 (insert "\n"))
 556             (indent-rigidly beg end depth)
 557             (notmuch-show-markup-citations-region beg end depth)
 558             ; Advance to the next part (if any) (so the outer loop can
 559             ; determine whether we've left the current message.
 560             (if (re-search-forward notmuch-show-part-begin-regexp nil t)
 561                 (beginning-of-line)))))
 562     (goto-char end)))
 563
 564 (defun notmuch-show-markup-parts-region (beg end depth)
 565   (save-excursion
 566     (goto-char beg)
 567     (while (< (point) end)
 568       (notmuch-show-markup-part beg end depth))))
 569
 570 (defun notmuch-show-markup-body (depth)
 571   (re-search-forward notmuch-show-body-begin-regexp)
 572   (forward-line)
 573   (let ((beg (point-marker)))
 574     (re-search-forward notmuch-show-body-end-regexp)
 575     (let ((end (copy-marker (match-beginning 0))))
 576       (notmuch-show-markup-parts-region beg end depth)
 577       (if (not (notmuch-show-message-unread-p))
 578           (overlay-put (make-overlay beg end)
 579                        'invisible 'notmuch-show-body-read))
 580       (set-marker beg nil)
 581       (set-marker end nil)
 582       )))
 583
 584 (defun notmuch-show-markup-header (depth)
 585   (re-search-forward notmuch-show-header-begin-regexp)
 586   (forward-line)
 587   (let ((beg (point-marker)))
 588     (end-of-line)
 589     ; Inverse video for subject
 590     (overlay-put (make-overlay beg (point)) 'face '(:inverse-video t))
 591     (forward-line 2)
 592     (let ((beg-hidden (point-marker)))
 593       (re-search-forward notmuch-show-header-end-regexp)
 594       (beginning-of-line)
 595       (let ((end (point-marker)))
 596         (goto-char beg)
 597         (forward-line)
 598         (while (looking-at "[A-Za-z][-A-Za-z0-9]*:")
 599           (beginning-of-line)
 600           (overlay-put (make-overlay (point) (re-search-forward ":"))
 601                        'face 'bold)
 602           (forward-line)
 603           )
 604         (indent-rigidly beg end depth)
 605         (overlay-put (make-overlay beg-hidden end)
 606                      'invisible 'notmuch-show-header)
 607         (set-marker beg nil)
 608         (set-marker beg-hidden nil)
 609         (set-marker end nil)
 610         ))))
 611
 612 (defun notmuch-show-markup-message ()
 613   (if (re-search-forward notmuch-show-message-begin-regexp nil t)
 614       (progn
 615         (re-search-forward notmuch-show-depth-regexp)
 616         (let ((depth (string-to-number (buffer-substring (match-beginning 1) (match-end 1)))))
 617           (notmuch-show-markup-header depth)
 618           (notmuch-show-markup-body depth)))
 619     (goto-char (point-max))))
 620
 621 (defun notmuch-show-hide-markers ()
 622   (save-excursion
 623     (goto-char (point-min))
 624     (while (not (eobp))
 625       (if (re-search-forward notmuch-show-marker-regexp nil t)
 626           (progn
 627             (overlay-put (make-overlay (match-beginning 0) (+ (match-end 0) 1))
 628                          'invisible 'notmuch-show-marker))
 629         (goto-char (point-max))))))
 630
 631 (defun notmuch-show-markup-messages ()
 632   (save-excursion
 633     (goto-char (point-min))
 634     (while (not (eobp))
 635       (notmuch-show-markup-message)))
 636   (notmuch-show-hide-markers))
 637
 638 (defun notmuch-show-toggle-citations-visible ()
 639   "Toggle visibility of citations"
 640   (interactive)
 641   (if notmuch-show-citations-visible
 642       (add-to-invisibility-spec 'notmuch-show-citation)
 643     (remove-from-invisibility-spec 'notmuch-show-citation))
 644   (set 'notmuch-show-citations-visible (not notmuch-show-citations-visible))
 645   ; Need to force the redisplay for some reason
 646   (force-window-update)
 647   (redisplay t))
 648
 649 (defun notmuch-show-toggle-signatures-visible ()
 650   "Toggle visibility of signatures"
 651   (interactive)
 652   (if notmuch-show-signatures-visible
 653       (add-to-invisibility-spec 'notmuch-show-signature)
 654     (remove-from-invisibility-spec 'notmuch-show-signature))
 655   (set 'notmuch-show-signatures-visible (not notmuch-show-signatures-visible))
 656   ; Need to force the redisplay for some reason
 657   (force-window-update)
 658   (redisplay t))
 659
 660 (defun notmuch-show-toggle-headers-visible ()
 661   "Toggle visibility of header fields"
 662   (interactive)
 663   (if notmuch-show-headers-visible
 664       (add-to-invisibility-spec 'notmuch-show-header)
 665     (remove-from-invisibility-spec 'notmuch-show-header))
 666   (set 'notmuch-show-headers-visible (not notmuch-show-headers-visible))
 667   ; Need to force the redisplay for some reason
 668   (force-window-update)
 669   (redisplay t))
 670
 671 (defun notmuch-show-toggle-body-read-visible ()
 672   "Toggle visibility of message bodies of read messages"
 673   (interactive)
 674   (if notmuch-show-body-read-visible
 675       (add-to-invisibility-spec 'notmuch-show-body-read)
 676     (remove-from-invisibility-spec 'notmuch-show-body-read))
 677   (set 'notmuch-show-body-read-visible (not notmuch-show-body-read-visible))
 678   ; Need to force the redisplay for some reason
 679   (force-window-update)
 680   (redisplay t))
 681
 682 ;;;###autoload
 683 (defun notmuch-show-mode ()
 684   "Major mode for viewing a thread with notmuch.
 685
 686 This buffer contains the results of the \"notmuch show\" command
 687 for displaying a single thread of email from your email archives.
 688
 689 By default, various components of email messages, (citations,
 690 signatures, already-read messages), are invisible to help you
 691 focus on the most important things, (new text from unread
 692 messages). See the various commands below for toggling the
 693 visibility of hidden components.
 694
 695 The `notmuch-show-next-message' and
 696 `notmuch-show-previous-message' commands, (bound to 'n' and 'p by
 697 default), allow you to navigate to the next and previous
 698 messages. Each time you navigate away from a message with
 699 `notmuch-show-next-message' the current message will have its
 700 \"unread\" tag removed.
 701
 702 You can add or remove tags from the current message with '+' and
 703 '-'.  You can also archive all messages in the current
 704 view, (remove the \"inbox\" tag from each), with
 705 `notmuch-show-archive-thread' (bound to 'a' by default).
 706
 707 \\{notmuch-show-mode-map}"
 708   (interactive)
 709   (kill-all-local-variables)
 710   (set (make-local-variable 'notmuch-show-headers-visible) t)
 711   (notmuch-show-toggle-headers-visible)
 712   (set (make-local-variable 'notmuch-show-body-read-visible) t)
 713   (notmuch-show-toggle-body-read-visible)
 714   (set (make-local-variable 'notmuch-show-citations-visible) t)
 715   (notmuch-show-toggle-citations-visible)
 716   (set (make-local-variable 'notmuch-show-signatures-visible) t)
 717   (notmuch-show-toggle-signatures-visible)
 718   (add-to-invisibility-spec 'notmuch-show-marker)
 719   (use-local-map notmuch-show-mode-map)
 720   (setq major-mode 'notmuch-show-mode
 721         mode-name "notmuch-show")
 722   (setq buffer-read-only t))
 723
 724 ;;;###autoload
 725
 726 (defgroup notmuch nil
 727   "Notmuch mail reader for Emacs."
 728   :group 'mail)
 729
 730 (defcustom notmuch-show-hook nil
 731   "List of functions to call when notmuch displays a message."
 732   :type 'hook
 733   :options '(goto-address)
 734   :group 'notmuch)
 735
 736 (defcustom notmuch-search-hook nil
 737   "List of functions to call when notmuch displays the search results."
 738   :type 'hook
 739   :options '(hl-line-mode)
 740   :group 'notmuch)
 741
 742 ; Make show mode a bit prettier, highlighting URLs and using word wrap
 743
 744 (defun notmuch-show-pretty-hook ()
 745   (goto-address-mode 1)
 746   (visual-line-mode))
 747
 748 (add-hook 'notmuch-show-hook 'notmuch-show-pretty-hook)
 749 (add-hook 'notmuch-search-hook
 750           (lambda()
 751             (hl-line-mode 1) ))
 752
 753 (defun notmuch-show (thread-id &optional parent-buffer)
 754   "Run \"notmuch show\" with the given thread ID and display results.
 755
 756 The optional PARENT-BUFFER is the notmuch-search buffer from
 757 which this notmuch-show command was executed, (so that the next
 758 thread from that buffer can be show when done with this one)."
 759   (interactive "sNotmuch show: ")
 760   (let ((buffer (get-buffer-create (concat "*notmuch-show-" thread-id "*"))))
 761     (switch-to-buffer buffer)
 762     (notmuch-show-mode)
 763     (set (make-local-variable 'notmuch-show-parent-buffer) parent-buffer)
 764     (let ((proc (get-buffer-process (current-buffer)))
 765           (inhibit-read-only t))
 766       (if proc
 767           (error "notmuch search process already running for query `%s'" thread-id)
 768         )
 769       (erase-buffer)
 770       (goto-char (point-min))
 771       (save-excursion
 772         (call-process notmuch-command nil t nil "show" thread-id)
 773         (notmuch-show-markup-messages)
 774         )
 775       (run-hooks 'notmuch-show-hook)
 776       ; Move straight to the first unread message
 777       (if (not (notmuch-show-message-unread-p))
 778           (progn
 779             (notmuch-show-next-unread-message)
 780             ; But if there are no unread messages, go back to the
 781             ; beginning of the buffer, and open up the bodies of all
 782             ; read message.
 783             (if (not (notmuch-show-message-unread-p))
 784                 (progn
 785                   (goto-char (point-min))
 786                   (notmuch-show-toggle-body-read-visible)))))
 787       )))
 788
 789 (defvar notmuch-search-authors-width 40
 790   "Number of columns to use to display authors in a notmuch-search buffer.")
 791
 792 (defvar notmuch-search-mode-map
 793   (let ((map (make-sparse-keymap)))
 794     (define-key map "a" 'notmuch-search-archive-thread)
 795     (define-key map "b" 'notmuch-search-scroll-down)
 796     (define-key map "f" 'notmuch-search-filter)
 797     (define-key map "m" 'message-mail)
 798     (define-key map "n" 'next-line)
 799     (define-key map "o" 'notmuch-search-toggle-order)
 800     (define-key map "p" 'previous-line)
 801     (define-key map "q" 'kill-this-buffer)
 802     (define-key map "r" 'notmuch-search-reply-to-thread)
 803     (define-key map "s" 'notmuch-search)
 804     (define-key map "t" 'notmuch-search-filter-by-tag)
 805     (define-key map "x" 'kill-this-buffer)
 806     (define-key map (kbd "RET") 'notmuch-search-show-thread)
 807     (define-key map "+" 'notmuch-search-add-tag)
 808     (define-key map "-" 'notmuch-search-remove-tag)
 809     (define-key map "<" 'beginning-of-buffer)
 810     (define-key map ">" 'notmuch-search-goto-last-thread)
 811     (define-key map "=" 'notmuch-search-refresh-view)
 812     (define-key map "\M->" 'notmuch-search-goto-last-thread)
 813     (define-key map " " 'notmuch-search-scroll-up)
 814     (define-key map (kbd "<DEL>") 'notmuch-search-scroll-down)
 815     (define-key map "?" 'describe-mode)
 816     map)
 817   "Keymap for \"notmuch search\" buffers.")
 818 (fset 'notmuch-search-mode-map notmuch-search-mode-map)
 819
 820 (defvar notmuch-search-query-string)
 821 (defvar notmuch-search-oldest-first)
 822
 823 (defun notmuch-search-scroll-up ()
 824   "Scroll up, moving point to last message in thread if at end."
 825   (interactive)
 826   (condition-case nil
 827       (scroll-up nil)
 828     ((end-of-buffer) (notmuch-search-goto-last-thread))))
 829
 830 (defun notmuch-search-scroll-down ()
 831   "Scroll down, moving point to first message in thread if at beginning."
 832   (interactive)
 833   ; I don't know why scroll-down doesn't signal beginning-of-buffer
 834   ; the way that scroll-up signals end-of-buffer, but c'est la vie.
 835   ;
 836   ; So instead of trapping a signal we instead check whether the
 837   ; window begins on the first line of the buffer and if so, move
 838   ; directly to that position. (We have to count lines since the
 839   ; window-start position is not the same as point-min due to the
 840   ; invisible thread-ID characters on the first line.
 841   (if (equal (count-lines (point-min) (window-start)) 1)
 842       (goto-char (window-start))
 843     (scroll-down nil)))
 844
 845 (defun notmuch-search-goto-last-thread ()
 846   "Move point to the last thread in the buffer."
 847   (interactive)
 848   (goto-char (point-max))
 849   (forward-line -1))
 850
 851 ;;;###autoload
 852 (defun notmuch-search-mode ()
 853   "Major mode for searching mail with notmuch.
 854
 855 This buffer contains the results of a \"notmuch search\" of your
 856 email archives. Each line in the buffer represents a single
 857 thread giving a relative date for the thread and a subject.
 858
 859 Pressing RET on any line displays that thread. The '+' and '-'
 860 keys can be used to add or remove tags from a thread. The 'a' key
 861 is a convenience key for archiving a thread (removing the
 862 \"inbox\" tag).
 863
 864 Other useful commands are `notmuch-search-filter' for filtering
 865 the current search based on an additional query string,
 866 `notmuch-search-filter-by-tag' for filtering to include only
 867 messages with a given tag, and `notmuch-search' to execute a new,
 868 global search.
 869
 870 \\{notmuch-search-mode-map}"
 871   (interactive)
 872   (kill-all-local-variables)
 873   (make-local-variable 'notmuch-search-query-string)
 874   (make-local-variable 'notmuch-search-oldest-first)
 875   (set (make-local-variable 'scroll-preserve-screen-position) t)
 876   (add-to-invisibility-spec 'notmuch-search)
 877   (use-local-map notmuch-search-mode-map)
 878   (setq truncate-lines t)
 879   (setq major-mode 'notmuch-search-mode
 880         mode-name "notmuch-search")
 881   (setq buffer-read-only t))
 882
 883 (defun notmuch-search-find-thread-id ()
 884   (save-excursion
 885     (beginning-of-line)
 886     (let ((beg (point)))
 887       (re-search-forward "thread:[a-fA-F0-9]*" nil t)
 888       (filter-buffer-substring beg (point)))))
 889
 890 (defun notmuch-search-markup-this-thread-id ()
 891   (beginning-of-line)
 892   (let ((beg (point)))
 893     (if (re-search-forward "thread:[a-fA-F0-9]*" nil t)
 894         (progn
 895           (forward-char)
 896           (overlay-put (make-overlay beg (point)) 'invisible 'notmuch-search)
 897           (re-search-forward ".*\\[[0-9]*/[0-9]*\\] \\([^;]*\\)\\(;\\)")
 898           (let* ((authors (buffer-substring (match-beginning 1) (match-end 1)))
 899                  (authors-length (length authors)))
 900             ;; Drop the semi-colon
 901             (replace-match "" t nil nil 2)
 902             (if (<= authors-length notmuch-search-authors-width)
 903                 (replace-match (concat authors (make-string
 904                                                 (- notmuch-search-authors-width
 905                                                    authors-length) ? )) t t nil 1)
 906               (replace-match (concat (substring authors 0 (- notmuch-search-authors-width 3)) "...") t t nil 1)))))))
 907
 908 (defun notmuch-search-markup-thread-ids ()
 909   (save-excursion
 910     (goto-char (point-min))
 911     (while (not (eobp))
 912       (notmuch-search-markup-this-thread-id)
 913       (forward-line))))
 914
 915 (defun notmuch-search-show-thread ()
 916   (interactive)
 917   (let ((thread-id (notmuch-search-find-thread-id)))
 918     (if (> (length thread-id) 0)
 919         (notmuch-show thread-id (current-buffer))
 920       (error "End of search results"))))
 921
 922 (defun notmuch-search-reply-to-thread ()
 923   "Begin composing a reply to the entire current thread in a new buffer."
 924   (interactive)
 925   (let ((message-id (notmuch-search-find-thread-id)))
 926     (notmuch-reply message-id)))
 927
 928 (defun notmuch-call-notmuch-process (&rest args)
 929   "Synchronously invoke \"notmuch\" with the given list of arguments.
 930
 931 Output from the process will be presented to the user as an error
 932 and will also appear in a buffer named \"*Notmuch errors*\"."
 933   (let ((error-buffer (get-buffer-create "*Notmuch errors*")))
 934     (with-current-buffer error-buffer
 935         (erase-buffer))
 936     (if (eq (apply 'call-process notmuch-command nil error-buffer nil args) 0)
 937         (point)
 938       (progn
 939         (with-current-buffer error-buffer
 940           (let ((beg (point-min))
 941                 (end (- (point-max) 1)))
 942             (error (buffer-substring beg end))
 943             ))))))
 944
 945 (defun notmuch-search-set-tags (tags)
 946   (save-excursion
 947     (end-of-line)
 948     (re-search-backward "(")
 949     (forward-char)
 950     (let ((beg (point))
 951           (inhibit-read-only t))
 952       (re-search-forward ")")
 953       (backward-char)
 954       (let ((end (point)))
 955         (delete-region beg end)
 956         (insert (mapconcat  'identity tags " "))))))
 957
 958 (defun notmuch-search-get-tags ()
 959   (save-excursion
 960     (end-of-line)
 961     (re-search-backward "(")
 962     (let ((beg (+ (point) 1)))
 963       (re-search-forward ")")
 964       (let ((end (- (point) 1)))
 965         (split-string (buffer-substring beg end))))))
 966
 967 (defun notmuch-search-add-tag (tag)
 968   (interactive "sTag to add: ")
 969   (notmuch-call-notmuch-process "tag" (concat "+" tag) (notmuch-search-find-thread-id))
 970   (notmuch-search-set-tags (delete-dups (sort (cons tag (notmuch-search-get-tags)) 'string<))))
 971
 972 (defun notmuch-search-remove-tag (tag)
 973   (interactive "sTag to remove: ")
 974   (notmuch-call-notmuch-process "tag" (concat "-" tag) (notmuch-search-find-thread-id))
 975   (notmuch-search-set-tags (delete tag (notmuch-search-get-tags))))
 976
 977 (defun notmuch-search-archive-thread ()
 978   "Archive the current thread (remove its \"inbox\" tag).
 979
 980 This function advances point to the next line when finished."
 981   (interactive)
 982   (notmuch-search-remove-tag "inbox")
 983   (forward-line))
 984
 985 (defun notmuch-search (query &optional oldest-first)
 986   "Run \"notmuch search\" with the given query string and display results."
 987   (interactive "sNotmuch search: ")
 988   (let ((buffer (get-buffer-create (concat "*notmuch-search-" query "*"))))
 989     (switch-to-buffer buffer)
 990     (notmuch-search-mode)
 991     (set 'notmuch-search-query-string query)
 992     (set 'notmuch-search-oldest-first oldest-first)
 993     (let ((proc (get-buffer-process (current-buffer)))
 994           (inhibit-read-only t))
 995       (if proc
 996           (error "notmuch search process already running for query `%s'" query)
 997         )
 998       (erase-buffer)
 999       (goto-char (point-min))
1000       (save-excursion
1001         (if oldest-first
1002             (call-process notmuch-command nil t nil "search" "--sort=oldest-first" query)
1003           (call-process notmuch-command nil t nil "search" "--sort=newest-first" query))
1004         (notmuch-search-markup-thread-ids)
1005         ))
1006     (run-hooks 'notmuch-search-hook)))
1007
1008 (defun notmuch-search-refresh-view ()
1009   "Refresh the current view.
1010
1011 Kills the current buffer and runs a new search with the same
1012 query string as the current search. If the current thread is in
1013 the new search results, then point will be placed on the same
1014 thread. Otherwise, point will be moved to attempt to be in the
1015 same relative position within the new buffer."
1016   (interactive)
1017   (let ((here (point))
1018         (oldest-first notmuch-search-oldest-first)
1019         (thread (notmuch-search-find-thread-id))
1020         (query notmuch-search-query-string))
1021     (kill-this-buffer)
1022     (notmuch-search query oldest-first)
1023     (goto-char (point-min))
1024     (if (re-search-forward (concat "^" thread) nil t)
1025         (beginning-of-line)
1026       (goto-char here))))
1027
1028 (defun notmuch-search-toggle-order ()
1029   "Toggle the current search order.
1030
1031 By default, the \"inbox\" view created by `notmuch' is displayed
1032 in chronological order (oldest thread at the beginning of the
1033 buffer), while any global searches created by `notmuch-search'
1034 are displayed in reverse-chronological order (newest thread at
1035 the beginning of the buffer).
1036
1037 This command toggles the sort order for the current search.
1038
1039 Note that any filtered searches created by
1040 `notmuch-search-filter' retain the search order of the parent
1041 search."
1042   (interactive)
1043   (set 'notmuch-search-oldest-first (not notmuch-search-oldest-first))
1044   (notmuch-search-refresh-view))
1045
1046 (defun notmuch-search-filter (query)
1047   "Filter the current search results based on an additional query string.
1048
1049 Runs a new search matching only messages that match both the
1050 current search results AND the additional query string provided."
1051   (interactive "sFilter search: ")
1052   (notmuch-search (concat notmuch-search-query-string " and " query) notmuch-search-oldest-first))
1053
1054 (defun notmuch-search-filter-by-tag (tag)
1055   "Filter the current search results based on a single tag.
1056
1057 Runs a new search matching only messages that match both the
1058 current search results AND that are tagged with the given tag."
1059   (interactive "sFilter by tag: ")
1060   (notmuch-search (concat notmuch-search-query-string " and tag:" tag) notmuch-search-oldest-first))
1061
1062 (defun notmuch ()
1063   "Run notmuch to display all mail with tag of 'inbox'"
1064   (interactive)
1065   (notmuch-search "tag:inbox" t))
1066
1067 (setq mail-user-agent 'message-user-agent)
1068
1069 (provide 'notmuch)