git.notmuchmail.org Git - notmuch/blob - notmuch.el

   1 ; notmuch.el --- run notmuch within emacs
   2 ;
   3 ; Copyright © Carl Worth
   4 ;
   5 ; This file is part of Notmuch.
   6 ;
   7 ; Notmuch is free software: you can redistribute it and/or modify it
   8 ; under the terms of the GNU General Public License as published by
   9 ; the Free Software Foundation, either version 3 of the License, or
  10 ; (at your option) any later version.
  11 ;
  12 ; Notmuch is distributed in the hope that it will be useful, but
  13 ; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 ; General Public License for more details.
  16 ;
  17 ; You should have received a copy of the GNU General Public License
  18 ; along with Notmuch.  If not, see <http://www.gnu.org/licenses/>.
  19 ;
  20 ; Authors: Carl Worth <cworth@cworth.org>
  21
  22 ; This is an emacs-based interface to the notmuch mail system.
  23 ;
  24 ; You will first need to have the notmuch program installed and have a
  25 ; notmuch database built in order to use this. See
  26 ; http://notmuchmail.org for details.
  27 ;
  28 ; To install this software, copy it to a directory that is on the
  29 ; `load-path' variable within emacs (a good candidate is
  30 ; /usr/local/share/emacs/site-lisp). If you are viewing this from the
  31 ; notmuch source distribution then you can simply run:
  32 ;
  33 ;       sudo make install-emacs
  34 ;
  35 ; to install it.
  36 ;
  37 ; Then, to actually run it, add:
  38 ;
  39 ;       (require 'notmuch)
  40 ;
  41 ; to your ~/.emacs file, and then run "M-x notmuch" from within emacs,
  42 ; or run:
  43 ;
  44 ;       emacs -f notmuch
  45 ;
  46 ; Have fun, and let us know if you have any comment, questions, or
  47 ; kudos: Notmuch list <notmuch@notmuchmail.org> (subscription is not
  48 ; required, but is available from http://notmuchmail.org).
  49
  50 (require 'cl)
  51 (require 'mm-view)
  52 (require 'message)
  53
  54 (defvar notmuch-show-mode-map
  55   (let ((map (make-sparse-keymap)))
  56     (define-key map "?" 'notmuch-help)
  57     (define-key map "q" 'kill-this-buffer)
  58     (define-key map (kbd "C-p") 'notmuch-show-previous-line)
  59     (define-key map (kbd "C-n") 'notmuch-show-next-line)
  60     (define-key map (kbd "M-TAB") 'notmuch-show-previous-button)
  61     (define-key map (kbd "TAB") 'notmuch-show-next-button)
  62     (define-key map "s" 'notmuch-search)
  63     (define-key map "m" 'message-mail)
  64     (define-key map "f" 'notmuch-show-forward-current)
  65     (define-key map "r" 'notmuch-show-reply)
  66     (define-key map "|" 'notmuch-show-pipe-message)
  67     (define-key map "w" 'notmuch-show-save-attachments)
  68     (define-key map "V" 'notmuch-show-view-raw-message)
  69     (define-key map "v" 'notmuch-show-view-all-mime-parts)
  70     (define-key map "-" 'notmuch-show-remove-tag)
  71     (define-key map "+" 'notmuch-show-add-tag)
  72     (define-key map "X" 'notmuch-show-mark-read-then-archive-then-exit)
  73     (define-key map "x" 'notmuch-show-archive-thread-then-exit)
  74     (define-key map "A" 'notmuch-show-mark-read-then-archive-thread)
  75     (define-key map "a" 'notmuch-show-archive-thread)
  76     (define-key map "p" 'notmuch-show-previous-message)
  77     (define-key map "N" 'notmuch-show-mark-read-then-next-open-message)
  78     (define-key map "n" 'notmuch-show-next-message)
  79     (define-key map (kbd "DEL") 'notmuch-show-rewind)
  80     (define-key map " " 'notmuch-show-advance-marking-read-and-archiving)
  81     map)
  82   "Keymap for \"notmuch show\" buffers.")
  83 (fset 'notmuch-show-mode-map notmuch-show-mode-map)
  84
  85 (defvar notmuch-show-signature-regexp "\\(-- ?\\|_+\\)$"
  86   "Pattern to match a line that separates content from signature.
  87
  88 The regexp can (and should) include $ to match the end of the
  89 line, but should not include ^ to match the beginning of the
  90 line. This is because notmuch may have inserted additional space
  91 for indentation at the beginning of the line. But notmuch will
  92 move past the indentation when testing this pattern, (so that the
  93 pattern can still test against the entire line).")
  94
  95 (defvar notmuch-show-signature-lines-max 12
  96   "Maximum length of signature that will be hidden by default.")
  97
  98 (defvar notmuch-command "notmuch"
  99   "Command to run the notmuch binary.")
 100
 101 (defvar notmuch-show-message-begin-regexp    "\fmessage{")
 102 (defvar notmuch-show-message-end-regexp      "\fmessage}")
 103 (defvar notmuch-show-header-begin-regexp     "\fheader{")
 104 (defvar notmuch-show-header-end-regexp       "\fheader}")
 105 (defvar notmuch-show-body-begin-regexp       "\fbody{")
 106 (defvar notmuch-show-body-end-regexp         "\fbody}")
 107 (defvar notmuch-show-attachment-begin-regexp "\fattachment{")
 108 (defvar notmuch-show-attachment-end-regexp   "\fattachment}")
 109 (defvar notmuch-show-part-begin-regexp       "\fpart{")
 110 (defvar notmuch-show-part-end-regexp         "\fpart}")
 111 (defvar notmuch-show-marker-regexp "\f\\(message\\|header\\|body\\|attachment\\|part\\)[{}].*$")
 112
 113 (defvar notmuch-show-id-regexp "\\(id:[^ ]*\\)")
 114 (defvar notmuch-show-depth-regexp " depth:\\([0-9]*\\) ")
 115 (defvar notmuch-show-filename-regexp "filename:\\(.*\\)$")
 116 (defvar notmuch-show-tags-regexp "(\\([^)]*\\))$")
 117
 118 (defvar notmuch-show-parent-buffer nil)
 119 (defvar notmuch-show-body-read-visible nil)
 120 (defvar notmuch-show-citations-visible nil)
 121 (defvar notmuch-show-signatures-visible nil)
 122 (defvar notmuch-show-headers-visible nil)
 123
 124 ; XXX: This should be a generic function in emacs somewhere, not here
 125 (defun point-invisible-p ()
 126   "Return whether the character at point is invisible.
 127
 128 Here visibility is determined by `buffer-invisibility-spec' and
 129 the invisible property of any overlays for point. It doesn't have
 130 anything to do with whether point is currently being displayed
 131 within the current window."
 132   (let ((prop (get-char-property (point) 'invisible)))
 133     (if (eq buffer-invisibility-spec t)
 134         prop
 135       (or (memq prop buffer-invisibility-spec)
 136           (assq prop buffer-invisibility-spec)))))
 137
 138 (defun notmuch-select-tag-with-completion (prompt &rest search-terms)
 139   (let ((tag-list
 140          (with-output-to-string
 141            (with-current-buffer standard-output
 142              (apply 'call-process notmuch-command nil t nil "search-tags" search-terms)))))
 143     (completing-read prompt (split-string tag-list "\n+" t) nil nil nil)))
 144
 145 (defun notmuch-show-next-line ()
 146   "Like builtin `next-line' but ensuring we end on a visible character.
 147
 148 By advancing forward until reaching a visible character.
 149
 150 Unlike builtin `next-line' this version accepts no arguments."
 151   (interactive)
 152   (set 'this-command 'next-line)
 153   (call-interactively 'next-line)
 154   (while (point-invisible-p)
 155     (forward-char)))
 156
 157 (defun notmuch-show-previous-line ()
 158   "Like builtin `previous-line' but ensuring we end on a visible character.
 159
 160 By advancing forward until reaching a visible character.
 161
 162 Unlike builtin `previous-line' this version accepts no arguments."
 163   (interactive)
 164   (set 'this-command 'previous-line)
 165   (call-interactively 'previous-line)
 166   (while (point-invisible-p)
 167     (forward-char)))
 168
 169 (defun notmuch-show-get-message-id ()
 170   (save-excursion
 171     (beginning-of-line)
 172     (if (not (looking-at notmuch-show-message-begin-regexp))
 173         (re-search-backward notmuch-show-message-begin-regexp))
 174     (re-search-forward notmuch-show-id-regexp)
 175     (buffer-substring-no-properties (match-beginning 1) (match-end 1))))
 176
 177 (defun notmuch-show-get-filename ()
 178   (save-excursion
 179     (beginning-of-line)
 180     (if (not (looking-at notmuch-show-message-begin-regexp))
 181         (re-search-backward notmuch-show-message-begin-regexp))
 182     (re-search-forward notmuch-show-filename-regexp)
 183     (buffer-substring-no-properties (match-beginning 1) (match-end 1))))
 184
 185 (defun notmuch-show-set-tags (tags)
 186   (save-excursion
 187     (beginning-of-line)
 188     (if (not (looking-at notmuch-show-message-begin-regexp))
 189         (re-search-backward notmuch-show-message-begin-regexp))
 190     (re-search-forward notmuch-show-tags-regexp)
 191     (let ((inhibit-read-only t)
 192           (beg (match-beginning 1))
 193           (end (match-end 1)))
 194       (delete-region beg end)
 195       (goto-char beg)
 196       (insert (mapconcat 'identity tags " ")))))
 197
 198 (defun notmuch-show-get-tags ()
 199   (save-excursion
 200     (beginning-of-line)
 201     (if (not (looking-at notmuch-show-message-begin-regexp))
 202         (re-search-backward notmuch-show-message-begin-regexp))
 203     (re-search-forward notmuch-show-tags-regexp)
 204     (split-string (buffer-substring (match-beginning 1) (match-end 1)))))
 205
 206 (defun notmuch-show-add-tag (&rest toadd)
 207   "Add a tag to the current message."
 208   (interactive
 209    (list (notmuch-select-tag-with-completion "Tag to add: ")))
 210   (apply 'notmuch-call-notmuch-process
 211          (append (cons "tag"
 212                        (mapcar (lambda (s) (concat "+" s)) toadd))
 213                  (cons (notmuch-show-get-message-id) nil)))
 214   (notmuch-show-set-tags (sort (union toadd (notmuch-show-get-tags) :test 'string=) 'string<)))
 215
 216 (defun notmuch-show-remove-tag (&rest toremove)
 217   "Remove a tag from the current message."
 218   (interactive
 219    (list (notmuch-select-tag-with-completion "Tag to remove: " (notmuch-show-get-message-id))))
 220   (let ((tags (notmuch-show-get-tags)))
 221     (if (intersection tags toremove :test 'string=)
 222         (progn
 223           (apply 'notmuch-call-notmuch-process
 224                  (append (cons "tag"
 225                                (mapcar (lambda (s) (concat "-" s)) toremove))
 226                          (cons (notmuch-show-get-message-id) nil)))
 227           (notmuch-show-set-tags (sort (set-difference tags toremove :test 'string=) 'string<))))))
 228
 229 (defun notmuch-show-archive-thread-maybe-mark-read (markread)
 230   (save-excursion
 231     (goto-char (point-min))
 232     (while (not (eobp))
 233       (if markread
 234           (notmuch-show-remove-tag "unread" "inbox")
 235         (notmuch-show-remove-tag "inbox"))
 236       (if (not (eobp))
 237           (forward-char))
 238       (if (not (re-search-forward notmuch-show-message-begin-regexp nil t))
 239           (goto-char (point-max)))))
 240   (let ((parent-buffer notmuch-show-parent-buffer))
 241     (kill-this-buffer)
 242     (if parent-buffer
 243         (progn
 244           (switch-to-buffer parent-buffer)
 245           (forward-line)
 246           (notmuch-search-show-thread)))))
 247
 248 (defun notmuch-show-mark-read-then-archive-thread ()
 249   "Remove unread tags from thread, then archive and show next thread.
 250
 251 Archive each message currently shown by removing the \"unread\"
 252 and \"inbox\" tag from each. Then kill this buffer and show the
 253 next thread from the search from which this thread was originally
 254 shown.
 255
 256 Note: This command is safe from any race condition of new messages
 257 being delivered to the same thread. It does not archive the
 258 entire thread, but only the messages shown in the current
 259 buffer."
 260   (interactive)
 261   (notmuch-show-archive-thread-maybe-mark-read t))
 262
 263 (defun notmuch-show-archive-thread ()
 264   "Archive each message in thread, then show next thread from search.
 265
 266 Archive each message currently shown by removing the \"inbox\"
 267 tag from each. Then kill this buffer and show the next thread
 268 from the search from which this thread was originally shown.
 269
 270 Note: This command is safe from any race condition of new messages
 271 being delivered to the same thread. It does not archive the
 272 entire thread, but only the messages shown in the current
 273 buffer."
 274   (interactive)
 275   (notmuch-show-archive-thread-maybe-mark-read nil))
 276
 277 (defun notmuch-show-archive-thread-then-exit ()
 278   "Archive each message in thread, then exit back to search results."
 279   (interactive)
 280   (notmuch-show-archive-thread)
 281   (kill-this-buffer))
 282
 283 (defun notmuch-show-mark-read-then-archive-then-exit ()
 284   "Remove unread tags from thread, then archive and exit to search results."
 285   (interactive)
 286   (notmuch-show-mark-read-then-archive-thread)
 287   (kill-this-buffer))
 288
 289 (defun notmuch-show-view-raw-message ()
 290   "View the raw email of the current message."
 291   (interactive)
 292   (view-file (notmuch-show-get-filename)))
 293
 294 (defmacro with-current-notmuch-show-message (&rest body)
 295   "Evaluate body with current buffer set to the text of current message"
 296   `(save-excursion
 297      (let ((filename (notmuch-show-get-filename)))
 298        (let ((buf (generate-new-buffer (concat "*notmuch-msg-" filename "*"))))
 299          (with-current-buffer buf
 300            (insert-file-contents filename nil nil nil t)
 301            ,@body)
 302         (kill-buffer buf)))))
 303
 304 (defun notmuch-show-view-all-mime-parts ()
 305   "Use external viewers to view all attachments from the current message."
 306   (interactive)
 307   (with-current-notmuch-show-message
 308    (mm-display-parts (mm-dissect-buffer))))
 309
 310 (defun notmuch-foreach-mime-part (function mm-handle)
 311   (cond ((stringp (car mm-handle))
 312          (dolist (part (cdr mm-handle))
 313            (notmuch-foreach-mime-part function part)))
 314         ((bufferp (car mm-handle))
 315          (funcall function mm-handle))
 316         (t (dolist (part mm-handle)
 317              (notmuch-foreach-mime-part function part)))))
 318
 319 (defun notmuch-count-attachments (mm-handle)
 320   (let ((count 0))
 321     (notmuch-foreach-mime-part
 322      (lambda (p)
 323        (let ((disposition (mm-handle-disposition p)))
 324          (and (listp disposition)
 325               (equal (car disposition) "attachment")
 326               (incf count))))
 327      mm-handle)
 328     count))
 329
 330 (defun notmuch-save-attachments (mm-handle &optional queryp)
 331   (notmuch-foreach-mime-part
 332    (lambda (p)
 333      (let ((disposition (mm-handle-disposition p)))
 334        (and (listp disposition)
 335             (equal (car disposition) "attachment")
 336             (or (not queryp)
 337                 (y-or-n-p
 338                  (concat "Save '" (cdr (assq 'filename disposition)) "' ")))
 339             (mm-save-part p))))
 340    mm-handle))
 341
 342 (defun notmuch-show-save-attachments ()
 343   "Save all attachments from the current message."
 344   (interactive)
 345   (with-current-notmuch-show-message
 346    (let ((mm-handle (mm-dissect-buffer)))
 347      (notmuch-save-attachments
 348       mm-handle (> (notmuch-count-attachments mm-handle) 1))))
 349   (message "Done"))
 350
 351 (defun notmuch-reply (query-string)
 352   (switch-to-buffer (generate-new-buffer "notmuch-draft"))
 353   (call-process notmuch-command nil t nil "reply" query-string)
 354   (message-insert-signature)
 355   (goto-char (point-min))
 356   (if (re-search-forward "^$" nil t)
 357       (progn
 358         (insert "--text follows this line--")
 359         (forward-line)))
 360   (message-mode))
 361
 362 (defun notmuch-show-reply ()
 363   "Begin composing a reply to the current message in a new buffer."
 364   (interactive)
 365   (let ((message-id (notmuch-show-get-message-id)))
 366     (notmuch-reply message-id)))
 367
 368 (defun notmuch-show-forward-current ()
 369   "Forward the current message."
 370   (interactive)
 371   (with-current-notmuch-show-message
 372    (message-forward)))
 373
 374 (defun notmuch-show-pipe-message (command)
 375   "Pipe the contents of the current message to the given command.
 376
 377 The given command will be executed with the raw contents of the
 378 current email message as stdin. Anything printed by the command
 379 to stdout or stderr will appear in the *Messages* buffer."
 380   (interactive "sPipe message to command: ")
 381   (apply 'start-process-shell-command "notmuch-pipe-command" "*notmuch-pipe*"
 382          (list command " < " (shell-quote-argument (notmuch-show-get-filename)))))
 383
 384 (defun notmuch-show-move-to-current-message-summary-line ()
 385   "Move to the beginning of the one-line summary of the current message.
 386
 387 This gives us a stable place to move to and work from since the
 388 summary line is always visible. This is important since moving to
 389 an invisible location is unreliable, (the main command loop moves
 390 point either forward or backward to the next visible character
 391 when a command ends with point on an invisible character).
 392
 393 Emits an error if point is not within a valid message, (that is
 394 no pattern of `notmuch-show-message-begin-regexp' could be found
 395 by searching backward)."
 396   (beginning-of-line)
 397   (if (not (looking-at notmuch-show-message-begin-regexp))
 398       (if (re-search-backward notmuch-show-message-begin-regexp nil t)
 399           (forward-line 2)
 400         (error "Not within a valid message."))
 401     (forward-line 2)))
 402
 403 (defun notmuch-show-last-message-p ()
 404   "Predicate testing whether point is within the last message."
 405   (save-window-excursion
 406     (save-excursion
 407       (notmuch-show-move-to-current-message-summary-line)
 408       (not (re-search-forward notmuch-show-message-begin-regexp nil t)))))
 409
 410 (defun notmuch-show-message-unread-p ()
 411   "Predicate testing whether current message is unread."
 412   (member "unread" (notmuch-show-get-tags)))
 413
 414 (defun notmuch-show-message-open-p ()
 415   "Predicate testing whether current message is open (body is visible)."
 416   (let ((btn (previous-button (point) t)))
 417     (while (not (button-has-type-p btn 'notmuch-button-body-toggle-type))
 418       (setq btn (previous-button (button-start btn))))
 419     (not (invisible-p (button-get btn 'invisibility-spec)))))
 420
 421 (defun notmuch-show-next-message ()
 422   "Advance to the beginning of the next message in the buffer.
 423
 424 Moves to the last visible character of the current message if
 425 already on the last message in the buffer.
 426
 427 Returns nil if already on the last message in the buffer."
 428   (interactive)
 429   (notmuch-show-move-to-current-message-summary-line)
 430   (if (re-search-forward notmuch-show-message-begin-regexp nil t)
 431       (progn
 432         (notmuch-show-move-to-current-message-summary-line)
 433         (recenter 0)
 434         t)
 435     (goto-char (- (point-max) 1))
 436     (while (point-invisible-p)
 437       (backward-char))
 438     (recenter 0)
 439     nil))
 440
 441 (defun notmuch-show-find-next-message ()
 442   "Returns the position of the next message in the buffer.
 443
 444 Or the position of the last visible character of the current
 445 message if already within the last message in the buffer."
 446   ; save-excursion doesn't save our window position
 447   ; save-window-excursion doesn't save point
 448   ; Looks like we have to use both.
 449   (save-excursion
 450     (save-window-excursion
 451       (notmuch-show-next-message)
 452       (point))))
 453
 454 (defun notmuch-show-next-unread-message ()
 455   "Advance to the beginning of the next unread message in the buffer.
 456
 457 Moves to the last visible character of the current message if
 458 there are no more unread messages past the current point."
 459   (notmuch-show-next-message)
 460   (while (and (not (notmuch-show-last-message-p))
 461               (not (notmuch-show-message-unread-p)))
 462     (notmuch-show-next-message))
 463   (if (not (notmuch-show-message-unread-p))
 464       (notmuch-show-next-message)))
 465
 466 (defun notmuch-show-next-open-message ()
 467   "Advance to the next open message (that is, body is not invisible)."
 468   (while (and (notmuch-show-next-message)
 469               (not (notmuch-show-message-open-p)))))
 470
 471 (defun notmuch-show-previous-message ()
 472   "Backup to the beginning of the previous message in the buffer.
 473
 474 If within a message rather than at the beginning of it, then
 475 simply move to the beginning of the current message."
 476   (interactive)
 477   (let ((start (point)))
 478     (notmuch-show-move-to-current-message-summary-line)
 479     (if (not (< (point) start))
 480         ; Go backward twice to skip the current message's marker
 481         (progn
 482           (re-search-backward notmuch-show-message-begin-regexp nil t)
 483           (re-search-backward notmuch-show-message-begin-regexp nil t)
 484           (notmuch-show-move-to-current-message-summary-line)
 485           ))
 486     (recenter 0)))
 487
 488 (defun notmuch-show-find-previous-message ()
 489   "Returns the position of the previous message in the buffer.
 490
 491 Or the position of the beginning of the current message if point
 492 is originally within the message rather than at the beginning of
 493 it."
 494   ; save-excursion doesn't save our window position
 495   ; save-window-excursion doesn't save point
 496   ; Looks like we have to use both.
 497   (save-excursion
 498     (save-window-excursion
 499       (notmuch-show-previous-message)
 500       (point))))
 501
 502 (defun notmuch-show-mark-read-then-next-open-message ()
 503   "Remove unread tag from this message, then advance to next open message."
 504   (interactive)
 505   (notmuch-show-remove-tag "unread")
 506   (notmuch-show-next-open-message))
 507
 508 (defun notmuch-show-rewind ()
 509   "Backup through the thread, (reverse scrolling compared to \\[notmuch-show-advance-marking-read-and-archiving]).
 510
 511 Specifically, if the beginning of the previous email is fewer
 512 than `window-height' lines from the current point, move to it
 513 just like `notmuch-show-previous-message'.
 514
 515 Otherwise, just scroll down a screenful of the current message.
 516
 517 This command does not modify any message tags, (it does not undo
 518 any effects from previous calls to
 519 `notmuch-show-advance-marking-read-and-archiving'."
 520   (interactive)
 521   (let ((previous (notmuch-show-find-previous-message)))
 522     (if (> (count-lines previous (point)) (- (window-height) next-screen-context-lines))
 523         (progn
 524           (condition-case nil
 525               (scroll-down nil)
 526             ((beginning-of-buffer) nil))
 527           (goto-char (window-start)))
 528       (notmuch-show-previous-message))))
 529
 530 (defun notmuch-show-advance-marking-read-and-archiving ()
 531   "Advance through thread, marking read and archiving.
 532
 533 This command is intended to be one of the simplest ways to
 534 process a thread of email. It does the following:
 535
 536 If the current message in the thread is not yet fully visible,
 537 scroll by a near screenful to read more of the message.
 538
 539 Otherwise, (the end of the current message is already within the
 540 current window), remove the \"unread\" tag (if present) from the
 541 current message and advance to the next open message.
 542
 543 Finally, if there is no further message to advance to, and this
 544 last message is already read, then archive the entire current
 545 thread, (remove the \"inbox\" tag from each message). Also kill
 546 this buffer, and display the next thread from the search from
 547 which this thread was originally shown."
 548   (interactive)
 549   (let ((next (notmuch-show-find-next-message))
 550         (unread (notmuch-show-message-unread-p)))
 551     (if (> next (window-end))
 552         (scroll-up nil)
 553       (let ((last (notmuch-show-last-message-p)))
 554         (notmuch-show-mark-read-then-next-open-message)
 555         (if last
 556             (notmuch-show-archive-thread))))))
 557
 558 (defun notmuch-show-next-button ()
 559   "Advance point to the next button in the buffer."
 560   (interactive)
 561   (goto-char (button-start (next-button (point)))))
 562
 563 (defun notmuch-show-previous-button ()
 564   "Move point back to the previous button in the buffer."
 565   (interactive)
 566   (goto-char (button-start (previous-button (point)))))
 567
 568 (defun notmuch-toggle-invisible-action (cite-button)
 569   (let ((invis-spec (button-get cite-button 'invisibility-spec)))
 570         (if (invisible-p invis-spec)
 571             (remove-from-invisibility-spec invis-spec)
 572           (add-to-invisibility-spec invis-spec)
 573           ))
 574   (force-window-update)
 575   (redisplay t))
 576
 577 (define-button-type 'notmuch-button-invisibility-toggle-type 'action 'notmuch-toggle-invisible-action 'follow-link t)
 578 (define-button-type 'notmuch-button-citation-toggle-type 'help-echo "mouse-1, RET: Show citation"
 579   :supertype 'notmuch-button-invisibility-toggle-type)
 580 (define-button-type 'notmuch-button-signature-toggle-type 'help-echo "mouse-1, RET: Show signature"
 581   :supertype 'notmuch-button-invisibility-toggle-type)
 582 (define-button-type 'notmuch-button-headers-toggle-type 'help-echo "mouse-1, RET: Show headers"
 583   :supertype 'notmuch-button-invisibility-toggle-type)
 584 (define-button-type 'notmuch-button-body-toggle-type 'help-echo "mouse-1, RET: Show message"
 585   :supertype 'notmuch-button-invisibility-toggle-type)
 586
 587 (defun notmuch-show-markup-citations-region (beg end depth)
 588   (goto-char beg)
 589   (beginning-of-line)
 590   (while (< (point) end)
 591     (let ((beg-sub (point-marker))
 592           (indent (make-string depth ? ))
 593           (citation "[[:space:]]*>"))
 594       (if (looking-at citation)
 595           (progn
 596             (while (looking-at citation)
 597               (forward-line))
 598             (let ((overlay (make-overlay beg-sub (point)))
 599                   (invis-spec (make-symbol "notmuch-citation-region")))
 600               (add-to-invisibility-spec invis-spec)
 601               (overlay-put overlay 'invisible invis-spec)
 602               (let ((p (point))
 603                     (cite-button-text
 604                      (concat "["  (number-to-string (count-lines beg-sub (point)))
 605                              "-line citation.]")))
 606                 (goto-char (- beg-sub 1))
 607                 (insert (concat "\n" indent))
 608                 (insert-button cite-button-text
 609                                'invisibility-spec invis-spec
 610                                :type 'notmuch-button-citation-toggle-type)
 611                 (insert "\n")
 612                 (goto-char (+ (length cite-button-text) p))
 613               ))))
 614       (move-to-column depth)
 615       (if (looking-at notmuch-show-signature-regexp)
 616           (let ((sig-lines (- (count-lines beg-sub end) 1)))
 617             (if (<= sig-lines notmuch-show-signature-lines-max)
 618                 (progn
 619                   (let ((invis-spec (make-symbol "notmuch-signature-region")))
 620                     (add-to-invisibility-spec invis-spec)
 621                     (overlay-put (make-overlay beg-sub end)
 622                                  'invisible invis-spec)
 623
 624                     (goto-char (- beg-sub 1))
 625                     (insert (concat "\n" indent))
 626                     (let ((sig-button-text (concat "[" (number-to-string sig-lines)
 627                                                    "-line signature.]")))
 628                       (insert-button sig-button-text 'invisibility-spec invis-spec
 629                                      :type 'notmuch-button-signature-toggle-type)
 630                      )
 631                     (insert "\n")
 632                     (goto-char end))))))
 633       (forward-line))))
 634
 635 (defun notmuch-show-markup-part (beg end depth mime-message)
 636   (if (re-search-forward notmuch-show-part-begin-regexp nil t)
 637       (progn
 638         (if (eq mime-message nil)
 639             (let ((filename (notmuch-show-get-filename)))
 640               (with-temp-buffer
 641                 (insert-file-contents filename nil nil nil t)
 642                 (setq mime-message (mm-dissect-buffer)))))
 643         (forward-line)
 644         (let ((part-beg (point-marker)))
 645           (re-search-forward notmuch-show-part-end-regexp)
 646
 647           (let ((part-end (copy-marker (match-beginning 0))))
 648             (goto-char part-end)
 649             (if (not (bolp))
 650                 (insert "\n"))
 651             (indent-rigidly part-beg part-end depth)
 652             (save-excursion
 653               (goto-char part-beg)
 654               (forward-line -1)
 655               (beginning-of-line)
 656               (let ((handle-type (mm-handle-type mime-message))
 657                     mime-type)
 658                 (if (sequencep (car handle-type))
 659                     (setq mime-type (car handle-type))
 660                   (setq mime-type (car (car (cdr handle-type))))
 661                   )
 662                 (if (equal mime-type "text/html")
 663                     (mm-display-part mime-message))))
 664
 665             (notmuch-show-markup-citations-region part-beg part-end depth)
 666             ; Advance to the next part (if any) (so the outer loop can
 667             ; determine whether we've left the current message.
 668             (if (re-search-forward notmuch-show-part-begin-regexp nil t)
 669                 (beginning-of-line)))))
 670     (goto-char end))
 671   mime-message)
 672
 673 (defun notmuch-show-markup-parts-region (beg end depth)
 674   (save-excursion
 675     (goto-char beg)
 676     (let (mime-message)
 677       (while (< (point) end)
 678         (setq mime-message
 679               (notmuch-show-markup-part
 680                beg end depth mime-message))))))
 681
 682 (defun notmuch-show-markup-body (depth btn)
 683   (re-search-forward notmuch-show-body-begin-regexp)
 684   (forward-line)
 685   (let ((beg (point-marker)))
 686     (re-search-forward notmuch-show-body-end-regexp)
 687     (let ((end (copy-marker (match-beginning 0))))
 688       (notmuch-show-markup-parts-region beg end depth)
 689       (let ((invis-spec (make-symbol "notmuch-show-body-read")))
 690         (overlay-put (make-overlay beg end)
 691                      'invisible invis-spec)
 692         (button-put btn 'invisibility-spec invis-spec)
 693         (if (not (notmuch-show-message-unread-p))
 694             (add-to-invisibility-spec invis-spec)))
 695       (set-marker beg nil)
 696       (set-marker end nil)
 697       )))
 698
 699 (defun notmuch-fontify-headers ()
 700   (while (looking-at "[[:space:]]")
 701     (forward-char))
 702   (if (looking-at "[Tt]o:")
 703       (progn
 704         (overlay-put (make-overlay (point) (re-search-forward ":"))
 705                      'face 'message-header-name)
 706         (overlay-put (make-overlay (point) (re-search-forward ".*$"))
 707                      'face 'message-header-to))
 708     (if (looking-at "[B]?[Cc][Cc]:")
 709         (progn
 710           (overlay-put (make-overlay (point) (re-search-forward ":"))
 711                        'face 'message-header-name)
 712           (overlay-put (make-overlay (point) (re-search-forward ".*$"))
 713                        'face 'message-header-cc))
 714       (if (looking-at "[Ss]ubject:")
 715           (progn
 716             (overlay-put (make-overlay (point) (re-search-forward ":"))
 717                          'face 'message-header-name)
 718             (overlay-put (make-overlay (point) (re-search-forward ".*$"))
 719                          'face 'message-header-subject))
 720         (if (looking-at "[Ff]rom:")
 721             (progn
 722               (overlay-put (make-overlay (point) (re-search-forward ":"))
 723                            'face 'message-header-name)
 724               (overlay-put (make-overlay (point) (re-search-forward ".*$"))
 725                            'face 'message-header-other)))))))
 726
 727 (defun notmuch-show-markup-header (depth)
 728   (re-search-forward notmuch-show-header-begin-regexp)
 729   (forward-line)
 730   (let ((beg (point-marker))
 731         (summary-end (copy-marker (line-beginning-position 2)))
 732         (subject-end (copy-marker (line-end-position 2)))
 733         (invis-spec (make-symbol "notmuch-show-header"))
 734         (btn nil))
 735     (re-search-forward notmuch-show-header-end-regexp)
 736     (beginning-of-line)
 737     (let ((end (point-marker)))
 738       (indent-rigidly beg end depth)
 739       (goto-char beg)
 740       (overlay-put (make-overlay (line-beginning-position) summary-end) 'face 'notmuch-message-summary-face)
 741       (setq btn (make-button (line-beginning-position) summary-end :type 'notmuch-button-body-toggle-type))
 742       (forward-line)
 743       (add-to-invisibility-spec invis-spec)
 744       (overlay-put (make-overlay subject-end end)
 745                    'invisible invis-spec)
 746       (make-button (line-beginning-position) subject-end
 747                    'invisibility-spec invis-spec
 748                    :type 'notmuch-button-headers-toggle-type)
 749       (while (looking-at "[[:space:]]*[A-Za-z][-A-Za-z0-9]*:")
 750         (beginning-of-line)
 751         (notmuch-fontify-headers)
 752         (forward-line)
 753         )
 754       (goto-char end)
 755       (insert "\n")
 756       (set-marker beg nil)
 757       (set-marker summary-end nil)
 758       (set-marker subject-end nil)
 759       (set-marker end nil)
 760       )
 761   btn))
 762
 763 (defun notmuch-show-markup-message ()
 764   (if (re-search-forward notmuch-show-message-begin-regexp nil t)
 765       (progn
 766         (re-search-forward notmuch-show-depth-regexp)
 767         (let ((depth (string-to-number (buffer-substring (match-beginning 1) (match-end 1))))
 768               (btn nil))
 769           (setq btn (notmuch-show-markup-header depth))
 770           (notmuch-show-markup-body depth btn)))
 771     (goto-char (point-max))))
 772
 773 (defun notmuch-show-hide-markers ()
 774   (save-excursion
 775     (goto-char (point-min))
 776     (while (not (eobp))
 777       (if (re-search-forward notmuch-show-marker-regexp nil t)
 778           (progn
 779             (overlay-put (make-overlay (match-beginning 0) (+ (match-end 0) 1))
 780                          'invisible 'notmuch-show-marker))
 781         (goto-char (point-max))))))
 782
 783 (defun notmuch-show-markup-messages ()
 784   (save-excursion
 785     (goto-char (point-min))
 786     (while (not (eobp))
 787       (notmuch-show-markup-message)))
 788   (notmuch-show-hide-markers))
 789
 790 (defun notmuch-documentation-first-line (symbol)
 791   "Return the first line of the documentation string for SYMBOL."
 792   (let ((doc (documentation symbol)))
 793     (if doc
 794         (with-temp-buffer
 795           (insert (documentation symbol t))
 796           (goto-char (point-min))
 797           (let ((beg (point)))
 798             (end-of-line)
 799             (buffer-substring beg (point))))
 800       "")))
 801
 802 (defun notmuch-prefix-key-description (key)
 803   "Given a prefix key code, return a human-readable string representation.
 804
 805 This is basically just `format-kbd-macro' but we also convert ESC to M-."
 806   (let ((desc (format-kbd-macro (vector key))))
 807     (if (string= desc "ESC")
 808         "M-"
 809       (concat desc " "))))
 810
 811 ; I would think that emacs would have code handy for walking a keymap
 812 ; and generating strings for each key, and I would prefer to just call
 813 ; that. But I couldn't find any (could be all implemented in C I
 814 ; suppose), so I wrote my own here.
 815 (defun notmuch-substitute-one-command-key-with-prefix (prefix binding)
 816   "For a key binding, return a string showing a human-readable
 817 representation of the prefixed key as well as the first line of
 818 documentation from the bound function.
 819
 820 For a mouse binding, return nil."
 821   (let ((key (car binding))
 822         (action (cdr binding)))
 823     (if (mouse-event-p key)
 824         nil
 825       (if (keymapp action)
 826           (let ((substitute (apply-partially 'notmuch-substitute-one-command-key-with-prefix (notmuch-prefix-key-description key))))
 827             (mapconcat substitute (cdr action) "\n"))
 828         (concat prefix (format-kbd-macro (vector key))
 829                 "\t"
 830                 (notmuch-documentation-first-line action))))))
 831
 832 (defalias 'notmuch-substitute-one-command-key
 833   (apply-partially 'notmuch-substitute-one-command-key-with-prefix nil))
 834
 835 (defun notmuch-substitute-command-keys (doc)
 836   "Like `substitute-command-keys' but with documentation, not function names."
 837   (let ((beg 0))
 838     (while (string-match "\\\\{\\([^}[:space:]]*\\)}" doc beg)
 839       (let ((map (substring doc (match-beginning 1) (match-end 1))))
 840         (setq doc (replace-match (mapconcat 'notmuch-substitute-one-command-key
 841                                             (cdr (symbol-value (intern map))) "\n") 1 1 doc)))
 842       (setq beg (match-end 0)))
 843     doc))
 844
 845 (defun notmuch-help ()
 846   "Display help for the current notmuch mode."
 847   (interactive)
 848   (let* ((mode major-mode)
 849          (doc (substitute-command-keys (notmuch-substitute-command-keys (documentation mode t)))))
 850     (with-current-buffer (generate-new-buffer "*notmuch-help*")
 851       (insert doc)
 852       (goto-char (point-min))
 853       (set-buffer-modified-p nil)
 854       (view-buffer (current-buffer) 'kill-buffer-if-not-modified))))
 855
 856 ;;;###autoload
 857 (defun notmuch-show-mode ()
 858   "Major mode for viewing a thread with notmuch.
 859
 860 This buffer contains the results of the \"notmuch show\" command
 861 for displaying a single thread of email from your email archives.
 862
 863 By default, various components of email messages, (citations,
 864 signatures, already-read messages), are hidden. You can make
 865 these parts visible by clicking with the mouse button or by
 866 pressing RET after positioning the cursor on a hidden part, (for
 867 which \\[notmuch-show-next-button] and \\[notmuch-show-previous-button] are helpful).
 868
 869 Reading the thread sequentially is well-supported by pressing
 870 \\[notmuch-show-advance-marking-read-and-archiving]. This will scroll the current message (if necessary),
 871 advance to the next message, or advance to the next thread (if
 872 already on the last message of a thread). As each message is
 873 scrolled away its \"unread\" tag will be removed, and as each
 874 thread is scrolled away the \"inbox\" tag will be removed from
 875 each message in the thread.
 876
 877 Other commands are available to read or manipulate the thread more
 878 selectively, (such as '\\[notmuch-show-next-message]' and '\\[notmuch-show-previous-message]' to advance to messages without
 879 removing any tags, and '\\[notmuch-show-archive-thread]' to archive an entire thread without
 880 scrolling through with \\[notmuch-show-advance-marking-read-and-archiving]).
 881
 882 You can add or remove arbitary tags from the current message with
 883 '\\[notmuch-show-add-tag]' or '\\[notmuch-show-remove-tag]'.
 884
 885 All currently available key bindings:
 886
 887 \\{notmuch-show-mode-map}"
 888   (interactive)
 889   (kill-all-local-variables)
 890   (add-to-invisibility-spec 'notmuch-show-marker)
 891   (use-local-map notmuch-show-mode-map)
 892   (setq major-mode 'notmuch-show-mode
 893         mode-name "notmuch-show")
 894   (setq buffer-read-only t))
 895
 896 (defgroup notmuch nil
 897   "Notmuch mail reader for Emacs."
 898   :group 'mail)
 899
 900 (defcustom notmuch-show-hook nil
 901   "List of functions to call when notmuch displays a message."
 902   :type 'hook
 903   :options '(goto-address)
 904   :group 'notmuch)
 905
 906 (defcustom notmuch-search-hook nil
 907   "List of functions to call when notmuch displays the search results."
 908   :type 'hook
 909   :options '(hl-line-mode)
 910   :group 'notmuch)
 911
 912 ; Make show mode a bit prettier, highlighting URLs and using word wrap
 913
 914 (defun notmuch-show-pretty-hook ()
 915   (goto-address-mode 1)
 916   (visual-line-mode))
 917
 918 (add-hook 'notmuch-show-hook 'notmuch-show-pretty-hook)
 919 (add-hook 'notmuch-search-hook
 920           (lambda()
 921             (hl-line-mode 1) ))
 922
 923 (defun notmuch-show (thread-id &optional parent-buffer)
 924   "Run \"notmuch show\" with the given thread ID and display results.
 925
 926 The optional PARENT-BUFFER is the notmuch-search buffer from
 927 which this notmuch-show command was executed, (so that the next
 928 thread from that buffer can be show when done with this one)."
 929   (interactive "sNotmuch show: ")
 930   (let ((buffer (get-buffer-create (concat "*notmuch-show-" thread-id "*"))))
 931     (switch-to-buffer buffer)
 932     (notmuch-show-mode)
 933     (set (make-local-variable 'notmuch-show-parent-buffer) parent-buffer)
 934     (let ((proc (get-buffer-process (current-buffer)))
 935           (inhibit-read-only t))
 936       (if proc
 937           (error "notmuch search process already running for query `%s'" thread-id)
 938         )
 939       (erase-buffer)
 940       (goto-char (point-min))
 941       (save-excursion
 942         (call-process notmuch-command nil t nil "show" "--entire-thread" thread-id)
 943         (notmuch-show-markup-messages)
 944         )
 945       (run-hooks 'notmuch-show-hook)
 946       ; Move straight to the first unread message
 947       (if (not (notmuch-show-message-unread-p))
 948           (progn
 949             (notmuch-show-next-unread-message)
 950             ; But if there are no unread messages, go back to the
 951             ; beginning of the buffer, and open up the bodies of all
 952             ; read message.
 953             (if (not (notmuch-show-message-unread-p))
 954                 (progn
 955                   (goto-char (point-min))
 956                   (let ((btn (forward-button 1)))
 957                     (while btn
 958                       (if (button-has-type-p btn 'notmuch-button-body-toggle-type)
 959                           (push-button))
 960                       (condition-case err
 961                           (setq btn (forward-button 1))
 962                         (error (setq btn nil)))
 963                     ))
 964                   (goto-char (point-min))
 965                   ))))
 966       )))
 967
 968 (defvar notmuch-search-authors-width 40
 969   "Number of columns to use to display authors in a notmuch-search buffer.")
 970
 971 (defvar notmuch-search-mode-map
 972   (let ((map (make-sparse-keymap)))
 973     (define-key map "?" 'notmuch-help)
 974     (define-key map "q" 'kill-this-buffer)
 975     (define-key map "x" 'kill-this-buffer)
 976     (define-key map (kbd "<DEL>") 'notmuch-search-scroll-down)
 977     (define-key map "b" 'notmuch-search-scroll-down)
 978     (define-key map " " 'notmuch-search-scroll-up)
 979     (define-key map "<" 'notmuch-search-first-thread)
 980     (define-key map ">" 'notmuch-search-last-thread)
 981     (define-key map "p" 'notmuch-search-previous-thread)
 982     (define-key map "n" 'notmuch-search-next-thread)
 983     (define-key map "r" 'notmuch-search-reply-to-thread)
 984     (define-key map "m" 'message-mail)
 985     (define-key map "s" 'notmuch-search)
 986     (define-key map "o" 'notmuch-search-toggle-order)
 987     (define-key map "=" 'notmuch-search-refresh-view)
 988     (define-key map "t" 'notmuch-search-filter-by-tag)
 989     (define-key map "f" 'notmuch-search-filter)
 990     (define-key map [mouse-1] 'notmuch-search-show-thread)
 991     (define-key map "*" 'notmuch-search-operate-all)
 992     (define-key map "a" 'notmuch-search-archive-thread)
 993     (define-key map "-" 'notmuch-search-remove-tag)
 994     (define-key map "+" 'notmuch-search-add-tag)
 995     (define-key map (kbd "RET") 'notmuch-search-show-thread)
 996     map)
 997   "Keymap for \"notmuch search\" buffers.")
 998 (fset 'notmuch-search-mode-map notmuch-search-mode-map)
 999
1000 (defvar notmuch-search-query-string)
1001 (defvar notmuch-search-oldest-first t
1002   "Show the oldest mail first in the search-mode")
1003
1004 (defun notmuch-search-scroll-up ()
1005   "Move forward through search results by one window's worth."
1006   (interactive)
1007   (condition-case nil
1008       (scroll-up nil)
1009     ((end-of-buffer) (notmuch-search-last-thread))))
1010
1011 (defun notmuch-search-scroll-down ()
1012   "Move backward through the search results by one window's worth."
1013   (interactive)
1014   ; I don't know why scroll-down doesn't signal beginning-of-buffer
1015   ; the way that scroll-up signals end-of-buffer, but c'est la vie.
1016   ;
1017   ; So instead of trapping a signal we instead check whether the
1018   ; window begins on the first line of the buffer and if so, move
1019   ; directly to that position. (We have to count lines since the
1020   ; window-start position is not the same as point-min due to the
1021   ; invisible thread-ID characters on the first line.
1022   (if (equal (count-lines (point-min) (window-start)) 0)
1023       (goto-char (point-min))
1024     (scroll-down nil)))
1025
1026 (defun notmuch-search-next-thread ()
1027   "Select the next thread in the search results."
1028   (interactive)
1029   (forward-line 1))
1030
1031 (defun notmuch-search-previous-thread ()
1032   "Select the previous thread in the search results."
1033   (interactive)
1034   (forward-line -1))
1035
1036 (defun notmuch-search-last-thread ()
1037   "Select the last thread in the search results."
1038   (interactive)
1039   (goto-char (point-max))
1040   (forward-line -2))
1041
1042 (defun notmuch-search-first-thread ()
1043   "Select the first thread in the search results."
1044   (interactive)
1045   (goto-char (point-min)))
1046
1047 (defface notmuch-message-summary-face
1048  '((((class color) (background light)) (:background "#f0f0f0"))
1049    (((class color) (background dark)) (:background "#303030")))
1050  "Face for the single-line message summary in notmuch-show-mode."
1051  :group 'notmuch)
1052
1053 (defface notmuch-tag-face
1054   '((((class color)
1055       (background dark))
1056      (:foreground "OliveDrab1"))
1057     (((class color)
1058       (background light))
1059      (:foreground "navy blue" :bold t))
1060     (t
1061      (:bold t)))
1062   "Notmuch search mode face used to highligh tags."
1063   :group 'notmuch)
1064
1065 (defvar notmuch-tag-face-alist nil
1066   "List containing the tag list that need to be highlighed")
1067
1068 (defvar notmuch-search-font-lock-keywords  nil)
1069
1070 ;;;###autoload
1071 (defun notmuch-search-mode ()
1072   "Major mode displaying results of a notmuch search.
1073
1074 This buffer contains the results of a \"notmuch search\" of your
1075 email archives. Each line in the buffer represents a single
1076 thread giving a summary of the thread (a relative date, the
1077 number of matched messages and total messages in the thread,
1078 participants in the thread, a representative subject line, and
1079 any tags).
1080
1081 Pressing \\[notmuch-search-show-thread] on any line displays that thread. The '\\[notmuch-search-add-tag]' and '\\[notmuch-search-remove-tag]'
1082 keys can be used to add or remove tags from a thread. The '\\[notmuch-search-archive-thread]' key
1083 is a convenience for archiving a thread (removing the \"inbox\"
1084 tag). The '\\[notmuch-search-operate-all]' key can be used to add or remove a tag from all
1085 threads in the current buffer.
1086
1087 Other useful commands are '\\[notmuch-search-filter]' for filtering the current search
1088 based on an additional query string, '\\[notmuch-search-filter-by-tag]' for filtering to include
1089 only messages with a given tag, and '\\[notmuch-search]' to execute a new, global
1090 search.
1091
1092 Complete list of currently available key bindings:
1093
1094 \\{notmuch-search-mode-map}"
1095   (interactive)
1096   (kill-all-local-variables)
1097   (make-local-variable 'notmuch-search-query-string)
1098   (make-local-variable 'notmuch-search-oldest-first)
1099   (set (make-local-variable 'scroll-preserve-screen-position) t)
1100   (add-to-invisibility-spec 'notmuch-search)
1101   (use-local-map notmuch-search-mode-map)
1102   (setq truncate-lines t)
1103   (setq major-mode 'notmuch-search-mode
1104         mode-name "notmuch-search")
1105   (setq buffer-read-only t)
1106   (if (not notmuch-tag-face-alist)
1107       (add-to-list 'notmuch-search-font-lock-keywords (list
1108                 "(\\([^)]*\\))$" '(1  'notmuch-tag-face)))
1109     (let ((notmuch-search-tags (mapcar 'car notmuch-tag-face-alist)))
1110       (loop for notmuch-search-tag  in notmuch-search-tags
1111             do (add-to-list 'notmuch-search-font-lock-keywords (list
1112                         (concat "([^)]*\\(" notmuch-search-tag "\\)[^)]*)$")
1113                         `(1  ,(cdr (assoc notmuch-search-tag notmuch-tag-face-alist))))))))
1114   (set (make-local-variable 'font-lock-defaults)
1115          '(notmuch-search-font-lock-keywords t)))
1116
1117 (defun notmuch-search-find-thread-id ()
1118   "Return the thread for the current thread"
1119   (get-text-property (point) 'notmuch-search-thread-id))
1120
1121 (defun notmuch-search-show-thread ()
1122   "Display the currently selected thread."
1123   (interactive)
1124   (let ((thread-id (notmuch-search-find-thread-id)))
1125     (if (> (length thread-id) 0)
1126         (notmuch-show thread-id (current-buffer))
1127       (error "End of search results"))))
1128
1129 (defun notmuch-search-reply-to-thread ()
1130   "Begin composing a reply to the entire current thread in a new buffer."
1131   (interactive)
1132   (let ((message-id (notmuch-search-find-thread-id)))
1133     (notmuch-reply message-id)))
1134
1135 (defun notmuch-call-notmuch-process (&rest args)
1136   "Synchronously invoke \"notmuch\" with the given list of arguments.
1137
1138 Output from the process will be presented to the user as an error
1139 and will also appear in a buffer named \"*Notmuch errors*\"."
1140   (let ((error-buffer (get-buffer-create "*Notmuch errors*")))
1141     (with-current-buffer error-buffer
1142         (erase-buffer))
1143     (if (eq (apply 'call-process notmuch-command nil error-buffer nil args) 0)
1144         (point)
1145       (progn
1146         (with-current-buffer error-buffer
1147           (let ((beg (point-min))
1148                 (end (- (point-max) 1)))
1149             (error (buffer-substring beg end))
1150             ))))))
1151
1152 (defun notmuch-search-set-tags (tags)
1153   (save-excursion
1154     (end-of-line)
1155     (re-search-backward "(")
1156     (forward-char)
1157     (let ((beg (point))
1158           (inhibit-read-only t))
1159       (re-search-forward ")")
1160       (backward-char)
1161       (let ((end (point)))
1162         (delete-region beg end)
1163         (insert (mapconcat  'identity tags " "))))))
1164
1165 (defun notmuch-search-get-tags ()
1166   (save-excursion
1167     (end-of-line)
1168     (re-search-backward "(")
1169     (let ((beg (+ (point) 1)))
1170       (re-search-forward ")")
1171       (let ((end (- (point) 1)))
1172         (split-string (buffer-substring beg end))))))
1173
1174 (defun notmuch-search-add-tag (tag)
1175   "Add a tag to the currently selected thread.
1176
1177 The tag is added to messages in the currently selected thread
1178 which match the current search terms."
1179   (interactive
1180    (list (notmuch-select-tag-with-completion "Tag to add: ")))
1181   (notmuch-call-notmuch-process "tag" (concat "+" tag) (notmuch-search-find-thread-id) " and " notmuch-search-query-string)
1182   (notmuch-search-set-tags (delete-dups (sort (cons tag (notmuch-search-get-tags)) 'string<))))
1183
1184 (defun notmuch-search-remove-tag (tag)
1185   "Remove a tag from the currently selected thread.
1186
1187 The tag is removed from messages in the currently selected thread
1188 which match the current search terms."
1189   (interactive
1190    (list (notmuch-select-tag-with-completion "Tag to remove: " (notmuch-search-find-thread-id))))
1191   (notmuch-call-notmuch-process "tag" (concat "-" tag) (notmuch-search-find-thread-id) " and " notmuch-search-query-string)
1192   (notmuch-search-set-tags (delete tag (notmuch-search-get-tags))))
1193
1194 (defun notmuch-search-archive-thread ()
1195   "Archive the currently selected thread (remove its \"inbox\" tag).
1196
1197 This function advances the next thread when finished."
1198   (interactive)
1199   (notmuch-search-remove-tag "inbox")
1200   (forward-line))
1201
1202 (defun notmuch-search-process-sentinel (proc msg)
1203   "Add a message to let user know when \"notmuch search\" exits"
1204   (let ((buffer (process-buffer proc))
1205         (status (process-status proc))
1206         (exit-status (process-exit-status proc)))
1207     (if (memq status '(exit signal))
1208         (if (buffer-live-p buffer)
1209             (with-current-buffer buffer
1210               (save-excursion
1211                 (let ((inhibit-read-only t))
1212                   (goto-char (point-max))
1213                   (if (eq status 'signal)
1214                       (insert "Incomplete search results (search process was killed).\n"))
1215                   (if (eq status 'exit)
1216                       (progn
1217                         (insert "End of search results.")
1218                         (if (not (= exit-status 0))
1219                             (insert (format " (process returned %d)" exit-status)))
1220                         (insert "\n"))))))))))
1221
1222 (defun notmuch-search-process-filter (proc string)
1223   "Process and filter the output of \"notmuch search\""
1224   (let ((buffer (process-buffer proc)))
1225     (if (buffer-live-p buffer)
1226         (with-current-buffer buffer
1227           (save-excursion
1228             (let ((line 0)
1229                   (more t)
1230                   (inhibit-read-only t))
1231               (while more
1232                 (if (string-match "^\\(thread:[0-9A-Fa-f]*\\) \\(.*\\) \\(\\[[0-9/]*\\]\\) \\([^:]*\\); \\(.*\\) (\\([^()]*\\))$" string line)
1233                     (let* ((thread-id (match-string 1 string))
1234                            (date (match-string 2 string))
1235                            (count (match-string 3 string))
1236                            (authors (match-string 4 string))
1237                            (authors-length (length authors))
1238                            (subject (match-string 5 string))
1239                            (tags (match-string 6 string)))
1240                       (if (> authors-length 40)
1241                           (set 'authors (concat (substring authors 0 (- 40 3)) "...")))
1242                       (goto-char (point-max))
1243                       (let ((beg (point-marker)))
1244                         (insert (format "%s %-7s %-40s %s (%s)\n" date count authors subject tags))
1245                         (put-text-property beg (point-marker) 'notmuch-search-thread-id thread-id))
1246                       (set 'line (match-end 0)))
1247                   (set 'more nil))))))
1248       (delete-process proc))))
1249
1250 (defun notmuch-search-operate-all (action)
1251   "Add/remove tags from all matching messages.
1252
1253 Tis command adds or removes tags from all messages matching the
1254 current search terms. When called interactively, this command
1255 will prompt for tags to be added or removed. Tags prefixed with
1256 '+' will be added and tags prefixed with '-' will be removed.
1257
1258 Each character of the tag name may consist of alphanumeric
1259 characters as well as `_.+-'.
1260 "
1261   (interactive "sOperation (+add -drop): notmuch tag ")
1262   (let ((action-split (split-string action " +")))
1263     ;; Perform some validation
1264     (let ((words action-split))
1265       (when (null words) (error "No operation given"))
1266       (while words
1267         (unless (string-match-p "^[-+][-+_.[:word:]]+$" (car words))
1268           (error "Action must be of the form `+thistag -that_tag'"))
1269         (setq words (cdr words))))
1270     (apply 'notmuch-call-notmuch-process "tag"
1271            (append action-split (list notmuch-search-query-string) nil))))
1272
1273 ;;;###autoload
1274 (defun notmuch-search (query &optional oldest-first)
1275   "Run \"notmuch search\" with the given query string and display results."
1276   (interactive "sNotmuch search: ")
1277   (let ((buffer (get-buffer-create (concat "*notmuch-search-" query "*"))))
1278     (switch-to-buffer buffer)
1279     (notmuch-search-mode)
1280     (set 'notmuch-search-query-string query)
1281     (set 'notmuch-search-oldest-first oldest-first)
1282     (let ((proc (get-buffer-process (current-buffer)))
1283           (inhibit-read-only t))
1284       (if proc
1285           (error "notmuch search process already running for query `%s'" query)
1286         )
1287       (erase-buffer)
1288       (goto-char (point-min))
1289       (save-excursion
1290         (let ((proc (start-process-shell-command
1291                      "notmuch-search" buffer notmuch-command "search"
1292                      (if oldest-first "--sort=oldest-first" "--sort=newest-first")
1293                      (shell-quote-argument query))))
1294           (set-process-sentinel proc 'notmuch-search-process-sentinel)
1295           (set-process-filter proc 'notmuch-search-process-filter))))
1296     (run-hooks 'notmuch-search-hook)))
1297
1298 (defun notmuch-search-refresh-view ()
1299   "Refresh the current view.
1300
1301 Kills the current buffer and runs a new search with the same
1302 query string as the current search. If the current thread is in
1303 the new search results, then point will be placed on the same
1304 thread. Otherwise, point will be moved to attempt to be in the
1305 same relative position within the new buffer."
1306   (interactive)
1307   (let ((here (point))
1308         (oldest-first notmuch-search-oldest-first)
1309         (thread (notmuch-search-find-thread-id))
1310         (query notmuch-search-query-string))
1311     (kill-this-buffer)
1312     (notmuch-search query oldest-first)
1313     (goto-char (point-min))
1314     (if (re-search-forward (concat "^" thread) nil t)
1315         (beginning-of-line)
1316       (goto-char here))))
1317
1318 (defun notmuch-search-toggle-order ()
1319   "Toggle the current search order.
1320
1321 By default, the \"inbox\" view created by `notmuch' is displayed
1322 in chronological order (oldest thread at the beginning of the
1323 buffer), while any global searches created by `notmuch-search'
1324 are displayed in reverse-chronological order (newest thread at
1325 the beginning of the buffer).
1326
1327 This command toggles the sort order for the current search.
1328
1329 Note that any filtered searches created by
1330 `notmuch-search-filter' retain the search order of the parent
1331 search."
1332   (interactive)
1333   (set 'notmuch-search-oldest-first (not notmuch-search-oldest-first))
1334   (notmuch-search-refresh-view))
1335
1336 (defun notmuch-search-filter (query)
1337   "Filter the current search results based on an additional query string.
1338
1339 Runs a new search matching only messages that match both the
1340 current search results AND the additional query string provided."
1341   (interactive "sFilter search: ")
1342   (notmuch-search (concat notmuch-search-query-string " and " query) notmuch-search-oldest-first))
1343
1344 (defun notmuch-search-filter-by-tag (tag)
1345   "Filter the current search results based on a single tag.
1346
1347 Runs a new search matching only messages that match both the
1348 current search results AND that are tagged with the given tag."
1349   (interactive
1350    (list (notmuch-select-tag-with-completion "Filter by tag: ")))
1351   (notmuch-search (concat notmuch-search-query-string " and tag:" tag) notmuch-search-oldest-first))
1352
1353
1354 ;;;###autoload
1355 (defun notmuch ()
1356   "Run notmuch to display all mail with tag of 'inbox'"
1357   (interactive)
1358   (notmuch-search "tag:inbox" notmuch-search-oldest-first))
1359
1360 (setq mail-user-agent 'message-user-agent)
1361
1362 (defvar notmuch-folder-mode-map
1363   (let ((map (make-sparse-keymap)))
1364     (define-key map "?" 'notmuch-help)
1365     (define-key map "x" 'kill-this-buffer)
1366     (define-key map "q" 'kill-this-buffer)
1367     (define-key map ">" 'notmuch-folder-last)
1368     (define-key map "<" 'notmuch-folder-first)
1369     (define-key map "=" 'notmuch-folder)
1370     (define-key map "s" 'notmuch-search)
1371     (define-key map [mouse-1] 'notmuch-folder-show-search)
1372     (define-key map (kbd "RET") 'notmuch-folder-show-search)
1373     (define-key map "p" 'notmuch-folder-previous)
1374     (define-key map "n" 'notmuch-folder-next)
1375     map)
1376   "Keymap for \"notmuch folder\" buffers.")
1377
1378 (fset 'notmuch-folder-mode-map notmuch-folder-mode-map)
1379
1380 (defcustom notmuch-folders (quote (("inbox" . "tag:inbox") ("unread" . "tag:unread")))
1381   "List of searches for the notmuch folder view"
1382   :type '(alist :key-type (string) :value-type (string))
1383   :group 'notmuch)
1384
1385 (defun notmuch-folder-mode ()
1386   "Major mode for showing notmuch 'folders'.
1387
1388 This buffer contains a list of message counts returned by a
1389 customizable set of searches of your email archives. Each line in
1390 the buffer shows the name of a saved search and the resulting
1391 message count.
1392
1393 Pressing RET on any line opens a search window containing the
1394 results for the saved search on that line.
1395
1396 Here is an example of how the search list could be
1397 customized, (the following text would be placed in your ~/.emacs
1398 file):
1399
1400 (setq notmuch-folders '((\"inbox\" . \"tag:inbox\")
1401                         (\"unread\" . \"tag:inbox AND tag:unread\")
1402                         (\"notmuch\" . \"tag:inbox AND to:notmuchmail.org\")))
1403
1404 Of course, you can have any number of folders, each configured
1405 with any supported search terms (see \"notmuch help search-terms\").
1406
1407 Currently available key bindings:
1408
1409 \\{notmuch-folder-mode-map}"
1410   (interactive)
1411   (kill-all-local-variables)
1412   (use-local-map 'notmuch-folder-mode-map)
1413   (setq truncate-lines t)
1414   (hl-line-mode 1)
1415   (setq major-mode 'notmuch-folder-mode
1416         mode-name "notmuch-folder")
1417   (setq buffer-read-only t))
1418
1419 (defun notmuch-folder-next ()
1420   "Select the next folder in the list."
1421   (interactive)
1422   (forward-line 1)
1423   (if (eobp)
1424       (forward-line -1)))
1425
1426 (defun notmuch-folder-previous ()
1427   "Select the previous folder in the list."
1428   (interactive)
1429   (forward-line -1))
1430
1431 (defun notmuch-folder-first ()
1432   "Select the first folder in the list."
1433   (interactive)
1434   (goto-char (point-min)))
1435
1436 (defun notmuch-folder-last ()
1437   "Select the last folder in the list."
1438   (interactive)
1439   (goto-char (point-max))
1440   (forward-line -1))
1441
1442 (defun notmuch-folder-add (folders)
1443   (if folders
1444       (let ((name (car (car folders)))
1445             (inhibit-read-only t)
1446             (search (cdr (car folders))))
1447         (insert name)
1448         (indent-to 16 1)
1449         (call-process notmuch-command nil t nil "count" search)
1450         (notmuch-folder-add (cdr folders)))))
1451
1452 (defun notmuch-folder-find-name ()
1453   (save-excursion
1454     (beginning-of-line)
1455     (let ((beg (point)))
1456       (forward-word)
1457       (filter-buffer-substring beg (point)))))
1458
1459 (defun notmuch-folder-show-search (&optional folder)
1460   "Show a search window for the search related to the specified folder."
1461   (interactive)
1462   (if (null folder)
1463       (setq folder (notmuch-folder-find-name)))
1464   (let ((search (assoc folder notmuch-folders)))
1465     (if search
1466         (notmuch-search (cdr search) notmuch-search-oldest-first))))
1467
1468 ;;;###autoload
1469 (defun notmuch-folder ()
1470   "Show the notmuch folder view and update the displayed counts."
1471   (interactive)
1472   (let ((buffer (get-buffer-create "*notmuch-folders*")))
1473     (switch-to-buffer buffer)
1474     (let ((inhibit-read-only t)
1475           (n (line-number-at-pos)))
1476       (erase-buffer)
1477       (notmuch-folder-mode)
1478       (notmuch-folder-add notmuch-folders)
1479       (goto-char (point-min))
1480       (goto-line n))))
1481
1482 (provide 'notmuch)