bc75f06e3ab8294e39416c73acd5e84a79823892
[notmuch] / test / test-lib.el
1 ;; test-lib.el --- auxiliary stuff for Notmuch Emacs tests.
2 ;;
3 ;; Copyright © Carl Worth
4 ;; Copyright © David Edmondson
5 ;;
6 ;; This file is part of Notmuch test suit.
7 ;;
8 ;; Notmuch is free software: you can redistribute it and/or modify it
9 ;; under the terms of the GNU General Public License as published by
10 ;; the Free Software Foundation, either version 3 of the License, or
11 ;; (at your option) any later version.
12 ;;
13 ;; Notmuch is distributed in the hope that it will be useful, but
14 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
16 ;; General Public License for more details.
17 ;;
18 ;; You should have received a copy of the GNU General Public License
19 ;; along with Notmuch.  If not, see <http://www.gnu.org/licenses/>.
20 ;;
21 ;; Authors: Dmitry Kurochkin <dmitry.kurochkin@gmail.com>
22
23 (require 'cl)   ;; This code is generally used uncompiled.
24
25 ;; `read-file-name' by default uses `completing-read' function to read
26 ;; user input.  It does not respect `standard-input' variable which we
27 ;; use in tests to provide user input.  So replace it with a plain
28 ;; `read' call.
29 (setq read-file-name-function (lambda (&rest _) (read)))
30
31 ;; Work around a bug in emacs 23.1 and emacs 23.2 which prevents
32 ;; noninteractive (kill-emacs) from emacsclient.
33 (if (and (= emacs-major-version 23) (< emacs-minor-version 3))
34   (defadvice kill-emacs (before disable-yes-or-no-p activate)
35     "Disable yes-or-no-p before executing kill-emacs"
36     (defun yes-or-no-p (prompt) t)))
37
38 (defun notmuch-test-wait ()
39   "Wait for process completion."
40   (while (get-buffer-process (current-buffer))
41     (sleep-for 0.1)))
42
43 (defun test-output (&optional filename)
44   "Save current buffer to file FILENAME.  Default FILENAME is OUTPUT."
45   (write-region (point-min) (point-max) (or filename "OUTPUT")))
46
47 (defun test-visible-output (&optional filename)
48   "Save visible text in current buffer to file FILENAME.  Default
49 FILENAME is OUTPUT."
50   (let ((text (visible-buffer-string)))
51     (with-temp-file (or filename "OUTPUT") (insert text))))
52
53 (defun visible-buffer-string ()
54   "Same as `buffer-string', but excludes invisible text."
55   (visible-buffer-substring (point-min) (point-max)))
56
57 (defun visible-buffer-substring (start end)
58   "Same as `buffer-substring', but excludes invisible text."
59   (let (str)
60     (while (< start end)
61       (let ((next-pos (next-char-property-change start end)))
62         (when (not (invisible-p start))
63           (setq str (concat str (buffer-substring start next-pos))))
64         (setq start next-pos)))
65     str))
66
67 (defun orphan-watchdog (pid)
68   "Periodically check that the process with id PID is still
69 running, quit if it terminated."
70   (if (not (process-attributes pid))
71       (kill-emacs)
72     (run-at-time "1 min" nil 'orphan-watchdog pid)))
73
74 (defun hook-counter (hook)
75   "Count how many times a hook is called.  Increments
76 `hook'-counter variable value if it is bound, otherwise does
77 nothing."
78   (let ((counter (intern (concat (symbol-name hook) "-counter"))))
79     (if (boundp counter)
80         (set counter (1+ (symbol-value counter))))))
81
82 (defun add-hook-counter (hook)
83   "Add hook to count how many times `hook' is called."
84   (add-hook hook (apply-partially 'hook-counter hook)))
85
86 (add-hook-counter 'notmuch-hello-mode-hook)
87 (add-hook-counter 'notmuch-hello-refresh-hook)
88
89 (defmacro notmuch-test-run (&rest body)
90   "Evaluate a BODY of test expressions and output the result."
91   `(with-temp-buffer
92      (let ((result (progn ,@body)))
93        (insert (if (stringp result)
94                    result
95                  (prin1-to-string result)))
96        (test-output))))
97
98 (defun notmuch-test-report-unexpected (output expected)
99   "Report that the OUTPUT does not match the EXPECTED result."
100   (concat "Expect:\t" (prin1-to-string expected) "\n"
101           "Output:\t" (prin1-to-string output) "\n"))
102
103 (defun notmuch-test-expect-equal (output expected)
104   "Compare OUTPUT with EXPECTED. Report any discrepencies."
105   (if (equal output expected)
106       t
107     (cond
108      ((and (listp output)
109            (listp expected))
110       ;; Reporting the difference between two lists is done by
111       ;; reporting differing elements of OUTPUT and EXPECTED
112       ;; pairwise. This is expected to make analysis of failures
113       ;; simpler.
114       (apply #'concat (loop for o in output
115                             for e in expected
116                             if (not (equal o e))
117                             collect (notmuch-test-report-unexpected o e))))
118
119      (t
120       (notmuch-test-report-unexpected output expected)))))