emacs: add notmuch-address-post-completion-hook
[notmuch] / emacs / notmuch-company.el
1 ;;; notmuch-company.el --- Mail address completion for notmuch via company-mode  -*- lexical-binding: t -*-
2
3 ;; Authors: Trevor Jim <tjim@mac.com>
4 ;;          Michal Sojka <sojkam1@fel.cvut.cz>
5 ;;
6 ;; Keywords: mail, completion
7
8 ;; This program is free software; you can redistribute it and/or modify
9 ;; it under the terms of the GNU General Public License as published by
10 ;; the Free Software Foundation, either version 3 of the License, or
11 ;; (at your option) any later version.
12
13 ;; This program is distributed in the hope that it will be useful,
14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16 ;; GNU General Public License for more details.
17
18 ;; You should have received a copy of the GNU General Public License
19 ;; along with this program.  If not, see <https://www.gnu.org/licenses/>.
20
21 ;;; Commentary:
22
23 ;; To enable this, install company mode (https://company-mode.github.io/)
24 ;;
25 ;; NB company-minimum-prefix-length defaults to 3 so you don't get
26 ;; completion unless you type 3 characters
27
28 ;;; Code:
29
30 (eval-when-compile (require 'cl))
31
32 (defvar notmuch-company-last-prefix nil)
33 (make-variable-buffer-local 'notmuch-company-last-prefix)
34 (declare-function company-begin-backend "company")
35 (declare-function company-grab "company")
36 (declare-function company-mode "company")
37 (declare-function company-manual-begin "company")
38 (defvar company-backends)
39
40 (declare-function notmuch-address-harvest "notmuch-address")
41 (declare-function notmuch-address-harvest-trigger "notmuch-address")
42 (declare-function notmuch-address-matching "notmuch-address")
43 (defvar notmuch-address-full-harvest-finished)
44 (defvar notmuch-address-completion-headers-regexp)
45
46 ;;;###autoload
47 (defun notmuch-company-setup ()
48   (company-mode)
49   (make-local-variable 'company-backends)
50   (setq company-backends '(notmuch-company))
51   ;; Disable automatic company completion unless an internal
52   ;; completion method is configured. Company completion (using
53   ;; internal completion) can still be accessed via standard company
54   ;; functions, e.g., company-complete.
55   (unless (eq notmuch-address-command 'internal)
56     (setq-local company-idle-delay nil)))
57
58 ;;;###autoload
59 (defun notmuch-company (command &optional arg &rest _ignore)
60   "`company-mode' completion back-end for `notmuch'."
61   (interactive (list 'interactive))
62   (require 'company)
63   (let ((case-fold-search t)
64         (completion-ignore-case t))
65     (case command
66       (interactive (company-begin-backend 'notmuch-company))
67       (prefix (and (derived-mode-p 'message-mode)
68                    (looking-back (concat notmuch-address-completion-headers-regexp ".*")
69                                  (line-beginning-position))
70                    (setq notmuch-company-last-prefix (company-grab "[:,][ \t]*\\(.*\\)" 1 (point-at-bol)))))
71       (candidates (cond
72                    (notmuch-address-full-harvest-finished
73                     ;; Update harvested addressed from time to time
74                     (notmuch-address-harvest-trigger)
75                     (notmuch-address-matching arg))
76                    (t
77                     (cons :async
78                           (lambda (callback)
79                             ;; First run quick asynchronous harvest based on what the user entered so far
80                             (notmuch-address-harvest
81                              arg nil
82                              (lambda (_proc _event)
83                                (funcall callback (notmuch-address-matching arg))
84                                ;; Then start the (potentially long-running) full asynchronous harvest if necessary
85                                (notmuch-address-harvest-trigger))))))))
86       (match (if (string-match notmuch-company-last-prefix arg)
87                  (match-end 0)
88                0))
89       (post-completion (run-hook-with-args 'notmuch-address-completion-hook arg))
90       (no-cache t))))
91
92
93 (provide 'notmuch-company)
94
95 ;;; notmuch-company.el ends here