Merge branch 'release'
[notmuch] / emacs / notmuch-company.el
1 ;;; notmuch-company.el --- Mail address completion for notmuch via company-mode  -*- lexical-binding: t -*-
2
3 ;; Authors: Trevor Jim <tjim@mac.com>
4 ;;          Michal Sojka <sojkam1@fel.cvut.cz>
5 ;;
6 ;; Keywords: mail, completion
7
8 ;; This program is free software; you can redistribute it and/or modify
9 ;; it under the terms of the GNU General Public License as published by
10 ;; the Free Software Foundation, either version 3 of the License, or
11 ;; (at your option) any later version.
12
13 ;; This program is distributed in the hope that it will be useful,
14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16 ;; GNU General Public License for more details.
17
18 ;; You should have received a copy of the GNU General Public License
19 ;; along with this program.  If not, see <https://www.gnu.org/licenses/>.
20
21 ;;; Commentary:
22
23 ;; To enable this, install company mode (https://company-mode.github.io/)
24 ;;
25 ;; NB company-minimum-prefix-length defaults to 3 so you don't get
26 ;; completion unless you type 3 characters
27
28 ;;; Code:
29
30 (eval-when-compile (require 'cl))
31 (require 'notmuch-lib)
32
33 (defvar notmuch-company-last-prefix nil)
34 (make-variable-buffer-local 'notmuch-company-last-prefix)
35 (declare-function company-begin-backend "company")
36 (declare-function company-grab "company")
37 (declare-function company-mode "company")
38 (declare-function company-manual-begin "company")
39 (defvar company-backends)
40
41 (declare-function notmuch-address-harvest "notmuch-address")
42 (declare-function notmuch-address-harvest-trigger "notmuch-address")
43 (declare-function notmuch-address-matching "notmuch-address")
44 (defvar notmuch-address-full-harvest-finished)
45 (defvar notmuch-address-completion-headers-regexp)
46
47 ;;;###autoload
48 (defun notmuch-company-setup ()
49   (company-mode)
50   (make-local-variable 'company-backends)
51   (setq company-backends '(notmuch-company))
52   ;; Disable automatic company completion unless an internal
53   ;; completion method is configured. Company completion (using
54   ;; internal completion) can still be accessed via standard company
55   ;; functions, e.g., company-complete.
56   (unless (eq notmuch-address-command 'internal)
57     (notmuch-setq-local company-idle-delay nil)))
58
59 ;;;###autoload
60 (defun notmuch-company (command &optional arg &rest _ignore)
61   "`company-mode' completion back-end for `notmuch'."
62   (interactive (list 'interactive))
63   (require 'company)
64   (let ((case-fold-search t)
65         (completion-ignore-case t))
66     (case command
67       (interactive (company-begin-backend 'notmuch-company))
68       (prefix (and (derived-mode-p 'message-mode)
69                    (looking-back (concat notmuch-address-completion-headers-regexp ".*")
70                                  (line-beginning-position))
71                    (setq notmuch-company-last-prefix (company-grab "[:,][ \t]*\\(.*\\)" 1 (point-at-bol)))))
72       (candidates (cond
73                    (notmuch-address-full-harvest-finished
74                     ;; Update harvested addressed from time to time
75                     (notmuch-address-harvest-trigger)
76                     (notmuch-address-matching arg))
77                    (t
78                     (cons :async
79                           (lambda (callback)
80                             ;; First run quick asynchronous harvest based on what the user entered so far
81                             (notmuch-address-harvest
82                              arg nil
83                              (lambda (_proc _event)
84                                (funcall callback (notmuch-address-matching arg))
85                                ;; Then start the (potentially long-running) full asynchronous harvest if necessary
86                                (notmuch-address-harvest-trigger))))))))
87       (match (if (string-match notmuch-company-last-prefix arg)
88                  (match-end 0)
89                0))
90       (post-completion (run-hook-with-args 'notmuch-address-post-completion-functions arg))
91       (no-cache t))))
92
93
94 (provide 'notmuch-company)
95
96 ;;; notmuch-company.el ends here