git.notmuchmail.org Git - notmuch/blob - emacs/notmuch-crypto.el

   1 ;;; notmuch-crypto.el --- functions for handling display of cryptographic metadata.
   2 ;;
   3 ;; Copyright © Jameson Rollins
   4 ;;
   5 ;; This file is part of Notmuch.
   6 ;;
   7 ;; Notmuch is free software: you can redistribute it and/or modify it
   8 ;; under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation, either version 3 of the License, or
  10 ;; (at your option) any later version.
  11 ;;
  12 ;; Notmuch is distributed in the hope that it will be useful, but
  13 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 ;; General Public License for more details.
  16 ;;
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with Notmuch.  If not, see <https://www.gnu.org/licenses/>.
  19 ;;
  20 ;; Authors: Jameson Rollins <jrollins@finestructure.net>
  21
  22 ;;; Code:
  23
  24 (require 'epg)
  25 (require 'notmuch-lib)
  26
  27 (defcustom notmuch-crypto-process-mime t
  28   "Should cryptographic MIME parts be processed?
  29
  30 If this variable is non-nil signatures in multipart/signed
  31 messages will be verified and multipart/encrypted parts will be
  32 decrypted.  The result of the crypto operation will be displayed
  33 in a specially colored header button at the top of the processed
  34 part.  Signed parts will have variously colored headers depending
  35 on the success or failure of the verification process and on the
  36 validity of user ID of the signer.
  37
  38 The effect of setting this variable can be seen temporarily by
  39 providing a prefix when viewing a signed or encrypted message, or
  40 by providing a prefix when reloading the message in notmuch-show
  41 mode."
  42   :type 'boolean
  43   :package-version '(notmuch . "0.25")
  44   :group 'notmuch-crypto)
  45
  46 (defcustom notmuch-crypto-get-keys-asynchronously t
  47   "Retrieve gpg keys asynchronously."
  48   :type 'boolean
  49   :group 'notmuch-crypto)
  50
  51 (defcustom notmuch-crypto-gpg-program epg-gpg-program
  52   "The gpg executable."
  53   :type 'string
  54   :group 'notmuch-crypto)
  55
  56 (defface notmuch-crypto-part-header
  57   '((((class color)
  58       (background dark))
  59      (:foreground "LightBlue1"))
  60     (((class color)
  61       (background light))
  62      (:foreground "blue")))
  63   "Face used for crypto parts headers."
  64   :group 'notmuch-crypto
  65   :group 'notmuch-faces)
  66
  67 (defface notmuch-crypto-signature-good
  68   '((t (:background "green" :foreground "black")))
  69   "Face used for good signatures."
  70   :group 'notmuch-crypto
  71   :group 'notmuch-faces)
  72
  73 (defface notmuch-crypto-signature-good-key
  74   '((t (:background "orange" :foreground "black")))
  75   "Face used for good signatures."
  76   :group 'notmuch-crypto
  77   :group 'notmuch-faces)
  78
  79 (defface notmuch-crypto-signature-bad
  80   '((t (:background "red" :foreground "black")))
  81   "Face used for bad signatures."
  82   :group 'notmuch-crypto
  83   :group 'notmuch-faces)
  84
  85 (defface notmuch-crypto-signature-unknown
  86   '((t (:background "red" :foreground "black")))
  87   "Face used for signatures of unknown status."
  88   :group 'notmuch-crypto
  89   :group 'notmuch-faces)
  90
  91 (defface notmuch-crypto-decryption
  92   '((t (:background "purple" :foreground "black")))
  93   "Face used for encryption/decryption status messages."
  94   :group 'notmuch-crypto
  95   :group 'notmuch-faces)
  96
  97 (define-button-type 'notmuch-crypto-status-button-type
  98   'action (lambda (button) (message (button-get button 'help-echo)))
  99   'follow-link t
 100   'help-echo "Set notmuch-crypto-process-mime to process cryptographic mime parts."
 101   :supertype 'notmuch-button-type)
 102
 103 (defun notmuch-crypto-insert-sigstatus-button (sigstatus from)
 104   "Insert a button describing the signature status SIGSTATUS sent
 105 by user FROM."
 106   (let* ((status (plist-get sigstatus :status))
 107          (show-button t)
 108          (face 'notmuch-crypto-signature-unknown)
 109          (button-action (lambda (button) (message (button-get button 'help-echo))))
 110          (keyid (concat "0x" (plist-get sigstatus :keyid)))
 111          label help-msg)
 112     (cond
 113      ((string= status "good")
 114       (let ((fingerprint (concat "0x" (plist-get sigstatus :fingerprint)))
 115             (userid (plist-get sigstatus :userid)))
 116         ;; If userid is present it has full or greater validity.
 117         (if userid
 118             (setq label (concat "Good signature by: " userid)
 119                   face 'notmuch-crypto-signature-good)
 120           (setq label (concat "Good signature by key: " fingerprint)
 121                 face 'notmuch-crypto-signature-good-key))
 122         (setq button-action 'notmuch-crypto-sigstatus-good-callback
 123               help-msg (concat "Click to list key ID 0x" fingerprint "."))))
 124
 125      ((string= status "error")
 126       (setq label (concat "Unknown key ID " keyid " or unsupported algorithm")
 127             button-action 'notmuch-crypto-sigstatus-error-callback
 128             help-msg (concat "Click to retrieve key ID " keyid
 129                              " from keyserver.")))
 130
 131      ((string= status "bad")
 132       (setq label (concat "Bad signature (claimed key ID " keyid ")")
 133             face 'notmuch-crypto-signature-bad))
 134
 135      (status
 136       (setq label (concat "Unknown signature status: " status)))
 137      (t
 138       (setq show-button nil)))
 139     (when show-button
 140       (insert-button
 141        (concat "[ " label " ]")
 142        :type 'notmuch-crypto-status-button-type
 143        'help-echo help-msg
 144        'face face
 145        'mouse-face face
 146        'action button-action
 147        :notmuch-sigstatus sigstatus
 148        :notmuch-from from)
 149       (insert "\n"))))
 150
 151 (defun notmuch-crypto-sigstatus-good-callback (button)
 152   (let* ((sigstatus (button-get button :notmuch-sigstatus))
 153          (fingerprint (concat "0x" (plist-get sigstatus :fingerprint)))
 154          (buffer (get-buffer-create "*notmuch-crypto-gpg-out*"))
 155          (window (display-buffer buffer)))
 156     (with-selected-window window
 157       (with-current-buffer buffer
 158         (goto-char (point-max))
 159         (call-process notmuch-crypto-gpg-program nil t t "--batch" "--no-tty" "--list-keys" fingerprint))
 160       (recenter -1))))
 161
 162 (declare-function notmuch-show-refresh-view "notmuch-show" (&optional reset-state))
 163
 164 (defun notmuch-crypto--async-key-sentinel (process event)
 165   "When the user asks for a GPG key to be retrieved
 166 asynchronously, handle completion of that task.
 167
 168 If the retrieval is successful, the thread where the retrieval
 169 was initiated is still displayed and the cursor has not moved,
 170 redisplay the thread."
 171   (let ((status (process-status process))
 172         (exit-status (process-exit-status process))
 173         (keyid (process-get process :gpg-key-id)))
 174     (when (memq status '(exit signal))
 175       (message "Getting the GPG key %s asynchronously...%s."
 176                keyid
 177                (if (= exit-status 0)
 178                    "completed"
 179                  "failed"))
 180       ;; If the original buffer is still alive and point didn't move
 181       ;; (i.e. the user didn't move on or away), refresh the buffer to
 182       ;; show the updated signature status.
 183       (let ((show-buffer (process-get process :notmuch-show-buffer))
 184             (show-point (process-get process :notmuch-show-point)))
 185         (when (and (bufferp show-buffer)
 186                    (buffer-live-p show-buffer)
 187                    (= show-point
 188                       (with-current-buffer show-buffer
 189                         (point))))
 190           (with-current-buffer show-buffer
 191             (notmuch-show-refresh-view)))))))
 192
 193 (defun notmuch-crypto--set-button-label (button label)
 194   "Set the text displayed in BUTTON to LABEL."
 195   (save-excursion
 196     (let ((inhibit-read-only t))
 197       ;; This knows rather too much about how we typically format
 198       ;; buttons.
 199       (goto-char (button-start button))
 200       (forward-char 2)
 201       (delete-region (point) (- (button-end button) 2))
 202       (insert label))))
 203
 204 (defun notmuch-crypto-sigstatus-error-callback (button)
 205   "When signature validation has failed, try to retrieve the
 206 corresponding key when the status button is pressed."
 207   (let* ((sigstatus (button-get button :notmuch-sigstatus))
 208          (keyid (concat "0x" (plist-get sigstatus :keyid)))
 209          (buffer (get-buffer-create "*notmuch-crypto-gpg-out*")))
 210     (if notmuch-crypto-get-keys-asynchronously
 211         (progn
 212           (notmuch-crypto--set-button-label
 213            button (format "Retrieving key %s asynchronously..." keyid))
 214           (let ((p (make-process :name "notmuch GPG key retrieval"
 215                                  :buffer buffer
 216                                  :command (list notmuch-crypto-gpg-program "--recv-keys" keyid)
 217                                  :connection-type 'pipe
 218                                  :sentinel #'notmuch-crypto--async-key-sentinel
 219                                  ;; Create the process stopped so that
 220                                  ;; we have time to store the key id,
 221                                  ;; etc. on it.
 222                                  :stop t)))
 223             (process-put p :gpg-key-id keyid)
 224             (process-put p :notmuch-show-buffer (current-buffer))
 225             (process-put p :notmuch-show-point (point))
 226             (message "Getting the GPG key %s asynchronously..." keyid)
 227             (continue-process p)))
 228
 229       (let ((window (display-buffer buffer)))
 230         (with-selected-window window
 231           (with-current-buffer buffer
 232             (goto-char (point-max))
 233             (call-process notmuch-crypto-gpg-program nil t t "--recv-keys" keyid)
 234             (insert "\n")
 235             (call-process notmuch-crypto-gpg-program nil t t "--list-keys" keyid))
 236           (recenter -1))
 237         (notmuch-show-refresh-view)))))
 238
 239 (defun notmuch-crypto-insert-encstatus-button (encstatus)
 240   "Insert a button describing the encryption status ENCSTATUS."
 241   (insert-button
 242    (concat "[ "
 243            (let ((status (plist-get encstatus :status)))
 244              (cond
 245               ((string= status "good")
 246                "Decryption successful")
 247               ((string= status "bad")
 248                "Decryption error")
 249               (t
 250                (concat "Unknown encryption status"
 251                        (if status (concat ": " status))))))
 252            " ]")
 253    :type 'notmuch-crypto-status-button-type
 254    'face 'notmuch-crypto-decryption
 255    'mouse-face 'notmuch-crypto-decryption)
 256   (insert "\n"))
 257
 258 ;;
 259
 260 (provide 'notmuch-crypto)
 261
 262 ;;; notmuch-crypto.el ends here