git.notmuchmail.org Git - notmuch/blob - emacs/notmuch-hello.el

   1 ;; notmuch-hello.el --- welcome to notmuch, a frontend
   2 ;;
   3 ;; Copyright © David Edmondson
   4 ;;
   5 ;; This file is part of Notmuch.
   6 ;;
   7 ;; Notmuch is free software: you can redistribute it and/or modify it
   8 ;; under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation, either version 3 of the License, or
  10 ;; (at your option) any later version.
  11 ;;
  12 ;; Notmuch is distributed in the hope that it will be useful, but
  13 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 ;; General Public License for more details.
  16 ;;
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with Notmuch.  If not, see <http://www.gnu.org/licenses/>.
  19 ;;
  20 ;; Authors: David Edmondson <dme@dme.org>
  21
  22 (eval-when-compile (require 'cl))
  23 (require 'widget)
  24 (require 'wid-edit) ; For `widget-forward'.
  25
  26 (require 'notmuch-lib)
  27 (require 'notmuch-mua)
  28
  29 (declare-function notmuch-search "notmuch" (&optional query oldest-first target-thread target-line continuation))
  30 (declare-function notmuch-poll "notmuch" ())
  31
  32 (defcustom notmuch-hello-recent-searches-max 10
  33   "The number of recent searches to display."
  34   :type 'integer
  35   :group 'notmuch-hello)
  36
  37 (defcustom notmuch-show-empty-saved-searches nil
  38   "Should saved searches with no messages be listed?"
  39   :type 'boolean
  40   :group 'notmuch-hello)
  41
  42 (defun notmuch-sort-saved-searches (alist)
  43   "Generate an alphabetically sorted saved searches alist."
  44   (sort (copy-sequence alist) (lambda (a b) (string< (car a) (car b)))))
  45
  46 (defcustom notmuch-saved-search-sort-function nil
  47   "Function used to sort the saved searches for the notmuch-hello view.
  48
  49 This variable controls how saved searches should be sorted. No
  50 sorting (nil) displays the saved searches in the order they are
  51 stored in `notmuch-saved-searches'. Sort alphabetically sorts the
  52 saved searches in alphabetical order. Custom sort function should
  53 be a function or a lambda expression that takes the saved
  54 searches alist as a parameter, and returns a new saved searches
  55 alist to be used."
  56   :type '(choice (const :tag "No sorting" nil)
  57                  (const :tag "Sort alphabetically" notmuch-sort-saved-searches)
  58                  (function :tag "Custom sort function"
  59                            :value notmuch-sort-saved-searches))
  60   :group 'notmuch-hello)
  61
  62 (defvar notmuch-hello-indent 4
  63   "How much to indent non-headers.")
  64
  65 (defcustom notmuch-show-logo t
  66   "Should the notmuch logo be shown?"
  67   :type 'boolean
  68   :group 'notmuch-hello)
  69
  70 (defcustom notmuch-show-all-tags-list nil
  71   "Should all tags be shown in the notmuch-hello view?"
  72   :type 'boolean
  73   :group 'notmuch-hello)
  74
  75 (defcustom notmuch-hello-tag-list-make-query nil
  76   "Function or string to generate queries for the all tags list.
  77
  78 This variable controls which query results are shown for each tag
  79 in the \"all tags\" list. If nil, it will use all messages with
  80 that tag. If this is set to a string, it is used as a filter for
  81 messages having that tag (equivalent to \"tag:TAG and (THIS-VARIABLE)\").
  82 Finally this can be a function that will be called for each tag and
  83 should return a filter for that tag, or nil to hide the tag."
  84   :type '(choice (const :tag "All messages" nil)
  85                  (const :tag "Unread messages" "tag:unread")
  86                  (string :tag "Custom filter"
  87                          :value "tag:unread")
  88                  (function :tag "Custom filter function"))
  89   :group 'notmuch-hello)
  90
  91 (defcustom notmuch-hello-hide-tags nil
  92   "List of tags to be hidden in the \"all tags\"-section."
  93   :type '(repeat string)
  94   :group 'notmuch-hello)
  95
  96 (defface notmuch-hello-logo-background
  97   '((((class color)
  98       (background dark))
  99      (:background "#5f5f5f"))
 100     (((class color)
 101       (background light))
 102      (:background "white")))
 103   "Background colour for the notmuch logo."
 104   :group 'notmuch-hello
 105   :group 'notmuch-faces)
 106
 107 (defcustom notmuch-column-control t
 108   "Controls the number of columns for saved searches/tags in notmuch view.
 109
 110 This variable has three potential sets of values:
 111
 112 - t: automatically calculate the number of columns possible based
 113   on the tags to be shown and the window width,
 114 - an integer: a lower bound on the number of characters that will
 115   be used to display each column,
 116 - a float: a fraction of the window width that is the lower bound
 117   on the number of characters that should be used for each
 118   column.
 119
 120 So:
 121 - if you would like two columns of tags, set this to 0.5.
 122 - if you would like a single column of tags, set this to 1.0.
 123 - if you would like tags to be 30 characters wide, set this to
 124   30.
 125 - if you don't want to worry about all of this nonsense, leave
 126   this set to `t'."
 127   :type '(choice
 128           (const :tag "Automatically calculated" t)
 129           (integer :tag "Number of characters")
 130           (float :tag "Fraction of window"))
 131   :group 'notmuch-hello)
 132
 133 (defcustom notmuch-hello-thousands-separator " "
 134   "The string used as a thousands separator.
 135
 136 Typically \",\" in the US and UK and \".\" or \" \" in Europe.
 137 The latter is recommended in the SI/ISO 31-0 standard and by the
 138 International Bureau of Weights and Measures."
 139   :type 'string
 140   :group 'notmuch-hello)
 141
 142 (defcustom notmuch-hello-mode-hook nil
 143   "Functions called after entering `notmuch-hello-mode'."
 144   :type 'hook
 145   :group 'notmuch-hello
 146   :group 'notmuch-hooks)
 147
 148 (defcustom notmuch-hello-refresh-hook nil
 149   "Functions called after updating a `notmuch-hello' buffer."
 150   :type 'hook
 151   :group 'notmuch-hello
 152   :group 'notmuch-hooks)
 153
 154 (defvar notmuch-hello-url "http://notmuchmail.org"
 155   "The `notmuch' web site.")
 156
 157 (defvar notmuch-hello-custom-section-options
 158   '((:filter (string :tag "Filter for each tag"))
 159     (:filter-count (string :tag "Different filter to generate message counts"))
 160     (:initially-hidden (const :tag "Hide this section on startup" t))
 161     (:show-empty-searches (const :tag "Show queries with no matching messages" t))
 162     (:hide-if-empty (const :tag "Hide this section if all queries are empty
 163 \(and not shown by show-empty-searches)" t)))
 164   "Various customization-options for notmuch-hello-tags/query-section.")
 165
 166 (define-widget 'notmuch-hello-tags-section 'lazy
 167   "Customize-type for notmuch-hello tag-list sections."
 168   :tag "Customized tag-list section (see docstring for details)"
 169   :type
 170   `(list :tag ""
 171          (const :tag "" notmuch-hello-insert-tags-section)
 172          (string :tag "Title for this section")
 173          (plist
 174           :inline t
 175           :options
 176           ,(append notmuch-hello-custom-section-options
 177                    '((:hide-tags (repeat :tag "Tags that will be hidden"
 178                                          string)))))))
 179
 180 (define-widget 'notmuch-hello-query-section 'lazy
 181   "Customize-type for custom saved-search-like sections"
 182   :tag "Customized queries section (see docstring for details)"
 183   :type
 184   `(list :tag ""
 185          (const :tag "" notmuch-hello-insert-searches)
 186          (string :tag "Title for this section")
 187          (repeat :tag "Queries"
 188                  (cons (string :tag "Name") (string :tag "Query")))
 189          (plist :inline t :options ,notmuch-hello-custom-section-options)))
 190
 191 (defcustom notmuch-hello-sections
 192   (list #'notmuch-hello-insert-header
 193         #'notmuch-hello-insert-saved-searches
 194         #'notmuch-hello-insert-search
 195         #'notmuch-hello-insert-recent-searches
 196         #'notmuch-hello-insert-alltags
 197         #'notmuch-hello-insert-footer)
 198   "Sections for notmuch-hello.
 199
 200 The list contains functions which are used to construct sections in
 201 notmuch-hello buffer.  When notmuch-hello buffer is constructed,
 202 these functions are run in the order they appear in this list.  Each
 203 function produces a section simply by adding content to the current
 204 buffer.  A section should not end with an empty line, because a
 205 newline will be inserted after each section by `notmuch-hello'.
 206
 207 Each function should take no arguments. The return value is
 208 ignored.
 209
 210 For convenience an element can also be a list of the form (FUNC ARG1
 211 ARG2 .. ARGN) in which case FUNC will be applied to the rest of the
 212 list.
 213
 214 A \"Customized tag-list section\" item in the customize-interface
 215 displays a list of all tags, optionally hiding some of them. It
 216 is also possible to filter the list of messages matching each tag
 217 by an additional filter query. Similarly, the count of messages
 218 displayed next to the buttons can be generated by applying a
 219 different filter to the tag query. These filters are also
 220 supported for \"Customized queries section\" items."
 221   :group 'notmuch-hello
 222   :type
 223   '(repeat
 224     (choice (function-item notmuch-hello-insert-header)
 225             (function-item notmuch-hello-insert-saved-searches)
 226             (function-item notmuch-hello-insert-search)
 227             (function-item notmuch-hello-insert-recent-searches)
 228             (function-item notmuch-hello-insert-alltags)
 229             (function-item notmuch-hello-insert-footer)
 230             (function-item notmuch-hello-insert-inbox)
 231             notmuch-hello-tags-section
 232             notmuch-hello-query-section
 233             (function :tag "Custom section"))))
 234
 235 (defcustom notmuch-hello-auto-refresh t
 236   "Automatically refresh when returning to the notmuch-hello buffer."
 237   :group 'notmuch-hello
 238   :type 'boolean)
 239
 240 (defvar notmuch-hello-hidden-sections nil
 241   "List of sections titles whose contents are hidden")
 242
 243 (defvar notmuch-hello-first-run t
 244   "True if `notmuch-hello' is run for the first time, set to nil
 245 afterwards.")
 246
 247 (defun notmuch-hello-nice-number (n)
 248   (let (result)
 249     (while (> n 0)
 250       (push (% n 1000) result)
 251       (setq n (/ n 1000)))
 252     (setq result (or result '(0)))
 253     (apply #'concat
 254      (number-to-string (car result))
 255      (mapcar (lambda (elem)
 256               (format "%s%03d" notmuch-hello-thousands-separator elem))
 257              (cdr result)))))
 258
 259 (defun notmuch-hello-trim (search)
 260   "Trim whitespace."
 261   (if (string-match "^[[:space:]]*\\(.*[^[:space:]]\\)[[:space:]]*$" search)
 262       (match-string 1 search)
 263     search))
 264
 265 (defun notmuch-hello-search (&optional search)
 266   (unless (null search)
 267     (setq search (notmuch-hello-trim search))
 268     (let ((history-delete-duplicates t))
 269       (add-to-history 'notmuch-search-history search)))
 270   (notmuch-search search notmuch-search-oldest-first))
 271
 272 (defun notmuch-saved-search-get (saved-search field)
 273   "Get FIELD from SAVED-SEARCH.
 274
 275 If SAVED-SEARCH is a plist, this is just `plist-get', but for
 276 backwards compatibility, this also deals with the two other
 277 possible formats for SAVED-SEARCH: cons cells (NAME . QUERY) and
 278 lists (NAME QUERY COUNT-QUERY)."
 279   (cond
 280    ((keywordp (car saved-search))
 281     (plist-get saved-search field))
 282    ;; It is not a plist so it is an old-style entry.
 283    ((consp (cdr saved-search)) ;; It is a list (NAME QUERY COUNT-QUERY)
 284     (case field
 285       (:name (first saved-search))
 286       (:query (second saved-search))
 287       (:count-query (third saved-search))
 288       (t nil)))
 289    (t  ;; It is a cons-cell (NAME . QUERY)
 290     (case field
 291       (:name (car saved-search))
 292       (:query (cdr saved-search))
 293       (t nil)))))
 294
 295 (defun notmuch-hello-saved-search-to-plist (saved-search)
 296   "Return a copy of SAVED-SEARCH in plist form.
 297
 298 If saved search is a plist then just return a copy. In other
 299 cases, for backwards compatability, convert to plist form and
 300 return that."
 301   (if (keywordp (car saved-search))
 302       (copy-seq saved-search)
 303     (let ((fields (list :name :query :count-query))
 304           plist-search)
 305       (dolist (field fields plist-search)
 306         (let ((string (notmuch-saved-search-get saved-search field)))
 307           (when string
 308             (setq plist-search (append plist-search (list field string)))))))))
 309
 310 (defun notmuch-hello-add-saved-search (widget)
 311   (interactive)
 312   (let ((search (widget-value
 313                  (symbol-value
 314                   (widget-get widget :notmuch-saved-search-widget))))
 315         (name (completing-read "Name for saved search: "
 316                                notmuch-saved-searches)))
 317     ;; If an existing saved search with this name exists, remove it.
 318     (setq notmuch-saved-searches
 319           (loop for elem in notmuch-saved-searches
 320                 if (not (equal name
 321                                (notmuch-saved-search-get elem :name)))
 322                 collect elem))
 323     ;; Add the new one.
 324     (customize-save-variable 'notmuch-saved-searches
 325                              (add-to-list 'notmuch-saved-searches
 326                                           (list :name name :query search) t))
 327     (message "Saved '%s' as '%s'." search name)
 328     (notmuch-hello-update)))
 329
 330 (defun notmuch-hello-delete-search-from-history (widget)
 331   (interactive)
 332   (let ((search (widget-value
 333                  (symbol-value
 334                   (widget-get widget :notmuch-saved-search-widget)))))
 335     (setq notmuch-search-history (delete search
 336                                          notmuch-search-history))
 337     (notmuch-hello-update)))
 338
 339 (defun notmuch-hello-longest-label (searches-alist)
 340   (or (loop for elem in searches-alist
 341             maximize (length (notmuch-saved-search-get elem :name)))
 342       0))
 343
 344 (defun notmuch-hello-reflect-generate-row (ncols nrows row list)
 345   (let ((len (length list)))
 346     (loop for col from 0 to (- ncols 1)
 347           collect (let ((offset (+ (* nrows col) row)))
 348                     (if (< offset len)
 349                         (nth offset list)
 350                       ;; Don't forget to insert an empty slot in the
 351                       ;; output matrix if there is no corresponding
 352                       ;; value in the input matrix.
 353                       nil)))))
 354
 355 (defun notmuch-hello-reflect (list ncols)
 356   "Reflect a `ncols' wide matrix represented by `list' along the
 357 diagonal."
 358   ;; Not very lispy...
 359   (let ((nrows (ceiling (length list) ncols)))
 360     (loop for row from 0 to (- nrows 1)
 361           append (notmuch-hello-reflect-generate-row ncols nrows row list))))
 362
 363 (defun notmuch-hello-widget-search (widget &rest ignore)
 364   (notmuch-search (widget-get widget
 365                               :notmuch-search-terms)
 366                   (widget-get widget
 367                               :notmuch-search-oldest-first)))
 368
 369 (defun notmuch-saved-search-count (search)
 370   (car (process-lines notmuch-command "count" search)))
 371
 372 (defun notmuch-hello-tags-per-line (widest)
 373   "Determine how many tags to show per line and how wide they
 374 should be. Returns a cons cell `(tags-per-line width)'."
 375   (let ((tags-per-line
 376          (cond
 377           ((integerp notmuch-column-control)
 378            (max 1
 379                 (/ (- (window-width) notmuch-hello-indent)
 380                    ;; Count is 9 wide (8 digits plus space), 1 for the space
 381                    ;; after the name.
 382                    (+ 9 1 (max notmuch-column-control widest)))))
 383
 384           ((floatp notmuch-column-control)
 385            (let* ((available-width (- (window-width) notmuch-hello-indent))
 386                   (proposed-width (max (* available-width notmuch-column-control) widest)))
 387              (floor available-width proposed-width)))
 388
 389           (t
 390            (max 1
 391                 (/ (- (window-width) notmuch-hello-indent)
 392                    ;; Count is 9 wide (8 digits plus space), 1 for the space
 393                    ;; after the name.
 394                    (+ 9 1 widest)))))))
 395
 396     (cons tags-per-line (/ (max 1
 397                                 (- (window-width) notmuch-hello-indent
 398                                    ;; Count is 9 wide (8 digits plus
 399                                    ;; space), 1 for the space after the
 400                                    ;; name.
 401                                    (* tags-per-line (+ 9 1))))
 402                            tags-per-line))))
 403
 404 (defun notmuch-hello-filtered-query (query filter)
 405   "Constructs a query to search all messages matching QUERY and FILTER.
 406
 407 If FILTER is a string, it is directly used in the returned query.
 408
 409 If FILTER is a function, it is called with QUERY as a parameter and
 410 the string it returns is used as the query. If nil is returned,
 411 the entry is hidden.
 412
 413 Otherwise, FILTER is ignored.
 414 "
 415   (cond
 416    ((functionp filter) (funcall filter query))
 417    ((stringp filter)
 418     (concat "(" query ") and (" filter ")"))
 419    (t query)))
 420
 421 (defun notmuch-hello-query-counts (query-list &rest options)
 422   "Compute list of counts of matched messages from QUERY-LIST.
 423
 424 QUERY-LIST must be a list of saved-searches. Ideally each of
 425 these is a plist but other options are available for backwards
 426 compatibility: see `notmuch-saved-searches' for details.
 427
 428 The result is a list of plists each of which includes the
 429 properties :name NAME, :query QUERY and :count COUNT, together
 430 with any properties in the original saved-search.
 431
 432 The values :show-empty-searches, :filter and :filter-count from
 433 options will be handled as specified for
 434 `notmuch-hello-insert-searches'."
 435   (with-temp-buffer
 436     (dolist (elem query-list nil)
 437       (let ((count-query (or (notmuch-saved-search-get elem :count-query)
 438                              (notmuch-saved-search-get elem :query))))
 439         (insert
 440          (replace-regexp-in-string
 441           "\n" " "
 442           (notmuch-hello-filtered-query count-query
 443                                         (or (plist-get options :filter-count)
 444                                             (plist-get options :filter))))
 445           "\n")))
 446
 447     (unless (= (call-process-region (point-min) (point-max) notmuch-command
 448                                     t t nil "count" "--batch") 0)
 449       (notmuch-logged-error "notmuch count --batch failed"
 450                             "Please check that the notmuch CLI is new enough to support `count
 451 --batch'. In general we recommend running matching versions of
 452 the CLI and emacs interface."))
 453
 454     (goto-char (point-min))
 455
 456     (notmuch-remove-if-not
 457      #'identity
 458      (mapcar
 459       (lambda (elem)
 460         (let* ((elem-plist (notmuch-hello-saved-search-to-plist elem))
 461                (search-query (plist-get elem-plist :query))
 462                (filtered-query (notmuch-hello-filtered-query
 463                                 search-query (plist-get options :filter)))
 464                (message-count (prog1 (read (current-buffer))
 465                                 (forward-line 1))))
 466           (when (and filtered-query (or (plist-get options :show-empty-searches) (> message-count 0)))
 467             (setq elem-plist (plist-put elem-plist :query filtered-query))
 468             (plist-put elem-plist :count message-count))))
 469       query-list))))
 470
 471 (defun notmuch-hello-insert-buttons (searches)
 472   "Insert buttons for SEARCHES.
 473
 474 SEARCHES must be a list of plists each of which should contain at
 475 least the properties :name NAME :query QUERY and :count COUNT,
 476 where QUERY is the query to start when the button for the
 477 corresponding entry is activated, and COUNT should be the number
 478 of messages matching the query.  Such a plist can be computed
 479 with `notmuch-hello-query-counts'."
 480   (let* ((widest (notmuch-hello-longest-label searches))
 481          (tags-and-width (notmuch-hello-tags-per-line widest))
 482          (tags-per-line (car tags-and-width))
 483          (column-width (cdr tags-and-width))
 484          (column-indent 0)
 485          (count 0)
 486          (reordered-list (notmuch-hello-reflect searches tags-per-line))
 487          ;; Hack the display of the buttons used.
 488          (widget-push-button-prefix "")
 489          (widget-push-button-suffix ""))
 490     ;; dme: It feels as though there should be a better way to
 491     ;; implement this loop than using an incrementing counter.
 492     (mapc (lambda (elem)
 493             ;; (not elem) indicates an empty slot in the matrix.
 494             (when elem
 495               (if (> column-indent 0)
 496                   (widget-insert (make-string column-indent ? )))
 497               (let* ((name (plist-get elem :name))
 498                      (query (plist-get elem :query))
 499                      (oldest-first (case (plist-get elem :sort-order)
 500                                      (newest-first nil)
 501                                      (oldest-first t)
 502                                      (otherwise notmuch-search-oldest-first)))
 503                      (msg-count (plist-get elem :count)))
 504                 (widget-insert (format "%8s "
 505                                        (notmuch-hello-nice-number msg-count)))
 506                 (widget-create 'push-button
 507                                :notify #'notmuch-hello-widget-search
 508                                :notmuch-search-terms query
 509                                :notmuch-search-oldest-first oldest-first
 510                                name)
 511                 (setq column-indent
 512                       (1+ (max 0 (- column-width (length name)))))))
 513             (setq count (1+ count))
 514             (when (eq (% count tags-per-line) 0)
 515               (setq column-indent 0)
 516               (widget-insert "\n")))
 517           reordered-list)
 518
 519     ;; If the last line was not full (and hence did not include a
 520     ;; carriage return), insert one now.
 521     (unless (eq (% count tags-per-line) 0)
 522       (widget-insert "\n"))))
 523
 524 (defimage notmuch-hello-logo ((:type png :file "notmuch-logo.png")))
 525
 526 (defun notmuch-hello-update (&optional no-display)
 527   "Update the current notmuch view."
 528   ;; Lazy - rebuild everything.
 529   (notmuch-hello no-display))
 530
 531 (defun notmuch-hello-window-configuration-change ()
 532   "Hook function to update the hello buffer when it is switched to."
 533   (let ((hello-buf (get-buffer "*notmuch-hello*"))
 534         (do-refresh nil))
 535     ;; Consider all windows in the currently selected frame, since
 536     ;; that's where the configuration change happened.  This also
 537     ;; refreshes our snapshot of all windows, so we have to do this
 538     ;; even if we know we won't refresh (e.g., hello-buf is null).
 539     (dolist (window (window-list))
 540       (let ((last-buf (window-parameter window 'notmuch-hello-last-buffer))
 541             (cur-buf (window-buffer window)))
 542         (when (not (eq last-buf cur-buf))
 543           ;; This window changed or is new.  Update recorded buffer
 544           ;; for next time.
 545           (set-window-parameter window 'notmuch-hello-last-buffer cur-buf)
 546           (when (and (eq cur-buf hello-buf) last-buf)
 547             ;; The user just switched to hello in this window (hello
 548             ;; is currently visible, was not visible on the last
 549             ;; configuration change, and this is not a new window)
 550             (setq do-refresh t)))))
 551     (when (and do-refresh notmuch-hello-auto-refresh)
 552       ;; Refresh hello as soon as we get back to redisplay.  On Emacs
 553       ;; 24, we can't do it right here because something in this
 554       ;; hook's call stack overrides hello's point placement.
 555       (run-at-time nil nil #'notmuch-hello t))
 556     (when (null hello-buf)
 557       ;; Clean up hook
 558       (remove-hook 'window-configuration-change-hook
 559                    #'notmuch-hello-window-configuration-change))))
 560
 561 ;; the following variable is defined as being defconst in notmuch-version.el
 562 (defvar notmuch-emacs-version)
 563
 564 (defun notmuch-hello-versions ()
 565   "Display the notmuch version(s)"
 566   (interactive)
 567   (let ((notmuch-cli-version (notmuch-version)))
 568     (message "notmuch version %s"
 569              (if (string= notmuch-emacs-version notmuch-cli-version)
 570                  notmuch-cli-version
 571                (concat notmuch-cli-version
 572                        " (emacs mua version " notmuch-emacs-version ")")))))
 573
 574 (defvar notmuch-hello-mode-map
 575   (let ((map (if (fboundp 'make-composed-keymap)
 576                  ;; Inherit both widget-keymap and notmuch-common-keymap
 577                  (make-composed-keymap widget-keymap)
 578                ;; Before Emacs 24, keymaps didn't support multiple
 579                ;; inheritance,, so just copy the widget keymap since
 580                ;; it's unlikely to change.
 581                (copy-keymap widget-keymap))))
 582     (set-keymap-parent map notmuch-common-keymap)
 583     (define-key map "v" 'notmuch-hello-versions)
 584     (define-key map (kbd "<C-tab>") 'widget-backward)
 585     map)
 586   "Keymap for \"notmuch hello\" buffers.")
 587 (fset 'notmuch-hello-mode-map notmuch-hello-mode-map)
 588
 589 (defun notmuch-hello-mode ()
 590  "Major mode for convenient notmuch navigation. This is your entry portal into notmuch.
 591
 592 Complete list of currently available key bindings:
 593
 594 \\{notmuch-hello-mode-map}"
 595  (interactive)
 596  (kill-all-local-variables)
 597  (setq notmuch-buffer-refresh-function #'notmuch-hello-update)
 598  (use-local-map notmuch-hello-mode-map)
 599  (setq major-mode 'notmuch-hello-mode
 600         mode-name "notmuch-hello")
 601  (run-mode-hooks 'notmuch-hello-mode-hook)
 602  ;;(setq buffer-read-only t)
 603 )
 604
 605 (defun notmuch-hello-generate-tag-alist (&optional hide-tags)
 606   "Return an alist from tags to queries to display in the all-tags section."
 607   (mapcar (lambda (tag)
 608             (cons tag (concat "tag:" (notmuch-escape-boolean-term tag))))
 609           (notmuch-remove-if-not
 610            (lambda (tag)
 611              (not (member tag hide-tags)))
 612            (process-lines notmuch-command "search" "--output=tags" "*"))))
 613
 614 (defun notmuch-hello-insert-header ()
 615   "Insert the default notmuch-hello header."
 616   (when notmuch-show-logo
 617     (let ((image notmuch-hello-logo))
 618       ;; The notmuch logo uses transparency. That can display poorly
 619       ;; when inserting the image into an emacs buffer (black logo on
 620       ;; a black background), so force the background colour of the
 621       ;; image. We use a face to represent the colour so that
 622       ;; `defface' can be used to declare the different possible
 623       ;; colours, which depend on whether the frame has a light or
 624       ;; dark background.
 625       (setq image (cons 'image
 626                         (append (cdr image)
 627                                 (list :background (face-background 'notmuch-hello-logo-background)))))
 628       (insert-image image))
 629     (widget-insert "  "))
 630
 631   (widget-insert "Welcome to ")
 632   ;; Hack the display of the links used.
 633   (let ((widget-link-prefix "")
 634         (widget-link-suffix ""))
 635     (widget-create 'link
 636                    :notify (lambda (&rest ignore)
 637                              (browse-url notmuch-hello-url))
 638                    :help-echo "Visit the notmuch website."
 639                    "notmuch")
 640     (widget-insert ". ")
 641     (widget-insert "You have ")
 642     (widget-create 'link
 643                    :notify (lambda (&rest ignore)
 644                              (notmuch-hello-update))
 645                    :help-echo "Refresh"
 646                    (notmuch-hello-nice-number
 647                     (string-to-number (car (process-lines notmuch-command "count")))))
 648     (widget-insert " messages.\n")))
 649
 650
 651 (defun notmuch-hello-insert-saved-searches ()
 652   "Insert the saved-searches section."
 653   (let ((searches (notmuch-hello-query-counts
 654                    (if notmuch-saved-search-sort-function
 655                        (funcall notmuch-saved-search-sort-function
 656                                 notmuch-saved-searches)
 657                      notmuch-saved-searches)
 658                    :show-empty-searches notmuch-show-empty-saved-searches)))
 659     (when searches
 660       (widget-insert "Saved searches: ")
 661       (widget-create 'push-button
 662                      :notify (lambda (&rest ignore)
 663                                (customize-variable 'notmuch-saved-searches))
 664                      "edit")
 665       (widget-insert "\n\n")
 666       (let ((start (point)))
 667         (notmuch-hello-insert-buttons searches)
 668         (indent-rigidly start (point) notmuch-hello-indent)))))
 669
 670 (defun notmuch-hello-insert-search ()
 671   "Insert a search widget."
 672   (widget-insert "Search: ")
 673   (widget-create 'editable-field
 674                  ;; Leave some space at the start and end of the
 675                  ;; search boxes.
 676                  :size (max 8 (- (window-width) notmuch-hello-indent
 677                                  (length "Search: ")))
 678                  :action (lambda (widget &rest ignore)
 679                            (notmuch-hello-search (widget-value widget))))
 680   ;; Add an invisible dot to make `widget-end-of-line' ignore
 681   ;; trailing spaces in the search widget field.  A dot is used
 682   ;; instead of a space to make `show-trailing-whitespace'
 683   ;; happy, i.e. avoid it marking the whole line as trailing
 684   ;; spaces.
 685   (widget-insert ".")
 686   (put-text-property (1- (point)) (point) 'invisible t)
 687   (widget-insert "\n"))
 688
 689 (defun notmuch-hello-insert-recent-searches ()
 690   "Insert recent searches."
 691   (when notmuch-search-history
 692     (widget-insert "Recent searches: ")
 693     (widget-create 'push-button
 694                    :notify (lambda (&rest ignore)
 695                              (when (y-or-n-p "Are you sure you want to clear the searches? ")
 696                                (setq notmuch-search-history nil)
 697                                (notmuch-hello-update)))
 698                    "clear")
 699     (widget-insert "\n\n")
 700     (let ((start (point)))
 701       (loop for i from 1 to notmuch-hello-recent-searches-max
 702             for search in notmuch-search-history do
 703             (let ((widget-symbol (intern (format "notmuch-hello-search-%d" i))))
 704               (set widget-symbol
 705                    (widget-create 'editable-field
 706                                   ;; Don't let the search boxes be
 707                                   ;; less than 8 characters wide.
 708                                   :size (max 8
 709                                              (- (window-width)
 710                                                 ;; Leave some space
 711                                                 ;; at the start and
 712                                                 ;; end of the
 713                                                 ;; boxes.
 714                                                 (* 2 notmuch-hello-indent)
 715                                                 ;; 1 for the space
 716                                                 ;; before the
 717                                                 ;; `[save]' button. 6
 718                                                 ;; for the `[save]'
 719                                                 ;; button.
 720                                                 1 6
 721                                                 ;; 1 for the space
 722                                                 ;; before the `[del]'
 723                                                 ;; button. 5 for the
 724                                                 ;; `[del]' button.
 725                                                 1 5))
 726                                   :action (lambda (widget &rest ignore)
 727                                             (notmuch-hello-search (widget-value widget)))
 728                                   search))
 729               (widget-insert " ")
 730               (widget-create 'push-button
 731                              :notify (lambda (widget &rest ignore)
 732                                        (notmuch-hello-add-saved-search widget))
 733                              :notmuch-saved-search-widget widget-symbol
 734                              "save")
 735               (widget-insert " ")
 736               (widget-create 'push-button
 737                              :notify (lambda (widget &rest ignore)
 738                                        (when (y-or-n-p "Are you sure you want to delete this search? ")
 739                                          (notmuch-hello-delete-search-from-history widget)))
 740                              :notmuch-saved-search-widget widget-symbol
 741                              "del"))
 742             (widget-insert "\n"))
 743       (indent-rigidly start (point) notmuch-hello-indent))
 744     nil))
 745
 746 (defun notmuch-hello-insert-searches (title query-list &rest options)
 747   "Insert a section with TITLE showing a list of buttons made from QUERY-LIST.
 748
 749 QUERY-LIST should ideally be a plist but for backwards
 750 compatibility other forms are also accepted (see
 751 `notmuch-saved-searches' for details).  The plist should
 752 contain keys :name and :query; if :count-query is also present
 753 then it specifies an alternate query to be used to generate the
 754 count for the associated search.
 755
 756 Supports the following entries in OPTIONS as a plist:
 757 :initially-hidden - if non-nil, section will be hidden on startup
 758 :show-empty-searches - show buttons with no matching messages
 759 :hide-if-empty - hide if no buttons would be shown
 760    (only makes sense without :show-empty-searches)
 761 :filter - This can be a function that takes the search query as its argument and
 762    returns a filter to be used in conjuction with the query for that search or nil
 763    to hide the element. This can also be a string that is used as a combined with
 764    each query using \"and\".
 765 :filter-count - Separate filter to generate the count displayed each search. Accepts
 766    the same values as :filter. If :filter and :filter-count are specified, this
 767    will be used instead of :filter, not in conjunction with it."
 768   (widget-insert title ": ")
 769   (if (and notmuch-hello-first-run (plist-get options :initially-hidden))
 770       (add-to-list 'notmuch-hello-hidden-sections title))
 771   (let ((is-hidden (member title notmuch-hello-hidden-sections))
 772         (start (point)))
 773     (if is-hidden
 774         (widget-create 'push-button
 775                        :notify `(lambda (widget &rest ignore)
 776                                   (setq notmuch-hello-hidden-sections
 777                                         (delete ,title notmuch-hello-hidden-sections))
 778                                   (notmuch-hello-update))
 779                        "show")
 780       (widget-create 'push-button
 781                      :notify `(lambda (widget &rest ignore)
 782                                 (add-to-list 'notmuch-hello-hidden-sections
 783                                              ,title)
 784                                 (notmuch-hello-update))
 785                      "hide"))
 786     (widget-insert "\n")
 787     (when (not is-hidden)
 788       (let ((searches (apply 'notmuch-hello-query-counts query-list options)))
 789         (when (or (not (plist-get options :hide-if-empty))
 790                   searches)
 791           (widget-insert "\n")
 792           (notmuch-hello-insert-buttons searches)
 793           (indent-rigidly start (point) notmuch-hello-indent))))))
 794
 795 (defun notmuch-hello-insert-tags-section (&optional title &rest options)
 796   "Insert a section displaying all tags with message counts.
 797
 798 TITLE defaults to \"All tags\".
 799 Allowed options are those accepted by `notmuch-hello-insert-searches' and the
 800 following:
 801
 802 :hide-tags - List of tags that should be excluded."
 803   (apply 'notmuch-hello-insert-searches
 804          (or title "All tags")
 805          (notmuch-hello-generate-tag-alist (plist-get options :hide-tags))
 806          options))
 807
 808 (defun notmuch-hello-insert-inbox ()
 809   "Show an entry for each saved search and inboxed messages for each tag"
 810   (notmuch-hello-insert-searches "What's in your inbox"
 811                                  (append
 812                                   notmuch-saved-searches
 813                                   (notmuch-hello-generate-tag-alist))
 814                                  :filter "tag:inbox"))
 815
 816 (defun notmuch-hello-insert-alltags ()
 817   "Insert a section displaying all tags and associated message counts"
 818   (notmuch-hello-insert-tags-section
 819    nil
 820    :initially-hidden (not notmuch-show-all-tags-list)
 821    :hide-tags notmuch-hello-hide-tags
 822    :filter notmuch-hello-tag-list-make-query))
 823
 824 (defun notmuch-hello-insert-footer ()
 825   "Insert the notmuch-hello footer."
 826   (let ((start (point)))
 827     (widget-insert "Type a search query and hit RET to view matching threads.\n")
 828     (when notmuch-search-history
 829       (widget-insert "Hit RET to re-submit a previous search. Edit it first if you like.\n")
 830       (widget-insert "Save recent searches with the `save' button.\n"))
 831     (when notmuch-saved-searches
 832       (widget-insert "Edit saved searches with the `edit' button.\n"))
 833     (widget-insert "Hit RET or click on a saved search or tag name to view matching threads.\n")
 834     (widget-insert "`=' to refresh this screen. `s' to search messages. `q' to quit.\n")
 835     (widget-create 'link
 836                    :notify (lambda (&rest ignore)
 837                              (customize-variable 'notmuch-hello-sections))
 838                    :button-prefix "" :button-suffix ""
 839                    "Customize")
 840     (widget-insert " this page.")
 841     (let ((fill-column (- (window-width) notmuch-hello-indent)))
 842       (center-region start (point)))))
 843
 844 ;;;###autoload
 845 (defun notmuch-hello (&optional no-display)
 846   "Run notmuch and display saved searches, known tags, etc."
 847   (interactive)
 848
 849   (notmuch-assert-cli-sane)
 850   ;; This may cause a window configuration change, so if the
 851   ;; auto-refresh hook is already installed, avoid recursive refresh.
 852   (let ((notmuch-hello-auto-refresh nil))
 853     (if no-display
 854         (set-buffer "*notmuch-hello*")
 855       (switch-to-buffer "*notmuch-hello*")))
 856
 857   ;; Install auto-refresh hook
 858   (when notmuch-hello-auto-refresh
 859     (add-hook 'window-configuration-change-hook
 860               #'notmuch-hello-window-configuration-change))
 861
 862   (let ((target-line (line-number-at-pos))
 863         (target-column (current-column))
 864         (inhibit-read-only t))
 865
 866     ;; Delete all editable widget fields.  Editable widget fields are
 867     ;; tracked in a buffer local variable `widget-field-list' (and
 868     ;; others).  If we do `erase-buffer' without properly deleting the
 869     ;; widgets, some widget-related functions are confused later.
 870     (mapc 'widget-delete widget-field-list)
 871
 872     (erase-buffer)
 873
 874     (unless (eq major-mode 'notmuch-hello-mode)
 875       (notmuch-hello-mode))
 876
 877     (let ((all (overlay-lists)))
 878       ;; Delete all the overlays.
 879       (mapc 'delete-overlay (car all))
 880       (mapc 'delete-overlay (cdr all)))
 881
 882     (mapc
 883      (lambda (section)
 884        (let ((point-before (point)))
 885          (if (functionp section)
 886              (funcall section)
 887            (apply (car section) (cdr section)))
 888          ;; don't insert a newline when the previous section didn't
 889          ;; show anything.
 890          (unless (eq (point) point-before)
 891            (widget-insert "\n"))))
 892      notmuch-hello-sections)
 893     (widget-setup)
 894
 895     ;; Move point back to where it was before refresh. Use line and
 896     ;; column instead of point directly to be insensitive to additions
 897     ;; and removals of text within earlier lines.
 898     (goto-char (point-min))
 899     (forward-line (1- target-line))
 900     (move-to-column target-column))
 901   (run-hooks 'notmuch-hello-refresh-hook)
 902   (setq notmuch-hello-first-run nil))
 903
 904 (defun notmuch-folder ()
 905   "Deprecated function for invoking notmuch---calling `notmuch' is preferred now."
 906   (interactive)
 907   (notmuch-hello))
 908
 909 ;;
 910
 911 (provide 'notmuch-hello)