git.notmuchmail.org Git - notmuch/blob - emacs/notmuch-hello.el

   1 ;; notmuch-hello.el --- welcome to notmuch, a frontend
   2 ;;
   3 ;; Copyright © David Edmondson
   4 ;;
   5 ;; This file is part of Notmuch.
   6 ;;
   7 ;; Notmuch is free software: you can redistribute it and/or modify it
   8 ;; under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation, either version 3 of the License, or
  10 ;; (at your option) any later version.
  11 ;;
  12 ;; Notmuch is distributed in the hope that it will be useful, but
  13 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 ;; General Public License for more details.
  16 ;;
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with Notmuch.  If not, see <http://www.gnu.org/licenses/>.
  19 ;;
  20 ;; Authors: David Edmondson <dme@dme.org>
  21
  22 (eval-when-compile (require 'cl))
  23 (require 'widget)
  24 (require 'wid-edit) ; For `widget-forward'.
  25
  26 (require 'notmuch-lib)
  27 (require 'notmuch-mua)
  28
  29 (declare-function notmuch-search "notmuch" (&optional query oldest-first target-thread target-line continuation))
  30 (declare-function notmuch-poll "notmuch" ())
  31
  32 (defcustom notmuch-hello-recent-searches-max 10
  33   "The number of recent searches to display."
  34   :type 'integer
  35   :group 'notmuch-hello)
  36
  37 (defcustom notmuch-show-empty-saved-searches nil
  38   "Should saved searches with no messages be listed?"
  39   :type 'boolean
  40   :group 'notmuch-hello)
  41
  42 (defun notmuch-sort-saved-searches (alist)
  43   "Generate an alphabetically sorted saved searches alist."
  44   (sort (copy-sequence alist) (lambda (a b) (string< (car a) (car b)))))
  45
  46 (defcustom notmuch-saved-search-sort-function nil
  47   "Function used to sort the saved searches for the notmuch-hello view.
  48
  49 This variable controls how saved searches should be sorted. No
  50 sorting (nil) displays the saved searches in the order they are
  51 stored in `notmuch-saved-searches'. Sort alphabetically sorts the
  52 saved searches in alphabetical order. Custom sort function should
  53 be a function or a lambda expression that takes the saved
  54 searches alist as a parameter, and returns a new saved searches
  55 alist to be used."
  56   :type '(choice (const :tag "No sorting" nil)
  57                  (const :tag "Sort alphabetically" notmuch-sort-saved-searches)
  58                  (function :tag "Custom sort function"
  59                            :value notmuch-sort-saved-searches))
  60   :group 'notmuch-hello)
  61
  62 (defvar notmuch-hello-indent 4
  63   "How much to indent non-headers.")
  64
  65 (defcustom notmuch-show-logo t
  66   "Should the notmuch logo be shown?"
  67   :type 'boolean
  68   :group 'notmuch-hello)
  69
  70 (defcustom notmuch-show-all-tags-list nil
  71   "Should all tags be shown in the notmuch-hello view?"
  72   :type 'boolean
  73   :group 'notmuch-hello)
  74
  75 (defcustom notmuch-hello-tag-list-make-query nil
  76   "Function or string to generate queries for the all tags list.
  77
  78 This variable controls which query results are shown for each tag
  79 in the \"all tags\" list. If nil, it will use all messages with
  80 that tag. If this is set to a string, it is used as a filter for
  81 messages having that tag (equivalent to \"tag:TAG and (THIS-VARIABLE)\").
  82 Finally this can be a function that will be called for each tag and
  83 should return a filter for that tag, or nil to hide the tag."
  84   :type '(choice (const :tag "All messages" nil)
  85                  (const :tag "Unread messages" "tag:unread")
  86                  (string :tag "Custom filter"
  87                          :value "tag:unread")
  88                  (function :tag "Custom filter function"))
  89   :group 'notmuch-hello)
  90
  91 (defcustom notmuch-hello-hide-tags nil
  92   "List of tags to be hidden in the \"all tags\"-section."
  93   :type '(repeat string)
  94   :group 'notmuch-hello)
  95
  96 (defface notmuch-hello-logo-background
  97   '((((class color)
  98       (background dark))
  99      (:background "#5f5f5f"))
 100     (((class color)
 101       (background light))
 102      (:background "white")))
 103   "Background colour for the notmuch logo."
 104   :group 'notmuch-hello
 105   :group 'notmuch-faces)
 106
 107 (defcustom notmuch-column-control t
 108   "Controls the number of columns for saved searches/tags in notmuch view.
 109
 110 This variable has three potential sets of values:
 111
 112 - t: automatically calculate the number of columns possible based
 113   on the tags to be shown and the window width,
 114 - an integer: a lower bound on the number of characters that will
 115   be used to display each column,
 116 - a float: a fraction of the window width that is the lower bound
 117   on the number of characters that should be used for each
 118   column.
 119
 120 So:
 121 - if you would like two columns of tags, set this to 0.5.
 122 - if you would like a single column of tags, set this to 1.0.
 123 - if you would like tags to be 30 characters wide, set this to
 124   30.
 125 - if you don't want to worry about all of this nonsense, leave
 126   this set to `t'."
 127   :type '(choice
 128           (const :tag "Automatically calculated" t)
 129           (integer :tag "Number of characters")
 130           (float :tag "Fraction of window"))
 131   :group 'notmuch-hello)
 132
 133 (defcustom notmuch-hello-thousands-separator " "
 134   "The string used as a thousands separator.
 135
 136 Typically \",\" in the US and UK and \".\" or \" \" in Europe.
 137 The latter is recommended in the SI/ISO 31-0 standard and by the
 138 International Bureau of Weights and Measures."
 139   :type 'string
 140   :group 'notmuch-hello)
 141
 142 (defcustom notmuch-hello-mode-hook nil
 143   "Functions called after entering `notmuch-hello-mode'."
 144   :type 'hook
 145   :group 'notmuch-hello
 146   :group 'notmuch-hooks)
 147
 148 (defcustom notmuch-hello-refresh-hook nil
 149   "Functions called after updating a `notmuch-hello' buffer."
 150   :type 'hook
 151   :group 'notmuch-hello
 152   :group 'notmuch-hooks)
 153
 154 (defvar notmuch-hello-url "http://notmuchmail.org"
 155   "The `notmuch' web site.")
 156
 157 (defvar notmuch-hello-custom-section-options
 158   '((:filter (string :tag "Filter for each tag"))
 159     (:filter-count (string :tag "Different filter to generate message counts"))
 160     (:initially-hidden (const :tag "Hide this section on startup" t))
 161     (:show-empty-searches (const :tag "Show queries with no matching messages" t))
 162     (:hide-if-empty (const :tag "Hide this section if all queries are empty
 163 \(and not shown by show-empty-searches)" t)))
 164   "Various customization-options for notmuch-hello-tags/query-section.")
 165
 166 (define-widget 'notmuch-hello-tags-section 'lazy
 167   "Customize-type for notmuch-hello tag-list sections."
 168   :tag "Customized tag-list section (see docstring for details)"
 169   :type
 170   `(list :tag ""
 171          (const :tag "" notmuch-hello-insert-tags-section)
 172          (string :tag "Title for this section")
 173          (plist
 174           :inline t
 175           :options
 176           ,(append notmuch-hello-custom-section-options
 177                    '((:hide-tags (repeat :tag "Tags that will be hidden"
 178                                          string)))))))
 179
 180 (define-widget 'notmuch-hello-query-section 'lazy
 181   "Customize-type for custom saved-search-like sections"
 182   :tag "Customized queries section (see docstring for details)"
 183   :type
 184   `(list :tag ""
 185          (const :tag "" notmuch-hello-insert-searches)
 186          (string :tag "Title for this section")
 187          (repeat :tag "Queries"
 188                  (cons (string :tag "Name") (string :tag "Query")))
 189          (plist :inline t :options ,notmuch-hello-custom-section-options)))
 190
 191 (defcustom notmuch-hello-sections
 192   (list #'notmuch-hello-insert-header
 193         #'notmuch-hello-insert-saved-searches
 194         #'notmuch-hello-insert-search
 195         #'notmuch-hello-insert-recent-searches
 196         #'notmuch-hello-insert-alltags
 197         #'notmuch-hello-insert-footer)
 198   "Sections for notmuch-hello.
 199
 200 The list contains functions which are used to construct sections in
 201 notmuch-hello buffer.  When notmuch-hello buffer is constructed,
 202 these functions are run in the order they appear in this list.  Each
 203 function produces a section simply by adding content to the current
 204 buffer.  A section should not end with an empty line, because a
 205 newline will be inserted after each section by `notmuch-hello'.
 206
 207 Each function should take no arguments. The return value is
 208 ignored.
 209
 210 For convenience an element can also be a list of the form (FUNC ARG1
 211 ARG2 .. ARGN) in which case FUNC will be applied to the rest of the
 212 list.
 213
 214 A \"Customized tag-list section\" item in the customize-interface
 215 displays a list of all tags, optionally hiding some of them. It
 216 is also possible to filter the list of messages matching each tag
 217 by an additional filter query. Similarly, the count of messages
 218 displayed next to the buttons can be generated by applying a
 219 different filter to the tag query. These filters are also
 220 supported for \"Customized queries section\" items."
 221   :group 'notmuch-hello
 222   :type
 223   '(repeat
 224     (choice (function-item notmuch-hello-insert-header)
 225             (function-item notmuch-hello-insert-saved-searches)
 226             (function-item notmuch-hello-insert-search)
 227             (function-item notmuch-hello-insert-recent-searches)
 228             (function-item notmuch-hello-insert-alltags)
 229             (function-item notmuch-hello-insert-footer)
 230             (function-item notmuch-hello-insert-inbox)
 231             notmuch-hello-tags-section
 232             notmuch-hello-query-section
 233             (function :tag "Custom section"))))
 234
 235 (defcustom notmuch-hello-auto-refresh t
 236   "Automatically refresh when returning to the notmuch-hello buffer."
 237   :group 'notmuch-hello
 238   :type 'boolean)
 239
 240 (defvar notmuch-hello-hidden-sections nil
 241   "List of sections titles whose contents are hidden")
 242
 243 (defvar notmuch-hello-first-run t
 244   "True if `notmuch-hello' is run for the first time, set to nil
 245 afterwards.")
 246
 247 (defun notmuch-hello-nice-number (n)
 248   (let (result)
 249     (while (> n 0)
 250       (push (% n 1000) result)
 251       (setq n (/ n 1000)))
 252     (setq result (or result '(0)))
 253     (apply #'concat
 254      (number-to-string (car result))
 255      (mapcar (lambda (elem)
 256               (format "%s%03d" notmuch-hello-thousands-separator elem))
 257              (cdr result)))))
 258
 259 (defun notmuch-hello-trim (search)
 260   "Trim whitespace."
 261   (if (string-match "^[[:space:]]*\\(.*[^[:space:]]\\)[[:space:]]*$" search)
 262       (match-string 1 search)
 263     search))
 264
 265 (defun notmuch-hello-search (&optional search)
 266   (unless (null search)
 267     (setq search (notmuch-hello-trim search))
 268     (let ((history-delete-duplicates t))
 269       (add-to-history 'notmuch-search-history search)))
 270   (notmuch-search search notmuch-search-oldest-first))
 271
 272 (defun notmuch-saved-search-get (saved-search field)
 273   "Get FIELD from SAVED-SEARCH.
 274
 275 If SAVED-SEARCH is a plist, this is just `plist-get', but for
 276 backwards compatibility, this also deals with the two other
 277 possible formats for SAVED-SEARCH: cons cells (NAME . QUERY) and
 278 lists (NAME QUERY COUNT-QUERY)."
 279   (cond
 280    ((keywordp (car saved-search))
 281     (plist-get saved-search field))
 282    ;; It is not a plist so it is an old-style entry.
 283    ((consp (cdr saved-search)) ;; It is a list (NAME QUERY COUNT-QUERY)
 284     (case field
 285       (:name (first saved-search))
 286       (:query (second saved-search))
 287       (:count-query (third saved-search))
 288       (t nil)))
 289    (t  ;; It is a cons-cell (NAME . QUERY)
 290     (case field
 291       (:name (car saved-search))
 292       (:query (cdr saved-search))
 293       (t nil)))))
 294
 295 (defun notmuch-hello-saved-search-to-plist (saved-search)
 296   "Return a copy of SAVED-SEARCH in plist form.
 297
 298 If saved search is a plist then just return a copy. In other
 299 cases, for backwards compatability, convert to plist form and
 300 return that."
 301   (if (keywordp (car saved-search))
 302       (copy-seq saved-search)
 303     (let ((fields (list :name :query :count-query))
 304           plist-search)
 305       (dolist (field fields plist-search)
 306         (let ((string (notmuch-saved-search-get saved-search field)))
 307           (when string
 308             (setq plist-search (append plist-search (list field string)))))))))
 309
 310 (defun notmuch-hello-add-saved-search (widget)
 311   (interactive)
 312   (let ((search (widget-value
 313                  (symbol-value
 314                   (widget-get widget :notmuch-saved-search-widget))))
 315         (name (completing-read "Name for saved search: "
 316                                notmuch-saved-searches)))
 317     ;; If an existing saved search with this name exists, remove it.
 318     (setq notmuch-saved-searches
 319           (loop for elem in notmuch-saved-searches
 320                 if (not (equal name
 321                                (notmuch-saved-search-get elem :name)))
 322                 collect elem))
 323     ;; Add the new one.
 324     (customize-save-variable 'notmuch-saved-searches
 325                              (add-to-list 'notmuch-saved-searches
 326                                           (cons name search) t))
 327     (message "Saved '%s' as '%s'." search name)
 328     (notmuch-hello-update)))
 329
 330 (defun notmuch-hello-delete-search-from-history (widget)
 331   (interactive)
 332   (let ((search (widget-value
 333                  (symbol-value
 334                   (widget-get widget :notmuch-saved-search-widget)))))
 335     (setq notmuch-search-history (delete search
 336                                          notmuch-search-history))
 337     (notmuch-hello-update)))
 338
 339 (defun notmuch-hello-longest-label (searches-alist)
 340   (or (loop for elem in searches-alist
 341             maximize (length (notmuch-saved-search-get elem :name)))
 342       0))
 343
 344 (defun notmuch-hello-reflect-generate-row (ncols nrows row list)
 345   (let ((len (length list)))
 346     (loop for col from 0 to (- ncols 1)
 347           collect (let ((offset (+ (* nrows col) row)))
 348                     (if (< offset len)
 349                         (nth offset list)
 350                       ;; Don't forget to insert an empty slot in the
 351                       ;; output matrix if there is no corresponding
 352                       ;; value in the input matrix.
 353                       nil)))))
 354
 355 (defun notmuch-hello-reflect (list ncols)
 356   "Reflect a `ncols' wide matrix represented by `list' along the
 357 diagonal."
 358   ;; Not very lispy...
 359   (let ((nrows (ceiling (length list) ncols)))
 360     (loop for row from 0 to (- nrows 1)
 361           append (notmuch-hello-reflect-generate-row ncols nrows row list))))
 362
 363 (defun notmuch-hello-widget-search (widget &rest ignore)
 364   (notmuch-search (widget-get widget
 365                               :notmuch-search-terms)
 366                   notmuch-search-oldest-first))
 367
 368 (defun notmuch-saved-search-count (search)
 369   (car (process-lines notmuch-command "count" search)))
 370
 371 (defun notmuch-hello-tags-per-line (widest)
 372   "Determine how many tags to show per line and how wide they
 373 should be. Returns a cons cell `(tags-per-line width)'."
 374   (let ((tags-per-line
 375          (cond
 376           ((integerp notmuch-column-control)
 377            (max 1
 378                 (/ (- (window-width) notmuch-hello-indent)
 379                    ;; Count is 9 wide (8 digits plus space), 1 for the space
 380                    ;; after the name.
 381                    (+ 9 1 (max notmuch-column-control widest)))))
 382
 383           ((floatp notmuch-column-control)
 384            (let* ((available-width (- (window-width) notmuch-hello-indent))
 385                   (proposed-width (max (* available-width notmuch-column-control) widest)))
 386              (floor available-width proposed-width)))
 387
 388           (t
 389            (max 1
 390                 (/ (- (window-width) notmuch-hello-indent)
 391                    ;; Count is 9 wide (8 digits plus space), 1 for the space
 392                    ;; after the name.
 393                    (+ 9 1 widest)))))))
 394
 395     (cons tags-per-line (/ (max 1
 396                                 (- (window-width) notmuch-hello-indent
 397                                    ;; Count is 9 wide (8 digits plus
 398                                    ;; space), 1 for the space after the
 399                                    ;; name.
 400                                    (* tags-per-line (+ 9 1))))
 401                            tags-per-line))))
 402
 403 (defun notmuch-hello-filtered-query (query filter)
 404   "Constructs a query to search all messages matching QUERY and FILTER.
 405
 406 If FILTER is a string, it is directly used in the returned query.
 407
 408 If FILTER is a function, it is called with QUERY as a parameter and
 409 the string it returns is used as the query. If nil is returned,
 410 the entry is hidden.
 411
 412 Otherwise, FILTER is ignored.
 413 "
 414   (cond
 415    ((functionp filter) (funcall filter query))
 416    ((stringp filter)
 417     (concat "(" query ") and (" filter ")"))
 418    (t query)))
 419
 420 (defun notmuch-hello-query-counts (query-list &rest options)
 421   "Compute list of counts of matched messages from QUERY-LIST.
 422
 423 QUERY-LIST must be a list of saved-searches. Ideally each of
 424 these is a plist but other options are available for backwards
 425 compatibility: see `notmuch-saved-searches' for details.
 426
 427 The result is the list of elements of the form (NAME QUERY COUNT).
 428
 429 The values :show-empty-searches, :filter and :filter-count from
 430 options will be handled as specified for
 431 `notmuch-hello-insert-searches'."
 432   (with-temp-buffer
 433     (dolist (elem query-list nil)
 434       (let ((count-query (or (notmuch-saved-search-get elem :count-query)
 435                              (notmuch-saved-search-get elem :query))))
 436         (insert
 437          (replace-regexp-in-string
 438           "\n" " "
 439           (notmuch-hello-filtered-query count-query
 440                                         (or (plist-get options :filter-count)
 441                                             (plist-get options :filter))))
 442           "\n")))
 443
 444     (unless (= (call-process-region (point-min) (point-max) notmuch-command
 445                                     t t nil "count" "--batch") 0)
 446       (notmuch-logged-error "notmuch count --batch failed"
 447                             "Please check that the notmuch CLI is new enough to support `count
 448 --batch'. In general we recommend running matching versions of
 449 the CLI and emacs interface."))
 450
 451     (goto-char (point-min))
 452
 453     (notmuch-remove-if-not
 454      #'identity
 455      (mapcar
 456       (lambda (elem)
 457         (let ((name (notmuch-saved-search-get elem :name))
 458               (search-query (notmuch-saved-search-get elem :query))
 459               (message-count (prog1 (read (current-buffer))
 460                                 (forward-line 1))))
 461           (and (or (plist-get options :show-empty-searches) (> message-count 0))
 462                (list name (notmuch-hello-filtered-query
 463                            search-query (plist-get options :filter))
 464                      message-count))))
 465       query-list))))
 466
 467 (defun notmuch-hello-insert-buttons (searches)
 468   "Insert buttons for SEARCHES.
 469
 470 SEARCHES must be a list containing lists of the form (NAME QUERY COUNT), where
 471 QUERY is the query to start when the button for the corresponding entry is
 472 activated. COUNT should be the number of messages matching the query.
 473 Such a list can be computed with `notmuch-hello-query-counts'."
 474   (let* ((widest (notmuch-hello-longest-label searches))
 475          (tags-and-width (notmuch-hello-tags-per-line widest))
 476          (tags-per-line (car tags-and-width))
 477          (column-width (cdr tags-and-width))
 478          (column-indent 0)
 479          (count 0)
 480          (reordered-list (notmuch-hello-reflect searches tags-per-line))
 481          ;; Hack the display of the buttons used.
 482          (widget-push-button-prefix "")
 483          (widget-push-button-suffix ""))
 484     ;; dme: It feels as though there should be a better way to
 485     ;; implement this loop than using an incrementing counter.
 486     (mapc (lambda (elem)
 487             ;; (not elem) indicates an empty slot in the matrix.
 488             (when elem
 489               (if (> column-indent 0)
 490                   (widget-insert (make-string column-indent ? )))
 491               (let* ((name (first elem))
 492                      (query (second elem))
 493                      (msg-count (third elem)))
 494                 (widget-insert (format "%8s "
 495                                        (notmuch-hello-nice-number msg-count)))
 496                 (widget-create 'push-button
 497                                :notify #'notmuch-hello-widget-search
 498                                :notmuch-search-terms query
 499                                name)
 500                 (setq column-indent
 501                       (1+ (max 0 (- column-width (length name)))))))
 502             (setq count (1+ count))
 503             (when (eq (% count tags-per-line) 0)
 504               (setq column-indent 0)
 505               (widget-insert "\n")))
 506           reordered-list)
 507
 508     ;; If the last line was not full (and hence did not include a
 509     ;; carriage return), insert one now.
 510     (unless (eq (% count tags-per-line) 0)
 511       (widget-insert "\n"))))
 512
 513 (defimage notmuch-hello-logo ((:type png :file "notmuch-logo.png")))
 514
 515 (defun notmuch-hello-update (&optional no-display)
 516   "Update the current notmuch view."
 517   ;; Lazy - rebuild everything.
 518   (notmuch-hello no-display))
 519
 520 (defun notmuch-hello-window-configuration-change ()
 521   "Hook function to update the hello buffer when it is switched to."
 522   (let ((hello-buf (get-buffer "*notmuch-hello*"))
 523         (do-refresh nil))
 524     ;; Consider all windows in the currently selected frame, since
 525     ;; that's where the configuration change happened.  This also
 526     ;; refreshes our snapshot of all windows, so we have to do this
 527     ;; even if we know we won't refresh (e.g., hello-buf is null).
 528     (dolist (window (window-list))
 529       (let ((last-buf (window-parameter window 'notmuch-hello-last-buffer))
 530             (cur-buf (window-buffer window)))
 531         (when (not (eq last-buf cur-buf))
 532           ;; This window changed or is new.  Update recorded buffer
 533           ;; for next time.
 534           (set-window-parameter window 'notmuch-hello-last-buffer cur-buf)
 535           (when (and (eq cur-buf hello-buf) last-buf)
 536             ;; The user just switched to hello in this window (hello
 537             ;; is currently visible, was not visible on the last
 538             ;; configuration change, and this is not a new window)
 539             (setq do-refresh t)))))
 540     (when (and do-refresh notmuch-hello-auto-refresh)
 541       ;; Refresh hello as soon as we get back to redisplay.  On Emacs
 542       ;; 24, we can't do it right here because something in this
 543       ;; hook's call stack overrides hello's point placement.
 544       (run-at-time nil nil #'notmuch-hello t))
 545     (when (null hello-buf)
 546       ;; Clean up hook
 547       (remove-hook 'window-configuration-change-hook
 548                    #'notmuch-hello-window-configuration-change))))
 549
 550 ;; the following variable is defined as being defconst in notmuch-version.el
 551 (defvar notmuch-emacs-version)
 552
 553 (defun notmuch-hello-versions ()
 554   "Display the notmuch version(s)"
 555   (interactive)
 556   (let ((notmuch-cli-version (notmuch-version)))
 557     (message "notmuch version %s"
 558              (if (string= notmuch-emacs-version notmuch-cli-version)
 559                  notmuch-cli-version
 560                (concat notmuch-cli-version
 561                        " (emacs mua version " notmuch-emacs-version ")")))))
 562
 563 (defvar notmuch-hello-mode-map
 564   (let ((map (if (fboundp 'make-composed-keymap)
 565                  ;; Inherit both widget-keymap and notmuch-common-keymap
 566                  (make-composed-keymap widget-keymap)
 567                ;; Before Emacs 24, keymaps didn't support multiple
 568                ;; inheritance,, so just copy the widget keymap since
 569                ;; it's unlikely to change.
 570                (copy-keymap widget-keymap))))
 571     (set-keymap-parent map notmuch-common-keymap)
 572     (define-key map "v" 'notmuch-hello-versions)
 573     (define-key map (kbd "<C-tab>") 'widget-backward)
 574     map)
 575   "Keymap for \"notmuch hello\" buffers.")
 576 (fset 'notmuch-hello-mode-map notmuch-hello-mode-map)
 577
 578 (defun notmuch-hello-mode ()
 579  "Major mode for convenient notmuch navigation. This is your entry portal into notmuch.
 580
 581 Complete list of currently available key bindings:
 582
 583 \\{notmuch-hello-mode-map}"
 584  (interactive)
 585  (kill-all-local-variables)
 586  (setq notmuch-buffer-refresh-function #'notmuch-hello-update)
 587  (use-local-map notmuch-hello-mode-map)
 588  (setq major-mode 'notmuch-hello-mode
 589         mode-name "notmuch-hello")
 590  (run-mode-hooks 'notmuch-hello-mode-hook)
 591  ;;(setq buffer-read-only t)
 592 )
 593
 594 (defun notmuch-hello-generate-tag-alist (&optional hide-tags)
 595   "Return an alist from tags to queries to display in the all-tags section."
 596   (mapcar (lambda (tag)
 597             (cons tag (concat "tag:" (notmuch-escape-boolean-term tag))))
 598           (notmuch-remove-if-not
 599            (lambda (tag)
 600              (not (member tag hide-tags)))
 601            (process-lines notmuch-command "search" "--output=tags" "*"))))
 602
 603 (defun notmuch-hello-insert-header ()
 604   "Insert the default notmuch-hello header."
 605   (when notmuch-show-logo
 606     (let ((image notmuch-hello-logo))
 607       ;; The notmuch logo uses transparency. That can display poorly
 608       ;; when inserting the image into an emacs buffer (black logo on
 609       ;; a black background), so force the background colour of the
 610       ;; image. We use a face to represent the colour so that
 611       ;; `defface' can be used to declare the different possible
 612       ;; colours, which depend on whether the frame has a light or
 613       ;; dark background.
 614       (setq image (cons 'image
 615                         (append (cdr image)
 616                                 (list :background (face-background 'notmuch-hello-logo-background)))))
 617       (insert-image image))
 618     (widget-insert "  "))
 619
 620   (widget-insert "Welcome to ")
 621   ;; Hack the display of the links used.
 622   (let ((widget-link-prefix "")
 623         (widget-link-suffix ""))
 624     (widget-create 'link
 625                    :notify (lambda (&rest ignore)
 626                              (browse-url notmuch-hello-url))
 627                    :help-echo "Visit the notmuch website."
 628                    "notmuch")
 629     (widget-insert ". ")
 630     (widget-insert "You have ")
 631     (widget-create 'link
 632                    :notify (lambda (&rest ignore)
 633                              (notmuch-hello-update))
 634                    :help-echo "Refresh"
 635                    (notmuch-hello-nice-number
 636                     (string-to-number (car (process-lines notmuch-command "count")))))
 637     (widget-insert " messages.\n")))
 638
 639
 640 (defun notmuch-hello-insert-saved-searches ()
 641   "Insert the saved-searches section."
 642   (let ((searches (notmuch-hello-query-counts
 643                    (if notmuch-saved-search-sort-function
 644                        (funcall notmuch-saved-search-sort-function
 645                                 notmuch-saved-searches)
 646                      notmuch-saved-searches)
 647                    :show-empty-searches notmuch-show-empty-saved-searches)))
 648     (when searches
 649       (widget-insert "Saved searches: ")
 650       (widget-create 'push-button
 651                      :notify (lambda (&rest ignore)
 652                                (customize-variable 'notmuch-saved-searches))
 653                      "edit")
 654       (widget-insert "\n\n")
 655       (let ((start (point)))
 656         (notmuch-hello-insert-buttons searches)
 657         (indent-rigidly start (point) notmuch-hello-indent)))))
 658
 659 (defun notmuch-hello-insert-search ()
 660   "Insert a search widget."
 661   (widget-insert "Search: ")
 662   (widget-create 'editable-field
 663                  ;; Leave some space at the start and end of the
 664                  ;; search boxes.
 665                  :size (max 8 (- (window-width) notmuch-hello-indent
 666                                  (length "Search: ")))
 667                  :action (lambda (widget &rest ignore)
 668                            (notmuch-hello-search (widget-value widget))))
 669   ;; Add an invisible dot to make `widget-end-of-line' ignore
 670   ;; trailing spaces in the search widget field.  A dot is used
 671   ;; instead of a space to make `show-trailing-whitespace'
 672   ;; happy, i.e. avoid it marking the whole line as trailing
 673   ;; spaces.
 674   (widget-insert ".")
 675   (put-text-property (1- (point)) (point) 'invisible t)
 676   (widget-insert "\n"))
 677
 678 (defun notmuch-hello-insert-recent-searches ()
 679   "Insert recent searches."
 680   (when notmuch-search-history
 681     (widget-insert "Recent searches: ")
 682     (widget-create 'push-button
 683                    :notify (lambda (&rest ignore)
 684                              (when (y-or-n-p "Are you sure you want to clear the searches? ")
 685                                (setq notmuch-search-history nil)
 686                                (notmuch-hello-update)))
 687                    "clear")
 688     (widget-insert "\n\n")
 689     (let ((start (point)))
 690       (loop for i from 1 to notmuch-hello-recent-searches-max
 691             for search in notmuch-search-history do
 692             (let ((widget-symbol (intern (format "notmuch-hello-search-%d" i))))
 693               (set widget-symbol
 694                    (widget-create 'editable-field
 695                                   ;; Don't let the search boxes be
 696                                   ;; less than 8 characters wide.
 697                                   :size (max 8
 698                                              (- (window-width)
 699                                                 ;; Leave some space
 700                                                 ;; at the start and
 701                                                 ;; end of the
 702                                                 ;; boxes.
 703                                                 (* 2 notmuch-hello-indent)
 704                                                 ;; 1 for the space
 705                                                 ;; before the
 706                                                 ;; `[save]' button. 6
 707                                                 ;; for the `[save]'
 708                                                 ;; button.
 709                                                 1 6
 710                                                 ;; 1 for the space
 711                                                 ;; before the `[del]'
 712                                                 ;; button. 5 for the
 713                                                 ;; `[del]' button.
 714                                                 1 5))
 715                                   :action (lambda (widget &rest ignore)
 716                                             (notmuch-hello-search (widget-value widget)))
 717                                   search))
 718               (widget-insert " ")
 719               (widget-create 'push-button
 720                              :notify (lambda (widget &rest ignore)
 721                                        (notmuch-hello-add-saved-search widget))
 722                              :notmuch-saved-search-widget widget-symbol
 723                              "save")
 724               (widget-insert " ")
 725               (widget-create 'push-button
 726                              :notify (lambda (widget &rest ignore)
 727                                        (when (y-or-n-p "Are you sure you want to delete this search? ")
 728                                          (notmuch-hello-delete-search-from-history widget)))
 729                              :notmuch-saved-search-widget widget-symbol
 730                              "del"))
 731             (widget-insert "\n"))
 732       (indent-rigidly start (point) notmuch-hello-indent))
 733     nil))
 734
 735 (defun notmuch-hello-insert-searches (title query-list &rest options)
 736   "Insert a section with TITLE showing a list of buttons made from QUERY-LIST.
 737
 738 QUERY-LIST should ideally be a plist but for backwards
 739 compatibility other forms are also accepted (see
 740 `notmuch-saved-searches' for details).  The plist should
 741 contain keys :name and :query; if :count-query is also present
 742 then it specifies an alternate query to be used to generate the
 743 count for the associated search.
 744
 745 Supports the following entries in OPTIONS as a plist:
 746 :initially-hidden - if non-nil, section will be hidden on startup
 747 :show-empty-searches - show buttons with no matching messages
 748 :hide-if-empty - hide if no buttons would be shown
 749    (only makes sense without :show-empty-searches)
 750 :filter - This can be a function that takes the search query as its argument and
 751    returns a filter to be used in conjuction with the query for that search or nil
 752    to hide the element. This can also be a string that is used as a combined with
 753    each query using \"and\".
 754 :filter-count - Separate filter to generate the count displayed each search. Accepts
 755    the same values as :filter. If :filter and :filter-count are specified, this
 756    will be used instead of :filter, not in conjunction with it."
 757   (widget-insert title ": ")
 758   (if (and notmuch-hello-first-run (plist-get options :initially-hidden))
 759       (add-to-list 'notmuch-hello-hidden-sections title))
 760   (let ((is-hidden (member title notmuch-hello-hidden-sections))
 761         (start (point)))
 762     (if is-hidden
 763         (widget-create 'push-button
 764                        :notify `(lambda (widget &rest ignore)
 765                                   (setq notmuch-hello-hidden-sections
 766                                         (delete ,title notmuch-hello-hidden-sections))
 767                                   (notmuch-hello-update))
 768                        "show")
 769       (widget-create 'push-button
 770                      :notify `(lambda (widget &rest ignore)
 771                                 (add-to-list 'notmuch-hello-hidden-sections
 772                                              ,title)
 773                                 (notmuch-hello-update))
 774                      "hide"))
 775     (widget-insert "\n")
 776     (when (not is-hidden)
 777       (let ((searches (apply 'notmuch-hello-query-counts query-list options)))
 778         (when (or (not (plist-get options :hide-if-empty))
 779                   searches)
 780           (widget-insert "\n")
 781           (notmuch-hello-insert-buttons searches)
 782           (indent-rigidly start (point) notmuch-hello-indent))))))
 783
 784 (defun notmuch-hello-insert-tags-section (&optional title &rest options)
 785   "Insert a section displaying all tags with message counts.
 786
 787 TITLE defaults to \"All tags\".
 788 Allowed options are those accepted by `notmuch-hello-insert-searches' and the
 789 following:
 790
 791 :hide-tags - List of tags that should be excluded."
 792   (apply 'notmuch-hello-insert-searches
 793          (or title "All tags")
 794          (notmuch-hello-generate-tag-alist (plist-get options :hide-tags))
 795          options))
 796
 797 (defun notmuch-hello-insert-inbox ()
 798   "Show an entry for each saved search and inboxed messages for each tag"
 799   (notmuch-hello-insert-searches "What's in your inbox"
 800                                  (append
 801                                   notmuch-saved-searches
 802                                   (notmuch-hello-generate-tag-alist))
 803                                  :filter "tag:inbox"))
 804
 805 (defun notmuch-hello-insert-alltags ()
 806   "Insert a section displaying all tags and associated message counts"
 807   (notmuch-hello-insert-tags-section
 808    nil
 809    :initially-hidden (not notmuch-show-all-tags-list)
 810    :hide-tags notmuch-hello-hide-tags
 811    :filter notmuch-hello-tag-list-make-query))
 812
 813 (defun notmuch-hello-insert-footer ()
 814   "Insert the notmuch-hello footer."
 815   (let ((start (point)))
 816     (widget-insert "Type a search query and hit RET to view matching threads.\n")
 817     (when notmuch-search-history
 818       (widget-insert "Hit RET to re-submit a previous search. Edit it first if you like.\n")
 819       (widget-insert "Save recent searches with the `save' button.\n"))
 820     (when notmuch-saved-searches
 821       (widget-insert "Edit saved searches with the `edit' button.\n"))
 822     (widget-insert "Hit RET or click on a saved search or tag name to view matching threads.\n")
 823     (widget-insert "`=' to refresh this screen. `s' to search messages. `q' to quit.\n")
 824     (widget-create 'link
 825                    :notify (lambda (&rest ignore)
 826                              (customize-variable 'notmuch-hello-sections))
 827                    :button-prefix "" :button-suffix ""
 828                    "Customize")
 829     (widget-insert " this page.")
 830     (let ((fill-column (- (window-width) notmuch-hello-indent)))
 831       (center-region start (point)))))
 832
 833 ;;;###autoload
 834 (defun notmuch-hello (&optional no-display)
 835   "Run notmuch and display saved searches, known tags, etc."
 836   (interactive)
 837
 838   (notmuch-assert-cli-sane)
 839   ;; This may cause a window configuration change, so if the
 840   ;; auto-refresh hook is already installed, avoid recursive refresh.
 841   (let ((notmuch-hello-auto-refresh nil))
 842     (if no-display
 843         (set-buffer "*notmuch-hello*")
 844       (switch-to-buffer "*notmuch-hello*")))
 845
 846   ;; Install auto-refresh hook
 847   (when notmuch-hello-auto-refresh
 848     (add-hook 'window-configuration-change-hook
 849               #'notmuch-hello-window-configuration-change))
 850
 851   (let ((target-line (line-number-at-pos))
 852         (target-column (current-column))
 853         (inhibit-read-only t))
 854
 855     ;; Delete all editable widget fields.  Editable widget fields are
 856     ;; tracked in a buffer local variable `widget-field-list' (and
 857     ;; others).  If we do `erase-buffer' without properly deleting the
 858     ;; widgets, some widget-related functions are confused later.
 859     (mapc 'widget-delete widget-field-list)
 860
 861     (erase-buffer)
 862
 863     (unless (eq major-mode 'notmuch-hello-mode)
 864       (notmuch-hello-mode))
 865
 866     (let ((all (overlay-lists)))
 867       ;; Delete all the overlays.
 868       (mapc 'delete-overlay (car all))
 869       (mapc 'delete-overlay (cdr all)))
 870
 871     (mapc
 872      (lambda (section)
 873        (let ((point-before (point)))
 874          (if (functionp section)
 875              (funcall section)
 876            (apply (car section) (cdr section)))
 877          ;; don't insert a newline when the previous section didn't
 878          ;; show anything.
 879          (unless (eq (point) point-before)
 880            (widget-insert "\n"))))
 881      notmuch-hello-sections)
 882     (widget-setup)
 883
 884     ;; Move point back to where it was before refresh. Use line and
 885     ;; column instead of point directly to be insensitive to additions
 886     ;; and removals of text within earlier lines.
 887     (goto-char (point-min))
 888     (forward-line (1- target-line))
 889     (move-to-column target-column))
 890   (run-hooks 'notmuch-hello-refresh-hook)
 891   (setq notmuch-hello-first-run nil))
 892
 893 (defun notmuch-folder ()
 894   "Deprecated function for invoking notmuch---calling `notmuch' is preferred now."
 895   (interactive)
 896   (notmuch-hello))
 897
 898 ;;
 899
 900 (provide 'notmuch-hello)