git.notmuchmail.org Git - notmuch/blob - emacs/notmuch-lib.el

   1 ;;; notmuch-lib.el --- common variables, functions and function declarations
   2 ;;
   3 ;; Copyright © Carl Worth
   4 ;;
   5 ;; This file is part of Notmuch.
   6 ;;
   7 ;; Notmuch is free software: you can redistribute it and/or modify it
   8 ;; under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation, either version 3 of the License, or
  10 ;; (at your option) any later version.
  11 ;;
  12 ;; Notmuch is distributed in the hope that it will be useful, but
  13 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 ;; General Public License for more details.
  16 ;;
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with Notmuch.  If not, see <https://www.gnu.org/licenses/>.
  19 ;;
  20 ;; Authors: Carl Worth <cworth@cworth.org>
  21
  22 ;;; Code:
  23
  24 (require 'cl-lib)
  25
  26 (require 'mm-util)
  27 (require 'mm-view)
  28 (require 'mm-decode)
  29
  30 (require 'notmuch-compat)
  31
  32 (unless (require 'notmuch-version nil t)
  33   (defconst notmuch-emacs-version "unknown"
  34     "Placeholder variable when notmuch-version.el[c] is not available."))
  35
  36 (defgroup notmuch nil
  37   "Notmuch mail reader for Emacs."
  38   :group 'mail)
  39
  40 (defgroup notmuch-hello nil
  41   "Overview of saved searches, tags, etc."
  42   :group 'notmuch)
  43
  44 (defgroup notmuch-search nil
  45   "Searching and sorting mail."
  46   :group 'notmuch)
  47
  48 (defgroup notmuch-show nil
  49   "Showing messages and threads."
  50   :group 'notmuch)
  51
  52 (defgroup notmuch-send nil
  53   "Sending messages from Notmuch."
  54   :group 'notmuch
  55   :group 'message)
  56
  57 (defgroup notmuch-tag nil
  58   "Tags and tagging in Notmuch."
  59   :group 'notmuch)
  60
  61 (defgroup notmuch-crypto nil
  62   "Processing and display of cryptographic MIME parts."
  63   :group 'notmuch)
  64
  65 (defgroup notmuch-hooks nil
  66   "Running custom code on well-defined occasions."
  67   :group 'notmuch)
  68
  69 (defgroup notmuch-external nil
  70   "Running external commands from within Notmuch."
  71   :group 'notmuch)
  72
  73 (defgroup notmuch-address nil
  74   "Address completion."
  75   :group 'notmuch)
  76
  77 (defgroup notmuch-faces nil
  78   "Graphical attributes for displaying text"
  79   :group 'notmuch)
  80
  81 (defcustom notmuch-command "notmuch"
  82   "Name of the notmuch binary.
  83
  84 This can be a relative or absolute path to the notmuch binary.
  85 If this is a relative path, it will be searched for in all of the
  86 directories given in `exec-path' (which is, by default, based on
  87 $PATH)."
  88   :type 'string
  89   :group 'notmuch-external)
  90
  91 (defcustom notmuch-search-oldest-first t
  92   "Show the oldest mail first when searching.
  93
  94 This variable defines the default sort order for displaying
  95 search results. Note that any filtered searches created by
  96 `notmuch-search-filter' retain the search order of the parent
  97 search."
  98   :type 'boolean
  99   :group 'notmuch-search)
 100
 101 (defcustom notmuch-poll-script nil
 102   "[Deprecated] Command to run to incorporate new mail into the notmuch database.
 103
 104 This option has been deprecated in favor of \"notmuch new\"
 105 hooks (see man notmuch-hooks).  To change the path to the notmuch
 106 binary, customize `notmuch-command'.
 107
 108 This variable controls the action invoked by
 109 `notmuch-poll-and-refresh-this-buffer' (bound by default to 'G')
 110 to incorporate new mail into the notmuch database.
 111
 112 If set to nil (the default), new mail is processed by invoking
 113 \"notmuch new\". Otherwise, this should be set to a string that
 114 gives the name of an external script that processes new mail. If
 115 set to the empty string, no command will be run.
 116
 117 The external script could do any of the following depending on
 118 the user's needs:
 119
 120 1. Invoke a program to transfer mail to the local mail store
 121 2. Invoke \"notmuch new\" to incorporate the new mail
 122 3. Invoke one or more \"notmuch tag\" commands to classify the mail"
 123   :type '(choice (const :tag "notmuch new" nil)
 124                  (const :tag "Disabled" "")
 125                  (string :tag "Custom script"))
 126   :group 'notmuch-external)
 127
 128 ;;
 129
 130 (defvar notmuch-search-history nil
 131   "Variable to store notmuch searches history.")
 132
 133 (defcustom notmuch-archive-tags '("-inbox")
 134   "List of tag changes to apply to a message or a thread when it is archived.
 135
 136 Tags starting with \"+\" (or not starting with either \"+\" or
 137 \"-\") in the list will be added, and tags starting with \"-\"
 138 will be removed from the message or thread being archived.
 139
 140 For example, if you wanted to remove an \"inbox\" tag and add an
 141 \"archived\" tag, you would set:
 142     (\"-inbox\" \"+archived\")"
 143   :type '(repeat string)
 144   :group 'notmuch-search
 145   :group 'notmuch-show)
 146
 147 (defvar notmuch-common-keymap
 148   (let ((map (make-sparse-keymap)))
 149     (define-key map "?" 'notmuch-help)
 150     (define-key map "v" 'notmuch-version)
 151     (define-key map "q" 'notmuch-bury-or-kill-this-buffer)
 152     (define-key map "s" 'notmuch-search)
 153     (define-key map "t" 'notmuch-search-by-tag)
 154     (define-key map "z" 'notmuch-tree)
 155     (define-key map "u" 'notmuch-unthreaded)
 156     (define-key map "m" 'notmuch-mua-new-mail)
 157     (define-key map "g" 'notmuch-refresh-this-buffer)
 158     (define-key map "=" 'notmuch-refresh-this-buffer)
 159     (define-key map (kbd "M-=") 'notmuch-refresh-all-buffers)
 160     (define-key map "G" 'notmuch-poll-and-refresh-this-buffer)
 161     (define-key map "j" 'notmuch-jump-search)
 162     map)
 163   "Keymap shared by all notmuch modes.")
 164
 165 ;; By default clicking on a button does not select the window
 166 ;; containing the button (as opposed to clicking on a widget which
 167 ;; does). This means that the button action is then executed in the
 168 ;; current selected window which can cause problems if the button
 169 ;; changes the buffer (e.g., id: links) or moves point.
 170 ;;
 171 ;; This provides a button type which overrides mouse-action so that
 172 ;; the button's window is selected before the action is run. Other
 173 ;; notmuch buttons can get the same behaviour by inheriting from this
 174 ;; button type.
 175 (define-button-type 'notmuch-button-type
 176   'mouse-action (lambda (button)
 177                   (select-window (posn-window (event-start last-input-event)))
 178                   (button-activate button)))
 179
 180 (defun notmuch-command-to-string (&rest args)
 181   "Synchronously invoke \"notmuch\" with the given list of arguments.
 182
 183 If notmuch exits with a non-zero status, output from the process
 184 will appear in a buffer named \"*Notmuch errors*\" and an error
 185 will be signaled.
 186
 187 Otherwise the output will be returned."
 188   (with-temp-buffer
 189     (let* ((status (apply #'call-process notmuch-command nil t nil args))
 190            (output (buffer-string)))
 191       (notmuch-check-exit-status status (cons notmuch-command args) output)
 192       output)))
 193
 194 (defvar notmuch--cli-sane-p nil
 195   "Cache whether the CLI seems to be configured sanely.")
 196
 197 (defun notmuch-cli-sane-p ()
 198   "Return t if the cli seems to be configured sanely."
 199   (unless notmuch--cli-sane-p
 200     (let ((status (call-process notmuch-command nil nil nil
 201                                 "config" "get" "user.primary_email")))
 202       (setq notmuch--cli-sane-p (= status 0))))
 203   notmuch--cli-sane-p)
 204
 205 (defun notmuch-assert-cli-sane ()
 206   (unless (notmuch-cli-sane-p)
 207     (notmuch-logged-error
 208      "notmuch cli seems misconfigured or unconfigured."
 209      "Perhaps you haven't run \"notmuch setup\" yet? Try running this
 210 on the command line, and then retry your notmuch command")))
 211
 212 (defun notmuch-cli-version ()
 213   "Return a string with the notmuch cli command version number."
 214   (let ((long-string
 215          ;; Trim off the trailing newline.
 216          (substring (notmuch-command-to-string "--version") 0 -1)))
 217     (if (string-match "^notmuch\\( version\\)? \\(.*\\)$"
 218                       long-string)
 219         (match-string 2 long-string)
 220       "unknown")))
 221
 222 (defvar notmuch-emacs-version)
 223
 224 (defun notmuch-version ()
 225   "Display the notmuch version.
 226 The versions of the Emacs package and the `notmuch' executable
 227 should match, but if and only if they don't, then this command
 228 displays both values separately."
 229   (interactive)
 230   (let ((cli-version (notmuch-cli-version)))
 231     (message "notmuch version %s"
 232              (if (string= notmuch-emacs-version cli-version)
 233                  cli-version
 234                (concat cli-version
 235                        " (emacs mua version " notmuch-emacs-version ")")))))
 236
 237 (defun notmuch-config-get (item)
 238   "Return a value from the notmuch configuration."
 239   (let* ((val (notmuch-command-to-string "config" "get" item))
 240          (len (length val)))
 241     ;; Trim off the trailing newline (if the value is empty or not
 242     ;; configured, there will be no newline)
 243     (if (and (> len 0) (= (aref val (- len 1)) ?\n))
 244         (substring val 0 -1)
 245       val)))
 246
 247 (defun notmuch-database-path ()
 248   "Return the database.path value from the notmuch configuration."
 249   (notmuch-config-get "database.path"))
 250
 251 (defun notmuch-user-name ()
 252   "Return the user.name value from the notmuch configuration."
 253   (notmuch-config-get "user.name"))
 254
 255 (defun notmuch-user-primary-email ()
 256   "Return the user.primary_email value from the notmuch configuration."
 257   (notmuch-config-get "user.primary_email"))
 258
 259 (defun notmuch-user-other-email ()
 260   "Return the user.other_email value (as a list) from the notmuch configuration."
 261   (split-string (notmuch-config-get "user.other_email") "\n" t))
 262
 263 (defun notmuch-user-emails ()
 264   (cons (notmuch-user-primary-email) (notmuch-user-other-email)))
 265
 266 (defun notmuch-poll ()
 267   "Run \"notmuch new\" or an external script to import mail.
 268
 269 Invokes `notmuch-poll-script', \"notmuch new\", or does nothing
 270 depending on the value of `notmuch-poll-script'."
 271   (interactive)
 272   (message "Polling mail...")
 273   (if (stringp notmuch-poll-script)
 274       (unless (string= notmuch-poll-script "")
 275         (unless (equal (call-process notmuch-poll-script nil nil) 0)
 276           (error "Notmuch: poll script `%s' failed!" notmuch-poll-script)))
 277     (notmuch-call-notmuch-process "new"))
 278   (message "Polling mail...done"))
 279
 280 (defun notmuch-bury-or-kill-this-buffer ()
 281   "Undisplay the current buffer.
 282
 283 Bury the current buffer, unless there is only one window showing
 284 it, in which case it is killed."
 285   (interactive)
 286   (if (> (length (get-buffer-window-list nil nil t)) 1)
 287       (bury-buffer)
 288     (kill-buffer)))
 289
 290 (defun notmuch-prefix-key-description (key)
 291   "Given a prefix key code, return a human-readable string representation.
 292
 293 This is basically just `format-kbd-macro' but we also convert ESC to M-."
 294   (let* ((key-vector (if (vectorp key) key (vector key)))
 295          (desc (format-kbd-macro key-vector)))
 296     (if (string= desc "ESC")
 297         "M-"
 298       (concat desc " "))))
 299
 300
 301 (defun notmuch-describe-key (actual-key binding prefix ua-keys tail)
 302   "Prepend cons cells describing prefix-arg ACTUAL-KEY and ACTUAL-KEY to TAIL.
 303
 304 It does not prepend if ACTUAL-KEY is already listed in TAIL."
 305   (let ((key-string (concat prefix (key-description actual-key))))
 306     ;; We don't include documentation if the key-binding is
 307     ;; over-ridden. Note, over-riding a binding automatically hides the
 308     ;; prefixed version too.
 309     (unless (assoc key-string tail)
 310       (when (and ua-keys (symbolp binding)
 311                  (get binding 'notmuch-prefix-doc))
 312         ;; Documentation for prefixed command
 313         (let ((ua-desc (key-description ua-keys)))
 314           (push (cons (concat ua-desc " " prefix (format-kbd-macro actual-key))
 315                       (get binding 'notmuch-prefix-doc))
 316                 tail)))
 317       ;; Documentation for command
 318       (push (cons key-string
 319                   (or (and (symbolp binding)
 320                            (get binding 'notmuch-doc))
 321                       (and (functionp binding)
 322                            (let ((doc (documentation binding)))
 323                              (and doc
 324                                   (string-match "\\`.+" doc)
 325                                   (match-string 0 doc))))))
 326             tail)))
 327   tail)
 328
 329 (defun notmuch-describe-remaps (remap-keymap ua-keys base-keymap prefix tail)
 330   ;; Remappings are represented as a binding whose first "event" is
 331   ;; 'remap.  Hence, if the keymap has any remappings, it will have a
 332   ;; binding whose "key" is 'remap, and whose "binding" is itself a
 333   ;; keymap that maps not from keys to commands, but from old (remapped)
 334   ;; functions to the commands to use in their stead.
 335   (map-keymap (lambda (command binding)
 336                 (mapc (lambda (actual-key)
 337                         (setq tail
 338                               (notmuch-describe-key actual-key binding
 339                                                     prefix ua-keys tail)))
 340                       (where-is-internal command base-keymap)))
 341               remap-keymap)
 342   tail)
 343
 344 (defun notmuch-describe-keymap (keymap ua-keys base-keymap &optional prefix tail)
 345   "Return a list of cons cells, each describing one binding in KEYMAP.
 346
 347 Each cons cell consists of a string giving a human-readable
 348 description of the key, and a one-line description of the bound
 349 function.  See `notmuch-help' for an overview of how this
 350 documentation is extracted.
 351
 352 UA-KEYS should be a key sequence bound to `universal-argument'.
 353 It will be used to describe bindings of commands that support a
 354 prefix argument.  PREFIX and TAIL are used internally."
 355   (map-keymap
 356    (lambda (key binding)
 357      (cond ((mouse-event-p key) nil)
 358            ((keymapp binding)
 359             (setq tail
 360                   (if (eq key 'remap)
 361                       (notmuch-describe-remaps
 362                        binding ua-keys base-keymap prefix tail)
 363                     (notmuch-describe-keymap
 364                      binding ua-keys base-keymap
 365                      (notmuch-prefix-key-description key)
 366                      tail))))
 367            (binding
 368             (setq tail
 369                   (notmuch-describe-key (vector key)
 370                                         binding prefix ua-keys tail)))))
 371    keymap)
 372   tail)
 373
 374 (defun notmuch-substitute-command-keys (doc)
 375   "Like `substitute-command-keys' but with documentation, not function names."
 376   (let ((beg 0))
 377     (while (string-match "\\\\{\\([^}[:space:]]*\\)}" doc beg)
 378       (let ((desc
 379              (save-match-data
 380                (let* ((keymap-name (substring doc
 381                                               (match-beginning 1)
 382                                               (match-end 1)))
 383                       (keymap (symbol-value (intern keymap-name)))
 384                       (ua-keys (where-is-internal 'universal-argument keymap t))
 385                       (desc-alist (notmuch-describe-keymap keymap ua-keys keymap))
 386                       (desc-list (mapcar (lambda (arg)
 387                                            (concat (car arg) "\t" (cdr arg)))
 388                                          desc-alist)))
 389                  (mapconcat #'identity desc-list "\n")))))
 390         (setq doc (replace-match desc 1 1 doc)))
 391       (setq beg (match-end 0)))
 392     doc))
 393
 394 (defun notmuch-help ()
 395   "Display help for the current notmuch mode.
 396
 397 This is similar to `describe-function' for the current major
 398 mode, but bindings tables are shown with documentation strings
 399 rather than command names.  By default, this uses the first line
 400 of each command's documentation string.  A command can override
 401 this by setting the 'notmuch-doc property of its command symbol.
 402 A command that supports a prefix argument can explicitly document
 403 its prefixed behavior by setting the 'notmuch-prefix-doc property
 404 of its command symbol."
 405   (interactive)
 406   (let* ((mode major-mode)
 407          (doc (substitute-command-keys
 408                (notmuch-substitute-command-keys (documentation mode t)))))
 409     (with-current-buffer (generate-new-buffer "*notmuch-help*")
 410       (insert doc)
 411       (goto-char (point-min))
 412       (set-buffer-modified-p nil)
 413       (view-buffer (current-buffer) 'kill-buffer-if-not-modified))))
 414
 415 (defun notmuch-subkeymap-help ()
 416   "Show help for a subkeymap."
 417   (interactive)
 418   (let* ((key (this-command-keys-vector))
 419          (prefix (make-vector (1- (length key)) nil))
 420          (i 0))
 421     (while (< i (length prefix))
 422       (aset prefix i (aref key i))
 423       (cl-incf i))
 424     (let* ((subkeymap (key-binding prefix))
 425            (ua-keys (where-is-internal 'universal-argument nil t))
 426            (prefix-string (notmuch-prefix-key-description prefix))
 427            (desc-alist (notmuch-describe-keymap
 428                         subkeymap ua-keys subkeymap prefix-string))
 429            (desc-list (mapcar (lambda (arg) (concat (car arg) "\t" (cdr arg)))
 430                               desc-alist))
 431            (desc (mapconcat #'identity desc-list "\n")))
 432       (with-help-window (help-buffer)
 433         (with-current-buffer standard-output
 434           (insert "\nPress 'q' to quit this window.\n\n")
 435           (insert desc)))
 436       (pop-to-buffer (help-buffer)))))
 437
 438 (defvar-local notmuch-buffer-refresh-function nil
 439   "Function to call to refresh the current buffer.")
 440
 441 (defun notmuch-refresh-this-buffer ()
 442   "Refresh the current buffer."
 443   (interactive)
 444   (when notmuch-buffer-refresh-function
 445     ;; Pass prefix argument, etc.
 446     (call-interactively notmuch-buffer-refresh-function)))
 447
 448 (defun notmuch-poll-and-refresh-this-buffer ()
 449   "Invoke `notmuch-poll' to import mail, then refresh the current buffer."
 450   (interactive)
 451   (notmuch-poll)
 452   (notmuch-refresh-this-buffer))
 453
 454 (defun notmuch-refresh-all-buffers ()
 455   "Invoke `notmuch-refresh-this-buffer' on all notmuch major-mode buffers.
 456
 457 The buffers are silently refreshed, i.e. they are not forced to
 458 be displayed."
 459   (interactive)
 460   (dolist (buffer (buffer-list))
 461     (let ((buffer-mode (buffer-local-value 'major-mode buffer)))
 462       (when (memq buffer-mode '(notmuch-show-mode
 463                                 notmuch-tree-mode
 464                                 notmuch-search-mode
 465                                 notmuch-hello-mode))
 466         (with-current-buffer buffer
 467           (notmuch-refresh-this-buffer))))))
 468
 469 (defun notmuch-prettify-subject (subject)
 470   ;; This function is used by `notmuch-search-process-filter' which
 471   ;; requires that we not disrupt its' matching state.
 472   (save-match-data
 473     (if (and subject
 474              (string-match "^[ \t]*$" subject))
 475         "[No Subject]"
 476       subject)))
 477
 478 (defun notmuch-sanitize (str)
 479   "Sanitize control character in STR.
 480
 481 This includes newlines, tabs, and other funny characters."
 482   (replace-regexp-in-string "[[:cntrl:]\x7f\u2028\u2029]+" " " str))
 483
 484 (defun notmuch-escape-boolean-term (term)
 485   "Escape a boolean term for use in a query.
 486
 487 The caller is responsible for prepending the term prefix and a
 488 colon.  This performs minimal escaping in order to produce
 489 user-friendly queries."
 490   (save-match-data
 491     (if (or (equal term "")
 492             ;; To be pessimistic, only pass through terms composed
 493             ;; entirely of ASCII printing characters other than ", (,
 494             ;; and ).
 495             (string-match "[^!#-'*-~]" term))
 496         ;; Requires escaping
 497         (concat "\"" (replace-regexp-in-string "\"" "\"\"" term t t) "\"")
 498       term)))
 499
 500 (defun notmuch-id-to-query (id)
 501   "Return a query that matches the message with id ID."
 502   (concat "id:" (notmuch-escape-boolean-term id)))
 503
 504 (defun notmuch-hex-encode (str)
 505   "Hex-encode STR (e.g., as used by batch tagging).
 506
 507 This replaces spaces, percents, and double quotes in STR with
 508 %NN where NN is the hexadecimal value of the character."
 509   (replace-regexp-in-string
 510    "[ %\"]" (lambda (match) (format "%%%02x" (aref match 0))) str))
 511
 512 ;;
 513
 514 (defun notmuch-common-do-stash (text)
 515   "Common function to stash text in kill ring, and display in minibuffer."
 516   (if text
 517       (progn
 518         (kill-new text)
 519         (message "Stashed: %s" text))
 520     ;; There is nothing to stash so stash an empty string so the user
 521     ;; doesn't accidentally paste something else somewhere.
 522     (kill-new "")
 523     (message "Nothing to stash!")))
 524
 525 ;;
 526
 527 (defun notmuch-plist-delete (plist property)
 528   (let* ((xplist (cons nil plist))
 529          (pred xplist))
 530     (while (cdr pred)
 531       (when (eq (cadr pred) property)
 532         (setcdr pred (cdddr pred)))
 533       (setq pred (cddr pred)))
 534     (cdr xplist)))
 535
 536 (defun notmuch-match-content-type (t1 t2)
 537   "Return t if t1 and t2 are matching content types, taking wildcards into account."
 538   (let ((st1 (split-string t1 "/"))
 539         (st2 (split-string t2 "/")))
 540     (if (or (string= (cadr st1) "*")
 541             (string= (cadr st2) "*"))
 542         ;; Comparison of content types should be case insensitive.
 543         (string= (downcase (car st1)) (downcase (car st2)))
 544       (string= (downcase t1) (downcase t2)))))
 545
 546 (defvar notmuch-multipart/alternative-discouraged
 547   '(;; Avoid HTML parts.
 548     "text/html"
 549     ;; multipart/related usually contain a text/html part and some
 550     ;; associated graphics.
 551     "multipart/related"))
 552
 553 (defun notmuch-multipart/alternative-determine-discouraged (msg)
 554   "Return the discouraged alternatives for the specified message."
 555   ;; If a function, return the result of calling it.
 556   (if (functionp notmuch-multipart/alternative-discouraged)
 557       (funcall notmuch-multipart/alternative-discouraged msg)
 558     ;; Otherwise simply return the value of the variable, which is
 559     ;; assumed to be a list of discouraged alternatives. This is the
 560     ;; default behaviour.
 561     notmuch-multipart/alternative-discouraged))
 562
 563 (defun notmuch-multipart/alternative-choose (msg types)
 564   "Return a list of preferred types from the given list of types
 565 for this message, if present."
 566   ;; Based on `mm-preferred-alternative-precedence'.
 567   (let ((discouraged (notmuch-multipart/alternative-determine-discouraged msg))
 568         (seq types))
 569     (dolist (pref (reverse discouraged))
 570       (dolist (elem (copy-sequence seq))
 571         (when (string-match pref elem)
 572           (setq seq (nconc (delete elem seq) (list elem))))))
 573     seq))
 574
 575 (defun notmuch-parts-filter-by-type (parts type)
 576   "Given a list of message parts, return a list containing the ones matching
 577 the given type."
 578   (cl-remove-if-not
 579    (lambda (part) (notmuch-match-content-type (plist-get part :content-type) type))
 580    parts))
 581
 582 (defun notmuch--get-bodypart-raw (msg part process-crypto binaryp cache)
 583   (let* ((plist-elem (if binaryp :content-binary :content))
 584          (data (or (plist-get part plist-elem)
 585                    (with-temp-buffer
 586                      ;; Emacs internally uses a UTF-8-like multibyte string
 587                      ;; representation by default (regardless of the coding
 588                      ;; system, which only affects how it goes from outside data
 589                      ;; to this internal representation).  This *almost* never
 590                      ;; matters.  Annoyingly, it does matter if we use this data
 591                      ;; in an image descriptor, since Emacs will use its internal
 592                      ;; data buffer directly and this multibyte representation
 593                      ;; corrupts binary image formats.  Since the caller is
 594                      ;; asking for binary data, a unibyte string is a more
 595                      ;; appropriate representation anyway.
 596                      (when binaryp
 597                        (set-buffer-multibyte nil))
 598                      (let ((args `("show" "--format=raw"
 599                                    ,(format "--part=%s" (plist-get part :id))
 600                                    ,@(and process-crypto '("--decrypt=true"))
 601                                    ,(notmuch-id-to-query (plist-get msg :id))))
 602                            (coding-system-for-read
 603                             (if binaryp
 604                                 'no-conversion
 605                               (let ((coding-system
 606                                      (mm-charset-to-coding-system
 607                                       (plist-get part :content-charset))))
 608                                 ;; Sadly,
 609                                 ;; `mm-charset-to-coding-system' seems
 610                                 ;; to return things that are not
 611                                 ;; considered acceptable values for
 612                                 ;; `coding-system-for-read'.
 613                                 (if (coding-system-p coding-system)
 614                                     coding-system
 615                                   ;; RFC 2047 says that the default
 616                                   ;; charset is US-ASCII. RFC6657
 617                                   ;; complicates this somewhat.
 618                                   'us-ascii)))))
 619                        (apply #'call-process
 620                               notmuch-command nil '(t nil) nil args)
 621                        (buffer-string))))))
 622     (when (and cache data)
 623       (plist-put part plist-elem data))
 624     data))
 625
 626 (defun notmuch-get-bodypart-binary (msg part process-crypto &optional cache)
 627   "Return the unprocessed content of PART in MSG as a unibyte string.
 628
 629 This returns the \"raw\" content of the given part after content
 630 transfer decoding, but with no further processing (see the
 631 discussion of --format=raw in man notmuch-show).  In particular,
 632 this does no charset conversion.
 633
 634 If CACHE is non-nil, the content of this part will be saved in
 635 MSG (if it isn't already)."
 636   (notmuch--get-bodypart-raw msg part process-crypto t cache))
 637
 638 (defun notmuch-get-bodypart-text (msg part process-crypto &optional cache)
 639   "Return the text content of PART in MSG.
 640
 641 This returns the content of the given part as a multibyte Lisp
 642 string after performing content transfer decoding and any
 643 necessary charset decoding.
 644
 645 If CACHE is non-nil, the content of this part will be saved in
 646 MSG (if it isn't already)."
 647   (notmuch--get-bodypart-raw msg part process-crypto nil cache))
 648
 649 (defun notmuch-mm-display-part-inline (msg part content-type process-crypto)
 650   "Use the mm-decode/mm-view functions to display a part in the
 651 current buffer, if possible."
 652   (let ((display-buffer (current-buffer)))
 653     (with-temp-buffer
 654       ;; In case we already have :content, use it and tell mm-* that
 655       ;; it's already been charset-decoded by using the fake
 656       ;; `gnus-decoded' charset.  Otherwise, we'll fetch the binary
 657       ;; part content and let mm-* decode it.
 658       (let* ((have-content (plist-member part :content))
 659              (charset (if have-content
 660                           'gnus-decoded
 661                         (plist-get part :content-charset)))
 662              (handle (mm-make-handle (current-buffer)
 663                                      `(,content-type (charset . ,charset)))))
 664         ;; If the user wants the part inlined, insert the content and
 665         ;; test whether we are able to inline it (which includes both
 666         ;; capability and suitability tests).
 667         (when (mm-inlined-p handle)
 668           (if have-content
 669               (insert (notmuch-get-bodypart-text msg part process-crypto))
 670             (insert (notmuch-get-bodypart-binary msg part process-crypto)))
 671           (when (mm-inlinable-p handle)
 672             (set-buffer display-buffer)
 673             (mm-display-part handle)
 674             t))))))
 675
 676 ;; Converts a plist of headers to an alist of headers. The input plist should
 677 ;; have symbols of the form :Header as keys, and the resulting alist will have
 678 ;; symbols of the form 'Header as keys.
 679 (defun notmuch-headers-plist-to-alist (plist)
 680   (cl-loop for (key value . rest) on plist by #'cddr
 681            collect (cons (intern (substring (symbol-name key) 1)) value)))
 682
 683 (defun notmuch-face-ensure-list-form (face)
 684   "Return FACE in face list form.
 685
 686 If FACE is already a face list, it will be returned as-is.  If
 687 FACE is a face name or face plist, it will be returned as a
 688 single element face list."
 689   (if (and (listp face) (not (keywordp (car face))))
 690       face
 691     (list face)))
 692
 693 (defun notmuch-apply-face (object face &optional below start end)
 694   "Combine FACE into the 'face text property of OBJECT between START and END.
 695
 696 This function combines FACE with any existing faces between START
 697 and END in OBJECT.  Attributes specified by FACE take precedence
 698 over existing attributes unless BELOW is non-nil.
 699
 700 OBJECT may be a string, a buffer, or nil (which means the current
 701 buffer).  If object is a string, START and END are 0-based;
 702 otherwise they are buffer positions (integers or markers).  FACE
 703 must be a face name (a symbol or string), a property list of face
 704 attributes, or a list of these.  If START and/or END are omitted,
 705 they default to the beginning/end of OBJECT.  For convenience
 706 when applied to strings, this returns OBJECT."
 707   ;; A face property can have three forms: a face name (a string or
 708   ;; symbol), a property list, or a list of these two forms.  In the
 709   ;; list case, the faces will be combined, with the earlier faces
 710   ;; taking precedent.  Here we canonicalize everything to list form
 711   ;; to make it easy to combine.
 712   (let ((pos (cond (start start)
 713                    ((stringp object) 0)
 714                    (t 1)))
 715         (end (cond (end end)
 716                    ((stringp object) (length object))
 717                    (t (1+ (buffer-size object)))))
 718         (face-list (notmuch-face-ensure-list-form face)))
 719     (while (< pos end)
 720       (let* ((cur (get-text-property pos 'face object))
 721              (cur-list (notmuch-face-ensure-list-form cur))
 722              (new (cond ((null cur-list) face)
 723                         (below (append cur-list face-list))
 724                         (t (append face-list cur-list))))
 725              (next (next-single-property-change pos 'face object end)))
 726         (put-text-property pos next 'face new object)
 727         (setq pos next))))
 728   object)
 729
 730 (defun notmuch-map-text-property (start end prop func &optional object)
 731   "Transform text property PROP using FUNC.
 732
 733 Applies FUNC to each distinct value of the text property PROP
 734 between START and END of OBJECT, setting PROP to the value
 735 returned by FUNC."
 736   (while (< start end)
 737     (let ((value (get-text-property start prop object))
 738           (next (next-single-property-change start prop object end)))
 739       (put-text-property start next prop (funcall func value) object)
 740       (setq start next))))
 741
 742 (defun notmuch-logged-error (msg &optional extra)
 743   "Log MSG and EXTRA to *Notmuch errors* and signal MSG.
 744
 745 This logs MSG and EXTRA to the *Notmuch errors* buffer and
 746 signals MSG as an error.  If EXTRA is non-nil, text referring the
 747 user to the *Notmuch errors* buffer will be appended to the
 748 signaled error.  This function does not return."
 749   (with-current-buffer (get-buffer-create "*Notmuch errors*")
 750     (goto-char (point-max))
 751     (unless (bobp)
 752       (newline))
 753     (save-excursion
 754       (insert "[" (current-time-string) "]\n" msg)
 755       (unless (bolp)
 756         (newline))
 757       (when extra
 758         (insert extra)
 759         (unless (bolp)
 760           (newline)))))
 761   (error "%s%s" msg (if extra " (see *Notmuch errors* for more details)" "")))
 762
 763 (defun notmuch-check-async-exit-status (proc msg &optional command err)
 764   "If PROC exited abnormally, pop up an error buffer and signal an error.
 765
 766 This is a wrapper around `notmuch-check-exit-status' for
 767 asynchronous process sentinels.  PROC and MSG must be the
 768 arguments passed to the sentinel.  COMMAND and ERR, if provided,
 769 are passed to `notmuch-check-exit-status'.  If COMMAND is not
 770 provided, it is taken from `process-command'."
 771   (let ((exit-status
 772          (cl-case (process-status proc)
 773            ((exit) (process-exit-status proc))
 774            ((signal) msg))))
 775     (when exit-status
 776       (notmuch-check-exit-status exit-status
 777                                  (or command (process-command proc))
 778                                  nil err))))
 779
 780 (defun notmuch-check-exit-status (exit-status command &optional output err)
 781   "If EXIT-STATUS is non-zero, pop up an error buffer and signal an error.
 782
 783 If EXIT-STATUS is non-zero, pop up a notmuch error buffer
 784 describing the error and signal an Elisp error.  EXIT-STATUS must
 785 be a number indicating the exit status code of a process or a
 786 string describing the signal that terminated the process (such as
 787 returned by `call-process').  COMMAND must be a list giving the
 788 command and its arguments.  OUTPUT, if provided, is a string
 789 giving the output of command.  ERR, if provided, is the error
 790 output of command.  OUTPUT and ERR will be included in the error
 791 message."
 792   (cond
 793    ((eq exit-status 0) t)
 794    ((eq exit-status 20)
 795     (notmuch-logged-error "notmuch CLI version mismatch
 796 Emacs requested an older output format than supported by the notmuch CLI.
 797 You may need to restart Emacs or upgrade your notmuch Emacs package."))
 798    ((eq exit-status 21)
 799     (notmuch-logged-error "notmuch CLI version mismatch
 800 Emacs requested a newer output format than supported by the notmuch CLI.
 801 You may need to restart Emacs or upgrade your notmuch package."))
 802    (t
 803     (pcase-let*
 804         ((`(,command . ,args) command)
 805          (command (if (equal (file-name-nondirectory command)
 806                              notmuch-command)
 807                       notmuch-command
 808                     command))
 809          (command-string
 810           (mapconcat (lambda (arg)
 811                        (shell-quote-argument
 812                         (cond ((stringp arg) arg)
 813                               ((symbolp arg) (symbol-name arg))
 814                               (t "*UNKNOWN ARGUMENT*"))))
 815                      (cons command args)
 816                      " "))
 817          (extra
 818           (concat "command: " command-string "\n"
 819                   (if (integerp exit-status)
 820                       (format "exit status: %s\n" exit-status)
 821                     (format "exit signal: %s\n" exit-status))
 822                   (and err    (concat "stderr:\n" err))
 823                   (and output (concat "stdout:\n" output)))))
 824       (if err
 825           ;; We have an error message straight from the CLI.
 826           (notmuch-logged-error
 827            (replace-regexp-in-string "[ \n\r\t\f]*\\'" "" err) extra)
 828         ;; We only have combined output from the CLI; don't inundate
 829         ;; the user with it.  Mimic `process-lines'.
 830         (notmuch-logged-error (format "%s exited with status %s"
 831                                       command exit-status)
 832                               extra))
 833       ;; `notmuch-logged-error' does not return.
 834       ))))
 835
 836 (defun notmuch-call-notmuch--helper (destination args)
 837   "Helper for synchronous notmuch invocation commands.
 838
 839 This wraps `call-process'.  DESTINATION has the same meaning as
 840 for `call-process'.  ARGS is as described for
 841 `notmuch-call-notmuch-process'."
 842   (let (stdin-string)
 843     (while (keywordp (car args))
 844       (cl-case (car args)
 845         (:stdin-string (setq stdin-string (cadr args))
 846                        (setq args (cddr args)))
 847         (otherwise
 848          (error "Unknown keyword argument: %s" (car args)))))
 849     (if (null stdin-string)
 850         (apply #'call-process notmuch-command nil destination nil args)
 851       (insert stdin-string)
 852       (apply #'call-process-region (point-min) (point-max)
 853              notmuch-command t destination nil args))))
 854
 855 (defun notmuch-call-notmuch-process (&rest args)
 856   "Synchronously invoke `notmuch-command' with ARGS.
 857
 858 The caller may provide keyword arguments before ARGS.  Currently
 859 supported keyword arguments are:
 860
 861   :stdin-string STRING - Write STRING to stdin
 862
 863 If notmuch exits with a non-zero status, output from the process
 864 will appear in a buffer named \"*Notmuch errors*\" and an error
 865 will be signaled."
 866   (with-temp-buffer
 867     (let ((status (notmuch-call-notmuch--helper t args)))
 868       (notmuch-check-exit-status status (cons notmuch-command args)
 869                                  (buffer-string)))))
 870
 871 (defun notmuch-call-notmuch-sexp (&rest args)
 872   "Invoke `notmuch-command' with ARGS and return the parsed S-exp output.
 873
 874 This is equivalent to `notmuch-call-notmuch-process', but parses
 875 notmuch's output as an S-expression and returns the parsed value.
 876 Like `notmuch-call-notmuch-process', if notmuch exits with a
 877 non-zero status, this will report its output and signal an
 878 error."
 879   (with-temp-buffer
 880     (let ((err-file (make-temp-file "nmerr")))
 881       (unwind-protect
 882           (let ((status (notmuch-call-notmuch--helper (list t err-file) args))
 883                 (err (with-temp-buffer
 884                        (insert-file-contents err-file)
 885                        (unless (eobp)
 886                          (buffer-string)))))
 887             (notmuch-check-exit-status status (cons notmuch-command args)
 888                                        (buffer-string) err)
 889             (goto-char (point-min))
 890             (read (current-buffer)))
 891         (delete-file err-file)))))
 892
 893 (defun notmuch-start-notmuch (name buffer sentinel &rest args)
 894   "Start and return an asynchronous notmuch command.
 895
 896 This starts and returns an asynchronous process running
 897 `notmuch-command' with ARGS.  The exit status is checked via
 898 `notmuch-check-async-exit-status'.  Output written to stderr is
 899 redirected and displayed when the process exits (even if the
 900 process exits successfully).  NAME and BUFFER are the same as in
 901 `start-process'.  SENTINEL is a process sentinel function to call
 902 when the process exits, or nil for none.  The caller must *not*
 903 invoke `set-process-sentinel' directly on the returned process,
 904 as that will interfere with the handling of stderr and the exit
 905 status."
 906   (let* ((command (or (executable-find notmuch-command)
 907                       (error "Command not found: %s" notmuch-command)))
 908          (err-buffer (generate-new-buffer " *notmuch-stderr*"))
 909          (proc (make-process
 910                 :name name
 911                 :buffer buffer
 912                 :command (cons command args)
 913                 :connection-type 'pipe
 914                 :stderr err-buffer))
 915          (err-proc (get-buffer-process err-buffer)))
 916     (process-put proc 'err-buffer err-buffer)
 917     (process-put proc 'sub-sentinel sentinel)
 918     (set-process-sentinel proc #'notmuch-start-notmuch-sentinel)
 919     (set-process-sentinel err-proc #'notmuch-start-notmuch-error-sentinel)
 920     proc))
 921
 922 (defun notmuch-start-notmuch-sentinel (proc event)
 923   "Process sentinel function used by `notmuch-start-notmuch'."
 924   (let* ((err-buffer (process-get proc 'err-buffer))
 925          (err (and (buffer-live-p err-buffer)
 926                    (not (zerop (buffer-size err-buffer)))
 927                    (with-current-buffer err-buffer (buffer-string))))
 928          (sub-sentinel (process-get proc 'sub-sentinel)))
 929     (condition-case err
 930         (progn
 931           ;; Invoke the sub-sentinel, if any
 932           (when sub-sentinel
 933             (funcall sub-sentinel proc event))
 934           ;; Check the exit status.  This will signal an error if the
 935           ;; exit status is non-zero.  Don't do this if the process
 936           ;; buffer is dead since that means Emacs killed the process
 937           ;; and there's no point in telling the user that (but we
 938           ;; still check for and report stderr output below).
 939           (when (buffer-live-p (process-buffer proc))
 940             (notmuch-check-async-exit-status proc event nil err))
 941           ;; If that didn't signal an error, then any error output was
 942           ;; really warning output.  Show warnings, if any.
 943           (let ((warnings
 944                  (and err
 945                       (with-current-buffer err-buffer
 946                         (goto-char (point-min))
 947                         (end-of-line)
 948                         ;; Show first line; stuff remaining lines in the
 949                         ;; errors buffer.
 950                         (let ((l1 (buffer-substring (point-min) (point))))
 951                           (skip-chars-forward "\n")
 952                           (cons l1 (and (not (eobp))
 953                                         (buffer-substring (point)
 954                                                           (point-max)))))))))
 955             (when warnings
 956               (notmuch-logged-error (car warnings) (cdr warnings)))))
 957       (error
 958        ;; Emacs behaves strangely if an error escapes from a sentinel,
 959        ;; so turn errors into messages.
 960        (message "%s" (error-message-string err))))))
 961
 962 (defun notmuch-start-notmuch-error-sentinel (proc event)
 963   (let ((buffer (process-buffer proc)))
 964     (when (buffer-live-p buffer)
 965       (kill-buffer buffer))))
 966
 967 (defvar-local notmuch-show-process-crypto nil)
 968
 969 (defun notmuch-interactive-region ()
 970   "Return the bounds of the current interactive region.
 971
 972 This returns (BEG END), where BEG and END are the bounds of the
 973 region if the region is active, or both `point' otherwise."
 974   (if (region-active-p)
 975       (list (region-beginning) (region-end))
 976     (list (point) (point))))
 977
 978 (define-obsolete-function-alias
 979   'notmuch-search-interactive-region
 980   'notmuch-interactive-region
 981   "notmuch 0.29")
 982
 983 (provide 'notmuch-lib)
 984
 985 ;;; notmuch-lib.el ends here