git.notmuchmail.org Git - notmuch/blob - emacs/notmuch-mua.el

   1 ;; notmuch-mua.el --- emacs style mail-user-agent
   2 ;;
   3 ;; Copyright © David Edmondson
   4 ;;
   5 ;; This file is part of Notmuch.
   6 ;;
   7 ;; Notmuch is free software: you can redistribute it and/or modify it
   8 ;; under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation, either version 3 of the License, or
  10 ;; (at your option) any later version.
  11 ;;
  12 ;; Notmuch is distributed in the hope that it will be useful, but
  13 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 ;; General Public License for more details.
  16 ;;
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with Notmuch.  If not, see <http://www.gnu.org/licenses/>.
  19 ;;
  20 ;; Authors: David Edmondson <dme@dme.org>
  21
  22 (require 'message)
  23
  24 (require 'notmuch-lib)
  25 (require 'notmuch-address)
  26
  27 ;;
  28
  29 (defcustom notmuch-mua-send-hook '(notmuch-mua-message-send-hook)
  30   "Hook run before sending messages."
  31   :group 'notmuch
  32   :type 'hook)
  33
  34 (defcustom notmuch-mua-user-agent-function 'notmuch-mua-user-agent-full
  35   "Function used to generate a `User-Agent:' string. If this is
  36 `nil' then no `User-Agent:' will be generated."
  37   :group 'notmuch
  38   :type 'function
  39   :options '(notmuch-mua-user-agent-full
  40              notmuch-mua-user-agent-notmuch
  41              notmuch-mua-user-agent-emacs))
  42
  43 (defcustom notmuch-mua-hidden-headers '("^User-Agent:")
  44   "Headers that are added to the `message-mode' hidden headers
  45 list."
  46   :group 'notmuch
  47   :type '(repeat string))
  48
  49 ;;
  50
  51 (defun notmuch-mua-user-agent-full ()
  52   "Generate a `User-Agent:' string suitable for notmuch."
  53   (concat (notmuch-mua-user-agent-notmuch)
  54           " "
  55           (notmuch-mua-user-agent-emacs)))
  56
  57 (defun notmuch-mua-user-agent-notmuch ()
  58   "Generate a `User-Agent:' string suitable for notmuch."
  59   (concat "Notmuch/" (notmuch-version) " (http://notmuchmail.org)"))
  60
  61 (defun notmuch-mua-user-agent-emacs ()
  62   "Generate a `User-Agent:' string suitable for notmuch."
  63   (concat "Emacs/" emacs-version " (" system-configuration ")"))
  64
  65 (defun notmuch-mua-add-more-hidden-headers ()
  66   "Add some headers to the list that are hidden by default."
  67   (mapc (lambda (header)
  68           (when (not (member header 'message-hidden-headers))
  69             (push header message-hidden-headers)))
  70         notmuch-mua-hidden-headers))
  71
  72 (defun notmuch-mua-reply (query-string &optional sender)
  73   (let (headers
  74         body
  75         (args '("reply")))
  76     (if notmuch-show-process-crypto
  77         (setq args (append args '("--decrypt"))))
  78     (setq args (append args (list query-string)))
  79     ;; This make assumptions about the output of `notmuch reply', but
  80     ;; really only that the headers come first followed by a blank
  81     ;; line and then the body.
  82     (with-temp-buffer
  83       (apply 'call-process (append (list notmuch-command nil (list t t) nil) args))
  84       (goto-char (point-min))
  85       (if (re-search-forward "^$" nil t)
  86           (save-excursion
  87             (save-restriction
  88               (narrow-to-region (point-min) (point))
  89               (goto-char (point-min))
  90               (setq headers (mail-header-extract)))))
  91       (forward-line 1)
  92       (setq body (buffer-substring (point) (point-max))))
  93     ;; If sender is non-nil, set the From: header to its value.
  94     (when sender
  95       (mail-header-set 'from sender headers))
  96     (let
  97         ;; Overlay the composition window on that being used to read
  98         ;; the original message.
  99         ((same-window-regexps '("\\*mail .*")))
 100       (notmuch-mua-mail (mail-header 'to headers)
 101                         (mail-header 'subject headers)
 102                         (message-headers-to-generate headers t '(to subject))))
 103     ;; insert the message body - but put it in front of the signature
 104     ;; if one is present
 105     (goto-char (point-max))
 106     (if (re-search-backward message-signature-separator nil t)
 107           (forward-line -1)
 108       (goto-char (point-max)))
 109     (insert body))
 110   (set-buffer-modified-p nil)
 111
 112   (message-goto-body))
 113
 114 (defun notmuch-mua-forward-message ()
 115   (message-forward)
 116
 117   (when notmuch-mua-user-agent-function
 118     (let ((user-agent (funcall notmuch-mua-user-agent-function)))
 119       (when (not (string= "" user-agent))
 120         (message-add-header (format "User-Agent: %s" user-agent)))))
 121   (message-sort-headers)
 122   (message-hide-headers)
 123   (set-buffer-modified-p nil)
 124
 125   (message-goto-to))
 126
 127 (defun notmuch-mua-mail (&optional to subject other-headers continue
 128                                    switch-function yank-action send-actions)
 129   "Invoke the notmuch mail composition window."
 130   (interactive)
 131
 132   (when notmuch-mua-user-agent-function
 133     (let ((user-agent (funcall notmuch-mua-user-agent-function)))
 134       (when (not (string= "" user-agent))
 135         (push (cons "User-Agent" user-agent) other-headers))))
 136
 137   (unless (mail-header 'from other-headers)
 138     (push (cons "From" (concat
 139                         (notmuch-user-name) " <" (notmuch-user-primary-email) ">")) other-headers))
 140
 141   (message-mail to subject other-headers continue
 142                 switch-function yank-action send-actions)
 143   (message-sort-headers)
 144   (message-hide-headers)
 145   (set-buffer-modified-p nil)
 146
 147   (message-goto-to))
 148
 149 (defcustom notmuch-identities nil
 150   "Identities that can be used as the From: address when composing a new message.
 151
 152 If this variable is left unset, then a list will be constructed from the
 153 name and addresses configured in the notmuch configuration file."
 154   :group 'notmuch
 155   :type '(repeat string))
 156
 157 (defcustom notmuch-always-prompt-for-sender nil
 158   "Always prompt for the From: address when composing a new message."
 159   :group 'notmuch
 160   :type 'boolean)
 161
 162 (defun notmuch-mua-sender-collection ()
 163   (if notmuch-identities
 164       notmuch-identities
 165     (mapcar (lambda (address)
 166               (concat (notmuch-user-name) " <" address ">"))
 167             (cons (notmuch-user-primary-email) (notmuch-user-other-email)))))
 168
 169 (defvar notmuch-mua-sender-history nil)
 170
 171 (defun notmuch-mua-prompt-for-sender ()
 172   (interactive)
 173   (let ((collection (notmuch-mua-sender-collection)))
 174     (ido-completing-read "Send mail From: " collection
 175                          nil 'confirm nil 'notmuch-mua-sender-history (car collection))))
 176
 177 (defun notmuch-mua-new-mail (&optional prompt-for-sender)
 178   "Invoke the notmuch mail composition window.
 179
 180 If PROMPT-FOR-SENDER is non-nil, the user will be prompted for
 181 the From: address first."
 182   (interactive "P")
 183   (let ((other-headers
 184          (when (or prompt-for-sender notmuch-always-prompt-for-sender)
 185            (list (cons 'from (notmuch-mua-prompt-for-sender))))))
 186     (notmuch-mua-mail nil nil other-headers)))
 187
 188 (defun notmuch-mua-new-forward-message (&optional prompt-for-sender)
 189   "Invoke the notmuch message forwarding window.
 190
 191 If PROMPT-FOR-SENDER is non-nil, the user will be prompted for
 192 the From: address first."
 193   (interactive "P")
 194   (if (or prompt-for-sender notmuch-always-prompt-for-sender)
 195       (let* ((sender (notmuch-mua-prompt-for-sender))
 196              (address-components (mail-extract-address-components sender))
 197              (user-full-name (car address-components))
 198              (user-mail-address (cadr address-components)))
 199         (notmuch-mua-forward-message))
 200     (notmuch-mua-forward-message)))
 201
 202 (defun notmuch-mua-new-reply (query-string &optional prompt-for-sender)
 203   "Invoke the notmuch reply window."
 204   (interactive "P")
 205   (let ((sender
 206          (when (or prompt-for-sender notmuch-always-prompt-for-sender)
 207            (notmuch-mua-prompt-for-sender))))
 208     (notmuch-mua-reply query-string sender)))
 209
 210 (defun notmuch-mua-send-and-exit (&optional arg)
 211   (interactive "P")
 212   (message-send-and-exit arg))
 213
 214 (defun notmuch-mua-kill-buffer ()
 215   (interactive)
 216   (message-kill-buffer))
 217
 218 (defun notmuch-mua-message-send-hook ()
 219   "The default function used for `notmuch-mua-send-hook', this
 220 simply runs the corresponding `message-mode' hook functions."
 221   (run-hooks 'message-send-hook))
 222
 223 ;;
 224
 225 (define-mail-user-agent 'notmuch-user-agent
 226   'notmuch-mua-mail 'notmuch-mua-send-and-exit
 227   'notmuch-mua-kill-buffer 'notmuch-mua-send-hook)
 228
 229 ;; Add some more headers to the list that `message-mode' hides when
 230 ;; composing a message.
 231 (notmuch-mua-add-more-hidden-headers)
 232
 233 ;;
 234
 235 (provide 'notmuch-mua)