emacs: convert to use format-version 3
[notmuch] / emacs / notmuch-show.el
1 ;;; notmuch-show.el --- displaying notmuch forests.
2 ;;
3 ;; Copyright © Carl Worth
4 ;; Copyright © David Edmondson
5 ;;
6 ;; This file is part of Notmuch.
7 ;;
8 ;; Notmuch is free software: you can redistribute it and/or modify it
9 ;; under the terms of the GNU General Public License as published by
10 ;; the Free Software Foundation, either version 3 of the License, or
11 ;; (at your option) any later version.
12 ;;
13 ;; Notmuch is distributed in the hope that it will be useful, but
14 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
16 ;; General Public License for more details.
17 ;;
18 ;; You should have received a copy of the GNU General Public License
19 ;; along with Notmuch.  If not, see <https://www.gnu.org/licenses/>.
20 ;;
21 ;; Authors: Carl Worth <cworth@cworth.org>
22 ;;          David Edmondson <dme@dme.org>
23
24 ;;; Code:
25
26 (eval-when-compile (require 'cl))
27 (require 'mm-view)
28 (require 'message)
29 (require 'mm-decode)
30 (require 'mailcap)
31 (require 'icalendar)
32 (require 'goto-addr)
33
34 (require 'notmuch-lib)
35 (require 'notmuch-tag)
36 (require 'notmuch-query)
37 (require 'notmuch-wash)
38 (require 'notmuch-mua)
39 (require 'notmuch-crypto)
40 (require 'notmuch-print)
41 (require 'notmuch-draft)
42
43 (declare-function notmuch-call-notmuch-process "notmuch" (&rest args))
44 (declare-function notmuch-search-next-thread "notmuch" nil)
45 (declare-function notmuch-search-previous-thread "notmuch" nil)
46 (declare-function notmuch-search-show-thread "notmuch" nil)
47 (declare-function notmuch-foreach-mime-part "notmuch" (function mm-handle))
48 (declare-function notmuch-count-attachments "notmuch" (mm-handle))
49 (declare-function notmuch-save-attachments "notmuch" (mm-handle &optional queryp))
50 (declare-function notmuch-tree "notmuch-tree"
51                   (&optional query query-context target buffer-name open-target))
52 (declare-function notmuch-tree-get-message-properties "notmuch-tree" nil)
53 (declare-function notmuch-read-query "notmuch" (prompt))
54 (declare-function notmuch-draft-resume "notmuch-draft" (id))
55
56 (defcustom notmuch-message-headers '("Subject" "To" "Cc" "Date")
57   "Headers that should be shown in a message, in this order.
58
59 For an open message, all of these headers will be made visible
60 according to `notmuch-message-headers-visible' or can be toggled
61 with `notmuch-show-toggle-visibility-headers'. For a closed message,
62 only the first header in the list will be visible."
63   :type '(repeat string)
64   :group 'notmuch-show)
65
66 (defcustom notmuch-message-headers-visible t
67   "Should the headers be visible by default?
68
69 If this value is non-nil, then all of the headers defined in
70 `notmuch-message-headers' will be visible by default in the display
71 of each message. Otherwise, these headers will be hidden and
72 `notmuch-show-toggle-visibility-headers' can be used to make them
73 visible for any given message."
74   :type 'boolean
75   :group 'notmuch-show)
76
77 (defcustom notmuch-show-relative-dates t
78   "Display relative dates in the message summary line."
79   :type 'boolean
80   :group 'notmuch-show)
81
82 (defvar notmuch-show-markup-headers-hook '(notmuch-show-colour-headers)
83   "A list of functions called to decorate the headers listed in
84 `notmuch-message-headers'.")
85
86 (defcustom notmuch-show-hook '(notmuch-show-turn-on-visual-line-mode)
87   "Functions called after populating a `notmuch-show' buffer."
88   :type 'hook
89   :options '(notmuch-show-turn-on-visual-line-mode)
90   :group 'notmuch-show
91   :group 'notmuch-hooks)
92
93 (defcustom notmuch-show-insert-text/plain-hook '(notmuch-wash-wrap-long-lines
94                                                  notmuch-wash-tidy-citations
95                                                  notmuch-wash-elide-blank-lines
96                                                  notmuch-wash-excerpt-citations)
97   "Functions used to improve the display of text/plain parts."
98   :type 'hook
99   :options '(notmuch-wash-convert-inline-patch-to-part
100              notmuch-wash-wrap-long-lines
101              notmuch-wash-tidy-citations
102              notmuch-wash-elide-blank-lines
103              notmuch-wash-excerpt-citations)
104   :group 'notmuch-show
105   :group 'notmuch-hooks)
106
107 (defcustom notmuch-show-max-text-part-size 100000
108   "Maximum size of a text part to be shown by default in characters.
109
110 Set to 0 to show the part regardless of size."
111   :type 'integer
112   :group 'notmuch-show)
113
114 ;; Mostly useful for debugging.
115 (defcustom notmuch-show-all-multipart/alternative-parts nil
116   "Should all parts of multipart/alternative parts be shown?"
117   :type 'boolean
118   :group 'notmuch-show)
119
120 (defcustom notmuch-show-indent-messages-width 1
121   "Width of message indentation in threads.
122
123 Messages are shown indented according to their depth in a thread.
124 This variable determines the width of this indentation measured
125 in number of blanks.  Defaults to `1', choose `0' to disable
126 indentation."
127   :type 'integer
128   :group 'notmuch-show)
129
130 (defcustom notmuch-show-indent-multipart nil
131   "Should the sub-parts of a multipart/* part be indented?"
132   ;; dme: Not sure which is a good default.
133   :type 'boolean
134   :group 'notmuch-show)
135
136 (defcustom notmuch-show-part-button-default-action 'notmuch-show-save-part
137   "Default part header button action (on ENTER or mouse click)."
138   :group 'notmuch-show
139   :type '(choice (const :tag "Save part"
140                         notmuch-show-save-part)
141                  (const :tag "View part"
142                         notmuch-show-view-part)
143                  (const :tag "View interactively"
144                         notmuch-show-interactively-view-part)))
145
146 (defcustom notmuch-show-only-matching-messages nil
147   "Only matching messages are shown by default."
148   :type 'boolean
149   :group 'notmuch-show)
150
151 ;; By default, block all external images to prevent privacy leaks and
152 ;; potential attacks.
153 (defcustom notmuch-show-text/html-blocked-images "."
154   "Remote images that have URLs matching this regexp will be blocked."
155   :type '(choice (const nil) regexp)
156   :group 'notmuch-show)
157
158 (defvar notmuch-show-thread-id nil)
159 (make-variable-buffer-local 'notmuch-show-thread-id)
160
161 (defvar notmuch-show-parent-buffer nil)
162 (make-variable-buffer-local 'notmuch-show-parent-buffer)
163
164 (defvar notmuch-show-query-context nil)
165 (make-variable-buffer-local 'notmuch-show-query-context)
166
167 (defvar notmuch-show-process-crypto nil)
168 (make-variable-buffer-local 'notmuch-show-process-crypto)
169
170 (defvar notmuch-show-elide-non-matching-messages nil)
171 (make-variable-buffer-local 'notmuch-show-elide-non-matching-messages)
172
173 (defvar notmuch-show-indent-content t)
174 (make-variable-buffer-local 'notmuch-show-indent-content)
175
176 (defvar notmuch-show-attachment-debug nil
177   "If t log stdout and stderr from attachment handlers
178
179 When set to nil (the default) stdout and stderr from attachment
180 handlers is discarded. When set to t the stdout and stderr from
181 each attachment handler is logged in buffers with names beginning
182 \" *notmuch-part*\". This option requires emacs version at least
183 24.3 to work.")
184
185 (defcustom notmuch-show-stash-mlarchive-link-alist
186   '(("Gmane" . "http://mid.gmane.org/")
187     ("MARC" . "https://marc.info/?i=")
188     ("Mail Archive, The" . "https://mid.mail-archive.com/")
189     ("LKML" . "https://lkml.kernel.org/r/")
190     ;; FIXME: can these services be searched by `Message-Id' ?
191     ;; ("MarkMail" . "http://markmail.org/")
192     ;; ("Nabble" . "http://nabble.com/")
193     ;; ("opensubscriber" . "http://opensubscriber.com/")
194     )
195   "List of Mailing List Archives to use when stashing links.
196
197 This list is used for generating a Mailing List Archive reference
198 URI with the current message's Message-Id in
199 `notmuch-show-stash-mlarchive-link'.
200
201 If the cdr of the alist element is not a function, the cdr is
202 expected to contain a URI that is concatenated with the current
203 message's Message-Id to create a ML archive reference URI.
204
205 If the cdr is a function, the function is called with the
206 Message-Id as the argument, and the function is expected to
207 return the ML archive reference URI."
208   :type '(alist :key-type (string :tag "Name")
209                 :value-type (choice
210                              (string :tag "URL")
211                              (function :tag "Function returning the URL")))
212   :group 'notmuch-show)
213
214 (defcustom notmuch-show-stash-mlarchive-link-default "Gmane"
215   "Default Mailing List Archive to use when stashing links.
216
217 This is used when `notmuch-show-stash-mlarchive-link' isn't
218 provided with an MLA argument nor `completing-read' input."
219   :type `(choice
220           ,@(mapcar
221              (lambda (mla)
222                (list 'const :tag (car mla) :value (car mla)))
223              notmuch-show-stash-mlarchive-link-alist))
224   :group 'notmuch-show)
225
226 (defcustom notmuch-show-mark-read-tags '("-unread")
227   "List of tag changes to apply to a message when it is marked as read.
228
229 Tags starting with \"+\" (or not starting with either \"+\" or
230 \"-\") in the list will be added, and tags starting with \"-\"
231 will be removed from the message being marked as read.
232
233 For example, if you wanted to remove an \"unread\" tag and add a
234 \"read\" tag (which would make little sense), you would set:
235     (\"-unread\" \"+read\")"
236   :type '(repeat string)
237   :group 'notmuch-show)
238
239 (defcustom notmuch-show-mark-read-function #'notmuch-show-seen-current-message
240   "Function to control which messages are marked read.
241
242 The function should take two arguments START and END which will
243 be the start and end of the visible portion of the buffer and
244 should mark the appropriate messages read by applying
245 `notmuch-show-mark-read'. This function will be called after
246 every user interaction with notmuch."
247   :type 'function
248   :group 'notmuch-show)
249
250 (defcustom notmuch-show-imenu-indent nil
251   "Should Imenu display messages indented.
252
253 By default, Imenu (see Info node `(emacs) Imenu') in a
254 notmuch-show buffer displays all messages straight.  This is
255 because the default Emacs frontend for Imenu makes it difficult
256 to select an Imenu entry with spaces in front.  Other imenu
257 frontends such as counsel-imenu does not have this limitation.
258 In these cases, Imenu entries can be indented to reflect the
259 position of the message in the thread."
260   :type 'boolean
261   :group 'notmuch-show)
262
263 (defmacro with-current-notmuch-show-message (&rest body)
264   "Evaluate body with current buffer set to the text of current message"
265   `(save-excursion
266      (let ((id (notmuch-show-get-message-id)))
267        (let ((buf (generate-new-buffer (concat "*notmuch-msg-" id "*"))))
268          (with-current-buffer buf
269            (let ((coding-system-for-read 'no-conversion))
270              (call-process notmuch-command nil t nil "show" "--format=raw" id))
271            ,@body)
272          (kill-buffer buf)))))
273
274 (defun notmuch-show-turn-on-visual-line-mode ()
275   "Enable Visual Line mode."
276   (visual-line-mode t))
277
278 ;; DEPRECATED in Notmuch 0.16 since we now have convenient part
279 ;; commands.  We'll keep the command around for a version or two in
280 ;; case people want to bind it themselves.
281 (defun notmuch-show-view-all-mime-parts ()
282   "Use external viewers to view all attachments from the current message."
283   (interactive)
284   (with-current-notmuch-show-message
285    ;; We override the mm-inline-media-tests to indicate which message
286    ;; parts are already sufficiently handled by the original
287    ;; presentation of the message in notmuch-show mode. These parts
288    ;; will be inserted directly into the temporary buffer of
289    ;; with-current-notmuch-show-message and silently discarded.
290    ;;
291    ;; Any MIME part not explicitly mentioned here will be handled by an
292    ;; external viewer as configured in the various mailcap files.
293    (let ((mm-inline-media-tests '(
294                                   ("text/.*" ignore identity)
295                                   ("application/pgp-signature" ignore identity)
296                                   ("multipart/alternative" ignore identity)
297                                   ("multipart/mixed" ignore identity)
298                                   ("multipart/related" ignore identity)
299                                  )))
300      (mm-display-parts (mm-dissect-buffer)))))
301
302 (defun notmuch-show-save-attachments ()
303   "Save all attachments from the current message."
304   (interactive)
305   (with-current-notmuch-show-message
306    (let ((mm-handle (mm-dissect-buffer)))
307      (notmuch-save-attachments
308       mm-handle (> (notmuch-count-attachments mm-handle) 1))))
309   (message "Done"))
310
311 (defun notmuch-show-with-message-as-text (fn)
312   "Apply FN to a text representation of the current message.
313
314 FN is called with one argument, the message properties. It should
315 operation on the contents of the current buffer."
316
317   ;; Remake the header to ensure that all information is available.
318   (let* ((to (notmuch-show-get-to))
319          (cc (notmuch-show-get-cc))
320          (from (notmuch-show-get-from))
321          (subject (notmuch-show-get-subject))
322          (date (notmuch-show-get-date))
323          (tags (notmuch-show-get-tags))
324          (depth (notmuch-show-get-depth))
325
326          (header (concat
327                   "Subject: " subject "\n"
328                   "To: " to "\n"
329                   (if (not (string= cc ""))
330                       (concat "Cc: " cc "\n")
331                     "")
332                   "From: " from "\n"
333                   "Date: " date "\n"
334                   (if tags
335                       (concat "Tags: "
336                               (mapconcat #'identity tags ", ") "\n")
337                     "")))
338          (all (buffer-substring (notmuch-show-message-top)
339                                 (notmuch-show-message-bottom)))
340
341          (props (notmuch-show-get-message-properties))
342          (indenting notmuch-show-indent-content))
343     (with-temp-buffer
344       (insert all)
345       (if indenting
346           (indent-rigidly (point-min) (point-max) (- (* notmuch-show-indent-messages-width depth))))
347       ;; Remove the original header.
348       (goto-char (point-min))
349       (re-search-forward "^$" (point-max) nil)
350       (delete-region (point-min) (point))
351       (insert header)
352       (funcall fn props))))
353
354 (defun notmuch-show-print-message ()
355   "Print the current message."
356   (interactive)
357   (notmuch-show-with-message-as-text 'notmuch-print-message))
358
359 (defun notmuch-show-fontify-header ()
360   (let ((face (cond
361                ((looking-at "[Tt]o:")
362                 'message-header-to)
363                ((looking-at "[Bb]?[Cc][Cc]:")
364                 'message-header-cc)
365                ((looking-at "[Ss]ubject:")
366                 'message-header-subject)
367                (t
368                 'message-header-other))))
369
370     (overlay-put (make-overlay (point) (re-search-forward ":"))
371                  'face 'message-header-name)
372     (overlay-put (make-overlay (point) (re-search-forward ".*$"))
373                  'face face)))
374
375 (defun notmuch-show-colour-headers ()
376   "Apply some colouring to the current headers."
377   (goto-char (point-min))
378   (while (looking-at "^[A-Za-z][-A-Za-z0-9]*:")
379     (notmuch-show-fontify-header)
380     (forward-line)))
381
382 (defun notmuch-show-spaces-n (n)
383   "Return a string comprised of `n' spaces."
384   (make-string n ? ))
385
386 (defun notmuch-show-update-tags (tags)
387   "Update the displayed tags of the current message."
388   (save-excursion
389     (goto-char (notmuch-show-message-top))
390     (if (re-search-forward "(\\([^()]*\\))$" (line-end-position) t)
391         (let ((inhibit-read-only t))
392           (replace-match (concat "("
393                                  (notmuch-tag-format-tags tags (notmuch-show-get-prop :orig-tags))
394                                  ")"))))))
395
396 (defun notmuch-clean-address (address)
397   "Try to clean a single email ADDRESS for display. Return a cons
398 cell of (AUTHOR_EMAIL AUTHOR_NAME). Return (ADDRESS nil) if
399 parsing fails."
400   (condition-case nil
401     (let (p-name p-address)
402       ;; It would be convenient to use `mail-header-parse-address',
403       ;; but that expects un-decoded mailbox parts, whereas our
404       ;; mailbox parts are already decoded (and hence may contain
405       ;; UTF-8). Given that notmuch should handle most of the awkward
406       ;; cases, some simple string deconstruction should be sufficient
407       ;; here.
408       (cond
409        ;; "User <user@dom.ain>" style.
410        ((string-match "\\(.*\\) <\\(.*\\)>" address)
411         (setq p-name (match-string 1 address)
412               p-address (match-string 2 address)))
413
414        ;; "<user@dom.ain>" style.
415        ((string-match "<\\(.*\\)>" address)
416         (setq p-address (match-string 1 address)))
417
418        ;; Everything else.
419        (t
420         (setq p-address address)))
421
422       (when p-name
423         ;; Remove elements of the mailbox part that are not relevant for
424         ;; display, even if they are required during transport:
425         ;;
426         ;; Backslashes.
427         (setq p-name (replace-regexp-in-string "\\\\" "" p-name))
428
429         ;; Outer single and double quotes, which might be nested.
430         (loop
431          with start-of-loop
432          do (setq start-of-loop p-name)
433
434          when (string-match "^\"\\(.*\\)\"$" p-name)
435          do (setq p-name (match-string 1 p-name))
436
437          when (string-match "^'\\(.*\\)'$" p-name)
438          do (setq p-name (match-string 1 p-name))
439
440          until (string= start-of-loop p-name)))
441
442       ;; If the address is 'foo@bar.com <foo@bar.com>' then show just
443       ;; 'foo@bar.com'.
444       (when (string= p-name p-address)
445         (setq p-name nil))
446
447       (cons p-address p-name))
448     (error (cons address nil))))
449
450 (defun notmuch-show-clean-address (address)
451   "Try to clean a single email ADDRESS for display.  Return
452 unchanged ADDRESS if parsing fails."
453   (let* ((clean-address (notmuch-clean-address address))
454          (p-address (car clean-address))
455          (p-name (cdr clean-address)))
456     ;; If no name, return just the address.
457     (if (not p-name)
458         p-address
459       ;; Otherwise format the name and address together.
460       (concat p-name " <" p-address ">"))))
461
462 (defun notmuch-show-insert-headerline (headers date tags depth)
463   "Insert a notmuch style headerline based on HEADERS for a
464 message at DEPTH in the current thread."
465   (let ((start (point)))
466     (insert (notmuch-show-spaces-n (* notmuch-show-indent-messages-width depth))
467             (notmuch-sanitize
468              (notmuch-show-clean-address (plist-get headers :From)))
469             " ("
470             date
471             ") ("
472             (notmuch-tag-format-tags tags tags)
473             ")\n")
474     (overlay-put (make-overlay start (point)) 'face 'notmuch-message-summary-face)))
475
476 (defun notmuch-show-insert-header (header header-value)
477   "Insert a single header."
478   (insert header ": " (notmuch-sanitize header-value) "\n"))
479
480 (defun notmuch-show-insert-headers (headers)
481   "Insert the headers of the current message."
482   (let ((start (point)))
483     (mapc (lambda (header)
484             (let* ((header-symbol (intern (concat ":" header)))
485                    (header-value (plist-get headers header-symbol)))
486               (if (and header-value
487                        (not (string-equal "" header-value)))
488                   (notmuch-show-insert-header header header-value))))
489           notmuch-message-headers)
490     (save-excursion
491       (save-restriction
492         (narrow-to-region start (point-max))
493         (run-hooks 'notmuch-show-markup-headers-hook)))))
494
495 (define-button-type 'notmuch-show-part-button-type
496   'action 'notmuch-show-part-button-default
497   'follow-link t
498   'face 'message-mml
499   :supertype 'notmuch-button-type)
500
501 (defun notmuch-show-insert-part-header (nth content-type declared-type &optional name comment)
502   (let ((button)
503         (base-label (concat (when name (concat name ": "))
504                             declared-type
505                             (unless (string-equal declared-type content-type)
506                               (concat " (as " content-type ")"))
507                             comment)))
508
509     (setq button
510           (insert-button
511            (concat "[ " base-label " ]")
512            :base-label base-label
513            :type 'notmuch-show-part-button-type
514            :notmuch-part-hidden nil))
515     (insert "\n")
516     ;; return button
517     button))
518
519 (defun notmuch-show-toggle-part-invisibility (&optional button)
520   (interactive)
521   (let ((button (or button (button-at (point)))))
522     (when button
523       (let ((overlay (button-get button 'overlay))
524             (lazy-part (button-get button :notmuch-lazy-part)))
525         ;; We have a part to toggle if there is an overlay or if there is a lazy part.
526         ;; If neither is present we cannot toggle the part so we just return nil.
527         (when (or overlay lazy-part)
528           (let* ((show (button-get button :notmuch-part-hidden))
529                  (new-start (button-start button))
530                  (button-label (button-get button :base-label))
531                  (old-point (point))
532                  (properties (text-properties-at (button-start button)))
533                  (inhibit-read-only t))
534             ;; Toggle the button itself.
535             (button-put button :notmuch-part-hidden (not show))
536             (goto-char new-start)
537             (insert "[ " button-label (if show " ]" " (hidden) ]"))
538             (set-text-properties new-start (point) properties)
539             (let ((old-end (button-end button)))
540               (move-overlay button new-start (point))
541               (delete-region (point) old-end))
542             (goto-char (min old-point (1- (button-end button))))
543             ;; Return nil if there is a lazy-part, it is empty, and we are
544             ;; trying to show it.  In all other cases return t.
545             (if lazy-part
546                 (when show
547                   (button-put button :notmuch-lazy-part nil)
548                   (notmuch-show-lazy-part lazy-part button))
549               ;; else there must be an overlay.
550               (overlay-put overlay 'invisible (not show))
551               t)))))))
552
553 ;; Part content ID handling
554
555 (defvar notmuch-show--cids nil
556   "Alist from raw content ID to (MSG PART).")
557 (make-variable-buffer-local 'notmuch-show--cids)
558
559 (defun notmuch-show--register-cids (msg part)
560   "Register content-IDs in PART and all of PART's sub-parts."
561   (let ((content-id (plist-get part :content-id)))
562     (when content-id
563       ;; Note that content-IDs are globally unique, except when they
564       ;; aren't: RFC 2046 section 5.1.4 permits children of a
565       ;; multipart/alternative to have the same content-ID, in which
566       ;; case the MUA is supposed to pick the best one it can render.
567       ;; We simply add the content-ID to the beginning of our alist;
568       ;; so if this happens, we'll take the last (and "best")
569       ;; alternative (even if we can't render it).
570       (push (list content-id msg part) notmuch-show--cids)))
571   ;; Recurse on sub-parts
572   (let ((ctype (notmuch-split-content-type
573                 (downcase (plist-get part :content-type)))))
574     (cond ((equal (first ctype) "multipart")
575            (mapc (apply-partially #'notmuch-show--register-cids msg)
576                  (plist-get part :content)))
577           ((equal ctype '("message" "rfc822"))
578            (notmuch-show--register-cids
579             msg
580             (first (plist-get (first (plist-get part :content)) :body)))))))
581
582 (defun notmuch-show--get-cid-content (cid)
583   "Return a list (CID-content content-type) or nil.
584
585 This will only find parts from messages that have been inserted
586 into the current buffer.  CID must be a raw content ID, without
587 enclosing angle brackets, a cid: prefix, or URL encoding.  This
588 will return nil if the CID is unknown or cannot be retrieved."
589   (let ((descriptor (cdr (assoc cid notmuch-show--cids))))
590     (when descriptor
591       (let* ((msg (first descriptor))
592              (part (second descriptor))
593              ;; Request caching for this content, as some messages
594              ;; reference the same cid: part many times (hundreds!).
595              (content (notmuch-get-bodypart-binary
596                        msg part notmuch-show-process-crypto 'cache))
597              (content-type (plist-get part :content-type)))
598         (list content content-type)))))
599
600 (defun notmuch-show-setup-w3m ()
601   "Instruct w3m how to retrieve content from a \"related\" part of a message."
602   (interactive)
603   (if (boundp 'w3m-cid-retrieve-function-alist)
604     (unless (assq 'notmuch-show-mode w3m-cid-retrieve-function-alist)
605       (push (cons 'notmuch-show-mode #'notmuch-show--cid-w3m-retrieve)
606             w3m-cid-retrieve-function-alist)))
607   (setq mm-inline-text-html-with-images t))
608
609 (defvar w3m-current-buffer) ;; From `w3m.el'.
610 (defun notmuch-show--cid-w3m-retrieve (url &rest args)
611   ;; url includes the cid: prefix and is URL encoded (see RFC 2392).
612   (let* ((cid (url-unhex-string (substring url 4)))
613          (content-and-type
614           (with-current-buffer w3m-current-buffer
615             (notmuch-show--get-cid-content cid))))
616     (when content-and-type
617       (insert (first content-and-type))
618       (second content-and-type))))
619
620 ;; MIME part renderers
621
622 (defun notmuch-show-multipart/*-to-list (part)
623   (mapcar (lambda (inner-part) (plist-get inner-part :content-type))
624           (plist-get part :content)))
625
626 (defun notmuch-show-insert-part-multipart/alternative (msg part content-type nth depth button)
627   (let ((chosen-type (car (notmuch-multipart/alternative-choose msg (notmuch-show-multipart/*-to-list part))))
628         (inner-parts (plist-get part :content))
629         (start (point)))
630     ;; This inserts all parts of the chosen type rather than just one,
631     ;; but it's not clear that this is the wrong thing to do - which
632     ;; should be chosen if there are more than one that match?
633     (mapc (lambda (inner-part)
634             (let* ((inner-type (plist-get inner-part :content-type))
635                   (hide (not (or notmuch-show-all-multipart/alternative-parts
636                            (string= chosen-type inner-type)))))
637               (notmuch-show-insert-bodypart msg inner-part depth hide)))
638           inner-parts)
639
640     (when notmuch-show-indent-multipart
641       (indent-rigidly start (point) 1)))
642   t)
643
644 (defun notmuch-show-insert-part-multipart/related (msg part content-type nth depth button)
645   (let ((inner-parts (plist-get part :content))
646         (start (point)))
647
648     ;; Render the primary part.  FIXME: Support RFC 2387 Start header.
649     (notmuch-show-insert-bodypart msg (car inner-parts) depth)
650     ;; Add hidden buttons for the rest
651     (mapc (lambda (inner-part)
652             (notmuch-show-insert-bodypart msg inner-part depth t))
653           (cdr inner-parts))
654
655     (when notmuch-show-indent-multipart
656       (indent-rigidly start (point) 1)))
657   t)
658
659 (defun notmuch-show-insert-part-multipart/signed (msg part content-type nth depth button)
660   (when button
661     (button-put button 'face 'notmuch-crypto-part-header))
662
663   ;; Insert a button detailing the signature status.
664   (notmuch-crypto-insert-sigstatus-button (car (plist-get part :sigstatus))
665                                           (notmuch-show-get-header :From msg))
666
667   (let ((inner-parts (plist-get part :content))
668         (start (point)))
669     ;; Show all of the parts.
670     (mapc (lambda (inner-part)
671             (notmuch-show-insert-bodypart msg inner-part depth))
672           inner-parts)
673
674     (when notmuch-show-indent-multipart
675       (indent-rigidly start (point) 1)))
676   t)
677
678 (defun notmuch-show-insert-part-multipart/encrypted (msg part content-type nth depth button)
679   (when button
680     (button-put button 'face 'notmuch-crypto-part-header))
681
682   ;; Insert a button detailing the encryption status.
683   (notmuch-crypto-insert-encstatus-button (car (plist-get part :encstatus)))
684
685   ;; Insert a button detailing the signature status.
686   (notmuch-crypto-insert-sigstatus-button (car (plist-get part :sigstatus))
687                                           (notmuch-show-get-header :From msg))
688
689   (let ((inner-parts (plist-get part :content))
690         (start (point)))
691     ;; Show all of the parts.
692     (mapc (lambda (inner-part)
693             (notmuch-show-insert-bodypart msg inner-part depth))
694           inner-parts)
695
696     (when notmuch-show-indent-multipart
697       (indent-rigidly start (point) 1)))
698   t)
699
700 (defun notmuch-show-insert-part-application/pgp-encrypted (msg part content-type nth depth button)
701   t)
702
703 (defun notmuch-show-insert-part-multipart/* (msg part content-type nth depth button)
704   (let ((inner-parts (plist-get part :content))
705         (start (point)))
706     ;; Show all of the parts.
707     (mapc (lambda (inner-part)
708             (notmuch-show-insert-bodypart msg inner-part depth))
709           inner-parts)
710
711     (when notmuch-show-indent-multipart
712       (indent-rigidly start (point) 1)))
713   t)
714
715 (defun notmuch-show-insert-part-message/rfc822 (msg part content-type nth depth button)
716   (let* ((message (car (plist-get part :content)))
717          (body (car (plist-get message :body)))
718          (start (point)))
719
720     ;; Override `notmuch-message-headers' to force `From' to be
721     ;; displayed.
722     (let ((notmuch-message-headers '("From" "Subject" "To" "Cc" "Date")))
723       (notmuch-show-insert-headers (plist-get message :headers)))
724
725     ;; Blank line after headers to be compatible with the normal
726     ;; message display.
727     (insert "\n")
728
729     ;; Show the body
730     (notmuch-show-insert-bodypart msg body depth)
731
732     (when notmuch-show-indent-multipart
733       (indent-rigidly start (point) 1)))
734   t)
735
736 (defun notmuch-show-insert-part-text/plain (msg part content-type nth depth button)
737   ;; For backward compatibility we want to apply the text/plain hook
738   ;; to the whole of the part including the part button if there is
739   ;; one.
740   (let ((start (if button
741                    (button-start button)
742                  (point))))
743     (insert (notmuch-get-bodypart-text msg part notmuch-show-process-crypto))
744     (save-excursion
745       (save-restriction
746         (narrow-to-region start (point-max))
747         (run-hook-with-args 'notmuch-show-insert-text/plain-hook msg depth))))
748   t)
749
750 (defun notmuch-show-insert-part-text/calendar (msg part content-type nth depth button)
751   (insert (with-temp-buffer
752             (insert (notmuch-get-bodypart-text msg part notmuch-show-process-crypto))
753             ;; notmuch-get-bodypart-text does no newline conversion.
754             ;; Replace CRLF with LF before icalendar can use it.
755             (goto-char (point-min))
756             (while (re-search-forward "\r\n" nil t)
757               (replace-match "\n" nil nil))
758             (let ((file (make-temp-file "notmuch-ical"))
759                   result)
760               (unwind-protect
761                   (progn
762                     (unless (icalendar-import-buffer file t)
763                       (error "Icalendar import error. See *icalendar-errors* for more information"))
764                     (set-buffer (get-file-buffer file))
765                     (setq result (buffer-substring (point-min) (point-max)))
766                     (set-buffer-modified-p nil)
767                     (kill-buffer (current-buffer)))
768                 (delete-file file))
769               result)))
770   t)
771
772 ;; For backwards compatibility.
773 (defun notmuch-show-insert-part-text/x-vcalendar (msg part content-type nth depth button)
774   (notmuch-show-insert-part-text/calendar msg part content-type nth depth button))
775
776 (defun notmuch-show-get-mime-type-of-application/octet-stream (part)
777   ;; If we can deduce a MIME type from the filename of the attachment,
778   ;; we return that.
779   (if (plist-get part :filename)
780       (let ((extension (file-name-extension (plist-get part :filename)))
781             mime-type)
782         (if extension
783             (progn
784               (mailcap-parse-mimetypes)
785               (setq mime-type (mailcap-extension-to-mime extension))
786               (if (and mime-type
787                        (not (string-equal mime-type "application/octet-stream")))
788                   mime-type
789                 nil))
790           nil))))
791
792 (defun notmuch-show-insert-part-text/html (msg part content-type nth depth button)
793   (if (eq mm-text-html-renderer 'shr)
794       ;; It's easier to drive shr ourselves than to work around the
795       ;; goofy things `mm-shr' does (like irreversibly taking over
796       ;; content ID handling).
797
798       ;; FIXME: If we block an image, offer a button to load external
799       ;; images.
800       (let ((shr-blocked-images notmuch-show-text/html-blocked-images))
801         (notmuch-show--insert-part-text/html-shr msg part))
802     ;; Otherwise, let message-mode do the heavy lifting
803     ;;
804     ;; w3m sets up a keymap which "leaks" outside the invisible region
805     ;; and causes strange effects in notmuch. We set
806     ;; mm-inline-text-html-with-w3m-keymap to nil to tell w3m not to
807     ;; set a keymap (so the normal notmuch-show-mode-map remains).
808     (let ((mm-inline-text-html-with-w3m-keymap nil)
809           ;; FIXME: If we block an image, offer a button to load external
810           ;; images.
811           (gnus-blocked-images notmuch-show-text/html-blocked-images))
812       (notmuch-show-insert-part-*/* msg part content-type nth depth button))))
813
814 ;; These functions are used by notmuch-show--insert-part-text/html-shr
815 (declare-function libxml-parse-html-region "xml.c")
816 (declare-function shr-insert-document "shr")
817
818 (defun notmuch-show--insert-part-text/html-shr (msg part)
819   ;; Make sure shr is loaded before we start let-binding its globals
820   (require 'shr)
821   (let ((dom (let ((process-crypto notmuch-show-process-crypto))
822                (with-temp-buffer
823                  (insert (notmuch-get-bodypart-text msg part process-crypto))
824                  (libxml-parse-html-region (point-min) (point-max)))))
825         (shr-content-function
826          (lambda (url)
827            ;; shr strips the "cid:" part of URL, but doesn't
828            ;; URL-decode it (see RFC 2392).
829            (let ((cid (url-unhex-string url)))
830              (first (notmuch-show--get-cid-content cid))))))
831     (shr-insert-document dom)
832     t))
833
834 (defun notmuch-show-insert-part-*/* (msg part content-type nth depth button)
835   ;; This handler _must_ succeed - it is the handler of last resort.
836   (notmuch-mm-display-part-inline msg part content-type notmuch-show-process-crypto)
837   t)
838
839 ;; Functions for determining how to handle MIME parts.
840
841 (defun notmuch-show-handlers-for (content-type)
842   "Return a list of content handlers for a part of type CONTENT-TYPE."
843   (let (result)
844     (mapc (lambda (func)
845             (if (functionp func)
846                 (push func result)))
847           ;; Reverse order of prefrence.
848           (list (intern (concat "notmuch-show-insert-part-*/*"))
849                 (intern (concat
850                          "notmuch-show-insert-part-"
851                          (car (notmuch-split-content-type content-type))
852                          "/*"))
853                 (intern (concat "notmuch-show-insert-part-" content-type))))
854     result))
855
856 ;; \f
857
858 (defun notmuch-show-insert-bodypart-internal (msg part content-type nth depth button)
859   ;; Run the handlers until one of them succeeds.
860   (loop for handler in (notmuch-show-handlers-for content-type)
861         until (condition-case err
862                   (funcall handler msg part content-type nth depth button)
863                 ;; Specifying `debug' here lets the debugger run if
864                 ;; `debug-on-error' is non-nil.
865                 ((debug error)
866                  (insert "!!! Bodypart handler `" (prin1-to-string handler) "' threw an error:\n"
867                          "!!! " (error-message-string err) "\n")
868                  nil))))
869
870 (defun notmuch-show-create-part-overlays (button beg end)
871   "Add an overlay to the part between BEG and END"
872
873   ;; If there is no button (i.e., the part is text/plain and the first
874   ;; part) or if the part has no content then we don't make the part
875   ;; toggleable.
876   (when (and button (/= beg end))
877     (button-put button 'overlay (make-overlay beg end))
878     ;; Return true if we created an overlay.
879     t))
880
881 (defun notmuch-show-record-part-information (part beg end)
882   "Store PART as a text property from BEG to END"
883
884   ;; Record part information.  Since we already inserted subparts,
885   ;; don't override existing :notmuch-part properties.
886   (notmuch-map-text-property beg end :notmuch-part
887                              (lambda (v) (or v part)))
888   ;; Make :notmuch-part front sticky and rear non-sticky so it stays
889   ;; applied to the beginning of each line when we indent the
890   ;; message.  Since we're operating on arbitrary renderer output,
891   ;; watch out for sticky specs of t, which means all properties are
892   ;; front-sticky/rear-nonsticky.
893   (notmuch-map-text-property beg end 'front-sticky
894                              (lambda (v) (if (listp v)
895                                              (pushnew :notmuch-part v)
896                                            v)))
897   (notmuch-map-text-property beg end 'rear-nonsticky
898                              (lambda (v) (if (listp v)
899                                              (pushnew :notmuch-part v)
900                                            v))))
901
902 (defun notmuch-show-lazy-part (part-args button)
903   ;; Insert the lazy part after the button for the part. We would just
904   ;; move to the start of the new line following the button and insert
905   ;; the part but that point might have text properties (eg colours
906   ;; from a message header etc) so instead we start from the last
907   ;; character of the button by adding a newline and finish by
908   ;; removing the extra newline from the end of the part.
909   (save-excursion
910     (goto-char (button-end button))
911     (insert "\n")
912     (let* ((inhibit-read-only t)
913            ;; We need to use markers for the start and end of the part
914            ;; because the part insertion functions do not guarantee
915            ;; to leave point at the end of the part.
916            (part-beg (copy-marker (point) nil))
917            (part-end (copy-marker (point) t))
918            ;; We have to save the depth as we can't find the depth
919            ;; when narrowed.
920            (depth (notmuch-show-get-depth)))
921       (save-restriction
922         (narrow-to-region part-beg part-end)
923         (delete-region part-beg part-end)
924         (apply #'notmuch-show-insert-bodypart-internal part-args)
925         (indent-rigidly part-beg part-end (* notmuch-show-indent-messages-width depth)))
926       (goto-char part-end)
927       (delete-char 1)
928       (notmuch-show-record-part-information (second part-args)
929                                             (button-start button)
930                                             part-end)
931       ;; Create the overlay. If the lazy-part turned out to be empty/not
932       ;; showable this returns nil.
933       (notmuch-show-create-part-overlays button part-beg part-end))))
934
935 (defun notmuch-show-mime-type (part)
936   "Return the correct mime-type to use for PART."
937   (let ((content-type (downcase (plist-get part :content-type))))
938     (or (and (string= content-type "application/octet-stream")
939              (notmuch-show-get-mime-type-of-application/octet-stream part))
940         (and (string= content-type "inline patch")
941              "text/x-diff")
942         content-type)))
943
944 ;; The following variable can be overridden by let bindings.
945 (defvar notmuch-show-insert-header-p-function 'notmuch-show-insert-header-p
946   "Specify which function decides which part headers get inserted.
947
948 The function should take two parameters, PART and HIDE, and
949 should return non-NIL if a header button should be inserted for
950 this part.")
951
952 (defun notmuch-show-insert-header-p (part hide)
953   ;; Show all part buttons except for the first part if it is text/plain.
954   (let ((mime-type (notmuch-show-mime-type part)))
955     (not (and (string= mime-type "text/plain")
956               (<= (plist-get part :id) 1)))))
957
958 (defun notmuch-show-reply-insert-header-p-never (part hide)
959   nil)
960
961 (defun notmuch-show-reply-insert-header-p-trimmed (part hide)
962   (let ((mime-type (notmuch-show-mime-type part)))
963     (and (not (notmuch-match-content-type mime-type "multipart/*"))
964          (not hide))))
965
966 (defun notmuch-show-reply-insert-header-p-minimal (part hide)
967   (let ((mime-type (notmuch-show-mime-type part)))
968     (and (notmuch-match-content-type mime-type "text/*")
969          (not hide))))
970
971 (defun notmuch-show-insert-bodypart (msg part depth &optional hide)
972   "Insert the body part PART at depth DEPTH in the current thread.
973
974 HIDE determines whether to show or hide the part and the button
975 as follows: If HIDE is nil, show the part and the button. If HIDE
976 is t, hide the part initially and show the button."
977
978   (let* ((content-type (downcase (plist-get part :content-type)))
979          (mime-type (notmuch-show-mime-type part))
980          (nth (plist-get part :id))
981          (long (and (notmuch-match-content-type mime-type "text/*")
982                     (> notmuch-show-max-text-part-size 0)
983                     (> (length (plist-get part :content)) notmuch-show-max-text-part-size)))
984          (beg (point))
985          ;; This default header-p function omits the part button for
986          ;; the first (or only) part if this is text/plain.
987          (button (when (funcall notmuch-show-insert-header-p-function part hide)
988                    (notmuch-show-insert-part-header nth mime-type content-type (plist-get part :filename))))
989          ;; Hide the part initially if HIDE is t, or if it is too long
990          ;; and we have a button to allow toggling.
991          (show-part (not (or (equal hide t)
992                              (and long button))))
993          (content-beg (point)))
994
995     ;; Store the computed mime-type for later use (e.g. by attachment handlers).
996     (plist-put part :computed-type mime-type)
997
998     (if show-part
999         (notmuch-show-insert-bodypart-internal msg part mime-type nth depth button)
1000       (when button
1001         (button-put button :notmuch-lazy-part
1002                     (list msg part mime-type nth depth button))))
1003
1004     ;; Some of the body part handlers leave point somewhere up in the
1005     ;; part, so we make sure that we're down at the end.
1006     (goto-char (point-max))
1007     ;; Ensure that the part ends with a carriage return.
1008     (unless (bolp)
1009       (insert "\n"))
1010     ;; We do not create the overlay for hidden (lazy) parts until
1011     ;; they are inserted.
1012     (if show-part
1013         (notmuch-show-create-part-overlays button content-beg (point))
1014       (save-excursion
1015         (notmuch-show-toggle-part-invisibility button)))
1016     (notmuch-show-record-part-information part beg (point))))
1017
1018 (defun notmuch-show-insert-body (msg body depth)
1019   "Insert the body BODY at depth DEPTH in the current thread."
1020
1021   ;; Register all content IDs for this message.  According to RFC
1022   ;; 2392, content IDs are *global*, but it's okay if an MUA treats
1023   ;; them as only global within a message.
1024   (notmuch-show--register-cids msg (first body))
1025
1026   (mapc (lambda (part) (notmuch-show-insert-bodypart msg part depth)) body))
1027
1028 (defun notmuch-show-make-symbol (type)
1029   (make-symbol (concat "notmuch-show-" type)))
1030
1031 (defun notmuch-show-strip-re (string)
1032   (replace-regexp-in-string "^\\([Rr]e: *\\)+" "" string))
1033
1034 (defvar notmuch-show-previous-subject "")
1035 (make-variable-buffer-local 'notmuch-show-previous-subject)
1036
1037 (defun notmuch-show-insert-msg (msg depth)
1038   "Insert the message MSG at depth DEPTH in the current thread."
1039   (let* ((headers (plist-get msg :headers))
1040          ;; Indentation causes the buffer offset of the start/end
1041          ;; points to move, so we must use markers.
1042          message-start message-end
1043          content-start content-end
1044          headers-start headers-end
1045          (bare-subject (notmuch-show-strip-re (plist-get headers :Subject))))
1046
1047     (setq message-start (point-marker))
1048
1049     (notmuch-show-insert-headerline headers
1050                                     (or (if notmuch-show-relative-dates
1051                                             (plist-get msg :date_relative)
1052                                           nil)
1053                                         (plist-get headers :Date))
1054                                     (plist-get msg :tags) depth)
1055
1056     (setq content-start (point-marker))
1057
1058     ;; Set `headers-start' to point after the 'Subject:' header to be
1059     ;; compatible with the existing implementation. This just sets it
1060     ;; to after the first header.
1061     (notmuch-show-insert-headers headers)
1062     (save-excursion
1063       (goto-char content-start)
1064       ;; If the subject of this message is the same as that of the
1065       ;; previous message, don't display it when this message is
1066       ;; collapsed.
1067       (when (not (string= notmuch-show-previous-subject
1068                           bare-subject))
1069         (forward-line 1))
1070       (setq headers-start (point-marker)))
1071     (setq headers-end (point-marker))
1072
1073     (setq notmuch-show-previous-subject bare-subject)
1074
1075     ;; A blank line between the headers and the body.
1076     (insert "\n")
1077     (notmuch-show-insert-body msg (plist-get msg :body)
1078                               (if notmuch-show-indent-content depth 0))
1079     ;; Ensure that the body ends with a newline.
1080     (unless (bolp)
1081       (insert "\n"))
1082     (setq content-end (point-marker))
1083
1084     ;; Indent according to the depth in the thread.
1085     (if notmuch-show-indent-content
1086         (indent-rigidly content-start content-end (* notmuch-show-indent-messages-width depth)))
1087
1088     (setq message-end (point-max-marker))
1089
1090     ;; Save the extents of this message over the whole text of the
1091     ;; message.
1092     (put-text-property message-start message-end :notmuch-message-extent (cons message-start message-end))
1093
1094     ;; Create overlays used to control visibility
1095     (plist-put msg :headers-overlay (make-overlay headers-start headers-end))
1096     (plist-put msg :message-overlay (make-overlay headers-start content-end))
1097
1098     (plist-put msg :depth depth)
1099
1100     ;; Save the properties for this message. Currently this saves the
1101     ;; entire message (augmented it with other stuff), which seems
1102     ;; like overkill. We might save a reduced subset (for example, not
1103     ;; the content).
1104     (notmuch-show-set-message-properties msg)
1105
1106     ;; Set header visibility.
1107     (notmuch-show-headers-visible msg notmuch-message-headers-visible)
1108
1109     ;; Message visibility depends on whether it matched the search
1110     ;; criteria.
1111     (notmuch-show-message-visible msg (and (plist-get msg :match)
1112                                            (not (plist-get msg :excluded))))))
1113
1114 (defun notmuch-show-toggle-process-crypto ()
1115   "Toggle the processing of cryptographic MIME parts."
1116   (interactive)
1117   (setq notmuch-show-process-crypto (not notmuch-show-process-crypto))
1118   (message (if notmuch-show-process-crypto
1119                "Processing cryptographic MIME parts."
1120              "Not processing cryptographic MIME parts."))
1121   (notmuch-show-refresh-view))
1122
1123 (defun notmuch-show-toggle-elide-non-matching ()
1124   "Toggle the display of non-matching messages."
1125   (interactive)
1126   (setq notmuch-show-elide-non-matching-messages (not notmuch-show-elide-non-matching-messages))
1127   (message (if notmuch-show-elide-non-matching-messages
1128                "Showing matching messages only."
1129              "Showing all messages."))
1130   (notmuch-show-refresh-view))
1131
1132 (defun notmuch-show-toggle-thread-indentation ()
1133   "Toggle the indentation of threads."
1134   (interactive)
1135   (setq notmuch-show-indent-content (not notmuch-show-indent-content))
1136   (message (if notmuch-show-indent-content
1137                "Content is indented."
1138              "Content is not indented."))
1139   (notmuch-show-refresh-view))
1140
1141 (defun notmuch-show-insert-tree (tree depth)
1142   "Insert the message tree TREE at depth DEPTH in the current thread."
1143   (let ((msg (car tree))
1144         (replies (cadr tree)))
1145     ;; We test whether there is a message or just some replies.
1146     (when msg
1147       (notmuch-show-insert-msg msg depth))
1148     (notmuch-show-insert-thread replies (1+ depth))))
1149
1150 (defun notmuch-show-insert-thread (thread depth)
1151   "Insert the thread THREAD at depth DEPTH in the current forest."
1152   (mapc (lambda (tree) (notmuch-show-insert-tree tree depth)) thread))
1153
1154 (defun notmuch-show-insert-forest (forest)
1155   "Insert the forest of threads FOREST."
1156   (mapc (lambda (thread) (notmuch-show-insert-thread thread 0)) forest))
1157
1158 (defvar notmuch-id-regexp
1159   (concat
1160    ;; Match the id: prefix only if it begins a word (to disallow, for
1161    ;; example, matching cid:).
1162    "\\<id:\\("
1163    ;; If the term starts with a ", then parse Xapian's quoted boolean
1164    ;; term syntax, which allows for anything as long as embedded
1165    ;; double quotes escaped by doubling them.  We also disallow
1166    ;; newlines (which Xapian allows) to prevent runaway terms.
1167    "\"\\([^\"\n]\\|\"\"\\)*\""
1168    ;; Otherwise, parse Xapian's unquoted syntax, which goes up to the
1169    ;; next space or ).  We disallow [.,;] as the last character
1170    ;; because these are probably part of the surrounding text, and not
1171    ;; part of the id.  This doesn't match single character ids; meh.
1172    "\\|[^\"[:space:])][^[:space:])]*[^])[:space:].,:;?!]"
1173    "\\)")
1174   "The regexp used to match id: links in messages.")
1175
1176 (defvar notmuch-mid-regexp
1177   ;; goto-address-url-regexp matched cid: links, which have the same
1178   ;; grammar as the message ID part of a mid: link.  Construct the
1179   ;; regexp using the same technique as goto-address-url-regexp.
1180   (concat "\\<mid:\\(" thing-at-point-url-path-regexp "\\)")
1181   "The regexp used to match mid: links in messages.
1182
1183 See RFC 2392.")
1184
1185 (defun notmuch-show-buttonise-links (start end)
1186   "Buttonise URLs and mail addresses between START and END.
1187
1188 This also turns id:\"<message id>\"-parts and mid: links into
1189 buttons for a corresponding notmuch search."
1190   (goto-address-fontify-region start end)
1191   (save-excursion
1192     (let (links
1193           (beg-line (progn (goto-char start) (line-beginning-position)))
1194           (end-line (progn (goto-char end) (line-end-position))))
1195       (goto-char beg-line)
1196       (while (re-search-forward notmuch-id-regexp end-line t)
1197         (push (list (match-beginning 0) (match-end 0)
1198                     (match-string-no-properties 0)) links))
1199       (goto-char beg-line)
1200       (while (re-search-forward notmuch-mid-regexp end-line t)
1201         (let* ((mid-cid (match-string-no-properties 1))
1202                (mid (save-match-data
1203                       (string-match "^[^/]*" mid-cid)
1204                       (url-unhex-string (match-string 0 mid-cid)))))
1205           (push (list (match-beginning 0) (match-end 0)
1206                       (notmuch-id-to-query mid)) links)))
1207       (dolist (link links)
1208         ;; Remove the overlay created by goto-address-mode
1209         (remove-overlays (first link) (second link) 'goto-address t)
1210         (make-text-button (first link) (second link)
1211                           :type 'notmuch-button-type
1212                           'action `(lambda (arg)
1213                                      (notmuch-show ,(third link) current-prefix-arg))
1214                           'follow-link t
1215                           'help-echo "Mouse-1, RET: search for this message"
1216                           'face goto-address-mail-face)))))
1217
1218 ;;;###autoload
1219 (defun notmuch-show (thread-id &optional elide-toggle parent-buffer query-context buffer-name)
1220   "Run \"notmuch show\" with the given thread ID and display results.
1221
1222 ELIDE-TOGGLE, if non-nil, inverts the default elide behavior.
1223
1224 The optional PARENT-BUFFER is the notmuch-search buffer from
1225 which this notmuch-show command was executed, (so that the
1226 next thread from that buffer can be show when done with this
1227 one).
1228
1229 The optional QUERY-CONTEXT is a notmuch search term. Only
1230 messages from the thread matching this search term are shown if
1231 non-nil.
1232
1233 The optional BUFFER-NAME provides the name of the buffer in
1234 which the message thread is shown. If it is nil (which occurs
1235 when the command is called interactively) the argument to the
1236 function is used.
1237
1238 Returns the buffer containing the messages, or NIL if no messages
1239 matched."
1240   (interactive "sNotmuch show: \nP")
1241   (let ((buffer-name (generate-new-buffer-name
1242                       (or buffer-name
1243                           (concat "*notmuch-" thread-id "*"))))
1244         ;; We override mm-inline-override-types to stop application/*
1245         ;; parts from being displayed unless the user has customized
1246         ;; it themselves.
1247         (mm-inline-override-types
1248          (if (equal mm-inline-override-types
1249                     (eval (car (get 'mm-inline-override-types 'standard-value))))
1250              (cons "application/*" mm-inline-override-types)
1251            mm-inline-override-types)))
1252     (switch-to-buffer (get-buffer-create buffer-name))
1253     ;; No need to track undo information for this buffer.
1254     (setq buffer-undo-list t)
1255
1256     (notmuch-show-mode)
1257
1258     ;; Set various buffer local variables to their appropriate initial
1259     ;; state. Do this after enabling `notmuch-show-mode' so that they
1260     ;; aren't wiped out.
1261     (setq notmuch-show-thread-id thread-id
1262           notmuch-show-parent-buffer parent-buffer
1263           notmuch-show-query-context query-context
1264
1265           notmuch-show-process-crypto notmuch-crypto-process-mime
1266           ;; If `elide-toggle', invert the default value.
1267           notmuch-show-elide-non-matching-messages
1268           (if elide-toggle
1269               (not notmuch-show-only-matching-messages)
1270             notmuch-show-only-matching-messages))
1271
1272     (add-hook 'post-command-hook #'notmuch-show-command-hook nil t)
1273     (jit-lock-register #'notmuch-show-buttonise-links)
1274
1275     (notmuch-tag-clear-cache)
1276
1277     (let ((inhibit-read-only t))
1278       (if (notmuch-show--build-buffer)
1279           ;; Messages were inserted into the buffer.
1280           (current-buffer)
1281
1282         ;; No messages were inserted - presumably none matched the
1283         ;; query.
1284         (kill-buffer (current-buffer))
1285         (ding)
1286         (message "No messages matched the query!")
1287         nil))))
1288
1289 (defun notmuch-show--build-queries (thread context)
1290   "Return a list of queries to try for this search.
1291
1292 THREAD and CONTEXT are both strings, though CONTEXT may be nil.
1293 When CONTEXT is not nil, the first query is the conjunction of it
1294 and THREAD.  The next query is THREAD alone, and serves as a
1295 fallback if the prior matches no messages."
1296   (let (queries)
1297     (push (list thread) queries)
1298     (if context (push (list thread "and (" context ")") queries))
1299     queries))
1300
1301 (defun notmuch-show--build-buffer (&optional state)
1302   "Display messages matching the current buffer context.
1303
1304 Apply the previously saved STATE if supplied, otherwise show the
1305 first relevant message.
1306
1307 If no messages match the query return NIL."
1308   (let* ((cli-args (cons "--exclude=false"
1309                          (when notmuch-show-elide-non-matching-messages
1310                            (list "--entire-thread=false"))))
1311          (queries (notmuch-show--build-queries
1312                    notmuch-show-thread-id notmuch-show-query-context))
1313          (forest nil)
1314          ;; Must be reset every time we are going to start inserting
1315          ;; messages into the buffer.
1316          (notmuch-show-previous-subject ""))
1317     ;; Use results from the first query that returns some.
1318     (while (and (not forest) queries)
1319       (setq forest (notmuch-query-get-threads
1320                     (append cli-args (list "'") (car queries) (list "'"))))
1321       (setq queries (cdr queries)))
1322     (when forest
1323       (notmuch-show-insert-forest forest)
1324
1325       ;; Store the original tags for each message so that we can
1326       ;; display changes.
1327       (notmuch-show-mapc
1328        (lambda () (notmuch-show-set-prop :orig-tags (notmuch-show-get-tags))))
1329
1330       ;; Set the header line to the subject of the first message.
1331       (setq header-line-format
1332             (replace-regexp-in-string "%" "%%"
1333                                       (notmuch-sanitize
1334                                        (notmuch-show-strip-re
1335                                         (notmuch-show-get-subject)))))
1336
1337       (run-hooks 'notmuch-show-hook)
1338
1339       (if state
1340           (notmuch-show-apply-state state)
1341         ;; With no state to apply, just go to the first message.
1342         (notmuch-show-goto-first-wanted-message)))
1343
1344     ;; Report back to the caller whether any messages matched.
1345     forest))
1346
1347 (defun notmuch-show-capture-state ()
1348   "Capture the state of the current buffer.
1349
1350 This includes:
1351  - the list of open messages,
1352  - the combination of current message id with/for each visible window."
1353   (let* ((win-list (get-buffer-window-list (current-buffer) nil t))
1354          (win-id-combo (mapcar (lambda (win)
1355                                  (with-selected-window win
1356                                    (list win (notmuch-show-get-message-id))))
1357                                win-list)))
1358     (list win-id-combo (notmuch-show-get-message-ids-for-open-messages))))
1359
1360 (defun notmuch-show-get-query ()
1361   "Return the current query in this show buffer"
1362   (if notmuch-show-query-context
1363       (concat notmuch-show-thread-id
1364               " and ("
1365               notmuch-show-query-context
1366               ")")
1367     notmuch-show-thread-id))
1368
1369 (defun notmuch-show-goto-message (msg-id)
1370   "Go to message with msg-id."
1371   (goto-char (point-min))
1372   (unless (loop if (string= msg-id (notmuch-show-get-message-id))
1373                 return t
1374                 until (not (notmuch-show-goto-message-next)))
1375     (goto-char (point-min))
1376     (message "Message-id not found."))
1377   (notmuch-show-message-adjust))
1378
1379 (defun notmuch-show-apply-state (state)
1380   "Apply STATE to the current buffer.
1381
1382 This includes:
1383  - opening the messages previously opened,
1384  - closing all other messages,
1385  - moving to the correct current message in every displayed window."
1386   (let ((win-msg-alist (car state))
1387         (open (cadr state)))
1388
1389     ;; Open those that were open.
1390     (goto-char (point-min))
1391     (loop do (notmuch-show-message-visible (notmuch-show-get-message-properties)
1392                                            (member (notmuch-show-get-message-id) open))
1393           until (not (notmuch-show-goto-message-next)))
1394
1395     (dolist (win-msg-pair win-msg-alist)
1396       (with-selected-window (car win-msg-pair)
1397         ;; Go to the previously open message in this window
1398         (notmuch-show-goto-message (cadr win-msg-pair))))))
1399
1400 (defun notmuch-show-refresh-view (&optional reset-state)
1401   "Refresh the current view.
1402
1403 Refreshes the current view, observing changes in display
1404 preferences. If invoked with a prefix argument (or RESET-STATE is
1405 non-nil) then the state of the buffer (open/closed messages) is
1406 reset based on the original query."
1407   (interactive "P")
1408   (let ((inhibit-read-only t)
1409         (state (unless reset-state
1410                  (notmuch-show-capture-state))))
1411     ;; `erase-buffer' does not seem to remove overlays, which can lead
1412     ;; to weird effects such as remaining images, so remove them
1413     ;; manually.
1414     (remove-overlays)
1415     (erase-buffer)
1416
1417     (unless (notmuch-show--build-buffer state)
1418       ;; No messages were inserted.
1419       (kill-buffer (current-buffer))
1420       (ding)
1421       (message "Refreshing the buffer resulted in no messages!"))))
1422
1423 (defvar notmuch-show-stash-map
1424   (let ((map (make-sparse-keymap)))
1425     (define-key map "c" 'notmuch-show-stash-cc)
1426     (define-key map "d" 'notmuch-show-stash-date)
1427     (define-key map "F" 'notmuch-show-stash-filename)
1428     (define-key map "f" 'notmuch-show-stash-from)
1429     (define-key map "i" 'notmuch-show-stash-message-id)
1430     (define-key map "I" 'notmuch-show-stash-message-id-stripped)
1431     (define-key map "s" 'notmuch-show-stash-subject)
1432     (define-key map "T" 'notmuch-show-stash-tags)
1433     (define-key map "t" 'notmuch-show-stash-to)
1434     (define-key map "l" 'notmuch-show-stash-mlarchive-link)
1435     (define-key map "L" 'notmuch-show-stash-mlarchive-link-and-go)
1436     (define-key map "G" 'notmuch-show-stash-git-send-email)
1437     (define-key map "?" 'notmuch-subkeymap-help)
1438     map)
1439   "Submap for stash commands")
1440 (fset 'notmuch-show-stash-map notmuch-show-stash-map)
1441
1442 (defvar notmuch-show-part-map
1443   (let ((map (make-sparse-keymap)))
1444     (define-key map "s" 'notmuch-show-save-part)
1445     (define-key map "v" 'notmuch-show-view-part)
1446     (define-key map "o" 'notmuch-show-interactively-view-part)
1447     (define-key map "|" 'notmuch-show-pipe-part)
1448     (define-key map "m" 'notmuch-show-choose-mime-of-part)
1449     (define-key map "?" 'notmuch-subkeymap-help)
1450     map)
1451   "Submap for part commands")
1452 (fset 'notmuch-show-part-map notmuch-show-part-map)
1453
1454 (defvar notmuch-show-mode-map
1455   (let ((map (make-sparse-keymap)))
1456     (set-keymap-parent map notmuch-common-keymap)
1457     (define-key map "Z" 'notmuch-tree-from-show-current-query)
1458     (define-key map (kbd "<C-tab>") 'widget-backward)
1459     (define-key map (kbd "M-TAB") 'notmuch-show-previous-button)
1460     (define-key map (kbd "<backtab>") 'notmuch-show-previous-button)
1461     (define-key map (kbd "TAB") 'notmuch-show-next-button)
1462     (define-key map "f" 'notmuch-show-forward-message)
1463     (define-key map "F" 'notmuch-show-forward-open-messages)
1464     (define-key map "b" 'notmuch-show-resend-message)
1465     (define-key map "l" 'notmuch-show-filter-thread)
1466     (define-key map "r" 'notmuch-show-reply-sender)
1467     (define-key map "R" 'notmuch-show-reply)
1468     (define-key map "|" 'notmuch-show-pipe-message)
1469     (define-key map "w" 'notmuch-show-save-attachments)
1470     (define-key map "V" 'notmuch-show-view-raw-message)
1471     (define-key map "e" 'notmuch-show-resume-message)
1472     (define-key map "c" 'notmuch-show-stash-map)
1473     (define-key map "h" 'notmuch-show-toggle-visibility-headers)
1474     (define-key map "k" 'notmuch-tag-jump)
1475     (define-key map "*" 'notmuch-show-tag-all)
1476     (define-key map "-" 'notmuch-show-remove-tag)
1477     (define-key map "+" 'notmuch-show-add-tag)
1478     (define-key map "X" 'notmuch-show-archive-thread-then-exit)
1479     (define-key map "x" 'notmuch-show-archive-message-then-next-or-exit)
1480     (define-key map "A" 'notmuch-show-archive-thread-then-next)
1481     (define-key map "a" 'notmuch-show-archive-message-then-next-or-next-thread)
1482     (define-key map "N" 'notmuch-show-next-message)
1483     (define-key map "P" 'notmuch-show-previous-message)
1484     (define-key map "n" 'notmuch-show-next-open-message)
1485     (define-key map "p" 'notmuch-show-previous-open-message)
1486     (define-key map (kbd "M-n") 'notmuch-show-next-thread-show)
1487     (define-key map (kbd "M-p") 'notmuch-show-previous-thread-show)
1488     (define-key map (kbd "DEL") 'notmuch-show-rewind)
1489     (define-key map " " 'notmuch-show-advance-and-archive)
1490     (define-key map (kbd "M-RET") 'notmuch-show-open-or-close-all)
1491     (define-key map (kbd "RET") 'notmuch-show-toggle-message)
1492     (define-key map "#" 'notmuch-show-print-message)
1493     (define-key map "!" 'notmuch-show-toggle-elide-non-matching)
1494     (define-key map "$" 'notmuch-show-toggle-process-crypto)
1495     (define-key map "<" 'notmuch-show-toggle-thread-indentation)
1496     (define-key map "t" 'toggle-truncate-lines)
1497     (define-key map "." 'notmuch-show-part-map)
1498     map)
1499   "Keymap for \"notmuch show\" buffers.")
1500 (fset 'notmuch-show-mode-map notmuch-show-mode-map)
1501
1502 (define-derived-mode notmuch-show-mode fundamental-mode "notmuch-show"
1503   "Major mode for viewing a thread with notmuch.
1504
1505 This buffer contains the results of the \"notmuch show\" command
1506 for displaying a single thread of email from your email archives.
1507
1508 By default, various components of email messages, (citations,
1509 signatures, already-read messages), are hidden. You can make
1510 these parts visible by clicking with the mouse button or by
1511 pressing RET after positioning the cursor on a hidden part, (for
1512 which \\[notmuch-show-next-button] and \\[notmuch-show-previous-button] are helpful).
1513
1514 Reading the thread sequentially is well-supported by pressing
1515 \\[notmuch-show-advance-and-archive]. This will scroll the current message (if necessary), advance
1516 to the next message, or advance to the next thread (if already on
1517 the last message of a thread).
1518
1519 Other commands are available to read or manipulate the thread
1520 more selectively, (such as '\\[notmuch-show-next-message]' and '\\[notmuch-show-previous-message]' to advance to messages
1521 without removing any tags, and '\\[notmuch-show-archive-thread]' to archive an entire thread
1522 without scrolling through with \\[notmuch-show-advance-and-archive]).
1523
1524 You can add or remove arbitrary tags from the current message with
1525 '\\[notmuch-show-add-tag]' or '\\[notmuch-show-remove-tag]'.
1526
1527 All currently available key bindings:
1528
1529 \\{notmuch-show-mode-map}"
1530   (setq notmuch-buffer-refresh-function #'notmuch-show-refresh-view)
1531   (setq buffer-read-only t
1532         truncate-lines t)
1533   (setq imenu-prev-index-position-function
1534         #'notmuch-show-imenu-prev-index-position-function)
1535   (setq imenu-extract-index-name-function
1536         #'notmuch-show-imenu-extract-index-name-function))
1537
1538 (defun notmuch-tree-from-show-current-query ()
1539   "Call notmuch tree with the current query"
1540   (interactive)
1541   (notmuch-tree notmuch-show-thread-id
1542                 notmuch-show-query-context
1543                 (notmuch-show-get-message-id)))
1544
1545 (defun notmuch-show-move-to-message-top ()
1546   (goto-char (notmuch-show-message-top)))
1547
1548 (defun notmuch-show-move-to-message-bottom ()
1549   (goto-char (notmuch-show-message-bottom)))
1550
1551 (defun notmuch-show-message-adjust ()
1552   (recenter 0))
1553
1554 ;; Movement related functions.
1555
1556 ;; There's some strangeness here where a text property applied to a
1557 ;; region a->b is not found when point is at b. We walk backwards
1558 ;; until finding the property.
1559 (defun notmuch-show-message-extent ()
1560   (let (r)
1561     (save-excursion
1562       (while (not (setq r (get-text-property (point) :notmuch-message-extent)))
1563         (backward-char)))
1564     r))
1565
1566 (defun notmuch-show-message-top ()
1567   (car (notmuch-show-message-extent)))
1568
1569 (defun notmuch-show-message-bottom ()
1570   (cdr (notmuch-show-message-extent)))
1571
1572 (defun notmuch-show-goto-message-next ()
1573   (let ((start (point)))
1574     (notmuch-show-move-to-message-bottom)
1575     (if (not (eobp))
1576         t
1577       (goto-char start)
1578       nil)))
1579
1580 (defun notmuch-show-goto-message-previous ()
1581   (notmuch-show-move-to-message-top)
1582   (if (bobp)
1583       nil
1584     (backward-char)
1585     (notmuch-show-move-to-message-top)
1586     t))
1587
1588 (defun notmuch-show-mapc (function)
1589   "Iterate through all messages in the current thread with
1590 `notmuch-show-goto-message-next' and call FUNCTION for side
1591 effects."
1592   (save-excursion
1593     (goto-char (point-min))
1594     (loop do (funcall function)
1595           while (notmuch-show-goto-message-next))))
1596
1597 ;; Functions relating to the visibility of messages and their
1598 ;; components.
1599
1600 (defun notmuch-show-message-visible (props visible-p)
1601   (overlay-put (plist-get props :message-overlay) 'invisible (not visible-p))
1602   (notmuch-show-set-prop :message-visible visible-p props))
1603
1604 (defun notmuch-show-headers-visible (props visible-p)
1605   (overlay-put (plist-get props :headers-overlay) 'invisible (not visible-p))
1606   (notmuch-show-set-prop :headers-visible visible-p props))
1607
1608 ;; Functions for setting and getting attributes of the current
1609 ;; message.
1610
1611 (defun notmuch-show-set-message-properties (props)
1612   (save-excursion
1613     (notmuch-show-move-to-message-top)
1614     (put-text-property (point) (+ (point) 1) :notmuch-message-properties props)))
1615
1616 (defun notmuch-show-get-message-properties ()
1617   "Return the properties of the current message as a plist.
1618
1619 Some useful entries are:
1620 :headers - Property list containing the headers :Date, :Subject, :From, etc.
1621 :body - Body of the message
1622 :tags - Tags for this message"
1623   (save-excursion
1624     (notmuch-show-move-to-message-top)
1625     (get-text-property (point) :notmuch-message-properties)))
1626
1627 (defun notmuch-show-get-part-properties ()
1628   "Return the properties of the innermost part containing point.
1629
1630 This is the part property list retrieved from the CLI.  Signals
1631 an error if there is no part containing point."
1632   (or (get-text-property (point) :notmuch-part)
1633       (error "No message part here")))
1634
1635 (defun notmuch-show-set-prop (prop val &optional props)
1636   (let ((inhibit-read-only t)
1637         (props (or props
1638                    (notmuch-show-get-message-properties))))
1639     (plist-put props prop val)
1640     (notmuch-show-set-message-properties props)))
1641
1642 (defun notmuch-show-get-prop (prop &optional props)
1643   "Get property PROP from current message in show or tree mode.
1644
1645 It gets property PROP from PROPS or, if PROPS is nil, the current
1646 message in either tree or show. This means that several utility
1647 functions in notmuch-show can be used directly by notmuch-tree as
1648 they just need the correct message properties."
1649   (let ((props (or props
1650                    (cond ((eq major-mode 'notmuch-show-mode)
1651                           (notmuch-show-get-message-properties))
1652                          ((eq major-mode 'notmuch-tree-mode)
1653                           (notmuch-tree-get-message-properties))
1654                          (t nil)))))
1655     (plist-get props prop)))
1656
1657 (defun notmuch-show-get-message-id (&optional bare)
1658   "Return an id: query for the Message-Id of the current message.
1659
1660 If optional argument BARE is non-nil, return
1661 the Message-Id without id: prefix and escaping."
1662   (if bare
1663       (notmuch-show-get-prop :id)
1664     (notmuch-id-to-query (notmuch-show-get-prop :id))))
1665
1666 (defun notmuch-show-get-messages-ids ()
1667   "Return all id: queries of messages in the current thread."
1668   (let ((message-ids))
1669     (notmuch-show-mapc
1670      (lambda () (push (notmuch-show-get-message-id) message-ids)))
1671     message-ids))
1672
1673 (defun notmuch-show-get-messages-ids-search ()
1674   "Return a search string for all message ids of messages in the
1675 current thread."
1676   (mapconcat 'identity (notmuch-show-get-messages-ids) " or "))
1677
1678 ;; dme: Would it make sense to use a macro for many of these?
1679
1680 ;; XXX TODO figure out what to do about multiple filenames
1681 (defun notmuch-show-get-filename ()
1682   "Return the filename of the current message."
1683   (car (notmuch-show-get-prop :filename)))
1684
1685 (defun notmuch-show-get-header (header &optional props)
1686   "Return the named header of the current message, if any."
1687   (plist-get (notmuch-show-get-prop :headers props) header))
1688
1689 (defun notmuch-show-get-cc ()
1690   (notmuch-show-get-header :Cc))
1691
1692 (defun notmuch-show-get-date ()
1693   (notmuch-show-get-header :Date))
1694
1695 (defun notmuch-show-get-timestamp ()
1696   (notmuch-show-get-prop :timestamp))
1697
1698 (defun notmuch-show-get-from ()
1699   (notmuch-show-get-header :From))
1700
1701 (defun notmuch-show-get-subject ()
1702   (notmuch-show-get-header :Subject))
1703
1704 (defun notmuch-show-get-to ()
1705   (notmuch-show-get-header :To))
1706
1707 (defun notmuch-show-get-depth ()
1708   (notmuch-show-get-prop :depth))
1709
1710 (defun notmuch-show-set-tags (tags)
1711   "Set the tags of the current message."
1712   (notmuch-show-set-prop :tags tags)
1713   (notmuch-show-update-tags tags))
1714
1715 (defun notmuch-show-get-tags ()
1716   "Return the tags of the current message."
1717   (notmuch-show-get-prop :tags))
1718
1719 (defun notmuch-show-message-visible-p ()
1720   "Is the current message visible?"
1721   (notmuch-show-get-prop :message-visible))
1722
1723 (defun notmuch-show-headers-visible-p ()
1724   "Are the headers of the current message visible?"
1725   (notmuch-show-get-prop :headers-visible))
1726
1727 (put 'notmuch-show-mark-read 'notmuch-prefix-doc
1728      "Mark the current message as unread.")
1729 (defun notmuch-show-mark-read (&optional unread)
1730   "Mark the current message as read.
1731
1732 Mark the current message as read by applying the tag changes in
1733 `notmuch-show-mark-read-tags' to it (remove the \"unread\" tag by
1734 default). If a prefix argument is given, the message will be
1735 marked as unread, i.e. the tag changes in
1736 `notmuch-show-mark-read-tags' will be reversed."
1737   (interactive "P")
1738   (when notmuch-show-mark-read-tags
1739     (apply 'notmuch-show-tag-message
1740            (notmuch-tag-change-list notmuch-show-mark-read-tags unread))))
1741
1742 (defun notmuch-show-seen-current-message (start end)
1743   "Mark the current message read if it is open.
1744
1745 We only mark it read once: if it is changed back then that is a
1746 user decision and we should not override it."
1747   (when (and (notmuch-show-message-visible-p)
1748              (not (notmuch-show-get-prop :seen)))
1749         (notmuch-show-mark-read)
1750         (notmuch-show-set-prop :seen t)))
1751
1752 (defvar notmuch-show--seen-has-errored nil)
1753 (make-variable-buffer-local 'notmuch-show--seen-has-errored)
1754
1755 (defun notmuch-show-command-hook ()
1756   (when (eq major-mode 'notmuch-show-mode)
1757     ;; We need to redisplay to get window-start and window-end correct.
1758     (redisplay)
1759     (save-excursion
1760       (condition-case err
1761           (funcall notmuch-show-mark-read-function (window-start) (window-end))
1762         ((debug error)
1763          (unless notmuch-show--seen-has-errored
1764            (setq notmuch-show--seen-has-errored 't)
1765            (setq header-line-format
1766                  (concat header-line-format
1767                          (propertize "  [some mark read tag changes may have failed]"
1768                                      'face font-lock-warning-face)))))))))
1769
1770 (defun notmuch-show-filter-thread (query)
1771   "Filter or LIMIT the current thread based on a new query string.
1772
1773 Reshows the current thread with matches defined by the new query-string."
1774   (interactive (list (notmuch-read-query "Filter thread: ")))
1775   (let ((msg-id (notmuch-show-get-message-id)))
1776     (setq notmuch-show-query-context (if (string= query "") nil query))
1777     (notmuch-show-refresh-view t)
1778     (notmuch-show-goto-message msg-id)))
1779
1780 ;; Functions for getting attributes of several messages in the current
1781 ;; thread.
1782
1783 (defun notmuch-show-get-message-ids-for-open-messages ()
1784   "Return a list of all id: queries for open messages in the current thread."
1785   (save-excursion
1786     (let (message-ids done)
1787       (goto-char (point-min))
1788       (while (not done)
1789         (if (notmuch-show-message-visible-p)
1790             (setq message-ids (append message-ids (list (notmuch-show-get-message-id)))))
1791         (setq done (not (notmuch-show-goto-message-next)))
1792         )
1793       message-ids
1794       )))
1795
1796 ;; Commands typically bound to keys.
1797
1798 (defun notmuch-show-advance ()
1799   "Advance through thread.
1800
1801 If the current message in the thread is not yet fully visible,
1802 scroll by a near screenful to read more of the message.
1803
1804 Otherwise, (the end of the current message is already within the
1805 current window), advance to the next open message."
1806   (interactive)
1807   (let* ((end-of-this-message (notmuch-show-message-bottom))
1808          (visible-end-of-this-message (1- end-of-this-message))
1809          (ret nil))
1810     (while (invisible-p visible-end-of-this-message)
1811       (setq visible-end-of-this-message
1812             (max (point-min)
1813                  (1- (previous-single-char-property-change
1814                       visible-end-of-this-message 'invisible)))))
1815     (cond
1816      ;; Ideally we would test `end-of-this-message' against the result
1817      ;; of `window-end', but that doesn't account for the fact that
1818      ;; the end of the message might be hidden.
1819      ((and visible-end-of-this-message
1820            (> visible-end-of-this-message (window-end)))
1821       ;; The bottom of this message is not visible - scroll.
1822       (scroll-up nil))
1823
1824      ((not (= end-of-this-message (point-max)))
1825       ;; This is not the last message - move to the next visible one.
1826       (notmuch-show-next-open-message))
1827
1828      ((not (= (point) (point-max)))
1829       ;; This is the last message, but the cursor is not at the end of
1830       ;; the buffer. Move it there.
1831       (goto-char (point-max)))
1832
1833      (t
1834       ;; This is the last message - change the return value
1835       (setq ret t)))
1836     ret))
1837
1838 (defun notmuch-show-advance-and-archive ()
1839   "Advance through thread and archive.
1840
1841 This command is intended to be one of the simplest ways to
1842 process a thread of email. It works exactly like
1843 notmuch-show-advance, in that it scrolls through messages in a
1844 show buffer, except that when it gets to the end of the buffer it
1845 archives the entire current thread, (apply changes in
1846 `notmuch-archive-tags'), kills the buffer, and displays the next
1847 thread from the search from which this thread was originally
1848 shown."
1849   (interactive)
1850   (if (notmuch-show-advance)
1851       (notmuch-show-archive-thread-then-next)))
1852
1853 (defun notmuch-show-rewind ()
1854   "Backup through the thread (reverse scrolling compared to \\[notmuch-show-advance-and-archive]).
1855
1856 Specifically, if the beginning of the previous email is fewer
1857 than `window-height' lines from the current point, move to it
1858 just like `notmuch-show-previous-message'.
1859
1860 Otherwise, just scroll down a screenful of the current message.
1861
1862 This command does not modify any message tags, (it does not undo
1863 any effects from previous calls to
1864 `notmuch-show-advance-and-archive'."
1865   (interactive)
1866   (let ((start-of-message (notmuch-show-message-top))
1867         (start-of-window (window-start)))
1868     (cond
1869       ;; Either this message is properly aligned with the start of the
1870       ;; window or the start of this message is not visible on the
1871       ;; screen - scroll.
1872      ((or (= start-of-message start-of-window)
1873           (< start-of-message start-of-window))
1874       (scroll-down)
1875       ;; If a small number of lines from the previous message are
1876       ;; visible, realign so that the top of the current message is at
1877       ;; the top of the screen.
1878       (when (<= (count-screen-lines (window-start) start-of-message)
1879                 next-screen-context-lines)
1880         (goto-char (notmuch-show-message-top))
1881         (notmuch-show-message-adjust))
1882       ;; Move to the top left of the window.
1883       (goto-char (window-start)))
1884      (t
1885       ;; Move to the previous message.
1886       (notmuch-show-previous-message)))))
1887
1888 (put 'notmuch-show-reply 'notmuch-prefix-doc "... and prompt for sender")
1889 (defun notmuch-show-reply (&optional prompt-for-sender)
1890   "Reply to the sender and all recipients of the current message."
1891   (interactive "P")
1892   (notmuch-mua-new-reply (notmuch-show-get-message-id) prompt-for-sender t))
1893
1894 (put 'notmuch-show-reply-sender 'notmuch-prefix-doc "... and prompt for sender")
1895 (defun notmuch-show-reply-sender (&optional prompt-for-sender)
1896   "Reply to the sender of the current message."
1897   (interactive "P")
1898   (notmuch-mua-new-reply (notmuch-show-get-message-id) prompt-for-sender nil))
1899
1900 (put 'notmuch-show-forward-message 'notmuch-prefix-doc
1901      "... and prompt for sender")
1902 (defun notmuch-show-forward-message (&optional prompt-for-sender)
1903   "Forward the current message."
1904   (interactive "P")
1905   (notmuch-mua-new-forward-messages (list (notmuch-show-get-message-id))
1906                                     prompt-for-sender))
1907
1908 (put 'notmuch-show-forward-open-messages 'notmuch-prefix-doc
1909      "... and prompt for sender")
1910 (defun notmuch-show-forward-open-messages (&optional prompt-for-sender)
1911   "Forward the currently open messages."
1912   (interactive "P")
1913   (let ((open-messages (notmuch-show-get-message-ids-for-open-messages)))
1914     (unless open-messages
1915       (error "No open messages to forward."))
1916     (notmuch-mua-new-forward-messages open-messages prompt-for-sender)))
1917
1918 (defun notmuch-show-resend-message (addresses)
1919   "Resend the current message."
1920   (interactive (list (notmuch-address-from-minibuffer "Resend to: ")))
1921   (when (y-or-n-p (concat "Confirm resend to " addresses " "))
1922     (notmuch-show-view-raw-message)
1923     (message-resend addresses)
1924     (notmuch-bury-or-kill-this-buffer)))
1925
1926 (defun notmuch-show-next-message (&optional pop-at-end)
1927   "Show the next message.
1928
1929 If a prefix argument is given and this is the last message in the
1930 thread, navigate to the next thread in the parent search buffer."
1931   (interactive "P")
1932   (if (notmuch-show-goto-message-next)
1933       (notmuch-show-message-adjust)
1934     (if pop-at-end
1935         (notmuch-show-next-thread)
1936       (goto-char (point-max)))))
1937
1938 (defun notmuch-show-previous-message ()
1939   "Show the previous message or the start of the current message."
1940   (interactive)
1941   (if (= (point) (notmuch-show-message-top))
1942       (notmuch-show-goto-message-previous)
1943     (notmuch-show-move-to-message-top))
1944   (notmuch-show-message-adjust))
1945
1946 (defun notmuch-show-next-open-message (&optional pop-at-end)
1947   "Show the next open message.
1948
1949 If a prefix argument is given and this is the last open message
1950 in the thread, navigate to the next thread in the parent search
1951 buffer. Return t if there was a next open message in the thread
1952 to show, nil otherwise."
1953   (interactive "P")
1954   (let (r)
1955     (while (and (setq r (notmuch-show-goto-message-next))
1956                 (not (notmuch-show-message-visible-p))))
1957     (if r
1958         (notmuch-show-message-adjust)
1959       (if pop-at-end
1960           (notmuch-show-next-thread)
1961         (goto-char (point-max))))
1962     r))
1963
1964 (defun notmuch-show-next-matching-message ()
1965   "Show the next matching message."
1966   (interactive)
1967   (let (r)
1968     (while (and (setq r (notmuch-show-goto-message-next))
1969                 (not (notmuch-show-get-prop :match))))
1970     (if r
1971         (notmuch-show-message-adjust)
1972       (goto-char (point-max)))))
1973
1974 (defun notmuch-show-open-if-matched ()
1975   "Open a message if it is matched (whether or not excluded)."
1976   (let ((props (notmuch-show-get-message-properties)))
1977     (notmuch-show-message-visible props (plist-get props :match))))
1978
1979 (defun notmuch-show-goto-first-wanted-message ()
1980   "Move to the first open message and mark it read"
1981   (goto-char (point-min))
1982   (unless (notmuch-show-message-visible-p)
1983     (notmuch-show-next-open-message))
1984   (when (eobp)
1985     ;; There are no matched non-excluded messages so open all matched
1986     ;; (necessarily excluded) messages and go to the first.
1987     (notmuch-show-mapc 'notmuch-show-open-if-matched)
1988     (force-window-update)
1989     (goto-char (point-min))
1990     (unless (notmuch-show-message-visible-p)
1991       (notmuch-show-next-open-message))))
1992
1993 (defun notmuch-show-previous-open-message ()
1994   "Show the previous open message."
1995   (interactive)
1996   (while (and (if (= (point) (notmuch-show-message-top))
1997                   (notmuch-show-goto-message-previous)
1998                 (notmuch-show-move-to-message-top))
1999               (not (notmuch-show-message-visible-p))))
2000   (notmuch-show-message-adjust))
2001
2002 (defun notmuch-show-view-raw-message ()
2003   "View the original source of the current message."
2004   (interactive)
2005   (let* ((id (notmuch-show-get-message-id))
2006          (buf (get-buffer-create (concat "*notmuch-raw-" id "*")))
2007          (inhibit-read-only t))
2008     (switch-to-buffer buf)
2009     (erase-buffer)
2010     (let ((coding-system-for-read 'no-conversion))
2011       (call-process notmuch-command nil t nil "show" "--format=raw" id))
2012     (goto-char (point-min))
2013     (set-buffer-modified-p nil)
2014     (setq buffer-read-only t)
2015     (view-buffer buf 'kill-buffer-if-not-modified)))
2016
2017 (defun notmuch-show-resume-message ()
2018   "Resume EDITING the current draft message."
2019   (interactive)
2020   (notmuch-draft-resume (notmuch-show-get-message-id)))
2021
2022 (put 'notmuch-show-pipe-message 'notmuch-doc
2023      "Pipe the contents of the current message to a command.")
2024 (put 'notmuch-show-pipe-message 'notmuch-prefix-doc
2025      "Pipe the thread as an mbox to a command.")
2026 (defun notmuch-show-pipe-message (entire-thread command)
2027   "Pipe the contents of the current message (or thread) to COMMAND.
2028
2029 COMMAND will be executed with the raw contents of the current
2030 email message as stdin. Anything printed by the command to stdout
2031 or stderr will appear in the *notmuch-pipe* buffer.
2032
2033 If ENTIRE-THREAD is non-nil (or when invoked with a prefix
2034 argument), COMMAND will receive all open messages in the current
2035 thread (formatted as an mbox) rather than only the current
2036 message."
2037   (interactive (let ((query-string (if current-prefix-arg
2038                                        "Pipe all open messages to command: "
2039                                      "Pipe message to command: ")))
2040                  (list current-prefix-arg (read-string query-string))))
2041   (let (shell-command)
2042     (if entire-thread
2043         (setq shell-command
2044               (concat notmuch-command " show --format=mbox --exclude=false "
2045                       (shell-quote-argument
2046                        (mapconcat 'identity (notmuch-show-get-message-ids-for-open-messages) " OR "))
2047                       " | " command))
2048       (setq shell-command
2049             (concat notmuch-command " show --format=raw "
2050                     (shell-quote-argument (notmuch-show-get-message-id)) " | " command)))
2051     (let ((cwd default-directory)
2052           (buf (get-buffer-create (concat "*notmuch-pipe*"))))
2053       (with-current-buffer buf
2054         (setq buffer-read-only nil)
2055         (erase-buffer)
2056         ;; Use the originating buffer's working directory instead of
2057         ;; that of the pipe buffer.
2058         (cd cwd)
2059         (let ((exit-code (call-process-shell-command shell-command nil buf)))
2060           (goto-char (point-max))
2061           (set-buffer-modified-p nil)
2062           (setq buffer-read-only t)
2063           (unless (zerop exit-code)
2064             (switch-to-buffer-other-window buf)
2065             (message (format "Command '%s' exited abnormally with code %d"
2066                              shell-command exit-code))))))))
2067
2068 (defun notmuch-show-tag-message (&rest tag-changes)
2069   "Change tags for the current message.
2070
2071 TAG-CHANGES is a list of tag operations for `notmuch-tag'."
2072   (let* ((current-tags (notmuch-show-get-tags))
2073          (new-tags (notmuch-update-tags current-tags tag-changes)))
2074     (unless (equal current-tags new-tags)
2075       (notmuch-tag (notmuch-show-get-message-id) tag-changes)
2076       (notmuch-show-set-tags new-tags))))
2077
2078 (defun notmuch-show-tag (tag-changes)
2079   "Change tags for the current message.
2080
2081 See `notmuch-tag' for information on the format of TAG-CHANGES."
2082   (interactive (list (notmuch-read-tag-changes (notmuch-show-get-tags)
2083                                                "Tag message")))
2084   (notmuch-tag (notmuch-show-get-message-id) tag-changes)
2085   (let* ((current-tags (notmuch-show-get-tags))
2086          (new-tags (notmuch-update-tags current-tags tag-changes)))
2087     (unless (equal current-tags new-tags)
2088       (notmuch-show-set-tags new-tags))))
2089
2090 (defun notmuch-show-tag-all (tag-changes)
2091   "Change tags for all messages in the current show buffer.
2092
2093 See `notmuch-tag' for information on the format of TAG-CHANGES."
2094   (interactive
2095    (list (let (tags)
2096            (notmuch-show-mapc
2097             (lambda () (setq tags (append (notmuch-show-get-tags) tags))))
2098            (notmuch-read-tag-changes tags "Tag thread"))))
2099   (notmuch-tag (notmuch-show-get-messages-ids-search) tag-changes)
2100   (notmuch-show-mapc
2101    (lambda ()
2102      (let* ((current-tags (notmuch-show-get-tags))
2103             (new-tags (notmuch-update-tags current-tags tag-changes)))
2104        (unless (equal current-tags new-tags)
2105          (notmuch-show-set-tags new-tags))))))
2106
2107 (defun notmuch-show-add-tag (tag-changes)
2108   "Change tags for the current message (defaulting to add).
2109
2110 Same as `notmuch-show-tag' but sets initial input to '+'."
2111   (interactive
2112    (list (notmuch-read-tag-changes (notmuch-show-get-tags) "Tag message" "+")))
2113   (notmuch-show-tag tag-changes))
2114
2115 (defun notmuch-show-remove-tag (tag-changes)
2116   "Change tags for the current message (defaulting to remove).
2117
2118 Same as `notmuch-show-tag' but sets initial input to '-'."
2119   (interactive
2120    (list (notmuch-read-tag-changes (notmuch-show-get-tags) "Tag message" "-")))
2121   (notmuch-show-tag tag-changes))
2122
2123 (defun notmuch-show-toggle-visibility-headers ()
2124   "Toggle the visibility of the current message headers."
2125   (interactive)
2126   (let ((props (notmuch-show-get-message-properties)))
2127     (notmuch-show-headers-visible
2128      props
2129      (not (plist-get props :headers-visible))))
2130   (force-window-update))
2131
2132 (defun notmuch-show-toggle-message ()
2133   "Toggle the visibility of the current message."
2134   (interactive)
2135   (let ((props (notmuch-show-get-message-properties)))
2136     (notmuch-show-message-visible
2137      props
2138      (not (plist-get props :message-visible))))
2139   (force-window-update))
2140
2141 (put 'notmuch-show-open-or-close-all 'notmuch-doc "Show all messages.")
2142 (put 'notmuch-show-open-or-close-all 'notmuch-prefix-doc "Hide all messages.")
2143 (defun notmuch-show-open-or-close-all ()
2144   "Set the visibility all of the messages in the current thread.
2145
2146 By default make all of the messages visible. With a prefix
2147 argument, hide all of the messages."
2148   (interactive)
2149   (save-excursion
2150     (goto-char (point-min))
2151     (loop do (notmuch-show-message-visible (notmuch-show-get-message-properties)
2152                                            (not current-prefix-arg))
2153           until (not (notmuch-show-goto-message-next))))
2154   (force-window-update))
2155
2156 (defun notmuch-show-next-button ()
2157   "Advance point to the next button in the buffer."
2158   (interactive)
2159   (forward-button 1))
2160
2161 (defun notmuch-show-previous-button ()
2162   "Move point back to the previous button in the buffer."
2163   (interactive)
2164   (backward-button 1))
2165
2166 (defun notmuch-show-next-thread (&optional show previous)
2167   "Move to the next item in the search results, if any.
2168
2169 If SHOW is non-nil, open the next item in a show
2170 buffer. Otherwise just highlight the next item in the search
2171 buffer. If PREVIOUS is non-nil, move to the previous item in the
2172 search results instead."
2173   (interactive "P")
2174   (let ((parent-buffer notmuch-show-parent-buffer))
2175     (notmuch-bury-or-kill-this-buffer)
2176     (when (buffer-live-p parent-buffer)
2177       (switch-to-buffer parent-buffer)
2178       (and (if previous
2179                (notmuch-search-previous-thread)
2180              (notmuch-search-next-thread))
2181            show
2182            (notmuch-search-show-thread)))))
2183
2184 (defun notmuch-show-next-thread-show ()
2185   "Show the next thread in the search results, if any."
2186   (interactive)
2187   (notmuch-show-next-thread t))
2188
2189 (defun notmuch-show-previous-thread-show ()
2190   "Show the previous thread in the search results, if any."
2191   (interactive)
2192   (notmuch-show-next-thread t t))
2193
2194 (put 'notmuch-show-archive-thread 'notmuch-prefix-doc
2195      "Un-archive each message in thread.")
2196 (defun notmuch-show-archive-thread (&optional unarchive)
2197   "Archive each message in thread.
2198
2199 Archive each message currently shown by applying the tag changes
2200 in `notmuch-archive-tags' to each. If a prefix argument is given,
2201 the messages will be \"unarchived\", i.e. the tag changes in
2202 `notmuch-archive-tags' will be reversed.
2203
2204 Note: This command is safe from any race condition of new messages
2205 being delivered to the same thread. It does not archive the
2206 entire thread, but only the messages shown in the current
2207 buffer."
2208   (interactive "P")
2209   (when notmuch-archive-tags
2210     (notmuch-show-tag-all
2211      (notmuch-tag-change-list notmuch-archive-tags unarchive))))
2212
2213 (defun notmuch-show-archive-thread-then-next ()
2214   "Archive all messages in the current buffer, then show next thread from search."
2215   (interactive)
2216   (notmuch-show-archive-thread)
2217   (notmuch-show-next-thread t))
2218
2219 (defun notmuch-show-archive-thread-then-exit ()
2220   "Archive all messages in the current buffer, then exit back to search results."
2221   (interactive)
2222   (notmuch-show-archive-thread)
2223   (notmuch-show-next-thread))
2224
2225 (put 'notmuch-show-archive-message 'notmuch-prefix-doc
2226      "Un-archive the current message.")
2227 (defun notmuch-show-archive-message (&optional unarchive)
2228   "Archive the current message.
2229
2230 Archive the current message by applying the tag changes in
2231 `notmuch-archive-tags' to it. If a prefix argument is given, the
2232 message will be \"unarchived\", i.e. the tag changes in
2233 `notmuch-archive-tags' will be reversed."
2234   (interactive "P")
2235   (when notmuch-archive-tags
2236     (apply 'notmuch-show-tag-message
2237            (notmuch-tag-change-list notmuch-archive-tags unarchive))))
2238
2239 (defun notmuch-show-archive-message-then-next-or-exit ()
2240   "Archive the current message, then show the next open message in the current thread.
2241
2242 If at the last open message in the current thread, then exit back
2243 to search results."
2244   (interactive)
2245   (notmuch-show-archive-message)
2246   (notmuch-show-next-open-message t))
2247
2248 (defun notmuch-show-archive-message-then-next-or-next-thread ()
2249   "Archive the current message, then show the next open message in the current thread.
2250
2251 If at the last open message in the current thread, then show next
2252 thread from search."
2253   (interactive)
2254   (notmuch-show-archive-message)
2255   (unless (notmuch-show-next-open-message)
2256     (notmuch-show-next-thread t)))
2257
2258 (defun notmuch-show-stash-cc ()
2259   "Copy CC field of current message to kill-ring."
2260   (interactive)
2261   (notmuch-common-do-stash (notmuch-show-get-cc)))
2262
2263 (put 'notmuch-show-stash-date 'notmuch-prefix-doc
2264      "Copy timestamp of current message to kill-ring.")
2265 (defun notmuch-show-stash-date (&optional stash-timestamp)
2266   "Copy date of current message to kill-ring.
2267
2268 If invoked with a prefix argument, copy timestamp of current
2269 message to kill-ring."
2270   (interactive "P")
2271   (if stash-timestamp
2272       (notmuch-common-do-stash (format "%d" (notmuch-show-get-timestamp)))
2273     (notmuch-common-do-stash (notmuch-show-get-date))))
2274
2275 (defun notmuch-show-stash-filename ()
2276   "Copy filename of current message to kill-ring."
2277   (interactive)
2278   (notmuch-common-do-stash (notmuch-show-get-filename)))
2279
2280 (defun notmuch-show-stash-from ()
2281   "Copy From address of current message to kill-ring."
2282   (interactive)
2283   (notmuch-common-do-stash (notmuch-show-get-from)))
2284
2285 (put 'notmuch-show-stash-message-id 'notmuch-prefix-doc
2286      "Copy thread: query matching current thread to kill-ring.")
2287 (defun notmuch-show-stash-message-id (&optional stash-thread-id)
2288   "Copy id: query matching the current message to kill-ring.
2289
2290 If invoked with a prefix argument (or STASH-THREAD-ID is
2291 non-nil), copy thread: query matching the current thread to
2292 kill-ring."
2293   (interactive "P")
2294   (if stash-thread-id
2295       (notmuch-common-do-stash notmuch-show-thread-id)
2296     (notmuch-common-do-stash (notmuch-show-get-message-id))))
2297
2298 (defun notmuch-show-stash-message-id-stripped ()
2299   "Copy message ID of current message (sans `id:' prefix) to kill-ring."
2300   (interactive)
2301   (notmuch-common-do-stash (notmuch-show-get-message-id t)))
2302
2303 (defun notmuch-show-stash-subject ()
2304   "Copy Subject field of current message to kill-ring."
2305   (interactive)
2306   (notmuch-common-do-stash (notmuch-show-get-subject)))
2307
2308 (defun notmuch-show-stash-tags ()
2309   "Copy tags of current message to kill-ring as a comma separated list."
2310   (interactive)
2311   (notmuch-common-do-stash (mapconcat 'identity (notmuch-show-get-tags) ",")))
2312
2313 (defun notmuch-show-stash-to ()
2314   "Copy To address of current message to kill-ring."
2315   (interactive)
2316   (notmuch-common-do-stash (notmuch-show-get-to)))
2317
2318 (defun notmuch-show-stash-mlarchive-link (&optional mla)
2319   "Copy an ML Archive URI for the current message to the kill-ring.
2320
2321 This presumes that the message is available at the selected Mailing List Archive.
2322
2323 If optional argument MLA is non-nil, use the provided key instead of prompting
2324 the user (see `notmuch-show-stash-mlarchive-link-alist')."
2325   (interactive)
2326   (let ((url (cdr (assoc
2327                    (or mla
2328                        (let ((completion-ignore-case t))
2329                          (completing-read
2330                           "Mailing List Archive: "
2331                           notmuch-show-stash-mlarchive-link-alist
2332                           nil t nil nil
2333                           notmuch-show-stash-mlarchive-link-default)))
2334                    notmuch-show-stash-mlarchive-link-alist))))
2335     (notmuch-common-do-stash
2336      (if (functionp url)
2337          (funcall url (notmuch-show-get-message-id t))
2338        (concat url (notmuch-show-get-message-id t))))))
2339
2340 (defun notmuch-show-stash-mlarchive-link-and-go (&optional mla)
2341   "Copy an ML Archive URI for the current message to the kill-ring and visit it.
2342
2343 This presumes that the message is available at the selected Mailing List Archive.
2344
2345 If optional argument MLA is non-nil, use the provided key instead of prompting
2346 the user (see `notmuch-show-stash-mlarchive-link-alist')."
2347   (interactive)
2348   (notmuch-show-stash-mlarchive-link mla)
2349   (browse-url (current-kill 0 t)))
2350
2351 (defun notmuch-show-stash-git-helper (addresses prefix)
2352   "Escape, trim, quote, and add PREFIX to each address in list of ADDRESSES, and return the result as a single string."
2353   (mapconcat (lambda (x)
2354                (concat prefix "\""
2355                        ;; escape double-quotes
2356                        (replace-regexp-in-string
2357                         "\"" "\\\\\""
2358                         ;; trim leading and trailing spaces
2359                         (replace-regexp-in-string
2360                          "\\(^ *\\| *$\\)" ""
2361                          x)) "\""))
2362              addresses " "))
2363
2364 (put 'notmuch-show-stash-git-send-email 'notmuch-prefix-doc
2365      "Copy From/To/Cc of current message to kill-ring in a form suitable for pasting to git send-email command line.")
2366
2367 (defun notmuch-show-stash-git-send-email (&optional no-in-reply-to)
2368   "Copy From/To/Cc/Message-Id of current message to kill-ring in a form suitable for pasting to git send-email command line.
2369
2370 If invoked with a prefix argument (or NO-IN-REPLY-TO is non-nil),
2371 omit --in-reply-to=<Message-Id>."
2372   (interactive "P")
2373   (notmuch-common-do-stash
2374    (mapconcat 'identity
2375               (remove ""
2376                       (list
2377                        (notmuch-show-stash-git-helper
2378                         (message-tokenize-header (notmuch-show-get-from)) "--to=")
2379                        (notmuch-show-stash-git-helper
2380                         (message-tokenize-header (notmuch-show-get-to)) "--to=")
2381                        (notmuch-show-stash-git-helper
2382                         (message-tokenize-header (notmuch-show-get-cc)) "--cc=")
2383                        (unless no-in-reply-to
2384                          (notmuch-show-stash-git-helper
2385                           (list (notmuch-show-get-message-id t)) "--in-reply-to="))))
2386               " ")))
2387
2388 ;; Interactive part functions and their helpers
2389
2390 (defun notmuch-show-generate-part-buffer (msg part)
2391   "Return a temporary buffer containing the specified part's content."
2392   (let ((buf (generate-new-buffer " *notmuch-part*"))
2393         (process-crypto notmuch-show-process-crypto))
2394     (with-current-buffer buf
2395       ;; This is always used in the content of mm handles, which
2396       ;; expect undecoded, binary part content.
2397       (insert (notmuch-get-bodypart-binary msg part process-crypto)))
2398     buf))
2399
2400 (defun notmuch-show-current-part-handle (&optional mime-type)
2401   "Return an mm-handle for the part containing point.
2402
2403 This creates a temporary buffer for the part's content; the
2404 caller is responsible for killing this buffer as appropriate.  If
2405 MIME-TYPE is given then set the handle's mime-type to MIME-TYPE."
2406   (let* ((msg (notmuch-show-get-message-properties))
2407          (part (notmuch-show-get-part-properties))
2408          (buf (notmuch-show-generate-part-buffer msg part))
2409          (computed-type (or mime-type (plist-get part :computed-type)))
2410          (filename (plist-get part :filename))
2411          (disposition (if filename `(attachment (filename . ,filename)))))
2412     (mm-make-handle buf (list computed-type) nil nil disposition)))
2413
2414 (defun notmuch-show-apply-to-current-part-handle (fn &optional mime-type)
2415   "Apply FN to an mm-handle for the part containing point.
2416
2417 This ensures that the temporary buffer created for the mm-handle
2418 is destroyed when FN returns. If MIME-TYPE is given then force
2419 part to be treated as if it had that mime-type."
2420   (let ((handle (notmuch-show-current-part-handle mime-type)))
2421     ;; emacs 24.3+ puts stdout/stderr into the calling buffer so we
2422     ;; call it from a temp-buffer, unless
2423     ;; notmuch-show-attachment-debug is non-nil in which case we put
2424     ;; it in " *notmuch-part*".
2425     (unwind-protect
2426         (if notmuch-show-attachment-debug
2427             (with-current-buffer (generate-new-buffer " *notmuch-part*")
2428               (funcall fn handle))
2429           (with-temp-buffer
2430             (funcall fn handle)))
2431       (kill-buffer (mm-handle-buffer handle)))))
2432
2433 (defun notmuch-show-part-button-default (&optional button)
2434   (interactive)
2435   (let ((button (or button (button-at (point)))))
2436     ;; Try to toggle the part, if that fails then call the default
2437     ;; action. The toggle fails if the part has no emacs renderable
2438     ;; content.
2439     (unless (notmuch-show-toggle-part-invisibility button)
2440       (call-interactively notmuch-show-part-button-default-action))))
2441
2442 (defun notmuch-show-save-part ()
2443   "Save the MIME part containing point to a file."
2444   (interactive)
2445   (notmuch-show-apply-to-current-part-handle #'mm-save-part))
2446
2447 (defun notmuch-show-view-part ()
2448   "View the MIME part containing point in an external viewer."
2449   (interactive)
2450   ;; Set mm-inlined-types to nil to force an external viewer
2451   (let ((mm-inlined-types nil))
2452     (notmuch-show-apply-to-current-part-handle #'mm-display-part)))
2453
2454 (defun notmuch-show-interactively-view-part ()
2455   "View the MIME part containing point, prompting for a viewer."
2456   (interactive)
2457   (notmuch-show-apply-to-current-part-handle #'mm-interactively-view-part))
2458
2459 (defun notmuch-show-pipe-part ()
2460   "Pipe the MIME part containing point to an external command."
2461   (interactive)
2462   (notmuch-show-apply-to-current-part-handle #'mm-pipe-part))
2463
2464
2465 (defun notmuch-show--mm-display-part (handle)
2466   "Use mm-display-part to display HANDLE in a new buffer.
2467
2468 If the part is displayed in an external application then close
2469 the new buffer."
2470   (let ((buf (get-buffer-create (generate-new-buffer-name
2471                                  (concat " *notmuch-internal-part*")))))
2472     (switch-to-buffer buf)
2473     (if (eq (mm-display-part handle) 'external)
2474         (kill-buffer buf)
2475       (goto-char (point-min))
2476       (set-buffer-modified-p nil)
2477       (view-buffer buf 'kill-buffer-if-not-modified))))
2478
2479 (defun notmuch-show-choose-mime-of-part (mime-type)
2480   "Choose the mime type to use for displaying part"
2481   (interactive
2482    (list (completing-read "Mime type to use (default text/plain): "
2483                           (mailcap-mime-types) nil nil nil nil "text/plain")))
2484   (notmuch-show-apply-to-current-part-handle #'notmuch-show--mm-display-part mime-type))
2485
2486 (defun notmuch-show-imenu-prev-index-position-function ()
2487   "Move point to previous message in notmuch-show buffer.
2488 This function is used as a value for
2489 `imenu-prev-index-position-function'."
2490   (if (bobp)
2491       nil
2492     (notmuch-show-previous-message)
2493     t))
2494
2495 (defun notmuch-show-imenu-extract-index-name-function ()
2496   "Return imenu name for line at point.
2497 This function is used as a value for
2498 `imenu-extract-index-name-function'.  Point should be at the
2499 beginning of the line."
2500   (back-to-indentation)
2501   (buffer-substring-no-properties (if notmuch-show-imenu-indent
2502                                       (line-beginning-position)
2503                                     (point))
2504                                   (line-end-position)))
2505
2506 (provide 'notmuch-show)
2507
2508 ;;; notmuch-show.el ends here