git.notmuchmail.org Git - notmuch/blob - emacs/notmuch-show.el

   1 ;; notmuch-show.el --- displaying notmuch forests.
   2 ;;
   3 ;; Copyright © Carl Worth
   4 ;; Copyright © David Edmondson
   5 ;;
   6 ;; This file is part of Notmuch.
   7 ;;
   8 ;; Notmuch is free software: you can redistribute it and/or modify it
   9 ;; under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation, either version 3 of the License, or
  11 ;; (at your option) any later version.
  12 ;;
  13 ;; Notmuch is distributed in the hope that it will be useful, but
  14 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 ;; General Public License for more details.
  17 ;;
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with Notmuch.  If not, see <http://www.gnu.org/licenses/>.
  20 ;;
  21 ;; Authors: Carl Worth <cworth@cworth.org>
  22 ;;          David Edmondson <dme@dme.org>
  23
  24 (eval-when-compile (require 'cl))
  25 (require 'mm-view)
  26 (require 'message)
  27 (require 'mm-decode)
  28 (require 'mailcap)
  29 (require 'icalendar)
  30 (require 'goto-addr)
  31
  32 (require 'notmuch-lib)
  33 (require 'notmuch-tag)
  34 (require 'notmuch-query)
  35 (require 'notmuch-wash)
  36 (require 'notmuch-mua)
  37 (require 'notmuch-crypto)
  38 (require 'notmuch-print)
  39
  40 (declare-function notmuch-call-notmuch-process "notmuch" (&rest args))
  41 (declare-function notmuch-search-next-thread "notmuch" nil)
  42 (declare-function notmuch-search-previous-thread "notmuch" nil)
  43 (declare-function notmuch-search-show-thread "notmuch" nil)
  44 (declare-function notmuch-foreach-mime-part "notmuch" (function mm-handle))
  45 (declare-function notmuch-count-attachments "notmuch" (mm-handle))
  46 (declare-function notmuch-save-attachments "notmuch" (mm-handle &optional queryp))
  47
  48 (defcustom notmuch-message-headers '("Subject" "To" "Cc" "Date")
  49   "Headers that should be shown in a message, in this order.
  50
  51 For an open message, all of these headers will be made visible
  52 according to `notmuch-message-headers-visible' or can be toggled
  53 with `notmuch-show-toggle-visibility-headers'. For a closed message,
  54 only the first header in the list will be visible."
  55   :type '(repeat string)
  56   :group 'notmuch-show)
  57
  58 (defcustom notmuch-message-headers-visible t
  59   "Should the headers be visible by default?
  60
  61 If this value is non-nil, then all of the headers defined in
  62 `notmuch-message-headers' will be visible by default in the display
  63 of each message. Otherwise, these headers will be hidden and
  64 `notmuch-show-toggle-visibility-headers' can be used to make them
  65 visible for any given message."
  66   :type 'boolean
  67   :group 'notmuch-show)
  68
  69 (defcustom notmuch-show-relative-dates t
  70   "Display relative dates in the message summary line."
  71   :type 'boolean
  72   :group 'notmuch-show)
  73
  74 (defvar notmuch-show-markup-headers-hook '(notmuch-show-colour-headers)
  75   "A list of functions called to decorate the headers listed in
  76 `notmuch-message-headers'.")
  77
  78 (defcustom notmuch-show-hook '(notmuch-show-turn-on-visual-line-mode)
  79   "Functions called after populating a `notmuch-show' buffer."
  80   :type 'hook
  81   :options '(notmuch-show-turn-on-visual-line-mode)
  82   :group 'notmuch-show
  83   :group 'notmuch-hooks)
  84
  85 (defcustom notmuch-show-insert-text/plain-hook '(notmuch-wash-wrap-long-lines
  86                                                  notmuch-wash-tidy-citations
  87                                                  notmuch-wash-elide-blank-lines
  88                                                  notmuch-wash-excerpt-citations)
  89   "Functions used to improve the display of text/plain parts."
  90   :type 'hook
  91   :options '(notmuch-wash-convert-inline-patch-to-part
  92              notmuch-wash-wrap-long-lines
  93              notmuch-wash-tidy-citations
  94              notmuch-wash-elide-blank-lines
  95              notmuch-wash-excerpt-citations)
  96   :group 'notmuch-show
  97   :group 'notmuch-hooks)
  98
  99 ;; Mostly useful for debugging.
 100 (defcustom notmuch-show-all-multipart/alternative-parts nil
 101   "Should all parts of multipart/alternative parts be shown?"
 102   :type 'boolean
 103   :group 'notmuch-show)
 104
 105 (defcustom notmuch-show-indent-messages-width 1
 106   "Width of message indentation in threads.
 107
 108 Messages are shown indented according to their depth in a thread.
 109 This variable determines the width of this indentation measured
 110 in number of blanks.  Defaults to `1', choose `0' to disable
 111 indentation."
 112   :type 'integer
 113   :group 'notmuch-show)
 114
 115 (defcustom notmuch-show-indent-multipart nil
 116   "Should the sub-parts of a multipart/* part be indented?"
 117   ;; dme: Not sure which is a good default.
 118   :type 'boolean
 119   :group 'notmuch-show)
 120
 121 (defcustom notmuch-show-part-button-default-action 'notmuch-show-save-part
 122   "Default part header button action (on ENTER or mouse click)."
 123   :group 'notmuch-show
 124   :type '(choice (const :tag "Save part"
 125                         notmuch-show-save-part)
 126                  (const :tag "View part"
 127                         notmuch-show-view-part)
 128                  (const :tag "View interactively"
 129                         notmuch-show-interactively-view-part)))
 130
 131 (defcustom notmuch-show-only-matching-messages nil
 132   "Only matching messages are shown by default."
 133   :type 'boolean
 134   :group 'notmuch-show)
 135
 136 (defvar notmuch-show-thread-id nil)
 137 (make-variable-buffer-local 'notmuch-show-thread-id)
 138 (put 'notmuch-show-thread-id 'permanent-local t)
 139
 140 (defvar notmuch-show-parent-buffer nil)
 141 (make-variable-buffer-local 'notmuch-show-parent-buffer)
 142 (put 'notmuch-show-parent-buffer 'permanent-local t)
 143
 144 (defvar notmuch-show-query-context nil)
 145 (make-variable-buffer-local 'notmuch-show-query-context)
 146 (put 'notmuch-show-query-context 'permanent-local t)
 147
 148 (defvar notmuch-show-process-crypto nil)
 149 (make-variable-buffer-local 'notmuch-show-process-crypto)
 150 (put 'notmuch-show-process-crypto 'permanent-local t)
 151
 152 (defvar notmuch-show-elide-non-matching-messages nil)
 153 (make-variable-buffer-local 'notmuch-show-elide-non-matching-messages)
 154 (put 'notmuch-show-elide-non-matching-messages 'permanent-local t)
 155
 156 (defvar notmuch-show-indent-content t)
 157 (make-variable-buffer-local 'notmuch-show-indent-content)
 158 (put 'notmuch-show-indent-content 'permanent-local t)
 159
 160 (defcustom notmuch-show-stash-mlarchive-link-alist
 161   '(("Gmane" . "http://mid.gmane.org/")
 162     ("MARC" . "http://marc.info/?i=")
 163     ("Mail Archive, The" . "http://mail-archive.com/search?l=mid&q=")
 164     ("LKML" . "http://lkml.kernel.org/r/")
 165     ;; FIXME: can these services be searched by `Message-Id' ?
 166     ;; ("MarkMail" . "http://markmail.org/")
 167     ;; ("Nabble" . "http://nabble.com/")
 168     ;; ("opensubscriber" . "http://opensubscriber.com/")
 169     )
 170   "List of Mailing List Archives to use when stashing links.
 171
 172 These URIs are concatenated with the current message's
 173 Message-Id in `notmuch-show-stash-mlarchive-link'."
 174   :type '(alist :key-type (string :tag "Name")
 175                 :value-type (string :tag "URL"))
 176   :group 'notmuch-show)
 177
 178 (defcustom notmuch-show-stash-mlarchive-link-default "Gmane"
 179   "Default Mailing List Archive to use when stashing links.
 180
 181 This is used when `notmuch-show-stash-mlarchive-link' isn't
 182 provided with an MLA argument nor `completing-read' input."
 183   :type `(choice
 184           ,@(mapcar
 185              (lambda (mla)
 186                (list 'const :tag (car mla) :value (car mla)))
 187              notmuch-show-stash-mlarchive-link-alist))
 188   :group 'notmuch-show)
 189
 190 (defcustom notmuch-show-mark-read-tags '("-unread")
 191   "List of tag changes to apply to a message when it is marked as read.
 192
 193 Tags starting with \"+\" (or not starting with either \"+\" or
 194 \"-\") in the list will be added, and tags starting with \"-\"
 195 will be removed from the message being marked as read.
 196
 197 For example, if you wanted to remove an \"unread\" tag and add a
 198 \"read\" tag (which would make little sense), you would set:
 199     (\"-unread\" \"+read\")"
 200   :type '(repeat string)
 201   :group 'notmuch-show)
 202
 203
 204 (defmacro with-current-notmuch-show-message (&rest body)
 205   "Evaluate body with current buffer set to the text of current message"
 206   `(save-excursion
 207      (let ((id (notmuch-show-get-message-id)))
 208        (let ((buf (generate-new-buffer (concat "*notmuch-msg-" id "*"))))
 209          (with-current-buffer buf
 210            (let ((coding-system-for-read 'no-conversion))
 211              (call-process notmuch-command nil t nil "show" "--format=raw" id)
 212              ,@body)
 213            (kill-buffer buf))))))
 214
 215 (defun notmuch-show-turn-on-visual-line-mode ()
 216   "Enable Visual Line mode."
 217   (visual-line-mode t))
 218
 219 ;; DEPRECATED in Notmuch 0.16 since we now have convenient part
 220 ;; commands.  We'll keep the command around for a version or two in
 221 ;; case people want to bind it themselves.
 222 (defun notmuch-show-view-all-mime-parts ()
 223   "Use external viewers to view all attachments from the current message."
 224   (interactive)
 225   (with-current-notmuch-show-message
 226    ;; We override the mm-inline-media-tests to indicate which message
 227    ;; parts are already sufficiently handled by the original
 228    ;; presentation of the message in notmuch-show mode. These parts
 229    ;; will be inserted directly into the temporary buffer of
 230    ;; with-current-notmuch-show-message and silently discarded.
 231    ;;
 232    ;; Any MIME part not explicitly mentioned here will be handled by an
 233    ;; external viewer as configured in the various mailcap files.
 234    (let ((mm-inline-media-tests '(
 235                                   ("text/.*" ignore identity)
 236                                   ("application/pgp-signature" ignore identity)
 237                                   ("multipart/alternative" ignore identity)
 238                                   ("multipart/mixed" ignore identity)
 239                                   ("multipart/related" ignore identity)
 240                                  )))
 241      (mm-display-parts (mm-dissect-buffer)))))
 242
 243 (defun notmuch-show-save-attachments ()
 244   "Save all attachments from the current message."
 245   (interactive)
 246   (with-current-notmuch-show-message
 247    (let ((mm-handle (mm-dissect-buffer)))
 248      (notmuch-save-attachments
 249       mm-handle (> (notmuch-count-attachments mm-handle) 1))))
 250   (message "Done"))
 251
 252 (defun notmuch-show-with-message-as-text (fn)
 253   "Apply FN to a text representation of the current message.
 254
 255 FN is called with one argument, the message properties. It should
 256 operation on the contents of the current buffer."
 257
 258   ;; Remake the header to ensure that all information is available.
 259   (let* ((to (notmuch-show-get-to))
 260          (cc (notmuch-show-get-cc))
 261          (from (notmuch-show-get-from))
 262          (subject (notmuch-show-get-subject))
 263          (date (notmuch-show-get-date))
 264          (tags (notmuch-show-get-tags))
 265          (depth (notmuch-show-get-depth))
 266
 267          (header (concat
 268                   "Subject: " subject "\n"
 269                   "To: " to "\n"
 270                   (if (not (string= cc ""))
 271                       (concat "Cc: " cc "\n")
 272                     "")
 273                   "From: " from "\n"
 274                   "Date: " date "\n"
 275                   (if tags
 276                       (concat "Tags: "
 277                               (mapconcat #'identity tags ", ") "\n")
 278                     "")))
 279          (all (buffer-substring (notmuch-show-message-top)
 280                                 (notmuch-show-message-bottom)))
 281
 282          (props (notmuch-show-get-message-properties))
 283          (indenting notmuch-show-indent-content))
 284     (with-temp-buffer
 285       (insert all)
 286       (if indenting
 287           (indent-rigidly (point-min) (point-max) (- depth)))
 288       ;; Remove the original header.
 289       (goto-char (point-min))
 290       (re-search-forward "^$" (point-max) nil)
 291       (delete-region (point-min) (point))
 292       (insert header)
 293       (funcall fn props))))
 294
 295 (defun notmuch-show-print-message ()
 296   "Print the current message."
 297   (interactive)
 298   (notmuch-show-with-message-as-text 'notmuch-print-message))
 299
 300 (defun notmuch-show-fontify-header ()
 301   (let ((face (cond
 302                ((looking-at "[Tt]o:")
 303                 'message-header-to)
 304                ((looking-at "[Bb]?[Cc][Cc]:")
 305                 'message-header-cc)
 306                ((looking-at "[Ss]ubject:")
 307                 'message-header-subject)
 308                ((looking-at "[Ff]rom:")
 309                 'message-header-from)
 310                (t
 311                 'message-header-other))))
 312
 313     (overlay-put (make-overlay (point) (re-search-forward ":"))
 314                  'face 'message-header-name)
 315     (overlay-put (make-overlay (point) (re-search-forward ".*$"))
 316                  'face face)))
 317
 318 (defun notmuch-show-colour-headers ()
 319   "Apply some colouring to the current headers."
 320   (goto-char (point-min))
 321   (while (looking-at "^[A-Za-z][-A-Za-z0-9]*:")
 322     (notmuch-show-fontify-header)
 323     (forward-line)))
 324
 325 (defun notmuch-show-spaces-n (n)
 326   "Return a string comprised of `n' spaces."
 327   (make-string n ? ))
 328
 329 (defun notmuch-show-update-tags (tags)
 330   "Update the displayed tags of the current message."
 331   (save-excursion
 332     (goto-char (notmuch-show-message-top))
 333     (if (re-search-forward "(\\([^()]*\\))$" (line-end-position) t)
 334         (let ((inhibit-read-only t))
 335           (replace-match (concat "("
 336                                  (notmuch-tag-format-tags tags)
 337                                  ")"))))))
 338
 339 (defun notmuch-clean-address (address)
 340   "Try to clean a single email ADDRESS for display. Return a cons
 341 cell of (AUTHOR_EMAIL AUTHOR_NAME). Return (ADDRESS nil) if
 342 parsing fails."
 343   (condition-case nil
 344     (let (p-name p-address)
 345       ;; It would be convenient to use `mail-header-parse-address',
 346       ;; but that expects un-decoded mailbox parts, whereas our
 347       ;; mailbox parts are already decoded (and hence may contain
 348       ;; UTF-8). Given that notmuch should handle most of the awkward
 349       ;; cases, some simple string deconstruction should be sufficient
 350       ;; here.
 351       (cond
 352        ;; "User <user@dom.ain>" style.
 353        ((string-match "\\(.*\\) <\\(.*\\)>" address)
 354         (setq p-name (match-string 1 address)
 355               p-address (match-string 2 address)))
 356
 357        ;; "<user@dom.ain>" style.
 358        ((string-match "<\\(.*\\)>" address)
 359         (setq p-address (match-string 1 address)))
 360
 361        ;; Everything else.
 362        (t
 363         (setq p-address address)))
 364
 365       (when p-name
 366         ;; Remove elements of the mailbox part that are not relevant for
 367         ;; display, even if they are required during transport:
 368         ;;
 369         ;; Backslashes.
 370         (setq p-name (replace-regexp-in-string "\\\\" "" p-name))
 371
 372         ;; Outer single and double quotes, which might be nested.
 373         (loop
 374          with start-of-loop
 375          do (setq start-of-loop p-name)
 376
 377          when (string-match "^\"\\(.*\\)\"$" p-name)
 378          do (setq p-name (match-string 1 p-name))
 379
 380          when (string-match "^'\\(.*\\)'$" p-name)
 381          do (setq p-name (match-string 1 p-name))
 382
 383          until (string= start-of-loop p-name)))
 384
 385       ;; If the address is 'foo@bar.com <foo@bar.com>' then show just
 386       ;; 'foo@bar.com'.
 387       (when (string= p-name p-address)
 388         (setq p-name nil))
 389
 390       (cons p-address p-name))
 391     (error (cons address nil))))
 392
 393 (defun notmuch-show-clean-address (address)
 394   "Try to clean a single email ADDRESS for display.  Return
 395 unchanged ADDRESS if parsing fails."
 396   (let* ((clean-address (notmuch-clean-address address))
 397          (p-address (car clean-address))
 398          (p-name (cdr clean-address)))
 399     ;; If no name, return just the address.
 400     (if (not p-name)
 401         p-address
 402       ;; Otherwise format the name and address together.
 403       (concat p-name " <" p-address ">"))))
 404
 405 (defun notmuch-show-insert-headerline (headers date tags depth)
 406   "Insert a notmuch style headerline based on HEADERS for a
 407 message at DEPTH in the current thread."
 408   (let ((start (point)))
 409     (insert (notmuch-show-spaces-n (* notmuch-show-indent-messages-width depth))
 410             (notmuch-show-clean-address (plist-get headers :From))
 411             " ("
 412             date
 413             ") ("
 414             (notmuch-tag-format-tags tags)
 415             ")\n")
 416     (overlay-put (make-overlay start (point)) 'face 'notmuch-message-summary-face)))
 417
 418 (defun notmuch-show-insert-header (header header-value)
 419   "Insert a single header."
 420   (insert header ": " header-value "\n"))
 421
 422 (defun notmuch-show-insert-headers (headers)
 423   "Insert the headers of the current message."
 424   (let ((start (point)))
 425     (mapc (lambda (header)
 426             (let* ((header-symbol (intern (concat ":" header)))
 427                    (header-value (plist-get headers header-symbol)))
 428               (if (and header-value
 429                        (not (string-equal "" header-value)))
 430                   (notmuch-show-insert-header header header-value))))
 431           notmuch-message-headers)
 432     (save-excursion
 433       (save-restriction
 434         (narrow-to-region start (point-max))
 435         (run-hooks 'notmuch-show-markup-headers-hook)))))
 436
 437 (define-button-type 'notmuch-show-part-button-type
 438   'action 'notmuch-show-part-button-default
 439   'follow-link t
 440   'face 'message-mml
 441   :supertype 'notmuch-button-type)
 442
 443 (defun notmuch-show-insert-part-header (nth content-type declared-type &optional name comment)
 444   (let ((button)
 445         (base-label (concat (when name (concat name ": "))
 446                             declared-type
 447                             (unless (string-equal declared-type content-type)
 448                               (concat " (as " content-type ")"))
 449                             comment)))
 450
 451     (setq button
 452           (insert-button
 453            (concat "[ " base-label " ]")
 454            :base-label base-label
 455            :type 'notmuch-show-part-button-type
 456            :notmuch-part-hidden nil))
 457     (insert "\n")
 458     ;; return button
 459     button))
 460
 461 (defun notmuch-show-toggle-part-invisibility (&optional button)
 462   (interactive)
 463   (let* ((button (or button (button-at (point))))
 464          (overlay (button-get button 'overlay))
 465          (lazy-part (button-get button :notmuch-lazy-part)))
 466     ;; We have a part to toggle if there is an overlay or if there is a lazy part.
 467     ;; If neither is present we cannot toggle the part so we just return nil.
 468     (when (or overlay lazy-part)
 469       (let* ((show (button-get button :notmuch-part-hidden))
 470              (new-start (button-start button))
 471              (button-label (button-get button :base-label))
 472              (old-point (point))
 473              (properties (text-properties-at (point)))
 474              (inhibit-read-only t))
 475         ;; Toggle the button itself.
 476         (button-put button :notmuch-part-hidden (not show))
 477         (goto-char new-start)
 478         (insert "[ " button-label (if show " ]" " (hidden) ]"))
 479         (set-text-properties new-start (point) properties)
 480         (let ((old-end (button-end button)))
 481           (move-overlay button new-start (point))
 482           (delete-region (point) old-end))
 483         (goto-char (min old-point (1- (button-end button))))
 484         ;; Return nil if there is a lazy-part, it is empty, and we are
 485         ;; trying to show it.  In all other cases return t.
 486         (if lazy-part
 487             (when show
 488               (button-put button :notmuch-lazy-part nil)
 489               (notmuch-show-lazy-part lazy-part button))
 490           ;; else there must be an overlay.
 491           (overlay-put overlay 'invisible (not show))
 492           t)))))
 493
 494 ;; MIME part renderers
 495
 496 (defun notmuch-show-multipart/*-to-list (part)
 497   (mapcar (lambda (inner-part) (plist-get inner-part :content-type))
 498           (plist-get part :content)))
 499
 500 (defun notmuch-show-insert-part-multipart/alternative (msg part content-type nth depth button)
 501   (let ((chosen-type (car (notmuch-multipart/alternative-choose (notmuch-show-multipart/*-to-list part))))
 502         (inner-parts (plist-get part :content))
 503         (start (point)))
 504     ;; This inserts all parts of the chosen type rather than just one,
 505     ;; but it's not clear that this is the wrong thing to do - which
 506     ;; should be chosen if there are more than one that match?
 507     (mapc (lambda (inner-part)
 508             (let* ((inner-type (plist-get inner-part :content-type))
 509                   (hide (not (or notmuch-show-all-multipart/alternative-parts
 510                            (string= chosen-type inner-type)))))
 511               (notmuch-show-insert-bodypart msg inner-part depth hide)))
 512           inner-parts)
 513
 514     (when notmuch-show-indent-multipart
 515       (indent-rigidly start (point) 1)))
 516   t)
 517
 518 (defun notmuch-show-setup-w3m ()
 519   "Instruct w3m how to retrieve content from a \"related\" part of a message."
 520   (interactive)
 521   (if (boundp 'w3m-cid-retrieve-function-alist)
 522     (unless (assq 'notmuch-show-mode w3m-cid-retrieve-function-alist)
 523       (push (cons 'notmuch-show-mode 'notmuch-show-w3m-cid-retrieve)
 524             w3m-cid-retrieve-function-alist)))
 525   (setq mm-inline-text-html-with-images t))
 526
 527 (defvar w3m-current-buffer) ;; From `w3m.el'.
 528 (defvar notmuch-show-w3m-cid-store nil)
 529 (make-variable-buffer-local 'notmuch-show-w3m-cid-store)
 530
 531 (defun notmuch-show-w3m-cid-store-internal (content-id
 532                                             message-id
 533                                             part-number
 534                                             content-type
 535                                             content)
 536   (push (list content-id
 537               message-id
 538               part-number
 539               content-type
 540               content)
 541         notmuch-show-w3m-cid-store))
 542
 543 (defun notmuch-show-w3m-cid-store (msg part)
 544   (let ((content-id (plist-get part :content-id)))
 545     (when content-id
 546       (notmuch-show-w3m-cid-store-internal (concat "cid:" content-id)
 547                                            (plist-get msg :id)
 548                                            (plist-get part :id)
 549                                            (plist-get part :content-type)
 550                                            nil))))
 551
 552 (defun notmuch-show-w3m-cid-retrieve (url &rest args)
 553   (let ((matching-part (with-current-buffer w3m-current-buffer
 554                          (assoc url notmuch-show-w3m-cid-store))))
 555     (if matching-part
 556         (let ((message-id (nth 1 matching-part))
 557               (part-number (nth 2 matching-part))
 558               (content-type (nth 3 matching-part))
 559               (content (nth 4 matching-part)))
 560           ;; If we don't already have the content, get it and cache
 561           ;; it, as some messages reference the same cid: part many
 562           ;; times (hundreds!), which results in many calls to
 563           ;; `notmuch part'.
 564           (unless content
 565             (setq content (notmuch-get-bodypart-internal (notmuch-id-to-query message-id)
 566                                                               part-number notmuch-show-process-crypto))
 567             (with-current-buffer w3m-current-buffer
 568               (notmuch-show-w3m-cid-store-internal url
 569                                                    message-id
 570                                                    part-number
 571                                                    content-type
 572                                                    content)))
 573           (insert content)
 574           content-type)
 575       nil)))
 576
 577 (defun notmuch-show-insert-part-multipart/related (msg part content-type nth depth button)
 578   (let ((inner-parts (plist-get part :content))
 579         (start (point)))
 580
 581     ;; We assume that the first part is text/html and the remainder
 582     ;; things that it references.
 583
 584     ;; Stash the non-primary parts.
 585     (mapc (lambda (part)
 586             (notmuch-show-w3m-cid-store msg part))
 587           (cdr inner-parts))
 588
 589     ;; Render the primary part.
 590     (notmuch-show-insert-bodypart msg (car inner-parts) depth)
 591
 592     (when notmuch-show-indent-multipart
 593       (indent-rigidly start (point) 1)))
 594   t)
 595
 596 (defun notmuch-show-insert-part-multipart/signed (msg part content-type nth depth button)
 597   (button-put button 'face 'notmuch-crypto-part-header)
 598   ;; add signature status button if sigstatus provided
 599   (if (plist-member part :sigstatus)
 600       (let* ((from (notmuch-show-get-header :From msg))
 601              (sigstatus (car (plist-get part :sigstatus))))
 602         (notmuch-crypto-insert-sigstatus-button sigstatus from))
 603     ;; if we're not adding sigstatus, tell the user how they can get it
 604     (button-put button 'help-echo "Set notmuch-crypto-process-mime to process cryptographic MIME parts."))
 605
 606   (let ((inner-parts (plist-get part :content))
 607         (start (point)))
 608     ;; Show all of the parts.
 609     (mapc (lambda (inner-part)
 610             (notmuch-show-insert-bodypart msg inner-part depth))
 611           inner-parts)
 612
 613     (when notmuch-show-indent-multipart
 614       (indent-rigidly start (point) 1)))
 615   t)
 616
 617 (defun notmuch-show-insert-part-multipart/encrypted (msg part content-type nth depth button)
 618   (button-put button 'face 'notmuch-crypto-part-header)
 619   ;; add encryption status button if encstatus specified
 620   (if (plist-member part :encstatus)
 621       (let ((encstatus (car (plist-get part :encstatus))))
 622         (notmuch-crypto-insert-encstatus-button encstatus)
 623         ;; add signature status button if sigstatus specified
 624         (if (plist-member part :sigstatus)
 625             (let* ((from (notmuch-show-get-header :From msg))
 626                    (sigstatus (car (plist-get part :sigstatus))))
 627               (notmuch-crypto-insert-sigstatus-button sigstatus from))))
 628     ;; if we're not adding encstatus, tell the user how they can get it
 629     (button-put button 'help-echo "Set notmuch-crypto-process-mime to process cryptographic MIME parts."))
 630
 631   (let ((inner-parts (plist-get part :content))
 632         (start (point)))
 633     ;; Show all of the parts.
 634     (mapc (lambda (inner-part)
 635             (notmuch-show-insert-bodypart msg inner-part depth))
 636           inner-parts)
 637
 638     (when notmuch-show-indent-multipart
 639       (indent-rigidly start (point) 1)))
 640   t)
 641
 642 (defun notmuch-show-insert-part-multipart/* (msg part content-type nth depth button)
 643   (let ((inner-parts (plist-get part :content))
 644         (start (point)))
 645     ;; Show all of the parts.
 646     (mapc (lambda (inner-part)
 647             (notmuch-show-insert-bodypart msg inner-part depth))
 648           inner-parts)
 649
 650     (when notmuch-show-indent-multipart
 651       (indent-rigidly start (point) 1)))
 652   t)
 653
 654 (defun notmuch-show-insert-part-message/rfc822 (msg part content-type nth depth button)
 655   (let* ((message (car (plist-get part :content)))
 656          (body (car (plist-get message :body)))
 657          (start (point)))
 658
 659     ;; Override `notmuch-message-headers' to force `From' to be
 660     ;; displayed.
 661     (let ((notmuch-message-headers '("From" "Subject" "To" "Cc" "Date")))
 662       (notmuch-show-insert-headers (plist-get message :headers)))
 663
 664     ;; Blank line after headers to be compatible with the normal
 665     ;; message display.
 666     (insert "\n")
 667
 668     ;; Show the body
 669     (notmuch-show-insert-bodypart msg body depth)
 670
 671     (when notmuch-show-indent-multipart
 672       (indent-rigidly start (point) 1)))
 673   t)
 674
 675 (defun notmuch-show-insert-part-text/plain (msg part content-type nth depth button)
 676   ;; For backward compatibility we want to apply the text/plain hook
 677   ;; to the whole of the part including the part button if there is
 678   ;; one.
 679   (let ((start (if button
 680                    (button-start button)
 681                  (point))))
 682     (insert (notmuch-get-bodypart-content msg part nth notmuch-show-process-crypto))
 683     (save-excursion
 684       (save-restriction
 685         (narrow-to-region start (point-max))
 686         (run-hook-with-args 'notmuch-show-insert-text/plain-hook msg depth))))
 687   t)
 688
 689 (defun notmuch-show-insert-part-text/calendar (msg part content-type nth depth button)
 690   (insert (with-temp-buffer
 691             (insert (notmuch-get-bodypart-content msg part nth notmuch-show-process-crypto))
 692             ;; notmuch-get-bodypart-content provides "raw", non-converted
 693             ;; data. Replace CRLF with LF before icalendar can use it.
 694             (goto-char (point-min))
 695             (while (re-search-forward "\r\n" nil t)
 696               (replace-match "\n" nil nil))
 697             (let ((file (make-temp-file "notmuch-ical"))
 698                   result)
 699               (unwind-protect
 700                   (progn
 701                     (unless (icalendar-import-buffer file t)
 702                       (error "Icalendar import error. See *icalendar-errors* for more information"))
 703                     (set-buffer (get-file-buffer file))
 704                     (setq result (buffer-substring (point-min) (point-max)))
 705                     (set-buffer-modified-p nil)
 706                     (kill-buffer (current-buffer)))
 707                 (delete-file file))
 708               result)))
 709   t)
 710
 711 ;; For backwards compatibility.
 712 (defun notmuch-show-insert-part-text/x-vcalendar (msg part content-type nth depth button)
 713   (notmuch-show-insert-part-text/calendar msg part content-type nth depth button))
 714
 715 (defun notmuch-show-get-mime-type-of-application/octet-stream (part)
 716   ;; If we can deduce a MIME type from the filename of the attachment,
 717   ;; we return that.
 718   (if (plist-get part :filename)
 719       (let ((extension (file-name-extension (plist-get part :filename)))
 720             mime-type)
 721         (if extension
 722             (progn
 723               (mailcap-parse-mimetypes)
 724               (setq mime-type (mailcap-extension-to-mime extension))
 725               (if (and mime-type
 726                        (not (string-equal mime-type "application/octet-stream")))
 727                   mime-type
 728                 nil))
 729           nil))))
 730
 731 (defun notmuch-show-insert-part-text/html (msg part content-type nth depth button)
 732   ;; text/html handler to work around bugs in renderers and our
 733   ;; invisibile parts code. In particular w3m sets up a keymap which
 734   ;; "leaks" outside the invisible region and causes strange effects
 735   ;; in notmuch. We set mm-inline-text-html-with-w3m-keymap to nil to
 736   ;; tell w3m not to set a keymap (so the normal notmuch-show-mode-map
 737   ;; remains).
 738   (let ((mm-inline-text-html-with-w3m-keymap nil))
 739     (notmuch-show-insert-part-*/* msg part content-type nth depth button)))
 740
 741 (defun notmuch-show-insert-part-*/* (msg part content-type nth depth button)
 742   ;; This handler _must_ succeed - it is the handler of last resort.
 743   (notmuch-mm-display-part-inline msg part nth content-type notmuch-show-process-crypto)
 744   t)
 745
 746 ;; Functions for determining how to handle MIME parts.
 747
 748 (defun notmuch-show-handlers-for (content-type)
 749   "Return a list of content handlers for a part of type CONTENT-TYPE."
 750   (let (result)
 751     (mapc (lambda (func)
 752             (if (functionp func)
 753                 (push func result)))
 754           ;; Reverse order of prefrence.
 755           (list (intern (concat "notmuch-show-insert-part-*/*"))
 756                 (intern (concat
 757                          "notmuch-show-insert-part-"
 758                          (car (notmuch-split-content-type content-type))
 759                          "/*"))
 760                 (intern (concat "notmuch-show-insert-part-" content-type))))
 761     result))
 762
 763 ;; \f
 764
 765 (defun notmuch-show-insert-bodypart-internal (msg part content-type nth depth button)
 766   (let ((handlers (notmuch-show-handlers-for content-type)))
 767     ;; Run the content handlers until one of them returns a non-nil
 768     ;; value.
 769     (while (and handlers
 770                 (not (condition-case err
 771                          (funcall (car handlers) msg part content-type nth depth button)
 772                        (error (progn
 773                                 (insert "!!! Bodypart insert error: ")
 774                                 (insert (error-message-string err))
 775                                 (insert " !!!\n") nil)))))
 776       (setq handlers (cdr handlers))))
 777   t)
 778
 779 (defun notmuch-show-create-part-overlays (button beg end)
 780   "Add an overlay to the part between BEG and END"
 781
 782   ;; If there is no button (i.e., the part is text/plain and the first
 783   ;; part) or if the part has no content then we don't make the part
 784   ;; toggleable.
 785   (when (and button (/= beg end))
 786     (button-put button 'overlay (make-overlay beg end))
 787     ;; Return true if we created an overlay.
 788     t))
 789
 790 (defun notmuch-show-record-part-information (part beg end)
 791   "Store PART as a text property from BEG to END"
 792
 793   ;; Record part information.  Since we already inserted subparts,
 794   ;; don't override existing :notmuch-part properties.
 795   (notmuch-map-text-property beg end :notmuch-part
 796                              (lambda (v) (or v part)))
 797   ;; Make :notmuch-part front sticky and rear non-sticky so it stays
 798   ;; applied to the beginning of each line when we indent the
 799   ;; message.  Since we're operating on arbitrary renderer output,
 800   ;; watch out for sticky specs of t, which means all properties are
 801   ;; front-sticky/rear-nonsticky.
 802   (notmuch-map-text-property beg end 'front-sticky
 803                              (lambda (v) (if (listp v)
 804                                              (pushnew :notmuch-part v)
 805                                            v)))
 806   (notmuch-map-text-property beg end 'rear-nonsticky
 807                              (lambda (v) (if (listp v)
 808                                              (pushnew :notmuch-part v)
 809                                            v))))
 810
 811 (defun notmuch-show-lazy-part (part-args button)
 812   ;; Insert the lazy part after the button for the part. We would just
 813   ;; move to the start of the new line following the button and insert
 814   ;; the part but that point might have text properties (eg colours
 815   ;; from a message header etc) so instead we start from the last
 816   ;; character of the button by adding a newline and finish by
 817   ;; removing the extra newline from the end of the part.
 818   (save-excursion
 819     (goto-char (button-end button))
 820     (insert "\n")
 821     (let* ((inhibit-read-only t)
 822            ;; We need to use markers for the start and end of the part
 823            ;; because the part insertion functions do not guarantee
 824            ;; to leave point at the end of the part.
 825            (part-beg (copy-marker (point) nil))
 826            (part-end (copy-marker (point) t))
 827            ;; We have to save the depth as we can't find the depth
 828            ;; when narrowed.
 829            (depth (notmuch-show-get-depth)))
 830       (save-restriction
 831         (narrow-to-region part-beg part-end)
 832         (delete-region part-beg part-end)
 833         (apply #'notmuch-show-insert-bodypart-internal part-args)
 834         (indent-rigidly part-beg part-end depth))
 835       (goto-char part-end)
 836       (delete-char 1)
 837       (notmuch-show-record-part-information (second part-args)
 838                                             (button-start button)
 839                                             part-end)
 840       ;; Create the overlay. If the lazy-part turned out to be empty/not
 841       ;; showable this returns nil.
 842       (notmuch-show-create-part-overlays button part-beg part-end))))
 843
 844 (defun notmuch-show-insert-bodypart (msg part depth &optional hide)
 845   "Insert the body part PART at depth DEPTH in the current thread.
 846
 847 HIDE determines whether to show or hide the part and the button
 848 as follows: If HIDE is nil, show the part and the button. If HIDE
 849 is t, hide the part initially and show the button. If HIDE is
 850 'no-buttons, show the part but do not add any buttons (this is
 851 useful for quoting in replies)."
 852
 853   (let* ((content-type (downcase (plist-get part :content-type)))
 854          (mime-type (or (and (string= content-type "application/octet-stream")
 855                              (notmuch-show-get-mime-type-of-application/octet-stream part))
 856                         (and (string= content-type "inline patch")
 857                              "text/x-diff")
 858                         content-type))
 859          (nth (plist-get part :id))
 860          (beg (point))
 861          ;; Hide the part initially if HIDE is t.
 862          (show-part (not (equal hide t)))
 863          ;; We omit the part button for the first (or only) part if
 864          ;; this is text/plain, or HIDE is 'no-buttons.
 865          (button (unless (or (equal hide 'no-buttons)
 866                              (and (string= mime-type "text/plain") (<= nth 1)))
 867                    (notmuch-show-insert-part-header nth mime-type content-type (plist-get part :filename))))
 868          (content-beg (point)))
 869
 870     ;; Store the computed mime-type for later use (e.g. by attachment handlers).
 871     (plist-put part :computed-type mime-type)
 872
 873     (if show-part
 874         (notmuch-show-insert-bodypart-internal msg part mime-type nth depth button)
 875       (button-put button :notmuch-lazy-part
 876                   (list msg part mime-type nth depth button)))
 877
 878     ;; Some of the body part handlers leave point somewhere up in the
 879     ;; part, so we make sure that we're down at the end.
 880     (goto-char (point-max))
 881     ;; Ensure that the part ends with a carriage return.
 882     (unless (bolp)
 883       (insert "\n"))
 884     ;; We do not create the overlay for hidden (lazy) parts until
 885     ;; they are inserted.
 886     (if show-part
 887         (notmuch-show-create-part-overlays button content-beg (point))
 888       (save-excursion
 889         (notmuch-show-toggle-part-invisibility button)))
 890     (notmuch-show-record-part-information part beg (point))))
 891
 892 (defun notmuch-show-insert-body (msg body depth)
 893   "Insert the body BODY at depth DEPTH in the current thread."
 894   (mapc (lambda (part) (notmuch-show-insert-bodypart msg part depth)) body))
 895
 896 (defun notmuch-show-make-symbol (type)
 897   (make-symbol (concat "notmuch-show-" type)))
 898
 899 (defun notmuch-show-strip-re (string)
 900   (replace-regexp-in-string "^\\([Rr]e: *\\)+" "" string))
 901
 902 (defvar notmuch-show-previous-subject "")
 903 (make-variable-buffer-local 'notmuch-show-previous-subject)
 904
 905 (defun notmuch-show-insert-msg (msg depth)
 906   "Insert the message MSG at depth DEPTH in the current thread."
 907   (let* ((headers (plist-get msg :headers))
 908          ;; Indentation causes the buffer offset of the start/end
 909          ;; points to move, so we must use markers.
 910          message-start message-end
 911          content-start content-end
 912          headers-start headers-end
 913          (bare-subject (notmuch-show-strip-re (plist-get headers :Subject))))
 914
 915     (setq message-start (point-marker))
 916
 917     (notmuch-show-insert-headerline headers
 918                                     (or (if notmuch-show-relative-dates
 919                                             (plist-get msg :date_relative)
 920                                           nil)
 921                                         (plist-get headers :Date))
 922                                     (plist-get msg :tags) depth)
 923
 924     (setq content-start (point-marker))
 925
 926     ;; Set `headers-start' to point after the 'Subject:' header to be
 927     ;; compatible with the existing implementation. This just sets it
 928     ;; to after the first header.
 929     (notmuch-show-insert-headers headers)
 930     (save-excursion
 931       (goto-char content-start)
 932       ;; If the subject of this message is the same as that of the
 933       ;; previous message, don't display it when this message is
 934       ;; collapsed.
 935       (when (not (string= notmuch-show-previous-subject
 936                           bare-subject))
 937         (forward-line 1))
 938       (setq headers-start (point-marker)))
 939     (setq headers-end (point-marker))
 940
 941     (setq notmuch-show-previous-subject bare-subject)
 942
 943     ;; A blank line between the headers and the body.
 944     (insert "\n")
 945     (notmuch-show-insert-body msg (plist-get msg :body)
 946                               (if notmuch-show-indent-content depth 0))
 947     ;; Ensure that the body ends with a newline.
 948     (unless (bolp)
 949       (insert "\n"))
 950     (setq content-end (point-marker))
 951
 952     ;; Indent according to the depth in the thread.
 953     (if notmuch-show-indent-content
 954         (indent-rigidly content-start content-end (* notmuch-show-indent-messages-width depth)))
 955
 956     (setq message-end (point-max-marker))
 957
 958     ;; Save the extents of this message over the whole text of the
 959     ;; message.
 960     (put-text-property message-start message-end :notmuch-message-extent (cons message-start message-end))
 961
 962     ;; Create overlays used to control visibility
 963     (plist-put msg :headers-overlay (make-overlay headers-start headers-end))
 964     (plist-put msg :message-overlay (make-overlay headers-start content-end))
 965
 966     (plist-put msg :depth depth)
 967
 968     ;; Save the properties for this message. Currently this saves the
 969     ;; entire message (augmented it with other stuff), which seems
 970     ;; like overkill. We might save a reduced subset (for example, not
 971     ;; the content).
 972     (notmuch-show-set-message-properties msg)
 973
 974     ;; Set header visibility.
 975     (notmuch-show-headers-visible msg notmuch-message-headers-visible)
 976
 977     ;; Message visibility depends on whether it matched the search
 978     ;; criteria.
 979     (notmuch-show-message-visible msg (and (plist-get msg :match)
 980                                            (not (plist-get msg :excluded))))))
 981
 982 (defun notmuch-show-toggle-process-crypto ()
 983   "Toggle the processing of cryptographic MIME parts."
 984   (interactive)
 985   (setq notmuch-show-process-crypto (not notmuch-show-process-crypto))
 986   (message (if notmuch-show-process-crypto
 987                "Processing cryptographic MIME parts."
 988              "Not processing cryptographic MIME parts."))
 989   (notmuch-show-refresh-view))
 990
 991 (defun notmuch-show-toggle-elide-non-matching ()
 992   "Toggle the display of non-matching messages."
 993   (interactive)
 994   (setq notmuch-show-elide-non-matching-messages (not notmuch-show-elide-non-matching-messages))
 995   (message (if notmuch-show-elide-non-matching-messages
 996                "Showing matching messages only."
 997              "Showing all messages."))
 998   (notmuch-show-refresh-view))
 999
1000 (defun notmuch-show-toggle-thread-indentation ()
1001   "Toggle the indentation of threads."
1002   (interactive)
1003   (setq notmuch-show-indent-content (not notmuch-show-indent-content))
1004   (message (if notmuch-show-indent-content
1005                "Content is indented."
1006              "Content is not indented."))
1007   (notmuch-show-refresh-view))
1008
1009 (defun notmuch-show-insert-tree (tree depth)
1010   "Insert the message tree TREE at depth DEPTH in the current thread."
1011   (let ((msg (car tree))
1012         (replies (cadr tree)))
1013     ;; We test whether there is a message or just some replies.
1014     (when msg
1015       (notmuch-show-insert-msg msg depth))
1016     (notmuch-show-insert-thread replies (1+ depth))))
1017
1018 (defun notmuch-show-insert-thread (thread depth)
1019   "Insert the thread THREAD at depth DEPTH in the current forest."
1020   (mapc (lambda (tree) (notmuch-show-insert-tree tree depth)) thread))
1021
1022 (defun notmuch-show-insert-forest (forest)
1023   "Insert the forest of threads FOREST."
1024   (mapc (lambda (thread) (notmuch-show-insert-thread thread 0)) forest))
1025
1026 (defvar notmuch-id-regexp
1027   (concat
1028    ;; Match the id: prefix only if it begins a word (to disallow, for
1029    ;; example, matching cid:).
1030    "\\<id:\\("
1031    ;; If the term starts with a ", then parse Xapian's quoted boolean
1032    ;; term syntax, which allows for anything as long as embedded
1033    ;; double quotes escaped by doubling them.  We also disallow
1034    ;; newlines (which Xapian allows) to prevent runaway terms.
1035    "\"\\([^\"\n]\\|\"\"\\)*\""
1036    ;; Otherwise, parse Xapian's unquoted syntax, which goes up to the
1037    ;; next space or ).  We disallow [.,;] as the last character
1038    ;; because these are probably part of the surrounding text, and not
1039    ;; part of the id.  This doesn't match single character ids; meh.
1040    "\\|[^\"[:space:])][^[:space:])]*[^])[:space:].,:;?!]"
1041    "\\)")
1042   "The regexp used to match id: links in messages.")
1043
1044 (defvar notmuch-mid-regexp
1045   ;; goto-address-url-regexp matched cid: links, which have the same
1046   ;; grammar as the message ID part of a mid: link.  Construct the
1047   ;; regexp using the same technique as goto-address-url-regexp.
1048   (concat "\\<mid:\\(" thing-at-point-url-path-regexp "\\)")
1049   "The regexp used to match mid: links in messages.
1050
1051 See RFC 2392.")
1052
1053 (defun notmuch-show-buttonise-links (start end)
1054   "Buttonise URLs and mail addresses between START and END.
1055
1056 This also turns id:\"<message id>\"-parts and mid: links into
1057 buttons for a corresponding notmuch search."
1058   (goto-address-fontify-region start end)
1059   (save-excursion
1060     (let (links)
1061       (goto-char start)
1062       (while (re-search-forward notmuch-id-regexp end t)
1063         (push (list (match-beginning 0) (match-end 0)
1064                     (match-string-no-properties 0)) links))
1065       (goto-char start)
1066       (while (re-search-forward notmuch-mid-regexp end t)
1067         (let* ((mid-cid (match-string-no-properties 1))
1068                (mid (save-match-data
1069                       (string-match "^[^/]*" mid-cid)
1070                       (url-unhex-string (match-string 0 mid-cid)))))
1071           (push (list (match-beginning 0) (match-end 0)
1072                       (notmuch-id-to-query mid)) links)))
1073       (dolist (link links)
1074         ;; Remove the overlay created by goto-address-mode
1075         (remove-overlays (first link) (second link) 'goto-address t)
1076         (make-text-button (first link) (second link)
1077                           :type 'notmuch-button-type
1078                           'action `(lambda (arg)
1079                                      (notmuch-show ,(third link)))
1080                           'follow-link t
1081                           'help-echo "Mouse-1, RET: search for this message"
1082                           'face goto-address-mail-face)))))
1083
1084 ;;;###autoload
1085 (defun notmuch-show (thread-id &optional parent-buffer query-context buffer-name)
1086   "Run \"notmuch show\" with the given thread ID and display results.
1087
1088 The optional PARENT-BUFFER is the notmuch-search buffer from
1089 which this notmuch-show command was executed, (so that the
1090 next thread from that buffer can be show when done with this
1091 one).
1092
1093 The optional QUERY-CONTEXT is a notmuch search term. Only
1094 messages from the thread matching this search term are shown if
1095 non-nil.
1096
1097 The optional BUFFER-NAME provides the name of the buffer in
1098 which the message thread is shown. If it is nil (which occurs
1099 when the command is called interactively) the argument to the
1100 function is used."
1101   (interactive "sNotmuch show: ")
1102   (let ((buffer-name (generate-new-buffer-name
1103                       (or buffer-name
1104                           (concat "*notmuch-" thread-id "*")))))
1105     (switch-to-buffer (get-buffer-create buffer-name))
1106     ;; Set the default value for `notmuch-show-process-crypto' in this
1107     ;; buffer.
1108     (setq notmuch-show-process-crypto notmuch-crypto-process-mime)
1109     ;; Set the default value for
1110     ;; `notmuch-show-elide-non-matching-messages' in this buffer. If
1111     ;; there is a prefix argument, invert the default.
1112     (setq notmuch-show-elide-non-matching-messages notmuch-show-only-matching-messages)
1113     (if current-prefix-arg
1114         (setq notmuch-show-elide-non-matching-messages (not notmuch-show-elide-non-matching-messages)))
1115
1116     (setq notmuch-show-thread-id thread-id
1117           notmuch-show-parent-buffer parent-buffer
1118           notmuch-show-query-context query-context)
1119     (notmuch-show-build-buffer)
1120     (notmuch-show-goto-first-wanted-message)
1121     (current-buffer)))
1122
1123 (defun notmuch-show-build-buffer ()
1124   (let ((inhibit-read-only t))
1125
1126     (notmuch-show-mode)
1127     ;; Don't track undo information for this buffer
1128     (set 'buffer-undo-list t)
1129
1130     (erase-buffer)
1131     (goto-char (point-min))
1132     (save-excursion
1133       (let* ((basic-args (list notmuch-show-thread-id))
1134              (args (if notmuch-show-query-context
1135                        (append (list "\'") basic-args
1136                                (list "and (" notmuch-show-query-context ")\'"))
1137                      (append (list "\'") basic-args (list "\'"))))
1138              (cli-args (cons "--exclude=false"
1139                              (when notmuch-show-elide-non-matching-messages
1140                                (list "--entire-thread=false")))))
1141
1142         (notmuch-show-insert-forest (notmuch-query-get-threads (append cli-args args)))
1143         ;; If the query context reduced the results to nothing, run
1144         ;; the basic query.
1145         (when (and (eq (buffer-size) 0)
1146                    notmuch-show-query-context)
1147           (notmuch-show-insert-forest
1148            (notmuch-query-get-threads (append cli-args basic-args)))))
1149
1150       (jit-lock-register #'notmuch-show-buttonise-links)
1151
1152       ;; Set the header line to the subject of the first message.
1153       (setq header-line-format (notmuch-show-strip-re (notmuch-show-get-subject)))
1154
1155       (run-hooks 'notmuch-show-hook))))
1156
1157 (defun notmuch-show-capture-state ()
1158   "Capture the state of the current buffer.
1159
1160 This includes:
1161  - the list of open messages,
1162  - the current message."
1163   (list (notmuch-show-get-message-id) (notmuch-show-get-message-ids-for-open-messages)))
1164
1165 (defun notmuch-show-apply-state (state)
1166   "Apply STATE to the current buffer.
1167
1168 This includes:
1169  - opening the messages previously opened,
1170  - closing all other messages,
1171  - moving to the correct current message."
1172   (let ((current (car state))
1173         (open (cadr state)))
1174
1175     ;; Open those that were open.
1176     (goto-char (point-min))
1177     (loop do (notmuch-show-message-visible (notmuch-show-get-message-properties)
1178                                            (member (notmuch-show-get-message-id) open))
1179           until (not (notmuch-show-goto-message-next)))
1180
1181     ;; Go to the previously open message.
1182     (goto-char (point-min))
1183     (unless (loop if (string= current (notmuch-show-get-message-id))
1184                   return t
1185                   until (not (notmuch-show-goto-message-next)))
1186       (goto-char (point-min))
1187       (message "Previously current message not found."))
1188     (notmuch-show-message-adjust)))
1189
1190 (defun notmuch-show-refresh-view (&optional reset-state)
1191   "Refresh the current view.
1192
1193 Refreshes the current view, observing changes in display
1194 preferences. If invoked with a prefix argument (or RESET-STATE is
1195 non-nil) then the state of the buffer (open/closed messages) is
1196 reset based on the original query."
1197   (interactive "P")
1198   (let ((inhibit-read-only t)
1199         (state (unless reset-state
1200                  (notmuch-show-capture-state))))
1201     ;; erase-buffer does not seem to remove overlays, which can lead
1202     ;; to weird effects such as remaining images, so remove them
1203     ;; manually.
1204     (remove-overlays)
1205     (erase-buffer)
1206     (notmuch-show-build-buffer)
1207     (if state
1208         (notmuch-show-apply-state state)
1209       ;; We're resetting state, so navigate to the first open message
1210       ;; and mark it read, just like opening a new show buffer.
1211       (notmuch-show-goto-first-wanted-message))))
1212
1213 (defvar notmuch-show-stash-map
1214   (let ((map (make-sparse-keymap)))
1215     (define-key map "c" 'notmuch-show-stash-cc)
1216     (define-key map "d" 'notmuch-show-stash-date)
1217     (define-key map "F" 'notmuch-show-stash-filename)
1218     (define-key map "f" 'notmuch-show-stash-from)
1219     (define-key map "i" 'notmuch-show-stash-message-id)
1220     (define-key map "I" 'notmuch-show-stash-message-id-stripped)
1221     (define-key map "s" 'notmuch-show-stash-subject)
1222     (define-key map "T" 'notmuch-show-stash-tags)
1223     (define-key map "t" 'notmuch-show-stash-to)
1224     (define-key map "l" 'notmuch-show-stash-mlarchive-link)
1225     (define-key map "L" 'notmuch-show-stash-mlarchive-link-and-go)
1226     map)
1227   "Submap for stash commands")
1228 (fset 'notmuch-show-stash-map notmuch-show-stash-map)
1229
1230 (defvar notmuch-show-part-map
1231   (let ((map (make-sparse-keymap)))
1232     (define-key map "s" 'notmuch-show-save-part)
1233     (define-key map "v" 'notmuch-show-view-part)
1234     (define-key map "o" 'notmuch-show-interactively-view-part)
1235     (define-key map "|" 'notmuch-show-pipe-part)
1236     map)
1237   "Submap for part commands")
1238 (fset 'notmuch-show-part-map notmuch-show-part-map)
1239
1240 (defvar notmuch-show-mode-map
1241       (let ((map (make-sparse-keymap)))
1242         (define-key map "?" 'notmuch-help)
1243         (define-key map "q" 'notmuch-kill-this-buffer)
1244         (define-key map (kbd "<C-tab>") 'widget-backward)
1245         (define-key map (kbd "M-TAB") 'notmuch-show-previous-button)
1246         (define-key map (kbd "<backtab>") 'notmuch-show-previous-button)
1247         (define-key map (kbd "TAB") 'notmuch-show-next-button)
1248         (define-key map "s" 'notmuch-search)
1249         (define-key map "m" 'notmuch-mua-new-mail)
1250         (define-key map "f" 'notmuch-show-forward-message)
1251         (define-key map "r" 'notmuch-show-reply-sender)
1252         (define-key map "R" 'notmuch-show-reply)
1253         (define-key map "|" 'notmuch-show-pipe-message)
1254         (define-key map "w" 'notmuch-show-save-attachments)
1255         (define-key map "V" 'notmuch-show-view-raw-message)
1256         (define-key map "c" 'notmuch-show-stash-map)
1257         (define-key map "=" 'notmuch-show-refresh-view)
1258         (define-key map "h" 'notmuch-show-toggle-visibility-headers)
1259         (define-key map "*" 'notmuch-show-tag-all)
1260         (define-key map "-" 'notmuch-show-remove-tag)
1261         (define-key map "+" 'notmuch-show-add-tag)
1262         (define-key map "X" 'notmuch-show-archive-thread-then-exit)
1263         (define-key map "x" 'notmuch-show-archive-message-then-next-or-exit)
1264         (define-key map "A" 'notmuch-show-archive-thread-then-next)
1265         (define-key map "a" 'notmuch-show-archive-message-then-next-or-next-thread)
1266         (define-key map "N" 'notmuch-show-next-message)
1267         (define-key map "P" 'notmuch-show-previous-message)
1268         (define-key map "n" 'notmuch-show-next-open-message)
1269         (define-key map "p" 'notmuch-show-previous-open-message)
1270         (define-key map (kbd "M-n") 'notmuch-show-next-thread-show)
1271         (define-key map (kbd "M-p") 'notmuch-show-previous-thread-show)
1272         (define-key map (kbd "DEL") 'notmuch-show-rewind)
1273         (define-key map " " 'notmuch-show-advance-and-archive)
1274         (define-key map (kbd "M-RET") 'notmuch-show-open-or-close-all)
1275         (define-key map (kbd "RET") 'notmuch-show-toggle-message)
1276         (define-key map "#" 'notmuch-show-print-message)
1277         (define-key map "!" 'notmuch-show-toggle-elide-non-matching)
1278         (define-key map "$" 'notmuch-show-toggle-process-crypto)
1279         (define-key map "<" 'notmuch-show-toggle-thread-indentation)
1280         (define-key map "t" 'toggle-truncate-lines)
1281         (define-key map "." 'notmuch-show-part-map)
1282         map)
1283       "Keymap for \"notmuch show\" buffers.")
1284 (fset 'notmuch-show-mode-map notmuch-show-mode-map)
1285
1286 (defun notmuch-show-mode ()
1287   "Major mode for viewing a thread with notmuch.
1288
1289 This buffer contains the results of the \"notmuch show\" command
1290 for displaying a single thread of email from your email archives.
1291
1292 By default, various components of email messages, (citations,
1293 signatures, already-read messages), are hidden. You can make
1294 these parts visible by clicking with the mouse button or by
1295 pressing RET after positioning the cursor on a hidden part, (for
1296 which \\[notmuch-show-next-button] and \\[notmuch-show-previous-button] are helpful).
1297
1298 Reading the thread sequentially is well-supported by pressing
1299 \\[notmuch-show-advance-and-archive]. This will scroll the current message (if necessary), advance
1300 to the next message, or advance to the next thread (if already on
1301 the last message of a thread).
1302
1303 Other commands are available to read or manipulate the thread
1304 more selectively, (such as '\\[notmuch-show-next-message]' and '\\[notmuch-show-previous-message]' to advance to messages
1305 without removing any tags, and '\\[notmuch-show-archive-thread]' to archive an entire thread
1306 without scrolling through with \\[notmuch-show-advance-and-archive]).
1307
1308 You can add or remove arbitrary tags from the current message with
1309 '\\[notmuch-show-add-tag]' or '\\[notmuch-show-remove-tag]'.
1310
1311 All currently available key bindings:
1312
1313 \\{notmuch-show-mode-map}"
1314   (interactive)
1315   (kill-all-local-variables)
1316   (use-local-map notmuch-show-mode-map)
1317   (setq major-mode 'notmuch-show-mode
1318         mode-name "notmuch-show")
1319   (setq buffer-read-only t
1320         truncate-lines t))
1321
1322 (defun notmuch-show-move-to-message-top ()
1323   (goto-char (notmuch-show-message-top)))
1324
1325 (defun notmuch-show-move-to-message-bottom ()
1326   (goto-char (notmuch-show-message-bottom)))
1327
1328 (defun notmuch-show-message-adjust ()
1329   (recenter 0))
1330
1331 ;; Movement related functions.
1332
1333 ;; There's some strangeness here where a text property applied to a
1334 ;; region a->b is not found when point is at b. We walk backwards
1335 ;; until finding the property.
1336 (defun notmuch-show-message-extent ()
1337   (let (r)
1338     (save-excursion
1339       (while (not (setq r (get-text-property (point) :notmuch-message-extent)))
1340         (backward-char)))
1341     r))
1342
1343 (defun notmuch-show-message-top ()
1344   (car (notmuch-show-message-extent)))
1345
1346 (defun notmuch-show-message-bottom ()
1347   (cdr (notmuch-show-message-extent)))
1348
1349 (defun notmuch-show-goto-message-next ()
1350   (let ((start (point)))
1351     (notmuch-show-move-to-message-bottom)
1352     (if (not (eobp))
1353         t
1354       (goto-char start)
1355       nil)))
1356
1357 (defun notmuch-show-goto-message-previous ()
1358   (notmuch-show-move-to-message-top)
1359   (if (bobp)
1360       nil
1361     (backward-char)
1362     (notmuch-show-move-to-message-top)
1363     t))
1364
1365 (defun notmuch-show-mapc (function)
1366   "Iterate through all messages in the current thread with
1367 `notmuch-show-goto-message-next' and call FUNCTION for side
1368 effects."
1369   (save-excursion
1370     (goto-char (point-min))
1371     (loop do (funcall function)
1372           while (notmuch-show-goto-message-next))))
1373
1374 ;; Functions relating to the visibility of messages and their
1375 ;; components.
1376
1377 (defun notmuch-show-message-visible (props visible-p)
1378   (overlay-put (plist-get props :message-overlay) 'invisible (not visible-p))
1379   (notmuch-show-set-prop :message-visible visible-p props))
1380
1381 (defun notmuch-show-headers-visible (props visible-p)
1382   (overlay-put (plist-get props :headers-overlay) 'invisible (not visible-p))
1383   (notmuch-show-set-prop :headers-visible visible-p props))
1384
1385 ;; Functions for setting and getting attributes of the current
1386 ;; message.
1387
1388 (defun notmuch-show-set-message-properties (props)
1389   (save-excursion
1390     (notmuch-show-move-to-message-top)
1391     (put-text-property (point) (+ (point) 1) :notmuch-message-properties props)))
1392
1393 (defun notmuch-show-get-message-properties ()
1394   "Return the properties of the current message as a plist.
1395
1396 Some useful entries are:
1397 :headers - Property list containing the headers :Date, :Subject, :From, etc.
1398 :body - Body of the message
1399 :tags - Tags for this message"
1400   (save-excursion
1401     (notmuch-show-move-to-message-top)
1402     (get-text-property (point) :notmuch-message-properties)))
1403
1404 (defun notmuch-show-get-part-properties ()
1405   "Return the properties of the innermost part containing point.
1406
1407 This is the part property list retrieved from the CLI.  Signals
1408 an error if there is no part containing point."
1409   (or (get-text-property (point) :notmuch-part)
1410       (error "No message part here")))
1411
1412 (defun notmuch-show-set-prop (prop val &optional props)
1413   (let ((inhibit-read-only t)
1414         (props (or props
1415                    (notmuch-show-get-message-properties))))
1416     (plist-put props prop val)
1417     (notmuch-show-set-message-properties props)))
1418
1419 (defun notmuch-show-get-prop (prop &optional props)
1420   (let ((props (or props
1421                    (notmuch-show-get-message-properties))))
1422     (plist-get props prop)))
1423
1424 (defun notmuch-show-get-message-id (&optional bare)
1425   "Return an id: query for the Message-Id of the current message.
1426
1427 If optional argument BARE is non-nil, return
1428 the Message-Id without id: prefix and escaping."
1429   (if bare
1430       (notmuch-show-get-prop :id)
1431     (notmuch-id-to-query (notmuch-show-get-prop :id))))
1432
1433 (defun notmuch-show-get-messages-ids ()
1434   "Return all id: queries of messages in the current thread."
1435   (let ((message-ids))
1436     (notmuch-show-mapc
1437      (lambda () (push (notmuch-show-get-message-id) message-ids)))
1438     message-ids))
1439
1440 (defun notmuch-show-get-messages-ids-search ()
1441   "Return a search string for all message ids of messages in the
1442 current thread."
1443   (mapconcat 'identity (notmuch-show-get-messages-ids) " or "))
1444
1445 ;; dme: Would it make sense to use a macro for many of these?
1446
1447 (defun notmuch-show-get-filename ()
1448   "Return the filename of the current message."
1449   (notmuch-show-get-prop :filename))
1450
1451 (defun notmuch-show-get-header (header &optional props)
1452   "Return the named header of the current message, if any."
1453   (plist-get (notmuch-show-get-prop :headers props) header))
1454
1455 (defun notmuch-show-get-cc ()
1456   (notmuch-show-get-header :Cc))
1457
1458 (defun notmuch-show-get-date ()
1459   (notmuch-show-get-header :Date))
1460
1461 (defun notmuch-show-get-from ()
1462   (notmuch-show-get-header :From))
1463
1464 (defun notmuch-show-get-subject ()
1465   (notmuch-show-get-header :Subject))
1466
1467 (defun notmuch-show-get-to ()
1468   (notmuch-show-get-header :To))
1469
1470 (defun notmuch-show-get-depth ()
1471   (notmuch-show-get-prop :depth))
1472
1473 (defun notmuch-show-set-tags (tags)
1474   "Set the tags of the current message."
1475   (notmuch-show-set-prop :tags tags)
1476   (notmuch-show-update-tags tags))
1477
1478 (defun notmuch-show-get-tags ()
1479   "Return the tags of the current message."
1480   (notmuch-show-get-prop :tags))
1481
1482 (defun notmuch-show-message-visible-p ()
1483   "Is the current message visible?"
1484   (notmuch-show-get-prop :message-visible))
1485
1486 (defun notmuch-show-headers-visible-p ()
1487   "Are the headers of the current message visible?"
1488   (notmuch-show-get-prop :headers-visible))
1489
1490 (defun notmuch-show-mark-read (&optional unread)
1491   "Mark the current message as read.
1492
1493 Mark the current message as read by applying the tag changes in
1494 `notmuch-show-mark-read-tags' to it (remove the \"unread\" tag by
1495 default). If a prefix argument is given, the message will be
1496 marked as unread, i.e. the tag changes in
1497 `notmuch-show-mark-read-tags' will be reversed."
1498   (interactive "P")
1499   (when notmuch-show-mark-read-tags
1500     (apply 'notmuch-show-tag-message
1501            (notmuch-tag-change-list notmuch-show-mark-read-tags unread))))
1502
1503 ;; Functions for getting attributes of several messages in the current
1504 ;; thread.
1505
1506 (defun notmuch-show-get-message-ids-for-open-messages ()
1507   "Return a list of all id: queries for open messages in the current thread."
1508   (save-excursion
1509     (let (message-ids done)
1510       (goto-char (point-min))
1511       (while (not done)
1512         (if (notmuch-show-message-visible-p)
1513             (setq message-ids (append message-ids (list (notmuch-show-get-message-id)))))
1514         (setq done (not (notmuch-show-goto-message-next)))
1515         )
1516       message-ids
1517       )))
1518
1519 ;; Commands typically bound to keys.
1520
1521 (defun notmuch-show-advance ()
1522   "Advance through thread.
1523
1524 If the current message in the thread is not yet fully visible,
1525 scroll by a near screenful to read more of the message.
1526
1527 Otherwise, (the end of the current message is already within the
1528 current window), advance to the next open message."
1529   (interactive)
1530   (let* ((end-of-this-message (notmuch-show-message-bottom))
1531          (visible-end-of-this-message (1- end-of-this-message))
1532          (ret nil))
1533     (while (invisible-p visible-end-of-this-message)
1534       (setq visible-end-of-this-message
1535             (max (point-min)
1536                  (1- (previous-single-char-property-change
1537                       visible-end-of-this-message 'invisible)))))
1538     (cond
1539      ;; Ideally we would test `end-of-this-message' against the result
1540      ;; of `window-end', but that doesn't account for the fact that
1541      ;; the end of the message might be hidden.
1542      ((and visible-end-of-this-message
1543            (> visible-end-of-this-message (window-end)))
1544       ;; The bottom of this message is not visible - scroll.
1545       (scroll-up nil))
1546
1547      ((not (= end-of-this-message (point-max)))
1548       ;; This is not the last message - move to the next visible one.
1549       (notmuch-show-next-open-message))
1550
1551      ((not (= (point) (point-max)))
1552       ;; This is the last message, but the cursor is not at the end of
1553       ;; the buffer. Move it there.
1554       (goto-char (point-max)))
1555
1556      (t
1557       ;; This is the last message - change the return value
1558       (setq ret t)))
1559     ret))
1560
1561 (defun notmuch-show-advance-and-archive ()
1562   "Advance through thread and archive.
1563
1564 This command is intended to be one of the simplest ways to
1565 process a thread of email. It works exactly like
1566 notmuch-show-advance, in that it scrolls through messages in a
1567 show buffer, except that when it gets to the end of the buffer it
1568 archives the entire current thread, (apply changes in
1569 `notmuch-archive-tags'), kills the buffer, and displays the next
1570 thread from the search from which this thread was originally
1571 shown."
1572   (interactive)
1573   (if (notmuch-show-advance)
1574       (notmuch-show-archive-thread-then-next)))
1575
1576 (defun notmuch-show-rewind ()
1577   "Backup through the thread, (reverse scrolling compared to \\[notmuch-show-advance-and-archive]).
1578
1579 Specifically, if the beginning of the previous email is fewer
1580 than `window-height' lines from the current point, move to it
1581 just like `notmuch-show-previous-message'.
1582
1583 Otherwise, just scroll down a screenful of the current message.
1584
1585 This command does not modify any message tags, (it does not undo
1586 any effects from previous calls to
1587 `notmuch-show-advance-and-archive'."
1588   (interactive)
1589   (let ((start-of-message (notmuch-show-message-top))
1590         (start-of-window (window-start)))
1591     (cond
1592       ;; Either this message is properly aligned with the start of the
1593       ;; window or the start of this message is not visible on the
1594       ;; screen - scroll.
1595      ((or (= start-of-message start-of-window)
1596           (< start-of-message start-of-window))
1597       (scroll-down)
1598       ;; If a small number of lines from the previous message are
1599       ;; visible, realign so that the top of the current message is at
1600       ;; the top of the screen.
1601       (when (<= (count-screen-lines (window-start) start-of-message)
1602                 next-screen-context-lines)
1603         (goto-char (notmuch-show-message-top))
1604         (notmuch-show-message-adjust))
1605       ;; Move to the top left of the window.
1606       (goto-char (window-start)))
1607      (t
1608       ;; Move to the previous message.
1609       (notmuch-show-previous-message)))))
1610
1611 (defun notmuch-show-reply (&optional prompt-for-sender)
1612   "Reply to the sender and all recipients of the current message."
1613   (interactive "P")
1614   (notmuch-mua-new-reply (notmuch-show-get-message-id) prompt-for-sender t))
1615
1616 (defun notmuch-show-reply-sender (&optional prompt-for-sender)
1617   "Reply to the sender of the current message."
1618   (interactive "P")
1619   (notmuch-mua-new-reply (notmuch-show-get-message-id) prompt-for-sender nil))
1620
1621 (defun notmuch-show-forward-message (&optional prompt-for-sender)
1622   "Forward the current message."
1623   (interactive "P")
1624   (with-current-notmuch-show-message
1625    (notmuch-mua-new-forward-message prompt-for-sender)))
1626
1627 (defun notmuch-show-next-message (&optional pop-at-end)
1628   "Show the next message.
1629
1630 If a prefix argument is given and this is the last message in the
1631 thread, navigate to the next thread in the parent search buffer."
1632   (interactive "P")
1633   (if (notmuch-show-goto-message-next)
1634       (progn
1635         (notmuch-show-mark-read)
1636         (notmuch-show-message-adjust))
1637     (if pop-at-end
1638         (notmuch-show-next-thread)
1639       (goto-char (point-max)))))
1640
1641 (defun notmuch-show-previous-message ()
1642   "Show the previous message or the start of the current message."
1643   (interactive)
1644   (if (= (point) (notmuch-show-message-top))
1645       (notmuch-show-goto-message-previous)
1646     (notmuch-show-move-to-message-top))
1647   (notmuch-show-mark-read)
1648   (notmuch-show-message-adjust))
1649
1650 (defun notmuch-show-next-open-message (&optional pop-at-end)
1651   "Show the next open message.
1652
1653 If a prefix argument is given and this is the last open message
1654 in the thread, navigate to the next thread in the parent search
1655 buffer. Return t if there was a next open message in the thread
1656 to show, nil otherwise."
1657   (interactive "P")
1658   (let (r)
1659     (while (and (setq r (notmuch-show-goto-message-next))
1660                 (not (notmuch-show-message-visible-p))))
1661     (if r
1662         (progn
1663           (notmuch-show-mark-read)
1664           (notmuch-show-message-adjust))
1665       (if pop-at-end
1666           (notmuch-show-next-thread)
1667         (goto-char (point-max))))
1668     r))
1669
1670 (defun notmuch-show-next-matching-message ()
1671   "Show the next matching message."
1672   (interactive)
1673   (let (r)
1674     (while (and (setq r (notmuch-show-goto-message-next))
1675                 (not (notmuch-show-get-prop :match))))
1676     (if r
1677         (progn
1678           (notmuch-show-mark-read)
1679           (notmuch-show-message-adjust))
1680       (goto-char (point-max)))))
1681
1682 (defun notmuch-show-open-if-matched ()
1683   "Open a message if it is matched (whether or not excluded)."
1684   (let ((props (notmuch-show-get-message-properties)))
1685     (notmuch-show-message-visible props (plist-get props :match))))
1686
1687 (defun notmuch-show-goto-first-wanted-message ()
1688   "Move to the first open message and mark it read"
1689   (goto-char (point-min))
1690   (if (notmuch-show-message-visible-p)
1691       (notmuch-show-mark-read)
1692     (notmuch-show-next-open-message))
1693   (when (eobp)
1694     ;; There are no matched non-excluded messages so open all matched
1695     ;; (necessarily excluded) messages and go to the first.
1696     (notmuch-show-mapc 'notmuch-show-open-if-matched)
1697     (force-window-update)
1698     (goto-char (point-min))
1699     (if (notmuch-show-message-visible-p)
1700         (notmuch-show-mark-read)
1701       (notmuch-show-next-open-message))))
1702
1703 (defun notmuch-show-previous-open-message ()
1704   "Show the previous open message."
1705   (interactive)
1706   (while (and (if (= (point) (notmuch-show-message-top))
1707                   (notmuch-show-goto-message-previous)
1708                 (notmuch-show-move-to-message-top))
1709               (not (notmuch-show-message-visible-p))))
1710   (notmuch-show-mark-read)
1711   (notmuch-show-message-adjust))
1712
1713 (defun notmuch-show-view-raw-message ()
1714   "View the file holding the current message."
1715   (interactive)
1716   (let* ((id (notmuch-show-get-message-id))
1717          (buf (get-buffer-create (concat "*notmuch-raw-" id "*"))))
1718     (call-process notmuch-command nil buf nil "show" "--format=raw" id)
1719     (switch-to-buffer buf)
1720     (goto-char (point-min))
1721     (set-buffer-modified-p nil)
1722     (view-buffer buf 'kill-buffer-if-not-modified)))
1723
1724 (defun notmuch-show-pipe-message (entire-thread command)
1725   "Pipe the contents of the current message (or thread) to the given command.
1726
1727 The given command will be executed with the raw contents of the
1728 current email message as stdin. Anything printed by the command
1729 to stdout or stderr will appear in the *notmuch-pipe* buffer.
1730
1731 When invoked with a prefix argument, the command will receive all
1732 open messages in the current thread (formatted as an mbox) rather
1733 than only the current message."
1734   (interactive (let ((query-string (if current-prefix-arg
1735                                        "Pipe all open messages to command: "
1736                                      "Pipe message to command: ")))
1737                  (list current-prefix-arg (read-string query-string))))
1738   (let (shell-command)
1739     (if entire-thread
1740         (setq shell-command
1741               (concat notmuch-command " show --format=mbox --exclude=false "
1742                       (shell-quote-argument
1743                        (mapconcat 'identity (notmuch-show-get-message-ids-for-open-messages) " OR "))
1744                       " | " command))
1745       (setq shell-command
1746             (concat notmuch-command " show --format=raw "
1747                     (shell-quote-argument (notmuch-show-get-message-id)) " | " command)))
1748     (let ((buf (get-buffer-create (concat "*notmuch-pipe*"))))
1749       (with-current-buffer buf
1750         (setq buffer-read-only nil)
1751         (erase-buffer)
1752         (let ((exit-code (call-process-shell-command shell-command nil buf)))
1753           (goto-char (point-max))
1754           (set-buffer-modified-p nil)
1755           (setq buffer-read-only t)
1756           (unless (zerop exit-code)
1757             (switch-to-buffer-other-window buf)
1758             (message (format "Command '%s' exited abnormally with code %d"
1759                              shell-command exit-code))))))))
1760
1761 (defun notmuch-show-tag-message (&rest tag-changes)
1762   "Change tags for the current message.
1763
1764 TAG-CHANGES is a list of tag operations for `notmuch-tag'."
1765   (let* ((current-tags (notmuch-show-get-tags))
1766          (new-tags (notmuch-update-tags current-tags tag-changes)))
1767     (unless (equal current-tags new-tags)
1768       (notmuch-tag (notmuch-show-get-message-id) tag-changes)
1769       (notmuch-show-set-tags new-tags))))
1770
1771 (defun notmuch-show-tag (&optional tag-changes)
1772   "Change tags for the current message.
1773
1774 See `notmuch-tag' for information on the format of TAG-CHANGES."
1775   (interactive)
1776   (let* ((tag-changes (notmuch-tag (notmuch-show-get-message-id) tag-changes))
1777          (current-tags (notmuch-show-get-tags))
1778          (new-tags (notmuch-update-tags current-tags tag-changes)))
1779     (unless (equal current-tags new-tags)
1780       (notmuch-show-set-tags new-tags))))
1781
1782 (defun notmuch-show-tag-all (&optional tag-changes)
1783   "Change tags for all messages in the current show buffer.
1784
1785 See `notmuch-tag' for information on the format of TAG-CHANGES."
1786   (interactive)
1787   (setq tag-changes (notmuch-tag (notmuch-show-get-messages-ids-search) tag-changes))
1788   (notmuch-show-mapc
1789    (lambda ()
1790      (let* ((current-tags (notmuch-show-get-tags))
1791             (new-tags (notmuch-update-tags current-tags tag-changes)))
1792        (unless (equal current-tags new-tags)
1793          (notmuch-show-set-tags new-tags))))))
1794
1795 (defun notmuch-show-add-tag ()
1796   "Same as `notmuch-show-tag' but sets initial input to '+'."
1797   (interactive)
1798   (notmuch-show-tag "+"))
1799
1800 (defun notmuch-show-remove-tag ()
1801   "Same as `notmuch-show-tag' but sets initial input to '-'."
1802   (interactive)
1803   (notmuch-show-tag "-"))
1804
1805 (defun notmuch-show-toggle-visibility-headers ()
1806   "Toggle the visibility of the current message headers."
1807   (interactive)
1808   (let ((props (notmuch-show-get-message-properties)))
1809     (notmuch-show-headers-visible
1810      props
1811      (not (plist-get props :headers-visible))))
1812   (force-window-update))
1813
1814 (defun notmuch-show-toggle-message ()
1815   "Toggle the visibility of the current message."
1816   (interactive)
1817   (let ((props (notmuch-show-get-message-properties)))
1818     (notmuch-show-message-visible
1819      props
1820      (not (plist-get props :message-visible))))
1821   (force-window-update))
1822
1823 (defun notmuch-show-open-or-close-all ()
1824   "Set the visibility all of the messages in the current thread.
1825 By default make all of the messages visible. With a prefix
1826 argument, hide all of the messages."
1827   (interactive)
1828   (save-excursion
1829     (goto-char (point-min))
1830     (loop do (notmuch-show-message-visible (notmuch-show-get-message-properties)
1831                                            (not current-prefix-arg))
1832           until (not (notmuch-show-goto-message-next))))
1833   (force-window-update))
1834
1835 (defun notmuch-show-next-button ()
1836   "Advance point to the next button in the buffer."
1837   (interactive)
1838   (forward-button 1))
1839
1840 (defun notmuch-show-previous-button ()
1841   "Move point back to the previous button in the buffer."
1842   (interactive)
1843   (backward-button 1))
1844
1845 (defun notmuch-show-next-thread (&optional show previous)
1846   "Move to the next item in the search results, if any.
1847
1848 If SHOW is non-nil, open the next item in a show
1849 buffer. Otherwise just highlight the next item in the search
1850 buffer. If PREVIOUS is non-nil, move to the previous item in the
1851 search results instead."
1852   (interactive "P")
1853   (let ((parent-buffer notmuch-show-parent-buffer))
1854     (notmuch-kill-this-buffer)
1855     (when (buffer-live-p parent-buffer)
1856       (switch-to-buffer parent-buffer)
1857       (and (if previous
1858                (notmuch-search-previous-thread)
1859              (notmuch-search-next-thread))
1860            show
1861            (notmuch-search-show-thread)))))
1862
1863 (defun notmuch-show-next-thread-show ()
1864   "Show the next thread in the search results, if any."
1865   (interactive)
1866   (notmuch-show-next-thread t))
1867
1868 (defun notmuch-show-previous-thread-show ()
1869   "Show the previous thread in the search results, if any."
1870   (interactive)
1871   (notmuch-show-next-thread t t))
1872
1873 (defun notmuch-show-archive-thread (&optional unarchive)
1874   "Archive each message in thread.
1875
1876 Archive each message currently shown by applying the tag changes
1877 in `notmuch-archive-tags' to each. If a prefix argument is given,
1878 the messages will be \"unarchived\", i.e. the tag changes in
1879 `notmuch-archive-tags' will be reversed.
1880
1881 Note: This command is safe from any race condition of new messages
1882 being delivered to the same thread. It does not archive the
1883 entire thread, but only the messages shown in the current
1884 buffer."
1885   (interactive "P")
1886   (when notmuch-archive-tags
1887     (notmuch-show-tag-all
1888      (notmuch-tag-change-list notmuch-archive-tags unarchive))))
1889
1890 (defun notmuch-show-archive-thread-then-next ()
1891   "Archive all messages in the current buffer, then show next thread from search."
1892   (interactive)
1893   (notmuch-show-archive-thread)
1894   (notmuch-show-next-thread t))
1895
1896 (defun notmuch-show-archive-thread-then-exit ()
1897   "Archive all messages in the current buffer, then exit back to search results."
1898   (interactive)
1899   (notmuch-show-archive-thread)
1900   (notmuch-show-next-thread))
1901
1902 (defun notmuch-show-archive-message (&optional unarchive)
1903   "Archive the current message.
1904
1905 Archive the current message by applying the tag changes in
1906 `notmuch-archive-tags' to it. If a prefix argument is given, the
1907 message will be \"unarchived\", i.e. the tag changes in
1908 `notmuch-archive-tags' will be reversed."
1909   (interactive "P")
1910   (when notmuch-archive-tags
1911     (apply 'notmuch-show-tag-message
1912            (notmuch-tag-change-list notmuch-archive-tags unarchive))))
1913
1914 (defun notmuch-show-archive-message-then-next-or-exit ()
1915   "Archive the current message, then show the next open message in the current thread.
1916
1917 If at the last open message in the current thread, then exit back
1918 to search results."
1919   (interactive)
1920   (notmuch-show-archive-message)
1921   (notmuch-show-next-open-message t))
1922
1923 (defun notmuch-show-archive-message-then-next-or-next-thread ()
1924   "Archive the current message, then show the next open message in the current thread.
1925
1926 If at the last open message in the current thread, then show next
1927 thread from search."
1928   (interactive)
1929   (notmuch-show-archive-message)
1930   (unless (notmuch-show-next-open-message)
1931     (notmuch-show-next-thread t)))
1932
1933 (defun notmuch-show-stash-cc ()
1934   "Copy CC field of current message to kill-ring."
1935   (interactive)
1936   (notmuch-common-do-stash (notmuch-show-get-cc)))
1937
1938 (defun notmuch-show-stash-date ()
1939   "Copy date of current message to kill-ring."
1940   (interactive)
1941   (notmuch-common-do-stash (notmuch-show-get-date)))
1942
1943 (defun notmuch-show-stash-filename ()
1944   "Copy filename of current message to kill-ring."
1945   (interactive)
1946   (notmuch-common-do-stash (notmuch-show-get-filename)))
1947
1948 (defun notmuch-show-stash-from ()
1949   "Copy From address of current message to kill-ring."
1950   (interactive)
1951   (notmuch-common-do-stash (notmuch-show-get-from)))
1952
1953 (defun notmuch-show-stash-message-id (&optional stash-thread-id)
1954   "Copy id: query matching the current message to kill-ring.
1955
1956 If invoked with a prefix argument (or STASH-THREAD-ID is
1957 non-nil), copy thread: query matching the current thread to
1958 kill-ring."
1959   (interactive "P")
1960   (if stash-thread-id
1961       (notmuch-common-do-stash notmuch-show-thread-id)
1962     (notmuch-common-do-stash (notmuch-show-get-message-id))))
1963
1964 (defun notmuch-show-stash-message-id-stripped ()
1965   "Copy message ID of current message (sans `id:' prefix) to kill-ring."
1966   (interactive)
1967   (notmuch-common-do-stash (notmuch-show-get-message-id t)))
1968
1969 (defun notmuch-show-stash-subject ()
1970   "Copy Subject field of current message to kill-ring."
1971   (interactive)
1972   (notmuch-common-do-stash (notmuch-show-get-subject)))
1973
1974 (defun notmuch-show-stash-tags ()
1975   "Copy tags of current message to kill-ring as a comma separated list."
1976   (interactive)
1977   (notmuch-common-do-stash (mapconcat 'identity (notmuch-show-get-tags) ",")))
1978
1979 (defun notmuch-show-stash-to ()
1980   "Copy To address of current message to kill-ring."
1981   (interactive)
1982   (notmuch-common-do-stash (notmuch-show-get-to)))
1983
1984 (defun notmuch-show-stash-mlarchive-link (&optional mla)
1985   "Copy an ML Archive URI for the current message to the kill-ring.
1986
1987 This presumes that the message is available at the selected Mailing List Archive.
1988
1989 If optional argument MLA is non-nil, use the provided key instead of prompting
1990 the user (see `notmuch-show-stash-mlarchive-link-alist')."
1991   (interactive)
1992   (notmuch-common-do-stash
1993    (concat (cdr (assoc
1994                  (or mla
1995                      (let ((completion-ignore-case t))
1996                        (completing-read
1997                         "Mailing List Archive: "
1998                         notmuch-show-stash-mlarchive-link-alist
1999                         nil t nil nil notmuch-show-stash-mlarchive-link-default)))
2000                  notmuch-show-stash-mlarchive-link-alist))
2001            (notmuch-show-get-message-id t))))
2002
2003 (defun notmuch-show-stash-mlarchive-link-and-go (&optional mla)
2004   "Copy an ML Archive URI for the current message to the kill-ring and visit it.
2005
2006 This presumes that the message is available at the selected Mailing List Archive.
2007
2008 If optional argument MLA is non-nil, use the provided key instead of prompting
2009 the user (see `notmuch-show-stash-mlarchive-link-alist')."
2010   (interactive)
2011   (notmuch-show-stash-mlarchive-link mla)
2012   (browse-url (current-kill 0 t)))
2013
2014 ;; Interactive part functions and their helpers
2015
2016 (defun notmuch-show-generate-part-buffer (message-id nth)
2017   "Return a temporary buffer containing the specified part's content."
2018   (let ((buf (generate-new-buffer " *notmuch-part*"))
2019         (process-crypto notmuch-show-process-crypto))
2020     (with-current-buffer buf
2021       (setq notmuch-show-process-crypto process-crypto)
2022       ;; Always acquires the part via `notmuch part', even if it is
2023       ;; available in the SEXP output.
2024       (insert (notmuch-get-bodypart-internal message-id nth notmuch-show-process-crypto)))
2025     buf))
2026
2027 (defun notmuch-show-current-part-handle ()
2028   "Return an mm-handle for the part containing point.
2029
2030 This creates a temporary buffer for the part's content; the
2031 caller is responsible for killing this buffer as appropriate."
2032   (let* ((part (notmuch-show-get-part-properties))
2033          (message-id (notmuch-show-get-message-id))
2034          (nth (plist-get part :id))
2035          (buf (notmuch-show-generate-part-buffer message-id nth))
2036          (computed-type (plist-get part :computed-type))
2037          (filename (plist-get part :filename))
2038          (disposition (if filename `(attachment (filename . ,filename)))))
2039     (mm-make-handle buf (list computed-type) nil nil disposition)))
2040
2041 (defun notmuch-show-apply-to-current-part-handle (fn)
2042   "Apply FN to an mm-handle for the part containing point.
2043
2044 This ensures that the temporary buffer created for the mm-handle
2045 is destroyed when FN returns."
2046   (let ((handle (notmuch-show-current-part-handle)))
2047     (unwind-protect
2048         (funcall fn handle)
2049       (kill-buffer (mm-handle-buffer handle)))))
2050
2051 (defun notmuch-show-part-button-default (&optional button)
2052   (interactive)
2053   (let ((button (or button (button-at (point)))))
2054     ;; Try to toggle the part, if that fails then call the default
2055     ;; action. The toggle fails if the part has no emacs renderable
2056     ;; content.
2057     (unless (notmuch-show-toggle-part-invisibility button)
2058       (call-interactively notmuch-show-part-button-default-action))))
2059
2060 (defun notmuch-show-save-part ()
2061   "Save the MIME part containing point to a file."
2062   (interactive)
2063   (notmuch-show-apply-to-current-part-handle #'mm-save-part))
2064
2065 (defun notmuch-show-view-part ()
2066   "View the MIME part containing point in an external viewer."
2067   (interactive)
2068   ;; Set mm-inlined-types to nil to force an external viewer
2069   (let ((mm-inlined-types nil))
2070     (notmuch-show-apply-to-current-part-handle #'mm-display-part)))
2071
2072 (defun notmuch-show-interactively-view-part ()
2073   "View the MIME part containing point, prompting for a viewer."
2074   (interactive)
2075   (notmuch-show-apply-to-current-part-handle #'mm-interactively-view-part))
2076
2077 (defun notmuch-show-pipe-part ()
2078   "Pipe the MIME part containing point to an external command."
2079   (interactive)
2080   (notmuch-show-apply-to-current-part-handle #'mm-pipe-part))
2081
2082
2083 (provide 'notmuch-show)