git.notmuchmail.org Git - notmuch/blob - emacs/notmuch-show.el

   1 ;; notmuch-show.el --- displaying notmuch forests.
   2 ;;
   3 ;; Copyright © Carl Worth
   4 ;; Copyright © David Edmondson
   5 ;;
   6 ;; This file is part of Notmuch.
   7 ;;
   8 ;; Notmuch is free software: you can redistribute it and/or modify it
   9 ;; under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation, either version 3 of the License, or
  11 ;; (at your option) any later version.
  12 ;;
  13 ;; Notmuch is distributed in the hope that it will be useful, but
  14 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 ;; General Public License for more details.
  17 ;;
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with Notmuch.  If not, see <http://www.gnu.org/licenses/>.
  20 ;;
  21 ;; Authors: Carl Worth <cworth@cworth.org>
  22 ;;          David Edmondson <dme@dme.org>
  23
  24 (eval-when-compile (require 'cl))
  25 (require 'mm-view)
  26 (require 'message)
  27 (require 'mm-decode)
  28 (require 'mailcap)
  29 (require 'icalendar)
  30 (require 'goto-addr)
  31
  32 (require 'notmuch-lib)
  33 (require 'notmuch-query)
  34 (require 'notmuch-wash)
  35 (require 'notmuch-mua)
  36 (require 'notmuch-crypto)
  37
  38 (declare-function notmuch-call-notmuch-process "notmuch" (&rest args))
  39 (declare-function notmuch-fontify-headers "notmuch" nil)
  40 (declare-function notmuch-select-tag-with-completion "notmuch" (prompt &rest search-terms))
  41 (declare-function notmuch-search-show-thread "notmuch" nil)
  42
  43 (defcustom notmuch-message-headers '("Subject" "To" "Cc" "Date")
  44   "Headers that should be shown in a message, in this order.
  45
  46 For an open message, all of these headers will be made visible
  47 according to `notmuch-message-headers-visible' or can be toggled
  48 with `notmuch-show-toggle-headers'. For a closed message, only
  49 the first header in the list will be visible."
  50   :group 'notmuch
  51   :type '(repeat string))
  52
  53 (defcustom notmuch-message-headers-visible t
  54   "Should the headers be visible by default?
  55
  56 If this value is non-nil, then all of the headers defined in
  57 `notmuch-message-headers' will be visible by default in the display
  58 of each message. Otherwise, these headers will be hidden and
  59 `notmuch-show-toggle-headers' can be used to make the visible for
  60 any given message."
  61   :group 'notmuch
  62   :type 'boolean)
  63
  64 (defcustom notmuch-show-relative-dates t
  65   "Display relative dates in the message summary line."
  66   :group 'notmuch
  67   :type 'boolean)
  68
  69 (defvar notmuch-show-markup-headers-hook '(notmuch-show-colour-headers)
  70   "A list of functions called to decorate the headers listed in
  71 `notmuch-message-headers'.")
  72
  73 (defcustom notmuch-show-hook nil
  74   "Functions called after populating a `notmuch-show' buffer."
  75   :group 'notmuch
  76   :type 'hook)
  77
  78 (defcustom notmuch-show-insert-text/plain-hook '(notmuch-wash-excerpt-citations)
  79   "Functions used to improve the display of text/plain parts."
  80   :group 'notmuch
  81   :type 'hook
  82   :options '(notmuch-wash-convert-inline-patch-to-part
  83              notmuch-wash-wrap-long-lines
  84              notmuch-wash-tidy-citations
  85              notmuch-wash-elide-blank-lines
  86              notmuch-wash-excerpt-citations))
  87
  88 ;; Mostly useful for debugging.
  89 (defcustom notmuch-show-all-multipart/alternative-parts t
  90   "Should all parts of multipart/alternative parts be shown?"
  91   :group 'notmuch
  92   :type 'boolean)
  93
  94 (defcustom notmuch-show-indent-multipart nil
  95   "Should the sub-parts of a multipart/* part be indented?"
  96   ;; dme: Not sure which is a good default.
  97   :group 'notmuch
  98   :type 'boolean)
  99
 100 (defmacro with-current-notmuch-show-message (&rest body)
 101   "Evaluate body with current buffer set to the text of current message"
 102   `(save-excursion
 103      (let ((id (notmuch-show-get-message-id)))
 104        (let ((buf (generate-new-buffer (concat "*notmuch-msg-" id "*"))))
 105          (with-current-buffer buf
 106             (call-process notmuch-command nil t nil "show" "--format=raw" id)
 107            ,@body)
 108          (kill-buffer buf)))))
 109
 110 (defun notmuch-show-view-all-mime-parts ()
 111   "Use external viewers to view all attachments from the current message."
 112   (interactive)
 113   (with-current-notmuch-show-message
 114    ; We override the mm-inline-media-tests to indicate which message
 115    ; parts are already sufficiently handled by the original
 116    ; presentation of the message in notmuch-show mode. These parts
 117    ; will be inserted directly into the temporary buffer of
 118    ; with-current-notmuch-show-message and silently discarded.
 119    ;
 120    ; Any MIME part not explicitly mentioned here will be handled by an
 121    ; external viewer as configured in the various mailcap files.
 122    (let ((mm-inline-media-tests '(
 123                                   ("text/.*" ignore identity)
 124                                   ("application/pgp-signature" ignore identity)
 125                                   ("multipart/alternative" ignore identity)
 126                                   ("multipart/mixed" ignore identity)
 127                                   ("multipart/related" ignore identity)
 128                                  )))
 129      (mm-display-parts (mm-dissect-buffer)))))
 130
 131 (defun notmuch-foreach-mime-part (function mm-handle)
 132   (cond ((stringp (car mm-handle))
 133          (dolist (part (cdr mm-handle))
 134            (notmuch-foreach-mime-part function part)))
 135         ((bufferp (car mm-handle))
 136          (funcall function mm-handle))
 137         (t (dolist (part mm-handle)
 138              (notmuch-foreach-mime-part function part)))))
 139
 140 (defun notmuch-count-attachments (mm-handle)
 141   (let ((count 0))
 142     (notmuch-foreach-mime-part
 143      (lambda (p)
 144        (let ((disposition (mm-handle-disposition p)))
 145          (and (listp disposition)
 146               (or (equal (car disposition) "attachment")
 147                   (and (equal (car disposition) "inline")
 148                        (assq 'filename disposition)))
 149               (incf count))))
 150      mm-handle)
 151     count))
 152
 153 (defun notmuch-save-attachments (mm-handle &optional queryp)
 154   (notmuch-foreach-mime-part
 155    (lambda (p)
 156      (let ((disposition (mm-handle-disposition p)))
 157        (and (listp disposition)
 158             (or (equal (car disposition) "attachment")
 159                 (and (equal (car disposition) "inline")
 160                      (assq 'filename disposition)))
 161             (or (not queryp)
 162                 (y-or-n-p
 163                  (concat "Save '" (cdr (assq 'filename disposition)) "' ")))
 164             (mm-save-part p))))
 165    mm-handle))
 166
 167 (defun notmuch-show-save-attachments ()
 168   "Save all attachments from the current message."
 169   (interactive)
 170   (with-current-notmuch-show-message
 171    (let ((mm-handle (mm-dissect-buffer)))
 172      (notmuch-save-attachments
 173       mm-handle (> (notmuch-count-attachments mm-handle) 1))))
 174   (message "Done"))
 175
 176 (defun notmuch-show-fontify-header ()
 177   (let ((face (cond
 178                ((looking-at "[Tt]o:")
 179                 'message-header-to)
 180                ((looking-at "[Bb]?[Cc][Cc]:")
 181                 'message-header-cc)
 182                ((looking-at "[Ss]ubject:")
 183                 'message-header-subject)
 184                ((looking-at "[Ff]rom:")
 185                 'message-header-from)
 186                (t
 187                 'message-header-other))))
 188
 189     (overlay-put (make-overlay (point) (re-search-forward ":"))
 190                  'face 'message-header-name)
 191     (overlay-put (make-overlay (point) (re-search-forward ".*$"))
 192                  'face face)))
 193
 194 (defun notmuch-show-colour-headers ()
 195   "Apply some colouring to the current headers."
 196   (goto-char (point-min))
 197   (while (looking-at "^[A-Za-z][-A-Za-z0-9]*:")
 198     (notmuch-show-fontify-header)
 199     (forward-line)))
 200
 201 (defun notmuch-show-spaces-n (n)
 202   "Return a string comprised of `n' spaces."
 203   (make-string n ? ))
 204
 205 (defun notmuch-show-update-tags (tags)
 206   "Update the displayed tags of the current message."
 207   (save-excursion
 208     (goto-char (notmuch-show-message-top))
 209     (if (re-search-forward "(\\([^()]*\\))$" (line-end-position) t)
 210         (let ((inhibit-read-only t))
 211           (replace-match (concat "("
 212                                  (propertize (mapconcat 'identity tags " ")
 213                                              'face 'notmuch-tag-face)
 214                                  ")"))))))
 215
 216 (defun notmuch-show-clean-address (address)
 217   "Try to clean a single email ADDRESS for display.  Return
 218 unchanged ADDRESS if parsing fails."
 219   (condition-case nil
 220     (let* ((parsed (mail-header-parse-address address))
 221            (address (car parsed))
 222            (name (cdr parsed)))
 223       ;; Remove double quotes. They might be required during transport,
 224       ;; but we don't need to see them.
 225       (when name
 226         (setq name (replace-regexp-in-string "\"" "" name)))
 227       ;; If the address is 'foo@bar.com <foo@bar.com>' then show just
 228       ;; 'foo@bar.com'.
 229       (when (string= name address)
 230         (setq name nil))
 231
 232       (if (not name)
 233         address
 234         (concat name " <" address ">")))
 235     (error address)))
 236
 237 (defun notmuch-show-insert-headerline (headers date tags depth)
 238   "Insert a notmuch style headerline based on HEADERS for a
 239 message at DEPTH in the current thread."
 240   (let ((start (point)))
 241     (insert (notmuch-show-spaces-n depth)
 242             (notmuch-show-clean-address (plist-get headers :From))
 243             " ("
 244             date
 245             ") ("
 246             (propertize (mapconcat 'identity tags " ")
 247                         'face 'notmuch-tag-face)
 248             ")\n")
 249     (overlay-put (make-overlay start (point)) 'face 'notmuch-message-summary-face)))
 250
 251 (defun notmuch-show-insert-header (header header-value)
 252   "Insert a single header."
 253   (insert header ": " header-value "\n"))
 254
 255 (defun notmuch-show-insert-headers (headers)
 256   "Insert the headers of the current message."
 257   (let ((start (point)))
 258     (mapc '(lambda (header)
 259              (let* ((header-symbol (intern (concat ":" header)))
 260                     (header-value (plist-get headers header-symbol)))
 261                (if (and header-value
 262                         (not (string-equal "" header-value)))
 263                    (notmuch-show-insert-header header header-value))))
 264           notmuch-message-headers)
 265     (save-excursion
 266       (save-restriction
 267         (narrow-to-region start (point-max))
 268         (run-hooks 'notmuch-show-markup-headers-hook)))))
 269
 270 (define-button-type 'notmuch-show-part-button-type
 271   'action 'notmuch-show-part-button-action
 272   'follow-link t
 273   'face 'message-mml)
 274
 275 (defun notmuch-show-insert-part-header (nth content-type declared-type &optional name comment)
 276   (let ((button))
 277     (setq button
 278           (insert-button
 279            (concat "[ "
 280                    (if name (concat name ": ") "")
 281                    declared-type
 282                    (if (not (string-equal declared-type content-type))
 283                        (concat " (as " content-type ")")
 284                      "")
 285                    (or comment "")
 286                    " ]")
 287            :type 'notmuch-show-part-button-type
 288            :notmuch-part nth
 289            :notmuch-filename name))
 290     (insert "\n")
 291     ;; return button
 292     button))
 293
 294 ;; Functions handling particular MIME parts.
 295
 296 (defun notmuch-show-save-part (message-id nth &optional filename)
 297   (let ((process-crypto notmuch-show-process-crypto))
 298     (with-temp-buffer
 299       (setq notmuch-show-process-crypto process-crypto)
 300       ;; Always acquires the part via `notmuch part', even if it is
 301       ;; available in the JSON output.
 302       (insert (notmuch-show-get-bodypart-internal message-id nth))
 303       (let ((file (read-file-name
 304                    "Filename to save as: "
 305                    (or mailcap-download-directory "~/")
 306                    nil nil
 307                    filename)))
 308         ;; Don't re-compress .gz & al.  Arguably we should make
 309         ;; `file-name-handler-alist' nil, but that would chop
 310         ;; ange-ftp, which is reasonable to use here.
 311         (mm-write-region (point-min) (point-max) file nil nil nil 'no-conversion t)))))
 312
 313 (defun notmuch-show-mm-display-part-inline (msg part content-type content)
 314   "Use the mm-decode/mm-view functions to display a part in the
 315 current buffer, if possible."
 316   (let ((display-buffer (current-buffer)))
 317     (with-temp-buffer
 318       (insert content)
 319       (let ((handle (mm-make-handle (current-buffer) (list content-type))))
 320         (set-buffer display-buffer)
 321         (if (and (mm-inlinable-p handle)
 322                  (mm-inlined-p handle))
 323             (progn
 324               (mm-display-part handle)
 325               t)
 326           nil)))))
 327
 328 (defvar notmuch-show-multipart/alternative-discouraged
 329   '(
 330     ;; Avoid HTML parts.
 331     "text/html"
 332     ;; multipart/related usually contain a text/html part and some associated graphics.
 333     "multipart/related"
 334     ))
 335
 336 (defun notmuch-show-multipart/*-to-list (part)
 337   (mapcar '(lambda (inner-part) (plist-get inner-part :content-type))
 338           (plist-get part :content)))
 339
 340 (defun notmuch-show-multipart/alternative-choose (types)
 341   ;; Based on `mm-preferred-alternative-precedence'.
 342   (let ((seq types))
 343     (dolist (pref (reverse notmuch-show-multipart/alternative-discouraged))
 344       (dolist (elem (copy-sequence seq))
 345         (when (string-match pref elem)
 346           (setq seq (nconc (delete elem seq) (list elem))))))
 347     seq))
 348
 349 (defun notmuch-show-insert-part-multipart/alternative (msg part content-type nth depth declared-type)
 350   (notmuch-show-insert-part-header nth declared-type content-type nil)
 351   (let ((chosen-type (car (notmuch-show-multipart/alternative-choose (notmuch-show-multipart/*-to-list part))))
 352         (inner-parts (plist-get part :content))
 353         (start (point)))
 354     ;; This inserts all parts of the chosen type rather than just one,
 355     ;; but it's not clear that this is the wrong thing to do - which
 356     ;; should be chosen if there are more than one that match?
 357     (mapc (lambda (inner-part)
 358             (let ((inner-type (plist-get inner-part :content-type)))
 359               (if (or notmuch-show-all-multipart/alternative-parts
 360                       (string= chosen-type inner-type))
 361                   (notmuch-show-insert-bodypart msg inner-part depth)
 362                 (notmuch-show-insert-part-header (plist-get inner-part :id) inner-type inner-type nil " (not shown)"))))
 363           inner-parts)
 364
 365     (when notmuch-show-indent-multipart
 366       (indent-rigidly start (point) 1)))
 367   t)
 368
 369 (defun notmuch-show-setup-w3m ()
 370   "Instruct w3m how to retrieve content from a \"related\" part of a message."
 371   (interactive)
 372   (if (boundp 'w3m-cid-retrieve-function-alist)
 373     (unless (assq 'notmuch-show-mode w3m-cid-retrieve-function-alist)
 374       (push (cons 'notmuch-show-mode 'notmuch-show-w3m-cid-retrieve)
 375             w3m-cid-retrieve-function-alist)))
 376   (setq mm-inline-text-html-with-images t))
 377
 378 (defvar w3m-current-buffer) ;; From `w3m.el'.
 379 (defvar notmuch-show-w3m-cid-store nil)
 380 (make-variable-buffer-local 'notmuch-show-w3m-cid-store)
 381
 382 (defun notmuch-show-w3m-cid-store-internal (content-id
 383                                             message-id
 384                                             part-number
 385                                             content-type
 386                                             content)
 387   (push (list content-id
 388               message-id
 389               part-number
 390               content-type
 391               content)
 392         notmuch-show-w3m-cid-store))
 393
 394 (defun notmuch-show-w3m-cid-store (msg part)
 395   (let ((content-id (plist-get part :content-id)))
 396     (when content-id
 397       (notmuch-show-w3m-cid-store-internal (concat "cid:" content-id)
 398                                            (plist-get msg :id)
 399                                            (plist-get part :id)
 400                                            (plist-get part :content-type)
 401                                            nil))))
 402
 403 (defun notmuch-show-w3m-cid-retrieve (url &rest args)
 404   (let ((matching-part (with-current-buffer w3m-current-buffer
 405                          (assoc url notmuch-show-w3m-cid-store))))
 406     (if matching-part
 407         (let ((message-id (nth 1 matching-part))
 408               (part-number (nth 2 matching-part))
 409               (content-type (nth 3 matching-part))
 410               (content (nth 4 matching-part)))
 411           ;; If we don't already have the content, get it and cache
 412           ;; it, as some messages reference the same cid: part many
 413           ;; times (hundreds!), which results in many calls to
 414           ;; `notmuch part'.
 415           (unless content
 416             (setq content (notmuch-show-get-bodypart-internal (concat "id:" message-id)
 417                                                               part-number))
 418             (with-current-buffer w3m-current-buffer
 419               (notmuch-show-w3m-cid-store-internal url
 420                                                    message-id
 421                                                    part-number
 422                                                    content-type
 423                                                    content)))
 424           (insert content)
 425           content-type)
 426       nil)))
 427
 428 (defun notmuch-show-insert-part-multipart/related (msg part content-type nth depth declared-type)
 429   (notmuch-show-insert-part-header nth declared-type content-type nil)
 430   (let ((inner-parts (plist-get part :content))
 431         (start (point)))
 432
 433     ;; We assume that the first part is text/html and the remainder
 434     ;; things that it references.
 435
 436     ;; Stash the non-primary parts.
 437     (mapc (lambda (part)
 438             (notmuch-show-w3m-cid-store msg part))
 439           (cdr inner-parts))
 440
 441     ;; Render the primary part.
 442     (notmuch-show-insert-bodypart msg (car inner-parts) depth)
 443
 444     (when notmuch-show-indent-multipart
 445       (indent-rigidly start (point) 1)))
 446   t)
 447
 448 (defun notmuch-show-insert-part-multipart/signed (msg part content-type nth depth declared-type)
 449   (let ((button (notmuch-show-insert-part-header nth declared-type content-type nil)))
 450     (button-put button 'face '(:foreground "blue"))
 451     ;; add signature status button if sigstatus provided
 452     (if (plist-member part :sigstatus)
 453         (let* ((headers (plist-get msg :headers))
 454                (from (plist-get headers :From))
 455                (sigstatus (car (plist-get part :sigstatus))))
 456           (notmuch-crypto-insert-sigstatus-button sigstatus from))
 457       ;; if we're not adding sigstatus, tell the user how they can get it
 458       (button-put button 'help-echo "Set notmuch-crypto-process-mime to process cryptographic mime parts.")))
 459
 460   (let ((inner-parts (plist-get part :content))
 461         (start (point)))
 462     ;; Show all of the parts.
 463     (mapc (lambda (inner-part)
 464             (notmuch-show-insert-bodypart msg inner-part depth))
 465           inner-parts)
 466
 467     (when notmuch-show-indent-multipart
 468       (indent-rigidly start (point) 1)))
 469   t)
 470
 471 (defun notmuch-show-insert-part-multipart/encrypted (msg part content-type nth depth declared-type)
 472   (let ((button (notmuch-show-insert-part-header nth declared-type content-type nil)))
 473     (button-put button 'face '(:foreground "blue"))
 474     ;; add encryption status button if encstatus specified
 475     (if (plist-member part :encstatus)
 476         (let ((encstatus (car (plist-get part :encstatus))))
 477           (notmuch-crypto-insert-encstatus-button encstatus)
 478           ;; add signature status button if sigstatus specified
 479           (if (plist-member part :sigstatus)
 480               (let* ((headers (plist-get msg :headers))
 481                      (from (plist-get headers :From))
 482                      (sigstatus (car (plist-get part :sigstatus))))
 483                 (notmuch-crypto-insert-sigstatus-button sigstatus from))))
 484       ;; if we're not adding encstatus, tell the user how they can get it
 485       (button-put button 'help-echo "Set notmuch-crypto-process-mime to process cryptographic mime parts.")))
 486
 487   (let ((inner-parts (plist-get part :content))
 488         (start (point)))
 489     ;; Show all of the parts.
 490     (mapc (lambda (inner-part)
 491             (notmuch-show-insert-bodypart msg inner-part depth))
 492           inner-parts)
 493
 494     (when notmuch-show-indent-multipart
 495       (indent-rigidly start (point) 1)))
 496   t)
 497
 498 (defun notmuch-show-insert-part-multipart/* (msg part content-type nth depth declared-type)
 499   (notmuch-show-insert-part-header nth declared-type content-type nil)
 500   (let ((inner-parts (plist-get part :content))
 501         (start (point)))
 502     ;; Show all of the parts.
 503     (mapc (lambda (inner-part)
 504             (notmuch-show-insert-bodypart msg inner-part depth))
 505           inner-parts)
 506
 507     (when notmuch-show-indent-multipart
 508       (indent-rigidly start (point) 1)))
 509   t)
 510
 511 (defun notmuch-show-insert-part-message/rfc822 (msg part content-type nth depth declared-type)
 512   (notmuch-show-insert-part-header nth declared-type content-type nil)
 513   (let* ((message (car (plist-get part :content)))
 514          (headers (plist-get message :headers))
 515          (body (car (plist-get message :body)))
 516          (start (point)))
 517
 518     ;; Override `notmuch-message-headers' to force `From' to be
 519     ;; displayed.
 520     (let ((notmuch-message-headers '("From" "Subject" "To" "Cc" "Date")))
 521       (notmuch-show-insert-headers (plist-get message :headers)))
 522
 523     ;; Blank line after headers to be compatible with the normal
 524     ;; message display.
 525     (insert "\n")
 526
 527     ;; Show the body
 528     (notmuch-show-insert-bodypart msg body depth)
 529
 530     (when notmuch-show-indent-multipart
 531       (indent-rigidly start (point) 1)))
 532   t)
 533
 534 (defun notmuch-show-insert-part-text/plain (msg part content-type nth depth declared-type)
 535   (let ((start (point)))
 536     ;; If this text/plain part is not the first part in the message,
 537     ;; insert a header to make this clear.
 538     (if (> nth 1)
 539         (notmuch-show-insert-part-header nth declared-type content-type (plist-get part :filename)))
 540     (insert (notmuch-show-get-bodypart-content msg part nth))
 541     (save-excursion
 542       (save-restriction
 543         (narrow-to-region start (point-max))
 544         (run-hook-with-args 'notmuch-show-insert-text/plain-hook msg depth))))
 545   t)
 546
 547 (defun notmuch-show-insert-part-text/x-vcalendar (msg part content-type nth depth declared-type)
 548   (notmuch-show-insert-part-header nth declared-type content-type (plist-get part :filename))
 549   (insert (with-temp-buffer
 550             (insert (notmuch-show-get-bodypart-content msg part nth))
 551             (goto-char (point-min))
 552             (let ((file (make-temp-file "notmuch-ical"))
 553                   result)
 554               (icalendar--convert-ical-to-diary
 555                (icalendar--read-element nil nil)
 556                file t)
 557               (set-buffer (get-file-buffer file))
 558               (setq result (buffer-substring (point-min) (point-max)))
 559               (set-buffer-modified-p nil)
 560               (kill-buffer (current-buffer))
 561               (delete-file file)
 562               result)))
 563   t)
 564
 565 (defun notmuch-show-insert-part-application/octet-stream (msg part content-type nth depth declared-type)
 566   ;; If we can deduce a MIME type from the filename of the attachment,
 567   ;; do so and pass it on to the handler for that type.
 568   (if (plist-get part :filename)
 569       (let ((extension (file-name-extension (plist-get part :filename)))
 570             mime-type)
 571         (if extension
 572             (progn
 573               (mailcap-parse-mimetypes)
 574               (setq mime-type (mailcap-extension-to-mime extension))
 575               (if (and mime-type
 576                        (not (string-equal mime-type "application/octet-stream")))
 577                   (notmuch-show-insert-bodypart-internal msg part mime-type nth depth content-type)
 578                 nil))
 579           nil))))
 580
 581 (defun notmuch-show-insert-part-application/* (msg part content-type nth depth declared-type
 582 )
 583   ;; do not render random "application" parts
 584   (notmuch-show-insert-part-header nth content-type declared-type (plist-get part :filename)))
 585
 586 (defun notmuch-show-insert-part-*/* (msg part content-type nth depth declared-type)
 587   ;; This handler _must_ succeed - it is the handler of last resort.
 588   (notmuch-show-insert-part-header nth content-type declared-type (plist-get part :filename))
 589   (let ((content (notmuch-show-get-bodypart-content msg part nth)))
 590     (if content
 591         (notmuch-show-mm-display-part-inline msg part content-type content)))
 592   t)
 593
 594 ;; Functions for determining how to handle MIME parts.
 595
 596 (defun notmuch-show-split-content-type (content-type)
 597   (split-string content-type "/"))
 598
 599 (defun notmuch-show-handlers-for (content-type)
 600   "Return a list of content handlers for a part of type CONTENT-TYPE."
 601   (let (result)
 602     (mapc (lambda (func)
 603             (if (functionp func)
 604                 (push func result)))
 605           ;; Reverse order of prefrence.
 606           (list (intern (concat "notmuch-show-insert-part-*/*"))
 607                 (intern (concat
 608                          "notmuch-show-insert-part-"
 609                          (car (notmuch-show-split-content-type content-type))
 610                          "/*"))
 611                 (intern (concat "notmuch-show-insert-part-" content-type))))
 612     result))
 613
 614 ;; Helper for parts which are generally not included in the default
 615 ;; JSON output.
 616 ;; Uses the buffer-local variable notmuch-show-process-crypto to
 617 ;; determine if parts should be decrypted first.
 618 (defun notmuch-show-get-bodypart-internal (message-id part-number)
 619   (let ((args '("show" "--format=raw"))
 620         (part-arg (format "--part=%s" part-number)))
 621     (setq args (append args (list part-arg)))
 622     (if notmuch-show-process-crypto
 623         (setq args (append args '("--decrypt"))))
 624     (setq args (append args (list message-id)))
 625     (with-temp-buffer
 626       (let ((coding-system-for-read 'no-conversion))
 627         (progn
 628           (apply 'call-process (append (list notmuch-command nil (list t nil) nil) args))
 629           (buffer-string))))))
 630
 631 (defun notmuch-show-get-bodypart-content (msg part nth)
 632   (or (plist-get part :content)
 633       (notmuch-show-get-bodypart-internal (concat "id:" (plist-get msg :id)) nth)))
 634
 635 ;; \f
 636
 637 (defun notmuch-show-insert-bodypart-internal (msg part content-type nth depth declared-type)
 638   (let ((handlers (notmuch-show-handlers-for content-type)))
 639     ;; Run the content handlers until one of them returns a non-nil
 640     ;; value.
 641     (while (and handlers
 642                 (not (funcall (car handlers) msg part content-type nth depth declared-type)))
 643       (setq handlers (cdr handlers))))
 644   t)
 645
 646 (defun notmuch-show-insert-bodypart (msg part depth)
 647   "Insert the body part PART at depth DEPTH in the current thread."
 648   (let ((content-type (downcase (plist-get part :content-type)))
 649         (nth (plist-get part :id)))
 650     (notmuch-show-insert-bodypart-internal msg part content-type nth depth content-type))
 651   ;; Some of the body part handlers leave point somewhere up in the
 652   ;; part, so we make sure that we're down at the end.
 653   (goto-char (point-max))
 654   ;; Ensure that the part ends with a carriage return.
 655   (if (not (bolp))
 656       (insert "\n")))
 657
 658 (defun notmuch-show-insert-body (msg body depth)
 659   "Insert the body BODY at depth DEPTH in the current thread."
 660   (mapc '(lambda (part) (notmuch-show-insert-bodypart msg part depth)) body))
 661
 662 (defun notmuch-show-make-symbol (type)
 663   (make-symbol (concat "notmuch-show-" type)))
 664
 665 (defun notmuch-show-strip-re (string)
 666   (replace-regexp-in-string "\\([Rr]e: *\\)+" "" string))
 667
 668 (defvar notmuch-show-previous-subject "")
 669 (make-variable-buffer-local 'notmuch-show-previous-subject)
 670
 671 (defun notmuch-show-insert-msg (msg depth)
 672   "Insert the message MSG at depth DEPTH in the current thread."
 673   (let* ((headers (plist-get msg :headers))
 674          ;; Indentation causes the buffer offset of the start/end
 675          ;; points to move, so we must use markers.
 676          message-start message-end
 677          content-start content-end
 678          headers-start headers-end
 679          body-start body-end
 680          (headers-invis-spec (notmuch-show-make-symbol "header"))
 681          (message-invis-spec (notmuch-show-make-symbol "message"))
 682          (bare-subject (notmuch-show-strip-re (plist-get headers :Subject))))
 683
 684     ;; Set `buffer-invisibility-spec' to `nil' (a list), otherwise
 685     ;; removing items from `buffer-invisibility-spec' (which is what
 686     ;; `notmuch-show-headers-visible' and
 687     ;; `notmuch-show-message-visible' do) is a no-op and has no
 688     ;; effect. This caused threads with only matching messages to have
 689     ;; those messages hidden initially because
 690     ;; `buffer-invisibility-spec' stayed `t'.
 691     ;;
 692     ;; This needs to be set here (rather than just above the call to
 693     ;; `notmuch-show-headers-visible') because some of the part
 694     ;; rendering or body washing functions
 695     ;; (e.g. `notmuch-wash-text/plain-citations') manipulate
 696     ;; `buffer-invisibility-spec').
 697     (when (eq buffer-invisibility-spec t)
 698       (setq buffer-invisibility-spec nil))
 699
 700     (setq message-start (point-marker))
 701
 702     (notmuch-show-insert-headerline headers
 703                                     (or (if notmuch-show-relative-dates
 704                                             (plist-get msg :date_relative)
 705                                           nil)
 706                                         (plist-get headers :Date))
 707                                     (plist-get msg :tags) depth)
 708
 709     (setq content-start (point-marker))
 710
 711     (plist-put msg :headers-invis-spec headers-invis-spec)
 712     (plist-put msg :message-invis-spec message-invis-spec)
 713
 714     ;; Set `headers-start' to point after the 'Subject:' header to be
 715     ;; compatible with the existing implementation. This just sets it
 716     ;; to after the first header.
 717     (notmuch-show-insert-headers headers)
 718     ;; Headers should include a blank line (backwards compatibility).
 719     (insert "\n")
 720     (save-excursion
 721       (goto-char content-start)
 722       ;; If the subject of this message is the same as that of the
 723       ;; previous message, don't display it when this message is
 724       ;; collapsed.
 725       (when (not (string= notmuch-show-previous-subject
 726                           bare-subject))
 727         (forward-line 1))
 728       (setq headers-start (point-marker)))
 729     (setq headers-end (point-marker))
 730
 731     (setq notmuch-show-previous-subject bare-subject)
 732
 733     (setq body-start (point-marker))
 734     (notmuch-show-insert-body msg (plist-get msg :body) depth)
 735     ;; Ensure that the body ends with a newline.
 736     (if (not (bolp))
 737         (insert "\n"))
 738     (setq body-end (point-marker))
 739     (setq content-end (point-marker))
 740
 741     ;; Indent according to the depth in the thread.
 742     (indent-rigidly content-start content-end depth)
 743
 744     (setq message-end (point-max-marker))
 745
 746     ;; Save the extents of this message over the whole text of the
 747     ;; message.
 748     (put-text-property message-start message-end :notmuch-message-extent (cons message-start message-end))
 749
 750     (let ((headers-overlay (make-overlay headers-start headers-end))
 751           (invis-specs (list headers-invis-spec message-invis-spec)))
 752       (overlay-put headers-overlay 'invisible invis-specs)
 753       (overlay-put headers-overlay 'priority 10))
 754     (overlay-put (make-overlay body-start body-end) 'invisible message-invis-spec)
 755
 756     ;; Save the properties for this message. Currently this saves the
 757     ;; entire message (augmented it with other stuff), which seems
 758     ;; like overkill. We might save a reduced subset (for example, not
 759     ;; the content).
 760     (notmuch-show-set-message-properties msg)
 761
 762     ;; Set header visibility.
 763     (notmuch-show-headers-visible msg notmuch-message-headers-visible)
 764
 765     ;; Message visibility depends on whether it matched the search
 766     ;; criteria.
 767     (notmuch-show-message-visible msg (plist-get msg :match))))
 768
 769 (defun notmuch-show-insert-tree (tree depth)
 770   "Insert the message tree TREE at depth DEPTH in the current thread."
 771   (let ((msg (car tree))
 772         (replies (cadr tree)))
 773     (notmuch-show-insert-msg msg depth)
 774     (notmuch-show-insert-thread replies (1+ depth))))
 775
 776 (defun notmuch-show-insert-thread (thread depth)
 777   "Insert the thread THREAD at depth DEPTH in the current forest."
 778   (mapc '(lambda (tree) (notmuch-show-insert-tree tree depth)) thread))
 779
 780 (defun notmuch-show-insert-forest (forest)
 781   "Insert the forest of threads FOREST."
 782   (mapc '(lambda (thread) (notmuch-show-insert-thread thread 0)) forest))
 783
 784 (defvar notmuch-show-thread-id nil)
 785 (make-variable-buffer-local 'notmuch-show-thread-id)
 786 (defvar notmuch-show-parent-buffer nil)
 787 (make-variable-buffer-local 'notmuch-show-parent-buffer)
 788 (defvar notmuch-show-query-context nil)
 789 (make-variable-buffer-local 'notmuch-show-query-context)
 790 (defvar notmuch-show-buffer-name nil)
 791 (make-variable-buffer-local 'notmuch-show-buffer-name)
 792
 793 (defun notmuch-show-buttonise-links (start end)
 794   "Buttonise URLs and mail addresses between START and END.
 795
 796 This also turns id:\"<message id>\"-parts into buttons for
 797 a corresponding notmuch search."
 798   (goto-address-fontify-region start end)
 799   (save-excursion
 800     (goto-char start)
 801     (while (re-search-forward "id:\\(\"?\\)[^[:space:]\"]+\\1" end t)
 802       ;; remove the overlay created by goto-address-mode
 803       (remove-overlays (match-beginning 0) (match-end 0) 'goto-address t)
 804       (make-text-button (match-beginning 0) (match-end 0)
 805                         'action `(lambda (arg)
 806                                    (notmuch-search ,(match-string-no-properties 0)))
 807                         'follow-link t
 808                         'help-echo "Mouse-1, RET: search for this message"
 809                         'face goto-address-mail-face))))
 810
 811 ;;;###autoload
 812 (defun notmuch-show (thread-id &optional parent-buffer query-context buffer-name crypto-switch)
 813   "Run \"notmuch show\" with the given thread ID and display results.
 814
 815 The optional PARENT-BUFFER is the notmuch-search buffer from
 816 which this notmuch-show command was executed, (so that the
 817 next thread from that buffer can be show when done with this
 818 one).
 819
 820 The optional QUERY-CONTEXT is a notmuch search term. Only
 821 messages from the thread matching this search term are shown if
 822 non-nil.
 823
 824 The optional BUFFER-NAME provides the name of the buffer in
 825 which the message thread is shown. If it is nil (which occurs
 826 when the command is called interactively) the argument to the
 827 function is used. "
 828   (interactive "sNotmuch show: ")
 829   (let* ((buffer-name (generate-new-buffer-name
 830                        (or buffer-name
 831                            (concat "*notmuch-" thread-id "*"))))
 832          (buffer (get-buffer-create buffer-name))
 833          (process-crypto (if crypto-switch
 834                              (not notmuch-crypto-process-mime)
 835                            notmuch-crypto-process-mime))
 836          (inhibit-read-only t))
 837     (switch-to-buffer buffer)
 838     (notmuch-show-mode)
 839
 840     (setq notmuch-show-thread-id thread-id)
 841     (setq notmuch-show-parent-buffer parent-buffer)
 842     (setq notmuch-show-query-context query-context)
 843     (setq notmuch-show-buffer-name buffer-name)
 844     (setq notmuch-show-process-crypto process-crypto)
 845
 846     (erase-buffer)
 847     (goto-char (point-min))
 848     (save-excursion
 849       (let* ((basic-args (list thread-id))
 850              (args (if query-context
 851                        (append (list "\'") basic-args (list "and (" query-context ")\'"))
 852                      (append (list "\'") basic-args (list "\'")))))
 853         (notmuch-show-insert-forest (notmuch-query-get-threads args))
 854         ;; If the query context reduced the results to nothing, run
 855         ;; the basic query.
 856         (when (and (eq (buffer-size) 0)
 857                    query-context)
 858           (notmuch-show-insert-forest
 859            (notmuch-query-get-threads basic-args))))
 860
 861       (jit-lock-register #'notmuch-show-buttonise-links)
 862
 863       ;; Act on visual lines rather than logical lines.
 864       (visual-line-mode t)
 865
 866       (run-hooks 'notmuch-show-hook))
 867
 868     ;; Move straight to the first open message
 869     (if (not (notmuch-show-message-visible-p))
 870         (notmuch-show-next-open-message))
 871
 872     ;; Set the header line to the subject of the first open message.
 873     (setq header-line-format (notmuch-show-strip-re (notmuch-show-get-subject)))
 874
 875     (notmuch-show-mark-read)))
 876
 877 (defun notmuch-show-refresh-view (&optional crypto-switch)
 878   "Refresh the current view (with crypto switch if prefix given).
 879
 880 Kills the current buffer and reruns notmuch show with the same
 881 thread id.  If a prefix is given, the current thread is
 882 redisplayed with the crypto switch activated, which switch the
 883 logic of the notmuch-crypto-process-mime customization variable."
 884   (interactive "P")
 885   (let ((thread-id notmuch-show-thread-id)
 886         (parent-buffer notmuch-show-parent-buffer)
 887         (query-context notmuch-show-query-context)
 888         (buffer-name notmuch-show-buffer-name))
 889     (notmuch-kill-this-buffer)
 890     (notmuch-show thread-id parent-buffer query-context buffer-name crypto-switch)))
 891
 892 (defvar notmuch-show-stash-map
 893   (let ((map (make-sparse-keymap)))
 894     (define-key map "c" 'notmuch-show-stash-cc)
 895     (define-key map "d" 'notmuch-show-stash-date)
 896     (define-key map "F" 'notmuch-show-stash-filename)
 897     (define-key map "f" 'notmuch-show-stash-from)
 898     (define-key map "i" 'notmuch-show-stash-message-id)
 899     (define-key map "s" 'notmuch-show-stash-subject)
 900     (define-key map "T" 'notmuch-show-stash-tags)
 901     (define-key map "t" 'notmuch-show-stash-to)
 902     map)
 903   "Submap for stash commands")
 904 (fset 'notmuch-show-stash-map notmuch-show-stash-map)
 905
 906 (defvar notmuch-show-mode-map
 907       (let ((map (make-sparse-keymap)))
 908         (define-key map "?" 'notmuch-help)
 909         (define-key map "q" 'notmuch-kill-this-buffer)
 910         (define-key map (kbd "<C-tab>") 'widget-backward)
 911         (define-key map (kbd "M-TAB") 'notmuch-show-previous-button)
 912         (define-key map (kbd "<backtab>") 'notmuch-show-previous-button)
 913         (define-key map (kbd "TAB") 'notmuch-show-next-button)
 914         (define-key map "s" 'notmuch-search)
 915         (define-key map "m" 'notmuch-mua-new-mail)
 916         (define-key map "f" 'notmuch-show-forward-message)
 917         (define-key map "r" 'notmuch-show-reply)
 918         (define-key map "|" 'notmuch-show-pipe-message)
 919         (define-key map "w" 'notmuch-show-save-attachments)
 920         (define-key map "V" 'notmuch-show-view-raw-message)
 921         (define-key map "v" 'notmuch-show-view-all-mime-parts)
 922         (define-key map "c" 'notmuch-show-stash-map)
 923         (define-key map "=" 'notmuch-show-refresh-view)
 924         (define-key map "h" 'notmuch-show-toggle-headers)
 925         (define-key map "-" 'notmuch-show-remove-tag)
 926         (define-key map "+" 'notmuch-show-add-tag)
 927         (define-key map "x" 'notmuch-show-archive-thread-then-exit)
 928         (define-key map "a" 'notmuch-show-archive-thread)
 929         (define-key map "N" 'notmuch-show-next-message)
 930         (define-key map "P" 'notmuch-show-previous-message)
 931         (define-key map "n" 'notmuch-show-next-open-message)
 932         (define-key map "p" 'notmuch-show-previous-open-message)
 933         (define-key map (kbd "DEL") 'notmuch-show-rewind)
 934         (define-key map " " 'notmuch-show-advance-and-archive)
 935         (define-key map (kbd "M-RET") 'notmuch-show-open-or-close-all)
 936         (define-key map (kbd "RET") 'notmuch-show-toggle-message)
 937         map)
 938       "Keymap for \"notmuch show\" buffers.")
 939 (fset 'notmuch-show-mode-map notmuch-show-mode-map)
 940
 941 (defun notmuch-show-mode ()
 942   "Major mode for viewing a thread with notmuch.
 943
 944 This buffer contains the results of the \"notmuch show\" command
 945 for displaying a single thread of email from your email archives.
 946
 947 By default, various components of email messages, (citations,
 948 signatures, already-read messages), are hidden. You can make
 949 these parts visible by clicking with the mouse button or by
 950 pressing RET after positioning the cursor on a hidden part, (for
 951 which \\[notmuch-show-next-button] and \\[notmuch-show-previous-button] are helpful).
 952
 953 Reading the thread sequentially is well-supported by pressing
 954 \\[notmuch-show-advance-and-archive]. This will scroll the current message (if necessary), advance
 955 to the next message, or advance to the next thread (if already on
 956 the last message of a thread).
 957
 958 Other commands are available to read or manipulate the thread
 959 more selectively, (such as '\\[notmuch-show-next-message]' and '\\[notmuch-show-previous-message]' to advance to messages
 960 without removing any tags, and '\\[notmuch-show-archive-thread]' to archive an entire thread
 961 without scrolling through with \\[notmuch-show-advance-and-archive]).
 962
 963 You can add or remove arbitrary tags from the current message with
 964 '\\[notmuch-show-add-tag]' or '\\[notmuch-show-remove-tag]'.
 965
 966 All currently available key bindings:
 967
 968 \\{notmuch-show-mode-map}"
 969   (interactive)
 970   (kill-all-local-variables)
 971   (use-local-map notmuch-show-mode-map)
 972   (setq major-mode 'notmuch-show-mode
 973         mode-name "notmuch-show")
 974   (setq buffer-read-only t))
 975
 976 (defun notmuch-show-move-to-message-top ()
 977   (goto-char (notmuch-show-message-top)))
 978
 979 (defun notmuch-show-move-to-message-bottom ()
 980   (goto-char (notmuch-show-message-bottom)))
 981
 982 (defun notmuch-show-message-adjust ()
 983   (recenter 0))
 984
 985 ;; Movement related functions.
 986
 987 ;; There's some strangeness here where a text property applied to a
 988 ;; region a->b is not found when point is at b. We walk backwards
 989 ;; until finding the property.
 990 (defun notmuch-show-message-extent ()
 991   (let (r)
 992     (save-excursion
 993       (while (not (setq r (get-text-property (point) :notmuch-message-extent)))
 994         (backward-char)))
 995     r))
 996
 997 (defun notmuch-show-message-top ()
 998   (car (notmuch-show-message-extent)))
 999
1000 (defun notmuch-show-message-bottom ()
1001   (cdr (notmuch-show-message-extent)))
1002
1003 (defun notmuch-show-goto-message-next ()
1004   (let ((start (point)))
1005     (notmuch-show-move-to-message-bottom)
1006     (if (not (eobp))
1007         t
1008       (goto-char start)
1009       nil)))
1010
1011 (defun notmuch-show-goto-message-previous ()
1012   (notmuch-show-move-to-message-top)
1013   (if (bobp)
1014       nil
1015     (backward-char)
1016     (notmuch-show-move-to-message-top)
1017     t))
1018
1019 ;; Functions relating to the visibility of messages and their
1020 ;; components.
1021
1022 (defun notmuch-show-element-visible (props visible-p spec-property)
1023   (let ((spec (plist-get props spec-property)))
1024     (if visible-p
1025         (remove-from-invisibility-spec spec)
1026       (add-to-invisibility-spec spec))))
1027
1028 (defun notmuch-show-message-visible (props visible-p)
1029   (notmuch-show-element-visible props visible-p :message-invis-spec)
1030   (notmuch-show-set-prop :message-visible visible-p props))
1031
1032 (defun notmuch-show-headers-visible (props visible-p)
1033   (notmuch-show-element-visible props visible-p :headers-invis-spec)
1034   (notmuch-show-set-prop :headers-visible visible-p props))
1035
1036 ;; Functions for setting and getting attributes of the current
1037 ;; message.
1038
1039 (defun notmuch-show-set-message-properties (props)
1040   (save-excursion
1041     (notmuch-show-move-to-message-top)
1042     (put-text-property (point) (+ (point) 1) :notmuch-message-properties props)))
1043
1044 (defun notmuch-show-get-message-properties ()
1045   (save-excursion
1046     (notmuch-show-move-to-message-top)
1047     (get-text-property (point) :notmuch-message-properties)))
1048
1049 (defun notmuch-show-set-prop (prop val &optional props)
1050   (let ((inhibit-read-only t)
1051         (props (or props
1052                    (notmuch-show-get-message-properties))))
1053     (plist-put props prop val)
1054     (notmuch-show-set-message-properties props)))
1055
1056 (defun notmuch-show-get-prop (prop &optional props)
1057   (let ((props (or props
1058                    (notmuch-show-get-message-properties))))
1059     (plist-get props prop)))
1060
1061 (defun notmuch-show-get-message-id ()
1062   "Return the message id of the current message."
1063   (concat "id:\"" (notmuch-show-get-prop :id) "\""))
1064
1065 ;; dme: Would it make sense to use a macro for many of these?
1066
1067 (defun notmuch-show-get-filename ()
1068   "Return the filename of the current message."
1069   (notmuch-show-get-prop :filename))
1070
1071 (defun notmuch-show-get-header (header)
1072   "Return the named header of the current message, if any."
1073   (plist-get (notmuch-show-get-prop :headers) header))
1074
1075 (defun notmuch-show-get-cc ()
1076   (notmuch-show-get-header :Cc))
1077
1078 (defun notmuch-show-get-date ()
1079   (notmuch-show-get-header :Date))
1080
1081 (defun notmuch-show-get-from ()
1082   (notmuch-show-get-header :From))
1083
1084 (defun notmuch-show-get-subject ()
1085   (notmuch-show-get-header :Subject))
1086
1087 (defun notmuch-show-get-to ()
1088   (notmuch-show-get-header :To))
1089
1090 (defun notmuch-show-set-tags (tags)
1091   "Set the tags of the current message."
1092   (notmuch-show-set-prop :tags tags)
1093   (notmuch-show-update-tags tags))
1094
1095 (defun notmuch-show-get-tags ()
1096   "Return the tags of the current message."
1097   (notmuch-show-get-prop :tags))
1098
1099 (defun notmuch-show-message-visible-p ()
1100   "Is the current message visible?"
1101   (notmuch-show-get-prop :message-visible))
1102
1103 (defun notmuch-show-headers-visible-p ()
1104   "Are the headers of the current message visible?"
1105   (notmuch-show-get-prop :headers-visible))
1106
1107 (defun notmuch-show-mark-read ()
1108   "Mark the current message as read."
1109   (notmuch-show-remove-tag "unread"))
1110
1111 ;; Functions for getting attributes of several messages in the current
1112 ;; thread.
1113
1114 (defun notmuch-show-get-message-ids-for-open-messages ()
1115   "Return a list of all message IDs for open messages in the current thread."
1116   (save-excursion
1117     (let (message-ids done)
1118       (goto-char (point-min))
1119       (while (not done)
1120         (if (notmuch-show-message-visible-p)
1121             (setq message-ids (append message-ids (list (notmuch-show-get-message-id)))))
1122         (setq done (not (notmuch-show-goto-message-next)))
1123         )
1124       message-ids
1125       )))
1126
1127 ;; Commands typically bound to keys.
1128
1129 (defun notmuch-show-advance-and-archive ()
1130   "Advance through thread and archive.
1131
1132 This command is intended to be one of the simplest ways to
1133 process a thread of email. It does the following:
1134
1135 If the current message in the thread is not yet fully visible,
1136 scroll by a near screenful to read more of the message.
1137
1138 Otherwise, (the end of the current message is already within the
1139 current window), advance to the next open message.
1140
1141 Finally, if there is no further message to advance to, and this
1142 last message is already read, then archive the entire current
1143 thread, (remove the \"inbox\" tag from each message). Also kill
1144 this buffer, and display the next thread from the search from
1145 which this thread was originally shown."
1146   (interactive)
1147   (let* ((end-of-this-message (notmuch-show-message-bottom))
1148          (visible-end-of-this-message (1- end-of-this-message)))
1149     (while (invisible-p visible-end-of-this-message)
1150       (setq visible-end-of-this-message
1151             (previous-single-char-property-change visible-end-of-this-message
1152                                                   'invisible)))
1153     (cond
1154      ;; Ideally we would test `end-of-this-message' against the result
1155      ;; of `window-end', but that doesn't account for the fact that
1156      ;; the end of the message might be hidden.
1157      ((and visible-end-of-this-message
1158            (> visible-end-of-this-message (window-end)))
1159       ;; The bottom of this message is not visible - scroll.
1160       (scroll-up nil))
1161
1162      ((not (= end-of-this-message (point-max)))
1163       ;; This is not the last message - move to the next visible one.
1164       (notmuch-show-next-open-message))
1165
1166      (t
1167       ;; This is the last message - archive the thread.
1168       (notmuch-show-archive-thread)))))
1169
1170 (defun notmuch-show-rewind ()
1171   "Backup through the thread, (reverse scrolling compared to \\[notmuch-show-advance-and-archive]).
1172
1173 Specifically, if the beginning of the previous email is fewer
1174 than `window-height' lines from the current point, move to it
1175 just like `notmuch-show-previous-message'.
1176
1177 Otherwise, just scroll down a screenful of the current message.
1178
1179 This command does not modify any message tags, (it does not undo
1180 any effects from previous calls to
1181 `notmuch-show-advance-and-archive'."
1182   (interactive)
1183   (let ((start-of-message (notmuch-show-message-top))
1184         (start-of-window (window-start)))
1185     (cond
1186       ;; Either this message is properly aligned with the start of the
1187       ;; window or the start of this message is not visible on the
1188       ;; screen - scroll.
1189      ((or (= start-of-message start-of-window)
1190           (< start-of-message start-of-window))
1191       (scroll-down)
1192       ;; If a small number of lines from the previous message are
1193       ;; visible, realign so that the top of the current message is at
1194       ;; the top of the screen.
1195       (if (<= (count-screen-lines (window-start) start-of-message)
1196               next-screen-context-lines)
1197           (progn
1198             (goto-char (notmuch-show-message-top))
1199             (notmuch-show-message-adjust)))
1200       ;; Move to the top left of the window.
1201       (goto-char (window-start)))
1202      (t
1203       ;; Move to the previous message.
1204       (notmuch-show-previous-message)))))
1205
1206 (defun notmuch-show-reply (&optional prompt-for-sender)
1207   "Reply to the current message."
1208   (interactive "P")
1209   (notmuch-mua-new-reply (notmuch-show-get-message-id) prompt-for-sender))
1210
1211 (defun notmuch-show-forward-message (&optional prompt-for-sender)
1212   "Forward the current message."
1213   (interactive "P")
1214   (with-current-notmuch-show-message
1215    (notmuch-mua-new-forward-message prompt-for-sender)))
1216
1217 (defun notmuch-show-next-message ()
1218   "Show the next message."
1219   (interactive)
1220   (if (notmuch-show-goto-message-next)
1221       (progn
1222         (notmuch-show-mark-read)
1223         (notmuch-show-message-adjust))
1224     (goto-char (point-max))))
1225
1226 (defun notmuch-show-previous-message ()
1227   "Show the previous message."
1228   (interactive)
1229   (notmuch-show-goto-message-previous)
1230   (notmuch-show-mark-read)
1231   (notmuch-show-message-adjust))
1232
1233 (defun notmuch-show-next-open-message ()
1234   "Show the next message."
1235   (interactive)
1236   (let (r)
1237     (while (and (setq r (notmuch-show-goto-message-next))
1238                 (not (notmuch-show-message-visible-p))))
1239     (if r
1240         (progn
1241           (notmuch-show-mark-read)
1242           (notmuch-show-message-adjust))
1243       (goto-char (point-max)))))
1244
1245 (defun notmuch-show-previous-open-message ()
1246   "Show the previous message."
1247   (interactive)
1248   (while (and (notmuch-show-goto-message-previous)
1249               (not (notmuch-show-message-visible-p))))
1250   (notmuch-show-mark-read)
1251   (notmuch-show-message-adjust))
1252
1253 (defun notmuch-show-view-raw-message ()
1254   "View the file holding the current message."
1255   (interactive)
1256   (let* ((id (notmuch-show-get-message-id))
1257          (buf (get-buffer-create (concat "*notmuch-raw-" id "*"))))
1258     (call-process notmuch-command nil buf nil "show" "--format=raw" id)
1259     (switch-to-buffer buf)
1260     (goto-char (point-min))
1261     (set-buffer-modified-p nil)
1262     (view-buffer buf 'kill-buffer-if-not-modified)))
1263
1264 (defun notmuch-show-pipe-message (entire-thread command)
1265   "Pipe the contents of the current message (or thread) to the given command.
1266
1267 The given command will be executed with the raw contents of the
1268 current email message as stdin. Anything printed by the command
1269 to stdout or stderr will appear in the *notmuch-pipe* buffer.
1270
1271 When invoked with a prefix argument, the command will receive all
1272 open messages in the current thread (formatted as an mbox) rather
1273 than only the current message."
1274   (interactive "P\nsPipe message to command: ")
1275   (let (shell-command)
1276     (if entire-thread
1277         (setq shell-command
1278               (concat notmuch-command " show --format=mbox "
1279                       (shell-quote-argument
1280                        (mapconcat 'identity (notmuch-show-get-message-ids-for-open-messages) " OR "))
1281                       " | " command))
1282       (setq shell-command
1283             (concat notmuch-command " show --format=raw "
1284                     (shell-quote-argument (notmuch-show-get-message-id)) " | " command)))
1285     (let ((buf (get-buffer-create (concat "*notmuch-pipe*"))))
1286       (with-current-buffer buf
1287         (setq buffer-read-only nil)
1288         (erase-buffer)
1289         (let ((exit-code (call-process-shell-command shell-command nil buf)))
1290           (goto-char (point-max))
1291           (set-buffer-modified-p nil)
1292           (setq buffer-read-only t)
1293           (unless (zerop exit-code)
1294             (switch-to-buffer-other-window buf)
1295             (message (format "Command '%s' exited abnormally with code %d"
1296                              shell-command exit-code))))))))
1297
1298 (defun notmuch-show-add-tags-worker (current-tags add-tags)
1299   "Add to `current-tags' with any tags from `add-tags' not
1300 currently present and return the result."
1301   (let ((result-tags (copy-sequence current-tags)))
1302     (mapc (lambda (add-tag)
1303             (unless (member add-tag current-tags)
1304               (setq result-tags (push add-tag result-tags))))
1305             add-tags)
1306     (sort result-tags 'string<)))
1307
1308 (defun notmuch-show-del-tags-worker (current-tags del-tags)
1309   "Remove any tags in `del-tags' from `current-tags' and return
1310 the result."
1311   (let ((result-tags (copy-sequence current-tags)))
1312     (mapc (lambda (del-tag)
1313             (setq result-tags (delete del-tag result-tags)))
1314           del-tags)
1315     result-tags))
1316
1317 (defun notmuch-show-add-tag (&rest toadd)
1318   "Add a tag to the current message."
1319   (interactive
1320    (list (notmuch-select-tag-with-completion "Tag to add: ")))
1321
1322   (let* ((current-tags (notmuch-show-get-tags))
1323          (new-tags (notmuch-show-add-tags-worker current-tags toadd)))
1324
1325     (unless (equal current-tags new-tags)
1326       (apply 'notmuch-tag (notmuch-show-get-message-id)
1327              (mapcar (lambda (s) (concat "+" s)) toadd))
1328       (notmuch-show-set-tags new-tags))))
1329
1330 (defun notmuch-show-remove-tag (&rest toremove)
1331   "Remove a tag from the current message."
1332   (interactive
1333    (list (notmuch-select-tag-with-completion
1334           "Tag to remove: " (notmuch-show-get-message-id))))
1335
1336   (let* ((current-tags (notmuch-show-get-tags))
1337          (new-tags (notmuch-show-del-tags-worker current-tags toremove)))
1338
1339     (unless (equal current-tags new-tags)
1340       (apply 'notmuch-tag (notmuch-show-get-message-id)
1341              (mapcar (lambda (s) (concat "-" s)) toremove))
1342       (notmuch-show-set-tags new-tags))))
1343
1344 (defun notmuch-show-toggle-headers ()
1345   "Toggle the visibility of the current message headers."
1346   (interactive)
1347   (let ((props (notmuch-show-get-message-properties)))
1348     (notmuch-show-headers-visible
1349      props
1350      (not (plist-get props :headers-visible))))
1351   (force-window-update))
1352
1353 (defun notmuch-show-toggle-message ()
1354   "Toggle the visibility of the current message."
1355   (interactive)
1356   (let ((props (notmuch-show-get-message-properties)))
1357     (notmuch-show-message-visible
1358      props
1359      (not (plist-get props :message-visible))))
1360   (force-window-update))
1361
1362 (defun notmuch-show-open-or-close-all ()
1363   "Set the visibility all of the messages in the current thread.
1364 By default make all of the messages visible. With a prefix
1365 argument, hide all of the messages."
1366   (interactive)
1367   (save-excursion
1368     (goto-char (point-min))
1369     (loop do (notmuch-show-message-visible (notmuch-show-get-message-properties)
1370                                            (not current-prefix-arg))
1371           until (not (notmuch-show-goto-message-next))))
1372   (force-window-update))
1373
1374 (defun notmuch-show-next-button ()
1375   "Advance point to the next button in the buffer."
1376   (interactive)
1377   (forward-button 1))
1378
1379 (defun notmuch-show-previous-button ()
1380   "Move point back to the previous button in the buffer."
1381   (interactive)
1382   (backward-button 1))
1383
1384 (defun notmuch-show-archive-thread-internal (show-next)
1385   ;; Remove the tag from the current set of messages.
1386   (goto-char (point-min))
1387   (loop do (notmuch-show-remove-tag "inbox")
1388         until (not (notmuch-show-goto-message-next)))
1389   ;; Move to the next item in the search results, if any.
1390   (let ((parent-buffer notmuch-show-parent-buffer))
1391     (notmuch-kill-this-buffer)
1392     (if parent-buffer
1393         (progn
1394           (switch-to-buffer parent-buffer)
1395           (forward-line)
1396           (if show-next
1397               (notmuch-search-show-thread))))))
1398
1399 (defun notmuch-show-archive-thread ()
1400   "Archive each message in thread, then show next thread from search.
1401
1402 Archive each message currently shown by removing the \"inbox\"
1403 tag from each. Then kill this buffer and show the next thread
1404 from the search from which this thread was originally shown.
1405
1406 Note: This command is safe from any race condition of new messages
1407 being delivered to the same thread. It does not archive the
1408 entire thread, but only the messages shown in the current
1409 buffer."
1410   (interactive)
1411   (notmuch-show-archive-thread-internal t))
1412
1413 (defun notmuch-show-archive-thread-then-exit ()
1414   "Archive each message in thread, then exit back to search results."
1415   (interactive)
1416   (notmuch-show-archive-thread-internal nil))
1417
1418 (defun notmuch-show-stash-cc ()
1419   "Copy CC field of current message to kill-ring."
1420   (interactive)
1421   (notmuch-common-do-stash (notmuch-show-get-cc)))
1422
1423 (defun notmuch-show-stash-date ()
1424   "Copy date of current message to kill-ring."
1425   (interactive)
1426   (notmuch-common-do-stash (notmuch-show-get-date)))
1427
1428 (defun notmuch-show-stash-filename ()
1429   "Copy filename of current message to kill-ring."
1430   (interactive)
1431   (notmuch-common-do-stash (notmuch-show-get-filename)))
1432
1433 (defun notmuch-show-stash-from ()
1434   "Copy From address of current message to kill-ring."
1435   (interactive)
1436   (notmuch-common-do-stash (notmuch-show-get-from)))
1437
1438 (defun notmuch-show-stash-message-id ()
1439   "Copy message ID of current message to kill-ring."
1440   (interactive)
1441   (notmuch-common-do-stash (notmuch-show-get-message-id)))
1442
1443 (defun notmuch-show-stash-subject ()
1444   "Copy Subject field of current message to kill-ring."
1445   (interactive)
1446   (notmuch-common-do-stash (notmuch-show-get-subject)))
1447
1448 (defun notmuch-show-stash-tags ()
1449   "Copy tags of current message to kill-ring as a comma separated list."
1450   (interactive)
1451   (notmuch-common-do-stash (mapconcat 'identity (notmuch-show-get-tags) ",")))
1452
1453 (defun notmuch-show-stash-to ()
1454   "Copy To address of current message to kill-ring."
1455   (interactive)
1456   (notmuch-common-do-stash (notmuch-show-get-to)))
1457
1458 ;; Commands typically bound to buttons.
1459
1460 (defun notmuch-show-part-button-action (button)
1461   (let ((nth (button-get button :notmuch-part)))
1462     (if nth
1463         (notmuch-show-save-part (notmuch-show-get-message-id) nth
1464                                 (button-get button :notmuch-filename))
1465       (message "Not a valid part (is it a fake part?)."))))
1466
1467 ;;
1468
1469 (provide 'notmuch-show)