exit lingering gpg agents at the end of relevant tests
[notmuch] / emacs / notmuch-show.el
1 ;;; notmuch-show.el --- displaying notmuch forests.
2 ;;
3 ;; Copyright © Carl Worth
4 ;; Copyright © David Edmondson
5 ;;
6 ;; This file is part of Notmuch.
7 ;;
8 ;; Notmuch is free software: you can redistribute it and/or modify it
9 ;; under the terms of the GNU General Public License as published by
10 ;; the Free Software Foundation, either version 3 of the License, or
11 ;; (at your option) any later version.
12 ;;
13 ;; Notmuch is distributed in the hope that it will be useful, but
14 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
16 ;; General Public License for more details.
17 ;;
18 ;; You should have received a copy of the GNU General Public License
19 ;; along with Notmuch.  If not, see <https://www.gnu.org/licenses/>.
20 ;;
21 ;; Authors: Carl Worth <cworth@cworth.org>
22 ;;          David Edmondson <dme@dme.org>
23
24 ;;; Code:
25
26 (eval-when-compile (require 'cl))
27 (require 'mm-view)
28 (require 'message)
29 (require 'mm-decode)
30 (require 'mailcap)
31 (require 'icalendar)
32 (require 'goto-addr)
33
34 (require 'notmuch-lib)
35 (require 'notmuch-tag)
36 (require 'notmuch-query)
37 (require 'notmuch-wash)
38 (require 'notmuch-mua)
39 (require 'notmuch-crypto)
40 (require 'notmuch-print)
41 (require 'notmuch-draft)
42
43 (declare-function notmuch-call-notmuch-process "notmuch" (&rest args))
44 (declare-function notmuch-search-next-thread "notmuch" nil)
45 (declare-function notmuch-search-previous-thread "notmuch" nil)
46 (declare-function notmuch-search-show-thread "notmuch" nil)
47 (declare-function notmuch-foreach-mime-part "notmuch" (function mm-handle))
48 (declare-function notmuch-count-attachments "notmuch" (mm-handle))
49 (declare-function notmuch-save-attachments "notmuch" (mm-handle &optional queryp))
50 (declare-function notmuch-tree "notmuch-tree"
51                   (&optional query query-context target buffer-name open-target))
52 (declare-function notmuch-tree-get-message-properties "notmuch-tree" nil)
53 (declare-function notmuch-read-query "notmuch" (prompt))
54 (declare-function notmuch-draft-resume "notmuch-draft" (id))
55
56 (defcustom notmuch-message-headers '("Subject" "To" "Cc" "Date")
57   "Headers that should be shown in a message, in this order.
58
59 For an open message, all of these headers will be made visible
60 according to `notmuch-message-headers-visible' or can be toggled
61 with `notmuch-show-toggle-visibility-headers'. For a closed message,
62 only the first header in the list will be visible."
63   :type '(repeat string)
64   :group 'notmuch-show)
65
66 (defcustom notmuch-message-headers-visible t
67   "Should the headers be visible by default?
68
69 If this value is non-nil, then all of the headers defined in
70 `notmuch-message-headers' will be visible by default in the display
71 of each message. Otherwise, these headers will be hidden and
72 `notmuch-show-toggle-visibility-headers' can be used to make them
73 visible for any given message."
74   :type 'boolean
75   :group 'notmuch-show)
76
77 (defcustom notmuch-show-relative-dates t
78   "Display relative dates in the message summary line."
79   :type 'boolean
80   :group 'notmuch-show)
81
82 (defvar notmuch-show-markup-headers-hook '(notmuch-show-colour-headers)
83   "A list of functions called to decorate the headers listed in
84 `notmuch-message-headers'.")
85
86 (defcustom notmuch-show-hook '(notmuch-show-turn-on-visual-line-mode)
87   "Functions called after populating a `notmuch-show' buffer."
88   :type 'hook
89   :options '(notmuch-show-turn-on-visual-line-mode)
90   :group 'notmuch-show
91   :group 'notmuch-hooks)
92
93 (defcustom notmuch-show-insert-text/plain-hook '(notmuch-wash-wrap-long-lines
94                                                  notmuch-wash-tidy-citations
95                                                  notmuch-wash-elide-blank-lines
96                                                  notmuch-wash-excerpt-citations)
97   "Functions used to improve the display of text/plain parts."
98   :type 'hook
99   :options '(notmuch-wash-convert-inline-patch-to-part
100              notmuch-wash-wrap-long-lines
101              notmuch-wash-tidy-citations
102              notmuch-wash-elide-blank-lines
103              notmuch-wash-excerpt-citations)
104   :group 'notmuch-show
105   :group 'notmuch-hooks)
106
107 (defcustom notmuch-show-max-text-part-size 100000
108   "Maximum size of a text part to be shown by default in characters.
109
110 Set to 0 to show the part regardless of size."
111   :type 'integer
112   :group 'notmuch-show)
113
114 ;; Mostly useful for debugging.
115 (defcustom notmuch-show-all-multipart/alternative-parts nil
116   "Should all parts of multipart/alternative parts be shown?"
117   :type 'boolean
118   :group 'notmuch-show)
119
120 (defcustom notmuch-show-indent-messages-width 1
121   "Width of message indentation in threads.
122
123 Messages are shown indented according to their depth in a thread.
124 This variable determines the width of this indentation measured
125 in number of blanks.  Defaults to `1', choose `0' to disable
126 indentation."
127   :type 'integer
128   :group 'notmuch-show)
129
130 (defcustom notmuch-show-indent-multipart nil
131   "Should the sub-parts of a multipart/* part be indented?"
132   ;; dme: Not sure which is a good default.
133   :type 'boolean
134   :group 'notmuch-show)
135
136 (defcustom notmuch-show-part-button-default-action 'notmuch-show-save-part
137   "Default part header button action (on ENTER or mouse click)."
138   :group 'notmuch-show
139   :type '(choice (const :tag "Save part"
140                         notmuch-show-save-part)
141                  (const :tag "View part"
142                         notmuch-show-view-part)
143                  (const :tag "View interactively"
144                         notmuch-show-interactively-view-part)))
145
146 (defcustom notmuch-show-only-matching-messages nil
147   "Only matching messages are shown by default."
148   :type 'boolean
149   :group 'notmuch-show)
150
151 ;; By default, block all external images to prevent privacy leaks and
152 ;; potential attacks.
153 (defcustom notmuch-show-text/html-blocked-images "."
154   "Remote images that have URLs matching this regexp will be blocked."
155   :type '(choice (const nil) regexp)
156   :group 'notmuch-show)
157
158 (defvar notmuch-show-thread-id nil)
159 (make-variable-buffer-local 'notmuch-show-thread-id)
160
161 (defvar notmuch-show-parent-buffer nil)
162 (make-variable-buffer-local 'notmuch-show-parent-buffer)
163
164 (defvar notmuch-show-query-context nil)
165 (make-variable-buffer-local 'notmuch-show-query-context)
166
167 (defvar notmuch-show-process-crypto nil)
168 (make-variable-buffer-local 'notmuch-show-process-crypto)
169
170 (defvar notmuch-show-elide-non-matching-messages nil)
171 (make-variable-buffer-local 'notmuch-show-elide-non-matching-messages)
172
173 (defvar notmuch-show-indent-content t)
174 (make-variable-buffer-local 'notmuch-show-indent-content)
175
176 (defvar notmuch-show-attachment-debug nil
177   "If t log stdout and stderr from attachment handlers
178
179 When set to nil (the default) stdout and stderr from attachment
180 handlers is discarded. When set to t the stdout and stderr from
181 each attachment handler is logged in buffers with names beginning
182 \" *notmuch-part*\". This option requires emacs version at least
183 24.3 to work.")
184
185 (defcustom notmuch-show-stash-mlarchive-link-alist
186   '(("Gmane" . "http://mid.gmane.org/")
187     ("MARC" . "https://marc.info/?i=")
188     ("Mail Archive, The" . "https://mid.mail-archive.com/")
189     ("LKML" . "https://lkml.kernel.org/r/")
190     ;; FIXME: can these services be searched by `Message-Id' ?
191     ;; ("MarkMail" . "http://markmail.org/")
192     ;; ("Nabble" . "http://nabble.com/")
193     ;; ("opensubscriber" . "http://opensubscriber.com/")
194     )
195   "List of Mailing List Archives to use when stashing links.
196
197 This list is used for generating a Mailing List Archive reference
198 URI with the current message's Message-Id in
199 `notmuch-show-stash-mlarchive-link'.
200
201 If the cdr of the alist element is not a function, the cdr is
202 expected to contain a URI that is concatenated with the current
203 message's Message-Id to create a ML archive reference URI.
204
205 If the cdr is a function, the function is called with the
206 Message-Id as the argument, and the function is expected to
207 return the ML archive reference URI."
208   :type '(alist :key-type (string :tag "Name")
209                 :value-type (choice
210                              (string :tag "URL")
211                              (function :tag "Function returning the URL")))
212   :group 'notmuch-show)
213
214 (defcustom notmuch-show-stash-mlarchive-link-default "Gmane"
215   "Default Mailing List Archive to use when stashing links.
216
217 This is used when `notmuch-show-stash-mlarchive-link' isn't
218 provided with an MLA argument nor `completing-read' input."
219   :type `(choice
220           ,@(mapcar
221              (lambda (mla)
222                (list 'const :tag (car mla) :value (car mla)))
223              notmuch-show-stash-mlarchive-link-alist))
224   :group 'notmuch-show)
225
226 (defcustom notmuch-show-mark-read-tags '("-unread")
227   "List of tag changes to apply to a message when it is marked as read.
228
229 Tags starting with \"+\" (or not starting with either \"+\" or
230 \"-\") in the list will be added, and tags starting with \"-\"
231 will be removed from the message being marked as read.
232
233 For example, if you wanted to remove an \"unread\" tag and add a
234 \"read\" tag (which would make little sense), you would set:
235     (\"-unread\" \"+read\")"
236   :type '(repeat string)
237   :group 'notmuch-show)
238
239 (defcustom notmuch-show-mark-read-function #'notmuch-show-seen-current-message
240   "Function to control which messages are marked read.
241
242 The function should take two arguments START and END which will
243 be the start and end of the visible portion of the buffer and
244 should mark the appropriate messages read by applying
245 `notmuch-show-mark-read'. This function will be called after
246 every user interaction with notmuch."
247   :type 'function
248   :group 'notmuch-show)
249
250 (defmacro with-current-notmuch-show-message (&rest body)
251   "Evaluate body with current buffer set to the text of current message"
252   `(save-excursion
253      (let ((id (notmuch-show-get-message-id)))
254        (let ((buf (generate-new-buffer (concat "*notmuch-msg-" id "*"))))
255          (with-current-buffer buf
256            (let ((coding-system-for-read 'no-conversion))
257              (call-process notmuch-command nil t nil "show" "--format=raw" id))
258            ,@body)
259          (kill-buffer buf)))))
260
261 (defun notmuch-show-turn-on-visual-line-mode ()
262   "Enable Visual Line mode."
263   (visual-line-mode t))
264
265 ;; DEPRECATED in Notmuch 0.16 since we now have convenient part
266 ;; commands.  We'll keep the command around for a version or two in
267 ;; case people want to bind it themselves.
268 (defun notmuch-show-view-all-mime-parts ()
269   "Use external viewers to view all attachments from the current message."
270   (interactive)
271   (with-current-notmuch-show-message
272    ;; We override the mm-inline-media-tests to indicate which message
273    ;; parts are already sufficiently handled by the original
274    ;; presentation of the message in notmuch-show mode. These parts
275    ;; will be inserted directly into the temporary buffer of
276    ;; with-current-notmuch-show-message and silently discarded.
277    ;;
278    ;; Any MIME part not explicitly mentioned here will be handled by an
279    ;; external viewer as configured in the various mailcap files.
280    (let ((mm-inline-media-tests '(
281                                   ("text/.*" ignore identity)
282                                   ("application/pgp-signature" ignore identity)
283                                   ("multipart/alternative" ignore identity)
284                                   ("multipart/mixed" ignore identity)
285                                   ("multipart/related" ignore identity)
286                                  )))
287      (mm-display-parts (mm-dissect-buffer)))))
288
289 (defun notmuch-show-save-attachments ()
290   "Save all attachments from the current message."
291   (interactive)
292   (with-current-notmuch-show-message
293    (let ((mm-handle (mm-dissect-buffer)))
294      (notmuch-save-attachments
295       mm-handle (> (notmuch-count-attachments mm-handle) 1))))
296   (message "Done"))
297
298 (defun notmuch-show-with-message-as-text (fn)
299   "Apply FN to a text representation of the current message.
300
301 FN is called with one argument, the message properties. It should
302 operation on the contents of the current buffer."
303
304   ;; Remake the header to ensure that all information is available.
305   (let* ((to (notmuch-show-get-to))
306          (cc (notmuch-show-get-cc))
307          (from (notmuch-show-get-from))
308          (subject (notmuch-show-get-subject))
309          (date (notmuch-show-get-date))
310          (tags (notmuch-show-get-tags))
311          (depth (notmuch-show-get-depth))
312
313          (header (concat
314                   "Subject: " subject "\n"
315                   "To: " to "\n"
316                   (if (not (string= cc ""))
317                       (concat "Cc: " cc "\n")
318                     "")
319                   "From: " from "\n"
320                   "Date: " date "\n"
321                   (if tags
322                       (concat "Tags: "
323                               (mapconcat #'identity tags ", ") "\n")
324                     "")))
325          (all (buffer-substring (notmuch-show-message-top)
326                                 (notmuch-show-message-bottom)))
327
328          (props (notmuch-show-get-message-properties))
329          (indenting notmuch-show-indent-content))
330     (with-temp-buffer
331       (insert all)
332       (if indenting
333           (indent-rigidly (point-min) (point-max) (- depth)))
334       ;; Remove the original header.
335       (goto-char (point-min))
336       (re-search-forward "^$" (point-max) nil)
337       (delete-region (point-min) (point))
338       (insert header)
339       (funcall fn props))))
340
341 (defun notmuch-show-print-message ()
342   "Print the current message."
343   (interactive)
344   (notmuch-show-with-message-as-text 'notmuch-print-message))
345
346 (defun notmuch-show-fontify-header ()
347   (let ((face (cond
348                ((looking-at "[Tt]o:")
349                 'message-header-to)
350                ((looking-at "[Bb]?[Cc][Cc]:")
351                 'message-header-cc)
352                ((looking-at "[Ss]ubject:")
353                 'message-header-subject)
354                (t
355                 'message-header-other))))
356
357     (overlay-put (make-overlay (point) (re-search-forward ":"))
358                  'face 'message-header-name)
359     (overlay-put (make-overlay (point) (re-search-forward ".*$"))
360                  'face face)))
361
362 (defun notmuch-show-colour-headers ()
363   "Apply some colouring to the current headers."
364   (goto-char (point-min))
365   (while (looking-at "^[A-Za-z][-A-Za-z0-9]*:")
366     (notmuch-show-fontify-header)
367     (forward-line)))
368
369 (defun notmuch-show-spaces-n (n)
370   "Return a string comprised of `n' spaces."
371   (make-string n ? ))
372
373 (defun notmuch-show-update-tags (tags)
374   "Update the displayed tags of the current message."
375   (save-excursion
376     (goto-char (notmuch-show-message-top))
377     (if (re-search-forward "(\\([^()]*\\))$" (line-end-position) t)
378         (let ((inhibit-read-only t))
379           (replace-match (concat "("
380                                  (notmuch-tag-format-tags tags (notmuch-show-get-prop :orig-tags))
381                                  ")"))))))
382
383 (defun notmuch-clean-address (address)
384   "Try to clean a single email ADDRESS for display. Return a cons
385 cell of (AUTHOR_EMAIL AUTHOR_NAME). Return (ADDRESS nil) if
386 parsing fails."
387   (condition-case nil
388     (let (p-name p-address)
389       ;; It would be convenient to use `mail-header-parse-address',
390       ;; but that expects un-decoded mailbox parts, whereas our
391       ;; mailbox parts are already decoded (and hence may contain
392       ;; UTF-8). Given that notmuch should handle most of the awkward
393       ;; cases, some simple string deconstruction should be sufficient
394       ;; here.
395       (cond
396        ;; "User <user@dom.ain>" style.
397        ((string-match "\\(.*\\) <\\(.*\\)>" address)
398         (setq p-name (match-string 1 address)
399               p-address (match-string 2 address)))
400
401        ;; "<user@dom.ain>" style.
402        ((string-match "<\\(.*\\)>" address)
403         (setq p-address (match-string 1 address)))
404
405        ;; Everything else.
406        (t
407         (setq p-address address)))
408
409       (when p-name
410         ;; Remove elements of the mailbox part that are not relevant for
411         ;; display, even if they are required during transport:
412         ;;
413         ;; Backslashes.
414         (setq p-name (replace-regexp-in-string "\\\\" "" p-name))
415
416         ;; Outer single and double quotes, which might be nested.
417         (loop
418          with start-of-loop
419          do (setq start-of-loop p-name)
420
421          when (string-match "^\"\\(.*\\)\"$" p-name)
422          do (setq p-name (match-string 1 p-name))
423
424          when (string-match "^'\\(.*\\)'$" p-name)
425          do (setq p-name (match-string 1 p-name))
426
427          until (string= start-of-loop p-name)))
428
429       ;; If the address is 'foo@bar.com <foo@bar.com>' then show just
430       ;; 'foo@bar.com'.
431       (when (string= p-name p-address)
432         (setq p-name nil))
433
434       (cons p-address p-name))
435     (error (cons address nil))))
436
437 (defun notmuch-show-clean-address (address)
438   "Try to clean a single email ADDRESS for display.  Return
439 unchanged ADDRESS if parsing fails."
440   (let* ((clean-address (notmuch-clean-address address))
441          (p-address (car clean-address))
442          (p-name (cdr clean-address)))
443     ;; If no name, return just the address.
444     (if (not p-name)
445         p-address
446       ;; Otherwise format the name and address together.
447       (concat p-name " <" p-address ">"))))
448
449 (defun notmuch-show-insert-headerline (headers date tags depth)
450   "Insert a notmuch style headerline based on HEADERS for a
451 message at DEPTH in the current thread."
452   (let ((start (point)))
453     (insert (notmuch-show-spaces-n (* notmuch-show-indent-messages-width depth))
454             (notmuch-sanitize
455              (notmuch-show-clean-address (plist-get headers :From)))
456             " ("
457             date
458             ") ("
459             (notmuch-tag-format-tags tags tags)
460             ")\n")
461     (overlay-put (make-overlay start (point)) 'face 'notmuch-message-summary-face)))
462
463 (defun notmuch-show-insert-header (header header-value)
464   "Insert a single header."
465   (insert header ": " (notmuch-sanitize header-value) "\n"))
466
467 (defun notmuch-show-insert-headers (headers)
468   "Insert the headers of the current message."
469   (let ((start (point)))
470     (mapc (lambda (header)
471             (let* ((header-symbol (intern (concat ":" header)))
472                    (header-value (plist-get headers header-symbol)))
473               (if (and header-value
474                        (not (string-equal "" header-value)))
475                   (notmuch-show-insert-header header header-value))))
476           notmuch-message-headers)
477     (save-excursion
478       (save-restriction
479         (narrow-to-region start (point-max))
480         (run-hooks 'notmuch-show-markup-headers-hook)))))
481
482 (define-button-type 'notmuch-show-part-button-type
483   'action 'notmuch-show-part-button-default
484   'follow-link t
485   'face 'message-mml
486   :supertype 'notmuch-button-type)
487
488 (defun notmuch-show-insert-part-header (nth content-type declared-type &optional name comment)
489   (let ((button)
490         (base-label (concat (when name (concat name ": "))
491                             declared-type
492                             (unless (string-equal declared-type content-type)
493                               (concat " (as " content-type ")"))
494                             comment)))
495
496     (setq button
497           (insert-button
498            (concat "[ " base-label " ]")
499            :base-label base-label
500            :type 'notmuch-show-part-button-type
501            :notmuch-part-hidden nil))
502     (insert "\n")
503     ;; return button
504     button))
505
506 (defun notmuch-show-toggle-part-invisibility (&optional button)
507   (interactive)
508   (let ((button (or button (button-at (point)))))
509     (when button
510       (let ((overlay (button-get button 'overlay))
511             (lazy-part (button-get button :notmuch-lazy-part)))
512         ;; We have a part to toggle if there is an overlay or if there is a lazy part.
513         ;; If neither is present we cannot toggle the part so we just return nil.
514         (when (or overlay lazy-part)
515           (let* ((show (button-get button :notmuch-part-hidden))
516                  (new-start (button-start button))
517                  (button-label (button-get button :base-label))
518                  (old-point (point))
519                  (properties (text-properties-at (button-start button)))
520                  (inhibit-read-only t))
521             ;; Toggle the button itself.
522             (button-put button :notmuch-part-hidden (not show))
523             (goto-char new-start)
524             (insert "[ " button-label (if show " ]" " (hidden) ]"))
525             (set-text-properties new-start (point) properties)
526             (let ((old-end (button-end button)))
527               (move-overlay button new-start (point))
528               (delete-region (point) old-end))
529             (goto-char (min old-point (1- (button-end button))))
530             ;; Return nil if there is a lazy-part, it is empty, and we are
531             ;; trying to show it.  In all other cases return t.
532             (if lazy-part
533                 (when show
534                   (button-put button :notmuch-lazy-part nil)
535                   (notmuch-show-lazy-part lazy-part button))
536               ;; else there must be an overlay.
537               (overlay-put overlay 'invisible (not show))
538               t)))))))
539
540 ;; Part content ID handling
541
542 (defvar notmuch-show--cids nil
543   "Alist from raw content ID to (MSG PART).")
544 (make-variable-buffer-local 'notmuch-show--cids)
545
546 (defun notmuch-show--register-cids (msg part)
547   "Register content-IDs in PART and all of PART's sub-parts."
548   (let ((content-id (plist-get part :content-id)))
549     (when content-id
550       ;; Note that content-IDs are globally unique, except when they
551       ;; aren't: RFC 2046 section 5.1.4 permits children of a
552       ;; multipart/alternative to have the same content-ID, in which
553       ;; case the MUA is supposed to pick the best one it can render.
554       ;; We simply add the content-ID to the beginning of our alist;
555       ;; so if this happens, we'll take the last (and "best")
556       ;; alternative (even if we can't render it).
557       (push (list content-id msg part) notmuch-show--cids)))
558   ;; Recurse on sub-parts
559   (let ((ctype (notmuch-split-content-type
560                 (downcase (plist-get part :content-type)))))
561     (cond ((equal (first ctype) "multipart")
562            (mapc (apply-partially #'notmuch-show--register-cids msg)
563                  (plist-get part :content)))
564           ((equal ctype '("message" "rfc822"))
565            (notmuch-show--register-cids
566             msg
567             (first (plist-get (first (plist-get part :content)) :body)))))))
568
569 (defun notmuch-show--get-cid-content (cid)
570   "Return a list (CID-content content-type) or nil.
571
572 This will only find parts from messages that have been inserted
573 into the current buffer.  CID must be a raw content ID, without
574 enclosing angle brackets, a cid: prefix, or URL encoding.  This
575 will return nil if the CID is unknown or cannot be retrieved."
576   (let ((descriptor (cdr (assoc cid notmuch-show--cids))))
577     (when descriptor
578       (let* ((msg (first descriptor))
579              (part (second descriptor))
580              ;; Request caching for this content, as some messages
581              ;; reference the same cid: part many times (hundreds!).
582              (content (notmuch-get-bodypart-binary
583                        msg part notmuch-show-process-crypto 'cache))
584              (content-type (plist-get part :content-type)))
585         (list content content-type)))))
586
587 (defun notmuch-show-setup-w3m ()
588   "Instruct w3m how to retrieve content from a \"related\" part of a message."
589   (interactive)
590   (if (boundp 'w3m-cid-retrieve-function-alist)
591     (unless (assq 'notmuch-show-mode w3m-cid-retrieve-function-alist)
592       (push (cons 'notmuch-show-mode #'notmuch-show--cid-w3m-retrieve)
593             w3m-cid-retrieve-function-alist)))
594   (setq mm-inline-text-html-with-images t))
595
596 (defvar w3m-current-buffer) ;; From `w3m.el'.
597 (defun notmuch-show--cid-w3m-retrieve (url &rest args)
598   ;; url includes the cid: prefix and is URL encoded (see RFC 2392).
599   (let* ((cid (url-unhex-string (substring url 4)))
600          (content-and-type
601           (with-current-buffer w3m-current-buffer
602             (notmuch-show--get-cid-content cid))))
603     (when content-and-type
604       (insert (first content-and-type))
605       (second content-and-type))))
606
607 ;; MIME part renderers
608
609 (defun notmuch-show-multipart/*-to-list (part)
610   (mapcar (lambda (inner-part) (plist-get inner-part :content-type))
611           (plist-get part :content)))
612
613 (defun notmuch-show-insert-part-multipart/alternative (msg part content-type nth depth button)
614   (let ((chosen-type (car (notmuch-multipart/alternative-choose msg (notmuch-show-multipart/*-to-list part))))
615         (inner-parts (plist-get part :content))
616         (start (point)))
617     ;; This inserts all parts of the chosen type rather than just one,
618     ;; but it's not clear that this is the wrong thing to do - which
619     ;; should be chosen if there are more than one that match?
620     (mapc (lambda (inner-part)
621             (let* ((inner-type (plist-get inner-part :content-type))
622                   (hide (not (or notmuch-show-all-multipart/alternative-parts
623                            (string= chosen-type inner-type)))))
624               (notmuch-show-insert-bodypart msg inner-part depth hide)))
625           inner-parts)
626
627     (when notmuch-show-indent-multipart
628       (indent-rigidly start (point) 1)))
629   t)
630
631 (defun notmuch-show-insert-part-multipart/related (msg part content-type nth depth button)
632   (let ((inner-parts (plist-get part :content))
633         (start (point)))
634
635     ;; Render the primary part.  FIXME: Support RFC 2387 Start header.
636     (notmuch-show-insert-bodypart msg (car inner-parts) depth)
637     ;; Add hidden buttons for the rest
638     (mapc (lambda (inner-part)
639             (notmuch-show-insert-bodypart msg inner-part depth t))
640           (cdr inner-parts))
641
642     (when notmuch-show-indent-multipart
643       (indent-rigidly start (point) 1)))
644   t)
645
646 (defun notmuch-show-insert-part-multipart/signed (msg part content-type nth depth button)
647   (when button
648     (button-put button 'face 'notmuch-crypto-part-header))
649
650   ;; Insert a button detailing the signature status.
651   (notmuch-crypto-insert-sigstatus-button (car (plist-get part :sigstatus))
652                                           (notmuch-show-get-header :From msg))
653
654   (let ((inner-parts (plist-get part :content))
655         (start (point)))
656     ;; Show all of the parts.
657     (mapc (lambda (inner-part)
658             (notmuch-show-insert-bodypart msg inner-part depth))
659           inner-parts)
660
661     (when notmuch-show-indent-multipart
662       (indent-rigidly start (point) 1)))
663   t)
664
665 (defun notmuch-show-insert-part-multipart/encrypted (msg part content-type nth depth button)
666   (when button
667     (button-put button 'face 'notmuch-crypto-part-header))
668
669   ;; Insert a button detailing the encryption status.
670   (notmuch-crypto-insert-encstatus-button (car (plist-get part :encstatus)))
671
672   ;; Insert a button detailing the signature status.
673   (notmuch-crypto-insert-sigstatus-button (car (plist-get part :sigstatus))
674                                           (notmuch-show-get-header :From msg))
675
676   (let ((inner-parts (plist-get part :content))
677         (start (point)))
678     ;; Show all of the parts.
679     (mapc (lambda (inner-part)
680             (notmuch-show-insert-bodypart msg inner-part depth))
681           inner-parts)
682
683     (when notmuch-show-indent-multipart
684       (indent-rigidly start (point) 1)))
685   t)
686
687 (defun notmuch-show-insert-part-application/pgp-encrypted (msg part content-type nth depth button)
688   t)
689
690 (defun notmuch-show-insert-part-multipart/* (msg part content-type nth depth button)
691   (let ((inner-parts (plist-get part :content))
692         (start (point)))
693     ;; Show all of the parts.
694     (mapc (lambda (inner-part)
695             (notmuch-show-insert-bodypart msg inner-part depth))
696           inner-parts)
697
698     (when notmuch-show-indent-multipart
699       (indent-rigidly start (point) 1)))
700   t)
701
702 (defun notmuch-show-insert-part-message/rfc822 (msg part content-type nth depth button)
703   (let* ((message (car (plist-get part :content)))
704          (body (car (plist-get message :body)))
705          (start (point)))
706
707     ;; Override `notmuch-message-headers' to force `From' to be
708     ;; displayed.
709     (let ((notmuch-message-headers '("From" "Subject" "To" "Cc" "Date")))
710       (notmuch-show-insert-headers (plist-get message :headers)))
711
712     ;; Blank line after headers to be compatible with the normal
713     ;; message display.
714     (insert "\n")
715
716     ;; Show the body
717     (notmuch-show-insert-bodypart msg body depth)
718
719     (when notmuch-show-indent-multipart
720       (indent-rigidly start (point) 1)))
721   t)
722
723 (defun notmuch-show-insert-part-text/plain (msg part content-type nth depth button)
724   ;; For backward compatibility we want to apply the text/plain hook
725   ;; to the whole of the part including the part button if there is
726   ;; one.
727   (let ((start (if button
728                    (button-start button)
729                  (point))))
730     (insert (notmuch-get-bodypart-text msg part notmuch-show-process-crypto))
731     (save-excursion
732       (save-restriction
733         (narrow-to-region start (point-max))
734         (run-hook-with-args 'notmuch-show-insert-text/plain-hook msg depth))))
735   t)
736
737 (defun notmuch-show-insert-part-text/calendar (msg part content-type nth depth button)
738   (insert (with-temp-buffer
739             (insert (notmuch-get-bodypart-text msg part notmuch-show-process-crypto))
740             ;; notmuch-get-bodypart-text does no newline conversion.
741             ;; Replace CRLF with LF before icalendar can use it.
742             (goto-char (point-min))
743             (while (re-search-forward "\r\n" nil t)
744               (replace-match "\n" nil nil))
745             (let ((file (make-temp-file "notmuch-ical"))
746                   result)
747               (unwind-protect
748                   (progn
749                     (unless (icalendar-import-buffer file t)
750                       (error "Icalendar import error. See *icalendar-errors* for more information"))
751                     (set-buffer (get-file-buffer file))
752                     (setq result (buffer-substring (point-min) (point-max)))
753                     (set-buffer-modified-p nil)
754                     (kill-buffer (current-buffer)))
755                 (delete-file file))
756               result)))
757   t)
758
759 ;; For backwards compatibility.
760 (defun notmuch-show-insert-part-text/x-vcalendar (msg part content-type nth depth button)
761   (notmuch-show-insert-part-text/calendar msg part content-type nth depth button))
762
763 (defun notmuch-show-get-mime-type-of-application/octet-stream (part)
764   ;; If we can deduce a MIME type from the filename of the attachment,
765   ;; we return that.
766   (if (plist-get part :filename)
767       (let ((extension (file-name-extension (plist-get part :filename)))
768             mime-type)
769         (if extension
770             (progn
771               (mailcap-parse-mimetypes)
772               (setq mime-type (mailcap-extension-to-mime extension))
773               (if (and mime-type
774                        (not (string-equal mime-type "application/octet-stream")))
775                   mime-type
776                 nil))
777           nil))))
778
779 (defun notmuch-show-insert-part-text/html (msg part content-type nth depth button)
780   (if (eq mm-text-html-renderer 'shr)
781       ;; It's easier to drive shr ourselves than to work around the
782       ;; goofy things `mm-shr' does (like irreversibly taking over
783       ;; content ID handling).
784
785       ;; FIXME: If we block an image, offer a button to load external
786       ;; images.
787       (let ((shr-blocked-images notmuch-show-text/html-blocked-images))
788         (notmuch-show--insert-part-text/html-shr msg part))
789     ;; Otherwise, let message-mode do the heavy lifting
790     ;;
791     ;; w3m sets up a keymap which "leaks" outside the invisible region
792     ;; and causes strange effects in notmuch. We set
793     ;; mm-inline-text-html-with-w3m-keymap to nil to tell w3m not to
794     ;; set a keymap (so the normal notmuch-show-mode-map remains).
795     (let ((mm-inline-text-html-with-w3m-keymap nil)
796           ;; FIXME: If we block an image, offer a button to load external
797           ;; images.
798           (gnus-blocked-images notmuch-show-text/html-blocked-images))
799       (notmuch-show-insert-part-*/* msg part content-type nth depth button))))
800
801 ;; These functions are used by notmuch-show--insert-part-text/html-shr
802 (declare-function libxml-parse-html-region "xml.c")
803 (declare-function shr-insert-document "shr")
804
805 (defun notmuch-show--insert-part-text/html-shr (msg part)
806   ;; Make sure shr is loaded before we start let-binding its globals
807   (require 'shr)
808   (let ((dom (let ((process-crypto notmuch-show-process-crypto))
809                (with-temp-buffer
810                  (insert (notmuch-get-bodypart-text msg part process-crypto))
811                  (libxml-parse-html-region (point-min) (point-max)))))
812         (shr-content-function
813          (lambda (url)
814            ;; shr strips the "cid:" part of URL, but doesn't
815            ;; URL-decode it (see RFC 2392).
816            (let ((cid (url-unhex-string url)))
817              (first (notmuch-show--get-cid-content cid))))))
818     (shr-insert-document dom)
819     t))
820
821 (defun notmuch-show-insert-part-*/* (msg part content-type nth depth button)
822   ;; This handler _must_ succeed - it is the handler of last resort.
823   (notmuch-mm-display-part-inline msg part content-type notmuch-show-process-crypto)
824   t)
825
826 ;; Functions for determining how to handle MIME parts.
827
828 (defun notmuch-show-handlers-for (content-type)
829   "Return a list of content handlers for a part of type CONTENT-TYPE."
830   (let (result)
831     (mapc (lambda (func)
832             (if (functionp func)
833                 (push func result)))
834           ;; Reverse order of prefrence.
835           (list (intern (concat "notmuch-show-insert-part-*/*"))
836                 (intern (concat
837                          "notmuch-show-insert-part-"
838                          (car (notmuch-split-content-type content-type))
839                          "/*"))
840                 (intern (concat "notmuch-show-insert-part-" content-type))))
841     result))
842
843 ;; \f
844
845 (defun notmuch-show-insert-bodypart-internal (msg part content-type nth depth button)
846   ;; Run the handlers until one of them succeeds.
847   (loop for handler in (notmuch-show-handlers-for content-type)
848         until (condition-case err
849                   (funcall handler msg part content-type nth depth button)
850                 ;; Specifying `debug' here lets the debugger run if
851                 ;; `debug-on-error' is non-nil.
852                 ((debug error)
853                  (insert "!!! Bodypart handler `" (prin1-to-string handler) "' threw an error:\n"
854                          "!!! " (error-message-string err) "\n")
855                  nil))))
856
857 (defun notmuch-show-create-part-overlays (button beg end)
858   "Add an overlay to the part between BEG and END"
859
860   ;; If there is no button (i.e., the part is text/plain and the first
861   ;; part) or if the part has no content then we don't make the part
862   ;; toggleable.
863   (when (and button (/= beg end))
864     (button-put button 'overlay (make-overlay beg end))
865     ;; Return true if we created an overlay.
866     t))
867
868 (defun notmuch-show-record-part-information (part beg end)
869   "Store PART as a text property from BEG to END"
870
871   ;; Record part information.  Since we already inserted subparts,
872   ;; don't override existing :notmuch-part properties.
873   (notmuch-map-text-property beg end :notmuch-part
874                              (lambda (v) (or v part)))
875   ;; Make :notmuch-part front sticky and rear non-sticky so it stays
876   ;; applied to the beginning of each line when we indent the
877   ;; message.  Since we're operating on arbitrary renderer output,
878   ;; watch out for sticky specs of t, which means all properties are
879   ;; front-sticky/rear-nonsticky.
880   (notmuch-map-text-property beg end 'front-sticky
881                              (lambda (v) (if (listp v)
882                                              (pushnew :notmuch-part v)
883                                            v)))
884   (notmuch-map-text-property beg end 'rear-nonsticky
885                              (lambda (v) (if (listp v)
886                                              (pushnew :notmuch-part v)
887                                            v))))
888
889 (defun notmuch-show-lazy-part (part-args button)
890   ;; Insert the lazy part after the button for the part. We would just
891   ;; move to the start of the new line following the button and insert
892   ;; the part but that point might have text properties (eg colours
893   ;; from a message header etc) so instead we start from the last
894   ;; character of the button by adding a newline and finish by
895   ;; removing the extra newline from the end of the part.
896   (save-excursion
897     (goto-char (button-end button))
898     (insert "\n")
899     (let* ((inhibit-read-only t)
900            ;; We need to use markers for the start and end of the part
901            ;; because the part insertion functions do not guarantee
902            ;; to leave point at the end of the part.
903            (part-beg (copy-marker (point) nil))
904            (part-end (copy-marker (point) t))
905            ;; We have to save the depth as we can't find the depth
906            ;; when narrowed.
907            (depth (notmuch-show-get-depth)))
908       (save-restriction
909         (narrow-to-region part-beg part-end)
910         (delete-region part-beg part-end)
911         (apply #'notmuch-show-insert-bodypart-internal part-args)
912         (indent-rigidly part-beg part-end depth))
913       (goto-char part-end)
914       (delete-char 1)
915       (notmuch-show-record-part-information (second part-args)
916                                             (button-start button)
917                                             part-end)
918       ;; Create the overlay. If the lazy-part turned out to be empty/not
919       ;; showable this returns nil.
920       (notmuch-show-create-part-overlays button part-beg part-end))))
921
922 (defun notmuch-show-mime-type (part)
923   "Return the correct mime-type to use for PART."
924   (let ((content-type (downcase (plist-get part :content-type))))
925     (or (and (string= content-type "application/octet-stream")
926              (notmuch-show-get-mime-type-of-application/octet-stream part))
927         (and (string= content-type "inline patch")
928              "text/x-diff")
929         content-type)))
930
931 ;; The following variable can be overridden by let bindings.
932 (defvar notmuch-show-insert-header-p-function 'notmuch-show-insert-header-p
933   "Specify which function decides which part headers get inserted.
934
935 The function should take two parameters, PART and HIDE, and
936 should return non-NIL if a header button should be inserted for
937 this part.")
938
939 (defun notmuch-show-insert-header-p (part hide)
940   ;; Show all part buttons except for the first part if it is text/plain.
941   (let ((mime-type (notmuch-show-mime-type part)))
942     (not (and (string= mime-type "text/plain")
943               (<= (plist-get part :id) 1)))))
944
945 (defun notmuch-show-reply-insert-header-p-never (part hide)
946   nil)
947
948 (defun notmuch-show-reply-insert-header-p-trimmed (part hide)
949   (let ((mime-type (notmuch-show-mime-type part)))
950     (and (not (notmuch-match-content-type mime-type "multipart/*"))
951          (not hide))))
952
953 (defun notmuch-show-reply-insert-header-p-minimal (part hide)
954   (let ((mime-type (notmuch-show-mime-type part)))
955     (and (notmuch-match-content-type mime-type "text/*")
956          (not hide))))
957
958 (defun notmuch-show-insert-bodypart (msg part depth &optional hide)
959   "Insert the body part PART at depth DEPTH in the current thread.
960
961 HIDE determines whether to show or hide the part and the button
962 as follows: If HIDE is nil, show the part and the button. If HIDE
963 is t, hide the part initially and show the button."
964
965   (let* ((content-type (downcase (plist-get part :content-type)))
966          (mime-type (notmuch-show-mime-type part))
967          (nth (plist-get part :id))
968          (long (and (notmuch-match-content-type mime-type "text/*")
969                     (> notmuch-show-max-text-part-size 0)
970                     (> (length (plist-get part :content)) notmuch-show-max-text-part-size)))
971          (beg (point))
972          ;; This default header-p function omits the part button for
973          ;; the first (or only) part if this is text/plain.
974          (button (when (funcall notmuch-show-insert-header-p-function part hide)
975                    (notmuch-show-insert-part-header nth mime-type content-type (plist-get part :filename))))
976          ;; Hide the part initially if HIDE is t, or if it is too long
977          ;; and we have a button to allow toggling.
978          (show-part (not (or (equal hide t)
979                              (and long button))))
980          (content-beg (point)))
981
982     ;; Store the computed mime-type for later use (e.g. by attachment handlers).
983     (plist-put part :computed-type mime-type)
984
985     (if show-part
986         (notmuch-show-insert-bodypart-internal msg part mime-type nth depth button)
987       (when button
988         (button-put button :notmuch-lazy-part
989                     (list msg part mime-type nth depth button))))
990
991     ;; Some of the body part handlers leave point somewhere up in the
992     ;; part, so we make sure that we're down at the end.
993     (goto-char (point-max))
994     ;; Ensure that the part ends with a carriage return.
995     (unless (bolp)
996       (insert "\n"))
997     ;; We do not create the overlay for hidden (lazy) parts until
998     ;; they are inserted.
999     (if show-part
1000         (notmuch-show-create-part-overlays button content-beg (point))
1001       (save-excursion
1002         (notmuch-show-toggle-part-invisibility button)))
1003     (notmuch-show-record-part-information part beg (point))))
1004
1005 (defun notmuch-show-insert-body (msg body depth)
1006   "Insert the body BODY at depth DEPTH in the current thread."
1007
1008   ;; Register all content IDs for this message.  According to RFC
1009   ;; 2392, content IDs are *global*, but it's okay if an MUA treats
1010   ;; them as only global within a message.
1011   (notmuch-show--register-cids msg (first body))
1012
1013   (mapc (lambda (part) (notmuch-show-insert-bodypart msg part depth)) body))
1014
1015 (defun notmuch-show-make-symbol (type)
1016   (make-symbol (concat "notmuch-show-" type)))
1017
1018 (defun notmuch-show-strip-re (string)
1019   (replace-regexp-in-string "^\\([Rr]e: *\\)+" "" string))
1020
1021 (defvar notmuch-show-previous-subject "")
1022 (make-variable-buffer-local 'notmuch-show-previous-subject)
1023
1024 (defun notmuch-show-insert-msg (msg depth)
1025   "Insert the message MSG at depth DEPTH in the current thread."
1026   (let* ((headers (plist-get msg :headers))
1027          ;; Indentation causes the buffer offset of the start/end
1028          ;; points to move, so we must use markers.
1029          message-start message-end
1030          content-start content-end
1031          headers-start headers-end
1032          (bare-subject (notmuch-show-strip-re (plist-get headers :Subject))))
1033
1034     (setq message-start (point-marker))
1035
1036     (notmuch-show-insert-headerline headers
1037                                     (or (if notmuch-show-relative-dates
1038                                             (plist-get msg :date_relative)
1039                                           nil)
1040                                         (plist-get headers :Date))
1041                                     (plist-get msg :tags) depth)
1042
1043     (setq content-start (point-marker))
1044
1045     ;; Set `headers-start' to point after the 'Subject:' header to be
1046     ;; compatible with the existing implementation. This just sets it
1047     ;; to after the first header.
1048     (notmuch-show-insert-headers headers)
1049     (save-excursion
1050       (goto-char content-start)
1051       ;; If the subject of this message is the same as that of the
1052       ;; previous message, don't display it when this message is
1053       ;; collapsed.
1054       (when (not (string= notmuch-show-previous-subject
1055                           bare-subject))
1056         (forward-line 1))
1057       (setq headers-start (point-marker)))
1058     (setq headers-end (point-marker))
1059
1060     (setq notmuch-show-previous-subject bare-subject)
1061
1062     ;; A blank line between the headers and the body.
1063     (insert "\n")
1064     (notmuch-show-insert-body msg (plist-get msg :body)
1065                               (if notmuch-show-indent-content depth 0))
1066     ;; Ensure that the body ends with a newline.
1067     (unless (bolp)
1068       (insert "\n"))
1069     (setq content-end (point-marker))
1070
1071     ;; Indent according to the depth in the thread.
1072     (if notmuch-show-indent-content
1073         (indent-rigidly content-start content-end (* notmuch-show-indent-messages-width depth)))
1074
1075     (setq message-end (point-max-marker))
1076
1077     ;; Save the extents of this message over the whole text of the
1078     ;; message.
1079     (put-text-property message-start message-end :notmuch-message-extent (cons message-start message-end))
1080
1081     ;; Create overlays used to control visibility
1082     (plist-put msg :headers-overlay (make-overlay headers-start headers-end))
1083     (plist-put msg :message-overlay (make-overlay headers-start content-end))
1084
1085     (plist-put msg :depth depth)
1086
1087     ;; Save the properties for this message. Currently this saves the
1088     ;; entire message (augmented it with other stuff), which seems
1089     ;; like overkill. We might save a reduced subset (for example, not
1090     ;; the content).
1091     (notmuch-show-set-message-properties msg)
1092
1093     ;; Set header visibility.
1094     (notmuch-show-headers-visible msg notmuch-message-headers-visible)
1095
1096     ;; Message visibility depends on whether it matched the search
1097     ;; criteria.
1098     (notmuch-show-message-visible msg (and (plist-get msg :match)
1099                                            (not (plist-get msg :excluded))))))
1100
1101 (defun notmuch-show-toggle-process-crypto ()
1102   "Toggle the processing of cryptographic MIME parts."
1103   (interactive)
1104   (setq notmuch-show-process-crypto (not notmuch-show-process-crypto))
1105   (message (if notmuch-show-process-crypto
1106                "Processing cryptographic MIME parts."
1107              "Not processing cryptographic MIME parts."))
1108   (notmuch-show-refresh-view))
1109
1110 (defun notmuch-show-toggle-elide-non-matching ()
1111   "Toggle the display of non-matching messages."
1112   (interactive)
1113   (setq notmuch-show-elide-non-matching-messages (not notmuch-show-elide-non-matching-messages))
1114   (message (if notmuch-show-elide-non-matching-messages
1115                "Showing matching messages only."
1116              "Showing all messages."))
1117   (notmuch-show-refresh-view))
1118
1119 (defun notmuch-show-toggle-thread-indentation ()
1120   "Toggle the indentation of threads."
1121   (interactive)
1122   (setq notmuch-show-indent-content (not notmuch-show-indent-content))
1123   (message (if notmuch-show-indent-content
1124                "Content is indented."
1125              "Content is not indented."))
1126   (notmuch-show-refresh-view))
1127
1128 (defun notmuch-show-insert-tree (tree depth)
1129   "Insert the message tree TREE at depth DEPTH in the current thread."
1130   (let ((msg (car tree))
1131         (replies (cadr tree)))
1132     ;; We test whether there is a message or just some replies.
1133     (when msg
1134       (notmuch-show-insert-msg msg depth))
1135     (notmuch-show-insert-thread replies (1+ depth))))
1136
1137 (defun notmuch-show-insert-thread (thread depth)
1138   "Insert the thread THREAD at depth DEPTH in the current forest."
1139   (mapc (lambda (tree) (notmuch-show-insert-tree tree depth)) thread))
1140
1141 (defun notmuch-show-insert-forest (forest)
1142   "Insert the forest of threads FOREST."
1143   (mapc (lambda (thread) (notmuch-show-insert-thread thread 0)) forest))
1144
1145 (defvar notmuch-id-regexp
1146   (concat
1147    ;; Match the id: prefix only if it begins a word (to disallow, for
1148    ;; example, matching cid:).
1149    "\\<id:\\("
1150    ;; If the term starts with a ", then parse Xapian's quoted boolean
1151    ;; term syntax, which allows for anything as long as embedded
1152    ;; double quotes escaped by doubling them.  We also disallow
1153    ;; newlines (which Xapian allows) to prevent runaway terms.
1154    "\"\\([^\"\n]\\|\"\"\\)*\""
1155    ;; Otherwise, parse Xapian's unquoted syntax, which goes up to the
1156    ;; next space or ).  We disallow [.,;] as the last character
1157    ;; because these are probably part of the surrounding text, and not
1158    ;; part of the id.  This doesn't match single character ids; meh.
1159    "\\|[^\"[:space:])][^[:space:])]*[^])[:space:].,:;?!]"
1160    "\\)")
1161   "The regexp used to match id: links in messages.")
1162
1163 (defvar notmuch-mid-regexp
1164   ;; goto-address-url-regexp matched cid: links, which have the same
1165   ;; grammar as the message ID part of a mid: link.  Construct the
1166   ;; regexp using the same technique as goto-address-url-regexp.
1167   (concat "\\<mid:\\(" thing-at-point-url-path-regexp "\\)")
1168   "The regexp used to match mid: links in messages.
1169
1170 See RFC 2392.")
1171
1172 (defun notmuch-show-buttonise-links (start end)
1173   "Buttonise URLs and mail addresses between START and END.
1174
1175 This also turns id:\"<message id>\"-parts and mid: links into
1176 buttons for a corresponding notmuch search."
1177   (goto-address-fontify-region start end)
1178   (save-excursion
1179     (let (links
1180           (beg-line (progn (goto-char start) (line-beginning-position)))
1181           (end-line (progn (goto-char end) (line-end-position))))
1182       (goto-char beg-line)
1183       (while (re-search-forward notmuch-id-regexp end-line t)
1184         (push (list (match-beginning 0) (match-end 0)
1185                     (match-string-no-properties 0)) links))
1186       (goto-char beg-line)
1187       (while (re-search-forward notmuch-mid-regexp end-line t)
1188         (let* ((mid-cid (match-string-no-properties 1))
1189                (mid (save-match-data
1190                       (string-match "^[^/]*" mid-cid)
1191                       (url-unhex-string (match-string 0 mid-cid)))))
1192           (push (list (match-beginning 0) (match-end 0)
1193                       (notmuch-id-to-query mid)) links)))
1194       (dolist (link links)
1195         ;; Remove the overlay created by goto-address-mode
1196         (remove-overlays (first link) (second link) 'goto-address t)
1197         (make-text-button (first link) (second link)
1198                           :type 'notmuch-button-type
1199                           'action `(lambda (arg)
1200                                      (notmuch-show ,(third link) current-prefix-arg))
1201                           'follow-link t
1202                           'help-echo "Mouse-1, RET: search for this message"
1203                           'face goto-address-mail-face)))))
1204
1205 ;;;###autoload
1206 (defun notmuch-show (thread-id &optional elide-toggle parent-buffer query-context buffer-name)
1207   "Run \"notmuch show\" with the given thread ID and display results.
1208
1209 ELIDE-TOGGLE, if non-nil, inverts the default elide behavior.
1210
1211 The optional PARENT-BUFFER is the notmuch-search buffer from
1212 which this notmuch-show command was executed, (so that the
1213 next thread from that buffer can be show when done with this
1214 one).
1215
1216 The optional QUERY-CONTEXT is a notmuch search term. Only
1217 messages from the thread matching this search term are shown if
1218 non-nil.
1219
1220 The optional BUFFER-NAME provides the name of the buffer in
1221 which the message thread is shown. If it is nil (which occurs
1222 when the command is called interactively) the argument to the
1223 function is used.
1224
1225 Returns the buffer containing the messages, or NIL if no messages
1226 matched."
1227   (interactive "sNotmuch show: \nP")
1228   (let ((buffer-name (generate-new-buffer-name
1229                       (or buffer-name
1230                           (concat "*notmuch-" thread-id "*"))))
1231         ;; We override mm-inline-override-types to stop application/*
1232         ;; parts from being displayed unless the user has customized
1233         ;; it themselves.
1234         (mm-inline-override-types
1235          (if (equal mm-inline-override-types
1236                     (eval (car (get 'mm-inline-override-types 'standard-value))))
1237              (cons "application/*" mm-inline-override-types)
1238            mm-inline-override-types)))
1239     (switch-to-buffer (get-buffer-create buffer-name))
1240     ;; No need to track undo information for this buffer.
1241     (setq buffer-undo-list t)
1242
1243     (notmuch-show-mode)
1244
1245     ;; Set various buffer local variables to their appropriate initial
1246     ;; state. Do this after enabling `notmuch-show-mode' so that they
1247     ;; aren't wiped out.
1248     (setq notmuch-show-thread-id thread-id
1249           notmuch-show-parent-buffer parent-buffer
1250           notmuch-show-query-context query-context
1251
1252           notmuch-show-process-crypto notmuch-crypto-process-mime
1253           ;; If `elide-toggle', invert the default value.
1254           notmuch-show-elide-non-matching-messages
1255           (if elide-toggle
1256               (not notmuch-show-only-matching-messages)
1257             notmuch-show-only-matching-messages))
1258
1259     (add-hook 'post-command-hook #'notmuch-show-command-hook nil t)
1260     (jit-lock-register #'notmuch-show-buttonise-links)
1261
1262     (notmuch-tag-clear-cache)
1263
1264     (let ((inhibit-read-only t))
1265       (if (notmuch-show--build-buffer)
1266           ;; Messages were inserted into the buffer.
1267           (current-buffer)
1268
1269         ;; No messages were inserted - presumably none matched the
1270         ;; query.
1271         (kill-buffer (current-buffer))
1272         (ding)
1273         (message "No messages matched the query!")
1274         nil))))
1275
1276 (defun notmuch-show--build-queries (thread context)
1277   "Return a list of queries to try for this search.
1278
1279 THREAD and CONTEXT are both strings, though CONTEXT may be nil.
1280 When CONTEXT is not nil, the first query is the conjunction of it
1281 and THREAD.  The next query is THREAD alone, and serves as a
1282 fallback if the prior matches no messages."
1283   (let (queries)
1284     (push (list thread) queries)
1285     (if context (push (list thread "and (" context ")") queries))
1286     queries))
1287
1288 (defun notmuch-show--build-buffer (&optional state)
1289   "Display messages matching the current buffer context.
1290
1291 Apply the previously saved STATE if supplied, otherwise show the
1292 first relevant message.
1293
1294 If no messages match the query return NIL."
1295   (let* ((cli-args (cons "--exclude=false"
1296                          (when notmuch-show-elide-non-matching-messages
1297                            (list "--entire-thread=false"))))
1298          (queries (notmuch-show--build-queries
1299                    notmuch-show-thread-id notmuch-show-query-context))
1300          (forest nil)
1301          ;; Must be reset every time we are going to start inserting
1302          ;; messages into the buffer.
1303          (notmuch-show-previous-subject ""))
1304     ;; Use results from the first query that returns some.
1305     (while (and (not forest) queries)
1306       (setq forest (notmuch-query-get-threads
1307                     (append cli-args (list "'") (car queries) (list "'"))))
1308       (setq queries (cdr queries)))
1309     (when forest
1310       (notmuch-show-insert-forest forest)
1311
1312       ;; Store the original tags for each message so that we can
1313       ;; display changes.
1314       (notmuch-show-mapc
1315        (lambda () (notmuch-show-set-prop :orig-tags (notmuch-show-get-tags))))
1316
1317       ;; Set the header line to the subject of the first message.
1318       (setq header-line-format
1319             (replace-regexp-in-string "%" "%%"
1320                                       (notmuch-sanitize
1321                                        (notmuch-show-strip-re
1322                                         (notmuch-show-get-subject)))))
1323
1324       (run-hooks 'notmuch-show-hook)
1325
1326       (if state
1327           (notmuch-show-apply-state state)
1328         ;; With no state to apply, just go to the first message.
1329         (notmuch-show-goto-first-wanted-message)))
1330
1331     ;; Report back to the caller whether any messages matched.
1332     forest))
1333
1334 (defun notmuch-show-capture-state ()
1335   "Capture the state of the current buffer.
1336
1337 This includes:
1338  - the list of open messages,
1339  - the combination of current message id with/for each visible window."
1340   (let* ((win-list (get-buffer-window-list (current-buffer) nil t))
1341          (win-id-combo (mapcar (lambda (win)
1342                                  (with-selected-window win
1343                                    (list win (notmuch-show-get-message-id))))
1344                                win-list)))
1345     (list win-id-combo (notmuch-show-get-message-ids-for-open-messages))))
1346
1347 (defun notmuch-show-get-query ()
1348   "Return the current query in this show buffer"
1349   (if notmuch-show-query-context
1350       (concat notmuch-show-thread-id
1351               " and ("
1352               notmuch-show-query-context
1353               ")")
1354     notmuch-show-thread-id))
1355
1356 (defun notmuch-show-goto-message (msg-id)
1357   "Go to message with msg-id."
1358   (goto-char (point-min))
1359   (unless (loop if (string= msg-id (notmuch-show-get-message-id))
1360                 return t
1361                 until (not (notmuch-show-goto-message-next)))
1362     (goto-char (point-min))
1363     (message "Message-id not found."))
1364   (notmuch-show-message-adjust))
1365
1366 (defun notmuch-show-apply-state (state)
1367   "Apply STATE to the current buffer.
1368
1369 This includes:
1370  - opening the messages previously opened,
1371  - closing all other messages,
1372  - moving to the correct current message in every displayed window."
1373   (let ((win-msg-alist (car state))
1374         (open (cadr state)))
1375
1376     ;; Open those that were open.
1377     (goto-char (point-min))
1378     (loop do (notmuch-show-message-visible (notmuch-show-get-message-properties)
1379                                            (member (notmuch-show-get-message-id) open))
1380           until (not (notmuch-show-goto-message-next)))
1381
1382     (dolist (win-msg-pair win-msg-alist)
1383       (with-selected-window (car win-msg-pair)
1384         ;; Go to the previously open message in this window
1385         (notmuch-show-goto-message (cadr win-msg-pair))))))
1386
1387 (defun notmuch-show-refresh-view (&optional reset-state)
1388   "Refresh the current view.
1389
1390 Refreshes the current view, observing changes in display
1391 preferences. If invoked with a prefix argument (or RESET-STATE is
1392 non-nil) then the state of the buffer (open/closed messages) is
1393 reset based on the original query."
1394   (interactive "P")
1395   (let ((inhibit-read-only t)
1396         (state (unless reset-state
1397                  (notmuch-show-capture-state))))
1398     ;; `erase-buffer' does not seem to remove overlays, which can lead
1399     ;; to weird effects such as remaining images, so remove them
1400     ;; manually.
1401     (remove-overlays)
1402     (erase-buffer)
1403
1404     (unless (notmuch-show--build-buffer state)
1405       ;; No messages were inserted.
1406       (kill-buffer (current-buffer))
1407       (ding)
1408       (message "Refreshing the buffer resulted in no messages!"))))
1409
1410 (defvar notmuch-show-stash-map
1411   (let ((map (make-sparse-keymap)))
1412     (define-key map "c" 'notmuch-show-stash-cc)
1413     (define-key map "d" 'notmuch-show-stash-date)
1414     (define-key map "F" 'notmuch-show-stash-filename)
1415     (define-key map "f" 'notmuch-show-stash-from)
1416     (define-key map "i" 'notmuch-show-stash-message-id)
1417     (define-key map "I" 'notmuch-show-stash-message-id-stripped)
1418     (define-key map "s" 'notmuch-show-stash-subject)
1419     (define-key map "T" 'notmuch-show-stash-tags)
1420     (define-key map "t" 'notmuch-show-stash-to)
1421     (define-key map "l" 'notmuch-show-stash-mlarchive-link)
1422     (define-key map "L" 'notmuch-show-stash-mlarchive-link-and-go)
1423     (define-key map "G" 'notmuch-show-stash-git-send-email)
1424     (define-key map "?" 'notmuch-subkeymap-help)
1425     map)
1426   "Submap for stash commands")
1427 (fset 'notmuch-show-stash-map notmuch-show-stash-map)
1428
1429 (defvar notmuch-show-part-map
1430   (let ((map (make-sparse-keymap)))
1431     (define-key map "s" 'notmuch-show-save-part)
1432     (define-key map "v" 'notmuch-show-view-part)
1433     (define-key map "o" 'notmuch-show-interactively-view-part)
1434     (define-key map "|" 'notmuch-show-pipe-part)
1435     (define-key map "m" 'notmuch-show-choose-mime-of-part)
1436     (define-key map "?" 'notmuch-subkeymap-help)
1437     map)
1438   "Submap for part commands")
1439 (fset 'notmuch-show-part-map notmuch-show-part-map)
1440
1441 (defvar notmuch-show-mode-map
1442   (let ((map (make-sparse-keymap)))
1443     (set-keymap-parent map notmuch-common-keymap)
1444     (define-key map "Z" 'notmuch-tree-from-show-current-query)
1445     (define-key map (kbd "<C-tab>") 'widget-backward)
1446     (define-key map (kbd "M-TAB") 'notmuch-show-previous-button)
1447     (define-key map (kbd "<backtab>") 'notmuch-show-previous-button)
1448     (define-key map (kbd "TAB") 'notmuch-show-next-button)
1449     (define-key map "f" 'notmuch-show-forward-message)
1450     (define-key map "F" 'notmuch-show-forward-open-messages)
1451     (define-key map "b" 'notmuch-show-resend-message)
1452     (define-key map "l" 'notmuch-show-filter-thread)
1453     (define-key map "r" 'notmuch-show-reply-sender)
1454     (define-key map "R" 'notmuch-show-reply)
1455     (define-key map "|" 'notmuch-show-pipe-message)
1456     (define-key map "w" 'notmuch-show-save-attachments)
1457     (define-key map "V" 'notmuch-show-view-raw-message)
1458     (define-key map "e" 'notmuch-show-resume-message)
1459     (define-key map "c" 'notmuch-show-stash-map)
1460     (define-key map "h" 'notmuch-show-toggle-visibility-headers)
1461     (define-key map "k" 'notmuch-tag-jump)
1462     (define-key map "*" 'notmuch-show-tag-all)
1463     (define-key map "-" 'notmuch-show-remove-tag)
1464     (define-key map "+" 'notmuch-show-add-tag)
1465     (define-key map "X" 'notmuch-show-archive-thread-then-exit)
1466     (define-key map "x" 'notmuch-show-archive-message-then-next-or-exit)
1467     (define-key map "A" 'notmuch-show-archive-thread-then-next)
1468     (define-key map "a" 'notmuch-show-archive-message-then-next-or-next-thread)
1469     (define-key map "N" 'notmuch-show-next-message)
1470     (define-key map "P" 'notmuch-show-previous-message)
1471     (define-key map "n" 'notmuch-show-next-open-message)
1472     (define-key map "p" 'notmuch-show-previous-open-message)
1473     (define-key map (kbd "M-n") 'notmuch-show-next-thread-show)
1474     (define-key map (kbd "M-p") 'notmuch-show-previous-thread-show)
1475     (define-key map (kbd "DEL") 'notmuch-show-rewind)
1476     (define-key map " " 'notmuch-show-advance-and-archive)
1477     (define-key map (kbd "M-RET") 'notmuch-show-open-or-close-all)
1478     (define-key map (kbd "RET") 'notmuch-show-toggle-message)
1479     (define-key map "#" 'notmuch-show-print-message)
1480     (define-key map "!" 'notmuch-show-toggle-elide-non-matching)
1481     (define-key map "$" 'notmuch-show-toggle-process-crypto)
1482     (define-key map "<" 'notmuch-show-toggle-thread-indentation)
1483     (define-key map "t" 'toggle-truncate-lines)
1484     (define-key map "." 'notmuch-show-part-map)
1485     map)
1486   "Keymap for \"notmuch show\" buffers.")
1487 (fset 'notmuch-show-mode-map notmuch-show-mode-map)
1488
1489 (define-derived-mode notmuch-show-mode fundamental-mode "notmuch-show"
1490   "Major mode for viewing a thread with notmuch.
1491
1492 This buffer contains the results of the \"notmuch show\" command
1493 for displaying a single thread of email from your email archives.
1494
1495 By default, various components of email messages, (citations,
1496 signatures, already-read messages), are hidden. You can make
1497 these parts visible by clicking with the mouse button or by
1498 pressing RET after positioning the cursor on a hidden part, (for
1499 which \\[notmuch-show-next-button] and \\[notmuch-show-previous-button] are helpful).
1500
1501 Reading the thread sequentially is well-supported by pressing
1502 \\[notmuch-show-advance-and-archive]. This will scroll the current message (if necessary), advance
1503 to the next message, or advance to the next thread (if already on
1504 the last message of a thread).
1505
1506 Other commands are available to read or manipulate the thread
1507 more selectively, (such as '\\[notmuch-show-next-message]' and '\\[notmuch-show-previous-message]' to advance to messages
1508 without removing any tags, and '\\[notmuch-show-archive-thread]' to archive an entire thread
1509 without scrolling through with \\[notmuch-show-advance-and-archive]).
1510
1511 You can add or remove arbitrary tags from the current message with
1512 '\\[notmuch-show-add-tag]' or '\\[notmuch-show-remove-tag]'.
1513
1514 All currently available key bindings:
1515
1516 \\{notmuch-show-mode-map}"
1517   (setq notmuch-buffer-refresh-function #'notmuch-show-refresh-view)
1518   (setq buffer-read-only t
1519         truncate-lines t))
1520
1521 (defun notmuch-tree-from-show-current-query ()
1522   "Call notmuch tree with the current query"
1523   (interactive)
1524   (notmuch-tree notmuch-show-thread-id
1525                 notmuch-show-query-context
1526                 (notmuch-show-get-message-id)))
1527
1528 (defun notmuch-show-move-to-message-top ()
1529   (goto-char (notmuch-show-message-top)))
1530
1531 (defun notmuch-show-move-to-message-bottom ()
1532   (goto-char (notmuch-show-message-bottom)))
1533
1534 (defun notmuch-show-message-adjust ()
1535   (recenter 0))
1536
1537 ;; Movement related functions.
1538
1539 ;; There's some strangeness here where a text property applied to a
1540 ;; region a->b is not found when point is at b. We walk backwards
1541 ;; until finding the property.
1542 (defun notmuch-show-message-extent ()
1543   (let (r)
1544     (save-excursion
1545       (while (not (setq r (get-text-property (point) :notmuch-message-extent)))
1546         (backward-char)))
1547     r))
1548
1549 (defun notmuch-show-message-top ()
1550   (car (notmuch-show-message-extent)))
1551
1552 (defun notmuch-show-message-bottom ()
1553   (cdr (notmuch-show-message-extent)))
1554
1555 (defun notmuch-show-goto-message-next ()
1556   (let ((start (point)))
1557     (notmuch-show-move-to-message-bottom)
1558     (if (not (eobp))
1559         t
1560       (goto-char start)
1561       nil)))
1562
1563 (defun notmuch-show-goto-message-previous ()
1564   (notmuch-show-move-to-message-top)
1565   (if (bobp)
1566       nil
1567     (backward-char)
1568     (notmuch-show-move-to-message-top)
1569     t))
1570
1571 (defun notmuch-show-mapc (function)
1572   "Iterate through all messages in the current thread with
1573 `notmuch-show-goto-message-next' and call FUNCTION for side
1574 effects."
1575   (save-excursion
1576     (goto-char (point-min))
1577     (loop do (funcall function)
1578           while (notmuch-show-goto-message-next))))
1579
1580 ;; Functions relating to the visibility of messages and their
1581 ;; components.
1582
1583 (defun notmuch-show-message-visible (props visible-p)
1584   (overlay-put (plist-get props :message-overlay) 'invisible (not visible-p))
1585   (notmuch-show-set-prop :message-visible visible-p props))
1586
1587 (defun notmuch-show-headers-visible (props visible-p)
1588   (overlay-put (plist-get props :headers-overlay) 'invisible (not visible-p))
1589   (notmuch-show-set-prop :headers-visible visible-p props))
1590
1591 ;; Functions for setting and getting attributes of the current
1592 ;; message.
1593
1594 (defun notmuch-show-set-message-properties (props)
1595   (save-excursion
1596     (notmuch-show-move-to-message-top)
1597     (put-text-property (point) (+ (point) 1) :notmuch-message-properties props)))
1598
1599 (defun notmuch-show-get-message-properties ()
1600   "Return the properties of the current message as a plist.
1601
1602 Some useful entries are:
1603 :headers - Property list containing the headers :Date, :Subject, :From, etc.
1604 :body - Body of the message
1605 :tags - Tags for this message"
1606   (save-excursion
1607     (notmuch-show-move-to-message-top)
1608     (get-text-property (point) :notmuch-message-properties)))
1609
1610 (defun notmuch-show-get-part-properties ()
1611   "Return the properties of the innermost part containing point.
1612
1613 This is the part property list retrieved from the CLI.  Signals
1614 an error if there is no part containing point."
1615   (or (get-text-property (point) :notmuch-part)
1616       (error "No message part here")))
1617
1618 (defun notmuch-show-set-prop (prop val &optional props)
1619   (let ((inhibit-read-only t)
1620         (props (or props
1621                    (notmuch-show-get-message-properties))))
1622     (plist-put props prop val)
1623     (notmuch-show-set-message-properties props)))
1624
1625 (defun notmuch-show-get-prop (prop &optional props)
1626   "Get property PROP from current message in show or tree mode.
1627
1628 It gets property PROP from PROPS or, if PROPS is nil, the current
1629 message in either tree or show. This means that several utility
1630 functions in notmuch-show can be used directly by notmuch-tree as
1631 they just need the correct message properties."
1632   (let ((props (or props
1633                    (cond ((eq major-mode 'notmuch-show-mode)
1634                           (notmuch-show-get-message-properties))
1635                          ((eq major-mode 'notmuch-tree-mode)
1636                           (notmuch-tree-get-message-properties))
1637                          (t nil)))))
1638     (plist-get props prop)))
1639
1640 (defun notmuch-show-get-message-id (&optional bare)
1641   "Return an id: query for the Message-Id of the current message.
1642
1643 If optional argument BARE is non-nil, return
1644 the Message-Id without id: prefix and escaping."
1645   (if bare
1646       (notmuch-show-get-prop :id)
1647     (notmuch-id-to-query (notmuch-show-get-prop :id))))
1648
1649 (defun notmuch-show-get-messages-ids ()
1650   "Return all id: queries of messages in the current thread."
1651   (let ((message-ids))
1652     (notmuch-show-mapc
1653      (lambda () (push (notmuch-show-get-message-id) message-ids)))
1654     message-ids))
1655
1656 (defun notmuch-show-get-messages-ids-search ()
1657   "Return a search string for all message ids of messages in the
1658 current thread."
1659   (mapconcat 'identity (notmuch-show-get-messages-ids) " or "))
1660
1661 ;; dme: Would it make sense to use a macro for many of these?
1662
1663 (defun notmuch-show-get-filename ()
1664   "Return the filename of the current message."
1665   (notmuch-show-get-prop :filename))
1666
1667 (defun notmuch-show-get-header (header &optional props)
1668   "Return the named header of the current message, if any."
1669   (plist-get (notmuch-show-get-prop :headers props) header))
1670
1671 (defun notmuch-show-get-cc ()
1672   (notmuch-show-get-header :Cc))
1673
1674 (defun notmuch-show-get-date ()
1675   (notmuch-show-get-header :Date))
1676
1677 (defun notmuch-show-get-from ()
1678   (notmuch-show-get-header :From))
1679
1680 (defun notmuch-show-get-subject ()
1681   (notmuch-show-get-header :Subject))
1682
1683 (defun notmuch-show-get-to ()
1684   (notmuch-show-get-header :To))
1685
1686 (defun notmuch-show-get-depth ()
1687   (notmuch-show-get-prop :depth))
1688
1689 (defun notmuch-show-set-tags (tags)
1690   "Set the tags of the current message."
1691   (notmuch-show-set-prop :tags tags)
1692   (notmuch-show-update-tags tags))
1693
1694 (defun notmuch-show-get-tags ()
1695   "Return the tags of the current message."
1696   (notmuch-show-get-prop :tags))
1697
1698 (defun notmuch-show-message-visible-p ()
1699   "Is the current message visible?"
1700   (notmuch-show-get-prop :message-visible))
1701
1702 (defun notmuch-show-headers-visible-p ()
1703   "Are the headers of the current message visible?"
1704   (notmuch-show-get-prop :headers-visible))
1705
1706 (put 'notmuch-show-mark-read 'notmuch-prefix-doc
1707      "Mark the current message as unread.")
1708 (defun notmuch-show-mark-read (&optional unread)
1709   "Mark the current message as read.
1710
1711 Mark the current message as read by applying the tag changes in
1712 `notmuch-show-mark-read-tags' to it (remove the \"unread\" tag by
1713 default). If a prefix argument is given, the message will be
1714 marked as unread, i.e. the tag changes in
1715 `notmuch-show-mark-read-tags' will be reversed."
1716   (interactive "P")
1717   (when notmuch-show-mark-read-tags
1718     (apply 'notmuch-show-tag-message
1719            (notmuch-tag-change-list notmuch-show-mark-read-tags unread))))
1720
1721 (defun notmuch-show-seen-current-message (start end)
1722   "Mark the current message read if it is open.
1723
1724 We only mark it read once: if it is changed back then that is a
1725 user decision and we should not override it."
1726   (when (and (notmuch-show-message-visible-p)
1727              (not (notmuch-show-get-prop :seen)))
1728         (notmuch-show-mark-read)
1729         (notmuch-show-set-prop :seen t)))
1730
1731 (defvar notmuch-show--seen-has-errored nil)
1732 (make-variable-buffer-local 'notmuch-show--seen-has-errored)
1733
1734 (defun notmuch-show-command-hook ()
1735   (when (eq major-mode 'notmuch-show-mode)
1736     ;; We need to redisplay to get window-start and window-end correct.
1737     (redisplay)
1738     (save-excursion
1739       (condition-case err
1740           (funcall notmuch-show-mark-read-function (window-start) (window-end))
1741         ((debug error)
1742          (unless notmuch-show--seen-has-errored
1743            (setq notmuch-show--seen-has-errored 't)
1744            (setq header-line-format
1745                  (concat header-line-format
1746                          (propertize "  [some mark read tag changes may have failed]"
1747                                      'face font-lock-warning-face)))))))))
1748
1749 (defun notmuch-show-filter-thread (query)
1750   "Filter or LIMIT the current thread based on a new query string.
1751
1752 Reshows the current thread with matches defined by the new query-string."
1753   (interactive (list (notmuch-read-query "Filter thread: ")))
1754   (let ((msg-id (notmuch-show-get-message-id)))
1755     (setq notmuch-show-query-context (if (string= query "") nil query))
1756     (notmuch-show-refresh-view t)
1757     (notmuch-show-goto-message msg-id)))
1758
1759 ;; Functions for getting attributes of several messages in the current
1760 ;; thread.
1761
1762 (defun notmuch-show-get-message-ids-for-open-messages ()
1763   "Return a list of all id: queries for open messages in the current thread."
1764   (save-excursion
1765     (let (message-ids done)
1766       (goto-char (point-min))
1767       (while (not done)
1768         (if (notmuch-show-message-visible-p)
1769             (setq message-ids (append message-ids (list (notmuch-show-get-message-id)))))
1770         (setq done (not (notmuch-show-goto-message-next)))
1771         )
1772       message-ids
1773       )))
1774
1775 ;; Commands typically bound to keys.
1776
1777 (defun notmuch-show-advance ()
1778   "Advance through thread.
1779
1780 If the current message in the thread is not yet fully visible,
1781 scroll by a near screenful to read more of the message.
1782
1783 Otherwise, (the end of the current message is already within the
1784 current window), advance to the next open message."
1785   (interactive)
1786   (let* ((end-of-this-message (notmuch-show-message-bottom))
1787          (visible-end-of-this-message (1- end-of-this-message))
1788          (ret nil))
1789     (while (invisible-p visible-end-of-this-message)
1790       (setq visible-end-of-this-message
1791             (max (point-min)
1792                  (1- (previous-single-char-property-change
1793                       visible-end-of-this-message 'invisible)))))
1794     (cond
1795      ;; Ideally we would test `end-of-this-message' against the result
1796      ;; of `window-end', but that doesn't account for the fact that
1797      ;; the end of the message might be hidden.
1798      ((and visible-end-of-this-message
1799            (> visible-end-of-this-message (window-end)))
1800       ;; The bottom of this message is not visible - scroll.
1801       (scroll-up nil))
1802
1803      ((not (= end-of-this-message (point-max)))
1804       ;; This is not the last message - move to the next visible one.
1805       (notmuch-show-next-open-message))
1806
1807      ((not (= (point) (point-max)))
1808       ;; This is the last message, but the cursor is not at the end of
1809       ;; the buffer. Move it there.
1810       (goto-char (point-max)))
1811
1812      (t
1813       ;; This is the last message - change the return value
1814       (setq ret t)))
1815     ret))
1816
1817 (defun notmuch-show-advance-and-archive ()
1818   "Advance through thread and archive.
1819
1820 This command is intended to be one of the simplest ways to
1821 process a thread of email. It works exactly like
1822 notmuch-show-advance, in that it scrolls through messages in a
1823 show buffer, except that when it gets to the end of the buffer it
1824 archives the entire current thread, (apply changes in
1825 `notmuch-archive-tags'), kills the buffer, and displays the next
1826 thread from the search from which this thread was originally
1827 shown."
1828   (interactive)
1829   (if (notmuch-show-advance)
1830       (notmuch-show-archive-thread-then-next)))
1831
1832 (defun notmuch-show-rewind ()
1833   "Backup through the thread (reverse scrolling compared to \\[notmuch-show-advance-and-archive]).
1834
1835 Specifically, if the beginning of the previous email is fewer
1836 than `window-height' lines from the current point, move to it
1837 just like `notmuch-show-previous-message'.
1838
1839 Otherwise, just scroll down a screenful of the current message.
1840
1841 This command does not modify any message tags, (it does not undo
1842 any effects from previous calls to
1843 `notmuch-show-advance-and-archive'."
1844   (interactive)
1845   (let ((start-of-message (notmuch-show-message-top))
1846         (start-of-window (window-start)))
1847     (cond
1848       ;; Either this message is properly aligned with the start of the
1849       ;; window or the start of this message is not visible on the
1850       ;; screen - scroll.
1851      ((or (= start-of-message start-of-window)
1852           (< start-of-message start-of-window))
1853       (scroll-down)
1854       ;; If a small number of lines from the previous message are
1855       ;; visible, realign so that the top of the current message is at
1856       ;; the top of the screen.
1857       (when (<= (count-screen-lines (window-start) start-of-message)
1858                 next-screen-context-lines)
1859         (goto-char (notmuch-show-message-top))
1860         (notmuch-show-message-adjust))
1861       ;; Move to the top left of the window.
1862       (goto-char (window-start)))
1863      (t
1864       ;; Move to the previous message.
1865       (notmuch-show-previous-message)))))
1866
1867 (put 'notmuch-show-reply 'notmuch-prefix-doc "... and prompt for sender")
1868 (defun notmuch-show-reply (&optional prompt-for-sender)
1869   "Reply to the sender and all recipients of the current message."
1870   (interactive "P")
1871   (notmuch-mua-new-reply (notmuch-show-get-message-id) prompt-for-sender t))
1872
1873 (put 'notmuch-show-reply-sender 'notmuch-prefix-doc "... and prompt for sender")
1874 (defun notmuch-show-reply-sender (&optional prompt-for-sender)
1875   "Reply to the sender of the current message."
1876   (interactive "P")
1877   (notmuch-mua-new-reply (notmuch-show-get-message-id) prompt-for-sender nil))
1878
1879 (put 'notmuch-show-forward-message 'notmuch-prefix-doc
1880      "... and prompt for sender")
1881 (defun notmuch-show-forward-message (&optional prompt-for-sender)
1882   "Forward the current message."
1883   (interactive "P")
1884   (notmuch-mua-new-forward-messages (list (notmuch-show-get-message-id))
1885                                     prompt-for-sender))
1886
1887 (put 'notmuch-show-forward-open-messages 'notmuch-prefix-doc
1888      "... and prompt for sender")
1889 (defun notmuch-show-forward-open-messages (&optional prompt-for-sender)
1890   "Forward the currently open messages."
1891   (interactive "P")
1892   (let ((open-messages (notmuch-show-get-message-ids-for-open-messages)))
1893     (unless open-messages
1894       (error "No open messages to forward."))
1895     (notmuch-mua-new-forward-messages open-messages prompt-for-sender)))
1896
1897 (defun notmuch-show-resend-message (addresses)
1898   "Resend the current message."
1899   (interactive (list (notmuch-address-from-minibuffer "Resend to: ")))
1900   (when (y-or-n-p (concat "Confirm resend to " addresses " "))
1901     (notmuch-show-view-raw-message)
1902     (message-resend addresses)
1903     (notmuch-bury-or-kill-this-buffer)))
1904
1905 (defun notmuch-show-next-message (&optional pop-at-end)
1906   "Show the next message.
1907
1908 If a prefix argument is given and this is the last message in the
1909 thread, navigate to the next thread in the parent search buffer."
1910   (interactive "P")
1911   (if (notmuch-show-goto-message-next)
1912       (notmuch-show-message-adjust)
1913     (if pop-at-end
1914         (notmuch-show-next-thread)
1915       (goto-char (point-max)))))
1916
1917 (defun notmuch-show-previous-message ()
1918   "Show the previous message or the start of the current message."
1919   (interactive)
1920   (if (= (point) (notmuch-show-message-top))
1921       (notmuch-show-goto-message-previous)
1922     (notmuch-show-move-to-message-top))
1923   (notmuch-show-message-adjust))
1924
1925 (defun notmuch-show-next-open-message (&optional pop-at-end)
1926   "Show the next open message.
1927
1928 If a prefix argument is given and this is the last open message
1929 in the thread, navigate to the next thread in the parent search
1930 buffer. Return t if there was a next open message in the thread
1931 to show, nil otherwise."
1932   (interactive "P")
1933   (let (r)
1934     (while (and (setq r (notmuch-show-goto-message-next))
1935                 (not (notmuch-show-message-visible-p))))
1936     (if r
1937         (notmuch-show-message-adjust)
1938       (if pop-at-end
1939           (notmuch-show-next-thread)
1940         (goto-char (point-max))))
1941     r))
1942
1943 (defun notmuch-show-next-matching-message ()
1944   "Show the next matching message."
1945   (interactive)
1946   (let (r)
1947     (while (and (setq r (notmuch-show-goto-message-next))
1948                 (not (notmuch-show-get-prop :match))))
1949     (if r
1950         (notmuch-show-message-adjust)
1951       (goto-char (point-max)))))
1952
1953 (defun notmuch-show-open-if-matched ()
1954   "Open a message if it is matched (whether or not excluded)."
1955   (let ((props (notmuch-show-get-message-properties)))
1956     (notmuch-show-message-visible props (plist-get props :match))))
1957
1958 (defun notmuch-show-goto-first-wanted-message ()
1959   "Move to the first open message and mark it read"
1960   (goto-char (point-min))
1961   (unless (notmuch-show-message-visible-p)
1962     (notmuch-show-next-open-message))
1963   (when (eobp)
1964     ;; There are no matched non-excluded messages so open all matched
1965     ;; (necessarily excluded) messages and go to the first.
1966     (notmuch-show-mapc 'notmuch-show-open-if-matched)
1967     (force-window-update)
1968     (goto-char (point-min))
1969     (unless (notmuch-show-message-visible-p)
1970       (notmuch-show-next-open-message))))
1971
1972 (defun notmuch-show-previous-open-message ()
1973   "Show the previous open message."
1974   (interactive)
1975   (while (and (if (= (point) (notmuch-show-message-top))
1976                   (notmuch-show-goto-message-previous)
1977                 (notmuch-show-move-to-message-top))
1978               (not (notmuch-show-message-visible-p))))
1979   (notmuch-show-message-adjust))
1980
1981 (defun notmuch-show-view-raw-message ()
1982   "View the original source of the current message."
1983   (interactive)
1984   (let* ((id (notmuch-show-get-message-id))
1985          (buf (get-buffer-create (concat "*notmuch-raw-" id "*")))
1986          (inhibit-read-only t))
1987     (switch-to-buffer buf)
1988     (erase-buffer)
1989     (let ((coding-system-for-read 'no-conversion))
1990       (call-process notmuch-command nil t nil "show" "--format=raw" id))
1991     (goto-char (point-min))
1992     (set-buffer-modified-p nil)
1993     (setq buffer-read-only t)
1994     (view-buffer buf 'kill-buffer-if-not-modified)))
1995
1996 (defun notmuch-show-resume-message ()
1997   "Resume EDITING the current draft message."
1998   (interactive)
1999   (notmuch-draft-resume (notmuch-show-get-message-id)))
2000
2001 (put 'notmuch-show-pipe-message 'notmuch-doc
2002      "Pipe the contents of the current message to a command.")
2003 (put 'notmuch-show-pipe-message 'notmuch-prefix-doc
2004      "Pipe the thread as an mbox to a command.")
2005 (defun notmuch-show-pipe-message (entire-thread command)
2006   "Pipe the contents of the current message (or thread) to COMMAND.
2007
2008 COMMAND will be executed with the raw contents of the current
2009 email message as stdin. Anything printed by the command to stdout
2010 or stderr will appear in the *notmuch-pipe* buffer.
2011
2012 If ENTIRE-THREAD is non-nil (or when invoked with a prefix
2013 argument), COMMAND will receive all open messages in the current
2014 thread (formatted as an mbox) rather than only the current
2015 message."
2016   (interactive (let ((query-string (if current-prefix-arg
2017                                        "Pipe all open messages to command: "
2018                                      "Pipe message to command: ")))
2019                  (list current-prefix-arg (read-string query-string))))
2020   (let (shell-command)
2021     (if entire-thread
2022         (setq shell-command
2023               (concat notmuch-command " show --format=mbox --exclude=false "
2024                       (shell-quote-argument
2025                        (mapconcat 'identity (notmuch-show-get-message-ids-for-open-messages) " OR "))
2026                       " | " command))
2027       (setq shell-command
2028             (concat notmuch-command " show --format=raw "
2029                     (shell-quote-argument (notmuch-show-get-message-id)) " | " command)))
2030     (let ((cwd default-directory)
2031           (buf (get-buffer-create (concat "*notmuch-pipe*"))))
2032       (with-current-buffer buf
2033         (setq buffer-read-only nil)
2034         (erase-buffer)
2035         ;; Use the originating buffer's working directory instead of
2036         ;; that of the pipe buffer.
2037         (cd cwd)
2038         (let ((exit-code (call-process-shell-command shell-command nil buf)))
2039           (goto-char (point-max))
2040           (set-buffer-modified-p nil)
2041           (setq buffer-read-only t)
2042           (unless (zerop exit-code)
2043             (switch-to-buffer-other-window buf)
2044             (message (format "Command '%s' exited abnormally with code %d"
2045                              shell-command exit-code))))))))
2046
2047 (defun notmuch-show-tag-message (&rest tag-changes)
2048   "Change tags for the current message.
2049
2050 TAG-CHANGES is a list of tag operations for `notmuch-tag'."
2051   (let* ((current-tags (notmuch-show-get-tags))
2052          (new-tags (notmuch-update-tags current-tags tag-changes)))
2053     (unless (equal current-tags new-tags)
2054       (notmuch-tag (notmuch-show-get-message-id) tag-changes)
2055       (notmuch-show-set-tags new-tags))))
2056
2057 (defun notmuch-show-tag (tag-changes)
2058   "Change tags for the current message.
2059
2060 See `notmuch-tag' for information on the format of TAG-CHANGES."
2061   (interactive (list (notmuch-read-tag-changes (notmuch-show-get-tags)
2062                                                "Tag message")))
2063   (notmuch-tag (notmuch-show-get-message-id) tag-changes)
2064   (let* ((current-tags (notmuch-show-get-tags))
2065          (new-tags (notmuch-update-tags current-tags tag-changes)))
2066     (unless (equal current-tags new-tags)
2067       (notmuch-show-set-tags new-tags))))
2068
2069 (defun notmuch-show-tag-all (tag-changes)
2070   "Change tags for all messages in the current show buffer.
2071
2072 See `notmuch-tag' for information on the format of TAG-CHANGES."
2073   (interactive
2074    (list (let (tags)
2075            (notmuch-show-mapc
2076             (lambda () (setq tags (append (notmuch-show-get-tags) tags))))
2077            (notmuch-read-tag-changes tags "Tag thread"))))
2078   (notmuch-tag (notmuch-show-get-messages-ids-search) tag-changes)
2079   (notmuch-show-mapc
2080    (lambda ()
2081      (let* ((current-tags (notmuch-show-get-tags))
2082             (new-tags (notmuch-update-tags current-tags tag-changes)))
2083        (unless (equal current-tags new-tags)
2084          (notmuch-show-set-tags new-tags))))))
2085
2086 (defun notmuch-show-add-tag (tag-changes)
2087   "Change tags for the current message (defaulting to add).
2088
2089 Same as `notmuch-show-tag' but sets initial input to '+'."
2090   (interactive
2091    (list (notmuch-read-tag-changes (notmuch-show-get-tags) "Tag message" "+")))
2092   (notmuch-show-tag tag-changes))
2093
2094 (defun notmuch-show-remove-tag (tag-changes)
2095   "Change tags for the current message (defaulting to remove).
2096
2097 Same as `notmuch-show-tag' but sets initial input to '-'."
2098   (interactive
2099    (list (notmuch-read-tag-changes (notmuch-show-get-tags) "Tag message" "-")))
2100   (notmuch-show-tag tag-changes))
2101
2102 (defun notmuch-show-toggle-visibility-headers ()
2103   "Toggle the visibility of the current message headers."
2104   (interactive)
2105   (let ((props (notmuch-show-get-message-properties)))
2106     (notmuch-show-headers-visible
2107      props
2108      (not (plist-get props :headers-visible))))
2109   (force-window-update))
2110
2111 (defun notmuch-show-toggle-message ()
2112   "Toggle the visibility of the current message."
2113   (interactive)
2114   (let ((props (notmuch-show-get-message-properties)))
2115     (notmuch-show-message-visible
2116      props
2117      (not (plist-get props :message-visible))))
2118   (force-window-update))
2119
2120 (put 'notmuch-show-open-or-close-all 'notmuch-doc "Show all messages.")
2121 (put 'notmuch-show-open-or-close-all 'notmuch-prefix-doc "Hide all messages.")
2122 (defun notmuch-show-open-or-close-all ()
2123   "Set the visibility all of the messages in the current thread.
2124
2125 By default make all of the messages visible. With a prefix
2126 argument, hide all of the messages."
2127   (interactive)
2128   (save-excursion
2129     (goto-char (point-min))
2130     (loop do (notmuch-show-message-visible (notmuch-show-get-message-properties)
2131                                            (not current-prefix-arg))
2132           until (not (notmuch-show-goto-message-next))))
2133   (force-window-update))
2134
2135 (defun notmuch-show-next-button ()
2136   "Advance point to the next button in the buffer."
2137   (interactive)
2138   (forward-button 1))
2139
2140 (defun notmuch-show-previous-button ()
2141   "Move point back to the previous button in the buffer."
2142   (interactive)
2143   (backward-button 1))
2144
2145 (defun notmuch-show-next-thread (&optional show previous)
2146   "Move to the next item in the search results, if any.
2147
2148 If SHOW is non-nil, open the next item in a show
2149 buffer. Otherwise just highlight the next item in the search
2150 buffer. If PREVIOUS is non-nil, move to the previous item in the
2151 search results instead."
2152   (interactive "P")
2153   (let ((parent-buffer notmuch-show-parent-buffer))
2154     (notmuch-bury-or-kill-this-buffer)
2155     (when (buffer-live-p parent-buffer)
2156       (switch-to-buffer parent-buffer)
2157       (and (if previous
2158                (notmuch-search-previous-thread)
2159              (notmuch-search-next-thread))
2160            show
2161            (notmuch-search-show-thread)))))
2162
2163 (defun notmuch-show-next-thread-show ()
2164   "Show the next thread in the search results, if any."
2165   (interactive)
2166   (notmuch-show-next-thread t))
2167
2168 (defun notmuch-show-previous-thread-show ()
2169   "Show the previous thread in the search results, if any."
2170   (interactive)
2171   (notmuch-show-next-thread t t))
2172
2173 (put 'notmuch-show-archive-thread 'notmuch-prefix-doc
2174      "Un-archive each message in thread.")
2175 (defun notmuch-show-archive-thread (&optional unarchive)
2176   "Archive each message in thread.
2177
2178 Archive each message currently shown by applying the tag changes
2179 in `notmuch-archive-tags' to each. If a prefix argument is given,
2180 the messages will be \"unarchived\", i.e. the tag changes in
2181 `notmuch-archive-tags' will be reversed.
2182
2183 Note: This command is safe from any race condition of new messages
2184 being delivered to the same thread. It does not archive the
2185 entire thread, but only the messages shown in the current
2186 buffer."
2187   (interactive "P")
2188   (when notmuch-archive-tags
2189     (notmuch-show-tag-all
2190      (notmuch-tag-change-list notmuch-archive-tags unarchive))))
2191
2192 (defun notmuch-show-archive-thread-then-next ()
2193   "Archive all messages in the current buffer, then show next thread from search."
2194   (interactive)
2195   (notmuch-show-archive-thread)
2196   (notmuch-show-next-thread t))
2197
2198 (defun notmuch-show-archive-thread-then-exit ()
2199   "Archive all messages in the current buffer, then exit back to search results."
2200   (interactive)
2201   (notmuch-show-archive-thread)
2202   (notmuch-show-next-thread))
2203
2204 (put 'notmuch-show-archive-message 'notmuch-prefix-doc
2205      "Un-archive the current message.")
2206 (defun notmuch-show-archive-message (&optional unarchive)
2207   "Archive the current message.
2208
2209 Archive the current message by applying the tag changes in
2210 `notmuch-archive-tags' to it. If a prefix argument is given, the
2211 message will be \"unarchived\", i.e. the tag changes in
2212 `notmuch-archive-tags' will be reversed."
2213   (interactive "P")
2214   (when notmuch-archive-tags
2215     (apply 'notmuch-show-tag-message
2216            (notmuch-tag-change-list notmuch-archive-tags unarchive))))
2217
2218 (defun notmuch-show-archive-message-then-next-or-exit ()
2219   "Archive the current message, then show the next open message in the current thread.
2220
2221 If at the last open message in the current thread, then exit back
2222 to search results."
2223   (interactive)
2224   (notmuch-show-archive-message)
2225   (notmuch-show-next-open-message t))
2226
2227 (defun notmuch-show-archive-message-then-next-or-next-thread ()
2228   "Archive the current message, then show the next open message in the current thread.
2229
2230 If at the last open message in the current thread, then show next
2231 thread from search."
2232   (interactive)
2233   (notmuch-show-archive-message)
2234   (unless (notmuch-show-next-open-message)
2235     (notmuch-show-next-thread t)))
2236
2237 (defun notmuch-show-stash-cc ()
2238   "Copy CC field of current message to kill-ring."
2239   (interactive)
2240   (notmuch-common-do-stash (notmuch-show-get-cc)))
2241
2242 (defun notmuch-show-stash-date ()
2243   "Copy date of current message to kill-ring."
2244   (interactive)
2245   (notmuch-common-do-stash (notmuch-show-get-date)))
2246
2247 (defun notmuch-show-stash-filename ()
2248   "Copy filename of current message to kill-ring."
2249   (interactive)
2250   (notmuch-common-do-stash (notmuch-show-get-filename)))
2251
2252 (defun notmuch-show-stash-from ()
2253   "Copy From address of current message to kill-ring."
2254   (interactive)
2255   (notmuch-common-do-stash (notmuch-show-get-from)))
2256
2257 (put 'notmuch-show-stash-message-id 'notmuch-prefix-doc
2258      "Copy thread: query matching current thread to kill-ring.")
2259 (defun notmuch-show-stash-message-id (&optional stash-thread-id)
2260   "Copy id: query matching the current message to kill-ring.
2261
2262 If invoked with a prefix argument (or STASH-THREAD-ID is
2263 non-nil), copy thread: query matching the current thread to
2264 kill-ring."
2265   (interactive "P")
2266   (if stash-thread-id
2267       (notmuch-common-do-stash notmuch-show-thread-id)
2268     (notmuch-common-do-stash (notmuch-show-get-message-id))))
2269
2270 (defun notmuch-show-stash-message-id-stripped ()
2271   "Copy message ID of current message (sans `id:' prefix) to kill-ring."
2272   (interactive)
2273   (notmuch-common-do-stash (notmuch-show-get-message-id t)))
2274
2275 (defun notmuch-show-stash-subject ()
2276   "Copy Subject field of current message to kill-ring."
2277   (interactive)
2278   (notmuch-common-do-stash (notmuch-show-get-subject)))
2279
2280 (defun notmuch-show-stash-tags ()
2281   "Copy tags of current message to kill-ring as a comma separated list."
2282   (interactive)
2283   (notmuch-common-do-stash (mapconcat 'identity (notmuch-show-get-tags) ",")))
2284
2285 (defun notmuch-show-stash-to ()
2286   "Copy To address of current message to kill-ring."
2287   (interactive)
2288   (notmuch-common-do-stash (notmuch-show-get-to)))
2289
2290 (defun notmuch-show-stash-mlarchive-link (&optional mla)
2291   "Copy an ML Archive URI for the current message to the kill-ring.
2292
2293 This presumes that the message is available at the selected Mailing List Archive.
2294
2295 If optional argument MLA is non-nil, use the provided key instead of prompting
2296 the user (see `notmuch-show-stash-mlarchive-link-alist')."
2297   (interactive)
2298   (let ((url (cdr (assoc
2299                    (or mla
2300                        (let ((completion-ignore-case t))
2301                          (completing-read
2302                           "Mailing List Archive: "
2303                           notmuch-show-stash-mlarchive-link-alist
2304                           nil t nil nil
2305                           notmuch-show-stash-mlarchive-link-default)))
2306                    notmuch-show-stash-mlarchive-link-alist))))
2307     (notmuch-common-do-stash
2308      (if (functionp url)
2309          (funcall url (notmuch-show-get-message-id t))
2310        (concat url (notmuch-show-get-message-id t))))))
2311
2312 (defun notmuch-show-stash-mlarchive-link-and-go (&optional mla)
2313   "Copy an ML Archive URI for the current message to the kill-ring and visit it.
2314
2315 This presumes that the message is available at the selected Mailing List Archive.
2316
2317 If optional argument MLA is non-nil, use the provided key instead of prompting
2318 the user (see `notmuch-show-stash-mlarchive-link-alist')."
2319   (interactive)
2320   (notmuch-show-stash-mlarchive-link mla)
2321   (browse-url (current-kill 0 t)))
2322
2323 (defun notmuch-show-stash-git-helper (addresses prefix)
2324   "Escape, trim, quote, and add PREFIX to each address in list of ADDRESSES, and return the result as a single string."
2325   (mapconcat (lambda (x)
2326                (concat prefix "\""
2327                        ;; escape double-quotes
2328                        (replace-regexp-in-string
2329                         "\"" "\\\\\""
2330                         ;; trim leading and trailing spaces
2331                         (replace-regexp-in-string
2332                          "\\(^ *\\| *$\\)" ""
2333                          x)) "\""))
2334              addresses " "))
2335
2336 (put 'notmuch-show-stash-git-send-email 'notmuch-prefix-doc
2337      "Copy From/To/Cc of current message to kill-ring in a form suitable for pasting to git send-email command line.")
2338
2339 (defun notmuch-show-stash-git-send-email (&optional no-in-reply-to)
2340   "Copy From/To/Cc/Message-Id of current message to kill-ring in a form suitable for pasting to git send-email command line.
2341
2342 If invoked with a prefix argument (or NO-IN-REPLY-TO is non-nil),
2343 omit --in-reply-to=<Message-Id>."
2344   (interactive "P")
2345   (notmuch-common-do-stash
2346    (mapconcat 'identity
2347               (remove ""
2348                       (list
2349                        (notmuch-show-stash-git-helper
2350                         (message-tokenize-header (notmuch-show-get-from)) "--to=")
2351                        (notmuch-show-stash-git-helper
2352                         (message-tokenize-header (notmuch-show-get-to)) "--to=")
2353                        (notmuch-show-stash-git-helper
2354                         (message-tokenize-header (notmuch-show-get-cc)) "--cc=")
2355                        (unless no-in-reply-to
2356                          (notmuch-show-stash-git-helper
2357                           (list (notmuch-show-get-message-id t)) "--in-reply-to="))))
2358               " ")))
2359
2360 ;; Interactive part functions and their helpers
2361
2362 (defun notmuch-show-generate-part-buffer (msg part)
2363   "Return a temporary buffer containing the specified part's content."
2364   (let ((buf (generate-new-buffer " *notmuch-part*"))
2365         (process-crypto notmuch-show-process-crypto))
2366     (with-current-buffer buf
2367       ;; This is always used in the content of mm handles, which
2368       ;; expect undecoded, binary part content.
2369       (insert (notmuch-get-bodypart-binary msg part process-crypto)))
2370     buf))
2371
2372 (defun notmuch-show-current-part-handle (&optional mime-type)
2373   "Return an mm-handle for the part containing point.
2374
2375 This creates a temporary buffer for the part's content; the
2376 caller is responsible for killing this buffer as appropriate.  If
2377 MIME-TYPE is given then set the handle's mime-type to MIME-TYPE."
2378   (let* ((msg (notmuch-show-get-message-properties))
2379          (part (notmuch-show-get-part-properties))
2380          (buf (notmuch-show-generate-part-buffer msg part))
2381          (computed-type (or mime-type (plist-get part :computed-type)))
2382          (filename (plist-get part :filename))
2383          (disposition (if filename `(attachment (filename . ,filename)))))
2384     (mm-make-handle buf (list computed-type) nil nil disposition)))
2385
2386 (defun notmuch-show-apply-to-current-part-handle (fn &optional mime-type)
2387   "Apply FN to an mm-handle for the part containing point.
2388
2389 This ensures that the temporary buffer created for the mm-handle
2390 is destroyed when FN returns. If MIME-TYPE is given then force
2391 part to be treated as if it had that mime-type."
2392   (let ((handle (notmuch-show-current-part-handle mime-type)))
2393     ;; emacs 24.3+ puts stdout/stderr into the calling buffer so we
2394     ;; call it from a temp-buffer, unless
2395     ;; notmuch-show-attachment-debug is non-nil in which case we put
2396     ;; it in " *notmuch-part*".
2397     (unwind-protect
2398         (if notmuch-show-attachment-debug
2399             (with-current-buffer (generate-new-buffer " *notmuch-part*")
2400               (funcall fn handle))
2401           (with-temp-buffer
2402             (funcall fn handle)))
2403       (kill-buffer (mm-handle-buffer handle)))))
2404
2405 (defun notmuch-show-part-button-default (&optional button)
2406   (interactive)
2407   (let ((button (or button (button-at (point)))))
2408     ;; Try to toggle the part, if that fails then call the default
2409     ;; action. The toggle fails if the part has no emacs renderable
2410     ;; content.
2411     (unless (notmuch-show-toggle-part-invisibility button)
2412       (call-interactively notmuch-show-part-button-default-action))))
2413
2414 (defun notmuch-show-save-part ()
2415   "Save the MIME part containing point to a file."
2416   (interactive)
2417   (notmuch-show-apply-to-current-part-handle #'mm-save-part))
2418
2419 (defun notmuch-show-view-part ()
2420   "View the MIME part containing point in an external viewer."
2421   (interactive)
2422   ;; Set mm-inlined-types to nil to force an external viewer
2423   (let ((mm-inlined-types nil))
2424     (notmuch-show-apply-to-current-part-handle #'mm-display-part)))
2425
2426 (defun notmuch-show-interactively-view-part ()
2427   "View the MIME part containing point, prompting for a viewer."
2428   (interactive)
2429   (notmuch-show-apply-to-current-part-handle #'mm-interactively-view-part))
2430
2431 (defun notmuch-show-pipe-part ()
2432   "Pipe the MIME part containing point to an external command."
2433   (interactive)
2434   (notmuch-show-apply-to-current-part-handle #'mm-pipe-part))
2435
2436
2437 (defun notmuch-show--mm-display-part (handle)
2438   "Use mm-display-part to display HANDLE in a new buffer.
2439
2440 If the part is displayed in an external application then close
2441 the new buffer."
2442   (let ((buf (get-buffer-create (generate-new-buffer-name
2443                                  (concat " *notmuch-internal-part*")))))
2444     (switch-to-buffer buf)
2445     (if (eq (mm-display-part handle) 'external)
2446         (kill-buffer buf)
2447       (goto-char (point-min))
2448       (set-buffer-modified-p nil)
2449       (view-buffer buf 'kill-buffer-if-not-modified))))
2450
2451 (defun notmuch-show-choose-mime-of-part (mime-type)
2452   "Choose the mime type to use for displaying part"
2453   (interactive
2454    (list (completing-read "Mime type to use (default text/plain): "
2455                           (mailcap-mime-types) nil nil nil nil "text/plain")))
2456   (notmuch-show-apply-to-current-part-handle #'notmuch-show--mm-display-part mime-type))
2457
2458 (provide 'notmuch-show)
2459
2460 ;;; notmuch-show.el ends here