git.notmuchmail.org Git - notmuch/blob - emacs/notmuch-show.el

   1 ;; notmuch-show.el --- displaying notmuch forests.
   2 ;;
   3 ;; Copyright © Carl Worth
   4 ;; Copyright © David Edmondson
   5 ;;
   6 ;; This file is part of Notmuch.
   7 ;;
   8 ;; Notmuch is free software: you can redistribute it and/or modify it
   9 ;; under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation, either version 3 of the License, or
  11 ;; (at your option) any later version.
  12 ;;
  13 ;; Notmuch is distributed in the hope that it will be useful, but
  14 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 ;; General Public License for more details.
  17 ;;
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with Notmuch.  If not, see <http://www.gnu.org/licenses/>.
  20 ;;
  21 ;; Authors: Carl Worth <cworth@cworth.org>
  22 ;;          David Edmondson <dme@dme.org>
  23
  24 (eval-when-compile (require 'cl))
  25 (require 'mm-view)
  26 (require 'message)
  27 (require 'mm-decode)
  28 (require 'mailcap)
  29 (require 'icalendar)
  30 (require 'goto-addr)
  31
  32 (require 'notmuch-lib)
  33 (require 'notmuch-tag)
  34 (require 'notmuch-query)
  35 (require 'notmuch-wash)
  36 (require 'notmuch-mua)
  37 (require 'notmuch-crypto)
  38 (require 'notmuch-print)
  39
  40 (declare-function notmuch-call-notmuch-process "notmuch" (&rest args))
  41 (declare-function notmuch-fontify-headers "notmuch" nil)
  42 (declare-function notmuch-search-next-thread "notmuch" nil)
  43 (declare-function notmuch-search-show-thread "notmuch" nil)
  44
  45 (defcustom notmuch-message-headers '("Subject" "To" "Cc" "Date")
  46   "Headers that should be shown in a message, in this order.
  47
  48 For an open message, all of these headers will be made visible
  49 according to `notmuch-message-headers-visible' or can be toggled
  50 with `notmuch-show-toggle-visibility-headers'. For a closed message,
  51 only the first header in the list will be visible."
  52   :type '(repeat string)
  53   :group 'notmuch-show)
  54
  55 (defcustom notmuch-message-headers-visible t
  56   "Should the headers be visible by default?
  57
  58 If this value is non-nil, then all of the headers defined in
  59 `notmuch-message-headers' will be visible by default in the display
  60 of each message. Otherwise, these headers will be hidden and
  61 `notmuch-show-toggle-visibility-headers' can be used to make them
  62 visible for any given message."
  63   :type 'boolean
  64   :group 'notmuch-show)
  65
  66 (defcustom notmuch-show-relative-dates t
  67   "Display relative dates in the message summary line."
  68   :type 'boolean
  69   :group 'notmuch-show)
  70
  71 (defvar notmuch-show-markup-headers-hook '(notmuch-show-colour-headers)
  72   "A list of functions called to decorate the headers listed in
  73 `notmuch-message-headers'.")
  74
  75 (defcustom notmuch-show-hook '(notmuch-show-turn-on-visual-line-mode)
  76   "Functions called after populating a `notmuch-show' buffer."
  77   :type 'hook
  78   :options '(notmuch-show-turn-on-visual-line-mode)
  79   :group 'notmuch-show
  80   :group 'notmuch-hooks)
  81
  82 (defcustom notmuch-show-insert-text/plain-hook '(notmuch-wash-wrap-long-lines
  83                                                  notmuch-wash-tidy-citations
  84                                                  notmuch-wash-elide-blank-lines
  85                                                  notmuch-wash-excerpt-citations)
  86   "Functions used to improve the display of text/plain parts."
  87   :type 'hook
  88   :options '(notmuch-wash-convert-inline-patch-to-part
  89              notmuch-wash-wrap-long-lines
  90              notmuch-wash-tidy-citations
  91              notmuch-wash-elide-blank-lines
  92              notmuch-wash-excerpt-citations)
  93   :group 'notmuch-show
  94   :group 'notmuch-hooks)
  95
  96 ;; Mostly useful for debugging.
  97 (defcustom notmuch-show-all-multipart/alternative-parts t
  98   "Should all parts of multipart/alternative parts be shown?"
  99   :type 'boolean
 100   :group 'notmuch-show)
 101
 102 (defcustom notmuch-show-indent-messages-width 1
 103   "Width of message indentation in threads.
 104
 105 Messages are shown indented according to their depth in a thread.
 106 This variable determines the width of this indentation measured
 107 in number of blanks.  Defaults to `1', choose `0' to disable
 108 indentation."
 109   :type 'integer
 110   :group 'notmuch-show)
 111
 112 (defcustom notmuch-show-indent-multipart nil
 113   "Should the sub-parts of a multipart/* part be indented?"
 114   ;; dme: Not sure which is a good default.
 115   :type 'boolean
 116   :group 'notmuch-show)
 117
 118 (defcustom notmuch-show-part-button-default-action 'notmuch-show-save-part
 119   "Default part header button action (on ENTER or mouse click)."
 120   :group 'notmuch-show
 121   :type '(choice (const :tag "Save part"
 122                         notmuch-show-save-part)
 123                  (const :tag "View part"
 124                         notmuch-show-view-part)
 125                  (const :tag "View interactively"
 126                         notmuch-show-interactively-view-part)))
 127
 128 (defcustom notmuch-show-only-matching-messages nil
 129   "Only matching messages are shown by default."
 130   :type 'boolean
 131   :group 'notmuch-show)
 132
 133 (defvar notmuch-show-thread-id nil)
 134 (make-variable-buffer-local 'notmuch-show-thread-id)
 135 (put 'notmuch-show-thread-id 'permanent-local t)
 136
 137 (defvar notmuch-show-parent-buffer nil)
 138 (make-variable-buffer-local 'notmuch-show-parent-buffer)
 139 (put 'notmuch-show-parent-buffer 'permanent-local t)
 140
 141 (defvar notmuch-show-query-context nil)
 142 (make-variable-buffer-local 'notmuch-show-query-context)
 143 (put 'notmuch-show-query-context 'permanent-local t)
 144
 145 (defvar notmuch-show-process-crypto nil)
 146 (make-variable-buffer-local 'notmuch-show-process-crypto)
 147 (put 'notmuch-show-process-crypto 'permanent-local t)
 148
 149 (defvar notmuch-show-elide-non-matching-messages nil)
 150 (make-variable-buffer-local 'notmuch-show-elide-non-matching-messages)
 151 (put 'notmuch-show-elide-non-matching-messages 'permanent-local t)
 152
 153 (defvar notmuch-show-indent-content t)
 154 (make-variable-buffer-local 'notmuch-show-indent-content)
 155 (put 'notmuch-show-indent-content 'permanent-local t)
 156
 157 (defcustom notmuch-show-stash-mlarchive-link-alist
 158   '(("Gmane" . "http://mid.gmane.org/")
 159     ("MARC" . "http://marc.info/?i=")
 160     ("Mail Archive, The" . "http://mail-archive.com/search?l=mid&q=")
 161     ;; FIXME: can these services be searched by `Message-Id' ?
 162     ;; ("MarkMail" . "http://markmail.org/")
 163     ;; ("Nabble" . "http://nabble.com/")
 164     ;; ("opensubscriber" . "http://opensubscriber.com/")
 165     )
 166   "List of Mailing List Archives to use when stashing links.
 167
 168 These URIs are concatenated with the current message's
 169 Message-Id in `notmuch-show-stash-mlarchive-link'."
 170   :type '(alist :key-type (string :tag "Name")
 171                 :value-type (string :tag "URL"))
 172   :group 'notmuch-show)
 173
 174 (defcustom notmuch-show-stash-mlarchive-link-default "Gmane"
 175   "Default Mailing List Archive to use when stashing links.
 176
 177 This is used when `notmuch-show-stash-mlarchive-link' isn't
 178 provided with an MLA argument nor `completing-read' input."
 179   :type `(choice
 180           ,@(mapcar
 181              (lambda (mla)
 182                (list 'const :tag (car mla) :value (car mla)))
 183              notmuch-show-stash-mlarchive-link-alist))
 184   :group 'notmuch-show)
 185
 186 (defcustom notmuch-show-mark-read-tags '("-unread")
 187   "List of tag changes to apply to a message when it is marked as read.
 188
 189 Tags starting with \"+\" (or not starting with either \"+\" or
 190 \"-\") in the list will be added, and tags starting with \"-\"
 191 will be removed from the message being marked as read.
 192
 193 For example, if you wanted to remove an \"unread\" tag and add a
 194 \"read\" tag (which would make little sense), you would set:
 195     (\"-unread\" \"+read\")"
 196   :type '(repeat string)
 197   :group 'notmuch-show)
 198
 199
 200 (defmacro with-current-notmuch-show-message (&rest body)
 201   "Evaluate body with current buffer set to the text of current message"
 202   `(save-excursion
 203      (let ((id (notmuch-show-get-message-id)))
 204        (let ((buf (generate-new-buffer (concat "*notmuch-msg-" id "*"))))
 205          (with-current-buffer buf
 206             (call-process notmuch-command nil t nil "show" "--format=raw" id)
 207            ,@body)
 208          (kill-buffer buf)))))
 209
 210 (defun notmuch-show-turn-on-visual-line-mode ()
 211   "Enable Visual Line mode."
 212   (visual-line-mode t))
 213
 214 (defun notmuch-show-view-all-mime-parts ()
 215   "Use external viewers to view all attachments from the current message."
 216   (interactive)
 217   (with-current-notmuch-show-message
 218    ;; We override the mm-inline-media-tests to indicate which message
 219    ;; parts are already sufficiently handled by the original
 220    ;; presentation of the message in notmuch-show mode. These parts
 221    ;; will be inserted directly into the temporary buffer of
 222    ;; with-current-notmuch-show-message and silently discarded.
 223    ;;
 224    ;; Any MIME part not explicitly mentioned here will be handled by an
 225    ;; external viewer as configured in the various mailcap files.
 226    (let ((mm-inline-media-tests '(
 227                                   ("text/.*" ignore identity)
 228                                   ("application/pgp-signature" ignore identity)
 229                                   ("multipart/alternative" ignore identity)
 230                                   ("multipart/mixed" ignore identity)
 231                                   ("multipart/related" ignore identity)
 232                                  )))
 233      (mm-display-parts (mm-dissect-buffer)))))
 234
 235 (defun notmuch-foreach-mime-part (function mm-handle)
 236   (cond ((stringp (car mm-handle))
 237          (dolist (part (cdr mm-handle))
 238            (notmuch-foreach-mime-part function part)))
 239         ((bufferp (car mm-handle))
 240          (funcall function mm-handle))
 241         (t (dolist (part mm-handle)
 242              (notmuch-foreach-mime-part function part)))))
 243
 244 (defun notmuch-count-attachments (mm-handle)
 245   (let ((count 0))
 246     (notmuch-foreach-mime-part
 247      (lambda (p)
 248        (let ((disposition (mm-handle-disposition p)))
 249          (and (listp disposition)
 250               (or (equal (car disposition) "attachment")
 251                   (and (equal (car disposition) "inline")
 252                        (assq 'filename disposition)))
 253               (incf count))))
 254      mm-handle)
 255     count))
 256
 257 (defun notmuch-save-attachments (mm-handle &optional queryp)
 258   (notmuch-foreach-mime-part
 259    (lambda (p)
 260      (let ((disposition (mm-handle-disposition p)))
 261        (and (listp disposition)
 262             (or (equal (car disposition) "attachment")
 263                 (and (equal (car disposition) "inline")
 264                      (assq 'filename disposition)))
 265             (or (not queryp)
 266                 (y-or-n-p
 267                  (concat "Save '" (cdr (assq 'filename disposition)) "' ")))
 268             (mm-save-part p))))
 269    mm-handle))
 270
 271 (defun notmuch-show-save-attachments ()
 272   "Save all attachments from the current message."
 273   (interactive)
 274   (with-current-notmuch-show-message
 275    (let ((mm-handle (mm-dissect-buffer)))
 276      (notmuch-save-attachments
 277       mm-handle (> (notmuch-count-attachments mm-handle) 1))))
 278   (message "Done"))
 279
 280 (defun notmuch-show-with-message-as-text (fn)
 281   "Apply FN to a text representation of the current message.
 282
 283 FN is called with one argument, the message properties. It should
 284 operation on the contents of the current buffer."
 285
 286   ;; Remake the header to ensure that all information is available.
 287   (let* ((to (notmuch-show-get-to))
 288          (cc (notmuch-show-get-cc))
 289          (from (notmuch-show-get-from))
 290          (subject (notmuch-show-get-subject))
 291          (date (notmuch-show-get-date))
 292          (tags (notmuch-show-get-tags))
 293          (depth (notmuch-show-get-depth))
 294
 295          (header (concat
 296                   "Subject: " subject "\n"
 297                   "To: " to "\n"
 298                   (if (not (string= cc ""))
 299                       (concat "Cc: " cc "\n")
 300                     "")
 301                   "From: " from "\n"
 302                   "Date: " date "\n"
 303                   (if tags
 304                       (concat "Tags: "
 305                               (mapconcat #'identity tags ", ") "\n")
 306                     "")))
 307          (all (buffer-substring (notmuch-show-message-top)
 308                                 (notmuch-show-message-bottom)))
 309
 310          (props (notmuch-show-get-message-properties))
 311          (indenting notmuch-show-indent-content))
 312     (with-temp-buffer
 313       (insert all)
 314       (if indenting
 315           (indent-rigidly (point-min) (point-max) (- depth)))
 316       ;; Remove the original header.
 317       (goto-char (point-min))
 318       (re-search-forward "^$" (point-max) nil)
 319       (delete-region (point-min) (point))
 320       (insert header)
 321       (funcall fn props))))
 322
 323 (defun notmuch-show-print-message ()
 324   "Print the current message."
 325   (interactive)
 326   (notmuch-show-with-message-as-text 'notmuch-print-message))
 327
 328 (defun notmuch-show-fontify-header ()
 329   (let ((face (cond
 330                ((looking-at "[Tt]o:")
 331                 'message-header-to)
 332                ((looking-at "[Bb]?[Cc][Cc]:")
 333                 'message-header-cc)
 334                ((looking-at "[Ss]ubject:")
 335                 'message-header-subject)
 336                ((looking-at "[Ff]rom:")
 337                 'message-header-from)
 338                (t
 339                 'message-header-other))))
 340
 341     (overlay-put (make-overlay (point) (re-search-forward ":"))
 342                  'face 'message-header-name)
 343     (overlay-put (make-overlay (point) (re-search-forward ".*$"))
 344                  'face face)))
 345
 346 (defun notmuch-show-colour-headers ()
 347   "Apply some colouring to the current headers."
 348   (goto-char (point-min))
 349   (while (looking-at "^[A-Za-z][-A-Za-z0-9]*:")
 350     (notmuch-show-fontify-header)
 351     (forward-line)))
 352
 353 (defun notmuch-show-spaces-n (n)
 354   "Return a string comprised of `n' spaces."
 355   (make-string n ? ))
 356
 357 (defun notmuch-show-update-tags (tags)
 358   "Update the displayed tags of the current message."
 359   (save-excursion
 360     (goto-char (notmuch-show-message-top))
 361     (if (re-search-forward "(\\([^()]*\\))$" (line-end-position) t)
 362         (let ((inhibit-read-only t))
 363           (replace-match (concat "("
 364                                  (propertize (mapconcat 'identity tags " ")
 365                                              'face 'notmuch-tag-face)
 366                                  ")"))))))
 367
 368 (defun notmuch-show-clean-address (address)
 369   "Try to clean a single email ADDRESS for display.  Return
 370 unchanged ADDRESS if parsing fails."
 371   (condition-case nil
 372     (let (p-name p-address)
 373       ;; It would be convenient to use `mail-header-parse-address',
 374       ;; but that expects un-decoded mailbox parts, whereas our
 375       ;; mailbox parts are already decoded (and hence may contain
 376       ;; UTF-8). Given that notmuch should handle most of the awkward
 377       ;; cases, some simple string deconstruction should be sufficient
 378       ;; here.
 379       (cond
 380        ;; "User <user@dom.ain>" style.
 381        ((string-match "\\(.*\\) <\\(.*\\)>" address)
 382         (setq p-name (match-string 1 address)
 383               p-address (match-string 2 address)))
 384
 385        ;; "<user@dom.ain>" style.
 386        ((string-match "<\\(.*\\)>" address)
 387         (setq p-address (match-string 1 address)))
 388
 389        ;; Everything else.
 390        (t
 391         (setq p-address address)))
 392
 393       (when p-name
 394         ;; Remove elements of the mailbox part that are not relevant for
 395         ;; display, even if they are required during transport:
 396         ;;
 397         ;; Backslashes.
 398         (setq p-name (replace-regexp-in-string "\\\\" "" p-name))
 399
 400         ;; Outer single and double quotes, which might be nested.
 401         (loop
 402          with start-of-loop
 403          do (setq start-of-loop p-name)
 404
 405          when (string-match "^\"\\(.*\\)\"$" p-name)
 406          do (setq p-name (match-string 1 p-name))
 407
 408          when (string-match "^'\\(.*\\)'$" p-name)
 409          do (setq p-name (match-string 1 p-name))
 410
 411          until (string= start-of-loop p-name)))
 412
 413       ;; If the address is 'foo@bar.com <foo@bar.com>' then show just
 414       ;; 'foo@bar.com'.
 415       (when (string= p-name p-address)
 416         (setq p-name nil))
 417
 418       ;; If no name results, return just the address.
 419       (if (not p-name)
 420           p-address
 421         ;; Otherwise format the name and address together.
 422         (concat p-name " <" p-address ">")))
 423     (error address)))
 424
 425 (defun notmuch-show-insert-headerline (headers date tags depth)
 426   "Insert a notmuch style headerline based on HEADERS for a
 427 message at DEPTH in the current thread."
 428   (let ((start (point)))
 429     (insert (notmuch-show-spaces-n (* notmuch-show-indent-messages-width depth))
 430             (notmuch-show-clean-address (plist-get headers :From))
 431             " ("
 432             date
 433             ") ("
 434             (propertize (mapconcat 'identity tags " ")
 435                         'face 'notmuch-tag-face)
 436             ")\n")
 437     (overlay-put (make-overlay start (point)) 'face 'notmuch-message-summary-face)))
 438
 439 (defun notmuch-show-insert-header (header header-value)
 440   "Insert a single header."
 441   (insert header ": " header-value "\n"))
 442
 443 (defun notmuch-show-insert-headers (headers)
 444   "Insert the headers of the current message."
 445   (let ((start (point)))
 446     (mapc (lambda (header)
 447             (let* ((header-symbol (intern (concat ":" header)))
 448                    (header-value (plist-get headers header-symbol)))
 449               (if (and header-value
 450                        (not (string-equal "" header-value)))
 451                   (notmuch-show-insert-header header header-value))))
 452           notmuch-message-headers)
 453     (save-excursion
 454       (save-restriction
 455         (narrow-to-region start (point-max))
 456         (run-hooks 'notmuch-show-markup-headers-hook)))))
 457
 458 (define-button-type 'notmuch-show-part-button-type
 459   'action 'notmuch-show-part-button-default
 460   'keymap 'notmuch-show-part-button-map
 461   'follow-link t
 462   'face 'message-mml)
 463
 464 (defvar notmuch-show-part-button-map
 465   (let ((map (make-sparse-keymap)))
 466     (set-keymap-parent map button-map)
 467     (define-key map "s" 'notmuch-show-part-button-save)
 468     (define-key map "v" 'notmuch-show-part-button-view)
 469     (define-key map "o" 'notmuch-show-part-button-interactively-view)
 470     (define-key map "|" 'notmuch-show-part-button-pipe)
 471     map)
 472   "Submap for button commands")
 473 (fset 'notmuch-show-part-button-map notmuch-show-part-button-map)
 474
 475 (defun notmuch-show-insert-part-header (nth content-type declared-type &optional name comment)
 476   (let ((button))
 477     (setq button
 478           (insert-button
 479            (concat "[ "
 480                    (if name (concat name ": ") "")
 481                    declared-type
 482                    (if (not (string-equal declared-type content-type))
 483                        (concat " (as " content-type ")")
 484                      "")
 485                    (or comment "")
 486                    " ]")
 487            :type 'notmuch-show-part-button-type
 488            :notmuch-part nth
 489            :notmuch-filename name
 490            :notmuch-content-type content-type))
 491     (insert "\n")
 492     ;; return button
 493     button))
 494
 495 ;; Functions handling particular MIME parts.
 496
 497 (defmacro notmuch-with-temp-part-buffer (message-id nth &rest body)
 498   (declare (indent 2))
 499   (let ((process-crypto (make-symbol "process-crypto")))
 500     `(let ((,process-crypto notmuch-show-process-crypto))
 501        (with-temp-buffer
 502          (setq notmuch-show-process-crypto ,process-crypto)
 503          ;; Always acquires the part via `notmuch part', even if it is
 504          ;; available in the JSON output.
 505          (insert (notmuch-get-bodypart-internal ,message-id ,nth notmuch-show-process-crypto))
 506          ,@body))))
 507
 508 (defun notmuch-show-save-part (message-id nth &optional filename content-type)
 509   (notmuch-with-temp-part-buffer message-id nth
 510     (let ((file (read-file-name
 511                  "Filename to save as: "
 512                  (or mailcap-download-directory "~/")
 513                  nil nil
 514                  filename)))
 515       ;; Don't re-compress .gz & al.  Arguably we should make
 516       ;; `file-name-handler-alist' nil, but that would chop
 517       ;; ange-ftp, which is reasonable to use here.
 518       (mm-write-region (point-min) (point-max) file nil nil nil 'no-conversion t))))
 519
 520 (defun notmuch-show-view-part (message-id nth &optional filename content-type )
 521   (notmuch-with-temp-part-buffer message-id nth
 522     ;; set mm-inlined-types to nil to force an external viewer
 523     (let ((handle (mm-make-handle (current-buffer) (list content-type)))
 524           (mm-inlined-types nil))
 525       ;; We override mm-save-part as notmuch-show-save-part is better
 526       ;; since it offers the filename. We need to lexically bind
 527       ;; everything we need for notmuch-show-save-part to prevent
 528       ;; potential dynamic shadowing.
 529       (lexical-let ((message-id message-id)
 530                     (nth nth)
 531                     (filename filename)
 532                     (content-type content-type))
 533         (flet ((mm-save-part (&rest args) (notmuch-show-save-part
 534                                            message-id nth filename content-type)))
 535           (mm-display-part handle))))))
 536
 537 (defun notmuch-show-interactively-view-part (message-id nth &optional filename content-type)
 538   (notmuch-with-temp-part-buffer message-id nth
 539     (let ((handle (mm-make-handle (current-buffer) (list content-type))))
 540       (mm-interactively-view-part handle))))
 541
 542 (defun notmuch-show-pipe-part (message-id nth &optional filename content-type)
 543   (notmuch-with-temp-part-buffer message-id nth
 544     (let ((handle (mm-make-handle (current-buffer) (list content-type))))
 545       (mm-pipe-part handle))))
 546
 547 (defun notmuch-show-multipart/*-to-list (part)
 548   (mapcar (lambda (inner-part) (plist-get inner-part :content-type))
 549           (plist-get part :content)))
 550
 551 (defun notmuch-show-insert-part-multipart/alternative (msg part content-type nth depth declared-type)
 552   (notmuch-show-insert-part-header nth declared-type content-type nil)
 553   (let ((chosen-type (car (notmuch-multipart/alternative-choose (notmuch-show-multipart/*-to-list part))))
 554         (inner-parts (plist-get part :content))
 555         (start (point)))
 556     ;; This inserts all parts of the chosen type rather than just one,
 557     ;; but it's not clear that this is the wrong thing to do - which
 558     ;; should be chosen if there are more than one that match?
 559     (mapc (lambda (inner-part)
 560             (let ((inner-type (plist-get inner-part :content-type)))
 561               (if (or notmuch-show-all-multipart/alternative-parts
 562                       (string= chosen-type inner-type))
 563                   (notmuch-show-insert-bodypart msg inner-part depth)
 564                 (notmuch-show-insert-part-header (plist-get inner-part :id) inner-type inner-type nil " (not shown)"))))
 565           inner-parts)
 566
 567     (when notmuch-show-indent-multipart
 568       (indent-rigidly start (point) 1)))
 569   t)
 570
 571 (defun notmuch-show-setup-w3m ()
 572   "Instruct w3m how to retrieve content from a \"related\" part of a message."
 573   (interactive)
 574   (if (boundp 'w3m-cid-retrieve-function-alist)
 575     (unless (assq 'notmuch-show-mode w3m-cid-retrieve-function-alist)
 576       (push (cons 'notmuch-show-mode 'notmuch-show-w3m-cid-retrieve)
 577             w3m-cid-retrieve-function-alist)))
 578   (setq mm-inline-text-html-with-images t))
 579
 580 (defvar w3m-current-buffer) ;; From `w3m.el'.
 581 (defvar notmuch-show-w3m-cid-store nil)
 582 (make-variable-buffer-local 'notmuch-show-w3m-cid-store)
 583
 584 (defun notmuch-show-w3m-cid-store-internal (content-id
 585                                             message-id
 586                                             part-number
 587                                             content-type
 588                                             content)
 589   (push (list content-id
 590               message-id
 591               part-number
 592               content-type
 593               content)
 594         notmuch-show-w3m-cid-store))
 595
 596 (defun notmuch-show-w3m-cid-store (msg part)
 597   (let ((content-id (plist-get part :content-id)))
 598     (when content-id
 599       (notmuch-show-w3m-cid-store-internal (concat "cid:" content-id)
 600                                            (plist-get msg :id)
 601                                            (plist-get part :id)
 602                                            (plist-get part :content-type)
 603                                            nil))))
 604
 605 (defun notmuch-show-w3m-cid-retrieve (url &rest args)
 606   (let ((matching-part (with-current-buffer w3m-current-buffer
 607                          (assoc url notmuch-show-w3m-cid-store))))
 608     (if matching-part
 609         (let ((message-id (nth 1 matching-part))
 610               (part-number (nth 2 matching-part))
 611               (content-type (nth 3 matching-part))
 612               (content (nth 4 matching-part)))
 613           ;; If we don't already have the content, get it and cache
 614           ;; it, as some messages reference the same cid: part many
 615           ;; times (hundreds!), which results in many calls to
 616           ;; `notmuch part'.
 617           (unless content
 618             (setq content (notmuch-get-bodypart-internal (notmuch-id-to-query message-id)
 619                                                               part-number notmuch-show-process-crypto))
 620             (with-current-buffer w3m-current-buffer
 621               (notmuch-show-w3m-cid-store-internal url
 622                                                    message-id
 623                                                    part-number
 624                                                    content-type
 625                                                    content)))
 626           (insert content)
 627           content-type)
 628       nil)))
 629
 630 (defun notmuch-show-insert-part-multipart/related (msg part content-type nth depth declared-type)
 631   (notmuch-show-insert-part-header nth declared-type content-type nil)
 632   (let ((inner-parts (plist-get part :content))
 633         (start (point)))
 634
 635     ;; We assume that the first part is text/html and the remainder
 636     ;; things that it references.
 637
 638     ;; Stash the non-primary parts.
 639     (mapc (lambda (part)
 640             (notmuch-show-w3m-cid-store msg part))
 641           (cdr inner-parts))
 642
 643     ;; Render the primary part.
 644     (notmuch-show-insert-bodypart msg (car inner-parts) depth)
 645
 646     (when notmuch-show-indent-multipart
 647       (indent-rigidly start (point) 1)))
 648   t)
 649
 650 (defun notmuch-show-insert-part-multipart/signed (msg part content-type nth depth declared-type)
 651   (let ((button (notmuch-show-insert-part-header nth declared-type content-type nil)))
 652     (button-put button 'face 'notmuch-crypto-part-header)
 653     ;; add signature status button if sigstatus provided
 654     (if (plist-member part :sigstatus)
 655         (let* ((from (notmuch-show-get-header :From msg))
 656                (sigstatus (car (plist-get part :sigstatus))))
 657           (notmuch-crypto-insert-sigstatus-button sigstatus from))
 658       ;; if we're not adding sigstatus, tell the user how they can get it
 659       (button-put button 'help-echo "Set notmuch-crypto-process-mime to process cryptographic MIME parts.")))
 660
 661   (let ((inner-parts (plist-get part :content))
 662         (start (point)))
 663     ;; Show all of the parts.
 664     (mapc (lambda (inner-part)
 665             (notmuch-show-insert-bodypart msg inner-part depth))
 666           inner-parts)
 667
 668     (when notmuch-show-indent-multipart
 669       (indent-rigidly start (point) 1)))
 670   t)
 671
 672 (defun notmuch-show-insert-part-multipart/encrypted (msg part content-type nth depth declared-type)
 673   (let ((button (notmuch-show-insert-part-header nth declared-type content-type nil)))
 674     (button-put button 'face 'notmuch-crypto-part-header)
 675     ;; add encryption status button if encstatus specified
 676     (if (plist-member part :encstatus)
 677         (let ((encstatus (car (plist-get part :encstatus))))
 678           (notmuch-crypto-insert-encstatus-button encstatus)
 679           ;; add signature status button if sigstatus specified
 680           (if (plist-member part :sigstatus)
 681               (let* ((from (notmuch-show-get-header :From msg))
 682                      (sigstatus (car (plist-get part :sigstatus))))
 683                 (notmuch-crypto-insert-sigstatus-button sigstatus from))))
 684       ;; if we're not adding encstatus, tell the user how they can get it
 685       (button-put button 'help-echo "Set notmuch-crypto-process-mime to process cryptographic MIME parts.")))
 686
 687   (let ((inner-parts (plist-get part :content))
 688         (start (point)))
 689     ;; Show all of the parts.
 690     (mapc (lambda (inner-part)
 691             (notmuch-show-insert-bodypart msg inner-part depth))
 692           inner-parts)
 693
 694     (when notmuch-show-indent-multipart
 695       (indent-rigidly start (point) 1)))
 696   t)
 697
 698 (defun notmuch-show-insert-part-multipart/* (msg part content-type nth depth declared-type)
 699   (notmuch-show-insert-part-header nth declared-type content-type nil)
 700   (let ((inner-parts (plist-get part :content))
 701         (start (point)))
 702     ;; Show all of the parts.
 703     (mapc (lambda (inner-part)
 704             (notmuch-show-insert-bodypart msg inner-part depth))
 705           inner-parts)
 706
 707     (when notmuch-show-indent-multipart
 708       (indent-rigidly start (point) 1)))
 709   t)
 710
 711 (defun notmuch-show-insert-part-message/rfc822 (msg part content-type nth depth declared-type)
 712   (notmuch-show-insert-part-header nth declared-type content-type nil)
 713   (let* ((message (car (plist-get part :content)))
 714          (body (car (plist-get message :body)))
 715          (start (point)))
 716
 717     ;; Override `notmuch-message-headers' to force `From' to be
 718     ;; displayed.
 719     (let ((notmuch-message-headers '("From" "Subject" "To" "Cc" "Date")))
 720       (notmuch-show-insert-headers (plist-get message :headers)))
 721
 722     ;; Blank line after headers to be compatible with the normal
 723     ;; message display.
 724     (insert "\n")
 725
 726     ;; Show the body
 727     (notmuch-show-insert-bodypart msg body depth)
 728
 729     (when notmuch-show-indent-multipart
 730       (indent-rigidly start (point) 1)))
 731   t)
 732
 733 (defun notmuch-show-insert-part-text/plain (msg part content-type nth depth declared-type)
 734   (let ((start (point)))
 735     ;; If this text/plain part is not the first part in the message,
 736     ;; insert a header to make this clear.
 737     (if (> nth 1)
 738         (notmuch-show-insert-part-header nth declared-type content-type (plist-get part :filename)))
 739     (insert (notmuch-get-bodypart-content msg part nth notmuch-show-process-crypto))
 740     (save-excursion
 741       (save-restriction
 742         (narrow-to-region start (point-max))
 743         (run-hook-with-args 'notmuch-show-insert-text/plain-hook msg depth))))
 744   t)
 745
 746 (defun notmuch-show-insert-part-text/calendar (msg part content-type nth depth declared-type)
 747   (notmuch-show-insert-part-header nth declared-type content-type (plist-get part :filename))
 748   (insert (with-temp-buffer
 749             (insert (notmuch-get-bodypart-content msg part nth notmuch-show-process-crypto))
 750             ;; notmuch-get-bodypart-content provides "raw", non-converted
 751             ;; data. Replace CRLF with LF before icalendar can use it.
 752             (goto-char (point-min))
 753             (while (re-search-forward "\r\n" nil t)
 754               (replace-match "\n" nil nil))
 755             (let ((file (make-temp-file "notmuch-ical"))
 756                   result)
 757               (icalendar-import-buffer file t)
 758               (set-buffer (get-file-buffer file))
 759               (setq result (buffer-substring (point-min) (point-max)))
 760               (set-buffer-modified-p nil)
 761               (kill-buffer (current-buffer))
 762               (delete-file file)
 763               result)))
 764   t)
 765
 766 ;; For backwards compatibility.
 767 (defun notmuch-show-insert-part-text/x-vcalendar (msg part content-type nth depth declared-type)
 768   (notmuch-show-insert-part-text/calendar msg part content-type nth depth declared-type))
 769
 770 (defun notmuch-show-insert-part-application/octet-stream (msg part content-type nth depth declared-type)
 771   ;; If we can deduce a MIME type from the filename of the attachment,
 772   ;; do so and pass it on to the handler for that type.
 773   (if (plist-get part :filename)
 774       (let ((extension (file-name-extension (plist-get part :filename)))
 775             mime-type)
 776         (if extension
 777             (progn
 778               (mailcap-parse-mimetypes)
 779               (setq mime-type (mailcap-extension-to-mime extension))
 780               (if (and mime-type
 781                        (not (string-equal mime-type "application/octet-stream")))
 782                   (notmuch-show-insert-bodypart-internal msg part mime-type nth depth content-type)
 783                 nil))
 784           nil))))
 785
 786 ;; Handler for wash generated inline patch fake parts.
 787 (defun notmuch-show-insert-part-inline-patch-fake-part (msg part content-type nth depth declared-type)
 788   (notmuch-show-insert-part-*/* msg part "text/x-diff" nth depth "inline patch"))
 789
 790 (defun notmuch-show-insert-part-*/* (msg part content-type nth depth declared-type)
 791   ;; This handler _must_ succeed - it is the handler of last resort.
 792   (notmuch-show-insert-part-header nth content-type declared-type (plist-get part :filename))
 793   (notmuch-mm-display-part-inline msg part nth content-type notmuch-show-process-crypto)
 794   t)
 795
 796 ;; Functions for determining how to handle MIME parts.
 797
 798 (defun notmuch-show-handlers-for (content-type)
 799   "Return a list of content handlers for a part of type CONTENT-TYPE."
 800   (let (result)
 801     (mapc (lambda (func)
 802             (if (functionp func)
 803                 (push func result)))
 804           ;; Reverse order of prefrence.
 805           (list (intern (concat "notmuch-show-insert-part-*/*"))
 806                 (intern (concat
 807                          "notmuch-show-insert-part-"
 808                          (car (notmuch-split-content-type content-type))
 809                          "/*"))
 810                 (intern (concat "notmuch-show-insert-part-" content-type))))
 811     result))
 812
 813 ;; \f
 814
 815 (defun notmuch-show-insert-bodypart-internal (msg part content-type nth depth declared-type)
 816   (let ((handlers (notmuch-show-handlers-for content-type)))
 817     ;; Run the content handlers until one of them returns a non-nil
 818     ;; value.
 819     (while (and handlers
 820                 (not (condition-case err
 821                          (funcall (car handlers) msg part content-type nth depth declared-type)
 822                        (error (progn
 823                                 (insert "!!! Bodypart insert error: ")
 824                                 (insert (error-message-string err))
 825                                 (insert " !!!\n") nil)))))
 826       (setq handlers (cdr handlers))))
 827   t)
 828
 829 (defun notmuch-show-insert-bodypart (msg part depth)
 830   "Insert the body part PART at depth DEPTH in the current thread."
 831   (let ((content-type (downcase (plist-get part :content-type)))
 832         (nth (plist-get part :id)))
 833     (notmuch-show-insert-bodypart-internal msg part content-type nth depth content-type))
 834   ;; Some of the body part handlers leave point somewhere up in the
 835   ;; part, so we make sure that we're down at the end.
 836   (goto-char (point-max))
 837   ;; Ensure that the part ends with a carriage return.
 838   (unless (bolp)
 839     (insert "\n")))
 840
 841 (defun notmuch-show-insert-body (msg body depth)
 842   "Insert the body BODY at depth DEPTH in the current thread."
 843   (mapc (lambda (part) (notmuch-show-insert-bodypart msg part depth)) body))
 844
 845 (defun notmuch-show-make-symbol (type)
 846   (make-symbol (concat "notmuch-show-" type)))
 847
 848 (defun notmuch-show-strip-re (string)
 849   (replace-regexp-in-string "^\\([Rr]e: *\\)+" "" string))
 850
 851 (defvar notmuch-show-previous-subject "")
 852 (make-variable-buffer-local 'notmuch-show-previous-subject)
 853
 854 (defun notmuch-show-insert-msg (msg depth)
 855   "Insert the message MSG at depth DEPTH in the current thread."
 856   (let* ((headers (plist-get msg :headers))
 857          ;; Indentation causes the buffer offset of the start/end
 858          ;; points to move, so we must use markers.
 859          message-start message-end
 860          content-start content-end
 861          headers-start headers-end
 862          body-start body-end
 863          (headers-invis-spec (notmuch-show-make-symbol "header"))
 864          (message-invis-spec (notmuch-show-make-symbol "message"))
 865          (bare-subject (notmuch-show-strip-re (plist-get headers :Subject))))
 866
 867     ;; Set `buffer-invisibility-spec' to `nil' (a list), otherwise
 868     ;; removing items from `buffer-invisibility-spec' (which is what
 869     ;; `notmuch-show-headers-visible' and
 870     ;; `notmuch-show-message-visible' do) is a no-op and has no
 871     ;; effect. This caused threads with only matching messages to have
 872     ;; those messages hidden initially because
 873     ;; `buffer-invisibility-spec' stayed `t'.
 874     ;;
 875     ;; This needs to be set here (rather than just above the call to
 876     ;; `notmuch-show-headers-visible') because some of the part
 877     ;; rendering or body washing functions
 878     ;; (e.g. `notmuch-wash-text/plain-citations') manipulate
 879     ;; `buffer-invisibility-spec').
 880     (when (eq buffer-invisibility-spec t)
 881       (setq buffer-invisibility-spec nil))
 882
 883     (setq message-start (point-marker))
 884
 885     (notmuch-show-insert-headerline headers
 886                                     (or (if notmuch-show-relative-dates
 887                                             (plist-get msg :date_relative)
 888                                           nil)
 889                                         (plist-get headers :Date))
 890                                     (plist-get msg :tags) depth)
 891
 892     (setq content-start (point-marker))
 893
 894     (plist-put msg :headers-invis-spec headers-invis-spec)
 895     (plist-put msg :message-invis-spec message-invis-spec)
 896
 897     ;; Set `headers-start' to point after the 'Subject:' header to be
 898     ;; compatible with the existing implementation. This just sets it
 899     ;; to after the first header.
 900     (notmuch-show-insert-headers headers)
 901     (save-excursion
 902       (goto-char content-start)
 903       ;; If the subject of this message is the same as that of the
 904       ;; previous message, don't display it when this message is
 905       ;; collapsed.
 906       (when (not (string= notmuch-show-previous-subject
 907                           bare-subject))
 908         (forward-line 1))
 909       (setq headers-start (point-marker)))
 910     (setq headers-end (point-marker))
 911
 912     (setq notmuch-show-previous-subject bare-subject)
 913
 914     (setq body-start (point-marker))
 915     ;; A blank line between the headers and the body.
 916     (insert "\n")
 917     (notmuch-show-insert-body msg (plist-get msg :body)
 918                               (if notmuch-show-indent-content depth 0))
 919     ;; Ensure that the body ends with a newline.
 920     (unless (bolp)
 921       (insert "\n"))
 922     (setq body-end (point-marker))
 923     (setq content-end (point-marker))
 924
 925     ;; Indent according to the depth in the thread.
 926     (if notmuch-show-indent-content
 927         (indent-rigidly content-start content-end (* notmuch-show-indent-messages-width depth)))
 928
 929     (setq message-end (point-max-marker))
 930
 931     ;; Save the extents of this message over the whole text of the
 932     ;; message.
 933     (put-text-property message-start message-end :notmuch-message-extent (cons message-start message-end))
 934
 935     (let ((headers-overlay (make-overlay headers-start headers-end))
 936           (invis-specs (list headers-invis-spec message-invis-spec)))
 937       (overlay-put headers-overlay 'invisible invis-specs)
 938       (overlay-put headers-overlay 'priority 10))
 939     (overlay-put (make-overlay body-start body-end) 'invisible message-invis-spec)
 940
 941     (plist-put msg :depth depth)
 942
 943     ;; Save the properties for this message. Currently this saves the
 944     ;; entire message (augmented it with other stuff), which seems
 945     ;; like overkill. We might save a reduced subset (for example, not
 946     ;; the content).
 947     (notmuch-show-set-message-properties msg)
 948
 949     ;; Set header visibility.
 950     (notmuch-show-headers-visible msg notmuch-message-headers-visible)
 951
 952     ;; Message visibility depends on whether it matched the search
 953     ;; criteria.
 954     (notmuch-show-message-visible msg (and (plist-get msg :match)
 955                                            (not (plist-get msg :excluded))))))
 956
 957 (defun notmuch-show-toggle-process-crypto ()
 958   "Toggle the processing of cryptographic MIME parts."
 959   (interactive)
 960   (setq notmuch-show-process-crypto (not notmuch-show-process-crypto))
 961   (message (if notmuch-show-process-crypto
 962                "Processing cryptographic MIME parts."
 963              "Not processing cryptographic MIME parts."))
 964   (notmuch-show-refresh-view))
 965
 966 (defun notmuch-show-toggle-elide-non-matching ()
 967   "Toggle the display of non-matching messages."
 968   (interactive)
 969   (setq notmuch-show-elide-non-matching-messages (not notmuch-show-elide-non-matching-messages))
 970   (message (if notmuch-show-elide-non-matching-messages
 971                "Showing matching messages only."
 972              "Showing all messages."))
 973   (notmuch-show-refresh-view))
 974
 975 (defun notmuch-show-toggle-thread-indentation ()
 976   "Toggle the indentation of threads."
 977   (interactive)
 978   (setq notmuch-show-indent-content (not notmuch-show-indent-content))
 979   (message (if notmuch-show-indent-content
 980                "Content is indented."
 981              "Content is not indented."))
 982   (notmuch-show-refresh-view))
 983
 984 (defun notmuch-show-insert-tree (tree depth)
 985   "Insert the message tree TREE at depth DEPTH in the current thread."
 986   (let ((msg (car tree))
 987         (replies (cadr tree)))
 988     ;; We test whether there is a message or just some replies.
 989     (when msg
 990       (notmuch-show-insert-msg msg depth))
 991     (notmuch-show-insert-thread replies (1+ depth))))
 992
 993 (defun notmuch-show-insert-thread (thread depth)
 994   "Insert the thread THREAD at depth DEPTH in the current forest."
 995   (mapc (lambda (tree) (notmuch-show-insert-tree tree depth)) thread))
 996
 997 (defun notmuch-show-insert-forest (forest)
 998   "Insert the forest of threads FOREST."
 999   (mapc (lambda (thread) (notmuch-show-insert-thread thread 0)) forest))
1000
1001 (defvar notmuch-id-regexp
1002   (concat
1003    ;; Match the id: prefix only if it begins a word (to disallow, for
1004    ;; example, matching cid:).
1005    "\\<id:\\("
1006    ;; If the term starts with a ", then parse Xapian's quoted boolean
1007    ;; term syntax, which allows for anything as long as embedded
1008    ;; double quotes escaped by doubling them.  We also disallow
1009    ;; newlines (which Xapian allows) to prevent runaway terms.
1010    "\"\\([^\"\n]\\|\"\"\\)*\""
1011    ;; Otherwise, parse Xapian's unquoted syntax, which goes up to the
1012    ;; next space or ).  We disallow [.,;] as the last character
1013    ;; because these are probably part of the surrounding text, and not
1014    ;; part of the id.  This doesn't match single character ids; meh.
1015    "\\|[^\"[:space:])][^[:space:])]*[^])[:space:].,:;?!]"
1016    "\\)")
1017   "The regexp used to match id: links in messages.")
1018
1019 (defvar notmuch-mid-regexp
1020   ;; goto-address-url-regexp matched cid: links, which have the same
1021   ;; grammar as the message ID part of a mid: link.  Construct the
1022   ;; regexp using the same technique as goto-address-url-regexp.
1023   (concat "\\<mid:\\(" thing-at-point-url-path-regexp "\\)")
1024   "The regexp used to match mid: links in messages.
1025
1026 See RFC 2392.")
1027
1028 (defun notmuch-show-buttonise-links (start end)
1029   "Buttonise URLs and mail addresses between START and END.
1030
1031 This also turns id:\"<message id>\"-parts and mid: links into
1032 buttons for a corresponding notmuch search."
1033   (goto-address-fontify-region start end)
1034   (save-excursion
1035     (let (links)
1036       (goto-char start)
1037       (while (re-search-forward notmuch-id-regexp end t)
1038         (push (list (match-beginning 0) (match-end 0)
1039                     (match-string-no-properties 0)) links))
1040       (goto-char start)
1041       (while (re-search-forward notmuch-mid-regexp end t)
1042         (let* ((mid-cid (match-string-no-properties 1))
1043                (mid (save-match-data
1044                       (string-match "^[^/]*" mid-cid)
1045                       (url-unhex-string (match-string 0 mid-cid)))))
1046           (push (list (match-beginning 0) (match-end 0)
1047                       (notmuch-id-to-query mid)) links)))
1048       (dolist (link links)
1049         ;; Remove the overlay created by goto-address-mode
1050         (remove-overlays (first link) (second link) 'goto-address t)
1051         (make-text-button (first link) (second link)
1052                           'action `(lambda (arg)
1053                                      (notmuch-show ,(third link)))
1054                           'follow-link t
1055                           'help-echo "Mouse-1, RET: search for this message"
1056                           'face goto-address-mail-face)))))
1057
1058 ;;;###autoload
1059 (defun notmuch-show (thread-id &optional parent-buffer query-context buffer-name)
1060   "Run \"notmuch show\" with the given thread ID and display results.
1061
1062 The optional PARENT-BUFFER is the notmuch-search buffer from
1063 which this notmuch-show command was executed, (so that the
1064 next thread from that buffer can be show when done with this
1065 one).
1066
1067 The optional QUERY-CONTEXT is a notmuch search term. Only
1068 messages from the thread matching this search term are shown if
1069 non-nil.
1070
1071 The optional BUFFER-NAME provides the name of the buffer in
1072 which the message thread is shown. If it is nil (which occurs
1073 when the command is called interactively) the argument to the
1074 function is used."
1075   (interactive "sNotmuch show: ")
1076   (let ((buffer-name (generate-new-buffer-name
1077                       (or buffer-name
1078                           (concat "*notmuch-" thread-id "*")))))
1079     (switch-to-buffer (get-buffer-create buffer-name))
1080     ;; Set the default value for `notmuch-show-process-crypto' in this
1081     ;; buffer.
1082     (setq notmuch-show-process-crypto notmuch-crypto-process-mime)
1083     ;; Set the default value for
1084     ;; `notmuch-show-elide-non-matching-messages' in this buffer. If
1085     ;; there is a prefix argument, invert the default.
1086     (setq notmuch-show-elide-non-matching-messages notmuch-show-only-matching-messages)
1087     (if current-prefix-arg
1088         (setq notmuch-show-elide-non-matching-messages (not notmuch-show-elide-non-matching-messages)))
1089
1090     (setq notmuch-show-thread-id thread-id
1091           notmuch-show-parent-buffer parent-buffer
1092           notmuch-show-query-context query-context)
1093     (notmuch-show-build-buffer)
1094     (notmuch-show-goto-first-wanted-message)
1095     (current-buffer)))
1096
1097 (defun notmuch-show-build-buffer ()
1098   (let ((inhibit-read-only t))
1099
1100     (notmuch-show-mode)
1101     ;; Don't track undo information for this buffer
1102     (set 'buffer-undo-list t)
1103
1104     (erase-buffer)
1105     (goto-char (point-min))
1106     (save-excursion
1107       (let* ((basic-args (list notmuch-show-thread-id))
1108              (args (if notmuch-show-query-context
1109                        (append (list "\'") basic-args
1110                                (list "and (" notmuch-show-query-context ")\'"))
1111                      (append (list "\'") basic-args (list "\'"))))
1112              (cli-args (cons "--exclude=false"
1113                              (when notmuch-show-elide-non-matching-messages
1114                                (list "--entire-thread=false")))))
1115
1116         (notmuch-show-insert-forest (notmuch-query-get-threads (append cli-args args)))
1117         ;; If the query context reduced the results to nothing, run
1118         ;; the basic query.
1119         (when (and (eq (buffer-size) 0)
1120                    notmuch-show-query-context)
1121           (notmuch-show-insert-forest
1122            (notmuch-query-get-threads (append cli-args basic-args)))))
1123
1124       (jit-lock-register #'notmuch-show-buttonise-links)
1125
1126       ;; Set the header line to the subject of the first message.
1127       (setq header-line-format (notmuch-show-strip-re (notmuch-show-get-subject)))
1128
1129       (run-hooks 'notmuch-show-hook))))
1130
1131 (defun notmuch-show-capture-state ()
1132   "Capture the state of the current buffer.
1133
1134 This includes:
1135  - the list of open messages,
1136  - the current message."
1137   (list (notmuch-show-get-message-id) (notmuch-show-get-message-ids-for-open-messages)))
1138
1139 (defun notmuch-show-apply-state (state)
1140   "Apply STATE to the current buffer.
1141
1142 This includes:
1143  - opening the messages previously opened,
1144  - closing all other messages,
1145  - moving to the correct current message."
1146   (let ((current (car state))
1147         (open (cadr state)))
1148
1149     ;; Open those that were open.
1150     (goto-char (point-min))
1151     (loop do (notmuch-show-message-visible (notmuch-show-get-message-properties)
1152                                            (member (notmuch-show-get-message-id) open))
1153           until (not (notmuch-show-goto-message-next)))
1154
1155     ;; Go to the previously open message.
1156     (goto-char (point-min))
1157     (unless (loop if (string= current (notmuch-show-get-message-id))
1158                   return t
1159                   until (not (notmuch-show-goto-message-next)))
1160       (goto-char (point-min))
1161       (message "Previously current message not found."))
1162     (notmuch-show-message-adjust)))
1163
1164 (defun notmuch-show-refresh-view (&optional reset-state)
1165   "Refresh the current view.
1166
1167 Refreshes the current view, observing changes in display
1168 preferences. If invoked with a prefix argument (or RESET-STATE is
1169 non-nil) then the state of the buffer (open/closed messages) is
1170 reset based on the original query."
1171   (interactive "P")
1172   (let ((inhibit-read-only t)
1173         (state (unless reset-state
1174                  (notmuch-show-capture-state))))
1175     (erase-buffer)
1176     (notmuch-show-build-buffer)
1177     (if state
1178         (notmuch-show-apply-state state)
1179       ;; We're resetting state, so navigate to the first open message
1180       ;; and mark it read, just like opening a new show buffer.
1181       (notmuch-show-goto-first-wanted-message))))
1182
1183 (defvar notmuch-show-stash-map
1184   (let ((map (make-sparse-keymap)))
1185     (define-key map "c" 'notmuch-show-stash-cc)
1186     (define-key map "d" 'notmuch-show-stash-date)
1187     (define-key map "F" 'notmuch-show-stash-filename)
1188     (define-key map "f" 'notmuch-show-stash-from)
1189     (define-key map "i" 'notmuch-show-stash-message-id)
1190     (define-key map "I" 'notmuch-show-stash-message-id-stripped)
1191     (define-key map "s" 'notmuch-show-stash-subject)
1192     (define-key map "T" 'notmuch-show-stash-tags)
1193     (define-key map "t" 'notmuch-show-stash-to)
1194     (define-key map "l" 'notmuch-show-stash-mlarchive-link)
1195     (define-key map "L" 'notmuch-show-stash-mlarchive-link-and-go)
1196     map)
1197   "Submap for stash commands")
1198 (fset 'notmuch-show-stash-map notmuch-show-stash-map)
1199
1200 (defvar notmuch-show-mode-map
1201       (let ((map (make-sparse-keymap)))
1202         (define-key map "?" 'notmuch-help)
1203         (define-key map "q" 'notmuch-kill-this-buffer)
1204         (define-key map (kbd "<C-tab>") 'widget-backward)
1205         (define-key map (kbd "M-TAB") 'notmuch-show-previous-button)
1206         (define-key map (kbd "<backtab>") 'notmuch-show-previous-button)
1207         (define-key map (kbd "TAB") 'notmuch-show-next-button)
1208         (define-key map "s" 'notmuch-search)
1209         (define-key map "m" 'notmuch-mua-new-mail)
1210         (define-key map "f" 'notmuch-show-forward-message)
1211         (define-key map "r" 'notmuch-show-reply-sender)
1212         (define-key map "R" 'notmuch-show-reply)
1213         (define-key map "|" 'notmuch-show-pipe-message)
1214         (define-key map "w" 'notmuch-show-save-attachments)
1215         (define-key map "V" 'notmuch-show-view-raw-message)
1216         (define-key map "v" 'notmuch-show-view-all-mime-parts)
1217         (define-key map "c" 'notmuch-show-stash-map)
1218         (define-key map "=" 'notmuch-show-refresh-view)
1219         (define-key map "h" 'notmuch-show-toggle-visibility-headers)
1220         (define-key map "*" 'notmuch-show-tag-all)
1221         (define-key map "-" 'notmuch-show-remove-tag)
1222         (define-key map "+" 'notmuch-show-add-tag)
1223         (define-key map "X" 'notmuch-show-archive-thread-then-exit)
1224         (define-key map "x" 'notmuch-show-archive-message-then-next-or-exit)
1225         (define-key map "A" 'notmuch-show-archive-thread-then-next)
1226         (define-key map "a" 'notmuch-show-archive-message-then-next-or-next-thread)
1227         (define-key map "N" 'notmuch-show-next-message)
1228         (define-key map "P" 'notmuch-show-previous-message)
1229         (define-key map "n" 'notmuch-show-next-open-message)
1230         (define-key map "p" 'notmuch-show-previous-open-message)
1231         (define-key map (kbd "DEL") 'notmuch-show-rewind)
1232         (define-key map " " 'notmuch-show-advance-and-archive)
1233         (define-key map (kbd "M-RET") 'notmuch-show-open-or-close-all)
1234         (define-key map (kbd "RET") 'notmuch-show-toggle-message)
1235         (define-key map "#" 'notmuch-show-print-message)
1236         (define-key map "!" 'notmuch-show-toggle-elide-non-matching)
1237         (define-key map "$" 'notmuch-show-toggle-process-crypto)
1238         (define-key map "<" 'notmuch-show-toggle-thread-indentation)
1239         (define-key map "t" 'toggle-truncate-lines)
1240         map)
1241       "Keymap for \"notmuch show\" buffers.")
1242 (fset 'notmuch-show-mode-map notmuch-show-mode-map)
1243
1244 (defun notmuch-show-mode ()
1245   "Major mode for viewing a thread with notmuch.
1246
1247 This buffer contains the results of the \"notmuch show\" command
1248 for displaying a single thread of email from your email archives.
1249
1250 By default, various components of email messages, (citations,
1251 signatures, already-read messages), are hidden. You can make
1252 these parts visible by clicking with the mouse button or by
1253 pressing RET after positioning the cursor on a hidden part, (for
1254 which \\[notmuch-show-next-button] and \\[notmuch-show-previous-button] are helpful).
1255
1256 Reading the thread sequentially is well-supported by pressing
1257 \\[notmuch-show-advance-and-archive]. This will scroll the current message (if necessary), advance
1258 to the next message, or advance to the next thread (if already on
1259 the last message of a thread).
1260
1261 Other commands are available to read or manipulate the thread
1262 more selectively, (such as '\\[notmuch-show-next-message]' and '\\[notmuch-show-previous-message]' to advance to messages
1263 without removing any tags, and '\\[notmuch-show-archive-thread]' to archive an entire thread
1264 without scrolling through with \\[notmuch-show-advance-and-archive]).
1265
1266 You can add or remove arbitrary tags from the current message with
1267 '\\[notmuch-show-add-tag]' or '\\[notmuch-show-remove-tag]'.
1268
1269 All currently available key bindings:
1270
1271 \\{notmuch-show-mode-map}"
1272   (interactive)
1273   (kill-all-local-variables)
1274   (use-local-map notmuch-show-mode-map)
1275   (setq major-mode 'notmuch-show-mode
1276         mode-name "notmuch-show")
1277   (setq buffer-read-only t
1278         truncate-lines t))
1279
1280 (defun notmuch-show-move-to-message-top ()
1281   (goto-char (notmuch-show-message-top)))
1282
1283 (defun notmuch-show-move-to-message-bottom ()
1284   (goto-char (notmuch-show-message-bottom)))
1285
1286 (defun notmuch-show-message-adjust ()
1287   (recenter 0))
1288
1289 ;; Movement related functions.
1290
1291 ;; There's some strangeness here where a text property applied to a
1292 ;; region a->b is not found when point is at b. We walk backwards
1293 ;; until finding the property.
1294 (defun notmuch-show-message-extent ()
1295   (let (r)
1296     (save-excursion
1297       (while (not (setq r (get-text-property (point) :notmuch-message-extent)))
1298         (backward-char)))
1299     r))
1300
1301 (defun notmuch-show-message-top ()
1302   (car (notmuch-show-message-extent)))
1303
1304 (defun notmuch-show-message-bottom ()
1305   (cdr (notmuch-show-message-extent)))
1306
1307 (defun notmuch-show-goto-message-next ()
1308   (let ((start (point)))
1309     (notmuch-show-move-to-message-bottom)
1310     (if (not (eobp))
1311         t
1312       (goto-char start)
1313       nil)))
1314
1315 (defun notmuch-show-goto-message-previous ()
1316   (notmuch-show-move-to-message-top)
1317   (if (bobp)
1318       nil
1319     (backward-char)
1320     (notmuch-show-move-to-message-top)
1321     t))
1322
1323 (defun notmuch-show-mapc (function)
1324   "Iterate through all messages in the current thread with
1325 `notmuch-show-goto-message-next' and call FUNCTION for side
1326 effects."
1327   (save-excursion
1328     (goto-char (point-min))
1329     (loop do (funcall function)
1330           while (notmuch-show-goto-message-next))))
1331
1332 ;; Functions relating to the visibility of messages and their
1333 ;; components.
1334
1335 (defun notmuch-show-element-visible (props visible-p spec-property)
1336   (let ((spec (plist-get props spec-property)))
1337     (if visible-p
1338         (remove-from-invisibility-spec spec)
1339       (add-to-invisibility-spec spec))))
1340
1341 (defun notmuch-show-message-visible (props visible-p)
1342   (notmuch-show-element-visible props visible-p :message-invis-spec)
1343   (notmuch-show-set-prop :message-visible visible-p props))
1344
1345 (defun notmuch-show-headers-visible (props visible-p)
1346   (notmuch-show-element-visible props visible-p :headers-invis-spec)
1347   (notmuch-show-set-prop :headers-visible visible-p props))
1348
1349 ;; Functions for setting and getting attributes of the current
1350 ;; message.
1351
1352 (defun notmuch-show-set-message-properties (props)
1353   (save-excursion
1354     (notmuch-show-move-to-message-top)
1355     (put-text-property (point) (+ (point) 1) :notmuch-message-properties props)))
1356
1357 (defun notmuch-show-get-message-properties ()
1358   "Return the properties of the current message as a plist.
1359
1360 Some useful entries are:
1361 :headers - Property list containing the headers :Date, :Subject, :From, etc.
1362 :body - Body of the message
1363 :tags - Tags for this message"
1364   (save-excursion
1365     (notmuch-show-move-to-message-top)
1366     (get-text-property (point) :notmuch-message-properties)))
1367
1368 (defun notmuch-show-set-prop (prop val &optional props)
1369   (let ((inhibit-read-only t)
1370         (props (or props
1371                    (notmuch-show-get-message-properties))))
1372     (plist-put props prop val)
1373     (notmuch-show-set-message-properties props)))
1374
1375 (defun notmuch-show-get-prop (prop &optional props)
1376   (let ((props (or props
1377                    (notmuch-show-get-message-properties))))
1378     (plist-get props prop)))
1379
1380 (defun notmuch-show-get-message-id (&optional bare)
1381   "Return an id: query for the Message-Id of the current message.
1382
1383 If optional argument BARE is non-nil, return
1384 the Message-Id without id: prefix and escaping."
1385   (if bare
1386       (notmuch-show-get-prop :id)
1387     (notmuch-id-to-query (notmuch-show-get-prop :id))))
1388
1389 (defun notmuch-show-get-messages-ids ()
1390   "Return all id: queries of messages in the current thread."
1391   (let ((message-ids))
1392     (notmuch-show-mapc
1393      (lambda () (push (notmuch-show-get-message-id) message-ids)))
1394     message-ids))
1395
1396 (defun notmuch-show-get-messages-ids-search ()
1397   "Return a search string for all message ids of messages in the
1398 current thread."
1399   (mapconcat 'identity (notmuch-show-get-messages-ids) " or "))
1400
1401 ;; dme: Would it make sense to use a macro for many of these?
1402
1403 (defun notmuch-show-get-filename ()
1404   "Return the filename of the current message."
1405   (notmuch-show-get-prop :filename))
1406
1407 (defun notmuch-show-get-header (header &optional props)
1408   "Return the named header of the current message, if any."
1409   (plist-get (notmuch-show-get-prop :headers props) header))
1410
1411 (defun notmuch-show-get-cc ()
1412   (notmuch-show-get-header :Cc))
1413
1414 (defun notmuch-show-get-date ()
1415   (notmuch-show-get-header :Date))
1416
1417 (defun notmuch-show-get-from ()
1418   (notmuch-show-get-header :From))
1419
1420 (defun notmuch-show-get-subject ()
1421   (notmuch-show-get-header :Subject))
1422
1423 (defun notmuch-show-get-to ()
1424   (notmuch-show-get-header :To))
1425
1426 (defun notmuch-show-get-depth ()
1427   (notmuch-show-get-prop :depth))
1428
1429 (defun notmuch-show-set-tags (tags)
1430   "Set the tags of the current message."
1431   (notmuch-show-set-prop :tags tags)
1432   (notmuch-show-update-tags tags))
1433
1434 (defun notmuch-show-get-tags ()
1435   "Return the tags of the current message."
1436   (notmuch-show-get-prop :tags))
1437
1438 (defun notmuch-show-message-visible-p ()
1439   "Is the current message visible?"
1440   (notmuch-show-get-prop :message-visible))
1441
1442 (defun notmuch-show-headers-visible-p ()
1443   "Are the headers of the current message visible?"
1444   (notmuch-show-get-prop :headers-visible))
1445
1446 (defun notmuch-show-mark-read (&optional unread)
1447   "Mark the current message as read.
1448
1449 Mark the current message as read by applying the tag changes in
1450 `notmuch-show-mark-read-tags' to it (remove the \"unread\" tag by
1451 default). If a prefix argument is given, the message will be
1452 marked as unread, i.e. the tag changes in
1453 `notmuch-show-mark-read-tags' will be reversed."
1454   (interactive "P")
1455   (when notmuch-show-mark-read-tags
1456     (apply 'notmuch-show-tag-message
1457            (notmuch-tag-change-list notmuch-show-mark-read-tags unread))))
1458
1459 ;; Functions for getting attributes of several messages in the current
1460 ;; thread.
1461
1462 (defun notmuch-show-get-message-ids-for-open-messages ()
1463   "Return a list of all id: queries for open messages in the current thread."
1464   (save-excursion
1465     (let (message-ids done)
1466       (goto-char (point-min))
1467       (while (not done)
1468         (if (notmuch-show-message-visible-p)
1469             (setq message-ids (append message-ids (list (notmuch-show-get-message-id)))))
1470         (setq done (not (notmuch-show-goto-message-next)))
1471         )
1472       message-ids
1473       )))
1474
1475 ;; Commands typically bound to keys.
1476
1477 (defun notmuch-show-advance ()
1478   "Advance through thread.
1479
1480 If the current message in the thread is not yet fully visible,
1481 scroll by a near screenful to read more of the message.
1482
1483 Otherwise, (the end of the current message is already within the
1484 current window), advance to the next open message."
1485   (interactive)
1486   (let* ((end-of-this-message (notmuch-show-message-bottom))
1487          (visible-end-of-this-message (1- end-of-this-message))
1488          (ret nil))
1489     (while (invisible-p visible-end-of-this-message)
1490       (setq visible-end-of-this-message
1491             (max (point-min)
1492                  (1- (previous-single-char-property-change
1493                       visible-end-of-this-message 'invisible)))))
1494     (cond
1495      ;; Ideally we would test `end-of-this-message' against the result
1496      ;; of `window-end', but that doesn't account for the fact that
1497      ;; the end of the message might be hidden.
1498      ((and visible-end-of-this-message
1499            (> visible-end-of-this-message (window-end)))
1500       ;; The bottom of this message is not visible - scroll.
1501       (scroll-up nil))
1502
1503      ((not (= end-of-this-message (point-max)))
1504       ;; This is not the last message - move to the next visible one.
1505       (notmuch-show-next-open-message))
1506
1507      ((not (= (point) (point-max)))
1508       ;; This is the last message, but the cursor is not at the end of
1509       ;; the buffer. Move it there.
1510       (goto-char (point-max)))
1511
1512      (t
1513       ;; This is the last message - change the return value
1514       (setq ret t)))
1515     ret))
1516
1517 (defun notmuch-show-advance-and-archive ()
1518   "Advance through thread and archive.
1519
1520 This command is intended to be one of the simplest ways to
1521 process a thread of email. It works exactly like
1522 notmuch-show-advance, in that it scrolls through messages in a
1523 show buffer, except that when it gets to the end of the buffer it
1524 archives the entire current thread, (remove the \"inbox\" tag
1525 from each message), kills the buffer, and displays the next
1526 thread from the search from which this thread was originally
1527 shown."
1528   (interactive)
1529   (if (notmuch-show-advance)
1530       (notmuch-show-archive-thread-then-next)))
1531
1532 (defun notmuch-show-rewind ()
1533   "Backup through the thread, (reverse scrolling compared to \\[notmuch-show-advance-and-archive]).
1534
1535 Specifically, if the beginning of the previous email is fewer
1536 than `window-height' lines from the current point, move to it
1537 just like `notmuch-show-previous-message'.
1538
1539 Otherwise, just scroll down a screenful of the current message.
1540
1541 This command does not modify any message tags, (it does not undo
1542 any effects from previous calls to
1543 `notmuch-show-advance-and-archive'."
1544   (interactive)
1545   (let ((start-of-message (notmuch-show-message-top))
1546         (start-of-window (window-start)))
1547     (cond
1548       ;; Either this message is properly aligned with the start of the
1549       ;; window or the start of this message is not visible on the
1550       ;; screen - scroll.
1551      ((or (= start-of-message start-of-window)
1552           (< start-of-message start-of-window))
1553       (scroll-down)
1554       ;; If a small number of lines from the previous message are
1555       ;; visible, realign so that the top of the current message is at
1556       ;; the top of the screen.
1557       (when (<= (count-screen-lines (window-start) start-of-message)
1558                 next-screen-context-lines)
1559         (goto-char (notmuch-show-message-top))
1560         (notmuch-show-message-adjust))
1561       ;; Move to the top left of the window.
1562       (goto-char (window-start)))
1563      (t
1564       ;; Move to the previous message.
1565       (notmuch-show-previous-message)))))
1566
1567 (defun notmuch-show-reply (&optional prompt-for-sender)
1568   "Reply to the sender and all recipients of the current message."
1569   (interactive "P")
1570   (notmuch-mua-new-reply (notmuch-show-get-message-id) prompt-for-sender t))
1571
1572 (defun notmuch-show-reply-sender (&optional prompt-for-sender)
1573   "Reply to the sender of the current message."
1574   (interactive "P")
1575   (notmuch-mua-new-reply (notmuch-show-get-message-id) prompt-for-sender nil))
1576
1577 (defun notmuch-show-forward-message (&optional prompt-for-sender)
1578   "Forward the current message."
1579   (interactive "P")
1580   (with-current-notmuch-show-message
1581    (notmuch-mua-new-forward-message prompt-for-sender)))
1582
1583 (defun notmuch-show-next-message (&optional pop-at-end)
1584   "Show the next message.
1585
1586 If a prefix argument is given and this is the last message in the
1587 thread, navigate to the next thread in the parent search buffer."
1588   (interactive "P")
1589   (if (notmuch-show-goto-message-next)
1590       (progn
1591         (notmuch-show-mark-read)
1592         (notmuch-show-message-adjust))
1593     (if pop-at-end
1594         (notmuch-show-next-thread)
1595       (goto-char (point-max)))))
1596
1597 (defun notmuch-show-previous-message ()
1598   "Show the previous message or the start of the current message."
1599   (interactive)
1600   (if (= (point) (notmuch-show-message-top))
1601       (notmuch-show-goto-message-previous)
1602     (notmuch-show-move-to-message-top))
1603   (notmuch-show-mark-read)
1604   (notmuch-show-message-adjust))
1605
1606 (defun notmuch-show-next-open-message (&optional pop-at-end)
1607   "Show the next open message.
1608
1609 If a prefix argument is given and this is the last open message
1610 in the thread, navigate to the next thread in the parent search
1611 buffer. Return t if there was a next open message in the thread
1612 to show, nil otherwise."
1613   (interactive "P")
1614   (let (r)
1615     (while (and (setq r (notmuch-show-goto-message-next))
1616                 (not (notmuch-show-message-visible-p))))
1617     (if r
1618         (progn
1619           (notmuch-show-mark-read)
1620           (notmuch-show-message-adjust))
1621       (if pop-at-end
1622           (notmuch-show-next-thread)
1623         (goto-char (point-max))))
1624     r))
1625
1626 (defun notmuch-show-next-matching-message ()
1627   "Show the next matching message."
1628   (interactive)
1629   (let (r)
1630     (while (and (setq r (notmuch-show-goto-message-next))
1631                 (not (notmuch-show-get-prop :match))))
1632     (if r
1633         (progn
1634           (notmuch-show-mark-read)
1635           (notmuch-show-message-adjust))
1636       (goto-char (point-max)))))
1637
1638 (defun notmuch-show-open-if-matched ()
1639   "Open a message if it is matched (whether or not excluded)."
1640   (let ((props (notmuch-show-get-message-properties)))
1641     (notmuch-show-message-visible props (plist-get props :match))))
1642
1643 (defun notmuch-show-goto-first-wanted-message ()
1644   "Move to the first open message and mark it read"
1645   (goto-char (point-min))
1646   (if (notmuch-show-message-visible-p)
1647       (notmuch-show-mark-read)
1648     (notmuch-show-next-open-message))
1649   (when (eobp)
1650     ;; There are no matched non-excluded messages so open all matched
1651     ;; (necessarily excluded) messages and go to the first.
1652     (notmuch-show-mapc 'notmuch-show-open-if-matched)
1653     (force-window-update)
1654     (goto-char (point-min))
1655     (if (notmuch-show-message-visible-p)
1656         (notmuch-show-mark-read)
1657       (notmuch-show-next-open-message))))
1658
1659 (defun notmuch-show-previous-open-message ()
1660   "Show the previous open message."
1661   (interactive)
1662   (while (and (if (= (point) (notmuch-show-message-top))
1663                   (notmuch-show-goto-message-previous)
1664                 (notmuch-show-move-to-message-top))
1665               (not (notmuch-show-message-visible-p))))
1666   (notmuch-show-mark-read)
1667   (notmuch-show-message-adjust))
1668
1669 (defun notmuch-show-view-raw-message ()
1670   "View the file holding the current message."
1671   (interactive)
1672   (let* ((id (notmuch-show-get-message-id))
1673          (buf (get-buffer-create (concat "*notmuch-raw-" id "*"))))
1674     (call-process notmuch-command nil buf nil "show" "--format=raw" id)
1675     (switch-to-buffer buf)
1676     (goto-char (point-min))
1677     (set-buffer-modified-p nil)
1678     (view-buffer buf 'kill-buffer-if-not-modified)))
1679
1680 (defun notmuch-show-pipe-message (entire-thread command)
1681   "Pipe the contents of the current message (or thread) to the given command.
1682
1683 The given command will be executed with the raw contents of the
1684 current email message as stdin. Anything printed by the command
1685 to stdout or stderr will appear in the *notmuch-pipe* buffer.
1686
1687 When invoked with a prefix argument, the command will receive all
1688 open messages in the current thread (formatted as an mbox) rather
1689 than only the current message."
1690   (interactive "P\nsPipe message to command: ")
1691   (let (shell-command)
1692     (if entire-thread
1693         (setq shell-command
1694               (concat notmuch-command " show --format=mbox --exclude=false "
1695                       (shell-quote-argument
1696                        (mapconcat 'identity (notmuch-show-get-message-ids-for-open-messages) " OR "))
1697                       " | " command))
1698       (setq shell-command
1699             (concat notmuch-command " show --format=raw "
1700                     (shell-quote-argument (notmuch-show-get-message-id)) " | " command)))
1701     (let ((buf (get-buffer-create (concat "*notmuch-pipe*"))))
1702       (with-current-buffer buf
1703         (setq buffer-read-only nil)
1704         (erase-buffer)
1705         (let ((exit-code (call-process-shell-command shell-command nil buf)))
1706           (goto-char (point-max))
1707           (set-buffer-modified-p nil)
1708           (setq buffer-read-only t)
1709           (unless (zerop exit-code)
1710             (switch-to-buffer-other-window buf)
1711             (message (format "Command '%s' exited abnormally with code %d"
1712                              shell-command exit-code))))))))
1713
1714 (defun notmuch-show-tag-message (&rest tag-changes)
1715   "Change tags for the current message.
1716
1717 TAG-CHANGES is a list of tag operations for `notmuch-tag'."
1718   (let* ((current-tags (notmuch-show-get-tags))
1719          (new-tags (notmuch-update-tags current-tags tag-changes)))
1720     (unless (equal current-tags new-tags)
1721       (funcall 'notmuch-tag (notmuch-show-get-message-id) tag-changes)
1722       (notmuch-show-set-tags new-tags))))
1723
1724 (defun notmuch-show-tag (&optional tag-changes)
1725   "Change tags for the current message.
1726
1727 See `notmuch-tag' for information on the format of TAG-CHANGES."
1728   (interactive)
1729   (setq tag-changes (funcall 'notmuch-tag (notmuch-show-get-message-id) tag-changes))
1730   (let* ((current-tags (notmuch-show-get-tags))
1731          (new-tags (notmuch-update-tags current-tags tag-changes)))
1732     (unless (equal current-tags new-tags)
1733       (notmuch-show-set-tags new-tags))))
1734
1735 (defun notmuch-show-tag-all (&optional tag-changes)
1736   "Change tags for all messages in the current show buffer.
1737
1738 See `notmuch-tag' for information on the format of TAG-CHANGES."
1739   (interactive)
1740   (setq tag-changes (funcall 'notmuch-tag (notmuch-show-get-messages-ids-search) tag-changes))
1741   (notmuch-show-mapc
1742    (lambda ()
1743      (let* ((current-tags (notmuch-show-get-tags))
1744             (new-tags (notmuch-update-tags current-tags tag-changes)))
1745        (unless (equal current-tags new-tags)
1746          (notmuch-show-set-tags new-tags))))))
1747
1748 (defun notmuch-show-add-tag ()
1749   "Same as `notmuch-show-tag' but sets initial input to '+'."
1750   (interactive)
1751   (notmuch-show-tag "+"))
1752
1753 (defun notmuch-show-remove-tag ()
1754   "Same as `notmuch-show-tag' but sets initial input to '-'."
1755   (interactive)
1756   (notmuch-show-tag "-"))
1757
1758 (defun notmuch-show-toggle-visibility-headers ()
1759   "Toggle the visibility of the current message headers."
1760   (interactive)
1761   (let ((props (notmuch-show-get-message-properties)))
1762     (notmuch-show-headers-visible
1763      props
1764      (not (plist-get props :headers-visible))))
1765   (force-window-update))
1766
1767 (defun notmuch-show-toggle-message ()
1768   "Toggle the visibility of the current message."
1769   (interactive)
1770   (let ((props (notmuch-show-get-message-properties)))
1771     (notmuch-show-message-visible
1772      props
1773      (not (plist-get props :message-visible))))
1774   (force-window-update))
1775
1776 (defun notmuch-show-open-or-close-all ()
1777   "Set the visibility all of the messages in the current thread.
1778 By default make all of the messages visible. With a prefix
1779 argument, hide all of the messages."
1780   (interactive)
1781   (save-excursion
1782     (goto-char (point-min))
1783     (loop do (notmuch-show-message-visible (notmuch-show-get-message-properties)
1784                                            (not current-prefix-arg))
1785           until (not (notmuch-show-goto-message-next))))
1786   (force-window-update))
1787
1788 (defun notmuch-show-next-button ()
1789   "Advance point to the next button in the buffer."
1790   (interactive)
1791   (forward-button 1))
1792
1793 (defun notmuch-show-previous-button ()
1794   "Move point back to the previous button in the buffer."
1795   (interactive)
1796   (backward-button 1))
1797
1798 (defun notmuch-show-next-thread (&optional show-next)
1799   "Move to the next item in the search results, if any."
1800   (interactive "P")
1801   (let ((parent-buffer notmuch-show-parent-buffer))
1802     (notmuch-kill-this-buffer)
1803     (when (buffer-live-p parent-buffer)
1804       (switch-to-buffer parent-buffer)
1805       (notmuch-search-next-thread)
1806       (if show-next
1807           (notmuch-search-show-thread)))))
1808
1809 (defun notmuch-show-archive-thread (&optional unarchive)
1810   "Archive each message in thread.
1811
1812 Archive each message currently shown by applying the tag changes
1813 in `notmuch-archive-tags' to each (remove the \"inbox\" tag by
1814 default). If a prefix argument is given, the messages will be
1815 \"unarchived\", i.e. the tag changes in `notmuch-archive-tags'
1816 will be reversed.
1817
1818 Note: This command is safe from any race condition of new messages
1819 being delivered to the same thread. It does not archive the
1820 entire thread, but only the messages shown in the current
1821 buffer."
1822   (interactive "P")
1823   (when notmuch-archive-tags
1824     (notmuch-show-tag-all
1825      (notmuch-tag-change-list notmuch-archive-tags unarchive))))
1826
1827 (defun notmuch-show-archive-thread-then-next ()
1828   "Archive all messages in the current buffer, then show next thread from search."
1829   (interactive)
1830   (notmuch-show-archive-thread)
1831   (notmuch-show-next-thread t))
1832
1833 (defun notmuch-show-archive-thread-then-exit ()
1834   "Archive all messages in the current buffer, then exit back to search results."
1835   (interactive)
1836   (notmuch-show-archive-thread)
1837   (notmuch-show-next-thread))
1838
1839 (defun notmuch-show-archive-message (&optional unarchive)
1840   "Archive the current message.
1841
1842 Archive the current message by applying the tag changes in
1843 `notmuch-archive-tags' to it (remove the \"inbox\" tag by
1844 default). If a prefix argument is given, the message will be
1845 \"unarchived\", i.e. the tag changes in `notmuch-archive-tags'
1846 will be reversed."
1847   (interactive "P")
1848   (when notmuch-archive-tags
1849     (apply 'notmuch-show-tag-message
1850            (notmuch-tag-change-list notmuch-archive-tags unarchive))))
1851
1852 (defun notmuch-show-archive-message-then-next-or-exit ()
1853   "Archive the current message, then show the next open message in the current thread.
1854
1855 If at the last open message in the current thread, then exit back
1856 to search results."
1857   (interactive)
1858   (notmuch-show-archive-message)
1859   (notmuch-show-next-open-message t))
1860
1861 (defun notmuch-show-archive-message-then-next-or-next-thread ()
1862   "Archive the current message, then show the next open message in the current thread.
1863
1864 If at the last open message in the current thread, then show next
1865 thread from search."
1866   (interactive)
1867   (notmuch-show-archive-message)
1868   (unless (notmuch-show-next-open-message)
1869     (notmuch-show-next-thread t)))
1870
1871 (defun notmuch-show-stash-cc ()
1872   "Copy CC field of current message to kill-ring."
1873   (interactive)
1874   (notmuch-common-do-stash (notmuch-show-get-cc)))
1875
1876 (defun notmuch-show-stash-date ()
1877   "Copy date of current message to kill-ring."
1878   (interactive)
1879   (notmuch-common-do-stash (notmuch-show-get-date)))
1880
1881 (defun notmuch-show-stash-filename ()
1882   "Copy filename of current message to kill-ring."
1883   (interactive)
1884   (notmuch-common-do-stash (notmuch-show-get-filename)))
1885
1886 (defun notmuch-show-stash-from ()
1887   "Copy From address of current message to kill-ring."
1888   (interactive)
1889   (notmuch-common-do-stash (notmuch-show-get-from)))
1890
1891 (defun notmuch-show-stash-message-id ()
1892   "Copy id: query matching the current message to kill-ring."
1893   (interactive)
1894   (notmuch-common-do-stash (notmuch-show-get-message-id)))
1895
1896 (defun notmuch-show-stash-message-id-stripped ()
1897   "Copy message ID of current message (sans `id:' prefix) to kill-ring."
1898   (interactive)
1899   (notmuch-common-do-stash (notmuch-show-get-message-id t)))
1900
1901 (defun notmuch-show-stash-subject ()
1902   "Copy Subject field of current message to kill-ring."
1903   (interactive)
1904   (notmuch-common-do-stash (notmuch-show-get-subject)))
1905
1906 (defun notmuch-show-stash-tags ()
1907   "Copy tags of current message to kill-ring as a comma separated list."
1908   (interactive)
1909   (notmuch-common-do-stash (mapconcat 'identity (notmuch-show-get-tags) ",")))
1910
1911 (defun notmuch-show-stash-to ()
1912   "Copy To address of current message to kill-ring."
1913   (interactive)
1914   (notmuch-common-do-stash (notmuch-show-get-to)))
1915
1916 (defun notmuch-show-stash-mlarchive-link (&optional mla)
1917   "Copy an ML Archive URI for the current message to the kill-ring.
1918
1919 This presumes that the message is available at the selected Mailing List Archive.
1920
1921 If optional argument MLA is non-nil, use the provided key instead of prompting
1922 the user (see `notmuch-show-stash-mlarchive-link-alist')."
1923   (interactive)
1924   (notmuch-common-do-stash
1925    (concat (cdr (assoc
1926                  (or mla
1927                      (let ((completion-ignore-case t))
1928                        (completing-read
1929                         "Mailing List Archive: "
1930                         notmuch-show-stash-mlarchive-link-alist
1931                         nil t nil nil notmuch-show-stash-mlarchive-link-default)))
1932                  notmuch-show-stash-mlarchive-link-alist))
1933            (notmuch-show-get-message-id t))))
1934
1935 (defun notmuch-show-stash-mlarchive-link-and-go (&optional mla)
1936   "Copy an ML Archive URI for the current message to the kill-ring and visit it.
1937
1938 This presumes that the message is available at the selected Mailing List Archive.
1939
1940 If optional argument MLA is non-nil, use the provided key instead of prompting
1941 the user (see `notmuch-show-stash-mlarchive-link-alist')."
1942   (interactive)
1943   (notmuch-show-stash-mlarchive-link mla)
1944   (browse-url (current-kill 0 t)))
1945
1946 ;; Commands typically bound to buttons.
1947
1948 (defun notmuch-show-part-button-default (&optional button)
1949   (interactive)
1950   (notmuch-show-part-button-internal button notmuch-show-part-button-default-action))
1951
1952 (defun notmuch-show-part-button-save (&optional button)
1953   (interactive)
1954   (notmuch-show-part-button-internal button #'notmuch-show-save-part))
1955
1956 (defun notmuch-show-part-button-view (&optional button)
1957   (interactive)
1958   (notmuch-show-part-button-internal button #'notmuch-show-view-part))
1959
1960 (defun notmuch-show-part-button-interactively-view (&optional button)
1961   (interactive)
1962   (notmuch-show-part-button-internal button #'notmuch-show-interactively-view-part))
1963
1964 (defun notmuch-show-part-button-pipe (&optional button)
1965   (interactive)
1966   (notmuch-show-part-button-internal button #'notmuch-show-pipe-part))
1967
1968 (defun notmuch-show-part-button-internal (button handler)
1969   (let ((button (or button (button-at (point)))))
1970     (if button
1971         (let ((nth (button-get button :notmuch-part)))
1972           (if nth
1973               (funcall handler (notmuch-show-get-message-id) nth
1974                        (button-get button :notmuch-filename)
1975                        (button-get button :notmuch-content-type)))))))
1976
1977 ;;
1978
1979 (provide 'notmuch-show)