git.notmuchmail.org Git - notmuch/blob - emacs/notmuch-show.el

   1 ;; notmuch-show.el --- displaying notmuch forests.
   2 ;;
   3 ;; Copyright © Carl Worth
   4 ;; Copyright © David Edmondson
   5 ;;
   6 ;; This file is part of Notmuch.
   7 ;;
   8 ;; Notmuch is free software: you can redistribute it and/or modify it
   9 ;; under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation, either version 3 of the License, or
  11 ;; (at your option) any later version.
  12 ;;
  13 ;; Notmuch is distributed in the hope that it will be useful, but
  14 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 ;; General Public License for more details.
  17 ;;
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with Notmuch.  If not, see <http://www.gnu.org/licenses/>.
  20 ;;
  21 ;; Authors: Carl Worth <cworth@cworth.org>
  22 ;;          David Edmondson <dme@dme.org>
  23
  24 (eval-when-compile (require 'cl))
  25 (require 'mm-view)
  26 (require 'message)
  27 (require 'mm-decode)
  28 (require 'mailcap)
  29 (require 'icalendar)
  30 (require 'goto-addr)
  31
  32 (require 'notmuch-lib)
  33 (require 'notmuch-query)
  34 (require 'notmuch-wash)
  35 (require 'notmuch-mua)
  36 (require 'notmuch-crypto)
  37 (require 'notmuch-print)
  38
  39 (declare-function notmuch-call-notmuch-process "notmuch" (&rest args))
  40 (declare-function notmuch-fontify-headers "notmuch" nil)
  41 (declare-function notmuch-read-tag-changes "notmuch" (&optional initial-input &rest search-terms))
  42 (declare-function notmuch-search-next-thread "notmuch" nil)
  43 (declare-function notmuch-search-show-thread "notmuch" nil)
  44 (declare-function notmuch-update-tags "notmuch" (current-tags tag-changes))
  45
  46 (defcustom notmuch-message-headers '("Subject" "To" "Cc" "Date")
  47   "Headers that should be shown in a message, in this order.
  48
  49 For an open message, all of these headers will be made visible
  50 according to `notmuch-message-headers-visible' or can be toggled
  51 with `notmuch-show-toggle-headers'. For a closed message, only
  52 the first header in the list will be visible."
  53   :type '(repeat string)
  54   :group 'notmuch-show)
  55
  56 (defcustom notmuch-message-headers-visible t
  57   "Should the headers be visible by default?
  58
  59 If this value is non-nil, then all of the headers defined in
  60 `notmuch-message-headers' will be visible by default in the display
  61 of each message. Otherwise, these headers will be hidden and
  62 `notmuch-show-toggle-headers' can be used to make the visible for
  63 any given message."
  64   :type 'boolean
  65   :group 'notmuch-show)
  66
  67 (defcustom notmuch-show-relative-dates t
  68   "Display relative dates in the message summary line."
  69   :type 'boolean
  70   :group 'notmuch-show)
  71
  72 (defvar notmuch-show-markup-headers-hook '(notmuch-show-colour-headers)
  73   "A list of functions called to decorate the headers listed in
  74 `notmuch-message-headers'.")
  75
  76 (defcustom notmuch-show-hook '(notmuch-show-turn-on-visual-line-mode)
  77   "Functions called after populating a `notmuch-show' buffer."
  78   :type 'hook
  79   :options '(notmuch-show-turn-on-visual-line-mode)
  80   :group 'notmuch-show
  81   :group 'notmuch-hooks)
  82
  83 (defcustom notmuch-show-insert-text/plain-hook '(notmuch-wash-wrap-long-lines
  84                                                  notmuch-wash-tidy-citations
  85                                                  notmuch-wash-elide-blank-lines
  86                                                  notmuch-wash-excerpt-citations)
  87   "Functions used to improve the display of text/plain parts."
  88   :type 'hook
  89   :options '(notmuch-wash-convert-inline-patch-to-part
  90              notmuch-wash-wrap-long-lines
  91              notmuch-wash-tidy-citations
  92              notmuch-wash-elide-blank-lines
  93              notmuch-wash-excerpt-citations)
  94   :group 'notmuch-show
  95   :group 'notmuch-hooks)
  96
  97 ;; Mostly useful for debugging.
  98 (defcustom notmuch-show-all-multipart/alternative-parts t
  99   "Should all parts of multipart/alternative parts be shown?"
 100   :type 'boolean
 101   :group 'notmuch-show)
 102
 103 (defcustom notmuch-show-indent-messages-width 1
 104   "Width of message indentation in threads.
 105
 106 Messages are shown indented according to their depth in a thread.
 107 This variable determines the width of this indentation measured
 108 in number of blanks.  Defaults to `1', choose `0' to disable
 109 indentation."
 110   :type 'integer
 111   :group 'notmuch-show)
 112
 113 (defcustom notmuch-show-indent-multipart nil
 114   "Should the sub-parts of a multipart/* part be indented?"
 115   ;; dme: Not sure which is a good default.
 116   :type 'boolean
 117   :group 'notmuch-show)
 118
 119 (defcustom notmuch-show-part-button-default-action 'notmuch-show-save-part
 120   "Default part header button action (on ENTER or mouse click)."
 121   :group 'notmuch-show
 122   :type '(choice (const :tag "Save part"
 123                         notmuch-show-save-part)
 124                  (const :tag "View part"
 125                         notmuch-show-view-part)
 126                  (const :tag "View interactively"
 127                         notmuch-show-interactively-view-part)))
 128
 129 (defcustom notmuch-show-only-matching-messages nil
 130   "Only matching messages are shown by default."
 131   :type 'boolean
 132   :group 'notmuch-show)
 133
 134 (defvar notmuch-show-thread-id nil)
 135 (make-variable-buffer-local 'notmuch-show-thread-id)
 136 (put 'notmuch-show-thread-id 'permanent-local t)
 137
 138 (defvar notmuch-show-parent-buffer nil)
 139 (make-variable-buffer-local 'notmuch-show-parent-buffer)
 140 (put 'notmuch-show-parent-buffer 'permanent-local t)
 141
 142 (defvar notmuch-show-query-context nil)
 143 (make-variable-buffer-local 'notmuch-show-query-context)
 144 (put 'notmuch-show-query-context 'permanent-local t)
 145
 146 (defvar notmuch-show-process-crypto nil)
 147 (make-variable-buffer-local 'notmuch-show-process-crypto)
 148 (put 'notmuch-show-process-crypto 'permanent-local t)
 149
 150 (defvar notmuch-show-elide-non-matching-messages nil)
 151 (make-variable-buffer-local 'notmuch-show-elide-non-matching-messages)
 152 (put 'notmuch-show-elide-non-matching-messages 'permanent-local t)
 153
 154 (defvar notmuch-show-indent-content t)
 155 (make-variable-buffer-local 'notmuch-show-indent-content)
 156 (put 'notmuch-show-indent-content 'permanent-local t)
 157
 158 (defcustom notmuch-show-stash-mlarchive-link-alist
 159   '(("Gmane" . "http://mid.gmane.org/")
 160     ("MARC" . "http://marc.info/?i=")
 161     ("Mail Archive, The" . "http://mail-archive.com/search?l=mid&q=")
 162     ;; FIXME: can these services be searched by `Message-Id' ?
 163     ;; ("MarkMail" . "http://markmail.org/")
 164     ;; ("Nabble" . "http://nabble.com/")
 165     ;; ("opensubscriber" . "http://opensubscriber.com/")
 166     )
 167   "List of Mailing List Archives to use when stashing links.
 168
 169 These URIs are concatenated with the current message's
 170 Message-Id in `notmuch-show-stash-mlarchive-link'."
 171   :type '(alist :key-type (string :tag "Name")
 172                 :value-type (string :tag "URL"))
 173   :group 'notmuch-show)
 174
 175 (defcustom notmuch-show-stash-mlarchive-link-default "Gmane"
 176   "Default Mailing List Archive to use when stashing links.
 177
 178 This is used when `notmuch-show-stash-mlarchive-link' isn't
 179 provided with an MLA argument nor `completing-read' input."
 180   :type `(choice
 181           ,@(mapcar
 182              (lambda (mla)
 183                (list 'const :tag (car mla) :value (car mla)))
 184              notmuch-show-stash-mlarchive-link-alist))
 185   :group 'notmuch-show)
 186
 187 (defmacro with-current-notmuch-show-message (&rest body)
 188   "Evaluate body with current buffer set to the text of current message"
 189   `(save-excursion
 190      (let ((id (notmuch-show-get-message-id)))
 191        (let ((buf (generate-new-buffer (concat "*notmuch-msg-" id "*"))))
 192          (with-current-buffer buf
 193             (call-process notmuch-command nil t nil "show" "--format=raw" id)
 194            ,@body)
 195          (kill-buffer buf)))))
 196
 197 (defun notmuch-show-turn-on-visual-line-mode ()
 198   "Enable Visual Line mode."
 199   (visual-line-mode t))
 200
 201 (defun notmuch-show-view-all-mime-parts ()
 202   "Use external viewers to view all attachments from the current message."
 203   (interactive)
 204   (with-current-notmuch-show-message
 205    ;; We override the mm-inline-media-tests to indicate which message
 206    ;; parts are already sufficiently handled by the original
 207    ;; presentation of the message in notmuch-show mode. These parts
 208    ;; will be inserted directly into the temporary buffer of
 209    ;; with-current-notmuch-show-message and silently discarded.
 210    ;;
 211    ;; Any MIME part not explicitly mentioned here will be handled by an
 212    ;; external viewer as configured in the various mailcap files.
 213    (let ((mm-inline-media-tests '(
 214                                   ("text/.*" ignore identity)
 215                                   ("application/pgp-signature" ignore identity)
 216                                   ("multipart/alternative" ignore identity)
 217                                   ("multipart/mixed" ignore identity)
 218                                   ("multipart/related" ignore identity)
 219                                  )))
 220      (mm-display-parts (mm-dissect-buffer)))))
 221
 222 (defun notmuch-foreach-mime-part (function mm-handle)
 223   (cond ((stringp (car mm-handle))
 224          (dolist (part (cdr mm-handle))
 225            (notmuch-foreach-mime-part function part)))
 226         ((bufferp (car mm-handle))
 227          (funcall function mm-handle))
 228         (t (dolist (part mm-handle)
 229              (notmuch-foreach-mime-part function part)))))
 230
 231 (defun notmuch-count-attachments (mm-handle)
 232   (let ((count 0))
 233     (notmuch-foreach-mime-part
 234      (lambda (p)
 235        (let ((disposition (mm-handle-disposition p)))
 236          (and (listp disposition)
 237               (or (equal (car disposition) "attachment")
 238                   (and (equal (car disposition) "inline")
 239                        (assq 'filename disposition)))
 240               (incf count))))
 241      mm-handle)
 242     count))
 243
 244 (defun notmuch-save-attachments (mm-handle &optional queryp)
 245   (notmuch-foreach-mime-part
 246    (lambda (p)
 247      (let ((disposition (mm-handle-disposition p)))
 248        (and (listp disposition)
 249             (or (equal (car disposition) "attachment")
 250                 (and (equal (car disposition) "inline")
 251                      (assq 'filename disposition)))
 252             (or (not queryp)
 253                 (y-or-n-p
 254                  (concat "Save '" (cdr (assq 'filename disposition)) "' ")))
 255             (mm-save-part p))))
 256    mm-handle))
 257
 258 (defun notmuch-show-save-attachments ()
 259   "Save all attachments from the current message."
 260   (interactive)
 261   (with-current-notmuch-show-message
 262    (let ((mm-handle (mm-dissect-buffer)))
 263      (notmuch-save-attachments
 264       mm-handle (> (notmuch-count-attachments mm-handle) 1))))
 265   (message "Done"))
 266
 267 (defun notmuch-show-with-message-as-text (fn)
 268   "Apply FN to a text representation of the current message.
 269
 270 FN is called with one argument, the message properties. It should
 271 operation on the contents of the current buffer."
 272
 273   ;; Remake the header to ensure that all information is available.
 274   (let* ((to (notmuch-show-get-to))
 275          (cc (notmuch-show-get-cc))
 276          (from (notmuch-show-get-from))
 277          (subject (notmuch-show-get-subject))
 278          (date (notmuch-show-get-date))
 279          (tags (notmuch-show-get-tags))
 280          (depth (notmuch-show-get-depth))
 281
 282          (header (concat
 283                   "Subject: " subject "\n"
 284                   "To: " to "\n"
 285                   (if (not (string= cc ""))
 286                       (concat "Cc: " cc "\n")
 287                     "")
 288                   "From: " from "\n"
 289                   "Date: " date "\n"
 290                   (if tags
 291                       (concat "Tags: "
 292                               (mapconcat #'identity tags ", ") "\n")
 293                     "")))
 294          (all (buffer-substring (notmuch-show-message-top)
 295                                 (notmuch-show-message-bottom)))
 296
 297          (props (notmuch-show-get-message-properties))
 298          (indenting notmuch-show-indent-content))
 299     (with-temp-buffer
 300       (insert all)
 301       (if indenting
 302           (indent-rigidly (point-min) (point-max) (- depth)))
 303       ;; Remove the original header.
 304       (goto-char (point-min))
 305       (re-search-forward "^$" (point-max) nil)
 306       (delete-region (point-min) (point))
 307       (insert header)
 308       (funcall fn props))))
 309
 310 (defun notmuch-show-print-message ()
 311   "Print the current message."
 312   (interactive)
 313   (notmuch-show-with-message-as-text 'notmuch-print-message))
 314
 315 (defun notmuch-show-fontify-header ()
 316   (let ((face (cond
 317                ((looking-at "[Tt]o:")
 318                 'message-header-to)
 319                ((looking-at "[Bb]?[Cc][Cc]:")
 320                 'message-header-cc)
 321                ((looking-at "[Ss]ubject:")
 322                 'message-header-subject)
 323                ((looking-at "[Ff]rom:")
 324                 'message-header-from)
 325                (t
 326                 'message-header-other))))
 327
 328     (overlay-put (make-overlay (point) (re-search-forward ":"))
 329                  'face 'message-header-name)
 330     (overlay-put (make-overlay (point) (re-search-forward ".*$"))
 331                  'face face)))
 332
 333 (defun notmuch-show-colour-headers ()
 334   "Apply some colouring to the current headers."
 335   (goto-char (point-min))
 336   (while (looking-at "^[A-Za-z][-A-Za-z0-9]*:")
 337     (notmuch-show-fontify-header)
 338     (forward-line)))
 339
 340 (defun notmuch-show-spaces-n (n)
 341   "Return a string comprised of `n' spaces."
 342   (make-string n ? ))
 343
 344 (defun notmuch-show-update-tags (tags)
 345   "Update the displayed tags of the current message."
 346   (save-excursion
 347     (goto-char (notmuch-show-message-top))
 348     (if (re-search-forward "(\\([^()]*\\))$" (line-end-position) t)
 349         (let ((inhibit-read-only t))
 350           (replace-match (concat "("
 351                                  (propertize (mapconcat 'identity tags " ")
 352                                              'face 'notmuch-tag-face)
 353                                  ")"))))))
 354
 355 (defun notmuch-show-clean-address (address)
 356   "Try to clean a single email ADDRESS for display.  Return
 357 unchanged ADDRESS if parsing fails."
 358   (condition-case nil
 359     (let (p-name p-address)
 360       ;; It would be convenient to use `mail-header-parse-address',
 361       ;; but that expects un-decoded mailbox parts, whereas our
 362       ;; mailbox parts are already decoded (and hence may contain
 363       ;; UTF-8). Given that notmuch should handle most of the awkward
 364       ;; cases, some simple string deconstruction should be sufficient
 365       ;; here.
 366       (cond
 367        ;; "User <user@dom.ain>" style.
 368        ((string-match "\\(.*\\) <\\(.*\\)>" address)
 369         (setq p-name (match-string 1 address)
 370               p-address (match-string 2 address)))
 371
 372        ;; "<user@dom.ain>" style.
 373        ((string-match "<\\(.*\\)>" address)
 374         (setq p-address (match-string 1 address)))
 375
 376        ;; Everything else.
 377        (t
 378         (setq p-address address)))
 379
 380       (when p-name
 381         ;; Remove elements of the mailbox part that are not relevant for
 382         ;; display, even if they are required during transport:
 383         ;;
 384         ;; Backslashes.
 385         (setq p-name (replace-regexp-in-string "\\\\" "" p-name))
 386
 387         ;; Outer single and double quotes, which might be nested.
 388         (loop
 389          with start-of-loop
 390          do (setq start-of-loop p-name)
 391
 392          when (string-match "^\"\\(.*\\)\"$" p-name)
 393          do (setq p-name (match-string 1 p-name))
 394
 395          when (string-match "^'\\(.*\\)'$" p-name)
 396          do (setq p-name (match-string 1 p-name))
 397
 398          until (string= start-of-loop p-name)))
 399
 400       ;; If the address is 'foo@bar.com <foo@bar.com>' then show just
 401       ;; 'foo@bar.com'.
 402       (when (string= p-name p-address)
 403         (setq p-name nil))
 404
 405       ;; If no name results, return just the address.
 406       (if (not p-name)
 407           p-address
 408         ;; Otherwise format the name and address together.
 409         (concat p-name " <" p-address ">")))
 410     (error address)))
 411
 412 (defun notmuch-show-insert-headerline (headers date tags depth)
 413   "Insert a notmuch style headerline based on HEADERS for a
 414 message at DEPTH in the current thread."
 415   (let ((start (point)))
 416     (insert (notmuch-show-spaces-n (* notmuch-show-indent-messages-width depth))
 417             (notmuch-show-clean-address (plist-get headers :From))
 418             " ("
 419             date
 420             ") ("
 421             (propertize (mapconcat 'identity tags " ")
 422                         'face 'notmuch-tag-face)
 423             ")\n")
 424     (overlay-put (make-overlay start (point)) 'face 'notmuch-message-summary-face)))
 425
 426 (defun notmuch-show-insert-header (header header-value)
 427   "Insert a single header."
 428   (insert header ": " header-value "\n"))
 429
 430 (defun notmuch-show-insert-headers (headers)
 431   "Insert the headers of the current message."
 432   (let ((start (point)))
 433     (mapc (lambda (header)
 434             (let* ((header-symbol (intern (concat ":" header)))
 435                    (header-value (plist-get headers header-symbol)))
 436               (if (and header-value
 437                        (not (string-equal "" header-value)))
 438                   (notmuch-show-insert-header header header-value))))
 439           notmuch-message-headers)
 440     (save-excursion
 441       (save-restriction
 442         (narrow-to-region start (point-max))
 443         (run-hooks 'notmuch-show-markup-headers-hook)))))
 444
 445 (define-button-type 'notmuch-show-part-button-type
 446   'action 'notmuch-show-part-button-default
 447   'keymap 'notmuch-show-part-button-map
 448   'follow-link t
 449   'face 'message-mml)
 450
 451 (defvar notmuch-show-part-button-map
 452   (let ((map (make-sparse-keymap)))
 453     (set-keymap-parent map button-map)
 454     (define-key map "s" 'notmuch-show-part-button-save)
 455     (define-key map "v" 'notmuch-show-part-button-view)
 456     (define-key map "o" 'notmuch-show-part-button-interactively-view)
 457     map)
 458   "Submap for button commands")
 459 (fset 'notmuch-show-part-button-map notmuch-show-part-button-map)
 460
 461 (defun notmuch-show-insert-part-header (nth content-type declared-type &optional name comment)
 462   (let ((button))
 463     (setq button
 464           (insert-button
 465            (concat "[ "
 466                    (if name (concat name ": ") "")
 467                    declared-type
 468                    (if (not (string-equal declared-type content-type))
 469                        (concat " (as " content-type ")")
 470                      "")
 471                    (or comment "")
 472                    " ]")
 473            :type 'notmuch-show-part-button-type
 474            :notmuch-part nth
 475            :notmuch-filename name
 476            :notmuch-content-type content-type))
 477     (insert "\n")
 478     ;; return button
 479     button))
 480
 481 ;; Functions handling particular MIME parts.
 482
 483 (defmacro notmuch-with-temp-part-buffer (message-id nth &rest body)
 484   (declare (indent 2))
 485   (let ((process-crypto (make-symbol "process-crypto")))
 486     `(let ((,process-crypto notmuch-show-process-crypto))
 487        (with-temp-buffer
 488          (setq notmuch-show-process-crypto ,process-crypto)
 489          ;; Always acquires the part via `notmuch part', even if it is
 490          ;; available in the JSON output.
 491          (insert (notmuch-show-get-bodypart-internal ,message-id ,nth))
 492          ,@body))))
 493
 494 (defun notmuch-show-save-part (message-id nth &optional filename content-type)
 495   (notmuch-with-temp-part-buffer message-id nth
 496     (let ((file (read-file-name
 497                  "Filename to save as: "
 498                  (or mailcap-download-directory "~/")
 499                  nil nil
 500                  filename)))
 501       ;; Don't re-compress .gz & al.  Arguably we should make
 502       ;; `file-name-handler-alist' nil, but that would chop
 503       ;; ange-ftp, which is reasonable to use here.
 504       (mm-write-region (point-min) (point-max) file nil nil nil 'no-conversion t))))
 505
 506 (defun notmuch-show-view-part (message-id nth &optional filename content-type )
 507   (notmuch-with-temp-part-buffer message-id nth
 508     ;; set mm-inlined-types to nil to force an external viewer
 509     (let ((handle (mm-make-handle (current-buffer) (list content-type)))
 510           (mm-inlined-types nil))
 511       ;; We override mm-save-part as notmuch-show-save-part is better
 512       ;; since it offers the filename. We need to lexically bind
 513       ;; everything we need for notmuch-show-save-part to prevent
 514       ;; potential dynamic shadowing.
 515       (lexical-let ((message-id message-id)
 516                     (nth nth)
 517                     (filename filename)
 518                     (content-type content-type))
 519         (flet ((mm-save-part (&rest args) (notmuch-show-save-part
 520                                            message-id nth filename content-type)))
 521           (mm-display-part handle))))))
 522
 523 (defun notmuch-show-interactively-view-part (message-id nth &optional filename content-type)
 524   (notmuch-with-temp-part-buffer message-id nth
 525     (let ((handle (mm-make-handle (current-buffer) (list content-type))))
 526       (mm-interactively-view-part handle))))
 527
 528 (defun notmuch-show-mm-display-part-inline (msg part nth content-type)
 529   "Use the mm-decode/mm-view functions to display a part in the
 530 current buffer, if possible."
 531   (let ((display-buffer (current-buffer)))
 532     (with-temp-buffer
 533       (let* ((charset (plist-get part :content-charset))
 534              (handle (mm-make-handle (current-buffer) `(,content-type (charset . ,charset)))))
 535         ;; If the user wants the part inlined, insert the content and
 536         ;; test whether we are able to inline it (which includes both
 537         ;; capability and suitability tests).
 538         (when (mm-inlined-p handle)
 539           (insert (notmuch-show-get-bodypart-content msg part nth))
 540           (when (mm-inlinable-p handle)
 541             (set-buffer display-buffer)
 542             (mm-display-part handle)
 543             t))))))
 544
 545 (defun notmuch-show-multipart/*-to-list (part)
 546   (mapcar (lambda (inner-part) (plist-get inner-part :content-type))
 547           (plist-get part :content)))
 548
 549 (defun notmuch-show-insert-part-multipart/alternative (msg part content-type nth depth declared-type)
 550   (notmuch-show-insert-part-header nth declared-type content-type nil)
 551   (let ((chosen-type (car (notmuch-multipart/alternative-choose (notmuch-show-multipart/*-to-list part))))
 552         (inner-parts (plist-get part :content))
 553         (start (point)))
 554     ;; This inserts all parts of the chosen type rather than just one,
 555     ;; but it's not clear that this is the wrong thing to do - which
 556     ;; should be chosen if there are more than one that match?
 557     (mapc (lambda (inner-part)
 558             (let ((inner-type (plist-get inner-part :content-type)))
 559               (if (or notmuch-show-all-multipart/alternative-parts
 560                       (string= chosen-type inner-type))
 561                   (notmuch-show-insert-bodypart msg inner-part depth)
 562                 (notmuch-show-insert-part-header (plist-get inner-part :id) inner-type inner-type nil " (not shown)"))))
 563           inner-parts)
 564
 565     (when notmuch-show-indent-multipart
 566       (indent-rigidly start (point) 1)))
 567   t)
 568
 569 (defun notmuch-show-setup-w3m ()
 570   "Instruct w3m how to retrieve content from a \"related\" part of a message."
 571   (interactive)
 572   (if (boundp 'w3m-cid-retrieve-function-alist)
 573     (unless (assq 'notmuch-show-mode w3m-cid-retrieve-function-alist)
 574       (push (cons 'notmuch-show-mode 'notmuch-show-w3m-cid-retrieve)
 575             w3m-cid-retrieve-function-alist)))
 576   (setq mm-inline-text-html-with-images t))
 577
 578 (defvar w3m-current-buffer) ;; From `w3m.el'.
 579 (defvar notmuch-show-w3m-cid-store nil)
 580 (make-variable-buffer-local 'notmuch-show-w3m-cid-store)
 581
 582 (defun notmuch-show-w3m-cid-store-internal (content-id
 583                                             message-id
 584                                             part-number
 585                                             content-type
 586                                             content)
 587   (push (list content-id
 588               message-id
 589               part-number
 590               content-type
 591               content)
 592         notmuch-show-w3m-cid-store))
 593
 594 (defun notmuch-show-w3m-cid-store (msg part)
 595   (let ((content-id (plist-get part :content-id)))
 596     (when content-id
 597       (notmuch-show-w3m-cid-store-internal (concat "cid:" content-id)
 598                                            (plist-get msg :id)
 599                                            (plist-get part :id)
 600                                            (plist-get part :content-type)
 601                                            nil))))
 602
 603 (defun notmuch-show-w3m-cid-retrieve (url &rest args)
 604   (let ((matching-part (with-current-buffer w3m-current-buffer
 605                          (assoc url notmuch-show-w3m-cid-store))))
 606     (if matching-part
 607         (let ((message-id (nth 1 matching-part))
 608               (part-number (nth 2 matching-part))
 609               (content-type (nth 3 matching-part))
 610               (content (nth 4 matching-part)))
 611           ;; If we don't already have the content, get it and cache
 612           ;; it, as some messages reference the same cid: part many
 613           ;; times (hundreds!), which results in many calls to
 614           ;; `notmuch part'.
 615           (unless content
 616             (setq content (notmuch-show-get-bodypart-internal (concat "id:" message-id)
 617                                                               part-number))
 618             (with-current-buffer w3m-current-buffer
 619               (notmuch-show-w3m-cid-store-internal url
 620                                                    message-id
 621                                                    part-number
 622                                                    content-type
 623                                                    content)))
 624           (insert content)
 625           content-type)
 626       nil)))
 627
 628 (defun notmuch-show-insert-part-multipart/related (msg part content-type nth depth declared-type)
 629   (notmuch-show-insert-part-header nth declared-type content-type nil)
 630   (let ((inner-parts (plist-get part :content))
 631         (start (point)))
 632
 633     ;; We assume that the first part is text/html and the remainder
 634     ;; things that it references.
 635
 636     ;; Stash the non-primary parts.
 637     (mapc (lambda (part)
 638             (notmuch-show-w3m-cid-store msg part))
 639           (cdr inner-parts))
 640
 641     ;; Render the primary part.
 642     (notmuch-show-insert-bodypart msg (car inner-parts) depth)
 643
 644     (when notmuch-show-indent-multipart
 645       (indent-rigidly start (point) 1)))
 646   t)
 647
 648 (defun notmuch-show-insert-part-multipart/signed (msg part content-type nth depth declared-type)
 649   (let ((button (notmuch-show-insert-part-header nth declared-type content-type nil)))
 650     (button-put button 'face 'notmuch-crypto-part-header)
 651     ;; add signature status button if sigstatus provided
 652     (if (plist-member part :sigstatus)
 653         (let* ((from (notmuch-show-get-header :From msg))
 654                (sigstatus (car (plist-get part :sigstatus))))
 655           (notmuch-crypto-insert-sigstatus-button sigstatus from))
 656       ;; if we're not adding sigstatus, tell the user how they can get it
 657       (button-put button 'help-echo "Set notmuch-crypto-process-mime to process cryptographic MIME parts.")))
 658
 659   (let ((inner-parts (plist-get part :content))
 660         (start (point)))
 661     ;; Show all of the parts.
 662     (mapc (lambda (inner-part)
 663             (notmuch-show-insert-bodypart msg inner-part depth))
 664           inner-parts)
 665
 666     (when notmuch-show-indent-multipart
 667       (indent-rigidly start (point) 1)))
 668   t)
 669
 670 (defun notmuch-show-insert-part-multipart/encrypted (msg part content-type nth depth declared-type)
 671   (let ((button (notmuch-show-insert-part-header nth declared-type content-type nil)))
 672     (button-put button 'face 'notmuch-crypto-part-header)
 673     ;; add encryption status button if encstatus specified
 674     (if (plist-member part :encstatus)
 675         (let ((encstatus (car (plist-get part :encstatus))))
 676           (notmuch-crypto-insert-encstatus-button encstatus)
 677           ;; add signature status button if sigstatus specified
 678           (if (plist-member part :sigstatus)
 679               (let* ((from (notmuch-show-get-header :From msg))
 680                      (sigstatus (car (plist-get part :sigstatus))))
 681                 (notmuch-crypto-insert-sigstatus-button sigstatus from))))
 682       ;; if we're not adding encstatus, tell the user how they can get it
 683       (button-put button 'help-echo "Set notmuch-crypto-process-mime to process cryptographic MIME parts.")))
 684
 685   (let ((inner-parts (plist-get part :content))
 686         (start (point)))
 687     ;; Show all of the parts.
 688     (mapc (lambda (inner-part)
 689             (notmuch-show-insert-bodypart msg inner-part depth))
 690           inner-parts)
 691
 692     (when notmuch-show-indent-multipart
 693       (indent-rigidly start (point) 1)))
 694   t)
 695
 696 (defun notmuch-show-insert-part-multipart/* (msg part content-type nth depth declared-type)
 697   (notmuch-show-insert-part-header nth declared-type content-type nil)
 698   (let ((inner-parts (plist-get part :content))
 699         (start (point)))
 700     ;; Show all of the parts.
 701     (mapc (lambda (inner-part)
 702             (notmuch-show-insert-bodypart msg inner-part depth))
 703           inner-parts)
 704
 705     (when notmuch-show-indent-multipart
 706       (indent-rigidly start (point) 1)))
 707   t)
 708
 709 (defun notmuch-show-insert-part-message/rfc822 (msg part content-type nth depth declared-type)
 710   (notmuch-show-insert-part-header nth declared-type content-type nil)
 711   (let* ((message (car (plist-get part :content)))
 712          (body (car (plist-get message :body)))
 713          (start (point)))
 714
 715     ;; Override `notmuch-message-headers' to force `From' to be
 716     ;; displayed.
 717     (let ((notmuch-message-headers '("From" "Subject" "To" "Cc" "Date")))
 718       (notmuch-show-insert-headers (plist-get message :headers)))
 719
 720     ;; Blank line after headers to be compatible with the normal
 721     ;; message display.
 722     (insert "\n")
 723
 724     ;; Show the body
 725     (notmuch-show-insert-bodypart msg body depth)
 726
 727     (when notmuch-show-indent-multipart
 728       (indent-rigidly start (point) 1)))
 729   t)
 730
 731 (defun notmuch-show-insert-part-text/plain (msg part content-type nth depth declared-type)
 732   (let ((start (point)))
 733     ;; If this text/plain part is not the first part in the message,
 734     ;; insert a header to make this clear.
 735     (if (> nth 1)
 736         (notmuch-show-insert-part-header nth declared-type content-type (plist-get part :filename)))
 737     (insert (notmuch-show-get-bodypart-content msg part nth))
 738     (save-excursion
 739       (save-restriction
 740         (narrow-to-region start (point-max))
 741         (run-hook-with-args 'notmuch-show-insert-text/plain-hook msg depth))))
 742   t)
 743
 744 (defun notmuch-show-insert-part-text/calendar (msg part content-type nth depth declared-type)
 745   (notmuch-show-insert-part-header nth declared-type content-type (plist-get part :filename))
 746   (insert (with-temp-buffer
 747             (insert (notmuch-show-get-bodypart-content msg part nth))
 748             (goto-char (point-min))
 749             (let ((file (make-temp-file "notmuch-ical"))
 750                   result)
 751               (icalendar--convert-ical-to-diary
 752                (icalendar--read-element nil nil)
 753                file t)
 754               (set-buffer (get-file-buffer file))
 755               (setq result (buffer-substring (point-min) (point-max)))
 756               (set-buffer-modified-p nil)
 757               (kill-buffer (current-buffer))
 758               (delete-file file)
 759               result)))
 760   t)
 761
 762 ;; For backwards compatibility.
 763 (defun notmuch-show-insert-part-text/x-vcalendar (msg part content-type nth depth declared-type)
 764   (notmuch-show-insert-part-text/calendar msg part content-type nth depth declared-type))
 765
 766 (defun notmuch-show-insert-part-application/octet-stream (msg part content-type nth depth declared-type)
 767   ;; If we can deduce a MIME type from the filename of the attachment,
 768   ;; do so and pass it on to the handler for that type.
 769   (if (plist-get part :filename)
 770       (let ((extension (file-name-extension (plist-get part :filename)))
 771             mime-type)
 772         (if extension
 773             (progn
 774               (mailcap-parse-mimetypes)
 775               (setq mime-type (mailcap-extension-to-mime extension))
 776               (if (and mime-type
 777                        (not (string-equal mime-type "application/octet-stream")))
 778                   (notmuch-show-insert-bodypart-internal msg part mime-type nth depth content-type)
 779                 nil))
 780           nil))))
 781
 782 ;; Handler for wash generated inline patch fake parts.
 783 (defun notmuch-show-insert-part-inline-patch-fake-part (msg part content-type nth depth declared-type)
 784   (notmuch-show-insert-part-*/* msg part "text/x-diff" nth depth "inline patch"))
 785
 786 (defun notmuch-show-insert-part-*/* (msg part content-type nth depth declared-type)
 787   ;; This handler _must_ succeed - it is the handler of last resort.
 788   (notmuch-show-insert-part-header nth content-type declared-type (plist-get part :filename))
 789   (notmuch-show-mm-display-part-inline msg part nth content-type)
 790   t)
 791
 792 ;; Functions for determining how to handle MIME parts.
 793
 794 (defun notmuch-show-handlers-for (content-type)
 795   "Return a list of content handlers for a part of type CONTENT-TYPE."
 796   (let (result)
 797     (mapc (lambda (func)
 798             (if (functionp func)
 799                 (push func result)))
 800           ;; Reverse order of prefrence.
 801           (list (intern (concat "notmuch-show-insert-part-*/*"))
 802                 (intern (concat
 803                          "notmuch-show-insert-part-"
 804                          (car (notmuch-split-content-type content-type))
 805                          "/*"))
 806                 (intern (concat "notmuch-show-insert-part-" content-type))))
 807     result))
 808
 809 ;; Helper for parts which are generally not included in the default
 810 ;; JSON output.
 811 (defun notmuch-show-get-bodypart-internal (message-id part-number)
 812   (let ((args '("show" "--format=raw"))
 813         (part-arg (format "--part=%s" part-number)))
 814     (setq args (append args (list part-arg)))
 815     (if notmuch-show-process-crypto
 816         (setq args (append args '("--decrypt"))))
 817     (setq args (append args (list message-id)))
 818     (with-temp-buffer
 819       (let ((coding-system-for-read 'no-conversion))
 820         (progn
 821           (apply 'call-process (append (list notmuch-command nil (list t nil) nil) args))
 822           (buffer-string))))))
 823
 824 (defun notmuch-show-get-bodypart-content (msg part nth)
 825   (or (plist-get part :content)
 826       (notmuch-show-get-bodypart-internal (concat "id:" (plist-get msg :id)) nth)))
 827
 828 ;; \f
 829
 830 (defun notmuch-show-insert-bodypart-internal (msg part content-type nth depth declared-type)
 831   (let ((handlers (notmuch-show-handlers-for content-type)))
 832     ;; Run the content handlers until one of them returns a non-nil
 833     ;; value.
 834     (while (and handlers
 835                 (not (funcall (car handlers) msg part content-type nth depth declared-type)))
 836       (setq handlers (cdr handlers))))
 837   t)
 838
 839 (defun notmuch-show-insert-bodypart (msg part depth)
 840   "Insert the body part PART at depth DEPTH in the current thread."
 841   (let ((content-type (downcase (plist-get part :content-type)))
 842         (nth (plist-get part :id)))
 843     (notmuch-show-insert-bodypart-internal msg part content-type nth depth content-type))
 844   ;; Some of the body part handlers leave point somewhere up in the
 845   ;; part, so we make sure that we're down at the end.
 846   (goto-char (point-max))
 847   ;; Ensure that the part ends with a carriage return.
 848   (unless (bolp)
 849     (insert "\n")))
 850
 851 (defun notmuch-show-insert-body (msg body depth)
 852   "Insert the body BODY at depth DEPTH in the current thread."
 853   (mapc (lambda (part) (notmuch-show-insert-bodypart msg part depth)) body))
 854
 855 (defun notmuch-show-make-symbol (type)
 856   (make-symbol (concat "notmuch-show-" type)))
 857
 858 (defun notmuch-show-strip-re (string)
 859   (replace-regexp-in-string "\\([Rr]e: *\\)+" "" string))
 860
 861 (defvar notmuch-show-previous-subject "")
 862 (make-variable-buffer-local 'notmuch-show-previous-subject)
 863
 864 (defun notmuch-show-insert-msg (msg depth)
 865   "Insert the message MSG at depth DEPTH in the current thread."
 866   (let* ((headers (plist-get msg :headers))
 867          ;; Indentation causes the buffer offset of the start/end
 868          ;; points to move, so we must use markers.
 869          message-start message-end
 870          content-start content-end
 871          headers-start headers-end
 872          body-start body-end
 873          (headers-invis-spec (notmuch-show-make-symbol "header"))
 874          (message-invis-spec (notmuch-show-make-symbol "message"))
 875          (bare-subject (notmuch-show-strip-re (plist-get headers :Subject))))
 876
 877     ;; Set `buffer-invisibility-spec' to `nil' (a list), otherwise
 878     ;; removing items from `buffer-invisibility-spec' (which is what
 879     ;; `notmuch-show-headers-visible' and
 880     ;; `notmuch-show-message-visible' do) is a no-op and has no
 881     ;; effect. This caused threads with only matching messages to have
 882     ;; those messages hidden initially because
 883     ;; `buffer-invisibility-spec' stayed `t'.
 884     ;;
 885     ;; This needs to be set here (rather than just above the call to
 886     ;; `notmuch-show-headers-visible') because some of the part
 887     ;; rendering or body washing functions
 888     ;; (e.g. `notmuch-wash-text/plain-citations') manipulate
 889     ;; `buffer-invisibility-spec').
 890     (when (eq buffer-invisibility-spec t)
 891       (setq buffer-invisibility-spec nil))
 892
 893     (setq message-start (point-marker))
 894
 895     (notmuch-show-insert-headerline headers
 896                                     (or (if notmuch-show-relative-dates
 897                                             (plist-get msg :date_relative)
 898                                           nil)
 899                                         (plist-get headers :Date))
 900                                     (plist-get msg :tags) depth)
 901
 902     (setq content-start (point-marker))
 903
 904     (plist-put msg :headers-invis-spec headers-invis-spec)
 905     (plist-put msg :message-invis-spec message-invis-spec)
 906
 907     ;; Set `headers-start' to point after the 'Subject:' header to be
 908     ;; compatible with the existing implementation. This just sets it
 909     ;; to after the first header.
 910     (notmuch-show-insert-headers headers)
 911     (save-excursion
 912       (goto-char content-start)
 913       ;; If the subject of this message is the same as that of the
 914       ;; previous message, don't display it when this message is
 915       ;; collapsed.
 916       (when (not (string= notmuch-show-previous-subject
 917                           bare-subject))
 918         (forward-line 1))
 919       (setq headers-start (point-marker)))
 920     (setq headers-end (point-marker))
 921
 922     (setq notmuch-show-previous-subject bare-subject)
 923
 924     (setq body-start (point-marker))
 925     ;; A blank line between the headers and the body.
 926     (insert "\n")
 927     (notmuch-show-insert-body msg (plist-get msg :body)
 928                               (if notmuch-show-indent-content depth 0))
 929     ;; Ensure that the body ends with a newline.
 930     (unless (bolp)
 931       (insert "\n"))
 932     (setq body-end (point-marker))
 933     (setq content-end (point-marker))
 934
 935     ;; Indent according to the depth in the thread.
 936     (if notmuch-show-indent-content
 937         (indent-rigidly content-start content-end (* notmuch-show-indent-messages-width depth)))
 938
 939     (setq message-end (point-max-marker))
 940
 941     ;; Save the extents of this message over the whole text of the
 942     ;; message.
 943     (put-text-property message-start message-end :notmuch-message-extent (cons message-start message-end))
 944
 945     (let ((headers-overlay (make-overlay headers-start headers-end))
 946           (invis-specs (list headers-invis-spec message-invis-spec)))
 947       (overlay-put headers-overlay 'invisible invis-specs)
 948       (overlay-put headers-overlay 'priority 10))
 949     (overlay-put (make-overlay body-start body-end) 'invisible message-invis-spec)
 950
 951     (plist-put msg :depth depth)
 952
 953     ;; Save the properties for this message. Currently this saves the
 954     ;; entire message (augmented it with other stuff), which seems
 955     ;; like overkill. We might save a reduced subset (for example, not
 956     ;; the content).
 957     (notmuch-show-set-message-properties msg)
 958
 959     ;; Set header visibility.
 960     (notmuch-show-headers-visible msg notmuch-message-headers-visible)
 961
 962     ;; Message visibility depends on whether it matched the search
 963     ;; criteria.
 964     (notmuch-show-message-visible msg (and (plist-get msg :match)
 965                                            (not (plist-get msg :excluded))))))
 966
 967 (defun notmuch-show-toggle-process-crypto ()
 968   "Toggle the processing of cryptographic MIME parts."
 969   (interactive)
 970   (setq notmuch-show-process-crypto (not notmuch-show-process-crypto))
 971   (message (if notmuch-show-process-crypto
 972                "Processing cryptographic MIME parts."
 973              "Not processing cryptographic MIME parts."))
 974   (notmuch-show-refresh-view))
 975
 976 (defun notmuch-show-toggle-elide-non-matching ()
 977   "Toggle the display of non-matching messages."
 978   (interactive)
 979   (setq notmuch-show-elide-non-matching-messages (not notmuch-show-elide-non-matching-messages))
 980   (message (if notmuch-show-elide-non-matching-messages
 981                "Showing matching messages only."
 982              "Showing all messages."))
 983   (notmuch-show-refresh-view))
 984
 985 (defun notmuch-show-toggle-thread-indentation ()
 986   "Toggle the indentation of threads."
 987   (interactive)
 988   (setq notmuch-show-indent-content (not notmuch-show-indent-content))
 989   (message (if notmuch-show-indent-content
 990                "Content is indented."
 991              "Content is not indented."))
 992   (notmuch-show-refresh-view))
 993
 994 (defun notmuch-show-insert-tree (tree depth)
 995   "Insert the message tree TREE at depth DEPTH in the current thread."
 996   (let ((msg (car tree))
 997         (replies (cadr tree)))
 998     (if (or (not notmuch-show-elide-non-matching-messages)
 999             (plist-get msg :match))
1000         (notmuch-show-insert-msg msg depth))
1001     (notmuch-show-insert-thread replies (1+ depth))))
1002
1003 (defun notmuch-show-insert-thread (thread depth)
1004   "Insert the thread THREAD at depth DEPTH in the current forest."
1005   (mapc (lambda (tree) (notmuch-show-insert-tree tree depth)) thread))
1006
1007 (defun notmuch-show-insert-forest (forest)
1008   "Insert the forest of threads FOREST."
1009   (mapc (lambda (thread) (notmuch-show-insert-thread thread 0)) forest))
1010
1011 (defun notmuch-show-buttonise-links (start end)
1012   "Buttonise URLs and mail addresses between START and END.
1013
1014 This also turns id:\"<message id>\"-parts into buttons for
1015 a corresponding notmuch search."
1016   (goto-address-fontify-region start end)
1017   (save-excursion
1018     (goto-char start)
1019     (while (re-search-forward "id:\\(\"?\\)[^[:space:]\"]+\\1" end t)
1020       ;; remove the overlay created by goto-address-mode
1021       (remove-overlays (match-beginning 0) (match-end 0) 'goto-address t)
1022       (make-text-button (match-beginning 0) (match-end 0)
1023                         'action `(lambda (arg)
1024                                    (notmuch-show ,(match-string-no-properties 0)))
1025                         'follow-link t
1026                         'help-echo "Mouse-1, RET: search for this message"
1027                         'face goto-address-mail-face))))
1028
1029 ;;;###autoload
1030 (defun notmuch-show (thread-id &optional parent-buffer query-context buffer-name)
1031   "Run \"notmuch show\" with the given thread ID and display results.
1032
1033 The optional PARENT-BUFFER is the notmuch-search buffer from
1034 which this notmuch-show command was executed, (so that the
1035 next thread from that buffer can be show when done with this
1036 one).
1037
1038 The optional QUERY-CONTEXT is a notmuch search term. Only
1039 messages from the thread matching this search term are shown if
1040 non-nil.
1041
1042 The optional BUFFER-NAME provides the name of the buffer in
1043 which the message thread is shown. If it is nil (which occurs
1044 when the command is called interactively) the argument to the
1045 function is used."
1046   (interactive "sNotmuch show: ")
1047   (let ((buffer-name (generate-new-buffer-name
1048                       (or buffer-name
1049                           (concat "*notmuch-" thread-id "*")))))
1050     (switch-to-buffer (get-buffer-create buffer-name))
1051     ;; Set the default value for `notmuch-show-process-crypto' in this
1052     ;; buffer.
1053     (setq notmuch-show-process-crypto notmuch-crypto-process-mime)
1054     ;; Set the default value for
1055     ;; `notmuch-show-elide-non-matching-messages' in this buffer. If
1056     ;; there is a prefix argument, invert the default.
1057     (setq notmuch-show-elide-non-matching-messages notmuch-show-only-matching-messages)
1058     (if current-prefix-arg
1059         (setq notmuch-show-elide-non-matching-messages (not notmuch-show-elide-non-matching-messages)))
1060
1061     (setq notmuch-show-thread-id thread-id
1062           notmuch-show-parent-buffer parent-buffer
1063           notmuch-show-query-context query-context)
1064     (notmuch-show-build-buffer)
1065     (notmuch-show-goto-first-wanted-message)))
1066
1067 (defun notmuch-show-build-buffer ()
1068   (let ((inhibit-read-only t))
1069
1070     (notmuch-show-mode)
1071     ;; Don't track undo information for this buffer
1072     (set 'buffer-undo-list t)
1073
1074     (erase-buffer)
1075     (goto-char (point-min))
1076     (save-excursion
1077       (let* ((basic-args (list notmuch-show-thread-id))
1078              (args (if notmuch-show-query-context
1079                        (append (list "\'") basic-args
1080                                (list "and (" notmuch-show-query-context ")\'"))
1081                      (append (list "\'") basic-args (list "\'")))))
1082         (notmuch-show-insert-forest (notmuch-query-get-threads args))
1083         ;; If the query context reduced the results to nothing, run
1084         ;; the basic query.
1085         (when (and (eq (buffer-size) 0)
1086                    notmuch-show-query-context)
1087           (notmuch-show-insert-forest
1088            (notmuch-query-get-threads basic-args))))
1089
1090       (jit-lock-register #'notmuch-show-buttonise-links)
1091
1092       (run-hooks 'notmuch-show-hook))
1093
1094     ;; Set the header line to the subject of the first message.
1095     (setq header-line-format (notmuch-show-strip-re (notmuch-show-get-pretty-subject)))))
1096
1097 (defun notmuch-show-capture-state ()
1098   "Capture the state of the current buffer.
1099
1100 This includes:
1101  - the list of open messages,
1102  - the current message."
1103   (list (notmuch-show-get-message-id) (notmuch-show-get-message-ids-for-open-messages)))
1104
1105 (defun notmuch-show-apply-state (state)
1106   "Apply STATE to the current buffer.
1107
1108 This includes:
1109  - opening the messages previously opened,
1110  - closing all other messages,
1111  - moving to the correct current message."
1112   (let ((current (car state))
1113         (open (cadr state)))
1114
1115     ;; Open those that were open.
1116     (goto-char (point-min))
1117     (loop do (notmuch-show-message-visible (notmuch-show-get-message-properties)
1118                                            (member (notmuch-show-get-message-id) open))
1119           until (not (notmuch-show-goto-message-next)))
1120
1121     ;; Go to the previously open message.
1122     (goto-char (point-min))
1123     (unless (loop if (string= current (notmuch-show-get-message-id))
1124                   return t
1125                   until (not (notmuch-show-goto-message-next)))
1126       (goto-char (point-min))
1127       (message "Previously current message not found."))
1128     (notmuch-show-message-adjust)))
1129
1130 (defun notmuch-show-refresh-view (&optional reset-state)
1131   "Refresh the current view.
1132
1133 Refreshes the current view, observing changes in display
1134 preferences. If invoked with a prefix argument (or RESET-STATE is
1135 non-nil) then the state of the buffer (open/closed messages) is
1136 reset based on the original query."
1137   (interactive "P")
1138   (let ((inhibit-read-only t)
1139         (state (unless reset-state
1140                  (notmuch-show-capture-state))))
1141     (erase-buffer)
1142     (notmuch-show-build-buffer)
1143     (if state
1144         (notmuch-show-apply-state state)
1145       ;; We're resetting state, so navigate to the first open message
1146       ;; and mark it read, just like opening a new show buffer.
1147       (notmuch-show-goto-first-wanted-message))))
1148
1149 (defvar notmuch-show-stash-map
1150   (let ((map (make-sparse-keymap)))
1151     (define-key map "c" 'notmuch-show-stash-cc)
1152     (define-key map "d" 'notmuch-show-stash-date)
1153     (define-key map "F" 'notmuch-show-stash-filename)
1154     (define-key map "f" 'notmuch-show-stash-from)
1155     (define-key map "i" 'notmuch-show-stash-message-id)
1156     (define-key map "I" 'notmuch-show-stash-message-id-stripped)
1157     (define-key map "s" 'notmuch-show-stash-subject)
1158     (define-key map "T" 'notmuch-show-stash-tags)
1159     (define-key map "t" 'notmuch-show-stash-to)
1160     (define-key map "l" 'notmuch-show-stash-mlarchive-link)
1161     (define-key map "L" 'notmuch-show-stash-mlarchive-link-and-go)
1162     map)
1163   "Submap for stash commands")
1164 (fset 'notmuch-show-stash-map notmuch-show-stash-map)
1165
1166 (defvar notmuch-show-mode-map
1167       (let ((map (make-sparse-keymap)))
1168         (define-key map "?" 'notmuch-help)
1169         (define-key map "q" 'notmuch-kill-this-buffer)
1170         (define-key map (kbd "<C-tab>") 'widget-backward)
1171         (define-key map (kbd "M-TAB") 'notmuch-show-previous-button)
1172         (define-key map (kbd "<backtab>") 'notmuch-show-previous-button)
1173         (define-key map (kbd "TAB") 'notmuch-show-next-button)
1174         (define-key map "s" 'notmuch-search)
1175         (define-key map "m" 'notmuch-mua-new-mail)
1176         (define-key map "f" 'notmuch-show-forward-message)
1177         (define-key map "r" 'notmuch-show-reply-sender)
1178         (define-key map "R" 'notmuch-show-reply)
1179         (define-key map "|" 'notmuch-show-pipe-message)
1180         (define-key map "w" 'notmuch-show-save-attachments)
1181         (define-key map "V" 'notmuch-show-view-raw-message)
1182         (define-key map "v" 'notmuch-show-view-all-mime-parts)
1183         (define-key map "c" 'notmuch-show-stash-map)
1184         (define-key map "=" 'notmuch-show-refresh-view)
1185         (define-key map "h" 'notmuch-show-toggle-headers)
1186         (define-key map "*" 'notmuch-show-tag-all)
1187         (define-key map "-" 'notmuch-show-remove-tag)
1188         (define-key map "+" 'notmuch-show-add-tag)
1189         (define-key map "X" 'notmuch-show-archive-thread-then-exit)
1190         (define-key map "x" 'notmuch-show-archive-message-then-next-or-exit)
1191         (define-key map "A" 'notmuch-show-archive-thread-then-next)
1192         (define-key map "a" 'notmuch-show-archive-message-then-next-or-next-thread)
1193         (define-key map "N" 'notmuch-show-next-message)
1194         (define-key map "P" 'notmuch-show-previous-message)
1195         (define-key map "n" 'notmuch-show-next-open-message)
1196         (define-key map "p" 'notmuch-show-previous-open-message)
1197         (define-key map (kbd "DEL") 'notmuch-show-rewind)
1198         (define-key map " " 'notmuch-show-advance-and-archive)
1199         (define-key map (kbd "M-RET") 'notmuch-show-open-or-close-all)
1200         (define-key map (kbd "RET") 'notmuch-show-toggle-message)
1201         (define-key map "#" 'notmuch-show-print-message)
1202         (define-key map "!" 'notmuch-show-toggle-elide-non-matching)
1203         (define-key map "$" 'notmuch-show-toggle-process-crypto)
1204         (define-key map "<" 'notmuch-show-toggle-thread-indentation)
1205         (define-key map "t" 'toggle-truncate-lines)
1206         map)
1207       "Keymap for \"notmuch show\" buffers.")
1208 (fset 'notmuch-show-mode-map notmuch-show-mode-map)
1209
1210 (defun notmuch-show-mode ()
1211   "Major mode for viewing a thread with notmuch.
1212
1213 This buffer contains the results of the \"notmuch show\" command
1214 for displaying a single thread of email from your email archives.
1215
1216 By default, various components of email messages, (citations,
1217 signatures, already-read messages), are hidden. You can make
1218 these parts visible by clicking with the mouse button or by
1219 pressing RET after positioning the cursor on a hidden part, (for
1220 which \\[notmuch-show-next-button] and \\[notmuch-show-previous-button] are helpful).
1221
1222 Reading the thread sequentially is well-supported by pressing
1223 \\[notmuch-show-advance-and-archive]. This will scroll the current message (if necessary), advance
1224 to the next message, or advance to the next thread (if already on
1225 the last message of a thread).
1226
1227 Other commands are available to read or manipulate the thread
1228 more selectively, (such as '\\[notmuch-show-next-message]' and '\\[notmuch-show-previous-message]' to advance to messages
1229 without removing any tags, and '\\[notmuch-show-archive-thread]' to archive an entire thread
1230 without scrolling through with \\[notmuch-show-advance-and-archive]).
1231
1232 You can add or remove arbitrary tags from the current message with
1233 '\\[notmuch-show-add-tag]' or '\\[notmuch-show-remove-tag]'.
1234
1235 All currently available key bindings:
1236
1237 \\{notmuch-show-mode-map}"
1238   (interactive)
1239   (kill-all-local-variables)
1240   (use-local-map notmuch-show-mode-map)
1241   (setq major-mode 'notmuch-show-mode
1242         mode-name "notmuch-show")
1243   (setq buffer-read-only t
1244         truncate-lines t))
1245
1246 (defun notmuch-show-move-to-message-top ()
1247   (goto-char (notmuch-show-message-top)))
1248
1249 (defun notmuch-show-move-to-message-bottom ()
1250   (goto-char (notmuch-show-message-bottom)))
1251
1252 (defun notmuch-show-message-adjust ()
1253   (recenter 0))
1254
1255 ;; Movement related functions.
1256
1257 ;; There's some strangeness here where a text property applied to a
1258 ;; region a->b is not found when point is at b. We walk backwards
1259 ;; until finding the property.
1260 (defun notmuch-show-message-extent ()
1261   (let (r)
1262     (save-excursion
1263       (while (not (setq r (get-text-property (point) :notmuch-message-extent)))
1264         (backward-char)))
1265     r))
1266
1267 (defun notmuch-show-message-top ()
1268   (car (notmuch-show-message-extent)))
1269
1270 (defun notmuch-show-message-bottom ()
1271   (cdr (notmuch-show-message-extent)))
1272
1273 (defun notmuch-show-goto-message-next ()
1274   (let ((start (point)))
1275     (notmuch-show-move-to-message-bottom)
1276     (if (not (eobp))
1277         t
1278       (goto-char start)
1279       nil)))
1280
1281 (defun notmuch-show-goto-message-previous ()
1282   (notmuch-show-move-to-message-top)
1283   (if (bobp)
1284       nil
1285     (backward-char)
1286     (notmuch-show-move-to-message-top)
1287     t))
1288
1289 (defun notmuch-show-mapc (function)
1290   "Iterate through all messages in the current thread with
1291 `notmuch-show-goto-message-next' and call FUNCTION for side
1292 effects."
1293   (save-excursion
1294     (goto-char (point-min))
1295     (loop do (funcall function)
1296           while (notmuch-show-goto-message-next))))
1297
1298 ;; Functions relating to the visibility of messages and their
1299 ;; components.
1300
1301 (defun notmuch-show-element-visible (props visible-p spec-property)
1302   (let ((spec (plist-get props spec-property)))
1303     (if visible-p
1304         (remove-from-invisibility-spec spec)
1305       (add-to-invisibility-spec spec))))
1306
1307 (defun notmuch-show-message-visible (props visible-p)
1308   (notmuch-show-element-visible props visible-p :message-invis-spec)
1309   (notmuch-show-set-prop :message-visible visible-p props))
1310
1311 (defun notmuch-show-headers-visible (props visible-p)
1312   (notmuch-show-element-visible props visible-p :headers-invis-spec)
1313   (notmuch-show-set-prop :headers-visible visible-p props))
1314
1315 ;; Functions for setting and getting attributes of the current
1316 ;; message.
1317
1318 (defun notmuch-show-set-message-properties (props)
1319   (save-excursion
1320     (notmuch-show-move-to-message-top)
1321     (put-text-property (point) (+ (point) 1) :notmuch-message-properties props)))
1322
1323 (defun notmuch-show-get-message-properties ()
1324   "Return the properties of the current message as a plist.
1325
1326 Some useful entries are:
1327 :headers - Property list containing the headers :Date, :Subject, :From, etc.
1328 :body - Body of the message
1329 :tags - Tags for this message"
1330   (save-excursion
1331     (notmuch-show-move-to-message-top)
1332     (get-text-property (point) :notmuch-message-properties)))
1333
1334 (defun notmuch-show-set-prop (prop val &optional props)
1335   (let ((inhibit-read-only t)
1336         (props (or props
1337                    (notmuch-show-get-message-properties))))
1338     (plist-put props prop val)
1339     (notmuch-show-set-message-properties props)))
1340
1341 (defun notmuch-show-get-prop (prop &optional props)
1342   (let ((props (or props
1343                    (notmuch-show-get-message-properties))))
1344     (plist-get props prop)))
1345
1346 (defun notmuch-show-get-message-id (&optional bare)
1347   "Return the Message-Id of the current message.
1348
1349 If optional argument BARE is non-nil, return
1350 the Message-Id without prefix and quotes."
1351   (if bare
1352       (notmuch-show-get-prop :id)
1353     (concat "id:\"" (notmuch-show-get-prop :id) "\"")))
1354
1355 (defun notmuch-show-get-messages-ids ()
1356   "Return all message ids of messages in the current thread."
1357   (let ((message-ids))
1358     (notmuch-show-mapc
1359      (lambda () (push (notmuch-show-get-message-id) message-ids)))
1360     message-ids))
1361
1362 (defun notmuch-show-get-messages-ids-search ()
1363   "Return a search string for all message ids of messages in the
1364 current thread."
1365   (mapconcat 'identity (notmuch-show-get-messages-ids) " or "))
1366
1367 ;; dme: Would it make sense to use a macro for many of these?
1368
1369 (defun notmuch-show-get-filename ()
1370   "Return the filename of the current message."
1371   (notmuch-show-get-prop :filename))
1372
1373 (defun notmuch-show-get-header (header &optional props)
1374   "Return the named header of the current message, if any."
1375   (plist-get (notmuch-show-get-prop :headers props) header))
1376
1377 (defun notmuch-show-get-cc ()
1378   (notmuch-show-get-header :Cc))
1379
1380 (defun notmuch-show-get-date ()
1381   (notmuch-show-get-header :Date))
1382
1383 (defun notmuch-show-get-from ()
1384   (notmuch-show-get-header :From))
1385
1386 (defun notmuch-show-get-subject ()
1387   (notmuch-show-get-header :Subject))
1388
1389 (defun notmuch-show-get-to ()
1390   (notmuch-show-get-header :To))
1391
1392 (defun notmuch-show-get-depth ()
1393   (notmuch-show-get-prop :depth))
1394
1395 (defun notmuch-show-get-pretty-subject ()
1396   (notmuch-prettify-subject (notmuch-show-get-subject)))
1397
1398 (defun notmuch-show-set-tags (tags)
1399   "Set the tags of the current message."
1400   (notmuch-show-set-prop :tags tags)
1401   (notmuch-show-update-tags tags))
1402
1403 (defun notmuch-show-get-tags ()
1404   "Return the tags of the current message."
1405   (notmuch-show-get-prop :tags))
1406
1407 (defun notmuch-show-message-visible-p ()
1408   "Is the current message visible?"
1409   (notmuch-show-get-prop :message-visible))
1410
1411 (defun notmuch-show-headers-visible-p ()
1412   "Are the headers of the current message visible?"
1413   (notmuch-show-get-prop :headers-visible))
1414
1415 (defun notmuch-show-mark-read ()
1416   "Mark the current message as read."
1417   (notmuch-show-tag-message "-unread"))
1418
1419 ;; Functions for getting attributes of several messages in the current
1420 ;; thread.
1421
1422 (defun notmuch-show-get-message-ids-for-open-messages ()
1423   "Return a list of all message IDs for open messages in the current thread."
1424   (save-excursion
1425     (let (message-ids done)
1426       (goto-char (point-min))
1427       (while (not done)
1428         (if (notmuch-show-message-visible-p)
1429             (setq message-ids (append message-ids (list (notmuch-show-get-message-id)))))
1430         (setq done (not (notmuch-show-goto-message-next)))
1431         )
1432       message-ids
1433       )))
1434
1435 ;; Commands typically bound to keys.
1436
1437 (defun notmuch-show-advance ()
1438   "Advance through thread.
1439
1440 If the current message in the thread is not yet fully visible,
1441 scroll by a near screenful to read more of the message.
1442
1443 Otherwise, (the end of the current message is already within the
1444 current window), advance to the next open message."
1445   (interactive)
1446   (let* ((end-of-this-message (notmuch-show-message-bottom))
1447          (visible-end-of-this-message (1- end-of-this-message))
1448          (ret nil))
1449     (while (invisible-p visible-end-of-this-message)
1450       (setq visible-end-of-this-message
1451             (max (point-min)
1452                  (1- (previous-single-char-property-change
1453                       visible-end-of-this-message 'invisible)))))
1454     (cond
1455      ;; Ideally we would test `end-of-this-message' against the result
1456      ;; of `window-end', but that doesn't account for the fact that
1457      ;; the end of the message might be hidden.
1458      ((and visible-end-of-this-message
1459            (> visible-end-of-this-message (window-end)))
1460       ;; The bottom of this message is not visible - scroll.
1461       (scroll-up nil))
1462
1463      ((not (= end-of-this-message (point-max)))
1464       ;; This is not the last message - move to the next visible one.
1465       (notmuch-show-next-open-message))
1466
1467      (t
1468       ;; This is the last message - change the return value
1469       (setq ret t)))
1470     ret))
1471
1472 (defun notmuch-show-advance-and-archive ()
1473   "Advance through thread and archive.
1474
1475 This command is intended to be one of the simplest ways to
1476 process a thread of email. It works exactly like
1477 notmuch-show-advance, in that it scrolls through messages in a
1478 show buffer, except that when it gets to the end of the buffer it
1479 archives the entire current thread, (remove the \"inbox\" tag
1480 from each message), kills the buffer, and displays the next
1481 thread from the search from which this thread was originally
1482 shown."
1483   (interactive)
1484   (if (notmuch-show-advance)
1485       (notmuch-show-archive-thread-then-next)))
1486
1487 (defun notmuch-show-rewind ()
1488   "Backup through the thread, (reverse scrolling compared to \\[notmuch-show-advance-and-archive]).
1489
1490 Specifically, if the beginning of the previous email is fewer
1491 than `window-height' lines from the current point, move to it
1492 just like `notmuch-show-previous-message'.
1493
1494 Otherwise, just scroll down a screenful of the current message.
1495
1496 This command does not modify any message tags, (it does not undo
1497 any effects from previous calls to
1498 `notmuch-show-advance-and-archive'."
1499   (interactive)
1500   (let ((start-of-message (notmuch-show-message-top))
1501         (start-of-window (window-start)))
1502     (cond
1503       ;; Either this message is properly aligned with the start of the
1504       ;; window or the start of this message is not visible on the
1505       ;; screen - scroll.
1506      ((or (= start-of-message start-of-window)
1507           (< start-of-message start-of-window))
1508       (scroll-down)
1509       ;; If a small number of lines from the previous message are
1510       ;; visible, realign so that the top of the current message is at
1511       ;; the top of the screen.
1512       (when (<= (count-screen-lines (window-start) start-of-message)
1513                 next-screen-context-lines)
1514         (goto-char (notmuch-show-message-top))
1515         (notmuch-show-message-adjust))
1516       ;; Move to the top left of the window.
1517       (goto-char (window-start)))
1518      (t
1519       ;; Move to the previous message.
1520       (notmuch-show-previous-message)))))
1521
1522 (defun notmuch-show-reply (&optional prompt-for-sender)
1523   "Reply to the sender and all recipients of the current message."
1524   (interactive "P")
1525   (notmuch-mua-new-reply (notmuch-show-get-message-id) prompt-for-sender t))
1526
1527 (defun notmuch-show-reply-sender (&optional prompt-for-sender)
1528   "Reply to the sender of the current message."
1529   (interactive "P")
1530   (notmuch-mua-new-reply (notmuch-show-get-message-id) prompt-for-sender nil))
1531
1532 (defun notmuch-show-forward-message (&optional prompt-for-sender)
1533   "Forward the current message."
1534   (interactive "P")
1535   (with-current-notmuch-show-message
1536    (notmuch-mua-new-forward-message prompt-for-sender)))
1537
1538 (defun notmuch-show-next-message (&optional pop-at-end)
1539   "Show the next message.
1540
1541 If a prefix argument is given and this is the last message in the
1542 thread, navigate to the next thread in the parent search buffer."
1543   (interactive "P")
1544   (if (notmuch-show-goto-message-next)
1545       (progn
1546         (notmuch-show-mark-read)
1547         (notmuch-show-message-adjust))
1548     (if pop-at-end
1549         (notmuch-show-next-thread)
1550       (goto-char (point-max)))))
1551
1552 (defun notmuch-show-previous-message ()
1553   "Show the previous message."
1554   (interactive)
1555   (notmuch-show-goto-message-previous)
1556   (notmuch-show-mark-read)
1557   (notmuch-show-message-adjust))
1558
1559 (defun notmuch-show-next-open-message (&optional pop-at-end)
1560   "Show the next open message.
1561
1562 If a prefix argument is given and this is the last open message
1563 in the thread, navigate to the next thread in the parent search
1564 buffer. Return t if there was a next open message in the thread
1565 to show, nil otherwise."
1566   (interactive "P")
1567   (let (r)
1568     (while (and (setq r (notmuch-show-goto-message-next))
1569                 (not (notmuch-show-message-visible-p))))
1570     (if r
1571         (progn
1572           (notmuch-show-mark-read)
1573           (notmuch-show-message-adjust))
1574       (if pop-at-end
1575           (notmuch-show-next-thread)
1576         (goto-char (point-max))))
1577     r))
1578
1579 (defun notmuch-show-next-matching-message ()
1580   "Show the next matching message."
1581   (interactive)
1582   (let (r)
1583     (while (and (setq r (notmuch-show-goto-message-next))
1584                 (not (notmuch-show-get-prop :match))))
1585     (if r
1586         (progn
1587           (notmuch-show-mark-read)
1588           (notmuch-show-message-adjust))
1589       (goto-char (point-max)))))
1590
1591 (defun notmuch-show-goto-first-wanted-message ()
1592   "Move to the first open message and mark it read"
1593   (goto-char (point-min))
1594   (if (notmuch-show-message-visible-p)
1595       (notmuch-show-mark-read)
1596     (notmuch-show-next-open-message))
1597   (when (eobp)
1598     (goto-char (point-min))
1599     (unless (notmuch-show-get-prop :match)
1600       (notmuch-show-next-matching-message))))
1601
1602 (defun notmuch-show-previous-open-message ()
1603   "Show the previous open message."
1604   (interactive)
1605   (while (and (notmuch-show-goto-message-previous)
1606               (not (notmuch-show-message-visible-p))))
1607   (notmuch-show-mark-read)
1608   (notmuch-show-message-adjust))
1609
1610 (defun notmuch-show-view-raw-message ()
1611   "View the file holding the current message."
1612   (interactive)
1613   (let* ((id (notmuch-show-get-message-id))
1614          (buf (get-buffer-create (concat "*notmuch-raw-" id "*"))))
1615     (call-process notmuch-command nil buf nil "show" "--format=raw" id)
1616     (switch-to-buffer buf)
1617     (goto-char (point-min))
1618     (set-buffer-modified-p nil)
1619     (view-buffer buf 'kill-buffer-if-not-modified)))
1620
1621 (defun notmuch-show-pipe-message (entire-thread command)
1622   "Pipe the contents of the current message (or thread) to the given command.
1623
1624 The given command will be executed with the raw contents of the
1625 current email message as stdin. Anything printed by the command
1626 to stdout or stderr will appear in the *notmuch-pipe* buffer.
1627
1628 When invoked with a prefix argument, the command will receive all
1629 open messages in the current thread (formatted as an mbox) rather
1630 than only the current message."
1631   (interactive "P\nsPipe message to command: ")
1632   (let (shell-command)
1633     (if entire-thread
1634         (setq shell-command
1635               (concat notmuch-command " show --format=mbox "
1636                       (shell-quote-argument
1637                        (mapconcat 'identity (notmuch-show-get-message-ids-for-open-messages) " OR "))
1638                       " | " command))
1639       (setq shell-command
1640             (concat notmuch-command " show --format=raw "
1641                     (shell-quote-argument (notmuch-show-get-message-id)) " | " command)))
1642     (let ((buf (get-buffer-create (concat "*notmuch-pipe*"))))
1643       (with-current-buffer buf
1644         (setq buffer-read-only nil)
1645         (erase-buffer)
1646         (let ((exit-code (call-process-shell-command shell-command nil buf)))
1647           (goto-char (point-max))
1648           (set-buffer-modified-p nil)
1649           (setq buffer-read-only t)
1650           (unless (zerop exit-code)
1651             (switch-to-buffer-other-window buf)
1652             (message (format "Command '%s' exited abnormally with code %d"
1653                              shell-command exit-code))))))))
1654
1655 (defun notmuch-show-tag-message (&rest tag-changes)
1656   "Change tags for the current message.
1657
1658 TAG-CHANGES is a list of tag operations for `notmuch-tag'."
1659   (let* ((current-tags (notmuch-show-get-tags))
1660          (new-tags (notmuch-update-tags current-tags tag-changes)))
1661     (unless (equal current-tags new-tags)
1662       (apply 'notmuch-tag (notmuch-show-get-message-id) tag-changes)
1663       (notmuch-show-set-tags new-tags))))
1664
1665 (defun notmuch-show-tag (&optional initial-input)
1666   "Change tags for the current message, read input from the minibuffer."
1667   (interactive)
1668   (let ((tag-changes (notmuch-read-tag-changes
1669                       initial-input (notmuch-show-get-message-id))))
1670     (apply 'notmuch-show-tag-message tag-changes)))
1671
1672 (defun notmuch-show-tag-all (&rest tag-changes)
1673   "Change tags for all messages in the current buffer.
1674
1675 TAG-CHANGES is a list of tag operations for `notmuch-tag'."
1676   (interactive (notmuch-read-tag-changes nil notmuch-show-thread-id))
1677   (apply 'notmuch-tag (notmuch-show-get-messages-ids-search) tag-changes)
1678   (notmuch-show-mapc
1679    (lambda ()
1680      (let* ((current-tags (notmuch-show-get-tags))
1681             (new-tags (notmuch-update-tags current-tags tag-changes)))
1682        (unless (equal current-tags new-tags)
1683          (notmuch-show-set-tags new-tags))))))
1684
1685 (defun notmuch-show-add-tag ()
1686   "Same as `notmuch-show-tag' but sets initial input to '+'."
1687   (interactive)
1688   (notmuch-show-tag "+"))
1689
1690 (defun notmuch-show-remove-tag ()
1691   "Same as `notmuch-show-tag' but sets initial input to '-'."
1692   (interactive)
1693   (notmuch-show-tag "-"))
1694
1695 (defun notmuch-show-toggle-headers ()
1696   "Toggle the visibility of the current message headers."
1697   (interactive)
1698   (let ((props (notmuch-show-get-message-properties)))
1699     (notmuch-show-headers-visible
1700      props
1701      (not (plist-get props :headers-visible))))
1702   (force-window-update))
1703
1704 (defun notmuch-show-toggle-message ()
1705   "Toggle the visibility of the current message."
1706   (interactive)
1707   (let ((props (notmuch-show-get-message-properties)))
1708     (notmuch-show-message-visible
1709      props
1710      (not (plist-get props :message-visible))))
1711   (force-window-update))
1712
1713 (defun notmuch-show-open-or-close-all ()
1714   "Set the visibility all of the messages in the current thread.
1715 By default make all of the messages visible. With a prefix
1716 argument, hide all of the messages."
1717   (interactive)
1718   (save-excursion
1719     (goto-char (point-min))
1720     (loop do (notmuch-show-message-visible (notmuch-show-get-message-properties)
1721                                            (not current-prefix-arg))
1722           until (not (notmuch-show-goto-message-next))))
1723   (force-window-update))
1724
1725 (defun notmuch-show-next-button ()
1726   "Advance point to the next button in the buffer."
1727   (interactive)
1728   (forward-button 1))
1729
1730 (defun notmuch-show-previous-button ()
1731   "Move point back to the previous button in the buffer."
1732   (interactive)
1733   (backward-button 1))
1734
1735 (defun notmuch-show-next-thread (&optional show-next)
1736   "Move to the next item in the search results, if any."
1737   (interactive "P")
1738   (let ((parent-buffer notmuch-show-parent-buffer))
1739     (notmuch-kill-this-buffer)
1740     (when (buffer-live-p parent-buffer)
1741       (switch-to-buffer parent-buffer)
1742       (notmuch-search-next-thread)
1743       (if show-next
1744           (notmuch-search-show-thread)))))
1745
1746 (defun notmuch-show-archive-thread (&optional unarchive)
1747   "Archive each message in thread.
1748
1749 If a prefix argument is given, the messages will be
1750 \"unarchived\" (ie. the \"inbox\" tag will be added instead of
1751 removed).
1752
1753 Archive each message currently shown by removing the \"inbox\"
1754 tag from each. Then kill this buffer and show the next thread
1755 from the search from which this thread was originally shown.
1756
1757 Note: This command is safe from any race condition of new messages
1758 being delivered to the same thread. It does not archive the
1759 entire thread, but only the messages shown in the current
1760 buffer."
1761   (interactive "P")
1762   (let ((op (if unarchive "+" "-")))
1763     (notmuch-show-tag-all (concat op "inbox"))))
1764
1765 (defun notmuch-show-archive-thread-then-next ()
1766   "Archive all messages in the current buffer, then show next thread from search."
1767   (interactive)
1768   (notmuch-show-archive-thread)
1769   (notmuch-show-next-thread t))
1770
1771 (defun notmuch-show-archive-thread-then-exit ()
1772   "Archive all messages in the current buffer, then exit back to search results."
1773   (interactive)
1774   (notmuch-show-archive-thread)
1775   (notmuch-show-next-thread))
1776
1777 (defun notmuch-show-archive-message (&optional unarchive)
1778   "Archive the current message.
1779
1780 If a prefix argument is given, the message will be
1781 \"unarchived\" (ie. the \"inbox\" tag will be added instead of
1782 removed)."
1783   (interactive "P")
1784   (let ((op (if unarchive "+" "-")))
1785     (notmuch-show-tag-message (concat op "inbox"))))
1786
1787 (defun notmuch-show-archive-message-then-next-or-exit ()
1788   "Archive the current message, then show the next open message in the current thread.
1789
1790 If at the last open message in the current thread, then exit back
1791 to search results."
1792   (interactive)
1793   (notmuch-show-archive-message)
1794   (notmuch-show-next-open-message t))
1795
1796 (defun notmuch-show-archive-message-then-next-or-next-thread ()
1797   "Archive the current message, then show the next open message in the current thread.
1798
1799 If at the last open message in the current thread, then show next
1800 thread from search."
1801   (interactive)
1802   (notmuch-show-archive-message)
1803   (unless (notmuch-show-next-open-message)
1804     (notmuch-show-next-thread t)))
1805
1806 (defun notmuch-show-stash-cc ()
1807   "Copy CC field of current message to kill-ring."
1808   (interactive)
1809   (notmuch-common-do-stash (notmuch-show-get-cc)))
1810
1811 (defun notmuch-show-stash-date ()
1812   "Copy date of current message to kill-ring."
1813   (interactive)
1814   (notmuch-common-do-stash (notmuch-show-get-date)))
1815
1816 (defun notmuch-show-stash-filename ()
1817   "Copy filename of current message to kill-ring."
1818   (interactive)
1819   (notmuch-common-do-stash (notmuch-show-get-filename)))
1820
1821 (defun notmuch-show-stash-from ()
1822   "Copy From address of current message to kill-ring."
1823   (interactive)
1824   (notmuch-common-do-stash (notmuch-show-get-from)))
1825
1826 (defun notmuch-show-stash-message-id ()
1827   "Copy message ID of current message to kill-ring."
1828   (interactive)
1829   (notmuch-common-do-stash (notmuch-show-get-message-id)))
1830
1831 (defun notmuch-show-stash-message-id-stripped ()
1832   "Copy message ID of current message (sans `id:' prefix) to kill-ring."
1833   (interactive)
1834   (notmuch-common-do-stash (notmuch-show-get-message-id t)))
1835
1836 (defun notmuch-show-stash-subject ()
1837   "Copy Subject field of current message to kill-ring."
1838   (interactive)
1839   (notmuch-common-do-stash (notmuch-show-get-subject)))
1840
1841 (defun notmuch-show-stash-tags ()
1842   "Copy tags of current message to kill-ring as a comma separated list."
1843   (interactive)
1844   (notmuch-common-do-stash (mapconcat 'identity (notmuch-show-get-tags) ",")))
1845
1846 (defun notmuch-show-stash-to ()
1847   "Copy To address of current message to kill-ring."
1848   (interactive)
1849   (notmuch-common-do-stash (notmuch-show-get-to)))
1850
1851 (defun notmuch-show-stash-mlarchive-link (&optional mla)
1852   "Copy an ML Archive URI for the current message to the kill-ring.
1853
1854 This presumes that the message is available at the selected Mailing List Archive.
1855
1856 If optional argument MLA is non-nil, use the provided key instead of prompting
1857 the user (see `notmuch-show-stash-mlarchive-link-alist')."
1858   (interactive)
1859   (notmuch-common-do-stash
1860    (concat (cdr (assoc
1861                  (or mla
1862                      (let ((completion-ignore-case t))
1863                        (completing-read
1864                         "Mailing List Archive: "
1865                         notmuch-show-stash-mlarchive-link-alist
1866                         nil t nil nil notmuch-show-stash-mlarchive-link-default)))
1867                  notmuch-show-stash-mlarchive-link-alist))
1868            (notmuch-show-get-message-id t))))
1869
1870 (defun notmuch-show-stash-mlarchive-link-and-go (&optional mla)
1871   "Copy an ML Archive URI for the current message to the kill-ring and visit it.
1872
1873 This presumes that the message is available at the selected Mailing List Archive.
1874
1875 If optional argument MLA is non-nil, use the provided key instead of prompting
1876 the user (see `notmuch-show-stash-mlarchive-link-alist')."
1877   (interactive)
1878   (notmuch-show-stash-mlarchive-link mla)
1879   (browse-url (current-kill 0 t)))
1880
1881 ;; Commands typically bound to buttons.
1882
1883 (defun notmuch-show-part-button-default (&optional button)
1884   (interactive)
1885   (notmuch-show-part-button-internal button notmuch-show-part-button-default-action))
1886
1887 (defun notmuch-show-part-button-save (&optional button)
1888   (interactive)
1889   (notmuch-show-part-button-internal button #'notmuch-show-save-part))
1890
1891 (defun notmuch-show-part-button-view (&optional button)
1892   (interactive)
1893   (notmuch-show-part-button-internal button #'notmuch-show-view-part))
1894
1895 (defun notmuch-show-part-button-interactively-view (&optional button)
1896   (interactive)
1897   (notmuch-show-part-button-internal button #'notmuch-show-interactively-view-part))
1898
1899 (defun notmuch-show-part-button-internal (button handler)
1900   (let ((button (or button (button-at (point)))))
1901     (if button
1902         (let ((nth (button-get button :notmuch-part)))
1903           (if nth
1904               (funcall handler (notmuch-show-get-message-id) nth
1905                        (button-get button :notmuch-filename)
1906                        (button-get button :notmuch-content-type)))))))
1907
1908 ;;
1909
1910 (provide 'notmuch-show)