emacs: tree: make jump close message pane
[notmuch] / emacs / notmuch-tree.el
1 ;;; notmuch-tree.el --- displaying notmuch forests.
2 ;;
3 ;; Copyright © Carl Worth
4 ;; Copyright © David Edmondson
5 ;; Copyright © Mark Walters
6 ;;
7 ;; This file is part of Notmuch.
8 ;;
9 ;; Notmuch is free software: you can redistribute it and/or modify it
10 ;; under the terms of the GNU General Public License as published by
11 ;; the Free Software Foundation, either version 3 of the License, or
12 ;; (at your option) any later version.
13 ;;
14 ;; Notmuch is distributed in the hope that it will be useful, but
15 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
17 ;; General Public License for more details.
18 ;;
19 ;; You should have received a copy of the GNU General Public License
20 ;; along with Notmuch.  If not, see <https://www.gnu.org/licenses/>.
21 ;;
22 ;; Authors: David Edmondson <dme@dme.org>
23 ;;          Mark Walters <markwalters1009@gmail.com>
24
25 ;;; Code:
26
27 (require 'mail-parse)
28
29 (require 'notmuch-lib)
30 (require 'notmuch-query)
31 (require 'notmuch-show)
32 (require 'notmuch-tag)
33 (require 'notmuch-parser)
34
35 (eval-when-compile (require 'cl))
36 (declare-function notmuch-search "notmuch" (&optional query oldest-first target-thread target-line))
37 (declare-function notmuch-call-notmuch-process "notmuch" (&rest args))
38 (declare-function notmuch-read-query "notmuch" (prompt))
39 (declare-function notmuch-search-find-thread-id "notmuch" (&optional bare))
40 (declare-function notmuch-search-find-subject "notmuch" ())
41
42 ;; the following variable is defined in notmuch.el
43 (defvar notmuch-search-query-string)
44
45 (defgroup notmuch-tree nil
46   "Showing message and thread structure."
47   :group 'notmuch)
48
49 (defcustom notmuch-tree-show-out nil
50   "View selected messages in new window rather than split-pane."
51   :type 'boolean
52   :group 'notmuch-tree)
53
54 (defcustom notmuch-tree-result-format
55   `(("date" . "%12s  ")
56     ("authors" . "%-20s")
57     ((("tree" . "%s")("subject" . "%s")) ." %-54s ")
58     ("tags" . "(%s)"))
59   "Result formatting for Tree view. Supported fields are: date,
60         authors, subject, tree, tags.  Tree means the thread tree
61         box graphics. The field may also be a list in which case
62         the formatting rules are applied recursively and then the
63         output of all the fields in the list is inserted
64         according to format-string.
65
66 Note the author string should not contain
67         whitespace (put it in the neighbouring fields instead).
68         For example:
69         (setq notmuch-tree-result-format \(\(\"authors\" . \"%-40s\"\)
70                                              \(\"subject\" . \"%s\"\)\)\)"
71   :type '(alist :key-type (string) :value-type (string))
72   :group 'notmuch-tree)
73
74 ;; Faces for messages that match the query.
75 (defface notmuch-tree-match-face
76   '((t :inherit default))
77   "Default face used in tree mode face for matching messages"
78   :group 'notmuch-tree
79   :group 'notmuch-faces)
80
81 (defface notmuch-tree-match-date-face
82   nil
83   "Face used in tree mode for the date in messages matching the query."
84   :group 'notmuch-tree
85   :group 'notmuch-faces)
86
87 (defface notmuch-tree-match-author-face
88   '((((class color)
89       (background dark))
90      (:foreground "OliveDrab1"))
91     (((class color)
92       (background light))
93      (:foreground "dark blue"))
94     (t
95      (:bold t)))
96   "Face used in tree mode for the date in messages matching the query."
97   :group 'notmuch-tree
98   :group 'notmuch-faces)
99
100 (defface notmuch-tree-match-subject-face
101   nil
102   "Face used in tree mode for the subject in messages matching the query."
103   :group 'notmuch-tree
104   :group 'notmuch-faces)
105
106 (defface notmuch-tree-match-tree-face
107   nil
108   "Face used in tree mode for the thread tree block graphics in messages matching the query."
109   :group 'notmuch-tree
110   :group 'notmuch-faces)
111
112 (defface notmuch-tree-match-tag-face
113   '((((class color)
114       (background dark))
115      (:foreground "OliveDrab1"))
116     (((class color)
117       (background light))
118      (:foreground "navy blue" :bold t))
119     (t
120      (:bold t)))
121   "Face used in tree mode for tags in messages matching the query."
122   :group 'notmuch-tree
123   :group 'notmuch-faces)
124
125 ;; Faces for messages that do not match the query.
126 (defface notmuch-tree-no-match-face
127   '((t (:foreground "gray")))
128   "Default face used in tree mode face for non-matching messages"
129   :group 'notmuch-tree
130   :group 'notmuch-faces)
131
132 (defface notmuch-tree-no-match-date-face
133   nil
134   "Face used in tree mode for non-matching dates."
135   :group 'notmuch-tree
136   :group 'notmuch-faces)
137
138 (defface notmuch-tree-no-match-subject-face
139   nil
140   "Face used in tree mode for non-matching subjects."
141   :group 'notmuch-tree
142   :group 'notmuch-faces)
143
144 (defface notmuch-tree-no-match-tree-face
145   nil
146   "Face used in tree mode for the thread tree block graphics in messages matching the query."
147   :group 'notmuch-tree
148   :group 'notmuch-faces)
149
150 (defface notmuch-tree-no-match-author-face
151   nil
152   "Face used in tree mode for the date in messages matching the query."
153   :group 'notmuch-tree
154   :group 'notmuch-faces)
155
156 (defface notmuch-tree-no-match-tag-face
157   nil
158   "Face used in tree mode face for non-matching tags."
159   :group 'notmuch-tree
160   :group 'notmuch-faces)
161
162 (defvar notmuch-tree-previous-subject
163   "The subject of the most recent result shown during the async display")
164 (make-variable-buffer-local 'notmuch-tree-previous-subject)
165
166 (defvar notmuch-tree-basic-query nil
167   "A buffer local copy of argument query to the function notmuch-tree")
168 (make-variable-buffer-local 'notmuch-tree-basic-query)
169
170 (defvar notmuch-tree-query-context nil
171   "A buffer local copy of argument query-context to the function notmuch-tree")
172 (make-variable-buffer-local 'notmuch-tree-query-context)
173
174 (defvar notmuch-tree-target-msg nil
175   "A buffer local copy of argument target to the function notmuch-tree")
176 (make-variable-buffer-local 'notmuch-tree-target-msg)
177
178 (defvar notmuch-tree-open-target nil
179   "A buffer local copy of argument open-target to the function notmuch-tree")
180 (make-variable-buffer-local 'notmuch-tree-open-target)
181
182 (defvar notmuch-tree-message-window nil
183   "The window of the message pane.
184
185 It is set in both the tree buffer and the child show buffer. It
186 is used to try and close the message pane when quitting tree view
187 or the child show buffer.")
188 (make-variable-buffer-local 'notmuch-tree-message-window)
189 (put 'notmuch-tree-message-window 'permanent-local t)
190
191 (defvar notmuch-tree-message-buffer nil
192   "The buffer name of the show buffer in the message pane.
193
194 This is used to try and make sure we don't close the message pane
195 if the user has loaded a different buffer in that window.")
196 (make-variable-buffer-local 'notmuch-tree-message-buffer)
197 (put 'notmuch-tree-message-buffer 'permanent-local t)
198
199 (defun notmuch-tree-to-message-pane (func)
200   "Execute FUNC in message pane.
201
202 This function returns a function (so can be used as a keybinding)
203 which executes function FUNC in the message pane if it is
204 open (if the message pane is closed it does nothing)."
205   `(lambda ()
206       ,(concat "(In message pane) " (documentation func t))
207      (interactive)
208      (when (window-live-p notmuch-tree-message-window)
209        (with-selected-window notmuch-tree-message-window
210          (call-interactively #',func)))))
211
212 (defun notmuch-tree-button-activate (&optional button)
213   "Activate BUTTON or button at point
214
215 This function does not give an error if there is no button."
216   (interactive)
217   (let ((button (or button (button-at (point)))))
218     (when button (button-activate button))))
219
220 (defun notmuch-tree-close-message-pane-and (func)
221   "Close message pane and execute FUNC.
222
223 This function returns a function (so can be used as a keybinding)
224 which closes the message pane if open and then executes function
225 FUNC."
226   `(lambda ()
227       ,(concat "(Close message pane and) " (documentation func t))
228      (interactive)
229      (notmuch-tree-close-message-window)
230      (call-interactively #',func)))
231
232 (defvar notmuch-tree-mode-map
233   (let ((map (make-sparse-keymap)))
234     (set-keymap-parent map notmuch-common-keymap)
235     ;; The following override the global keymap.
236     ;; Override because we want to close message pane first.
237     (define-key map [remap notmuch-help] (notmuch-tree-close-message-pane-and #'notmuch-help))
238     ;; Override because we first close message pane and then close tree buffer.
239     (define-key map [remap notmuch-bury-or-kill-this-buffer] 'notmuch-tree-quit)
240     ;; Override because we close message pane after the search query is entered.
241     (define-key map [remap notmuch-search] 'notmuch-tree-to-search)
242     ;; Override because we want to close message pane first.
243     (define-key map [remap notmuch-mua-new-mail] (notmuch-tree-close-message-pane-and #'notmuch-mua-new-mail))
244     ;; Override because we want to close message pane first.
245     (define-key map [remap notmuch-jump-search] (notmuch-tree-close-message-pane-and #'notmuch-jump-search))
246
247     (define-key map "S" 'notmuch-search-from-tree-current-query)
248
249     ;; these use notmuch-show functions directly
250     (define-key map "|" 'notmuch-show-pipe-message)
251     (define-key map "w" 'notmuch-show-save-attachments)
252     (define-key map "v" 'notmuch-show-view-all-mime-parts)
253     (define-key map "c" 'notmuch-show-stash-map)
254
255     ;; these apply to the message pane
256     (define-key map (kbd "M-TAB") (notmuch-tree-to-message-pane #'notmuch-show-previous-button))
257     (define-key map (kbd "<backtab>")  (notmuch-tree-to-message-pane #'notmuch-show-previous-button))
258     (define-key map (kbd "TAB") (notmuch-tree-to-message-pane #'notmuch-show-next-button))
259     (define-key map "e" (notmuch-tree-to-message-pane #'notmuch-tree-button-activate))
260
261     ;; bindings from show (or elsewhere) but we close the message pane first.
262     (define-key map "f" (notmuch-tree-close-message-pane-and #'notmuch-show-forward-message))
263     (define-key map "r" (notmuch-tree-close-message-pane-and #'notmuch-show-reply-sender))
264     (define-key map "R" (notmuch-tree-close-message-pane-and #'notmuch-show-reply))
265     (define-key map "V" (notmuch-tree-close-message-pane-and #'notmuch-show-view-raw-message))
266
267     ;; The main tree view bindings
268     (define-key map (kbd "RET") 'notmuch-tree-show-message)
269     (define-key map [mouse-1] 'notmuch-tree-show-message)
270     (define-key map "x" 'notmuch-tree-quit)
271     (define-key map "A" 'notmuch-tree-archive-thread)
272     (define-key map "a" 'notmuch-tree-archive-message-then-next)
273     (define-key map "=" 'notmuch-tree-refresh-view)
274     (define-key map "z" 'notmuch-tree-to-tree)
275     (define-key map "n" 'notmuch-tree-next-matching-message)
276     (define-key map "p" 'notmuch-tree-prev-matching-message)
277     (define-key map "N" 'notmuch-tree-next-message)
278     (define-key map "P" 'notmuch-tree-prev-message)
279     (define-key map (kbd "M-p") 'notmuch-tree-prev-thread)
280     (define-key map (kbd "M-n") 'notmuch-tree-next-thread)
281     (define-key map "-" 'notmuch-tree-remove-tag)
282     (define-key map "+" 'notmuch-tree-add-tag)
283     (define-key map "*" 'notmuch-tree-tag-thread)
284     (define-key map " " 'notmuch-tree-scroll-or-next)
285     (define-key map "b" 'notmuch-tree-scroll-message-window-back)
286     map))
287 (fset 'notmuch-tree-mode-map notmuch-tree-mode-map)
288
289 (defun notmuch-tree-get-message-properties ()
290   "Return the properties of the current message as a plist.
291
292 Some useful entries are:
293 :headers - Property list containing the headers :Date, :Subject, :From, etc.
294 :tags - Tags for this message"
295   (save-excursion
296     (beginning-of-line)
297     (get-text-property (point) :notmuch-message-properties)))
298
299 (defun notmuch-tree-set-message-properties (props)
300   (save-excursion
301     (beginning-of-line)
302     (put-text-property (point) (+ (point) 1) :notmuch-message-properties props)))
303
304 (defun notmuch-tree-set-prop (prop val &optional props)
305   (let ((inhibit-read-only t)
306         (props (or props
307                    (notmuch-tree-get-message-properties))))
308     (plist-put props prop val)
309     (notmuch-tree-set-message-properties props)))
310
311 (defun notmuch-tree-get-prop (prop &optional props)
312   (let ((props (or props
313                    (notmuch-tree-get-message-properties))))
314     (plist-get props prop)))
315
316 (defun notmuch-tree-set-tags (tags)
317   "Set the tags of the current message."
318   (notmuch-tree-set-prop :tags tags))
319
320 (defun notmuch-tree-get-tags ()
321   "Return the tags of the current message."
322   (notmuch-tree-get-prop :tags))
323
324 (defun notmuch-tree-get-message-id (&optional bare)
325   "Return the message id of the current message."
326   (let ((id (notmuch-tree-get-prop :id)))
327     (if id
328         (if bare
329             id
330           (notmuch-id-to-query id))
331       nil)))
332
333 (defun notmuch-tree-get-match ()
334   "Return whether the current message is a match."
335   (interactive)
336   (notmuch-tree-get-prop :match))
337
338 (defun notmuch-tree-refresh-result ()
339   "Redisplay the current message line.
340
341 This redisplays the current line based on the messages
342 properties (as they are now). This is used when tags are
343 updated."
344   (let ((init-point (point))
345         (end (line-end-position))
346         (msg (notmuch-tree-get-message-properties))
347         (inhibit-read-only t))
348     (beginning-of-line)
349     ;; This is a little tricky: we override
350     ;; notmuch-tree-previous-subject to get the decision between
351     ;; ... and a subject right and it stops notmuch-tree-insert-msg
352     ;; from overwriting the buffer local copy of
353     ;; notmuch-tree-previous-subject if this is called while the
354     ;; buffer is displaying.
355     (let ((notmuch-tree-previous-subject (notmuch-tree-get-prop :previous-subject)))
356       (delete-region (point) (1+ (line-end-position)))
357       (notmuch-tree-insert-msg msg))
358     (let ((new-end (line-end-position)))
359       (goto-char (if (= init-point end)
360                      new-end
361                    (min init-point (- new-end 1)))))))
362
363 (defun notmuch-tree-tag-update-display (&optional tag-changes)
364   "Update display for TAG-CHANGES to current message.
365
366 Does NOT change the database."
367   (let* ((current-tags (notmuch-tree-get-tags))
368          (new-tags (notmuch-update-tags current-tags tag-changes)))
369     (unless (equal current-tags new-tags)
370       (notmuch-tree-set-tags new-tags)
371       (notmuch-tree-refresh-result))))
372
373 (defun notmuch-tree-tag (tag-changes)
374   "Change tags for the current message"
375   (interactive
376    (list (notmuch-read-tag-changes (notmuch-tree-get-tags) "Tag message")))
377   (notmuch-tag (notmuch-tree-get-message-id) tag-changes)
378   (notmuch-tree-tag-update-display tag-changes))
379
380 (defun notmuch-tree-add-tag (tag-changes)
381   "Same as `notmuch-tree-tag' but sets initial input to '+'."
382   (interactive
383    (list (notmuch-read-tag-changes (notmuch-tree-get-tags) "Tag message" "+")))
384   (notmuch-tree-tag tag-changes))
385
386 (defun notmuch-tree-remove-tag (tag-changes)
387   "Same as `notmuch-tree-tag' but sets initial input to '-'."
388   (interactive
389    (list (notmuch-read-tag-changes (notmuch-tree-get-tags) "Tag message" "-")))
390   (notmuch-tree-tag tag-changes))
391
392 ;; The next two functions close the message window before calling
393 ;; notmuch-search or notmuch-tree but they do so after the user has
394 ;; entered the query (in case the user was basing the query on
395 ;; something in the message window).
396
397 (defun notmuch-tree-to-search ()
398   "Run \"notmuch search\" with the given `query' and display results."
399   (interactive)
400   (let ((query (notmuch-read-query "Notmuch search: ")))
401     (notmuch-tree-close-message-window)
402     (notmuch-search query)))
403
404 (defun notmuch-tree-to-tree ()
405   "Run a query and display results in Tree view"
406   (interactive)
407   (let ((query (notmuch-read-query "Notmuch tree view search: ")))
408     (notmuch-tree-close-message-window)
409     (notmuch-tree query)))
410
411 (defun notmuch-search-from-tree-current-query ()
412   "Call notmuch search with the current query"
413   (interactive)
414   (notmuch-tree-close-message-window)
415   (notmuch-search (notmuch-tree-get-query)))
416
417 (defun notmuch-tree-message-window-kill-hook ()
418   "Close the message pane when exiting the show buffer."
419   (let ((buffer (current-buffer)))
420     (when (and (window-live-p notmuch-tree-message-window)
421                (eq (window-buffer notmuch-tree-message-window) buffer))
422       ;; We do not want an error if this is the sole window in the
423       ;; frame and I do not know how to test for that in emacs pre
424       ;; 24. Hence we just ignore-errors.
425       (ignore-errors
426         (delete-window notmuch-tree-message-window)))))
427
428 (defun notmuch-tree-command-hook ()
429   (when (eq major-mode 'notmuch-tree-mode)
430     ;; We just run the notmuch-show-command-hook on the message pane.
431     (when (buffer-live-p notmuch-tree-message-buffer)
432       (with-current-buffer notmuch-tree-message-buffer
433         (notmuch-show-command-hook)))))
434
435 (defun notmuch-tree-show-message-in ()
436   "Show the current message (in split-pane)."
437   (interactive)
438   (let ((id (notmuch-tree-get-message-id))
439         (inhibit-read-only t)
440         buffer)
441     (when id
442       ;; We close and reopen the window to kill off un-needed buffers
443       ;; this might cause flickering but seems ok.
444       (notmuch-tree-close-message-window)
445       (setq notmuch-tree-message-window
446             (split-window-vertically (/ (window-height) 4)))
447       (with-selected-window notmuch-tree-message-window
448         ;; Since we are only displaying one message do not indent.
449         (let ((notmuch-show-indent-messages-width 0)
450               (notmuch-show-only-matching-messages t))
451           (setq buffer (notmuch-show id))))
452       ;; We need the `let' as notmuch-tree-message-window is buffer local.
453       (let ((window notmuch-tree-message-window))
454         (with-current-buffer buffer
455           (setq notmuch-tree-message-window window)
456           (add-hook 'kill-buffer-hook 'notmuch-tree-message-window-kill-hook)))
457       (when notmuch-show-mark-read-tags
458         (notmuch-tree-tag-update-display notmuch-show-mark-read-tags))
459       (setq notmuch-tree-message-buffer buffer))))
460
461 (defun notmuch-tree-show-message-out ()
462   "Show the current message (in whole window)."
463   (interactive)
464   (let ((id (notmuch-tree-get-message-id))
465         (inhibit-read-only t)
466         buffer)
467     (when id
468       ;; We close the window to kill off un-needed buffers.
469       (notmuch-tree-close-message-window)
470       (notmuch-show id))))
471
472 (defun notmuch-tree-show-message (arg)
473   "Show the current message.
474
475 Shows in split pane or whole window according to value of
476 `notmuch-tree-show-out'. A prefix argument reverses the choice."
477   (interactive "P")
478   (if (or (and notmuch-tree-show-out  (not arg))
479           (and (not notmuch-tree-show-out) arg))
480       (notmuch-tree-show-message-out)
481     (notmuch-tree-show-message-in)))
482
483 (defun notmuch-tree-scroll-message-window ()
484   "Scroll the message window (if it exists)"
485   (interactive)
486   (when (window-live-p notmuch-tree-message-window)
487     (with-selected-window notmuch-tree-message-window
488       (if (pos-visible-in-window-p (point-max))
489           t
490         (scroll-up)))))
491
492 (defun notmuch-tree-scroll-message-window-back ()
493   "Scroll the message window back(if it exists)"
494   (interactive)
495   (when (window-live-p notmuch-tree-message-window)
496     (with-selected-window notmuch-tree-message-window
497       (if (pos-visible-in-window-p (point-min))
498           t
499         (scroll-down)))))
500
501 (defun notmuch-tree-scroll-or-next ()
502   "Scroll the message window. If it at end go to next message."
503   (interactive)
504   (when (notmuch-tree-scroll-message-window)
505     (notmuch-tree-next-matching-message)))
506
507 (defun notmuch-tree-quit ()
508   "Close the split view or exit tree."
509   (interactive)
510   (unless (notmuch-tree-close-message-window)
511     (kill-buffer (current-buffer))))
512
513 (defun notmuch-tree-close-message-window ()
514   "Close the message-window. Return t if close succeeds."
515   (interactive)
516   (when (and (window-live-p notmuch-tree-message-window)
517              (eq (window-buffer notmuch-tree-message-window) notmuch-tree-message-buffer))
518     (delete-window notmuch-tree-message-window)
519     (unless (get-buffer-window-list notmuch-tree-message-buffer)
520       (kill-buffer notmuch-tree-message-buffer))
521     t))
522
523 (defun notmuch-tree-archive-message (&optional unarchive)
524   "Archive the current message.
525
526 Archive the current message by applying the tag changes in
527 `notmuch-archive-tags' to it. If a prefix argument is given, the
528 message will be \"unarchived\", i.e. the tag changes in
529 `notmuch-archive-tags' will be reversed."
530   (interactive "P")
531   (when notmuch-archive-tags
532     (notmuch-tree-tag (notmuch-tag-change-list notmuch-archive-tags unarchive))))
533
534 (defun notmuch-tree-archive-message-then-next (&optional unarchive)
535   "Archive the current message and move to next matching message."
536   (interactive "P")
537   (notmuch-tree-archive-message unarchive)
538   (notmuch-tree-next-matching-message))
539
540 (defun notmuch-tree-next-message ()
541   "Move to next message."
542   (interactive)
543   (forward-line)
544   (when (window-live-p notmuch-tree-message-window)
545     (notmuch-tree-show-message-in)))
546
547 (defun notmuch-tree-prev-message ()
548   "Move to previous message."
549   (interactive)
550   (forward-line -1)
551   (when (window-live-p notmuch-tree-message-window)
552     (notmuch-tree-show-message-in)))
553
554 (defun notmuch-tree-prev-matching-message ()
555   "Move to previous matching message."
556   (interactive)
557   (forward-line -1)
558   (while (and (not (bobp)) (not (notmuch-tree-get-match)))
559     (forward-line -1))
560   (when (window-live-p notmuch-tree-message-window)
561     (notmuch-tree-show-message-in)))
562
563 (defun notmuch-tree-next-matching-message ()
564   "Move to next matching message."
565   (interactive)
566   (forward-line)
567   (while (and (not (eobp)) (not (notmuch-tree-get-match)))
568     (forward-line))
569   (when (window-live-p notmuch-tree-message-window)
570     (notmuch-tree-show-message-in)))
571
572 (defun notmuch-tree-refresh-view ()
573   "Refresh view."
574   (interactive)
575   (let ((inhibit-read-only t)
576         (basic-query notmuch-tree-basic-query)
577         (query-context notmuch-tree-query-context)
578         (target (notmuch-tree-get-message-id)))
579     (erase-buffer)
580     (notmuch-tree-worker basic-query
581                          query-context
582                          target)))
583
584 (defun notmuch-tree-thread-top ()
585   (when (notmuch-tree-get-message-properties)
586     (while (not (or (notmuch-tree-get-prop :first) (eobp)))
587       (forward-line -1))))
588
589 (defun notmuch-tree-prev-thread ()
590   (interactive)
591   (forward-line -1)
592   (notmuch-tree-thread-top))
593
594 (defun notmuch-tree-next-thread ()
595   (interactive)
596   (forward-line 1)
597   (while (not (or (notmuch-tree-get-prop :first) (eobp)))
598     (forward-line 1)))
599
600 (defun notmuch-tree-thread-mapcar (function)
601   "Iterate through all messages in the current thread
602  and call FUNCTION for side effects."
603   (save-excursion
604     (notmuch-tree-thread-top)
605     (loop collect (funcall function)
606           do (forward-line)
607           while (and (notmuch-tree-get-message-properties)
608                      (not (notmuch-tree-get-prop :first))))))
609
610 (defun notmuch-tree-get-messages-ids-thread-search ()
611   "Return a search string for all message ids of messages in the current thread."
612   (mapconcat 'identity
613              (notmuch-tree-thread-mapcar 'notmuch-tree-get-message-id)
614              " or "))
615
616 (defun notmuch-tree-tag-thread (tag-changes)
617   "Tag all messages in the current thread"
618   (interactive
619    (let ((tags (apply #'append (notmuch-tree-thread-mapcar
620                                 (lambda () (notmuch-tree-get-tags))))))
621      (list (notmuch-read-tag-changes tags "Tag thread"))))
622   (when (notmuch-tree-get-message-properties)
623     (notmuch-tag (notmuch-tree-get-messages-ids-thread-search) tag-changes)
624     (notmuch-tree-thread-mapcar
625      (lambda () (notmuch-tree-tag-update-display tag-changes)))))
626
627 (defun notmuch-tree-archive-thread (&optional unarchive)
628   "Archive each message in thread.
629
630 Archive each message currently shown by applying the tag changes
631 in `notmuch-archive-tags' to each. If a prefix argument is given,
632 the messages will be \"unarchived\", i.e. the tag changes in
633 `notmuch-archive-tags' will be reversed.
634
635 Note: This command is safe from any race condition of new messages
636 being delivered to the same thread. It does not archive the
637 entire thread, but only the messages shown in the current
638 buffer."
639   (interactive "P")
640   (when notmuch-archive-tags
641     (notmuch-tree-tag-thread
642      (notmuch-tag-change-list notmuch-archive-tags unarchive))))
643
644 ;; Functions below here display the tree buffer itself.
645
646 (defun notmuch-tree-clean-address (address)
647   "Try to clean a single email ADDRESS for display. Return
648 AUTHOR_NAME if present, otherwise return AUTHOR_EMAIL. Return
649 unchanged ADDRESS if parsing fails."
650   (let* ((clean-address (notmuch-clean-address address))
651          (p-address (car clean-address))
652          (p-name (cdr clean-address)))
653
654     ;; If we have a name return that otherwise return the address.
655     (or p-name p-address)))
656
657 (defun notmuch-tree-format-field (field format-string msg)
658   "Format a FIELD of MSG according to FORMAT-STRING and return string"
659   (let* ((headers (plist-get msg :headers))
660          (match (plist-get msg :match)))
661     (cond
662      ((listp field)
663       (format format-string (notmuch-tree-format-field-list field msg)))
664
665      ((string-equal field "date")
666       (let ((face (if match
667                       'notmuch-tree-match-date-face
668                     'notmuch-tree-no-match-date-face)))
669         (propertize (format format-string (plist-get msg :date_relative)) 'face face)))
670
671      ((string-equal field "tree")
672       (let ((tree-status (plist-get msg :tree-status))
673             (face (if match
674                       'notmuch-tree-match-tree-face
675                     'notmuch-tree-no-match-tree-face)))
676
677         (propertize (format format-string
678                             (mapconcat #'identity (reverse tree-status) ""))
679                     'face face)))
680
681      ((string-equal field "subject")
682       (let ((bare-subject (notmuch-show-strip-re (plist-get headers :Subject)))
683             (previous-subject notmuch-tree-previous-subject)
684             (face (if match
685                       'notmuch-tree-match-subject-face
686                     'notmuch-tree-no-match-subject-face)))
687
688         (setq notmuch-tree-previous-subject bare-subject)
689         (propertize (format format-string
690                             (if (string= previous-subject bare-subject)
691                                 " ..."
692                               bare-subject))
693                     'face face)))
694
695      ((string-equal field "authors")
696       (let ((author (notmuch-tree-clean-address (plist-get headers :From)))
697             (len (length (format format-string "")))
698             (face (if match
699                       'notmuch-tree-match-author-face
700                     'notmuch-tree-no-match-author-face)))
701         (when (> (length author) len)
702           (setq author (substring author 0 len)))
703         (propertize (format format-string author) 'face face)))
704
705      ((string-equal field "tags")
706       (let ((tags (plist-get msg :tags))
707             (orig-tags (plist-get msg :orig-tags))
708             (face (if match
709                       'notmuch-tree-match-tag-face
710                     'notmuch-tree-no-match-tag-face)))
711         (format format-string (notmuch-tag-format-tags tags orig-tags face)))))))
712
713 (defun notmuch-tree-format-field-list (field-list msg)
714   "Format fields of MSG according to FIELD-LIST and return string"
715   (let ((face (if (plist-get msg :match)
716                   'notmuch-tree-match-face
717                 'notmuch-tree-no-match-face))
718         (result-string))
719     (dolist (spec field-list result-string)
720       (let ((field-string (notmuch-tree-format-field (car spec) (cdr spec) msg)))
721         (setq result-string (concat result-string field-string))))
722     (notmuch-apply-face result-string face t)))
723
724 (defun notmuch-tree-insert-msg (msg)
725   "Insert the message MSG according to notmuch-tree-result-format"
726   ;; We need to save the previous subject as it will get overwritten
727   ;; by the insert-field calls.
728   (let ((previous-subject notmuch-tree-previous-subject))
729     (insert (notmuch-tree-format-field-list notmuch-tree-result-format msg))
730     (notmuch-tree-set-message-properties msg)
731     (notmuch-tree-set-prop :previous-subject previous-subject)
732     (insert "\n")))
733
734 (defun notmuch-tree-goto-and-insert-msg (msg)
735   "Insert msg at the end of the buffer. Move point to msg if it is the target"
736   (save-excursion
737     (goto-char (point-max))
738     (notmuch-tree-insert-msg msg))
739   (let ((msg-id (notmuch-id-to-query (plist-get msg :id)))
740         (target notmuch-tree-target-msg))
741     (when (or (and (not target) (plist-get msg :match))
742               (string= msg-id target))
743       (setq notmuch-tree-target-msg "found")
744       (goto-char (point-max))
745       (forward-line -1)
746       (when notmuch-tree-open-target
747         (notmuch-tree-show-message-in)))))
748
749 (defun notmuch-tree-insert-tree (tree depth tree-status first last)
750   "Insert the message tree TREE at depth DEPTH in the current thread.
751
752 A message tree is another name for a single sub-thread: i.e., a
753 message together with all its descendents."
754   (let ((msg (car tree))
755         (replies (cadr tree)))
756
757       (cond
758        ((and (< 0 depth) (not last))
759         (push "├" tree-status))
760        ((and (< 0 depth) last)
761         (push "╰" tree-status))
762        ((and (eq 0 depth) first last)
763 ;;        (push "─" tree-status)) choice between this and next line is matter of taste.
764         (push " " tree-status))
765        ((and (eq 0 depth) first (not last))
766           (push "┬" tree-status))
767        ((and (eq 0 depth) (not first) last)
768         (push "╰" tree-status))
769        ((and (eq 0 depth) (not first) (not last))
770         (push "├" tree-status)))
771
772       (push (concat (if replies "┬" "─") "►") tree-status)
773       (setq msg (plist-put msg :first (and first (eq 0 depth))))
774       (setq msg (plist-put msg :tree-status tree-status))
775       (setq msg (plist-put msg :orig-tags (plist-get msg :tags)))
776       (notmuch-tree-goto-and-insert-msg msg)
777       (pop tree-status)
778       (pop tree-status)
779
780       (if last
781           (push " " tree-status)
782         (push "│" tree-status))
783
784     (notmuch-tree-insert-thread replies (1+ depth) tree-status)))
785
786 (defun notmuch-tree-insert-thread (thread depth tree-status)
787   "Insert the collection of sibling sub-threads THREAD at depth DEPTH in the current forest."
788   (let ((n (length thread)))
789     (loop for tree in thread
790           for count from 1 to n
791
792           do (notmuch-tree-insert-tree tree depth tree-status (eq count 1) (eq count n)))))
793
794 (defun notmuch-tree-insert-forest-thread (forest-thread)
795   "Insert a single complete thread."
796   (let (tree-status)
797     ;; Reset at the start of each main thread.
798     (setq notmuch-tree-previous-subject nil)
799     (notmuch-tree-insert-thread forest-thread 0 tree-status)))
800
801 (defun notmuch-tree-insert-forest (forest)
802   "Insert a forest of threads.
803
804 This function inserts a collection of several complete threads as
805 passed to it by notmuch-tree-process-filter."
806   (mapc 'notmuch-tree-insert-forest-thread forest))
807
808 (define-derived-mode notmuch-tree-mode fundamental-mode "notmuch-tree"
809   "Major mode displaying messages (as opposed to threads) of of a notmuch search.
810
811 This buffer contains the results of a \"notmuch tree\" of your
812 email archives. Each line in the buffer represents a single
813 message giving the relative date, the author, subject, and any
814 tags.
815
816 Pressing \\[notmuch-tree-show-message] on any line displays that message.
817
818 Complete list of currently available key bindings:
819
820 \\{notmuch-tree-mode-map}"
821
822   (setq notmuch-buffer-refresh-function #'notmuch-tree-refresh-view)
823   (hl-line-mode 1)
824   (setq buffer-read-only t
825         truncate-lines t))
826
827 (defun notmuch-tree-process-sentinel (proc msg)
828   "Add a message to let user know when \"notmuch tree\" exits"
829   (let ((buffer (process-buffer proc))
830         (status (process-status proc))
831         (exit-status (process-exit-status proc))
832         (never-found-target-thread nil))
833     (when (memq status '(exit signal))
834         (kill-buffer (process-get proc 'parse-buf))
835         (if (buffer-live-p buffer)
836             (with-current-buffer buffer
837               (save-excursion
838                 (let ((inhibit-read-only t)
839                       (atbob (bobp)))
840                   (goto-char (point-max))
841                   (if (eq status 'signal)
842                       (insert "Incomplete search results (tree view process was killed).\n"))
843                   (when (eq status 'exit)
844                     (insert "End of search results.")
845                     (unless (= exit-status 0)
846                       (insert (format " (process returned %d)" exit-status)))
847                     (insert "\n")))))))))
848
849 (defun notmuch-tree-process-filter (proc string)
850   "Process and filter the output of \"notmuch show\" for tree view"
851   (let ((results-buf (process-buffer proc))
852         (parse-buf (process-get proc 'parse-buf))
853         (inhibit-read-only t)
854         done)
855     (if (not (buffer-live-p results-buf))
856         (delete-process proc)
857       (with-current-buffer parse-buf
858         ;; Insert new data
859         (save-excursion
860           (goto-char (point-max))
861           (insert string))
862         (notmuch-sexp-parse-partial-list 'notmuch-tree-insert-forest-thread
863                                          results-buf)))))
864
865 (defun notmuch-tree-worker (basic-query &optional query-context target open-target)
866   "Insert the tree view of the search in the current buffer.
867
868 This is is a helper function for notmuch-tree. The arguments are
869 the same as for the function notmuch-tree."
870   (interactive)
871   (notmuch-tree-mode)
872   (add-hook 'post-command-hook #'notmuch-tree-command-hook t t)
873   (setq notmuch-tree-basic-query basic-query)
874   (setq notmuch-tree-query-context query-context)
875   (setq notmuch-tree-target-msg target)
876   (setq notmuch-tree-open-target open-target)
877   ;; Set the default value for `notmuch-show-process-crypto' in this
878   ;; buffer. Although we don't use this some of the functions we call
879   ;; (such as reply) do. It is a buffer local variable so setting it
880   ;; will not affect genuine show buffers.
881   (setq notmuch-show-process-crypto notmuch-crypto-process-mime)
882
883   (erase-buffer)
884   (goto-char (point-min))
885   (let* ((search-args (concat basic-query
886                        (if query-context (concat " and (" query-context ")"))
887                        ))
888          (message-arg "--entire-thread"))
889     (if (equal (car (process-lines notmuch-command "count" search-args)) "0")
890         (setq search-args basic-query))
891     (notmuch-tag-clear-cache)
892     (let ((proc (notmuch-start-notmuch
893                  "notmuch-tree" (current-buffer) #'notmuch-tree-process-sentinel
894                  "show" "--body=false" "--format=sexp"
895                  message-arg search-args))
896           ;; Use a scratch buffer to accumulate partial output.
897           ;; This buffer will be killed by the sentinel, which
898           ;; should be called no matter how the process dies.
899           (parse-buf (generate-new-buffer " *notmuch tree parse*")))
900       (process-put proc 'parse-buf parse-buf)
901       (set-process-filter proc 'notmuch-tree-process-filter)
902       (set-process-query-on-exit-flag proc nil))))
903
904 (defun notmuch-tree-get-query ()
905   "Return the current query in this tree buffer"
906   (if notmuch-tree-query-context
907       (concat notmuch-tree-basic-query
908               " and ("
909               notmuch-tree-query-context
910               ")")
911     notmuch-tree-basic-query))
912
913 (defun notmuch-tree (&optional query query-context target buffer-name open-target)
914   "Display threads matching QUERY in Tree View.
915
916 The arguments are:
917   QUERY: the main query. This can be any query but in many cases will be
918       a single thread. If nil this is read interactively from the minibuffer.
919   QUERY-CONTEXT: is an additional term for the query. The query used
920       is QUERY and QUERY-CONTEXT unless that does not match any messages
921       in which case we fall back to just QUERY.
922   TARGET: A message ID (with the id: prefix) that will be made
923       current if it appears in the tree view results.
924   BUFFER-NAME: the name of the buffer to display the tree view. If
925       it is nil \"*notmuch-tree\" followed by QUERY is used.
926   OPEN-TARGET: If TRUE open the target message in the message pane."
927   (interactive)
928   (if (null query)
929       (setq query (notmuch-read-query "Notmuch tree view search: ")))
930   (let ((buffer (get-buffer-create (generate-new-buffer-name
931                                     (or buffer-name
932                                         (concat "*notmuch-tree-" query "*")))))
933         (inhibit-read-only t))
934
935     (switch-to-buffer buffer))
936   ;; Don't track undo information for this buffer
937   (set 'buffer-undo-list t)
938
939   (notmuch-tree-worker query query-context target open-target)
940
941   (setq truncate-lines t))
942
943
944 ;;
945
946 (provide 'notmuch-tree)
947
948 ;;; notmuch-tree.el ends here