git.notmuchmail.org Git - notmuch/blob - emacs/notmuch-tree.el

   1 ;;; notmuch-tree.el --- displaying notmuch forests  -*- lexical-binding: t -*-
   2 ;;
   3 ;; Copyright © Carl Worth
   4 ;; Copyright © David Edmondson
   5 ;; Copyright © Mark Walters
   6 ;;
   7 ;; This file is part of Notmuch.
   8 ;;
   9 ;; Notmuch is free software: you can redistribute it and/or modify it
  10 ;; under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation, either version 3 of the License, or
  12 ;; (at your option) any later version.
  13 ;;
  14 ;; Notmuch is distributed in the hope that it will be useful, but
  15 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 ;; General Public License for more details.
  18 ;;
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with Notmuch.  If not, see <https://www.gnu.org/licenses/>.
  21 ;;
  22 ;; Authors: David Edmondson <dme@dme.org>
  23 ;;          Mark Walters <markwalters1009@gmail.com>
  24
  25 ;;; Code:
  26
  27 (require 'mail-parse)
  28
  29 (require 'notmuch-lib)
  30 (require 'notmuch-query)
  31 (require 'notmuch-show)
  32 (require 'notmuch-tag)
  33 (require 'notmuch-parser)
  34 (require 'notmuch-jump)
  35
  36 (declare-function notmuch-search "notmuch"
  37                   (&optional query oldest-first target-thread target-line
  38                              no-display))
  39 (declare-function notmuch-call-notmuch-process "notmuch-lib" (&rest args))
  40 (declare-function notmuch-read-query "notmuch" (prompt))
  41 (declare-function notmuch-search-find-thread-id "notmuch" (&optional bare))
  42 (declare-function notmuch-search-find-subject "notmuch" ())
  43
  44 ;; For `notmuch-tree-next-thread-from-search'.
  45 (declare-function notmuch-search-next-thread "notmuch" ())
  46 (declare-function notmuch-search-previous-thread "notmuch" ())
  47 (declare-function notmuch-tree-from-search-thread "notmuch" ())
  48
  49 ;; the following variable is defined in notmuch.el
  50 (defvar notmuch-search-query-string)
  51
  52 ;; this variable distinguishes the unthreaded display from the normal tree display
  53 (defvar-local notmuch-tree-unthreaded nil
  54   "A buffer local copy of argument unthreaded to the function notmuch-tree.")
  55
  56 ;;; Options
  57
  58 (defgroup notmuch-tree nil
  59   "Showing message and thread structure."
  60   :group 'notmuch)
  61
  62 (defcustom notmuch-tree-show-out nil
  63   "View selected messages in new window rather than split-pane."
  64   :type 'boolean
  65   :group 'notmuch-tree)
  66
  67 (defcustom notmuch-unthreaded-show-out t
  68   "View selected messages in new window rather than split-pane."
  69   :type 'boolean
  70   :group 'notmuch-tree)
  71
  72 (defun notmuch-tree-show-out ()
  73   (if notmuch-tree-unthreaded
  74       notmuch-unthreaded-show-out
  75     notmuch-tree-show-out))
  76
  77 (defcustom notmuch-tree-result-format
  78   `(("date" . "%12s  ")
  79     ("authors" . "%-20s")
  80     ((("tree" . "%s")("subject" . "%s")) ." %-54s ")
  81     ("tags" . "(%s)"))
  82   "Result formatting for tree view. Supported fields are: date,
  83 authors, subject, tree, tags.  Tree means the thread tree
  84 box graphics. The field may also be a list in which case
  85 the formatting rules are applied recursively and then the
  86 output of all the fields in the list is inserted
  87 according to format-string.
  88
  89 Note the author string should not contain
  90 whitespace (put it in the neighbouring fields instead).
  91 For example:
  92         (setq notmuch-tree-result-format \(\(\"authors\" . \"%-40s\"\)
  93                                           \(\"subject\" . \"%s\"\)\)\)"
  94   :type '(alist :key-type (string) :value-type (string))
  95   :group 'notmuch-tree)
  96
  97 (defcustom notmuch-unthreaded-result-format
  98   `(("date" . "%12s  ")
  99     ("authors" . "%-20s")
 100     ((("subject" . "%s")) ." %-54s ")
 101     ("tags" . "(%s)"))
 102   "Result formatting for unthreaded tree view. Supported fields are: date,
 103 authors, subject, tree, tags.  Tree means the thread tree
 104 box graphics. The field may also be a list in which case
 105 the formatting rules are applied recursively and then the
 106 output of all the fields in the list is inserted
 107 according to format-string.
 108
 109 Note the author string should not contain
 110 whitespace (put it in the neighbouring fields instead).
 111 For example:
 112         (setq notmuch-tree-result-format \(\(\"authors\" . \"%-40s\"\)
 113                                           \(\"subject\" . \"%s\"\)\)\)"
 114   :type '(alist :key-type (string) :value-type (string))
 115   :group 'notmuch-tree)
 116
 117 (defun notmuch-tree-result-format ()
 118   (if notmuch-tree-unthreaded
 119       notmuch-unthreaded-result-format
 120     notmuch-tree-result-format))
 121
 122 ;;; Faces
 123 ;;;; Faces for messages that match the query
 124
 125 (defface notmuch-tree-match-face
 126   '((t :inherit default))
 127   "Default face used in tree mode face for matching messages"
 128   :group 'notmuch-tree
 129   :group 'notmuch-faces)
 130
 131 (defface notmuch-tree-match-date-face
 132   nil
 133   "Face used in tree mode for the date in messages matching the query."
 134   :group 'notmuch-tree
 135   :group 'notmuch-faces)
 136
 137 (defface notmuch-tree-match-author-face
 138   '((((class color)
 139       (background dark))
 140      (:foreground "OliveDrab1"))
 141     (((class color)
 142       (background light))
 143      (:foreground "dark blue"))
 144     (t
 145      (:bold t)))
 146   "Face used in tree mode for the date in messages matching the query."
 147   :group 'notmuch-tree
 148   :group 'notmuch-faces)
 149
 150 (defface notmuch-tree-match-subject-face
 151   nil
 152   "Face used in tree mode for the subject in messages matching the query."
 153   :group 'notmuch-tree
 154   :group 'notmuch-faces)
 155
 156 (defface notmuch-tree-match-tree-face
 157   nil
 158   "Face used in tree mode for the thread tree block graphics in messages matching the query."
 159   :group 'notmuch-tree
 160   :group 'notmuch-faces)
 161
 162 (defface notmuch-tree-match-tag-face
 163   '((((class color)
 164       (background dark))
 165      (:foreground "OliveDrab1"))
 166     (((class color)
 167       (background light))
 168      (:foreground "navy blue" :bold t))
 169     (t
 170      (:bold t)))
 171   "Face used in tree mode for tags in messages matching the query."
 172   :group 'notmuch-tree
 173   :group 'notmuch-faces)
 174
 175 ;;;; Faces for messages that do not match the query
 176
 177 (defface notmuch-tree-no-match-face
 178   '((t (:foreground "gray")))
 179   "Default face used in tree mode face for non-matching messages."
 180   :group 'notmuch-tree
 181   :group 'notmuch-faces)
 182
 183 (defface notmuch-tree-no-match-date-face
 184   nil
 185   "Face used in tree mode for non-matching dates."
 186   :group 'notmuch-tree
 187   :group 'notmuch-faces)
 188
 189 (defface notmuch-tree-no-match-subject-face
 190   nil
 191   "Face used in tree mode for non-matching subjects."
 192   :group 'notmuch-tree
 193   :group 'notmuch-faces)
 194
 195 (defface notmuch-tree-no-match-tree-face
 196   nil
 197   "Face used in tree mode for the thread tree block graphics in messages matching the query."
 198   :group 'notmuch-tree
 199   :group 'notmuch-faces)
 200
 201 (defface notmuch-tree-no-match-author-face
 202   nil
 203   "Face used in tree mode for the date in messages matching the query."
 204   :group 'notmuch-tree
 205   :group 'notmuch-faces)
 206
 207 (defface notmuch-tree-no-match-tag-face
 208   nil
 209   "Face used in tree mode face for non-matching tags."
 210   :group 'notmuch-tree
 211   :group 'notmuch-faces)
 212
 213 ;;; Variables
 214
 215 (defvar-local notmuch-tree-previous-subject
 216   "The subject of the most recent result shown during the async display.")
 217
 218 (defvar-local notmuch-tree-basic-query nil
 219   "A buffer local copy of argument query to the function notmuch-tree.")
 220
 221 (defvar-local notmuch-tree-query-context nil
 222   "A buffer local copy of argument query-context to the function notmuch-tree.")
 223
 224 (defvar-local notmuch-tree-target-msg nil
 225   "A buffer local copy of argument target to the function notmuch-tree.")
 226
 227 (defvar-local notmuch-tree-open-target nil
 228   "A buffer local copy of argument open-target to the function notmuch-tree.")
 229
 230 (defvar-local notmuch-tree-parent-buffer nil)
 231
 232 (defvar-local notmuch-tree-message-window nil
 233   "The window of the message pane.
 234
 235 It is set in both the tree buffer and the child show buffer. It
 236 is used to try and close the message pane when quitting tree view
 237 or the child show buffer.")
 238 (put 'notmuch-tree-message-window 'permanent-local t)
 239
 240 (defvar-local notmuch-tree-message-buffer nil
 241   "The buffer name of the show buffer in the message pane.
 242
 243 This is used to try and make sure we don't close the message pane
 244 if the user has loaded a different buffer in that window.")
 245 (put 'notmuch-tree-message-buffer 'permanent-local t)
 246
 247 ;;; Tree wrapper commands
 248
 249 (defmacro notmuch-tree--define-do-in-message-window (name cmd)
 250   "Define NAME as a command that calls CMD interactively in the message window.
 251 If the message pane is closed then this command does nothing.
 252 Avoid using this macro in new code; it will be removed."
 253   `(defun ,name ()
 254      ,(concat "(In message window) " (documentation cmd t))
 255      (interactive)
 256      (when (window-live-p notmuch-tree-message-window)
 257        (with-selected-window notmuch-tree-message-window
 258          (call-interactively #',cmd)))))
 259
 260 (notmuch-tree--define-do-in-message-window
 261  notmuch-tree-previous-message-button
 262  notmuch-show-previous-button)
 263 (notmuch-tree--define-do-in-message-window
 264  notmuch-tree-next-message-button
 265  notmuch-show-next-button)
 266 (notmuch-tree--define-do-in-message-window
 267  notmuch-tree-toggle-message-process-crypto
 268  notmuch-show-toggle-process-crypto)
 269
 270 (defun notmuch-tree--message-process-crypto ()
 271   "Return value of `notmuch-show-process-crypto' in the message window.
 272 If that window isn't alive, then return the current value.
 273 Avoid using this function in new code; it will be removed."
 274   (if (window-live-p notmuch-tree-message-window)
 275       (with-selected-window notmuch-tree-message-window
 276         notmuch-show-process-crypto)
 277     notmuch-show-process-crypto))
 278
 279 (defmacro notmuch-tree--define-close-message-window-and (name cmd)
 280   "Define NAME as a variant of CMD.
 281
 282 NAME determines the value of `notmuch-show-process-crypto' in the
 283 message window, closes the window, and then call CMD interactively
 284 with that value let-bound.  If the message window does not exist,
 285 then NAME behaves like CMD."
 286   `(defun ,name ()
 287      ,(concat "(Close message pane and) " (documentation cmd t))
 288      (interactive)
 289      (let ((notmuch-show-process-crypto
 290             (notmuch-tree--message-process-crypto)))
 291        (notmuch-tree-close-message-window)
 292        (call-interactively #',cmd))))
 293
 294 (notmuch-tree--define-close-message-window-and
 295  notmuch-tree-help
 296  notmuch-help)
 297 (notmuch-tree--define-close-message-window-and
 298  notmuch-tree-new-mail
 299  notmuch-mua-new-mail)
 300 (notmuch-tree--define-close-message-window-and
 301  notmuch-tree-jump-search
 302  notmuch-jump-search)
 303 (notmuch-tree--define-close-message-window-and
 304  notmuch-tree-forward-message
 305  notmuch-show-forward-message)
 306 (notmuch-tree--define-close-message-window-and
 307  notmuch-tree-reply-sender
 308  notmuch-show-reply-sender)
 309 (notmuch-tree--define-close-message-window-and
 310  notmuch-tree-reply
 311  notmuch-show-reply)
 312 (notmuch-tree--define-close-message-window-and
 313  notmuch-tree-view-raw-message
 314  notmuch-show-view-raw-message)
 315
 316 ;;; Keymap
 317
 318 (defvar notmuch-tree-mode-map
 319   (let ((map (make-sparse-keymap)))
 320     (set-keymap-parent map notmuch-common-keymap)
 321     ;; These bindings shadow common bindings with variants
 322     ;; that additionally close the message window.
 323     (define-key map [remap notmuch-bury-or-kill-this-buffer] 'notmuch-tree-quit)
 324     (define-key map [remap notmuch-search]       'notmuch-tree-to-search)
 325     (define-key map [remap notmuch-help]         'notmuch-tree-help)
 326     (define-key map [remap notmuch-mua-new-mail] 'notmuch-tree-new-mail)
 327     (define-key map [remap notmuch-jump-search]  'notmuch-tree-jump-search)
 328
 329     (define-key map "o" 'notmuch-tree-toggle-order)
 330     (define-key map "S" 'notmuch-search-from-tree-current-query)
 331     (define-key map "U" 'notmuch-unthreaded-from-tree-current-query)
 332     (define-key map "Z" 'notmuch-tree-from-unthreaded-current-query)
 333
 334     ;; these use notmuch-show functions directly
 335     (define-key map "|" 'notmuch-show-pipe-message)
 336     (define-key map "w" 'notmuch-show-save-attachments)
 337     (define-key map "v" 'notmuch-show-view-all-mime-parts)
 338     (define-key map "c" 'notmuch-show-stash-map)
 339     (define-key map "b" 'notmuch-show-resend-message)
 340
 341     ;; these apply to the message pane
 342     (define-key map (kbd "M-TAB")     'notmuch-tree-previous-message-button)
 343     (define-key map (kbd "<backtab>") 'notmuch-tree-previous-message-button)
 344     (define-key map (kbd "TAB")       'notmuch-tree-next-message-button)
 345     (define-key map "$" 'notmuch-tree-toggle-message-process-crypto)
 346
 347     ;; bindings from show (or elsewhere) but we close the message pane first.
 348     (define-key map "f" 'notmuch-tree-forward-message)
 349     (define-key map "r" 'notmuch-tree-reply-sender)
 350     (define-key map "R" 'notmuch-tree-reply)
 351     (define-key map "V" 'notmuch-tree-view-raw-message)
 352     (define-key map "l" 'notmuch-tree-filter)
 353
 354     ;; The main tree view bindings
 355     (define-key map (kbd "RET") 'notmuch-tree-show-message)
 356     (define-key map [mouse-1] 'notmuch-tree-show-message)
 357     (define-key map "x" 'notmuch-tree-archive-message-then-next-or-exit)
 358     (define-key map "X" 'notmuch-tree-archive-thread-then-exit)
 359     (define-key map "A" 'notmuch-tree-archive-thread-then-next)
 360     (define-key map "a" 'notmuch-tree-archive-message-then-next)
 361     (define-key map "z" 'notmuch-tree-to-tree)
 362     (define-key map "n" 'notmuch-tree-next-matching-message)
 363     (define-key map "p" 'notmuch-tree-prev-matching-message)
 364     (define-key map "N" 'notmuch-tree-next-message)
 365     (define-key map "P" 'notmuch-tree-prev-message)
 366     (define-key map (kbd "M-p") 'notmuch-tree-prev-thread)
 367     (define-key map (kbd "M-n") 'notmuch-tree-next-thread)
 368     (define-key map "k" 'notmuch-tag-jump)
 369     (define-key map "-" 'notmuch-tree-remove-tag)
 370     (define-key map "+" 'notmuch-tree-add-tag)
 371     (define-key map "*" 'notmuch-tree-tag-thread)
 372     (define-key map " " 'notmuch-tree-scroll-or-next)
 373     (define-key map (kbd "DEL") 'notmuch-tree-scroll-message-window-back)
 374     (define-key map "e" 'notmuch-tree-resume-message)
 375     map)
 376   "Keymap for \"notmuch tree\" buffers.")
 377
 378 ;;; Message properties
 379
 380 (defun notmuch-tree-get-message-properties ()
 381   "Return the properties of the current message as a plist.
 382
 383 Some useful entries are:
 384 :headers - Property list containing the headers :Date, :Subject, :From, etc.
 385 :tags - Tags for this message."
 386   (save-excursion
 387     (beginning-of-line)
 388     (get-text-property (point) :notmuch-message-properties)))
 389
 390 (defun notmuch-tree-set-message-properties (props)
 391   (save-excursion
 392     (beginning-of-line)
 393     (put-text-property (point)
 394                        (+ (point) 1)
 395                        :notmuch-message-properties props)))
 396
 397 (defun notmuch-tree-set-prop (prop val &optional props)
 398   (let ((inhibit-read-only t)
 399         (props (or props
 400                    (notmuch-tree-get-message-properties))))
 401     (plist-put props prop val)
 402     (notmuch-tree-set-message-properties props)))
 403
 404 (defun notmuch-tree-get-prop (prop &optional props)
 405   (plist-get (or props (notmuch-tree-get-message-properties))
 406              prop))
 407
 408 (defun notmuch-tree-set-tags (tags)
 409   "Set the tags of the current message."
 410   (notmuch-tree-set-prop :tags tags))
 411
 412 (defun notmuch-tree-get-tags ()
 413   "Return the tags of the current message."
 414   (notmuch-tree-get-prop :tags))
 415
 416 (defun notmuch-tree-get-message-id (&optional bare)
 417   "Return the message id of the current message."
 418   (let ((id (notmuch-tree-get-prop :id)))
 419     (if id
 420         (if bare
 421             id
 422           (notmuch-id-to-query id))
 423       nil)))
 424
 425 (defun notmuch-tree-get-match ()
 426   "Return whether the current message is a match."
 427   (notmuch-tree-get-prop :match))
 428
 429 ;;; Update display
 430
 431 (defun notmuch-tree-refresh-result ()
 432   "Redisplay the current message line.
 433
 434 This redisplays the current line based on the messages
 435 properties (as they are now). This is used when tags are
 436 updated."
 437   (let ((init-point (point))
 438         (end (line-end-position))
 439         (msg (notmuch-tree-get-message-properties))
 440         (inhibit-read-only t))
 441     (beginning-of-line)
 442     ;; This is a little tricky: we override
 443     ;; notmuch-tree-previous-subject to get the decision between
 444     ;; ... and a subject right and it stops notmuch-tree-insert-msg
 445     ;; from overwriting the buffer local copy of
 446     ;; notmuch-tree-previous-subject if this is called while the
 447     ;; buffer is displaying.
 448     (let ((notmuch-tree-previous-subject
 449            (notmuch-tree-get-prop :previous-subject)))
 450       (delete-region (point) (1+ (line-end-position)))
 451       (notmuch-tree-insert-msg msg))
 452     (let ((new-end (line-end-position)))
 453       (goto-char (if (= init-point end)
 454                      new-end
 455                    (min init-point (- new-end 1)))))))
 456
 457 (defun notmuch-tree-tag-update-display (&optional tag-changes)
 458   "Update display for TAG-CHANGES to current message.
 459
 460 Updates the message in the message pane if appropriate, but does
 461 NOT change the database."
 462   (let* ((current-tags (notmuch-tree-get-tags))
 463          (new-tags (notmuch-update-tags current-tags tag-changes))
 464          (tree-msg-id (notmuch-tree-get-message-id)))
 465     (unless (equal current-tags new-tags)
 466       (notmuch-tree-set-tags new-tags)
 467       (notmuch-tree-refresh-result)
 468       (when (window-live-p notmuch-tree-message-window)
 469         (with-selected-window notmuch-tree-message-window
 470           (when (string= tree-msg-id (notmuch-show-get-message-id))
 471             (notmuch-show-update-tags new-tags)))))))
 472
 473 ;;; Commands (and some helper functions used by them)
 474
 475 (defun notmuch-tree-tag (tag-changes)
 476   "Change tags for the current message."
 477   (interactive
 478    (list (notmuch-read-tag-changes (notmuch-tree-get-tags) "Tag message")))
 479   (notmuch-tag (notmuch-tree-get-message-id) tag-changes)
 480   (notmuch-tree-tag-update-display tag-changes))
 481
 482 (defun notmuch-tree-add-tag (tag-changes)
 483   "Same as `notmuch-tree-tag' but sets initial input to '+'."
 484   (interactive
 485    (list (notmuch-read-tag-changes (notmuch-tree-get-tags) "Tag message" "+")))
 486   (notmuch-tree-tag tag-changes))
 487
 488 (defun notmuch-tree-remove-tag (tag-changes)
 489   "Same as `notmuch-tree-tag' but sets initial input to '-'."
 490   (interactive
 491    (list (notmuch-read-tag-changes (notmuch-tree-get-tags) "Tag message" "-")))
 492   (notmuch-tree-tag tag-changes))
 493
 494 (defun notmuch-tree-resume-message ()
 495   "Resume EDITING the current draft message."
 496   (interactive)
 497   (notmuch-tree-close-message-window)
 498   (let ((id (notmuch-tree-get-message-id)))
 499     (if id
 500         (notmuch-draft-resume id)
 501       (message "No message to resume!"))))
 502
 503 ;; The next two functions close the message window before calling
 504 ;; notmuch-search or notmuch-tree but they do so after the user has
 505 ;; entered the query (in case the user was basing the query on
 506 ;; something in the message window).
 507
 508 (defun notmuch-tree-to-search ()
 509   "Run \"notmuch search\" with the given `query' and display results."
 510   (interactive)
 511   (let ((query (notmuch-read-query "Notmuch search: ")))
 512     (notmuch-tree-close-message-window)
 513     (notmuch-search query)))
 514
 515 (defun notmuch-tree-to-tree ()
 516   "Run a query and display results in tree view."
 517   (interactive)
 518   (let ((query (notmuch-read-query "Notmuch tree view search: ")))
 519     (notmuch-tree-close-message-window)
 520     (notmuch-tree query)))
 521
 522 (defun notmuch-tree-archive-thread-then-next ()
 523   "Archive all messages in the current buffer, then show next thread from search."
 524   (interactive)
 525   (notmuch-tree-archive-thread)
 526   (notmuch-tree-next-thread))
 527
 528 (defun notmuch-unthreaded-from-tree-current-query ()
 529   "Switch from tree view to unthreaded view."
 530   (interactive)
 531   (unless notmuch-tree-unthreaded
 532     (notmuch-tree-refresh-view 'unthreaded)))
 533
 534 (defun notmuch-tree-from-unthreaded-current-query ()
 535   "Switch from unthreaded view to tree view."
 536   (interactive)
 537   (when notmuch-tree-unthreaded
 538     (notmuch-tree-refresh-view 'tree)))
 539
 540 (defun notmuch-search-from-tree-current-query ()
 541   "Call notmuch search with the current query."
 542   (interactive)
 543   (notmuch-tree-close-message-window)
 544   (notmuch-search (notmuch-tree-get-query)))
 545
 546 (defun notmuch-tree-message-window-kill-hook ()
 547   "Close the message pane when exiting the show buffer."
 548   (let ((buffer (current-buffer)))
 549     (when (and (window-live-p notmuch-tree-message-window)
 550                (eq (window-buffer notmuch-tree-message-window) buffer))
 551       ;; We could check whether this is the only window in its frame,
 552       ;; but simply ignoring the error that is thrown otherwise is
 553       ;; what we had to do for Emacs 24 and we stick to that because
 554       ;; it is still the simplest approach.
 555       (ignore-errors
 556         (delete-window notmuch-tree-message-window)))))
 557
 558 (defun notmuch-tree-command-hook ()
 559   (when (eq major-mode 'notmuch-tree-mode)
 560     ;; We just run the notmuch-show-command-hook on the message pane.
 561     (when (buffer-live-p notmuch-tree-message-buffer)
 562       (with-current-buffer notmuch-tree-message-buffer
 563         (notmuch-show-command-hook)))))
 564
 565 (defun notmuch-tree-show-message-in ()
 566   "Show the current message (in split-pane)."
 567   (interactive)
 568   (let ((id (notmuch-tree-get-message-id))
 569         (inhibit-read-only t)
 570         buffer)
 571     (when id
 572       ;; We close and reopen the window to kill off un-needed buffers
 573       ;; this might cause flickering but seems ok.
 574       (notmuch-tree-close-message-window)
 575       (setq notmuch-tree-message-window
 576             (split-window-vertically (/ (window-height) 4)))
 577       (with-selected-window notmuch-tree-message-window
 578         (let (;; Since we are only displaying one message do not indent.
 579               (notmuch-show-indent-messages-width 0)
 580               (notmuch-show-single-message t)
 581               ;; Ensure that `pop-to-buffer-same-window' uses the
 582               ;; window we want it to use.
 583               (display-buffer-overriding-action
 584                  '((display-buffer-same-window)
 585                    (inhibit-same-window . nil))))
 586           (setq buffer (notmuch-show id))))
 587       ;; We need the `let' as notmuch-tree-message-window is buffer local.
 588       (let ((window notmuch-tree-message-window))
 589         (with-current-buffer buffer
 590           (setq notmuch-tree-message-window window)
 591           (add-hook 'kill-buffer-hook 'notmuch-tree-message-window-kill-hook)))
 592       (when notmuch-show-mark-read-tags
 593         (notmuch-tree-tag-update-display notmuch-show-mark-read-tags))
 594       (setq notmuch-tree-message-buffer buffer))))
 595
 596 (defun notmuch-tree-show-message-out ()
 597   "Show the current message (in whole window)."
 598   (interactive)
 599   (let ((id (notmuch-tree-get-message-id))
 600         (inhibit-read-only t))
 601     (when id
 602       ;; We close the window to kill off un-needed buffers.
 603       (notmuch-tree-close-message-window)
 604       ;; n-s-s-m is buffer local, so use inner let.
 605       (let ((notmuch-show-single-message t))
 606         (notmuch-show id)))))
 607
 608 (defun notmuch-tree-show-message (arg)
 609   "Show the current message.
 610
 611 Shows in split pane or whole window according to value of
 612 `notmuch-tree-show-out'. A prefix argument reverses the choice."
 613   (interactive "P")
 614   (if (or (and (notmuch-tree-show-out) (not arg))
 615           (and (not (notmuch-tree-show-out)) arg))
 616       (notmuch-tree-show-message-out)
 617     (notmuch-tree-show-message-in)))
 618
 619 (defun notmuch-tree-scroll-message-window ()
 620   "Scroll the message window (if it exists)."
 621   (interactive)
 622   (when (window-live-p notmuch-tree-message-window)
 623     (with-selected-window notmuch-tree-message-window
 624       (if (pos-visible-in-window-p (point-max))
 625           t
 626         (scroll-up)))))
 627
 628 (defun notmuch-tree-scroll-message-window-back ()
 629   "Scroll the message window back (if it exists)."
 630   (interactive)
 631   (when (window-live-p notmuch-tree-message-window)
 632     (with-selected-window notmuch-tree-message-window
 633       (if (pos-visible-in-window-p (point-min))
 634           t
 635         (scroll-down)))))
 636
 637 (defun notmuch-tree-scroll-or-next ()
 638   "Scroll the message window.
 639 If it at end go to next message."
 640   (interactive)
 641   (when (notmuch-tree-scroll-message-window)
 642     (notmuch-tree-next-matching-message)))
 643
 644 (defun notmuch-tree-quit (&optional kill-both)
 645   "Close the split view or exit tree."
 646   (interactive "P")
 647   (when (or (not (notmuch-tree-close-message-window)) kill-both)
 648     (kill-buffer (current-buffer))))
 649
 650 (defun notmuch-tree-close-message-window ()
 651   "Close the message-window. Return t if close succeeds."
 652   (interactive)
 653   (when (and (window-live-p notmuch-tree-message-window)
 654              (eq (window-buffer notmuch-tree-message-window)
 655                  notmuch-tree-message-buffer))
 656     (delete-window notmuch-tree-message-window)
 657     (unless (get-buffer-window-list notmuch-tree-message-buffer)
 658       (kill-buffer notmuch-tree-message-buffer))
 659     t))
 660
 661 (defun notmuch-tree-archive-message (&optional unarchive)
 662   "Archive the current message.
 663
 664 Archive the current message by applying the tag changes in
 665 `notmuch-archive-tags' to it. If a prefix argument is given, the
 666 message will be \"unarchived\", i.e. the tag changes in
 667 `notmuch-archive-tags' will be reversed."
 668   (interactive "P")
 669   (when notmuch-archive-tags
 670     (notmuch-tree-tag
 671      (notmuch-tag-change-list notmuch-archive-tags unarchive))))
 672
 673 (defun notmuch-tree-archive-message-then-next (&optional unarchive)
 674   "Archive the current message and move to next matching message."
 675   (interactive "P")
 676   (notmuch-tree-archive-message unarchive)
 677   (notmuch-tree-next-matching-message))
 678
 679 (defun notmuch-tree-archive-thread-then-exit ()
 680   "Archive all messages in the current buffer, then exit notmuch-tree."
 681   (interactive)
 682   (notmuch-tree-archive-thread)
 683   (notmuch-tree-quit t))
 684
 685 (defun notmuch-tree-archive-message-then-next-or-exit ()
 686   "Archive current message, then show next open message in current thread.
 687
 688 If at the last open message in the current thread, then exit back
 689 to search results."
 690   (interactive)
 691   (notmuch-tree-archive-message)
 692   (notmuch-tree-next-matching-message t))
 693
 694 (defun notmuch-tree-next-message ()
 695   "Move to next message."
 696   (interactive)
 697   (forward-line)
 698   (when (window-live-p notmuch-tree-message-window)
 699     (notmuch-tree-show-message-in)))
 700
 701 (defun notmuch-tree-prev-message ()
 702   "Move to previous message."
 703   (interactive)
 704   (forward-line -1)
 705   (when (window-live-p notmuch-tree-message-window)
 706     (notmuch-tree-show-message-in)))
 707
 708 (defun notmuch-tree-goto-matching-message (&optional prev)
 709   "Move to the next or previous matching message.
 710
 711 Returns t if there was a next matching message in the thread to show,
 712 nil otherwise."
 713   (let ((dir (if prev -1 nil))
 714         (eobfn (if prev #'bobp #'eobp)))
 715     (while (and (not (funcall eobfn))
 716                 (not (notmuch-tree-get-match)))
 717       (forward-line dir))
 718     (not (funcall eobfn))))
 719
 720 (defun notmuch-tree-matching-message (&optional prev pop-at-end)
 721   "Move to the next or previous matching message."
 722   (interactive "P")
 723   (forward-line (if prev -1 nil))
 724   (if (and (not (notmuch-tree-goto-matching-message prev)) pop-at-end)
 725       (notmuch-tree-quit pop-at-end)
 726     (when (window-live-p notmuch-tree-message-window)
 727       (notmuch-tree-show-message-in))))
 728
 729 (defun notmuch-tree-prev-matching-message (&optional pop-at-end)
 730   "Move to previous matching message."
 731   (interactive "P")
 732   (notmuch-tree-matching-message t pop-at-end))
 733
 734 (defun notmuch-tree-next-matching-message (&optional pop-at-end)
 735   "Move to next matching message."
 736   (interactive "P")
 737   (notmuch-tree-matching-message nil pop-at-end))
 738
 739 (defun notmuch-tree-refresh-view (&optional view)
 740   "Refresh view."
 741   (interactive)
 742   (when (get-buffer-process (current-buffer))
 743     (error "notmuch tree process already running for current buffer"))
 744   (let ((inhibit-read-only t)
 745         (basic-query notmuch-tree-basic-query)
 746         (unthreaded (cond ((eq view 'unthreaded) t)
 747                           ((eq view 'tree) nil)
 748                           (t notmuch-tree-unthreaded)))
 749         (query-context notmuch-tree-query-context)
 750         (target (notmuch-tree-get-message-id)))
 751     (erase-buffer)
 752     (notmuch-tree-worker basic-query
 753                          query-context
 754                          target
 755                          nil
 756                          unthreaded
 757                          notmuch-search-oldest-first)))
 758
 759 (defun notmuch-tree-thread-top ()
 760   (when (notmuch-tree-get-message-properties)
 761     (while (not (or (notmuch-tree-get-prop :first) (eobp)))
 762       (forward-line -1))))
 763
 764 (defun notmuch-tree-prev-thread-in-tree ()
 765   "Move to the previous thread in the current tree"
 766   (interactive)
 767   (forward-line -1)
 768   (notmuch-tree-thread-top)
 769   (not (bobp)))
 770
 771 (defun notmuch-tree-next-thread-in-tree ()
 772   "Get the next thread in the current tree. Returns t if a thread was
 773 found or nil if not."
 774   (interactive)
 775   (forward-line 1)
 776   (while (not (or (notmuch-tree-get-prop :first) (eobp)))
 777     (forward-line 1))
 778   (not (eobp)))
 779
 780 (defun notmuch-tree-next-thread-from-search (&optional previous)
 781   "Move to the next thread in the parent search results, if any.
 782
 783 If PREVIOUS is non-nil, move to the previous item in the
 784 search results instead."
 785   (interactive "P")
 786   (let ((parent-buffer notmuch-tree-parent-buffer))
 787     (notmuch-tree-quit t)
 788     (when (buffer-live-p parent-buffer)
 789       (switch-to-buffer parent-buffer)
 790       (if previous
 791           (notmuch-search-previous-thread)
 792         (notmuch-search-next-thread))
 793       (notmuch-tree-from-search-thread))))
 794
 795 (defun notmuch-tree-next-thread (&optional previous)
 796   "Move to the next thread in the current tree or parent search results.
 797
 798 If PREVIOUS is non-nil, move to the previous thread in the tree or
 799 search results instead."
 800   (interactive)
 801   (unless (if previous (notmuch-tree-prev-thread-in-tree)
 802             (notmuch-tree-next-thread-in-tree))
 803     (notmuch-tree-next-thread-from-search previous)))
 804
 805 (defun notmuch-tree-prev-thread ()
 806   "Move to the previous thread in the current tree or parent search results."
 807   (interactive)
 808   (notmuch-tree-next-thread t))
 809
 810 (defun notmuch-tree-thread-mapcar (function)
 811   "Call FUNCTION for each message in the current thread.
 812 FUNCTION is called for side effects only."
 813   (save-excursion
 814     (notmuch-tree-thread-top)
 815     (cl-loop collect (funcall function)
 816              do (forward-line)
 817              while (and (notmuch-tree-get-message-properties)
 818                         (not (notmuch-tree-get-prop :first))))))
 819
 820 (defun notmuch-tree-get-messages-ids-thread-search ()
 821   "Return a search string for all message ids of messages in the current thread."
 822   (mapconcat 'identity
 823              (notmuch-tree-thread-mapcar 'notmuch-tree-get-message-id)
 824              " or "))
 825
 826 (defun notmuch-tree-tag-thread (tag-changes)
 827   "Tag all messages in the current thread."
 828   (interactive
 829    (let ((tags (apply #'append (notmuch-tree-thread-mapcar
 830                                 (lambda () (notmuch-tree-get-tags))))))
 831      (list (notmuch-read-tag-changes tags "Tag thread"))))
 832   (when (notmuch-tree-get-message-properties)
 833     (notmuch-tag (notmuch-tree-get-messages-ids-thread-search) tag-changes)
 834     (notmuch-tree-thread-mapcar
 835      (lambda () (notmuch-tree-tag-update-display tag-changes)))))
 836
 837 (defun notmuch-tree-archive-thread (&optional unarchive)
 838   "Archive each message in thread.
 839
 840 Archive each message currently shown by applying the tag changes
 841 in `notmuch-archive-tags' to each. If a prefix argument is given,
 842 the messages will be \"unarchived\", i.e. the tag changes in
 843 `notmuch-archive-tags' will be reversed.
 844
 845 Note: This command is safe from any race condition of new messages
 846 being delivered to the same thread. It does not archive the
 847 entire thread, but only the messages shown in the current
 848 buffer."
 849   (interactive "P")
 850   (when notmuch-archive-tags
 851     (notmuch-tree-tag-thread
 852      (notmuch-tag-change-list notmuch-archive-tags unarchive))))
 853
 854 ;;; Functions for displaying the tree buffer itself
 855
 856 (defun notmuch-tree-clean-address (address)
 857   "Try to clean a single email ADDRESS for display. Return
 858 AUTHOR_NAME if present, otherwise return AUTHOR_EMAIL. Return
 859 unchanged ADDRESS if parsing fails."
 860   (let* ((clean-address (notmuch-clean-address address))
 861          (p-address (car clean-address))
 862          (p-name (cdr clean-address)))
 863
 864     ;; If we have a name return that otherwise return the address.
 865     (or p-name p-address)))
 866
 867 (defun notmuch-tree-format-field (field format-string msg)
 868   "Format a FIELD of MSG according to FORMAT-STRING and return string."
 869   (let* ((headers (plist-get msg :headers))
 870          (match (plist-get msg :match)))
 871     (cond
 872      ((listp field)
 873       (format format-string (notmuch-tree-format-field-list field msg)))
 874
 875      ((string-equal field "date")
 876       (let ((face (if match
 877                       'notmuch-tree-match-date-face
 878                     'notmuch-tree-no-match-date-face)))
 879         (propertize (format format-string (plist-get msg :date_relative))
 880                     'face face)))
 881
 882      ((string-equal field "tree")
 883       (let ((tree-status (plist-get msg :tree-status))
 884             (face (if match
 885                       'notmuch-tree-match-tree-face
 886                     'notmuch-tree-no-match-tree-face)))
 887
 888         (propertize (format format-string
 889                             (mapconcat #'identity (reverse tree-status) ""))
 890                     'face face)))
 891
 892      ((string-equal field "subject")
 893       (let ((bare-subject (notmuch-show-strip-re (plist-get headers :Subject)))
 894             (previous-subject notmuch-tree-previous-subject)
 895             (face (if match
 896                       'notmuch-tree-match-subject-face
 897                     'notmuch-tree-no-match-subject-face)))
 898
 899         (setq notmuch-tree-previous-subject bare-subject)
 900         (propertize (format format-string
 901                             (if (string= previous-subject bare-subject)
 902                                 " ..."
 903                               bare-subject))
 904                     'face face)))
 905
 906      ((string-equal field "authors")
 907       (let ((author (notmuch-tree-clean-address (plist-get headers :From)))
 908             (len (length (format format-string "")))
 909             (face (if match
 910                       'notmuch-tree-match-author-face
 911                     'notmuch-tree-no-match-author-face)))
 912         (when (> (length author) len)
 913           (setq author (substring author 0 len)))
 914         (propertize (format format-string author) 'face face)))
 915
 916      ((string-equal field "tags")
 917       (let ((tags (plist-get msg :tags))
 918             (orig-tags (plist-get msg :orig-tags))
 919             (face (if match
 920                       'notmuch-tree-match-tag-face
 921                     'notmuch-tree-no-match-tag-face)))
 922         (format format-string (notmuch-tag-format-tags tags orig-tags face)))))))
 923
 924 (defun notmuch-tree-format-field-list (field-list msg)
 925   "Format fields of MSG according to FIELD-LIST and return string."
 926   (let ((face (if (plist-get msg :match)
 927                   'notmuch-tree-match-face
 928                 'notmuch-tree-no-match-face))
 929         (result-string))
 930     (dolist (spec field-list result-string)
 931       (let ((field-string (notmuch-tree-format-field (car spec) (cdr spec) msg)))
 932         (setq result-string (concat result-string field-string))))
 933     (notmuch-apply-face result-string face t)))
 934
 935 (defun notmuch-tree-insert-msg (msg)
 936   "Insert the message MSG according to notmuch-tree-result-format."
 937   ;; We need to save the previous subject as it will get overwritten
 938   ;; by the insert-field calls.
 939   (let ((previous-subject notmuch-tree-previous-subject))
 940     (insert (notmuch-tree-format-field-list (notmuch-tree-result-format) msg))
 941     (notmuch-tree-set-message-properties msg)
 942     (notmuch-tree-set-prop :previous-subject previous-subject)
 943     (insert "\n")))
 944
 945 (defun notmuch-tree-goto-and-insert-msg (msg)
 946   "Insert msg at the end of the buffer. Move point to msg if it is the target."
 947   (save-excursion
 948     (goto-char (point-max))
 949     (notmuch-tree-insert-msg msg))
 950   (let ((msg-id (notmuch-id-to-query (plist-get msg :id)))
 951         (target notmuch-tree-target-msg))
 952     (when (or (and (not target) (plist-get msg :match))
 953               (string= msg-id target))
 954       (setq notmuch-tree-target-msg "found")
 955       (goto-char (point-max))
 956       (forward-line -1)
 957       (when notmuch-tree-open-target
 958         (notmuch-tree-show-message-in)
 959         (notmuch-tree-command-hook)))))
 960
 961 (defun notmuch-tree-insert-tree (tree depth tree-status first last)
 962   "Insert the message tree TREE at depth DEPTH in the current thread.
 963
 964 A message tree is another name for a single sub-thread: i.e., a
 965 message together with all its descendents."
 966   (let ((msg (car tree))
 967         (replies (cadr tree)))
 968     (cond
 969      ((and (< 0 depth) (not last))
 970       (push "├" tree-status))
 971      ((and (< 0 depth) last)
 972       (push "╰" tree-status))
 973      ((and (eq 0 depth) first last)
 974       ;; Choice between these two variants is a matter of taste.
 975       ;; (push "─" tree-status))
 976       (push " " tree-status))
 977      ((and (eq 0 depth) first (not last))
 978       (push "┬" tree-status))
 979      ((and (eq 0 depth) (not first) last)
 980       (push "╰" tree-status))
 981      ((and (eq 0 depth) (not first) (not last))
 982       (push "├" tree-status)))
 983     (push (concat (if replies "┬" "─") "►") tree-status)
 984     (setq msg (plist-put msg :first (and first (eq 0 depth))))
 985     (setq msg (plist-put msg :tree-status tree-status))
 986     (setq msg (plist-put msg :orig-tags (plist-get msg :tags)))
 987     (notmuch-tree-goto-and-insert-msg msg)
 988     (pop tree-status)
 989     (pop tree-status)
 990     (if last
 991         (push " " tree-status)
 992       (push "│" tree-status))
 993     (notmuch-tree-insert-thread replies (1+ depth) tree-status)))
 994
 995 (defun notmuch-tree-insert-thread (thread depth tree-status)
 996   "Insert the collection of sibling sub-threads THREAD at depth DEPTH in the current forest."
 997   (let ((n (length thread)))
 998     (cl-loop for tree in thread
 999              for count from 1 to n
1000              do (notmuch-tree-insert-tree tree depth tree-status
1001                                           (eq count 1)
1002                                           (eq count n)))))
1003
1004 (defun notmuch-tree-insert-forest-thread (forest-thread)
1005   "Insert a single complete thread."
1006   ;; Reset at the start of each main thread.
1007   (setq notmuch-tree-previous-subject nil)
1008   (notmuch-tree-insert-thread forest-thread 0 nil))
1009
1010 (defun notmuch-tree-insert-forest (forest)
1011   "Insert a forest of threads.
1012
1013 This function inserts a collection of several complete threads as
1014 passed to it by notmuch-tree-process-filter."
1015   (mapc 'notmuch-tree-insert-forest-thread forest))
1016
1017 (define-derived-mode notmuch-tree-mode fundamental-mode "notmuch-tree"
1018   "Major mode displaying messages (as opposed to threads) of a notmuch search.
1019
1020 This buffer contains the results of a \"notmuch tree\" of your
1021 email archives. Each line in the buffer represents a single
1022 message giving the relative date, the author, subject, and any
1023 tags.
1024
1025 Pressing \\[notmuch-tree-show-message] on any line displays that message.
1026
1027 Complete list of currently available key bindings:
1028
1029 \\{notmuch-tree-mode-map}"
1030   (setq notmuch-buffer-refresh-function #'notmuch-tree-refresh-view)
1031   (hl-line-mode 1)
1032   (setq buffer-read-only t)
1033   (setq truncate-lines t))
1034
1035 (defun notmuch-tree-process-sentinel (proc _msg)
1036   "Add a message to let user know when \"notmuch tree\" exits."
1037   (let ((buffer (process-buffer proc))
1038         (status (process-status proc))
1039         (exit-status (process-exit-status proc)))
1040     (when (memq status '(exit signal))
1041       (kill-buffer (process-get proc 'parse-buf))
1042       (when (buffer-live-p buffer)
1043         (with-current-buffer buffer
1044           (save-excursion
1045             (let ((inhibit-read-only t))
1046               (goto-char (point-max))
1047               (when (eq status 'signal)
1048                 (insert "Incomplete search results (tree view process was killed).\n"))
1049               (when (eq status 'exit)
1050                 (insert "End of search results.")
1051                 (unless (= exit-status 0)
1052                   (insert (format " (process returned %d)" exit-status)))
1053                 (insert "\n")))))))))
1054
1055 (defun notmuch-tree-process-filter (proc string)
1056   "Process and filter the output of \"notmuch show\" for tree view."
1057   (let ((results-buf (process-buffer proc))
1058         (parse-buf (process-get proc 'parse-buf))
1059         (inhibit-read-only t))
1060     (if (not (buffer-live-p results-buf))
1061         (delete-process proc)
1062       (with-current-buffer parse-buf
1063         ;; Insert new data
1064         (save-excursion
1065           (goto-char (point-max))
1066           (insert string))
1067         (notmuch-sexp-parse-partial-list 'notmuch-tree-insert-forest-thread
1068                                          results-buf)))))
1069
1070 (defun notmuch-tree-worker (basic-query &optional query-context target
1071                                         open-target unthreaded oldest-first)
1072   "Insert the tree view of the search in the current buffer.
1073
1074 This is is a helper function for notmuch-tree. The arguments are
1075 the same as for the function notmuch-tree."
1076   (interactive)
1077   (notmuch-tree-mode)
1078   (add-hook 'post-command-hook #'notmuch-tree-command-hook t t)
1079   (setq notmuch-search-oldest-first oldest-first)
1080   (setq notmuch-tree-unthreaded unthreaded)
1081   (setq notmuch-tree-basic-query basic-query)
1082   (setq notmuch-tree-query-context (if (or (string= query-context "")
1083                                            (string= query-context "*"))
1084                                        nil
1085                                      query-context))
1086   (setq notmuch-tree-target-msg target)
1087   (setq notmuch-tree-open-target open-target)
1088   ;; Set the default value for `notmuch-show-process-crypto' in this
1089   ;; buffer. Although we don't use this some of the functions we call
1090   ;; (such as reply) do. It is a buffer local variable so setting it
1091   ;; will not affect genuine show buffers.
1092   (setq notmuch-show-process-crypto notmuch-crypto-process-mime)
1093   (erase-buffer)
1094   (goto-char (point-min))
1095   (let* ((search-args (concat basic-query
1096                               (and query-context
1097                                    (concat " and (" query-context ")"))))
1098          (sort-arg (if oldest-first "--sort=oldest-first" "--sort=newest-first"))
1099          (message-arg (if unthreaded "--unthreaded" "--entire-thread")))
1100     (when (equal (car (process-lines notmuch-command "count" search-args)) "0")
1101       (setq search-args basic-query))
1102     (notmuch-tag-clear-cache)
1103     (let ((proc (notmuch-start-notmuch
1104                  "notmuch-tree" (current-buffer) #'notmuch-tree-process-sentinel
1105                  "show" "--body=false" "--format=sexp" "--format-version=4"
1106                  sort-arg message-arg search-args))
1107           ;; Use a scratch buffer to accumulate partial output.
1108           ;; This buffer will be killed by the sentinel, which
1109           ;; should be called no matter how the process dies.
1110           (parse-buf (generate-new-buffer " *notmuch tree parse*")))
1111       (process-put proc 'parse-buf parse-buf)
1112       (set-process-filter proc 'notmuch-tree-process-filter)
1113       (set-process-query-on-exit-flag proc nil))))
1114
1115 (defun notmuch-tree-get-query ()
1116   "Return the current query in this tree buffer."
1117   (if notmuch-tree-query-context
1118       (concat notmuch-tree-basic-query
1119               " and ("
1120               notmuch-tree-query-context
1121               ")")
1122     notmuch-tree-basic-query))
1123
1124 (defun notmuch-tree-toggle-order ()
1125   "Toggle the current search order.
1126
1127 This command toggles the sort order for the current search. The
1128 default sort order is defined by `notmuch-search-oldest-first'."
1129   (interactive)
1130   (setq notmuch-search-oldest-first (not notmuch-search-oldest-first))
1131   (notmuch-tree-refresh-view))
1132
1133 (defun notmuch-tree (&optional query query-context target buffer-name
1134                                open-target unthreaded parent-buffer oldest-first)
1135   "Display threads matching QUERY in tree view.
1136
1137 The arguments are:
1138   QUERY: the main query. This can be any query but in many cases will be
1139       a single thread. If nil this is read interactively from the minibuffer.
1140   QUERY-CONTEXT: is an additional term for the query. The query used
1141       is QUERY and QUERY-CONTEXT unless that does not match any messages
1142       in which case we fall back to just QUERY.
1143   TARGET: A message ID (with the id: prefix) that will be made
1144       current if it appears in the tree view results.
1145   BUFFER-NAME: the name of the buffer to display the tree view. If
1146       it is nil \"*notmuch-tree\" followed by QUERY is used.
1147   OPEN-TARGET: If TRUE open the target message in the message pane.
1148   UNTHREADED: If TRUE only show matching messages in an unthreaded view."
1149   (interactive)
1150   (unless query
1151     (setq query (notmuch-read-query (concat "Notmuch "
1152                                             (if unthreaded "unthreaded " "tree ")
1153                                             "view search: "))))
1154   (let ((buffer (get-buffer-create (generate-new-buffer-name
1155                                     (or buffer-name
1156                                         (concat "*notmuch-"
1157                                                 (if unthreaded "unthreaded-" "tree-")
1158                                                 query "*")))))
1159         (inhibit-read-only t))
1160     (pop-to-buffer-same-window buffer))
1161   ;; Don't track undo information for this buffer
1162   (setq buffer-undo-list t)
1163   (notmuch-tree-worker query query-context target open-target unthreaded oldest-first)
1164   (setq notmuch-tree-parent-buffer parent-buffer)
1165   (setq truncate-lines t))
1166
1167 (defun notmuch-unthreaded (&optional query query-context target buffer-name
1168                                      open-target)
1169   (interactive)
1170   (notmuch-tree query query-context target buffer-name open-target t))
1171
1172 (defun notmuch-tree-filter (query)
1173   "Filter or LIMIT the current search results based on an additional query string.
1174
1175 Runs a new tree search matching only messages that match both the
1176 current search results AND the additional query string provided."
1177   (interactive (list (notmuch-read-query "Filter search: ")))
1178   (let ((notmuch-show-process-crypto (notmuch-tree--message-process-crypto))
1179         (grouped-query (notmuch-group-disjunctive-query-string query))
1180         (grouped-original-query (notmuch-group-disjunctive-query-string
1181                                  (notmuch-tree-get-query))))
1182     (notmuch-tree-close-message-window)
1183     (notmuch-tree (if (string= grouped-original-query "*")
1184                       grouped-query
1185                     (concat grouped-original-query " and " grouped-query)))))
1186
1187 ;;; _
1188
1189 (provide 'notmuch-tree)
1190
1191 ;;; notmuch-tree.el ends here