emacs: Use --format-version for search, show, and reply
[notmuch] / emacs / notmuch.el
1 ;; notmuch.el --- run notmuch within emacs
2 ;;
3 ;; Copyright © Carl Worth
4 ;;
5 ;; This file is part of Notmuch.
6 ;;
7 ;; Notmuch is free software: you can redistribute it and/or modify it
8 ;; under the terms of the GNU General Public License as published by
9 ;; the Free Software Foundation, either version 3 of the License, or
10 ;; (at your option) any later version.
11 ;;
12 ;; Notmuch is distributed in the hope that it will be useful, but
13 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
15 ;; General Public License for more details.
16 ;;
17 ;; You should have received a copy of the GNU General Public License
18 ;; along with Notmuch.  If not, see <http://www.gnu.org/licenses/>.
19 ;;
20 ;; Authors: Carl Worth <cworth@cworth.org>
21
22 ;; This is an emacs-based interface to the notmuch mail system.
23 ;;
24 ;; You will first need to have the notmuch program installed and have a
25 ;; notmuch database built in order to use this. See
26 ;; http://notmuchmail.org for details.
27 ;;
28 ;; To install this software, copy it to a directory that is on the
29 ;; `load-path' variable within emacs (a good candidate is
30 ;; /usr/local/share/emacs/site-lisp). If you are viewing this from the
31 ;; notmuch source distribution then you can simply run:
32 ;;
33 ;;      sudo make install-emacs
34 ;;
35 ;; to install it.
36 ;;
37 ;; Then, to actually run it, add:
38 ;;
39 ;;      (require 'notmuch)
40 ;;
41 ;; to your ~/.emacs file, and then run "M-x notmuch" from within emacs,
42 ;; or run:
43 ;;
44 ;;      emacs -f notmuch
45 ;;
46 ;; Have fun, and let us know if you have any comment, questions, or
47 ;; kudos: Notmuch list <notmuch@notmuchmail.org> (subscription is not
48 ;; required, but is available from http://notmuchmail.org).
49
50 (eval-when-compile (require 'cl))
51 (require 'mm-view)
52 (require 'message)
53
54 (require 'notmuch-lib)
55 (require 'notmuch-tag)
56 (require 'notmuch-show)
57 (require 'notmuch-mua)
58 (require 'notmuch-hello)
59 (require 'notmuch-maildir-fcc)
60 (require 'notmuch-message)
61
62 (defcustom notmuch-search-result-format
63   `(("date" . "%12s ")
64     ("count" . "%-7s ")
65     ("authors" . "%-20s ")
66     ("subject" . "%s ")
67     ("tags" . "(%s)"))
68   "Search result formatting. Supported fields are:
69         date, count, authors, subject, tags
70 For example:
71         (setq notmuch-search-result-format \(\(\"authors\" . \"%-40s\"\)
72                                              \(\"subject\" . \"%s\"\)\)\)
73 Line breaks are permitted in format strings (though this is
74 currently experimental).  Note that a line break at the end of an
75 \"authors\" field will get elided if the authors list is long;
76 place it instead at the beginning of the following field.  To
77 enter a line break when setting this variable with setq, use \\n.
78 To enter a line break in customize, press \\[quoted-insert] C-j."
79   :type '(alist :key-type (string) :value-type (string))
80   :group 'notmuch-search)
81
82 (defvar notmuch-query-history nil
83   "Variable to store minibuffer history for notmuch queries")
84
85 (defun notmuch-foreach-mime-part (function mm-handle)
86   (cond ((stringp (car mm-handle))
87          (dolist (part (cdr mm-handle))
88            (notmuch-foreach-mime-part function part)))
89         ((bufferp (car mm-handle))
90          (funcall function mm-handle))
91         (t (dolist (part mm-handle)
92              (notmuch-foreach-mime-part function part)))))
93
94 (defun notmuch-count-attachments (mm-handle)
95   (let ((count 0))
96     (notmuch-foreach-mime-part
97      (lambda (p)
98        (let ((disposition (mm-handle-disposition p)))
99          (and (listp disposition)
100               (or (equal (car disposition) "attachment")
101                   (and (equal (car disposition) "inline")
102                        (assq 'filename disposition)))
103               (incf count))))
104      mm-handle)
105     count))
106
107 (defun notmuch-save-attachments (mm-handle &optional queryp)
108   (notmuch-foreach-mime-part
109    (lambda (p)
110      (let ((disposition (mm-handle-disposition p)))
111        (and (listp disposition)
112             (or (equal (car disposition) "attachment")
113                 (and (equal (car disposition) "inline")
114                      (assq 'filename disposition)))
115             (or (not queryp)
116                 (y-or-n-p
117                  (concat "Save '" (cdr (assq 'filename disposition)) "' ")))
118             (mm-save-part p))))
119    mm-handle))
120
121 (defun notmuch-documentation-first-line (symbol)
122   "Return the first line of the documentation string for SYMBOL."
123   (let ((doc (documentation symbol)))
124     (if doc
125         (with-temp-buffer
126           (insert (documentation symbol t))
127           (goto-char (point-min))
128           (let ((beg (point)))
129             (end-of-line)
130             (buffer-substring beg (point))))
131       "")))
132
133 (defun notmuch-prefix-key-description (key)
134   "Given a prefix key code, return a human-readable string representation.
135
136 This is basically just `format-kbd-macro' but we also convert ESC to M-."
137   (let ((desc (format-kbd-macro (vector key))))
138     (if (string= desc "ESC")
139         "M-"
140       (concat desc " "))))
141
142 ;; I would think that emacs would have code handy for walking a keymap
143 ;; and generating strings for each key, and I would prefer to just call
144 ;; that. But I couldn't find any (could be all implemented in C I
145 ;; suppose), so I wrote my own here.
146 (defun notmuch-substitute-one-command-key-with-prefix (prefix binding)
147   "For a key binding, return a string showing a human-readable
148 representation of the prefixed key as well as the first line of
149 documentation from the bound function.
150
151 For a mouse binding, return nil."
152   (let ((key (car binding))
153         (action (cdr binding)))
154     (if (mouse-event-p key)
155         nil
156       (if (keymapp action)
157           (let ((substitute (apply-partially 'notmuch-substitute-one-command-key-with-prefix (notmuch-prefix-key-description key)))
158                 (as-list))
159             (map-keymap (lambda (a b)
160                           (push (cons a b) as-list))
161                         action)
162             (mapconcat substitute as-list "\n"))
163         (concat prefix (format-kbd-macro (vector key))
164                 "\t"
165                 (notmuch-documentation-first-line action))))))
166
167 (defun notmuch-substitute-command-keys-one (key)
168   ;; A `keymap' key indicates inheritance from a parent keymap - the
169   ;; inherited mappings follow, so there is nothing to print for
170   ;; `keymap' itself.
171   (when (not (eq key 'keymap))
172     (notmuch-substitute-one-command-key-with-prefix nil key)))
173
174 (defun notmuch-substitute-command-keys (doc)
175   "Like `substitute-command-keys' but with documentation, not function names."
176   (let ((beg 0))
177     (while (string-match "\\\\{\\([^}[:space:]]*\\)}" doc beg)
178       (let* ((keymap-name (substring doc (match-beginning 1) (match-end 1)))
179              (keymap (symbol-value (intern keymap-name))))
180         (setq doc (replace-match
181                    (mapconcat #'notmuch-substitute-command-keys-one
182                               (cdr keymap) "\n")
183                    1 1 doc)))
184       (setq beg (match-end 0)))
185     doc))
186
187 (defun notmuch-help ()
188   "Display help for the current notmuch mode."
189   (interactive)
190   (let* ((mode major-mode)
191          (doc (substitute-command-keys (notmuch-substitute-command-keys (documentation mode t)))))
192     (with-current-buffer (generate-new-buffer "*notmuch-help*")
193       (insert doc)
194       (goto-char (point-min))
195       (set-buffer-modified-p nil)
196       (view-buffer (current-buffer) 'kill-buffer-if-not-modified))))
197
198 (require 'hl-line)
199
200 (defun notmuch-hl-line-mode ()
201   (prog1 (hl-line-mode)
202     (when hl-line-overlay
203       (overlay-put hl-line-overlay 'priority 1))))
204
205 (defcustom notmuch-search-hook '(notmuch-hl-line-mode)
206   "List of functions to call when notmuch displays the search results."
207   :type 'hook
208   :options '(notmuch-hl-line-mode)
209   :group 'notmuch-search
210   :group 'notmuch-hooks)
211
212 (defvar notmuch-search-mode-map
213   (let ((map (make-sparse-keymap)))
214     (define-key map "?" 'notmuch-help)
215     (define-key map "q" 'notmuch-search-quit)
216     (define-key map "x" 'notmuch-search-quit)
217     (define-key map (kbd "<DEL>") 'notmuch-search-scroll-down)
218     (define-key map "b" 'notmuch-search-scroll-down)
219     (define-key map " " 'notmuch-search-scroll-up)
220     (define-key map "<" 'notmuch-search-first-thread)
221     (define-key map ">" 'notmuch-search-last-thread)
222     (define-key map "p" 'notmuch-search-previous-thread)
223     (define-key map "n" 'notmuch-search-next-thread)
224     (define-key map "r" 'notmuch-search-reply-to-thread-sender)
225     (define-key map "R" 'notmuch-search-reply-to-thread)
226     (define-key map "m" 'notmuch-mua-new-mail)
227     (define-key map "s" 'notmuch-search)
228     (define-key map "o" 'notmuch-search-toggle-order)
229     (define-key map "c" 'notmuch-search-stash-map)
230     (define-key map "=" 'notmuch-search-refresh-view)
231     (define-key map "G" 'notmuch-search-poll-and-refresh-view)
232     (define-key map "t" 'notmuch-search-filter-by-tag)
233     (define-key map "f" 'notmuch-search-filter)
234     (define-key map [mouse-1] 'notmuch-search-show-thread)
235     (define-key map "*" 'notmuch-search-tag-all)
236     (define-key map "a" 'notmuch-search-archive-thread)
237     (define-key map "-" 'notmuch-search-remove-tag)
238     (define-key map "+" 'notmuch-search-add-tag)
239     (define-key map (kbd "RET") 'notmuch-search-show-thread)
240     map)
241   "Keymap for \"notmuch search\" buffers.")
242 (fset 'notmuch-search-mode-map notmuch-search-mode-map)
243
244 (defvar notmuch-search-stash-map
245   (let ((map (make-sparse-keymap)))
246     (define-key map "i" 'notmuch-search-stash-thread-id)
247     map)
248   "Submap for stash commands")
249 (fset 'notmuch-search-stash-map notmuch-search-stash-map)
250
251 (defun notmuch-search-stash-thread-id ()
252   "Copy thread ID of current thread to kill-ring."
253   (interactive)
254   (notmuch-common-do-stash (notmuch-search-find-thread-id)))
255
256 (defvar notmuch-search-query-string)
257 (defvar notmuch-search-target-thread)
258 (defvar notmuch-search-target-line)
259 (defvar notmuch-search-continuation)
260
261 (defvar notmuch-search-disjunctive-regexp      "\\<[oO][rR]\\>")
262
263 (defun notmuch-search-quit ()
264   "Exit the search buffer, calling any defined continuation function."
265   (interactive)
266   (let ((continuation notmuch-search-continuation))
267     (notmuch-kill-this-buffer)
268     (when continuation
269       (funcall continuation))))
270
271 (defun notmuch-search-scroll-up ()
272   "Move forward through search results by one window's worth."
273   (interactive)
274   (condition-case nil
275       (scroll-up nil)
276     ((end-of-buffer) (notmuch-search-last-thread))))
277
278 (defun notmuch-search-scroll-down ()
279   "Move backward through the search results by one window's worth."
280   (interactive)
281   ;; I don't know why scroll-down doesn't signal beginning-of-buffer
282   ;; the way that scroll-up signals end-of-buffer, but c'est la vie.
283   ;;
284   ;; So instead of trapping a signal we instead check whether the
285   ;; window begins on the first line of the buffer and if so, move
286   ;; directly to that position. (We have to count lines since the
287   ;; window-start position is not the same as point-min due to the
288   ;; invisible thread-ID characters on the first line.
289   (if (equal (count-lines (point-min) (window-start)) 0)
290       (goto-char (point-min))
291     (scroll-down nil)))
292
293 (defun notmuch-search-next-thread ()
294   "Select the next thread in the search results."
295   (interactive)
296   (when (notmuch-search-get-result)
297     (goto-char (notmuch-search-result-end))))
298
299 (defun notmuch-search-previous-thread ()
300   "Select the previous thread in the search results."
301   (interactive)
302   (if (notmuch-search-get-result)
303       (unless (bobp)
304         (goto-char (notmuch-search-result-beginning (- (point) 1))))
305     ;; We must be past the end; jump to the last result
306     (notmuch-search-last-thread)))
307
308 (defun notmuch-search-last-thread ()
309   "Select the last thread in the search results."
310   (interactive)
311   (goto-char (point-max))
312   (forward-line -2)
313   (let ((beg (notmuch-search-result-beginning)))
314     (when beg (goto-char beg))))
315
316 (defun notmuch-search-first-thread ()
317   "Select the first thread in the search results."
318   (interactive)
319   (goto-char (point-min)))
320
321 (defface notmuch-message-summary-face
322  '((((class color) (background light)) (:background "#f0f0f0"))
323    (((class color) (background dark)) (:background "#303030")))
324  "Face for the single-line message summary in notmuch-show-mode."
325  :group 'notmuch-show
326  :group 'notmuch-faces)
327
328 (defface notmuch-search-date
329   '((t :inherit default))
330   "Face used in search mode for dates."
331   :group 'notmuch-search
332   :group 'notmuch-faces)
333
334 (defface notmuch-search-count
335   '((t :inherit default))
336   "Face used in search mode for the count matching the query."
337   :group 'notmuch-search
338   :group 'notmuch-faces)
339
340 (defface notmuch-search-subject
341   '((t :inherit default))
342   "Face used in search mode for subjects."
343   :group 'notmuch-search
344   :group 'notmuch-faces)
345
346 (defface notmuch-search-matching-authors
347   '((t :inherit default))
348   "Face used in search mode for authors matching the query."
349   :group 'notmuch-search
350   :group 'notmuch-faces)
351
352 (defface notmuch-search-non-matching-authors
353   '((((class color)
354       (background dark))
355      (:foreground "grey30"))
356     (((class color)
357       (background light))
358      (:foreground "grey60"))
359     (t
360      (:italic t)))
361   "Face used in search mode for authors not matching the query."
362   :group 'notmuch-search
363   :group 'notmuch-faces)
364
365 (defface notmuch-tag-face
366   '((((class color)
367       (background dark))
368      (:foreground "OliveDrab1"))
369     (((class color)
370       (background light))
371      (:foreground "navy blue" :bold t))
372     (t
373      (:bold t)))
374   "Face used in search mode face for tags."
375   :group 'notmuch-search
376   :group 'notmuch-faces)
377
378 (defun notmuch-search-mode ()
379   "Major mode displaying results of a notmuch search.
380
381 This buffer contains the results of a \"notmuch search\" of your
382 email archives. Each line in the buffer represents a single
383 thread giving a summary of the thread (a relative date, the
384 number of matched messages and total messages in the thread,
385 participants in the thread, a representative subject line, and
386 any tags).
387
388 Pressing \\[notmuch-search-show-thread] on any line displays that thread. The '\\[notmuch-search-add-tag]' and '\\[notmuch-search-remove-tag]'
389 keys can be used to add or remove tags from a thread. The '\\[notmuch-search-archive-thread]' key
390 is a convenience for archiving a thread (removing the \"inbox\"
391 tag). The '\\[notmuch-search-tag-all]' key can be used to add and/or remove tags from all
392 messages (as opposed to threads) that match the current query.  Use with caution, as this
393 will also tag matching messages that arrived *after* constructing the buffer.
394
395 Other useful commands are '\\[notmuch-search-filter]' for filtering the current search
396 based on an additional query string, '\\[notmuch-search-filter-by-tag]' for filtering to include
397 only messages with a given tag, and '\\[notmuch-search]' to execute a new, global
398 search.
399
400 Complete list of currently available key bindings:
401
402 \\{notmuch-search-mode-map}"
403   (interactive)
404   (kill-all-local-variables)
405   (make-local-variable 'notmuch-search-query-string)
406   (make-local-variable 'notmuch-search-oldest-first)
407   (make-local-variable 'notmuch-search-target-thread)
408   (make-local-variable 'notmuch-search-target-line)
409   (set (make-local-variable 'notmuch-search-continuation) nil)
410   (set (make-local-variable 'scroll-preserve-screen-position) t)
411   (add-to-invisibility-spec (cons 'ellipsis t))
412   (use-local-map notmuch-search-mode-map)
413   (setq truncate-lines t)
414   (setq major-mode 'notmuch-search-mode
415         mode-name "notmuch-search")
416   (setq buffer-read-only t))
417
418 (defun notmuch-search-get-result (&optional pos)
419   "Return the result object for the thread at POS (or point).
420
421 If there is no thread at POS (or point), returns nil."
422   (get-text-property (or pos (point)) 'notmuch-search-result))
423
424 (defun notmuch-search-result-beginning (&optional pos)
425   "Return the point at the beginning of the thread at POS (or point).
426
427 If there is no thread at POS (or point), returns nil."
428   (when (notmuch-search-get-result pos)
429     ;; We pass 1+point because previous-single-property-change starts
430     ;; searching one before the position we give it.
431     (previous-single-property-change (1+ (or pos (point)))
432                                      'notmuch-search-result nil (point-min))))
433
434 (defun notmuch-search-result-end (&optional pos)
435   "Return the point at the end of the thread at POS (or point).
436
437 The returned point will be just after the newline character that
438 ends the result line.  If there is no thread at POS (or point),
439 returns nil"
440   (when (notmuch-search-get-result pos)
441     (next-single-property-change (or pos (point)) 'notmuch-search-result
442                                  nil (point-max))))
443
444 (defun notmuch-search-foreach-result (beg end function)
445   "Invoke FUNCTION for each result between BEG and END.
446
447 FUNCTION should take one argument.  It will be applied to the
448 character position of the beginning of each result that overlaps
449 the region between points BEG and END.  As a special case, if (=
450 BEG END), FUNCTION will be applied to the result containing point
451 BEG."
452
453   (lexical-let ((pos (notmuch-search-result-beginning beg))
454                 ;; End must be a marker in case function changes the
455                 ;; text.
456                 (end (copy-marker end))
457                 ;; Make sure we examine at least one result, even if
458                 ;; (= beg end).
459                 (first t))
460     ;; We have to be careful if the region extends beyond the results.
461     ;; In this case, pos could be null or there could be no result at
462     ;; pos.
463     (while (and pos (or (< pos end) first))
464       (when (notmuch-search-get-result pos)
465         (funcall function pos))
466       (setq pos (notmuch-search-result-end pos)
467             first nil))))
468 ;; Unindent the function argument of notmuch-search-foreach-result so
469 ;; the indentation of callers doesn't get out of hand.
470 (put 'notmuch-search-foreach-result 'lisp-indent-function 2)
471
472 (defun notmuch-search-properties-in-region (property beg end)
473   (let (output)
474     (notmuch-search-foreach-result beg end
475       (lambda (pos)
476         (push (plist-get (notmuch-search-get-result pos) property) output)))
477     output))
478
479 (defun notmuch-search-find-thread-id (&optional bare)
480   "Return the thread for the current thread
481
482 If BARE is set then do not prefix with \"thread:\""
483   (let ((thread (plist-get (notmuch-search-get-result) :thread)))
484     (when thread (concat (unless bare "thread:") thread))))
485
486 (defun notmuch-search-find-thread-id-region (beg end)
487   "Return a list of threads for the current region"
488   (mapcar (lambda (thread) (concat "thread:" thread))
489           (notmuch-search-properties-in-region :thread beg end)))
490
491 (defun notmuch-search-find-thread-id-region-search (beg end)
492   "Return a search string for threads for the current region"
493   (mapconcat 'identity (notmuch-search-find-thread-id-region beg end) " or "))
494
495 (defun notmuch-search-find-authors ()
496   "Return the authors for the current thread"
497   (plist-get (notmuch-search-get-result) :authors))
498
499 (defun notmuch-search-find-authors-region (beg end)
500   "Return a list of authors for the current region"
501   (notmuch-search-properties-in-region :authors beg end))
502
503 (defun notmuch-search-find-subject ()
504   "Return the subject for the current thread"
505   (plist-get (notmuch-search-get-result) :subject))
506
507 (defun notmuch-search-find-subject-region (beg end)
508   "Return a list of authors for the current region"
509   (notmuch-search-properties-in-region :subject beg end))
510
511 (defun notmuch-search-show-thread ()
512   "Display the currently selected thread."
513   (interactive)
514   (let ((thread-id (notmuch-search-find-thread-id))
515         (subject (notmuch-search-find-subject)))
516     (if (> (length thread-id) 0)
517         (notmuch-show thread-id
518                       (current-buffer)
519                       notmuch-search-query-string
520                       ;; Name the buffer based on the subject.
521                       (concat "*" (truncate-string-to-width subject 30 nil nil t) "*"))
522       (message "End of search results."))))
523
524 (defun notmuch-search-reply-to-thread (&optional prompt-for-sender)
525   "Begin composing a reply-all to the entire current thread in a new buffer."
526   (interactive "P")
527   (let ((message-id (notmuch-search-find-thread-id)))
528     (notmuch-mua-new-reply message-id prompt-for-sender t)))
529
530 (defun notmuch-search-reply-to-thread-sender (&optional prompt-for-sender)
531   "Begin composing a reply to the entire current thread in a new buffer."
532   (interactive "P")
533   (let ((message-id (notmuch-search-find-thread-id)))
534     (notmuch-mua-new-reply message-id prompt-for-sender nil)))
535
536 (defun notmuch-call-notmuch-process (&rest args)
537   "Synchronously invoke \"notmuch\" with the given list of arguments.
538
539 If notmuch exits with a non-zero status, output from the process
540 will appear in a buffer named \"*Notmuch errors*\" and an error
541 will be signaled."
542   (with-temp-buffer
543     (let ((status (apply #'call-process notmuch-command nil t nil args)))
544       (notmuch-check-exit-status status (cons notmuch-command args)
545                                  (buffer-string)))))
546
547 (defun notmuch-search-set-tags (tags &optional pos)
548   (let ((new-result (plist-put (notmuch-search-get-result pos) :tags tags)))
549     (notmuch-search-update-result new-result pos)))
550
551 (defun notmuch-search-get-tags (&optional pos)
552   (plist-get (notmuch-search-get-result pos) :tags))
553
554 (defun notmuch-search-get-tags-region (beg end)
555   (let (output)
556     (notmuch-search-foreach-result beg end
557       (lambda (pos)
558         (setq output (append output (notmuch-search-get-tags pos)))))
559     output))
560
561 (defun notmuch-search-tag-region (beg end &optional tag-changes)
562   "Change tags for threads in the given region."
563   (let ((search-string (notmuch-search-find-thread-id-region-search beg end)))
564     (setq tag-changes (funcall 'notmuch-tag search-string tag-changes))
565     (notmuch-search-foreach-result beg end
566       (lambda (pos)
567         (notmuch-search-set-tags
568          (notmuch-update-tags (notmuch-search-get-tags pos) tag-changes)
569          pos)))))
570
571 (defun notmuch-search-tag (&optional tag-changes)
572   "Change tags for the currently selected thread or region.
573
574 See `notmuch-tag' for information on the format of TAG-CHANGES."
575   (interactive)
576   (let* ((beg (if (region-active-p) (region-beginning) (point)))
577          (end (if (region-active-p) (region-end) (point))))
578     (funcall 'notmuch-search-tag-region beg end tag-changes)))
579
580 (defun notmuch-search-add-tag ()
581   "Same as `notmuch-search-tag' but sets initial input to '+'."
582   (interactive)
583   (notmuch-search-tag "+"))
584
585 (defun notmuch-search-remove-tag ()
586   "Same as `notmuch-search-tag' but sets initial input to '-'."
587   (interactive)
588   (notmuch-search-tag "-"))
589
590 (defun notmuch-search-archive-thread (&optional unarchive)
591   "Archive the currently selected thread.
592
593 Archive each message in the currently selected thread by applying
594 the tag changes in `notmuch-archive-tags' to each (remove the
595 \"inbox\" tag by default). If a prefix argument is given, the
596 messages will be \"unarchived\" (i.e. the tag changes in
597 `notmuch-archive-tags' will be reversed).
598
599 This function advances the next thread when finished."
600   (interactive "P")
601   (when notmuch-archive-tags
602     (notmuch-search-tag
603      (notmuch-tag-change-list notmuch-archive-tags unarchive)))
604   (notmuch-search-next-thread))
605
606 (defun notmuch-search-update-result (result &optional pos)
607   "Replace the result object of the thread at POS (or point) by
608 RESULT and redraw it.
609
610 This will keep point in a reasonable location.  However, if there
611 are enclosing save-excursions and the saved point is in the
612 result being updated, the point will be restored to the beginning
613 of the result."
614   (let ((start (notmuch-search-result-beginning pos))
615         (end (notmuch-search-result-end pos))
616         (init-point (point))
617         (inhibit-read-only t))
618     ;; Delete the current thread
619     (delete-region start end)
620     ;; Insert the updated thread
621     (notmuch-search-show-result result start)
622     ;; If point was inside the old result, make an educated guess
623     ;; about where to place it now.  Unfortunately, this won't work
624     ;; with save-excursion (or any other markers that would be nice to
625     ;; preserve, such as the window start), but there's nothing we can
626     ;; do about that without a way to retrieve markers in a region.
627     (when (and (>= init-point start) (<= init-point end))
628       (let* ((new-end (notmuch-search-result-end start))
629              (new-point (if (= init-point end)
630                             new-end
631                           (min init-point (- new-end 1)))))
632         (goto-char new-point)))))
633
634 (defun notmuch-search-process-sentinel (proc msg)
635   "Add a message to let user know when \"notmuch search\" exits"
636   (let ((buffer (process-buffer proc))
637         (status (process-status proc))
638         (exit-status (process-exit-status proc))
639         (never-found-target-thread nil))
640     (when (memq status '(exit signal))
641       (catch 'return
642         (kill-buffer (process-get proc 'parse-buf))
643         (if (buffer-live-p buffer)
644             (with-current-buffer buffer
645               (save-excursion
646                 (let ((inhibit-read-only t)
647                       (atbob (bobp)))
648                   (goto-char (point-max))
649                   (if (eq status 'signal)
650                       (insert "Incomplete search results (search process was killed).\n"))
651                   (when (eq status 'exit)
652                     (insert "End of search results.\n")
653                     ;; For version mismatch, there's no point in
654                     ;; showing the search buffer
655                     (when (or (= exit-status 20) (= exit-status 21))
656                       (kill-buffer))
657                     (condition-case nil
658                         (notmuch-check-async-exit-status proc msg)
659                       ;; Suppress the error signal since strange
660                       ;; things happen if a sentinel signals.
661                       (error (throw 'return nil)))
662                     (if (and atbob
663                              (not (string= notmuch-search-target-thread "found")))
664                         (set 'never-found-target-thread t)))))
665               (when (and never-found-target-thread
666                        notmuch-search-target-line)
667                   (goto-char (point-min))
668                   (forward-line (1- notmuch-search-target-line)))))))))
669
670 (defcustom notmuch-search-line-faces '(("unread" :weight bold)
671                                        ("flagged" :foreground "blue"))
672   "Tag/face mapping for line highlighting in notmuch-search.
673
674 Here is an example of how to color search results based on tags.
675  (the following text would be placed in your ~/.emacs file):
676
677  (setq notmuch-search-line-faces '((\"deleted\" . (:foreground \"red\"
678                                                   :background \"blue\"))
679                                    (\"unread\" . (:foreground \"green\"))))
680
681 The attributes defined for matching tags are merged, with later
682 attributes overriding earlier. A message having both \"deleted\"
683 and \"unread\" tags with the above settings would have a green
684 foreground and blue background."
685   :type '(alist :key-type (string) :value-type (custom-face-edit))
686   :group 'notmuch-search
687   :group 'notmuch-faces)
688
689 (defun notmuch-search-color-line (start end line-tag-list)
690   "Colorize lines in `notmuch-show' based on tags."
691   (mapc (lambda (elem)
692           (let ((tag (car elem))
693                 (attributes (cdr elem)))
694             (when (member tag line-tag-list)
695               (notmuch-combine-face-text-property start end attributes))))
696         ;; Reverse the list so earlier entries take precedence
697         (reverse notmuch-search-line-faces)))
698
699 (defun notmuch-search-author-propertize (authors)
700   "Split `authors' into matching and non-matching authors and
701 propertize appropriately. If no boundary between authors and
702 non-authors is found, assume that all of the authors match."
703   (if (string-match "\\(.*\\)|\\(.*\\)" authors)
704       (concat (propertize (concat (match-string 1 authors) ",")
705                           'face 'notmuch-search-matching-authors)
706               (propertize (match-string 2 authors)
707                           'face 'notmuch-search-non-matching-authors))
708     (propertize authors 'face 'notmuch-search-matching-authors)))
709
710 (defun notmuch-search-insert-authors (format-string authors)
711   ;; Save the match data to avoid interfering with
712   ;; `notmuch-search-process-filter'.
713   (save-match-data
714     (let* ((formatted-authors (format format-string authors))
715            (formatted-sample (format format-string ""))
716            (visible-string formatted-authors)
717            (invisible-string "")
718            (padding ""))
719
720       ;; Truncate the author string to fit the specification.
721       (if (> (length formatted-authors)
722              (length formatted-sample))
723           (let ((visible-length (- (length formatted-sample)
724                                    (length "... "))))
725             ;; Truncate the visible string according to the width of
726             ;; the display string.
727             (setq visible-string (substring formatted-authors 0 visible-length)
728                   invisible-string (substring formatted-authors visible-length))
729             ;; If possible, truncate the visible string at a natural
730             ;; break (comma or pipe), as incremental search doesn't
731             ;; match across the visible/invisible border.
732             (when (string-match "\\(.*\\)\\([,|] \\)\\([^,|]*\\)" visible-string)
733               ;; Second clause is destructive on `visible-string', so
734               ;; order is important.
735               (setq invisible-string (concat (match-string 3 visible-string)
736                                              invisible-string)
737                     visible-string (concat (match-string 1 visible-string)
738                                            (match-string 2 visible-string))))
739             ;; `visible-string' may be shorter than the space allowed
740             ;; by `format-string'. If so we must insert some padding
741             ;; after `invisible-string'.
742             (setq padding (make-string (- (length formatted-sample)
743                                           (length visible-string)
744                                           (length "..."))
745                                        ? ))))
746
747       ;; Use different faces to show matching and non-matching authors.
748       (if (string-match "\\(.*\\)|\\(.*\\)" visible-string)
749           ;; The visible string contains both matching and
750           ;; non-matching authors.
751           (setq visible-string (notmuch-search-author-propertize visible-string)
752                 ;; The invisible string must contain only non-matching
753                 ;; authors, as the visible-string contains both.
754                 invisible-string (propertize invisible-string
755                                              'face 'notmuch-search-non-matching-authors))
756         ;; The visible string contains only matching authors.
757         (setq visible-string (propertize visible-string
758                                          'face 'notmuch-search-matching-authors)
759               ;; The invisible string may contain both matching and
760               ;; non-matching authors.
761               invisible-string (notmuch-search-author-propertize invisible-string)))
762
763       ;; If there is any invisible text, add it as a tooltip to the
764       ;; visible text.
765       (when (not (string= invisible-string ""))
766         (setq visible-string (propertize visible-string 'help-echo (concat "..." invisible-string))))
767
768       ;; Insert the visible and, if present, invisible author strings.
769       (insert visible-string)
770       (when (not (string= invisible-string ""))
771         (let ((start (point))
772               overlay)
773           (insert invisible-string)
774           (setq overlay (make-overlay start (point)))
775           (overlay-put overlay 'invisible 'ellipsis)
776           (overlay-put overlay 'isearch-open-invisible #'delete-overlay)))
777       (insert padding))))
778
779 (defun notmuch-search-insert-field (field format-string result)
780   (cond
781    ((string-equal field "date")
782     (insert (propertize (format format-string (plist-get result :date_relative))
783                         'face 'notmuch-search-date)))
784    ((string-equal field "count")
785     (insert (propertize (format format-string
786                                 (format "[%s/%s]" (plist-get result :matched)
787                                         (plist-get result :total)))
788                         'face 'notmuch-search-count)))
789    ((string-equal field "subject")
790     (insert (propertize (format format-string (plist-get result :subject))
791                         'face 'notmuch-search-subject)))
792
793    ((string-equal field "authors")
794     (notmuch-search-insert-authors format-string (plist-get result :authors)))
795
796    ((string-equal field "tags")
797     (let ((tags-str (mapconcat 'identity (plist-get result :tags) " ")))
798       (insert (propertize (format format-string tags-str)
799                           'face 'notmuch-tag-face))))))
800
801 (defun notmuch-search-show-result (result &optional pos)
802   "Insert RESULT at POS or the end of the buffer if POS is null."
803   ;; Ignore excluded matches
804   (unless (= (plist-get result :matched) 0)
805     (let ((beg (or pos (point-max))))
806       (save-excursion
807         (goto-char beg)
808         (dolist (spec notmuch-search-result-format)
809           (notmuch-search-insert-field (car spec) (cdr spec) result))
810         (insert "\n")
811         (notmuch-search-color-line beg (point) (plist-get result :tags))
812         (put-text-property beg (point) 'notmuch-search-result result))
813       (when (string= (plist-get result :thread) notmuch-search-target-thread)
814         (setq notmuch-search-target-thread "found")
815         (goto-char beg)))))
816
817 (defun notmuch-search-show-error (string &rest objects)
818   (save-excursion
819     (goto-char (point-max))
820     (insert "Error: Unexpected output from notmuch search:\n")
821     (insert (apply #'format string objects))
822     (insert "\n")))
823
824 (defun notmuch-search-process-filter (proc string)
825   "Process and filter the output of \"notmuch search\""
826   (let ((results-buf (process-buffer proc))
827         (parse-buf (process-get proc 'parse-buf))
828         (inhibit-read-only t)
829         done)
830     (if (not (buffer-live-p results-buf))
831         (delete-process proc)
832       (with-current-buffer parse-buf
833         ;; Insert new data
834         (save-excursion
835           (goto-char (point-max))
836           (insert string))
837         (notmuch-json-parse-partial-list 'notmuch-search-show-result
838                                          'notmuch-search-show-error
839                                          results-buf)))))
840
841 (defun notmuch-search-tag-all (&optional tag-changes)
842   "Add/remove tags from all messages in current search buffer.
843
844 See `notmuch-tag' for information on the format of TAG-CHANGES."
845   (interactive)
846   (apply 'notmuch-tag notmuch-search-query-string tag-changes))
847
848 (defun notmuch-search-buffer-title (query)
849   "Returns the title for a buffer with notmuch search results."
850   (let* ((saved-search
851           (let (longest
852                 (longest-length 0))
853             (loop for tuple in notmuch-saved-searches
854                   if (let ((quoted-query (regexp-quote (cdr tuple))))
855                        (and (string-match (concat "^" quoted-query) query)
856                             (> (length (match-string 0 query))
857                                longest-length)))
858                   do (setq longest tuple))
859             longest))
860          (saved-search-name (car saved-search))
861          (saved-search-query (cdr saved-search)))
862     (cond ((and saved-search (equal saved-search-query query))
863            ;; Query is the same as saved search (ignoring case)
864            (concat "*notmuch-saved-search-" saved-search-name "*"))
865           (saved-search
866            (concat "*notmuch-search-"
867                    (replace-regexp-in-string (concat "^" (regexp-quote saved-search-query))
868                                              (concat "[ " saved-search-name " ]")
869                                              query)
870                    "*"))
871           (t
872            (concat "*notmuch-search-" query "*"))
873           )))
874
875 (defun notmuch-read-query (prompt)
876   "Read a notmuch-query from the minibuffer with completion.
877
878 PROMPT is the string to prompt with."
879   (lexical-let
880       ((completions
881         (append (list "folder:" "thread:" "id:" "date:" "from:" "to:"
882                       "subject:" "attachment:")
883                 (mapcar (lambda (tag)
884                           (concat "tag:" (notmuch-escape-boolean-term tag)))
885                         (process-lines notmuch-command "search" "--output=tags" "*")))))
886     (let ((keymap (copy-keymap minibuffer-local-map))
887           (minibuffer-completion-table
888            (completion-table-dynamic
889             (lambda (string)
890               ;; generate a list of possible completions for the current input
891               (cond
892                ;; this ugly regexp is used to get the last word of the input
893                ;; possibly preceded by a '('
894                ((string-match "\\(^\\|.* (?\\)\\([^ ]*\\)$" string)
895                 (mapcar (lambda (compl)
896                           (concat (match-string-no-properties 1 string) compl))
897                         (all-completions (match-string-no-properties 2 string)
898                                          completions)))
899                (t (list string)))))))
900       ;; this was simpler than convincing completing-read to accept spaces:
901       (define-key keymap (kbd "TAB") 'minibuffer-complete)
902       (let ((history-delete-duplicates t))
903         (read-from-minibuffer prompt nil keymap nil
904                               'notmuch-search-history nil nil)))))
905
906 ;;;###autoload
907 (defun notmuch-search (&optional query oldest-first target-thread target-line continuation)
908   "Run \"notmuch search\" with the given `query' and display results.
909
910 If `query' is nil, it is read interactively from the minibuffer.
911 Other optional parameters are used as follows:
912
913   oldest-first: A Boolean controlling the sort order of returned threads
914   target-thread: A thread ID (without the thread: prefix) that will be made
915                  current if it appears in the search results.
916   target-line: The line number to move to if the target thread does not
917                appear in the search results."
918   (interactive)
919   (if (null query)
920       (setq query (notmuch-read-query "Notmuch search: ")))
921   (let ((buffer (get-buffer-create (notmuch-search-buffer-title query))))
922     (switch-to-buffer buffer)
923     (notmuch-search-mode)
924     ;; Don't track undo information for this buffer
925     (set 'buffer-undo-list t)
926     (set 'notmuch-search-query-string query)
927     (set 'notmuch-search-oldest-first oldest-first)
928     (set 'notmuch-search-target-thread target-thread)
929     (set 'notmuch-search-target-line target-line)
930     (set 'notmuch-search-continuation continuation)
931     (let ((proc (get-buffer-process (current-buffer)))
932           (inhibit-read-only t))
933       (if proc
934           (error "notmuch search process already running for query `%s'" query)
935         )
936       (erase-buffer)
937       (goto-char (point-min))
938       (save-excursion
939         (let ((proc (start-process
940                      "notmuch-search" buffer
941                      notmuch-command "search"
942                      "--format=json" "--format-version=1"
943                      (if oldest-first
944                          "--sort=oldest-first"
945                        "--sort=newest-first")
946                      query))
947               ;; Use a scratch buffer to accumulate partial output.
948               ;; This buffer will be killed by the sentinel, which
949               ;; should be called no matter how the process dies.
950               (parse-buf (generate-new-buffer " *notmuch search parse*")))
951           (process-put proc 'parse-buf parse-buf)
952           (set-process-sentinel proc 'notmuch-search-process-sentinel)
953           (set-process-filter proc 'notmuch-search-process-filter)
954           (set-process-query-on-exit-flag proc nil))))
955     (run-hooks 'notmuch-search-hook)))
956
957 (defun notmuch-search-refresh-view ()
958   "Refresh the current view.
959
960 Kills the current buffer and runs a new search with the same
961 query string as the current search. If the current thread is in
962 the new search results, then point will be placed on the same
963 thread. Otherwise, point will be moved to attempt to be in the
964 same relative position within the new buffer."
965   (interactive)
966   (let ((target-line (line-number-at-pos))
967         (oldest-first notmuch-search-oldest-first)
968         (target-thread (notmuch-search-find-thread-id 'bare))
969         (query notmuch-search-query-string)
970         (continuation notmuch-search-continuation))
971     (notmuch-kill-this-buffer)
972     (notmuch-search query oldest-first target-thread target-line continuation)
973     (goto-char (point-min))))
974
975 (defcustom notmuch-poll-script nil
976   "An external script to incorporate new mail into the notmuch database.
977
978 This variable controls the action invoked by
979 `notmuch-search-poll-and-refresh-view' and
980 `notmuch-hello-poll-and-update' (each have a default keybinding
981 of 'G') to incorporate new mail into the notmuch database.
982
983 If set to nil (the default), new mail is processed by invoking
984 \"notmuch new\". Otherwise, this should be set to a string that
985 gives the name of an external script that processes new mail. If
986 set to the empty string, no command will be run.
987
988 The external script could do any of the following depending on
989 the user's needs:
990
991 1. Invoke a program to transfer mail to the local mail store
992 2. Invoke \"notmuch new\" to incorporate the new mail
993 3. Invoke one or more \"notmuch tag\" commands to classify the mail
994
995 Note that the recommended way of achieving the same is using
996 \"notmuch new\" hooks."
997   :type '(choice (const :tag "notmuch new" nil)
998                  (const :tag "Disabled" "")
999                  (string :tag "Custom script"))
1000   :group 'notmuch-external)
1001
1002 (defun notmuch-poll ()
1003   "Run \"notmuch new\" or an external script to import mail.
1004
1005 Invokes `notmuch-poll-script', \"notmuch new\", or does nothing
1006 depending on the value of `notmuch-poll-script'."
1007   (interactive)
1008   (if (stringp notmuch-poll-script)
1009       (unless (string= notmuch-poll-script "")
1010         (call-process notmuch-poll-script nil nil))
1011     (call-process notmuch-command nil nil nil "new")))
1012
1013 (defun notmuch-search-poll-and-refresh-view ()
1014   "Invoke `notmuch-poll' to import mail, then refresh the current view."
1015   (interactive)
1016   (notmuch-poll)
1017   (notmuch-search-refresh-view))
1018
1019 (defun notmuch-search-toggle-order ()
1020   "Toggle the current search order.
1021
1022 By default, the \"inbox\" view created by `notmuch' is displayed
1023 in chronological order (oldest thread at the beginning of the
1024 buffer), while any global searches created by `notmuch-search'
1025 are displayed in reverse-chronological order (newest thread at
1026 the beginning of the buffer).
1027
1028 This command toggles the sort order for the current search.
1029
1030 Note that any filtered searches created by
1031 `notmuch-search-filter' retain the search order of the parent
1032 search."
1033   (interactive)
1034   (set 'notmuch-search-oldest-first (not notmuch-search-oldest-first))
1035   (notmuch-search-refresh-view))
1036
1037 (defun notmuch-search-filter (query)
1038   "Filter the current search results based on an additional query string.
1039
1040 Runs a new search matching only messages that match both the
1041 current search results AND the additional query string provided."
1042   (interactive (list (notmuch-read-query "Filter search: ")))
1043   (let ((grouped-query (if (string-match-p notmuch-search-disjunctive-regexp query)
1044                            (concat "( " query " )")
1045                          query)))
1046     (notmuch-search (if (string= notmuch-search-query-string "*")
1047                         grouped-query
1048                       (concat notmuch-search-query-string " and " grouped-query)) notmuch-search-oldest-first)))
1049
1050 (defun notmuch-search-filter-by-tag (tag)
1051   "Filter the current search results based on a single tag.
1052
1053 Runs a new search matching only messages that match both the
1054 current search results AND that are tagged with the given tag."
1055   (interactive
1056    (list (notmuch-select-tag-with-completion "Filter by tag: ")))
1057   (notmuch-search (concat notmuch-search-query-string " and tag:" tag) notmuch-search-oldest-first))
1058
1059 ;;;###autoload
1060 (defun notmuch ()
1061   "Run notmuch and display saved searches, known tags, etc."
1062   (interactive)
1063   (notmuch-hello))
1064
1065 (defun notmuch-interesting-buffer (b)
1066   "Is the current buffer of interest to a notmuch user?"
1067   (with-current-buffer b
1068     (memq major-mode '(notmuch-show-mode
1069                        notmuch-search-mode
1070                        notmuch-hello-mode
1071                        message-mode))))
1072
1073 ;;;###autoload
1074 (defun notmuch-cycle-notmuch-buffers ()
1075   "Cycle through any existing notmuch buffers (search, show or hello).
1076
1077 If the current buffer is the only notmuch buffer, bury it. If no
1078 notmuch buffers exist, run `notmuch'."
1079   (interactive)
1080
1081   (let (start first)
1082     ;; If the current buffer is a notmuch buffer, remember it and then
1083     ;; bury it.
1084     (when (notmuch-interesting-buffer (current-buffer))
1085       (setq start (current-buffer))
1086       (bury-buffer))
1087
1088     ;; Find the first notmuch buffer.
1089     (setq first (loop for buffer in (buffer-list)
1090                      if (notmuch-interesting-buffer buffer)
1091                      return buffer))
1092
1093     (if first
1094         ;; If the first one we found is any other than the starting
1095         ;; buffer, switch to it.
1096         (unless (eq first start)
1097           (switch-to-buffer first))
1098       (notmuch))))
1099
1100 (setq mail-user-agent 'notmuch-user-agent)
1101
1102 (provide 'notmuch)