git.notmuchmail.org Git - notmuch/blob - emacs/notmuch.el

   1 ;;; notmuch.el --- run notmuch within emacs
   2 ;;
   3 ;; Copyright © Carl Worth
   4 ;;
   5 ;; This file is part of Notmuch.
   6 ;;
   7 ;; Notmuch is free software: you can redistribute it and/or modify it
   8 ;; under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation, either version 3 of the License, or
  10 ;; (at your option) any later version.
  11 ;;
  12 ;; Notmuch is distributed in the hope that it will be useful, but
  13 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 ;; General Public License for more details.
  16 ;;
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with Notmuch.  If not, see <https://www.gnu.org/licenses/>.
  19 ;;
  20 ;; Authors: Carl Worth <cworth@cworth.org>
  21 ;; Homepage: https://notmuchmail.org/
  22
  23 ;;; Commentary:
  24
  25 ;; This is an emacs-based interface to the notmuch mail system.
  26 ;;
  27 ;; You will first need to have the notmuch program installed and have a
  28 ;; notmuch database built in order to use this. See
  29 ;; https://notmuchmail.org for details.
  30 ;;
  31 ;; To install this software, copy it to a directory that is on the
  32 ;; `load-path' variable within emacs (a good candidate is
  33 ;; /usr/local/share/emacs/site-lisp). If you are viewing this from the
  34 ;; notmuch source distribution then you can simply run:
  35 ;;
  36 ;;      sudo make install-emacs
  37 ;;
  38 ;; to install it.
  39 ;;
  40 ;; Then, to actually run it, add:
  41 ;;
  42 ;;      (autoload 'notmuch "notmuch" "Notmuch mail" t)
  43 ;;
  44 ;; to your ~/.emacs file, and then run "M-x notmuch" from within emacs,
  45 ;; or run:
  46 ;;
  47 ;;      emacs -f notmuch
  48 ;;
  49 ;; Have fun, and let us know if you have any comment, questions, or
  50 ;; kudos: Notmuch list <notmuch@notmuchmail.org> (subscription is not
  51 ;; required, but is available from https://notmuchmail.org).
  52
  53 ;;; Code:
  54
  55 (eval-when-compile (require 'cl))
  56 (require 'mm-view)
  57 (require 'message)
  58
  59 (require 'notmuch-lib)
  60 (require 'notmuch-tag)
  61 (require 'notmuch-show)
  62 (require 'notmuch-tree)
  63 (require 'notmuch-mua)
  64 (require 'notmuch-hello)
  65 (require 'notmuch-maildir-fcc)
  66 (require 'notmuch-message)
  67 (require 'notmuch-parser)
  68
  69 (defcustom notmuch-search-result-format
  70   `(("date" . "%12s ")
  71     ("count" . "%-7s ")
  72     ("authors" . "%-20s ")
  73     ("subject" . "%s ")
  74     ("tags" . "(%s)"))
  75   "Search result formatting. Supported fields are:
  76         date, count, authors, subject, tags
  77 For example:
  78         (setq notmuch-search-result-format \(\(\"authors\" . \"%-40s\"\)
  79                                              \(\"subject\" . \"%s\"\)\)\)
  80 Line breaks are permitted in format strings (though this is
  81 currently experimental).  Note that a line break at the end of an
  82 \"authors\" field will get elided if the authors list is long;
  83 place it instead at the beginning of the following field.  To
  84 enter a line break when setting this variable with setq, use \\n.
  85 To enter a line break in customize, press \\[quoted-insert] C-j."
  86   :type '(alist :key-type (string) :value-type (string))
  87   :group 'notmuch-search)
  88
  89 ;; The name of this variable `notmuch-init-file' is consistent with the
  90 ;; convention used in e.g. emacs and gnus. The value, `notmuch-config[.el[c]]'
  91 ;; is consistent with notmuch cli configuration file `~/.notmuch-config'.
  92 (defcustom notmuch-init-file (locate-user-emacs-file "notmuch-config")
  93   "Your Notmuch Emacs-Lisp configuration file name.
  94 If a file with one of the suffixes defined by `get-load-suffixes' exists,
  95 it will be read instead.
  96 This file is read once when notmuch is loaded; the notmuch hooks added
  97 there will be called at other points of notmuch execution."
  98   :type 'file
  99   :group 'notmuch)
 100
 101 (defvar notmuch-query-history nil
 102   "Variable to store minibuffer history for notmuch queries")
 103
 104 (defun notmuch-foreach-mime-part (function mm-handle)
 105   (cond ((stringp (car mm-handle))
 106          (dolist (part (cdr mm-handle))
 107            (notmuch-foreach-mime-part function part)))
 108         ((bufferp (car mm-handle))
 109          (funcall function mm-handle))
 110         (t (dolist (part mm-handle)
 111              (notmuch-foreach-mime-part function part)))))
 112
 113 (defun notmuch-count-attachments (mm-handle)
 114   (let ((count 0))
 115     (notmuch-foreach-mime-part
 116      (lambda (p)
 117        (let ((disposition (mm-handle-disposition p)))
 118          (and (listp disposition)
 119               (or (equal (car disposition) "attachment")
 120                   (and (equal (car disposition) "inline")
 121                        (assq 'filename disposition)))
 122               (incf count))))
 123      mm-handle)
 124     count))
 125
 126 (defun notmuch-save-attachments (mm-handle &optional queryp)
 127   (notmuch-foreach-mime-part
 128    (lambda (p)
 129      (let ((disposition (mm-handle-disposition p)))
 130        (and (listp disposition)
 131             (or (equal (car disposition) "attachment")
 132                 (and (equal (car disposition) "inline")
 133                      (assq 'filename disposition)))
 134             (or (not queryp)
 135                 (y-or-n-p
 136                  (concat "Save '" (cdr (assq 'filename disposition)) "' ")))
 137             (mm-save-part p))))
 138    mm-handle))
 139
 140 (require 'hl-line)
 141
 142 (defun notmuch-hl-line-mode ()
 143   (prog1 (hl-line-mode)
 144     (when hl-line-overlay
 145       (overlay-put hl-line-overlay 'priority 1))))
 146
 147 (defcustom notmuch-search-hook '(notmuch-hl-line-mode)
 148   "List of functions to call when notmuch displays the search results."
 149   :type 'hook
 150   :options '(notmuch-hl-line-mode)
 151   :group 'notmuch-search
 152   :group 'notmuch-hooks)
 153
 154 (defvar notmuch-search-mode-map
 155   (let ((map (make-sparse-keymap)))
 156     (set-keymap-parent map notmuch-common-keymap)
 157     (define-key map "x" 'notmuch-bury-or-kill-this-buffer)
 158     (define-key map (kbd "<DEL>") 'notmuch-search-scroll-down)
 159     (define-key map "b" 'notmuch-search-scroll-down)
 160     (define-key map " " 'notmuch-search-scroll-up)
 161     (define-key map "<" 'notmuch-search-first-thread)
 162     (define-key map ">" 'notmuch-search-last-thread)
 163     (define-key map "p" 'notmuch-search-previous-thread)
 164     (define-key map "n" 'notmuch-search-next-thread)
 165     (define-key map "r" 'notmuch-search-reply-to-thread-sender)
 166     (define-key map "R" 'notmuch-search-reply-to-thread)
 167     (define-key map "o" 'notmuch-search-toggle-order)
 168     (define-key map "c" 'notmuch-search-stash-map)
 169     (define-key map "t" 'notmuch-search-filter-by-tag)
 170     (define-key map "l" 'notmuch-search-filter)
 171     (define-key map [mouse-1] 'notmuch-search-show-thread)
 172     (define-key map "*" 'notmuch-search-tag-all)
 173     (define-key map "a" 'notmuch-search-archive-thread)
 174     (define-key map "-" 'notmuch-search-remove-tag)
 175     (define-key map "+" 'notmuch-search-add-tag)
 176     (define-key map (kbd "RET") 'notmuch-search-show-thread)
 177     (define-key map "Z" 'notmuch-tree-from-search-current-query)
 178     map)
 179   "Keymap for \"notmuch search\" buffers.")
 180 (fset 'notmuch-search-mode-map notmuch-search-mode-map)
 181
 182 (defvar notmuch-search-stash-map
 183   (let ((map (make-sparse-keymap)))
 184     (define-key map "i" 'notmuch-search-stash-thread-id)
 185     (define-key map "q" 'notmuch-stash-query)
 186     (define-key map "?" 'notmuch-subkeymap-help)
 187     map)
 188   "Submap for stash commands")
 189 (fset 'notmuch-search-stash-map notmuch-search-stash-map)
 190
 191 (defun notmuch-search-stash-thread-id ()
 192   "Copy thread ID of current thread to kill-ring."
 193   (interactive)
 194   (notmuch-common-do-stash (notmuch-search-find-thread-id)))
 195
 196 (defun notmuch-stash-query ()
 197   "Copy current query to kill-ring."
 198   (interactive)
 199   (notmuch-common-do-stash (notmuch-search-get-query)))
 200
 201 (defvar notmuch-search-query-string)
 202 (defvar notmuch-search-target-thread)
 203 (defvar notmuch-search-target-line)
 204
 205 (defvar notmuch-search-disjunctive-regexp      "\\<[oO][rR]\\>")
 206
 207 (defun notmuch-search-scroll-up ()
 208   "Move forward through search results by one window's worth."
 209   (interactive)
 210   (condition-case nil
 211       (scroll-up nil)
 212     ((end-of-buffer) (notmuch-search-last-thread))))
 213
 214 (defun notmuch-search-scroll-down ()
 215   "Move backward through the search results by one window's worth."
 216   (interactive)
 217   ;; I don't know why scroll-down doesn't signal beginning-of-buffer
 218   ;; the way that scroll-up signals end-of-buffer, but c'est la vie.
 219   ;;
 220   ;; So instead of trapping a signal we instead check whether the
 221   ;; window begins on the first line of the buffer and if so, move
 222   ;; directly to that position. (We have to count lines since the
 223   ;; window-start position is not the same as point-min due to the
 224   ;; invisible thread-ID characters on the first line.
 225   (if (equal (count-lines (point-min) (window-start)) 0)
 226       (goto-char (point-min))
 227     (scroll-down nil)))
 228
 229 (defun notmuch-search-next-thread ()
 230   "Select the next thread in the search results."
 231   (interactive)
 232   (when (notmuch-search-get-result)
 233     (goto-char (notmuch-search-result-end))))
 234
 235 (defun notmuch-search-previous-thread ()
 236   "Select the previous thread in the search results."
 237   (interactive)
 238   (if (notmuch-search-get-result)
 239       (unless (bobp)
 240         (goto-char (notmuch-search-result-beginning (- (point) 1))))
 241     ;; We must be past the end; jump to the last result
 242     (notmuch-search-last-thread)))
 243
 244 (defun notmuch-search-last-thread ()
 245   "Select the last thread in the search results."
 246   (interactive)
 247   (goto-char (point-max))
 248   (forward-line -2)
 249   (let ((beg (notmuch-search-result-beginning)))
 250     (when beg (goto-char beg))))
 251
 252 (defun notmuch-search-first-thread ()
 253   "Select the first thread in the search results."
 254   (interactive)
 255   (goto-char (point-min)))
 256
 257 (defface notmuch-message-summary-face
 258  '((((class color) (background light)) (:background "#f0f0f0"))
 259    (((class color) (background dark)) (:background "#303030")))
 260  "Face for the single-line message summary in notmuch-show-mode."
 261  :group 'notmuch-show
 262  :group 'notmuch-faces)
 263
 264 (defface notmuch-search-date
 265   '((t :inherit default))
 266   "Face used in search mode for dates."
 267   :group 'notmuch-search
 268   :group 'notmuch-faces)
 269
 270 (defface notmuch-search-count
 271   '((t :inherit default))
 272   "Face used in search mode for the count matching the query."
 273   :group 'notmuch-search
 274   :group 'notmuch-faces)
 275
 276 (defface notmuch-search-subject
 277   '((t :inherit default))
 278   "Face used in search mode for subjects."
 279   :group 'notmuch-search
 280   :group 'notmuch-faces)
 281
 282 (defface notmuch-search-matching-authors
 283   '((t :inherit default))
 284   "Face used in search mode for authors matching the query."
 285   :group 'notmuch-search
 286   :group 'notmuch-faces)
 287
 288 (defface notmuch-search-non-matching-authors
 289   '((((class color)
 290       (background dark))
 291      (:foreground "grey30"))
 292     (((class color)
 293       (background light))
 294      (:foreground "grey60"))
 295     (t
 296      (:italic t)))
 297   "Face used in search mode for authors not matching the query."
 298   :group 'notmuch-search
 299   :group 'notmuch-faces)
 300
 301 (defface notmuch-tag-face
 302   '((((class color)
 303       (background dark))
 304      (:foreground "OliveDrab1"))
 305     (((class color)
 306       (background light))
 307      (:foreground "navy blue" :bold t))
 308     (t
 309      (:bold t)))
 310   "Face used in search mode face for tags."
 311   :group 'notmuch-search
 312   :group 'notmuch-faces)
 313
 314 (defface notmuch-search-flagged-face
 315   '((t
 316      (:weight bold)))
 317   "Face used in search mode face for flagged threads.
 318
 319 This face is the default value for the \"flagged\" tag in
 320 `notmuch-search-line-faces`."
 321   :group 'notmuch-search
 322   :group 'notmuch-faces)
 323
 324 (defface notmuch-search-unread-face
 325   '((t
 326      (:foreground "blue")))
 327   "Face used in search mode for unread threads.
 328
 329 This face is the default value for the \"unread\" tag in
 330 `notmuch-search-line-faces`."
 331   :group 'notmuch-search
 332   :group 'notmuch-faces)
 333
 334 (define-derived-mode notmuch-search-mode fundamental-mode "notmuch-search"
 335   "Major mode displaying results of a notmuch search.
 336
 337 This buffer contains the results of a \"notmuch search\" of your
 338 email archives. Each line in the buffer represents a single
 339 thread giving a summary of the thread (a relative date, the
 340 number of matched messages and total messages in the thread,
 341 participants in the thread, a representative subject line, and
 342 any tags).
 343
 344 Pressing \\[notmuch-search-show-thread] on any line displays that
 345 thread. The '\\[notmuch-search-add-tag]' and
 346 '\\[notmuch-search-remove-tag]' keys can be used to add or remove
 347 tags from a thread. The '\\[notmuch-search-archive-thread]' key
 348 is a convenience for archiving a thread (applying changes in
 349 `notmuch-archive-tags'). The '\\[notmuch-search-tag-all]' key can
 350 be used to add and/or remove tags from all messages (as opposed
 351 to threads) that match the current query.  Use with caution, as
 352 this will also tag matching messages that arrived *after*
 353 constructing the buffer.
 354
 355 Other useful commands are '\\[notmuch-search-filter]' for
 356 filtering the current search based on an additional query string,
 357 '\\[notmuch-search-filter-by-tag]' for filtering to include only
 358 messages with a given tag, and '\\[notmuch-search]' to execute a
 359 new, global search.
 360
 361 Complete list of currently available key bindings:
 362
 363 \\{notmuch-search-mode-map}"
 364   (make-local-variable 'notmuch-search-query-string)
 365   (make-local-variable 'notmuch-search-oldest-first)
 366   (make-local-variable 'notmuch-search-target-thread)
 367   (make-local-variable 'notmuch-search-target-line)
 368   (setq notmuch-buffer-refresh-function #'notmuch-search-refresh-view)
 369   (set (make-local-variable 'scroll-preserve-screen-position) t)
 370   (add-to-invisibility-spec (cons 'ellipsis t))
 371   (setq truncate-lines t)
 372   (setq buffer-read-only t))
 373
 374 (defun notmuch-search-get-result (&optional pos)
 375   "Return the result object for the thread at POS (or point).
 376
 377 If there is no thread at POS (or point), returns nil."
 378   (get-text-property (or pos (point)) 'notmuch-search-result))
 379
 380 (defun notmuch-search-result-beginning (&optional pos)
 381   "Return the point at the beginning of the thread at POS (or point).
 382
 383 If there is no thread at POS (or point), returns nil."
 384   (when (notmuch-search-get-result pos)
 385     ;; We pass 1+point because previous-single-property-change starts
 386     ;; searching one before the position we give it.
 387     (previous-single-property-change (1+ (or pos (point)))
 388                                      'notmuch-search-result nil (point-min))))
 389
 390 (defun notmuch-search-result-end (&optional pos)
 391   "Return the point at the end of the thread at POS (or point).
 392
 393 The returned point will be just after the newline character that
 394 ends the result line.  If there is no thread at POS (or point),
 395 returns nil"
 396   (when (notmuch-search-get-result pos)
 397     (next-single-property-change (or pos (point)) 'notmuch-search-result
 398                                  nil (point-max))))
 399
 400 (defun notmuch-search-foreach-result (beg end function)
 401   "Invoke FUNCTION for each result between BEG and END.
 402
 403 FUNCTION should take one argument.  It will be applied to the
 404 character position of the beginning of each result that overlaps
 405 the region between points BEG and END.  As a special case, if (=
 406 BEG END), FUNCTION will be applied to the result containing point
 407 BEG."
 408
 409   (lexical-let ((pos (notmuch-search-result-beginning beg))
 410                 ;; End must be a marker in case function changes the
 411                 ;; text.
 412                 (end (copy-marker end))
 413                 ;; Make sure we examine at least one result, even if
 414                 ;; (= beg end).
 415                 (first t))
 416     ;; We have to be careful if the region extends beyond the results.
 417     ;; In this case, pos could be null or there could be no result at
 418     ;; pos.
 419     (while (and pos (or (< pos end) first))
 420       (when (notmuch-search-get-result pos)
 421         (funcall function pos))
 422       (setq pos (notmuch-search-result-end pos)
 423             first nil))))
 424 ;; Unindent the function argument of notmuch-search-foreach-result so
 425 ;; the indentation of callers doesn't get out of hand.
 426 (put 'notmuch-search-foreach-result 'lisp-indent-function 2)
 427
 428 (defun notmuch-search-properties-in-region (property beg end)
 429   (let (output)
 430     (notmuch-search-foreach-result beg end
 431       (lambda (pos)
 432         (push (plist-get (notmuch-search-get-result pos) property) output)))
 433     output))
 434
 435 (defun notmuch-search-find-thread-id (&optional bare)
 436   "Return the thread for the current thread
 437
 438 If BARE is set then do not prefix with \"thread:\""
 439   (let ((thread (plist-get (notmuch-search-get-result) :thread)))
 440     (when thread (concat (unless bare "thread:") thread))))
 441
 442 (defun notmuch-search-find-stable-query ()
 443   "Return the stable queries for the current thread.
 444
 445 This returns a list (MATCHED-QUERY UNMATCHED-QUERY) for the
 446 matched and unmatched messages in the current thread."
 447   (plist-get (notmuch-search-get-result) :query))
 448
 449 (defun notmuch-search-find-stable-query-region (beg end &optional only-matched)
 450   "Return the stable query for the current region.
 451
 452 If ONLY-MATCHED is non-nil, include only matched messages.  If it
 453 is nil, include both matched and unmatched messages. If there are
 454 no messages in the region then return nil."
 455   (let ((query-list nil) (all (not only-matched)))
 456     (dolist (queries (notmuch-search-properties-in-region :query beg end))
 457       (when (first queries)
 458         (push (first queries) query-list))
 459       (when (and all (second queries))
 460         (push (second queries) query-list)))
 461     (when query-list
 462       (concat "(" (mapconcat 'identity query-list ") or (") ")"))))
 463
 464 (defun notmuch-search-find-authors ()
 465   "Return the authors for the current thread"
 466   (plist-get (notmuch-search-get-result) :authors))
 467
 468 (defun notmuch-search-find-authors-region (beg end)
 469   "Return a list of authors for the current region"
 470   (notmuch-search-properties-in-region :authors beg end))
 471
 472 (defun notmuch-search-find-subject ()
 473   "Return the subject for the current thread"
 474   (plist-get (notmuch-search-get-result) :subject))
 475
 476 (defun notmuch-search-find-subject-region (beg end)
 477   "Return a list of authors for the current region"
 478   (notmuch-search-properties-in-region :subject beg end))
 479
 480 (defun notmuch-search-show-thread (&optional elide-toggle)
 481   "Display the currently selected thread.
 482
 483 With a prefix argument, invert the default value of
 484 `notmuch-show-only-matching-messages' when displaying the
 485 thread."
 486   (interactive "P")
 487   (let ((thread-id (notmuch-search-find-thread-id))
 488         (subject (notmuch-search-find-subject)))
 489     (if (> (length thread-id) 0)
 490         (notmuch-show thread-id
 491                       elide-toggle
 492                       (current-buffer)
 493                       notmuch-search-query-string
 494                       ;; Name the buffer based on the subject.
 495                       (concat "*" (truncate-string-to-width subject 30 nil nil t) "*"))
 496       (message "End of search results."))))
 497
 498 (defun notmuch-tree-from-search-current-query ()
 499   "Call notmuch tree with the current query"
 500   (interactive)
 501   (notmuch-tree notmuch-search-query-string))
 502
 503 (defun notmuch-tree-from-search-thread ()
 504   "Show the selected thread with notmuch-tree"
 505   (interactive)
 506   (notmuch-tree (notmuch-search-find-thread-id)
 507                 notmuch-search-query-string
 508                 nil
 509                 (notmuch-prettify-subject (notmuch-search-find-subject))
 510                 t))
 511
 512 (defun notmuch-search-reply-to-thread (&optional prompt-for-sender)
 513   "Begin composing a reply-all to the entire current thread in a new buffer."
 514   (interactive "P")
 515   (let ((message-id (notmuch-search-find-thread-id)))
 516     (notmuch-mua-new-reply message-id prompt-for-sender t)))
 517
 518 (defun notmuch-search-reply-to-thread-sender (&optional prompt-for-sender)
 519   "Begin composing a reply to the entire current thread in a new buffer."
 520   (interactive "P")
 521   (let ((message-id (notmuch-search-find-thread-id)))
 522     (notmuch-mua-new-reply message-id prompt-for-sender nil)))
 523
 524 (defun notmuch-search-set-tags (tags &optional pos)
 525   (let ((new-result (plist-put (notmuch-search-get-result pos) :tags tags)))
 526     (notmuch-search-update-result new-result pos)))
 527
 528 (defun notmuch-search-get-tags (&optional pos)
 529   (plist-get (notmuch-search-get-result pos) :tags))
 530
 531 (defun notmuch-search-get-tags-region (beg end)
 532   (let (output)
 533     (notmuch-search-foreach-result beg end
 534       (lambda (pos)
 535         (setq output (append output (notmuch-search-get-tags pos)))))
 536     output))
 537
 538 (defun notmuch-search-interactive-region ()
 539   "Return the bounds of the current interactive region.
 540
 541 This returns (BEG END), where BEG and END are the bounds of the
 542 region if the region is active, or both `point' otherwise."
 543   (if (region-active-p)
 544       (list (region-beginning) (region-end))
 545     (list (point) (point))))
 546
 547 (defun notmuch-search-interactive-tag-changes (&optional initial-input)
 548   "Prompt for tag changes for the current thread or region.
 549
 550 Returns (TAG-CHANGES REGION-BEGIN REGION-END)."
 551   (let* ((region (notmuch-search-interactive-region))
 552          (beg (first region)) (end (second region))
 553          (prompt (if (= beg end) "Tag thread" "Tag region")))
 554     (cons (notmuch-read-tag-changes
 555            (notmuch-search-get-tags-region beg end) prompt initial-input)
 556           region)))
 557
 558 (defun notmuch-search-tag (tag-changes &optional beg end only-matched)
 559   "Change tags for the currently selected thread or region.
 560
 561 See `notmuch-tag' for information on the format of TAG-CHANGES.
 562 When called interactively, this uses the region if the region is
 563 active.  When called directly, BEG and END provide the region.
 564 If these are nil or not provided, this applies to the thread at
 565 point.
 566
 567 If ONLY-MATCHED is non-nil, only tag matched messages."
 568   (interactive (notmuch-search-interactive-tag-changes))
 569   (unless (and beg end) (setq beg (point) end (point)))
 570   (let ((search-string (notmuch-search-find-stable-query-region
 571                         beg end only-matched)))
 572     (notmuch-tag search-string tag-changes)
 573     (notmuch-search-foreach-result beg end
 574       (lambda (pos)
 575         (notmuch-search-set-tags
 576          (notmuch-update-tags (notmuch-search-get-tags pos) tag-changes)
 577          pos)))))
 578
 579 (defun notmuch-search-add-tag (tag-changes &optional beg end)
 580   "Change tags for the current thread or region (defaulting to add).
 581
 582 Same as `notmuch-search-tag' but sets initial input to '+'."
 583   (interactive (notmuch-search-interactive-tag-changes "+"))
 584   (notmuch-search-tag tag-changes beg end))
 585
 586 (defun notmuch-search-remove-tag (tag-changes &optional beg end)
 587   "Change tags for the current thread or region (defaulting to remove).
 588
 589 Same as `notmuch-search-tag' but sets initial input to '-'."
 590   (interactive (notmuch-search-interactive-tag-changes "-"))
 591   (notmuch-search-tag tag-changes beg end))
 592
 593 (put 'notmuch-search-archive-thread 'notmuch-prefix-doc
 594      "Un-archive the currently selected thread.")
 595 (defun notmuch-search-archive-thread (&optional unarchive beg end)
 596   "Archive the currently selected thread or region.
 597
 598 Archive each message in the currently selected thread by applying
 599 the tag changes in `notmuch-archive-tags' to each (remove the
 600 \"inbox\" tag by default). If a prefix argument is given, the
 601 messages will be \"unarchived\" (i.e. the tag changes in
 602 `notmuch-archive-tags' will be reversed).
 603
 604 This function advances the next thread when finished."
 605   (interactive (cons current-prefix-arg (notmuch-search-interactive-region)))
 606   (when notmuch-archive-tags
 607     (notmuch-search-tag
 608      (notmuch-tag-change-list notmuch-archive-tags unarchive) beg end))
 609   (when (eq beg end)
 610     (notmuch-search-next-thread)))
 611
 612 (defun notmuch-search-update-result (result &optional pos)
 613   "Replace the result object of the thread at POS (or point) by
 614 RESULT and redraw it.
 615
 616 This will keep point in a reasonable location.  However, if there
 617 are enclosing save-excursions and the saved point is in the
 618 result being updated, the point will be restored to the beginning
 619 of the result."
 620   (let ((start (notmuch-search-result-beginning pos))
 621         (end (notmuch-search-result-end pos))
 622         (init-point (point))
 623         (inhibit-read-only t))
 624     ;; Delete the current thread
 625     (delete-region start end)
 626     ;; Insert the updated thread
 627     (notmuch-search-show-result result start)
 628     ;; If point was inside the old result, make an educated guess
 629     ;; about where to place it now.  Unfortunately, this won't work
 630     ;; with save-excursion (or any other markers that would be nice to
 631     ;; preserve, such as the window start), but there's nothing we can
 632     ;; do about that without a way to retrieve markers in a region.
 633     (when (and (>= init-point start) (<= init-point end))
 634       (let* ((new-end (notmuch-search-result-end start))
 635              (new-point (if (= init-point end)
 636                             new-end
 637                           (min init-point (- new-end 1)))))
 638         (goto-char new-point)))))
 639
 640 (defun notmuch-search-process-sentinel (proc msg)
 641   "Add a message to let user know when \"notmuch search\" exits"
 642   (let ((buffer (process-buffer proc))
 643         (status (process-status proc))
 644         (exit-status (process-exit-status proc))
 645         (never-found-target-thread nil))
 646     (when (memq status '(exit signal))
 647       (catch 'return
 648         (kill-buffer (process-get proc 'parse-buf))
 649         (if (buffer-live-p buffer)
 650             (with-current-buffer buffer
 651               (save-excursion
 652                 (let ((inhibit-read-only t)
 653                       (atbob (bobp)))
 654                   (goto-char (point-max))
 655                   (if (eq status 'signal)
 656                       (insert "Incomplete search results (search process was killed).\n"))
 657                   (when (eq status 'exit)
 658                     (insert "End of search results.\n")
 659                     ;; For version mismatch, there's no point in
 660                     ;; showing the search buffer
 661                     (when (or (= exit-status 20) (= exit-status 21))
 662                       (kill-buffer)
 663                       (throw 'return nil))
 664                     (if (and atbob
 665                              (not (string= notmuch-search-target-thread "found")))
 666                         (set 'never-found-target-thread t)))))
 667               (when (and never-found-target-thread
 668                        notmuch-search-target-line)
 669                   (goto-char (point-min))
 670                   (forward-line (1- notmuch-search-target-line)))))))))
 671
 672 (defcustom notmuch-search-line-faces
 673   '(("unread" 'notmuch-search-unread-face)
 674     ("flagged" 'notmuch-search-flagged-face))
 675   "Alist of tags to faces for line highlighting in notmuch-search.
 676 Each element looks like (TAG . FACE).
 677 A thread with TAG will have FACE applied.
 678
 679 Here is an example of how to color search results based on tags.
 680  (the following text would be placed in your ~/.emacs file):
 681
 682  (setq notmuch-search-line-faces '((\"unread\" . (:foreground \"green\"))
 683                                    (\"deleted\" . (:foreground \"red\"
 684                                                   :background \"blue\"))))
 685
 686 The FACE must be a face name (a symbol or string), a property
 687 list of face attributes, or a list of these.  The faces for
 688 matching tags are merged, with earlier attributes overriding
 689 later. A message having both \"deleted\" and \"unread\" tags with
 690 the above settings would have a green foreground and blue
 691 background."
 692   :type '(alist :key-type (string) :value-type (custom-face-edit))
 693   :group 'notmuch-search
 694   :group 'notmuch-faces)
 695
 696 (defun notmuch-search-color-line (start end line-tag-list)
 697   "Colorize lines in `notmuch-show' based on tags."
 698   (mapc (lambda (elem)
 699           (let ((tag (car elem))
 700                 (attributes (cdr elem)))
 701             (when (member tag line-tag-list)
 702               (notmuch-apply-face nil attributes nil start end))))
 703         ;; Reverse the list so earlier entries take precedence
 704         (reverse notmuch-search-line-faces)))
 705
 706 (defun notmuch-search-author-propertize (authors)
 707   "Split `authors' into matching and non-matching authors and
 708 propertize appropriately. If no boundary between authors and
 709 non-authors is found, assume that all of the authors match."
 710   (if (string-match "\\(.*\\)|\\(.*\\)" authors)
 711       (concat (propertize (concat (match-string 1 authors) ",")
 712                           'face 'notmuch-search-matching-authors)
 713               (propertize (match-string 2 authors)
 714                           'face 'notmuch-search-non-matching-authors))
 715     (propertize authors 'face 'notmuch-search-matching-authors)))
 716
 717 (defun notmuch-search-insert-authors (format-string authors)
 718   ;; Save the match data to avoid interfering with
 719   ;; `notmuch-search-process-filter'.
 720   (save-match-data
 721     (let* ((formatted-authors (format format-string authors))
 722            (formatted-sample (format format-string ""))
 723            (visible-string formatted-authors)
 724            (invisible-string "")
 725            (padding ""))
 726
 727       ;; Truncate the author string to fit the specification.
 728       (if (> (length formatted-authors)
 729              (length formatted-sample))
 730           (let ((visible-length (- (length formatted-sample)
 731                                    (length "... "))))
 732             ;; Truncate the visible string according to the width of
 733             ;; the display string.
 734             (setq visible-string (substring formatted-authors 0 visible-length)
 735                   invisible-string (substring formatted-authors visible-length))
 736             ;; If possible, truncate the visible string at a natural
 737             ;; break (comma or pipe), as incremental search doesn't
 738             ;; match across the visible/invisible border.
 739             (when (string-match "\\(.*\\)\\([,|] \\)\\([^,|]*\\)" visible-string)
 740               ;; Second clause is destructive on `visible-string', so
 741               ;; order is important.
 742               (setq invisible-string (concat (match-string 3 visible-string)
 743                                              invisible-string)
 744                     visible-string (concat (match-string 1 visible-string)
 745                                            (match-string 2 visible-string))))
 746             ;; `visible-string' may be shorter than the space allowed
 747             ;; by `format-string'. If so we must insert some padding
 748             ;; after `invisible-string'.
 749             (setq padding (make-string (- (length formatted-sample)
 750                                           (length visible-string)
 751                                           (length "..."))
 752                                        ? ))))
 753
 754       ;; Use different faces to show matching and non-matching authors.
 755       (if (string-match "\\(.*\\)|\\(.*\\)" visible-string)
 756           ;; The visible string contains both matching and
 757           ;; non-matching authors.
 758           (setq visible-string (notmuch-search-author-propertize visible-string)
 759                 ;; The invisible string must contain only non-matching
 760                 ;; authors, as the visible-string contains both.
 761                 invisible-string (propertize invisible-string
 762                                              'face 'notmuch-search-non-matching-authors))
 763         ;; The visible string contains only matching authors.
 764         (setq visible-string (propertize visible-string
 765                                          'face 'notmuch-search-matching-authors)
 766               ;; The invisible string may contain both matching and
 767               ;; non-matching authors.
 768               invisible-string (notmuch-search-author-propertize invisible-string)))
 769
 770       ;; If there is any invisible text, add it as a tooltip to the
 771       ;; visible text.
 772       (when (not (string= invisible-string ""))
 773         (setq visible-string (propertize visible-string 'help-echo (concat "..." invisible-string))))
 774
 775       ;; Insert the visible and, if present, invisible author strings.
 776       (insert visible-string)
 777       (when (not (string= invisible-string ""))
 778         (let ((start (point))
 779               overlay)
 780           (insert invisible-string)
 781           (setq overlay (make-overlay start (point)))
 782           (overlay-put overlay 'invisible 'ellipsis)
 783           (overlay-put overlay 'isearch-open-invisible #'delete-overlay)))
 784       (insert padding))))
 785
 786 (defun notmuch-search-insert-field (field format-string result)
 787   (cond
 788    ((string-equal field "date")
 789     (insert (propertize (format format-string (plist-get result :date_relative))
 790                         'face 'notmuch-search-date)))
 791    ((string-equal field "count")
 792     (insert (propertize (format format-string
 793                                 (format "[%s/%s]" (plist-get result :matched)
 794                                         (plist-get result :total)))
 795                         'face 'notmuch-search-count)))
 796    ((string-equal field "subject")
 797     (insert (propertize (format format-string
 798                                 (notmuch-sanitize (plist-get result :subject)))
 799                         'face 'notmuch-search-subject)))
 800
 801    ((string-equal field "authors")
 802     (notmuch-search-insert-authors
 803      format-string (notmuch-sanitize (plist-get result :authors))))
 804
 805    ((string-equal field "tags")
 806     (let ((tags (plist-get result :tags))
 807           (orig-tags (plist-get result :orig-tags)))
 808       (insert (format format-string (notmuch-tag-format-tags tags orig-tags)))))))
 809
 810 (defun notmuch-search-show-result (result pos)
 811   "Insert RESULT at POS."
 812   ;; Ignore excluded matches
 813   (unless (= (plist-get result :matched) 0)
 814     (save-excursion
 815       (goto-char pos)
 816       (dolist (spec notmuch-search-result-format)
 817         (notmuch-search-insert-field (car spec) (cdr spec) result))
 818       (insert "\n")
 819       (notmuch-search-color-line pos (point) (plist-get result :tags))
 820       (put-text-property pos (point) 'notmuch-search-result result))))
 821
 822 (defun notmuch-search-append-result (result)
 823   "Insert RESULT at the end of the buffer.
 824
 825 This is only called when a result is first inserted so it also
 826 sets the :orig-tag property."
 827   (let ((new-result (plist-put result :orig-tags (plist-get result :tags)))
 828         (pos (point-max)))
 829     (notmuch-search-show-result new-result pos)
 830     (when (string= (plist-get result :thread) notmuch-search-target-thread)
 831       (setq notmuch-search-target-thread "found")
 832       (goto-char pos))))
 833
 834 (defun notmuch-search-process-filter (proc string)
 835   "Process and filter the output of \"notmuch search\""
 836   (let ((results-buf (process-buffer proc))
 837         (parse-buf (process-get proc 'parse-buf))
 838         (inhibit-read-only t)
 839         done)
 840     (when (buffer-live-p results-buf)
 841       (with-current-buffer parse-buf
 842         ;; Insert new data
 843         (save-excursion
 844           (goto-char (point-max))
 845           (insert string))
 846         (notmuch-sexp-parse-partial-list 'notmuch-search-append-result
 847                                          results-buf)))))
 848
 849 (defun notmuch-search-tag-all (tag-changes)
 850   "Add/remove tags from all messages in current search buffer.
 851
 852 See `notmuch-tag' for information on the format of TAG-CHANGES."
 853   (interactive
 854    (list (notmuch-read-tag-changes
 855           (notmuch-search-get-tags-region (point-min) (point-max)) "Tag all")))
 856   (notmuch-search-tag tag-changes (point-min) (point-max) t))
 857
 858 (defun notmuch-search-buffer-title (query)
 859   "Returns the title for a buffer with notmuch search results."
 860   (let* ((saved-search
 861           (let (longest
 862                 (longest-length 0))
 863             (loop for tuple in notmuch-saved-searches
 864                   if (let ((quoted-query (regexp-quote (notmuch-saved-search-get tuple :query))))
 865                        (and (string-match (concat "^" quoted-query) query)
 866                             (> (length (match-string 0 query))
 867                                longest-length)))
 868                   do (setq longest tuple))
 869             longest))
 870          (saved-search-name (notmuch-saved-search-get saved-search :name))
 871          (saved-search-query (notmuch-saved-search-get saved-search :query)))
 872     (cond ((and saved-search (equal saved-search-query query))
 873            ;; Query is the same as saved search (ignoring case)
 874            (concat "*notmuch-saved-search-" saved-search-name "*"))
 875           (saved-search
 876            (concat "*notmuch-search-"
 877                    (replace-regexp-in-string (concat "^" (regexp-quote saved-search-query))
 878                                              (concat "[ " saved-search-name " ]")
 879                                              query)
 880                    "*"))
 881           (t
 882            (concat "*notmuch-search-" query "*"))
 883           )))
 884
 885 (defun notmuch-read-query (prompt)
 886   "Read a notmuch-query from the minibuffer with completion.
 887
 888 PROMPT is the string to prompt with."
 889   (lexical-let*
 890       ((all-tags
 891         (mapcar (lambda (tag) (notmuch-escape-boolean-term tag))
 892                 (process-lines notmuch-command "search" "--output=tags" "*")))
 893        (completions
 894          (append (list "folder:" "path:" "thread:" "id:" "date:" "from:" "to:"
 895                        "subject:" "attachment:" "mimetype:")
 896                  (mapcar (lambda (tag) (concat "tag:" tag)) all-tags)
 897                  (mapcar (lambda (tag) (concat "is:" tag)) all-tags))))
 898     (let ((keymap (copy-keymap minibuffer-local-map))
 899           (current-query (case major-mode
 900                            (notmuch-search-mode (notmuch-search-get-query))
 901                            (notmuch-show-mode (notmuch-show-get-query))
 902                            (notmuch-tree-mode (notmuch-tree-get-query))))
 903           (minibuffer-completion-table
 904            (completion-table-dynamic
 905             (lambda (string)
 906               ;; generate a list of possible completions for the current input
 907               (cond
 908                ;; this ugly regexp is used to get the last word of the input
 909                ;; possibly preceded by a '('
 910                ((string-match "\\(^\\|.* (?\\)\\([^ ]*\\)$" string)
 911                 (mapcar (lambda (compl)
 912                           (concat (match-string-no-properties 1 string) compl))
 913                         (all-completions (match-string-no-properties 2 string)
 914                                          completions)))
 915                (t (list string)))))))
 916       ;; this was simpler than convincing completing-read to accept spaces:
 917       (define-key keymap (kbd "TAB") 'minibuffer-complete)
 918       (let ((history-delete-duplicates t))
 919         (read-from-minibuffer prompt nil keymap nil
 920                               'notmuch-search-history current-query nil)))))
 921
 922 (defun notmuch-search-get-query ()
 923   "Return the current query in this search buffer"
 924   notmuch-search-query-string)
 925
 926 ;;;###autoload
 927 (put 'notmuch-search 'notmuch-doc "Search for messages.")
 928 (defun notmuch-search (&optional query oldest-first target-thread target-line)
 929   "Display threads matching QUERY in a notmuch-search buffer.
 930
 931 If QUERY is nil, it is read interactively from the minibuffer.
 932 Other optional parameters are used as follows:
 933
 934   OLDEST-FIRST: A Boolean controlling the sort order of returned threads
 935   TARGET-THREAD: A thread ID (without the thread: prefix) that will be made
 936                  current if it appears in the search results.
 937   TARGET-LINE: The line number to move to if the target thread does not
 938                appear in the search results.
 939
 940 When called interactively, this will prompt for a query and use
 941 the configured default sort order."
 942   (interactive
 943    (list
 944     ;; Prompt for a query
 945     nil
 946     ;; Use the default search order (if we're doing a search from a
 947     ;; search buffer, ignore any buffer-local overrides)
 948     (default-value 'notmuch-search-oldest-first)))
 949
 950   (let* ((query (or query (notmuch-read-query "Notmuch search: ")))
 951          (buffer (get-buffer-create (notmuch-search-buffer-title query))))
 952     (switch-to-buffer buffer)
 953     (notmuch-search-mode)
 954     ;; Don't track undo information for this buffer
 955     (set 'buffer-undo-list t)
 956     (set 'notmuch-search-query-string query)
 957     (set 'notmuch-search-oldest-first oldest-first)
 958     (set 'notmuch-search-target-thread target-thread)
 959     (set 'notmuch-search-target-line target-line)
 960     (notmuch-tag-clear-cache)
 961     (let ((proc (get-buffer-process (current-buffer)))
 962           (inhibit-read-only t))
 963       (if proc
 964           (error "notmuch search process already running for query `%s'" query)
 965         )
 966       (erase-buffer)
 967       (goto-char (point-min))
 968       (save-excursion
 969         (let ((proc (notmuch-start-notmuch
 970                      "notmuch-search" buffer #'notmuch-search-process-sentinel
 971                      "search" "--format=sexp" "--format-version=2"
 972                      (if oldest-first
 973                          "--sort=oldest-first"
 974                        "--sort=newest-first")
 975                      query))
 976               ;; Use a scratch buffer to accumulate partial output.
 977               ;; This buffer will be killed by the sentinel, which
 978               ;; should be called no matter how the process dies.
 979               (parse-buf (generate-new-buffer " *notmuch search parse*")))
 980           (process-put proc 'parse-buf parse-buf)
 981           (set-process-filter proc 'notmuch-search-process-filter)
 982           (set-process-query-on-exit-flag proc nil))))
 983     (run-hooks 'notmuch-search-hook)))
 984
 985 (defun notmuch-search-refresh-view ()
 986   "Refresh the current view.
 987
 988 Kills the current buffer and runs a new search with the same
 989 query string as the current search. If the current thread is in
 990 the new search results, then point will be placed on the same
 991 thread. Otherwise, point will be moved to attempt to be in the
 992 same relative position within the new buffer."
 993   (let ((target-line (line-number-at-pos))
 994         (oldest-first notmuch-search-oldest-first)
 995         (target-thread (notmuch-search-find-thread-id 'bare))
 996         (query notmuch-search-query-string))
 997     (notmuch-bury-or-kill-this-buffer)
 998     (notmuch-search query oldest-first target-thread target-line)
 999     (goto-char (point-min))))
1000
1001 (defun notmuch-search-toggle-order ()
1002   "Toggle the current search order.
1003
1004 This command toggles the sort order for the current search. The
1005 default sort order is defined by `notmuch-search-oldest-first'."
1006   (interactive)
1007   (set 'notmuch-search-oldest-first (not notmuch-search-oldest-first))
1008   (notmuch-search-refresh-view))
1009
1010 (defun notmuch-group-disjunctive-query-string (query-string)
1011   "Group query if it contains a complex expression.
1012
1013 Enclose QUERY-STRING in parentheses if it matches
1014 `notmuch-search-disjunctive-regexp'."
1015   (if (string-match-p notmuch-search-disjunctive-regexp query-string)
1016       (concat "( " query-string " )")
1017     query-string))
1018
1019 (defun notmuch-search-filter (query)
1020   "Filter or LIMIT the current search results based on an additional query string.
1021
1022 Runs a new search matching only messages that match both the
1023 current search results AND the additional query string provided."
1024   (interactive (list (notmuch-read-query "Filter search: ")))
1025   (let ((grouped-query (notmuch-group-disjunctive-query-string query))
1026         (grouped-original-query (notmuch-group-disjunctive-query-string
1027                                  notmuch-search-query-string)))
1028     (notmuch-search (if (string= grouped-original-query "*")
1029                         grouped-query
1030                       (concat grouped-original-query " and " grouped-query))
1031                     notmuch-search-oldest-first)))
1032
1033 (defun notmuch-search-filter-by-tag (tag)
1034   "Filter the current search results based on a single tag.
1035
1036 Runs a new search matching only messages that match both the
1037 current search results AND that are tagged with the given tag."
1038   (interactive
1039    (list (notmuch-select-tag-with-completion "Filter by tag: ")))
1040   (notmuch-search (concat notmuch-search-query-string " and tag:" tag) notmuch-search-oldest-first))
1041
1042 ;;;###autoload
1043 (defun notmuch ()
1044   "Run notmuch and display saved searches, known tags, etc."
1045   (interactive)
1046   (notmuch-hello))
1047
1048 (defun notmuch-interesting-buffer (b)
1049   "Is the current buffer of interest to a notmuch user?"
1050   (with-current-buffer b
1051     (memq major-mode '(notmuch-show-mode
1052                        notmuch-search-mode
1053                        notmuch-hello-mode
1054                        message-mode))))
1055
1056 ;;;###autoload
1057 (defun notmuch-cycle-notmuch-buffers ()
1058   "Cycle through any existing notmuch buffers (search, show or hello).
1059
1060 If the current buffer is the only notmuch buffer, bury it. If no
1061 notmuch buffers exist, run `notmuch'."
1062   (interactive)
1063
1064   (let (start first)
1065     ;; If the current buffer is a notmuch buffer, remember it and then
1066     ;; bury it.
1067     (when (notmuch-interesting-buffer (current-buffer))
1068       (setq start (current-buffer))
1069       (bury-buffer))
1070
1071     ;; Find the first notmuch buffer.
1072     (setq first (loop for buffer in (buffer-list)
1073                      if (notmuch-interesting-buffer buffer)
1074                      return buffer))
1075
1076     (if first
1077         ;; If the first one we found is any other than the starting
1078         ;; buffer, switch to it.
1079         (unless (eq first start)
1080           (switch-to-buffer first))
1081       (notmuch))))
1082
1083 (setq mail-user-agent 'notmuch-user-agent)
1084
1085 (provide 'notmuch)
1086
1087 ;; After provide to avoid loops if notmuch was require'd via notmuch-init-file.
1088 (if init-file-user ; don't load init file if the -q option was used.
1089     (let ((init-file (locate-file notmuch-init-file '("/")
1090                                   (get-load-suffixes))))
1091       (if init-file (load init-file nil t t))))
1092
1093 ;;; notmuch.el ends here