git.notmuchmail.org Git - notmuch/blob - emacs/notmuch.el

   1 ;; notmuch.el --- run notmuch within emacs
   2 ;;
   3 ;; Copyright © Carl Worth
   4 ;;
   5 ;; This file is part of Notmuch.
   6 ;;
   7 ;; Notmuch is free software: you can redistribute it and/or modify it
   8 ;; under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation, either version 3 of the License, or
  10 ;; (at your option) any later version.
  11 ;;
  12 ;; Notmuch is distributed in the hope that it will be useful, but
  13 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 ;; General Public License for more details.
  16 ;;
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with Notmuch.  If not, see <http://www.gnu.org/licenses/>.
  19 ;;
  20 ;; Authors: Carl Worth <cworth@cworth.org>
  21
  22 ;; This is an emacs-based interface to the notmuch mail system.
  23 ;;
  24 ;; You will first need to have the notmuch program installed and have a
  25 ;; notmuch database built in order to use this. See
  26 ;; http://notmuchmail.org for details.
  27 ;;
  28 ;; To install this software, copy it to a directory that is on the
  29 ;; `load-path' variable within emacs (a good candidate is
  30 ;; /usr/local/share/emacs/site-lisp). If you are viewing this from the
  31 ;; notmuch source distribution then you can simply run:
  32 ;;
  33 ;;      sudo make install-emacs
  34 ;;
  35 ;; to install it.
  36 ;;
  37 ;; Then, to actually run it, add:
  38 ;;
  39 ;;      (require 'notmuch)
  40 ;;
  41 ;; to your ~/.emacs file, and then run "M-x notmuch" from within emacs,
  42 ;; or run:
  43 ;;
  44 ;;      emacs -f notmuch
  45 ;;
  46 ;; Have fun, and let us know if you have any comment, questions, or
  47 ;; kudos: Notmuch list <notmuch@notmuchmail.org> (subscription is not
  48 ;; required, but is available from http://notmuchmail.org).
  49
  50 (eval-when-compile (require 'cl))
  51 (require 'mm-view)
  52 (require 'message)
  53
  54 (require 'notmuch-lib)
  55 (require 'notmuch-tag)
  56 (require 'notmuch-show)
  57 (require 'notmuch-mua)
  58 (require 'notmuch-hello)
  59 (require 'notmuch-maildir-fcc)
  60 (require 'notmuch-message)
  61 (require 'notmuch-parser)
  62
  63 (defcustom notmuch-search-result-format
  64   `(("date" . "%12s ")
  65     ("count" . "%-7s ")
  66     ("authors" . "%-20s ")
  67     ("subject" . "%s ")
  68     ("tags" . "(%s)"))
  69   "Search result formatting. Supported fields are:
  70         date, count, authors, subject, tags
  71 For example:
  72         (setq notmuch-search-result-format \(\(\"authors\" . \"%-40s\"\)
  73                                              \(\"subject\" . \"%s\"\)\)\)
  74 Line breaks are permitted in format strings (though this is
  75 currently experimental).  Note that a line break at the end of an
  76 \"authors\" field will get elided if the authors list is long;
  77 place it instead at the beginning of the following field.  To
  78 enter a line break when setting this variable with setq, use \\n.
  79 To enter a line break in customize, press \\[quoted-insert] C-j."
  80   :type '(alist :key-type (string) :value-type (string))
  81   :group 'notmuch-search)
  82
  83 (defvar notmuch-query-history nil
  84   "Variable to store minibuffer history for notmuch queries")
  85
  86 (defun notmuch-foreach-mime-part (function mm-handle)
  87   (cond ((stringp (car mm-handle))
  88          (dolist (part (cdr mm-handle))
  89            (notmuch-foreach-mime-part function part)))
  90         ((bufferp (car mm-handle))
  91          (funcall function mm-handle))
  92         (t (dolist (part mm-handle)
  93              (notmuch-foreach-mime-part function part)))))
  94
  95 (defun notmuch-count-attachments (mm-handle)
  96   (let ((count 0))
  97     (notmuch-foreach-mime-part
  98      (lambda (p)
  99        (let ((disposition (mm-handle-disposition p)))
 100          (and (listp disposition)
 101               (or (equal (car disposition) "attachment")
 102                   (and (equal (car disposition) "inline")
 103                        (assq 'filename disposition)))
 104               (incf count))))
 105      mm-handle)
 106     count))
 107
 108 (defun notmuch-save-attachments (mm-handle &optional queryp)
 109   (notmuch-foreach-mime-part
 110    (lambda (p)
 111      (let ((disposition (mm-handle-disposition p)))
 112        (and (listp disposition)
 113             (or (equal (car disposition) "attachment")
 114                 (and (equal (car disposition) "inline")
 115                      (assq 'filename disposition)))
 116             (or (not queryp)
 117                 (y-or-n-p
 118                  (concat "Save '" (cdr (assq 'filename disposition)) "' ")))
 119             (mm-save-part p))))
 120    mm-handle))
 121
 122 (defun notmuch-documentation-first-line (symbol)
 123   "Return the first line of the documentation string for SYMBOL."
 124   (let ((doc (documentation symbol)))
 125     (if doc
 126         (with-temp-buffer
 127           (insert (documentation symbol t))
 128           (goto-char (point-min))
 129           (let ((beg (point)))
 130             (end-of-line)
 131             (buffer-substring beg (point))))
 132       "")))
 133
 134 (defun notmuch-prefix-key-description (key)
 135   "Given a prefix key code, return a human-readable string representation.
 136
 137 This is basically just `format-kbd-macro' but we also convert ESC to M-."
 138   (let ((desc (format-kbd-macro (vector key))))
 139     (if (string= desc "ESC")
 140         "M-"
 141       (concat desc " "))))
 142
 143 (defun notmuch-describe-keymap (keymap ua-keys &optional prefix tail)
 144   "Return a list of strings, each describing one binding in KEYMAP.
 145
 146 Each string gives a human-readable description of the key and a
 147 one-line description of the bound function.  See `notmuch-help'
 148 for an overview of how this documentation is extracted.
 149
 150 UA-KEYS should be a key sequence bound to `universal-argument'.
 151 It will be used to describe bindings of commands that support a
 152 prefix argument.  PREFIX and TAIL are used internally."
 153   (map-keymap
 154    (lambda (key binding)
 155      (cond ((mouse-event-p key) nil)
 156            ((keymapp binding)
 157             (setq tail
 158                   (notmuch-describe-keymap
 159                    binding ua-keys (notmuch-prefix-key-description key) tail)))
 160            (t
 161             (when (and ua-keys (symbolp binding)
 162                        (get binding 'notmuch-prefix-doc))
 163               ;; Documentation for prefixed command
 164               (let ((ua-desc (key-description ua-keys)))
 165                 (push (concat ua-desc " " prefix (format-kbd-macro (vector key))
 166                               "\t" (get binding 'notmuch-prefix-doc))
 167                       tail)))
 168             ;; Documentation for command
 169             (push (concat prefix (format-kbd-macro (vector key)) "\t"
 170                           (or (and (symbolp binding) (get binding 'notmuch-doc))
 171                               (notmuch-documentation-first-line binding)))
 172                   tail))))
 173    keymap)
 174   tail)
 175
 176 (defun notmuch-substitute-command-keys (doc)
 177   "Like `substitute-command-keys' but with documentation, not function names."
 178   (let ((beg 0))
 179     (while (string-match "\\\\{\\([^}[:space:]]*\\)}" doc beg)
 180       (let* ((keymap-name (substring doc (match-beginning 1) (match-end 1)))
 181              (keymap (symbol-value (intern keymap-name)))
 182              (ua-keys (where-is-internal 'universal-argument keymap t))
 183              (desc-list (notmuch-describe-keymap keymap ua-keys))
 184              (desc (mapconcat #'identity desc-list "\n")))
 185         (setq doc (replace-match desc 1 1 doc)))
 186       (setq beg (match-end 0)))
 187     doc))
 188
 189 (defun notmuch-help ()
 190   "Display help for the current notmuch mode.
 191
 192 This is similar to `describe-function' for the current major
 193 mode, but bindings tables are shown with documentation strings
 194 rather than command names.  By default, this uses the first line
 195 of each command's documentation string.  A command can override
 196 this by setting the 'notmuch-doc property of its command symbol.
 197 A command that supports a prefix argument can explicitly document
 198 its prefixed behavior by setting the 'notmuch-prefix-doc property
 199 of its command symbol."
 200   (interactive)
 201   (let* ((mode major-mode)
 202          (doc (substitute-command-keys (notmuch-substitute-command-keys (documentation mode t)))))
 203     (with-current-buffer (generate-new-buffer "*notmuch-help*")
 204       (insert doc)
 205       (goto-char (point-min))
 206       (set-buffer-modified-p nil)
 207       (view-buffer (current-buffer) 'kill-buffer-if-not-modified))))
 208
 209 (require 'hl-line)
 210
 211 (defun notmuch-hl-line-mode ()
 212   (prog1 (hl-line-mode)
 213     (when hl-line-overlay
 214       (overlay-put hl-line-overlay 'priority 1))))
 215
 216 (defcustom notmuch-search-hook '(notmuch-hl-line-mode)
 217   "List of functions to call when notmuch displays the search results."
 218   :type 'hook
 219   :options '(notmuch-hl-line-mode)
 220   :group 'notmuch-search
 221   :group 'notmuch-hooks)
 222
 223 (defvar notmuch-search-mode-map
 224   (let ((map (make-sparse-keymap)))
 225     (set-keymap-parent map notmuch-common-keymap)
 226     (define-key map "x" 'notmuch-kill-this-buffer)
 227     (define-key map (kbd "<DEL>") 'notmuch-search-scroll-down)
 228     (define-key map "b" 'notmuch-search-scroll-down)
 229     (define-key map " " 'notmuch-search-scroll-up)
 230     (define-key map "<" 'notmuch-search-first-thread)
 231     (define-key map ">" 'notmuch-search-last-thread)
 232     (define-key map "p" 'notmuch-search-previous-thread)
 233     (define-key map "n" 'notmuch-search-next-thread)
 234     (define-key map "r" 'notmuch-search-reply-to-thread-sender)
 235     (define-key map "R" 'notmuch-search-reply-to-thread)
 236     (define-key map "o" 'notmuch-search-toggle-order)
 237     (define-key map "c" 'notmuch-search-stash-map)
 238     (define-key map "t" 'notmuch-search-filter-by-tag)
 239     (define-key map "f" 'notmuch-search-filter)
 240     (define-key map [mouse-1] 'notmuch-search-show-thread)
 241     (define-key map "*" 'notmuch-search-tag-all)
 242     (define-key map "a" 'notmuch-search-archive-thread)
 243     (define-key map "-" 'notmuch-search-remove-tag)
 244     (define-key map "+" 'notmuch-search-add-tag)
 245     (define-key map (kbd "RET") 'notmuch-search-show-thread)
 246     map)
 247   "Keymap for \"notmuch search\" buffers.")
 248 (fset 'notmuch-search-mode-map notmuch-search-mode-map)
 249
 250 (defvar notmuch-search-stash-map
 251   (let ((map (make-sparse-keymap)))
 252     (define-key map "i" 'notmuch-search-stash-thread-id)
 253     map)
 254   "Submap for stash commands")
 255 (fset 'notmuch-search-stash-map notmuch-search-stash-map)
 256
 257 (defun notmuch-search-stash-thread-id ()
 258   "Copy thread ID of current thread to kill-ring."
 259   (interactive)
 260   (notmuch-common-do-stash (notmuch-search-find-thread-id)))
 261
 262 (defvar notmuch-search-query-string)
 263 (defvar notmuch-search-target-thread)
 264 (defvar notmuch-search-target-line)
 265
 266 (defvar notmuch-search-disjunctive-regexp      "\\<[oO][rR]\\>")
 267
 268 (defun notmuch-search-scroll-up ()
 269   "Move forward through search results by one window's worth."
 270   (interactive)
 271   (condition-case nil
 272       (scroll-up nil)
 273     ((end-of-buffer) (notmuch-search-last-thread))))
 274
 275 (defun notmuch-search-scroll-down ()
 276   "Move backward through the search results by one window's worth."
 277   (interactive)
 278   ;; I don't know why scroll-down doesn't signal beginning-of-buffer
 279   ;; the way that scroll-up signals end-of-buffer, but c'est la vie.
 280   ;;
 281   ;; So instead of trapping a signal we instead check whether the
 282   ;; window begins on the first line of the buffer and if so, move
 283   ;; directly to that position. (We have to count lines since the
 284   ;; window-start position is not the same as point-min due to the
 285   ;; invisible thread-ID characters on the first line.
 286   (if (equal (count-lines (point-min) (window-start)) 0)
 287       (goto-char (point-min))
 288     (scroll-down nil)))
 289
 290 (defun notmuch-search-next-thread ()
 291   "Select the next thread in the search results."
 292   (interactive)
 293   (when (notmuch-search-get-result)
 294     (goto-char (notmuch-search-result-end))))
 295
 296 (defun notmuch-search-previous-thread ()
 297   "Select the previous thread in the search results."
 298   (interactive)
 299   (if (notmuch-search-get-result)
 300       (unless (bobp)
 301         (goto-char (notmuch-search-result-beginning (- (point) 1))))
 302     ;; We must be past the end; jump to the last result
 303     (notmuch-search-last-thread)))
 304
 305 (defun notmuch-search-last-thread ()
 306   "Select the last thread in the search results."
 307   (interactive)
 308   (goto-char (point-max))
 309   (forward-line -2)
 310   (let ((beg (notmuch-search-result-beginning)))
 311     (when beg (goto-char beg))))
 312
 313 (defun notmuch-search-first-thread ()
 314   "Select the first thread in the search results."
 315   (interactive)
 316   (goto-char (point-min)))
 317
 318 (defface notmuch-message-summary-face
 319  '((((class color) (background light)) (:background "#f0f0f0"))
 320    (((class color) (background dark)) (:background "#303030")))
 321  "Face for the single-line message summary in notmuch-show-mode."
 322  :group 'notmuch-show
 323  :group 'notmuch-faces)
 324
 325 (defface notmuch-search-date
 326   '((t :inherit default))
 327   "Face used in search mode for dates."
 328   :group 'notmuch-search
 329   :group 'notmuch-faces)
 330
 331 (defface notmuch-search-count
 332   '((t :inherit default))
 333   "Face used in search mode for the count matching the query."
 334   :group 'notmuch-search
 335   :group 'notmuch-faces)
 336
 337 (defface notmuch-search-subject
 338   '((t :inherit default))
 339   "Face used in search mode for subjects."
 340   :group 'notmuch-search
 341   :group 'notmuch-faces)
 342
 343 (defface notmuch-search-matching-authors
 344   '((t :inherit default))
 345   "Face used in search mode for authors matching the query."
 346   :group 'notmuch-search
 347   :group 'notmuch-faces)
 348
 349 (defface notmuch-search-non-matching-authors
 350   '((((class color)
 351       (background dark))
 352      (:foreground "grey30"))
 353     (((class color)
 354       (background light))
 355      (:foreground "grey60"))
 356     (t
 357      (:italic t)))
 358   "Face used in search mode for authors not matching the query."
 359   :group 'notmuch-search
 360   :group 'notmuch-faces)
 361
 362 (defface notmuch-tag-face
 363   '((((class color)
 364       (background dark))
 365      (:foreground "OliveDrab1"))
 366     (((class color)
 367       (background light))
 368      (:foreground "navy blue" :bold t))
 369     (t
 370      (:bold t)))
 371   "Face used in search mode face for tags."
 372   :group 'notmuch-search
 373   :group 'notmuch-faces)
 374
 375 (defun notmuch-search-mode ()
 376   "Major mode displaying results of a notmuch search.
 377
 378 This buffer contains the results of a \"notmuch search\" of your
 379 email archives. Each line in the buffer represents a single
 380 thread giving a summary of the thread (a relative date, the
 381 number of matched messages and total messages in the thread,
 382 participants in the thread, a representative subject line, and
 383 any tags).
 384
 385 Pressing \\[notmuch-search-show-thread] on any line displays that
 386 thread. The '\\[notmuch-search-add-tag]' and
 387 '\\[notmuch-search-remove-tag]' keys can be used to add or remove
 388 tags from a thread. The '\\[notmuch-search-archive-thread]' key
 389 is a convenience for archiving a thread (applying changes in
 390 `notmuch-archive-tags'). The '\\[notmuch-search-tag-all]' key can
 391 be used to add and/or remove tags from all messages (as opposed
 392 to threads) that match the current query.  Use with caution, as
 393 this will also tag matching messages that arrived *after*
 394 constructing the buffer.
 395
 396 Other useful commands are '\\[notmuch-search-filter]' for
 397 filtering the current search based on an additional query string,
 398 '\\[notmuch-search-filter-by-tag]' for filtering to include only
 399 messages with a given tag, and '\\[notmuch-search]' to execute a
 400 new, global search.
 401
 402 Complete list of currently available key bindings:
 403
 404 \\{notmuch-search-mode-map}"
 405   (interactive)
 406   (kill-all-local-variables)
 407   (make-local-variable 'notmuch-search-query-string)
 408   (make-local-variable 'notmuch-search-oldest-first)
 409   (make-local-variable 'notmuch-search-target-thread)
 410   (make-local-variable 'notmuch-search-target-line)
 411   (setq notmuch-buffer-refresh-function #'notmuch-search-refresh-view)
 412   (set (make-local-variable 'scroll-preserve-screen-position) t)
 413   (add-to-invisibility-spec (cons 'ellipsis t))
 414   (use-local-map notmuch-search-mode-map)
 415   (setq truncate-lines t)
 416   (setq major-mode 'notmuch-search-mode
 417         mode-name "notmuch-search")
 418   (setq buffer-read-only t))
 419
 420 (defun notmuch-search-get-result (&optional pos)
 421   "Return the result object for the thread at POS (or point).
 422
 423 If there is no thread at POS (or point), returns nil."
 424   (get-text-property (or pos (point)) 'notmuch-search-result))
 425
 426 (defun notmuch-search-result-beginning (&optional pos)
 427   "Return the point at the beginning of the thread at POS (or point).
 428
 429 If there is no thread at POS (or point), returns nil."
 430   (when (notmuch-search-get-result pos)
 431     ;; We pass 1+point because previous-single-property-change starts
 432     ;; searching one before the position we give it.
 433     (previous-single-property-change (1+ (or pos (point)))
 434                                      'notmuch-search-result nil (point-min))))
 435
 436 (defun notmuch-search-result-end (&optional pos)
 437   "Return the point at the end of the thread at POS (or point).
 438
 439 The returned point will be just after the newline character that
 440 ends the result line.  If there is no thread at POS (or point),
 441 returns nil"
 442   (when (notmuch-search-get-result pos)
 443     (next-single-property-change (or pos (point)) 'notmuch-search-result
 444                                  nil (point-max))))
 445
 446 (defun notmuch-search-foreach-result (beg end function)
 447   "Invoke FUNCTION for each result between BEG and END.
 448
 449 FUNCTION should take one argument.  It will be applied to the
 450 character position of the beginning of each result that overlaps
 451 the region between points BEG and END.  As a special case, if (=
 452 BEG END), FUNCTION will be applied to the result containing point
 453 BEG."
 454
 455   (lexical-let ((pos (notmuch-search-result-beginning beg))
 456                 ;; End must be a marker in case function changes the
 457                 ;; text.
 458                 (end (copy-marker end))
 459                 ;; Make sure we examine at least one result, even if
 460                 ;; (= beg end).
 461                 (first t))
 462     ;; We have to be careful if the region extends beyond the results.
 463     ;; In this case, pos could be null or there could be no result at
 464     ;; pos.
 465     (while (and pos (or (< pos end) first))
 466       (when (notmuch-search-get-result pos)
 467         (funcall function pos))
 468       (setq pos (notmuch-search-result-end pos)
 469             first nil))))
 470 ;; Unindent the function argument of notmuch-search-foreach-result so
 471 ;; the indentation of callers doesn't get out of hand.
 472 (put 'notmuch-search-foreach-result 'lisp-indent-function 2)
 473
 474 (defun notmuch-search-properties-in-region (property beg end)
 475   (let (output)
 476     (notmuch-search-foreach-result beg end
 477       (lambda (pos)
 478         (push (plist-get (notmuch-search-get-result pos) property) output)))
 479     output))
 480
 481 (defun notmuch-search-find-thread-id (&optional bare)
 482   "Return the thread for the current thread
 483
 484 If BARE is set then do not prefix with \"thread:\""
 485   (let ((thread (plist-get (notmuch-search-get-result) :thread)))
 486     (when thread (concat (unless bare "thread:") thread))))
 487
 488 (defun notmuch-search-find-thread-id-region (beg end)
 489   "Return a list of threads for the current region"
 490   (mapcar (lambda (thread) (concat "thread:" thread))
 491           (notmuch-search-properties-in-region :thread beg end)))
 492
 493 (defun notmuch-search-find-thread-id-region-search (beg end)
 494   "Return a search string for threads for the current region"
 495   (mapconcat 'identity (notmuch-search-find-thread-id-region beg end) " or "))
 496
 497 (defun notmuch-search-find-authors ()
 498   "Return the authors for the current thread"
 499   (plist-get (notmuch-search-get-result) :authors))
 500
 501 (defun notmuch-search-find-authors-region (beg end)
 502   "Return a list of authors for the current region"
 503   (notmuch-search-properties-in-region :authors beg end))
 504
 505 (defun notmuch-search-find-subject ()
 506   "Return the subject for the current thread"
 507   (plist-get (notmuch-search-get-result) :subject))
 508
 509 (defun notmuch-search-find-subject-region (beg end)
 510   "Return a list of authors for the current region"
 511   (notmuch-search-properties-in-region :subject beg end))
 512
 513 (defun notmuch-search-show-thread (&optional elide-toggle)
 514   "Display the currently selected thread."
 515   (interactive "P")
 516   (let ((thread-id (notmuch-search-find-thread-id))
 517         (subject (notmuch-search-find-subject)))
 518     (if (> (length thread-id) 0)
 519         (notmuch-show thread-id
 520                       elide-toggle
 521                       (current-buffer)
 522                       notmuch-search-query-string
 523                       ;; Name the buffer based on the subject.
 524                       (concat "*" (truncate-string-to-width subject 30 nil nil t) "*"))
 525       (message "End of search results."))))
 526
 527 (defun notmuch-search-reply-to-thread (&optional prompt-for-sender)
 528   "Begin composing a reply-all to the entire current thread in a new buffer."
 529   (interactive "P")
 530   (let ((message-id (notmuch-search-find-thread-id)))
 531     (notmuch-mua-new-reply message-id prompt-for-sender t)))
 532
 533 (defun notmuch-search-reply-to-thread-sender (&optional prompt-for-sender)
 534   "Begin composing a reply to the entire current thread in a new buffer."
 535   (interactive "P")
 536   (let ((message-id (notmuch-search-find-thread-id)))
 537     (notmuch-mua-new-reply message-id prompt-for-sender nil)))
 538
 539 (defun notmuch-call-notmuch-process (&rest args)
 540   "Synchronously invoke \"notmuch\" with the given list of arguments.
 541
 542 If notmuch exits with a non-zero status, output from the process
 543 will appear in a buffer named \"*Notmuch errors*\" and an error
 544 will be signaled."
 545   (with-temp-buffer
 546     (let ((status (apply #'call-process notmuch-command nil t nil args)))
 547       (notmuch-check-exit-status status (cons notmuch-command args)
 548                                  (buffer-string)))))
 549
 550 (defun notmuch-search-set-tags (tags &optional pos)
 551   (let ((new-result (plist-put (notmuch-search-get-result pos) :tags tags)))
 552     (notmuch-search-update-result new-result pos)))
 553
 554 (defun notmuch-search-get-tags (&optional pos)
 555   (plist-get (notmuch-search-get-result pos) :tags))
 556
 557 (defun notmuch-search-get-tags-region (beg end)
 558   (let (output)
 559     (notmuch-search-foreach-result beg end
 560       (lambda (pos)
 561         (setq output (append output (notmuch-search-get-tags pos)))))
 562     output))
 563
 564 (defun notmuch-search-tag-region (beg end &optional tag-changes)
 565   "Change tags for threads in the given region."
 566   (let ((search-string (notmuch-search-find-thread-id-region-search beg end)))
 567     (setq tag-changes (notmuch-tag search-string tag-changes))
 568     (notmuch-search-foreach-result beg end
 569       (lambda (pos)
 570         (notmuch-search-set-tags
 571          (notmuch-update-tags (notmuch-search-get-tags pos) tag-changes)
 572          pos)))))
 573
 574 (defun notmuch-search-tag (&optional tag-changes)
 575   "Change tags for the currently selected thread or region.
 576
 577 See `notmuch-tag' for information on the format of TAG-CHANGES."
 578   (interactive)
 579   (let* ((beg (if (region-active-p) (region-beginning) (point)))
 580          (end (if (region-active-p) (region-end) (point))))
 581     (notmuch-search-tag-region beg end tag-changes)))
 582
 583 (defun notmuch-search-add-tag ()
 584   "Change tags for the current thread (defaulting to add).
 585
 586 Same as `notmuch-search-tag' but sets initial input to '+'."
 587   (interactive)
 588   (notmuch-search-tag "+"))
 589
 590 (defun notmuch-search-remove-tag ()
 591   "Change tags for the current thread (defaulting to remove).
 592
 593 Same as `notmuch-search-tag' but sets initial input to '-'."
 594   (interactive)
 595   (notmuch-search-tag "-"))
 596
 597 (put 'notmuch-search-archive-thread 'notmuch-prefix-doc
 598      "Un-archive the currently selected thread.")
 599 (defun notmuch-search-archive-thread (&optional unarchive)
 600   "Archive the currently selected thread.
 601
 602 Archive each message in the currently selected thread by applying
 603 the tag changes in `notmuch-archive-tags' to each (remove the
 604 \"inbox\" tag by default). If a prefix argument is given, the
 605 messages will be \"unarchived\" (i.e. the tag changes in
 606 `notmuch-archive-tags' will be reversed).
 607
 608 This function advances the next thread when finished."
 609   (interactive "P")
 610   (when notmuch-archive-tags
 611     (notmuch-search-tag
 612      (notmuch-tag-change-list notmuch-archive-tags unarchive)))
 613   (notmuch-search-next-thread))
 614
 615 (defun notmuch-search-update-result (result &optional pos)
 616   "Replace the result object of the thread at POS (or point) by
 617 RESULT and redraw it.
 618
 619 This will keep point in a reasonable location.  However, if there
 620 are enclosing save-excursions and the saved point is in the
 621 result being updated, the point will be restored to the beginning
 622 of the result."
 623   (let ((start (notmuch-search-result-beginning pos))
 624         (end (notmuch-search-result-end pos))
 625         (init-point (point))
 626         (inhibit-read-only t))
 627     ;; Delete the current thread
 628     (delete-region start end)
 629     ;; Insert the updated thread
 630     (notmuch-search-show-result result start)
 631     ;; If point was inside the old result, make an educated guess
 632     ;; about where to place it now.  Unfortunately, this won't work
 633     ;; with save-excursion (or any other markers that would be nice to
 634     ;; preserve, such as the window start), but there's nothing we can
 635     ;; do about that without a way to retrieve markers in a region.
 636     (when (and (>= init-point start) (<= init-point end))
 637       (let* ((new-end (notmuch-search-result-end start))
 638              (new-point (if (= init-point end)
 639                             new-end
 640                           (min init-point (- new-end 1)))))
 641         (goto-char new-point)))))
 642
 643 (defun notmuch-search-process-sentinel (proc msg)
 644   "Add a message to let user know when \"notmuch search\" exits"
 645   (let ((buffer (process-buffer proc))
 646         (status (process-status proc))
 647         (exit-status (process-exit-status proc))
 648         (never-found-target-thread nil))
 649     (when (memq status '(exit signal))
 650       (catch 'return
 651         (kill-buffer (process-get proc 'parse-buf))
 652         (if (buffer-live-p buffer)
 653             (with-current-buffer buffer
 654               (save-excursion
 655                 (let ((inhibit-read-only t)
 656                       (atbob (bobp)))
 657                   (goto-char (point-max))
 658                   (if (eq status 'signal)
 659                       (insert "Incomplete search results (search process was killed).\n"))
 660                   (when (eq status 'exit)
 661                     (insert "End of search results.\n")
 662                     ;; For version mismatch, there's no point in
 663                     ;; showing the search buffer
 664                     (when (or (= exit-status 20) (= exit-status 21))
 665                       (kill-buffer)
 666                       (throw 'return nil))
 667                     (if (and atbob
 668                              (not (string= notmuch-search-target-thread "found")))
 669                         (set 'never-found-target-thread t)))))
 670               (when (and never-found-target-thread
 671                        notmuch-search-target-line)
 672                   (goto-char (point-min))
 673                   (forward-line (1- notmuch-search-target-line)))))))))
 674
 675 (defcustom notmuch-search-line-faces '(("unread" :weight bold)
 676                                        ("flagged" :foreground "blue"))
 677   "Tag/face mapping for line highlighting in notmuch-search.
 678
 679 Here is an example of how to color search results based on tags.
 680  (the following text would be placed in your ~/.emacs file):
 681
 682  (setq notmuch-search-line-faces '((\"deleted\" . (:foreground \"red\"
 683                                                   :background \"blue\"))
 684                                    (\"unread\" . (:foreground \"green\"))))
 685
 686 The attributes defined for matching tags are merged, with later
 687 attributes overriding earlier. A message having both \"deleted\"
 688 and \"unread\" tags with the above settings would have a green
 689 foreground and blue background."
 690   :type '(alist :key-type (string) :value-type (custom-face-edit))
 691   :group 'notmuch-search
 692   :group 'notmuch-faces)
 693
 694 (defun notmuch-search-color-line (start end line-tag-list)
 695   "Colorize lines in `notmuch-show' based on tags."
 696   (mapc (lambda (elem)
 697           (let ((tag (car elem))
 698                 (attributes (cdr elem)))
 699             (when (member tag line-tag-list)
 700               (notmuch-combine-face-text-property start end attributes))))
 701         ;; Reverse the list so earlier entries take precedence
 702         (reverse notmuch-search-line-faces)))
 703
 704 (defun notmuch-search-author-propertize (authors)
 705   "Split `authors' into matching and non-matching authors and
 706 propertize appropriately. If no boundary between authors and
 707 non-authors is found, assume that all of the authors match."
 708   (if (string-match "\\(.*\\)|\\(.*\\)" authors)
 709       (concat (propertize (concat (match-string 1 authors) ",")
 710                           'face 'notmuch-search-matching-authors)
 711               (propertize (match-string 2 authors)
 712                           'face 'notmuch-search-non-matching-authors))
 713     (propertize authors 'face 'notmuch-search-matching-authors)))
 714
 715 (defun notmuch-search-insert-authors (format-string authors)
 716   ;; Save the match data to avoid interfering with
 717   ;; `notmuch-search-process-filter'.
 718   (save-match-data
 719     (let* ((formatted-authors (format format-string authors))
 720            (formatted-sample (format format-string ""))
 721            (visible-string formatted-authors)
 722            (invisible-string "")
 723            (padding ""))
 724
 725       ;; Truncate the author string to fit the specification.
 726       (if (> (length formatted-authors)
 727              (length formatted-sample))
 728           (let ((visible-length (- (length formatted-sample)
 729                                    (length "... "))))
 730             ;; Truncate the visible string according to the width of
 731             ;; the display string.
 732             (setq visible-string (substring formatted-authors 0 visible-length)
 733                   invisible-string (substring formatted-authors visible-length))
 734             ;; If possible, truncate the visible string at a natural
 735             ;; break (comma or pipe), as incremental search doesn't
 736             ;; match across the visible/invisible border.
 737             (when (string-match "\\(.*\\)\\([,|] \\)\\([^,|]*\\)" visible-string)
 738               ;; Second clause is destructive on `visible-string', so
 739               ;; order is important.
 740               (setq invisible-string (concat (match-string 3 visible-string)
 741                                              invisible-string)
 742                     visible-string (concat (match-string 1 visible-string)
 743                                            (match-string 2 visible-string))))
 744             ;; `visible-string' may be shorter than the space allowed
 745             ;; by `format-string'. If so we must insert some padding
 746             ;; after `invisible-string'.
 747             (setq padding (make-string (- (length formatted-sample)
 748                                           (length visible-string)
 749                                           (length "..."))
 750                                        ? ))))
 751
 752       ;; Use different faces to show matching and non-matching authors.
 753       (if (string-match "\\(.*\\)|\\(.*\\)" visible-string)
 754           ;; The visible string contains both matching and
 755           ;; non-matching authors.
 756           (setq visible-string (notmuch-search-author-propertize visible-string)
 757                 ;; The invisible string must contain only non-matching
 758                 ;; authors, as the visible-string contains both.
 759                 invisible-string (propertize invisible-string
 760                                              'face 'notmuch-search-non-matching-authors))
 761         ;; The visible string contains only matching authors.
 762         (setq visible-string (propertize visible-string
 763                                          'face 'notmuch-search-matching-authors)
 764               ;; The invisible string may contain both matching and
 765               ;; non-matching authors.
 766               invisible-string (notmuch-search-author-propertize invisible-string)))
 767
 768       ;; If there is any invisible text, add it as a tooltip to the
 769       ;; visible text.
 770       (when (not (string= invisible-string ""))
 771         (setq visible-string (propertize visible-string 'help-echo (concat "..." invisible-string))))
 772
 773       ;; Insert the visible and, if present, invisible author strings.
 774       (insert visible-string)
 775       (when (not (string= invisible-string ""))
 776         (let ((start (point))
 777               overlay)
 778           (insert invisible-string)
 779           (setq overlay (make-overlay start (point)))
 780           (overlay-put overlay 'invisible 'ellipsis)
 781           (overlay-put overlay 'isearch-open-invisible #'delete-overlay)))
 782       (insert padding))))
 783
 784 (defun notmuch-search-insert-field (field format-string result)
 785   (cond
 786    ((string-equal field "date")
 787     (insert (propertize (format format-string (plist-get result :date_relative))
 788                         'face 'notmuch-search-date)))
 789    ((string-equal field "count")
 790     (insert (propertize (format format-string
 791                                 (format "[%s/%s]" (plist-get result :matched)
 792                                         (plist-get result :total)))
 793                         'face 'notmuch-search-count)))
 794    ((string-equal field "subject")
 795     (insert (propertize (format format-string (plist-get result :subject))
 796                         'face 'notmuch-search-subject)))
 797
 798    ((string-equal field "authors")
 799     (notmuch-search-insert-authors format-string (plist-get result :authors)))
 800
 801    ((string-equal field "tags")
 802     (let ((tags (plist-get result :tags)))
 803       (insert (format format-string (notmuch-tag-format-tags tags)))))))
 804
 805 (defun notmuch-search-show-result (result &optional pos)
 806   "Insert RESULT at POS or the end of the buffer if POS is null."
 807   ;; Ignore excluded matches
 808   (unless (= (plist-get result :matched) 0)
 809     (let ((beg (or pos (point-max))))
 810       (save-excursion
 811         (goto-char beg)
 812         (dolist (spec notmuch-search-result-format)
 813           (notmuch-search-insert-field (car spec) (cdr spec) result))
 814         (insert "\n")
 815         (notmuch-search-color-line beg (point) (plist-get result :tags))
 816         (put-text-property beg (point) 'notmuch-search-result result))
 817       (when (string= (plist-get result :thread) notmuch-search-target-thread)
 818         (setq notmuch-search-target-thread "found")
 819         (goto-char beg)))))
 820
 821 (defun notmuch-search-process-filter (proc string)
 822   "Process and filter the output of \"notmuch search\""
 823   (let ((results-buf (process-buffer proc))
 824         (parse-buf (process-get proc 'parse-buf))
 825         (inhibit-read-only t)
 826         done)
 827     (when (buffer-live-p results-buf)
 828       (with-current-buffer parse-buf
 829         ;; Insert new data
 830         (save-excursion
 831           (goto-char (point-max))
 832           (insert string))
 833         (notmuch-sexp-parse-partial-list 'notmuch-search-show-result
 834                                          results-buf)))))
 835
 836 (defun notmuch-search-tag-all (&optional tag-changes)
 837   "Add/remove tags from all messages in current search buffer.
 838
 839 See `notmuch-tag' for information on the format of TAG-CHANGES."
 840   (interactive)
 841   (notmuch-tag notmuch-search-query-string tag-changes))
 842
 843 (defun notmuch-search-buffer-title (query)
 844   "Returns the title for a buffer with notmuch search results."
 845   (let* ((saved-search
 846           (let (longest
 847                 (longest-length 0))
 848             (loop for tuple in notmuch-saved-searches
 849                   if (let ((quoted-query (regexp-quote (cdr tuple))))
 850                        (and (string-match (concat "^" quoted-query) query)
 851                             (> (length (match-string 0 query))
 852                                longest-length)))
 853                   do (setq longest tuple))
 854             longest))
 855          (saved-search-name (car saved-search))
 856          (saved-search-query (cdr saved-search)))
 857     (cond ((and saved-search (equal saved-search-query query))
 858            ;; Query is the same as saved search (ignoring case)
 859            (concat "*notmuch-saved-search-" saved-search-name "*"))
 860           (saved-search
 861            (concat "*notmuch-search-"
 862                    (replace-regexp-in-string (concat "^" (regexp-quote saved-search-query))
 863                                              (concat "[ " saved-search-name " ]")
 864                                              query)
 865                    "*"))
 866           (t
 867            (concat "*notmuch-search-" query "*"))
 868           )))
 869
 870 (defun notmuch-read-query (prompt)
 871   "Read a notmuch-query from the minibuffer with completion.
 872
 873 PROMPT is the string to prompt with."
 874   (lexical-let
 875       ((completions
 876         (append (list "folder:" "thread:" "id:" "date:" "from:" "to:"
 877                       "subject:" "attachment:")
 878                 (mapcar (lambda (tag)
 879                           (concat "tag:" (notmuch-escape-boolean-term tag)))
 880                         (process-lines notmuch-command "search" "--output=tags" "*")))))
 881     (let ((keymap (copy-keymap minibuffer-local-map))
 882           (minibuffer-completion-table
 883            (completion-table-dynamic
 884             (lambda (string)
 885               ;; generate a list of possible completions for the current input
 886               (cond
 887                ;; this ugly regexp is used to get the last word of the input
 888                ;; possibly preceded by a '('
 889                ((string-match "\\(^\\|.* (?\\)\\([^ ]*\\)$" string)
 890                 (mapcar (lambda (compl)
 891                           (concat (match-string-no-properties 1 string) compl))
 892                         (all-completions (match-string-no-properties 2 string)
 893                                          completions)))
 894                (t (list string)))))))
 895       ;; this was simpler than convincing completing-read to accept spaces:
 896       (define-key keymap (kbd "TAB") 'minibuffer-complete)
 897       (let ((history-delete-duplicates t))
 898         (read-from-minibuffer prompt nil keymap nil
 899                               'notmuch-search-history nil nil)))))
 900
 901 ;;;###autoload
 902 (put 'notmuch-search 'notmuch-doc "Search for messages.")
 903 (defun notmuch-search (&optional query oldest-first target-thread target-line)
 904   "Display threads matching QUERY in a notmuch-search buffer.
 905
 906 If QUERY is nil, it is read interactively from the minibuffer.
 907 Other optional parameters are used as follows:
 908
 909   OLDEST-FIRST: A Boolean controlling the sort order of returned threads
 910   TARGET-THREAD: A thread ID (without the thread: prefix) that will be made
 911                  current if it appears in the search results.
 912   TARGET-LINE: The line number to move to if the target thread does not
 913                appear in the search results.
 914
 915 When called interactively, this will prompt for a query and use
 916 the configured default sort order."
 917   (interactive
 918    (list
 919     ;; Prompt for a query
 920     nil
 921     ;; Use the default search order (if we're doing a search from a
 922     ;; search buffer, ignore any buffer-local overrides)
 923     (default-value 'notmuch-search-oldest-first)))
 924
 925   (let* ((query (or query (notmuch-read-query "Notmuch search: ")))
 926          (buffer (get-buffer-create (notmuch-search-buffer-title query))))
 927     (switch-to-buffer buffer)
 928     (notmuch-search-mode)
 929     ;; Don't track undo information for this buffer
 930     (set 'buffer-undo-list t)
 931     (set 'notmuch-search-query-string query)
 932     (set 'notmuch-search-oldest-first oldest-first)
 933     (set 'notmuch-search-target-thread target-thread)
 934     (set 'notmuch-search-target-line target-line)
 935     (let ((proc (get-buffer-process (current-buffer)))
 936           (inhibit-read-only t))
 937       (if proc
 938           (error "notmuch search process already running for query `%s'" query)
 939         )
 940       (erase-buffer)
 941       (goto-char (point-min))
 942       (save-excursion
 943         (let ((proc (notmuch-start-notmuch
 944                      "notmuch-search" buffer #'notmuch-search-process-sentinel
 945                      "search" "--format=sexp" "--format-version=1"
 946                      (if oldest-first
 947                          "--sort=oldest-first"
 948                        "--sort=newest-first")
 949                      query))
 950               ;; Use a scratch buffer to accumulate partial output.
 951               ;; This buffer will be killed by the sentinel, which
 952               ;; should be called no matter how the process dies.
 953               (parse-buf (generate-new-buffer " *notmuch search parse*")))
 954           (process-put proc 'parse-buf parse-buf)
 955           (set-process-filter proc 'notmuch-search-process-filter)
 956           (set-process-query-on-exit-flag proc nil))))
 957     (run-hooks 'notmuch-search-hook)))
 958
 959 (defun notmuch-search-refresh-view ()
 960   "Refresh the current view.
 961
 962 Kills the current buffer and runs a new search with the same
 963 query string as the current search. If the current thread is in
 964 the new search results, then point will be placed on the same
 965 thread. Otherwise, point will be moved to attempt to be in the
 966 same relative position within the new buffer."
 967   (let ((target-line (line-number-at-pos))
 968         (oldest-first notmuch-search-oldest-first)
 969         (target-thread (notmuch-search-find-thread-id 'bare))
 970         (query notmuch-search-query-string))
 971     (notmuch-kill-this-buffer)
 972     (notmuch-search query oldest-first target-thread target-line)
 973     (goto-char (point-min))))
 974
 975 (defun notmuch-search-toggle-order ()
 976   "Toggle the current search order.
 977
 978 This command toggles the sort order for the current search. The
 979 default sort order is defined by `notmuch-search-oldest-first'."
 980   (interactive)
 981   (set 'notmuch-search-oldest-first (not notmuch-search-oldest-first))
 982   (notmuch-search-refresh-view))
 983
 984 (defun notmuch-search-filter (query)
 985   "Filter the current search results based on an additional query string.
 986
 987 Runs a new search matching only messages that match both the
 988 current search results AND the additional query string provided."
 989   (interactive (list (notmuch-read-query "Filter search: ")))
 990   (let ((grouped-query (if (string-match-p notmuch-search-disjunctive-regexp query)
 991                            (concat "( " query " )")
 992                          query)))
 993     (notmuch-search (if (string= notmuch-search-query-string "*")
 994                         grouped-query
 995                       (concat notmuch-search-query-string " and " grouped-query)) notmuch-search-oldest-first)))
 996
 997 (defun notmuch-search-filter-by-tag (tag)
 998   "Filter the current search results based on a single tag.
 999
1000 Runs a new search matching only messages that match both the
1001 current search results AND that are tagged with the given tag."
1002   (interactive
1003    (list (notmuch-select-tag-with-completion "Filter by tag: ")))
1004   (notmuch-search (concat notmuch-search-query-string " and tag:" tag) notmuch-search-oldest-first))
1005
1006 ;;;###autoload
1007 (defun notmuch ()
1008   "Run notmuch and display saved searches, known tags, etc."
1009   (interactive)
1010   (notmuch-hello))
1011
1012 (defun notmuch-interesting-buffer (b)
1013   "Is the current buffer of interest to a notmuch user?"
1014   (with-current-buffer b
1015     (memq major-mode '(notmuch-show-mode
1016                        notmuch-search-mode
1017                        notmuch-hello-mode
1018                        message-mode))))
1019
1020 ;;;###autoload
1021 (defun notmuch-cycle-notmuch-buffers ()
1022   "Cycle through any existing notmuch buffers (search, show or hello).
1023
1024 If the current buffer is the only notmuch buffer, bury it. If no
1025 notmuch buffers exist, run `notmuch'."
1026   (interactive)
1027
1028   (let (start first)
1029     ;; If the current buffer is a notmuch buffer, remember it and then
1030     ;; bury it.
1031     (when (notmuch-interesting-buffer (current-buffer))
1032       (setq start (current-buffer))
1033       (bury-buffer))
1034
1035     ;; Find the first notmuch buffer.
1036     (setq first (loop for buffer in (buffer-list)
1037                      if (notmuch-interesting-buffer buffer)
1038                      return buffer))
1039
1040     (if first
1041         ;; If the first one we found is any other than the starting
1042         ;; buffer, switch to it.
1043         (unless (eq first start)
1044           (switch-to-buffer first))
1045       (notmuch))))
1046
1047 (setq mail-user-agent 'notmuch-user-agent)
1048
1049 (provide 'notmuch)