git.notmuchmail.org Git - notmuch/blob - emacs/notmuch.el

   1 ;;; notmuch.el --- run notmuch within emacs
   2 ;;
   3 ;; Copyright © Carl Worth
   4 ;;
   5 ;; This file is part of Notmuch.
   6 ;;
   7 ;; Notmuch is free software: you can redistribute it and/or modify it
   8 ;; under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation, either version 3 of the License, or
  10 ;; (at your option) any later version.
  11 ;;
  12 ;; Notmuch is distributed in the hope that it will be useful, but
  13 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 ;; General Public License for more details.
  16 ;;
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with Notmuch.  If not, see <https://www.gnu.org/licenses/>.
  19 ;;
  20 ;; Authors: Carl Worth <cworth@cworth.org>
  21 ;; Homepage: https://notmuchmail.org/
  22
  23 ;;; Commentary:
  24
  25 ;; This is an emacs-based interface to the notmuch mail system.
  26 ;;
  27 ;; You will first need to have the notmuch program installed and have a
  28 ;; notmuch database built in order to use this. See
  29 ;; https://notmuchmail.org for details.
  30 ;;
  31 ;; To install this software, copy it to a directory that is on the
  32 ;; `load-path' variable within emacs (a good candidate is
  33 ;; /usr/local/share/emacs/site-lisp). If you are viewing this from the
  34 ;; notmuch source distribution then you can simply run:
  35 ;;
  36 ;;      sudo make install-emacs
  37 ;;
  38 ;; to install it.
  39 ;;
  40 ;; Then, to actually run it, add:
  41 ;;
  42 ;;      (autoload 'notmuch "notmuch" "Notmuch mail" t)
  43 ;;
  44 ;; to your ~/.emacs file, and then run "M-x notmuch" from within emacs,
  45 ;; or run:
  46 ;;
  47 ;;      emacs -f notmuch
  48 ;;
  49 ;; Have fun, and let us know if you have any comment, questions, or
  50 ;; kudos: Notmuch list <notmuch@notmuchmail.org> (subscription is not
  51 ;; required, but is available from https://notmuchmail.org).
  52
  53 ;;; Code:
  54
  55 (eval-when-compile (require 'cl))
  56 (require 'mm-view)
  57 (require 'message)
  58
  59 (require 'notmuch-lib)
  60 (require 'notmuch-tag)
  61 (require 'notmuch-show)
  62 (require 'notmuch-tree)
  63 (require 'notmuch-mua)
  64 (require 'notmuch-hello)
  65 (require 'notmuch-maildir-fcc)
  66 (require 'notmuch-message)
  67 (require 'notmuch-parser)
  68
  69 (defcustom notmuch-search-result-format
  70   `(("date" . "%12s ")
  71     ("count" . "%-7s ")
  72     ("authors" . "%-20s ")
  73     ("subject" . "%s ")
  74     ("tags" . "(%s)"))
  75   "Search result formatting. Supported fields are:
  76         date, count, authors, subject, tags
  77 For example:
  78         (setq notmuch-search-result-format \(\(\"authors\" . \"%-40s\"\)
  79                                              \(\"subject\" . \"%s\"\)\)\)
  80 Line breaks are permitted in format strings (though this is
  81 currently experimental).  Note that a line break at the end of an
  82 \"authors\" field will get elided if the authors list is long;
  83 place it instead at the beginning of the following field.  To
  84 enter a line break when setting this variable with setq, use \\n.
  85 To enter a line break in customize, press \\[quoted-insert] C-j."
  86   :type '(alist :key-type (string) :value-type (string))
  87   :group 'notmuch-search)
  88
  89 ;; The name of this variable `notmuch-init-file' is consistent with the
  90 ;; convention used in e.g. emacs and gnus. The value, `notmuch-config[.el[c]]'
  91 ;; is consistent with notmuch cli configuration file `~/.notmuch-config'.
  92 (defcustom notmuch-init-file (locate-user-emacs-file "notmuch-config")
  93   "Your Notmuch Emacs-Lisp configuration file name.
  94 If a file with one of the suffixes defined by `get-load-suffixes' exists,
  95 it will be read instead.
  96 This file is read once when notmuch is loaded; the notmuch hooks added
  97 there will be called at other points of notmuch execution."
  98   :type 'file
  99   :group 'notmuch)
 100
 101 (defvar notmuch-query-history nil
 102   "Variable to store minibuffer history for notmuch queries")
 103
 104 (defun notmuch-foreach-mime-part (function mm-handle)
 105   (cond ((stringp (car mm-handle))
 106          (dolist (part (cdr mm-handle))
 107            (notmuch-foreach-mime-part function part)))
 108         ((bufferp (car mm-handle))
 109          (funcall function mm-handle))
 110         (t (dolist (part mm-handle)
 111              (notmuch-foreach-mime-part function part)))))
 112
 113 (defun notmuch-count-attachments (mm-handle)
 114   (let ((count 0))
 115     (notmuch-foreach-mime-part
 116      (lambda (p)
 117        (let ((disposition (mm-handle-disposition p)))
 118          (and (listp disposition)
 119               (or (equal (car disposition) "attachment")
 120                   (and (equal (car disposition) "inline")
 121                        (assq 'filename disposition)))
 122               (incf count))))
 123      mm-handle)
 124     count))
 125
 126 (defun notmuch-save-attachments (mm-handle &optional queryp)
 127   (notmuch-foreach-mime-part
 128    (lambda (p)
 129      (let ((disposition (mm-handle-disposition p)))
 130        (and (listp disposition)
 131             (or (equal (car disposition) "attachment")
 132                 (and (equal (car disposition) "inline")
 133                      (assq 'filename disposition)))
 134             (or (not queryp)
 135                 (y-or-n-p
 136                  (concat "Save '" (cdr (assq 'filename disposition)) "' ")))
 137             (mm-save-part p))))
 138    mm-handle))
 139
 140 (require 'hl-line)
 141
 142 (defun notmuch-hl-line-mode ()
 143   (prog1 (hl-line-mode)
 144     (when hl-line-overlay
 145       (overlay-put hl-line-overlay 'priority 1))))
 146
 147 (defcustom notmuch-search-hook '(notmuch-hl-line-mode)
 148   "List of functions to call when notmuch displays the search results."
 149   :type 'hook
 150   :options '(notmuch-hl-line-mode)
 151   :group 'notmuch-search
 152   :group 'notmuch-hooks)
 153
 154 (defvar notmuch-search-mode-map
 155   (let ((map (make-sparse-keymap)))
 156     (set-keymap-parent map notmuch-common-keymap)
 157     (define-key map "x" 'notmuch-bury-or-kill-this-buffer)
 158     (define-key map (kbd "<DEL>") 'notmuch-search-scroll-down)
 159     (define-key map "b" 'notmuch-search-scroll-down)
 160     (define-key map " " 'notmuch-search-scroll-up)
 161     (define-key map "<" 'notmuch-search-first-thread)
 162     (define-key map ">" 'notmuch-search-last-thread)
 163     (define-key map "p" 'notmuch-search-previous-thread)
 164     (define-key map "n" 'notmuch-search-next-thread)
 165     (define-key map "r" 'notmuch-search-reply-to-thread-sender)
 166     (define-key map "R" 'notmuch-search-reply-to-thread)
 167     (define-key map "o" 'notmuch-search-toggle-order)
 168     (define-key map "c" 'notmuch-search-stash-map)
 169     (define-key map "t" 'notmuch-search-filter-by-tag)
 170     (define-key map "l" 'notmuch-search-filter)
 171     (define-key map [mouse-1] 'notmuch-search-show-thread)
 172     (define-key map "k" 'notmuch-tag-jump)
 173     (define-key map "*" 'notmuch-search-tag-all)
 174     (define-key map "a" 'notmuch-search-archive-thread)
 175     (define-key map "-" 'notmuch-search-remove-tag)
 176     (define-key map "+" 'notmuch-search-add-tag)
 177     (define-key map (kbd "RET") 'notmuch-search-show-thread)
 178     (define-key map "Z" 'notmuch-tree-from-search-current-query)
 179     map)
 180   "Keymap for \"notmuch search\" buffers.")
 181 (fset 'notmuch-search-mode-map notmuch-search-mode-map)
 182
 183 (defvar notmuch-search-stash-map
 184   (let ((map (make-sparse-keymap)))
 185     (define-key map "i" 'notmuch-search-stash-thread-id)
 186     (define-key map "q" 'notmuch-stash-query)
 187     (define-key map "?" 'notmuch-subkeymap-help)
 188     map)
 189   "Submap for stash commands")
 190 (fset 'notmuch-search-stash-map notmuch-search-stash-map)
 191
 192 (defun notmuch-search-stash-thread-id ()
 193   "Copy thread ID of current thread to kill-ring."
 194   (interactive)
 195   (notmuch-common-do-stash (notmuch-search-find-thread-id)))
 196
 197 (defun notmuch-stash-query ()
 198   "Copy current query to kill-ring."
 199   (interactive)
 200   (notmuch-common-do-stash (notmuch-search-get-query)))
 201
 202 (defvar notmuch-search-query-string)
 203 (defvar notmuch-search-target-thread)
 204 (defvar notmuch-search-target-line)
 205
 206 (defvar notmuch-search-disjunctive-regexp      "\\<[oO][rR]\\>")
 207
 208 (defun notmuch-search-scroll-up ()
 209   "Move forward through search results by one window's worth."
 210   (interactive)
 211   (condition-case nil
 212       (scroll-up nil)
 213     ((end-of-buffer) (notmuch-search-last-thread))))
 214
 215 (defun notmuch-search-scroll-down ()
 216   "Move backward through the search results by one window's worth."
 217   (interactive)
 218   ;; I don't know why scroll-down doesn't signal beginning-of-buffer
 219   ;; the way that scroll-up signals end-of-buffer, but c'est la vie.
 220   ;;
 221   ;; So instead of trapping a signal we instead check whether the
 222   ;; window begins on the first line of the buffer and if so, move
 223   ;; directly to that position. (We have to count lines since the
 224   ;; window-start position is not the same as point-min due to the
 225   ;; invisible thread-ID characters on the first line.
 226   (if (equal (count-lines (point-min) (window-start)) 0)
 227       (goto-char (point-min))
 228     (scroll-down nil)))
 229
 230 (defun notmuch-search-next-thread ()
 231   "Select the next thread in the search results."
 232   (interactive)
 233   (when (notmuch-search-get-result)
 234     (goto-char (notmuch-search-result-end))))
 235
 236 (defun notmuch-search-previous-thread ()
 237   "Select the previous thread in the search results."
 238   (interactive)
 239   (if (notmuch-search-get-result)
 240       (unless (bobp)
 241         (goto-char (notmuch-search-result-beginning (- (point) 1))))
 242     ;; We must be past the end; jump to the last result
 243     (notmuch-search-last-thread)))
 244
 245 (defun notmuch-search-last-thread ()
 246   "Select the last thread in the search results."
 247   (interactive)
 248   (goto-char (point-max))
 249   (forward-line -2)
 250   (let ((beg (notmuch-search-result-beginning)))
 251     (when beg (goto-char beg))))
 252
 253 (defun notmuch-search-first-thread ()
 254   "Select the first thread in the search results."
 255   (interactive)
 256   (goto-char (point-min)))
 257
 258 (defface notmuch-message-summary-face
 259  '((((class color) (background light)) (:background "#f0f0f0"))
 260    (((class color) (background dark)) (:background "#303030")))
 261  "Face for the single-line message summary in notmuch-show-mode."
 262  :group 'notmuch-show
 263  :group 'notmuch-faces)
 264
 265 (defface notmuch-search-date
 266   '((t :inherit default))
 267   "Face used in search mode for dates."
 268   :group 'notmuch-search
 269   :group 'notmuch-faces)
 270
 271 (defface notmuch-search-count
 272   '((t :inherit default))
 273   "Face used in search mode for the count matching the query."
 274   :group 'notmuch-search
 275   :group 'notmuch-faces)
 276
 277 (defface notmuch-search-subject
 278   '((t :inherit default))
 279   "Face used in search mode for subjects."
 280   :group 'notmuch-search
 281   :group 'notmuch-faces)
 282
 283 (defface notmuch-search-matching-authors
 284   '((t :inherit default))
 285   "Face used in search mode for authors matching the query."
 286   :group 'notmuch-search
 287   :group 'notmuch-faces)
 288
 289 (defface notmuch-search-non-matching-authors
 290   '((((class color)
 291       (background dark))
 292      (:foreground "grey30"))
 293     (((class color)
 294       (background light))
 295      (:foreground "grey60"))
 296     (t
 297      (:italic t)))
 298   "Face used in search mode for authors not matching the query."
 299   :group 'notmuch-search
 300   :group 'notmuch-faces)
 301
 302 (defface notmuch-tag-face
 303   '((((class color)
 304       (background dark))
 305      (:foreground "OliveDrab1"))
 306     (((class color)
 307       (background light))
 308      (:foreground "navy blue" :bold t))
 309     (t
 310      (:bold t)))
 311   "Face used in search mode face for tags."
 312   :group 'notmuch-search
 313   :group 'notmuch-faces)
 314
 315 (defface notmuch-search-flagged-face
 316   '((t
 317      (:weight bold)))
 318   "Face used in search mode face for flagged threads.
 319
 320 This face is the default value for the \"flagged\" tag in
 321 `notmuch-search-line-faces`."
 322   :group 'notmuch-search
 323   :group 'notmuch-faces)
 324
 325 (defface notmuch-search-unread-face
 326   '((t
 327      (:foreground "blue")))
 328   "Face used in search mode for unread threads.
 329
 330 This face is the default value for the \"unread\" tag in
 331 `notmuch-search-line-faces`."
 332   :group 'notmuch-search
 333   :group 'notmuch-faces)
 334
 335 (define-derived-mode notmuch-search-mode fundamental-mode "notmuch-search"
 336   "Major mode displaying results of a notmuch search.
 337
 338 This buffer contains the results of a \"notmuch search\" of your
 339 email archives. Each line in the buffer represents a single
 340 thread giving a summary of the thread (a relative date, the
 341 number of matched messages and total messages in the thread,
 342 participants in the thread, a representative subject line, and
 343 any tags).
 344
 345 Pressing \\[notmuch-search-show-thread] on any line displays that
 346 thread. The '\\[notmuch-search-add-tag]' and
 347 '\\[notmuch-search-remove-tag]' keys can be used to add or remove
 348 tags from a thread. The '\\[notmuch-search-archive-thread]' key
 349 is a convenience for archiving a thread (applying changes in
 350 `notmuch-archive-tags'). The '\\[notmuch-search-tag-all]' key can
 351 be used to add and/or remove tags from all messages (as opposed
 352 to threads) that match the current query.  Use with caution, as
 353 this will also tag matching messages that arrived *after*
 354 constructing the buffer.
 355
 356 Other useful commands are '\\[notmuch-search-filter]' for
 357 filtering the current search based on an additional query string,
 358 '\\[notmuch-search-filter-by-tag]' for filtering to include only
 359 messages with a given tag, and '\\[notmuch-search]' to execute a
 360 new, global search.
 361
 362 Complete list of currently available key bindings:
 363
 364 \\{notmuch-search-mode-map}"
 365   (make-local-variable 'notmuch-search-query-string)
 366   (make-local-variable 'notmuch-search-oldest-first)
 367   (make-local-variable 'notmuch-search-target-thread)
 368   (make-local-variable 'notmuch-search-target-line)
 369   (setq notmuch-buffer-refresh-function #'notmuch-search-refresh-view)
 370   (set (make-local-variable 'scroll-preserve-screen-position) t)
 371   (add-to-invisibility-spec (cons 'ellipsis t))
 372   (setq truncate-lines t)
 373   (setq buffer-read-only t))
 374
 375 (defun notmuch-search-get-result (&optional pos)
 376   "Return the result object for the thread at POS (or point).
 377
 378 If there is no thread at POS (or point), returns nil."
 379   (get-text-property (or pos (point)) 'notmuch-search-result))
 380
 381 (defun notmuch-search-result-beginning (&optional pos)
 382   "Return the point at the beginning of the thread at POS (or point).
 383
 384 If there is no thread at POS (or point), returns nil."
 385   (when (notmuch-search-get-result pos)
 386     ;; We pass 1+point because previous-single-property-change starts
 387     ;; searching one before the position we give it.
 388     (previous-single-property-change (1+ (or pos (point)))
 389                                      'notmuch-search-result nil (point-min))))
 390
 391 (defun notmuch-search-result-end (&optional pos)
 392   "Return the point at the end of the thread at POS (or point).
 393
 394 The returned point will be just after the newline character that
 395 ends the result line.  If there is no thread at POS (or point),
 396 returns nil"
 397   (when (notmuch-search-get-result pos)
 398     (next-single-property-change (or pos (point)) 'notmuch-search-result
 399                                  nil (point-max))))
 400
 401 (defun notmuch-search-foreach-result (beg end function)
 402   "Invoke FUNCTION for each result between BEG and END.
 403
 404 FUNCTION should take one argument.  It will be applied to the
 405 character position of the beginning of each result that overlaps
 406 the region between points BEG and END.  As a special case, if (=
 407 BEG END), FUNCTION will be applied to the result containing point
 408 BEG."
 409
 410   (lexical-let ((pos (notmuch-search-result-beginning beg))
 411                 ;; End must be a marker in case function changes the
 412                 ;; text.
 413                 (end (copy-marker end))
 414                 ;; Make sure we examine at least one result, even if
 415                 ;; (= beg end).
 416                 (first t))
 417     ;; We have to be careful if the region extends beyond the results.
 418     ;; In this case, pos could be null or there could be no result at
 419     ;; pos.
 420     (while (and pos (or (< pos end) first))
 421       (when (notmuch-search-get-result pos)
 422         (funcall function pos))
 423       (setq pos (notmuch-search-result-end pos)
 424             first nil))))
 425 ;; Unindent the function argument of notmuch-search-foreach-result so
 426 ;; the indentation of callers doesn't get out of hand.
 427 (put 'notmuch-search-foreach-result 'lisp-indent-function 2)
 428
 429 (defun notmuch-search-properties-in-region (property beg end)
 430   (let (output)
 431     (notmuch-search-foreach-result beg end
 432       (lambda (pos)
 433         (push (plist-get (notmuch-search-get-result pos) property) output)))
 434     output))
 435
 436 (defun notmuch-search-find-thread-id (&optional bare)
 437   "Return the thread for the current thread
 438
 439 If BARE is set then do not prefix with \"thread:\""
 440   (let ((thread (plist-get (notmuch-search-get-result) :thread)))
 441     (when thread (concat (unless bare "thread:") thread))))
 442
 443 (defun notmuch-search-find-stable-query ()
 444   "Return the stable queries for the current thread.
 445
 446 This returns a list (MATCHED-QUERY UNMATCHED-QUERY) for the
 447 matched and unmatched messages in the current thread."
 448   (plist-get (notmuch-search-get-result) :query))
 449
 450 (defun notmuch-search-find-stable-query-region (beg end &optional only-matched)
 451   "Return the stable query for the current region.
 452
 453 If ONLY-MATCHED is non-nil, include only matched messages.  If it
 454 is nil, include both matched and unmatched messages. If there are
 455 no messages in the region then return nil."
 456   (let ((query-list nil) (all (not only-matched)))
 457     (dolist (queries (notmuch-search-properties-in-region :query beg end))
 458       (when (first queries)
 459         (push (first queries) query-list))
 460       (when (and all (second queries))
 461         (push (second queries) query-list)))
 462     (when query-list
 463       (concat "(" (mapconcat 'identity query-list ") or (") ")"))))
 464
 465 (defun notmuch-search-find-authors ()
 466   "Return the authors for the current thread"
 467   (plist-get (notmuch-search-get-result) :authors))
 468
 469 (defun notmuch-search-find-authors-region (beg end)
 470   "Return a list of authors for the current region"
 471   (notmuch-search-properties-in-region :authors beg end))
 472
 473 (defun notmuch-search-find-subject ()
 474   "Return the subject for the current thread"
 475   (plist-get (notmuch-search-get-result) :subject))
 476
 477 (defun notmuch-search-find-subject-region (beg end)
 478   "Return a list of authors for the current region"
 479   (notmuch-search-properties-in-region :subject beg end))
 480
 481 (defun notmuch-search-show-thread (&optional elide-toggle)
 482   "Display the currently selected thread.
 483
 484 With a prefix argument, invert the default value of
 485 `notmuch-show-only-matching-messages' when displaying the
 486 thread."
 487   (interactive "P")
 488   (let ((thread-id (notmuch-search-find-thread-id))
 489         (subject (notmuch-search-find-subject)))
 490     (if (> (length thread-id) 0)
 491         (notmuch-show thread-id
 492                       elide-toggle
 493                       (current-buffer)
 494                       notmuch-search-query-string
 495                       ;; Name the buffer based on the subject.
 496                       (concat "*" (truncate-string-to-width subject 30 nil nil t) "*"))
 497       (message "End of search results."))))
 498
 499 (defun notmuch-tree-from-search-current-query ()
 500   "Call notmuch tree with the current query"
 501   (interactive)
 502   (notmuch-tree notmuch-search-query-string))
 503
 504 (defun notmuch-tree-from-search-thread ()
 505   "Show the selected thread with notmuch-tree"
 506   (interactive)
 507   (notmuch-tree (notmuch-search-find-thread-id)
 508                 notmuch-search-query-string
 509                 nil
 510                 (notmuch-prettify-subject (notmuch-search-find-subject))
 511                 t))
 512
 513 (defun notmuch-search-reply-to-thread (&optional prompt-for-sender)
 514   "Begin composing a reply-all to the entire current thread in a new buffer."
 515   (interactive "P")
 516   (let ((message-id (notmuch-search-find-thread-id)))
 517     (notmuch-mua-new-reply message-id prompt-for-sender t)))
 518
 519 (defun notmuch-search-reply-to-thread-sender (&optional prompt-for-sender)
 520   "Begin composing a reply to the entire current thread in a new buffer."
 521   (interactive "P")
 522   (let ((message-id (notmuch-search-find-thread-id)))
 523     (notmuch-mua-new-reply message-id prompt-for-sender nil)))
 524
 525 (defun notmuch-search-set-tags (tags &optional pos)
 526   (let ((new-result (plist-put (notmuch-search-get-result pos) :tags tags)))
 527     (notmuch-search-update-result new-result pos)))
 528
 529 (defun notmuch-search-get-tags (&optional pos)
 530   (plist-get (notmuch-search-get-result pos) :tags))
 531
 532 (defun notmuch-search-get-tags-region (beg end)
 533   (let (output)
 534     (notmuch-search-foreach-result beg end
 535       (lambda (pos)
 536         (setq output (append output (notmuch-search-get-tags pos)))))
 537     output))
 538
 539 (defun notmuch-search-interactive-region ()
 540   "Return the bounds of the current interactive region.
 541
 542 This returns (BEG END), where BEG and END are the bounds of the
 543 region if the region is active, or both `point' otherwise."
 544   (if (region-active-p)
 545       (list (region-beginning) (region-end))
 546     (list (point) (point))))
 547
 548 (defun notmuch-search-interactive-tag-changes (&optional initial-input)
 549   "Prompt for tag changes for the current thread or region.
 550
 551 Returns (TAG-CHANGES REGION-BEGIN REGION-END)."
 552   (let* ((region (notmuch-search-interactive-region))
 553          (beg (first region)) (end (second region))
 554          (prompt (if (= beg end) "Tag thread" "Tag region")))
 555     (cons (notmuch-read-tag-changes
 556            (notmuch-search-get-tags-region beg end) prompt initial-input)
 557           region)))
 558
 559 (defun notmuch-search-tag (tag-changes &optional beg end only-matched)
 560   "Change tags for the currently selected thread or region.
 561
 562 See `notmuch-tag' for information on the format of TAG-CHANGES.
 563 When called interactively, this uses the region if the region is
 564 active.  When called directly, BEG and END provide the region.
 565 If these are nil or not provided, this applies to the thread at
 566 point.
 567
 568 If ONLY-MATCHED is non-nil, only tag matched messages."
 569   (interactive (notmuch-search-interactive-tag-changes))
 570   (unless (and beg end) (setq beg (point) end (point)))
 571   (let ((search-string (notmuch-search-find-stable-query-region
 572                         beg end only-matched)))
 573     (notmuch-tag search-string tag-changes)
 574     (notmuch-search-foreach-result beg end
 575       (lambda (pos)
 576         (notmuch-search-set-tags
 577          (notmuch-update-tags (notmuch-search-get-tags pos) tag-changes)
 578          pos)))))
 579
 580 (defun notmuch-search-add-tag (tag-changes &optional beg end)
 581   "Change tags for the current thread or region (defaulting to add).
 582
 583 Same as `notmuch-search-tag' but sets initial input to '+'."
 584   (interactive (notmuch-search-interactive-tag-changes "+"))
 585   (notmuch-search-tag tag-changes beg end))
 586
 587 (defun notmuch-search-remove-tag (tag-changes &optional beg end)
 588   "Change tags for the current thread or region (defaulting to remove).
 589
 590 Same as `notmuch-search-tag' but sets initial input to '-'."
 591   (interactive (notmuch-search-interactive-tag-changes "-"))
 592   (notmuch-search-tag tag-changes beg end))
 593
 594 (put 'notmuch-search-archive-thread 'notmuch-prefix-doc
 595      "Un-archive the currently selected thread.")
 596 (defun notmuch-search-archive-thread (&optional unarchive beg end)
 597   "Archive the currently selected thread or region.
 598
 599 Archive each message in the currently selected thread by applying
 600 the tag changes in `notmuch-archive-tags' to each (remove the
 601 \"inbox\" tag by default). If a prefix argument is given, the
 602 messages will be \"unarchived\" (i.e. the tag changes in
 603 `notmuch-archive-tags' will be reversed).
 604
 605 This function advances the next thread when finished."
 606   (interactive (cons current-prefix-arg (notmuch-search-interactive-region)))
 607   (when notmuch-archive-tags
 608     (notmuch-search-tag
 609      (notmuch-tag-change-list notmuch-archive-tags unarchive) beg end))
 610   (when (eq beg end)
 611     (notmuch-search-next-thread)))
 612
 613 (defun notmuch-search-update-result (result &optional pos)
 614   "Replace the result object of the thread at POS (or point) by
 615 RESULT and redraw it.
 616
 617 This will keep point in a reasonable location.  However, if there
 618 are enclosing save-excursions and the saved point is in the
 619 result being updated, the point will be restored to the beginning
 620 of the result."
 621   (let ((start (notmuch-search-result-beginning pos))
 622         (end (notmuch-search-result-end pos))
 623         (init-point (point))
 624         (inhibit-read-only t))
 625     ;; Delete the current thread
 626     (delete-region start end)
 627     ;; Insert the updated thread
 628     (notmuch-search-show-result result start)
 629     ;; If point was inside the old result, make an educated guess
 630     ;; about where to place it now.  Unfortunately, this won't work
 631     ;; with save-excursion (or any other markers that would be nice to
 632     ;; preserve, such as the window start), but there's nothing we can
 633     ;; do about that without a way to retrieve markers in a region.
 634     (when (and (>= init-point start) (<= init-point end))
 635       (let* ((new-end (notmuch-search-result-end start))
 636              (new-point (if (= init-point end)
 637                             new-end
 638                           (min init-point (- new-end 1)))))
 639         (goto-char new-point)))))
 640
 641 (defun notmuch-search-process-sentinel (proc msg)
 642   "Add a message to let user know when \"notmuch search\" exits"
 643   (let ((buffer (process-buffer proc))
 644         (status (process-status proc))
 645         (exit-status (process-exit-status proc))
 646         (never-found-target-thread nil))
 647     (when (memq status '(exit signal))
 648       (catch 'return
 649         (kill-buffer (process-get proc 'parse-buf))
 650         (if (buffer-live-p buffer)
 651             (with-current-buffer buffer
 652               (save-excursion
 653                 (let ((inhibit-read-only t)
 654                       (atbob (bobp)))
 655                   (goto-char (point-max))
 656                   (if (eq status 'signal)
 657                       (insert "Incomplete search results (search process was killed).\n"))
 658                   (when (eq status 'exit)
 659                     (insert "End of search results.\n")
 660                     ;; For version mismatch, there's no point in
 661                     ;; showing the search buffer
 662                     (when (or (= exit-status 20) (= exit-status 21))
 663                       (kill-buffer)
 664                       (throw 'return nil))
 665                     (if (and atbob
 666                              (not (string= notmuch-search-target-thread "found")))
 667                         (set 'never-found-target-thread t)))))
 668               (when (and never-found-target-thread
 669                        notmuch-search-target-line)
 670                   (goto-char (point-min))
 671                   (forward-line (1- notmuch-search-target-line)))))))))
 672
 673 (defcustom notmuch-search-line-faces
 674   '(("unread" 'notmuch-search-unread-face)
 675     ("flagged" 'notmuch-search-flagged-face))
 676   "Alist of tags to faces for line highlighting in notmuch-search.
 677 Each element looks like (TAG . FACE).
 678 A thread with TAG will have FACE applied.
 679
 680 Here is an example of how to color search results based on tags.
 681  (the following text would be placed in your ~/.emacs file):
 682
 683  (setq notmuch-search-line-faces '((\"unread\" . (:foreground \"green\"))
 684                                    (\"deleted\" . (:foreground \"red\"
 685                                                   :background \"blue\"))))
 686
 687 The FACE must be a face name (a symbol or string), a property
 688 list of face attributes, or a list of these.  The faces for
 689 matching tags are merged, with earlier attributes overriding
 690 later. A message having both \"deleted\" and \"unread\" tags with
 691 the above settings would have a green foreground and blue
 692 background."
 693   :type '(alist :key-type (string) :value-type (custom-face-edit))
 694   :group 'notmuch-search
 695   :group 'notmuch-faces)
 696
 697 (defun notmuch-search-color-line (start end line-tag-list)
 698   "Colorize lines in `notmuch-show' based on tags."
 699   ;; Reverse the list so earlier entries take precedence
 700   (dolist (elem (reverse notmuch-search-line-faces))
 701     (let ((tag (car elem))
 702           (face (cdr elem)))
 703       (when (member tag line-tag-list)
 704         (notmuch-apply-face nil face nil start end)))))
 705
 706 (defun notmuch-search-author-propertize (authors)
 707   "Split `authors' into matching and non-matching authors and
 708 propertize appropriately. If no boundary between authors and
 709 non-authors is found, assume that all of the authors match."
 710   (if (string-match "\\(.*\\)|\\(.*\\)" authors)
 711       (concat (propertize (concat (match-string 1 authors) ",")
 712                           'face 'notmuch-search-matching-authors)
 713               (propertize (match-string 2 authors)
 714                           'face 'notmuch-search-non-matching-authors))
 715     (propertize authors 'face 'notmuch-search-matching-authors)))
 716
 717 (defun notmuch-search-insert-authors (format-string authors)
 718   ;; Save the match data to avoid interfering with
 719   ;; `notmuch-search-process-filter'.
 720   (save-match-data
 721     (let* ((formatted-authors (format format-string authors))
 722            (formatted-sample (format format-string ""))
 723            (visible-string formatted-authors)
 724            (invisible-string "")
 725            (padding ""))
 726
 727       ;; Truncate the author string to fit the specification.
 728       (if (> (length formatted-authors)
 729              (length formatted-sample))
 730           (let ((visible-length (- (length formatted-sample)
 731                                    (length "... "))))
 732             ;; Truncate the visible string according to the width of
 733             ;; the display string.
 734             (setq visible-string (substring formatted-authors 0 visible-length)
 735                   invisible-string (substring formatted-authors visible-length))
 736             ;; If possible, truncate the visible string at a natural
 737             ;; break (comma or pipe), as incremental search doesn't
 738             ;; match across the visible/invisible border.
 739             (when (string-match "\\(.*\\)\\([,|] \\)\\([^,|]*\\)" visible-string)
 740               ;; Second clause is destructive on `visible-string', so
 741               ;; order is important.
 742               (setq invisible-string (concat (match-string 3 visible-string)
 743                                              invisible-string)
 744                     visible-string (concat (match-string 1 visible-string)
 745                                            (match-string 2 visible-string))))
 746             ;; `visible-string' may be shorter than the space allowed
 747             ;; by `format-string'. If so we must insert some padding
 748             ;; after `invisible-string'.
 749             (setq padding (make-string (- (length formatted-sample)
 750                                           (length visible-string)
 751                                           (length "..."))
 752                                        ? ))))
 753
 754       ;; Use different faces to show matching and non-matching authors.
 755       (if (string-match "\\(.*\\)|\\(.*\\)" visible-string)
 756           ;; The visible string contains both matching and
 757           ;; non-matching authors.
 758           (setq visible-string (notmuch-search-author-propertize visible-string)
 759                 ;; The invisible string must contain only non-matching
 760                 ;; authors, as the visible-string contains both.
 761                 invisible-string (propertize invisible-string
 762                                              'face 'notmuch-search-non-matching-authors))
 763         ;; The visible string contains only matching authors.
 764         (setq visible-string (propertize visible-string
 765                                          'face 'notmuch-search-matching-authors)
 766               ;; The invisible string may contain both matching and
 767               ;; non-matching authors.
 768               invisible-string (notmuch-search-author-propertize invisible-string)))
 769
 770       ;; If there is any invisible text, add it as a tooltip to the
 771       ;; visible text.
 772       (when (not (string= invisible-string ""))
 773         (setq visible-string (propertize visible-string 'help-echo (concat "..." invisible-string))))
 774
 775       ;; Insert the visible and, if present, invisible author strings.
 776       (insert visible-string)
 777       (when (not (string= invisible-string ""))
 778         (let ((start (point))
 779               overlay)
 780           (insert invisible-string)
 781           (setq overlay (make-overlay start (point)))
 782           (overlay-put overlay 'invisible 'ellipsis)
 783           (overlay-put overlay 'isearch-open-invisible #'delete-overlay)))
 784       (insert padding))))
 785
 786 (defun notmuch-search-insert-field (field format-string result)
 787   (cond
 788    ((string-equal field "date")
 789     (insert (propertize (format format-string (plist-get result :date_relative))
 790                         'face 'notmuch-search-date)))
 791    ((string-equal field "count")
 792     (insert (propertize (format format-string
 793                                 (format "[%s/%s]" (plist-get result :matched)
 794                                         (plist-get result :total)))
 795                         'face 'notmuch-search-count)))
 796    ((string-equal field "subject")
 797     (insert (propertize (format format-string
 798                                 (notmuch-sanitize (plist-get result :subject)))
 799                         'face 'notmuch-search-subject)))
 800
 801    ((string-equal field "authors")
 802     (notmuch-search-insert-authors
 803      format-string (notmuch-sanitize (plist-get result :authors))))
 804
 805    ((string-equal field "tags")
 806     (let ((tags (plist-get result :tags))
 807           (orig-tags (plist-get result :orig-tags)))
 808       (insert (format format-string (notmuch-tag-format-tags tags orig-tags)))))))
 809
 810 (defun notmuch-search-show-result (result pos)
 811   "Insert RESULT at POS."
 812   ;; Ignore excluded matches
 813   (unless (= (plist-get result :matched) 0)
 814     (save-excursion
 815       (goto-char pos)
 816       (dolist (spec notmuch-search-result-format)
 817         (notmuch-search-insert-field (car spec) (cdr spec) result))
 818       (insert "\n")
 819       (notmuch-search-color-line pos (point) (plist-get result :tags))
 820       (put-text-property pos (point) 'notmuch-search-result result))))
 821
 822 (defun notmuch-search-append-result (result)
 823   "Insert RESULT at the end of the buffer.
 824
 825 This is only called when a result is first inserted so it also
 826 sets the :orig-tag property."
 827   (let ((new-result (plist-put result :orig-tags (plist-get result :tags)))
 828         (pos (point-max)))
 829     (notmuch-search-show-result new-result pos)
 830     (when (string= (plist-get result :thread) notmuch-search-target-thread)
 831       (setq notmuch-search-target-thread "found")
 832       (goto-char pos))))
 833
 834 (defun notmuch-search-process-filter (proc string)
 835   "Process and filter the output of \"notmuch search\""
 836   (let ((results-buf (process-buffer proc))
 837         (parse-buf (process-get proc 'parse-buf))
 838         (inhibit-read-only t)
 839         done)
 840     (when (buffer-live-p results-buf)
 841       (with-current-buffer parse-buf
 842         ;; Insert new data
 843         (save-excursion
 844           (goto-char (point-max))
 845           (insert string))
 846         (notmuch-sexp-parse-partial-list 'notmuch-search-append-result
 847                                          results-buf)))))
 848
 849 (defun notmuch-search-tag-all (tag-changes)
 850   "Add/remove tags from all messages in current search buffer.
 851
 852 See `notmuch-tag' for information on the format of TAG-CHANGES."
 853   (interactive
 854    (list (notmuch-read-tag-changes
 855           (notmuch-search-get-tags-region (point-min) (point-max)) "Tag all")))
 856   (notmuch-search-tag tag-changes (point-min) (point-max) t))
 857
 858 (defun notmuch-search-buffer-title (query)
 859   "Returns the title for a buffer with notmuch search results."
 860   (let* ((saved-search
 861           (let (longest
 862                 (longest-length 0))
 863             (loop for tuple in notmuch-saved-searches
 864                   if (let ((quoted-query (regexp-quote (notmuch-saved-search-get tuple :query))))
 865                        (and (string-match (concat "^" quoted-query) query)
 866                             (> (length (match-string 0 query))
 867                                longest-length)))
 868                   do (setq longest tuple))
 869             longest))
 870          (saved-search-name (notmuch-saved-search-get saved-search :name))
 871          (saved-search-query (notmuch-saved-search-get saved-search :query)))
 872     (cond ((and saved-search (equal saved-search-query query))
 873            ;; Query is the same as saved search (ignoring case)
 874            (concat "*notmuch-saved-search-" saved-search-name "*"))
 875           (saved-search
 876            (concat "*notmuch-search-"
 877                    (replace-regexp-in-string (concat "^" (regexp-quote saved-search-query))
 878                                              (concat "[ " saved-search-name " ]")
 879                                              query)
 880                    "*"))
 881           (t
 882            (concat "*notmuch-search-" query "*"))
 883           )))
 884
 885 (defun notmuch-read-query (prompt)
 886   "Read a notmuch-query from the minibuffer with completion.
 887
 888 PROMPT is the string to prompt with."
 889   (lexical-let*
 890       ((all-tags
 891         (mapcar (lambda (tag) (notmuch-escape-boolean-term tag))
 892                 (process-lines notmuch-command "search" "--output=tags" "*")))
 893        (completions
 894          (append (list "folder:" "path:" "thread:" "id:" "date:" "from:" "to:"
 895                        "subject:" "attachment:")
 896                  (mapcar (lambda (tag) (concat "tag:" tag)) all-tags)
 897                  (mapcar (lambda (tag) (concat "is:" tag)) all-tags)
 898                  (mapcar (lambda (mimetype) (concat "mimetype:" mimetype)) (mailcap-mime-types)))))
 899     (let ((keymap (copy-keymap minibuffer-local-map))
 900           (current-query (case major-mode
 901                            (notmuch-search-mode (notmuch-search-get-query))
 902                            (notmuch-show-mode (notmuch-show-get-query))
 903                            (notmuch-tree-mode (notmuch-tree-get-query))))
 904           (minibuffer-completion-table
 905            (completion-table-dynamic
 906             (lambda (string)
 907               ;; generate a list of possible completions for the current input
 908               (cond
 909                ;; this ugly regexp is used to get the last word of the input
 910                ;; possibly preceded by a '('
 911                ((string-match "\\(^\\|.* (?\\)\\([^ ]*\\)$" string)
 912                 (mapcar (lambda (compl)
 913                           (concat (match-string-no-properties 1 string) compl))
 914                         (all-completions (match-string-no-properties 2 string)
 915                                          completions)))
 916                (t (list string)))))))
 917       ;; this was simpler than convincing completing-read to accept spaces:
 918       (define-key keymap (kbd "TAB") 'minibuffer-complete)
 919       (let ((history-delete-duplicates t))
 920         (read-from-minibuffer prompt nil keymap nil
 921                               'notmuch-search-history current-query nil)))))
 922
 923 (defun notmuch-search-get-query ()
 924   "Return the current query in this search buffer"
 925   notmuch-search-query-string)
 926
 927 ;;;###autoload
 928 (put 'notmuch-search 'notmuch-doc "Search for messages.")
 929 (defun notmuch-search (&optional query oldest-first target-thread target-line)
 930   "Display threads matching QUERY in a notmuch-search buffer.
 931
 932 If QUERY is nil, it is read interactively from the minibuffer.
 933 Other optional parameters are used as follows:
 934
 935   OLDEST-FIRST: A Boolean controlling the sort order of returned threads
 936   TARGET-THREAD: A thread ID (without the thread: prefix) that will be made
 937                  current if it appears in the search results.
 938   TARGET-LINE: The line number to move to if the target thread does not
 939                appear in the search results.
 940
 941 When called interactively, this will prompt for a query and use
 942 the configured default sort order."
 943   (interactive
 944    (list
 945     ;; Prompt for a query
 946     nil
 947     ;; Use the default search order (if we're doing a search from a
 948     ;; search buffer, ignore any buffer-local overrides)
 949     (default-value 'notmuch-search-oldest-first)))
 950
 951   (let* ((query (or query (notmuch-read-query "Notmuch search: ")))
 952          (buffer (get-buffer-create (notmuch-search-buffer-title query))))
 953     (switch-to-buffer buffer)
 954     (notmuch-search-mode)
 955     ;; Don't track undo information for this buffer
 956     (set 'buffer-undo-list t)
 957     (set 'notmuch-search-query-string query)
 958     (set 'notmuch-search-oldest-first oldest-first)
 959     (set 'notmuch-search-target-thread target-thread)
 960     (set 'notmuch-search-target-line target-line)
 961     (notmuch-tag-clear-cache)
 962     (let ((proc (get-buffer-process (current-buffer)))
 963           (inhibit-read-only t))
 964       (if proc
 965           (error "notmuch search process already running for query `%s'" query)
 966         )
 967       (erase-buffer)
 968       (goto-char (point-min))
 969       (save-excursion
 970         (let ((proc (notmuch-start-notmuch
 971                      "notmuch-search" buffer #'notmuch-search-process-sentinel
 972                      "search" "--format=sexp" "--format-version=2"
 973                      (if oldest-first
 974                          "--sort=oldest-first"
 975                        "--sort=newest-first")
 976                      query))
 977               ;; Use a scratch buffer to accumulate partial output.
 978               ;; This buffer will be killed by the sentinel, which
 979               ;; should be called no matter how the process dies.
 980               (parse-buf (generate-new-buffer " *notmuch search parse*")))
 981           (process-put proc 'parse-buf parse-buf)
 982           (set-process-filter proc 'notmuch-search-process-filter)
 983           (set-process-query-on-exit-flag proc nil))))
 984     (run-hooks 'notmuch-search-hook)))
 985
 986 (defun notmuch-search-refresh-view ()
 987   "Refresh the current view.
 988
 989 Kills the current buffer and runs a new search with the same
 990 query string as the current search. If the current thread is in
 991 the new search results, then point will be placed on the same
 992 thread. Otherwise, point will be moved to attempt to be in the
 993 same relative position within the new buffer."
 994   (interactive)
 995   (let ((target-line (line-number-at-pos))
 996         (oldest-first notmuch-search-oldest-first)
 997         (target-thread (notmuch-search-find-thread-id 'bare))
 998         (query notmuch-search-query-string))
 999     (notmuch-bury-or-kill-this-buffer)
1000     (notmuch-search query oldest-first target-thread target-line)
1001     (goto-char (point-min))))
1002
1003 (defun notmuch-search-toggle-order ()
1004   "Toggle the current search order.
1005
1006 This command toggles the sort order for the current search. The
1007 default sort order is defined by `notmuch-search-oldest-first'."
1008   (interactive)
1009   (set 'notmuch-search-oldest-first (not notmuch-search-oldest-first))
1010   (notmuch-search-refresh-view))
1011
1012 (defun notmuch-group-disjunctive-query-string (query-string)
1013   "Group query if it contains a complex expression.
1014
1015 Enclose QUERY-STRING in parentheses if it matches
1016 `notmuch-search-disjunctive-regexp'."
1017   (if (string-match-p notmuch-search-disjunctive-regexp query-string)
1018       (concat "( " query-string " )")
1019     query-string))
1020
1021 (defun notmuch-search-filter (query)
1022   "Filter or LIMIT the current search results based on an additional query string.
1023
1024 Runs a new search matching only messages that match both the
1025 current search results AND the additional query string provided."
1026   (interactive (list (notmuch-read-query "Filter search: ")))
1027   (let ((grouped-query (notmuch-group-disjunctive-query-string query))
1028         (grouped-original-query (notmuch-group-disjunctive-query-string
1029                                  notmuch-search-query-string)))
1030     (notmuch-search (if (string= grouped-original-query "*")
1031                         grouped-query
1032                       (concat grouped-original-query " and " grouped-query))
1033                     notmuch-search-oldest-first)))
1034
1035 (defun notmuch-search-filter-by-tag (tag)
1036   "Filter the current search results based on a single tag.
1037
1038 Runs a new search matching only messages that match both the
1039 current search results AND that are tagged with the given tag."
1040   (interactive
1041    (list (notmuch-select-tag-with-completion "Filter by tag: ")))
1042   (notmuch-search (concat notmuch-search-query-string " and tag:" tag) notmuch-search-oldest-first))
1043
1044 ;;;###autoload
1045 (defun notmuch ()
1046   "Run notmuch and display saved searches, known tags, etc."
1047   (interactive)
1048   (notmuch-hello))
1049
1050 (defun notmuch-interesting-buffer (b)
1051   "Is the current buffer of interest to a notmuch user?"
1052   (with-current-buffer b
1053     (memq major-mode '(notmuch-show-mode
1054                        notmuch-search-mode
1055                        notmuch-hello-mode
1056                        message-mode))))
1057
1058 ;;;###autoload
1059 (defun notmuch-cycle-notmuch-buffers ()
1060   "Cycle through any existing notmuch buffers (search, show or hello).
1061
1062 If the current buffer is the only notmuch buffer, bury it. If no
1063 notmuch buffers exist, run `notmuch'."
1064   (interactive)
1065
1066   (let (start first)
1067     ;; If the current buffer is a notmuch buffer, remember it and then
1068     ;; bury it.
1069     (when (notmuch-interesting-buffer (current-buffer))
1070       (setq start (current-buffer))
1071       (bury-buffer))
1072
1073     ;; Find the first notmuch buffer.
1074     (setq first (loop for buffer in (buffer-list)
1075                      if (notmuch-interesting-buffer buffer)
1076                      return buffer))
1077
1078     (if first
1079         ;; If the first one we found is any other than the starting
1080         ;; buffer, switch to it.
1081         (unless (eq first start)
1082           (switch-to-buffer first))
1083       (notmuch))))
1084
1085 (setq mail-user-agent 'notmuch-user-agent)
1086
1087 (provide 'notmuch)
1088
1089 ;; After provide to avoid loops if notmuch was require'd via notmuch-init-file.
1090 (if init-file-user ; don't load init file if the -q option was used.
1091     (let ((init-file (locate-file notmuch-init-file '("/")
1092                                   (get-load-suffixes))))
1093       (if init-file (load init-file nil t t))))
1094
1095 ;;; notmuch.el ends here