git.notmuchmail.org Git - notmuch/blob - emacs/notmuch.el

   1 ;; notmuch.el --- run notmuch within emacs
   2 ;;
   3 ;; Copyright © Carl Worth
   4 ;;
   5 ;; This file is part of Notmuch.
   6 ;;
   7 ;; Notmuch is free software: you can redistribute it and/or modify it
   8 ;; under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation, either version 3 of the License, or
  10 ;; (at your option) any later version.
  11 ;;
  12 ;; Notmuch is distributed in the hope that it will be useful, but
  13 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 ;; General Public License for more details.
  16 ;;
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with Notmuch.  If not, see <http://www.gnu.org/licenses/>.
  19 ;;
  20 ;; Authors: Carl Worth <cworth@cworth.org>
  21
  22 ;; This is an emacs-based interface to the notmuch mail system.
  23 ;;
  24 ;; You will first need to have the notmuch program installed and have a
  25 ;; notmuch database built in order to use this. See
  26 ;; http://notmuchmail.org for details.
  27 ;;
  28 ;; To install this software, copy it to a directory that is on the
  29 ;; `load-path' variable within emacs (a good candidate is
  30 ;; /usr/local/share/emacs/site-lisp). If you are viewing this from the
  31 ;; notmuch source distribution then you can simply run:
  32 ;;
  33 ;;      sudo make install-emacs
  34 ;;
  35 ;; to install it.
  36 ;;
  37 ;; Then, to actually run it, add:
  38 ;;
  39 ;;      (require 'notmuch)
  40 ;;
  41 ;; to your ~/.emacs file, and then run "M-x notmuch" from within emacs,
  42 ;; or run:
  43 ;;
  44 ;;      emacs -f notmuch
  45 ;;
  46 ;; Have fun, and let us know if you have any comment, questions, or
  47 ;; kudos: Notmuch list <notmuch@notmuchmail.org> (subscription is not
  48 ;; required, but is available from http://notmuchmail.org).
  49
  50 (eval-when-compile (require 'cl))
  51 (require 'mm-view)
  52 (require 'message)
  53
  54 (require 'notmuch-lib)
  55 (require 'notmuch-tag)
  56 (require 'notmuch-show)
  57 (require 'notmuch-mua)
  58 (require 'notmuch-hello)
  59 (require 'notmuch-maildir-fcc)
  60 (require 'notmuch-message)
  61 (require 'notmuch-parser)
  62
  63 (defcustom notmuch-search-result-format
  64   `(("date" . "%12s ")
  65     ("count" . "%-7s ")
  66     ("authors" . "%-20s ")
  67     ("subject" . "%s ")
  68     ("tags" . "(%s)"))
  69   "Search result formatting. Supported fields are:
  70         date, count, authors, subject, tags
  71 For example:
  72         (setq notmuch-search-result-format \(\(\"authors\" . \"%-40s\"\)
  73                                              \(\"subject\" . \"%s\"\)\)\)
  74 Line breaks are permitted in format strings (though this is
  75 currently experimental).  Note that a line break at the end of an
  76 \"authors\" field will get elided if the authors list is long;
  77 place it instead at the beginning of the following field.  To
  78 enter a line break when setting this variable with setq, use \\n.
  79 To enter a line break in customize, press \\[quoted-insert] C-j."
  80   :type '(alist :key-type (string) :value-type (string))
  81   :group 'notmuch-search)
  82
  83 (defvar notmuch-query-history nil
  84   "Variable to store minibuffer history for notmuch queries")
  85
  86 (defun notmuch-foreach-mime-part (function mm-handle)
  87   (cond ((stringp (car mm-handle))
  88          (dolist (part (cdr mm-handle))
  89            (notmuch-foreach-mime-part function part)))
  90         ((bufferp (car mm-handle))
  91          (funcall function mm-handle))
  92         (t (dolist (part mm-handle)
  93              (notmuch-foreach-mime-part function part)))))
  94
  95 (defun notmuch-count-attachments (mm-handle)
  96   (let ((count 0))
  97     (notmuch-foreach-mime-part
  98      (lambda (p)
  99        (let ((disposition (mm-handle-disposition p)))
 100          (and (listp disposition)
 101               (or (equal (car disposition) "attachment")
 102                   (and (equal (car disposition) "inline")
 103                        (assq 'filename disposition)))
 104               (incf count))))
 105      mm-handle)
 106     count))
 107
 108 (defun notmuch-save-attachments (mm-handle &optional queryp)
 109   (notmuch-foreach-mime-part
 110    (lambda (p)
 111      (let ((disposition (mm-handle-disposition p)))
 112        (and (listp disposition)
 113             (or (equal (car disposition) "attachment")
 114                 (and (equal (car disposition) "inline")
 115                      (assq 'filename disposition)))
 116             (or (not queryp)
 117                 (y-or-n-p
 118                  (concat "Save '" (cdr (assq 'filename disposition)) "' ")))
 119             (mm-save-part p))))
 120    mm-handle))
 121
 122 (defun notmuch-documentation-first-line (symbol)
 123   "Return the first line of the documentation string for SYMBOL."
 124   (let ((doc (documentation symbol)))
 125     (if doc
 126         (with-temp-buffer
 127           (insert (documentation symbol t))
 128           (goto-char (point-min))
 129           (let ((beg (point)))
 130             (end-of-line)
 131             (buffer-substring beg (point))))
 132       "")))
 133
 134 (defun notmuch-prefix-key-description (key)
 135   "Given a prefix key code, return a human-readable string representation.
 136
 137 This is basically just `format-kbd-macro' but we also convert ESC to M-."
 138   (let ((desc (format-kbd-macro (vector key))))
 139     (if (string= desc "ESC")
 140         "M-"
 141       (concat desc " "))))
 142
 143 (defun notmuch-describe-keymap (keymap &optional prefix tail)
 144   "Return a list of strings, each describing one key in KEYMAP.
 145
 146 Each string gives a human-readable description of the key and the
 147 first line of documentation for the bound function."
 148   (map-keymap
 149    (lambda (key binding)
 150      (cond ((mouse-event-p key) nil)
 151            ((keymapp binding)
 152             (setq tail
 153                   (notmuch-describe-keymap
 154                    binding (notmuch-prefix-key-description key) tail)))
 155            (t
 156             (push (concat prefix (format-kbd-macro (vector key)) "\t"
 157                           (notmuch-documentation-first-line binding))
 158                   tail))))
 159    keymap)
 160   tail)
 161
 162 (defun notmuch-substitute-command-keys (doc)
 163   "Like `substitute-command-keys' but with documentation, not function names."
 164   (let ((beg 0))
 165     (while (string-match "\\\\{\\([^}[:space:]]*\\)}" doc beg)
 166       (let* ((keymap-name (substring doc (match-beginning 1) (match-end 1)))
 167              (keymap (symbol-value (intern keymap-name)))
 168              (desc-list (notmuch-describe-keymap keymap))
 169              (desc (mapconcat #'identity desc-list "\n")))
 170         (setq doc (replace-match desc 1 1 doc)))
 171       (setq beg (match-end 0)))
 172     doc))
 173
 174 (defun notmuch-help ()
 175   "Display help for the current notmuch mode."
 176   (interactive)
 177   (let* ((mode major-mode)
 178          (doc (substitute-command-keys (notmuch-substitute-command-keys (documentation mode t)))))
 179     (with-current-buffer (generate-new-buffer "*notmuch-help*")
 180       (insert doc)
 181       (goto-char (point-min))
 182       (set-buffer-modified-p nil)
 183       (view-buffer (current-buffer) 'kill-buffer-if-not-modified))))
 184
 185 (require 'hl-line)
 186
 187 (defun notmuch-hl-line-mode ()
 188   (prog1 (hl-line-mode)
 189     (when hl-line-overlay
 190       (overlay-put hl-line-overlay 'priority 1))))
 191
 192 (defcustom notmuch-search-hook '(notmuch-hl-line-mode)
 193   "List of functions to call when notmuch displays the search results."
 194   :type 'hook
 195   :options '(notmuch-hl-line-mode)
 196   :group 'notmuch-search
 197   :group 'notmuch-hooks)
 198
 199 (defvar notmuch-search-mode-map
 200   (let ((map (make-sparse-keymap)))
 201     (define-key map "?" 'notmuch-help)
 202     (define-key map "q" 'notmuch-kill-this-buffer)
 203     (define-key map "x" 'notmuch-kill-this-buffer)
 204     (define-key map (kbd "<DEL>") 'notmuch-search-scroll-down)
 205     (define-key map "b" 'notmuch-search-scroll-down)
 206     (define-key map " " 'notmuch-search-scroll-up)
 207     (define-key map "<" 'notmuch-search-first-thread)
 208     (define-key map ">" 'notmuch-search-last-thread)
 209     (define-key map "p" 'notmuch-search-previous-thread)
 210     (define-key map "n" 'notmuch-search-next-thread)
 211     (define-key map "r" 'notmuch-search-reply-to-thread-sender)
 212     (define-key map "R" 'notmuch-search-reply-to-thread)
 213     (define-key map "m" 'notmuch-mua-new-mail)
 214     (define-key map "s" 'notmuch-search)
 215     (define-key map "o" 'notmuch-search-toggle-order)
 216     (define-key map "c" 'notmuch-search-stash-map)
 217     (define-key map "=" 'notmuch-refresh-this-buffer)
 218     (define-key map "G" 'notmuch-poll-and-refresh-this-buffer)
 219     (define-key map "t" 'notmuch-search-filter-by-tag)
 220     (define-key map "f" 'notmuch-search-filter)
 221     (define-key map [mouse-1] 'notmuch-search-show-thread)
 222     (define-key map "*" 'notmuch-search-tag-all)
 223     (define-key map "a" 'notmuch-search-archive-thread)
 224     (define-key map "-" 'notmuch-search-remove-tag)
 225     (define-key map "+" 'notmuch-search-add-tag)
 226     (define-key map (kbd "RET") 'notmuch-search-show-thread)
 227     map)
 228   "Keymap for \"notmuch search\" buffers.")
 229 (fset 'notmuch-search-mode-map notmuch-search-mode-map)
 230
 231 (defvar notmuch-search-stash-map
 232   (let ((map (make-sparse-keymap)))
 233     (define-key map "i" 'notmuch-search-stash-thread-id)
 234     map)
 235   "Submap for stash commands")
 236 (fset 'notmuch-search-stash-map notmuch-search-stash-map)
 237
 238 (defun notmuch-search-stash-thread-id ()
 239   "Copy thread ID of current thread to kill-ring."
 240   (interactive)
 241   (notmuch-common-do-stash (notmuch-search-find-thread-id)))
 242
 243 (defvar notmuch-search-query-string)
 244 (defvar notmuch-search-target-thread)
 245 (defvar notmuch-search-target-line)
 246
 247 (defvar notmuch-search-disjunctive-regexp      "\\<[oO][rR]\\>")
 248
 249 (defun notmuch-search-scroll-up ()
 250   "Move forward through search results by one window's worth."
 251   (interactive)
 252   (condition-case nil
 253       (scroll-up nil)
 254     ((end-of-buffer) (notmuch-search-last-thread))))
 255
 256 (defun notmuch-search-scroll-down ()
 257   "Move backward through the search results by one window's worth."
 258   (interactive)
 259   ;; I don't know why scroll-down doesn't signal beginning-of-buffer
 260   ;; the way that scroll-up signals end-of-buffer, but c'est la vie.
 261   ;;
 262   ;; So instead of trapping a signal we instead check whether the
 263   ;; window begins on the first line of the buffer and if so, move
 264   ;; directly to that position. (We have to count lines since the
 265   ;; window-start position is not the same as point-min due to the
 266   ;; invisible thread-ID characters on the first line.
 267   (if (equal (count-lines (point-min) (window-start)) 0)
 268       (goto-char (point-min))
 269     (scroll-down nil)))
 270
 271 (defun notmuch-search-next-thread ()
 272   "Select the next thread in the search results."
 273   (interactive)
 274   (when (notmuch-search-get-result)
 275     (goto-char (notmuch-search-result-end))))
 276
 277 (defun notmuch-search-previous-thread ()
 278   "Select the previous thread in the search results."
 279   (interactive)
 280   (if (notmuch-search-get-result)
 281       (unless (bobp)
 282         (goto-char (notmuch-search-result-beginning (- (point) 1))))
 283     ;; We must be past the end; jump to the last result
 284     (notmuch-search-last-thread)))
 285
 286 (defun notmuch-search-last-thread ()
 287   "Select the last thread in the search results."
 288   (interactive)
 289   (goto-char (point-max))
 290   (forward-line -2)
 291   (let ((beg (notmuch-search-result-beginning)))
 292     (when beg (goto-char beg))))
 293
 294 (defun notmuch-search-first-thread ()
 295   "Select the first thread in the search results."
 296   (interactive)
 297   (goto-char (point-min)))
 298
 299 (defface notmuch-message-summary-face
 300  '((((class color) (background light)) (:background "#f0f0f0"))
 301    (((class color) (background dark)) (:background "#303030")))
 302  "Face for the single-line message summary in notmuch-show-mode."
 303  :group 'notmuch-show
 304  :group 'notmuch-faces)
 305
 306 (defface notmuch-search-date
 307   '((t :inherit default))
 308   "Face used in search mode for dates."
 309   :group 'notmuch-search
 310   :group 'notmuch-faces)
 311
 312 (defface notmuch-search-count
 313   '((t :inherit default))
 314   "Face used in search mode for the count matching the query."
 315   :group 'notmuch-search
 316   :group 'notmuch-faces)
 317
 318 (defface notmuch-search-subject
 319   '((t :inherit default))
 320   "Face used in search mode for subjects."
 321   :group 'notmuch-search
 322   :group 'notmuch-faces)
 323
 324 (defface notmuch-search-matching-authors
 325   '((t :inherit default))
 326   "Face used in search mode for authors matching the query."
 327   :group 'notmuch-search
 328   :group 'notmuch-faces)
 329
 330 (defface notmuch-search-non-matching-authors
 331   '((((class color)
 332       (background dark))
 333      (:foreground "grey30"))
 334     (((class color)
 335       (background light))
 336      (:foreground "grey60"))
 337     (t
 338      (:italic t)))
 339   "Face used in search mode for authors not matching the query."
 340   :group 'notmuch-search
 341   :group 'notmuch-faces)
 342
 343 (defface notmuch-tag-face
 344   '((((class color)
 345       (background dark))
 346      (:foreground "OliveDrab1"))
 347     (((class color)
 348       (background light))
 349      (:foreground "navy blue" :bold t))
 350     (t
 351      (:bold t)))
 352   "Face used in search mode face for tags."
 353   :group 'notmuch-search
 354   :group 'notmuch-faces)
 355
 356 (defun notmuch-search-mode ()
 357   "Major mode displaying results of a notmuch search.
 358
 359 This buffer contains the results of a \"notmuch search\" of your
 360 email archives. Each line in the buffer represents a single
 361 thread giving a summary of the thread (a relative date, the
 362 number of matched messages and total messages in the thread,
 363 participants in the thread, a representative subject line, and
 364 any tags).
 365
 366 Pressing \\[notmuch-search-show-thread] on any line displays that
 367 thread. The '\\[notmuch-search-add-tag]' and
 368 '\\[notmuch-search-remove-tag]' keys can be used to add or remove
 369 tags from a thread. The '\\[notmuch-search-archive-thread]' key
 370 is a convenience for archiving a thread (applying changes in
 371 `notmuch-archive-tags'). The '\\[notmuch-search-tag-all]' key can
 372 be used to add and/or remove tags from all messages (as opposed
 373 to threads) that match the current query.  Use with caution, as
 374 this will also tag matching messages that arrived *after*
 375 constructing the buffer.
 376
 377 Other useful commands are '\\[notmuch-search-filter]' for
 378 filtering the current search based on an additional query string,
 379 '\\[notmuch-search-filter-by-tag]' for filtering to include only
 380 messages with a given tag, and '\\[notmuch-search]' to execute a
 381 new, global search.
 382
 383 Complete list of currently available key bindings:
 384
 385 \\{notmuch-search-mode-map}"
 386   (interactive)
 387   (kill-all-local-variables)
 388   (make-local-variable 'notmuch-search-query-string)
 389   (make-local-variable 'notmuch-search-oldest-first)
 390   (make-local-variable 'notmuch-search-target-thread)
 391   (make-local-variable 'notmuch-search-target-line)
 392   (setq notmuch-buffer-refresh-function #'notmuch-search-refresh-view)
 393   (set (make-local-variable 'scroll-preserve-screen-position) t)
 394   (add-to-invisibility-spec (cons 'ellipsis t))
 395   (use-local-map notmuch-search-mode-map)
 396   (setq truncate-lines t)
 397   (setq major-mode 'notmuch-search-mode
 398         mode-name "notmuch-search")
 399   (setq buffer-read-only t))
 400
 401 (defun notmuch-search-get-result (&optional pos)
 402   "Return the result object for the thread at POS (or point).
 403
 404 If there is no thread at POS (or point), returns nil."
 405   (get-text-property (or pos (point)) 'notmuch-search-result))
 406
 407 (defun notmuch-search-result-beginning (&optional pos)
 408   "Return the point at the beginning of the thread at POS (or point).
 409
 410 If there is no thread at POS (or point), returns nil."
 411   (when (notmuch-search-get-result pos)
 412     ;; We pass 1+point because previous-single-property-change starts
 413     ;; searching one before the position we give it.
 414     (previous-single-property-change (1+ (or pos (point)))
 415                                      'notmuch-search-result nil (point-min))))
 416
 417 (defun notmuch-search-result-end (&optional pos)
 418   "Return the point at the end of the thread at POS (or point).
 419
 420 The returned point will be just after the newline character that
 421 ends the result line.  If there is no thread at POS (or point),
 422 returns nil"
 423   (when (notmuch-search-get-result pos)
 424     (next-single-property-change (or pos (point)) 'notmuch-search-result
 425                                  nil (point-max))))
 426
 427 (defun notmuch-search-foreach-result (beg end function)
 428   "Invoke FUNCTION for each result between BEG and END.
 429
 430 FUNCTION should take one argument.  It will be applied to the
 431 character position of the beginning of each result that overlaps
 432 the region between points BEG and END.  As a special case, if (=
 433 BEG END), FUNCTION will be applied to the result containing point
 434 BEG."
 435
 436   (lexical-let ((pos (notmuch-search-result-beginning beg))
 437                 ;; End must be a marker in case function changes the
 438                 ;; text.
 439                 (end (copy-marker end))
 440                 ;; Make sure we examine at least one result, even if
 441                 ;; (= beg end).
 442                 (first t))
 443     ;; We have to be careful if the region extends beyond the results.
 444     ;; In this case, pos could be null or there could be no result at
 445     ;; pos.
 446     (while (and pos (or (< pos end) first))
 447       (when (notmuch-search-get-result pos)
 448         (funcall function pos))
 449       (setq pos (notmuch-search-result-end pos)
 450             first nil))))
 451 ;; Unindent the function argument of notmuch-search-foreach-result so
 452 ;; the indentation of callers doesn't get out of hand.
 453 (put 'notmuch-search-foreach-result 'lisp-indent-function 2)
 454
 455 (defun notmuch-search-properties-in-region (property beg end)
 456   (let (output)
 457     (notmuch-search-foreach-result beg end
 458       (lambda (pos)
 459         (push (plist-get (notmuch-search-get-result pos) property) output)))
 460     output))
 461
 462 (defun notmuch-search-find-thread-id (&optional bare)
 463   "Return the thread for the current thread
 464
 465 If BARE is set then do not prefix with \"thread:\""
 466   (let ((thread (plist-get (notmuch-search-get-result) :thread)))
 467     (when thread (concat (unless bare "thread:") thread))))
 468
 469 (defun notmuch-search-find-thread-id-region (beg end)
 470   "Return a list of threads for the current region"
 471   (mapcar (lambda (thread) (concat "thread:" thread))
 472           (notmuch-search-properties-in-region :thread beg end)))
 473
 474 (defun notmuch-search-find-thread-id-region-search (beg end)
 475   "Return a search string for threads for the current region"
 476   (mapconcat 'identity (notmuch-search-find-thread-id-region beg end) " or "))
 477
 478 (defun notmuch-search-find-authors ()
 479   "Return the authors for the current thread"
 480   (plist-get (notmuch-search-get-result) :authors))
 481
 482 (defun notmuch-search-find-authors-region (beg end)
 483   "Return a list of authors for the current region"
 484   (notmuch-search-properties-in-region :authors beg end))
 485
 486 (defun notmuch-search-find-subject ()
 487   "Return the subject for the current thread"
 488   (plist-get (notmuch-search-get-result) :subject))
 489
 490 (defun notmuch-search-find-subject-region (beg end)
 491   "Return a list of authors for the current region"
 492   (notmuch-search-properties-in-region :subject beg end))
 493
 494 (defun notmuch-search-show-thread ()
 495   "Display the currently selected thread."
 496   (interactive)
 497   (let ((thread-id (notmuch-search-find-thread-id))
 498         (subject (notmuch-search-find-subject)))
 499     (if (> (length thread-id) 0)
 500         (notmuch-show thread-id
 501                       (current-buffer)
 502                       notmuch-search-query-string
 503                       ;; Name the buffer based on the subject.
 504                       (concat "*" (truncate-string-to-width subject 30 nil nil t) "*"))
 505       (message "End of search results."))))
 506
 507 (defun notmuch-search-reply-to-thread (&optional prompt-for-sender)
 508   "Begin composing a reply-all to the entire current thread in a new buffer."
 509   (interactive "P")
 510   (let ((message-id (notmuch-search-find-thread-id)))
 511     (notmuch-mua-new-reply message-id prompt-for-sender t)))
 512
 513 (defun notmuch-search-reply-to-thread-sender (&optional prompt-for-sender)
 514   "Begin composing a reply to the entire current thread in a new buffer."
 515   (interactive "P")
 516   (let ((message-id (notmuch-search-find-thread-id)))
 517     (notmuch-mua-new-reply message-id prompt-for-sender nil)))
 518
 519 (defun notmuch-call-notmuch-process (&rest args)
 520   "Synchronously invoke \"notmuch\" with the given list of arguments.
 521
 522 If notmuch exits with a non-zero status, output from the process
 523 will appear in a buffer named \"*Notmuch errors*\" and an error
 524 will be signaled."
 525   (with-temp-buffer
 526     (let ((status (apply #'call-process notmuch-command nil t nil args)))
 527       (notmuch-check-exit-status status (cons notmuch-command args)
 528                                  (buffer-string)))))
 529
 530 (defun notmuch-search-set-tags (tags &optional pos)
 531   (let ((new-result (plist-put (notmuch-search-get-result pos) :tags tags)))
 532     (notmuch-search-update-result new-result pos)))
 533
 534 (defun notmuch-search-get-tags (&optional pos)
 535   (plist-get (notmuch-search-get-result pos) :tags))
 536
 537 (defun notmuch-search-get-tags-region (beg end)
 538   (let (output)
 539     (notmuch-search-foreach-result beg end
 540       (lambda (pos)
 541         (setq output (append output (notmuch-search-get-tags pos)))))
 542     output))
 543
 544 (defun notmuch-search-tag-region (beg end &optional tag-changes)
 545   "Change tags for threads in the given region."
 546   (let ((search-string (notmuch-search-find-thread-id-region-search beg end)))
 547     (setq tag-changes (notmuch-tag search-string tag-changes))
 548     (notmuch-search-foreach-result beg end
 549       (lambda (pos)
 550         (notmuch-search-set-tags
 551          (notmuch-update-tags (notmuch-search-get-tags pos) tag-changes)
 552          pos)))))
 553
 554 (defun notmuch-search-tag (&optional tag-changes)
 555   "Change tags for the currently selected thread or region.
 556
 557 See `notmuch-tag' for information on the format of TAG-CHANGES."
 558   (interactive)
 559   (let* ((beg (if (region-active-p) (region-beginning) (point)))
 560          (end (if (region-active-p) (region-end) (point))))
 561     (notmuch-search-tag-region beg end tag-changes)))
 562
 563 (defun notmuch-search-add-tag ()
 564   "Same as `notmuch-search-tag' but sets initial input to '+'."
 565   (interactive)
 566   (notmuch-search-tag "+"))
 567
 568 (defun notmuch-search-remove-tag ()
 569   "Same as `notmuch-search-tag' but sets initial input to '-'."
 570   (interactive)
 571   (notmuch-search-tag "-"))
 572
 573 (defun notmuch-search-archive-thread (&optional unarchive)
 574   "Archive the currently selected thread.
 575
 576 Archive each message in the currently selected thread by applying
 577 the tag changes in `notmuch-archive-tags' to each (remove the
 578 \"inbox\" tag by default). If a prefix argument is given, the
 579 messages will be \"unarchived\" (i.e. the tag changes in
 580 `notmuch-archive-tags' will be reversed).
 581
 582 This function advances the next thread when finished."
 583   (interactive "P")
 584   (when notmuch-archive-tags
 585     (notmuch-search-tag
 586      (notmuch-tag-change-list notmuch-archive-tags unarchive)))
 587   (notmuch-search-next-thread))
 588
 589 (defun notmuch-search-update-result (result &optional pos)
 590   "Replace the result object of the thread at POS (or point) by
 591 RESULT and redraw it.
 592
 593 This will keep point in a reasonable location.  However, if there
 594 are enclosing save-excursions and the saved point is in the
 595 result being updated, the point will be restored to the beginning
 596 of the result."
 597   (let ((start (notmuch-search-result-beginning pos))
 598         (end (notmuch-search-result-end pos))
 599         (init-point (point))
 600         (inhibit-read-only t))
 601     ;; Delete the current thread
 602     (delete-region start end)
 603     ;; Insert the updated thread
 604     (notmuch-search-show-result result start)
 605     ;; If point was inside the old result, make an educated guess
 606     ;; about where to place it now.  Unfortunately, this won't work
 607     ;; with save-excursion (or any other markers that would be nice to
 608     ;; preserve, such as the window start), but there's nothing we can
 609     ;; do about that without a way to retrieve markers in a region.
 610     (when (and (>= init-point start) (<= init-point end))
 611       (let* ((new-end (notmuch-search-result-end start))
 612              (new-point (if (= init-point end)
 613                             new-end
 614                           (min init-point (- new-end 1)))))
 615         (goto-char new-point)))))
 616
 617 (defun notmuch-search-process-sentinel (proc msg)
 618   "Add a message to let user know when \"notmuch search\" exits"
 619   (let ((buffer (process-buffer proc))
 620         (status (process-status proc))
 621         (exit-status (process-exit-status proc))
 622         (never-found-target-thread nil))
 623     (when (memq status '(exit signal))
 624       (catch 'return
 625         (kill-buffer (process-get proc 'parse-buf))
 626         (if (buffer-live-p buffer)
 627             (with-current-buffer buffer
 628               (save-excursion
 629                 (let ((inhibit-read-only t)
 630                       (atbob (bobp)))
 631                   (goto-char (point-max))
 632                   (if (eq status 'signal)
 633                       (insert "Incomplete search results (search process was killed).\n"))
 634                   (when (eq status 'exit)
 635                     (insert "End of search results.\n")
 636                     ;; For version mismatch, there's no point in
 637                     ;; showing the search buffer
 638                     (when (or (= exit-status 20) (= exit-status 21))
 639                       (kill-buffer)
 640                       (throw 'return nil))
 641                     (if (and atbob
 642                              (not (string= notmuch-search-target-thread "found")))
 643                         (set 'never-found-target-thread t)))))
 644               (when (and never-found-target-thread
 645                        notmuch-search-target-line)
 646                   (goto-char (point-min))
 647                   (forward-line (1- notmuch-search-target-line)))))))))
 648
 649 (defcustom notmuch-search-line-faces '(("unread" :weight bold)
 650                                        ("flagged" :foreground "blue"))
 651   "Tag/face mapping for line highlighting in notmuch-search.
 652
 653 Here is an example of how to color search results based on tags.
 654  (the following text would be placed in your ~/.emacs file):
 655
 656  (setq notmuch-search-line-faces '((\"deleted\" . (:foreground \"red\"
 657                                                   :background \"blue\"))
 658                                    (\"unread\" . (:foreground \"green\"))))
 659
 660 The attributes defined for matching tags are merged, with later
 661 attributes overriding earlier. A message having both \"deleted\"
 662 and \"unread\" tags with the above settings would have a green
 663 foreground and blue background."
 664   :type '(alist :key-type (string) :value-type (custom-face-edit))
 665   :group 'notmuch-search
 666   :group 'notmuch-faces)
 667
 668 (defun notmuch-search-color-line (start end line-tag-list)
 669   "Colorize lines in `notmuch-show' based on tags."
 670   (mapc (lambda (elem)
 671           (let ((tag (car elem))
 672                 (attributes (cdr elem)))
 673             (when (member tag line-tag-list)
 674               (notmuch-combine-face-text-property start end attributes))))
 675         ;; Reverse the list so earlier entries take precedence
 676         (reverse notmuch-search-line-faces)))
 677
 678 (defun notmuch-search-author-propertize (authors)
 679   "Split `authors' into matching and non-matching authors and
 680 propertize appropriately. If no boundary between authors and
 681 non-authors is found, assume that all of the authors match."
 682   (if (string-match "\\(.*\\)|\\(.*\\)" authors)
 683       (concat (propertize (concat (match-string 1 authors) ",")
 684                           'face 'notmuch-search-matching-authors)
 685               (propertize (match-string 2 authors)
 686                           'face 'notmuch-search-non-matching-authors))
 687     (propertize authors 'face 'notmuch-search-matching-authors)))
 688
 689 (defun notmuch-search-insert-authors (format-string authors)
 690   ;; Save the match data to avoid interfering with
 691   ;; `notmuch-search-process-filter'.
 692   (save-match-data
 693     (let* ((formatted-authors (format format-string authors))
 694            (formatted-sample (format format-string ""))
 695            (visible-string formatted-authors)
 696            (invisible-string "")
 697            (padding ""))
 698
 699       ;; Truncate the author string to fit the specification.
 700       (if (> (length formatted-authors)
 701              (length formatted-sample))
 702           (let ((visible-length (- (length formatted-sample)
 703                                    (length "... "))))
 704             ;; Truncate the visible string according to the width of
 705             ;; the display string.
 706             (setq visible-string (substring formatted-authors 0 visible-length)
 707                   invisible-string (substring formatted-authors visible-length))
 708             ;; If possible, truncate the visible string at a natural
 709             ;; break (comma or pipe), as incremental search doesn't
 710             ;; match across the visible/invisible border.
 711             (when (string-match "\\(.*\\)\\([,|] \\)\\([^,|]*\\)" visible-string)
 712               ;; Second clause is destructive on `visible-string', so
 713               ;; order is important.
 714               (setq invisible-string (concat (match-string 3 visible-string)
 715                                              invisible-string)
 716                     visible-string (concat (match-string 1 visible-string)
 717                                            (match-string 2 visible-string))))
 718             ;; `visible-string' may be shorter than the space allowed
 719             ;; by `format-string'. If so we must insert some padding
 720             ;; after `invisible-string'.
 721             (setq padding (make-string (- (length formatted-sample)
 722                                           (length visible-string)
 723                                           (length "..."))
 724                                        ? ))))
 725
 726       ;; Use different faces to show matching and non-matching authors.
 727       (if (string-match "\\(.*\\)|\\(.*\\)" visible-string)
 728           ;; The visible string contains both matching and
 729           ;; non-matching authors.
 730           (setq visible-string (notmuch-search-author-propertize visible-string)
 731                 ;; The invisible string must contain only non-matching
 732                 ;; authors, as the visible-string contains both.
 733                 invisible-string (propertize invisible-string
 734                                              'face 'notmuch-search-non-matching-authors))
 735         ;; The visible string contains only matching authors.
 736         (setq visible-string (propertize visible-string
 737                                          'face 'notmuch-search-matching-authors)
 738               ;; The invisible string may contain both matching and
 739               ;; non-matching authors.
 740               invisible-string (notmuch-search-author-propertize invisible-string)))
 741
 742       ;; If there is any invisible text, add it as a tooltip to the
 743       ;; visible text.
 744       (when (not (string= invisible-string ""))
 745         (setq visible-string (propertize visible-string 'help-echo (concat "..." invisible-string))))
 746
 747       ;; Insert the visible and, if present, invisible author strings.
 748       (insert visible-string)
 749       (when (not (string= invisible-string ""))
 750         (let ((start (point))
 751               overlay)
 752           (insert invisible-string)
 753           (setq overlay (make-overlay start (point)))
 754           (overlay-put overlay 'invisible 'ellipsis)
 755           (overlay-put overlay 'isearch-open-invisible #'delete-overlay)))
 756       (insert padding))))
 757
 758 (defun notmuch-search-insert-field (field format-string result)
 759   (cond
 760    ((string-equal field "date")
 761     (insert (propertize (format format-string (plist-get result :date_relative))
 762                         'face 'notmuch-search-date)))
 763    ((string-equal field "count")
 764     (insert (propertize (format format-string
 765                                 (format "[%s/%s]" (plist-get result :matched)
 766                                         (plist-get result :total)))
 767                         'face 'notmuch-search-count)))
 768    ((string-equal field "subject")
 769     (insert (propertize (format format-string (plist-get result :subject))
 770                         'face 'notmuch-search-subject)))
 771
 772    ((string-equal field "authors")
 773     (notmuch-search-insert-authors format-string (plist-get result :authors)))
 774
 775    ((string-equal field "tags")
 776     (let ((tags (plist-get result :tags)))
 777       (insert (format format-string (notmuch-tag-format-tags tags)))))))
 778
 779 (defun notmuch-search-show-result (result &optional pos)
 780   "Insert RESULT at POS or the end of the buffer if POS is null."
 781   ;; Ignore excluded matches
 782   (unless (= (plist-get result :matched) 0)
 783     (let ((beg (or pos (point-max))))
 784       (save-excursion
 785         (goto-char beg)
 786         (dolist (spec notmuch-search-result-format)
 787           (notmuch-search-insert-field (car spec) (cdr spec) result))
 788         (insert "\n")
 789         (notmuch-search-color-line beg (point) (plist-get result :tags))
 790         (put-text-property beg (point) 'notmuch-search-result result))
 791       (when (string= (plist-get result :thread) notmuch-search-target-thread)
 792         (setq notmuch-search-target-thread "found")
 793         (goto-char beg)))))
 794
 795 (defun notmuch-search-process-filter (proc string)
 796   "Process and filter the output of \"notmuch search\""
 797   (let ((results-buf (process-buffer proc))
 798         (parse-buf (process-get proc 'parse-buf))
 799         (inhibit-read-only t)
 800         done)
 801     (when (buffer-live-p results-buf)
 802       (with-current-buffer parse-buf
 803         ;; Insert new data
 804         (save-excursion
 805           (goto-char (point-max))
 806           (insert string))
 807         (notmuch-sexp-parse-partial-list 'notmuch-search-show-result
 808                                          results-buf)))))
 809
 810 (defun notmuch-search-tag-all (&optional tag-changes)
 811   "Add/remove tags from all messages in current search buffer.
 812
 813 See `notmuch-tag' for information on the format of TAG-CHANGES."
 814   (interactive)
 815   (apply 'notmuch-tag notmuch-search-query-string tag-changes))
 816
 817 (defun notmuch-search-buffer-title (query)
 818   "Returns the title for a buffer with notmuch search results."
 819   (let* ((saved-search
 820           (let (longest
 821                 (longest-length 0))
 822             (loop for tuple in notmuch-saved-searches
 823                   if (let ((quoted-query (regexp-quote (cdr tuple))))
 824                        (and (string-match (concat "^" quoted-query) query)
 825                             (> (length (match-string 0 query))
 826                                longest-length)))
 827                   do (setq longest tuple))
 828             longest))
 829          (saved-search-name (car saved-search))
 830          (saved-search-query (cdr saved-search)))
 831     (cond ((and saved-search (equal saved-search-query query))
 832            ;; Query is the same as saved search (ignoring case)
 833            (concat "*notmuch-saved-search-" saved-search-name "*"))
 834           (saved-search
 835            (concat "*notmuch-search-"
 836                    (replace-regexp-in-string (concat "^" (regexp-quote saved-search-query))
 837                                              (concat "[ " saved-search-name " ]")
 838                                              query)
 839                    "*"))
 840           (t
 841            (concat "*notmuch-search-" query "*"))
 842           )))
 843
 844 (defun notmuch-read-query (prompt)
 845   "Read a notmuch-query from the minibuffer with completion.
 846
 847 PROMPT is the string to prompt with."
 848   (lexical-let
 849       ((completions
 850         (append (list "folder:" "thread:" "id:" "date:" "from:" "to:"
 851                       "subject:" "attachment:")
 852                 (mapcar (lambda (tag)
 853                           (concat "tag:" (notmuch-escape-boolean-term tag)))
 854                         (process-lines notmuch-command "search" "--output=tags" "*")))))
 855     (let ((keymap (copy-keymap minibuffer-local-map))
 856           (minibuffer-completion-table
 857            (completion-table-dynamic
 858             (lambda (string)
 859               ;; generate a list of possible completions for the current input
 860               (cond
 861                ;; this ugly regexp is used to get the last word of the input
 862                ;; possibly preceded by a '('
 863                ((string-match "\\(^\\|.* (?\\)\\([^ ]*\\)$" string)
 864                 (mapcar (lambda (compl)
 865                           (concat (match-string-no-properties 1 string) compl))
 866                         (all-completions (match-string-no-properties 2 string)
 867                                          completions)))
 868                (t (list string)))))))
 869       ;; this was simpler than convincing completing-read to accept spaces:
 870       (define-key keymap (kbd "TAB") 'minibuffer-complete)
 871       (let ((history-delete-duplicates t))
 872         (read-from-minibuffer prompt nil keymap nil
 873                               'notmuch-search-history nil nil)))))
 874
 875 ;;;###autoload
 876 (defun notmuch-search (&optional query oldest-first target-thread target-line)
 877   "Run \"notmuch search\" with the given `query' and display results.
 878
 879 If `query' is nil, it is read interactively from the minibuffer.
 880 Other optional parameters are used as follows:
 881
 882   oldest-first: A Boolean controlling the sort order of returned threads
 883   target-thread: A thread ID (without the thread: prefix) that will be made
 884                  current if it appears in the search results.
 885   target-line: The line number to move to if the target thread does not
 886                appear in the search results.
 887
 888 When called interactively, this will prompt for a query and use
 889 the configured default sort order."
 890   (interactive
 891    (list
 892     ;; Prompt for a query
 893     nil
 894     ;; Use the default search order (if we're doing a search from a
 895     ;; search buffer, ignore any buffer-local overrides)
 896     (default-value notmuch-search-oldest-first)))
 897
 898   (let* ((query (or query (notmuch-read-query "Notmuch search: ")))
 899          (buffer (get-buffer-create (notmuch-search-buffer-title query))))
 900     (switch-to-buffer buffer)
 901     (notmuch-search-mode)
 902     ;; Don't track undo information for this buffer
 903     (set 'buffer-undo-list t)
 904     (set 'notmuch-search-query-string query)
 905     (set 'notmuch-search-oldest-first oldest-first)
 906     (set 'notmuch-search-target-thread target-thread)
 907     (set 'notmuch-search-target-line target-line)
 908     (let ((proc (get-buffer-process (current-buffer)))
 909           (inhibit-read-only t))
 910       (if proc
 911           (error "notmuch search process already running for query `%s'" query)
 912         )
 913       (erase-buffer)
 914       (goto-char (point-min))
 915       (save-excursion
 916         (let ((proc (notmuch-start-notmuch
 917                      "notmuch-search" buffer #'notmuch-search-process-sentinel
 918                      "search" "--format=sexp" "--format-version=1"
 919                      (if oldest-first
 920                          "--sort=oldest-first"
 921                        "--sort=newest-first")
 922                      query))
 923               ;; Use a scratch buffer to accumulate partial output.
 924               ;; This buffer will be killed by the sentinel, which
 925               ;; should be called no matter how the process dies.
 926               (parse-buf (generate-new-buffer " *notmuch search parse*")))
 927           (process-put proc 'parse-buf parse-buf)
 928           (set-process-filter proc 'notmuch-search-process-filter)
 929           (set-process-query-on-exit-flag proc nil))))
 930     (run-hooks 'notmuch-search-hook)))
 931
 932 (defun notmuch-search-refresh-view ()
 933   "Refresh the current view.
 934
 935 Kills the current buffer and runs a new search with the same
 936 query string as the current search. If the current thread is in
 937 the new search results, then point will be placed on the same
 938 thread. Otherwise, point will be moved to attempt to be in the
 939 same relative position within the new buffer."
 940   (let ((target-line (line-number-at-pos))
 941         (oldest-first notmuch-search-oldest-first)
 942         (target-thread (notmuch-search-find-thread-id 'bare))
 943         (query notmuch-search-query-string))
 944     (notmuch-kill-this-buffer)
 945     (notmuch-search query oldest-first target-thread target-line)
 946     (goto-char (point-min))))
 947
 948 (defun notmuch-search-toggle-order ()
 949   "Toggle the current search order.
 950
 951 This command toggles the sort order for the current search. The
 952 default sort order is defined by `notmuch-search-oldest-first'."
 953   (interactive)
 954   (set 'notmuch-search-oldest-first (not notmuch-search-oldest-first))
 955   (notmuch-search-refresh-view))
 956
 957 (defun notmuch-search-filter (query)
 958   "Filter the current search results based on an additional query string.
 959
 960 Runs a new search matching only messages that match both the
 961 current search results AND the additional query string provided."
 962   (interactive (list (notmuch-read-query "Filter search: ")))
 963   (let ((grouped-query (if (string-match-p notmuch-search-disjunctive-regexp query)
 964                            (concat "( " query " )")
 965                          query)))
 966     (notmuch-search (if (string= notmuch-search-query-string "*")
 967                         grouped-query
 968                       (concat notmuch-search-query-string " and " grouped-query)) notmuch-search-oldest-first)))
 969
 970 (defun notmuch-search-filter-by-tag (tag)
 971   "Filter the current search results based on a single tag.
 972
 973 Runs a new search matching only messages that match both the
 974 current search results AND that are tagged with the given tag."
 975   (interactive
 976    (list (notmuch-select-tag-with-completion "Filter by tag: ")))
 977   (notmuch-search (concat notmuch-search-query-string " and tag:" tag) notmuch-search-oldest-first))
 978
 979 ;;;###autoload
 980 (defun notmuch ()
 981   "Run notmuch and display saved searches, known tags, etc."
 982   (interactive)
 983   (notmuch-hello))
 984
 985 (defun notmuch-interesting-buffer (b)
 986   "Is the current buffer of interest to a notmuch user?"
 987   (with-current-buffer b
 988     (memq major-mode '(notmuch-show-mode
 989                        notmuch-search-mode
 990                        notmuch-hello-mode
 991                        message-mode))))
 992
 993 ;;;###autoload
 994 (defun notmuch-cycle-notmuch-buffers ()
 995   "Cycle through any existing notmuch buffers (search, show or hello).
 996
 997 If the current buffer is the only notmuch buffer, bury it. If no
 998 notmuch buffers exist, run `notmuch'."
 999   (interactive)
1000
1001   (let (start first)
1002     ;; If the current buffer is a notmuch buffer, remember it and then
1003     ;; bury it.
1004     (when (notmuch-interesting-buffer (current-buffer))
1005       (setq start (current-buffer))
1006       (bury-buffer))
1007
1008     ;; Find the first notmuch buffer.
1009     (setq first (loop for buffer in (buffer-list)
1010                      if (notmuch-interesting-buffer buffer)
1011                      return buffer))
1012
1013     (if first
1014         ;; If the first one we found is any other than the starting
1015         ;; buffer, switch to it.
1016         (unless (eq first start)
1017           (switch-to-buffer first))
1018       (notmuch))))
1019
1020 (setq mail-user-agent 'notmuch-user-agent)
1021
1022 (provide 'notmuch)