git.notmuchmail.org Git - notmuch/blob - emacs/notmuch.el

   1 ;;; notmuch.el --- run notmuch within emacs  -*- lexical-binding: t -*-
   2 ;;
   3 ;; Copyright © Carl Worth
   4 ;;
   5 ;; This file is part of Notmuch.
   6 ;;
   7 ;; Notmuch is free software: you can redistribute it and/or modify it
   8 ;; under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation, either version 3 of the License, or
  10 ;; (at your option) any later version.
  11 ;;
  12 ;; Notmuch is distributed in the hope that it will be useful, but
  13 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 ;; General Public License for more details.
  16 ;;
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with Notmuch.  If not, see <https://www.gnu.org/licenses/>.
  19 ;;
  20 ;; Authors: Carl Worth <cworth@cworth.org>
  21 ;; Homepage: https://notmuchmail.org
  22
  23 ;;; Commentary:
  24
  25 ;; This is an emacs-based interface to the notmuch mail system.
  26 ;;
  27 ;; You will first need to have the notmuch program installed and have a
  28 ;; notmuch database built in order to use this. See
  29 ;; https://notmuchmail.org for details.
  30 ;;
  31 ;; To install this software, copy it to a directory that is on the
  32 ;; `load-path' variable within emacs (a good candidate is
  33 ;; /usr/local/share/emacs/site-lisp). If you are viewing this from the
  34 ;; notmuch source distribution then you can simply run:
  35 ;;
  36 ;;      sudo make install-emacs
  37 ;;
  38 ;; to install it.
  39 ;;
  40 ;; Then, to actually run it, add:
  41 ;;
  42 ;;      (autoload 'notmuch "notmuch" "Notmuch mail" t)
  43 ;;
  44 ;; to your ~/.emacs file, and then run "M-x notmuch" from within emacs,
  45 ;; or run:
  46 ;;
  47 ;;      emacs -f notmuch
  48 ;;
  49 ;; Have fun, and let us know if you have any comment, questions, or
  50 ;; kudos: Notmuch list <notmuch@notmuchmail.org> (subscription is not
  51 ;; required, but is available from https://notmuchmail.org).
  52 ;;
  53 ;; Note for MELPA users (and others tracking the development version
  54 ;; of notmuch-emacs):
  55 ;;
  56 ;; This emacs package needs a fairly closely matched version of the
  57 ;; notmuch program. If you use the MELPA version of notmuch.el (as
  58 ;; opposed to MELPA stable), you should be prepared to track the
  59 ;; master development branch (i.e. build from git) for the notmuch
  60 ;; program as well. Upgrading notmuch-emacs too far beyond the notmuch
  61 ;; program can CAUSE YOUR EMAIL TO STOP WORKING.
  62 ;;
  63 ;; TL;DR: notmuch-emacs from MELPA and notmuch from distro packages is
  64 ;; NOT SUPPORTED.
  65
  66 ;;; Code:
  67
  68 (eval-when-compile (require 'cl-lib))
  69
  70 (require 'mm-view)
  71 (require 'message)
  72
  73 (require 'notmuch-lib)
  74 (require 'notmuch-tag)
  75 (require 'notmuch-show)
  76 (require 'notmuch-tree)
  77 (require 'notmuch-mua)
  78 (require 'notmuch-hello)
  79 (require 'notmuch-maildir-fcc)
  80 (require 'notmuch-message)
  81 (require 'notmuch-parser)
  82
  83 ;;; Options
  84
  85 (defcustom notmuch-search-result-format
  86   `(("date" . "%12s ")
  87     ("count" . "%-7s ")
  88     ("authors" . "%-20s ")
  89     ("subject" . "%s ")
  90     ("tags" . "(%s)"))
  91   "Search result formatting. Supported fields are:
  92         date, count, authors, subject, tags
  93 For example:
  94         (setq notmuch-search-result-format \(\(\"authors\" . \"%-40s\"\)
  95                                              \(\"subject\" . \"%s\"\)\)\)
  96 Line breaks are permitted in format strings (though this is
  97 currently experimental).  Note that a line break at the end of an
  98 \"authors\" field will get elided if the authors list is long;
  99 place it instead at the beginning of the following field.  To
 100 enter a line break when setting this variable with setq, use \\n.
 101 To enter a line break in customize, press \\[quoted-insert] C-j."
 102   :type '(alist :key-type (string) :value-type (string))
 103   :group 'notmuch-search)
 104
 105 ;; The name of this variable `notmuch-init-file' is consistent with the
 106 ;; convention used in e.g. emacs and gnus. The value, `notmuch-config[.el[c]]'
 107 ;; is consistent with notmuch cli configuration file `~/.notmuch-config'.
 108 (defcustom notmuch-init-file (locate-user-emacs-file "notmuch-config")
 109   "Your Notmuch Emacs-Lisp configuration file name.
 110 If a file with one of the suffixes defined by `get-load-suffixes' exists,
 111 it will be read instead.
 112 This file is read once when notmuch is loaded; the notmuch hooks added
 113 there will be called at other points of notmuch execution."
 114   :type 'file
 115   :group 'notmuch)
 116
 117 (defvar notmuch-query-history nil
 118   "Variable to store minibuffer history for notmuch queries.")
 119
 120 ;;; Mime Utilities
 121
 122 (defun notmuch-foreach-mime-part (function mm-handle)
 123   (cond ((stringp (car mm-handle))
 124          (dolist (part (cdr mm-handle))
 125            (notmuch-foreach-mime-part function part)))
 126         ((bufferp (car mm-handle))
 127          (funcall function mm-handle))
 128         (t (dolist (part mm-handle)
 129              (notmuch-foreach-mime-part function part)))))
 130
 131 (defun notmuch-count-attachments (mm-handle)
 132   (let ((count 0))
 133     (notmuch-foreach-mime-part
 134      (lambda (p)
 135        (let ((disposition (mm-handle-disposition p)))
 136          (and (listp disposition)
 137               (or (equal (car disposition) "attachment")
 138                   (and (equal (car disposition) "inline")
 139                        (assq 'filename disposition)))
 140               (cl-incf count))))
 141      mm-handle)
 142     count))
 143
 144 (defun notmuch-save-attachments (mm-handle &optional queryp)
 145   (notmuch-foreach-mime-part
 146    (lambda (p)
 147      (let ((disposition (mm-handle-disposition p)))
 148        (and (listp disposition)
 149             (or (equal (car disposition) "attachment")
 150                 (and (equal (car disposition) "inline")
 151                      (assq 'filename disposition)))
 152             (or (not queryp)
 153                 (y-or-n-p
 154                  (concat "Save '" (cdr (assq 'filename disposition)) "' ")))
 155             (mm-save-part p))))
 156    mm-handle))
 157
 158 ;;; Integrations
 159
 160 (require 'hl-line)
 161
 162 (defun notmuch-hl-line-mode ()
 163   (prog1 (hl-line-mode)
 164     (when hl-line-overlay
 165       (overlay-put hl-line-overlay 'priority 1))))
 166
 167 ;;; Options
 168
 169 (defcustom notmuch-search-hook '(notmuch-hl-line-mode)
 170   "List of functions to call when notmuch displays the search results."
 171   :type 'hook
 172   :options '(notmuch-hl-line-mode)
 173   :group 'notmuch-search
 174   :group 'notmuch-hooks)
 175
 176 ;;; Keymap
 177
 178 (defvar notmuch-search-mode-map
 179   (let ((map (make-sparse-keymap)))
 180     (set-keymap-parent map notmuch-common-keymap)
 181     (define-key map "x" 'notmuch-bury-or-kill-this-buffer)
 182     (define-key map (kbd "DEL") 'notmuch-search-scroll-down)
 183     (define-key map "b" 'notmuch-search-scroll-down)
 184     (define-key map " " 'notmuch-search-scroll-up)
 185     (define-key map "<" 'notmuch-search-first-thread)
 186     (define-key map ">" 'notmuch-search-last-thread)
 187     (define-key map "p" 'notmuch-search-previous-thread)
 188     (define-key map "n" 'notmuch-search-next-thread)
 189     (define-key map "r" 'notmuch-search-reply-to-thread-sender)
 190     (define-key map "R" 'notmuch-search-reply-to-thread)
 191     (define-key map "o" 'notmuch-search-toggle-order)
 192     (define-key map "c" 'notmuch-search-stash-map)
 193     (define-key map "t" 'notmuch-search-filter-by-tag)
 194     (define-key map "l" 'notmuch-search-filter)
 195     (define-key map [mouse-1] 'notmuch-search-show-thread)
 196     (define-key map "k" 'notmuch-tag-jump)
 197     (define-key map "*" 'notmuch-search-tag-all)
 198     (define-key map "a" 'notmuch-search-archive-thread)
 199     (define-key map "-" 'notmuch-search-remove-tag)
 200     (define-key map "+" 'notmuch-search-add-tag)
 201     (define-key map (kbd "RET") 'notmuch-search-show-thread)
 202     (define-key map (kbd "M-RET") 'notmuch-tree-from-search-thread)
 203     (define-key map "Z" 'notmuch-tree-from-search-current-query)
 204     (define-key map "U" 'notmuch-unthreaded-from-search-current-query)
 205     map)
 206   "Keymap for \"notmuch search\" buffers.")
 207
 208 ;;; Stashing
 209
 210 (defvar notmuch-search-stash-map
 211   (let ((map (make-sparse-keymap)))
 212     (define-key map "i" 'notmuch-search-stash-thread-id)
 213     (define-key map "q" 'notmuch-stash-query)
 214     (define-key map "?" 'notmuch-subkeymap-help)
 215     map)
 216   "Submap for stash commands.")
 217 (fset 'notmuch-search-stash-map notmuch-search-stash-map)
 218
 219 (defun notmuch-search-stash-thread-id ()
 220   "Copy thread ID of current thread to kill-ring."
 221   (interactive)
 222   (notmuch-common-do-stash (notmuch-search-find-thread-id)))
 223
 224 (defun notmuch-stash-query ()
 225   "Copy current query to kill-ring."
 226   (interactive)
 227   (notmuch-common-do-stash (notmuch-search-get-query)))
 228
 229 ;;; Variables
 230
 231 (defvar notmuch-search-query-string)
 232 (defvar notmuch-search-target-thread)
 233 (defvar notmuch-search-target-line)
 234
 235 ;;; Movement
 236
 237 (defun notmuch-search-scroll-up ()
 238   "Move forward through search results by one window's worth."
 239   (interactive)
 240   (condition-case nil
 241       (scroll-up nil)
 242     ((end-of-buffer) (notmuch-search-last-thread))))
 243
 244 (defun notmuch-search-scroll-down ()
 245   "Move backward through the search results by one window's worth."
 246   (interactive)
 247   ;; I don't know why scroll-down doesn't signal beginning-of-buffer
 248   ;; the way that scroll-up signals end-of-buffer, but c'est la vie.
 249   ;;
 250   ;; So instead of trapping a signal we instead check whether the
 251   ;; window begins on the first line of the buffer and if so, move
 252   ;; directly to that position. (We have to count lines since the
 253   ;; window-start position is not the same as point-min due to the
 254   ;; invisible thread-ID characters on the first line.
 255   (if (equal (count-lines (point-min) (window-start)) 0)
 256       (goto-char (point-min))
 257     (scroll-down nil)))
 258
 259 (defun notmuch-search-next-thread ()
 260   "Select the next thread in the search results."
 261   (interactive)
 262   (when (notmuch-search-get-result)
 263     (goto-char (notmuch-search-result-end))))
 264
 265 (defun notmuch-search-previous-thread ()
 266   "Select the previous thread in the search results."
 267   (interactive)
 268   (if (notmuch-search-get-result)
 269       (unless (bobp)
 270         (goto-char (notmuch-search-result-beginning (- (point) 1))))
 271     ;; We must be past the end; jump to the last result
 272     (notmuch-search-last-thread)))
 273
 274 (defun notmuch-search-last-thread ()
 275   "Select the last thread in the search results."
 276   (interactive)
 277   (goto-char (point-max))
 278   (forward-line -2)
 279   (let ((beg (notmuch-search-result-beginning)))
 280     (when beg
 281       (goto-char beg))))
 282
 283 (defun notmuch-search-first-thread ()
 284   "Select the first thread in the search results."
 285   (interactive)
 286   (goto-char (point-min)))
 287
 288 ;;; Faces
 289
 290 (defface notmuch-message-summary-face
 291   `((((class color) (background light))
 292      ,@(and (>= emacs-major-version 27) '(:extend t))
 293      :background "#f0f0f0")
 294     (((class color) (background dark))
 295      ,@(and (>= emacs-major-version 27) '(:extend t))
 296      :background "#303030"))
 297   "Face for the single-line message summary in notmuch-show-mode."
 298   :group 'notmuch-show
 299   :group 'notmuch-faces)
 300
 301 (defface notmuch-search-date
 302   '((t :inherit default))
 303   "Face used in search mode for dates."
 304   :group 'notmuch-search
 305   :group 'notmuch-faces)
 306
 307 (defface notmuch-search-count
 308   '((t :inherit default))
 309   "Face used in search mode for the count matching the query."
 310   :group 'notmuch-search
 311   :group 'notmuch-faces)
 312
 313 (defface notmuch-search-subject
 314   '((t :inherit default))
 315   "Face used in search mode for subjects."
 316   :group 'notmuch-search
 317   :group 'notmuch-faces)
 318
 319 (defface notmuch-search-matching-authors
 320   '((t :inherit default))
 321   "Face used in search mode for authors matching the query."
 322   :group 'notmuch-search
 323   :group 'notmuch-faces)
 324
 325 (defface notmuch-search-non-matching-authors
 326   '((((class color)
 327       (background dark))
 328      (:foreground "grey30"))
 329     (((class color)
 330       (background light))
 331      (:foreground "grey60"))
 332     (t
 333      (:italic t)))
 334   "Face used in search mode for authors not matching the query."
 335   :group 'notmuch-search
 336   :group 'notmuch-faces)
 337
 338 (defface notmuch-tag-face
 339   '((((class color)
 340       (background dark))
 341      (:foreground "OliveDrab1"))
 342     (((class color)
 343       (background light))
 344      (:foreground "navy blue" :bold t))
 345     (t
 346      (:bold t)))
 347   "Face used in search mode face for tags."
 348   :group 'notmuch-search
 349   :group 'notmuch-faces)
 350
 351 (defface notmuch-search-flagged-face
 352   '((((class color)
 353       (background dark))
 354      (:foreground "LightBlue1"))
 355     (((class color)
 356       (background light))
 357      (:foreground "blue")))
 358   "Face used in search mode face for flagged threads.
 359
 360 This face is the default value for the \"flagged\" tag in
 361 `notmuch-search-line-faces'."
 362   :group 'notmuch-search
 363   :group 'notmuch-faces)
 364
 365 (defface notmuch-search-unread-face
 366   '((t
 367      (:weight bold)))
 368   "Face used in search mode for unread threads.
 369
 370 This face is the default value for the \"unread\" tag in
 371 `notmuch-search-line-faces'."
 372   :group 'notmuch-search
 373   :group 'notmuch-faces)
 374
 375 ;;; Mode
 376
 377 (define-derived-mode notmuch-search-mode fundamental-mode "notmuch-search"
 378   "Major mode displaying results of a notmuch search.
 379
 380 This buffer contains the results of a \"notmuch search\" of your
 381 email archives. Each line in the buffer represents a single
 382 thread giving a summary of the thread (a relative date, the
 383 number of matched messages and total messages in the thread,
 384 participants in the thread, a representative subject line, and
 385 any tags).
 386
 387 Pressing \\[notmuch-search-show-thread] on any line displays that
 388 thread. The '\\[notmuch-search-add-tag]' and
 389 '\\[notmuch-search-remove-tag]' keys can be used to add or remove
 390 tags from a thread. The '\\[notmuch-search-archive-thread]' key
 391 is a convenience for archiving a thread (applying changes in
 392 `notmuch-archive-tags'). The '\\[notmuch-search-tag-all]' key can
 393 be used to add and/or remove tags from all messages (as opposed
 394 to threads) that match the current query.  Use with caution, as
 395 this will also tag matching messages that arrived *after*
 396 constructing the buffer.
 397
 398 Other useful commands are '\\[notmuch-search-filter]' for
 399 filtering the current search based on an additional query string,
 400 '\\[notmuch-search-filter-by-tag]' for filtering to include only
 401 messages with a given tag, and '\\[notmuch-search]' to execute a
 402 new, global search.
 403
 404 Complete list of currently available key bindings:
 405
 406 \\{notmuch-search-mode-map}"
 407   (make-local-variable 'notmuch-search-query-string)
 408   (make-local-variable 'notmuch-search-oldest-first)
 409   (make-local-variable 'notmuch-search-target-thread)
 410   (make-local-variable 'notmuch-search-target-line)
 411   (setq notmuch-buffer-refresh-function #'notmuch-search-refresh-view)
 412   (setq-local scroll-preserve-screen-position t)
 413   (add-to-invisibility-spec (cons 'ellipsis t))
 414   (setq truncate-lines t)
 415   (setq buffer-read-only t)
 416   (setq imenu-prev-index-position-function
 417         #'notmuch-search-imenu-prev-index-position-function)
 418   (setq imenu-extract-index-name-function
 419         #'notmuch-search-imenu-extract-index-name-function))
 420
 421 ;;; Search Results
 422
 423 (defun notmuch-search-get-result (&optional pos)
 424   "Return the result object for the thread at POS (or point).
 425
 426 If there is no thread at POS (or point), returns nil."
 427   (get-text-property (or pos (point)) 'notmuch-search-result))
 428
 429 (defun notmuch-search-result-beginning (&optional pos)
 430   "Return the point at the beginning of the thread at POS (or point).
 431
 432 If there is no thread at POS (or point), returns nil."
 433   (and (notmuch-search-get-result pos)
 434        ;; We pass 1+point because previous-single-property-change starts
 435        ;; searching one before the position we give it.
 436        (previous-single-property-change (1+ (or pos (point)))
 437                                         'notmuch-search-result nil
 438                                         (point-min))))
 439
 440 (defun notmuch-search-result-end (&optional pos)
 441   "Return the point at the end of the thread at POS (or point).
 442
 443 The returned point will be just after the newline character that
 444 ends the result line.  If there is no thread at POS (or point),
 445 returns nil."
 446   (and (notmuch-search-get-result pos)
 447        (next-single-property-change (or pos (point))
 448                                     'notmuch-search-result nil
 449                                     (point-max))))
 450
 451 (defun notmuch-search-foreach-result (beg end fn)
 452   "Invoke FN for each result between BEG and END.
 453
 454 FN should take one argument.  It will be applied to the character
 455 position of the beginning of each result that overlaps the region
 456 between points BEG and END.  As a special case, if (= BEG END),
 457 FN will be applied to the result containing point BEG."
 458   (let ((pos (notmuch-search-result-beginning beg))
 459         ;; End must be a marker in case fn changes the
 460         ;; text.
 461         (end (copy-marker end))
 462         ;; Make sure we examine at least one result, even if
 463         ;; (= beg end).
 464         (first t))
 465     ;; We have to be careful if the region extends beyond the results.
 466     ;; In this case, pos could be null or there could be no result at
 467     ;; pos.
 468     (while (and pos (or (< pos end) first))
 469       (when (notmuch-search-get-result pos)
 470         (funcall fn pos))
 471       (setq pos (notmuch-search-result-end pos))
 472       (setq first nil))))
 473 ;; Unindent the function argument of notmuch-search-foreach-result so
 474 ;; the indentation of callers doesn't get out of hand.
 475 (put 'notmuch-search-foreach-result 'lisp-indent-function 2)
 476
 477 (defun notmuch-search-properties-in-region (property beg end)
 478   (let (output)
 479     (notmuch-search-foreach-result beg end
 480       (lambda (pos)
 481         (push (plist-get (notmuch-search-get-result pos) property) output)))
 482     output))
 483
 484 (defun notmuch-search-find-thread-id (&optional bare)
 485   "Return the thread for the current thread.
 486
 487 If BARE is set then do not prefix with \"thread:\"."
 488   (let ((thread (plist-get (notmuch-search-get-result) :thread)))
 489     (when thread
 490       (concat (and (not bare) "thread:") thread))))
 491
 492 (defun notmuch-search-find-stable-query ()
 493   "Return the stable queries for the current thread.
 494
 495 Return a list (MATCHED-QUERY UNMATCHED-QUERY) for the
 496 matched and unmatched messages in the current thread."
 497   (plist-get (notmuch-search-get-result) :query))
 498
 499 (defun notmuch-search-find-stable-query-region (beg end &optional only-matched)
 500   "Return the stable query for the current region.
 501
 502 If ONLY-MATCHED is non-nil, include only matched messages.  If it
 503 is nil, include both matched and unmatched messages. If there are
 504 no messages in the region then return nil."
 505   (let ((query-list nil) (all (not only-matched)))
 506     (dolist (queries (notmuch-search-properties-in-region :query beg end))
 507       (when (car queries)
 508         (push (car queries) query-list))
 509       (when (and all (cadr queries))
 510         (push (cadr queries) query-list)))
 511     (and query-list
 512          (concat "(" (mapconcat 'identity query-list ") or (") ")"))))
 513
 514 (defun notmuch-search-find-authors ()
 515   "Return the authors for the current thread."
 516   (plist-get (notmuch-search-get-result) :authors))
 517
 518 (defun notmuch-search-find-authors-region (beg end)
 519   "Return a list of authors for the current region."
 520   (notmuch-search-properties-in-region :authors beg end))
 521
 522 (defun notmuch-search-find-subject ()
 523   "Return the subject for the current thread."
 524   (plist-get (notmuch-search-get-result) :subject))
 525
 526 (defun notmuch-search-find-subject-region (beg end)
 527   "Return a list of authors for the current region."
 528   (notmuch-search-properties-in-region :subject beg end))
 529
 530 (defun notmuch-search-show-thread (&optional elide-toggle)
 531   "Display the currently selected thread.
 532
 533 With a prefix argument, invert the default value of
 534 `notmuch-show-only-matching-messages' when displaying the
 535 thread."
 536   (interactive "P")
 537   (let ((thread-id (notmuch-search-find-thread-id))
 538         (subject (notmuch-search-find-subject)))
 539     (if (> (length thread-id) 0)
 540         (notmuch-show thread-id
 541                       elide-toggle
 542                       (current-buffer)
 543                       notmuch-search-query-string
 544                       ;; Name the buffer based on the subject.
 545                       (concat "*"
 546                               (truncate-string-to-width subject 30 nil nil t)
 547                               "*"))
 548       (message "End of search results."))))
 549
 550 (defun notmuch-tree-from-search-current-query ()
 551   "Call notmuch tree with the current query."
 552   (interactive)
 553   (notmuch-tree notmuch-search-query-string))
 554
 555 (defun notmuch-unthreaded-from-search-current-query ()
 556   "Call notmuch tree with the current query."
 557   (interactive)
 558   (notmuch-unthreaded notmuch-search-query-string))
 559
 560 (defun notmuch-tree-from-search-thread ()
 561   "Show the selected thread with notmuch-tree."
 562   (interactive)
 563   (notmuch-tree (notmuch-search-find-thread-id)
 564                 notmuch-search-query-string
 565                 nil
 566                 (notmuch-prettify-subject (notmuch-search-find-subject))
 567                 t nil (current-buffer)))
 568
 569 (defun notmuch-search-reply-to-thread (&optional prompt-for-sender)
 570   "Begin composing a reply-all to the entire current thread in a new buffer."
 571   (interactive "P")
 572   (let ((message-id (notmuch-search-find-thread-id)))
 573     (notmuch-mua-new-reply message-id prompt-for-sender t)))
 574
 575 (defun notmuch-search-reply-to-thread-sender (&optional prompt-for-sender)
 576   "Begin composing a reply to the entire current thread in a new buffer."
 577   (interactive "P")
 578   (let ((message-id (notmuch-search-find-thread-id)))
 579     (notmuch-mua-new-reply message-id prompt-for-sender nil)))
 580
 581 ;;; Tags
 582
 583 (defun notmuch-search-set-tags (tags &optional pos)
 584   (let ((new-result (plist-put (notmuch-search-get-result pos) :tags tags)))
 585     (notmuch-search-update-result new-result pos)))
 586
 587 (defun notmuch-search-get-tags (&optional pos)
 588   (plist-get (notmuch-search-get-result pos) :tags))
 589
 590 (defun notmuch-search-get-tags-region (beg end)
 591   (let (output)
 592     (notmuch-search-foreach-result beg end
 593       (lambda (pos)
 594         (setq output (append output (notmuch-search-get-tags pos)))))
 595     output))
 596
 597 (defun notmuch-search-interactive-tag-changes (&optional initial-input)
 598   "Prompt for tag changes for the current thread or region.
 599
 600 Return (TAG-CHANGES REGION-BEGIN REGION-END)."
 601   (pcase-let ((`(,beg ,end) (notmuch-interactive-region)))
 602     (list (notmuch-read-tag-changes (notmuch-search-get-tags-region beg end)
 603                                     (if (= beg end) "Tag thread" "Tag region")
 604                                     initial-input)
 605           beg end)))
 606
 607 (defun notmuch-search-tag (tag-changes &optional beg end only-matched)
 608   "Change tags for the currently selected thread or region.
 609
 610 See `notmuch-tag' for information on the format of TAG-CHANGES.
 611 When called interactively, this uses the region if the region is
 612 active.  When called directly, BEG and END provide the region.
 613 If these are nil or not provided, then, if the region is active
 614 this applied to all threads meeting the region, and if the region
 615 is inactive this applies to the thread at point.
 616
 617 If ONLY-MATCHED is non-nil, only tag matched messages."
 618   (interactive (notmuch-search-interactive-tag-changes))
 619   (unless (and beg end)
 620     (setq beg (car (notmuch-interactive-region)))
 621     (setq end (cadr (notmuch-interactive-region))))
 622   (let ((search-string (notmuch-search-find-stable-query-region
 623                         beg end only-matched)))
 624     (notmuch-tag search-string tag-changes)
 625     (notmuch-search-foreach-result beg end
 626       (lambda (pos)
 627         (notmuch-search-set-tags
 628          (notmuch-update-tags (notmuch-search-get-tags pos) tag-changes)
 629          pos)))))
 630
 631 (defun notmuch-search-add-tag (tag-changes &optional beg end)
 632   "Change tags for the current thread or region (defaulting to add).
 633
 634 Same as `notmuch-search-tag' but sets initial input to '+'."
 635   (interactive (notmuch-search-interactive-tag-changes "+"))
 636   (notmuch-search-tag tag-changes beg end))
 637
 638 (defun notmuch-search-remove-tag (tag-changes &optional beg end)
 639   "Change tags for the current thread or region (defaulting to remove).
 640
 641 Same as `notmuch-search-tag' but sets initial input to '-'."
 642   (interactive (notmuch-search-interactive-tag-changes "-"))
 643   (notmuch-search-tag tag-changes beg end))
 644
 645 (put 'notmuch-search-archive-thread 'notmuch-prefix-doc
 646      "Un-archive the currently selected thread.")
 647 (defun notmuch-search-archive-thread (&optional unarchive beg end)
 648   "Archive the currently selected thread or region.
 649
 650 Archive each message in the currently selected thread by applying
 651 the tag changes in `notmuch-archive-tags' to each (remove the
 652 \"inbox\" tag by default). If a prefix argument is given, the
 653 messages will be \"unarchived\" (i.e. the tag changes in
 654 `notmuch-archive-tags' will be reversed).
 655
 656 This function advances the next thread when finished."
 657   (interactive (cons current-prefix-arg (notmuch-interactive-region)))
 658   (when notmuch-archive-tags
 659     (notmuch-search-tag
 660      (notmuch-tag-change-list notmuch-archive-tags unarchive) beg end))
 661   (when (eq beg end)
 662     (notmuch-search-next-thread)))
 663
 664 ;;; Search Results
 665
 666 (defun notmuch-search-update-result (result &optional pos)
 667   "Replace the result object of the thread at POS (or point) by
 668 RESULT and redraw it.
 669
 670 This will keep point in a reasonable location.  However, if there
 671 are enclosing save-excursions and the saved point is in the
 672 result being updated, the point will be restored to the beginning
 673 of the result."
 674   (let ((start (notmuch-search-result-beginning pos))
 675         (end (notmuch-search-result-end pos))
 676         (init-point (point))
 677         (inhibit-read-only t))
 678     ;; Delete the current thread
 679     (delete-region start end)
 680     ;; Insert the updated thread
 681     (notmuch-search-show-result result start)
 682     ;; If point was inside the old result, make an educated guess
 683     ;; about where to place it now.  Unfortunately, this won't work
 684     ;; with save-excursion (or any other markers that would be nice to
 685     ;; preserve, such as the window start), but there's nothing we can
 686     ;; do about that without a way to retrieve markers in a region.
 687     (when (and (>= init-point start) (<= init-point end))
 688       (let* ((new-end (notmuch-search-result-end start))
 689              (new-point (if (= init-point end)
 690                             new-end
 691                           (min init-point (- new-end 1)))))
 692         (goto-char new-point)))))
 693
 694 (defun notmuch-search-process-sentinel (proc _msg)
 695   "Add a message to let user know when \"notmuch search\" exits."
 696   (let ((buffer (process-buffer proc))
 697         (status (process-status proc))
 698         (exit-status (process-exit-status proc))
 699         (never-found-target-thread nil))
 700     (when (memq status '(exit signal))
 701       (catch 'return
 702         (kill-buffer (process-get proc 'parse-buf))
 703         (when (buffer-live-p buffer)
 704           (with-current-buffer buffer
 705             (save-excursion
 706               (let ((inhibit-read-only t)
 707                     (atbob (bobp)))
 708                 (goto-char (point-max))
 709                 (when (eq status 'signal)
 710                   (insert "Incomplete search results (search process was killed).\n"))
 711                 (when (eq status 'exit)
 712                   (insert "End of search results.\n")
 713                   ;; For version mismatch, there's no point in
 714                   ;; showing the search buffer
 715                   (when (or (= exit-status 20) (= exit-status 21))
 716                     (kill-buffer)
 717                     (throw 'return nil))
 718                   (when (and atbob
 719                              (not (string= notmuch-search-target-thread "found")))
 720                     (setq never-found-target-thread t)))))
 721             (when (and never-found-target-thread
 722                        notmuch-search-target-line)
 723               (goto-char (point-min))
 724               (forward-line (1- notmuch-search-target-line)))))))))
 725
 726 (define-widget 'notmuch--custom-face-edit 'lazy
 727   "Custom face edit with a tag Edit Face"
 728   ;; I could not persuage custom-face-edit to respect the :tag
 729   ;; property so create a widget specially
 730   :tag "Manually specify face"
 731   :type 'custom-face-edit)
 732
 733 (defcustom notmuch-search-line-faces
 734   '(("unread" . notmuch-search-unread-face)
 735     ("flagged" . notmuch-search-flagged-face))
 736   "Alist of tags to faces for line highlighting in notmuch-search.
 737 Each element looks like (TAG . FACE).
 738 A thread with TAG will have FACE applied.
 739
 740 Here is an example of how to color search results based on tags.
 741  (the following text would be placed in your ~/.emacs file):
 742
 743  (setq notmuch-search-line-faces \\='((\"unread\" . (:foreground \"green\"))
 744                                    (\"deleted\" . (:foreground \"red\"
 745                                                   :background \"blue\"))))
 746
 747 The FACE must be a face name (a symbol or string), a property
 748 list of face attributes, or a list of these.  The faces for
 749 matching tags are merged, with earlier attributes overriding
 750 later. A message having both \"deleted\" and \"unread\" tags with
 751 the above settings would have a green foreground and blue
 752 background."
 753   :type '(alist :key-type (string)
 754                 :value-type (radio (face :tag "Face name")
 755                                    (notmuch--custom-face-edit)))
 756   :group 'notmuch-search
 757   :group 'notmuch-faces)
 758
 759 (defun notmuch-search-color-line (start end line-tag-list)
 760   "Colorize lines in `notmuch-show' based on tags."
 761   ;; Reverse the list so earlier entries take precedence
 762   (dolist (elem (reverse notmuch-search-line-faces))
 763     (let ((tag (car elem))
 764           (face (cdr elem)))
 765       (when (member tag line-tag-list)
 766         (notmuch-apply-face nil face nil start end)))))
 767
 768 (defun notmuch-search-author-propertize (authors)
 769   "Split `authors' into matching and non-matching authors and
 770 propertize appropriately. If no boundary between authors and
 771 non-authors is found, assume that all of the authors match."
 772   (if (string-match "\\(.*\\)|\\(.*\\)" authors)
 773       (concat (propertize (concat (match-string 1 authors) ",")
 774                           'face 'notmuch-search-matching-authors)
 775               (propertize (match-string 2 authors)
 776                           'face 'notmuch-search-non-matching-authors))
 777     (propertize authors 'face 'notmuch-search-matching-authors)))
 778
 779 (defun notmuch-search-insert-authors (format-string authors)
 780   ;; Save the match data to avoid interfering with
 781   ;; `notmuch-search-process-filter'.
 782   (save-match-data
 783     (let* ((formatted-authors (format format-string authors))
 784            (formatted-sample (format format-string ""))
 785            (visible-string formatted-authors)
 786            (invisible-string "")
 787            (padding ""))
 788       ;; Truncate the author string to fit the specification.
 789       (when (> (length formatted-authors)
 790                (length formatted-sample))
 791         (let ((visible-length (- (length formatted-sample)
 792                                  (length "... "))))
 793           ;; Truncate the visible string according to the width of
 794           ;; the display string.
 795           (setq visible-string (substring formatted-authors 0 visible-length))
 796           (setq invisible-string (substring formatted-authors visible-length))
 797           ;; If possible, truncate the visible string at a natural
 798           ;; break (comma or pipe), as incremental search doesn't
 799           ;; match across the visible/invisible border.
 800           (when (string-match "\\(.*\\)\\([,|] \\)\\([^,|]*\\)" visible-string)
 801             ;; Second clause is destructive on `visible-string', so
 802             ;; order is important.
 803             (setq invisible-string (concat (match-string 3 visible-string)
 804                                            invisible-string))
 805             (setq visible-string (concat (match-string 1 visible-string)
 806                                          (match-string 2 visible-string))))
 807           ;; `visible-string' may be shorter than the space allowed
 808           ;; by `format-string'. If so we must insert some padding
 809           ;; after `invisible-string'.
 810           (setq padding (make-string (- (length formatted-sample)
 811                                         (length visible-string)
 812                                         (length "..."))
 813                                      ? ))))
 814       ;; Use different faces to show matching and non-matching authors.
 815       (if (string-match "\\(.*\\)|\\(.*\\)" visible-string)
 816           ;; The visible string contains both matching and
 817           ;; non-matching authors.
 818           (progn
 819             (setq visible-string (notmuch-search-author-propertize visible-string))
 820             ;; The invisible string must contain only non-matching
 821             ;; authors, as the visible-string contains both.
 822             (setq invisible-string (propertize invisible-string
 823                                                'face 'notmuch-search-non-matching-authors)))
 824         ;; The visible string contains only matching authors.
 825         (setq visible-string (propertize visible-string
 826                                          'face 'notmuch-search-matching-authors))
 827         ;; The invisible string may contain both matching and
 828         ;; non-matching authors.
 829         (setq invisible-string (notmuch-search-author-propertize invisible-string)))
 830       ;; If there is any invisible text, add it as a tooltip to the
 831       ;; visible text.
 832       (unless (string= invisible-string "")
 833         (setq visible-string
 834               (propertize visible-string
 835                           'help-echo (concat "..." invisible-string))))
 836       ;; Insert the visible and, if present, invisible author strings.
 837       (insert visible-string)
 838       (unless (string= invisible-string "")
 839         (let ((start (point))
 840               overlay)
 841           (insert invisible-string)
 842           (setq overlay (make-overlay start (point)))
 843           (overlay-put overlay 'invisible 'ellipsis)
 844           (overlay-put overlay 'isearch-open-invisible #'delete-overlay)))
 845       (insert padding))))
 846
 847 (defun notmuch-search-insert-field (field format-string result)
 848   (cond
 849    ((string-equal field "date")
 850     (insert (propertize (format format-string (plist-get result :date_relative))
 851                         'face 'notmuch-search-date)))
 852    ((string-equal field "count")
 853     (insert (propertize (format format-string
 854                                 (format "[%s/%s]" (plist-get result :matched)
 855                                         (plist-get result :total)))
 856                         'face 'notmuch-search-count)))
 857    ((string-equal field "subject")
 858     (insert (propertize (format format-string
 859                                 (notmuch-sanitize (plist-get result :subject)))
 860                         'face 'notmuch-search-subject)))
 861    ((string-equal field "authors")
 862     (notmuch-search-insert-authors
 863      format-string (notmuch-sanitize (plist-get result :authors))))
 864    ((string-equal field "tags")
 865     (let ((tags (plist-get result :tags))
 866           (orig-tags (plist-get result :orig-tags)))
 867       (insert (format format-string (notmuch-tag-format-tags tags orig-tags)))))))
 868
 869 (defun notmuch-search-show-result (result pos)
 870   "Insert RESULT at POS."
 871   ;; Ignore excluded matches
 872   (unless (= (plist-get result :matched) 0)
 873     (save-excursion
 874       (goto-char pos)
 875       (dolist (spec notmuch-search-result-format)
 876         (notmuch-search-insert-field (car spec) (cdr spec) result))
 877       (insert "\n")
 878       (notmuch-search-color-line pos (point) (plist-get result :tags))
 879       (put-text-property pos (point) 'notmuch-search-result result))))
 880
 881 (defun notmuch-search-append-result (result)
 882   "Insert RESULT at the end of the buffer.
 883
 884 This is only called when a result is first inserted so it also
 885 sets the :orig-tag property."
 886   (let ((new-result (plist-put result :orig-tags (plist-get result :tags)))
 887         (pos (point-max)))
 888     (notmuch-search-show-result new-result pos)
 889     (when (string= (plist-get result :thread) notmuch-search-target-thread)
 890       (setq notmuch-search-target-thread "found")
 891       (goto-char pos))))
 892
 893 (defun notmuch-search-process-filter (proc string)
 894   "Process and filter the output of \"notmuch search\"."
 895   (let ((results-buf (process-buffer proc))
 896         (parse-buf (process-get proc 'parse-buf))
 897         (inhibit-read-only t))
 898     (when (buffer-live-p results-buf)
 899       (with-current-buffer parse-buf
 900         ;; Insert new data
 901         (save-excursion
 902           (goto-char (point-max))
 903           (insert string))
 904         (notmuch-sexp-parse-partial-list 'notmuch-search-append-result
 905                                          results-buf)))))
 906
 907 ;;; Commands (and some helper functions used by them)
 908
 909 (defun notmuch-search-tag-all (tag-changes)
 910   "Add/remove tags from all messages in current search buffer.
 911
 912 See `notmuch-tag' for information on the format of TAG-CHANGES."
 913   (interactive
 914    (list (notmuch-read-tag-changes
 915           (notmuch-search-get-tags-region (point-min) (point-max)) "Tag all")))
 916   (notmuch-search-tag tag-changes (point-min) (point-max) t))
 917
 918 (defun notmuch-search-buffer-title (query)
 919   "Returns the title for a buffer with notmuch search results."
 920   (let* ((saved-search
 921           (let (longest
 922                 (longest-length 0))
 923             (cl-loop for tuple in notmuch-saved-searches
 924                      if (let ((quoted-query
 925                                (regexp-quote
 926                                 (notmuch-saved-search-get tuple :query))))
 927                           (and (string-match (concat "^" quoted-query) query)
 928                                (> (length (match-string 0 query))
 929                                   longest-length)))
 930                      do (setq longest tuple))
 931             longest))
 932          (saved-search-name (notmuch-saved-search-get saved-search :name))
 933          (saved-search-query (notmuch-saved-search-get saved-search :query)))
 934     (cond ((and saved-search (equal saved-search-query query))
 935            ;; Query is the same as saved search (ignoring case)
 936            (concat "*notmuch-saved-search-" saved-search-name "*"))
 937           (saved-search
 938            (concat "*notmuch-search-"
 939                    (replace-regexp-in-string
 940                     (concat "^" (regexp-quote saved-search-query))
 941                     (concat "[ " saved-search-name " ]")
 942                     query)
 943                    "*"))
 944           (t
 945            (concat "*notmuch-search-" query "*")))))
 946
 947 (defun notmuch-read-query (prompt)
 948   "Read a notmuch-query from the minibuffer with completion.
 949
 950 PROMPT is the string to prompt with."
 951   (let* ((all-tags
 952           (mapcar (lambda (tag) (notmuch-escape-boolean-term tag))
 953                   (process-lines notmuch-command "search" "--output=tags" "*")))
 954          (completions
 955           (append (list "folder:" "path:" "thread:" "id:" "date:" "from:" "to:"
 956                         "subject:" "attachment:")
 957                   (mapcar (lambda (tag) (concat "tag:" tag)) all-tags)
 958                   (mapcar (lambda (tag) (concat "is:" tag)) all-tags)
 959                   (mapcar (lambda (mimetype) (concat "mimetype:" mimetype))
 960                           (mailcap-mime-types))))
 961          (keymap (copy-keymap minibuffer-local-map))
 962          (current-query (cl-case major-mode
 963                           (notmuch-search-mode (notmuch-search-get-query))
 964                           (notmuch-show-mode (notmuch-show-get-query))
 965                           (notmuch-tree-mode (notmuch-tree-get-query))))
 966          (minibuffer-completion-table
 967           (completion-table-dynamic
 968            (lambda (string)
 969              ;; Generate a list of possible completions for the current input.
 970              (cond
 971               ;; This ugly regexp is used to get the last word of the input
 972               ;; possibly preceded by a '('.
 973               ((string-match "\\(^\\|.* (?\\)\\([^ ]*\\)$" string)
 974                (mapcar (lambda (compl)
 975                          (concat (match-string-no-properties 1 string) compl))
 976                        (all-completions (match-string-no-properties 2 string)
 977                                         completions)))
 978               (t (list string)))))))
 979     ;; This was simpler than convincing completing-read to accept spaces:
 980     (define-key keymap (kbd "TAB") 'minibuffer-complete)
 981     (let ((history-delete-duplicates t))
 982       (read-from-minibuffer prompt nil keymap nil
 983                             'notmuch-search-history current-query nil))))
 984
 985 (defun notmuch-search-get-query ()
 986   "Return the current query in this search buffer."
 987   notmuch-search-query-string)
 988
 989 (put 'notmuch-search 'notmuch-doc "Search for messages.")
 990 ;;;###autoload
 991 (defun notmuch-search (&optional query oldest-first target-thread target-line no-display)
 992   "Display threads matching QUERY in a notmuch-search buffer.
 993
 994 If QUERY is nil, it is read interactively from the minibuffer.
 995 Other optional parameters are used as follows:
 996
 997   OLDEST-FIRST: A Boolean controlling the sort order of returned threads
 998   TARGET-THREAD: A thread ID (without the thread: prefix) that will be made
 999                  current if it appears in the search results.
1000   TARGET-LINE: The line number to move to if the target thread does not
1001                appear in the search results.
1002   NO-DISPLAY: Do not try to foreground the search results buffer. If it is
1003               already foregrounded i.e. displayed in a window, this has no
1004               effect, meaning the buffer will remain visible.
1005
1006 When called interactively, this will prompt for a query and use
1007 the configured default sort order."
1008   (interactive
1009    (list
1010     ;; Prompt for a query
1011     nil
1012     ;; Use the default search order (if we're doing a search from a
1013     ;; search buffer, ignore any buffer-local overrides)
1014     (default-value 'notmuch-search-oldest-first)))
1015
1016   (let* ((query (or query (notmuch-read-query "Notmuch search: ")))
1017          (buffer (get-buffer-create (notmuch-search-buffer-title query))))
1018     (if no-display
1019         (set-buffer buffer)
1020       (pop-to-buffer-same-window buffer))
1021     (notmuch-search-mode)
1022     ;; Don't track undo information for this buffer
1023     (setq buffer-undo-list t)
1024     (setq notmuch-search-query-string query)
1025     (setq notmuch-search-oldest-first oldest-first)
1026     (setq notmuch-search-target-thread target-thread)
1027     (setq notmuch-search-target-line target-line)
1028     (notmuch-tag-clear-cache)
1029     (let ((proc (get-buffer-process (current-buffer)))
1030           (inhibit-read-only t))
1031       (when proc
1032         (error "notmuch search process already running for query `%s'" query))
1033       (erase-buffer)
1034       (goto-char (point-min))
1035       (save-excursion
1036         (let ((proc (notmuch-start-notmuch
1037                      "notmuch-search" buffer #'notmuch-search-process-sentinel
1038                      "search" "--format=sexp" "--format-version=4"
1039                      (if oldest-first
1040                          "--sort=oldest-first"
1041                        "--sort=newest-first")
1042                      query)))
1043           ;; Use a scratch buffer to accumulate partial output.
1044           ;; This buffer will be killed by the sentinel, which
1045           ;; should be called no matter how the process dies.
1046           (process-put proc 'parse-buf
1047                        (generate-new-buffer " *notmuch search parse*"))
1048           (set-process-filter proc 'notmuch-search-process-filter)
1049           (set-process-query-on-exit-flag proc nil))))
1050     (run-hooks 'notmuch-search-hook)))
1051
1052 (defun notmuch-search-refresh-view ()
1053   "Refresh the current view.
1054
1055 Erases the current buffer and runs a new search with the same
1056 query string as the current search. If the current thread is in
1057 the new search results, then point will be placed on the same
1058 thread. Otherwise, point will be moved to attempt to be in the
1059 same relative position within the new buffer."
1060   (interactive)
1061   (let ((target-line (line-number-at-pos))
1062         (oldest-first notmuch-search-oldest-first)
1063         (target-thread (notmuch-search-find-thread-id 'bare))
1064         (query notmuch-search-query-string))
1065     ;; notmuch-search erases the current buffer.
1066     (notmuch-search query oldest-first target-thread target-line t)
1067     (goto-char (point-min))))
1068
1069 (defun notmuch-search-toggle-order ()
1070   "Toggle the current search order.
1071
1072 This command toggles the sort order for the current search. The
1073 default sort order is defined by `notmuch-search-oldest-first'."
1074   (interactive)
1075   (setq notmuch-search-oldest-first (not notmuch-search-oldest-first))
1076   (notmuch-search-refresh-view))
1077
1078 (defun notmuch-group-disjunctive-query-string (query-string)
1079   "Group query if it contains a complex expression.
1080 Enclose QUERY-STRING in parentheses if contains \"OR\" operators."
1081   (if (string-match-p "\\<[oO][rR]\\>" query-string)
1082       (concat "( " query-string " )")
1083     query-string))
1084
1085 (defun notmuch-search-filter (query)
1086   "Filter or LIMIT the current search results based on an additional query string.
1087
1088 Runs a new search matching only messages that match both the
1089 current search results AND the additional query string provided."
1090   (interactive (list (notmuch-read-query "Filter search: ")))
1091   (let ((grouped-query (notmuch-group-disjunctive-query-string query))
1092         (grouped-original-query (notmuch-group-disjunctive-query-string
1093                                  notmuch-search-query-string)))
1094     (notmuch-search (if (string= grouped-original-query "*")
1095                         grouped-query
1096                       (concat grouped-original-query " and " grouped-query))
1097                     notmuch-search-oldest-first)))
1098
1099 (defun notmuch-search-filter-by-tag (tag)
1100   "Filter the current search results based on a single TAG.
1101
1102 Run a new search matching only messages that match the current
1103 search results and that are also tagged with the given TAG."
1104   (interactive
1105    (list (notmuch-select-tag-with-completion "Filter by tag: "
1106                                              notmuch-search-query-string)))
1107   (notmuch-search (concat notmuch-search-query-string " and tag:" tag)
1108                   notmuch-search-oldest-first))
1109
1110 (defun notmuch-search-by-tag (tag)
1111   "Display threads matching TAG in a notmuch-search buffer."
1112   (interactive
1113    (list (notmuch-select-tag-with-completion "Notmuch search tag: ")))
1114   (notmuch-search (concat "tag:" tag)))
1115
1116 ;;;###autoload
1117 (defun notmuch ()
1118   "Run notmuch and display saved searches, known tags, etc."
1119   (interactive)
1120   (notmuch-hello))
1121
1122 (defun notmuch-interesting-buffer (b)
1123   "Whether the current buffer's major-mode is a notmuch mode."
1124   (with-current-buffer b
1125     (memq major-mode '(notmuch-show-mode
1126                        notmuch-search-mode
1127                        notmuch-tree-mode
1128                        notmuch-hello-mode
1129                        notmuch-message-mode))))
1130
1131 ;;;###autoload
1132 (defun notmuch-cycle-notmuch-buffers ()
1133   "Cycle through any existing notmuch buffers (search, show or hello).
1134
1135 If the current buffer is the only notmuch buffer, bury it.
1136 If no notmuch buffers exist, run `notmuch'."
1137   (interactive)
1138   (let (start first)
1139     ;; If the current buffer is a notmuch buffer, remember it and then
1140     ;; bury it.
1141     (when (notmuch-interesting-buffer (current-buffer))
1142       (setq start (current-buffer))
1143       (bury-buffer))
1144
1145     ;; Find the first notmuch buffer.
1146     (setq first (cl-loop for buffer in (buffer-list)
1147                          if (notmuch-interesting-buffer buffer)
1148                          return buffer))
1149
1150     (if first
1151         ;; If the first one we found is any other than the starting
1152         ;; buffer, switch to it.
1153         (unless (eq first start)
1154           (pop-to-buffer-same-window first))
1155       (notmuch))))
1156
1157 ;;; Imenu Support
1158
1159 (defun notmuch-search-imenu-prev-index-position-function ()
1160   "Move point to previous message in notmuch-search buffer.
1161 Used as`imenu-prev-index-position-function' in notmuch buffers."
1162   (notmuch-search-previous-thread))
1163
1164 (defun notmuch-search-imenu-extract-index-name-function ()
1165   "Return imenu name for line at point.
1166 Used as `imenu-extract-index-name-function' in notmuch buffers.
1167 Point should be at the beginning of the line."
1168   (let ((subject (notmuch-search-find-subject))
1169         (author (notmuch-search-find-authors)))
1170     (format "%s (%s)" subject author)))
1171
1172 ;;; _
1173
1174 (setq mail-user-agent 'notmuch-user-agent)
1175
1176 (provide 'notmuch)
1177
1178 ;; After provide to avoid loops if notmuch was require'd via notmuch-init-file.
1179 (when init-file-user ; don't load init file if the -q option was used.
1180   (load notmuch-init-file t t nil t))
1181
1182 ;;; notmuch.el ends here