git.notmuchmail.org Git - notmuch/blob - emacs/notmuch.el

   1 ;; notmuch.el --- run notmuch within emacs
   2 ;;
   3 ;; Copyright © Carl Worth
   4 ;;
   5 ;; This file is part of Notmuch.
   6 ;;
   7 ;; Notmuch is free software: you can redistribute it and/or modify it
   8 ;; under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation, either version 3 of the License, or
  10 ;; (at your option) any later version.
  11 ;;
  12 ;; Notmuch is distributed in the hope that it will be useful, but
  13 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 ;; General Public License for more details.
  16 ;;
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with Notmuch.  If not, see <http://www.gnu.org/licenses/>.
  19 ;;
  20 ;; Authors: Carl Worth <cworth@cworth.org>
  21
  22 ;; This is an emacs-based interface to the notmuch mail system.
  23 ;;
  24 ;; You will first need to have the notmuch program installed and have a
  25 ;; notmuch database built in order to use this. See
  26 ;; http://notmuchmail.org for details.
  27 ;;
  28 ;; To install this software, copy it to a directory that is on the
  29 ;; `load-path' variable within emacs (a good candidate is
  30 ;; /usr/local/share/emacs/site-lisp). If you are viewing this from the
  31 ;; notmuch source distribution then you can simply run:
  32 ;;
  33 ;;      sudo make install-emacs
  34 ;;
  35 ;; to install it.
  36 ;;
  37 ;; Then, to actually run it, add:
  38 ;;
  39 ;;      (require 'notmuch)
  40 ;;
  41 ;; to your ~/.emacs file, and then run "M-x notmuch" from within emacs,
  42 ;; or run:
  43 ;;
  44 ;;      emacs -f notmuch
  45 ;;
  46 ;; Have fun, and let us know if you have any comment, questions, or
  47 ;; kudos: Notmuch list <notmuch@notmuchmail.org> (subscription is not
  48 ;; required, but is available from http://notmuchmail.org).
  49
  50 (eval-when-compile (require 'cl))
  51 (require 'mm-view)
  52 (require 'message)
  53
  54 (require 'notmuch-lib)
  55 (require 'notmuch-tag)
  56 (require 'notmuch-show)
  57 (require 'notmuch-mua)
  58 (require 'notmuch-hello)
  59 (require 'notmuch-maildir-fcc)
  60 (require 'notmuch-message)
  61 (require 'notmuch-parser)
  62
  63 (defcustom notmuch-search-result-format
  64   `(("date" . "%12s ")
  65     ("count" . "%-7s ")
  66     ("authors" . "%-20s ")
  67     ("subject" . "%s ")
  68     ("tags" . "(%s)"))
  69   "Search result formatting. Supported fields are:
  70         date, count, authors, subject, tags
  71 For example:
  72         (setq notmuch-search-result-format \(\(\"authors\" . \"%-40s\"\)
  73                                              \(\"subject\" . \"%s\"\)\)\)
  74 Line breaks are permitted in format strings (though this is
  75 currently experimental).  Note that a line break at the end of an
  76 \"authors\" field will get elided if the authors list is long;
  77 place it instead at the beginning of the following field.  To
  78 enter a line break when setting this variable with setq, use \\n.
  79 To enter a line break in customize, press \\[quoted-insert] C-j."
  80   :type '(alist :key-type (string) :value-type (string))
  81   :group 'notmuch-search)
  82
  83 (defvar notmuch-query-history nil
  84   "Variable to store minibuffer history for notmuch queries")
  85
  86 (defun notmuch-foreach-mime-part (function mm-handle)
  87   (cond ((stringp (car mm-handle))
  88          (dolist (part (cdr mm-handle))
  89            (notmuch-foreach-mime-part function part)))
  90         ((bufferp (car mm-handle))
  91          (funcall function mm-handle))
  92         (t (dolist (part mm-handle)
  93              (notmuch-foreach-mime-part function part)))))
  94
  95 (defun notmuch-count-attachments (mm-handle)
  96   (let ((count 0))
  97     (notmuch-foreach-mime-part
  98      (lambda (p)
  99        (let ((disposition (mm-handle-disposition p)))
 100          (and (listp disposition)
 101               (or (equal (car disposition) "attachment")
 102                   (and (equal (car disposition) "inline")
 103                        (assq 'filename disposition)))
 104               (incf count))))
 105      mm-handle)
 106     count))
 107
 108 (defun notmuch-save-attachments (mm-handle &optional queryp)
 109   (notmuch-foreach-mime-part
 110    (lambda (p)
 111      (let ((disposition (mm-handle-disposition p)))
 112        (and (listp disposition)
 113             (or (equal (car disposition) "attachment")
 114                 (and (equal (car disposition) "inline")
 115                      (assq 'filename disposition)))
 116             (or (not queryp)
 117                 (y-or-n-p
 118                  (concat "Save '" (cdr (assq 'filename disposition)) "' ")))
 119             (mm-save-part p))))
 120    mm-handle))
 121
 122 (defun notmuch-documentation-first-line (symbol)
 123   "Return the first line of the documentation string for SYMBOL."
 124   (let ((doc (documentation symbol)))
 125     (if doc
 126         (with-temp-buffer
 127           (insert (documentation symbol t))
 128           (goto-char (point-min))
 129           (let ((beg (point)))
 130             (end-of-line)
 131             (buffer-substring beg (point))))
 132       "")))
 133
 134 (defun notmuch-prefix-key-description (key)
 135   "Given a prefix key code, return a human-readable string representation.
 136
 137 This is basically just `format-kbd-macro' but we also convert ESC to M-."
 138   (let ((desc (format-kbd-macro (vector key))))
 139     (if (string= desc "ESC")
 140         "M-"
 141       (concat desc " "))))
 142
 143 (defun notmuch-describe-keymap (keymap ua-keys &optional prefix tail)
 144   "Return a list of strings, each describing one key in KEYMAP.
 145
 146 Each string gives a human-readable description of the key and the
 147 first line of documentation for the bound function."
 148   (map-keymap
 149    (lambda (key binding)
 150      (cond ((mouse-event-p key) nil)
 151            ((keymapp binding)
 152             (setq tail
 153                   (notmuch-describe-keymap
 154                    binding ua-keys (notmuch-prefix-key-description key) tail)))
 155            (t
 156             (when (and ua-keys (symbolp binding)
 157                        (get binding 'notmuch-prefix-doc))
 158               ;; Documentation for prefixed command
 159               (let ((ua-desc (key-description ua-keys)))
 160                 (push (concat ua-desc " " prefix (format-kbd-macro (vector key))
 161                               "\t" (get binding 'notmuch-prefix-doc))
 162                       tail)))
 163             ;; Documentation for command
 164             (push (concat prefix (format-kbd-macro (vector key)) "\t"
 165                           (or (and (symbolp binding) (get binding 'notmuch-doc))
 166                               (notmuch-documentation-first-line binding)))
 167                   tail))))
 168    keymap)
 169   tail)
 170
 171 (defun notmuch-substitute-command-keys (doc)
 172   "Like `substitute-command-keys' but with documentation, not function names."
 173   (let ((beg 0))
 174     (while (string-match "\\\\{\\([^}[:space:]]*\\)}" doc beg)
 175       (let* ((keymap-name (substring doc (match-beginning 1) (match-end 1)))
 176              (keymap (symbol-value (intern keymap-name)))
 177              (ua-keys (where-is-internal 'universal-argument keymap t))
 178              (desc-list (notmuch-describe-keymap keymap ua-keys))
 179              (desc (mapconcat #'identity desc-list "\n")))
 180         (setq doc (replace-match desc 1 1 doc)))
 181       (setq beg (match-end 0)))
 182     doc))
 183
 184 (defun notmuch-help ()
 185   "Display help for the current notmuch mode.
 186
 187 This is similar to `describe-function' for the current major
 188 mode, but bindings tables are shown with documentation strings
 189 rather than command names.  By default, this uses the first line
 190 of each command's documentation string.  A command can override
 191 this by setting the 'notmuch-doc property of its command symbol.
 192 A command that supports a prefix argument can explicitly document
 193 its prefixed behavior by setting the 'notmuch-prefix-doc property
 194 of its command symbol."
 195   (interactive)
 196   (let* ((mode major-mode)
 197          (doc (substitute-command-keys (notmuch-substitute-command-keys (documentation mode t)))))
 198     (with-current-buffer (generate-new-buffer "*notmuch-help*")
 199       (insert doc)
 200       (goto-char (point-min))
 201       (set-buffer-modified-p nil)
 202       (view-buffer (current-buffer) 'kill-buffer-if-not-modified))))
 203
 204 (require 'hl-line)
 205
 206 (defun notmuch-hl-line-mode ()
 207   (prog1 (hl-line-mode)
 208     (when hl-line-overlay
 209       (overlay-put hl-line-overlay 'priority 1))))
 210
 211 (defcustom notmuch-search-hook '(notmuch-hl-line-mode)
 212   "List of functions to call when notmuch displays the search results."
 213   :type 'hook
 214   :options '(notmuch-hl-line-mode)
 215   :group 'notmuch-search
 216   :group 'notmuch-hooks)
 217
 218 (defvar notmuch-search-mode-map
 219   (let ((map (make-sparse-keymap)))
 220     (set-keymap-parent map notmuch-common-keymap)
 221     (define-key map "x" 'notmuch-kill-this-buffer)
 222     (define-key map (kbd "<DEL>") 'notmuch-search-scroll-down)
 223     (define-key map "b" 'notmuch-search-scroll-down)
 224     (define-key map " " 'notmuch-search-scroll-up)
 225     (define-key map "<" 'notmuch-search-first-thread)
 226     (define-key map ">" 'notmuch-search-last-thread)
 227     (define-key map "p" 'notmuch-search-previous-thread)
 228     (define-key map "n" 'notmuch-search-next-thread)
 229     (define-key map "r" 'notmuch-search-reply-to-thread-sender)
 230     (define-key map "R" 'notmuch-search-reply-to-thread)
 231     (define-key map "o" 'notmuch-search-toggle-order)
 232     (define-key map "c" 'notmuch-search-stash-map)
 233     (define-key map "t" 'notmuch-search-filter-by-tag)
 234     (define-key map "f" 'notmuch-search-filter)
 235     (define-key map [mouse-1] 'notmuch-search-show-thread)
 236     (define-key map "*" 'notmuch-search-tag-all)
 237     (define-key map "a" 'notmuch-search-archive-thread)
 238     (define-key map "-" 'notmuch-search-remove-tag)
 239     (define-key map "+" 'notmuch-search-add-tag)
 240     (define-key map (kbd "RET") 'notmuch-search-show-thread)
 241     map)
 242   "Keymap for \"notmuch search\" buffers.")
 243 (fset 'notmuch-search-mode-map notmuch-search-mode-map)
 244
 245 (defvar notmuch-search-stash-map
 246   (let ((map (make-sparse-keymap)))
 247     (define-key map "i" 'notmuch-search-stash-thread-id)
 248     map)
 249   "Submap for stash commands")
 250 (fset 'notmuch-search-stash-map notmuch-search-stash-map)
 251
 252 (defun notmuch-search-stash-thread-id ()
 253   "Copy thread ID of current thread to kill-ring."
 254   (interactive)
 255   (notmuch-common-do-stash (notmuch-search-find-thread-id)))
 256
 257 (defvar notmuch-search-query-string)
 258 (defvar notmuch-search-target-thread)
 259 (defvar notmuch-search-target-line)
 260
 261 (defvar notmuch-search-disjunctive-regexp      "\\<[oO][rR]\\>")
 262
 263 (defun notmuch-search-scroll-up ()
 264   "Move forward through search results by one window's worth."
 265   (interactive)
 266   (condition-case nil
 267       (scroll-up nil)
 268     ((end-of-buffer) (notmuch-search-last-thread))))
 269
 270 (defun notmuch-search-scroll-down ()
 271   "Move backward through the search results by one window's worth."
 272   (interactive)
 273   ;; I don't know why scroll-down doesn't signal beginning-of-buffer
 274   ;; the way that scroll-up signals end-of-buffer, but c'est la vie.
 275   ;;
 276   ;; So instead of trapping a signal we instead check whether the
 277   ;; window begins on the first line of the buffer and if so, move
 278   ;; directly to that position. (We have to count lines since the
 279   ;; window-start position is not the same as point-min due to the
 280   ;; invisible thread-ID characters on the first line.
 281   (if (equal (count-lines (point-min) (window-start)) 0)
 282       (goto-char (point-min))
 283     (scroll-down nil)))
 284
 285 (defun notmuch-search-next-thread ()
 286   "Select the next thread in the search results."
 287   (interactive)
 288   (when (notmuch-search-get-result)
 289     (goto-char (notmuch-search-result-end))))
 290
 291 (defun notmuch-search-previous-thread ()
 292   "Select the previous thread in the search results."
 293   (interactive)
 294   (if (notmuch-search-get-result)
 295       (unless (bobp)
 296         (goto-char (notmuch-search-result-beginning (- (point) 1))))
 297     ;; We must be past the end; jump to the last result
 298     (notmuch-search-last-thread)))
 299
 300 (defun notmuch-search-last-thread ()
 301   "Select the last thread in the search results."
 302   (interactive)
 303   (goto-char (point-max))
 304   (forward-line -2)
 305   (let ((beg (notmuch-search-result-beginning)))
 306     (when beg (goto-char beg))))
 307
 308 (defun notmuch-search-first-thread ()
 309   "Select the first thread in the search results."
 310   (interactive)
 311   (goto-char (point-min)))
 312
 313 (defface notmuch-message-summary-face
 314  '((((class color) (background light)) (:background "#f0f0f0"))
 315    (((class color) (background dark)) (:background "#303030")))
 316  "Face for the single-line message summary in notmuch-show-mode."
 317  :group 'notmuch-show
 318  :group 'notmuch-faces)
 319
 320 (defface notmuch-search-date
 321   '((t :inherit default))
 322   "Face used in search mode for dates."
 323   :group 'notmuch-search
 324   :group 'notmuch-faces)
 325
 326 (defface notmuch-search-count
 327   '((t :inherit default))
 328   "Face used in search mode for the count matching the query."
 329   :group 'notmuch-search
 330   :group 'notmuch-faces)
 331
 332 (defface notmuch-search-subject
 333   '((t :inherit default))
 334   "Face used in search mode for subjects."
 335   :group 'notmuch-search
 336   :group 'notmuch-faces)
 337
 338 (defface notmuch-search-matching-authors
 339   '((t :inherit default))
 340   "Face used in search mode for authors matching the query."
 341   :group 'notmuch-search
 342   :group 'notmuch-faces)
 343
 344 (defface notmuch-search-non-matching-authors
 345   '((((class color)
 346       (background dark))
 347      (:foreground "grey30"))
 348     (((class color)
 349       (background light))
 350      (:foreground "grey60"))
 351     (t
 352      (:italic t)))
 353   "Face used in search mode for authors not matching the query."
 354   :group 'notmuch-search
 355   :group 'notmuch-faces)
 356
 357 (defface notmuch-tag-face
 358   '((((class color)
 359       (background dark))
 360      (:foreground "OliveDrab1"))
 361     (((class color)
 362       (background light))
 363      (:foreground "navy blue" :bold t))
 364     (t
 365      (:bold t)))
 366   "Face used in search mode face for tags."
 367   :group 'notmuch-search
 368   :group 'notmuch-faces)
 369
 370 (defun notmuch-search-mode ()
 371   "Major mode displaying results of a notmuch search.
 372
 373 This buffer contains the results of a \"notmuch search\" of your
 374 email archives. Each line in the buffer represents a single
 375 thread giving a summary of the thread (a relative date, the
 376 number of matched messages and total messages in the thread,
 377 participants in the thread, a representative subject line, and
 378 any tags).
 379
 380 Pressing \\[notmuch-search-show-thread] on any line displays that
 381 thread. The '\\[notmuch-search-add-tag]' and
 382 '\\[notmuch-search-remove-tag]' keys can be used to add or remove
 383 tags from a thread. The '\\[notmuch-search-archive-thread]' key
 384 is a convenience for archiving a thread (applying changes in
 385 `notmuch-archive-tags'). The '\\[notmuch-search-tag-all]' key can
 386 be used to add and/or remove tags from all messages (as opposed
 387 to threads) that match the current query.  Use with caution, as
 388 this will also tag matching messages that arrived *after*
 389 constructing the buffer.
 390
 391 Other useful commands are '\\[notmuch-search-filter]' for
 392 filtering the current search based on an additional query string,
 393 '\\[notmuch-search-filter-by-tag]' for filtering to include only
 394 messages with a given tag, and '\\[notmuch-search]' to execute a
 395 new, global search.
 396
 397 Complete list of currently available key bindings:
 398
 399 \\{notmuch-search-mode-map}"
 400   (interactive)
 401   (kill-all-local-variables)
 402   (make-local-variable 'notmuch-search-query-string)
 403   (make-local-variable 'notmuch-search-oldest-first)
 404   (make-local-variable 'notmuch-search-target-thread)
 405   (make-local-variable 'notmuch-search-target-line)
 406   (setq notmuch-buffer-refresh-function #'notmuch-search-refresh-view)
 407   (set (make-local-variable 'scroll-preserve-screen-position) t)
 408   (add-to-invisibility-spec (cons 'ellipsis t))
 409   (use-local-map notmuch-search-mode-map)
 410   (setq truncate-lines t)
 411   (setq major-mode 'notmuch-search-mode
 412         mode-name "notmuch-search")
 413   (setq buffer-read-only t))
 414
 415 (defun notmuch-search-get-result (&optional pos)
 416   "Return the result object for the thread at POS (or point).
 417
 418 If there is no thread at POS (or point), returns nil."
 419   (get-text-property (or pos (point)) 'notmuch-search-result))
 420
 421 (defun notmuch-search-result-beginning (&optional pos)
 422   "Return the point at the beginning of the thread at POS (or point).
 423
 424 If there is no thread at POS (or point), returns nil."
 425   (when (notmuch-search-get-result pos)
 426     ;; We pass 1+point because previous-single-property-change starts
 427     ;; searching one before the position we give it.
 428     (previous-single-property-change (1+ (or pos (point)))
 429                                      'notmuch-search-result nil (point-min))))
 430
 431 (defun notmuch-search-result-end (&optional pos)
 432   "Return the point at the end of the thread at POS (or point).
 433
 434 The returned point will be just after the newline character that
 435 ends the result line.  If there is no thread at POS (or point),
 436 returns nil"
 437   (when (notmuch-search-get-result pos)
 438     (next-single-property-change (or pos (point)) 'notmuch-search-result
 439                                  nil (point-max))))
 440
 441 (defun notmuch-search-foreach-result (beg end function)
 442   "Invoke FUNCTION for each result between BEG and END.
 443
 444 FUNCTION should take one argument.  It will be applied to the
 445 character position of the beginning of each result that overlaps
 446 the region between points BEG and END.  As a special case, if (=
 447 BEG END), FUNCTION will be applied to the result containing point
 448 BEG."
 449
 450   (lexical-let ((pos (notmuch-search-result-beginning beg))
 451                 ;; End must be a marker in case function changes the
 452                 ;; text.
 453                 (end (copy-marker end))
 454                 ;; Make sure we examine at least one result, even if
 455                 ;; (= beg end).
 456                 (first t))
 457     ;; We have to be careful if the region extends beyond the results.
 458     ;; In this case, pos could be null or there could be no result at
 459     ;; pos.
 460     (while (and pos (or (< pos end) first))
 461       (when (notmuch-search-get-result pos)
 462         (funcall function pos))
 463       (setq pos (notmuch-search-result-end pos)
 464             first nil))))
 465 ;; Unindent the function argument of notmuch-search-foreach-result so
 466 ;; the indentation of callers doesn't get out of hand.
 467 (put 'notmuch-search-foreach-result 'lisp-indent-function 2)
 468
 469 (defun notmuch-search-properties-in-region (property beg end)
 470   (let (output)
 471     (notmuch-search-foreach-result beg end
 472       (lambda (pos)
 473         (push (plist-get (notmuch-search-get-result pos) property) output)))
 474     output))
 475
 476 (defun notmuch-search-find-thread-id (&optional bare)
 477   "Return the thread for the current thread
 478
 479 If BARE is set then do not prefix with \"thread:\""
 480   (let ((thread (plist-get (notmuch-search-get-result) :thread)))
 481     (when thread (concat (unless bare "thread:") thread))))
 482
 483 (defun notmuch-search-find-thread-id-region (beg end)
 484   "Return a list of threads for the current region"
 485   (mapcar (lambda (thread) (concat "thread:" thread))
 486           (notmuch-search-properties-in-region :thread beg end)))
 487
 488 (defun notmuch-search-find-thread-id-region-search (beg end)
 489   "Return a search string for threads for the current region"
 490   (mapconcat 'identity (notmuch-search-find-thread-id-region beg end) " or "))
 491
 492 (defun notmuch-search-find-authors ()
 493   "Return the authors for the current thread"
 494   (plist-get (notmuch-search-get-result) :authors))
 495
 496 (defun notmuch-search-find-authors-region (beg end)
 497   "Return a list of authors for the current region"
 498   (notmuch-search-properties-in-region :authors beg end))
 499
 500 (defun notmuch-search-find-subject ()
 501   "Return the subject for the current thread"
 502   (plist-get (notmuch-search-get-result) :subject))
 503
 504 (defun notmuch-search-find-subject-region (beg end)
 505   "Return a list of authors for the current region"
 506   (notmuch-search-properties-in-region :subject beg end))
 507
 508 (defun notmuch-search-show-thread ()
 509   "Display the currently selected thread."
 510   (interactive)
 511   (let ((thread-id (notmuch-search-find-thread-id))
 512         (subject (notmuch-search-find-subject)))
 513     (if (> (length thread-id) 0)
 514         (notmuch-show thread-id
 515                       (current-buffer)
 516                       notmuch-search-query-string
 517                       ;; Name the buffer based on the subject.
 518                       (concat "*" (truncate-string-to-width subject 30 nil nil t) "*"))
 519       (message "End of search results."))))
 520
 521 (defun notmuch-search-reply-to-thread (&optional prompt-for-sender)
 522   "Begin composing a reply-all to the entire current thread in a new buffer."
 523   (interactive "P")
 524   (let ((message-id (notmuch-search-find-thread-id)))
 525     (notmuch-mua-new-reply message-id prompt-for-sender t)))
 526
 527 (defun notmuch-search-reply-to-thread-sender (&optional prompt-for-sender)
 528   "Begin composing a reply to the entire current thread in a new buffer."
 529   (interactive "P")
 530   (let ((message-id (notmuch-search-find-thread-id)))
 531     (notmuch-mua-new-reply message-id prompt-for-sender nil)))
 532
 533 (defun notmuch-call-notmuch-process (&rest args)
 534   "Synchronously invoke \"notmuch\" with the given list of arguments.
 535
 536 If notmuch exits with a non-zero status, output from the process
 537 will appear in a buffer named \"*Notmuch errors*\" and an error
 538 will be signaled."
 539   (with-temp-buffer
 540     (let ((status (apply #'call-process notmuch-command nil t nil args)))
 541       (notmuch-check-exit-status status (cons notmuch-command args)
 542                                  (buffer-string)))))
 543
 544 (defun notmuch-search-set-tags (tags &optional pos)
 545   (let ((new-result (plist-put (notmuch-search-get-result pos) :tags tags)))
 546     (notmuch-search-update-result new-result pos)))
 547
 548 (defun notmuch-search-get-tags (&optional pos)
 549   (plist-get (notmuch-search-get-result pos) :tags))
 550
 551 (defun notmuch-search-get-tags-region (beg end)
 552   (let (output)
 553     (notmuch-search-foreach-result beg end
 554       (lambda (pos)
 555         (setq output (append output (notmuch-search-get-tags pos)))))
 556     output))
 557
 558 (defun notmuch-search-tag-region (beg end &optional tag-changes)
 559   "Change tags for threads in the given region."
 560   (let ((search-string (notmuch-search-find-thread-id-region-search beg end)))
 561     (setq tag-changes (notmuch-tag search-string tag-changes))
 562     (notmuch-search-foreach-result beg end
 563       (lambda (pos)
 564         (notmuch-search-set-tags
 565          (notmuch-update-tags (notmuch-search-get-tags pos) tag-changes)
 566          pos)))))
 567
 568 (defun notmuch-search-tag (&optional tag-changes)
 569   "Change tags for the currently selected thread or region.
 570
 571 See `notmuch-tag' for information on the format of TAG-CHANGES."
 572   (interactive)
 573   (let* ((beg (if (region-active-p) (region-beginning) (point)))
 574          (end (if (region-active-p) (region-end) (point))))
 575     (notmuch-search-tag-region beg end tag-changes)))
 576
 577 (defun notmuch-search-add-tag ()
 578   "Change tags for the current thread (defaulting to add).
 579
 580 Same as `notmuch-search-tag' but sets initial input to '+'."
 581   (interactive)
 582   (notmuch-search-tag "+"))
 583
 584 (defun notmuch-search-remove-tag ()
 585   "Change tags for the current thread (defaulting to remove).
 586
 587 Same as `notmuch-search-tag' but sets initial input to '-'."
 588   (interactive)
 589   (notmuch-search-tag "-"))
 590
 591 (put 'notmuch-search-archive-thread 'notmuch-prefix-doc
 592      "Un-archive the currently selected thread.")
 593 (defun notmuch-search-archive-thread (&optional unarchive)
 594   "Archive the currently selected thread.
 595
 596 Archive each message in the currently selected thread by applying
 597 the tag changes in `notmuch-archive-tags' to each (remove the
 598 \"inbox\" tag by default). If a prefix argument is given, the
 599 messages will be \"unarchived\" (i.e. the tag changes in
 600 `notmuch-archive-tags' will be reversed).
 601
 602 This function advances the next thread when finished."
 603   (interactive "P")
 604   (when notmuch-archive-tags
 605     (notmuch-search-tag
 606      (notmuch-tag-change-list notmuch-archive-tags unarchive)))
 607   (notmuch-search-next-thread))
 608
 609 (defun notmuch-search-update-result (result &optional pos)
 610   "Replace the result object of the thread at POS (or point) by
 611 RESULT and redraw it.
 612
 613 This will keep point in a reasonable location.  However, if there
 614 are enclosing save-excursions and the saved point is in the
 615 result being updated, the point will be restored to the beginning
 616 of the result."
 617   (let ((start (notmuch-search-result-beginning pos))
 618         (end (notmuch-search-result-end pos))
 619         (init-point (point))
 620         (inhibit-read-only t))
 621     ;; Delete the current thread
 622     (delete-region start end)
 623     ;; Insert the updated thread
 624     (notmuch-search-show-result result start)
 625     ;; If point was inside the old result, make an educated guess
 626     ;; about where to place it now.  Unfortunately, this won't work
 627     ;; with save-excursion (or any other markers that would be nice to
 628     ;; preserve, such as the window start), but there's nothing we can
 629     ;; do about that without a way to retrieve markers in a region.
 630     (when (and (>= init-point start) (<= init-point end))
 631       (let* ((new-end (notmuch-search-result-end start))
 632              (new-point (if (= init-point end)
 633                             new-end
 634                           (min init-point (- new-end 1)))))
 635         (goto-char new-point)))))
 636
 637 (defun notmuch-search-process-sentinel (proc msg)
 638   "Add a message to let user know when \"notmuch search\" exits"
 639   (let ((buffer (process-buffer proc))
 640         (status (process-status proc))
 641         (exit-status (process-exit-status proc))
 642         (never-found-target-thread nil))
 643     (when (memq status '(exit signal))
 644       (catch 'return
 645         (kill-buffer (process-get proc 'parse-buf))
 646         (if (buffer-live-p buffer)
 647             (with-current-buffer buffer
 648               (save-excursion
 649                 (let ((inhibit-read-only t)
 650                       (atbob (bobp)))
 651                   (goto-char (point-max))
 652                   (if (eq status 'signal)
 653                       (insert "Incomplete search results (search process was killed).\n"))
 654                   (when (eq status 'exit)
 655                     (insert "End of search results.\n")
 656                     ;; For version mismatch, there's no point in
 657                     ;; showing the search buffer
 658                     (when (or (= exit-status 20) (= exit-status 21))
 659                       (kill-buffer)
 660                       (throw 'return nil))
 661                     (if (and atbob
 662                              (not (string= notmuch-search-target-thread "found")))
 663                         (set 'never-found-target-thread t)))))
 664               (when (and never-found-target-thread
 665                        notmuch-search-target-line)
 666                   (goto-char (point-min))
 667                   (forward-line (1- notmuch-search-target-line)))))))))
 668
 669 (defcustom notmuch-search-line-faces '(("unread" :weight bold)
 670                                        ("flagged" :foreground "blue"))
 671   "Tag/face mapping for line highlighting in notmuch-search.
 672
 673 Here is an example of how to color search results based on tags.
 674  (the following text would be placed in your ~/.emacs file):
 675
 676  (setq notmuch-search-line-faces '((\"deleted\" . (:foreground \"red\"
 677                                                   :background \"blue\"))
 678                                    (\"unread\" . (:foreground \"green\"))))
 679
 680 The attributes defined for matching tags are merged, with later
 681 attributes overriding earlier. A message having both \"deleted\"
 682 and \"unread\" tags with the above settings would have a green
 683 foreground and blue background."
 684   :type '(alist :key-type (string) :value-type (custom-face-edit))
 685   :group 'notmuch-search
 686   :group 'notmuch-faces)
 687
 688 (defun notmuch-search-color-line (start end line-tag-list)
 689   "Colorize lines in `notmuch-show' based on tags."
 690   (mapc (lambda (elem)
 691           (let ((tag (car elem))
 692                 (attributes (cdr elem)))
 693             (when (member tag line-tag-list)
 694               (notmuch-combine-face-text-property start end attributes))))
 695         ;; Reverse the list so earlier entries take precedence
 696         (reverse notmuch-search-line-faces)))
 697
 698 (defun notmuch-search-author-propertize (authors)
 699   "Split `authors' into matching and non-matching authors and
 700 propertize appropriately. If no boundary between authors and
 701 non-authors is found, assume that all of the authors match."
 702   (if (string-match "\\(.*\\)|\\(.*\\)" authors)
 703       (concat (propertize (concat (match-string 1 authors) ",")
 704                           'face 'notmuch-search-matching-authors)
 705               (propertize (match-string 2 authors)
 706                           'face 'notmuch-search-non-matching-authors))
 707     (propertize authors 'face 'notmuch-search-matching-authors)))
 708
 709 (defun notmuch-search-insert-authors (format-string authors)
 710   ;; Save the match data to avoid interfering with
 711   ;; `notmuch-search-process-filter'.
 712   (save-match-data
 713     (let* ((formatted-authors (format format-string authors))
 714            (formatted-sample (format format-string ""))
 715            (visible-string formatted-authors)
 716            (invisible-string "")
 717            (padding ""))
 718
 719       ;; Truncate the author string to fit the specification.
 720       (if (> (length formatted-authors)
 721              (length formatted-sample))
 722           (let ((visible-length (- (length formatted-sample)
 723                                    (length "... "))))
 724             ;; Truncate the visible string according to the width of
 725             ;; the display string.
 726             (setq visible-string (substring formatted-authors 0 visible-length)
 727                   invisible-string (substring formatted-authors visible-length))
 728             ;; If possible, truncate the visible string at a natural
 729             ;; break (comma or pipe), as incremental search doesn't
 730             ;; match across the visible/invisible border.
 731             (when (string-match "\\(.*\\)\\([,|] \\)\\([^,|]*\\)" visible-string)
 732               ;; Second clause is destructive on `visible-string', so
 733               ;; order is important.
 734               (setq invisible-string (concat (match-string 3 visible-string)
 735                                              invisible-string)
 736                     visible-string (concat (match-string 1 visible-string)
 737                                            (match-string 2 visible-string))))
 738             ;; `visible-string' may be shorter than the space allowed
 739             ;; by `format-string'. If so we must insert some padding
 740             ;; after `invisible-string'.
 741             (setq padding (make-string (- (length formatted-sample)
 742                                           (length visible-string)
 743                                           (length "..."))
 744                                        ? ))))
 745
 746       ;; Use different faces to show matching and non-matching authors.
 747       (if (string-match "\\(.*\\)|\\(.*\\)" visible-string)
 748           ;; The visible string contains both matching and
 749           ;; non-matching authors.
 750           (setq visible-string (notmuch-search-author-propertize visible-string)
 751                 ;; The invisible string must contain only non-matching
 752                 ;; authors, as the visible-string contains both.
 753                 invisible-string (propertize invisible-string
 754                                              'face 'notmuch-search-non-matching-authors))
 755         ;; The visible string contains only matching authors.
 756         (setq visible-string (propertize visible-string
 757                                          'face 'notmuch-search-matching-authors)
 758               ;; The invisible string may contain both matching and
 759               ;; non-matching authors.
 760               invisible-string (notmuch-search-author-propertize invisible-string)))
 761
 762       ;; If there is any invisible text, add it as a tooltip to the
 763       ;; visible text.
 764       (when (not (string= invisible-string ""))
 765         (setq visible-string (propertize visible-string 'help-echo (concat "..." invisible-string))))
 766
 767       ;; Insert the visible and, if present, invisible author strings.
 768       (insert visible-string)
 769       (when (not (string= invisible-string ""))
 770         (let ((start (point))
 771               overlay)
 772           (insert invisible-string)
 773           (setq overlay (make-overlay start (point)))
 774           (overlay-put overlay 'invisible 'ellipsis)
 775           (overlay-put overlay 'isearch-open-invisible #'delete-overlay)))
 776       (insert padding))))
 777
 778 (defun notmuch-search-insert-field (field format-string result)
 779   (cond
 780    ((string-equal field "date")
 781     (insert (propertize (format format-string (plist-get result :date_relative))
 782                         'face 'notmuch-search-date)))
 783    ((string-equal field "count")
 784     (insert (propertize (format format-string
 785                                 (format "[%s/%s]" (plist-get result :matched)
 786                                         (plist-get result :total)))
 787                         'face 'notmuch-search-count)))
 788    ((string-equal field "subject")
 789     (insert (propertize (format format-string (plist-get result :subject))
 790                         'face 'notmuch-search-subject)))
 791
 792    ((string-equal field "authors")
 793     (notmuch-search-insert-authors format-string (plist-get result :authors)))
 794
 795    ((string-equal field "tags")
 796     (let ((tags (plist-get result :tags)))
 797       (insert (format format-string (notmuch-tag-format-tags tags)))))))
 798
 799 (defun notmuch-search-show-result (result &optional pos)
 800   "Insert RESULT at POS or the end of the buffer if POS is null."
 801   ;; Ignore excluded matches
 802   (unless (= (plist-get result :matched) 0)
 803     (let ((beg (or pos (point-max))))
 804       (save-excursion
 805         (goto-char beg)
 806         (dolist (spec notmuch-search-result-format)
 807           (notmuch-search-insert-field (car spec) (cdr spec) result))
 808         (insert "\n")
 809         (notmuch-search-color-line beg (point) (plist-get result :tags))
 810         (put-text-property beg (point) 'notmuch-search-result result))
 811       (when (string= (plist-get result :thread) notmuch-search-target-thread)
 812         (setq notmuch-search-target-thread "found")
 813         (goto-char beg)))))
 814
 815 (defun notmuch-search-process-filter (proc string)
 816   "Process and filter the output of \"notmuch search\""
 817   (let ((results-buf (process-buffer proc))
 818         (parse-buf (process-get proc 'parse-buf))
 819         (inhibit-read-only t)
 820         done)
 821     (when (buffer-live-p results-buf)
 822       (with-current-buffer parse-buf
 823         ;; Insert new data
 824         (save-excursion
 825           (goto-char (point-max))
 826           (insert string))
 827         (notmuch-sexp-parse-partial-list 'notmuch-search-show-result
 828                                          results-buf)))))
 829
 830 (defun notmuch-search-tag-all (&optional tag-changes)
 831   "Add/remove tags from all messages in current search buffer.
 832
 833 See `notmuch-tag' for information on the format of TAG-CHANGES."
 834   (interactive)
 835   (apply 'notmuch-tag notmuch-search-query-string tag-changes))
 836
 837 (defun notmuch-search-buffer-title (query)
 838   "Returns the title for a buffer with notmuch search results."
 839   (let* ((saved-search
 840           (let (longest
 841                 (longest-length 0))
 842             (loop for tuple in notmuch-saved-searches
 843                   if (let ((quoted-query (regexp-quote (cdr tuple))))
 844                        (and (string-match (concat "^" quoted-query) query)
 845                             (> (length (match-string 0 query))
 846                                longest-length)))
 847                   do (setq longest tuple))
 848             longest))
 849          (saved-search-name (car saved-search))
 850          (saved-search-query (cdr saved-search)))
 851     (cond ((and saved-search (equal saved-search-query query))
 852            ;; Query is the same as saved search (ignoring case)
 853            (concat "*notmuch-saved-search-" saved-search-name "*"))
 854           (saved-search
 855            (concat "*notmuch-search-"
 856                    (replace-regexp-in-string (concat "^" (regexp-quote saved-search-query))
 857                                              (concat "[ " saved-search-name " ]")
 858                                              query)
 859                    "*"))
 860           (t
 861            (concat "*notmuch-search-" query "*"))
 862           )))
 863
 864 (defun notmuch-read-query (prompt)
 865   "Read a notmuch-query from the minibuffer with completion.
 866
 867 PROMPT is the string to prompt with."
 868   (lexical-let
 869       ((completions
 870         (append (list "folder:" "thread:" "id:" "date:" "from:" "to:"
 871                       "subject:" "attachment:")
 872                 (mapcar (lambda (tag)
 873                           (concat "tag:" (notmuch-escape-boolean-term tag)))
 874                         (process-lines notmuch-command "search" "--output=tags" "*")))))
 875     (let ((keymap (copy-keymap minibuffer-local-map))
 876           (minibuffer-completion-table
 877            (completion-table-dynamic
 878             (lambda (string)
 879               ;; generate a list of possible completions for the current input
 880               (cond
 881                ;; this ugly regexp is used to get the last word of the input
 882                ;; possibly preceded by a '('
 883                ((string-match "\\(^\\|.* (?\\)\\([^ ]*\\)$" string)
 884                 (mapcar (lambda (compl)
 885                           (concat (match-string-no-properties 1 string) compl))
 886                         (all-completions (match-string-no-properties 2 string)
 887                                          completions)))
 888                (t (list string)))))))
 889       ;; this was simpler than convincing completing-read to accept spaces:
 890       (define-key keymap (kbd "TAB") 'minibuffer-complete)
 891       (let ((history-delete-duplicates t))
 892         (read-from-minibuffer prompt nil keymap nil
 893                               'notmuch-search-history nil nil)))))
 894
 895 ;;;###autoload
 896 (put 'notmuch-search 'notmuch-doc "Search for messages.")
 897 (defun notmuch-search (&optional query oldest-first target-thread target-line)
 898   "Display threads matching QUERY in a notmuch-search buffer.
 899
 900 If QUERY is nil, it is read interactively from the minibuffer.
 901 Other optional parameters are used as follows:
 902
 903   OLDEST-FIRST: A Boolean controlling the sort order of returned threads
 904   TARGET-THREAD: A thread ID (without the thread: prefix) that will be made
 905                  current if it appears in the search results.
 906   TARGET-LINE: The line number to move to if the target thread does not
 907                appear in the search results.
 908
 909 When called interactively, this will prompt for a query and use
 910 the configured default sort order."
 911   (interactive
 912    (list
 913     ;; Prompt for a query
 914     nil
 915     ;; Use the default search order (if we're doing a search from a
 916     ;; search buffer, ignore any buffer-local overrides)
 917     (default-value 'notmuch-search-oldest-first)))
 918
 919   (let* ((query (or query (notmuch-read-query "Notmuch search: ")))
 920          (buffer (get-buffer-create (notmuch-search-buffer-title query))))
 921     (switch-to-buffer buffer)
 922     (notmuch-search-mode)
 923     ;; Don't track undo information for this buffer
 924     (set 'buffer-undo-list t)
 925     (set 'notmuch-search-query-string query)
 926     (set 'notmuch-search-oldest-first oldest-first)
 927     (set 'notmuch-search-target-thread target-thread)
 928     (set 'notmuch-search-target-line target-line)
 929     (let ((proc (get-buffer-process (current-buffer)))
 930           (inhibit-read-only t))
 931       (if proc
 932           (error "notmuch search process already running for query `%s'" query)
 933         )
 934       (erase-buffer)
 935       (goto-char (point-min))
 936       (save-excursion
 937         (let ((proc (notmuch-start-notmuch
 938                      "notmuch-search" buffer #'notmuch-search-process-sentinel
 939                      "search" "--format=sexp" "--format-version=1"
 940                      (if oldest-first
 941                          "--sort=oldest-first"
 942                        "--sort=newest-first")
 943                      query))
 944               ;; Use a scratch buffer to accumulate partial output.
 945               ;; This buffer will be killed by the sentinel, which
 946               ;; should be called no matter how the process dies.
 947               (parse-buf (generate-new-buffer " *notmuch search parse*")))
 948           (process-put proc 'parse-buf parse-buf)
 949           (set-process-filter proc 'notmuch-search-process-filter)
 950           (set-process-query-on-exit-flag proc nil))))
 951     (run-hooks 'notmuch-search-hook)))
 952
 953 (defun notmuch-search-refresh-view ()
 954   "Refresh the current view.
 955
 956 Kills the current buffer and runs a new search with the same
 957 query string as the current search. If the current thread is in
 958 the new search results, then point will be placed on the same
 959 thread. Otherwise, point will be moved to attempt to be in the
 960 same relative position within the new buffer."
 961   (let ((target-line (line-number-at-pos))
 962         (oldest-first notmuch-search-oldest-first)
 963         (target-thread (notmuch-search-find-thread-id 'bare))
 964         (query notmuch-search-query-string))
 965     (notmuch-kill-this-buffer)
 966     (notmuch-search query oldest-first target-thread target-line)
 967     (goto-char (point-min))))
 968
 969 (defun notmuch-search-toggle-order ()
 970   "Toggle the current search order.
 971
 972 This command toggles the sort order for the current search. The
 973 default sort order is defined by `notmuch-search-oldest-first'."
 974   (interactive)
 975   (set 'notmuch-search-oldest-first (not notmuch-search-oldest-first))
 976   (notmuch-search-refresh-view))
 977
 978 (defun notmuch-search-filter (query)
 979   "Filter the current search results based on an additional query string.
 980
 981 Runs a new search matching only messages that match both the
 982 current search results AND the additional query string provided."
 983   (interactive (list (notmuch-read-query "Filter search: ")))
 984   (let ((grouped-query (if (string-match-p notmuch-search-disjunctive-regexp query)
 985                            (concat "( " query " )")
 986                          query)))
 987     (notmuch-search (if (string= notmuch-search-query-string "*")
 988                         grouped-query
 989                       (concat notmuch-search-query-string " and " grouped-query)) notmuch-search-oldest-first)))
 990
 991 (defun notmuch-search-filter-by-tag (tag)
 992   "Filter the current search results based on a single tag.
 993
 994 Runs a new search matching only messages that match both the
 995 current search results AND that are tagged with the given tag."
 996   (interactive
 997    (list (notmuch-select-tag-with-completion "Filter by tag: ")))
 998   (notmuch-search (concat notmuch-search-query-string " and tag:" tag) notmuch-search-oldest-first))
 999
1000 ;;;###autoload
1001 (defun notmuch ()
1002   "Run notmuch and display saved searches, known tags, etc."
1003   (interactive)
1004   (notmuch-hello))
1005
1006 (defun notmuch-interesting-buffer (b)
1007   "Is the current buffer of interest to a notmuch user?"
1008   (with-current-buffer b
1009     (memq major-mode '(notmuch-show-mode
1010                        notmuch-search-mode
1011                        notmuch-hello-mode
1012                        message-mode))))
1013
1014 ;;;###autoload
1015 (defun notmuch-cycle-notmuch-buffers ()
1016   "Cycle through any existing notmuch buffers (search, show or hello).
1017
1018 If the current buffer is the only notmuch buffer, bury it. If no
1019 notmuch buffers exist, run `notmuch'."
1020   (interactive)
1021
1022   (let (start first)
1023     ;; If the current buffer is a notmuch buffer, remember it and then
1024     ;; bury it.
1025     (when (notmuch-interesting-buffer (current-buffer))
1026       (setq start (current-buffer))
1027       (bury-buffer))
1028
1029     ;; Find the first notmuch buffer.
1030     (setq first (loop for buffer in (buffer-list)
1031                      if (notmuch-interesting-buffer buffer)
1032                      return buffer))
1033
1034     (if first
1035         ;; If the first one we found is any other than the starting
1036         ;; buffer, switch to it.
1037         (unless (eq first start)
1038           (switch-to-buffer first))
1039       (notmuch))))
1040
1041 (setq mail-user-agent 'notmuch-user-agent)
1042
1043 (provide 'notmuch)