switch to button-1, which seems to interact poorly with text-selection by mouse
[notmuch] / notmuch.el
1 ; notmuch.el --- run notmuch within emacs
2 ;
3 ; Copyright © Carl Worth
4 ;
5 ; This file is part of Notmuch.
6 ;
7 ; Notmuch is free software: you can redistribute it and/or modify it
8 ; under the terms of the GNU General Public License as published by
9 ; the Free Software Foundation, either version 3 of the License, or
10 ; (at your option) any later version.
11 ;
12 ; Notmuch is distributed in the hope that it will be useful, but
13 ; WITHOUT ANY WARRANTY; without even the implied warranty of
14 ; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
15 ; General Public License for more details.
16 ;
17 ; You should have received a copy of the GNU General Public License
18 ; along with Notmuch.  If not, see <http://www.gnu.org/licenses/>.
19 ;
20 ; Authors: Carl Worth <cworth@cworth.org>
21
22 ; This is an emacs-based interface to the notmuch mail system.
23 ;
24 ; You will first need to have the notmuch program installed and have a
25 ; notmuch database built in order to use this. See
26 ; http://notmuchmail.org for details.
27 ;
28 ; To install this software, copy it to a directory that is on the
29 ; `load-path' variable within emacs (a good candidate is
30 ; /usr/local/share/emacs/site-lisp). If you are viewing this from the
31 ; notmuch source distribution then you can simply run:
32 ;
33 ;       sudo make install-emacs
34 ;
35 ; to install it.
36 ;
37 ; Then, to actually run it, add:
38 ;
39 ;       (require 'notmuch)
40 ;
41 ; to your ~/.emacs file, and then run "M-x notmuch" from within emacs,
42 ; or run:
43 ;
44 ;       emacs -f notmuch
45 ;
46 ; Have fun, and let us know if you have any comment, questions, or
47 ; kudos: Notmuch list <notmuch@notmuchmail.org> (subscription is not
48 ; required, but is available from http://notmuchmail.org).
49
50 (require 'cl)
51 (require 'mm-view)
52
53 (defvar notmuch-show-mode-map
54   (let ((map (make-sparse-keymap)))
55     ; I don't actually want all of these toggle commands occupying
56     ; keybindings. They steal valuable key-binding space, are hard
57     ; to remember, and act globally rather than locally.
58     ;
59     ; Will be much preferable to switch to direct manipulation for
60     ; toggling visibility of these components. Probably using
61     ; overlays-at to query and manipulate the current overlay.
62     (define-key map "a" 'notmuch-show-archive-thread)
63     (define-key map "A" 'notmuch-show-mark-read-then-archive-thread)
64     (define-key map "b" 'notmuch-show-toggle-body-read-visible)
65     (define-key map "c" 'notmuch-show-toggle-citations-visible)
66     (define-key map "h" 'notmuch-show-toggle-headers-visible)
67     (define-key map "m" 'message-mail)
68     (define-key map "n" 'notmuch-show-next-message)
69     (define-key map "N" 'notmuch-show-mark-read-then-next-open-message)
70     (define-key map "p" 'notmuch-show-previous-message)
71     (define-key map (kbd "C-n") 'notmuch-show-next-line)
72     (define-key map (kbd "C-p") 'notmuch-show-previous-line)
73     (define-key map "q" 'kill-this-buffer)
74     (define-key map "r" 'notmuch-show-reply)
75     (define-key map "s" 'notmuch-show-toggle-signatures-visible)
76     (define-key map "v" 'notmuch-show-view-all-mime-parts)
77     (define-key map "w" 'notmuch-show-view-raw-message)
78     (define-key map "x" 'kill-this-buffer)
79     (define-key map "+" 'notmuch-show-add-tag)
80     (define-key map "-" 'notmuch-show-remove-tag)
81     (define-key map (kbd "DEL") 'notmuch-show-rewind)
82     (define-key map " " 'notmuch-show-advance-marking-read-and-archiving)
83     (define-key map "|" 'notmuch-show-pipe-message)
84     (define-key map "?" 'describe-mode)
85     map)
86   "Keymap for \"notmuch show\" buffers.")
87 (fset 'notmuch-show-mode-map notmuch-show-mode-map)
88
89 (defvar notmuch-show-signature-regexp "\\(-- ?\\|_+\\)$"
90   "Pattern to match a line that separates content from signature.
91
92 The regexp can (and should) include $ to match the end of the
93 line, but should not include ^ to match the beginning of the
94 line. This is because notmuch may have inserted additional space
95 for indentation at the beginning of the line. But notmuch will
96 move past the indentation when testing this pattern, (so that the
97 pattern can still test against the entire line).")
98
99 (defvar notmuch-show-signature-lines-max 12
100   "Maximum length of signature that will be hidden by default.")
101
102 (defvar notmuch-command "notmuch"
103   "Command to run the notmuch binary.")
104
105 (defvar notmuch-show-message-begin-regexp    "\fmessage{")
106 (defvar notmuch-show-message-end-regexp      "\fmessage}")
107 (defvar notmuch-show-header-begin-regexp     "\fheader{")
108 (defvar notmuch-show-header-end-regexp       "\fheader}")
109 (defvar notmuch-show-body-begin-regexp       "\fbody{")
110 (defvar notmuch-show-body-end-regexp         "\fbody}")
111 (defvar notmuch-show-attachment-begin-regexp "\fattachment{")
112 (defvar notmuch-show-attachment-end-regexp   "\fattachment}")
113 (defvar notmuch-show-part-begin-regexp       "\fpart{")
114 (defvar notmuch-show-part-end-regexp         "\fpart}")
115 (defvar notmuch-show-marker-regexp "\f\\(message\\|header\\|body\\|attachment\\|part\\)[{}].*$")
116
117 (defvar notmuch-show-id-regexp "\\(id:[^ ]*\\)")
118 (defvar notmuch-show-depth-regexp " depth:\\([0-9]*\\) ")
119 (defvar notmuch-show-filename-regexp "filename:\\(.*\\)$")
120 (defvar notmuch-show-tags-regexp "(\\([^)]*\\))$")
121
122 (defvar notmuch-show-parent-buffer nil)
123 (defvar notmuch-show-body-read-visible nil)
124 (defvar notmuch-show-citations-visible nil)
125 (defvar notmuch-show-signatures-visible nil)
126 (defvar notmuch-show-headers-visible nil)
127
128 ; XXX: This should be a generic function in emacs somewhere, not here
129 (defun point-invisible-p ()
130   "Return whether the character at point is invisible.
131
132 Here visibility is determined by `buffer-invisibility-spec' and
133 the invisible property of any overlays for point. It doesn't have
134 anything to do with whether point is currently being displayed
135 within the current window."
136   (let ((prop (get-char-property (point) 'invisible)))
137     (if (eq buffer-invisibility-spec t)
138         prop
139       (or (memq prop buffer-invisibility-spec)
140           (assq prop buffer-invisibility-spec)))))
141
142 (defun notmuch-show-next-line ()
143   "Like builtin `next-line' but ensuring we end on a visible character.
144
145 By advancing forward until reaching a visible character.
146
147 Unlike builtin `next-line' this version accepts no arguments."
148   (interactive)
149   (set 'this-command 'next-line)
150   (call-interactively 'next-line)
151   (while (point-invisible-p)
152     (forward-char)))
153
154 (defun notmuch-show-previous-line ()
155   "Like builtin `previous-line' but ensuring we end on a visible character.
156
157 By advancing forward until reaching a visible character.
158
159 Unlike builtin `next-line' this version accepts no arguments."
160   (interactive)
161   (set 'this-command 'previous-line)
162   (call-interactively 'previous-line)
163   (while (point-invisible-p)
164     (forward-char)))
165
166 (defun notmuch-show-get-message-id ()
167   (save-excursion
168     (beginning-of-line)
169     (if (not (looking-at notmuch-show-message-begin-regexp))
170         (re-search-backward notmuch-show-message-begin-regexp))
171     (re-search-forward notmuch-show-id-regexp)
172     (buffer-substring (match-beginning 1) (match-end 1))))
173
174 (defun notmuch-show-get-filename ()
175   (save-excursion
176     (beginning-of-line)
177     (if (not (looking-at notmuch-show-message-begin-regexp))
178         (re-search-backward notmuch-show-message-begin-regexp))
179     (re-search-forward notmuch-show-filename-regexp)
180     (buffer-substring (match-beginning 1) (match-end 1))))
181
182 (defun notmuch-show-set-tags (tags)
183   (save-excursion
184     (beginning-of-line)
185     (if (not (looking-at notmuch-show-message-begin-regexp))
186         (re-search-backward notmuch-show-message-begin-regexp))
187     (re-search-forward notmuch-show-tags-regexp)
188     (let ((inhibit-read-only t)
189           (beg (match-beginning 1))
190           (end (match-end 1)))
191       (delete-region beg end)
192       (goto-char beg)
193       (insert (mapconcat 'identity tags " ")))))
194
195 (defun notmuch-show-get-tags ()
196   (save-excursion
197     (beginning-of-line)
198     (if (not (looking-at notmuch-show-message-begin-regexp))
199         (re-search-backward notmuch-show-message-begin-regexp))
200     (re-search-forward notmuch-show-tags-regexp)
201     (split-string (buffer-substring (match-beginning 1) (match-end 1)))))
202
203 (defun notmuch-show-add-tag (&rest toadd)
204   "Add a tag to the current message."
205   (interactive "sTag to add: ")
206   (apply 'notmuch-call-notmuch-process
207          (append (cons "tag"
208                        (mapcar (lambda (s) (concat "+" s)) toadd))
209                  (cons (notmuch-show-get-message-id) nil)))
210   (notmuch-show-set-tags (sort (union toadd (notmuch-show-get-tags) :test 'string=) 'string<)))
211
212 (defun notmuch-show-remove-tag (&rest toremove)
213   "Remove a tag from the current message."
214   (interactive "sTag to remove: ")
215   (let ((tags (notmuch-show-get-tags)))
216     (if (intersection tags toremove :test 'string=)
217         (progn
218           (apply 'notmuch-call-notmuch-process
219                  (append (cons "tag"
220                                (mapcar (lambda (s) (concat "-" s)) toremove))
221                          (cons (notmuch-show-get-message-id) nil)))
222           (notmuch-show-set-tags (sort (set-difference tags toremove :test 'string=) 'string<))))))
223
224 (defun notmuch-show-archive-thread-maybe-mark-read (markread)
225   (save-excursion
226     (goto-char (point-min))
227     (while (not (eobp))
228       (if markread
229           (notmuch-show-remove-tag "unread" "inbox")
230         (notmuch-show-remove-tag "inbox"))
231       (if (not (eobp))
232           (forward-char))
233       (if (not (re-search-forward notmuch-show-message-begin-regexp nil t))
234           (goto-char (point-max)))))
235   (let ((parent-buffer notmuch-show-parent-buffer))
236     (kill-this-buffer)
237     (if parent-buffer
238         (progn
239           (switch-to-buffer parent-buffer)
240           (forward-line)
241           (notmuch-search-show-thread)))))
242
243 (defun notmuch-show-mark-read-then-archive-thread ()
244   "Remove \"unread\" tag from each message, then archive and show next thread.
245
246 Archive each message currently shown by removing the \"unread\"
247 and \"inbox\" tag from each. Then kill this buffer and show the
248 next thread from the search from which this thread was originally
249 shown.
250
251 Note: This command is safe from any race condition of new messages
252 being delivered to the same thread. It does not archive the
253 entire thread, but only the messages shown in the current
254 buffer."
255   (interactive)
256   (notmuch-show-archive-thread-maybe-mark-read t))
257
258 (defun notmuch-show-archive-thread ()
259   "Archive each message in thread, and show next thread from search.
260
261 Archive each message currently shown by removing the \"inbox\"
262 tag from each. Then kill this buffer and show the next thread
263 from the search from which this thread was originally shown.
264
265 Note: This command is safe from any race condition of new messages
266 being delivered to the same thread. It does not archive the
267 entire thread, but only the messages shown in the current
268 buffer."
269   (interactive)
270   (notmuch-show-archive-thread-maybe-mark-read nil))
271
272 (defun notmuch-show-view-raw-message ()
273   "View the raw email of the current message."
274   (interactive)
275   (view-file (notmuch-show-get-filename)))
276
277 (defun notmuch-show-view-all-mime-parts ()
278   "Use external viewers (according to mailcap) to view all MIME-encoded parts."
279   (interactive)
280   (save-excursion
281     (let ((filename (notmuch-show-get-filename)))
282       (switch-to-buffer (generate-new-buffer (concat "*notmuch-mime-"
283                                                      filename
284                                                      "*")))
285       (insert-file-contents filename nil nil nil t)
286       (mm-display-parts (mm-dissect-buffer))
287       (kill-this-buffer))))
288
289 (defun notmuch-reply (query-string)
290   (switch-to-buffer (generate-new-buffer "notmuch-draft"))
291   (call-process notmuch-command nil t nil "reply" query-string)
292   (goto-char (point-min))
293   (if (re-search-forward "^$" nil t)
294       (progn
295         (insert "--text follows this line--")
296         (forward-line)))
297   (message-mode))
298
299 (defun notmuch-show-reply ()
300   "Begin composing a reply to the current message in a new buffer."
301   (interactive)
302   (let ((message-id (notmuch-show-get-message-id)))
303     (notmuch-reply message-id)))
304
305 (defun notmuch-show-pipe-message (command)
306   "Pipe the contents of the current message to the given command.
307
308 The given command will be executed with the raw contents of the
309 current email message as stdin. Anything printed by the command
310 to stdout or stderr will appear in the *Messages* buffer."
311   (interactive "sPipe message to command: ")
312   (apply 'start-process-shell-command "notmuch-pipe-command" "*notmuch-pipe*" (split-string (concat command " < " (notmuch-show-get-filename)))))
313
314 (defun notmuch-show-move-to-current-message-summary-line ()
315   "Move to the beginning of the one-line summary of the current message.
316
317 This gives us a stable place to move to and work from since the
318 summary line is always visible. This is important since moving to
319 an invisible location is unreliable, (the main command loop moves
320 point either forward or backward to the next visible character
321 when a command ends with point on an invisible character).
322
323 Emits an error if point is not within a valid message, (that is
324 not pattern of `notmuch-show-message-begin-regexp' could be found
325 by searching backward)."
326   (beginning-of-line)
327   (if (not (looking-at notmuch-show-message-begin-regexp))
328       (if (re-search-backward notmuch-show-message-begin-regexp nil t)
329           (forward-line 2)
330         (error "Not within a valid message."))
331     (forward-line 2)))
332
333 (defun notmuch-show-last-message-p ()
334   "Predicate testing whether point is within the last message."
335   (save-window-excursion
336     (save-excursion
337       (notmuch-show-move-to-current-message-summary-line)
338       (not (re-search-forward notmuch-show-message-begin-regexp nil t)))))
339
340 (defun notmuch-show-message-unread-p ()
341   "Preficate testing whether current message is unread."
342   (member "unread" (notmuch-show-get-tags)))
343
344 (defun notmuch-show-next-message ()
345   "Advance to the beginning of the next message in the buffer.
346
347 Moves to the last visible character of the current message if
348 already on the last message in the buffer."
349   (interactive)
350   (notmuch-show-move-to-current-message-summary-line)
351   (if (re-search-forward notmuch-show-message-begin-regexp nil t)
352       (notmuch-show-move-to-current-message-summary-line)
353     (goto-char (- (point-max) 1))
354     (while (point-invisible-p)
355       (backward-char)))
356   (recenter 0))
357
358 (defun notmuch-show-find-next-message ()
359   "Returns the position of the next message in the buffer.
360
361 Or the position of the last visible character of the current
362 message if already within the last message in the buffer."
363   ; save-excursion doesn't save our window position
364   ; save-window-excursion doesn't save point
365   ; Looks like we have to use both.
366   (save-excursion
367     (save-window-excursion
368       (notmuch-show-next-message)
369       (point))))
370
371 (defun notmuch-show-next-unread-message ()
372   "Advance to the beginning of the next unread message in the buffer.
373
374 Moves to the last visible character of the current message if
375 there are no more unread messages past the current point."
376   (notmuch-show-next-message)
377   (while (and (not (notmuch-show-last-message-p))
378               (not (notmuch-show-message-unread-p)))
379     (notmuch-show-next-message))
380   (if (not (notmuch-show-message-unread-p))
381       (notmuch-show-next-message)))
382
383 (defun notmuch-show-next-open-message ()
384   "Advance to the next message which is not hidden.
385
386 If read messages are currently hidden, advance to the next unread
387 message. Otherwise, advance to the next message."
388   (if (or (memq 'notmuch-show-body-read buffer-invisibility-spec)
389           (assq 'notmuch-show-body-read buffer-invisibility-spec))
390       (notmuch-show-next-unread-message)
391     (notmuch-show-next-message)))
392
393 (defun notmuch-show-previous-message ()
394   "Backup to the beginning of the previous message in the buffer.
395
396 If within a message rather than at the beginning of it, then
397 simply move to the beginning of the current message."
398   (interactive)
399   (let ((start (point)))
400     (notmuch-show-move-to-current-message-summary-line)
401     (if (not (< (point) start))
402         ; Go backward twice to skip the current message's marker
403         (progn
404           (re-search-backward notmuch-show-message-begin-regexp nil t)
405           (re-search-backward notmuch-show-message-begin-regexp nil t)
406           (notmuch-show-move-to-current-message-summary-line)
407           ))
408     (recenter 0)))
409
410 (defun notmuch-show-find-previous-message ()
411   "Returns the position of the previous message in the buffer.
412
413 Or the position of the beginning of the current message if point
414 is originally within the message rather than at the beginning of
415 it."
416   ; save-excursion doesn't save our window position
417   ; save-window-excursion doesn't save point
418   ; Looks like we have to use both.
419   (save-excursion
420     (save-window-excursion
421       (notmuch-show-previous-message)
422       (point))))
423
424 (defun notmuch-show-mark-read-then-next-open-message ()
425   "Remove unread tag from current message, then advance to next unread message."
426   (interactive)
427   (notmuch-show-remove-tag "unread")
428   (notmuch-show-next-open-message))
429
430 (defun notmuch-show-rewind ()
431   "Do reverse scrolling compared to `notmuch-show-advance-marking-read-and-archiving'
432
433 Specifically, if the beginning of the previous email is fewer
434 than `window-height' lines from the current point, move to it
435 just like `notmuch-show-previous-message'.
436
437 Otherwise, just scroll down a screenful of the current message.
438
439 This command does not modify any message tags, (it does not undo
440 any effects from previous calls to
441 `notmuch-show-advance-marking-read-and-archiving'."
442   (interactive)
443   (let ((previous (notmuch-show-find-previous-message)))
444     (if (> (count-lines previous (point)) (- (window-height) next-screen-context-lines))
445         (progn
446           (condition-case nil
447               (scroll-down nil)
448             ((beginning-of-buffer) nil))
449           (goto-char (window-start)))
450       (notmuch-show-previous-message))))
451
452 (defun notmuch-show-advance-marking-read-and-archiving ()
453   "Advance through buffer, marking read and archiving.
454
455 This command is intended to be one of the simplest ways to
456 process a thread of email. It does the following:
457
458 If the current message in the thread is not yet fully visible,
459 scroll by a near screenful to read more of the message.
460
461 Otherwise, (the end of the current message is already within the
462 current window), remove the \"unread\" tag (if present) from the
463 current message and advance to the next open message.
464
465 Finally, if there is no further message to advance to, and this
466 last message is already read, then archive the entire current
467 thread, (remove the \"inbox\" tag from each message). Also kill
468 this buffer, and display the next thread from the search from
469 which this thread was originally shown."
470   (interactive)
471   (let ((next (notmuch-show-find-next-message))
472         (unread (notmuch-show-message-unread-p)))
473     (if (> next (window-end))
474         (scroll-up nil)
475       (let ((last (notmuch-show-last-message-p)))
476         (notmuch-show-mark-read-then-next-open-message)
477         (if last
478             (notmuch-show-archive-thread))))))
479
480 (defun notmuch-toggle-invisible-action (cite-button)
481   (let ((invis-spec (button-get button 'invisibility-spec)))
482         (if (invisible-p invis-spec)
483             (remove-from-invisibility-spec invis-spec)
484           (add-to-invisibility-spec invis-spec)
485           ))
486   (force-window-update)
487   (redisplay t))
488
489 (defun notmuch-show-markup-citations-region (beg end depth)
490   (goto-char beg)
491   (beginning-of-line)
492   (while (< (point) end)
493     (let ((beg-sub (point-marker))
494           (indent (make-string depth ? ))
495           (citation "[[:space:]]*>"))
496       (if (looking-at citation)
497           (progn
498             (while (looking-at citation)
499               (forward-line))
500             (let ((overlay (make-overlay beg-sub (point)))
501                   (invis-spec (make-symbol "notmuch-citation-region")))
502               (add-to-invisibility-spec invis-spec)
503               (overlay-put overlay 'invisible invis-spec)
504               (let (
505                     (p (point))
506                     (cite-button-text
507                      (concat "["  (number-to-string (count-lines beg-sub (point)))
508                              "-line citation.]"))
509                     )
510                 (goto-char (- beg-sub 1))
511                 (insert (concat "\n" indent))
512                 (let ((cite-button (insert-button cite-button-text)))
513                   (button-put cite-button 'invisibility-spec invis-spec)
514                   (button-put cite-button 'action 'notmuch-toggle-invisible-action)
515                   (button-put cite-button 'follow-link t)
516                   (button-put cite-button 'help-echo
517                               "mouse-1, RET: Show citation")
518
519                   )
520                 (insert "\n")
521                 (goto-char (+ (length cite-button-text) p))
522               ))))
523       (move-to-column depth)
524       (if (looking-at notmuch-show-signature-regexp)
525           (let ((sig-lines (- (count-lines beg-sub end) 1)))
526             (if (<= sig-lines notmuch-show-signature-lines-max)
527                 (progn
528                   (let ((invis-spec (make-symbol "notmuch-signature-region")))
529                     (add-to-invisibility-spec invis-spec)
530                     (overlay-put (make-overlay beg-sub end)
531                                  'invisible invis-spec)
532                   
533                     (goto-char (- beg-sub 1))
534                     (insert (concat "\n" indent))
535                     (let ((sig-button (insert-button 
536                                        (concat "[" (number-to-string sig-lines)
537                                          "-line signature.]"))))
538                       (button-put sig-button 'invisibility-spec invis-spec)
539                       (button-put sig-button 'action
540                                   'notmuch-toggle-invisible-action)
541                       (button-put sig-button 'follow-link t)
542                       (button-put sig-button 'help-echo
543                                   "mouse-1, RET: Show signature")
544                       )
545                     (insert "\n")
546                     (goto-char end))))))
547       (forward-line))))
548
549 (defun notmuch-show-markup-part (beg end depth)
550   (if (re-search-forward notmuch-show-part-begin-regexp nil t)
551       (progn
552         (forward-line)
553         (let ((beg (point-marker)))
554           (re-search-forward notmuch-show-part-end-regexp)
555           (let ((end (copy-marker (match-beginning 0))))
556             (goto-char end)
557             (if (not (bolp))
558                 (insert "\n"))
559             (indent-rigidly beg end depth)
560             (notmuch-show-markup-citations-region beg end depth)
561             ; Advance to the next part (if any) (so the outer loop can
562             ; determine whether we've left the current message.
563             (if (re-search-forward notmuch-show-part-begin-regexp nil t)
564                 (beginning-of-line)))))
565     (goto-char end)))
566
567 (defun notmuch-show-markup-parts-region (beg end depth)
568   (save-excursion
569     (goto-char beg)
570     (while (< (point) end)
571       (notmuch-show-markup-part beg end depth))))
572
573 (defun notmuch-show-markup-body (depth)
574   (re-search-forward notmuch-show-body-begin-regexp)
575   (forward-line)
576   (let ((beg (point-marker)))
577     (re-search-forward notmuch-show-body-end-regexp)
578     (let ((end (copy-marker (match-beginning 0))))
579       (notmuch-show-markup-parts-region beg end depth)
580       (if (not (notmuch-show-message-unread-p))
581           (overlay-put (make-overlay beg end)
582                        'invisible 'notmuch-show-body-read))
583       (set-marker beg nil)
584       (set-marker end nil)
585       )))
586
587 (defun notmuch-show-markup-header (depth)
588   (re-search-forward notmuch-show-header-begin-regexp)
589   (forward-line)
590   (let ((beg (point-marker)))
591     (end-of-line)
592     ; Inverse video for subject
593     (overlay-put (make-overlay beg (point)) 'face '(:inverse-video t))
594     (forward-line 2)
595     (let ((beg-hidden (point-marker)))
596       (re-search-forward notmuch-show-header-end-regexp)
597       (beginning-of-line)
598       (let ((end (point-marker)))
599         (goto-char beg)
600         (forward-line)
601         (while (looking-at "[A-Za-z][-A-Za-z0-9]*:")
602           (beginning-of-line)
603           (overlay-put (make-overlay (point) (re-search-forward ":"))
604                        'face 'bold)
605           (forward-line)
606           )
607         (indent-rigidly beg end depth)
608         (overlay-put (make-overlay beg-hidden end)
609                      'invisible 'notmuch-show-header)
610         (goto-char end)
611         (insert "\n")
612         (set-marker beg nil)
613         (set-marker beg-hidden nil)
614         (set-marker end nil)
615         ))))
616
617 (defun notmuch-show-markup-message ()
618   (if (re-search-forward notmuch-show-message-begin-regexp nil t)
619       (progn
620         (re-search-forward notmuch-show-depth-regexp)
621         (let ((depth (string-to-number (buffer-substring (match-beginning 1) (match-end 1)))))
622           (notmuch-show-markup-header depth)
623           (notmuch-show-markup-body depth)))
624     (goto-char (point-max))))
625
626 (defun notmuch-show-hide-markers ()
627   (save-excursion
628     (goto-char (point-min))
629     (while (not (eobp))
630       (if (re-search-forward notmuch-show-marker-regexp nil t)
631           (progn
632             (overlay-put (make-overlay (match-beginning 0) (+ (match-end 0) 1))
633                          'invisible 'notmuch-show-marker))
634         (goto-char (point-max))))))
635
636 (defun notmuch-show-markup-messages ()
637   (save-excursion
638     (goto-char (point-min))
639     (while (not (eobp))
640       (notmuch-show-markup-message)))
641   (notmuch-show-hide-markers))
642
643 (defun notmuch-show-toggle-citations-visible ()
644   "Toggle visibility of citations"
645   (interactive)
646   (if notmuch-show-citations-visible
647       (add-to-invisibility-spec 'notmuch-show-citation)
648     (remove-from-invisibility-spec 'notmuch-show-citation))
649   (set 'notmuch-show-citations-visible (not notmuch-show-citations-visible))
650   ; Need to force the redisplay for some reason
651   (force-window-update)
652   (redisplay t))
653
654 (defun notmuch-show-toggle-signatures-visible ()
655   "Toggle visibility of signatures"
656   (interactive)
657   (if notmuch-show-signatures-visible
658       (add-to-invisibility-spec 'notmuch-show-signature)
659     (remove-from-invisibility-spec 'notmuch-show-signature))
660   (set 'notmuch-show-signatures-visible (not notmuch-show-signatures-visible))
661   ; Need to force the redisplay for some reason
662   (force-window-update)
663   (redisplay t))
664
665 (defun notmuch-show-toggle-headers-visible ()
666   "Toggle visibility of header fields"
667   (interactive)
668   (if notmuch-show-headers-visible
669       (add-to-invisibility-spec 'notmuch-show-header)
670     (remove-from-invisibility-spec 'notmuch-show-header))
671   (set 'notmuch-show-headers-visible (not notmuch-show-headers-visible))
672   ; Need to force the redisplay for some reason
673   (force-window-update)
674   (redisplay t))
675
676 (defun notmuch-show-toggle-body-read-visible ()
677   "Toggle visibility of message bodies of read messages"
678   (interactive)
679   (if notmuch-show-body-read-visible
680       (add-to-invisibility-spec 'notmuch-show-body-read)
681     (remove-from-invisibility-spec 'notmuch-show-body-read))
682   (set 'notmuch-show-body-read-visible (not notmuch-show-body-read-visible))
683   ; Need to force the redisplay for some reason
684   (force-window-update)
685   (redisplay t))
686
687 ;;;###autoload
688 (defun notmuch-show-mode ()
689   "Major mode for viewing a thread with notmuch.
690
691 This buffer contains the results of the \"notmuch show\" command
692 for displaying a single thread of email from your email archives.
693
694 By default, various components of email messages, (citations,
695 signatures, already-read messages), are invisible to help you
696 focus on the most important things, (new text from unread
697 messages). See the various commands below for toggling the
698 visibility of hidden components.
699
700 The `notmuch-show-next-message' and
701 `notmuch-show-previous-message' commands, (bound to 'n' and 'p by
702 default), allow you to navigate to the next and previous
703 messages. Each time you navigate away from a message with
704 `notmuch-show-next-message' the current message will have its
705 \"unread\" tag removed.
706
707 You can add or remove tags from the current message with '+' and
708 '-'.  You can also archive all messages in the current
709 view, (remove the \"inbox\" tag from each), with
710 `notmuch-show-archive-thread' (bound to 'a' by default).
711
712 \\{notmuch-show-mode-map}"
713   (interactive)
714   (kill-all-local-variables)
715   (set (make-local-variable 'notmuch-show-headers-visible) t)
716   (notmuch-show-toggle-headers-visible)
717   (set (make-local-variable 'notmuch-show-body-read-visible) t)
718   (notmuch-show-toggle-body-read-visible)
719   (set (make-local-variable 'notmuch-show-citations-visible) t)
720   (notmuch-show-toggle-citations-visible)
721   (set (make-local-variable 'notmuch-show-signatures-visible) t)
722   (notmuch-show-toggle-signatures-visible)
723   (add-to-invisibility-spec 'notmuch-show-marker)
724   (use-local-map notmuch-show-mode-map)
725   (setq major-mode 'notmuch-show-mode
726         mode-name "notmuch-show")
727   (setq buffer-read-only t))
728
729 ;;;###autoload
730
731 (defgroup notmuch nil
732   "Notmuch mail reader for Emacs."
733   :group 'mail)
734
735 (defcustom notmuch-show-hook nil
736   "List of functions to call when notmuch displays a message."
737   :type 'hook
738   :options '(goto-address)
739   :group 'notmuch)
740
741 (defcustom notmuch-search-hook nil
742   "List of functions to call when notmuch displays the search results."
743   :type 'hook
744   :options '(hl-line-mode)
745   :group 'notmuch)
746
747 ; Make show mode a bit prettier, highlighting URLs and using word wrap
748
749 (defun notmuch-show-pretty-hook ()
750   (goto-address-mode 1)
751   (visual-line-mode))
752
753 (add-hook 'notmuch-show-hook 'notmuch-show-pretty-hook)
754 (add-hook 'notmuch-search-hook
755           (lambda()
756             (hl-line-mode 1) ))
757
758 (defun notmuch-show (thread-id &optional parent-buffer)
759   "Run \"notmuch show\" with the given thread ID and display results.
760
761 The optional PARENT-BUFFER is the notmuch-search buffer from
762 which this notmuch-show command was executed, (so that the next
763 thread from that buffer can be show when done with this one)."
764   (interactive "sNotmuch show: ")
765   (let ((buffer (get-buffer-create (concat "*notmuch-show-" thread-id "*"))))
766     (switch-to-buffer buffer)
767     (notmuch-show-mode)
768     (set (make-local-variable 'notmuch-show-parent-buffer) parent-buffer)
769     (let ((proc (get-buffer-process (current-buffer)))
770           (inhibit-read-only t))
771       (if proc
772           (error "notmuch search process already running for query `%s'" thread-id)
773         )
774       (erase-buffer)
775       (goto-char (point-min))
776       (save-excursion
777         (call-process notmuch-command nil t nil "show" thread-id)
778         (notmuch-show-markup-messages)
779         )
780       (run-hooks 'notmuch-show-hook)
781       ; Move straight to the first unread message
782       (if (not (notmuch-show-message-unread-p))
783           (progn
784             (notmuch-show-next-unread-message)
785             ; But if there are no unread messages, go back to the
786             ; beginning of the buffer, and open up the bodies of all
787             ; read message.
788             (if (not (notmuch-show-message-unread-p))
789                 (progn
790                   (goto-char (point-min))
791                   (notmuch-show-toggle-body-read-visible)))))
792       )))
793
794 (defvar notmuch-search-authors-width 40
795   "Number of columns to use to display authors in a notmuch-search buffer.")
796
797 (defvar notmuch-search-mode-map
798   (let ((map (make-sparse-keymap)))
799     (define-key map "a" 'notmuch-search-archive-thread)
800     (define-key map "b" 'notmuch-search-scroll-down)
801     (define-key map "f" 'notmuch-search-filter)
802     (define-key map "m" 'message-mail)
803     (define-key map "n" 'next-line)
804     (define-key map "o" 'notmuch-search-toggle-order)
805     (define-key map "p" 'previous-line)
806     (define-key map "q" 'kill-this-buffer)
807     (define-key map "r" 'notmuch-search-reply-to-thread)
808     (define-key map "s" 'notmuch-search)
809     (define-key map "t" 'notmuch-search-filter-by-tag)
810     (define-key map "x" 'kill-this-buffer)
811     (define-key map (kbd "RET") 'notmuch-search-show-thread)
812     (define-key map "+" 'notmuch-search-add-tag)
813     (define-key map "-" 'notmuch-search-remove-tag)
814     (define-key map "<" 'beginning-of-buffer)
815     (define-key map ">" 'notmuch-search-goto-last-thread)
816     (define-key map "=" 'notmuch-search-refresh-view)
817     (define-key map "\M->" 'notmuch-search-goto-last-thread)
818     (define-key map " " 'notmuch-search-scroll-up)
819     (define-key map (kbd "<DEL>") 'notmuch-search-scroll-down)
820     (define-key map "?" 'describe-mode)
821     map)
822   "Keymap for \"notmuch search\" buffers.")
823 (fset 'notmuch-search-mode-map notmuch-search-mode-map)
824
825 (defvar notmuch-search-query-string)
826 (defvar notmuch-search-oldest-first)
827
828 (defun notmuch-search-scroll-up ()
829   "Scroll up, moving point to last message in thread if at end."
830   (interactive)
831   (condition-case nil
832       (scroll-up nil)
833     ((end-of-buffer) (notmuch-search-goto-last-thread))))
834
835 (defun notmuch-search-scroll-down ()
836   "Scroll down, moving point to first message in thread if at beginning."
837   (interactive)
838   ; I don't know why scroll-down doesn't signal beginning-of-buffer
839   ; the way that scroll-up signals end-of-buffer, but c'est la vie.
840   ;
841   ; So instead of trapping a signal we instead check whether the
842   ; window begins on the first line of the buffer and if so, move
843   ; directly to that position. (We have to count lines since the
844   ; window-start position is not the same as point-min due to the
845   ; invisible thread-ID characters on the first line.
846   (if (equal (count-lines (point-min) (window-start)) 1)
847       (goto-char (window-start))
848     (scroll-down nil)))
849
850 (defun notmuch-search-goto-last-thread ()
851   "Move point to the last thread in the buffer."
852   (interactive)
853   (goto-char (point-max))
854   (forward-line -1))
855
856 ;;;###autoload
857 (defun notmuch-search-mode ()
858   "Major mode for searching mail with notmuch.
859
860 This buffer contains the results of a \"notmuch search\" of your
861 email archives. Each line in the buffer represents a single
862 thread giving a relative date for the thread and a subject.
863
864 Pressing RET on any line displays that thread. The '+' and '-'
865 keys can be used to add or remove tags from a thread. The 'a' key
866 is a convenience key for archiving a thread (removing the
867 \"inbox\" tag).
868
869 Other useful commands are `notmuch-search-filter' for filtering
870 the current search based on an additional query string,
871 `notmuch-search-filter-by-tag' for filtering to include only
872 messages with a given tag, and `notmuch-search' to execute a new,
873 global search.
874
875 \\{notmuch-search-mode-map}"
876   (interactive)
877   (kill-all-local-variables)
878   (make-local-variable 'notmuch-search-query-string)
879   (make-local-variable 'notmuch-search-oldest-first)
880   (set (make-local-variable 'scroll-preserve-screen-position) t)
881   (add-to-invisibility-spec 'notmuch-search)
882   (use-local-map notmuch-search-mode-map)
883   (setq truncate-lines t)
884   (setq major-mode 'notmuch-search-mode
885         mode-name "notmuch-search")
886   (setq buffer-read-only t))
887
888 (defun notmuch-search-find-thread-id ()
889   (save-excursion
890     (beginning-of-line)
891     (let ((beg (point)))
892       (re-search-forward "thread:[a-fA-F0-9]*" nil t)
893       (filter-buffer-substring beg (point)))))
894
895 (defun notmuch-search-markup-this-thread-id ()
896   (beginning-of-line)
897   (let ((beg (point)))
898     (if (re-search-forward "thread:[a-fA-F0-9]*" nil t)
899         (progn
900           (forward-char)
901           (overlay-put (make-overlay beg (point)) 'invisible 'notmuch-search)
902           (re-search-forward ".*\\[[0-9]*/[0-9]*\\] \\([^;]*\\)\\(;\\)")
903           (let* ((authors (buffer-substring (match-beginning 1) (match-end 1)))
904                  (authors-length (length authors)))
905             ;; Drop the semi-colon
906             (replace-match "" t nil nil 2)
907             (if (<= authors-length notmuch-search-authors-width)
908                 (replace-match (concat authors (make-string
909                                                 (- notmuch-search-authors-width
910                                                    authors-length) ? )) t t nil 1)
911               (replace-match (concat (substring authors 0 (- notmuch-search-authors-width 3)) "...") t t nil 1)))))))
912
913 (defun notmuch-search-markup-thread-ids ()
914   (save-excursion
915     (goto-char (point-min))
916     (while (not (eobp))
917       (notmuch-search-markup-this-thread-id)
918       (forward-line))))
919
920 (defun notmuch-search-show-thread ()
921   (interactive)
922   (let ((thread-id (notmuch-search-find-thread-id)))
923     (if (> (length thread-id) 0)
924         (notmuch-show thread-id (current-buffer))
925       (error "End of search results"))))
926
927 (defun notmuch-search-reply-to-thread ()
928   "Begin composing a reply to the entire current thread in a new buffer."
929   (interactive)
930   (let ((message-id (notmuch-search-find-thread-id)))
931     (notmuch-reply message-id)))
932
933 (defun notmuch-call-notmuch-process (&rest args)
934   "Synchronously invoke \"notmuch\" with the given list of arguments.
935
936 Output from the process will be presented to the user as an error
937 and will also appear in a buffer named \"*Notmuch errors*\"."
938   (let ((error-buffer (get-buffer-create "*Notmuch errors*")))
939     (with-current-buffer error-buffer
940         (erase-buffer))
941     (if (eq (apply 'call-process notmuch-command nil error-buffer nil args) 0)
942         (point)
943       (progn
944         (with-current-buffer error-buffer
945           (let ((beg (point-min))
946                 (end (- (point-max) 1)))
947             (error (buffer-substring beg end))
948             ))))))
949
950 (defun notmuch-search-set-tags (tags)
951   (save-excursion
952     (end-of-line)
953     (re-search-backward "(")
954     (forward-char)
955     (let ((beg (point))
956           (inhibit-read-only t))
957       (re-search-forward ")")
958       (backward-char)
959       (let ((end (point)))
960         (delete-region beg end)
961         (insert (mapconcat  'identity tags " "))))))
962
963 (defun notmuch-search-get-tags ()
964   (save-excursion
965     (end-of-line)
966     (re-search-backward "(")
967     (let ((beg (+ (point) 1)))
968       (re-search-forward ")")
969       (let ((end (- (point) 1)))
970         (split-string (buffer-substring beg end))))))
971
972 (defun notmuch-search-add-tag (tag)
973   (interactive "sTag to add: ")
974   (notmuch-call-notmuch-process "tag" (concat "+" tag) (notmuch-search-find-thread-id))
975   (notmuch-search-set-tags (delete-dups (sort (cons tag (notmuch-search-get-tags)) 'string<))))
976
977 (defun notmuch-search-remove-tag (tag)
978   (interactive "sTag to remove: ")
979   (notmuch-call-notmuch-process "tag" (concat "-" tag) (notmuch-search-find-thread-id))
980   (notmuch-search-set-tags (delete tag (notmuch-search-get-tags))))
981
982 (defun notmuch-search-archive-thread ()
983   "Archive the current thread (remove its \"inbox\" tag).
984
985 This function advances point to the next line when finished."
986   (interactive)
987   (notmuch-search-remove-tag "inbox")
988   (forward-line))
989
990 (defun notmuch-search (query &optional oldest-first)
991   "Run \"notmuch search\" with the given query string and display results."
992   (interactive "sNotmuch search: ")
993   (let ((buffer (get-buffer-create (concat "*notmuch-search-" query "*"))))
994     (switch-to-buffer buffer)
995     (notmuch-search-mode)
996     (set 'notmuch-search-query-string query)
997     (set 'notmuch-search-oldest-first oldest-first)
998     (let ((proc (get-buffer-process (current-buffer)))
999           (inhibit-read-only t))
1000       (if proc
1001           (error "notmuch search process already running for query `%s'" query)
1002         )
1003       (erase-buffer)
1004       (goto-char (point-min))
1005       (save-excursion
1006         (if oldest-first
1007             (call-process notmuch-command nil t nil "search" "--sort=oldest-first" query)
1008           (call-process notmuch-command nil t nil "search" "--sort=newest-first" query))
1009         (notmuch-search-markup-thread-ids)
1010         ))
1011     (run-hooks 'notmuch-search-hook)))
1012
1013 (defun notmuch-search-refresh-view ()
1014   "Refresh the current view.
1015
1016 Kills the current buffer and runs a new search with the same
1017 query string as the current search. If the current thread is in
1018 the new search results, then point will be placed on the same
1019 thread. Otherwise, point will be moved to attempt to be in the
1020 same relative position within the new buffer."
1021   (interactive)
1022   (let ((here (point))
1023         (oldest-first notmuch-search-oldest-first)
1024         (thread (notmuch-search-find-thread-id))
1025         (query notmuch-search-query-string))
1026     (kill-this-buffer)
1027     (notmuch-search query oldest-first)
1028     (goto-char (point-min))
1029     (if (re-search-forward (concat "^" thread) nil t)
1030         (beginning-of-line)
1031       (goto-char here))))
1032
1033 (defun notmuch-search-toggle-order ()
1034   "Toggle the current search order.
1035
1036 By default, the \"inbox\" view created by `notmuch' is displayed
1037 in chronological order (oldest thread at the beginning of the
1038 buffer), while any global searches created by `notmuch-search'
1039 are displayed in reverse-chronological order (newest thread at
1040 the beginning of the buffer).
1041
1042 This command toggles the sort order for the current search.
1043
1044 Note that any filtered searches created by
1045 `notmuch-search-filter' retain the search order of the parent
1046 search."
1047   (interactive)
1048   (set 'notmuch-search-oldest-first (not notmuch-search-oldest-first))
1049   (notmuch-search-refresh-view))
1050
1051 (defun notmuch-search-filter (query)
1052   "Filter the current search results based on an additional query string.
1053
1054 Runs a new search matching only messages that match both the
1055 current search results AND the additional query string provided."
1056   (interactive "sFilter search: ")
1057   (notmuch-search (concat notmuch-search-query-string " and " query) notmuch-search-oldest-first))
1058
1059 (defun notmuch-search-filter-by-tag (tag)
1060   "Filter the current search results based on a single tag.
1061
1062 Runs a new search matching only messages that match both the
1063 current search results AND that are tagged with the given tag."
1064   (interactive "sFilter by tag: ")
1065   (notmuch-search (concat notmuch-search-query-string " and tag:" tag) notmuch-search-oldest-first))
1066
1067 (defun notmuch ()
1068   "Run notmuch to display all mail with tag of 'inbox'"
1069   (interactive)
1070   (notmuch-search "tag:inbox" t))
1071
1072 (setq mail-user-agent 'message-user-agent)
1073
1074 (provide 'notmuch)