try-emacs-mua: Trim `require' advice for Emacs 25
[notmuch] / emacs / notmuch-jump.el
1 ;;; notmuch-jump.el --- User-friendly shortcut keys
2 ;;
3 ;; Copyright © Austin Clements
4 ;;
5 ;; This file is part of Notmuch.
6 ;;
7 ;; Notmuch is free software: you can redistribute it and/or modify it
8 ;; under the terms of the GNU General Public License as published by
9 ;; the Free Software Foundation, either version 3 of the License, or
10 ;; (at your option) any later version.
11 ;;
12 ;; Notmuch is distributed in the hope that it will be useful, but
13 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
15 ;; General Public License for more details.
16 ;;
17 ;; You should have received a copy of the GNU General Public License
18 ;; along with Notmuch.  If not, see <https://www.gnu.org/licenses/>.
19 ;;
20 ;; Authors: Austin Clements <aclements@csail.mit.edu>
21 ;;          David Edmondson <dme@dme.org>
22
23 ;;; Code:
24
25 (eval-when-compile
26   (require 'cl-lib)
27   (require 'pcase))
28
29 (require 'notmuch-lib)
30 (require 'notmuch-hello)
31
32 (eval-and-compile
33   (unless (fboundp 'window-body-width)
34     ;; Compatibility for Emacs pre-24
35     (defalias 'window-body-width 'window-width)))
36
37 ;;;###autoload
38 (defun notmuch-jump-search ()
39   "Jump to a saved search by shortcut key.
40
41 This prompts for and performs a saved search using the shortcut
42 keys configured in the :key property of `notmuch-saved-searches'.
43 Typically these shortcuts are a single key long, so this is a
44 fast way to jump to a saved search from anywhere in Notmuch."
45   (interactive)
46
47   ;; Build the action map
48   (let (action-map)
49     (dolist (saved-search notmuch-saved-searches)
50       (let* ((saved-search (notmuch-hello-saved-search-to-plist saved-search))
51              (key (plist-get saved-search :key)))
52         (when key
53           (let ((name (plist-get saved-search :name))
54                 (query (plist-get saved-search :query))
55                 (oldest-first
56                  (cl-case (plist-get saved-search :sort-order)
57                    (newest-first nil)
58                    (oldest-first t)
59                    (otherwise (default-value 'notmuch-search-oldest-first)))))
60             (push (list key name
61                         (cond
62                          ((eq (plist-get saved-search :search-type) 'tree)
63                           `(lambda () (notmuch-tree ',query)))
64                          ((eq (plist-get saved-search :search-type) 'unthreaded)
65                           `(lambda () (notmuch-unthreaded ',query)))
66                          (t
67                           `(lambda () (notmuch-search ',query ',oldest-first)))))
68                   action-map)))))
69     (setq action-map (nreverse action-map))
70
71     (if action-map
72         (notmuch-jump action-map "Search: ")
73       (error "To use notmuch-jump, please customize shortcut keys in notmuch-saved-searches."))))
74
75 (defvar notmuch-jump--action nil)
76
77 (defun notmuch-jump (action-map prompt)
78   "Interactively prompt for one of the keys in ACTION-MAP.
79
80 Displays a summary of all bindings in ACTION-MAP in the
81 minibuffer, reads a key from the minibuffer, and performs the
82 corresponding action.  The prompt can be canceled with C-g or
83 RET.  PROMPT must be a string to use for the prompt.  PROMPT
84 should include a space at the end.
85
86 ACTION-MAP must be a list of triples of the form
87   (KEY LABEL ACTION)
88 where KEY is a key binding, LABEL is a string label to display in
89 the buffer, and ACTION is a nullary function to call.  LABEL may
90 be null, in which case the action will still be bound, but will
91 not appear in the pop-up buffer.
92 "
93
94   (let* ((items (notmuch-jump--format-actions action-map))
95          ;; Format the table of bindings and the full prompt
96          (table
97           (with-temp-buffer
98             (notmuch-jump--insert-items (window-body-width) items)
99             (buffer-string)))
100          (full-prompt
101           (concat table "\n\n"
102                   (propertize prompt 'face 'minibuffer-prompt)))
103          ;; By default, the minibuffer applies the minibuffer face to
104          ;; the entire prompt.  However, we want to clearly
105          ;; distinguish bindings (which we put in the prompt face
106          ;; ourselves) from their labels, so disable the minibuffer's
107          ;; own re-face-ing.
108          (minibuffer-prompt-properties
109           (notmuch-plist-delete
110            (copy-sequence minibuffer-prompt-properties)
111            'face))
112          ;; Build the keymap with our bindings
113          (minibuffer-map (notmuch-jump--make-keymap action-map prompt))
114          ;; The bindings save the the action in notmuch-jump--action
115          (notmuch-jump--action nil))
116     ;; Read the action
117     (read-from-minibuffer full-prompt nil minibuffer-map)
118
119     ;; If we got an action, do it
120     (when notmuch-jump--action
121       (funcall notmuch-jump--action))))
122
123 (defun notmuch-jump--format-actions (action-map)
124   "Format the actions in ACTION-MAP.
125
126 Returns a list of strings, one for each item with a label in
127 ACTION-MAP.  These strings can be inserted into a tabular
128 buffer."
129
130   ;; Compute the maximum key description width
131   (let ((key-width 1))
132     (pcase-dolist (`(,key ,desc) action-map)
133       (setq key-width
134             (max key-width
135                  (string-width (format-kbd-macro key)))))
136     ;; Format each action
137     (mapcar (pcase-lambda (`(,key ,desc))
138               (setq key (format-kbd-macro key))
139               (concat (propertize key 'face 'minibuffer-prompt)
140                       (make-string (- key-width (length key)) ? )
141                       " " desc))
142             action-map)))
143
144 (defun notmuch-jump--insert-items (width items)
145   "Make a table of ITEMS up to WIDTH wide in the current buffer."
146   (let* ((nitems (length items))
147          (col-width (+ 3 (apply #'max (mapcar #'string-width items))))
148          (ncols (if (> (* col-width nitems) width)
149                     (max 1 (/ width col-width))
150                   ;; Items fit on one line.  Space them out
151                   (setq col-width (/ width nitems))
152                   (length items))))
153     (while items
154       (dotimes (col ncols)
155         (when items
156           (let ((item (pop items)))
157             (insert item)
158             (when (and items (< col (- ncols 1)))
159               (insert (make-string (- col-width (string-width item)) ? ))))))
160       (when items
161         (insert "\n")))))
162
163 (defvar notmuch-jump-minibuffer-map
164   (let ((map (make-sparse-keymap)))
165     (set-keymap-parent map minibuffer-local-map)
166     ;; Make this like a special-mode keymap, with no self-insert-command
167     (suppress-keymap map)
168     (define-key map (kbd "DEL") 'exit-minibuffer)
169     map)
170   "Base keymap for notmuch-jump's minibuffer keymap.")
171
172 (defun notmuch-jump--make-keymap (action-map prompt)
173   "Translate ACTION-MAP into a minibuffer keymap."
174   (let ((map (make-sparse-keymap)))
175     (set-keymap-parent map notmuch-jump-minibuffer-map)
176     (pcase-dolist (`(,key ,name ,fn) action-map)
177       (if (= (length key) 1)
178           (define-key map key
179             `(lambda () (interactive)
180                (setq notmuch-jump--action ',fn)
181                (exit-minibuffer)))))
182     ;; By doing this in two passes (and checking if we already have a
183     ;; binding) we avoid problems if the user specifies a binding which
184     ;; is a prefix of another binding.
185     (pcase-dolist (`(,key ,name ,fn) action-map)
186       (if (> (length key) 1)
187           (let* ((key (elt key 0))
188                  (keystr (string key))
189                  (new-prompt (concat prompt (format-kbd-macro keystr) " "))
190                  (action-submap nil))
191             (unless (lookup-key map keystr)
192               (pcase-dolist (`(,k ,n ,f) action-map)
193                 (when (= key (elt k 0))
194                   (push (list (substring k 1) n f) action-submap)))
195               ;; We deal with backspace specially
196               (push (list (kbd "DEL")
197                           "Backup"
198                           (apply-partially #'notmuch-jump action-map prompt))
199                     action-submap)
200               (setq action-submap (nreverse action-submap))
201               (define-key map keystr
202                 `(lambda () (interactive)
203                    (setq notmuch-jump--action
204                          ',(apply-partially #'notmuch-jump action-submap new-prompt))
205                    (exit-minibuffer)))))))
206     map))
207
208 ;;
209
210 (provide 'notmuch-jump)
211
212 ;;; notmuch-jump.el ends here