configure: fix reference to possibly undefined $PKG_CONFIG_PATH
[notmuch] / emacs / notmuch-lib.el
1 ;;; notmuch-lib.el --- common variables, functions and function declarations
2 ;;
3 ;; Copyright © Carl Worth
4 ;;
5 ;; This file is part of Notmuch.
6 ;;
7 ;; Notmuch is free software: you can redistribute it and/or modify it
8 ;; under the terms of the GNU General Public License as published by
9 ;; the Free Software Foundation, either version 3 of the License, or
10 ;; (at your option) any later version.
11 ;;
12 ;; Notmuch is distributed in the hope that it will be useful, but
13 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
15 ;; General Public License for more details.
16 ;;
17 ;; You should have received a copy of the GNU General Public License
18 ;; along with Notmuch.  If not, see <https://www.gnu.org/licenses/>.
19 ;;
20 ;; Authors: Carl Worth <cworth@cworth.org>
21
22 ;; This is an part of an emacs-based interface to the notmuch mail system.
23
24 ;;; Code:
25
26 (require 'mm-util)
27 (require 'mm-view)
28 (require 'mm-decode)
29 (require 'cl)
30 (require 'notmuch-compat)
31
32 (unless (require 'notmuch-version nil t)
33   (defconst notmuch-emacs-version "unknown"
34     "Placeholder variable when notmuch-version.el[c] is not available."))
35
36 (autoload 'notmuch-jump-search "notmuch-jump"
37   "Jump to a saved search by shortcut key." t)
38
39 (defgroup notmuch nil
40   "Notmuch mail reader for Emacs."
41   :group 'mail)
42
43 (defgroup notmuch-hello nil
44   "Overview of saved searches, tags, etc."
45   :group 'notmuch)
46
47 (defgroup notmuch-search nil
48   "Searching and sorting mail."
49   :group 'notmuch)
50
51 (defgroup notmuch-show nil
52   "Showing messages and threads."
53   :group 'notmuch)
54
55 (defgroup notmuch-send nil
56   "Sending messages from Notmuch."
57   :group 'notmuch)
58
59 (custom-add-to-group 'notmuch-send 'message 'custom-group)
60
61 (defgroup notmuch-tag nil
62   "Tags and tagging in Notmuch."
63   :group 'notmuch)
64
65 (defgroup notmuch-crypto nil
66   "Processing and display of cryptographic MIME parts."
67   :group 'notmuch)
68
69 (defgroup notmuch-hooks nil
70   "Running custom code on well-defined occasions."
71   :group 'notmuch)
72
73 (defgroup notmuch-external nil
74   "Running external commands from within Notmuch."
75   :group 'notmuch)
76
77 (defgroup notmuch-address nil
78   "Address completion."
79   :group 'notmuch)
80
81 (defgroup notmuch-faces nil
82   "Graphical attributes for displaying text"
83   :group 'notmuch)
84
85 (defcustom notmuch-command "notmuch"
86   "Name of the notmuch binary.
87
88 This can be a relative or absolute path to the notmuch binary.
89 If this is a relative path, it will be searched for in all of the
90 directories given in `exec-path' (which is, by default, based on
91 $PATH)."
92   :type 'string
93   :group 'notmuch-external)
94
95 (defcustom notmuch-search-oldest-first t
96   "Show the oldest mail first when searching.
97
98 This variable defines the default sort order for displaying
99 search results. Note that any filtered searches created by
100 `notmuch-search-filter' retain the search order of the parent
101 search."
102   :type 'boolean
103   :group 'notmuch-search)
104
105 (defcustom notmuch-poll-script nil
106   "[Deprecated] Command to run to incorporate new mail into the notmuch database.
107
108 This option has been deprecated in favor of \"notmuch new\"
109 hooks (see man notmuch-hooks).  To change the path to the notmuch
110 binary, customize `notmuch-command'.
111
112 This variable controls the action invoked by
113 `notmuch-poll-and-refresh-this-buffer' (bound by default to 'G')
114 to incorporate new mail into the notmuch database.
115
116 If set to nil (the default), new mail is processed by invoking
117 \"notmuch new\". Otherwise, this should be set to a string that
118 gives the name of an external script that processes new mail. If
119 set to the empty string, no command will be run.
120
121 The external script could do any of the following depending on
122 the user's needs:
123
124 1. Invoke a program to transfer mail to the local mail store
125 2. Invoke \"notmuch new\" to incorporate the new mail
126 3. Invoke one or more \"notmuch tag\" commands to classify the mail"
127   :type '(choice (const :tag "notmuch new" nil)
128                  (const :tag "Disabled" "")
129                  (string :tag "Custom script"))
130   :group 'notmuch-external)
131
132 ;;
133
134 (defvar notmuch-search-history nil
135   "Variable to store notmuch searches history.")
136
137 (defcustom notmuch-archive-tags '("-inbox")
138   "List of tag changes to apply to a message or a thread when it is archived.
139
140 Tags starting with \"+\" (or not starting with either \"+\" or
141 \"-\") in the list will be added, and tags starting with \"-\"
142 will be removed from the message or thread being archived.
143
144 For example, if you wanted to remove an \"inbox\" tag and add an
145 \"archived\" tag, you would set:
146     (\"-inbox\" \"+archived\")"
147   :type '(repeat string)
148   :group 'notmuch-search
149   :group 'notmuch-show)
150
151 (defvar notmuch-common-keymap
152   (let ((map (make-sparse-keymap)))
153     (define-key map "?" 'notmuch-help)
154     (define-key map "q" 'notmuch-bury-or-kill-this-buffer)
155     (define-key map "s" 'notmuch-search)
156     (define-key map "z" 'notmuch-tree)
157     (define-key map "m" 'notmuch-mua-new-mail)
158     (define-key map "g" 'notmuch-refresh-this-buffer)
159     (define-key map "=" 'notmuch-refresh-this-buffer)
160     (define-key map (kbd "M-=") 'notmuch-refresh-all-buffers)
161     (define-key map "G" 'notmuch-poll-and-refresh-this-buffer)
162     (define-key map "j" 'notmuch-jump-search)
163     map)
164   "Keymap shared by all notmuch modes.")
165
166 ;; By default clicking on a button does not select the window
167 ;; containing the button (as opposed to clicking on a widget which
168 ;; does). This means that the button action is then executed in the
169 ;; current selected window which can cause problems if the button
170 ;; changes the buffer (e.g., id: links) or moves point.
171 ;;
172 ;; This provides a button type which overrides mouse-action so that
173 ;; the button's window is selected before the action is run. Other
174 ;; notmuch buttons can get the same behaviour by inheriting from this
175 ;; button type.
176 (define-button-type 'notmuch-button-type
177   'mouse-action (lambda (button)
178                   (select-window (posn-window (event-start last-input-event)))
179                   (button-activate button)))
180
181 (defun notmuch-command-to-string (&rest args)
182   "Synchronously invoke \"notmuch\" with the given list of arguments.
183
184 If notmuch exits with a non-zero status, output from the process
185 will appear in a buffer named \"*Notmuch errors*\" and an error
186 will be signaled.
187
188 Otherwise the output will be returned"
189   (with-temp-buffer
190     (let* ((status (apply #'call-process notmuch-command nil t nil args))
191            (output (buffer-string)))
192       (notmuch-check-exit-status status (cons notmuch-command args) output)
193       output)))
194
195 (defvar notmuch--cli-sane-p nil
196   "Cache whether the CLI seems to be configured sanely.")
197
198 (defun notmuch-cli-sane-p ()
199   "Return t if the cli seems to be configured sanely."
200   (unless notmuch--cli-sane-p
201     (let ((status (call-process notmuch-command nil nil nil
202                                 "config" "get" "user.primary_email")))
203       (setq notmuch--cli-sane-p (= status 0))))
204   notmuch--cli-sane-p)
205
206 (defun notmuch-assert-cli-sane ()
207   (unless (notmuch-cli-sane-p)
208     (notmuch-logged-error
209      "notmuch cli seems misconfigured or unconfigured."
210 "Perhaps you haven't run \"notmuch setup\" yet? Try running this
211 on the command line, and then retry your notmuch command")))
212
213 (defun notmuch-cli-version ()
214   "Return a string with the notmuch cli command version number."
215   (let ((long-string
216          ;; Trim off the trailing newline.
217          (substring (notmuch-command-to-string "--version") 0 -1)))
218     (if (string-match "^notmuch\\( version\\)? \\(.*\\)$"
219                       long-string)
220         (match-string 2 long-string)
221       "unknown")))
222
223 (defun notmuch-config-get (item)
224   "Return a value from the notmuch configuration."
225   (let* ((val (notmuch-command-to-string "config" "get" item))
226          (len (length val)))
227     ;; Trim off the trailing newline (if the value is empty or not
228     ;; configured, there will be no newline)
229     (if (and (> len 0) (= (aref val (- len 1)) ?\n))
230         (substring val 0 -1)
231       val)))
232
233 (defun notmuch-database-path ()
234   "Return the database.path value from the notmuch configuration."
235   (notmuch-config-get "database.path"))
236
237 (defun notmuch-user-name ()
238   "Return the user.name value from the notmuch configuration."
239   (notmuch-config-get "user.name"))
240
241 (defun notmuch-user-primary-email ()
242   "Return the user.primary_email value from the notmuch configuration."
243   (notmuch-config-get "user.primary_email"))
244
245 (defun notmuch-user-other-email ()
246   "Return the user.other_email value (as a list) from the notmuch configuration."
247   (split-string (notmuch-config-get "user.other_email") "\n" t))
248
249 (defun notmuch-user-emails ()
250   (cons (notmuch-user-primary-email) (notmuch-user-other-email)))
251
252 (defun notmuch-poll ()
253   "Run \"notmuch new\" or an external script to import mail.
254
255 Invokes `notmuch-poll-script', \"notmuch new\", or does nothing
256 depending on the value of `notmuch-poll-script'."
257   (interactive)
258   (if (stringp notmuch-poll-script)
259       (unless (string= notmuch-poll-script "")
260         (unless (equal (call-process notmuch-poll-script nil nil) 0)
261           (error "Notmuch: poll script `%s' failed!" notmuch-poll-script)))
262     (notmuch-call-notmuch-process "new")))
263
264 (defun notmuch-bury-or-kill-this-buffer ()
265   "Undisplay the current buffer.
266
267 Bury the current buffer, unless there is only one window showing
268 it, in which case it is killed."
269   (interactive)
270   (if (> (length (get-buffer-window-list nil nil t)) 1)
271       (bury-buffer)
272     (kill-buffer)))
273
274 (defun notmuch-documentation-first-line (symbol)
275   "Return the first line of the documentation string for SYMBOL."
276   (let ((doc (documentation symbol)))
277     (if doc
278         (with-temp-buffer
279           (insert (documentation symbol t))
280           (goto-char (point-min))
281           (let ((beg (point)))
282             (end-of-line)
283             (buffer-substring beg (point))))
284       "")))
285
286 (defun notmuch-prefix-key-description (key)
287   "Given a prefix key code, return a human-readable string representation.
288
289 This is basically just `format-kbd-macro' but we also convert ESC to M-."
290   (let* ((key-vector (if (vectorp key) key (vector key)))
291          (desc (format-kbd-macro key-vector)))
292     (if (string= desc "ESC")
293         "M-"
294       (concat desc " "))))
295
296
297 (defun notmuch-describe-key (actual-key binding prefix ua-keys tail)
298   "Prepend cons cells describing prefix-arg ACTUAL-KEY and ACTUAL-KEY to TAIL
299
300 It does not prepend if ACTUAL-KEY is already listed in TAIL."
301   (let ((key-string (concat prefix (key-description actual-key))))
302     ;; We don't include documentation if the key-binding is
303     ;; over-ridden. Note, over-riding a binding automatically hides the
304     ;; prefixed version too.
305     (unless (assoc key-string tail)
306       (when (and ua-keys (symbolp binding)
307                  (get binding 'notmuch-prefix-doc))
308         ;; Documentation for prefixed command
309         (let ((ua-desc (key-description ua-keys)))
310           (push (cons (concat ua-desc " " prefix (format-kbd-macro actual-key))
311                       (get binding 'notmuch-prefix-doc))
312                 tail)))
313       ;; Documentation for command
314       (push (cons key-string
315                   (or (and (symbolp binding) (get binding 'notmuch-doc))
316                       (and (functionp binding) (notmuch-documentation-first-line binding))))
317             tail)))
318     tail)
319
320 (defun notmuch-describe-remaps (remap-keymap ua-keys base-keymap prefix tail)
321   ;; Remappings are represented as a binding whose first "event" is
322   ;; 'remap.  Hence, if the keymap has any remappings, it will have a
323   ;; binding whose "key" is 'remap, and whose "binding" is itself a
324   ;; keymap that maps not from keys to commands, but from old (remapped)
325   ;; functions to the commands to use in their stead.
326   (map-keymap
327    (lambda (command binding)
328      (mapc
329       (lambda (actual-key)
330         (setq tail (notmuch-describe-key actual-key binding prefix ua-keys tail)))
331       (where-is-internal command base-keymap)))
332    remap-keymap)
333   tail)
334
335 (defun notmuch-describe-keymap (keymap ua-keys base-keymap &optional prefix tail)
336   "Return a list of cons cells, each describing one binding in KEYMAP.
337
338 Each cons cell consists of a string giving a human-readable
339 description of the key, and a one-line description of the bound
340 function.  See `notmuch-help' for an overview of how this
341 documentation is extracted.
342
343 UA-KEYS should be a key sequence bound to `universal-argument'.
344 It will be used to describe bindings of commands that support a
345 prefix argument.  PREFIX and TAIL are used internally."
346   (map-keymap
347    (lambda (key binding)
348      (cond ((mouse-event-p key) nil)
349            ((keymapp binding)
350             (setq tail
351                   (if (eq key 'remap)
352                       (notmuch-describe-remaps
353                        binding ua-keys base-keymap prefix tail)
354                     (notmuch-describe-keymap
355                      binding ua-keys base-keymap (notmuch-prefix-key-description key) tail))))
356            (binding
357             (setq tail (notmuch-describe-key (vector key) binding prefix ua-keys tail)))))
358    keymap)
359   tail)
360
361 (defun notmuch-substitute-command-keys (doc)
362   "Like `substitute-command-keys' but with documentation, not function names."
363   (let ((beg 0))
364     (while (string-match "\\\\{\\([^}[:space:]]*\\)}" doc beg)
365       (let ((desc
366              (save-match-data
367                (let* ((keymap-name (substring doc (match-beginning 1) (match-end 1)))
368                       (keymap (symbol-value (intern keymap-name)))
369                       (ua-keys (where-is-internal 'universal-argument keymap t))
370                       (desc-alist (notmuch-describe-keymap keymap ua-keys keymap))
371                       (desc-list (mapcar (lambda (arg) (concat (car arg) "\t" (cdr arg))) desc-alist)))
372                  (mapconcat #'identity desc-list "\n")))))
373         (setq doc (replace-match desc 1 1 doc)))
374       (setq beg (match-end 0)))
375     doc))
376
377 (defun notmuch-help ()
378   "Display help for the current notmuch mode.
379
380 This is similar to `describe-function' for the current major
381 mode, but bindings tables are shown with documentation strings
382 rather than command names.  By default, this uses the first line
383 of each command's documentation string.  A command can override
384 this by setting the 'notmuch-doc property of its command symbol.
385 A command that supports a prefix argument can explicitly document
386 its prefixed behavior by setting the 'notmuch-prefix-doc property
387 of its command symbol."
388   (interactive)
389   (let* ((mode major-mode)
390          (doc (substitute-command-keys (notmuch-substitute-command-keys (documentation mode t)))))
391     (with-current-buffer (generate-new-buffer "*notmuch-help*")
392       (insert doc)
393       (goto-char (point-min))
394       (set-buffer-modified-p nil)
395       (view-buffer (current-buffer) 'kill-buffer-if-not-modified))))
396
397 (defun notmuch-subkeymap-help ()
398   "Show help for a subkeymap."
399   (interactive)
400   (let* ((key (this-command-keys-vector))
401         (prefix (make-vector (1- (length key)) nil))
402         (i 0))
403     (while (< i (length prefix))
404       (aset prefix i (aref key i))
405       (setq i (1+ i)))
406
407     (let* ((subkeymap (key-binding prefix))
408            (ua-keys (where-is-internal 'universal-argument nil t))
409            (prefix-string (notmuch-prefix-key-description prefix))
410            (desc-alist (notmuch-describe-keymap subkeymap ua-keys subkeymap prefix-string))
411            (desc-list (mapcar (lambda (arg) (concat (car arg) "\t" (cdr arg))) desc-alist))
412            (desc (mapconcat #'identity desc-list "\n")))
413       (with-help-window (help-buffer)
414         (with-current-buffer standard-output
415           (insert "\nPress 'q' to quit this window.\n\n")
416           (insert desc)))
417       (pop-to-buffer (help-buffer)))))
418
419 (defvar notmuch-buffer-refresh-function nil
420   "Function to call to refresh the current buffer.")
421 (make-variable-buffer-local 'notmuch-buffer-refresh-function)
422
423 (defun notmuch-refresh-this-buffer ()
424   "Refresh the current buffer."
425   (interactive)
426   (when notmuch-buffer-refresh-function
427     ;; Pass prefix argument, etc.
428     (call-interactively notmuch-buffer-refresh-function)))
429
430 (defun notmuch-poll-and-refresh-this-buffer ()
431   "Invoke `notmuch-poll' to import mail, then refresh the current buffer."
432   (interactive)
433   (notmuch-poll)
434   (notmuch-refresh-this-buffer))
435
436 (defun notmuch-refresh-all-buffers ()
437   "Invoke `notmuch-refresh-this-buffer' on all notmuch major-mode buffers.
438
439 The buffers are silently refreshed, i.e. they are not forced to
440 be displayed."
441   (interactive)
442   (dolist (buffer (buffer-list))
443     (let ((buffer-mode (buffer-local-value 'major-mode buffer)))
444       (when (memq buffer-mode '(notmuch-show-mode
445                                 notmuch-tree-mode
446                                 notmuch-search-mode
447                                 notmuch-hello-mode))
448         (with-current-buffer buffer
449           (notmuch-refresh-this-buffer))))))
450
451 (defun notmuch-prettify-subject (subject)
452   ;; This function is used by `notmuch-search-process-filter' which
453   ;; requires that we not disrupt its' matching state.
454   (save-match-data
455     (if (and subject
456              (string-match "^[ \t]*$" subject))
457         "[No Subject]"
458       subject)))
459
460 (defun notmuch-sanitize (str)
461   "Sanitize control character in STR.
462
463 This includes newlines, tabs, and other funny characters."
464   (replace-regexp-in-string "[[:cntrl:]\x7f\u2028\u2029]+" " " str))
465
466 (defun notmuch-escape-boolean-term (term)
467   "Escape a boolean term for use in a query.
468
469 The caller is responsible for prepending the term prefix and a
470 colon.  This performs minimal escaping in order to produce
471 user-friendly queries."
472
473   (save-match-data
474     (if (or (equal term "")
475             ;; To be pessimistic, only pass through terms composed
476             ;; entirely of ASCII printing characters other than ", (,
477             ;; and ).
478             (string-match "[^!#-'*-~]" term))
479         ;; Requires escaping
480         (concat "\"" (replace-regexp-in-string "\"" "\"\"" term t t) "\"")
481       term)))
482
483 (defun notmuch-id-to-query (id)
484   "Return a query that matches the message with id ID."
485   (concat "id:" (notmuch-escape-boolean-term id)))
486
487 (defun notmuch-hex-encode (str)
488   "Hex-encode STR (e.g., as used by batch tagging).
489
490 This replaces spaces, percents, and double quotes in STR with
491 %NN where NN is the hexadecimal value of the character."
492   (replace-regexp-in-string
493    "[ %\"]" (lambda (match) (format "%%%02x" (aref match 0))) str))
494
495 ;;
496
497 (defun notmuch-common-do-stash (text)
498   "Common function to stash text in kill ring, and display in minibuffer."
499   (if text
500       (progn
501         (kill-new text)
502         (message "Stashed: %s" text))
503     ;; There is nothing to stash so stash an empty string so the user
504     ;; doesn't accidentally paste something else somewhere.
505     (kill-new "")
506     (message "Nothing to stash!")))
507
508 ;;
509
510 (defun notmuch-remove-if-not (predicate list)
511   "Return a copy of LIST with all items not satisfying PREDICATE removed."
512   (let (out)
513     (while list
514       (when (funcall predicate (car list))
515         (push (car list) out))
516       (setq list (cdr list)))
517     (nreverse out)))
518
519 (defun notmuch-plist-delete (plist property)
520   (let* ((xplist (cons nil plist))
521          (pred xplist))
522     (while (cdr pred)
523       (when (eq (cadr pred) property)
524         (setcdr pred (cdddr pred)))
525       (setq pred (cddr pred)))
526     (cdr xplist)))
527
528 (defun notmuch-split-content-type (content-type)
529   "Split content/type into 'content' and 'type'"
530   (split-string content-type "/"))
531
532 (defun notmuch-match-content-type (t1 t2)
533   "Return t if t1 and t2 are matching content types, taking wildcards into account"
534   (let ((st1 (notmuch-split-content-type t1))
535         (st2 (notmuch-split-content-type t2)))
536     (if (or (string= (cadr st1) "*")
537             (string= (cadr st2) "*"))
538         ;; Comparison of content types should be case insensitive.
539         (string= (downcase (car st1)) (downcase (car st2)))
540       (string= (downcase t1) (downcase t2)))))
541
542 (defvar notmuch-multipart/alternative-discouraged
543   '(
544     ;; Avoid HTML parts.
545     "text/html"
546     ;; multipart/related usually contain a text/html part and some associated graphics.
547     "multipart/related"
548     ))
549
550 (defun notmuch-multipart/alternative-determine-discouraged (msg)
551   "Return the discouraged alternatives for the specified message."
552   ;; If a function, return the result of calling it.
553   (if (functionp notmuch-multipart/alternative-discouraged)
554       (funcall notmuch-multipart/alternative-discouraged msg)
555     ;; Otherwise simply return the value of the variable, which is
556     ;; assumed to be a list of discouraged alternatives. This is the
557     ;; default behaviour.
558     notmuch-multipart/alternative-discouraged))
559
560 (defun notmuch-multipart/alternative-choose (msg types)
561   "Return a list of preferred types from the given list of types
562 for this message, if present."
563   ;; Based on `mm-preferred-alternative-precedence'.
564   (let ((discouraged (notmuch-multipart/alternative-determine-discouraged msg))
565         (seq types))
566     (dolist (pref (reverse discouraged))
567       (dolist (elem (copy-sequence seq))
568         (when (string-match pref elem)
569           (setq seq (nconc (delete elem seq) (list elem))))))
570     seq))
571
572 (defun notmuch-parts-filter-by-type (parts type)
573   "Given a list of message parts, return a list containing the ones matching
574 the given type."
575   (remove-if-not
576    (lambda (part) (notmuch-match-content-type (plist-get part :content-type) type))
577    parts))
578
579 (defun notmuch--get-bodypart-raw (msg part process-crypto binaryp cache)
580   (let* ((plist-elem (if binaryp :content-binary :content))
581          (data (or (plist-get part plist-elem)
582                    (with-temp-buffer
583                      ;; Emacs internally uses a UTF-8-like multibyte string
584                      ;; representation by default (regardless of the coding
585                      ;; system, which only affects how it goes from outside data
586                      ;; to this internal representation).  This *almost* never
587                      ;; matters.  Annoyingly, it does matter if we use this data
588                      ;; in an image descriptor, since Emacs will use its internal
589                      ;; data buffer directly and this multibyte representation
590                      ;; corrupts binary image formats.  Since the caller is
591                      ;; asking for binary data, a unibyte string is a more
592                      ;; appropriate representation anyway.
593                      (when binaryp
594                        (set-buffer-multibyte nil))
595                      (let ((args `("show" "--format=raw"
596                                    ,(format "--part=%s" (plist-get part :id))
597                                    ,@(when process-crypto '("--decrypt=true"))
598                                    ,(notmuch-id-to-query (plist-get msg :id))))
599                            (coding-system-for-read
600                             (if binaryp 'no-conversion
601                               (let ((coding-system (mm-charset-to-coding-system
602                                                     (plist-get part :content-charset))))
603                                 ;; Sadly,
604                                 ;; `mm-charset-to-coding-system' seems
605                                 ;; to return things that are not
606                                 ;; considered acceptable values for
607                                 ;; `coding-system-for-read'.
608                                 (if (coding-system-p coding-system)
609                                     coding-system
610                                   ;; RFC 2047 says that the default
611                                   ;; charset is US-ASCII. RFC6657
612                                   ;; complicates this somewhat.
613                                   'us-ascii)))))
614                        (apply #'call-process notmuch-command nil '(t nil) nil args)
615                        (buffer-string))))))
616     (when (and cache data)
617       (plist-put part plist-elem data))
618     data))
619
620 (defun notmuch-get-bodypart-binary (msg part process-crypto &optional cache)
621   "Return the unprocessed content of PART in MSG as a unibyte string.
622
623 This returns the \"raw\" content of the given part after content
624 transfer decoding, but with no further processing (see the
625 discussion of --format=raw in man notmuch-show).  In particular,
626 this does no charset conversion.
627
628 If CACHE is non-nil, the content of this part will be saved in
629 MSG (if it isn't already)."
630   (notmuch--get-bodypart-raw msg part process-crypto t cache))
631
632 (defun notmuch-get-bodypart-text (msg part process-crypto &optional cache)
633   "Return the text content of PART in MSG.
634
635 This returns the content of the given part as a multibyte Lisp
636 string after performing content transfer decoding and any
637 necessary charset decoding.
638
639 If CACHE is non-nil, the content of this part will be saved in
640 MSG (if it isn't already)."
641   (notmuch--get-bodypart-raw msg part process-crypto nil cache))
642
643 ;; Workaround: The call to `mm-display-part' below triggers a bug in
644 ;; Emacs 24 if it attempts to use the shr renderer to display an HTML
645 ;; part with images in it (demonstrated in 24.1 and 24.2 on Debian and
646 ;; Fedora 17, though unreproducable in other configurations).
647 ;; `mm-shr' references the variable `gnus-inhibit-images' without
648 ;; first loading gnus-art, which defines it, resulting in a
649 ;; void-variable error.  Hence, we advise `mm-shr' to ensure gnus-art
650 ;; is loaded.
651 (if (>= emacs-major-version 24)
652     (defadvice mm-shr (before load-gnus-arts activate)
653       (require 'gnus-art nil t)
654       (ad-disable-advice 'mm-shr 'before 'load-gnus-arts)
655       (ad-activate 'mm-shr)))
656
657 (defun notmuch-mm-display-part-inline (msg part content-type process-crypto)
658   "Use the mm-decode/mm-view functions to display a part in the
659 current buffer, if possible."
660   (let ((display-buffer (current-buffer)))
661     (with-temp-buffer
662       ;; In case we already have :content, use it and tell mm-* that
663       ;; it's already been charset-decoded by using the fake
664       ;; `gnus-decoded' charset.  Otherwise, we'll fetch the binary
665       ;; part content and let mm-* decode it.
666       (let* ((have-content (plist-member part :content))
667              (charset (if have-content 'gnus-decoded
668                         (plist-get part :content-charset)))
669              (handle (mm-make-handle (current-buffer) `(,content-type (charset . ,charset)))))
670         ;; If the user wants the part inlined, insert the content and
671         ;; test whether we are able to inline it (which includes both
672         ;; capability and suitability tests).
673         (when (mm-inlined-p handle)
674           (if have-content
675               (insert (notmuch-get-bodypart-text msg part process-crypto))
676             (insert (notmuch-get-bodypart-binary msg part process-crypto)))
677           (when (mm-inlinable-p handle)
678             (set-buffer display-buffer)
679             (mm-display-part handle)
680             t))))))
681
682 ;; Converts a plist of headers to an alist of headers. The input plist should
683 ;; have symbols of the form :Header as keys, and the resulting alist will have
684 ;; symbols of the form 'Header as keys.
685 (defun notmuch-headers-plist-to-alist (plist)
686   (loop for (key value . rest) on plist by #'cddr
687         collect (cons (intern (substring (symbol-name key) 1)) value)))
688
689 (defun notmuch-face-ensure-list-form (face)
690   "Return FACE in face list form.
691
692 If FACE is already a face list, it will be returned as-is.  If
693 FACE is a face name or face plist, it will be returned as a
694 single element face list."
695   (if (and (listp face) (not (keywordp (car face))))
696       face
697     (list face)))
698
699 (defun notmuch-apply-face (object face &optional below start end)
700   "Combine FACE into the 'face text property of OBJECT between START and END.
701
702 This function combines FACE with any existing faces between START
703 and END in OBJECT.  Attributes specified by FACE take precedence
704 over existing attributes unless BELOW is non-nil.
705
706 OBJECT may be a string, a buffer, or nil (which means the current
707 buffer).  If object is a string, START and END are 0-based;
708 otherwise they are buffer positions (integers or markers).  FACE
709 must be a face name (a symbol or string), a property list of face
710 attributes, or a list of these.  If START and/or END are omitted,
711 they default to the beginning/end of OBJECT.  For convenience
712 when applied to strings, this returns OBJECT."
713
714   ;; A face property can have three forms: a face name (a string or
715   ;; symbol), a property list, or a list of these two forms.  In the
716   ;; list case, the faces will be combined, with the earlier faces
717   ;; taking precedent.  Here we canonicalize everything to list form
718   ;; to make it easy to combine.
719   (let ((pos (cond (start start)
720                    ((stringp object) 0)
721                    (t 1)))
722         (end (cond (end end)
723                    ((stringp object) (length object))
724                    (t (1+ (buffer-size object)))))
725         (face-list (notmuch-face-ensure-list-form face)))
726     (while (< pos end)
727       (let* ((cur (get-text-property pos 'face object))
728              (cur-list (notmuch-face-ensure-list-form cur))
729              (new (cond ((null cur-list) face)
730                         (below (append cur-list face-list))
731                         (t (append face-list cur-list))))
732              (next (next-single-property-change pos 'face object end)))
733         (put-text-property pos next 'face new object)
734         (setq pos next))))
735   object)
736
737 (defun notmuch-map-text-property (start end prop func &optional object)
738   "Transform text property PROP using FUNC.
739
740 Applies FUNC to each distinct value of the text property PROP
741 between START and END of OBJECT, setting PROP to the value
742 returned by FUNC."
743   (while (< start end)
744     (let ((value (get-text-property start prop object))
745           (next (next-single-property-change start prop object end)))
746       (put-text-property start next prop (funcall func value) object)
747       (setq start next))))
748
749 (defun notmuch-logged-error (msg &optional extra)
750   "Log MSG and EXTRA to *Notmuch errors* and signal MSG.
751
752 This logs MSG and EXTRA to the *Notmuch errors* buffer and
753 signals MSG as an error.  If EXTRA is non-nil, text referring the
754 user to the *Notmuch errors* buffer will be appended to the
755 signaled error.  This function does not return."
756
757   (with-current-buffer (get-buffer-create "*Notmuch errors*")
758     (goto-char (point-max))
759     (unless (bobp)
760       (newline))
761     (save-excursion
762       (insert "[" (current-time-string) "]\n" msg)
763       (unless (bolp)
764         (newline))
765       (when extra
766         (insert extra)
767         (unless (bolp)
768           (newline)))))
769   (error "%s" (concat msg (when extra
770                             " (see *Notmuch errors* for more details)"))))
771
772 (defun notmuch-check-async-exit-status (proc msg &optional command err)
773   "If PROC exited abnormally, pop up an error buffer and signal an error.
774
775 This is a wrapper around `notmuch-check-exit-status' for
776 asynchronous process sentinels.  PROC and MSG must be the
777 arguments passed to the sentinel.  COMMAND and ERR, if provided,
778 are passed to `notmuch-check-exit-status'.  If COMMAND is not
779 provided, it is taken from `process-command'."
780   (let ((exit-status
781          (case (process-status proc)
782            ((exit) (process-exit-status proc))
783            ((signal) msg))))
784     (when exit-status
785       (notmuch-check-exit-status exit-status (or command (process-command proc))
786                                  nil err))))
787
788 (defun notmuch-check-exit-status (exit-status command &optional output err)
789   "If EXIT-STATUS is non-zero, pop up an error buffer and signal an error.
790
791 If EXIT-STATUS is non-zero, pop up a notmuch error buffer
792 describing the error and signal an Elisp error.  EXIT-STATUS must
793 be a number indicating the exit status code of a process or a
794 string describing the signal that terminated the process (such as
795 returned by `call-process').  COMMAND must be a list giving the
796 command and its arguments.  OUTPUT, if provided, is a string
797 giving the output of command.  ERR, if provided, is the error
798 output of command.  OUTPUT and ERR will be included in the error
799 message."
800
801   (cond
802    ((eq exit-status 0) t)
803    ((eq exit-status 20)
804     (notmuch-logged-error "notmuch CLI version mismatch
805 Emacs requested an older output format than supported by the notmuch CLI.
806 You may need to restart Emacs or upgrade your notmuch Emacs package."))
807    ((eq exit-status 21)
808     (notmuch-logged-error "notmuch CLI version mismatch
809 Emacs requested a newer output format than supported by the notmuch CLI.
810 You may need to restart Emacs or upgrade your notmuch package."))
811    (t
812     (let* ((command-string
813             (mapconcat (lambda (arg)
814                          (shell-quote-argument
815                           (cond ((stringp arg) arg)
816                                 ((symbolp arg) (symbol-name arg))
817                                 (t "*UNKNOWN ARGUMENT*"))))
818                        command " "))
819            (extra
820             (concat "command: " command-string "\n"
821              (if (integerp exit-status)
822                  (format "exit status: %s\n" exit-status)
823                (format "exit signal: %s\n" exit-status))
824              (when err
825                (concat "stderr:\n" err))
826              (when output
827                (concat "stdout:\n" output)))))
828         (if err
829             ;; We have an error message straight from the CLI.
830             (notmuch-logged-error
831              (replace-regexp-in-string "[ \n\r\t\f]*\\'" "" err) extra)
832           ;; We only have combined output from the CLI; don't inundate
833           ;; the user with it.  Mimic `process-lines'.
834           (notmuch-logged-error (format "%s exited with status %s"
835                                         (car command) exit-status)
836                                 extra))
837         ;; `notmuch-logged-error' does not return.
838         ))))
839
840 (defun notmuch-call-notmuch--helper (destination args)
841   "Helper for synchronous notmuch invocation commands.
842
843 This wraps `call-process'.  DESTINATION has the same meaning as
844 for `call-process'.  ARGS is as described for
845 `notmuch-call-notmuch-process'."
846
847   (let (stdin-string)
848     (while (keywordp (car args))
849       (case (car args)
850         (:stdin-string (setq stdin-string (cadr args)
851                              args (cddr args)))
852         (otherwise
853          (error "Unknown keyword argument: %s" (car args)))))
854     (if (null stdin-string)
855         (apply #'call-process notmuch-command nil destination nil args)
856       (insert stdin-string)
857       (apply #'call-process-region (point-min) (point-max)
858              notmuch-command t destination nil args))))
859
860 (defun notmuch-call-notmuch-process (&rest args)
861   "Synchronously invoke `notmuch-command' with ARGS.
862
863 The caller may provide keyword arguments before ARGS.  Currently
864 supported keyword arguments are:
865
866   :stdin-string STRING - Write STRING to stdin
867
868 If notmuch exits with a non-zero status, output from the process
869 will appear in a buffer named \"*Notmuch errors*\" and an error
870 will be signaled."
871   (with-temp-buffer
872     (let ((status (notmuch-call-notmuch--helper t args)))
873       (notmuch-check-exit-status status (cons notmuch-command args)
874                                  (buffer-string)))))
875
876 (defun notmuch-call-notmuch-sexp (&rest args)
877   "Invoke `notmuch-command' with ARGS and return the parsed S-exp output.
878
879 This is equivalent to `notmuch-call-notmuch-process', but parses
880 notmuch's output as an S-expression and returns the parsed value.
881 Like `notmuch-call-notmuch-process', if notmuch exits with a
882 non-zero status, this will report its output and signal an
883 error."
884
885   (with-temp-buffer
886     (let ((err-file (make-temp-file "nmerr")))
887       (unwind-protect
888           (let ((status (notmuch-call-notmuch--helper (list t err-file) args))
889                 (err (with-temp-buffer
890                        (insert-file-contents err-file)
891                        (unless (eobp)
892                          (buffer-string)))))
893             (notmuch-check-exit-status status (cons notmuch-command args)
894                                        (buffer-string) err)
895             (goto-char (point-min))
896             (read (current-buffer)))
897         (delete-file err-file)))))
898
899 (defun notmuch-start-notmuch (name buffer sentinel &rest args)
900   "Start and return an asynchronous notmuch command.
901
902 This starts and returns an asynchronous process running
903 `notmuch-command' with ARGS.  The exit status is checked via
904 `notmuch-check-async-exit-status'.  Output written to stderr is
905 redirected and displayed when the process exits (even if the
906 process exits successfully).  NAME and BUFFER are the same as in
907 `start-process'.  SENTINEL is a process sentinel function to call
908 when the process exits, or nil for none.  The caller must *not*
909 invoke `set-process-sentinel' directly on the returned process,
910 as that will interfere with the handling of stderr and the exit
911 status."
912
913   (let (err-file err-buffer proc err-proc
914         ;; Find notmuch using Emacs' `exec-path'
915         (command (or (executable-find notmuch-command)
916                      (error "Command not found: %s" notmuch-command))))
917     (if (fboundp 'make-process)
918         (progn
919           (setq err-buffer (generate-new-buffer " *notmuch-stderr*"))
920           ;; Emacs 25 and newer has `make-process', which allows
921           ;; redirecting stderr independently from stdout to a
922           ;; separate buffer. As this allows us to avoid using a
923           ;; temporary file and shell invocation, use it when
924           ;; available.
925           (setq proc (make-process
926                       :name name
927                       :buffer buffer
928                       :command (cons command args)
929                       :connection-type 'pipe
930                       :stderr err-buffer)
931                 err-proc (get-buffer-process err-buffer))
932           (process-put proc 'err-buffer err-buffer)
933
934           (process-put err-proc 'err-file err-file)
935           (process-put err-proc 'err-buffer err-buffer)
936           (set-process-sentinel err-proc #'notmuch-start-notmuch-error-sentinel))
937
938       ;; On Emacs versions before 25, there is no way to capture
939       ;; stdout and stderr separately for asynchronous processes, or
940       ;; even to redirect stderr to a file, so we use a trivial shell
941       ;; wrapper to send stderr to a temporary file and clean things
942       ;; up in the sentinel.
943       (setq err-file (make-temp-file "nmerr"))
944       (let ((process-connection-type nil)) ;; Use a pipe
945         (setq proc (apply #'start-process name buffer
946                           "/bin/sh" "-c"
947                           "exec 2>\"$1\"; shift; exec \"$0\" \"$@\""
948                           command err-file args)))
949       (process-put proc 'err-file err-file))
950
951     (process-put proc 'sub-sentinel sentinel)
952     (process-put proc 'real-command (cons notmuch-command args))
953     (set-process-sentinel proc #'notmuch-start-notmuch-sentinel)
954     proc))
955
956 (defun notmuch-start-notmuch-sentinel (proc event)
957   "Process sentinel function used by `notmuch-start-notmuch'."
958   (let* ((err-file (process-get proc 'err-file))
959          (err-buffer (or (process-get proc 'err-buffer)
960                          (find-file-noselect err-file)))
961          (err (when (not (zerop (buffer-size err-buffer)))
962                 (with-current-buffer err-buffer (buffer-string))))
963          (sub-sentinel (process-get proc 'sub-sentinel))
964          (real-command (process-get proc 'real-command)))
965     (condition-case err
966         (progn
967           ;; Invoke the sub-sentinel, if any
968           (when sub-sentinel
969             (funcall sub-sentinel proc event))
970           ;; Check the exit status.  This will signal an error if the
971           ;; exit status is non-zero.  Don't do this if the process
972           ;; buffer is dead since that means Emacs killed the process
973           ;; and there's no point in telling the user that (but we
974           ;; still check for and report stderr output below).
975           (when (buffer-live-p (process-buffer proc))
976             (notmuch-check-async-exit-status proc event real-command err))
977           ;; If that didn't signal an error, then any error output was
978           ;; really warning output.  Show warnings, if any.
979           (let ((warnings
980                  (when err
981                    (with-current-buffer err-buffer
982                      (goto-char (point-min))
983                      (end-of-line)
984                      ;; Show first line; stuff remaining lines in the
985                      ;; errors buffer.
986                      (let ((l1 (buffer-substring (point-min) (point))))
987                        (skip-chars-forward "\n")
988                        (cons l1 (unless (eobp)
989                                   (buffer-substring (point) (point-max)))))))))
990             (when warnings
991               (notmuch-logged-error (car warnings) (cdr warnings)))))
992       (error
993        ;; Emacs behaves strangely if an error escapes from a sentinel,
994        ;; so turn errors into messages.
995        (message "%s" (error-message-string err))))
996     (when err-file (ignore-errors (delete-file err-file)))))
997
998 (defun notmuch-start-notmuch-error-sentinel (proc event)
999   (let* ((err-file (process-get proc 'err-file))
1000          ;; When `make-process' is available, use the error buffer
1001          ;; associated with the process, otherwise the error file.
1002          (err-buffer (or (process-get proc 'err-buffer)
1003                          (find-file-noselect err-file))))
1004     (when err-buffer (kill-buffer err-buffer))))
1005
1006 ;; This variable is used only buffer local, but it needs to be
1007 ;; declared globally first to avoid compiler warnings.
1008 (defvar notmuch-show-process-crypto nil)
1009 (make-variable-buffer-local 'notmuch-show-process-crypto)
1010
1011 (defun notmuch-interactive-region ()
1012   "Return the bounds of the current interactive region.
1013
1014 This returns (BEG END), where BEG and END are the bounds of the
1015 region if the region is active, or both `point' otherwise."
1016   (if (region-active-p)
1017       (list (region-beginning) (region-end))
1018     (list (point) (point))))
1019
1020 (define-obsolete-function-alias
1021     'notmuch-search-interactive-region
1022     'notmuch-interactive-region
1023   "notmuch 0.29")
1024
1025 (provide 'notmuch-lib)
1026
1027 ;; Local Variables:
1028 ;; byte-compile-warnings: (not cl-functions)
1029 ;; End:
1030
1031 ;;; notmuch-lib.el ends here