try-emacs-mua: Trim `require' advice for Emacs 25
[notmuch] / emacs / notmuch-mua.el
1 ;;; notmuch-mua.el --- emacs style mail-user-agent
2 ;;
3 ;; Copyright © David Edmondson
4 ;;
5 ;; This file is part of Notmuch.
6 ;;
7 ;; Notmuch is free software: you can redistribute it and/or modify it
8 ;; under the terms of the GNU General Public License as published by
9 ;; the Free Software Foundation, either version 3 of the License, or
10 ;; (at your option) any later version.
11 ;;
12 ;; Notmuch is distributed in the hope that it will be useful, but
13 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
15 ;; General Public License for more details.
16 ;;
17 ;; You should have received a copy of the GNU General Public License
18 ;; along with Notmuch.  If not, see <https://www.gnu.org/licenses/>.
19 ;;
20 ;; Authors: David Edmondson <dme@dme.org>
21
22 ;;; Code:
23
24 (eval-when-compile (require 'cl-lib))
25
26 (require 'message)
27 (require 'mm-view)
28 (require 'format-spec)
29
30 (require 'notmuch-lib)
31 (require 'notmuch-address)
32 (require 'notmuch-draft)
33 (require 'notmuch-message)
34
35 (declare-function notmuch-show-insert-body "notmuch-show" (msg body depth))
36 (declare-function notmuch-fcc-header-setup "notmuch-maildir-fcc" ())
37 (declare-function notmuch-maildir-message-do-fcc "notmuch-maildir-fcc" ())
38 (declare-function notmuch-draft-postpone "notmuch-draft" ())
39 (declare-function notmuch-draft-save "notmuch-draft" ())
40
41 ;;
42
43 (defcustom notmuch-mua-send-hook '(notmuch-mua-message-send-hook)
44   "Hook run before sending messages."
45   :type 'hook
46   :group 'notmuch-send
47   :group 'notmuch-hooks)
48
49 (defcustom notmuch-mua-compose-in 'current-window
50   (concat
51    "Where to create the mail buffer used to compose a new message.
52 Possible values are `current-window' (default), `new-window' and
53 `new-frame'. If set to `current-window', the mail buffer will be
54 displayed in the current window, so the old buffer will be
55 restored when the mail buffer is killed. If set to `new-window'
56 or `new-frame', the mail buffer will be displayed in a new
57 window/frame that will be destroyed when the buffer is killed.
58 You may want to customize `message-kill-buffer-on-exit'
59 accordingly."
60    (when (< emacs-major-version 24)
61            " Due to a known bug in Emacs 23, you should not set
62 this to `new-window' if `message-kill-buffer-on-exit' is
63 disabled: this would result in an incorrect behavior."))
64   :group 'notmuch-send
65   :type '(choice (const :tag "Compose in the current window" current-window)
66                  (const :tag "Compose mail in a new window"  new-window)
67                  (const :tag "Compose mail in a new frame"   new-frame)))
68
69 (defcustom notmuch-mua-user-agent-function nil
70   "Function used to generate a `User-Agent:' string. If this is
71 `nil' then no `User-Agent:' will be generated."
72   :type '(choice (const :tag "No user agent string" nil)
73                  (const :tag "Full" notmuch-mua-user-agent-full)
74                  (const :tag "Notmuch" notmuch-mua-user-agent-notmuch)
75                  (const :tag "Emacs" notmuch-mua-user-agent-emacs)
76                  (function :tag "Custom user agent function"
77                            :value notmuch-mua-user-agent-full))
78   :group 'notmuch-send)
79
80 (defcustom notmuch-mua-hidden-headers nil
81   "Headers that are added to the `message-mode' hidden headers
82 list."
83   :type '(repeat string)
84   :group 'notmuch-send)
85
86 (defgroup notmuch-reply nil
87   "Replying to messages in notmuch"
88   :group 'notmuch)
89
90 (defcustom notmuch-mua-cite-function 'message-cite-original
91   "*Function for citing an original message.
92 Predefined functions include `message-cite-original' and
93 `message-cite-original-without-signature'.
94 Note that these functions use `mail-citation-hook' if that is non-nil."
95   :type '(radio (function-item message-cite-original)
96                 (function-item message-cite-original-without-signature)
97                 (function-item sc-cite-original)
98                 (function :tag "Other"))
99   :link '(custom-manual "(message)Insertion Variables")
100   :group 'notmuch-reply)
101
102 (defcustom notmuch-mua-reply-insert-header-p-function
103   'notmuch-show-reply-insert-header-p-never
104   "Function to decide which parts get a header when replying.
105
106 This function specifies which parts of a mime message with
107 multiple parts get a header."
108   :type '(radio (const :tag "No part headers"
109                                notmuch-show-reply-insert-header-p-never)
110                 (const :tag "All except multipart/* and hidden parts"
111                                notmuch-show-reply-insert-header-p-trimmed)
112                 (const :tag "Only for included text parts"
113                                notmuch-show-reply-insert-header-p-minimal)
114                 (const :tag "Exactly as in show view"
115                                notmuch-show-insert-header-p)
116                 (function :tag "Other"))
117   :group 'notmuch-reply)
118
119 (defcustom notmuch-mua-attachment-regexp
120   "\\b\\(attache\?ment\\|attached\\|attach\\|pi[èe]ce\s+jointe?\\)\\b"
121   "Message body text indicating that an attachment is expected.
122
123 This is not used unless `notmuch-mua-attachment-check' is added
124 to `notmuch-mua-send-hook'."
125   :type 'regexp
126   :group 'notmuch-send)
127
128 ;;
129
130 (defun notmuch-mua-attachment-check ()
131   "Signal an error if the message text indicates that an
132 attachment is expected but no MML referencing an attachment is
133 found.
134
135 Typically this is added to `notmuch-mua-send-hook'."
136   (when (and
137          ;; When the message mentions attachment...
138          (save-excursion
139            (message-goto-body)
140            ;; Limit search from reaching other possible parts of the message
141            (let ((search-limit (search-forward "\n<#" nil t)))
142              (message-goto-body)
143              (cl-loop while (re-search-forward notmuch-mua-attachment-regexp
144                                                search-limit t)
145                       ;; For every instance of the "attachment" string
146                       ;; found, examine the text properties. If the text
147                       ;; has either a `face' or `syntax-table' property
148                       ;; then it is quoted text and should *not* cause the
149                       ;; user to be asked about a missing attachment.
150                       if (let ((props (text-properties-at (match-beginning 0))))
151                            (not (or (memq 'syntax-table props)
152                                     (memq 'face props))))
153                       return t
154                       finally return nil)))
155          ;; ...but doesn't have a part with a filename...
156          (save-excursion
157            (message-goto-body)
158            (not (re-search-forward "^<#part [^>]*filename=" nil t)))
159          ;; ...and that's not okay...
160          (not (y-or-n-p "Attachment mentioned, but no attachment - is that okay?")))
161     ;; ...signal an error.
162     (error "Missing attachment")))
163
164 (defun notmuch-mua-get-switch-function ()
165   "Get a switch function according to `notmuch-mua-compose-in'."
166   (cond ((eq notmuch-mua-compose-in 'current-window)
167          'switch-to-buffer)
168         ((eq notmuch-mua-compose-in 'new-window)
169          'switch-to-buffer-other-window)
170         ((eq notmuch-mua-compose-in 'new-frame)
171          'switch-to-buffer-other-frame)
172         (t (error "Invalid value for `notmuch-mua-compose-in'"))))
173
174 (defun notmuch-mua-maybe-set-window-dedicated ()
175   "Set the selected window as dedicated according to
176 `notmuch-mua-compose-in'."
177   (when (or (eq notmuch-mua-compose-in 'new-frame)
178             (eq notmuch-mua-compose-in 'new-window))
179     (set-window-dedicated-p (selected-window) t)))
180
181 (defun notmuch-mua-user-agent-full ()
182   "Generate a `User-Agent:' string suitable for notmuch."
183   (concat (notmuch-mua-user-agent-notmuch)
184           " "
185           (notmuch-mua-user-agent-emacs)))
186
187 (defun notmuch-mua-user-agent-notmuch ()
188   "Generate a `User-Agent:' string suitable for notmuch."
189   (let ((notmuch-version (if (string= notmuch-emacs-version "unknown")
190                              (notmuch-cli-version)
191                            notmuch-emacs-version)))
192     (concat "Notmuch/" notmuch-version " (https://notmuchmail.org)")))
193
194 (defun notmuch-mua-user-agent-emacs ()
195   "Generate a `User-Agent:' string suitable for notmuch."
196   (concat "Emacs/" emacs-version " (" system-configuration ")"))
197
198 (defun notmuch-mua-add-more-hidden-headers ()
199   "Add some headers to the list that are hidden by default."
200   (mapc (lambda (header)
201           (when (not (member header message-hidden-headers))
202             (push header message-hidden-headers)))
203         notmuch-mua-hidden-headers))
204
205 (defun notmuch-mua-reply-crypto (parts)
206   "Add mml sign-encrypt flag if any part of original message is encrypted."
207   (cl-loop for part in parts
208            if (notmuch-match-content-type (plist-get part :content-type) "multipart/encrypted")
209              do (mml-secure-message-sign-encrypt)
210            else if (notmuch-match-content-type (plist-get part :content-type) "multipart/*")
211              do (notmuch-mua-reply-crypto (plist-get part :content))))
212
213 ;; There is a bug in emacs 23's message.el that results in a newline
214 ;; not being inserted after the References header, so the next header
215 ;; is concatenated to the end of it. This function fixes the problem,
216 ;; while guarding against the possibility that some current or future
217 ;; version of emacs has the bug fixed.
218 (defun notmuch-mua-insert-references (original-func header references)
219   (funcall original-func header references)
220   (unless (bolp) (insert "\n")))
221
222 (defun notmuch-mua-reply (query-string &optional sender reply-all)
223   (let ((args '("reply" "--format=sexp" "--format-version=4"))
224         (process-crypto notmuch-show-process-crypto)
225         reply
226         original)
227     (when process-crypto
228       (setq args (append args '("--decrypt=true"))))
229
230     (if reply-all
231         (setq args (append args '("--reply-to=all")))
232       (setq args (append args '("--reply-to=sender"))))
233     (setq args (append args (list query-string)))
234
235     ;; Get the reply object as SEXP, and parse it into an elisp object.
236     (setq reply (apply #'notmuch-call-notmuch-sexp args))
237
238     ;; Extract the original message to simplify the following code.
239     (setq original (plist-get reply :original))
240
241     ;; Extract the headers of both the reply and the original message.
242     (let* ((original-headers (plist-get original :headers))
243            (reply-headers (plist-get reply :reply-headers)))
244
245       ;; If sender is non-nil, set the From: header to its value.
246       (when sender
247         (plist-put reply-headers :From sender))
248       (let
249           ;; Overlay the composition window on that being used to read
250           ;; the original message.
251           ((same-window-regexps '("\\*mail .*")))
252
253         ;; We modify message-header-format-alist to get around a bug in message.el.
254         ;; See the comment above on notmuch-mua-insert-references.
255         (let ((message-header-format-alist
256                (cl-loop for pair in message-header-format-alist
257                         if (eq (car pair) 'References)
258                         collect (cons 'References
259                                       (apply-partially
260                                        'notmuch-mua-insert-references
261                                        (cdr pair)))
262                         else
263                         collect pair)))
264           (notmuch-mua-mail (plist-get reply-headers :To)
265                             (notmuch-sanitize (plist-get reply-headers :Subject))
266                             (notmuch-headers-plist-to-alist reply-headers)
267                             nil (notmuch-mua-get-switch-function))))
268
269       ;; Create a buffer-local queue for tag changes triggered when sending the reply
270       (when notmuch-message-replied-tags
271         (setq-local notmuch-message-queued-tag-changes
272                     (list (cons query-string notmuch-message-replied-tags))))
273
274       ;; Insert the message body - but put it in front of the signature
275       ;; if one is present, and after any other content
276       ;; message*setup-hooks may have added to the message body already.
277       (save-restriction
278         (message-goto-body)
279         (narrow-to-region (point) (point-max))
280         (goto-char (point-max))
281         (if (re-search-backward message-signature-separator nil t)
282             (if message-signature-insert-empty-line
283                 (forward-line -1))
284           (goto-char (point-max))))
285
286       (let ((from (plist-get original-headers :From))
287             (date (plist-get original-headers :Date))
288             (start (point)))
289
290         ;; notmuch-mua-cite-function constructs a citation line based
291         ;; on the From and Date headers of the original message, which
292         ;; are assumed to be in the buffer.
293         (insert "From: " from "\n")
294         (insert "Date: " date "\n\n")
295
296         (insert (with-temp-buffer
297                   (let
298                       ;; Don't attempt to clean up messages, excerpt
299                       ;; citations, etc. in the original message before
300                       ;; quoting.
301                       ((notmuch-show-insert-text/plain-hook nil)
302                        ;; Don't omit long parts.
303                        (notmuch-show-max-text-part-size 0)
304                        ;; Insert headers for parts as appropriate for replying.
305                        (notmuch-show-insert-header-p-function notmuch-mua-reply-insert-header-p-function)
306                        ;; Ensure that any encrypted parts are
307                        ;; decrypted during the generation of the reply
308                        ;; text.
309                        (notmuch-show-process-crypto process-crypto)
310                        ;; Don't indent multipart sub-parts.
311                        (notmuch-show-indent-multipart nil))
312                     ;; We don't want sigstatus buttons (an information leak and usually wrong anyway).
313                     (cl-letf (((symbol-function 'notmuch-crypto-insert-sigstatus-button) #'ignore)
314                               ((symbol-function 'notmuch-crypto-insert-encstatus-button) #'ignore))
315                       (notmuch-show-insert-body original (plist-get original :body) 0)
316                       (buffer-substring-no-properties (point-min) (point-max))))))
317
318         (set-mark (point))
319         (goto-char start)
320         ;; Quote the original message according to the user's configured style.
321         (funcall notmuch-mua-cite-function)))
322
323     ;; Crypto processing based crypto content of the original message
324     (when process-crypto
325       (notmuch-mua-reply-crypto (plist-get original :body))))
326
327   ;; Push mark right before signature, if any.
328   (message-goto-signature)
329   (unless (eobp)
330     (end-of-line -1))
331   (push-mark)
332
333   (message-goto-body)
334   (set-buffer-modified-p nil))
335
336 (define-derived-mode notmuch-message-mode message-mode "Message[Notmuch]"
337   "Notmuch message composition mode. Mostly like `message-mode'"
338   (notmuch-address-setup))
339
340 (put 'notmuch-message-mode 'flyspell-mode-predicate 'mail-mode-flyspell-verify)
341
342 (define-key notmuch-message-mode-map (kbd "C-c C-c") #'notmuch-mua-send-and-exit)
343 (define-key notmuch-message-mode-map (kbd "C-c C-s") #'notmuch-mua-send)
344 (define-key notmuch-message-mode-map (kbd "C-c C-p") #'notmuch-draft-postpone)
345 (define-key notmuch-message-mode-map (kbd "C-x C-s") #'notmuch-draft-save)
346
347 (defun notmuch-mua-pop-to-buffer (name switch-function)
348   "Pop to buffer NAME, and warn if it already exists and is
349 modified. This function is notmuch addaptation of
350 `message-pop-to-buffer'."
351   (let ((buffer (get-buffer name)))
352     (if (and buffer
353              (buffer-name buffer))
354         (let ((window (get-buffer-window buffer 0)))
355           (if window
356               ;; Raise the frame already displaying the message buffer.
357               (progn
358                 (select-frame-set-input-focus (window-frame window))
359                 (select-window window))
360             (funcall switch-function buffer)
361             (set-buffer buffer))
362           (when (and (buffer-modified-p)
363                      (not (prog1
364                               (y-or-n-p
365                                "Message already being composed; erase? ")
366                             (message nil))))
367             (error "Message being composed")))
368       (funcall switch-function name)
369       (set-buffer name))
370     (erase-buffer)
371     (notmuch-message-mode)))
372
373 (defun notmuch-mua-mail (&optional to subject other-headers continue
374                                    switch-function yank-action send-actions
375                                    return-action &rest ignored)
376   "Invoke the notmuch mail composition window."
377   (interactive)
378
379   (when notmuch-mua-user-agent-function
380     (let ((user-agent (funcall notmuch-mua-user-agent-function)))
381       (when (not (string= "" user-agent))
382         (push (cons 'User-Agent user-agent) other-headers))))
383
384   (unless (assq 'From other-headers)
385     (push (cons 'From (message-make-from
386                        (notmuch-user-name) (notmuch-user-primary-email))) other-headers))
387
388   (notmuch-mua-pop-to-buffer (message-buffer-name "mail" to)
389                              (or switch-function (notmuch-mua-get-switch-function)))
390   (let ((headers
391          (append
392           ;; The following is copied from `message-mail'
393           `((To . ,(or to "")) (Subject . ,(or subject "")))
394           ;; C-h f compose-mail says that headers should be specified as
395           ;; (string . value); however all the rest of message expects
396           ;; headers to be symbols, not strings (eg message-header-format-alist).
397           ;; https://lists.gnu.org/archive/html/emacs-devel/2011-01/msg00337.html
398           ;; We need to convert any string input, eg from rmail-start-mail.
399           (dolist (h other-headers other-headers)
400             (if (stringp (car h)) (setcar h (intern (capitalize (car h))))))))
401         (args (list yank-action send-actions))
402         ;; Cause `message-setup-1' to do things relevant for mail,
403         ;; such as observe `message-default-mail-headers'.
404         (message-this-is-mail t))
405     ;; message-setup-1 in Emacs 23 does not accept return-action
406     ;; argument. Pass it only if it is supplied by the caller. This
407     ;; will never be the case when we're called by `compose-mail' in
408     ;; Emacs 23.
409     (when return-action (nconc args '(return-action)))
410     (apply 'message-setup-1 headers args))
411   (notmuch-fcc-header-setup)
412   (message-sort-headers)
413   (message-hide-headers)
414   (set-buffer-modified-p nil)
415   (notmuch-mua-maybe-set-window-dedicated)
416
417   (message-goto-to))
418
419 (defcustom notmuch-identities nil
420   "Identities that can be used as the From: address when composing a new message.
421
422 If this variable is left unset, then a list will be constructed from the
423 name and addresses configured in the notmuch configuration file."
424   :type '(repeat string)
425   :group 'notmuch-send)
426
427 (defcustom notmuch-always-prompt-for-sender nil
428   "Always prompt for the From: address when composing or forwarding a message.
429
430 This is not taken into account when replying to a message, because in that case
431 the From: header is already filled in by notmuch."
432   :type 'boolean
433   :group 'notmuch-send)
434
435 (defvar notmuch-mua-sender-history nil)
436
437 ;; Workaround: Running `ido-completing-read' in emacs 23.1, 23.2 and 23.3
438 ;; without some explicit initialization fill freeze the operation.
439 ;; Hence, we advice `ido-completing-read' to ensure required initialization
440 ;; is done.
441 (if (and (= emacs-major-version 23) (< emacs-minor-version 4))
442     (defadvice ido-completing-read (before notmuch-ido-mode-init activate)
443       (ido-init-completion-maps)
444       (add-hook 'minibuffer-setup-hook 'ido-minibuffer-setup)
445       (add-hook 'choose-completion-string-functions
446                 'ido-choose-completion-string)
447       (ad-disable-advice 'ido-completing-read 'before 'notmuch-ido-mode-init)
448       (ad-activate 'ido-completing-read)))
449
450 (defun notmuch-mua-prompt-for-sender ()
451   "Prompt for a sender from the user's configured identities."
452   (if notmuch-identities
453       (ido-completing-read "Send mail from: " notmuch-identities
454                            nil nil nil 'notmuch-mua-sender-history
455                            (car notmuch-identities))
456     (let* ((name (notmuch-user-name))
457            (addrs (cons (notmuch-user-primary-email)
458                         (notmuch-user-other-email)))
459            (address
460             (ido-completing-read (concat "Sender address for " name ": ") addrs
461                                  nil nil nil 'notmuch-mua-sender-history
462                                  (car addrs))))
463       (message-make-from name address))))
464
465 (put 'notmuch-mua-new-mail 'notmuch-prefix-doc "... and prompt for sender")
466 (defun notmuch-mua-new-mail (&optional prompt-for-sender)
467   "Compose new mail.
468
469 If PROMPT-FOR-SENDER is non-nil, the user will be prompted for
470 the From: address first."
471   (interactive "P")
472   (let ((other-headers
473          (when (or prompt-for-sender notmuch-always-prompt-for-sender)
474            (list (cons 'From (notmuch-mua-prompt-for-sender))))))
475     (notmuch-mua-mail nil nil other-headers nil (notmuch-mua-get-switch-function))))
476
477 (defun notmuch-mua-new-forward-messages (messages &optional prompt-for-sender)
478   "Compose a new message forwarding MESSAGES.
479
480 If PROMPT-FOR-SENDER is non-nil, the user will be prompteed for
481 the From: address."
482   (let* ((other-headers
483           (when (or prompt-for-sender notmuch-always-prompt-for-sender)
484             (list (cons 'From (notmuch-mua-prompt-for-sender)))))
485          forward-subject  ;; Comes from the first message and is
486                           ;; applied later.
487          forward-references ;; List of accumulated message-references of forwarded messages
488          forward-queries) ;; List of corresponding message-query
489
490     ;; Generate the template for the outgoing message.
491     (notmuch-mua-mail nil "" other-headers nil (notmuch-mua-get-switch-function))
492
493     (save-excursion
494       ;; Insert all of the forwarded messages.
495       (mapc (lambda (id)
496               (let ((temp-buffer (get-buffer-create
497                                   (concat "*notmuch-fwd-raw-" id "*"))))
498                 ;; Get the raw version of this message in the buffer.
499                 (with-current-buffer temp-buffer
500                   (erase-buffer)
501                   (let ((coding-system-for-read 'no-conversion))
502                     (call-process notmuch-command nil t nil "show" "--format=raw" id))
503                   ;; Because we process the messages in reverse order,
504                   ;; always generate a forwarded subject, then use the
505                   ;; last (i.e. first) one.
506                   (setq forward-subject (message-make-forward-subject))
507                   (push (message-fetch-field "Message-ID") forward-references)
508                   (push id forward-queries))
509                 ;; Make a copy ready to be forwarded in the
510                 ;; composition buffer.
511                 (message-forward-make-body temp-buffer)
512                 ;; Kill the temporary buffer.
513                 (kill-buffer temp-buffer)))
514             ;; `message-forward-make-body' always puts the message at
515             ;; the top, so do them in reverse order.
516             (reverse messages))
517
518       ;; Add in the appropriate subject.
519       (save-restriction
520         (message-narrow-to-headers)
521         (message-remove-header "Subject")
522         (message-add-header (concat "Subject: " forward-subject))
523         (message-remove-header "References")
524         (message-add-header (concat "References: "
525                                     (mapconcat 'identity forward-references " "))))
526
527       ;; Create a buffer-local queue for tag changes triggered when sending the message
528       (when notmuch-message-forwarded-tags
529         (setq-local notmuch-message-queued-tag-changes
530                     (cl-loop for id in forward-queries
531                              collect
532                              (cons id notmuch-message-forwarded-tags))))
533
534       ;; `message-forward-make-body' shows the User-agent header.  Hide
535       ;; it again.
536       (message-hide-headers)
537       (set-buffer-modified-p nil))))
538
539 (defun notmuch-mua-new-reply (query-string &optional prompt-for-sender reply-all)
540   "Compose a reply to the message identified by QUERY-STRING.
541
542 If PROMPT-FOR-SENDER is non-nil, the user will be prompted for
543 the From: address first.  If REPLY-ALL is non-nil, the message
544 will be addressed to all recipients of the source message."
545
546 ;; In current emacs (24.3) select-active-regions is set to t by
547 ;; default. The reply insertion code sets the region to the quoted
548 ;; message to make it easy to delete (kill-region or C-w). These two
549 ;; things combine to put the quoted message in the primary selection.
550 ;;
551 ;; This is not what the user wanted and is a privacy risk (accidental
552 ;; pasting of the quoted message). We can avoid some of the problems
553 ;; by let-binding select-active-regions to nil. This fixes if the
554 ;; primary selection was previously in a non-emacs window but not if
555 ;; it was in an emacs window. To avoid the problem in the latter case
556 ;; we deactivate mark.
557
558   (let ((sender
559          (when prompt-for-sender
560            (notmuch-mua-prompt-for-sender)))
561         (select-active-regions nil))
562     (notmuch-mua-reply query-string sender reply-all)
563     (deactivate-mark)))
564
565 (defun notmuch-mua-check-no-misplaced-secure-tag ()
566   "Query user if there is a misplaced secure mml tag.
567
568 Emacs message-send will (probably) ignore a secure mml tag unless
569 it is at the start of the body. Returns t if there is no such
570 tag, or the user confirms they mean it."
571   (save-excursion
572     (let ((body-start (progn (message-goto-body) (point))))
573       (goto-char (point-max))
574       (or
575        ;; We are always fine if there is no secure tag.
576        (not (search-backward "<#secure" nil 't))
577        ;; There is a secure tag, so it must be at the start of the
578        ;; body, with no secure tag earlier (i.e., in the headers).
579        (and (= (point) body-start)
580             (not (search-backward "<#secure" nil 't)))
581        ;; The user confirms they means it.
582        (yes-or-no-p "\
583 There is a <#secure> tag not at the start of the body. It is
584 likely that the message will be sent unsigned and unencrypted.
585 Really send? ")))))
586
587 (defun notmuch-mua-check-secure-tag-has-newline ()
588   "Query if the secure mml tag has a newline following it.
589
590 Emacs message-send will (probably) ignore a correctly placed
591 secure mml tag unless it is followed by a newline. Returns t if
592 any secure tag is followed by a newline, or the user confirms
593 they mean it."
594   (save-excursion
595     (message-goto-body)
596     (or
597      ;; There is no (correctly placed) secure tag.
598      (not (looking-at "<#secure"))
599      ;; The secure tag is followed by a newline.
600      (looking-at "<#secure[^\n>]*>\n")
601      ;; The user confirms they means it.
602      (yes-or-no-p "\
603 The <#secure> tag at the start of the body is not followed by a
604 newline. It is likely that the message will be sent unsigned and
605 unencrypted.  Really send? "))))
606
607 (defun notmuch-mua-send-common (arg &optional exit)
608   (interactive "P")
609   (run-hooks 'notmuch-mua-send-hook)
610   (when (and (notmuch-mua-check-no-misplaced-secure-tag)
611              (notmuch-mua-check-secure-tag-has-newline))
612     (cl-letf (((symbol-function 'message-do-fcc) #'notmuch-maildir-message-do-fcc))
613       (if exit
614           (message-send-and-exit arg)
615         (message-send arg)))))
616
617 (defun notmuch-mua-send-and-exit (&optional arg)
618   (interactive "P")
619   (notmuch-mua-send-common arg 't))
620
621 (defun notmuch-mua-send (&optional arg)
622   (interactive "P")
623   (notmuch-mua-send-common arg))
624
625 (defun notmuch-mua-kill-buffer ()
626   (interactive)
627   (message-kill-buffer))
628
629 (defun notmuch-mua-message-send-hook ()
630   "The default function used for `notmuch-mua-send-hook', this
631 simply runs the corresponding `message-mode' hook functions."
632   (run-hooks 'message-send-hook))
633
634 ;;
635
636 (define-mail-user-agent 'notmuch-user-agent
637   'notmuch-mua-mail 'notmuch-mua-send-and-exit
638   'notmuch-mua-kill-buffer 'notmuch-mua-send-hook)
639
640 ;; Add some more headers to the list that `message-mode' hides when
641 ;; composing a message.
642 (notmuch-mua-add-more-hidden-headers)
643
644 ;;
645
646 (provide 'notmuch-mua)
647
648 ;;; notmuch-mua.el ends here