emacs: notmuch-tree: mark the initial message at point as read
[notmuch] / emacs / notmuch-show.el
1 ;;; notmuch-show.el --- displaying notmuch forests  -*- lexical-binding: t -*-
2 ;;
3 ;; Copyright © Carl Worth
4 ;; Copyright © David Edmondson
5 ;;
6 ;; This file is part of Notmuch.
7 ;;
8 ;; Notmuch is free software: you can redistribute it and/or modify it
9 ;; under the terms of the GNU General Public License as published by
10 ;; the Free Software Foundation, either version 3 of the License, or
11 ;; (at your option) any later version.
12 ;;
13 ;; Notmuch is distributed in the hope that it will be useful, but
14 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
16 ;; General Public License for more details.
17 ;;
18 ;; You should have received a copy of the GNU General Public License
19 ;; along with Notmuch.  If not, see <https://www.gnu.org/licenses/>.
20 ;;
21 ;; Authors: Carl Worth <cworth@cworth.org>
22 ;;          David Edmondson <dme@dme.org>
23
24 ;;; Code:
25
26 (require 'mm-view)
27 (require 'message)
28 (require 'mm-decode)
29 (require 'mailcap)
30 (require 'icalendar)
31 (require 'goto-addr)
32
33 (require 'notmuch-lib)
34 (require 'notmuch-tag)
35 (require 'notmuch-query)
36 (require 'notmuch-wash)
37 (require 'notmuch-mua)
38 (require 'notmuch-crypto)
39 (require 'notmuch-print)
40 (require 'notmuch-draft)
41
42 (declare-function notmuch-call-notmuch-process "notmuch-lib" (&rest args))
43 (declare-function notmuch-search-next-thread "notmuch" nil)
44 (declare-function notmuch-search-previous-thread "notmuch" nil)
45 (declare-function notmuch-search-show-thread "notmuch")
46 (declare-function notmuch-foreach-mime-part "notmuch" (function mm-handle))
47 (declare-function notmuch-count-attachments "notmuch" (mm-handle))
48 (declare-function notmuch-save-attachments "notmuch" (mm-handle &optional queryp))
49 (declare-function notmuch-tree "notmuch-tree"
50                   (&optional query query-context target buffer-name
51                              open-target unthreaded parent-buffer))
52 (declare-function notmuch-tree-get-message-properties "notmuch-tree" nil)
53 (declare-function notmuch-unthreaded "notmuch-tree"
54                   (&optional query query-context target buffer-name
55                              open-target))
56 (declare-function notmuch-read-query "notmuch" (prompt))
57 (declare-function notmuch-draft-resume "notmuch-draft" (id))
58
59 (defvar shr-blocked-images)
60 (defvar gnus-blocked-images)
61 (defvar shr-content-function)
62
63 ;;; Options
64
65 (defcustom notmuch-message-headers '("Subject" "To" "Cc" "Date")
66   "Headers that should be shown in a message, in this order.
67
68 For an open message, all of these headers will be made visible
69 according to `notmuch-message-headers-visible' or can be toggled
70 with `notmuch-show-toggle-visibility-headers'. For a closed message,
71 only the first header in the list will be visible."
72   :type '(repeat string)
73   :group 'notmuch-show)
74
75 (defcustom notmuch-message-headers-visible t
76   "Should the headers be visible by default?
77
78 If this value is non-nil, then all of the headers defined in
79 `notmuch-message-headers' will be visible by default in the display
80 of each message. Otherwise, these headers will be hidden and
81 `notmuch-show-toggle-visibility-headers' can be used to make them
82 visible for any given message."
83   :type 'boolean
84   :group 'notmuch-show)
85
86 (defcustom notmuch-show-relative-dates t
87   "Display relative dates in the message summary line."
88   :type 'boolean
89   :group 'notmuch-show)
90
91 (defvar notmuch-show-markup-headers-hook '(notmuch-show-colour-headers)
92   "A list of functions called to decorate the headers listed in
93 `notmuch-message-headers'.")
94
95 (defcustom notmuch-show-hook '(notmuch-show-turn-on-visual-line-mode)
96   "Functions called after populating a `notmuch-show' buffer."
97   :type 'hook
98   :options '(notmuch-show-turn-on-visual-line-mode)
99   :group 'notmuch-show
100   :group 'notmuch-hooks)
101
102 (defcustom notmuch-show-insert-text/plain-hook
103   '(notmuch-wash-wrap-long-lines
104     notmuch-wash-tidy-citations
105     notmuch-wash-elide-blank-lines
106     notmuch-wash-excerpt-citations)
107   "Functions used to improve the display of text/plain parts."
108   :type 'hook
109   :options '(notmuch-wash-convert-inline-patch-to-part
110              notmuch-wash-wrap-long-lines
111              notmuch-wash-tidy-citations
112              notmuch-wash-elide-blank-lines
113              notmuch-wash-excerpt-citations)
114   :group 'notmuch-show
115   :group 'notmuch-hooks)
116
117 (defcustom notmuch-show-max-text-part-size 100000
118   "Maximum size of a text part to be shown by default in characters.
119
120 Set to 0 to show the part regardless of size."
121   :type 'integer
122   :group 'notmuch-show)
123
124 ;; Mostly useful for debugging.
125 (defcustom notmuch-show-all-multipart/alternative-parts nil
126   "Should all parts of multipart/alternative parts be shown?"
127   :type 'boolean
128   :group 'notmuch-show)
129
130 (defcustom notmuch-show-indent-messages-width 1
131   "Width of message indentation in threads.
132
133 Messages are shown indented according to their depth in a thread.
134 This variable determines the width of this indentation measured
135 in number of blanks.  Defaults to `1', choose `0' to disable
136 indentation."
137   :type 'integer
138   :group 'notmuch-show)
139
140 (defcustom notmuch-show-indent-multipart nil
141   "Should the sub-parts of a multipart/* part be indented?"
142   ;; dme: Not sure which is a good default.
143   :type 'boolean
144   :group 'notmuch-show)
145
146 (defcustom notmuch-show-part-button-default-action 'notmuch-show-save-part
147   "Default part header button action (on ENTER or mouse click)."
148   :group 'notmuch-show
149   :type '(choice (const :tag "Save part"
150                         notmuch-show-save-part)
151                  (const :tag "View part"
152                         notmuch-show-view-part)
153                  (const :tag "View interactively"
154                         notmuch-show-interactively-view-part)))
155
156 (defcustom notmuch-show-only-matching-messages nil
157   "Only matching messages are shown by default."
158   :type 'boolean
159   :group 'notmuch-show)
160
161 ;; By default, block all external images to prevent privacy leaks and
162 ;; potential attacks.
163 (defcustom notmuch-show-text/html-blocked-images "."
164   "Remote images that have URLs matching this regexp will be blocked."
165   :type '(choice (const nil) regexp)
166   :group 'notmuch-show)
167
168 ;;; Variables
169
170 (defvar-local notmuch-show-thread-id nil)
171
172 (defvar-local notmuch-show-parent-buffer nil)
173
174 (defvar-local notmuch-show-query-context nil)
175
176 (defvar-local notmuch-show-process-crypto nil)
177
178 (defvar-local notmuch-show-elide-non-matching-messages nil)
179
180 (defvar-local notmuch-show-indent-content t)
181
182 (defvar notmuch-show-attachment-debug nil
183   "If t log stdout and stderr from attachment handlers.
184
185 When set to nil (the default) stdout and stderr from attachment
186 handlers is discarded. When set to t the stdout and stderr from
187 each attachment handler is logged in buffers with names beginning
188 \" *notmuch-part*\".")
189
190 ;;; Options
191
192 (defcustom notmuch-show-stash-mlarchive-link-alist
193   '(("MARC" . "https://marc.info/?i=")
194     ("Mail Archive, The" . "https://mid.mail-archive.com/")
195     ("Lore" . "https://lore.kernel.org/r/")
196     ("Notmuch" . "https://nmbug.notmuchmail.org/nmweb/show/")
197     ;; FIXME: can these services be searched by `Message-Id' ?
198     ;; ("MarkMail" . "http://markmail.org/")
199     ;; ("Nabble" . "http://nabble.com/")
200     ;; ("opensubscriber" . "http://opensubscriber.com/")
201     )
202   "List of Mailing List Archives to use when stashing links.
203
204 This list is used for generating a Mailing List Archive reference
205 URI with the current message's Message-Id in
206 `notmuch-show-stash-mlarchive-link'.
207
208 If the cdr of the alist element is not a function, the cdr is
209 expected to contain a URI that is concatenated with the current
210 message's Message-Id to create a ML archive reference URI.
211
212 If the cdr is a function, the function is called with the
213 Message-Id as the argument, and the function is expected to
214 return the ML archive reference URI."
215   :type '(alist :key-type (string :tag "Name")
216                 :value-type (choice
217                              (string :tag "URL")
218                              (function :tag "Function returning the URL")))
219   :group 'notmuch-show)
220
221 (defcustom notmuch-show-stash-mlarchive-link-default "MARC"
222   "Default Mailing List Archive to use when stashing links.
223
224 This is used when `notmuch-show-stash-mlarchive-link' isn't
225 provided with an MLA argument nor `completing-read' input."
226   :type `(choice
227           ,@(mapcar
228              (lambda (mla)
229                (list 'const :tag (car mla) :value (car mla)))
230              notmuch-show-stash-mlarchive-link-alist))
231   :group 'notmuch-show)
232
233 (defcustom notmuch-show-mark-read-tags '("-unread")
234   "List of tag changes to apply to a message when it is marked as read.
235
236 Tags starting with \"+\" (or not starting with either \"+\" or
237 \"-\") in the list will be added, and tags starting with \"-\"
238 will be removed from the message being marked as read.
239
240 For example, if you wanted to remove an \"unread\" tag and add a
241 \"read\" tag (which would make little sense), you would set:
242     (\"-unread\" \"+read\")"
243   :type '(repeat string)
244   :group 'notmuch-show)
245
246 (defcustom notmuch-show-mark-read-function #'notmuch-show-seen-current-message
247   "Function to control which messages are marked read.
248
249 The function should take two arguments START and END which will
250 be the start and end of the visible portion of the buffer and
251 should mark the appropriate messages read by applying
252 `notmuch-show-mark-read'. This function will be called after
253 every user interaction with notmuch."
254   :type 'function
255   :group 'notmuch-show)
256
257 (defcustom notmuch-show-imenu-indent nil
258   "Should Imenu display messages indented.
259
260 By default, Imenu (see Info node `(emacs) Imenu') in a
261 notmuch-show buffer displays all messages straight.  This is
262 because the default Emacs frontend for Imenu makes it difficult
263 to select an Imenu entry with spaces in front.  Other imenu
264 frontends such as counsel-imenu does not have this limitation.
265 In these cases, Imenu entries can be indented to reflect the
266 position of the message in the thread."
267   :type 'boolean
268   :group 'notmuch-show)
269
270 ;;; Utilities
271
272 (defmacro with-current-notmuch-show-message (&rest body)
273   "Evaluate body with current buffer set to the text of current message."
274   `(save-excursion
275      (let ((id (notmuch-show-get-message-id)))
276        (let ((buf (generate-new-buffer (concat "*notmuch-msg-" id "*"))))
277          (with-current-buffer buf
278            (let ((coding-system-for-read 'no-conversion))
279              (call-process notmuch-command nil t nil "show" "--format=raw" id))
280            ,@body)
281          (kill-buffer buf)))))
282
283 (defun notmuch-show-turn-on-visual-line-mode ()
284   "Enable Visual Line mode."
285   (visual-line-mode t))
286
287 ;;; Commands
288
289 ;; DEPRECATED in Notmuch 0.16 since we now have convenient part
290 ;; commands.  We'll keep the command around for a version or two in
291 ;; case people want to bind it themselves.
292 (defun notmuch-show-view-all-mime-parts ()
293   "Use external viewers to view all attachments from the current message."
294   (interactive)
295   (with-current-notmuch-show-message
296    ;; We override the mm-inline-media-tests to indicate which message
297    ;; parts are already sufficiently handled by the original
298    ;; presentation of the message in notmuch-show mode. These parts
299    ;; will be inserted directly into the temporary buffer of
300    ;; with-current-notmuch-show-message and silently discarded.
301    ;;
302    ;; Any MIME part not explicitly mentioned here will be handled by an
303    ;; external viewer as configured in the various mailcap files.
304    (let ((mm-inline-media-tests
305           '(("text/.*" ignore identity)
306             ("application/pgp-signature" ignore identity)
307             ("multipart/alternative" ignore identity)
308             ("multipart/mixed" ignore identity)
309             ("multipart/related" ignore identity))))
310      (mm-display-parts (mm-dissect-buffer)))))
311
312 (defun notmuch-show-save-attachments ()
313   "Save all attachments from the current message."
314   (interactive)
315   (with-current-notmuch-show-message
316    (let ((mm-handle (mm-dissect-buffer)))
317      (notmuch-save-attachments
318       mm-handle (> (notmuch-count-attachments mm-handle) 1))))
319   (message "Done"))
320
321 (defun notmuch-show-with-message-as-text (fn)
322   "Apply FN to a text representation of the current message.
323
324 FN is called with one argument, the message properties. It should
325 operation on the contents of the current buffer."
326   ;; Remake the header to ensure that all information is available.
327   (let* ((to (notmuch-show-get-to))
328          (cc (notmuch-show-get-cc))
329          (from (notmuch-show-get-from))
330          (subject (notmuch-show-get-subject))
331          (date (notmuch-show-get-date))
332          (tags (notmuch-show-get-tags))
333          (depth (notmuch-show-get-depth))
334          (header (concat
335                   "Subject: " subject "\n"
336                   "To: " to "\n"
337                   (if (not (string-empty-p cc))
338                       (concat "Cc: " cc "\n")
339                     "")
340                   "From: " from "\n"
341                   "Date: " date "\n"
342                   (if tags
343                       (concat "Tags: "
344                               (mapconcat #'identity tags ", ") "\n")
345                     "")))
346          (all (buffer-substring (notmuch-show-message-top)
347                                 (notmuch-show-message-bottom)))
348
349          (props (notmuch-show-get-message-properties))
350          (indenting notmuch-show-indent-content))
351     (with-temp-buffer
352       (insert all)
353       (when indenting
354         (indent-rigidly (point-min)
355                         (point-max)
356                         (- (* notmuch-show-indent-messages-width depth))))
357       ;; Remove the original header.
358       (goto-char (point-min))
359       (re-search-forward "^$" (point-max) nil)
360       (delete-region (point-min) (point))
361       (insert header)
362       (funcall fn props))))
363
364 (defun notmuch-show-print-message ()
365   "Print the current message."
366   (interactive)
367   (notmuch-show-with-message-as-text 'notmuch-print-message))
368
369 ;;; Headers
370
371 (defun notmuch-show-fontify-header ()
372   (let ((face (cond
373                ((looking-at "[Tt]o:")
374                 'message-header-to)
375                ((looking-at "[Bb]?[Cc][Cc]:")
376                 'message-header-cc)
377                ((looking-at "[Ss]ubject:")
378                 'message-header-subject)
379                (t
380                 'message-header-other))))
381     (overlay-put (make-overlay (point) (re-search-forward ":"))
382                  'face 'message-header-name)
383     (overlay-put (make-overlay (point) (re-search-forward ".*$"))
384                  'face face)))
385
386 (defun notmuch-show-colour-headers ()
387   "Apply some colouring to the current headers."
388   (goto-char (point-min))
389   (while (looking-at "^[A-Za-z][-A-Za-z0-9]*:")
390     (notmuch-show-fontify-header)
391     (forward-line)))
392
393 (defun notmuch-show-spaces-n (n)
394   "Return a string comprised of `n' spaces."
395   (make-string n ? ))
396
397 (defun notmuch-show-update-tags (tags)
398   "Update the displayed tags of the current message."
399   (save-excursion
400     (goto-char (notmuch-show-message-top))
401     (when (re-search-forward "(\\([^()]*\\))$" (line-end-position) t)
402       (let ((inhibit-read-only t))
403         (replace-match (concat "("
404                                (notmuch-tag-format-tags
405                                 tags
406                                 (notmuch-show-get-prop :orig-tags))
407                                ")"))))))
408
409 (defun notmuch-clean-address (address)
410   "Try to clean a single email ADDRESS for display. Return a cons
411 cell of (AUTHOR_EMAIL AUTHOR_NAME). Return (ADDRESS nil) if
412 parsing fails."
413   (condition-case nil
414       (let (p-name p-address)
415         ;; It would be convenient to use `mail-header-parse-address',
416         ;; but that expects un-decoded mailbox parts, whereas our
417         ;; mailbox parts are already decoded (and hence may contain
418         ;; UTF-8). Given that notmuch should handle most of the awkward
419         ;; cases, some simple string deconstruction should be sufficient
420         ;; here.
421         (cond
422          ;; "User <user@dom.ain>" style.
423          ((string-match "\\(.*\\) <\\(.*\\)>" address)
424           (setq p-name (match-string 1 address))
425           (setq p-address (match-string 2 address)))
426
427          ;; "<user@dom.ain>" style.
428          ((string-match "<\\(.*\\)>" address)
429           (setq p-address (match-string 1 address)))
430          ;; Everything else.
431          (t
432           (setq p-address address)))
433         (when p-name
434           ;; Remove elements of the mailbox part that are not relevant for
435           ;; display, even if they are required during transport:
436           ;;
437           ;; Backslashes.
438           (setq p-name (replace-regexp-in-string "\\\\" "" p-name))
439           ;; Outer single and double quotes, which might be nested.
440           (cl-loop with start-of-loop
441                    do   (setq start-of-loop p-name)
442                    when (string-match "^\"\\(.*\\)\"$" p-name)
443                    do   (setq p-name (match-string 1 p-name))
444                    when (string-match "^'\\(.*\\)'$" p-name)
445                    do   (setq p-name (match-string 1 p-name))
446                    until (string= start-of-loop p-name)))
447         ;; If the address is 'foo@bar.com <foo@bar.com>' then show just
448         ;; 'foo@bar.com'.
449         (when (string= p-name p-address)
450           (setq p-name nil))
451         (cons p-address p-name))
452     (error (cons address nil))))
453
454 (defun notmuch-show-clean-address (address)
455   "Try to clean a single email ADDRESS for display.
456 Return unchanged ADDRESS if parsing fails."
457   (let* ((clean-address (notmuch-clean-address address))
458          (p-address (car clean-address))
459          (p-name (cdr clean-address)))
460     ;; If no name, return just the address.
461     (if (not p-name)
462         p-address
463       ;; Otherwise format the name and address together.
464       (concat p-name " <" p-address ">"))))
465
466 (defun notmuch-show-insert-headerline (headers date tags depth)
467   "Insert a notmuch style headerline based on HEADERS for a
468 message at DEPTH in the current thread."
469   (let ((start (point))
470         (from (notmuch-sanitize
471                (notmuch-show-clean-address (plist-get headers :From)))))
472     (when (string-match "\\cR" from)
473       ;; If the From header has a right-to-left character add
474       ;; invisible U+200E LEFT-TO-RIGHT MARK character which forces
475       ;; the header paragraph as left-to-right text.
476       (insert (propertize (string ?\x200e) 'invisible t)))
477     (insert (if notmuch-show-indent-content
478                 (notmuch-show-spaces-n (* notmuch-show-indent-messages-width
479                                           depth))
480               "")
481             from
482             " ("
483             date
484             ") ("
485             (notmuch-tag-format-tags tags tags)
486             ")\n")
487     (overlay-put (make-overlay start (point))
488                  'face 'notmuch-message-summary-face)))
489
490 (defun notmuch-show-insert-header (header header-value)
491   "Insert a single header."
492   (insert header ": " (notmuch-sanitize header-value) "\n"))
493
494 (defun notmuch-show-insert-headers (headers)
495   "Insert the headers of the current message."
496   (let ((start (point)))
497     (mapc (lambda (header)
498             (let* ((header-symbol (intern (concat ":" header)))
499                    (header-value (plist-get headers header-symbol)))
500               (when (and header-value
501                          (not (string-equal "" header-value)))
502                 (notmuch-show-insert-header header header-value))))
503           notmuch-message-headers)
504     (save-excursion
505       (save-restriction
506         (narrow-to-region start (point-max))
507         (run-hooks 'notmuch-show-markup-headers-hook)))))
508
509 ;;; Parts
510
511 (define-button-type 'notmuch-show-part-button-type
512   'action 'notmuch-show-part-button-default
513   'follow-link t
514   'face 'message-mml
515   :supertype 'notmuch-button-type)
516
517 (defun notmuch-show-insert-part-header (_nth content-type declared-type
518                                             &optional name comment)
519   (let ((base-label (concat (and name (concat name ": "))
520                             declared-type
521                             (and (not (string-equal declared-type content-type))
522                                  (concat " (as " content-type ")"))
523                             comment)))
524     (prog1 (insert-button
525             (concat "[ " base-label " ]")
526             :base-label base-label
527             :type 'notmuch-show-part-button-type
528             :notmuch-part-hidden nil)
529       (insert "\n"))))
530
531 (defun notmuch-show-toggle-part-invisibility (&optional button)
532   (interactive)
533   (let ((button (or button (button-at (point)))))
534     (when button
535       (let ((overlay (button-get button 'overlay))
536             (lazy-part (button-get button :notmuch-lazy-part)))
537         ;; We have a part to toggle if there is an overlay or if there
538         ;; is a lazy part.  If neither is present we cannot toggle the
539         ;; part so we just return nil.
540         (when (or overlay lazy-part)
541           (let* ((show (button-get button :notmuch-part-hidden))
542                  (new-start (button-start button))
543                  (button-label (button-get button :base-label))
544                  (old-point (point))
545                  (properties (text-properties-at (button-start button)))
546                  (inhibit-read-only t))
547             ;; Toggle the button itself.
548             (button-put button :notmuch-part-hidden (not show))
549             (goto-char new-start)
550             (insert "[ " button-label (if show " ]" " (hidden) ]"))
551             (set-text-properties new-start (point) properties)
552             (let ((old-end (button-end button)))
553               (move-overlay button new-start (point))
554               (delete-region (point) old-end))
555             (goto-char (min old-point (1- (button-end button))))
556             ;; Return nil if there is a lazy-part, it is empty, and we are
557             ;; trying to show it.  In all other cases return t.
558             (if lazy-part
559                 (when show
560                   (button-put button :notmuch-lazy-part nil)
561                   (notmuch-show-lazy-part lazy-part button))
562               ;; else there must be an overlay.
563               (overlay-put overlay 'invisible (not show))
564               t)))))))
565
566 ;;; Part content ID handling
567
568 (defvar notmuch-show--cids nil
569   "Alist from raw content ID to (MSG PART).")
570 (make-variable-buffer-local 'notmuch-show--cids)
571
572 (defun notmuch-show--register-cids (msg part)
573   "Register content-IDs in PART and all of PART's sub-parts."
574   (let ((content-id (plist-get part :content-id)))
575     (when content-id
576       ;; Note that content-IDs are globally unique, except when they
577       ;; aren't: RFC 2046 section 5.1.4 permits children of a
578       ;; multipart/alternative to have the same content-ID, in which
579       ;; case the MUA is supposed to pick the best one it can render.
580       ;; We simply add the content-ID to the beginning of our alist;
581       ;; so if this happens, we'll take the last (and "best")
582       ;; alternative (even if we can't render it).
583       (push (list content-id msg part) notmuch-show--cids)))
584   ;; Recurse on sub-parts
585   (when-let ((type (plist-get part :content-type)))
586     (pcase-let ((`(,type ,subtype)
587                  (split-string (downcase type) "/")))
588       (cond ((equal type "multipart")
589              (mapc (apply-partially #'notmuch-show--register-cids msg)
590                    (plist-get part :content)))
591             ((and (equal type "message")
592                   (equal subtype "rfc822"))
593              (notmuch-show--register-cids
594               msg
595               (car (plist-get (car (plist-get part :content)) :body))))))))
596
597 (defun notmuch-show--get-cid-content (cid)
598   "Return a list (CID-content content-type) or nil.
599
600 This will only find parts from messages that have been inserted
601 into the current buffer.  CID must be a raw content ID, without
602 enclosing angle brackets, a cid: prefix, or URL encoding.  This
603 will return nil if the CID is unknown or cannot be retrieved."
604   (when-let ((descriptor (cdr (assoc cid notmuch-show--cids))))
605     (pcase-let ((`(,msg ,part) descriptor))
606       ;; Request caching for this content, as some messages
607       ;; reference the same cid: part many times (hundreds!).
608       (list (notmuch-get-bodypart-binary
609              msg part notmuch-show-process-crypto 'cache)
610             (plist-get part :content-type)))))
611
612 (defun notmuch-show-setup-w3m ()
613   "Instruct w3m how to retrieve content from a \"related\" part of a message."
614   (interactive)
615   (when (and (boundp 'w3m-cid-retrieve-function-alist)
616              (not (assq 'notmuch-show-mode w3m-cid-retrieve-function-alist)))
617     (push (cons 'notmuch-show-mode #'notmuch-show--cid-w3m-retrieve)
618           w3m-cid-retrieve-function-alist))
619   (setq mm-html-inhibit-images nil))
620
621 (defvar w3m-current-buffer) ;; From `w3m.el'.
622 (defun notmuch-show--cid-w3m-retrieve (url &rest _args)
623   ;; url includes the cid: prefix and is URL encoded (see RFC 2392).
624   (let* ((cid (url-unhex-string (substring url 4)))
625          (content-and-type
626           (with-current-buffer w3m-current-buffer
627             (notmuch-show--get-cid-content cid))))
628     (when content-and-type
629       (insert (car content-and-type))
630       (cadr content-and-type))))
631
632 ;; MIME part renderers
633
634 (defun notmuch-show-multipart/*-to-list (part)
635   (mapcar (lambda (inner-part) (plist-get inner-part :content-type))
636           (plist-get part :content)))
637
638 (defun notmuch-show-insert-part-multipart/alternative (msg part _content-type _nth depth _button)
639   (let ((chosen-type (car (notmuch-multipart/alternative-choose
640                            msg (notmuch-show-multipart/*-to-list part))))
641         (inner-parts (plist-get part :content))
642         (start (point)))
643     ;; This inserts all parts of the chosen type rather than just one,
644     ;; but it's not clear that this is the wrong thing to do - which
645     ;; should be chosen if there are more than one that match?
646     (mapc (lambda (inner-part)
647             (let* ((inner-type (plist-get inner-part :content-type))
648                    (hide (not (or notmuch-show-all-multipart/alternative-parts
649                                   (string= chosen-type inner-type)))))
650               (notmuch-show-insert-bodypart msg inner-part depth hide)))
651           inner-parts)
652
653     (when notmuch-show-indent-multipart
654       (indent-rigidly start (point) 1)))
655   t)
656
657 (defun notmuch-show-insert-part-multipart/related (msg part _content-type _nth depth _button)
658   (let ((inner-parts (plist-get part :content))
659         (start (point)))
660     ;; Render the primary part.  FIXME: Support RFC 2387 Start header.
661     (notmuch-show-insert-bodypart msg (car inner-parts) depth)
662     ;; Add hidden buttons for the rest
663     (mapc (lambda (inner-part)
664             (notmuch-show-insert-bodypart msg inner-part depth t))
665           (cdr inner-parts))
666     (when notmuch-show-indent-multipart
667       (indent-rigidly start (point) 1)))
668   t)
669
670 (defun notmuch-show-insert-part-multipart/signed (msg part _content-type _nth depth button)
671   (when button
672     (button-put button 'face 'notmuch-crypto-part-header))
673   ;; Insert a button detailing the signature status.
674   (notmuch-crypto-insert-sigstatus-button (car (plist-get part :sigstatus))
675                                           (notmuch-show-get-header :From msg))
676   (let ((inner-parts (plist-get part :content))
677         (start (point)))
678     ;; Show all of the parts.
679     (mapc (lambda (inner-part)
680             (notmuch-show-insert-bodypart msg inner-part depth))
681           inner-parts)
682     (when notmuch-show-indent-multipart
683       (indent-rigidly start (point) 1)))
684   t)
685
686 (defun notmuch-show-insert-part-multipart/encrypted (msg part _content-type _nth depth button)
687   (when button
688     (button-put button 'face 'notmuch-crypto-part-header))
689   ;; Insert a button detailing the encryption status.
690   (notmuch-crypto-insert-encstatus-button (car (plist-get part :encstatus)))
691   ;; Insert a button detailing the signature status.
692   (notmuch-crypto-insert-sigstatus-button (car (plist-get part :sigstatus))
693                                           (notmuch-show-get-header :From msg))
694   (let ((inner-parts (plist-get part :content))
695         (start (point)))
696     ;; Show all of the parts.
697     (mapc (lambda (inner-part)
698             (notmuch-show-insert-bodypart msg inner-part depth))
699           inner-parts)
700     (when notmuch-show-indent-multipart
701       (indent-rigidly start (point) 1)))
702   t)
703
704 (defun notmuch-show-insert-part-application/pgp-encrypted (_msg _part _content-type _nth _depth _button)
705   t)
706
707 (defun notmuch-show-insert-part-multipart/* (msg part _content-type _nth depth _button)
708   (let ((inner-parts (plist-get part :content))
709         (start (point)))
710     ;; Show all of the parts.
711     (mapc (lambda (inner-part)
712             (notmuch-show-insert-bodypart msg inner-part depth))
713           inner-parts)
714     (when notmuch-show-indent-multipart
715       (indent-rigidly start (point) 1)))
716   t)
717
718 (defun notmuch-show-insert-part-message/rfc822 (msg part _content-type _nth depth _button)
719   (let* ((message (car (plist-get part :content)))
720          (body (car (plist-get message :body)))
721          (start (point)))
722     ;; Override `notmuch-message-headers' to force `From' to be
723     ;; displayed.
724     (let ((notmuch-message-headers '("From" "Subject" "To" "Cc" "Date")))
725       (notmuch-show-insert-headers (plist-get message :headers)))
726     ;; Blank line after headers to be compatible with the normal
727     ;; message display.
728     (insert "\n")
729     ;; Show the body
730     (notmuch-show-insert-bodypart msg body depth)
731     (when notmuch-show-indent-multipart
732       (indent-rigidly start (point) 1)))
733   t)
734
735 (defun notmuch-show-insert-part-text/plain (msg part _content-type _nth depth button)
736   ;; For backward compatibility we want to apply the text/plain hook
737   ;; to the whole of the part including the part button if there is
738   ;; one.
739   (let ((start (if button
740                    (button-start button)
741                  (point))))
742     (insert (notmuch-get-bodypart-text msg part notmuch-show-process-crypto))
743     (save-excursion
744       (save-restriction
745         (narrow-to-region start (point-max))
746         (run-hook-with-args 'notmuch-show-insert-text/plain-hook msg depth))))
747   t)
748
749 (defun notmuch-show-insert-part-text/calendar (msg part _content-type _nth _depth _button)
750   (insert (with-temp-buffer
751             (insert (notmuch-get-bodypart-text msg part notmuch-show-process-crypto))
752             ;; notmuch-get-bodypart-text does no newline conversion.
753             ;; Replace CRLF with LF before icalendar can use it.
754             (goto-char (point-min))
755             (while (re-search-forward "\r\n" nil t)
756               (replace-match "\n" nil nil))
757             (let ((file (make-temp-file "notmuch-ical"))
758                   result)
759               (unwind-protect
760                   (progn
761                     (unless (icalendar-import-buffer file t)
762                       (error "Icalendar import error. %s"
763                              "See *icalendar-errors* for more information"))
764                     (set-buffer (get-file-buffer file))
765                     (setq result (buffer-substring (point-min) (point-max)))
766                     (set-buffer-modified-p nil)
767                     (kill-buffer (current-buffer)))
768                 (delete-file file))
769               result)))
770   t)
771
772 ;; For backwards compatibility.
773 (defun notmuch-show-insert-part-text/x-vcalendar (msg part _content-type _nth depth _button)
774   (notmuch-show-insert-part-text/calendar msg part nil nil depth nil))
775
776 (when (version< emacs-version "25.3")
777   ;; https://bugs.gnu.org/28350
778   ;;
779   ;; For newer emacs, we fall back to notmuch-show-insert-part-*/*
780   ;; (see notmuch-show-handlers-for)
781   (defun notmuch-show-insert-part-text/enriched
782       (msg part content-type nth depth button)
783     ;; By requiring enriched below, we ensure that the function
784     ;; enriched-decode-display-prop is defined before it will be
785     ;; shadowed by the letf below. Otherwise the version in
786     ;; enriched.el may be loaded a bit later and used instead (for
787     ;; the first time).
788     (require 'enriched)
789     (cl-letf (((symbol-function 'enriched-decode-display-prop)
790                (lambda (start end &optional _param) (list start end))))
791       (notmuch-show-insert-part-*/* msg part content-type nth depth button))))
792
793 (defun notmuch-show-get-mime-type-of-application/octet-stream (part)
794   ;; If we can deduce a MIME type from the filename of the attachment,
795   ;; we return that.
796   (and (plist-get part :filename)
797        (let ((extension (file-name-extension (plist-get part :filename))))
798          (and extension
799               (progn
800                 (mailcap-parse-mimetypes)
801                 (let ((mime-type (mailcap-extension-to-mime extension)))
802                   (and mime-type
803                        (not (string-equal mime-type "application/octet-stream"))
804                        mime-type)))))))
805
806 (defun notmuch-show-insert-part-text/html (msg part content-type nth depth button)
807   (if (eq mm-text-html-renderer 'shr)
808       ;; It's easier to drive shr ourselves than to work around the
809       ;; goofy things `mm-shr' does (like irreversibly taking over
810       ;; content ID handling).
811       ;; FIXME: If we block an image, offer a button to load external
812       ;; images.
813       (let ((shr-blocked-images notmuch-show-text/html-blocked-images))
814         (notmuch-show--insert-part-text/html-shr msg part))
815     ;; Otherwise, let message-mode do the heavy lifting
816     ;;
817     ;; w3m sets up a keymap which "leaks" outside the invisible region
818     ;; and causes strange effects in notmuch. We set
819     ;; mm-inline-text-html-with-w3m-keymap to nil to tell w3m not to
820     ;; set a keymap (so the normal notmuch-show-mode-map remains).
821     (let ((mm-inline-text-html-with-w3m-keymap nil)
822           ;; FIXME: If we block an image, offer a button to load external
823           ;; images.
824           (gnus-blocked-images notmuch-show-text/html-blocked-images))
825       (notmuch-show-insert-part-*/* msg part content-type nth depth button))))
826
827 ;;; Functions used by notmuch-show--insert-part-text/html-shr
828
829 (declare-function libxml-parse-html-region "xml.c")
830 (declare-function shr-insert-document "shr")
831
832 (defun notmuch-show--insert-part-text/html-shr (msg part)
833   ;; Make sure shr is loaded before we start let-binding its globals
834   (require 'shr)
835   (let ((dom (let ((process-crypto notmuch-show-process-crypto))
836                (with-temp-buffer
837                  (insert (notmuch-get-bodypart-text msg part process-crypto))
838                  (libxml-parse-html-region (point-min) (point-max)))))
839         (shr-content-function
840          (lambda (url)
841            ;; shr strips the "cid:" part of URL, but doesn't
842            ;; URL-decode it (see RFC 2392).
843            (let ((cid (url-unhex-string url)))
844              (car (notmuch-show--get-cid-content cid))))))
845     (shr-insert-document dom)
846     t))
847
848 (defun notmuch-show-insert-part-*/* (msg part content-type _nth _depth _button)
849   ;; This handler _must_ succeed - it is the handler of last resort.
850   (notmuch-mm-display-part-inline msg part content-type notmuch-show-process-crypto)
851   t)
852
853 ;;; Functions for determining how to handle MIME parts.
854
855 (defun notmuch-show-handlers-for (content-type)
856   "Return a list of content handlers for a part of type CONTENT-TYPE."
857   (let (result)
858     (mapc (lambda (func)
859             (when (functionp func)
860               (push func result)))
861           ;; Reverse order of prefrence.
862           (list (intern (concat "notmuch-show-insert-part-*/*"))
863                 (intern (concat "notmuch-show-insert-part-"
864                                 (car (split-string content-type "/"))
865                                 "/*"))
866                 (intern (concat "notmuch-show-insert-part-" content-type))))
867     result))
868
869 ;;; Parts
870
871 (defun notmuch-show-insert-bodypart-internal (msg part content-type nth depth button)
872   ;; Run the handlers until one of them succeeds.
873   (cl-loop for handler in (notmuch-show-handlers-for content-type)
874            until (condition-case err
875                      (funcall handler msg part content-type nth depth button)
876                    ;; Specifying `debug' here lets the debugger run if
877                    ;; `debug-on-error' is non-nil.
878                    ((debug error)
879                     (insert "!!! Bodypart handler `" (prin1-to-string handler)
880                             "' threw an error:\n"
881                             "!!! " (error-message-string err) "\n")
882                     nil))))
883
884 (defun notmuch-show-create-part-overlays (button beg end)
885   "Add an overlay to the part between BEG and END."
886   ;; If there is no button (i.e., the part is text/plain and the first
887   ;; part) or if the part has no content then we don't make the part
888   ;; toggleable.
889   (when (and button (/= beg end))
890     (button-put button 'overlay (make-overlay beg end))
891     ;; Return true if we created an overlay.
892     t))
893
894 (defun notmuch-show-record-part-information (part beg end)
895   "Store PART as a text property from BEG to END."
896   ;; Record part information.  Since we already inserted subparts,
897   ;; don't override existing :notmuch-part properties.
898   (notmuch-map-text-property beg end :notmuch-part
899                              (lambda (v) (or v part)))
900   ;; Make :notmuch-part front sticky and rear non-sticky so it stays
901   ;; applied to the beginning of each line when we indent the
902   ;; message.  Since we're operating on arbitrary renderer output,
903   ;; watch out for sticky specs of t, which means all properties are
904   ;; front-sticky/rear-nonsticky.
905   (notmuch-map-text-property beg end 'front-sticky
906                              (lambda (v)
907                                (if (listp v)
908                                    (cl-pushnew :notmuch-part v)
909                                  v)))
910   (notmuch-map-text-property beg end 'rear-nonsticky
911                              (lambda (v)
912                                (if (listp v)
913                                    (cl-pushnew :notmuch-part v)
914                                  v))))
915
916 (defun notmuch-show-lazy-part (part-args button)
917   ;; Insert the lazy part after the button for the part. We would just
918   ;; move to the start of the new line following the button and insert
919   ;; the part but that point might have text properties (eg colours
920   ;; from a message header etc) so instead we start from the last
921   ;; character of the button by adding a newline and finish by
922   ;; removing the extra newline from the end of the part.
923   (save-excursion
924     (goto-char (button-end button))
925     (insert "\n")
926     (let* ((inhibit-read-only t)
927            ;; We need to use markers for the start and end of the part
928            ;; because the part insertion functions do not guarantee
929            ;; to leave point at the end of the part.
930            (part-beg (copy-marker (point) nil))
931            (part-end (copy-marker (point) t))
932            ;; We have to save the depth as we can't find the depth
933            ;; when narrowed.
934            (depth (notmuch-show-get-depth)))
935       (save-restriction
936         (narrow-to-region part-beg part-end)
937         (delete-region part-beg part-end)
938         (apply #'notmuch-show-insert-bodypart-internal part-args)
939         (indent-rigidly part-beg
940                         part-end
941                         (* notmuch-show-indent-messages-width depth)))
942       (goto-char part-end)
943       (delete-char 1)
944       (notmuch-show-record-part-information (cadr part-args)
945                                             (button-start button)
946                                             part-end)
947       ;; Create the overlay. If the lazy-part turned out to be empty/not
948       ;; showable this returns nil.
949       (notmuch-show-create-part-overlays button part-beg part-end))))
950
951 (defun notmuch-show-mime-type (part)
952   "Return the correct mime-type to use for PART."
953   (when-let ((content-type (plist-get part :content-type)))
954     (setq content-type (downcase content-type))
955     (or (and (string= content-type "application/octet-stream")
956              (notmuch-show-get-mime-type-of-application/octet-stream part))
957         (and (string= content-type "inline patch")
958              "text/x-diff")
959         content-type)))
960
961 ;; The following variable can be overridden by let bindings.
962 (defvar notmuch-show-insert-header-p-function 'notmuch-show-insert-header-p
963   "Specify which function decides which part headers get inserted.
964
965 The function should take two parameters, PART and HIDE, and
966 should return non-NIL if a header button should be inserted for
967 this part.")
968
969 (defun notmuch-show-insert-header-p (part _hide)
970   ;; Show all part buttons except for the first part if it is text/plain.
971   (let ((mime-type (notmuch-show-mime-type part)))
972     (not (and (string= mime-type "text/plain")
973               (<= (plist-get part :id) 1)))))
974
975 (defun notmuch-show-reply-insert-header-p-never (_part _hide)
976   nil)
977
978 (defun notmuch-show-reply-insert-header-p-trimmed (part hide)
979   (let ((mime-type (notmuch-show-mime-type part)))
980     (and (not (notmuch-match-content-type mime-type "multipart/*"))
981          (not hide))))
982
983 (defun notmuch-show-reply-insert-header-p-minimal (part hide)
984   (let ((mime-type (notmuch-show-mime-type part)))
985     (and (notmuch-match-content-type mime-type "text/*")
986          (not hide))))
987
988 (defun notmuch-show-insert-bodypart (msg part depth &optional hide)
989   "Insert the body part PART at depth DEPTH in the current thread.
990
991 HIDE determines whether to show or hide the part and the button
992 as follows: If HIDE is nil, show the part and the button. If HIDE
993 is t, hide the part initially and show the button."
994   (let* ((content-type (plist-get part :content-type))
995          (mime-type (notmuch-show-mime-type part))
996          (nth (plist-get part :id))
997          (long (and (notmuch-match-content-type mime-type "text/*")
998                     (> notmuch-show-max-text-part-size 0)
999                     (> (length (plist-get part :content))
1000                        notmuch-show-max-text-part-size)))
1001          (beg (point))
1002          ;; This default header-p function omits the part button for
1003          ;; the first (or only) part if this is text/plain.
1004          (button (and (funcall notmuch-show-insert-header-p-function part hide)
1005                       (notmuch-show-insert-part-header
1006                        nth mime-type
1007                        (and content-type (downcase content-type))
1008                        (plist-get part :filename))))
1009          ;; Hide the part initially if HIDE is t, or if it is too long
1010          ;; and we have a button to allow toggling.
1011          (show-part (not (or (equal hide t)
1012                              (and long button))))
1013          (content-beg (point)))
1014     ;; Store the computed mime-type for later use (e.g. by attachment handlers).
1015     (plist-put part :computed-type mime-type)
1016     (if show-part
1017         (notmuch-show-insert-bodypart-internal msg part mime-type nth depth button)
1018       (when button
1019         (button-put button :notmuch-lazy-part
1020                     (list msg part mime-type nth depth button))))
1021     ;; Some of the body part handlers leave point somewhere up in the
1022     ;; part, so we make sure that we're down at the end.
1023     (goto-char (point-max))
1024     ;; Ensure that the part ends with a carriage return.
1025     (unless (bolp)
1026       (insert "\n"))
1027     ;; We do not create the overlay for hidden (lazy) parts until
1028     ;; they are inserted.
1029     (if show-part
1030         (notmuch-show-create-part-overlays button content-beg (point))
1031       (save-excursion
1032         (notmuch-show-toggle-part-invisibility button)))
1033     (notmuch-show-record-part-information part beg (point))))
1034
1035 (defun notmuch-show-insert-body (msg body depth)
1036   "Insert the body BODY at depth DEPTH in the current thread."
1037   ;; Register all content IDs for this message.  According to RFC
1038   ;; 2392, content IDs are *global*, but it's okay if an MUA treats
1039   ;; them as only global within a message.
1040   (notmuch-show--register-cids msg (car body))
1041   (mapc (lambda (part) (notmuch-show-insert-bodypart msg part depth)) body))
1042
1043 (defun notmuch-show-make-symbol (type)
1044   (make-symbol (concat "notmuch-show-" type)))
1045
1046 (defun notmuch-show-strip-re (string)
1047   (replace-regexp-in-string "^\\([Rr]e: *\\)+" "" string))
1048
1049 (defvar notmuch-show-previous-subject "")
1050 (make-variable-buffer-local 'notmuch-show-previous-subject)
1051
1052 (defun notmuch-show-insert-msg (msg depth)
1053   "Insert the message MSG at depth DEPTH in the current thread."
1054   (let* ((headers (plist-get msg :headers))
1055          ;; Indentation causes the buffer offset of the start/end
1056          ;; points to move, so we must use markers.
1057          message-start message-end
1058          content-start content-end
1059          headers-start headers-end
1060          (bare-subject (notmuch-show-strip-re (plist-get headers :Subject))))
1061     (setq message-start (point-marker))
1062     (notmuch-show-insert-headerline headers
1063                                     (or (and notmuch-show-relative-dates
1064                                              (plist-get msg :date_relative))
1065                                         (plist-get headers :Date))
1066                                     (plist-get msg :tags) depth)
1067     (setq content-start (point-marker))
1068     ;; Set `headers-start' to point after the 'Subject:' header to be
1069     ;; compatible with the existing implementation. This just sets it
1070     ;; to after the first header.
1071     (notmuch-show-insert-headers headers)
1072     (save-excursion
1073       (goto-char content-start)
1074       ;; If the subject of this message is the same as that of the
1075       ;; previous message, don't display it when this message is
1076       ;; collapsed.
1077       (unless (string= notmuch-show-previous-subject bare-subject)
1078         (forward-line 1))
1079       (setq headers-start (point-marker)))
1080     (setq headers-end (point-marker))
1081     (setq notmuch-show-previous-subject bare-subject)
1082     ;; A blank line between the headers and the body.
1083     (insert "\n")
1084     (notmuch-show-insert-body msg (plist-get msg :body)
1085                               (if notmuch-show-indent-content depth 0))
1086     ;; Ensure that the body ends with a newline.
1087     (unless (bolp)
1088       (insert "\n"))
1089     (setq content-end (point-marker))
1090     ;; Indent according to the depth in the thread.
1091     (when notmuch-show-indent-content
1092       (indent-rigidly content-start
1093                       content-end
1094                       (* notmuch-show-indent-messages-width depth)))
1095     (setq message-end (point-max-marker))
1096     ;; Save the extents of this message over the whole text of the
1097     ;; message.
1098     (put-text-property message-start message-end
1099                        :notmuch-message-extent
1100                        (cons message-start message-end))
1101     ;; Create overlays used to control visibility
1102     (plist-put msg :headers-overlay (make-overlay headers-start headers-end))
1103     (plist-put msg :message-overlay (make-overlay headers-start content-end))
1104     (plist-put msg :depth depth)
1105     ;; Save the properties for this message. Currently this saves the
1106     ;; entire message (augmented it with other stuff), which seems
1107     ;; like overkill. We might save a reduced subset (for example, not
1108     ;; the content).
1109     (notmuch-show-set-message-properties msg)
1110     ;; Set header visibility.
1111     (notmuch-show-headers-visible msg notmuch-message-headers-visible)
1112     ;; Message visibility depends on whether it matched the search
1113     ;; criteria.
1114     (notmuch-show-message-visible msg (and (plist-get msg :match)
1115                                            (not (plist-get msg :excluded))))))
1116
1117 ;;; Toggle commands
1118
1119 (defun notmuch-show-toggle-process-crypto ()
1120   "Toggle the processing of cryptographic MIME parts."
1121   (interactive)
1122   (setq notmuch-show-process-crypto (not notmuch-show-process-crypto))
1123   (message (if notmuch-show-process-crypto
1124                "Processing cryptographic MIME parts."
1125              "Not processing cryptographic MIME parts."))
1126   (notmuch-show-refresh-view))
1127
1128 (defun notmuch-show-toggle-elide-non-matching ()
1129   "Toggle the display of non-matching messages."
1130   (interactive)
1131   (setq notmuch-show-elide-non-matching-messages
1132         (not notmuch-show-elide-non-matching-messages))
1133   (message (if notmuch-show-elide-non-matching-messages
1134                "Showing matching messages only."
1135              "Showing all messages."))
1136   (notmuch-show-refresh-view))
1137
1138 (defun notmuch-show-toggle-thread-indentation ()
1139   "Toggle the indentation of threads."
1140   (interactive)
1141   (setq notmuch-show-indent-content (not notmuch-show-indent-content))
1142   (message (if notmuch-show-indent-content
1143                "Content is indented."
1144              "Content is not indented."))
1145   (notmuch-show-refresh-view))
1146
1147 ;;; Main insert functions
1148
1149 (defun notmuch-show-insert-tree (tree depth)
1150   "Insert the message tree TREE at depth DEPTH in the current thread."
1151   (let ((msg (car tree))
1152         (replies (cadr tree)))
1153     ;; We test whether there is a message or just some replies.
1154     (when msg
1155       (notmuch-show-insert-msg msg depth))
1156     (notmuch-show-insert-thread replies (1+ depth))))
1157
1158 (defun notmuch-show-insert-thread (thread depth)
1159   "Insert the thread THREAD at depth DEPTH in the current forest."
1160   (mapc (lambda (tree) (notmuch-show-insert-tree tree depth)) thread))
1161
1162 (defun notmuch-show-insert-forest (forest)
1163   "Insert the forest of threads FOREST."
1164   (mapc (lambda (thread) (notmuch-show-insert-thread thread 0)) forest))
1165
1166 ;;; Link buttons
1167
1168 (defvar notmuch-id-regexp
1169   (concat
1170    ;; Match the id: prefix only if it begins a word (to disallow, for
1171    ;; example, matching cid:).
1172    "\\<id:\\("
1173    ;; If the term starts with a ", then parse Xapian's quoted boolean
1174    ;; term syntax, which allows for anything as long as embedded
1175    ;; double quotes escaped by doubling them.  We also disallow
1176    ;; newlines (which Xapian allows) to prevent runaway terms.
1177    "\"\\([^\"\n]\\|\"\"\\)*\""
1178    ;; Otherwise, parse Xapian's unquoted syntax, which goes up to the
1179    ;; next space or ).  We disallow [.,;] as the last character
1180    ;; because these are probably part of the surrounding text, and not
1181    ;; part of the id.  This doesn't match single character ids; meh.
1182    "\\|[^\"[:space:])][^[:space:])]*[^])[:space:].,:;?!]"
1183    "\\)")
1184   "The regexp used to match id: links in messages.")
1185
1186 (defvar notmuch-mid-regexp
1187   ;; goto-address-url-regexp matched cid: links, which have the same
1188   ;; grammar as the message ID part of a mid: link.  Construct the
1189   ;; regexp using the same technique as goto-address-url-regexp.
1190   (concat "\\<mid:\\(" thing-at-point-url-path-regexp "\\)")
1191   "The regexp used to match mid: links in messages.
1192
1193 See RFC 2392.")
1194
1195 (defun notmuch-show-buttonise-links (start end)
1196   "Buttonise URLs and mail addresses between START and END.
1197
1198 This also turns id:\"<message id>\"-parts and mid: links into
1199 buttons for a corresponding notmuch search."
1200   (goto-address-fontify-region start end)
1201   (save-excursion
1202     (let (links
1203           (beg-line (progn (goto-char start) (line-beginning-position)))
1204           (end-line (progn (goto-char end) (line-end-position))))
1205       (goto-char beg-line)
1206       (while (re-search-forward notmuch-id-regexp end-line t)
1207         (push (list (match-beginning 0) (match-end 0)
1208                     (match-string-no-properties 0)) links))
1209       (goto-char beg-line)
1210       (while (re-search-forward notmuch-mid-regexp end-line t)
1211         (let* ((mid-cid (match-string-no-properties 1))
1212                (mid (save-match-data
1213                       (string-match "^[^/]*" mid-cid)
1214                       (url-unhex-string (match-string 0 mid-cid)))))
1215           (push (list (match-beginning 0) (match-end 0)
1216                       (notmuch-id-to-query mid)) links)))
1217       (pcase-dolist (`(,beg ,end ,link) links)
1218         ;; Remove the overlay created by goto-address-mode
1219         (remove-overlays beg end 'goto-address t)
1220         (make-text-button beg end
1221                           :type 'notmuch-button-type
1222                           'action `(lambda (arg)
1223                                      (notmuch-show ,link current-prefix-arg))
1224                           'follow-link t
1225                           'help-echo "Mouse-1, RET: search for this message"
1226                           'face goto-address-mail-face)))))
1227
1228 ;;; Show command
1229
1230 ;;;###autoload
1231 (defun notmuch-show (thread-id &optional elide-toggle parent-buffer query-context buffer-name)
1232   "Run \"notmuch show\" with the given thread ID and display results.
1233
1234 ELIDE-TOGGLE, if non-nil, inverts the default elide behavior.
1235
1236 The optional PARENT-BUFFER is the notmuch-search buffer from
1237 which this notmuch-show command was executed, (so that the
1238 next thread from that buffer can be show when done with this
1239 one).
1240
1241 The optional QUERY-CONTEXT is a notmuch search term. Only
1242 messages from the thread matching this search term are shown if
1243 non-nil.
1244
1245 The optional BUFFER-NAME provides the name of the buffer in
1246 which the message thread is shown. If it is nil (which occurs
1247 when the command is called interactively) the argument to the
1248 function is used.
1249
1250 Returns the buffer containing the messages, or NIL if no messages
1251 matched."
1252   (interactive "sNotmuch show: \nP")
1253   (let ((buffer-name (generate-new-buffer-name
1254                       (or buffer-name
1255                           (concat "*notmuch-" thread-id "*"))))
1256         ;; We override mm-inline-override-types to stop application/*
1257         ;; parts from being displayed unless the user has customized
1258         ;; it themselves.
1259         (mm-inline-override-types
1260          (if (equal mm-inline-override-types
1261                     (eval (car (get 'mm-inline-override-types 'standard-value))))
1262              (cons "application/*" mm-inline-override-types)
1263            mm-inline-override-types)))
1264     (pop-to-buffer-same-window (get-buffer-create buffer-name))
1265     ;; No need to track undo information for this buffer.
1266     (setq buffer-undo-list t)
1267     (notmuch-show-mode)
1268     ;; Set various buffer local variables to their appropriate initial
1269     ;; state. Do this after enabling `notmuch-show-mode' so that they
1270     ;; aren't wiped out.
1271     (setq notmuch-show-thread-id thread-id)
1272     (setq notmuch-show-parent-buffer parent-buffer)
1273     (setq notmuch-show-query-context
1274           (if (or (string= query-context "")
1275                   (string= query-context "*"))
1276               nil
1277             query-context))
1278     (setq notmuch-show-process-crypto notmuch-crypto-process-mime)
1279     ;; If `elide-toggle', invert the default value.
1280     (setq notmuch-show-elide-non-matching-messages
1281           (if elide-toggle
1282               (not notmuch-show-only-matching-messages)
1283             notmuch-show-only-matching-messages))
1284     (add-hook 'post-command-hook #'notmuch-show-command-hook nil t)
1285     (jit-lock-register #'notmuch-show-buttonise-links)
1286     (notmuch-tag-clear-cache)
1287     (let ((inhibit-read-only t))
1288       (if (notmuch-show--build-buffer)
1289           ;; Messages were inserted into the buffer.
1290           (current-buffer)
1291         ;; No messages were inserted - presumably none matched the
1292         ;; query.
1293         (kill-buffer (current-buffer))
1294         (ding)
1295         (message "No messages matched the query!")
1296         nil))))
1297
1298 (defun notmuch-show--build-queries (thread context)
1299   "Return a list of queries to try for this search.
1300
1301 THREAD and CONTEXT are both strings, though CONTEXT may be nil.
1302 When CONTEXT is not nil, the first query is the conjunction of it
1303 and THREAD.  The next query is THREAD alone, and serves as a
1304 fallback if the prior matches no messages."
1305   (let (queries)
1306     (push (list thread) queries)
1307     (when context
1308       (push (list thread "and (" context ")") queries))
1309     queries))
1310
1311 (defun notmuch-show--build-buffer (&optional state)
1312   "Display messages matching the current buffer context.
1313
1314 Apply the previously saved STATE if supplied, otherwise show the
1315 first relevant message.
1316
1317 If no messages match the query return NIL."
1318   (let* ((cli-args (cons "--exclude=false"
1319                          (and notmuch-show-elide-non-matching-messages
1320                               (list "--entire-thread=false"))))
1321          (queries (notmuch-show--build-queries
1322                    notmuch-show-thread-id notmuch-show-query-context))
1323          (forest nil)
1324          ;; Must be reset every time we are going to start inserting
1325          ;; messages into the buffer.
1326          (notmuch-show-previous-subject ""))
1327     ;; Use results from the first query that returns some.
1328     (while (and (not forest) queries)
1329       (setq forest (notmuch-query-get-threads
1330                     (append cli-args (list "'") (car queries) (list "'"))))
1331       (setq queries (cdr queries)))
1332     (when forest
1333       (notmuch-show-insert-forest forest)
1334       ;; Store the original tags for each message so that we can
1335       ;; display changes.
1336       (notmuch-show-mapc
1337        (lambda () (notmuch-show-set-prop :orig-tags (notmuch-show-get-tags))))
1338       ;; Set the header line to the subject of the first message.
1339       (setq header-line-format
1340             (replace-regexp-in-string "%" "%%"
1341                                       (notmuch-sanitize
1342                                        (notmuch-show-strip-re
1343                                         (notmuch-show-get-subject)))))
1344       (run-hooks 'notmuch-show-hook)
1345       (if state
1346           (notmuch-show-apply-state state)
1347         ;; With no state to apply, just go to the first message.
1348         (notmuch-show-goto-first-wanted-message)))
1349     ;; Report back to the caller whether any messages matched.
1350     forest))
1351
1352 ;;; Refresh command
1353
1354 (defun notmuch-show-capture-state ()
1355   "Capture the state of the current buffer.
1356
1357 This includes:
1358  - the list of open messages,
1359  - the combination of current message id with/for each visible window."
1360   (let* ((win-list (get-buffer-window-list (current-buffer) nil t))
1361          (win-id-combo (mapcar (lambda (win)
1362                                  (with-selected-window win
1363                                    (list win (notmuch-show-get-message-id))))
1364                                win-list)))
1365     (list win-id-combo (notmuch-show-get-message-ids-for-open-messages))))
1366
1367 (defun notmuch-show-get-query ()
1368   "Return the current query in this show buffer."
1369   (if notmuch-show-query-context
1370       (concat notmuch-show-thread-id
1371               " and ("
1372               notmuch-show-query-context
1373               ")")
1374     notmuch-show-thread-id))
1375
1376 (defun notmuch-show-goto-message (msg-id)
1377   "Go to message with msg-id."
1378   (goto-char (point-min))
1379   (unless (cl-loop if (string= msg-id (notmuch-show-get-message-id))
1380                    return t
1381                    until (not (notmuch-show-goto-message-next)))
1382     (goto-char (point-min))
1383     (message "Message-id not found."))
1384   (notmuch-show-message-adjust))
1385
1386 (defun notmuch-show-apply-state (state)
1387   "Apply STATE to the current buffer.
1388
1389 This includes:
1390  - opening the messages previously opened,
1391  - closing all other messages,
1392  - moving to the correct current message in every displayed window."
1393   (let ((win-msg-alist (car state))
1394         (open (cadr state)))
1395     ;; Open those that were open.
1396     (goto-char (point-min))
1397     (cl-loop do (notmuch-show-message-visible
1398                  (notmuch-show-get-message-properties)
1399                  (member (notmuch-show-get-message-id) open))
1400              until (not (notmuch-show-goto-message-next)))
1401     (dolist (win-msg-pair win-msg-alist)
1402       (with-selected-window (car win-msg-pair)
1403         ;; Go to the previously open message in this window
1404         (notmuch-show-goto-message (cadr win-msg-pair))))))
1405
1406 (defun notmuch-show-refresh-view (&optional reset-state)
1407   "Refresh the current view.
1408
1409 Refreshes the current view, observing changes in display
1410 preferences. If invoked with a prefix argument (or RESET-STATE is
1411 non-nil) then the state of the buffer (open/closed messages) is
1412 reset based on the original query."
1413   (interactive "P")
1414   (let ((inhibit-read-only t)
1415         (state (unless reset-state
1416                  (notmuch-show-capture-state))))
1417     ;; `erase-buffer' does not seem to remove overlays, which can lead
1418     ;; to weird effects such as remaining images, so remove them
1419     ;; manually.
1420     (remove-overlays)
1421     (erase-buffer)
1422     (unless (notmuch-show--build-buffer state)
1423       ;; No messages were inserted.
1424       (kill-buffer (current-buffer))
1425       (ding)
1426       (message "Refreshing the buffer resulted in no messages!"))))
1427
1428 ;;; Keymaps
1429
1430 (defvar notmuch-show-stash-map
1431   (let ((map (make-sparse-keymap)))
1432     (define-key map "c" 'notmuch-show-stash-cc)
1433     (define-key map "d" 'notmuch-show-stash-date)
1434     (define-key map "F" 'notmuch-show-stash-filename)
1435     (define-key map "f" 'notmuch-show-stash-from)
1436     (define-key map "i" 'notmuch-show-stash-message-id)
1437     (define-key map "I" 'notmuch-show-stash-message-id-stripped)
1438     (define-key map "s" 'notmuch-show-stash-subject)
1439     (define-key map "T" 'notmuch-show-stash-tags)
1440     (define-key map "t" 'notmuch-show-stash-to)
1441     (define-key map "l" 'notmuch-show-stash-mlarchive-link)
1442     (define-key map "L" 'notmuch-show-stash-mlarchive-link-and-go)
1443     (define-key map "G" 'notmuch-show-stash-git-send-email)
1444     (define-key map "?" 'notmuch-subkeymap-help)
1445     map)
1446   "Submap for stash commands.")
1447 (fset 'notmuch-show-stash-map notmuch-show-stash-map)
1448
1449 (defvar notmuch-show-part-map
1450   (let ((map (make-sparse-keymap)))
1451     (define-key map "s" 'notmuch-show-save-part)
1452     (define-key map "v" 'notmuch-show-view-part)
1453     (define-key map "o" 'notmuch-show-interactively-view-part)
1454     (define-key map "|" 'notmuch-show-pipe-part)
1455     (define-key map "m" 'notmuch-show-choose-mime-of-part)
1456     (define-key map "?" 'notmuch-subkeymap-help)
1457     map)
1458   "Submap for part commands.")
1459 (fset 'notmuch-show-part-map notmuch-show-part-map)
1460
1461 (defvar notmuch-show-mode-map
1462   (let ((map (make-sparse-keymap)))
1463     (set-keymap-parent map notmuch-common-keymap)
1464     (define-key map "Z" 'notmuch-tree-from-show-current-query)
1465     (define-key map "U" 'notmuch-unthreaded-from-show-current-query)
1466     (define-key map (kbd "<C-tab>") 'widget-backward)
1467     (define-key map (kbd "M-TAB") 'notmuch-show-previous-button)
1468     (define-key map (kbd "<backtab>") 'notmuch-show-previous-button)
1469     (define-key map (kbd "TAB") 'notmuch-show-next-button)
1470     (define-key map "f" 'notmuch-show-forward-message)
1471     (define-key map "F" 'notmuch-show-forward-open-messages)
1472     (define-key map "b" 'notmuch-show-resend-message)
1473     (define-key map "l" 'notmuch-show-filter-thread)
1474     (define-key map "r" 'notmuch-show-reply-sender)
1475     (define-key map "R" 'notmuch-show-reply)
1476     (define-key map "|" 'notmuch-show-pipe-message)
1477     (define-key map "w" 'notmuch-show-save-attachments)
1478     (define-key map "V" 'notmuch-show-view-raw-message)
1479     (define-key map "e" 'notmuch-show-resume-message)
1480     (define-key map "c" 'notmuch-show-stash-map)
1481     (define-key map "h" 'notmuch-show-toggle-visibility-headers)
1482     (define-key map "k" 'notmuch-tag-jump)
1483     (define-key map "*" 'notmuch-show-tag-all)
1484     (define-key map "-" 'notmuch-show-remove-tag)
1485     (define-key map "+" 'notmuch-show-add-tag)
1486     (define-key map "X" 'notmuch-show-archive-thread-then-exit)
1487     (define-key map "x" 'notmuch-show-archive-message-then-next-or-exit)
1488     (define-key map "A" 'notmuch-show-archive-thread-then-next)
1489     (define-key map "a" 'notmuch-show-archive-message-then-next-or-next-thread)
1490     (define-key map "N" 'notmuch-show-next-message)
1491     (define-key map "P" 'notmuch-show-previous-message)
1492     (define-key map "n" 'notmuch-show-next-open-message)
1493     (define-key map "p" 'notmuch-show-previous-open-message)
1494     (define-key map (kbd "M-n") 'notmuch-show-next-thread-show)
1495     (define-key map (kbd "M-p") 'notmuch-show-previous-thread-show)
1496     (define-key map (kbd "DEL") 'notmuch-show-rewind)
1497     (define-key map " " 'notmuch-show-advance-and-archive)
1498     (define-key map (kbd "M-RET") 'notmuch-show-open-or-close-all)
1499     (define-key map (kbd "RET") 'notmuch-show-toggle-message)
1500     (define-key map "#" 'notmuch-show-print-message)
1501     (define-key map "!" 'notmuch-show-toggle-elide-non-matching)
1502     (define-key map "$" 'notmuch-show-toggle-process-crypto)
1503     (define-key map "<" 'notmuch-show-toggle-thread-indentation)
1504     (define-key map "t" 'toggle-truncate-lines)
1505     (define-key map "." 'notmuch-show-part-map)
1506     (define-key map "B" 'notmuch-show-browse-urls)
1507     map)
1508   "Keymap for \"notmuch show\" buffers.")
1509
1510 ;;; Mode
1511
1512 (define-derived-mode notmuch-show-mode fundamental-mode "notmuch-show"
1513   "Major mode for viewing a thread with notmuch.
1514
1515 This buffer contains the results of the \"notmuch show\" command
1516 for displaying a single thread of email from your email archives.
1517
1518 By default, various components of email messages, (citations,
1519 signatures, already-read messages), are hidden. You can make
1520 these parts visible by clicking with the mouse button or by
1521 pressing RET after positioning the cursor on a hidden part, (for
1522 which \\[notmuch-show-next-button] and \\[notmuch-show-previous-button] are helpful).
1523
1524 Reading the thread sequentially is well-supported by pressing
1525 \\[notmuch-show-advance-and-archive]. This will scroll the current message (if necessary), advance
1526 to the next message, or advance to the next thread (if already on
1527 the last message of a thread).
1528
1529 Other commands are available to read or manipulate the thread
1530 more selectively, (such as '\\[notmuch-show-next-message]' and '\\[notmuch-show-previous-message]' to advance to messages
1531 without removing any tags, and '\\[notmuch-show-archive-thread]' to archive an entire thread
1532 without scrolling through with \\[notmuch-show-advance-and-archive]).
1533
1534 You can add or remove arbitrary tags from the current message with
1535 '\\[notmuch-show-add-tag]' or '\\[notmuch-show-remove-tag]'.
1536
1537 All currently available key bindings:
1538
1539 \\{notmuch-show-mode-map}"
1540   (setq notmuch-buffer-refresh-function #'notmuch-show-refresh-view)
1541   (setq buffer-read-only t)
1542   (setq truncate-lines t)
1543   (setq imenu-prev-index-position-function
1544         #'notmuch-show-imenu-prev-index-position-function)
1545   (setq imenu-extract-index-name-function
1546         #'notmuch-show-imenu-extract-index-name-function))
1547
1548 ;;; Tree commands
1549
1550 (defun notmuch-tree-from-show-current-query ()
1551   "Call notmuch tree with the current query."
1552   (interactive)
1553   (notmuch-tree notmuch-show-thread-id
1554                 notmuch-show-query-context
1555                 (notmuch-show-get-message-id)))
1556
1557 (defun notmuch-unthreaded-from-show-current-query ()
1558   "Call notmuch unthreaded with the current query."
1559   (interactive)
1560   (notmuch-unthreaded notmuch-show-thread-id
1561                       notmuch-show-query-context
1562                       (notmuch-show-get-message-id)))
1563
1564 ;;; Movement related functions.
1565
1566 (defun notmuch-show-move-to-message-top ()
1567   (goto-char (notmuch-show-message-top)))
1568
1569 (defun notmuch-show-move-to-message-bottom ()
1570   (goto-char (notmuch-show-message-bottom)))
1571
1572 ;; There's some strangeness here where a text property applied to a
1573 ;; region a->b is not found when point is at b. We walk backwards
1574 ;; until finding the property.
1575 (defun notmuch-show-message-extent ()
1576   "Return a cons cell containing the start and end buffer offset
1577 of the current message."
1578   (let (r)
1579     (save-excursion
1580       (while (not (setq r (get-text-property (point) :notmuch-message-extent)))
1581         (backward-char)))
1582     r))
1583
1584 (defun notmuch-show-message-top ()
1585   (car (notmuch-show-message-extent)))
1586
1587 (defun notmuch-show-message-bottom ()
1588   (cdr (notmuch-show-message-extent)))
1589
1590 (defun notmuch-show-goto-message-next ()
1591   (let ((start (point)))
1592     (notmuch-show-move-to-message-bottom)
1593     (if (not (eobp))
1594         t
1595       (goto-char start)
1596       nil)))
1597
1598 (defun notmuch-show-goto-message-previous ()
1599   (notmuch-show-move-to-message-top)
1600   (if (bobp)
1601       nil
1602     (backward-char)
1603     (notmuch-show-move-to-message-top)
1604     t))
1605
1606 (defun notmuch-show-mapc (function)
1607   "Iterate through all messages in the current thread with
1608 `notmuch-show-goto-message-next' and call FUNCTION for side
1609 effects."
1610   (save-excursion
1611     (goto-char (point-min))
1612     (cl-loop do (funcall function)
1613              while (notmuch-show-goto-message-next))))
1614
1615 ;;; Functions relating to the visibility of messages and their components.
1616
1617 (defun notmuch-show-message-visible (props visible-p)
1618   (overlay-put (plist-get props :message-overlay) 'invisible (not visible-p))
1619   (notmuch-show-set-prop :message-visible visible-p props))
1620
1621 (defun notmuch-show-headers-visible (props visible-p)
1622   (overlay-put (plist-get props :headers-overlay) 'invisible (not visible-p))
1623   (notmuch-show-set-prop :headers-visible visible-p props))
1624
1625 ;;; Functions for setting and getting attributes of the current message.
1626
1627 (defun notmuch-show-set-message-properties (props)
1628   (save-excursion
1629     (notmuch-show-move-to-message-top)
1630     (put-text-property (point) (+ (point) 1)
1631                        :notmuch-message-properties props)))
1632
1633 (defun notmuch-show-get-message-properties ()
1634   "Return the properties of the current message as a plist.
1635
1636 Some useful entries are:
1637 :headers - Property list containing the headers :Date, :Subject, :From, etc.
1638 :body - Body of the message
1639 :tags - Tags for this message"
1640   (save-excursion
1641     (notmuch-show-move-to-message-top)
1642     (get-text-property (point) :notmuch-message-properties)))
1643
1644 (defun notmuch-show-get-part-properties ()
1645   "Return the properties of the innermost part containing point.
1646
1647 This is the part property list retrieved from the CLI.  Signals
1648 an error if there is no part containing point."
1649   (or (get-text-property (point) :notmuch-part)
1650       (error "No message part here")))
1651
1652 (defun notmuch-show-set-prop (prop val &optional props)
1653   (let ((inhibit-read-only t)
1654         (props (or props
1655                    (notmuch-show-get-message-properties))))
1656     (plist-put props prop val)
1657     (notmuch-show-set-message-properties props)))
1658
1659 (defun notmuch-show-get-prop (prop &optional props)
1660   "Get property PROP from current message in show or tree mode.
1661
1662 It gets property PROP from PROPS or, if PROPS is nil, the current
1663 message in either tree or show. This means that several utility
1664 functions in notmuch-show can be used directly by notmuch-tree as
1665 they just need the correct message properties."
1666   (plist-get (or props
1667                  (cond ((eq major-mode 'notmuch-show-mode)
1668                         (notmuch-show-get-message-properties))
1669                        ((eq major-mode 'notmuch-tree-mode)
1670                         (notmuch-tree-get-message-properties))
1671                        (t nil)))
1672              prop))
1673
1674 (defun notmuch-show-get-message-id (&optional bare)
1675   "Return an id: query for the Message-Id of the current message.
1676
1677 If optional argument BARE is non-nil, return
1678 the Message-Id without id: prefix and escaping."
1679   (if bare
1680       (notmuch-show-get-prop :id)
1681     (notmuch-id-to-query (notmuch-show-get-prop :id))))
1682
1683 (defun notmuch-show-get-messages-ids ()
1684   "Return all id: queries of messages in the current thread."
1685   (let ((message-ids))
1686     (notmuch-show-mapc
1687      (lambda () (push (notmuch-show-get-message-id) message-ids)))
1688     message-ids))
1689
1690 (defun notmuch-show-get-messages-ids-search ()
1691   "Return a search string for all message ids of messages in the
1692 current thread."
1693   (mapconcat 'identity (notmuch-show-get-messages-ids) " or "))
1694
1695 ;; dme: Would it make sense to use a macro for many of these?
1696
1697 ;; XXX TODO figure out what to do about multiple filenames
1698 (defun notmuch-show-get-filename ()
1699   "Return the filename of the current message."
1700   (car (notmuch-show-get-prop :filename)))
1701
1702 (defun notmuch-show-get-header (header &optional props)
1703   "Return the named header of the current message, if any."
1704   (plist-get (notmuch-show-get-prop :headers props) header))
1705
1706 (defun notmuch-show-get-cc ()
1707   (notmuch-show-get-header :Cc))
1708
1709 (defun notmuch-show-get-date ()
1710   (notmuch-show-get-header :Date))
1711
1712 (defun notmuch-show-get-timestamp ()
1713   (notmuch-show-get-prop :timestamp))
1714
1715 (defun notmuch-show-get-from ()
1716   (notmuch-show-get-header :From))
1717
1718 (defun notmuch-show-get-subject ()
1719   (notmuch-show-get-header :Subject))
1720
1721 (defun notmuch-show-get-to ()
1722   (notmuch-show-get-header :To))
1723
1724 (defun notmuch-show-get-depth ()
1725   (notmuch-show-get-prop :depth))
1726
1727 (defun notmuch-show-set-tags (tags)
1728   "Set the tags of the current message."
1729   (notmuch-show-set-prop :tags tags)
1730   (notmuch-show-update-tags tags))
1731
1732 (defun notmuch-show-get-tags ()
1733   "Return the tags of the current message."
1734   (notmuch-show-get-prop :tags))
1735
1736 (defun notmuch-show-message-visible-p ()
1737   "Is the current message visible?"
1738   (notmuch-show-get-prop :message-visible))
1739
1740 (defun notmuch-show-headers-visible-p ()
1741   "Are the headers of the current message visible?"
1742   (notmuch-show-get-prop :headers-visible))
1743
1744 (put 'notmuch-show-mark-read 'notmuch-prefix-doc
1745      "Mark the current message as unread.")
1746 (defun notmuch-show-mark-read (&optional unread)
1747   "Mark the current message as read.
1748
1749 Mark the current message as read by applying the tag changes in
1750 `notmuch-show-mark-read-tags' to it (remove the \"unread\" tag by
1751 default). If a prefix argument is given, the message will be
1752 marked as unread, i.e. the tag changes in
1753 `notmuch-show-mark-read-tags' will be reversed."
1754   (interactive "P")
1755   (when notmuch-show-mark-read-tags
1756     (apply 'notmuch-show-tag-message
1757            (notmuch-tag-change-list notmuch-show-mark-read-tags unread))))
1758
1759 (defun notmuch-show-seen-current-message (_start _end)
1760   "Mark the current message read if it is open.
1761
1762 We only mark it read once: if it is changed back then that is a
1763 user decision and we should not override it."
1764   (when (and (notmuch-show-message-visible-p)
1765              (not (notmuch-show-get-prop :seen)))
1766     (notmuch-show-mark-read)
1767     (notmuch-show-set-prop :seen t)))
1768
1769 (defvar notmuch-show--seen-has-errored nil)
1770 (make-variable-buffer-local 'notmuch-show--seen-has-errored)
1771
1772 (defun notmuch-show-command-hook ()
1773   (when (eq major-mode 'notmuch-show-mode)
1774     ;; We need to redisplay to get window-start and window-end correct.
1775     (redisplay)
1776     (save-excursion
1777       (condition-case nil
1778           (funcall notmuch-show-mark-read-function (window-start) (window-end))
1779         ((debug error)
1780          (unless notmuch-show--seen-has-errored
1781            (setq notmuch-show--seen-has-errored t)
1782            (setq header-line-format
1783                  (concat header-line-format
1784                          (propertize
1785                           "  [some mark read tag changes may have failed]"
1786                           'face font-lock-warning-face)))))))))
1787
1788 (defun notmuch-show-filter-thread (query)
1789   "Filter or LIMIT the current thread based on a new query string.
1790
1791 Reshows the current thread with matches defined by the new query-string."
1792   (interactive (list (notmuch-read-query "Filter thread: ")))
1793   (let ((msg-id (notmuch-show-get-message-id)))
1794     (setq notmuch-show-query-context (if (string-empty-p query) nil query))
1795     (notmuch-show-refresh-view t)
1796     (notmuch-show-goto-message msg-id)))
1797
1798 ;;; Functions for getting attributes of several messages in the current thread.
1799
1800 (defun notmuch-show-get-message-ids-for-open-messages ()
1801   "Return a list of all id: queries for open messages in the current thread."
1802   (save-excursion
1803     (let (message-ids done)
1804       (goto-char (point-min))
1805       (while (not done)
1806         (when (notmuch-show-message-visible-p)
1807           (setq message-ids
1808                 (append message-ids (list (notmuch-show-get-message-id)))))
1809         (setq done (not (notmuch-show-goto-message-next))))
1810       message-ids)))
1811
1812 ;;; Commands typically bound to keys.
1813
1814 (defun notmuch-show-advance ()
1815   "Advance through thread.
1816
1817 If the current message in the thread is not yet fully visible,
1818 scroll by a near screenful to read more of the message.
1819
1820 Otherwise, (the end of the current message is already within the
1821 current window), advance to the next open message."
1822   (interactive)
1823   (let* ((end-of-this-message (notmuch-show-message-bottom))
1824          (visible-end-of-this-message (1- end-of-this-message))
1825          (ret nil))
1826     (while (invisible-p visible-end-of-this-message)
1827       (setq visible-end-of-this-message
1828             (max (point-min)
1829                  (1- (previous-single-char-property-change
1830                       visible-end-of-this-message 'invisible)))))
1831     (cond
1832      ;; Ideally we would test `end-of-this-message' against the result
1833      ;; of `window-end', but that doesn't account for the fact that
1834      ;; the end of the message might be hidden.
1835      ((and visible-end-of-this-message
1836            (> visible-end-of-this-message (window-end)))
1837       ;; The bottom of this message is not visible - scroll.
1838       (scroll-up nil))
1839      ((not (= end-of-this-message (point-max)))
1840       ;; This is not the last message - move to the next visible one.
1841       (notmuch-show-next-open-message))
1842      ((not (= (point) (point-max)))
1843       ;; This is the last message, but the cursor is not at the end of
1844       ;; the buffer. Move it there.
1845       (goto-char (point-max)))
1846      (t
1847       ;; This is the last message - change the return value
1848       (setq ret t)))
1849     ret))
1850
1851 (defun notmuch-show-advance-and-archive ()
1852   "Advance through thread and archive.
1853
1854 This command is intended to be one of the simplest ways to
1855 process a thread of email. It works exactly like
1856 notmuch-show-advance, in that it scrolls through messages in a
1857 show buffer, except that when it gets to the end of the buffer it
1858 archives the entire current thread, (apply changes in
1859 `notmuch-archive-tags'), kills the buffer, and displays the next
1860 thread from the search from which this thread was originally
1861 shown."
1862   (interactive)
1863   (when (notmuch-show-advance)
1864     (notmuch-show-archive-thread-then-next)))
1865
1866 (defun notmuch-show-rewind ()
1867   "Backup through the thread (reverse scrolling compared to \
1868 \\[notmuch-show-advance-and-archive]).
1869
1870 Specifically, if the beginning of the previous email is fewer
1871 than `window-height' lines from the current point, move to it
1872 just like `notmuch-show-previous-message'.
1873
1874 Otherwise, just scroll down a screenful of the current message.
1875
1876 This command does not modify any message tags, (it does not undo
1877 any effects from previous calls to
1878 `notmuch-show-advance-and-archive'."
1879   (interactive)
1880   (let ((start-of-message (notmuch-show-message-top))
1881         (start-of-window (window-start)))
1882     (cond
1883      ;; Either this message is properly aligned with the start of the
1884      ;; window or the start of this message is not visible on the
1885      ;; screen - scroll.
1886      ((or (= start-of-message start-of-window)
1887           (< start-of-message start-of-window))
1888       (scroll-down)
1889       ;; If a small number of lines from the previous message are
1890       ;; visible, realign so that the top of the current message is at
1891       ;; the top of the screen.
1892       (when (<= (count-screen-lines (window-start) start-of-message)
1893                 next-screen-context-lines)
1894         (goto-char (notmuch-show-message-top))
1895         (notmuch-show-message-adjust))
1896       ;; Move to the top left of the window.
1897       (goto-char (window-start)))
1898      (t
1899       ;; Move to the previous message.
1900       (notmuch-show-previous-message)))))
1901
1902 (put 'notmuch-show-reply 'notmuch-prefix-doc "... and prompt for sender")
1903 (defun notmuch-show-reply (&optional prompt-for-sender)
1904   "Reply to the sender and all recipients of the current message."
1905   (interactive "P")
1906   (notmuch-mua-new-reply (notmuch-show-get-message-id) prompt-for-sender t))
1907
1908 (put 'notmuch-show-reply-sender 'notmuch-prefix-doc "... and prompt for sender")
1909 (defun notmuch-show-reply-sender (&optional prompt-for-sender)
1910   "Reply to the sender of the current message."
1911   (interactive "P")
1912   (notmuch-mua-new-reply (notmuch-show-get-message-id) prompt-for-sender nil))
1913
1914 (put 'notmuch-show-forward-message 'notmuch-prefix-doc
1915      "... and prompt for sender")
1916 (defun notmuch-show-forward-message (&optional prompt-for-sender)
1917   "Forward the current message."
1918   (interactive "P")
1919   (notmuch-mua-new-forward-messages (list (notmuch-show-get-message-id))
1920                                     prompt-for-sender))
1921
1922 (put 'notmuch-show-forward-open-messages 'notmuch-prefix-doc
1923      "... and prompt for sender")
1924 (defun notmuch-show-forward-open-messages (&optional prompt-for-sender)
1925   "Forward the currently open messages."
1926   (interactive "P")
1927   (let ((open-messages (notmuch-show-get-message-ids-for-open-messages)))
1928     (unless open-messages
1929       (error "No open messages to forward."))
1930     (notmuch-mua-new-forward-messages open-messages prompt-for-sender)))
1931
1932 (defun notmuch-show-resend-message (addresses)
1933   "Resend the current message."
1934   (interactive (list (notmuch-address-from-minibuffer "Resend to: ")))
1935   (when (y-or-n-p (concat "Confirm resend to " addresses " "))
1936     (notmuch-show-view-raw-message)
1937     (message-resend addresses)
1938     (notmuch-bury-or-kill-this-buffer)))
1939
1940 (defun notmuch-show-message-adjust ()
1941   (recenter 0))
1942
1943 (defun notmuch-show-next-message (&optional pop-at-end)
1944   "Show the next message.
1945
1946 If a prefix argument is given and this is the last message in the
1947 thread, navigate to the next thread in the parent search buffer."
1948   (interactive "P")
1949   (if (notmuch-show-goto-message-next)
1950       (notmuch-show-message-adjust)
1951     (if pop-at-end
1952         (notmuch-show-next-thread)
1953       (goto-char (point-max)))))
1954
1955 (defun notmuch-show-previous-message ()
1956   "Show the previous message or the start of the current message."
1957   (interactive)
1958   (if (= (point) (notmuch-show-message-top))
1959       (notmuch-show-goto-message-previous)
1960     (notmuch-show-move-to-message-top))
1961   (notmuch-show-message-adjust))
1962
1963 (defun notmuch-show-next-open-message (&optional pop-at-end)
1964   "Show the next open message.
1965
1966 If a prefix argument is given and this is the last open message
1967 in the thread, navigate to the next thread in the parent search
1968 buffer. Return t if there was a next open message in the thread
1969 to show, nil otherwise."
1970   (interactive "P")
1971   (let (r)
1972     (while (and (setq r (notmuch-show-goto-message-next))
1973                 (not (notmuch-show-message-visible-p))))
1974     (if r
1975         (notmuch-show-message-adjust)
1976       (if pop-at-end
1977           (notmuch-show-next-thread)
1978         (goto-char (point-max))))
1979     r))
1980
1981 (defun notmuch-show-next-matching-message ()
1982   "Show the next matching message."
1983   (interactive)
1984   (let (r)
1985     (while (and (setq r (notmuch-show-goto-message-next))
1986                 (not (notmuch-show-get-prop :match))))
1987     (if r
1988         (notmuch-show-message-adjust)
1989       (goto-char (point-max)))))
1990
1991 (defun notmuch-show-open-if-matched ()
1992   "Open a message if it is matched (whether or not excluded)."
1993   (let ((props (notmuch-show-get-message-properties)))
1994     (notmuch-show-message-visible props (plist-get props :match))))
1995
1996 (defun notmuch-show-goto-first-wanted-message ()
1997   "Move to the first open message and mark it read."
1998   (goto-char (point-min))
1999   (unless (notmuch-show-message-visible-p)
2000     (notmuch-show-next-open-message))
2001   (when (eobp)
2002     ;; There are no matched non-excluded messages so open all matched
2003     ;; (necessarily excluded) messages and go to the first.
2004     (notmuch-show-mapc 'notmuch-show-open-if-matched)
2005     (force-window-update)
2006     (goto-char (point-min))
2007     (unless (notmuch-show-message-visible-p)
2008       (notmuch-show-next-open-message))))
2009
2010 (defun notmuch-show-previous-open-message ()
2011   "Show the previous open message."
2012   (interactive)
2013   (while (and (if (= (point) (notmuch-show-message-top))
2014                   (notmuch-show-goto-message-previous)
2015                 (notmuch-show-move-to-message-top))
2016               (not (notmuch-show-message-visible-p))))
2017   (notmuch-show-message-adjust))
2018
2019 (defun notmuch-show-view-raw-message ()
2020   "View the original source of the current message."
2021   (interactive)
2022   (let* ((id (notmuch-show-get-message-id))
2023          (buf (get-buffer-create (concat "*notmuch-raw-" id "*")))
2024          (inhibit-read-only t))
2025     (pop-to-buffer-same-window buf)
2026     (erase-buffer)
2027     (let ((coding-system-for-read 'no-conversion))
2028       (call-process notmuch-command nil t nil "show" "--format=raw" id))
2029     (goto-char (point-min))
2030     (set-buffer-modified-p nil)
2031     (setq buffer-read-only t)
2032     (view-buffer buf 'kill-buffer-if-not-modified)))
2033
2034 (defun notmuch-show-resume-message ()
2035   "Resume EDITING the current draft message."
2036   (interactive)
2037   (notmuch-draft-resume (notmuch-show-get-message-id)))
2038
2039 (put 'notmuch-show-pipe-message 'notmuch-doc
2040      "Pipe the contents of the current message to a command.")
2041 (put 'notmuch-show-pipe-message 'notmuch-prefix-doc
2042      "Pipe the thread as an mbox to a command.")
2043 (defun notmuch-show-pipe-message (entire-thread command)
2044   "Pipe the contents of the current message (or thread) to COMMAND.
2045
2046 COMMAND will be executed with the raw contents of the current
2047 email message as stdin. Anything printed by the command to stdout
2048 or stderr will appear in the *notmuch-pipe* buffer.
2049
2050 If ENTIRE-THREAD is non-nil (or when invoked with a prefix
2051 argument), COMMAND will receive all open messages in the current
2052 thread (formatted as an mbox) rather than only the current
2053 message."
2054   (interactive (let ((query-string (if current-prefix-arg
2055                                        "Pipe all open messages to command: "
2056                                      "Pipe message to command: ")))
2057                  (list current-prefix-arg (read-string query-string))))
2058   (let (shell-command)
2059     (if entire-thread
2060         (setq shell-command
2061               (concat notmuch-command " show --format=mbox --exclude=false "
2062                       (shell-quote-argument
2063                        (mapconcat 'identity
2064                                   (notmuch-show-get-message-ids-for-open-messages)
2065                                   " OR "))
2066                       " | " command))
2067       (setq shell-command
2068             (concat notmuch-command " show --format=raw "
2069                     (shell-quote-argument (notmuch-show-get-message-id))
2070                     " | " command)))
2071     (let ((cwd default-directory)
2072           (buf (get-buffer-create (concat "*notmuch-pipe*"))))
2073       (with-current-buffer buf
2074         (setq buffer-read-only nil)
2075         (erase-buffer)
2076         ;; Use the originating buffer's working directory instead of
2077         ;; that of the pipe buffer.
2078         (cd cwd)
2079         (let ((exit-code (call-process-shell-command shell-command nil buf)))
2080           (goto-char (point-max))
2081           (set-buffer-modified-p nil)
2082           (setq buffer-read-only t)
2083           (unless (zerop exit-code)
2084             (pop-to-buffer buf)
2085             (message (format "Command '%s' exited abnormally with code %d"
2086                              shell-command exit-code))))))))
2087
2088 (defun notmuch-show-tag-message (&rest tag-changes)
2089   "Change tags for the current message.
2090
2091 TAG-CHANGES is a list of tag operations for `notmuch-tag'."
2092   (let* ((current-tags (notmuch-show-get-tags))
2093          (new-tags (notmuch-update-tags current-tags tag-changes)))
2094     (unless (equal current-tags new-tags)
2095       (notmuch-tag (notmuch-show-get-message-id) tag-changes)
2096       (notmuch-show-set-tags new-tags))))
2097
2098 (defun notmuch-show-tag (tag-changes)
2099   "Change tags for the current message.
2100
2101 See `notmuch-tag' for information on the format of TAG-CHANGES."
2102   (interactive (list (notmuch-read-tag-changes (notmuch-show-get-tags)
2103                                                "Tag message")))
2104   (notmuch-tag (notmuch-show-get-message-id) tag-changes)
2105   (let* ((current-tags (notmuch-show-get-tags))
2106          (new-tags (notmuch-update-tags current-tags tag-changes)))
2107     (unless (equal current-tags new-tags)
2108       (notmuch-show-set-tags new-tags))))
2109
2110 (defun notmuch-show-tag-all (tag-changes)
2111   "Change tags for all messages in the current show buffer.
2112
2113 See `notmuch-tag' for information on the format of TAG-CHANGES."
2114   (interactive
2115    (list (let (tags)
2116            (notmuch-show-mapc
2117             (lambda () (setq tags (append (notmuch-show-get-tags) tags))))
2118            (notmuch-read-tag-changes tags "Tag thread"))))
2119   (notmuch-tag (notmuch-show-get-messages-ids-search) tag-changes)
2120   (notmuch-show-mapc
2121    (lambda ()
2122      (let* ((current-tags (notmuch-show-get-tags))
2123             (new-tags (notmuch-update-tags current-tags tag-changes)))
2124        (unless (equal current-tags new-tags)
2125          (notmuch-show-set-tags new-tags))))))
2126
2127 (defun notmuch-show-add-tag (tag-changes)
2128   "Change tags for the current message (defaulting to add).
2129
2130 Same as `notmuch-show-tag' but sets initial input to '+'."
2131   (interactive
2132    (list (notmuch-read-tag-changes (notmuch-show-get-tags) "Tag message" "+")))
2133   (notmuch-show-tag tag-changes))
2134
2135 (defun notmuch-show-remove-tag (tag-changes)
2136   "Change tags for the current message (defaulting to remove).
2137
2138 Same as `notmuch-show-tag' but sets initial input to '-'."
2139   (interactive
2140    (list (notmuch-read-tag-changes (notmuch-show-get-tags) "Tag message" "-")))
2141   (notmuch-show-tag tag-changes))
2142
2143 (defun notmuch-show-toggle-visibility-headers ()
2144   "Toggle the visibility of the current message headers."
2145   (interactive)
2146   (let ((props (notmuch-show-get-message-properties)))
2147     (notmuch-show-headers-visible
2148      props
2149      (not (plist-get props :headers-visible))))
2150   (force-window-update))
2151
2152 (defun notmuch-show-toggle-message ()
2153   "Toggle the visibility of the current message."
2154   (interactive)
2155   (let ((props (notmuch-show-get-message-properties)))
2156     (notmuch-show-message-visible
2157      props
2158      (not (plist-get props :message-visible))))
2159   (force-window-update))
2160
2161 (put 'notmuch-show-open-or-close-all 'notmuch-doc "Show all messages.")
2162 (put 'notmuch-show-open-or-close-all 'notmuch-prefix-doc "Hide all messages.")
2163 (defun notmuch-show-open-or-close-all ()
2164   "Set the visibility all of the messages in the current thread.
2165
2166 By default make all of the messages visible. With a prefix
2167 argument, hide all of the messages."
2168   (interactive)
2169   (save-excursion
2170     (goto-char (point-min))
2171     (cl-loop do (notmuch-show-message-visible
2172                  (notmuch-show-get-message-properties)
2173                  (not current-prefix-arg))
2174              until (not (notmuch-show-goto-message-next))))
2175   (force-window-update))
2176
2177 (defun notmuch-show-next-button ()
2178   "Advance point to the next button in the buffer."
2179   (interactive)
2180   (forward-button 1))
2181
2182 (defun notmuch-show-previous-button ()
2183   "Move point back to the previous button in the buffer."
2184   (interactive)
2185   (backward-button 1))
2186
2187 (defun notmuch-show-next-thread (&optional show previous)
2188   "Move to the next item in the search results, if any.
2189
2190 If SHOW is non-nil, open the next item in a show
2191 buffer. Otherwise just highlight the next item in the search
2192 buffer. If PREVIOUS is non-nil, move to the previous item in the
2193 search results instead."
2194   (interactive "P")
2195   (let ((parent-buffer notmuch-show-parent-buffer))
2196     (notmuch-bury-or-kill-this-buffer)
2197     (when (buffer-live-p parent-buffer)
2198       (switch-to-buffer parent-buffer)
2199       (and (if previous
2200                (notmuch-search-previous-thread)
2201              (notmuch-search-next-thread))
2202            show
2203            (notmuch-search-show-thread)))))
2204
2205 (defun notmuch-show-next-thread-show ()
2206   "Show the next thread in the search results, if any."
2207   (interactive)
2208   (notmuch-show-next-thread t))
2209
2210 (defun notmuch-show-previous-thread-show ()
2211   "Show the previous thread in the search results, if any."
2212   (interactive)
2213   (notmuch-show-next-thread t t))
2214
2215 (put 'notmuch-show-archive-thread 'notmuch-prefix-doc
2216      "Un-archive each message in thread.")
2217 (defun notmuch-show-archive-thread (&optional unarchive)
2218   "Archive each message in thread.
2219
2220 Archive each message currently shown by applying the tag changes
2221 in `notmuch-archive-tags' to each. If a prefix argument is given,
2222 the messages will be \"unarchived\", i.e. the tag changes in
2223 `notmuch-archive-tags' will be reversed.
2224
2225 Note: This command is safe from any race condition of new messages
2226 being delivered to the same thread. It does not archive the
2227 entire thread, but only the messages shown in the current
2228 buffer."
2229   (interactive "P")
2230   (when notmuch-archive-tags
2231     (notmuch-show-tag-all
2232      (notmuch-tag-change-list notmuch-archive-tags unarchive))))
2233
2234 (defun notmuch-show-archive-thread-then-next ()
2235   "Archive all messages in the current buffer, then show next thread from search."
2236   (interactive)
2237   (notmuch-show-archive-thread)
2238   (notmuch-show-next-thread t))
2239
2240 (defun notmuch-show-archive-thread-then-exit ()
2241   "Archive all messages in the current buffer, then exit back to search results."
2242   (interactive)
2243   (notmuch-show-archive-thread)
2244   (notmuch-show-next-thread))
2245
2246 (put 'notmuch-show-archive-message 'notmuch-prefix-doc
2247      "Un-archive the current message.")
2248 (defun notmuch-show-archive-message (&optional unarchive)
2249   "Archive the current message.
2250
2251 Archive the current message by applying the tag changes in
2252 `notmuch-archive-tags' to it. If a prefix argument is given, the
2253 message will be \"unarchived\", i.e. the tag changes in
2254 `notmuch-archive-tags' will be reversed."
2255   (interactive "P")
2256   (when notmuch-archive-tags
2257     (apply 'notmuch-show-tag-message
2258            (notmuch-tag-change-list notmuch-archive-tags unarchive))))
2259
2260 (defun notmuch-show-archive-message-then-next-or-exit ()
2261   "Archive current message, then show next open message in current thread.
2262
2263 If at the last open message in the current thread, then exit back
2264 to search results."
2265   (interactive)
2266   (notmuch-show-archive-message)
2267   (notmuch-show-next-open-message t))
2268
2269 (defun notmuch-show-archive-message-then-next-or-next-thread ()
2270   "Archive current message, then show next open message in current or next thread.
2271
2272 If at the last open message in the current thread, then show next
2273 thread from search."
2274   (interactive)
2275   (notmuch-show-archive-message)
2276   (unless (notmuch-show-next-open-message)
2277     (notmuch-show-next-thread t)))
2278
2279 (defun notmuch-show-stash-cc ()
2280   "Copy CC field of current message to kill-ring."
2281   (interactive)
2282   (notmuch-common-do-stash (notmuch-show-get-cc)))
2283
2284 (put 'notmuch-show-stash-date 'notmuch-prefix-doc
2285      "Copy timestamp of current message to kill-ring.")
2286 (defun notmuch-show-stash-date (&optional stash-timestamp)
2287   "Copy date of current message to kill-ring.
2288
2289 If invoked with a prefix argument, copy timestamp of current
2290 message to kill-ring."
2291   (interactive "P")
2292   (if stash-timestamp
2293       (notmuch-common-do-stash (format "%d" (notmuch-show-get-timestamp)))
2294     (notmuch-common-do-stash (notmuch-show-get-date))))
2295
2296 (defun notmuch-show-stash-filename ()
2297   "Copy filename of current message to kill-ring."
2298   (interactive)
2299   (notmuch-common-do-stash (notmuch-show-get-filename)))
2300
2301 (defun notmuch-show-stash-from ()
2302   "Copy From address of current message to kill-ring."
2303   (interactive)
2304   (notmuch-common-do-stash (notmuch-show-get-from)))
2305
2306 (put 'notmuch-show-stash-message-id 'notmuch-prefix-doc
2307      "Copy thread: query matching current thread to kill-ring.")
2308 (defun notmuch-show-stash-message-id (&optional stash-thread-id)
2309   "Copy id: query matching the current message to kill-ring.
2310
2311 If invoked with a prefix argument (or STASH-THREAD-ID is
2312 non-nil), copy thread: query matching the current thread to
2313 kill-ring."
2314   (interactive "P")
2315   (if stash-thread-id
2316       (notmuch-common-do-stash notmuch-show-thread-id)
2317     (notmuch-common-do-stash (notmuch-show-get-message-id))))
2318
2319 (defun notmuch-show-stash-message-id-stripped ()
2320   "Copy message ID of current message (sans `id:' prefix) to kill-ring."
2321   (interactive)
2322   (notmuch-common-do-stash (notmuch-show-get-message-id t)))
2323
2324 (defun notmuch-show-stash-subject ()
2325   "Copy Subject field of current message to kill-ring."
2326   (interactive)
2327   (notmuch-common-do-stash (notmuch-show-get-subject)))
2328
2329 (defun notmuch-show-stash-tags ()
2330   "Copy tags of current message to kill-ring as a comma separated list."
2331   (interactive)
2332   (notmuch-common-do-stash (mapconcat 'identity (notmuch-show-get-tags) ",")))
2333
2334 (defun notmuch-show-stash-to ()
2335   "Copy To address of current message to kill-ring."
2336   (interactive)
2337   (notmuch-common-do-stash (notmuch-show-get-to)))
2338
2339 (defun notmuch-show-stash-mlarchive-link (&optional mla)
2340   "Copy an ML Archive URI for the current message to the kill-ring.
2341
2342 This presumes that the message is available at the selected Mailing List Archive.
2343
2344 If optional argument MLA is non-nil, use the provided key instead of prompting
2345 the user (see `notmuch-show-stash-mlarchive-link-alist')."
2346   (interactive)
2347   (let ((url (cdr (assoc
2348                    (or mla
2349                        (let ((completion-ignore-case t))
2350                          (completing-read
2351                           "Mailing List Archive: "
2352                           notmuch-show-stash-mlarchive-link-alist
2353                           nil t nil nil
2354                           notmuch-show-stash-mlarchive-link-default)))
2355                    notmuch-show-stash-mlarchive-link-alist))))
2356     (notmuch-common-do-stash
2357      (if (functionp url)
2358          (funcall url (notmuch-show-get-message-id t))
2359        (concat url (notmuch-show-get-message-id t))))))
2360
2361 (defun notmuch-show-stash-mlarchive-link-and-go (&optional mla)
2362   "Copy an ML Archive URI for the current message to the kill-ring and visit it.
2363
2364 This presumes that the message is available at the selected Mailing List Archive.
2365
2366 If optional argument MLA is non-nil, use the provided key instead of prompting
2367 the user (see `notmuch-show-stash-mlarchive-link-alist')."
2368   (interactive)
2369   (notmuch-show-stash-mlarchive-link mla)
2370   (browse-url (current-kill 0 t)))
2371
2372 (defun notmuch-show-stash-git-helper (addresses prefix)
2373   "Normalize all ADDRESSES while adding PREFIX.
2374 Escape, trim, quote and add PREFIX to each address in list
2375 of ADDRESSES, and return the result as a single string."
2376   (mapconcat (lambda (x)
2377                (concat prefix "\""
2378                        ;; escape double-quotes
2379                        (replace-regexp-in-string
2380                         "\"" "\\\\\""
2381                         ;; trim leading and trailing spaces
2382                         (replace-regexp-in-string
2383                          "\\(^ *\\| *$\\)" ""
2384                          x)) "\""))
2385              addresses " "))
2386
2387 (put 'notmuch-show-stash-git-send-email 'notmuch-prefix-doc
2388      "Copy From/To/Cc of current message to kill-ring.
2389 Use a form suitable for pasting to git send-email command line.")
2390
2391 (defun notmuch-show-stash-git-send-email (&optional no-in-reply-to)
2392   "Copy From/To/Cc/Message-Id of current message to kill-ring.
2393 Use a form suitable for pasting to git send-email command line.
2394
2395 If invoked with a prefix argument (or NO-IN-REPLY-TO is non-nil),
2396 omit --in-reply-to=<Message-Id>."
2397   (interactive "P")
2398   (notmuch-common-do-stash
2399    (mapconcat 'identity
2400               (remove ""
2401                       (list
2402                        (notmuch-show-stash-git-helper
2403                         (message-tokenize-header (notmuch-show-get-from)) "--to=")
2404                        (notmuch-show-stash-git-helper
2405                         (message-tokenize-header (notmuch-show-get-to)) "--to=")
2406                        (notmuch-show-stash-git-helper
2407                         (message-tokenize-header (notmuch-show-get-cc)) "--cc=")
2408                        (unless no-in-reply-to
2409                          (notmuch-show-stash-git-helper
2410                           (list (notmuch-show-get-message-id t)) "--in-reply-to="))))
2411               " ")))
2412
2413 ;;; Interactive part functions and their helpers
2414
2415 (defun notmuch-show-generate-part-buffer (msg part)
2416   "Return a temporary buffer containing the specified part's content."
2417   (let ((buf (generate-new-buffer " *notmuch-part*"))
2418         (process-crypto notmuch-show-process-crypto))
2419     (with-current-buffer buf
2420       ;; This is always used in the content of mm handles, which
2421       ;; expect undecoded, binary part content.
2422       (insert (notmuch-get-bodypart-binary msg part process-crypto)))
2423     buf))
2424
2425 (defun notmuch-show-current-part-handle (&optional mime-type)
2426   "Return an mm-handle for the part containing point.
2427
2428 This creates a temporary buffer for the part's content; the
2429 caller is responsible for killing this buffer as appropriate.  If
2430 MIME-TYPE is given then set the handle's mime-type to MIME-TYPE."
2431   (let* ((msg (notmuch-show-get-message-properties))
2432          (part (notmuch-show-get-part-properties))
2433          (buf (notmuch-show-generate-part-buffer msg part))
2434          (computed-type (or mime-type (plist-get part :computed-type)))
2435          (filename (plist-get part :filename))
2436          (disposition (and filename `(attachment (filename . ,filename)))))
2437     (mm-make-handle buf (list computed-type) nil nil disposition)))
2438
2439 (defun notmuch-show-apply-to-current-part-handle (fn &optional mime-type)
2440   "Apply FN to an mm-handle for the part containing point.
2441
2442 This ensures that the temporary buffer created for the mm-handle
2443 is destroyed when FN returns. If MIME-TYPE is given then force
2444 part to be treated as if it had that mime-type."
2445   (let ((handle (notmuch-show-current-part-handle mime-type)))
2446     ;; Emacs puts stdout/stderr into the calling buffer so we call
2447     ;; it from a temp-buffer, unless notmuch-show-attachment-debug
2448     ;; is non-nil, in which case we put it in " *notmuch-part*".
2449     (unwind-protect
2450         (if notmuch-show-attachment-debug
2451             (with-current-buffer (generate-new-buffer " *notmuch-part*")
2452               (funcall fn handle))
2453           (with-temp-buffer
2454             (funcall fn handle)))
2455       (kill-buffer (mm-handle-buffer handle)))))
2456
2457 (defun notmuch-show-part-button-default (&optional button)
2458   (interactive)
2459   (let ((button (or button (button-at (point)))))
2460     ;; Try to toggle the part, if that fails then call the default
2461     ;; action. The toggle fails if the part has no emacs renderable
2462     ;; content.
2463     (unless (notmuch-show-toggle-part-invisibility button)
2464       (call-interactively notmuch-show-part-button-default-action))))
2465
2466 (defun notmuch-show-save-part ()
2467   "Save the MIME part containing point to a file."
2468   (interactive)
2469   (notmuch-show-apply-to-current-part-handle #'mm-save-part))
2470
2471 (defun notmuch-show-view-part ()
2472   "View the MIME part containing point in an external viewer."
2473   (interactive)
2474   ;; Set mm-inlined-types to nil to force an external viewer
2475   (let ((mm-inlined-types nil))
2476     (notmuch-show-apply-to-current-part-handle #'mm-display-part)))
2477
2478 (defun notmuch-show-interactively-view-part ()
2479   "View the MIME part containing point, prompting for a viewer."
2480   (interactive)
2481   (notmuch-show-apply-to-current-part-handle #'mm-interactively-view-part))
2482
2483 (defun notmuch-show-pipe-part ()
2484   "Pipe the MIME part containing point to an external command."
2485   (interactive)
2486   (notmuch-show-apply-to-current-part-handle #'mm-pipe-part))
2487
2488 (defun notmuch-show--mm-display-part (handle)
2489   "Use mm-display-part to display HANDLE in a new buffer.
2490
2491 If the part is displayed in an external application then close
2492 the new buffer."
2493   (let ((buf (get-buffer-create (generate-new-buffer-name
2494                                  (concat " *notmuch-internal-part*")))))
2495     (pop-to-buffer-same-window buf)
2496     (if (eq (mm-display-part handle) 'external)
2497         (kill-buffer buf)
2498       (goto-char (point-min))
2499       (set-buffer-modified-p nil)
2500       (view-buffer buf 'kill-buffer-if-not-modified))))
2501
2502 (defun notmuch-show-choose-mime-of-part (mime-type)
2503   "Choose the mime type to use for displaying part."
2504   (interactive
2505    (list (completing-read "Mime type to use (default text/plain): "
2506                           (mailcap-mime-types) nil nil nil nil "text/plain")))
2507   (notmuch-show-apply-to-current-part-handle #'notmuch-show--mm-display-part
2508                                              mime-type))
2509
2510 (defun notmuch-show-imenu-prev-index-position-function ()
2511   "Move point to previous message in notmuch-show buffer.
2512 This function is used as a value for
2513 `imenu-prev-index-position-function'."
2514   (if (bobp)
2515       nil
2516     (notmuch-show-previous-message)
2517     t))
2518
2519 (defun notmuch-show-imenu-extract-index-name-function ()
2520   "Return imenu name for line at point.
2521 This function is used as a value for
2522 `imenu-extract-index-name-function'.  Point should be at the
2523 beginning of the line."
2524   (back-to-indentation)
2525   (buffer-substring-no-properties (if notmuch-show-imenu-indent
2526                                       (line-beginning-position)
2527                                     (point))
2528                                   (line-end-position)))
2529
2530 (defmacro notmuch-show--with-currently-shown-message (&rest body)
2531   "Evaluate BODY with display restricted to the currently shown
2532 message."
2533   `(save-excursion
2534      (save-restriction
2535        (let ((extent (notmuch-show-message-extent)))
2536          (narrow-to-region (car extent) (cdr extent))
2537          ,@body))))
2538
2539 (defun notmuch-show--gather-urls ()
2540   "Gather any URLs in the current message."
2541   (notmuch-show--with-currently-shown-message
2542    (let (urls)
2543      (goto-char (point-min))
2544      (while (re-search-forward goto-address-url-regexp (point-max) t)
2545        (push (match-string-no-properties 0) urls))
2546      (reverse urls))))
2547
2548 (defun notmuch-show-browse-urls (&optional kill)
2549   "Offer to browse any URLs in the current message.
2550 With a prefix argument, copy the URL to the kill ring rather than
2551 browsing."
2552   (interactive "P")
2553   (let ((urls (notmuch-show--gather-urls))
2554         (prompt (if kill "Copy URL to kill ring: " "Browse URL: "))
2555         (fn (if kill #'kill-new #'browse-url)))
2556     (if urls
2557         (funcall fn (completing-read prompt urls nil nil nil nil (car urls)))
2558       (message "No URLs found."))))
2559
2560 ;;; _
2561
2562 (provide 'notmuch-show)
2563
2564 ;;; notmuch-show.el ends here