configure: fix reference to possibly undefined $PKG_CONFIG_PATH
[notmuch] / emacs / notmuch-show.el
1 ;;; notmuch-show.el --- displaying notmuch forests.
2 ;;
3 ;; Copyright © Carl Worth
4 ;; Copyright © David Edmondson
5 ;;
6 ;; This file is part of Notmuch.
7 ;;
8 ;; Notmuch is free software: you can redistribute it and/or modify it
9 ;; under the terms of the GNU General Public License as published by
10 ;; the Free Software Foundation, either version 3 of the License, or
11 ;; (at your option) any later version.
12 ;;
13 ;; Notmuch is distributed in the hope that it will be useful, but
14 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
16 ;; General Public License for more details.
17 ;;
18 ;; You should have received a copy of the GNU General Public License
19 ;; along with Notmuch.  If not, see <https://www.gnu.org/licenses/>.
20 ;;
21 ;; Authors: Carl Worth <cworth@cworth.org>
22 ;;          David Edmondson <dme@dme.org>
23
24 ;;; Code:
25
26 (eval-when-compile (require 'cl))
27 (require 'mm-view)
28 (require 'message)
29 (require 'mm-decode)
30 (require 'mailcap)
31 (require 'icalendar)
32 (require 'goto-addr)
33
34 (require 'notmuch-lib)
35 (require 'notmuch-tag)
36 (require 'notmuch-query)
37 (require 'notmuch-wash)
38 (require 'notmuch-mua)
39 (require 'notmuch-crypto)
40 (require 'notmuch-print)
41 (require 'notmuch-draft)
42
43 (declare-function notmuch-call-notmuch-process "notmuch" (&rest args))
44 (declare-function notmuch-search-next-thread "notmuch" nil)
45 (declare-function notmuch-search-previous-thread "notmuch" nil)
46 (declare-function notmuch-search-show-thread "notmuch" nil)
47 (declare-function notmuch-foreach-mime-part "notmuch" (function mm-handle))
48 (declare-function notmuch-count-attachments "notmuch" (mm-handle))
49 (declare-function notmuch-save-attachments "notmuch" (mm-handle &optional queryp))
50 (declare-function notmuch-tree "notmuch-tree"
51                   (&optional query query-context target buffer-name open-target))
52 (declare-function notmuch-tree-get-message-properties "notmuch-tree" nil)
53 (declare-function notmuch-read-query "notmuch" (prompt))
54 (declare-function notmuch-draft-resume "notmuch-draft" (id))
55
56 (defcustom notmuch-message-headers '("Subject" "To" "Cc" "Date")
57   "Headers that should be shown in a message, in this order.
58
59 For an open message, all of these headers will be made visible
60 according to `notmuch-message-headers-visible' or can be toggled
61 with `notmuch-show-toggle-visibility-headers'. For a closed message,
62 only the first header in the list will be visible."
63   :type '(repeat string)
64   :group 'notmuch-show)
65
66 (defcustom notmuch-message-headers-visible t
67   "Should the headers be visible by default?
68
69 If this value is non-nil, then all of the headers defined in
70 `notmuch-message-headers' will be visible by default in the display
71 of each message. Otherwise, these headers will be hidden and
72 `notmuch-show-toggle-visibility-headers' can be used to make them
73 visible for any given message."
74   :type 'boolean
75   :group 'notmuch-show)
76
77 (defcustom notmuch-show-relative-dates t
78   "Display relative dates in the message summary line."
79   :type 'boolean
80   :group 'notmuch-show)
81
82 (defvar notmuch-show-markup-headers-hook '(notmuch-show-colour-headers)
83   "A list of functions called to decorate the headers listed in
84 `notmuch-message-headers'.")
85
86 (defcustom notmuch-show-hook '(notmuch-show-turn-on-visual-line-mode)
87   "Functions called after populating a `notmuch-show' buffer."
88   :type 'hook
89   :options '(notmuch-show-turn-on-visual-line-mode)
90   :group 'notmuch-show
91   :group 'notmuch-hooks)
92
93 (defcustom notmuch-show-insert-text/plain-hook '(notmuch-wash-wrap-long-lines
94                                                  notmuch-wash-tidy-citations
95                                                  notmuch-wash-elide-blank-lines
96                                                  notmuch-wash-excerpt-citations)
97   "Functions used to improve the display of text/plain parts."
98   :type 'hook
99   :options '(notmuch-wash-convert-inline-patch-to-part
100              notmuch-wash-wrap-long-lines
101              notmuch-wash-tidy-citations
102              notmuch-wash-elide-blank-lines
103              notmuch-wash-excerpt-citations)
104   :group 'notmuch-show
105   :group 'notmuch-hooks)
106
107 (defcustom notmuch-show-max-text-part-size 100000
108   "Maximum size of a text part to be shown by default in characters.
109
110 Set to 0 to show the part regardless of size."
111   :type 'integer
112   :group 'notmuch-show)
113
114 ;; Mostly useful for debugging.
115 (defcustom notmuch-show-all-multipart/alternative-parts nil
116   "Should all parts of multipart/alternative parts be shown?"
117   :type 'boolean
118   :group 'notmuch-show)
119
120 (defcustom notmuch-show-indent-messages-width 1
121   "Width of message indentation in threads.
122
123 Messages are shown indented according to their depth in a thread.
124 This variable determines the width of this indentation measured
125 in number of blanks.  Defaults to `1', choose `0' to disable
126 indentation."
127   :type 'integer
128   :group 'notmuch-show)
129
130 (defcustom notmuch-show-indent-multipart nil
131   "Should the sub-parts of a multipart/* part be indented?"
132   ;; dme: Not sure which is a good default.
133   :type 'boolean
134   :group 'notmuch-show)
135
136 (defcustom notmuch-show-part-button-default-action 'notmuch-show-save-part
137   "Default part header button action (on ENTER or mouse click)."
138   :group 'notmuch-show
139   :type '(choice (const :tag "Save part"
140                         notmuch-show-save-part)
141                  (const :tag "View part"
142                         notmuch-show-view-part)
143                  (const :tag "View interactively"
144                         notmuch-show-interactively-view-part)))
145
146 (defcustom notmuch-show-only-matching-messages nil
147   "Only matching messages are shown by default."
148   :type 'boolean
149   :group 'notmuch-show)
150
151 ;; By default, block all external images to prevent privacy leaks and
152 ;; potential attacks.
153 (defcustom notmuch-show-text/html-blocked-images "."
154   "Remote images that have URLs matching this regexp will be blocked."
155   :type '(choice (const nil) regexp)
156   :group 'notmuch-show)
157
158 (defvar notmuch-show-thread-id nil)
159 (make-variable-buffer-local 'notmuch-show-thread-id)
160
161 (defvar notmuch-show-parent-buffer nil)
162 (make-variable-buffer-local 'notmuch-show-parent-buffer)
163
164 (defvar notmuch-show-query-context nil)
165 (make-variable-buffer-local 'notmuch-show-query-context)
166
167 (defvar notmuch-show-process-crypto nil)
168 (make-variable-buffer-local 'notmuch-show-process-crypto)
169
170 (defvar notmuch-show-elide-non-matching-messages nil)
171 (make-variable-buffer-local 'notmuch-show-elide-non-matching-messages)
172
173 (defvar notmuch-show-indent-content t)
174 (make-variable-buffer-local 'notmuch-show-indent-content)
175
176 (defvar notmuch-show-attachment-debug nil
177   "If t log stdout and stderr from attachment handlers
178
179 When set to nil (the default) stdout and stderr from attachment
180 handlers is discarded. When set to t the stdout and stderr from
181 each attachment handler is logged in buffers with names beginning
182 \" *notmuch-part*\". This option requires emacs version at least
183 24.3 to work.")
184
185 (defcustom notmuch-show-stash-mlarchive-link-alist
186   '(("Gmane" . "https://mid.gmane.org/")
187     ("MARC" . "https://marc.info/?i=")
188     ("Mail Archive, The" . "https://mid.mail-archive.com/")
189     ("LKML" . "https://lkml.kernel.org/r/")
190     ;; FIXME: can these services be searched by `Message-Id' ?
191     ;; ("MarkMail" . "http://markmail.org/")
192     ;; ("Nabble" . "http://nabble.com/")
193     ;; ("opensubscriber" . "http://opensubscriber.com/")
194     )
195   "List of Mailing List Archives to use when stashing links.
196
197 This list is used for generating a Mailing List Archive reference
198 URI with the current message's Message-Id in
199 `notmuch-show-stash-mlarchive-link'.
200
201 If the cdr of the alist element is not a function, the cdr is
202 expected to contain a URI that is concatenated with the current
203 message's Message-Id to create a ML archive reference URI.
204
205 If the cdr is a function, the function is called with the
206 Message-Id as the argument, and the function is expected to
207 return the ML archive reference URI."
208   :type '(alist :key-type (string :tag "Name")
209                 :value-type (choice
210                              (string :tag "URL")
211                              (function :tag "Function returning the URL")))
212   :group 'notmuch-show)
213
214 (defcustom notmuch-show-stash-mlarchive-link-default "Gmane"
215   "Default Mailing List Archive to use when stashing links.
216
217 This is used when `notmuch-show-stash-mlarchive-link' isn't
218 provided with an MLA argument nor `completing-read' input."
219   :type `(choice
220           ,@(mapcar
221              (lambda (mla)
222                (list 'const :tag (car mla) :value (car mla)))
223              notmuch-show-stash-mlarchive-link-alist))
224   :group 'notmuch-show)
225
226 (defcustom notmuch-show-mark-read-tags '("-unread")
227   "List of tag changes to apply to a message when it is marked as read.
228
229 Tags starting with \"+\" (or not starting with either \"+\" or
230 \"-\") in the list will be added, and tags starting with \"-\"
231 will be removed from the message being marked as read.
232
233 For example, if you wanted to remove an \"unread\" tag and add a
234 \"read\" tag (which would make little sense), you would set:
235     (\"-unread\" \"+read\")"
236   :type '(repeat string)
237   :group 'notmuch-show)
238
239 (defcustom notmuch-show-mark-read-function #'notmuch-show-seen-current-message
240   "Function to control which messages are marked read.
241
242 The function should take two arguments START and END which will
243 be the start and end of the visible portion of the buffer and
244 should mark the appropriate messages read by applying
245 `notmuch-show-mark-read'. This function will be called after
246 every user interaction with notmuch."
247   :type 'function
248   :group 'notmuch-show)
249
250 (defcustom notmuch-show-imenu-indent nil
251   "Should Imenu display messages indented.
252
253 By default, Imenu (see Info node `(emacs) Imenu') in a
254 notmuch-show buffer displays all messages straight.  This is
255 because the default Emacs frontend for Imenu makes it difficult
256 to select an Imenu entry with spaces in front.  Other imenu
257 frontends such as counsel-imenu does not have this limitation.
258 In these cases, Imenu entries can be indented to reflect the
259 position of the message in the thread."
260   :type 'boolean
261   :group 'notmuch-show)
262
263 (defmacro with-current-notmuch-show-message (&rest body)
264   "Evaluate body with current buffer set to the text of current message"
265   `(save-excursion
266      (let ((id (notmuch-show-get-message-id)))
267        (let ((buf (generate-new-buffer (concat "*notmuch-msg-" id "*"))))
268          (with-current-buffer buf
269            (let ((coding-system-for-read 'no-conversion))
270              (call-process notmuch-command nil t nil "show" "--format=raw" id))
271            ,@body)
272          (kill-buffer buf)))))
273
274 (defun notmuch-show-turn-on-visual-line-mode ()
275   "Enable Visual Line mode."
276   (visual-line-mode t))
277
278 ;; DEPRECATED in Notmuch 0.16 since we now have convenient part
279 ;; commands.  We'll keep the command around for a version or two in
280 ;; case people want to bind it themselves.
281 (defun notmuch-show-view-all-mime-parts ()
282   "Use external viewers to view all attachments from the current message."
283   (interactive)
284   (with-current-notmuch-show-message
285    ;; We override the mm-inline-media-tests to indicate which message
286    ;; parts are already sufficiently handled by the original
287    ;; presentation of the message in notmuch-show mode. These parts
288    ;; will be inserted directly into the temporary buffer of
289    ;; with-current-notmuch-show-message and silently discarded.
290    ;;
291    ;; Any MIME part not explicitly mentioned here will be handled by an
292    ;; external viewer as configured in the various mailcap files.
293    (let ((mm-inline-media-tests '(
294                                   ("text/.*" ignore identity)
295                                   ("application/pgp-signature" ignore identity)
296                                   ("multipart/alternative" ignore identity)
297                                   ("multipart/mixed" ignore identity)
298                                   ("multipart/related" ignore identity)
299                                  )))
300      (mm-display-parts (mm-dissect-buffer)))))
301
302 (defun notmuch-show-save-attachments ()
303   "Save all attachments from the current message."
304   (interactive)
305   (with-current-notmuch-show-message
306    (let ((mm-handle (mm-dissect-buffer)))
307      (notmuch-save-attachments
308       mm-handle (> (notmuch-count-attachments mm-handle) 1))))
309   (message "Done"))
310
311 (defun notmuch-show-with-message-as-text (fn)
312   "Apply FN to a text representation of the current message.
313
314 FN is called with one argument, the message properties. It should
315 operation on the contents of the current buffer."
316
317   ;; Remake the header to ensure that all information is available.
318   (let* ((to (notmuch-show-get-to))
319          (cc (notmuch-show-get-cc))
320          (from (notmuch-show-get-from))
321          (subject (notmuch-show-get-subject))
322          (date (notmuch-show-get-date))
323          (tags (notmuch-show-get-tags))
324          (depth (notmuch-show-get-depth))
325
326          (header (concat
327                   "Subject: " subject "\n"
328                   "To: " to "\n"
329                   (if (not (string= cc ""))
330                       (concat "Cc: " cc "\n")
331                     "")
332                   "From: " from "\n"
333                   "Date: " date "\n"
334                   (if tags
335                       (concat "Tags: "
336                               (mapconcat #'identity tags ", ") "\n")
337                     "")))
338          (all (buffer-substring (notmuch-show-message-top)
339                                 (notmuch-show-message-bottom)))
340
341          (props (notmuch-show-get-message-properties))
342          (indenting notmuch-show-indent-content))
343     (with-temp-buffer
344       (insert all)
345       (if indenting
346           (indent-rigidly (point-min) (point-max) (- (* notmuch-show-indent-messages-width depth))))
347       ;; Remove the original header.
348       (goto-char (point-min))
349       (re-search-forward "^$" (point-max) nil)
350       (delete-region (point-min) (point))
351       (insert header)
352       (funcall fn props))))
353
354 (defun notmuch-show-print-message ()
355   "Print the current message."
356   (interactive)
357   (notmuch-show-with-message-as-text 'notmuch-print-message))
358
359 (defun notmuch-show-fontify-header ()
360   (let ((face (cond
361                ((looking-at "[Tt]o:")
362                 'message-header-to)
363                ((looking-at "[Bb]?[Cc][Cc]:")
364                 'message-header-cc)
365                ((looking-at "[Ss]ubject:")
366                 'message-header-subject)
367                (t
368                 'message-header-other))))
369
370     (overlay-put (make-overlay (point) (re-search-forward ":"))
371                  'face 'message-header-name)
372     (overlay-put (make-overlay (point) (re-search-forward ".*$"))
373                  'face face)))
374
375 (defun notmuch-show-colour-headers ()
376   "Apply some colouring to the current headers."
377   (goto-char (point-min))
378   (while (looking-at "^[A-Za-z][-A-Za-z0-9]*:")
379     (notmuch-show-fontify-header)
380     (forward-line)))
381
382 (defun notmuch-show-spaces-n (n)
383   "Return a string comprised of `n' spaces."
384   (make-string n ? ))
385
386 (defun notmuch-show-update-tags (tags)
387   "Update the displayed tags of the current message."
388   (save-excursion
389     (goto-char (notmuch-show-message-top))
390     (if (re-search-forward "(\\([^()]*\\))$" (line-end-position) t)
391         (let ((inhibit-read-only t))
392           (replace-match (concat "("
393                                  (notmuch-tag-format-tags tags (notmuch-show-get-prop :orig-tags))
394                                  ")"))))))
395
396 (defun notmuch-clean-address (address)
397   "Try to clean a single email ADDRESS for display. Return a cons
398 cell of (AUTHOR_EMAIL AUTHOR_NAME). Return (ADDRESS nil) if
399 parsing fails."
400   (condition-case nil
401     (let (p-name p-address)
402       ;; It would be convenient to use `mail-header-parse-address',
403       ;; but that expects un-decoded mailbox parts, whereas our
404       ;; mailbox parts are already decoded (and hence may contain
405       ;; UTF-8). Given that notmuch should handle most of the awkward
406       ;; cases, some simple string deconstruction should be sufficient
407       ;; here.
408       (cond
409        ;; "User <user@dom.ain>" style.
410        ((string-match "\\(.*\\) <\\(.*\\)>" address)
411         (setq p-name (match-string 1 address)
412               p-address (match-string 2 address)))
413
414        ;; "<user@dom.ain>" style.
415        ((string-match "<\\(.*\\)>" address)
416         (setq p-address (match-string 1 address)))
417
418        ;; Everything else.
419        (t
420         (setq p-address address)))
421
422       (when p-name
423         ;; Remove elements of the mailbox part that are not relevant for
424         ;; display, even if they are required during transport:
425         ;;
426         ;; Backslashes.
427         (setq p-name (replace-regexp-in-string "\\\\" "" p-name))
428
429         ;; Outer single and double quotes, which might be nested.
430         (loop
431          with start-of-loop
432          do (setq start-of-loop p-name)
433
434          when (string-match "^\"\\(.*\\)\"$" p-name)
435          do (setq p-name (match-string 1 p-name))
436
437          when (string-match "^'\\(.*\\)'$" p-name)
438          do (setq p-name (match-string 1 p-name))
439
440          until (string= start-of-loop p-name)))
441
442       ;; If the address is 'foo@bar.com <foo@bar.com>' then show just
443       ;; 'foo@bar.com'.
444       (when (string= p-name p-address)
445         (setq p-name nil))
446
447       (cons p-address p-name))
448     (error (cons address nil))))
449
450 (defun notmuch-show-clean-address (address)
451   "Try to clean a single email ADDRESS for display.  Return
452 unchanged ADDRESS if parsing fails."
453   (let* ((clean-address (notmuch-clean-address address))
454          (p-address (car clean-address))
455          (p-name (cdr clean-address)))
456     ;; If no name, return just the address.
457     (if (not p-name)
458         p-address
459       ;; Otherwise format the name and address together.
460       (concat p-name " <" p-address ">"))))
461
462 (defun notmuch-show-insert-headerline (headers date tags depth)
463   "Insert a notmuch style headerline based on HEADERS for a
464 message at DEPTH in the current thread."
465   (let ((start (point)))
466     (insert (notmuch-show-spaces-n (* notmuch-show-indent-messages-width depth))
467             (notmuch-sanitize
468              (notmuch-show-clean-address (plist-get headers :From)))
469             " ("
470             date
471             ") ("
472             (notmuch-tag-format-tags tags tags)
473             ")\n")
474     (overlay-put (make-overlay start (point)) 'face 'notmuch-message-summary-face)))
475
476 (defun notmuch-show-insert-header (header header-value)
477   "Insert a single header."
478   (insert header ": " (notmuch-sanitize header-value) "\n"))
479
480 (defun notmuch-show-insert-headers (headers)
481   "Insert the headers of the current message."
482   (let ((start (point)))
483     (mapc (lambda (header)
484             (let* ((header-symbol (intern (concat ":" header)))
485                    (header-value (plist-get headers header-symbol)))
486               (if (and header-value
487                        (not (string-equal "" header-value)))
488                   (notmuch-show-insert-header header header-value))))
489           notmuch-message-headers)
490     (save-excursion
491       (save-restriction
492         (narrow-to-region start (point-max))
493         (run-hooks 'notmuch-show-markup-headers-hook)))))
494
495 (define-button-type 'notmuch-show-part-button-type
496   'action 'notmuch-show-part-button-default
497   'follow-link t
498   'face 'message-mml
499   :supertype 'notmuch-button-type)
500
501 (defun notmuch-show-insert-part-header (nth content-type declared-type &optional name comment)
502   (let ((button)
503         (base-label (concat (when name (concat name ": "))
504                             declared-type
505                             (unless (string-equal declared-type content-type)
506                               (concat " (as " content-type ")"))
507                             comment)))
508
509     (setq button
510           (insert-button
511            (concat "[ " base-label " ]")
512            :base-label base-label
513            :type 'notmuch-show-part-button-type
514            :notmuch-part-hidden nil))
515     (insert "\n")
516     ;; return button
517     button))
518
519 (defun notmuch-show-toggle-part-invisibility (&optional button)
520   (interactive)
521   (let ((button (or button (button-at (point)))))
522     (when button
523       (let ((overlay (button-get button 'overlay))
524             (lazy-part (button-get button :notmuch-lazy-part)))
525         ;; We have a part to toggle if there is an overlay or if there is a lazy part.
526         ;; If neither is present we cannot toggle the part so we just return nil.
527         (when (or overlay lazy-part)
528           (let* ((show (button-get button :notmuch-part-hidden))
529                  (new-start (button-start button))
530                  (button-label (button-get button :base-label))
531                  (old-point (point))
532                  (properties (text-properties-at (button-start button)))
533                  (inhibit-read-only t))
534             ;; Toggle the button itself.
535             (button-put button :notmuch-part-hidden (not show))
536             (goto-char new-start)
537             (insert "[ " button-label (if show " ]" " (hidden) ]"))
538             (set-text-properties new-start (point) properties)
539             (let ((old-end (button-end button)))
540               (move-overlay button new-start (point))
541               (delete-region (point) old-end))
542             (goto-char (min old-point (1- (button-end button))))
543             ;; Return nil if there is a lazy-part, it is empty, and we are
544             ;; trying to show it.  In all other cases return t.
545             (if lazy-part
546                 (when show
547                   (button-put button :notmuch-lazy-part nil)
548                   (notmuch-show-lazy-part lazy-part button))
549               ;; else there must be an overlay.
550               (overlay-put overlay 'invisible (not show))
551               t)))))))
552
553 ;; Part content ID handling
554
555 (defvar notmuch-show--cids nil
556   "Alist from raw content ID to (MSG PART).")
557 (make-variable-buffer-local 'notmuch-show--cids)
558
559 (defun notmuch-show--register-cids (msg part)
560   "Register content-IDs in PART and all of PART's sub-parts."
561   (let ((content-id (plist-get part :content-id)))
562     (when content-id
563       ;; Note that content-IDs are globally unique, except when they
564       ;; aren't: RFC 2046 section 5.1.4 permits children of a
565       ;; multipart/alternative to have the same content-ID, in which
566       ;; case the MUA is supposed to pick the best one it can render.
567       ;; We simply add the content-ID to the beginning of our alist;
568       ;; so if this happens, we'll take the last (and "best")
569       ;; alternative (even if we can't render it).
570       (push (list content-id msg part) notmuch-show--cids)))
571   ;; Recurse on sub-parts
572   (let ((ctype (notmuch-split-content-type
573                 (downcase (plist-get part :content-type)))))
574     (cond ((equal (first ctype) "multipart")
575            (mapc (apply-partially #'notmuch-show--register-cids msg)
576                  (plist-get part :content)))
577           ((equal ctype '("message" "rfc822"))
578            (notmuch-show--register-cids
579             msg
580             (first (plist-get (first (plist-get part :content)) :body)))))))
581
582 (defun notmuch-show--get-cid-content (cid)
583   "Return a list (CID-content content-type) or nil.
584
585 This will only find parts from messages that have been inserted
586 into the current buffer.  CID must be a raw content ID, without
587 enclosing angle brackets, a cid: prefix, or URL encoding.  This
588 will return nil if the CID is unknown or cannot be retrieved."
589   (let ((descriptor (cdr (assoc cid notmuch-show--cids))))
590     (when descriptor
591       (let* ((msg (first descriptor))
592              (part (second descriptor))
593              ;; Request caching for this content, as some messages
594              ;; reference the same cid: part many times (hundreds!).
595              (content (notmuch-get-bodypart-binary
596                        msg part notmuch-show-process-crypto 'cache))
597              (content-type (plist-get part :content-type)))
598         (list content content-type)))))
599
600 (defun notmuch-show-setup-w3m ()
601   "Instruct w3m how to retrieve content from a \"related\" part of a message."
602   (interactive)
603   (if (boundp 'w3m-cid-retrieve-function-alist)
604     (unless (assq 'notmuch-show-mode w3m-cid-retrieve-function-alist)
605       (push (cons 'notmuch-show-mode #'notmuch-show--cid-w3m-retrieve)
606             w3m-cid-retrieve-function-alist)))
607   (setq mm-html-inhibit-images nil))
608
609 (defvar w3m-current-buffer) ;; From `w3m.el'.
610 (defun notmuch-show--cid-w3m-retrieve (url &rest args)
611   ;; url includes the cid: prefix and is URL encoded (see RFC 2392).
612   (let* ((cid (url-unhex-string (substring url 4)))
613          (content-and-type
614           (with-current-buffer w3m-current-buffer
615             (notmuch-show--get-cid-content cid))))
616     (when content-and-type
617       (insert (first content-and-type))
618       (second content-and-type))))
619
620 ;; MIME part renderers
621
622 (defun notmuch-show-multipart/*-to-list (part)
623   (mapcar (lambda (inner-part) (plist-get inner-part :content-type))
624           (plist-get part :content)))
625
626 (defun notmuch-show-insert-part-multipart/alternative (msg part content-type nth depth button)
627   (let ((chosen-type (car (notmuch-multipart/alternative-choose msg (notmuch-show-multipart/*-to-list part))))
628         (inner-parts (plist-get part :content))
629         (start (point)))
630     ;; This inserts all parts of the chosen type rather than just one,
631     ;; but it's not clear that this is the wrong thing to do - which
632     ;; should be chosen if there are more than one that match?
633     (mapc (lambda (inner-part)
634             (let* ((inner-type (plist-get inner-part :content-type))
635                   (hide (not (or notmuch-show-all-multipart/alternative-parts
636                            (string= chosen-type inner-type)))))
637               (notmuch-show-insert-bodypart msg inner-part depth hide)))
638           inner-parts)
639
640     (when notmuch-show-indent-multipart
641       (indent-rigidly start (point) 1)))
642   t)
643
644 (defun notmuch-show-insert-part-multipart/related (msg part content-type nth depth button)
645   (let ((inner-parts (plist-get part :content))
646         (start (point)))
647
648     ;; Render the primary part.  FIXME: Support RFC 2387 Start header.
649     (notmuch-show-insert-bodypart msg (car inner-parts) depth)
650     ;; Add hidden buttons for the rest
651     (mapc (lambda (inner-part)
652             (notmuch-show-insert-bodypart msg inner-part depth t))
653           (cdr inner-parts))
654
655     (when notmuch-show-indent-multipart
656       (indent-rigidly start (point) 1)))
657   t)
658
659 (defun notmuch-show-insert-part-multipart/signed (msg part content-type nth depth button)
660   (when button
661     (button-put button 'face 'notmuch-crypto-part-header))
662
663   ;; Insert a button detailing the signature status.
664   (notmuch-crypto-insert-sigstatus-button (car (plist-get part :sigstatus))
665                                           (notmuch-show-get-header :From msg))
666
667   (let ((inner-parts (plist-get part :content))
668         (start (point)))
669     ;; Show all of the parts.
670     (mapc (lambda (inner-part)
671             (notmuch-show-insert-bodypart msg inner-part depth))
672           inner-parts)
673
674     (when notmuch-show-indent-multipart
675       (indent-rigidly start (point) 1)))
676   t)
677
678 (defun notmuch-show-insert-part-multipart/encrypted (msg part content-type nth depth button)
679   (when button
680     (button-put button 'face 'notmuch-crypto-part-header))
681
682   ;; Insert a button detailing the encryption status.
683   (notmuch-crypto-insert-encstatus-button (car (plist-get part :encstatus)))
684
685   ;; Insert a button detailing the signature status.
686   (notmuch-crypto-insert-sigstatus-button (car (plist-get part :sigstatus))
687                                           (notmuch-show-get-header :From msg))
688
689   (let ((inner-parts (plist-get part :content))
690         (start (point)))
691     ;; Show all of the parts.
692     (mapc (lambda (inner-part)
693             (notmuch-show-insert-bodypart msg inner-part depth))
694           inner-parts)
695
696     (when notmuch-show-indent-multipart
697       (indent-rigidly start (point) 1)))
698   t)
699
700 (defun notmuch-show-insert-part-application/pgp-encrypted (msg part content-type nth depth button)
701   t)
702
703 (defun notmuch-show-insert-part-multipart/* (msg part content-type nth depth button)
704   (let ((inner-parts (plist-get part :content))
705         (start (point)))
706     ;; Show all of the parts.
707     (mapc (lambda (inner-part)
708             (notmuch-show-insert-bodypart msg inner-part depth))
709           inner-parts)
710
711     (when notmuch-show-indent-multipart
712       (indent-rigidly start (point) 1)))
713   t)
714
715 (defun notmuch-show-insert-part-message/rfc822 (msg part content-type nth depth button)
716   (let* ((message (car (plist-get part :content)))
717          (body (car (plist-get message :body)))
718          (start (point)))
719
720     ;; Override `notmuch-message-headers' to force `From' to be
721     ;; displayed.
722     (let ((notmuch-message-headers '("From" "Subject" "To" "Cc" "Date")))
723       (notmuch-show-insert-headers (plist-get message :headers)))
724
725     ;; Blank line after headers to be compatible with the normal
726     ;; message display.
727     (insert "\n")
728
729     ;; Show the body
730     (notmuch-show-insert-bodypart msg body depth)
731
732     (when notmuch-show-indent-multipart
733       (indent-rigidly start (point) 1)))
734   t)
735
736 (defun notmuch-show-insert-part-text/plain (msg part content-type nth depth button)
737   ;; For backward compatibility we want to apply the text/plain hook
738   ;; to the whole of the part including the part button if there is
739   ;; one.
740   (let ((start (if button
741                    (button-start button)
742                  (point))))
743     (insert (notmuch-get-bodypart-text msg part notmuch-show-process-crypto))
744     (save-excursion
745       (save-restriction
746         (narrow-to-region start (point-max))
747         (run-hook-with-args 'notmuch-show-insert-text/plain-hook msg depth))))
748   t)
749
750 (defun notmuch-show-insert-part-text/calendar (msg part content-type nth depth button)
751   (insert (with-temp-buffer
752             (insert (notmuch-get-bodypart-text msg part notmuch-show-process-crypto))
753             ;; notmuch-get-bodypart-text does no newline conversion.
754             ;; Replace CRLF with LF before icalendar can use it.
755             (goto-char (point-min))
756             (while (re-search-forward "\r\n" nil t)
757               (replace-match "\n" nil nil))
758             (let ((file (make-temp-file "notmuch-ical"))
759                   result)
760               (unwind-protect
761                   (progn
762                     (unless (icalendar-import-buffer file t)
763                       (error "Icalendar import error. See *icalendar-errors* for more information"))
764                     (set-buffer (get-file-buffer file))
765                     (setq result (buffer-substring (point-min) (point-max)))
766                     (set-buffer-modified-p nil)
767                     (kill-buffer (current-buffer)))
768                 (delete-file file))
769               result)))
770   t)
771
772 ;; For backwards compatibility.
773 (defun notmuch-show-insert-part-text/x-vcalendar (msg part content-type nth depth button)
774   (notmuch-show-insert-part-text/calendar msg part content-type nth depth button))
775
776 (if (version< emacs-version "25.3")
777     ;; https://bugs.gnu.org/28350
778     ;;
779     ;; For newer emacs, we fall back to notmuch-show-insert-part-*/*
780     ;; (see notmuch-show-handlers-for)
781     (defun notmuch-show-insert-part-text/enriched (msg part content-type nth depth button)
782       ;; By requiring enriched below, we ensure that the function enriched-decode-display-prop
783       ;; is defined before it will be shadowed by the letf below. Otherwise the version
784       ;; in enriched.el may be loaded a bit later and used instead (for the first time).
785       (require 'enriched)
786       (letf (((symbol-function 'enriched-decode-display-prop)
787                  (lambda (start end &optional param) (list start end))))
788         (notmuch-show-insert-part-*/* msg part content-type nth depth button))))
789
790 (defun notmuch-show-get-mime-type-of-application/octet-stream (part)
791   ;; If we can deduce a MIME type from the filename of the attachment,
792   ;; we return that.
793   (if (plist-get part :filename)
794       (let ((extension (file-name-extension (plist-get part :filename)))
795             mime-type)
796         (if extension
797             (progn
798               (mailcap-parse-mimetypes)
799               (setq mime-type (mailcap-extension-to-mime extension))
800               (if (and mime-type
801                        (not (string-equal mime-type "application/octet-stream")))
802                   mime-type
803                 nil))
804           nil))))
805
806 (defun notmuch-show-insert-part-text/html (msg part content-type nth depth button)
807   (if (eq mm-text-html-renderer 'shr)
808       ;; It's easier to drive shr ourselves than to work around the
809       ;; goofy things `mm-shr' does (like irreversibly taking over
810       ;; content ID handling).
811
812       ;; FIXME: If we block an image, offer a button to load external
813       ;; images.
814       (let ((shr-blocked-images notmuch-show-text/html-blocked-images))
815         (notmuch-show--insert-part-text/html-shr msg part))
816     ;; Otherwise, let message-mode do the heavy lifting
817     ;;
818     ;; w3m sets up a keymap which "leaks" outside the invisible region
819     ;; and causes strange effects in notmuch. We set
820     ;; mm-inline-text-html-with-w3m-keymap to nil to tell w3m not to
821     ;; set a keymap (so the normal notmuch-show-mode-map remains).
822     (let ((mm-inline-text-html-with-w3m-keymap nil)
823           ;; FIXME: If we block an image, offer a button to load external
824           ;; images.
825           (gnus-blocked-images notmuch-show-text/html-blocked-images))
826       (notmuch-show-insert-part-*/* msg part content-type nth depth button))))
827
828 ;; These functions are used by notmuch-show--insert-part-text/html-shr
829 (declare-function libxml-parse-html-region "xml.c")
830 (declare-function shr-insert-document "shr")
831
832 (defun notmuch-show--insert-part-text/html-shr (msg part)
833   ;; Make sure shr is loaded before we start let-binding its globals
834   (require 'shr)
835   (let ((dom (let ((process-crypto notmuch-show-process-crypto))
836                (with-temp-buffer
837                  (insert (notmuch-get-bodypart-text msg part process-crypto))
838                  (libxml-parse-html-region (point-min) (point-max)))))
839         (shr-content-function
840          (lambda (url)
841            ;; shr strips the "cid:" part of URL, but doesn't
842            ;; URL-decode it (see RFC 2392).
843            (let ((cid (url-unhex-string url)))
844              (first (notmuch-show--get-cid-content cid))))))
845     (shr-insert-document dom)
846     t))
847
848 (defun notmuch-show-insert-part-*/* (msg part content-type nth depth button)
849   ;; This handler _must_ succeed - it is the handler of last resort.
850   (notmuch-mm-display-part-inline msg part content-type notmuch-show-process-crypto)
851   t)
852
853 ;; Functions for determining how to handle MIME parts.
854
855 (defun notmuch-show-handlers-for (content-type)
856   "Return a list of content handlers for a part of type CONTENT-TYPE."
857   (let (result)
858     (mapc (lambda (func)
859             (if (functionp func)
860                 (push func result)))
861           ;; Reverse order of prefrence.
862           (list (intern (concat "notmuch-show-insert-part-*/*"))
863                 (intern (concat
864                          "notmuch-show-insert-part-"
865                          (car (notmuch-split-content-type content-type))
866                          "/*"))
867                 (intern (concat "notmuch-show-insert-part-" content-type))))
868     result))
869
870 ;; \f
871
872 (defun notmuch-show-insert-bodypart-internal (msg part content-type nth depth button)
873   ;; Run the handlers until one of them succeeds.
874   (loop for handler in (notmuch-show-handlers-for content-type)
875         until (condition-case err
876                   (funcall handler msg part content-type nth depth button)
877                 ;; Specifying `debug' here lets the debugger run if
878                 ;; `debug-on-error' is non-nil.
879                 ((debug error)
880                  (insert "!!! Bodypart handler `" (prin1-to-string handler) "' threw an error:\n"
881                          "!!! " (error-message-string err) "\n")
882                  nil))))
883
884 (defun notmuch-show-create-part-overlays (button beg end)
885   "Add an overlay to the part between BEG and END"
886
887   ;; If there is no button (i.e., the part is text/plain and the first
888   ;; part) or if the part has no content then we don't make the part
889   ;; toggleable.
890   (when (and button (/= beg end))
891     (button-put button 'overlay (make-overlay beg end))
892     ;; Return true if we created an overlay.
893     t))
894
895 (defun notmuch-show-record-part-information (part beg end)
896   "Store PART as a text property from BEG to END"
897
898   ;; Record part information.  Since we already inserted subparts,
899   ;; don't override existing :notmuch-part properties.
900   (notmuch-map-text-property beg end :notmuch-part
901                              (lambda (v) (or v part)))
902   ;; Make :notmuch-part front sticky and rear non-sticky so it stays
903   ;; applied to the beginning of each line when we indent the
904   ;; message.  Since we're operating on arbitrary renderer output,
905   ;; watch out for sticky specs of t, which means all properties are
906   ;; front-sticky/rear-nonsticky.
907   (notmuch-map-text-property beg end 'front-sticky
908                              (lambda (v) (if (listp v)
909                                              (pushnew :notmuch-part v)
910                                            v)))
911   (notmuch-map-text-property beg end 'rear-nonsticky
912                              (lambda (v) (if (listp v)
913                                              (pushnew :notmuch-part v)
914                                            v))))
915
916 (defun notmuch-show-lazy-part (part-args button)
917   ;; Insert the lazy part after the button for the part. We would just
918   ;; move to the start of the new line following the button and insert
919   ;; the part but that point might have text properties (eg colours
920   ;; from a message header etc) so instead we start from the last
921   ;; character of the button by adding a newline and finish by
922   ;; removing the extra newline from the end of the part.
923   (save-excursion
924     (goto-char (button-end button))
925     (insert "\n")
926     (let* ((inhibit-read-only t)
927            ;; We need to use markers for the start and end of the part
928            ;; because the part insertion functions do not guarantee
929            ;; to leave point at the end of the part.
930            (part-beg (copy-marker (point) nil))
931            (part-end (copy-marker (point) t))
932            ;; We have to save the depth as we can't find the depth
933            ;; when narrowed.
934            (depth (notmuch-show-get-depth)))
935       (save-restriction
936         (narrow-to-region part-beg part-end)
937         (delete-region part-beg part-end)
938         (apply #'notmuch-show-insert-bodypart-internal part-args)
939         (indent-rigidly part-beg part-end (* notmuch-show-indent-messages-width depth)))
940       (goto-char part-end)
941       (delete-char 1)
942       (notmuch-show-record-part-information (second part-args)
943                                             (button-start button)
944                                             part-end)
945       ;; Create the overlay. If the lazy-part turned out to be empty/not
946       ;; showable this returns nil.
947       (notmuch-show-create-part-overlays button part-beg part-end))))
948
949 (defun notmuch-show-mime-type (part)
950   "Return the correct mime-type to use for PART."
951   (let ((content-type (downcase (plist-get part :content-type))))
952     (or (and (string= content-type "application/octet-stream")
953              (notmuch-show-get-mime-type-of-application/octet-stream part))
954         (and (string= content-type "inline patch")
955              "text/x-diff")
956         content-type)))
957
958 ;; The following variable can be overridden by let bindings.
959 (defvar notmuch-show-insert-header-p-function 'notmuch-show-insert-header-p
960   "Specify which function decides which part headers get inserted.
961
962 The function should take two parameters, PART and HIDE, and
963 should return non-NIL if a header button should be inserted for
964 this part.")
965
966 (defun notmuch-show-insert-header-p (part hide)
967   ;; Show all part buttons except for the first part if it is text/plain.
968   (let ((mime-type (notmuch-show-mime-type part)))
969     (not (and (string= mime-type "text/plain")
970               (<= (plist-get part :id) 1)))))
971
972 (defun notmuch-show-reply-insert-header-p-never (part hide)
973   nil)
974
975 (defun notmuch-show-reply-insert-header-p-trimmed (part hide)
976   (let ((mime-type (notmuch-show-mime-type part)))
977     (and (not (notmuch-match-content-type mime-type "multipart/*"))
978          (not hide))))
979
980 (defun notmuch-show-reply-insert-header-p-minimal (part hide)
981   (let ((mime-type (notmuch-show-mime-type part)))
982     (and (notmuch-match-content-type mime-type "text/*")
983          (not hide))))
984
985 (defun notmuch-show-insert-bodypart (msg part depth &optional hide)
986   "Insert the body part PART at depth DEPTH in the current thread.
987
988 HIDE determines whether to show or hide the part and the button
989 as follows: If HIDE is nil, show the part and the button. If HIDE
990 is t, hide the part initially and show the button."
991
992   (let* ((content-type (downcase (plist-get part :content-type)))
993          (mime-type (notmuch-show-mime-type part))
994          (nth (plist-get part :id))
995          (long (and (notmuch-match-content-type mime-type "text/*")
996                     (> notmuch-show-max-text-part-size 0)
997                     (> (length (plist-get part :content)) notmuch-show-max-text-part-size)))
998          (beg (point))
999          ;; This default header-p function omits the part button for
1000          ;; the first (or only) part if this is text/plain.
1001          (button (when (funcall notmuch-show-insert-header-p-function part hide)
1002                    (notmuch-show-insert-part-header nth mime-type content-type (plist-get part :filename))))
1003          ;; Hide the part initially if HIDE is t, or if it is too long
1004          ;; and we have a button to allow toggling.
1005          (show-part (not (or (equal hide t)
1006                              (and long button))))
1007          (content-beg (point)))
1008
1009     ;; Store the computed mime-type for later use (e.g. by attachment handlers).
1010     (plist-put part :computed-type mime-type)
1011
1012     (if show-part
1013         (notmuch-show-insert-bodypart-internal msg part mime-type nth depth button)
1014       (when button
1015         (button-put button :notmuch-lazy-part
1016                     (list msg part mime-type nth depth button))))
1017
1018     ;; Some of the body part handlers leave point somewhere up in the
1019     ;; part, so we make sure that we're down at the end.
1020     (goto-char (point-max))
1021     ;; Ensure that the part ends with a carriage return.
1022     (unless (bolp)
1023       (insert "\n"))
1024     ;; We do not create the overlay for hidden (lazy) parts until
1025     ;; they are inserted.
1026     (if show-part
1027         (notmuch-show-create-part-overlays button content-beg (point))
1028       (save-excursion
1029         (notmuch-show-toggle-part-invisibility button)))
1030     (notmuch-show-record-part-information part beg (point))))
1031
1032 (defun notmuch-show-insert-body (msg body depth)
1033   "Insert the body BODY at depth DEPTH in the current thread."
1034
1035   ;; Register all content IDs for this message.  According to RFC
1036   ;; 2392, content IDs are *global*, but it's okay if an MUA treats
1037   ;; them as only global within a message.
1038   (notmuch-show--register-cids msg (first body))
1039
1040   (mapc (lambda (part) (notmuch-show-insert-bodypart msg part depth)) body))
1041
1042 (defun notmuch-show-make-symbol (type)
1043   (make-symbol (concat "notmuch-show-" type)))
1044
1045 (defun notmuch-show-strip-re (string)
1046   (replace-regexp-in-string "^\\([Rr]e: *\\)+" "" string))
1047
1048 (defvar notmuch-show-previous-subject "")
1049 (make-variable-buffer-local 'notmuch-show-previous-subject)
1050
1051 (defun notmuch-show-insert-msg (msg depth)
1052   "Insert the message MSG at depth DEPTH in the current thread."
1053   (let* ((headers (plist-get msg :headers))
1054          ;; Indentation causes the buffer offset of the start/end
1055          ;; points to move, so we must use markers.
1056          message-start message-end
1057          content-start content-end
1058          headers-start headers-end
1059          (bare-subject (notmuch-show-strip-re (plist-get headers :Subject))))
1060
1061     (setq message-start (point-marker))
1062
1063     (notmuch-show-insert-headerline headers
1064                                     (or (if notmuch-show-relative-dates
1065                                             (plist-get msg :date_relative)
1066                                           nil)
1067                                         (plist-get headers :Date))
1068                                     (plist-get msg :tags) depth)
1069
1070     (setq content-start (point-marker))
1071
1072     ;; Set `headers-start' to point after the 'Subject:' header to be
1073     ;; compatible with the existing implementation. This just sets it
1074     ;; to after the first header.
1075     (notmuch-show-insert-headers headers)
1076     (save-excursion
1077       (goto-char content-start)
1078       ;; If the subject of this message is the same as that of the
1079       ;; previous message, don't display it when this message is
1080       ;; collapsed.
1081       (when (not (string= notmuch-show-previous-subject
1082                           bare-subject))
1083         (forward-line 1))
1084       (setq headers-start (point-marker)))
1085     (setq headers-end (point-marker))
1086
1087     (setq notmuch-show-previous-subject bare-subject)
1088
1089     ;; A blank line between the headers and the body.
1090     (insert "\n")
1091     (notmuch-show-insert-body msg (plist-get msg :body)
1092                               (if notmuch-show-indent-content depth 0))
1093     ;; Ensure that the body ends with a newline.
1094     (unless (bolp)
1095       (insert "\n"))
1096     (setq content-end (point-marker))
1097
1098     ;; Indent according to the depth in the thread.
1099     (if notmuch-show-indent-content
1100         (indent-rigidly content-start content-end (* notmuch-show-indent-messages-width depth)))
1101
1102     (setq message-end (point-max-marker))
1103
1104     ;; Save the extents of this message over the whole text of the
1105     ;; message.
1106     (put-text-property message-start message-end :notmuch-message-extent (cons message-start message-end))
1107
1108     ;; Create overlays used to control visibility
1109     (plist-put msg :headers-overlay (make-overlay headers-start headers-end))
1110     (plist-put msg :message-overlay (make-overlay headers-start content-end))
1111
1112     (plist-put msg :depth depth)
1113
1114     ;; Save the properties for this message. Currently this saves the
1115     ;; entire message (augmented it with other stuff), which seems
1116     ;; like overkill. We might save a reduced subset (for example, not
1117     ;; the content).
1118     (notmuch-show-set-message-properties msg)
1119
1120     ;; Set header visibility.
1121     (notmuch-show-headers-visible msg notmuch-message-headers-visible)
1122
1123     ;; Message visibility depends on whether it matched the search
1124     ;; criteria.
1125     (notmuch-show-message-visible msg (and (plist-get msg :match)
1126                                            (not (plist-get msg :excluded))))))
1127
1128 (defun notmuch-show-toggle-process-crypto ()
1129   "Toggle the processing of cryptographic MIME parts."
1130   (interactive)
1131   (setq notmuch-show-process-crypto (not notmuch-show-process-crypto))
1132   (message (if notmuch-show-process-crypto
1133                "Processing cryptographic MIME parts."
1134              "Not processing cryptographic MIME parts."))
1135   (notmuch-show-refresh-view))
1136
1137 (defun notmuch-show-toggle-elide-non-matching ()
1138   "Toggle the display of non-matching messages."
1139   (interactive)
1140   (setq notmuch-show-elide-non-matching-messages (not notmuch-show-elide-non-matching-messages))
1141   (message (if notmuch-show-elide-non-matching-messages
1142                "Showing matching messages only."
1143              "Showing all messages."))
1144   (notmuch-show-refresh-view))
1145
1146 (defun notmuch-show-toggle-thread-indentation ()
1147   "Toggle the indentation of threads."
1148   (interactive)
1149   (setq notmuch-show-indent-content (not notmuch-show-indent-content))
1150   (message (if notmuch-show-indent-content
1151                "Content is indented."
1152              "Content is not indented."))
1153   (notmuch-show-refresh-view))
1154
1155 (defun notmuch-show-insert-tree (tree depth)
1156   "Insert the message tree TREE at depth DEPTH in the current thread."
1157   (let ((msg (car tree))
1158         (replies (cadr tree)))
1159     ;; We test whether there is a message or just some replies.
1160     (when msg
1161       (notmuch-show-insert-msg msg depth))
1162     (notmuch-show-insert-thread replies (1+ depth))))
1163
1164 (defun notmuch-show-insert-thread (thread depth)
1165   "Insert the thread THREAD at depth DEPTH in the current forest."
1166   (mapc (lambda (tree) (notmuch-show-insert-tree tree depth)) thread))
1167
1168 (defun notmuch-show-insert-forest (forest)
1169   "Insert the forest of threads FOREST."
1170   (mapc (lambda (thread) (notmuch-show-insert-thread thread 0)) forest))
1171
1172 (defvar notmuch-id-regexp
1173   (concat
1174    ;; Match the id: prefix only if it begins a word (to disallow, for
1175    ;; example, matching cid:).
1176    "\\<id:\\("
1177    ;; If the term starts with a ", then parse Xapian's quoted boolean
1178    ;; term syntax, which allows for anything as long as embedded
1179    ;; double quotes escaped by doubling them.  We also disallow
1180    ;; newlines (which Xapian allows) to prevent runaway terms.
1181    "\"\\([^\"\n]\\|\"\"\\)*\""
1182    ;; Otherwise, parse Xapian's unquoted syntax, which goes up to the
1183    ;; next space or ).  We disallow [.,;] as the last character
1184    ;; because these are probably part of the surrounding text, and not
1185    ;; part of the id.  This doesn't match single character ids; meh.
1186    "\\|[^\"[:space:])][^[:space:])]*[^])[:space:].,:;?!]"
1187    "\\)")
1188   "The regexp used to match id: links in messages.")
1189
1190 (defvar notmuch-mid-regexp
1191   ;; goto-address-url-regexp matched cid: links, which have the same
1192   ;; grammar as the message ID part of a mid: link.  Construct the
1193   ;; regexp using the same technique as goto-address-url-regexp.
1194   (concat "\\<mid:\\(" thing-at-point-url-path-regexp "\\)")
1195   "The regexp used to match mid: links in messages.
1196
1197 See RFC 2392.")
1198
1199 (defun notmuch-show-buttonise-links (start end)
1200   "Buttonise URLs and mail addresses between START and END.
1201
1202 This also turns id:\"<message id>\"-parts and mid: links into
1203 buttons for a corresponding notmuch search."
1204   (goto-address-fontify-region start end)
1205   (save-excursion
1206     (let (links
1207           (beg-line (progn (goto-char start) (line-beginning-position)))
1208           (end-line (progn (goto-char end) (line-end-position))))
1209       (goto-char beg-line)
1210       (while (re-search-forward notmuch-id-regexp end-line t)
1211         (push (list (match-beginning 0) (match-end 0)
1212                     (match-string-no-properties 0)) links))
1213       (goto-char beg-line)
1214       (while (re-search-forward notmuch-mid-regexp end-line t)
1215         (let* ((mid-cid (match-string-no-properties 1))
1216                (mid (save-match-data
1217                       (string-match "^[^/]*" mid-cid)
1218                       (url-unhex-string (match-string 0 mid-cid)))))
1219           (push (list (match-beginning 0) (match-end 0)
1220                       (notmuch-id-to-query mid)) links)))
1221       (dolist (link links)
1222         ;; Remove the overlay created by goto-address-mode
1223         (remove-overlays (first link) (second link) 'goto-address t)
1224         (make-text-button (first link) (second link)
1225                           :type 'notmuch-button-type
1226                           'action `(lambda (arg)
1227                                      (notmuch-show ,(third link) current-prefix-arg))
1228                           'follow-link t
1229                           'help-echo "Mouse-1, RET: search for this message"
1230                           'face goto-address-mail-face)))))
1231
1232 ;;;###autoload
1233 (defun notmuch-show (thread-id &optional elide-toggle parent-buffer query-context buffer-name)
1234   "Run \"notmuch show\" with the given thread ID and display results.
1235
1236 ELIDE-TOGGLE, if non-nil, inverts the default elide behavior.
1237
1238 The optional PARENT-BUFFER is the notmuch-search buffer from
1239 which this notmuch-show command was executed, (so that the
1240 next thread from that buffer can be show when done with this
1241 one).
1242
1243 The optional QUERY-CONTEXT is a notmuch search term. Only
1244 messages from the thread matching this search term are shown if
1245 non-nil.
1246
1247 The optional BUFFER-NAME provides the name of the buffer in
1248 which the message thread is shown. If it is nil (which occurs
1249 when the command is called interactively) the argument to the
1250 function is used.
1251
1252 Returns the buffer containing the messages, or NIL if no messages
1253 matched."
1254   (interactive "sNotmuch show: \nP")
1255   (let ((buffer-name (generate-new-buffer-name
1256                       (or buffer-name
1257                           (concat "*notmuch-" thread-id "*"))))
1258         ;; We override mm-inline-override-types to stop application/*
1259         ;; parts from being displayed unless the user has customized
1260         ;; it themselves.
1261         (mm-inline-override-types
1262          (if (equal mm-inline-override-types
1263                     (eval (car (get 'mm-inline-override-types 'standard-value))))
1264              (cons "application/*" mm-inline-override-types)
1265            mm-inline-override-types)))
1266     (switch-to-buffer (get-buffer-create buffer-name))
1267     ;; No need to track undo information for this buffer.
1268     (setq buffer-undo-list t)
1269
1270     (notmuch-show-mode)
1271
1272     ;; Set various buffer local variables to their appropriate initial
1273     ;; state. Do this after enabling `notmuch-show-mode' so that they
1274     ;; aren't wiped out.
1275     (setq notmuch-show-thread-id thread-id
1276           notmuch-show-parent-buffer parent-buffer
1277           notmuch-show-query-context (if (or (string= query-context "")
1278                                              (string= query-context "*"))
1279                                          nil query-context)
1280
1281           notmuch-show-process-crypto notmuch-crypto-process-mime
1282           ;; If `elide-toggle', invert the default value.
1283           notmuch-show-elide-non-matching-messages
1284           (if elide-toggle
1285               (not notmuch-show-only-matching-messages)
1286             notmuch-show-only-matching-messages))
1287
1288     (add-hook 'post-command-hook #'notmuch-show-command-hook nil t)
1289     (jit-lock-register #'notmuch-show-buttonise-links)
1290
1291     (notmuch-tag-clear-cache)
1292
1293     (let ((inhibit-read-only t))
1294       (if (notmuch-show--build-buffer)
1295           ;; Messages were inserted into the buffer.
1296           (current-buffer)
1297
1298         ;; No messages were inserted - presumably none matched the
1299         ;; query.
1300         (kill-buffer (current-buffer))
1301         (ding)
1302         (message "No messages matched the query!")
1303         nil))))
1304
1305 (defun notmuch-show--build-queries (thread context)
1306   "Return a list of queries to try for this search.
1307
1308 THREAD and CONTEXT are both strings, though CONTEXT may be nil.
1309 When CONTEXT is not nil, the first query is the conjunction of it
1310 and THREAD.  The next query is THREAD alone, and serves as a
1311 fallback if the prior matches no messages."
1312   (let (queries)
1313     (push (list thread) queries)
1314     (if context (push (list thread "and (" context ")") queries))
1315     queries))
1316
1317 (defun notmuch-show--build-buffer (&optional state)
1318   "Display messages matching the current buffer context.
1319
1320 Apply the previously saved STATE if supplied, otherwise show the
1321 first relevant message.
1322
1323 If no messages match the query return NIL."
1324   (let* ((cli-args (cons "--exclude=false"
1325                          (when notmuch-show-elide-non-matching-messages
1326                            (list "--entire-thread=false"))))
1327          (queries (notmuch-show--build-queries
1328                    notmuch-show-thread-id notmuch-show-query-context))
1329          (forest nil)
1330          ;; Must be reset every time we are going to start inserting
1331          ;; messages into the buffer.
1332          (notmuch-show-previous-subject ""))
1333     ;; Use results from the first query that returns some.
1334     (while (and (not forest) queries)
1335       (setq forest (notmuch-query-get-threads
1336                     (append cli-args (list "'") (car queries) (list "'"))))
1337       (setq queries (cdr queries)))
1338     (when forest
1339       (notmuch-show-insert-forest forest)
1340
1341       ;; Store the original tags for each message so that we can
1342       ;; display changes.
1343       (notmuch-show-mapc
1344        (lambda () (notmuch-show-set-prop :orig-tags (notmuch-show-get-tags))))
1345
1346       ;; Set the header line to the subject of the first message.
1347       (setq header-line-format
1348             (replace-regexp-in-string "%" "%%"
1349                                       (notmuch-sanitize
1350                                        (notmuch-show-strip-re
1351                                         (notmuch-show-get-subject)))))
1352
1353       (run-hooks 'notmuch-show-hook)
1354
1355       (if state
1356           (notmuch-show-apply-state state)
1357         ;; With no state to apply, just go to the first message.
1358         (notmuch-show-goto-first-wanted-message)))
1359
1360     ;; Report back to the caller whether any messages matched.
1361     forest))
1362
1363 (defun notmuch-show-capture-state ()
1364   "Capture the state of the current buffer.
1365
1366 This includes:
1367  - the list of open messages,
1368  - the combination of current message id with/for each visible window."
1369   (let* ((win-list (get-buffer-window-list (current-buffer) nil t))
1370          (win-id-combo (mapcar (lambda (win)
1371                                  (with-selected-window win
1372                                    (list win (notmuch-show-get-message-id))))
1373                                win-list)))
1374     (list win-id-combo (notmuch-show-get-message-ids-for-open-messages))))
1375
1376 (defun notmuch-show-get-query ()
1377   "Return the current query in this show buffer"
1378   (if notmuch-show-query-context
1379       (concat notmuch-show-thread-id
1380               " and ("
1381               notmuch-show-query-context
1382               ")")
1383     notmuch-show-thread-id))
1384
1385 (defun notmuch-show-goto-message (msg-id)
1386   "Go to message with msg-id."
1387   (goto-char (point-min))
1388   (unless (loop if (string= msg-id (notmuch-show-get-message-id))
1389                 return t
1390                 until (not (notmuch-show-goto-message-next)))
1391     (goto-char (point-min))
1392     (message "Message-id not found."))
1393   (notmuch-show-message-adjust))
1394
1395 (defun notmuch-show-apply-state (state)
1396   "Apply STATE to the current buffer.
1397
1398 This includes:
1399  - opening the messages previously opened,
1400  - closing all other messages,
1401  - moving to the correct current message in every displayed window."
1402   (let ((win-msg-alist (car state))
1403         (open (cadr state)))
1404
1405     ;; Open those that were open.
1406     (goto-char (point-min))
1407     (loop do (notmuch-show-message-visible (notmuch-show-get-message-properties)
1408                                            (member (notmuch-show-get-message-id) open))
1409           until (not (notmuch-show-goto-message-next)))
1410
1411     (dolist (win-msg-pair win-msg-alist)
1412       (with-selected-window (car win-msg-pair)
1413         ;; Go to the previously open message in this window
1414         (notmuch-show-goto-message (cadr win-msg-pair))))))
1415
1416 (defun notmuch-show-refresh-view (&optional reset-state)
1417   "Refresh the current view.
1418
1419 Refreshes the current view, observing changes in display
1420 preferences. If invoked with a prefix argument (or RESET-STATE is
1421 non-nil) then the state of the buffer (open/closed messages) is
1422 reset based on the original query."
1423   (interactive "P")
1424   (let ((inhibit-read-only t)
1425         (state (unless reset-state
1426                  (notmuch-show-capture-state))))
1427     ;; `erase-buffer' does not seem to remove overlays, which can lead
1428     ;; to weird effects such as remaining images, so remove them
1429     ;; manually.
1430     (remove-overlays)
1431     (erase-buffer)
1432
1433     (unless (notmuch-show--build-buffer state)
1434       ;; No messages were inserted.
1435       (kill-buffer (current-buffer))
1436       (ding)
1437       (message "Refreshing the buffer resulted in no messages!"))))
1438
1439 (defvar notmuch-show-stash-map
1440   (let ((map (make-sparse-keymap)))
1441     (define-key map "c" 'notmuch-show-stash-cc)
1442     (define-key map "d" 'notmuch-show-stash-date)
1443     (define-key map "F" 'notmuch-show-stash-filename)
1444     (define-key map "f" 'notmuch-show-stash-from)
1445     (define-key map "i" 'notmuch-show-stash-message-id)
1446     (define-key map "I" 'notmuch-show-stash-message-id-stripped)
1447     (define-key map "s" 'notmuch-show-stash-subject)
1448     (define-key map "T" 'notmuch-show-stash-tags)
1449     (define-key map "t" 'notmuch-show-stash-to)
1450     (define-key map "l" 'notmuch-show-stash-mlarchive-link)
1451     (define-key map "L" 'notmuch-show-stash-mlarchive-link-and-go)
1452     (define-key map "G" 'notmuch-show-stash-git-send-email)
1453     (define-key map "?" 'notmuch-subkeymap-help)
1454     map)
1455   "Submap for stash commands")
1456 (fset 'notmuch-show-stash-map notmuch-show-stash-map)
1457
1458 (defvar notmuch-show-part-map
1459   (let ((map (make-sparse-keymap)))
1460     (define-key map "s" 'notmuch-show-save-part)
1461     (define-key map "v" 'notmuch-show-view-part)
1462     (define-key map "o" 'notmuch-show-interactively-view-part)
1463     (define-key map "|" 'notmuch-show-pipe-part)
1464     (define-key map "m" 'notmuch-show-choose-mime-of-part)
1465     (define-key map "?" 'notmuch-subkeymap-help)
1466     map)
1467   "Submap for part commands")
1468 (fset 'notmuch-show-part-map notmuch-show-part-map)
1469
1470 (defvar notmuch-show-mode-map
1471   (let ((map (make-sparse-keymap)))
1472     (set-keymap-parent map notmuch-common-keymap)
1473     (define-key map "Z" 'notmuch-tree-from-show-current-query)
1474     (define-key map (kbd "<C-tab>") 'widget-backward)
1475     (define-key map (kbd "M-TAB") 'notmuch-show-previous-button)
1476     (define-key map (kbd "<backtab>") 'notmuch-show-previous-button)
1477     (define-key map (kbd "TAB") 'notmuch-show-next-button)
1478     (define-key map "f" 'notmuch-show-forward-message)
1479     (define-key map "F" 'notmuch-show-forward-open-messages)
1480     (define-key map "b" 'notmuch-show-resend-message)
1481     (define-key map "l" 'notmuch-show-filter-thread)
1482     (define-key map "r" 'notmuch-show-reply-sender)
1483     (define-key map "R" 'notmuch-show-reply)
1484     (define-key map "|" 'notmuch-show-pipe-message)
1485     (define-key map "w" 'notmuch-show-save-attachments)
1486     (define-key map "V" 'notmuch-show-view-raw-message)
1487     (define-key map "e" 'notmuch-show-resume-message)
1488     (define-key map "c" 'notmuch-show-stash-map)
1489     (define-key map "h" 'notmuch-show-toggle-visibility-headers)
1490     (define-key map "k" 'notmuch-tag-jump)
1491     (define-key map "*" 'notmuch-show-tag-all)
1492     (define-key map "-" 'notmuch-show-remove-tag)
1493     (define-key map "+" 'notmuch-show-add-tag)
1494     (define-key map "X" 'notmuch-show-archive-thread-then-exit)
1495     (define-key map "x" 'notmuch-show-archive-message-then-next-or-exit)
1496     (define-key map "A" 'notmuch-show-archive-thread-then-next)
1497     (define-key map "a" 'notmuch-show-archive-message-then-next-or-next-thread)
1498     (define-key map "N" 'notmuch-show-next-message)
1499     (define-key map "P" 'notmuch-show-previous-message)
1500     (define-key map "n" 'notmuch-show-next-open-message)
1501     (define-key map "p" 'notmuch-show-previous-open-message)
1502     (define-key map (kbd "M-n") 'notmuch-show-next-thread-show)
1503     (define-key map (kbd "M-p") 'notmuch-show-previous-thread-show)
1504     (define-key map (kbd "DEL") 'notmuch-show-rewind)
1505     (define-key map " " 'notmuch-show-advance-and-archive)
1506     (define-key map (kbd "M-RET") 'notmuch-show-open-or-close-all)
1507     (define-key map (kbd "RET") 'notmuch-show-toggle-message)
1508     (define-key map "#" 'notmuch-show-print-message)
1509     (define-key map "!" 'notmuch-show-toggle-elide-non-matching)
1510     (define-key map "$" 'notmuch-show-toggle-process-crypto)
1511     (define-key map "<" 'notmuch-show-toggle-thread-indentation)
1512     (define-key map "t" 'toggle-truncate-lines)
1513     (define-key map "." 'notmuch-show-part-map)
1514     (define-key map "B" 'notmuch-show-browse-urls)
1515     map)
1516   "Keymap for \"notmuch show\" buffers.")
1517 (fset 'notmuch-show-mode-map notmuch-show-mode-map)
1518
1519 (define-derived-mode notmuch-show-mode fundamental-mode "notmuch-show"
1520   "Major mode for viewing a thread with notmuch.
1521
1522 This buffer contains the results of the \"notmuch show\" command
1523 for displaying a single thread of email from your email archives.
1524
1525 By default, various components of email messages, (citations,
1526 signatures, already-read messages), are hidden. You can make
1527 these parts visible by clicking with the mouse button or by
1528 pressing RET after positioning the cursor on a hidden part, (for
1529 which \\[notmuch-show-next-button] and \\[notmuch-show-previous-button] are helpful).
1530
1531 Reading the thread sequentially is well-supported by pressing
1532 \\[notmuch-show-advance-and-archive]. This will scroll the current message (if necessary), advance
1533 to the next message, or advance to the next thread (if already on
1534 the last message of a thread).
1535
1536 Other commands are available to read or manipulate the thread
1537 more selectively, (such as '\\[notmuch-show-next-message]' and '\\[notmuch-show-previous-message]' to advance to messages
1538 without removing any tags, and '\\[notmuch-show-archive-thread]' to archive an entire thread
1539 without scrolling through with \\[notmuch-show-advance-and-archive]).
1540
1541 You can add or remove arbitrary tags from the current message with
1542 '\\[notmuch-show-add-tag]' or '\\[notmuch-show-remove-tag]'.
1543
1544 All currently available key bindings:
1545
1546 \\{notmuch-show-mode-map}"
1547   (setq notmuch-buffer-refresh-function #'notmuch-show-refresh-view)
1548   (setq buffer-read-only t
1549         truncate-lines t)
1550   (setq imenu-prev-index-position-function
1551         #'notmuch-show-imenu-prev-index-position-function)
1552   (setq imenu-extract-index-name-function
1553         #'notmuch-show-imenu-extract-index-name-function))
1554
1555 (defun notmuch-tree-from-show-current-query ()
1556   "Call notmuch tree with the current query"
1557   (interactive)
1558   (notmuch-tree notmuch-show-thread-id
1559                 notmuch-show-query-context
1560                 (notmuch-show-get-message-id)))
1561
1562 (defun notmuch-show-move-to-message-top ()
1563   (goto-char (notmuch-show-message-top)))
1564
1565 (defun notmuch-show-move-to-message-bottom ()
1566   (goto-char (notmuch-show-message-bottom)))
1567
1568 (defun notmuch-show-message-adjust ()
1569   (recenter 0))
1570
1571 ;; Movement related functions.
1572
1573 ;; There's some strangeness here where a text property applied to a
1574 ;; region a->b is not found when point is at b. We walk backwards
1575 ;; until finding the property.
1576 (defun notmuch-show-message-extent ()
1577   "Return a cons cell containing the start and end buffer offset
1578 of the current message."
1579   (let (r)
1580     (save-excursion
1581       (while (not (setq r (get-text-property (point) :notmuch-message-extent)))
1582         (backward-char)))
1583     r))
1584
1585 (defun notmuch-show-message-top ()
1586   (car (notmuch-show-message-extent)))
1587
1588 (defun notmuch-show-message-bottom ()
1589   (cdr (notmuch-show-message-extent)))
1590
1591 (defun notmuch-show-goto-message-next ()
1592   (let ((start (point)))
1593     (notmuch-show-move-to-message-bottom)
1594     (if (not (eobp))
1595         t
1596       (goto-char start)
1597       nil)))
1598
1599 (defun notmuch-show-goto-message-previous ()
1600   (notmuch-show-move-to-message-top)
1601   (if (bobp)
1602       nil
1603     (backward-char)
1604     (notmuch-show-move-to-message-top)
1605     t))
1606
1607 (defun notmuch-show-mapc (function)
1608   "Iterate through all messages in the current thread with
1609 `notmuch-show-goto-message-next' and call FUNCTION for side
1610 effects."
1611   (save-excursion
1612     (goto-char (point-min))
1613     (loop do (funcall function)
1614           while (notmuch-show-goto-message-next))))
1615
1616 ;; Functions relating to the visibility of messages and their
1617 ;; components.
1618
1619 (defun notmuch-show-message-visible (props visible-p)
1620   (overlay-put (plist-get props :message-overlay) 'invisible (not visible-p))
1621   (notmuch-show-set-prop :message-visible visible-p props))
1622
1623 (defun notmuch-show-headers-visible (props visible-p)
1624   (overlay-put (plist-get props :headers-overlay) 'invisible (not visible-p))
1625   (notmuch-show-set-prop :headers-visible visible-p props))
1626
1627 ;; Functions for setting and getting attributes of the current
1628 ;; message.
1629
1630 (defun notmuch-show-set-message-properties (props)
1631   (save-excursion
1632     (notmuch-show-move-to-message-top)
1633     (put-text-property (point) (+ (point) 1) :notmuch-message-properties props)))
1634
1635 (defun notmuch-show-get-message-properties ()
1636   "Return the properties of the current message as a plist.
1637
1638 Some useful entries are:
1639 :headers - Property list containing the headers :Date, :Subject, :From, etc.
1640 :body - Body of the message
1641 :tags - Tags for this message"
1642   (save-excursion
1643     (notmuch-show-move-to-message-top)
1644     (get-text-property (point) :notmuch-message-properties)))
1645
1646 (defun notmuch-show-get-part-properties ()
1647   "Return the properties of the innermost part containing point.
1648
1649 This is the part property list retrieved from the CLI.  Signals
1650 an error if there is no part containing point."
1651   (or (get-text-property (point) :notmuch-part)
1652       (error "No message part here")))
1653
1654 (defun notmuch-show-set-prop (prop val &optional props)
1655   (let ((inhibit-read-only t)
1656         (props (or props
1657                    (notmuch-show-get-message-properties))))
1658     (plist-put props prop val)
1659     (notmuch-show-set-message-properties props)))
1660
1661 (defun notmuch-show-get-prop (prop &optional props)
1662   "Get property PROP from current message in show or tree mode.
1663
1664 It gets property PROP from PROPS or, if PROPS is nil, the current
1665 message in either tree or show. This means that several utility
1666 functions in notmuch-show can be used directly by notmuch-tree as
1667 they just need the correct message properties."
1668   (let ((props (or props
1669                    (cond ((eq major-mode 'notmuch-show-mode)
1670                           (notmuch-show-get-message-properties))
1671                          ((eq major-mode 'notmuch-tree-mode)
1672                           (notmuch-tree-get-message-properties))
1673                          (t nil)))))
1674     (plist-get props prop)))
1675
1676 (defun notmuch-show-get-message-id (&optional bare)
1677   "Return an id: query for the Message-Id of the current message.
1678
1679 If optional argument BARE is non-nil, return
1680 the Message-Id without id: prefix and escaping."
1681   (if bare
1682       (notmuch-show-get-prop :id)
1683     (notmuch-id-to-query (notmuch-show-get-prop :id))))
1684
1685 (defun notmuch-show-get-messages-ids ()
1686   "Return all id: queries of messages in the current thread."
1687   (let ((message-ids))
1688     (notmuch-show-mapc
1689      (lambda () (push (notmuch-show-get-message-id) message-ids)))
1690     message-ids))
1691
1692 (defun notmuch-show-get-messages-ids-search ()
1693   "Return a search string for all message ids of messages in the
1694 current thread."
1695   (mapconcat 'identity (notmuch-show-get-messages-ids) " or "))
1696
1697 ;; dme: Would it make sense to use a macro for many of these?
1698
1699 ;; XXX TODO figure out what to do about multiple filenames
1700 (defun notmuch-show-get-filename ()
1701   "Return the filename of the current message."
1702   (car (notmuch-show-get-prop :filename)))
1703
1704 (defun notmuch-show-get-header (header &optional props)
1705   "Return the named header of the current message, if any."
1706   (plist-get (notmuch-show-get-prop :headers props) header))
1707
1708 (defun notmuch-show-get-cc ()
1709   (notmuch-show-get-header :Cc))
1710
1711 (defun notmuch-show-get-date ()
1712   (notmuch-show-get-header :Date))
1713
1714 (defun notmuch-show-get-timestamp ()
1715   (notmuch-show-get-prop :timestamp))
1716
1717 (defun notmuch-show-get-from ()
1718   (notmuch-show-get-header :From))
1719
1720 (defun notmuch-show-get-subject ()
1721   (notmuch-show-get-header :Subject))
1722
1723 (defun notmuch-show-get-to ()
1724   (notmuch-show-get-header :To))
1725
1726 (defun notmuch-show-get-depth ()
1727   (notmuch-show-get-prop :depth))
1728
1729 (defun notmuch-show-set-tags (tags)
1730   "Set the tags of the current message."
1731   (notmuch-show-set-prop :tags tags)
1732   (notmuch-show-update-tags tags))
1733
1734 (defun notmuch-show-get-tags ()
1735   "Return the tags of the current message."
1736   (notmuch-show-get-prop :tags))
1737
1738 (defun notmuch-show-message-visible-p ()
1739   "Is the current message visible?"
1740   (notmuch-show-get-prop :message-visible))
1741
1742 (defun notmuch-show-headers-visible-p ()
1743   "Are the headers of the current message visible?"
1744   (notmuch-show-get-prop :headers-visible))
1745
1746 (put 'notmuch-show-mark-read 'notmuch-prefix-doc
1747      "Mark the current message as unread.")
1748 (defun notmuch-show-mark-read (&optional unread)
1749   "Mark the current message as read.
1750
1751 Mark the current message as read by applying the tag changes in
1752 `notmuch-show-mark-read-tags' to it (remove the \"unread\" tag by
1753 default). If a prefix argument is given, the message will be
1754 marked as unread, i.e. the tag changes in
1755 `notmuch-show-mark-read-tags' will be reversed."
1756   (interactive "P")
1757   (when notmuch-show-mark-read-tags
1758     (apply 'notmuch-show-tag-message
1759            (notmuch-tag-change-list notmuch-show-mark-read-tags unread))))
1760
1761 (defun notmuch-show-seen-current-message (start end)
1762   "Mark the current message read if it is open.
1763
1764 We only mark it read once: if it is changed back then that is a
1765 user decision and we should not override it."
1766   (when (and (notmuch-show-message-visible-p)
1767              (not (notmuch-show-get-prop :seen)))
1768         (notmuch-show-mark-read)
1769         (notmuch-show-set-prop :seen t)))
1770
1771 (defvar notmuch-show--seen-has-errored nil)
1772 (make-variable-buffer-local 'notmuch-show--seen-has-errored)
1773
1774 (defun notmuch-show-command-hook ()
1775   (when (eq major-mode 'notmuch-show-mode)
1776     ;; We need to redisplay to get window-start and window-end correct.
1777     (redisplay)
1778     (save-excursion
1779       (condition-case err
1780           (funcall notmuch-show-mark-read-function (window-start) (window-end))
1781         ((debug error)
1782          (unless notmuch-show--seen-has-errored
1783            (setq notmuch-show--seen-has-errored 't)
1784            (setq header-line-format
1785                  (concat header-line-format
1786                          (propertize "  [some mark read tag changes may have failed]"
1787                                      'face font-lock-warning-face)))))))))
1788
1789 (defun notmuch-show-filter-thread (query)
1790   "Filter or LIMIT the current thread based on a new query string.
1791
1792 Reshows the current thread with matches defined by the new query-string."
1793   (interactive (list (notmuch-read-query "Filter thread: ")))
1794   (let ((msg-id (notmuch-show-get-message-id)))
1795     (setq notmuch-show-query-context (if (string= query "") nil query))
1796     (notmuch-show-refresh-view t)
1797     (notmuch-show-goto-message msg-id)))
1798
1799 ;; Functions for getting attributes of several messages in the current
1800 ;; thread.
1801
1802 (defun notmuch-show-get-message-ids-for-open-messages ()
1803   "Return a list of all id: queries for open messages in the current thread."
1804   (save-excursion
1805     (let (message-ids done)
1806       (goto-char (point-min))
1807       (while (not done)
1808         (if (notmuch-show-message-visible-p)
1809             (setq message-ids (append message-ids (list (notmuch-show-get-message-id)))))
1810         (setq done (not (notmuch-show-goto-message-next)))
1811         )
1812       message-ids
1813       )))
1814
1815 ;; Commands typically bound to keys.
1816
1817 (defun notmuch-show-advance ()
1818   "Advance through thread.
1819
1820 If the current message in the thread is not yet fully visible,
1821 scroll by a near screenful to read more of the message.
1822
1823 Otherwise, (the end of the current message is already within the
1824 current window), advance to the next open message."
1825   (interactive)
1826   (let* ((end-of-this-message (notmuch-show-message-bottom))
1827          (visible-end-of-this-message (1- end-of-this-message))
1828          (ret nil))
1829     (while (invisible-p visible-end-of-this-message)
1830       (setq visible-end-of-this-message
1831             (max (point-min)
1832                  (1- (previous-single-char-property-change
1833                       visible-end-of-this-message 'invisible)))))
1834     (cond
1835      ;; Ideally we would test `end-of-this-message' against the result
1836      ;; of `window-end', but that doesn't account for the fact that
1837      ;; the end of the message might be hidden.
1838      ((and visible-end-of-this-message
1839            (> visible-end-of-this-message (window-end)))
1840       ;; The bottom of this message is not visible - scroll.
1841       (scroll-up nil))
1842
1843      ((not (= end-of-this-message (point-max)))
1844       ;; This is not the last message - move to the next visible one.
1845       (notmuch-show-next-open-message))
1846
1847      ((not (= (point) (point-max)))
1848       ;; This is the last message, but the cursor is not at the end of
1849       ;; the buffer. Move it there.
1850       (goto-char (point-max)))
1851
1852      (t
1853       ;; This is the last message - change the return value
1854       (setq ret t)))
1855     ret))
1856
1857 (defun notmuch-show-advance-and-archive ()
1858   "Advance through thread and archive.
1859
1860 This command is intended to be one of the simplest ways to
1861 process a thread of email. It works exactly like
1862 notmuch-show-advance, in that it scrolls through messages in a
1863 show buffer, except that when it gets to the end of the buffer it
1864 archives the entire current thread, (apply changes in
1865 `notmuch-archive-tags'), kills the buffer, and displays the next
1866 thread from the search from which this thread was originally
1867 shown."
1868   (interactive)
1869   (if (notmuch-show-advance)
1870       (notmuch-show-archive-thread-then-next)))
1871
1872 (defun notmuch-show-rewind ()
1873   "Backup through the thread (reverse scrolling compared to \\[notmuch-show-advance-and-archive]).
1874
1875 Specifically, if the beginning of the previous email is fewer
1876 than `window-height' lines from the current point, move to it
1877 just like `notmuch-show-previous-message'.
1878
1879 Otherwise, just scroll down a screenful of the current message.
1880
1881 This command does not modify any message tags, (it does not undo
1882 any effects from previous calls to
1883 `notmuch-show-advance-and-archive'."
1884   (interactive)
1885   (let ((start-of-message (notmuch-show-message-top))
1886         (start-of-window (window-start)))
1887     (cond
1888       ;; Either this message is properly aligned with the start of the
1889       ;; window or the start of this message is not visible on the
1890       ;; screen - scroll.
1891      ((or (= start-of-message start-of-window)
1892           (< start-of-message start-of-window))
1893       (scroll-down)
1894       ;; If a small number of lines from the previous message are
1895       ;; visible, realign so that the top of the current message is at
1896       ;; the top of the screen.
1897       (when (<= (count-screen-lines (window-start) start-of-message)
1898                 next-screen-context-lines)
1899         (goto-char (notmuch-show-message-top))
1900         (notmuch-show-message-adjust))
1901       ;; Move to the top left of the window.
1902       (goto-char (window-start)))
1903      (t
1904       ;; Move to the previous message.
1905       (notmuch-show-previous-message)))))
1906
1907 (put 'notmuch-show-reply 'notmuch-prefix-doc "... and prompt for sender")
1908 (defun notmuch-show-reply (&optional prompt-for-sender)
1909   "Reply to the sender and all recipients of the current message."
1910   (interactive "P")
1911   (notmuch-mua-new-reply (notmuch-show-get-message-id) prompt-for-sender t))
1912
1913 (put 'notmuch-show-reply-sender 'notmuch-prefix-doc "... and prompt for sender")
1914 (defun notmuch-show-reply-sender (&optional prompt-for-sender)
1915   "Reply to the sender of the current message."
1916   (interactive "P")
1917   (notmuch-mua-new-reply (notmuch-show-get-message-id) prompt-for-sender nil))
1918
1919 (put 'notmuch-show-forward-message 'notmuch-prefix-doc
1920      "... and prompt for sender")
1921 (defun notmuch-show-forward-message (&optional prompt-for-sender)
1922   "Forward the current message."
1923   (interactive "P")
1924   (notmuch-mua-new-forward-messages (list (notmuch-show-get-message-id))
1925                                     prompt-for-sender))
1926
1927 (put 'notmuch-show-forward-open-messages 'notmuch-prefix-doc
1928      "... and prompt for sender")
1929 (defun notmuch-show-forward-open-messages (&optional prompt-for-sender)
1930   "Forward the currently open messages."
1931   (interactive "P")
1932   (let ((open-messages (notmuch-show-get-message-ids-for-open-messages)))
1933     (unless open-messages
1934       (error "No open messages to forward."))
1935     (notmuch-mua-new-forward-messages open-messages prompt-for-sender)))
1936
1937 (defun notmuch-show-resend-message (addresses)
1938   "Resend the current message."
1939   (interactive (list (notmuch-address-from-minibuffer "Resend to: ")))
1940   (when (y-or-n-p (concat "Confirm resend to " addresses " "))
1941     (notmuch-show-view-raw-message)
1942     (message-resend addresses)
1943     (notmuch-bury-or-kill-this-buffer)))
1944
1945 (defun notmuch-show-next-message (&optional pop-at-end)
1946   "Show the next message.
1947
1948 If a prefix argument is given and this is the last message in the
1949 thread, navigate to the next thread in the parent search buffer."
1950   (interactive "P")
1951   (if (notmuch-show-goto-message-next)
1952       (notmuch-show-message-adjust)
1953     (if pop-at-end
1954         (notmuch-show-next-thread)
1955       (goto-char (point-max)))))
1956
1957 (defun notmuch-show-previous-message ()
1958   "Show the previous message or the start of the current message."
1959   (interactive)
1960   (if (= (point) (notmuch-show-message-top))
1961       (notmuch-show-goto-message-previous)
1962     (notmuch-show-move-to-message-top))
1963   (notmuch-show-message-adjust))
1964
1965 (defun notmuch-show-next-open-message (&optional pop-at-end)
1966   "Show the next open message.
1967
1968 If a prefix argument is given and this is the last open message
1969 in the thread, navigate to the next thread in the parent search
1970 buffer. Return t if there was a next open message in the thread
1971 to show, nil otherwise."
1972   (interactive "P")
1973   (let (r)
1974     (while (and (setq r (notmuch-show-goto-message-next))
1975                 (not (notmuch-show-message-visible-p))))
1976     (if r
1977         (notmuch-show-message-adjust)
1978       (if pop-at-end
1979           (notmuch-show-next-thread)
1980         (goto-char (point-max))))
1981     r))
1982
1983 (defun notmuch-show-next-matching-message ()
1984   "Show the next matching message."
1985   (interactive)
1986   (let (r)
1987     (while (and (setq r (notmuch-show-goto-message-next))
1988                 (not (notmuch-show-get-prop :match))))
1989     (if r
1990         (notmuch-show-message-adjust)
1991       (goto-char (point-max)))))
1992
1993 (defun notmuch-show-open-if-matched ()
1994   "Open a message if it is matched (whether or not excluded)."
1995   (let ((props (notmuch-show-get-message-properties)))
1996     (notmuch-show-message-visible props (plist-get props :match))))
1997
1998 (defun notmuch-show-goto-first-wanted-message ()
1999   "Move to the first open message and mark it read"
2000   (goto-char (point-min))
2001   (unless (notmuch-show-message-visible-p)
2002     (notmuch-show-next-open-message))
2003   (when (eobp)
2004     ;; There are no matched non-excluded messages so open all matched
2005     ;; (necessarily excluded) messages and go to the first.
2006     (notmuch-show-mapc 'notmuch-show-open-if-matched)
2007     (force-window-update)
2008     (goto-char (point-min))
2009     (unless (notmuch-show-message-visible-p)
2010       (notmuch-show-next-open-message))))
2011
2012 (defun notmuch-show-previous-open-message ()
2013   "Show the previous open message."
2014   (interactive)
2015   (while (and (if (= (point) (notmuch-show-message-top))
2016                   (notmuch-show-goto-message-previous)
2017                 (notmuch-show-move-to-message-top))
2018               (not (notmuch-show-message-visible-p))))
2019   (notmuch-show-message-adjust))
2020
2021 (defun notmuch-show-view-raw-message ()
2022   "View the original source of the current message."
2023   (interactive)
2024   (let* ((id (notmuch-show-get-message-id))
2025          (buf (get-buffer-create (concat "*notmuch-raw-" id "*")))
2026          (inhibit-read-only t))
2027     (switch-to-buffer buf)
2028     (erase-buffer)
2029     (let ((coding-system-for-read 'no-conversion))
2030       (call-process notmuch-command nil t nil "show" "--format=raw" id))
2031     (goto-char (point-min))
2032     (set-buffer-modified-p nil)
2033     (setq buffer-read-only t)
2034     (view-buffer buf 'kill-buffer-if-not-modified)))
2035
2036 (defun notmuch-show-resume-message ()
2037   "Resume EDITING the current draft message."
2038   (interactive)
2039   (notmuch-draft-resume (notmuch-show-get-message-id)))
2040
2041 (put 'notmuch-show-pipe-message 'notmuch-doc
2042      "Pipe the contents of the current message to a command.")
2043 (put 'notmuch-show-pipe-message 'notmuch-prefix-doc
2044      "Pipe the thread as an mbox to a command.")
2045 (defun notmuch-show-pipe-message (entire-thread command)
2046   "Pipe the contents of the current message (or thread) to COMMAND.
2047
2048 COMMAND will be executed with the raw contents of the current
2049 email message as stdin. Anything printed by the command to stdout
2050 or stderr will appear in the *notmuch-pipe* buffer.
2051
2052 If ENTIRE-THREAD is non-nil (or when invoked with a prefix
2053 argument), COMMAND will receive all open messages in the current
2054 thread (formatted as an mbox) rather than only the current
2055 message."
2056   (interactive (let ((query-string (if current-prefix-arg
2057                                        "Pipe all open messages to command: "
2058                                      "Pipe message to command: ")))
2059                  (list current-prefix-arg (read-string query-string))))
2060   (let (shell-command)
2061     (if entire-thread
2062         (setq shell-command
2063               (concat notmuch-command " show --format=mbox --exclude=false "
2064                       (shell-quote-argument
2065                        (mapconcat 'identity (notmuch-show-get-message-ids-for-open-messages) " OR "))
2066                       " | " command))
2067       (setq shell-command
2068             (concat notmuch-command " show --format=raw "
2069                     (shell-quote-argument (notmuch-show-get-message-id)) " | " command)))
2070     (let ((cwd default-directory)
2071           (buf (get-buffer-create (concat "*notmuch-pipe*"))))
2072       (with-current-buffer buf
2073         (setq buffer-read-only nil)
2074         (erase-buffer)
2075         ;; Use the originating buffer's working directory instead of
2076         ;; that of the pipe buffer.
2077         (cd cwd)
2078         (let ((exit-code (call-process-shell-command shell-command nil buf)))
2079           (goto-char (point-max))
2080           (set-buffer-modified-p nil)
2081           (setq buffer-read-only t)
2082           (unless (zerop exit-code)
2083             (switch-to-buffer-other-window buf)
2084             (message (format "Command '%s' exited abnormally with code %d"
2085                              shell-command exit-code))))))))
2086
2087 (defun notmuch-show-tag-message (&rest tag-changes)
2088   "Change tags for the current message.
2089
2090 TAG-CHANGES is a list of tag operations for `notmuch-tag'."
2091   (let* ((current-tags (notmuch-show-get-tags))
2092          (new-tags (notmuch-update-tags current-tags tag-changes)))
2093     (unless (equal current-tags new-tags)
2094       (notmuch-tag (notmuch-show-get-message-id) tag-changes)
2095       (notmuch-show-set-tags new-tags))))
2096
2097 (defun notmuch-show-tag (tag-changes)
2098   "Change tags for the current message.
2099
2100 See `notmuch-tag' for information on the format of TAG-CHANGES."
2101   (interactive (list (notmuch-read-tag-changes (notmuch-show-get-tags)
2102                                                "Tag message")))
2103   (notmuch-tag (notmuch-show-get-message-id) tag-changes)
2104   (let* ((current-tags (notmuch-show-get-tags))
2105          (new-tags (notmuch-update-tags current-tags tag-changes)))
2106     (unless (equal current-tags new-tags)
2107       (notmuch-show-set-tags new-tags))))
2108
2109 (defun notmuch-show-tag-all (tag-changes)
2110   "Change tags for all messages in the current show buffer.
2111
2112 See `notmuch-tag' for information on the format of TAG-CHANGES."
2113   (interactive
2114    (list (let (tags)
2115            (notmuch-show-mapc
2116             (lambda () (setq tags (append (notmuch-show-get-tags) tags))))
2117            (notmuch-read-tag-changes tags "Tag thread"))))
2118   (notmuch-tag (notmuch-show-get-messages-ids-search) tag-changes)
2119   (notmuch-show-mapc
2120    (lambda ()
2121      (let* ((current-tags (notmuch-show-get-tags))
2122             (new-tags (notmuch-update-tags current-tags tag-changes)))
2123        (unless (equal current-tags new-tags)
2124          (notmuch-show-set-tags new-tags))))))
2125
2126 (defun notmuch-show-add-tag (tag-changes)
2127   "Change tags for the current message (defaulting to add).
2128
2129 Same as `notmuch-show-tag' but sets initial input to '+'."
2130   (interactive
2131    (list (notmuch-read-tag-changes (notmuch-show-get-tags) "Tag message" "+")))
2132   (notmuch-show-tag tag-changes))
2133
2134 (defun notmuch-show-remove-tag (tag-changes)
2135   "Change tags for the current message (defaulting to remove).
2136
2137 Same as `notmuch-show-tag' but sets initial input to '-'."
2138   (interactive
2139    (list (notmuch-read-tag-changes (notmuch-show-get-tags) "Tag message" "-")))
2140   (notmuch-show-tag tag-changes))
2141
2142 (defun notmuch-show-toggle-visibility-headers ()
2143   "Toggle the visibility of the current message headers."
2144   (interactive)
2145   (let ((props (notmuch-show-get-message-properties)))
2146     (notmuch-show-headers-visible
2147      props
2148      (not (plist-get props :headers-visible))))
2149   (force-window-update))
2150
2151 (defun notmuch-show-toggle-message ()
2152   "Toggle the visibility of the current message."
2153   (interactive)
2154   (let ((props (notmuch-show-get-message-properties)))
2155     (notmuch-show-message-visible
2156      props
2157      (not (plist-get props :message-visible))))
2158   (force-window-update))
2159
2160 (put 'notmuch-show-open-or-close-all 'notmuch-doc "Show all messages.")
2161 (put 'notmuch-show-open-or-close-all 'notmuch-prefix-doc "Hide all messages.")
2162 (defun notmuch-show-open-or-close-all ()
2163   "Set the visibility all of the messages in the current thread.
2164
2165 By default make all of the messages visible. With a prefix
2166 argument, hide all of the messages."
2167   (interactive)
2168   (save-excursion
2169     (goto-char (point-min))
2170     (loop do (notmuch-show-message-visible (notmuch-show-get-message-properties)
2171                                            (not current-prefix-arg))
2172           until (not (notmuch-show-goto-message-next))))
2173   (force-window-update))
2174
2175 (defun notmuch-show-next-button ()
2176   "Advance point to the next button in the buffer."
2177   (interactive)
2178   (forward-button 1))
2179
2180 (defun notmuch-show-previous-button ()
2181   "Move point back to the previous button in the buffer."
2182   (interactive)
2183   (backward-button 1))
2184
2185 (defun notmuch-show-next-thread (&optional show previous)
2186   "Move to the next item in the search results, if any.
2187
2188 If SHOW is non-nil, open the next item in a show
2189 buffer. Otherwise just highlight the next item in the search
2190 buffer. If PREVIOUS is non-nil, move to the previous item in the
2191 search results instead."
2192   (interactive "P")
2193   (let ((parent-buffer notmuch-show-parent-buffer))
2194     (notmuch-bury-or-kill-this-buffer)
2195     (when (buffer-live-p parent-buffer)
2196       (switch-to-buffer parent-buffer)
2197       (and (if previous
2198                (notmuch-search-previous-thread)
2199              (notmuch-search-next-thread))
2200            show
2201            (notmuch-search-show-thread)))))
2202
2203 (defun notmuch-show-next-thread-show ()
2204   "Show the next thread in the search results, if any."
2205   (interactive)
2206   (notmuch-show-next-thread t))
2207
2208 (defun notmuch-show-previous-thread-show ()
2209   "Show the previous thread in the search results, if any."
2210   (interactive)
2211   (notmuch-show-next-thread t t))
2212
2213 (put 'notmuch-show-archive-thread 'notmuch-prefix-doc
2214      "Un-archive each message in thread.")
2215 (defun notmuch-show-archive-thread (&optional unarchive)
2216   "Archive each message in thread.
2217
2218 Archive each message currently shown by applying the tag changes
2219 in `notmuch-archive-tags' to each. If a prefix argument is given,
2220 the messages will be \"unarchived\", i.e. the tag changes in
2221 `notmuch-archive-tags' will be reversed.
2222
2223 Note: This command is safe from any race condition of new messages
2224 being delivered to the same thread. It does not archive the
2225 entire thread, but only the messages shown in the current
2226 buffer."
2227   (interactive "P")
2228   (when notmuch-archive-tags
2229     (notmuch-show-tag-all
2230      (notmuch-tag-change-list notmuch-archive-tags unarchive))))
2231
2232 (defun notmuch-show-archive-thread-then-next ()
2233   "Archive all messages in the current buffer, then show next thread from search."
2234   (interactive)
2235   (notmuch-show-archive-thread)
2236   (notmuch-show-next-thread t))
2237
2238 (defun notmuch-show-archive-thread-then-exit ()
2239   "Archive all messages in the current buffer, then exit back to search results."
2240   (interactive)
2241   (notmuch-show-archive-thread)
2242   (notmuch-show-next-thread))
2243
2244 (put 'notmuch-show-archive-message 'notmuch-prefix-doc
2245      "Un-archive the current message.")
2246 (defun notmuch-show-archive-message (&optional unarchive)
2247   "Archive the current message.
2248
2249 Archive the current message by applying the tag changes in
2250 `notmuch-archive-tags' to it. If a prefix argument is given, the
2251 message will be \"unarchived\", i.e. the tag changes in
2252 `notmuch-archive-tags' will be reversed."
2253   (interactive "P")
2254   (when notmuch-archive-tags
2255     (apply 'notmuch-show-tag-message
2256            (notmuch-tag-change-list notmuch-archive-tags unarchive))))
2257
2258 (defun notmuch-show-archive-message-then-next-or-exit ()
2259   "Archive current message, then show next open message in current thread.
2260
2261 If at the last open message in the current thread, then exit back
2262 to search results."
2263   (interactive)
2264   (notmuch-show-archive-message)
2265   (notmuch-show-next-open-message t))
2266
2267 (defun notmuch-show-archive-message-then-next-or-next-thread ()
2268   "Archive current message, then show next open message in current or next thread.
2269
2270 If at the last open message in the current thread, then show next
2271 thread from search."
2272   (interactive)
2273   (notmuch-show-archive-message)
2274   (unless (notmuch-show-next-open-message)
2275     (notmuch-show-next-thread t)))
2276
2277 (defun notmuch-show-stash-cc ()
2278   "Copy CC field of current message to kill-ring."
2279   (interactive)
2280   (notmuch-common-do-stash (notmuch-show-get-cc)))
2281
2282 (put 'notmuch-show-stash-date 'notmuch-prefix-doc
2283      "Copy timestamp of current message to kill-ring.")
2284 (defun notmuch-show-stash-date (&optional stash-timestamp)
2285   "Copy date of current message to kill-ring.
2286
2287 If invoked with a prefix argument, copy timestamp of current
2288 message to kill-ring."
2289   (interactive "P")
2290   (if stash-timestamp
2291       (notmuch-common-do-stash (format "%d" (notmuch-show-get-timestamp)))
2292     (notmuch-common-do-stash (notmuch-show-get-date))))
2293
2294 (defun notmuch-show-stash-filename ()
2295   "Copy filename of current message to kill-ring."
2296   (interactive)
2297   (notmuch-common-do-stash (notmuch-show-get-filename)))
2298
2299 (defun notmuch-show-stash-from ()
2300   "Copy From address of current message to kill-ring."
2301   (interactive)
2302   (notmuch-common-do-stash (notmuch-show-get-from)))
2303
2304 (put 'notmuch-show-stash-message-id 'notmuch-prefix-doc
2305      "Copy thread: query matching current thread to kill-ring.")
2306 (defun notmuch-show-stash-message-id (&optional stash-thread-id)
2307   "Copy id: query matching the current message to kill-ring.
2308
2309 If invoked with a prefix argument (or STASH-THREAD-ID is
2310 non-nil), copy thread: query matching the current thread to
2311 kill-ring."
2312   (interactive "P")
2313   (if stash-thread-id
2314       (notmuch-common-do-stash notmuch-show-thread-id)
2315     (notmuch-common-do-stash (notmuch-show-get-message-id))))
2316
2317 (defun notmuch-show-stash-message-id-stripped ()
2318   "Copy message ID of current message (sans `id:' prefix) to kill-ring."
2319   (interactive)
2320   (notmuch-common-do-stash (notmuch-show-get-message-id t)))
2321
2322 (defun notmuch-show-stash-subject ()
2323   "Copy Subject field of current message to kill-ring."
2324   (interactive)
2325   (notmuch-common-do-stash (notmuch-show-get-subject)))
2326
2327 (defun notmuch-show-stash-tags ()
2328   "Copy tags of current message to kill-ring as a comma separated list."
2329   (interactive)
2330   (notmuch-common-do-stash (mapconcat 'identity (notmuch-show-get-tags) ",")))
2331
2332 (defun notmuch-show-stash-to ()
2333   "Copy To address of current message to kill-ring."
2334   (interactive)
2335   (notmuch-common-do-stash (notmuch-show-get-to)))
2336
2337 (defun notmuch-show-stash-mlarchive-link (&optional mla)
2338   "Copy an ML Archive URI for the current message to the kill-ring.
2339
2340 This presumes that the message is available at the selected Mailing List Archive.
2341
2342 If optional argument MLA is non-nil, use the provided key instead of prompting
2343 the user (see `notmuch-show-stash-mlarchive-link-alist')."
2344   (interactive)
2345   (let ((url (cdr (assoc
2346                    (or mla
2347                        (let ((completion-ignore-case t))
2348                          (completing-read
2349                           "Mailing List Archive: "
2350                           notmuch-show-stash-mlarchive-link-alist
2351                           nil t nil nil
2352                           notmuch-show-stash-mlarchive-link-default)))
2353                    notmuch-show-stash-mlarchive-link-alist))))
2354     (notmuch-common-do-stash
2355      (if (functionp url)
2356          (funcall url (notmuch-show-get-message-id t))
2357        (concat url (notmuch-show-get-message-id t))))))
2358
2359 (defun notmuch-show-stash-mlarchive-link-and-go (&optional mla)
2360   "Copy an ML Archive URI for the current message to the kill-ring and visit it.
2361
2362 This presumes that the message is available at the selected Mailing List Archive.
2363
2364 If optional argument MLA is non-nil, use the provided key instead of prompting
2365 the user (see `notmuch-show-stash-mlarchive-link-alist')."
2366   (interactive)
2367   (notmuch-show-stash-mlarchive-link mla)
2368   (browse-url (current-kill 0 t)))
2369
2370 (defun notmuch-show-stash-git-helper (addresses prefix)
2371   "Escape, trim, quote, and add PREFIX to each address in list of ADDRESSES, and return the result as a single string."
2372   (mapconcat (lambda (x)
2373                (concat prefix "\""
2374                        ;; escape double-quotes
2375                        (replace-regexp-in-string
2376                         "\"" "\\\\\""
2377                         ;; trim leading and trailing spaces
2378                         (replace-regexp-in-string
2379                          "\\(^ *\\| *$\\)" ""
2380                          x)) "\""))
2381              addresses " "))
2382
2383 (put 'notmuch-show-stash-git-send-email 'notmuch-prefix-doc
2384      "Copy From/To/Cc of current message to kill-ring in a form suitable for pasting to git send-email command line.")
2385
2386 (defun notmuch-show-stash-git-send-email (&optional no-in-reply-to)
2387   "Copy From/To/Cc/Message-Id of current message to kill-ring in a form suitable for pasting to git send-email command line.
2388
2389 If invoked with a prefix argument (or NO-IN-REPLY-TO is non-nil),
2390 omit --in-reply-to=<Message-Id>."
2391   (interactive "P")
2392   (notmuch-common-do-stash
2393    (mapconcat 'identity
2394               (remove ""
2395                       (list
2396                        (notmuch-show-stash-git-helper
2397                         (message-tokenize-header (notmuch-show-get-from)) "--to=")
2398                        (notmuch-show-stash-git-helper
2399                         (message-tokenize-header (notmuch-show-get-to)) "--to=")
2400                        (notmuch-show-stash-git-helper
2401                         (message-tokenize-header (notmuch-show-get-cc)) "--cc=")
2402                        (unless no-in-reply-to
2403                          (notmuch-show-stash-git-helper
2404                           (list (notmuch-show-get-message-id t)) "--in-reply-to="))))
2405               " ")))
2406
2407 ;; Interactive part functions and their helpers
2408
2409 (defun notmuch-show-generate-part-buffer (msg part)
2410   "Return a temporary buffer containing the specified part's content."
2411   (let ((buf (generate-new-buffer " *notmuch-part*"))
2412         (process-crypto notmuch-show-process-crypto))
2413     (with-current-buffer buf
2414       ;; This is always used in the content of mm handles, which
2415       ;; expect undecoded, binary part content.
2416       (insert (notmuch-get-bodypart-binary msg part process-crypto)))
2417     buf))
2418
2419 (defun notmuch-show-current-part-handle (&optional mime-type)
2420   "Return an mm-handle for the part containing point.
2421
2422 This creates a temporary buffer for the part's content; the
2423 caller is responsible for killing this buffer as appropriate.  If
2424 MIME-TYPE is given then set the handle's mime-type to MIME-TYPE."
2425   (let* ((msg (notmuch-show-get-message-properties))
2426          (part (notmuch-show-get-part-properties))
2427          (buf (notmuch-show-generate-part-buffer msg part))
2428          (computed-type (or mime-type (plist-get part :computed-type)))
2429          (filename (plist-get part :filename))
2430          (disposition (if filename `(attachment (filename . ,filename)))))
2431     (mm-make-handle buf (list computed-type) nil nil disposition)))
2432
2433 (defun notmuch-show-apply-to-current-part-handle (fn &optional mime-type)
2434   "Apply FN to an mm-handle for the part containing point.
2435
2436 This ensures that the temporary buffer created for the mm-handle
2437 is destroyed when FN returns. If MIME-TYPE is given then force
2438 part to be treated as if it had that mime-type."
2439   (let ((handle (notmuch-show-current-part-handle mime-type)))
2440     ;; emacs 24.3+ puts stdout/stderr into the calling buffer so we
2441     ;; call it from a temp-buffer, unless
2442     ;; notmuch-show-attachment-debug is non-nil in which case we put
2443     ;; it in " *notmuch-part*".
2444     (unwind-protect
2445         (if notmuch-show-attachment-debug
2446             (with-current-buffer (generate-new-buffer " *notmuch-part*")
2447               (funcall fn handle))
2448           (with-temp-buffer
2449             (funcall fn handle)))
2450       (kill-buffer (mm-handle-buffer handle)))))
2451
2452 (defun notmuch-show-part-button-default (&optional button)
2453   (interactive)
2454   (let ((button (or button (button-at (point)))))
2455     ;; Try to toggle the part, if that fails then call the default
2456     ;; action. The toggle fails if the part has no emacs renderable
2457     ;; content.
2458     (unless (notmuch-show-toggle-part-invisibility button)
2459       (call-interactively notmuch-show-part-button-default-action))))
2460
2461 (defun notmuch-show-save-part ()
2462   "Save the MIME part containing point to a file."
2463   (interactive)
2464   (notmuch-show-apply-to-current-part-handle #'mm-save-part))
2465
2466 (defun notmuch-show-view-part ()
2467   "View the MIME part containing point in an external viewer."
2468   (interactive)
2469   ;; Set mm-inlined-types to nil to force an external viewer
2470   (let ((mm-inlined-types nil))
2471     (notmuch-show-apply-to-current-part-handle #'mm-display-part)))
2472
2473 (defun notmuch-show-interactively-view-part ()
2474   "View the MIME part containing point, prompting for a viewer."
2475   (interactive)
2476   (notmuch-show-apply-to-current-part-handle #'mm-interactively-view-part))
2477
2478 (defun notmuch-show-pipe-part ()
2479   "Pipe the MIME part containing point to an external command."
2480   (interactive)
2481   (notmuch-show-apply-to-current-part-handle #'mm-pipe-part))
2482
2483
2484 (defun notmuch-show--mm-display-part (handle)
2485   "Use mm-display-part to display HANDLE in a new buffer.
2486
2487 If the part is displayed in an external application then close
2488 the new buffer."
2489   (let ((buf (get-buffer-create (generate-new-buffer-name
2490                                  (concat " *notmuch-internal-part*")))))
2491     (switch-to-buffer buf)
2492     (if (eq (mm-display-part handle) 'external)
2493         (kill-buffer buf)
2494       (goto-char (point-min))
2495       (set-buffer-modified-p nil)
2496       (view-buffer buf 'kill-buffer-if-not-modified))))
2497
2498 (defun notmuch-show-choose-mime-of-part (mime-type)
2499   "Choose the mime type to use for displaying part"
2500   (interactive
2501    (list (completing-read "Mime type to use (default text/plain): "
2502                           (mailcap-mime-types) nil nil nil nil "text/plain")))
2503   (notmuch-show-apply-to-current-part-handle #'notmuch-show--mm-display-part mime-type))
2504
2505 (defun notmuch-show-imenu-prev-index-position-function ()
2506   "Move point to previous message in notmuch-show buffer.
2507 This function is used as a value for
2508 `imenu-prev-index-position-function'."
2509   (if (bobp)
2510       nil
2511     (notmuch-show-previous-message)
2512     t))
2513
2514 (defun notmuch-show-imenu-extract-index-name-function ()
2515   "Return imenu name for line at point.
2516 This function is used as a value for
2517 `imenu-extract-index-name-function'.  Point should be at the
2518 beginning of the line."
2519   (back-to-indentation)
2520   (buffer-substring-no-properties (if notmuch-show-imenu-indent
2521                                       (line-beginning-position)
2522                                     (point))
2523                                   (line-end-position)))
2524
2525 (defmacro notmuch-show--with-currently-shown-message (&rest body)
2526   "Evaluate BODY with display restricted to the currently shown
2527 message."
2528   `(save-excursion
2529      (save-restriction
2530       (let ((extent (notmuch-show-message-extent)))
2531         (narrow-to-region (car extent) (cdr extent))
2532         ,@body))))
2533
2534 (defun notmuch-show--gather-urls ()
2535   "Gather any URLs in the current message."
2536   (notmuch-show--with-currently-shown-message
2537    (let (urls)
2538      (goto-char (point-min))
2539      (while (re-search-forward goto-address-url-regexp (point-max) t)
2540        (push (match-string-no-properties 0) urls))
2541      (reverse urls))))
2542
2543 (defun notmuch-show-browse-urls ()
2544   "Offer to browse any URLs in the current message."
2545   (interactive)
2546   (let ((urls (notmuch-show--gather-urls)))
2547     (if urls
2548         (browse-url (completing-read "Browse URL: " (cdr urls) nil nil (car urls)))
2549       (message "No URLs found."))))
2550
2551 (provide 'notmuch-show)
2552
2553 ;;; notmuch-show.el ends here