notmuch-mutt: replace shell pipeline with internal pipe processing
[notmuch] / emacs / rstdoc.el
1 ;;; rstdoc.el --- help generate documentation from docstrings -*-lexical-binding: t-*-
2
3 ;; Copyright (C) 2018 David Bremner
4
5 ;; Author: David Bremner <david@tethera.net>
6 ;; Created: 26 May 2018
7 ;; Keywords: emacs lisp, documentation
8 ;; Homepage: https://notmuchmail.org
9
10 ;; This file is not part of GNU Emacs.
11
12 ;; rstdoc.el is free software: you can redistribute it and/or modify it
13 ;; under the terms of the GNU General Public License as published by
14 ;; the Free Software Foundation, either version 3 of the License, or
15 ;; (at your option) any later version.
16 ;;
17 ;; rstdoc.el is distributed in the hope that it will be useful, but
18 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
20 ;; General Public License for more details.
21 ;;
22 ;; You should have received a copy of the GNU General Public License
23 ;; along with rstdoc.el.  If not, see <https://www.gnu.org/licenses/>.
24 ;;
25
26 ;;; Commentary:
27
28 ;; Rstdoc provides a facility to extract all of the docstrings defined in
29 ;; an elisp source file. Usage:
30 ;;
31 ;; emacs -Q --batch -L . -l rstdoc -f rstdoc-batch-extract foo.el foo.rsti
32
33 ;;; Code:
34
35 (defun rstdoc-batch-extract ()
36   "Extract docstrings to and from the files on the command line."
37   (apply #'rstdoc-extract command-line-args-left))
38
39 (defun rstdoc-extract (in-file out-file)
40   "Write docstrings from IN-FILE to OUT-FILE."
41   (load-file in-file)
42   (let* ((definitions (cdr (assoc (expand-file-name in-file) load-history)))
43          (doc-hash (make-hash-table :test 'eq)))
44     (mapc
45      (lambda (elt)
46        (let ((pair
47               (pcase elt
48                 (`(defun . ,name) (cons name (documentation name)))
49                 (`(,_ . ,_)  nil)
50                 (sym (cons sym (get sym 'variable-documentation))))))
51          (when (and pair (cdr pair))
52            (puthash (car pair) (cdr pair) doc-hash))))
53      definitions)
54     (with-temp-buffer
55       (maphash
56        (lambda (key val)
57          (rstdoc--insert-docstring key val))
58        doc-hash)
59       (write-region (point-min) (point-max) out-file))))
60
61 (defun rstdoc--insert-docstring (symbol docstring)
62   (insert (format "\n.. |docstring::%s| replace::\n" symbol))
63   (insert (replace-regexp-in-string "^" "    "
64                                     (rstdoc--rst-quote-string docstring)))
65   (insert "\n"))
66
67 (defvar rst--escape-alist
68   '(("\\\\='" . "\\\\'")
69     ("\\([^\\]\\)'" . "\\1`")
70     ("^[[:space:]\t]*$" . "|br|")
71     ("^[[:space:]\t]" . "|indent| "))
72   "List of (regex . replacement) pairs.")
73
74 (defun rstdoc--rst-quote-string (str)
75   (with-temp-buffer
76     (insert str)
77     (dolist (pair rst--escape-alist)
78       (goto-char (point-min))
79       (while (re-search-forward (car pair) nil t)
80         (replace-match (cdr pair))))
81     (buffer-substring (point-min) (point-max))))
82
83 (provide 'rstdoc)
84
85 ;;; rstdoc.el ends here